src/HOL/Power.thy
author paulson <lp15@cam.ac.uk>
Wed Apr 29 14:04:22 2015 +0100 (2015-04-29)
changeset 60155 91477b3a2d6b
parent 59867 58043346ca64
child 60685 cb21b7022b00
permissions -rw-r--r--
Tidying. Improved simplification for numerals, esp in exponents.
     1 (*  Title:      HOL/Power.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1997  University of Cambridge
     4 *)
     5 
     6 section {* Exponentiation *}
     7 
     8 theory Power
     9 imports Num Equiv_Relations
    10 begin
    11 
    12 subsection {* Powers for Arbitrary Monoids *}
    13 
    14 class power = one + times
    15 begin
    16 
    17 primrec power :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^" 80) where
    18     power_0: "a ^ 0 = 1"
    19   | power_Suc: "a ^ Suc n = a * a ^ n"
    20 
    21 notation (latex output)
    22   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    23 
    24 notation (HTML output)
    25   power ("(_\<^bsup>_\<^esup>)" [1000] 1000)
    26 
    27 text {* Special syntax for squares. *}
    28 
    29 abbreviation (xsymbols)
    30   power2 :: "'a \<Rightarrow> 'a"  ("(_\<^sup>2)" [1000] 999) where
    31   "x\<^sup>2 \<equiv> x ^ 2"
    32 
    33 notation (latex output)
    34   power2  ("(_\<^sup>2)" [1000] 999)
    35 
    36 notation (HTML output)
    37   power2  ("(_\<^sup>2)" [1000] 999)
    38 
    39 end
    40 
    41 context monoid_mult
    42 begin
    43 
    44 subclass power .
    45 
    46 lemma power_one [simp]:
    47   "1 ^ n = 1"
    48   by (induct n) simp_all
    49 
    50 lemma power_one_right [simp]:
    51   "a ^ 1 = a"
    52   by simp
    53 
    54 lemma power_Suc0_right [simp]:
    55   "a ^ Suc 0 = a"
    56   by simp
    57 
    58 lemma power_commutes:
    59   "a ^ n * a = a * a ^ n"
    60   by (induct n) (simp_all add: mult.assoc)
    61 
    62 lemma power_Suc2:
    63   "a ^ Suc n = a ^ n * a"
    64   by (simp add: power_commutes)
    65 
    66 lemma power_add:
    67   "a ^ (m + n) = a ^ m * a ^ n"
    68   by (induct m) (simp_all add: algebra_simps)
    69 
    70 lemma power_mult:
    71   "a ^ (m * n) = (a ^ m) ^ n"
    72   by (induct n) (simp_all add: power_add)
    73 
    74 lemma power2_eq_square: "a\<^sup>2 = a * a"
    75   by (simp add: numeral_2_eq_2)
    76 
    77 lemma power3_eq_cube: "a ^ 3 = a * a * a"
    78   by (simp add: numeral_3_eq_3 mult.assoc)
    79 
    80 lemma power_even_eq:
    81   "a ^ (2 * n) = (a ^ n)\<^sup>2"
    82   by (subst mult.commute) (simp add: power_mult)
    83 
    84 lemma power_odd_eq:
    85   "a ^ Suc (2*n) = a * (a ^ n)\<^sup>2"
    86   by (simp add: power_even_eq)
    87 
    88 lemma power_numeral_even:
    89   "z ^ numeral (Num.Bit0 w) = (let w = z ^ (numeral w) in w * w)"
    90   unfolding numeral_Bit0 power_add Let_def ..
    91 
    92 lemma power_numeral_odd:
    93   "z ^ numeral (Num.Bit1 w) = (let w = z ^ (numeral w) in z * w * w)"
    94   unfolding numeral_Bit1 One_nat_def add_Suc_right add_0_right
    95   unfolding power_Suc power_add Let_def mult.assoc ..
    96 
    97 lemma funpow_times_power:
    98   "(times x ^^ f x) = times (x ^ f x)"
    99 proof (induct "f x" arbitrary: f)
   100   case 0 then show ?case by (simp add: fun_eq_iff)
   101 next
   102   case (Suc n)
   103   def g \<equiv> "\<lambda>x. f x - 1"
   104   with Suc have "n = g x" by simp
   105   with Suc have "times x ^^ g x = times (x ^ g x)" by simp
   106   moreover from Suc g_def have "f x = g x + 1" by simp
   107   ultimately show ?case by (simp add: power_add funpow_add fun_eq_iff mult.assoc)
   108 qed
   109 
   110 lemma power_commuting_commutes:
   111   assumes "x * y = y * x"
   112   shows "x ^ n * y = y * x ^n"
   113 proof (induct n)
   114   case (Suc n)
   115   have "x ^ Suc n * y = x ^ n * y * x"
   116     by (subst power_Suc2) (simp add: assms ac_simps)
   117   also have "\<dots> = y * x ^ Suc n"
   118     unfolding Suc power_Suc2
   119     by (simp add: ac_simps)
   120   finally show ?case .
   121 qed simp
   122 
   123 end
   124 
   125 context comm_monoid_mult
   126 begin
   127 
   128 lemma power_mult_distrib [field_simps]:
   129   "(a * b) ^ n = (a ^ n) * (b ^ n)"
   130   by (induct n) (simp_all add: ac_simps)
   131 
   132 end
   133 
   134 text{*Extract constant factors from powers*}
   135 declare power_mult_distrib [where a = "numeral w" for w, simp]
   136 declare power_mult_distrib [where b = "numeral w" for w, simp]
   137 
   138 lemma power_add_numeral [simp]:
   139   fixes a :: "'a :: monoid_mult"
   140   shows "a^numeral m * a^numeral n = a^numeral (m + n)"
   141   by (simp add: power_add [symmetric])
   142 
   143 lemma power_add_numeral2 [simp]:
   144   fixes a :: "'a :: monoid_mult"
   145   shows "a^numeral m * (a^numeral n * b) = a^numeral (m + n) * b"
   146   by (simp add: mult.assoc [symmetric])
   147 
   148 lemma power_mult_numeral [simp]:
   149   fixes a :: "'a :: monoid_mult"
   150   shows"(a^numeral m)^numeral n = a^numeral (m * n)"
   151   by (simp only: numeral_mult power_mult)
   152 
   153 context semiring_numeral
   154 begin
   155 
   156 lemma numeral_sqr: "numeral (Num.sqr k) = numeral k * numeral k"
   157   by (simp only: sqr_conv_mult numeral_mult)
   158 
   159 lemma numeral_pow: "numeral (Num.pow k l) = numeral k ^ numeral l"
   160   by (induct l, simp_all only: numeral_class.numeral.simps pow.simps
   161     numeral_sqr numeral_mult power_add power_one_right)
   162 
   163 lemma power_numeral [simp]: "numeral k ^ numeral l = numeral (Num.pow k l)"
   164   by (rule numeral_pow [symmetric])
   165 
   166 end
   167 
   168 context semiring_1
   169 begin
   170 
   171 lemma of_nat_power:
   172   "of_nat (m ^ n) = of_nat m ^ n"
   173   by (induct n) (simp_all add: of_nat_mult)
   174 
   175 lemma zero_power:
   176   "0 < n \<Longrightarrow> 0 ^ n = 0"
   177   by (cases n) simp_all
   178 
   179 lemma power_zero_numeral [simp]:
   180   "0 ^ numeral k = 0"
   181   by (simp add: numeral_eq_Suc)
   182 
   183 lemma zero_power2: "0\<^sup>2 = 0" (* delete? *)
   184   by (rule power_zero_numeral)
   185 
   186 lemma one_power2: "1\<^sup>2 = 1" (* delete? *)
   187   by (rule power_one)
   188 
   189 end
   190 
   191 context comm_semiring_1
   192 begin
   193 
   194 text {* The divides relation *}
   195 
   196 lemma le_imp_power_dvd:
   197   assumes "m \<le> n" shows "a ^ m dvd a ^ n"
   198 proof
   199   have "a ^ n = a ^ (m + (n - m))"
   200     using `m \<le> n` by simp
   201   also have "\<dots> = a ^ m * a ^ (n - m)"
   202     by (rule power_add)
   203   finally show "a ^ n = a ^ m * a ^ (n - m)" .
   204 qed
   205 
   206 lemma power_le_dvd:
   207   "a ^ n dvd b \<Longrightarrow> m \<le> n \<Longrightarrow> a ^ m dvd b"
   208   by (rule dvd_trans [OF le_imp_power_dvd])
   209 
   210 lemma dvd_power_same:
   211   "x dvd y \<Longrightarrow> x ^ n dvd y ^ n"
   212   by (induct n) (auto simp add: mult_dvd_mono)
   213 
   214 lemma dvd_power_le:
   215   "x dvd y \<Longrightarrow> m \<ge> n \<Longrightarrow> x ^ n dvd y ^ m"
   216   by (rule power_le_dvd [OF dvd_power_same])
   217 
   218 lemma dvd_power [simp]:
   219   assumes "n > (0::nat) \<or> x = 1"
   220   shows "x dvd (x ^ n)"
   221 using assms proof
   222   assume "0 < n"
   223   then have "x ^ n = x ^ Suc (n - 1)" by simp
   224   then show "x dvd (x ^ n)" by simp
   225 next
   226   assume "x = 1"
   227   then show "x dvd (x ^ n)" by simp
   228 qed
   229 
   230 end
   231 
   232 context ring_1
   233 begin
   234 
   235 lemma power_minus:
   236   "(- a) ^ n = (- 1) ^ n * a ^ n"
   237 proof (induct n)
   238   case 0 show ?case by simp
   239 next
   240   case (Suc n) then show ?case
   241     by (simp del: power_Suc add: power_Suc2 mult.assoc)
   242 qed
   243 
   244 lemma power_minus_Bit0:
   245   "(- x) ^ numeral (Num.Bit0 k) = x ^ numeral (Num.Bit0 k)"
   246   by (induct k, simp_all only: numeral_class.numeral.simps power_add
   247     power_one_right mult_minus_left mult_minus_right minus_minus)
   248 
   249 lemma power_minus_Bit1:
   250   "(- x) ^ numeral (Num.Bit1 k) = - (x ^ numeral (Num.Bit1 k))"
   251   by (simp only: eval_nat_numeral(3) power_Suc power_minus_Bit0 mult_minus_left)
   252 
   253 lemma power2_minus [simp]:
   254   "(- a)\<^sup>2 = a\<^sup>2"
   255   by (rule power_minus_Bit0)
   256 
   257 lemma power_minus1_even [simp]:
   258   "(- 1) ^ (2*n) = 1"
   259 proof (induct n)
   260   case 0 show ?case by simp
   261 next
   262   case (Suc n) then show ?case by (simp add: power_add power2_eq_square)
   263 qed
   264 
   265 lemma power_minus1_odd:
   266   "(- 1) ^ Suc (2*n) = -1"
   267   by simp
   268 
   269 lemma power_minus_even [simp]:
   270   "(-a) ^ (2*n) = a ^ (2*n)"
   271   by (simp add: power_minus [of a])
   272 
   273 end
   274 
   275 lemma power_eq_0_nat_iff [simp]:
   276   fixes m n :: nat
   277   shows "m ^ n = 0 \<longleftrightarrow> m = 0 \<and> n > 0"
   278   by (induct n) auto
   279 
   280 context ring_1_no_zero_divisors
   281 begin
   282 
   283 lemma power_eq_0_iff [simp]:
   284   "a ^ n = 0 \<longleftrightarrow> a = 0 \<and> n > 0"
   285   by (induct n) auto
   286 
   287 lemma field_power_not_zero:
   288   "a \<noteq> 0 \<Longrightarrow> a ^ n \<noteq> 0"
   289   by (induct n) auto
   290 
   291 lemma zero_eq_power2 [simp]:
   292   "a\<^sup>2 = 0 \<longleftrightarrow> a = 0"
   293   unfolding power2_eq_square by simp
   294 
   295 lemma power2_eq_1_iff:
   296   "a\<^sup>2 = 1 \<longleftrightarrow> a = 1 \<or> a = - 1"
   297   unfolding power2_eq_square by (rule square_eq_1_iff)
   298 
   299 end
   300 
   301 context idom
   302 begin
   303 
   304 lemma power2_eq_iff: "x\<^sup>2 = y\<^sup>2 \<longleftrightarrow> x = y \<or> x = - y"
   305   unfolding power2_eq_square by (rule square_eq_iff)
   306 
   307 end
   308 
   309 context division_ring
   310 begin
   311 
   312 text {* FIXME reorient or rename to @{text nonzero_inverse_power} *}
   313 lemma nonzero_power_inverse:
   314   "a \<noteq> 0 \<Longrightarrow> inverse (a ^ n) = (inverse a) ^ n"
   315   by (induct n)
   316     (simp_all add: nonzero_inverse_mult_distrib power_commutes field_power_not_zero)
   317 
   318 end
   319 
   320 context field
   321 begin
   322 
   323 lemma nonzero_power_divide:
   324   "b \<noteq> 0 \<Longrightarrow> (a / b) ^ n = a ^ n / b ^ n"
   325   by (simp add: divide_inverse power_mult_distrib nonzero_power_inverse)
   326 
   327 declare nonzero_power_divide [where b = "numeral w" for w, simp]
   328 
   329 end
   330 
   331 
   332 subsection {* Exponentiation on ordered types *}
   333 
   334 context linordered_ring (* TODO: move *)
   335 begin
   336 
   337 lemma sum_squares_ge_zero:
   338   "0 \<le> x * x + y * y"
   339   by (intro add_nonneg_nonneg zero_le_square)
   340 
   341 lemma not_sum_squares_lt_zero:
   342   "\<not> x * x + y * y < 0"
   343   by (simp add: not_less sum_squares_ge_zero)
   344 
   345 end
   346 
   347 context linordered_semidom
   348 begin
   349 
   350 lemma zero_less_power [simp]:
   351   "0 < a \<Longrightarrow> 0 < a ^ n"
   352   by (induct n) simp_all
   353 
   354 lemma zero_le_power [simp]:
   355   "0 \<le> a \<Longrightarrow> 0 \<le> a ^ n"
   356   by (induct n) simp_all
   357 
   358 lemma power_mono:
   359   "a \<le> b \<Longrightarrow> 0 \<le> a \<Longrightarrow> a ^ n \<le> b ^ n"
   360   by (induct n) (auto intro: mult_mono order_trans [of 0 a b])
   361 
   362 lemma one_le_power [simp]: "1 \<le> a \<Longrightarrow> 1 \<le> a ^ n"
   363   using power_mono [of 1 a n] by simp
   364 
   365 lemma power_le_one: "\<lbrakk>0 \<le> a; a \<le> 1\<rbrakk> \<Longrightarrow> a ^ n \<le> 1"
   366   using power_mono [of a 1 n] by simp
   367 
   368 lemma power_gt1_lemma:
   369   assumes gt1: "1 < a"
   370   shows "1 < a * a ^ n"
   371 proof -
   372   from gt1 have "0 \<le> a"
   373     by (fact order_trans [OF zero_le_one less_imp_le])
   374   have "1 * 1 < a * 1" using gt1 by simp
   375   also have "\<dots> \<le> a * a ^ n" using gt1
   376     by (simp only: mult_mono `0 \<le> a` one_le_power order_less_imp_le
   377         zero_le_one order_refl)
   378   finally show ?thesis by simp
   379 qed
   380 
   381 lemma power_gt1:
   382   "1 < a \<Longrightarrow> 1 < a ^ Suc n"
   383   by (simp add: power_gt1_lemma)
   384 
   385 lemma one_less_power [simp]:
   386   "1 < a \<Longrightarrow> 0 < n \<Longrightarrow> 1 < a ^ n"
   387   by (cases n) (simp_all add: power_gt1_lemma)
   388 
   389 lemma power_le_imp_le_exp:
   390   assumes gt1: "1 < a"
   391   shows "a ^ m \<le> a ^ n \<Longrightarrow> m \<le> n"
   392 proof (induct m arbitrary: n)
   393   case 0
   394   show ?case by simp
   395 next
   396   case (Suc m)
   397   show ?case
   398   proof (cases n)
   399     case 0
   400     with Suc.prems Suc.hyps have "a * a ^ m \<le> 1" by simp
   401     with gt1 show ?thesis
   402       by (force simp only: power_gt1_lemma
   403           not_less [symmetric])
   404   next
   405     case (Suc n)
   406     with Suc.prems Suc.hyps show ?thesis
   407       by (force dest: mult_left_le_imp_le
   408           simp add: less_trans [OF zero_less_one gt1])
   409   qed
   410 qed
   411 
   412 text{*Surely we can strengthen this? It holds for @{text "0<a<1"} too.*}
   413 lemma power_inject_exp [simp]:
   414   "1 < a \<Longrightarrow> a ^ m = a ^ n \<longleftrightarrow> m = n"
   415   by (force simp add: order_antisym power_le_imp_le_exp)
   416 
   417 text{*Can relax the first premise to @{term "0<a"} in the case of the
   418 natural numbers.*}
   419 lemma power_less_imp_less_exp:
   420   "1 < a \<Longrightarrow> a ^ m < a ^ n \<Longrightarrow> m < n"
   421   by (simp add: order_less_le [of m n] less_le [of "a^m" "a^n"]
   422     power_le_imp_le_exp)
   423 
   424 lemma power_strict_mono [rule_format]:
   425   "a < b \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 < n \<longrightarrow> a ^ n < b ^ n"
   426   by (induct n)
   427    (auto simp add: mult_strict_mono le_less_trans [of 0 a b])
   428 
   429 text{*Lemma for @{text power_strict_decreasing}*}
   430 lemma power_Suc_less:
   431   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a * a ^ n < a ^ n"
   432   by (induct n)
   433     (auto simp add: mult_strict_left_mono)
   434 
   435 lemma power_strict_decreasing [rule_format]:
   436   "n < N \<Longrightarrow> 0 < a \<Longrightarrow> a < 1 \<longrightarrow> a ^ N < a ^ n"
   437 proof (induct N)
   438   case 0 then show ?case by simp
   439 next
   440   case (Suc N) then show ?case 
   441   apply (auto simp add: power_Suc_less less_Suc_eq)
   442   apply (subgoal_tac "a * a^N < 1 * a^n")
   443   apply simp
   444   apply (rule mult_strict_mono) apply auto
   445   done
   446 qed
   447 
   448 text{*Proof resembles that of @{text power_strict_decreasing}*}
   449 lemma power_decreasing [rule_format]:
   450   "n \<le> N \<Longrightarrow> 0 \<le> a \<Longrightarrow> a \<le> 1 \<longrightarrow> a ^ N \<le> a ^ n"
   451 proof (induct N)
   452   case 0 then show ?case by simp
   453 next
   454   case (Suc N) then show ?case 
   455   apply (auto simp add: le_Suc_eq)
   456   apply (subgoal_tac "a * a^N \<le> 1 * a^n", simp)
   457   apply (rule mult_mono) apply auto
   458   done
   459 qed
   460 
   461 lemma power_Suc_less_one:
   462   "0 < a \<Longrightarrow> a < 1 \<Longrightarrow> a ^ Suc n < 1"
   463   using power_strict_decreasing [of 0 "Suc n" a] by simp
   464 
   465 text{*Proof again resembles that of @{text power_strict_decreasing}*}
   466 lemma power_increasing [rule_format]:
   467   "n \<le> N \<Longrightarrow> 1 \<le> a \<Longrightarrow> a ^ n \<le> a ^ N"
   468 proof (induct N)
   469   case 0 then show ?case by simp
   470 next
   471   case (Suc N) then show ?case 
   472   apply (auto simp add: le_Suc_eq)
   473   apply (subgoal_tac "1 * a^n \<le> a * a^N", simp)
   474   apply (rule mult_mono) apply (auto simp add: order_trans [OF zero_le_one])
   475   done
   476 qed
   477 
   478 text{*Lemma for @{text power_strict_increasing}*}
   479 lemma power_less_power_Suc:
   480   "1 < a \<Longrightarrow> a ^ n < a * a ^ n"
   481   by (induct n) (auto simp add: mult_strict_left_mono less_trans [OF zero_less_one])
   482 
   483 lemma power_strict_increasing [rule_format]:
   484   "n < N \<Longrightarrow> 1 < a \<longrightarrow> a ^ n < a ^ N"
   485 proof (induct N)
   486   case 0 then show ?case by simp
   487 next
   488   case (Suc N) then show ?case 
   489   apply (auto simp add: power_less_power_Suc less_Suc_eq)
   490   apply (subgoal_tac "1 * a^n < a * a^N", simp)
   491   apply (rule mult_strict_mono) apply (auto simp add: less_trans [OF zero_less_one] less_imp_le)
   492   done
   493 qed
   494 
   495 lemma power_increasing_iff [simp]:
   496   "1 < b \<Longrightarrow> b ^ x \<le> b ^ y \<longleftrightarrow> x \<le> y"
   497   by (blast intro: power_le_imp_le_exp power_increasing less_imp_le)
   498 
   499 lemma power_strict_increasing_iff [simp]:
   500   "1 < b \<Longrightarrow> b ^ x < b ^ y \<longleftrightarrow> x < y"
   501 by (blast intro: power_less_imp_less_exp power_strict_increasing) 
   502 
   503 lemma power_le_imp_le_base:
   504   assumes le: "a ^ Suc n \<le> b ^ Suc n"
   505     and ynonneg: "0 \<le> b"
   506   shows "a \<le> b"
   507 proof (rule ccontr)
   508   assume "~ a \<le> b"
   509   then have "b < a" by (simp only: linorder_not_le)
   510   then have "b ^ Suc n < a ^ Suc n"
   511     by (simp only: assms power_strict_mono)
   512   from le and this show False
   513     by (simp add: linorder_not_less [symmetric])
   514 qed
   515 
   516 lemma power_less_imp_less_base:
   517   assumes less: "a ^ n < b ^ n"
   518   assumes nonneg: "0 \<le> b"
   519   shows "a < b"
   520 proof (rule contrapos_pp [OF less])
   521   assume "~ a < b"
   522   hence "b \<le> a" by (simp only: linorder_not_less)
   523   hence "b ^ n \<le> a ^ n" using nonneg by (rule power_mono)
   524   thus "\<not> a ^ n < b ^ n" by (simp only: linorder_not_less)
   525 qed
   526 
   527 lemma power_inject_base:
   528   "a ^ Suc n = b ^ Suc n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> a = b"
   529 by (blast intro: power_le_imp_le_base antisym eq_refl sym)
   530 
   531 lemma power_eq_imp_eq_base:
   532   "a ^ n = b ^ n \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 < n \<Longrightarrow> a = b"
   533   by (cases n) (simp_all del: power_Suc, rule power_inject_base)
   534 
   535 lemma power2_le_imp_le:
   536   "x\<^sup>2 \<le> y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x \<le> y"
   537   unfolding numeral_2_eq_2 by (rule power_le_imp_le_base)
   538 
   539 lemma power2_less_imp_less:
   540   "x\<^sup>2 < y\<^sup>2 \<Longrightarrow> 0 \<le> y \<Longrightarrow> x < y"
   541   by (rule power_less_imp_less_base)
   542 
   543 lemma power2_eq_imp_eq:
   544   "x\<^sup>2 = y\<^sup>2 \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> x = y"
   545   unfolding numeral_2_eq_2 by (erule (2) power_eq_imp_eq_base) simp
   546 
   547 end
   548 
   549 context linordered_ring_strict
   550 begin
   551 
   552 lemma sum_squares_eq_zero_iff:
   553   "x * x + y * y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   554   by (simp add: add_nonneg_eq_0_iff)
   555 
   556 lemma sum_squares_le_zero_iff:
   557   "x * x + y * y \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   558   by (simp add: le_less not_sum_squares_lt_zero sum_squares_eq_zero_iff)
   559 
   560 lemma sum_squares_gt_zero_iff:
   561   "0 < x * x + y * y \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   562   by (simp add: not_le [symmetric] sum_squares_le_zero_iff)
   563 
   564 end
   565 
   566 context linordered_idom
   567 begin
   568 
   569 lemma power_abs:
   570   "abs (a ^ n) = abs a ^ n"
   571   by (induct n) (auto simp add: abs_mult)
   572 
   573 lemma abs_power_minus [simp]:
   574   "abs ((-a) ^ n) = abs (a ^ n)"
   575   by (simp add: power_abs)
   576 
   577 lemma zero_less_power_abs_iff [simp]:
   578   "0 < abs a ^ n \<longleftrightarrow> a \<noteq> 0 \<or> n = 0"
   579 proof (induct n)
   580   case 0 show ?case by simp
   581 next
   582   case (Suc n) show ?case by (auto simp add: Suc zero_less_mult_iff)
   583 qed
   584 
   585 lemma zero_le_power_abs [simp]:
   586   "0 \<le> abs a ^ n"
   587   by (rule zero_le_power [OF abs_ge_zero])
   588 
   589 lemma zero_le_power2 [simp]:
   590   "0 \<le> a\<^sup>2"
   591   by (simp add: power2_eq_square)
   592 
   593 lemma zero_less_power2 [simp]:
   594   "0 < a\<^sup>2 \<longleftrightarrow> a \<noteq> 0"
   595   by (force simp add: power2_eq_square zero_less_mult_iff linorder_neq_iff)
   596 
   597 lemma power2_less_0 [simp]:
   598   "\<not> a\<^sup>2 < 0"
   599   by (force simp add: power2_eq_square mult_less_0_iff)
   600 
   601 lemma power2_less_eq_zero_iff [simp]:
   602   "a\<^sup>2 \<le> 0 \<longleftrightarrow> a = 0"
   603   by (simp add: le_less)
   604 
   605 lemma abs_power2 [simp]:
   606   "abs (a\<^sup>2) = a\<^sup>2"
   607   by (simp add: power2_eq_square abs_mult abs_mult_self)
   608 
   609 lemma power2_abs [simp]:
   610   "(abs a)\<^sup>2 = a\<^sup>2"
   611   by (simp add: power2_eq_square abs_mult_self)
   612 
   613 lemma odd_power_less_zero:
   614   "a < 0 \<Longrightarrow> a ^ Suc (2*n) < 0"
   615 proof (induct n)
   616   case 0
   617   then show ?case by simp
   618 next
   619   case (Suc n)
   620   have "a ^ Suc (2 * Suc n) = (a*a) * a ^ Suc(2*n)"
   621     by (simp add: ac_simps power_add power2_eq_square)
   622   thus ?case
   623     by (simp del: power_Suc add: Suc mult_less_0_iff mult_neg_neg)
   624 qed
   625 
   626 lemma odd_0_le_power_imp_0_le:
   627   "0 \<le> a ^ Suc (2*n) \<Longrightarrow> 0 \<le> a"
   628   using odd_power_less_zero [of a n]
   629     by (force simp add: linorder_not_less [symmetric]) 
   630 
   631 lemma zero_le_even_power'[simp]:
   632   "0 \<le> a ^ (2*n)"
   633 proof (induct n)
   634   case 0
   635     show ?case by simp
   636 next
   637   case (Suc n)
   638     have "a ^ (2 * Suc n) = (a*a) * a ^ (2*n)" 
   639       by (simp add: ac_simps power_add power2_eq_square)
   640     thus ?case
   641       by (simp add: Suc zero_le_mult_iff)
   642 qed
   643 
   644 lemma sum_power2_ge_zero:
   645   "0 \<le> x\<^sup>2 + y\<^sup>2"
   646   by (intro add_nonneg_nonneg zero_le_power2)
   647 
   648 lemma not_sum_power2_lt_zero:
   649   "\<not> x\<^sup>2 + y\<^sup>2 < 0"
   650   unfolding not_less by (rule sum_power2_ge_zero)
   651 
   652 lemma sum_power2_eq_zero_iff:
   653   "x\<^sup>2 + y\<^sup>2 = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   654   unfolding power2_eq_square by (simp add: add_nonneg_eq_0_iff)
   655 
   656 lemma sum_power2_le_zero_iff:
   657   "x\<^sup>2 + y\<^sup>2 \<le> 0 \<longleftrightarrow> x = 0 \<and> y = 0"
   658   by (simp add: le_less sum_power2_eq_zero_iff not_sum_power2_lt_zero)
   659 
   660 lemma sum_power2_gt_zero_iff:
   661   "0 < x\<^sup>2 + y\<^sup>2 \<longleftrightarrow> x \<noteq> 0 \<or> y \<noteq> 0"
   662   unfolding not_le [symmetric] by (simp add: sum_power2_le_zero_iff)
   663 
   664 lemma abs_le_square_iff:
   665    "\<bar>x\<bar> \<le> \<bar>y\<bar> \<longleftrightarrow> x\<^sup>2 \<le> y\<^sup>2"
   666 proof
   667   assume "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   668   then have "\<bar>x\<bar>\<^sup>2 \<le> \<bar>y\<bar>\<^sup>2" by (rule power_mono, simp)
   669   then show "x\<^sup>2 \<le> y\<^sup>2" by simp
   670 next
   671   assume "x\<^sup>2 \<le> y\<^sup>2"
   672   then show "\<bar>x\<bar> \<le> \<bar>y\<bar>"
   673     by (auto intro!: power2_le_imp_le [OF _ abs_ge_zero])
   674 qed
   675 
   676 lemma abs_square_le_1:"x\<^sup>2 \<le> 1 \<longleftrightarrow> abs(x) \<le> 1"
   677   using abs_le_square_iff [of x 1]
   678   by simp
   679 
   680 lemma abs_square_eq_1: "x\<^sup>2 = 1 \<longleftrightarrow> abs(x) = 1"
   681   by (auto simp add: abs_if power2_eq_1_iff)
   682   
   683 lemma abs_square_less_1: "x\<^sup>2 < 1 \<longleftrightarrow> abs(x) < 1"
   684   using  abs_square_eq_1 [of x] abs_square_le_1 [of x]
   685   by (auto simp add: le_less)
   686 
   687 end
   688 
   689 
   690 subsection {* Miscellaneous rules *}
   691 
   692 lemma self_le_power:
   693   fixes x::"'a::linordered_semidom" 
   694   shows "1 \<le> x \<Longrightarrow> 0 < n \<Longrightarrow> x \<le> x ^ n"
   695   using power_increasing[of 1 n x] power_one_right[of x] by auto
   696 
   697 lemma power_eq_if: "p ^ m = (if m=0 then 1 else p * (p ^ (m - 1)))"
   698   unfolding One_nat_def by (cases m) simp_all
   699 
   700 lemma (in comm_semiring_1) power2_sum:
   701   "(x + y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 + 2 * x * y"
   702   by (simp add: algebra_simps power2_eq_square mult_2_right)
   703 
   704 lemma (in comm_ring_1) power2_diff:
   705   "(x - y)\<^sup>2 = x\<^sup>2 + y\<^sup>2 - 2 * x * y"
   706   by (simp add: algebra_simps power2_eq_square mult_2_right)
   707 
   708 lemma power_0_Suc [simp]:
   709   "(0::'a::{power, semiring_0}) ^ Suc n = 0"
   710   by simp
   711 
   712 text{*It looks plausible as a simprule, but its effect can be strange.*}
   713 lemma power_0_left:
   714   "0 ^ n = (if n = 0 then 1 else (0::'a::{power, semiring_0}))"
   715   by (induct n) simp_all
   716 
   717 lemma (in field) power_diff:
   718   assumes nz: "a \<noteq> 0"
   719   shows "n \<le> m \<Longrightarrow> a ^ (m - n) = a ^ m / a ^ n"
   720   by (induct m n rule: diff_induct) (simp_all add: nz field_power_not_zero)
   721 
   722 text{*Perhaps these should be simprules.*}
   723 lemma power_inverse:
   724   fixes a :: "'a::division_ring"
   725   shows "inverse (a ^ n) = inverse a ^ n"
   726 apply (cases "a = 0")
   727 apply (simp add: power_0_left)
   728 apply (simp add: nonzero_power_inverse)
   729 done (* TODO: reorient or rename to inverse_power *)
   730 
   731 lemma power_one_over:
   732   "1 / (a::'a::{field, power}) ^ n =  (1 / a) ^ n"
   733   by (simp add: divide_inverse) (rule power_inverse)
   734 
   735 lemma power_divide [field_simps, divide_simps]:
   736   "(a / b) ^ n = (a::'a::field) ^ n / b ^ n"
   737 apply (cases "b = 0")
   738 apply (simp add: power_0_left)
   739 apply (rule nonzero_power_divide)
   740 apply assumption
   741 done
   742 
   743 text {* Simprules for comparisons where common factors can be cancelled. *}
   744 
   745 lemmas zero_compare_simps =
   746     add_strict_increasing add_strict_increasing2 add_increasing
   747     zero_le_mult_iff zero_le_divide_iff 
   748     zero_less_mult_iff zero_less_divide_iff 
   749     mult_le_0_iff divide_le_0_iff 
   750     mult_less_0_iff divide_less_0_iff 
   751     zero_le_power2 power2_less_0
   752 
   753 
   754 subsection {* Exponentiation for the Natural Numbers *}
   755 
   756 lemma nat_one_le_power [simp]:
   757   "Suc 0 \<le> i \<Longrightarrow> Suc 0 \<le> i ^ n"
   758   by (rule one_le_power [of i n, unfolded One_nat_def])
   759 
   760 lemma nat_zero_less_power_iff [simp]:
   761   "x ^ n > 0 \<longleftrightarrow> x > (0::nat) \<or> n = 0"
   762   by (induct n) auto
   763 
   764 lemma nat_power_eq_Suc_0_iff [simp]: 
   765   "x ^ m = Suc 0 \<longleftrightarrow> m = 0 \<or> x = Suc 0"
   766   by (induct m) auto
   767 
   768 lemma power_Suc_0 [simp]:
   769   "Suc 0 ^ n = Suc 0"
   770   by simp
   771 
   772 text{*Valid for the naturals, but what if @{text"0<i<1"}?
   773 Premises cannot be weakened: consider the case where @{term "i=0"},
   774 @{term "m=1"} and @{term "n=0"}.*}
   775 lemma nat_power_less_imp_less:
   776   assumes nonneg: "0 < (i\<Colon>nat)"
   777   assumes less: "i ^ m < i ^ n"
   778   shows "m < n"
   779 proof (cases "i = 1")
   780   case True with less power_one [where 'a = nat] show ?thesis by simp
   781 next
   782   case False with nonneg have "1 < i" by auto
   783   from power_strict_increasing_iff [OF this] less show ?thesis ..
   784 qed
   785 
   786 lemma power_dvd_imp_le:
   787   "i ^ m dvd i ^ n \<Longrightarrow> (1::nat) < i \<Longrightarrow> m \<le> n"
   788   apply (rule power_le_imp_le_exp, assumption)
   789   apply (erule dvd_imp_le, simp)
   790   done
   791 
   792 lemma power2_nat_le_eq_le:
   793   fixes m n :: nat
   794   shows "m\<^sup>2 \<le> n\<^sup>2 \<longleftrightarrow> m \<le> n"
   795   by (auto intro: power2_le_imp_le power_mono)
   796 
   797 lemma power2_nat_le_imp_le:
   798   fixes m n :: nat
   799   assumes "m\<^sup>2 \<le> n"
   800   shows "m \<le> n"
   801 proof (cases m)
   802   case 0 then show ?thesis by simp
   803 next
   804   case (Suc k)
   805   show ?thesis
   806   proof (rule ccontr)
   807     assume "\<not> m \<le> n"
   808     then have "n < m" by simp
   809     with assms Suc show False
   810       by (auto simp add: algebra_simps) (simp add: power2_eq_square)
   811   qed
   812 qed
   813 
   814 subsubsection {* Cardinality of the Powerset *}
   815 
   816 lemma card_UNIV_bool [simp]: "card (UNIV :: bool set) = 2"
   817   unfolding UNIV_bool by simp
   818 
   819 lemma card_Pow: "finite A \<Longrightarrow> card (Pow A) = 2 ^ card A"
   820 proof (induct rule: finite_induct)
   821   case empty 
   822     show ?case by auto
   823 next
   824   case (insert x A)
   825   then have "inj_on (insert x) (Pow A)" 
   826     unfolding inj_on_def by (blast elim!: equalityE)
   827   then have "card (Pow A) + card (insert x ` Pow A) = 2 * 2 ^ card A" 
   828     by (simp add: mult_2 card_image Pow_insert insert.hyps)
   829   then show ?case using insert
   830     apply (simp add: Pow_insert)
   831     apply (subst card_Un_disjoint, auto)
   832     done
   833 qed
   834 
   835 
   836 subsubsection {* Generalized sum over a set *}
   837 
   838 lemma setsum_zero_power [simp]:
   839   fixes c :: "nat \<Rightarrow> 'a::division_ring"
   840   shows "(\<Sum>i\<in>A. c i * 0^i) = (if finite A \<and> 0 \<in> A then c 0 else 0)"
   841 apply (cases "finite A")
   842   by (induction A rule: finite_induct) auto
   843 
   844 lemma setsum_zero_power' [simp]:
   845   fixes c :: "nat \<Rightarrow> 'a::field"
   846   shows "(\<Sum>i\<in>A. c i * 0^i / d i) = (if finite A \<and> 0 \<in> A then c 0 / d 0 else 0)"
   847   using setsum_zero_power [of "\<lambda>i. c i / d i" A]
   848   by auto
   849 
   850 
   851 subsubsection {* Generalized product over a set *}
   852 
   853 lemma setprod_constant: "finite A ==> (\<Prod>x\<in> A. (y::'a::{comm_monoid_mult})) = y^(card A)"
   854 apply (erule finite_induct)
   855 apply auto
   856 done
   857 
   858 lemma setprod_power_distrib:
   859   fixes f :: "'a \<Rightarrow> 'b::comm_semiring_1"
   860   shows "setprod f A ^ n = setprod (\<lambda>x. (f x) ^ n) A"
   861 proof (cases "finite A") 
   862   case True then show ?thesis 
   863     by (induct A rule: finite_induct) (auto simp add: power_mult_distrib)
   864 next
   865   case False then show ?thesis 
   866     by simp
   867 qed
   868 
   869 lemma power_setsum:
   870   "c ^ (\<Sum>a\<in>A. f a) = (\<Prod>a\<in>A. c ^ f a)"
   871   by (induct A rule: infinite_finite_induct) (simp_all add: power_add)
   872 
   873 lemma setprod_gen_delta:
   874   assumes fS: "finite S"
   875   shows "setprod (\<lambda>k. if k=a then b k else c) S = (if a \<in> S then (b a ::'a::comm_monoid_mult) * c^ (card S - 1) else c^ card S)"
   876 proof-
   877   let ?f = "(\<lambda>k. if k=a then b k else c)"
   878   {assume a: "a \<notin> S"
   879     hence "\<forall> k\<in> S. ?f k = c" by simp
   880     hence ?thesis  using a setprod_constant[OF fS, of c] by simp }
   881   moreover 
   882   {assume a: "a \<in> S"
   883     let ?A = "S - {a}"
   884     let ?B = "{a}"
   885     have eq: "S = ?A \<union> ?B" using a by blast 
   886     have dj: "?A \<inter> ?B = {}" by simp
   887     from fS have fAB: "finite ?A" "finite ?B" by auto  
   888     have fA0:"setprod ?f ?A = setprod (\<lambda>i. c) ?A"
   889       apply (rule setprod.cong) by auto
   890     have cA: "card ?A = card S - 1" using fS a by auto
   891     have fA1: "setprod ?f ?A = c ^ card ?A"  unfolding fA0 apply (rule setprod_constant) using fS by auto
   892     have "setprod ?f ?A * setprod ?f ?B = setprod ?f S"
   893       using setprod.union_disjoint[OF fAB dj, of ?f, unfolded eq[symmetric]]
   894       by simp
   895     then have ?thesis using a cA
   896       by (simp add: fA1 field_simps cong add: setprod.cong cong del: if_weak_cong)}
   897   ultimately show ?thesis by blast
   898 qed
   899 
   900 subsection {* Code generator tweak *}
   901 
   902 lemma power_power_power [code]:
   903   "power = power.power (1::'a::{power}) (op *)"
   904   unfolding power_def power.power_def ..
   905 
   906 declare power.power.simps [code]
   907 
   908 code_identifier
   909   code_module Power \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
   910 
   911 end
   912