src/HOL/Enum.thy
 author wenzelm Tue Sep 26 20:54:40 2017 +0200 (22 months ago) changeset 66695 91500c024c7f parent 65956 639eb3617a86 child 66806 a4e82b58d833 permissions -rw-r--r--
tuned;
1 (* Author: Florian Haftmann, TU Muenchen *)
3 section \<open>Finite types as explicit enumerations\<close>
5 theory Enum
6 imports Map Groups_List
7 begin
9 subsection \<open>Class \<open>enum\<close>\<close>
11 class enum =
12   fixes enum :: "'a list"
13   fixes enum_all :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
14   fixes enum_ex :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
15   assumes UNIV_enum: "UNIV = set enum"
16     and enum_distinct: "distinct enum"
17   assumes enum_all_UNIV: "enum_all P \<longleftrightarrow> Ball UNIV P"
18   assumes enum_ex_UNIV: "enum_ex P \<longleftrightarrow> Bex UNIV P"
19    \<comment> \<open>tailored towards simple instantiation\<close>
20 begin
22 subclass finite proof
25 lemma enum_UNIV:
26   "set enum = UNIV"
27   by (simp only: UNIV_enum)
29 lemma in_enum: "x \<in> set enum"
32 lemma enum_eq_I:
33   assumes "\<And>x. x \<in> set xs"
34   shows "set enum = set xs"
35 proof -
36   from assms UNIV_eq_I have "UNIV = set xs" by auto
37   with enum_UNIV show ?thesis by simp
38 qed
40 lemma card_UNIV_length_enum:
41   "card (UNIV :: 'a set) = length enum"
42   by (simp add: UNIV_enum distinct_card enum_distinct)
44 lemma enum_all [simp]:
45   "enum_all = HOL.All"
46   by (simp add: fun_eq_iff enum_all_UNIV)
48 lemma enum_ex [simp]:
49   "enum_ex = HOL.Ex"
50   by (simp add: fun_eq_iff enum_ex_UNIV)
52 end
55 subsection \<open>Implementations using @{class enum}\<close>
57 subsubsection \<open>Unbounded operations and quantifiers\<close>
59 lemma Collect_code [code]:
60   "Collect P = set (filter P enum)"
63 lemma vimage_code [code]:
64   "f -` B = set (filter (%x. f x : B) enum_class.enum)"
65   unfolding vimage_def Collect_code ..
67 definition card_UNIV :: "'a itself \<Rightarrow> nat"
68 where
69   [code del]: "card_UNIV TYPE('a) = card (UNIV :: 'a set)"
71 lemma [code]:
72   "card_UNIV TYPE('a :: enum) = card (set (Enum.enum :: 'a list))"
73   by (simp only: card_UNIV_def enum_UNIV)
75 lemma all_code [code]: "(\<forall>x. P x) \<longleftrightarrow> enum_all P"
76   by simp
78 lemma exists_code [code]: "(\<exists>x. P x) \<longleftrightarrow> enum_ex P"
79   by simp
81 lemma exists1_code [code]: "(\<exists>!x. P x) \<longleftrightarrow> list_ex1 P enum"
82   by (auto simp add: list_ex1_iff enum_UNIV)
85 subsubsection \<open>An executable choice operator\<close>
87 definition
88   [code del]: "enum_the = The"
90 lemma [code]:
91   "The P = (case filter P enum of [x] => x | _ => enum_the P)"
92 proof -
93   {
94     fix a
95     assume filter_enum: "filter P enum = [a]"
96     have "The P = a"
97     proof (rule the_equality)
98       fix x
99       assume "P x"
100       show "x = a"
101       proof (rule ccontr)
102         assume "x \<noteq> a"
103         from filter_enum obtain us vs
104           where enum_eq: "enum = us @ [a] @ vs"
105           and "\<forall> x \<in> set us. \<not> P x"
106           and "\<forall> x \<in> set vs. \<not> P x"
107           and "P a"
108           by (auto simp add: filter_eq_Cons_iff) (simp only: filter_empty_conv[symmetric])
109         with \<open>P x\<close> in_enum[of x, unfolded enum_eq] \<open>x \<noteq> a\<close> show "False" by auto
110       qed
111     next
112       from filter_enum show "P a" by (auto simp add: filter_eq_Cons_iff)
113     qed
114   }
115   from this show ?thesis
116     unfolding enum_the_def by (auto split: list.split)
117 qed
119 declare [[code abort: enum_the]]
121 code_printing
122   constant enum_the \<rightharpoonup> (Eval) "(fn '_ => raise Match)"
125 subsubsection \<open>Equality and order on functions\<close>
127 instantiation "fun" :: (enum, equal) equal
128 begin
130 definition
131   "HOL.equal f g \<longleftrightarrow> (\<forall>x \<in> set enum. f x = g x)"
133 instance proof
134 qed (simp_all add: equal_fun_def fun_eq_iff enum_UNIV)
136 end
138 lemma [code]:
139   "HOL.equal f g \<longleftrightarrow> enum_all (%x. f x = g x)"
140   by (auto simp add: equal fun_eq_iff)
142 lemma [code nbe]:
143   "HOL.equal (f :: _ \<Rightarrow> _) f \<longleftrightarrow> True"
144   by (fact equal_refl)
146 lemma order_fun [code]:
147   fixes f g :: "'a::enum \<Rightarrow> 'b::order"
148   shows "f \<le> g \<longleftrightarrow> enum_all (\<lambda>x. f x \<le> g x)"
149     and "f < g \<longleftrightarrow> f \<le> g \<and> enum_ex (\<lambda>x. f x \<noteq> g x)"
150   by (simp_all add: fun_eq_iff le_fun_def order_less_le)
153 subsubsection \<open>Operations on relations\<close>
155 lemma [code]:
156   "Id = image (\<lambda>x. (x, x)) (set Enum.enum)"
157   by (auto intro: imageI in_enum)
159 lemma tranclp_unfold [code]:
160   "tranclp r a b \<longleftrightarrow> (a, b) \<in> trancl {(x, y). r x y}"
163 lemma rtranclp_rtrancl_eq [code]:
164   "rtranclp r x y \<longleftrightarrow> (x, y) \<in> rtrancl {(x, y). r x y}"
167 lemma max_ext_eq [code]:
168   "max_ext R = {(X, Y). finite X \<and> finite Y \<and> Y \<noteq> {} \<and> (\<forall>x. x \<in> X \<longrightarrow> (\<exists>xa \<in> Y. (x, xa) \<in> R))}"
169   by (auto simp add: max_ext.simps)
171 lemma max_extp_eq [code]:
172   "max_extp r x y \<longleftrightarrow> (x, y) \<in> max_ext {(x, y). r x y}"
175 lemma mlex_eq [code]:
176   "f <*mlex*> R = {(x, y). f x < f y \<or> (f x \<le> f y \<and> (x, y) \<in> R)}"
177   by (auto simp add: mlex_prod_def)
180 subsubsection \<open>Bounded accessible part\<close>
182 primrec bacc :: "('a \<times> 'a) set \<Rightarrow> nat \<Rightarrow> 'a set"
183 where
184   "bacc r 0 = {x. \<forall> y. (y, x) \<notin> r}"
185 | "bacc r (Suc n) = (bacc r n \<union> {x. \<forall>y. (y, x) \<in> r \<longrightarrow> y \<in> bacc r n})"
187 lemma bacc_subseteq_acc:
188   "bacc r n \<subseteq> Wellfounded.acc r"
189   by (induct n) (auto intro: acc.intros)
191 lemma bacc_mono:
192   "n \<le> m \<Longrightarrow> bacc r n \<subseteq> bacc r m"
193   by (induct rule: dec_induct) auto
195 lemma bacc_upper_bound:
196   "bacc (r :: ('a \<times> 'a) set)  (card (UNIV :: 'a::finite set)) = (\<Union>n. bacc r n)"
197 proof -
198   have "mono (bacc r)" unfolding mono_def by (simp add: bacc_mono)
199   moreover have "\<forall>n. bacc r n = bacc r (Suc n) \<longrightarrow> bacc r (Suc n) = bacc r (Suc (Suc n))" by auto
200   moreover have "finite (range (bacc r))" by auto
201   ultimately show ?thesis
202    by (intro finite_mono_strict_prefix_implies_finite_fixpoint)
203      (auto intro: finite_mono_remains_stable_implies_strict_prefix)
204 qed
206 lemma acc_subseteq_bacc:
207   assumes "finite r"
208   shows "Wellfounded.acc r \<subseteq> (\<Union>n. bacc r n)"
209 proof
210   fix x
211   assume "x : Wellfounded.acc r"
212   then have "\<exists> n. x : bacc r n"
213   proof (induct x arbitrary: rule: acc.induct)
214     case (accI x)
215     then have "\<forall>y. \<exists> n. (y, x) \<in> r --> y : bacc r n" by simp
216     from choice[OF this] obtain n where n: "\<forall>y. (y, x) \<in> r \<longrightarrow> y \<in> bacc r (n y)" ..
217     obtain n where "\<And>y. (y, x) : r \<Longrightarrow> y : bacc r n"
218     proof
219       fix y assume y: "(y, x) : r"
220       with n have "y : bacc r (n y)" by auto
221       moreover have "n y <= Max ((%(y, x). n y) ` r)"
222         using y \<open>finite r\<close> by (auto intro!: Max_ge)
223       note bacc_mono[OF this, of r]
224       ultimately show "y : bacc r (Max ((%(y, x). n y) ` r))" by auto
225     qed
226     then show ?case
227       by (auto simp add: Let_def intro!: exI[of _ "Suc n"])
228   qed
229   then show "x : (UN n. bacc r n)" by auto
230 qed
232 lemma acc_bacc_eq:
233   fixes A :: "('a :: finite \<times> 'a) set"
234   assumes "finite A"
235   shows "Wellfounded.acc A = bacc A (card (UNIV :: 'a set))"
236   using assms by (metis acc_subseteq_bacc bacc_subseteq_acc bacc_upper_bound order_eq_iff)
238 lemma [code]:
239   fixes xs :: "('a::finite \<times> 'a) list"
240   shows "Wellfounded.acc (set xs) = bacc (set xs) (card_UNIV TYPE('a))"
241   by (simp add: card_UNIV_def acc_bacc_eq)
244 subsection \<open>Default instances for @{class enum}\<close>
246 lemma map_of_zip_enum_is_Some:
247   assumes "length ys = length (enum :: 'a::enum list)"
248   shows "\<exists>y. map_of (zip (enum :: 'a::enum list) ys) x = Some y"
249 proof -
250   from assms have "x \<in> set (enum :: 'a::enum list) \<longleftrightarrow>
251     (\<exists>y. map_of (zip (enum :: 'a::enum list) ys) x = Some y)"
252     by (auto intro!: map_of_zip_is_Some)
253   then show ?thesis using enum_UNIV by auto
254 qed
256 lemma map_of_zip_enum_inject:
257   fixes xs ys :: "'b::enum list"
258   assumes length: "length xs = length (enum :: 'a::enum list)"
259       "length ys = length (enum :: 'a::enum list)"
260     and map_of: "the \<circ> map_of (zip (enum :: 'a::enum list) xs) = the \<circ> map_of (zip (enum :: 'a::enum list) ys)"
261   shows "xs = ys"
262 proof -
263   have "map_of (zip (enum :: 'a list) xs) = map_of (zip (enum :: 'a list) ys)"
264   proof
265     fix x :: 'a
266     from length map_of_zip_enum_is_Some obtain y1 y2
267       where "map_of (zip (enum :: 'a list) xs) x = Some y1"
268         and "map_of (zip (enum :: 'a list) ys) x = Some y2" by blast
269     moreover from map_of
270       have "the (map_of (zip (enum :: 'a::enum list) xs) x) = the (map_of (zip (enum :: 'a::enum list) ys) x)"
271       by (auto dest: fun_cong)
272     ultimately show "map_of (zip (enum :: 'a::enum list) xs) x = map_of (zip (enum :: 'a::enum list) ys) x"
273       by simp
274   qed
275   with length enum_distinct show "xs = ys" by (rule map_of_zip_inject)
276 qed
278 definition all_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
279 where
280   "all_n_lists P n \<longleftrightarrow> (\<forall>xs \<in> set (List.n_lists n enum). P xs)"
282 lemma [code]:
283   "all_n_lists P n \<longleftrightarrow> (if n = 0 then P [] else enum_all (%x. all_n_lists (%xs. P (x # xs)) (n - 1)))"
284   unfolding all_n_lists_def enum_all
285   by (cases n) (auto simp add: enum_UNIV)
287 definition ex_n_lists :: "(('a :: enum) list \<Rightarrow> bool) \<Rightarrow> nat \<Rightarrow> bool"
288 where
289   "ex_n_lists P n \<longleftrightarrow> (\<exists>xs \<in> set (List.n_lists n enum). P xs)"
291 lemma [code]:
292   "ex_n_lists P n \<longleftrightarrow> (if n = 0 then P [] else enum_ex (%x. ex_n_lists (%xs. P (x # xs)) (n - 1)))"
293   unfolding ex_n_lists_def enum_ex
294   by (cases n) (auto simp add: enum_UNIV)
296 instantiation "fun" :: (enum, enum) enum
297 begin
299 definition
300   "enum = map (\<lambda>ys. the o map_of (zip (enum::'a list) ys)) (List.n_lists (length (enum::'a::enum list)) enum)"
302 definition
303   "enum_all P = all_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
305 definition
306   "enum_ex P = ex_n_lists (\<lambda>bs. P (the o map_of (zip enum bs))) (length (enum :: 'a list))"
308 instance proof
309   show "UNIV = set (enum :: ('a \<Rightarrow> 'b) list)"
310   proof (rule UNIV_eq_I)
311     fix f :: "'a \<Rightarrow> 'b"
312     have "f = the \<circ> map_of (zip (enum :: 'a::enum list) (map f enum))"
313       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
314     then show "f \<in> set enum"
315       by (auto simp add: enum_fun_def set_n_lists intro: in_enum)
316   qed
317 next
318   from map_of_zip_enum_inject
319   show "distinct (enum :: ('a \<Rightarrow> 'b) list)"
320     by (auto intro!: inj_onI simp add: enum_fun_def
321       distinct_map distinct_n_lists enum_distinct set_n_lists)
322 next
323   fix P
324   show "enum_all (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = Ball UNIV P"
325   proof
326     assume "enum_all P"
327     show "Ball UNIV P"
328     proof
329       fix f :: "'a \<Rightarrow> 'b"
330       have f: "f = the \<circ> map_of (zip (enum :: 'a::enum list) (map f enum))"
331         by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
332       from \<open>enum_all P\<close> have "P (the \<circ> map_of (zip enum (map f enum)))"
333         unfolding enum_all_fun_def all_n_lists_def
335         apply (erule_tac x="map f enum" in allE)
336         apply (auto intro!: in_enum)
337         done
338       from this f show "P f" by auto
339     qed
340   next
341     assume "Ball UNIV P"
342     from this show "enum_all P"
343       unfolding enum_all_fun_def all_n_lists_def by auto
344   qed
345 next
346   fix P
347   show "enum_ex (P :: ('a \<Rightarrow> 'b) \<Rightarrow> bool) = Bex UNIV P"
348   proof
349     assume "enum_ex P"
350     from this show "Bex UNIV P"
351       unfolding enum_ex_fun_def ex_n_lists_def by auto
352   next
353     assume "Bex UNIV P"
354     from this obtain f where "P f" ..
355     have f: "f = the \<circ> map_of (zip (enum :: 'a::enum list) (map f enum))"
356       by (auto simp add: map_of_zip_map fun_eq_iff intro: in_enum)
357     from \<open>P f\<close> this have "P (the \<circ> map_of (zip (enum :: 'a::enum list) (map f enum)))"
358       by auto
359     from  this show "enum_ex P"
360       unfolding enum_ex_fun_def ex_n_lists_def
361       apply (auto simp add: set_n_lists)
362       apply (rule_tac x="map f enum" in exI)
363       apply (auto intro!: in_enum)
364       done
365   qed
366 qed
368 end
370 lemma enum_fun_code [code]: "enum = (let enum_a = (enum :: 'a::{enum, equal} list)
371   in map (\<lambda>ys. the o map_of (zip enum_a ys)) (List.n_lists (length enum_a) enum))"
372   by (simp add: enum_fun_def Let_def)
374 lemma enum_all_fun_code [code]:
375   "enum_all P = (let enum_a = (enum :: 'a::{enum, equal} list)
376    in all_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
377   by (simp only: enum_all_fun_def Let_def)
379 lemma enum_ex_fun_code [code]:
380   "enum_ex P = (let enum_a = (enum :: 'a::{enum, equal} list)
381    in ex_n_lists (\<lambda>bs. P (the o map_of (zip enum_a bs))) (length enum_a))"
382   by (simp only: enum_ex_fun_def Let_def)
384 instantiation set :: (enum) enum
385 begin
387 definition
388   "enum = map set (subseqs enum)"
390 definition
391   "enum_all P \<longleftrightarrow> (\<forall>A\<in>set enum. P (A::'a set))"
393 definition
394   "enum_ex P \<longleftrightarrow> (\<exists>A\<in>set enum. P (A::'a set))"
396 instance proof
397 qed (simp_all add: enum_set_def enum_all_set_def enum_ex_set_def subseqs_powset distinct_set_subseqs
398   enum_distinct enum_UNIV)
400 end
402 instantiation unit :: enum
403 begin
405 definition
406   "enum = [()]"
408 definition
409   "enum_all P = P ()"
411 definition
412   "enum_ex P = P ()"
414 instance proof
415 qed (auto simp add: enum_unit_def enum_all_unit_def enum_ex_unit_def)
417 end
419 instantiation bool :: enum
420 begin
422 definition
423   "enum = [False, True]"
425 definition
426   "enum_all P \<longleftrightarrow> P False \<and> P True"
428 definition
429   "enum_ex P \<longleftrightarrow> P False \<or> P True"
431 instance proof
432 qed (simp_all only: enum_bool_def enum_all_bool_def enum_ex_bool_def UNIV_bool, simp_all)
434 end
436 instantiation prod :: (enum, enum) enum
437 begin
439 definition
440   "enum = List.product enum enum"
442 definition
443   "enum_all P = enum_all (%x. enum_all (%y. P (x, y)))"
445 definition
446   "enum_ex P = enum_ex (%x. enum_ex (%y. P (x, y)))"
449 instance
450   by standard
452       enum_UNIV enum_distinct enum_all_prod_def enum_ex_prod_def)
454 end
456 instantiation sum :: (enum, enum) enum
457 begin
459 definition
460   "enum = map Inl enum @ map Inr enum"
462 definition
463   "enum_all P \<longleftrightarrow> enum_all (\<lambda>x. P (Inl x)) \<and> enum_all (\<lambda>x. P (Inr x))"
465 definition
466   "enum_ex P \<longleftrightarrow> enum_ex (\<lambda>x. P (Inl x)) \<or> enum_ex (\<lambda>x. P (Inr x))"
468 instance proof
469 qed (simp_all only: enum_sum_def enum_all_sum_def enum_ex_sum_def UNIV_sum,
470   auto simp add: enum_UNIV distinct_map enum_distinct)
472 end
474 instantiation option :: (enum) enum
475 begin
477 definition
478   "enum = None # map Some enum"
480 definition
481   "enum_all P \<longleftrightarrow> P None \<and> enum_all (\<lambda>x. P (Some x))"
483 definition
484   "enum_ex P \<longleftrightarrow> P None \<or> enum_ex (\<lambda>x. P (Some x))"
486 instance proof
487 qed (simp_all only: enum_option_def enum_all_option_def enum_ex_option_def UNIV_option_conv,
488   auto simp add: distinct_map enum_UNIV enum_distinct)
490 end
493 subsection \<open>Small finite types\<close>
495 text \<open>We define small finite types for use in Quickcheck\<close>
497 datatype (plugins only: code "quickcheck" extraction) finite_1 =
498   a\<^sub>1
500 notation (output) a\<^sub>1  ("a\<^sub>1")
502 lemma UNIV_finite_1:
503   "UNIV = {a\<^sub>1}"
504   by (auto intro: finite_1.exhaust)
506 instantiation finite_1 :: enum
507 begin
509 definition
510   "enum = [a\<^sub>1]"
512 definition
513   "enum_all P = P a\<^sub>1"
515 definition
516   "enum_ex P = P a\<^sub>1"
518 instance proof
519 qed (simp_all only: enum_finite_1_def enum_all_finite_1_def enum_ex_finite_1_def UNIV_finite_1, simp_all)
521 end
523 instantiation finite_1 :: linorder
524 begin
526 definition less_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
527 where
528   "x < (y :: finite_1) \<longleftrightarrow> False"
530 definition less_eq_finite_1 :: "finite_1 \<Rightarrow> finite_1 \<Rightarrow> bool"
531 where
532   "x \<le> (y :: finite_1) \<longleftrightarrow> True"
534 instance
535 apply (intro_classes)
536 apply (auto simp add: less_finite_1_def less_eq_finite_1_def)
537 apply (metis finite_1.exhaust)
538 done
540 end
542 instance finite_1 :: "{dense_linorder, wellorder}"
543 by intro_classes (simp_all add: less_finite_1_def)
545 instantiation finite_1 :: complete_lattice
546 begin
548 definition [simp]: "Inf = (\<lambda>_. a\<^sub>1)"
549 definition [simp]: "Sup = (\<lambda>_. a\<^sub>1)"
550 definition [simp]: "bot = a\<^sub>1"
551 definition [simp]: "top = a\<^sub>1"
552 definition [simp]: "inf = (\<lambda>_ _. a\<^sub>1)"
553 definition [simp]: "sup = (\<lambda>_ _. a\<^sub>1)"
555 instance by intro_classes(simp_all add: less_eq_finite_1_def)
556 end
558 instance finite_1 :: complete_distrib_lattice
559   by standard simp_all
561 instance finite_1 :: complete_linorder ..
563 lemma finite_1_eq: "x = a\<^sub>1"
564 by(cases x) simp
566 simproc_setup finite_1_eq ("x::finite_1") = \<open>
567   fn _ => fn _ => fn ct =>
568     (case Thm.term_of ct of
569       Const (@{const_name a\<^sub>1}, _) => NONE
570     | _ => SOME (mk_meta_eq @{thm finite_1_eq}))
571 \<close>
573 instantiation finite_1 :: complete_boolean_algebra
574 begin
575 definition [simp]: "op - = (\<lambda>_ _. a\<^sub>1)"
576 definition [simp]: "uminus = (\<lambda>_. a\<^sub>1)"
577 instance by intro_classes simp_all
578 end
580 instantiation finite_1 ::
581   "{linordered_ring_strict, linordered_comm_semiring_strict, ordered_comm_ring,
582     ordered_cancel_comm_monoid_diff, comm_monoid_mult, ordered_ring_abs,
583     one, modulo, sgn, inverse}"
584 begin
585 definition [simp]: "Groups.zero = a\<^sub>1"
586 definition [simp]: "Groups.one = a\<^sub>1"
587 definition [simp]: "op + = (\<lambda>_ _. a\<^sub>1)"
588 definition [simp]: "op * = (\<lambda>_ _. a\<^sub>1)"
589 definition [simp]: "op mod = (\<lambda>_ _. a\<^sub>1)"
590 definition [simp]: "abs = (\<lambda>_. a\<^sub>1)"
591 definition [simp]: "sgn = (\<lambda>_. a\<^sub>1)"
592 definition [simp]: "inverse = (\<lambda>_. a\<^sub>1)"
593 definition [simp]: "divide = (\<lambda>_ _. a\<^sub>1)"
595 instance by intro_classes(simp_all add: less_finite_1_def)
596 end
598 declare [[simproc del: finite_1_eq]]
599 hide_const (open) a\<^sub>1
601 datatype (plugins only: code "quickcheck" extraction) finite_2 =
602   a\<^sub>1 | a\<^sub>2
604 notation (output) a\<^sub>1  ("a\<^sub>1")
605 notation (output) a\<^sub>2  ("a\<^sub>2")
607 lemma UNIV_finite_2:
608   "UNIV = {a\<^sub>1, a\<^sub>2}"
609   by (auto intro: finite_2.exhaust)
611 instantiation finite_2 :: enum
612 begin
614 definition
615   "enum = [a\<^sub>1, a\<^sub>2]"
617 definition
618   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2"
620 definition
621   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2"
623 instance proof
624 qed (simp_all only: enum_finite_2_def enum_all_finite_2_def enum_ex_finite_2_def UNIV_finite_2, simp_all)
626 end
628 instantiation finite_2 :: linorder
629 begin
631 definition less_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
632 where
633   "x < y \<longleftrightarrow> x = a\<^sub>1 \<and> y = a\<^sub>2"
635 definition less_eq_finite_2 :: "finite_2 \<Rightarrow> finite_2 \<Rightarrow> bool"
636 where
637   "x \<le> y \<longleftrightarrow> x = y \<or> x < (y :: finite_2)"
639 instance
640 apply (intro_classes)
641 apply (auto simp add: less_finite_2_def less_eq_finite_2_def)
642 apply (metis finite_2.nchotomy)+
643 done
645 end
647 instance finite_2 :: wellorder
648 by(rule wf_wellorderI)(simp add: less_finite_2_def, intro_classes)
650 instantiation finite_2 :: complete_lattice
651 begin
653 definition "\<Sqinter>A = (if a\<^sub>1 \<in> A then a\<^sub>1 else a\<^sub>2)"
654 definition "\<Squnion>A = (if a\<^sub>2 \<in> A then a\<^sub>2 else a\<^sub>1)"
655 definition [simp]: "bot = a\<^sub>1"
656 definition [simp]: "top = a\<^sub>2"
657 definition "x \<sqinter> y = (if x = a\<^sub>1 \<or> y = a\<^sub>1 then a\<^sub>1 else a\<^sub>2)"
658 definition "x \<squnion> y = (if x = a\<^sub>2 \<or> y = a\<^sub>2 then a\<^sub>2 else a\<^sub>1)"
660 lemma neq_finite_2_a\<^sub>1_iff [simp]: "x \<noteq> a\<^sub>1 \<longleftrightarrow> x = a\<^sub>2"
661 by(cases x) simp_all
663 lemma neq_finite_2_a\<^sub>1_iff' [simp]: "a\<^sub>1 \<noteq> x \<longleftrightarrow> x = a\<^sub>2"
664 by(cases x) simp_all
666 lemma neq_finite_2_a\<^sub>2_iff [simp]: "x \<noteq> a\<^sub>2 \<longleftrightarrow> x = a\<^sub>1"
667 by(cases x) simp_all
669 lemma neq_finite_2_a\<^sub>2_iff' [simp]: "a\<^sub>2 \<noteq> x \<longleftrightarrow> x = a\<^sub>1"
670 by(cases x) simp_all
672 instance
673 proof
674   fix x :: finite_2 and A
675   assume "x \<in> A"
676   then show "\<Sqinter>A \<le> x" "x \<le> \<Squnion>A"
677     by(case_tac [!] x)(auto simp add: less_eq_finite_2_def less_finite_2_def Inf_finite_2_def Sup_finite_2_def)
678 qed(auto simp add: less_eq_finite_2_def less_finite_2_def inf_finite_2_def sup_finite_2_def Inf_finite_2_def Sup_finite_2_def)
679 end
681 instance finite_2 :: complete_distrib_lattice
682   by standard (auto simp add: sup_finite_2_def inf_finite_2_def Inf_finite_2_def Sup_finite_2_def)
684 instance finite_2 :: complete_linorder ..
686 instantiation finite_2 :: "{field, idom_abs_sgn}" begin
687 definition [simp]: "0 = a\<^sub>1"
688 definition [simp]: "1 = a\<^sub>2"
689 definition "x + y = (case (x, y) of (a\<^sub>1, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>2) \<Rightarrow> a\<^sub>1 | _ \<Rightarrow> a\<^sub>2)"
690 definition "uminus = (\<lambda>x :: finite_2. x)"
691 definition "op - = (op + :: finite_2 \<Rightarrow> _)"
692 definition "x * y = (case (x, y) of (a\<^sub>2, a\<^sub>2) \<Rightarrow> a\<^sub>2 | _ \<Rightarrow> a\<^sub>1)"
693 definition "inverse = (\<lambda>x :: finite_2. x)"
694 definition "divide = (op * :: finite_2 \<Rightarrow> _)"
695 definition "abs = (\<lambda>x :: finite_2. x)"
696 definition "sgn = (\<lambda>x :: finite_2. x)"
697 instance
698   by standard
699     (simp_all add: plus_finite_2_def uminus_finite_2_def minus_finite_2_def times_finite_2_def
700       inverse_finite_2_def divide_finite_2_def abs_finite_2_def sgn_finite_2_def
701       split: finite_2.splits)
702 end
704 lemma two_finite_2 [simp]:
705   "2 = a\<^sub>1"
706   by (simp add: numeral.simps plus_finite_2_def)
708 lemma dvd_finite_2_unfold:
709   "x dvd y \<longleftrightarrow> x = a\<^sub>2 \<or> y = a\<^sub>1"
710   by (auto simp add: dvd_def times_finite_2_def split: finite_2.splits)
712 instantiation finite_2 :: "{ring_div, normalization_semidom}" begin
713 definition [simp]: "normalize = (id :: finite_2 \<Rightarrow> _)"
714 definition [simp]: "unit_factor = (id :: finite_2 \<Rightarrow> _)"
715 definition "x mod y = (case (x, y) of (a\<^sub>2, a\<^sub>1) \<Rightarrow> a\<^sub>2 | _ \<Rightarrow> a\<^sub>1)"
716 instance
717   by standard
719       divide_finite_2_def modulo_finite_2_def split: finite_2.splits)
720 end
723 hide_const (open) a\<^sub>1 a\<^sub>2
725 datatype (plugins only: code "quickcheck" extraction) finite_3 =
726   a\<^sub>1 | a\<^sub>2 | a\<^sub>3
728 notation (output) a\<^sub>1  ("a\<^sub>1")
729 notation (output) a\<^sub>2  ("a\<^sub>2")
730 notation (output) a\<^sub>3  ("a\<^sub>3")
732 lemma UNIV_finite_3:
733   "UNIV = {a\<^sub>1, a\<^sub>2, a\<^sub>3}"
734   by (auto intro: finite_3.exhaust)
736 instantiation finite_3 :: enum
737 begin
739 definition
740   "enum = [a\<^sub>1, a\<^sub>2, a\<^sub>3]"
742 definition
743   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2 \<and> P a\<^sub>3"
745 definition
746   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2 \<or> P a\<^sub>3"
748 instance proof
749 qed (simp_all only: enum_finite_3_def enum_all_finite_3_def enum_ex_finite_3_def UNIV_finite_3, simp_all)
751 end
753 lemma finite_3_not_eq_unfold:
754   "x \<noteq> a\<^sub>1 \<longleftrightarrow> x \<in> {a\<^sub>2, a\<^sub>3}"
755   "x \<noteq> a\<^sub>2 \<longleftrightarrow> x \<in> {a\<^sub>1, a\<^sub>3}"
756   "x \<noteq> a\<^sub>3 \<longleftrightarrow> x \<in> {a\<^sub>1, a\<^sub>2}"
757   by (cases x; simp)+
759 instantiation finite_3 :: linorder
760 begin
762 definition less_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
763 where
764   "x < y = (case x of a\<^sub>1 \<Rightarrow> y \<noteq> a\<^sub>1 | a\<^sub>2 \<Rightarrow> y = a\<^sub>3 | a\<^sub>3 \<Rightarrow> False)"
766 definition less_eq_finite_3 :: "finite_3 \<Rightarrow> finite_3 \<Rightarrow> bool"
767 where
768   "x \<le> y \<longleftrightarrow> x = y \<or> x < (y :: finite_3)"
770 instance proof (intro_classes)
771 qed (auto simp add: less_finite_3_def less_eq_finite_3_def split: finite_3.split_asm)
773 end
775 instance finite_3 :: wellorder
776 proof(rule wf_wellorderI)
777   have "inv_image less_than (case_finite_3 0 1 2) = {(x, y). x < y}"
778     by(auto simp add: less_finite_3_def split: finite_3.splits)
779   from this[symmetric] show "wf \<dots>" by simp
780 qed intro_classes
782 instantiation finite_3 :: complete_lattice
783 begin
785 definition "\<Sqinter>A = (if a\<^sub>1 \<in> A then a\<^sub>1 else if a\<^sub>2 \<in> A then a\<^sub>2 else a\<^sub>3)"
786 definition "\<Squnion>A = (if a\<^sub>3 \<in> A then a\<^sub>3 else if a\<^sub>2 \<in> A then a\<^sub>2 else a\<^sub>1)"
787 definition [simp]: "bot = a\<^sub>1"
788 definition [simp]: "top = a\<^sub>3"
789 definition [simp]: "inf = (min :: finite_3 \<Rightarrow> _)"
790 definition [simp]: "sup = (max :: finite_3 \<Rightarrow> _)"
792 instance
793 proof
794   fix x :: finite_3 and A
795   assume "x \<in> A"
796   then show "\<Sqinter>A \<le> x" "x \<le> \<Squnion>A"
797     by(case_tac [!] x)(auto simp add: Inf_finite_3_def Sup_finite_3_def less_eq_finite_3_def less_finite_3_def)
798 next
799   fix A and z :: finite_3
800   assume "\<And>x. x \<in> A \<Longrightarrow> z \<le> x"
801   then show "z \<le> \<Sqinter>A"
802     by(cases z)(auto simp add: Inf_finite_3_def less_eq_finite_3_def less_finite_3_def)
803 next
804   fix A and z :: finite_3
805   assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<le> z"
806   show "\<Squnion>A \<le> z"
807     by(auto simp add: Sup_finite_3_def less_eq_finite_3_def less_finite_3_def dest: *)
808 qed(auto simp add: Inf_finite_3_def Sup_finite_3_def)
809 end
811 instance finite_3 :: complete_distrib_lattice
812 proof
813   fix a :: finite_3 and B
814   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
815   proof(cases a "\<Sqinter>B" rule: finite_3.exhaust[case_product finite_3.exhaust])
816     case a\<^sub>2_a\<^sub>3
817     then have "\<And>x. x \<in> B \<Longrightarrow> x = a\<^sub>3"
818       by(case_tac x)(auto simp add: Inf_finite_3_def split: if_split_asm)
819     then show ?thesis using a\<^sub>2_a\<^sub>3
820       by(auto simp add: Inf_finite_3_def max_def less_eq_finite_3_def less_finite_3_def split: if_split_asm)
821   qed (auto simp add: Inf_finite_3_def max_def less_finite_3_def less_eq_finite_3_def split: if_split_asm)
822   show "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
823     by (cases a "\<Squnion>B" rule: finite_3.exhaust[case_product finite_3.exhaust])
824       (auto simp add: Sup_finite_3_def min_def less_finite_3_def less_eq_finite_3_def split: if_split_asm)
825 qed
827 instance finite_3 :: complete_linorder ..
829 instantiation finite_3 :: "{field, idom_abs_sgn}" begin
830 definition [simp]: "0 = a\<^sub>1"
831 definition [simp]: "1 = a\<^sub>2"
832 definition
833   "x + y = (case (x, y) of
834      (a\<^sub>1, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>1 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>1
835    | (a\<^sub>1, a\<^sub>2) \<Rightarrow> a\<^sub>2 | (a\<^sub>2, a\<^sub>1) \<Rightarrow> a\<^sub>2 | (a\<^sub>3, a\<^sub>3) \<Rightarrow> a\<^sub>2
836    | _ \<Rightarrow> a\<^sub>3)"
837 definition "- x = (case x of a\<^sub>1 \<Rightarrow> a\<^sub>1 | a\<^sub>2 \<Rightarrow> a\<^sub>3 | a\<^sub>3 \<Rightarrow> a\<^sub>2)"
838 definition "x - y = x + (- y :: finite_3)"
839 definition "x * y = (case (x, y) of (a\<^sub>2, a\<^sub>2) \<Rightarrow> a\<^sub>2 | (a\<^sub>3, a\<^sub>3) \<Rightarrow> a\<^sub>2 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>3 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>3 | _ \<Rightarrow> a\<^sub>1)"
840 definition "inverse = (\<lambda>x :: finite_3. x)"
841 definition "x div y = x * inverse (y :: finite_3)"
842 definition "abs = (\<lambda>x. case x of a\<^sub>3 \<Rightarrow> a\<^sub>2 | _ \<Rightarrow> x)"
843 definition "sgn = (\<lambda>x :: finite_3. x)"
844 instance
845   by standard
846     (simp_all add: plus_finite_3_def uminus_finite_3_def minus_finite_3_def times_finite_3_def
847       inverse_finite_3_def divide_finite_3_def abs_finite_3_def sgn_finite_3_def
848       less_finite_3_def
849       split: finite_3.splits)
850 end
852 lemma two_finite_3 [simp]:
853   "2 = a\<^sub>3"
854   by (simp add: numeral.simps plus_finite_3_def)
856 lemma dvd_finite_3_unfold:
857   "x dvd y \<longleftrightarrow> x = a\<^sub>2 \<or> x = a\<^sub>3 \<or> y = a\<^sub>1"
858   by (cases x) (auto simp add: dvd_def times_finite_3_def split: finite_3.splits)
860 instantiation finite_3 :: "{ring_div, normalization_semidom}" begin
861 definition "normalize x = (case x of a\<^sub>3 \<Rightarrow> a\<^sub>2 | _ \<Rightarrow> x)"
862 definition [simp]: "unit_factor = (id :: finite_3 \<Rightarrow> _)"
863 definition "x mod y = (case (x, y) of (a\<^sub>2, a\<^sub>1) \<Rightarrow> a\<^sub>2 | (a\<^sub>3, a\<^sub>1) \<Rightarrow> a\<^sub>3 | _ \<Rightarrow> a\<^sub>1)"
864 instance
865   by standard
866     (auto simp add: finite_3_not_eq_unfold plus_finite_3_def
867       dvd_finite_3_unfold times_finite_3_def inverse_finite_3_def
868       normalize_finite_3_def divide_finite_3_def modulo_finite_3_def
869       split: finite_3.splits)
870 end
874 hide_const (open) a\<^sub>1 a\<^sub>2 a\<^sub>3
876 datatype (plugins only: code "quickcheck" extraction) finite_4 =
877   a\<^sub>1 | a\<^sub>2 | a\<^sub>3 | a\<^sub>4
879 notation (output) a\<^sub>1  ("a\<^sub>1")
880 notation (output) a\<^sub>2  ("a\<^sub>2")
881 notation (output) a\<^sub>3  ("a\<^sub>3")
882 notation (output) a\<^sub>4  ("a\<^sub>4")
884 lemma UNIV_finite_4:
885   "UNIV = {a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4}"
886   by (auto intro: finite_4.exhaust)
888 instantiation finite_4 :: enum
889 begin
891 definition
892   "enum = [a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4]"
894 definition
895   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2 \<and> P a\<^sub>3 \<and> P a\<^sub>4"
897 definition
898   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2 \<or> P a\<^sub>3 \<or> P a\<^sub>4"
900 instance proof
901 qed (simp_all only: enum_finite_4_def enum_all_finite_4_def enum_ex_finite_4_def UNIV_finite_4, simp_all)
903 end
905 instantiation finite_4 :: complete_lattice begin
907 text \<open>@{term a\<^sub>1} \$<\$ @{term a\<^sub>2},@{term a\<^sub>3} \$<\$ @{term a\<^sub>4},
908   but @{term a\<^sub>2} and @{term a\<^sub>3} are incomparable.\<close>
910 definition
911   "x < y \<longleftrightarrow> (case (x, y) of
912      (a\<^sub>1, a\<^sub>1) \<Rightarrow> False | (a\<^sub>1, _) \<Rightarrow> True
913    |  (a\<^sub>2, a\<^sub>4) \<Rightarrow> True
914    |  (a\<^sub>3, a\<^sub>4) \<Rightarrow> True  | _ \<Rightarrow> False)"
916 definition
917   "x \<le> y \<longleftrightarrow> (case (x, y) of
918      (a\<^sub>1, _) \<Rightarrow> True
919    | (a\<^sub>2, a\<^sub>2) \<Rightarrow> True | (a\<^sub>2, a\<^sub>4) \<Rightarrow> True
920    | (a\<^sub>3, a\<^sub>3) \<Rightarrow> True | (a\<^sub>3, a\<^sub>4) \<Rightarrow> True
921    | (a\<^sub>4, a\<^sub>4) \<Rightarrow> True | _ \<Rightarrow> False)"
923 definition
924   "\<Sqinter>A = (if a\<^sub>1 \<in> A \<or> a\<^sub>2 \<in> A \<and> a\<^sub>3 \<in> A then a\<^sub>1 else if a\<^sub>2 \<in> A then a\<^sub>2 else if a\<^sub>3 \<in> A then a\<^sub>3 else a\<^sub>4)"
925 definition
926   "\<Squnion>A = (if a\<^sub>4 \<in> A \<or> a\<^sub>2 \<in> A \<and> a\<^sub>3 \<in> A then a\<^sub>4 else if a\<^sub>2 \<in> A then a\<^sub>2 else if a\<^sub>3 \<in> A then a\<^sub>3 else a\<^sub>1)"
927 definition [simp]: "bot = a\<^sub>1"
928 definition [simp]: "top = a\<^sub>4"
929 definition
930   "x \<sqinter> y = (case (x, y) of
931      (a\<^sub>1, _) \<Rightarrow> a\<^sub>1 | (_, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>1 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>1
932    | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
933    | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
934    | _ \<Rightarrow> a\<^sub>4)"
935 definition
936   "x \<squnion> y = (case (x, y) of
937      (a\<^sub>4, _) \<Rightarrow> a\<^sub>4 | (_, a\<^sub>4) \<Rightarrow> a\<^sub>4 | (a\<^sub>2, a\<^sub>3) \<Rightarrow> a\<^sub>4 | (a\<^sub>3, a\<^sub>2) \<Rightarrow> a\<^sub>4
938   | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
939   | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
940   | _ \<Rightarrow> a\<^sub>1)"
942 instance
943 proof
944   fix A and z :: finite_4
945   assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<le> z"
946   show "\<Squnion>A \<le> z"
947     by(auto simp add: Sup_finite_4_def less_eq_finite_4_def dest!: * split: finite_4.splits)
948 next
949   fix A and z :: finite_4
950   assume *: "\<And>x. x \<in> A \<Longrightarrow> z \<le> x"
951   show "z \<le> \<Sqinter>A"
952     by(auto simp add: Inf_finite_4_def less_eq_finite_4_def dest!: * split: finite_4.splits)
953 qed(auto simp add: less_finite_4_def less_eq_finite_4_def Inf_finite_4_def Sup_finite_4_def inf_finite_4_def sup_finite_4_def split: finite_4.splits)
955 end
957 instance finite_4 :: complete_distrib_lattice
958 proof
959   fix a :: finite_4 and B
960   show "a \<squnion> \<Sqinter>B = (\<Sqinter>b\<in>B. a \<squnion> b)"
961     by(cases a "\<Sqinter>B" rule: finite_4.exhaust[case_product finite_4.exhaust])
962       (auto simp add: sup_finite_4_def Inf_finite_4_def split: finite_4.splits if_split_asm)
963   show "a \<sqinter> \<Squnion>B = (\<Squnion>b\<in>B. a \<sqinter> b)"
964     by(cases a "\<Squnion>B" rule: finite_4.exhaust[case_product finite_4.exhaust])
965       (auto simp add: inf_finite_4_def Sup_finite_4_def split: finite_4.splits if_split_asm)
966 qed
968 instantiation finite_4 :: complete_boolean_algebra begin
969 definition "- x = (case x of a\<^sub>1 \<Rightarrow> a\<^sub>4 | a\<^sub>2 \<Rightarrow> a\<^sub>3 | a\<^sub>3 \<Rightarrow> a\<^sub>2 | a\<^sub>4 \<Rightarrow> a\<^sub>1)"
970 definition "x - y = x \<sqinter> - (y :: finite_4)"
971 instance
972 by intro_classes
973   (simp_all add: inf_finite_4_def sup_finite_4_def uminus_finite_4_def minus_finite_4_def split: finite_4.splits)
974 end
976 hide_const (open) a\<^sub>1 a\<^sub>2 a\<^sub>3 a\<^sub>4
978 datatype (plugins only: code "quickcheck" extraction) finite_5 =
979   a\<^sub>1 | a\<^sub>2 | a\<^sub>3 | a\<^sub>4 | a\<^sub>5
981 notation (output) a\<^sub>1  ("a\<^sub>1")
982 notation (output) a\<^sub>2  ("a\<^sub>2")
983 notation (output) a\<^sub>3  ("a\<^sub>3")
984 notation (output) a\<^sub>4  ("a\<^sub>4")
985 notation (output) a\<^sub>5  ("a\<^sub>5")
987 lemma UNIV_finite_5:
988   "UNIV = {a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4, a\<^sub>5}"
989   by (auto intro: finite_5.exhaust)
991 instantiation finite_5 :: enum
992 begin
994 definition
995   "enum = [a\<^sub>1, a\<^sub>2, a\<^sub>3, a\<^sub>4, a\<^sub>5]"
997 definition
998   "enum_all P \<longleftrightarrow> P a\<^sub>1 \<and> P a\<^sub>2 \<and> P a\<^sub>3 \<and> P a\<^sub>4 \<and> P a\<^sub>5"
1000 definition
1001   "enum_ex P \<longleftrightarrow> P a\<^sub>1 \<or> P a\<^sub>2 \<or> P a\<^sub>3 \<or> P a\<^sub>4 \<or> P a\<^sub>5"
1003 instance proof
1004 qed (simp_all only: enum_finite_5_def enum_all_finite_5_def enum_ex_finite_5_def UNIV_finite_5, simp_all)
1006 end
1008 instantiation finite_5 :: complete_lattice
1009 begin
1011 text \<open>The non-distributive pentagon lattice \$N_5\$\<close>
1013 definition
1014   "x < y \<longleftrightarrow> (case (x, y) of
1015      (a\<^sub>1, a\<^sub>1) \<Rightarrow> False | (a\<^sub>1, _) \<Rightarrow> True
1016    | (a\<^sub>2, a\<^sub>3) \<Rightarrow> True  | (a\<^sub>2, a\<^sub>5) \<Rightarrow> True
1017    | (a\<^sub>3, a\<^sub>5) \<Rightarrow> True
1018    | (a\<^sub>4, a\<^sub>5) \<Rightarrow> True  | _ \<Rightarrow> False)"
1020 definition
1021   "x \<le> y \<longleftrightarrow> (case (x, y) of
1022      (a\<^sub>1, _) \<Rightarrow> True
1023    | (a\<^sub>2, a\<^sub>2) \<Rightarrow> True | (a\<^sub>2, a\<^sub>3) \<Rightarrow> True | (a\<^sub>2, a\<^sub>5) \<Rightarrow> True
1024    | (a\<^sub>3, a\<^sub>3) \<Rightarrow> True | (a\<^sub>3, a\<^sub>5) \<Rightarrow> True
1025    | (a\<^sub>4, a\<^sub>4) \<Rightarrow> True | (a\<^sub>4, a\<^sub>5) \<Rightarrow> True
1026    | (a\<^sub>5, a\<^sub>5) \<Rightarrow> True | _ \<Rightarrow> False)"
1028 definition
1029   "\<Sqinter>A =
1030   (if a\<^sub>1 \<in> A \<or> a\<^sub>4 \<in> A \<and> (a\<^sub>2 \<in> A \<or> a\<^sub>3 \<in> A) then a\<^sub>1
1031    else if a\<^sub>2 \<in> A then a\<^sub>2
1032    else if a\<^sub>3 \<in> A then a\<^sub>3
1033    else if a\<^sub>4 \<in> A then a\<^sub>4
1034    else a\<^sub>5)"
1035 definition
1036   "\<Squnion>A =
1037   (if a\<^sub>5 \<in> A \<or> a\<^sub>4 \<in> A \<and> (a\<^sub>2 \<in> A \<or> a\<^sub>3 \<in> A) then a\<^sub>5
1038    else if a\<^sub>3 \<in> A then a\<^sub>3
1039    else if a\<^sub>2 \<in> A then a\<^sub>2
1040    else if a\<^sub>4 \<in> A then a\<^sub>4
1041    else a\<^sub>1)"
1042 definition [simp]: "bot = a\<^sub>1"
1043 definition [simp]: "top = a\<^sub>5"
1044 definition
1045   "x \<sqinter> y = (case (x, y) of
1046      (a\<^sub>1, _) \<Rightarrow> a\<^sub>1 | (_, a\<^sub>1) \<Rightarrow> a\<^sub>1 | (a\<^sub>2, a\<^sub>4) \<Rightarrow> a\<^sub>1 | (a\<^sub>4, a\<^sub>2) \<Rightarrow> a\<^sub>1 | (a\<^sub>3, a\<^sub>4) \<Rightarrow> a\<^sub>1 | (a\<^sub>4, a\<^sub>3) \<Rightarrow> a\<^sub>1
1047    | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
1048    | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
1049    | (a\<^sub>4, _) \<Rightarrow> a\<^sub>4 | (_, a\<^sub>4) \<Rightarrow> a\<^sub>4
1050    | _ \<Rightarrow> a\<^sub>5)"
1051 definition
1052   "x \<squnion> y = (case (x, y) of
1053      (a\<^sub>5, _) \<Rightarrow> a\<^sub>5 | (_, a\<^sub>5) \<Rightarrow> a\<^sub>5 | (a\<^sub>2, a\<^sub>4) \<Rightarrow> a\<^sub>5 | (a\<^sub>4, a\<^sub>2) \<Rightarrow> a\<^sub>5 | (a\<^sub>3, a\<^sub>4) \<Rightarrow> a\<^sub>5 | (a\<^sub>4, a\<^sub>3) \<Rightarrow> a\<^sub>5
1054    | (a\<^sub>3, _) \<Rightarrow> a\<^sub>3 | (_, a\<^sub>3) \<Rightarrow> a\<^sub>3
1055    | (a\<^sub>2, _) \<Rightarrow> a\<^sub>2 | (_, a\<^sub>2) \<Rightarrow> a\<^sub>2
1056    | (a\<^sub>4, _) \<Rightarrow> a\<^sub>4 | (_, a\<^sub>4) \<Rightarrow> a\<^sub>4
1057    | _ \<Rightarrow> a\<^sub>1)"
1059 instance
1060 proof intro_classes
1061   fix A and z :: finite_5
1062   assume *: "\<And>x. x \<in> A \<Longrightarrow> z \<le> x"
1063   show "z \<le> \<Sqinter>A"
1064     by(auto simp add: less_eq_finite_5_def Inf_finite_5_def split: finite_5.splits if_split_asm dest!: *)
1065 next
1066   fix A and z :: finite_5
1067   assume *: "\<And>x. x \<in> A \<Longrightarrow> x \<le> z"
1068   show "\<Squnion>A \<le> z"
1069     by(auto simp add: less_eq_finite_5_def Sup_finite_5_def split: finite_5.splits if_split_asm dest!: *)
1070 qed(auto simp add: less_eq_finite_5_def less_finite_5_def inf_finite_5_def sup_finite_5_def Inf_finite_5_def Sup_finite_5_def split: finite_5.splits if_split_asm)
1072 end
1074 hide_const (open) a\<^sub>1 a\<^sub>2 a\<^sub>3 a\<^sub>4 a\<^sub>5
1077 subsection \<open>Closing up\<close>
1079 hide_type (open) finite_1 finite_2 finite_3 finite_4 finite_5
1080 hide_const (open) enum enum_all enum_ex all_n_lists ex_n_lists ntrancl
1082 end