src/HOL/Limits.thy
author wenzelm
Tue Sep 26 20:54:40 2017 +0200 (21 months ago)
changeset 66695 91500c024c7f
parent 66456 621897f47fab
child 66793 deabce3ccf1f
permissions -rw-r--r--
tuned;
     1 (*  Title:      HOL/Limits.thy
     2     Author:     Brian Huffman
     3     Author:     Jacques D. Fleuriot, University of Cambridge
     4     Author:     Lawrence C Paulson
     5     Author:     Jeremy Avigad
     6 *)
     7 
     8 section \<open>Limits on Real Vector Spaces\<close>
     9 
    10 theory Limits
    11   imports Real_Vector_Spaces
    12 begin
    13 
    14 subsection \<open>Filter going to infinity norm\<close>
    15 
    16 definition at_infinity :: "'a::real_normed_vector filter"
    17   where "at_infinity = (INF r. principal {x. r \<le> norm x})"
    18 
    19 lemma eventually_at_infinity: "eventually P at_infinity \<longleftrightarrow> (\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> P x)"
    20   unfolding at_infinity_def
    21   by (subst eventually_INF_base)
    22      (auto simp: subset_eq eventually_principal intro!: exI[of _ "max a b" for a b])
    23 
    24 corollary eventually_at_infinity_pos:
    25   "eventually p at_infinity \<longleftrightarrow> (\<exists>b. 0 < b \<and> (\<forall>x. norm x \<ge> b \<longrightarrow> p x))"
    26   apply (simp add: eventually_at_infinity)
    27   apply auto
    28   apply (case_tac "b \<le> 0")
    29   using norm_ge_zero order_trans zero_less_one apply blast
    30   apply force
    31   done
    32 
    33 lemma at_infinity_eq_at_top_bot: "(at_infinity :: real filter) = sup at_top at_bot"
    34   apply (simp add: filter_eq_iff eventually_sup eventually_at_infinity
    35       eventually_at_top_linorder eventually_at_bot_linorder)
    36   apply safe
    37     apply (rule_tac x="b" in exI)
    38     apply simp
    39    apply (rule_tac x="- b" in exI)
    40    apply simp
    41   apply (rule_tac x="max (- Na) N" in exI)
    42   apply (auto simp: abs_real_def)
    43   done
    44 
    45 lemma at_top_le_at_infinity: "at_top \<le> (at_infinity :: real filter)"
    46   unfolding at_infinity_eq_at_top_bot by simp
    47 
    48 lemma at_bot_le_at_infinity: "at_bot \<le> (at_infinity :: real filter)"
    49   unfolding at_infinity_eq_at_top_bot by simp
    50 
    51 lemma filterlim_at_top_imp_at_infinity: "filterlim f at_top F \<Longrightarrow> filterlim f at_infinity F"
    52   for f :: "_ \<Rightarrow> real"
    53   by (rule filterlim_mono[OF _ at_top_le_at_infinity order_refl])
    54 
    55 lemma lim_infinity_imp_sequentially: "(f \<longlongrightarrow> l) at_infinity \<Longrightarrow> ((\<lambda>n. f(n)) \<longlongrightarrow> l) sequentially"
    56   by (simp add: filterlim_at_top_imp_at_infinity filterlim_compose filterlim_real_sequentially)
    57 
    58 
    59 subsubsection \<open>Boundedness\<close>
    60 
    61 definition Bfun :: "('a \<Rightarrow> 'b::metric_space) \<Rightarrow> 'a filter \<Rightarrow> bool"
    62   where Bfun_metric_def: "Bfun f F = (\<exists>y. \<exists>K>0. eventually (\<lambda>x. dist (f x) y \<le> K) F)"
    63 
    64 abbreviation Bseq :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool"
    65   where "Bseq X \<equiv> Bfun X sequentially"
    66 
    67 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially" ..
    68 
    69 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
    70   unfolding Bfun_metric_def by (subst eventually_sequentially_seg)
    71 
    72 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
    73   unfolding Bfun_metric_def by (subst (asm) eventually_sequentially_seg)
    74 
    75 lemma Bfun_def: "Bfun f F \<longleftrightarrow> (\<exists>K>0. eventually (\<lambda>x. norm (f x) \<le> K) F)"
    76   unfolding Bfun_metric_def norm_conv_dist
    77 proof safe
    78   fix y K
    79   assume K: "0 < K" and *: "eventually (\<lambda>x. dist (f x) y \<le> K) F"
    80   moreover have "eventually (\<lambda>x. dist (f x) 0 \<le> dist (f x) y + dist 0 y) F"
    81     by (intro always_eventually) (metis dist_commute dist_triangle)
    82   with * have "eventually (\<lambda>x. dist (f x) 0 \<le> K + dist 0 y) F"
    83     by eventually_elim auto
    84   with \<open>0 < K\<close> show "\<exists>K>0. eventually (\<lambda>x. dist (f x) 0 \<le> K) F"
    85     by (intro exI[of _ "K + dist 0 y"] add_pos_nonneg conjI zero_le_dist) auto
    86 qed (force simp del: norm_conv_dist [symmetric])
    87 
    88 lemma BfunI:
    89   assumes K: "eventually (\<lambda>x. norm (f x) \<le> K) F"
    90   shows "Bfun f F"
    91   unfolding Bfun_def
    92 proof (intro exI conjI allI)
    93   show "0 < max K 1" by simp
    94   show "eventually (\<lambda>x. norm (f x) \<le> max K 1) F"
    95     using K by (rule eventually_mono) simp
    96 qed
    97 
    98 lemma BfunE:
    99   assumes "Bfun f F"
   100   obtains B where "0 < B" and "eventually (\<lambda>x. norm (f x) \<le> B) F"
   101   using assms unfolding Bfun_def by blast
   102 
   103 lemma Cauchy_Bseq: "Cauchy X \<Longrightarrow> Bseq X"
   104   unfolding Cauchy_def Bfun_metric_def eventually_sequentially
   105   apply (erule_tac x=1 in allE)
   106   apply simp
   107   apply safe
   108   apply (rule_tac x="X M" in exI)
   109   apply (rule_tac x=1 in exI)
   110   apply (erule_tac x=M in allE)
   111   apply simp
   112   apply (rule_tac x=M in exI)
   113   apply (auto simp: dist_commute)
   114   done
   115 
   116 
   117 subsubsection \<open>Bounded Sequences\<close>
   118 
   119 lemma BseqI': "(\<And>n. norm (X n) \<le> K) \<Longrightarrow> Bseq X"
   120   by (intro BfunI) (auto simp: eventually_sequentially)
   121 
   122 lemma BseqI2': "\<forall>n\<ge>N. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   123   by (intro BfunI) (auto simp: eventually_sequentially)
   124 
   125 lemma Bseq_def: "Bseq X \<longleftrightarrow> (\<exists>K>0. \<forall>n. norm (X n) \<le> K)"
   126   unfolding Bfun_def eventually_sequentially
   127 proof safe
   128   fix N K
   129   assume "0 < K" "\<forall>n\<ge>N. norm (X n) \<le> K"
   130   then show "\<exists>K>0. \<forall>n. norm (X n) \<le> K"
   131     by (intro exI[of _ "max (Max (norm ` X ` {..N})) K"] max.strict_coboundedI2)
   132        (auto intro!: imageI not_less[where 'a=nat, THEN iffD1] Max_ge simp: le_max_iff_disj)
   133 qed auto
   134 
   135 lemma BseqE: "Bseq X \<Longrightarrow> (\<And>K. 0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Q) \<Longrightarrow> Q"
   136   unfolding Bseq_def by auto
   137 
   138 lemma BseqD: "Bseq X \<Longrightarrow> \<exists>K. 0 < K \<and> (\<forall>n. norm (X n) \<le> K)"
   139   by (simp add: Bseq_def)
   140 
   141 lemma BseqI: "0 < K \<Longrightarrow> \<forall>n. norm (X n) \<le> K \<Longrightarrow> Bseq X"
   142   by (auto simp add: Bseq_def)
   143 
   144 lemma Bseq_bdd_above: "Bseq X \<Longrightarrow> bdd_above (range X)"
   145   for X :: "nat \<Rightarrow> real"
   146 proof (elim BseqE, intro bdd_aboveI2)
   147   fix K n
   148   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   149   then show "X n \<le> K"
   150     by (auto elim!: allE[of _ n])
   151 qed
   152 
   153 lemma Bseq_bdd_above': "Bseq X \<Longrightarrow> bdd_above (range (\<lambda>n. norm (X n)))"
   154   for X :: "nat \<Rightarrow> 'a :: real_normed_vector"
   155 proof (elim BseqE, intro bdd_aboveI2)
   156   fix K n
   157   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   158   then show "norm (X n) \<le> K"
   159     by (auto elim!: allE[of _ n])
   160 qed
   161 
   162 lemma Bseq_bdd_below: "Bseq X \<Longrightarrow> bdd_below (range X)"
   163   for X :: "nat \<Rightarrow> real"
   164 proof (elim BseqE, intro bdd_belowI2)
   165   fix K n
   166   assume "0 < K" "\<forall>n. norm (X n) \<le> K"
   167   then show "- K \<le> X n"
   168     by (auto elim!: allE[of _ n])
   169 qed
   170 
   171 lemma Bseq_eventually_mono:
   172   assumes "eventually (\<lambda>n. norm (f n) \<le> norm (g n)) sequentially" "Bseq g"
   173   shows "Bseq f"
   174 proof -
   175   from assms(1) obtain N where N: "\<And>n. n \<ge> N \<Longrightarrow> norm (f n) \<le> norm (g n)"
   176     by (auto simp: eventually_at_top_linorder)
   177   moreover from assms(2) obtain K where K: "\<And>n. norm (g n) \<le> K"
   178     by (blast elim!: BseqE)
   179   ultimately have "norm (f n) \<le> max K (Max {norm (f n) |n. n < N})" for n
   180     apply (cases "n < N")
   181     subgoal by (rule max.coboundedI2, rule Max.coboundedI) auto
   182     subgoal by (rule max.coboundedI1) (force intro: order.trans[OF N K])
   183     done
   184   then show ?thesis by (blast intro: BseqI')
   185 qed
   186 
   187 lemma lemma_NBseq_def: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   188 proof safe
   189   fix K :: real
   190   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   191   then have "K \<le> real (Suc n)" by auto
   192   moreover assume "\<forall>m. norm (X m) \<le> K"
   193   ultimately have "\<forall>m. norm (X m) \<le> real (Suc n)"
   194     by (blast intro: order_trans)
   195   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   196 next
   197   show "\<And>N. \<forall>n. norm (X n) \<le> real (Suc N) \<Longrightarrow> \<exists>K>0. \<forall>n. norm (X n) \<le> K"
   198     using of_nat_0_less_iff by blast
   199 qed
   200 
   201 text \<open>Alternative definition for \<open>Bseq\<close>.\<close>
   202 lemma Bseq_iff: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   203   by (simp add: Bseq_def) (simp add: lemma_NBseq_def)
   204 
   205 lemma lemma_NBseq_def2: "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   206   apply (subst lemma_NBseq_def)
   207   apply auto
   208    apply (rule_tac x = "Suc N" in exI)
   209    apply (rule_tac [2] x = N in exI)
   210    apply auto
   211    prefer 2 apply (blast intro: order_less_imp_le)
   212   apply (drule_tac x = n in spec)
   213   apply simp
   214   done
   215 
   216 text \<open>Yet another definition for Bseq.\<close>
   217 lemma Bseq_iff1a: "Bseq X \<longleftrightarrow> (\<exists>N. \<forall>n. norm (X n) < real (Suc N))"
   218   by (simp add: Bseq_def lemma_NBseq_def2)
   219 
   220 subsubsection \<open>A Few More Equivalence Theorems for Boundedness\<close>
   221 
   222 text \<open>Alternative formulation for boundedness.\<close>
   223 lemma Bseq_iff2: "Bseq X \<longleftrightarrow> (\<exists>k > 0. \<exists>x. \<forall>n. norm (X n + - x) \<le> k)"
   224   apply (unfold Bseq_def)
   225   apply safe
   226    apply (rule_tac [2] x = "k + norm x" in exI)
   227    apply (rule_tac x = K in exI)
   228    apply simp
   229    apply (rule exI [where x = 0])
   230    apply auto
   231    apply (erule order_less_le_trans)
   232    apply simp
   233   apply (drule_tac x=n in spec)
   234   apply (drule order_trans [OF norm_triangle_ineq2])
   235   apply simp
   236   done
   237 
   238 text \<open>Alternative formulation for boundedness.\<close>
   239 lemma Bseq_iff3: "Bseq X \<longleftrightarrow> (\<exists>k>0. \<exists>N. \<forall>n. norm (X n + - X N) \<le> k)"
   240   (is "?P \<longleftrightarrow> ?Q")
   241 proof
   242   assume ?P
   243   then obtain K where *: "0 < K" and **: "\<And>n. norm (X n) \<le> K"
   244     by (auto simp add: Bseq_def)
   245   from * have "0 < K + norm (X 0)" by (rule order_less_le_trans) simp
   246   from ** have "\<forall>n. norm (X n - X 0) \<le> K + norm (X 0)"
   247     by (auto intro: order_trans norm_triangle_ineq4)
   248   then have "\<forall>n. norm (X n + - X 0) \<le> K + norm (X 0)"
   249     by simp
   250   with \<open>0 < K + norm (X 0)\<close> show ?Q by blast
   251 next
   252   assume ?Q
   253   then show ?P by (auto simp add: Bseq_iff2)
   254 qed
   255 
   256 lemma BseqI2: "\<forall>n. k \<le> f n \<and> f n \<le> K \<Longrightarrow> Bseq f"
   257   for k K :: real
   258   apply (simp add: Bseq_def)
   259   apply (rule_tac x = "(\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI)
   260   apply auto
   261   apply (drule_tac x = n in spec)
   262   apply arith
   263   done
   264 
   265 
   266 subsubsection \<open>Upper Bounds and Lubs of Bounded Sequences\<close>
   267 
   268 lemma Bseq_minus_iff: "Bseq (\<lambda>n. - (X n) :: 'a::real_normed_vector) \<longleftrightarrow> Bseq X"
   269   by (simp add: Bseq_def)
   270 
   271 lemma Bseq_add:
   272   fixes f :: "nat \<Rightarrow> 'a::real_normed_vector"
   273   assumes "Bseq f"
   274   shows "Bseq (\<lambda>x. f x + c)"
   275 proof -
   276   from assms obtain K where K: "\<And>x. norm (f x) \<le> K"
   277     unfolding Bseq_def by blast
   278   {
   279     fix x :: nat
   280     have "norm (f x + c) \<le> norm (f x) + norm c" by (rule norm_triangle_ineq)
   281     also have "norm (f x) \<le> K" by (rule K)
   282     finally have "norm (f x + c) \<le> K + norm c" by simp
   283   }
   284   then show ?thesis by (rule BseqI')
   285 qed
   286 
   287 lemma Bseq_add_iff: "Bseq (\<lambda>x. f x + c) \<longleftrightarrow> Bseq f"
   288   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   289   using Bseq_add[of f c] Bseq_add[of "\<lambda>x. f x + c" "-c"] by auto
   290 
   291 lemma Bseq_mult:
   292   fixes f g :: "nat \<Rightarrow> 'a::real_normed_field"
   293   assumes "Bseq f" and "Bseq g"
   294   shows "Bseq (\<lambda>x. f x * g x)"
   295 proof -
   296   from assms obtain K1 K2 where K: "norm (f x) \<le> K1" "K1 > 0" "norm (g x) \<le> K2" "K2 > 0"
   297     for x
   298     unfolding Bseq_def by blast
   299   then have "norm (f x * g x) \<le> K1 * K2" for x
   300     by (auto simp: norm_mult intro!: mult_mono)
   301   then show ?thesis by (rule BseqI')
   302 qed
   303 
   304 lemma Bfun_const [simp]: "Bfun (\<lambda>_. c) F"
   305   unfolding Bfun_metric_def by (auto intro!: exI[of _ c] exI[of _ "1::real"])
   306 
   307 lemma Bseq_cmult_iff:
   308   fixes c :: "'a::real_normed_field"
   309   assumes "c \<noteq> 0"
   310   shows "Bseq (\<lambda>x. c * f x) \<longleftrightarrow> Bseq f"
   311 proof
   312   assume "Bseq (\<lambda>x. c * f x)"
   313   with Bfun_const have "Bseq (\<lambda>x. inverse c * (c * f x))"
   314     by (rule Bseq_mult)
   315   with \<open>c \<noteq> 0\<close> show "Bseq f"
   316     by (simp add: divide_simps)
   317 qed (intro Bseq_mult Bfun_const)
   318 
   319 lemma Bseq_subseq: "Bseq f \<Longrightarrow> Bseq (\<lambda>x. f (g x))"
   320   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   321   unfolding Bseq_def by auto
   322 
   323 lemma Bseq_Suc_iff: "Bseq (\<lambda>n. f (Suc n)) \<longleftrightarrow> Bseq f"
   324   for f :: "nat \<Rightarrow> 'a::real_normed_vector"
   325   using Bseq_offset[of f 1] by (auto intro: Bseq_subseq)
   326 
   327 lemma increasing_Bseq_subseq_iff:
   328   assumes "\<And>x y. x \<le> y \<Longrightarrow> norm (f x :: 'a::real_normed_vector) \<le> norm (f y)" "strict_mono g"
   329   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   330 proof
   331   assume "Bseq (\<lambda>x. f (g x))"
   332   then obtain K where K: "\<And>x. norm (f (g x)) \<le> K"
   333     unfolding Bseq_def by auto
   334   {
   335     fix x :: nat
   336     from filterlim_subseq[OF assms(2)] obtain y where "g y \<ge> x"
   337       by (auto simp: filterlim_at_top eventually_at_top_linorder)
   338     then have "norm (f x) \<le> norm (f (g y))"
   339       using assms(1) by blast
   340     also have "norm (f (g y)) \<le> K" by (rule K)
   341     finally have "norm (f x) \<le> K" .
   342   }
   343   then show "Bseq f" by (rule BseqI')
   344 qed (use Bseq_subseq[of f g] in simp_all)
   345 
   346 lemma nonneg_incseq_Bseq_subseq_iff:
   347   fixes f :: "nat \<Rightarrow> real"
   348     and g :: "nat \<Rightarrow> nat"
   349   assumes "\<And>x. f x \<ge> 0" "incseq f" "strict_mono g"
   350   shows "Bseq (\<lambda>x. f (g x)) \<longleftrightarrow> Bseq f"
   351   using assms by (intro increasing_Bseq_subseq_iff) (auto simp: incseq_def)
   352 
   353 lemma Bseq_eq_bounded: "range f \<subseteq> {a..b} \<Longrightarrow> Bseq f"
   354   for a b :: real
   355   apply (simp add: subset_eq)
   356   apply (rule BseqI'[where K="max (norm a) (norm b)"])
   357   apply (erule_tac x=n in allE)
   358   apply auto
   359   done
   360 
   361 lemma incseq_bounded: "incseq X \<Longrightarrow> \<forall>i. X i \<le> B \<Longrightarrow> Bseq X"
   362   for B :: real
   363   by (intro Bseq_eq_bounded[of X "X 0" B]) (auto simp: incseq_def)
   364 
   365 lemma decseq_bounded: "decseq X \<Longrightarrow> \<forall>i. B \<le> X i \<Longrightarrow> Bseq X"
   366   for B :: real
   367   by (intro Bseq_eq_bounded[of X B "X 0"]) (auto simp: decseq_def)
   368 
   369 
   370 subsection \<open>Bounded Monotonic Sequences\<close>
   371 
   372 subsubsection \<open>A Bounded and Monotonic Sequence Converges\<close>
   373 
   374 (* TODO: delete *)
   375 (* FIXME: one use in NSA/HSEQ.thy *)
   376 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n \<longrightarrow> X n = X m \<Longrightarrow> \<exists>L. X \<longlonglongrightarrow> L"
   377   apply (rule_tac x="X m" in exI)
   378   apply (rule filterlim_cong[THEN iffD2, OF refl refl _ tendsto_const])
   379   unfolding eventually_sequentially
   380   apply blast
   381   done
   382 
   383 
   384 subsection \<open>Convergence to Zero\<close>
   385 
   386 definition Zfun :: "('a \<Rightarrow> 'b::real_normed_vector) \<Rightarrow> 'a filter \<Rightarrow> bool"
   387   where "Zfun f F = (\<forall>r>0. eventually (\<lambda>x. norm (f x) < r) F)"
   388 
   389 lemma ZfunI: "(\<And>r. 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F) \<Longrightarrow> Zfun f F"
   390   by (simp add: Zfun_def)
   391 
   392 lemma ZfunD: "Zfun f F \<Longrightarrow> 0 < r \<Longrightarrow> eventually (\<lambda>x. norm (f x) < r) F"
   393   by (simp add: Zfun_def)
   394 
   395 lemma Zfun_ssubst: "eventually (\<lambda>x. f x = g x) F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun f F"
   396   unfolding Zfun_def by (auto elim!: eventually_rev_mp)
   397 
   398 lemma Zfun_zero: "Zfun (\<lambda>x. 0) F"
   399   unfolding Zfun_def by simp
   400 
   401 lemma Zfun_norm_iff: "Zfun (\<lambda>x. norm (f x)) F = Zfun (\<lambda>x. f x) F"
   402   unfolding Zfun_def by simp
   403 
   404 lemma Zfun_imp_Zfun:
   405   assumes f: "Zfun f F"
   406     and g: "eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F"
   407   shows "Zfun (\<lambda>x. g x) F"
   408 proof (cases "0 < K")
   409   case K: True
   410   show ?thesis
   411   proof (rule ZfunI)
   412     fix r :: real
   413     assume "0 < r"
   414     then have "0 < r / K" using K by simp
   415     then have "eventually (\<lambda>x. norm (f x) < r / K) F"
   416       using ZfunD [OF f] by blast
   417     with g show "eventually (\<lambda>x. norm (g x) < r) F"
   418     proof eventually_elim
   419       case (elim x)
   420       then have "norm (f x) * K < r"
   421         by (simp add: pos_less_divide_eq K)
   422       then show ?case
   423         by (simp add: order_le_less_trans [OF elim(1)])
   424     qed
   425   qed
   426 next
   427   case False
   428   then have K: "K \<le> 0" by (simp only: not_less)
   429   show ?thesis
   430   proof (rule ZfunI)
   431     fix r :: real
   432     assume "0 < r"
   433     from g show "eventually (\<lambda>x. norm (g x) < r) F"
   434     proof eventually_elim
   435       case (elim x)
   436       also have "norm (f x) * K \<le> norm (f x) * 0"
   437         using K norm_ge_zero by (rule mult_left_mono)
   438       finally show ?case
   439         using \<open>0 < r\<close> by simp
   440     qed
   441   qed
   442 qed
   443 
   444 lemma Zfun_le: "Zfun g F \<Longrightarrow> \<forall>x. norm (f x) \<le> norm (g x) \<Longrightarrow> Zfun f F"
   445   by (erule Zfun_imp_Zfun [where K = 1]) simp
   446 
   447 lemma Zfun_add:
   448   assumes f: "Zfun f F"
   449     and g: "Zfun g F"
   450   shows "Zfun (\<lambda>x. f x + g x) F"
   451 proof (rule ZfunI)
   452   fix r :: real
   453   assume "0 < r"
   454   then have r: "0 < r / 2" by simp
   455   have "eventually (\<lambda>x. norm (f x) < r/2) F"
   456     using f r by (rule ZfunD)
   457   moreover
   458   have "eventually (\<lambda>x. norm (g x) < r/2) F"
   459     using g r by (rule ZfunD)
   460   ultimately
   461   show "eventually (\<lambda>x. norm (f x + g x) < r) F"
   462   proof eventually_elim
   463     case (elim x)
   464     have "norm (f x + g x) \<le> norm (f x) + norm (g x)"
   465       by (rule norm_triangle_ineq)
   466     also have "\<dots> < r/2 + r/2"
   467       using elim by (rule add_strict_mono)
   468     finally show ?case
   469       by simp
   470   qed
   471 qed
   472 
   473 lemma Zfun_minus: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. - f x) F"
   474   unfolding Zfun_def by simp
   475 
   476 lemma Zfun_diff: "Zfun f F \<Longrightarrow> Zfun g F \<Longrightarrow> Zfun (\<lambda>x. f x - g x) F"
   477   using Zfun_add [of f F "\<lambda>x. - g x"] by (simp add: Zfun_minus)
   478 
   479 lemma (in bounded_linear) Zfun:
   480   assumes g: "Zfun g F"
   481   shows "Zfun (\<lambda>x. f (g x)) F"
   482 proof -
   483   obtain K where "norm (f x) \<le> norm x * K" for x
   484     using bounded by blast
   485   then have "eventually (\<lambda>x. norm (f (g x)) \<le> norm (g x) * K) F"
   486     by simp
   487   with g show ?thesis
   488     by (rule Zfun_imp_Zfun)
   489 qed
   490 
   491 lemma (in bounded_bilinear) Zfun:
   492   assumes f: "Zfun f F"
   493     and g: "Zfun g F"
   494   shows "Zfun (\<lambda>x. f x ** g x) F"
   495 proof (rule ZfunI)
   496   fix r :: real
   497   assume r: "0 < r"
   498   obtain K where K: "0 < K"
   499     and norm_le: "norm (x ** y) \<le> norm x * norm y * K" for x y
   500     using pos_bounded by blast
   501   from K have K': "0 < inverse K"
   502     by (rule positive_imp_inverse_positive)
   503   have "eventually (\<lambda>x. norm (f x) < r) F"
   504     using f r by (rule ZfunD)
   505   moreover
   506   have "eventually (\<lambda>x. norm (g x) < inverse K) F"
   507     using g K' by (rule ZfunD)
   508   ultimately
   509   show "eventually (\<lambda>x. norm (f x ** g x) < r) F"
   510   proof eventually_elim
   511     case (elim x)
   512     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   513       by (rule norm_le)
   514     also have "norm (f x) * norm (g x) * K < r * inverse K * K"
   515       by (intro mult_strict_right_mono mult_strict_mono' norm_ge_zero elim K)
   516     also from K have "r * inverse K * K = r"
   517       by simp
   518     finally show ?case .
   519   qed
   520 qed
   521 
   522 lemma (in bounded_bilinear) Zfun_left: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. f x ** a) F"
   523   by (rule bounded_linear_left [THEN bounded_linear.Zfun])
   524 
   525 lemma (in bounded_bilinear) Zfun_right: "Zfun f F \<Longrightarrow> Zfun (\<lambda>x. a ** f x) F"
   526   by (rule bounded_linear_right [THEN bounded_linear.Zfun])
   527 
   528 lemmas Zfun_mult = bounded_bilinear.Zfun [OF bounded_bilinear_mult]
   529 lemmas Zfun_mult_right = bounded_bilinear.Zfun_right [OF bounded_bilinear_mult]
   530 lemmas Zfun_mult_left = bounded_bilinear.Zfun_left [OF bounded_bilinear_mult]
   531 
   532 lemma tendsto_Zfun_iff: "(f \<longlongrightarrow> a) F = Zfun (\<lambda>x. f x - a) F"
   533   by (simp only: tendsto_iff Zfun_def dist_norm)
   534 
   535 lemma tendsto_0_le:
   536   "(f \<longlongrightarrow> 0) F \<Longrightarrow> eventually (\<lambda>x. norm (g x) \<le> norm (f x) * K) F \<Longrightarrow> (g \<longlongrightarrow> 0) F"
   537   by (simp add: Zfun_imp_Zfun tendsto_Zfun_iff)
   538 
   539 
   540 subsubsection \<open>Distance and norms\<close>
   541 
   542 lemma tendsto_dist [tendsto_intros]:
   543   fixes l m :: "'a::metric_space"
   544   assumes f: "(f \<longlongrightarrow> l) F"
   545     and g: "(g \<longlongrightarrow> m) F"
   546   shows "((\<lambda>x. dist (f x) (g x)) \<longlongrightarrow> dist l m) F"
   547 proof (rule tendstoI)
   548   fix e :: real
   549   assume "0 < e"
   550   then have e2: "0 < e/2" by simp
   551   from tendstoD [OF f e2] tendstoD [OF g e2]
   552   show "eventually (\<lambda>x. dist (dist (f x) (g x)) (dist l m) < e) F"
   553   proof (eventually_elim)
   554     case (elim x)
   555     then show "dist (dist (f x) (g x)) (dist l m) < e"
   556       unfolding dist_real_def
   557       using dist_triangle2 [of "f x" "g x" "l"]
   558         and dist_triangle2 [of "g x" "l" "m"]
   559         and dist_triangle3 [of "l" "m" "f x"]
   560         and dist_triangle [of "f x" "m" "g x"]
   561       by arith
   562   qed
   563 qed
   564 
   565 lemma continuous_dist[continuous_intros]:
   566   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   567   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. dist (f x) (g x))"
   568   unfolding continuous_def by (rule tendsto_dist)
   569 
   570 lemma continuous_on_dist[continuous_intros]:
   571   fixes f g :: "_ \<Rightarrow> 'a :: metric_space"
   572   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. dist (f x) (g x))"
   573   unfolding continuous_on_def by (auto intro: tendsto_dist)
   574 
   575 lemma tendsto_norm [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> norm a) F"
   576   unfolding norm_conv_dist by (intro tendsto_intros)
   577 
   578 lemma continuous_norm [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. norm (f x))"
   579   unfolding continuous_def by (rule tendsto_norm)
   580 
   581 lemma continuous_on_norm [continuous_intros]:
   582   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. norm (f x))"
   583   unfolding continuous_on_def by (auto intro: tendsto_norm)
   584 
   585 lemma tendsto_norm_zero: "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F"
   586   by (drule tendsto_norm) simp
   587 
   588 lemma tendsto_norm_zero_cancel: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   589   unfolding tendsto_iff dist_norm by simp
   590 
   591 lemma tendsto_norm_zero_iff: "((\<lambda>x. norm (f x)) \<longlongrightarrow> 0) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   592   unfolding tendsto_iff dist_norm by simp
   593 
   594 lemma tendsto_rabs [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> \<bar>l\<bar>) F"
   595   for l :: real
   596   by (fold real_norm_def) (rule tendsto_norm)
   597 
   598 lemma continuous_rabs [continuous_intros]:
   599   "continuous F f \<Longrightarrow> continuous F (\<lambda>x. \<bar>f x :: real\<bar>)"
   600   unfolding real_norm_def[symmetric] by (rule continuous_norm)
   601 
   602 lemma continuous_on_rabs [continuous_intros]:
   603   "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. \<bar>f x :: real\<bar>)"
   604   unfolding real_norm_def[symmetric] by (rule continuous_on_norm)
   605 
   606 lemma tendsto_rabs_zero: "(f \<longlongrightarrow> (0::real)) F \<Longrightarrow> ((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> 0) F"
   607   by (fold real_norm_def) (rule tendsto_norm_zero)
   608 
   609 lemma tendsto_rabs_zero_cancel: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<Longrightarrow> (f \<longlongrightarrow> 0) F"
   610   by (fold real_norm_def) (rule tendsto_norm_zero_cancel)
   611 
   612 lemma tendsto_rabs_zero_iff: "((\<lambda>x. \<bar>f x\<bar>) \<longlongrightarrow> (0::real)) F \<longleftrightarrow> (f \<longlongrightarrow> 0) F"
   613   by (fold real_norm_def) (rule tendsto_norm_zero_iff)
   614 
   615 
   616 subsection \<open>Topological Monoid\<close>
   617 
   618 class topological_monoid_add = topological_space + monoid_add +
   619   assumes tendsto_add_Pair: "LIM x (nhds a \<times>\<^sub>F nhds b). fst x + snd x :> nhds (a + b)"
   620 
   621 class topological_comm_monoid_add = topological_monoid_add + comm_monoid_add
   622 
   623 lemma tendsto_add [tendsto_intros]:
   624   fixes a b :: "'a::topological_monoid_add"
   625   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> a + b) F"
   626   using filterlim_compose[OF tendsto_add_Pair, of "\<lambda>x. (f x, g x)" a b F]
   627   by (simp add: nhds_prod[symmetric] tendsto_Pair)
   628 
   629 lemma continuous_add [continuous_intros]:
   630   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   631   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x + g x)"
   632   unfolding continuous_def by (rule tendsto_add)
   633 
   634 lemma continuous_on_add [continuous_intros]:
   635   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   636   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x + g x)"
   637   unfolding continuous_on_def by (auto intro: tendsto_add)
   638 
   639 lemma tendsto_add_zero:
   640   fixes f g :: "_ \<Rightarrow> 'b::topological_monoid_add"
   641   shows "(f \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x + g x) \<longlongrightarrow> 0) F"
   642   by (drule (1) tendsto_add) simp
   643 
   644 lemma tendsto_sum [tendsto_intros]:
   645   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::topological_comm_monoid_add"
   646   shows "(\<And>i. i \<in> I \<Longrightarrow> (f i \<longlongrightarrow> a i) F) \<Longrightarrow> ((\<lambda>x. \<Sum>i\<in>I. f i x) \<longlongrightarrow> (\<Sum>i\<in>I. a i)) F"
   647   by (induct I rule: infinite_finite_induct) (simp_all add: tendsto_add)
   648 
   649 lemma continuous_sum [continuous_intros]:
   650   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
   651   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Sum>i\<in>I. f i x)"
   652   unfolding continuous_def by (rule tendsto_sum)
   653 
   654 lemma continuous_on_sum [continuous_intros]:
   655   fixes f :: "'a \<Rightarrow> 'b::topological_space \<Rightarrow> 'c::topological_comm_monoid_add"
   656   shows "(\<And>i. i \<in> I \<Longrightarrow> continuous_on S (f i)) \<Longrightarrow> continuous_on S (\<lambda>x. \<Sum>i\<in>I. f i x)"
   657   unfolding continuous_on_def by (auto intro: tendsto_sum)
   658 
   659 instance nat :: topological_comm_monoid_add
   660   by standard
   661     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   662 
   663 instance int :: topological_comm_monoid_add
   664   by standard
   665     (simp add: nhds_discrete principal_prod_principal filterlim_principal eventually_principal)
   666 
   667 
   668 subsubsection \<open>Topological group\<close>
   669 
   670 class topological_group_add = topological_monoid_add + group_add +
   671   assumes tendsto_uminus_nhds: "(uminus \<longlongrightarrow> - a) (nhds a)"
   672 begin
   673 
   674 lemma tendsto_minus [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> - a) F"
   675   by (rule filterlim_compose[OF tendsto_uminus_nhds])
   676 
   677 end
   678 
   679 class topological_ab_group_add = topological_group_add + ab_group_add
   680 
   681 instance topological_ab_group_add < topological_comm_monoid_add ..
   682 
   683 lemma continuous_minus [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. - f x)"
   684   for f :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
   685   unfolding continuous_def by (rule tendsto_minus)
   686 
   687 lemma continuous_on_minus [continuous_intros]: "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. - f x)"
   688   for f :: "_ \<Rightarrow> 'b::topological_group_add"
   689   unfolding continuous_on_def by (auto intro: tendsto_minus)
   690 
   691 lemma tendsto_minus_cancel: "((\<lambda>x. - f x) \<longlongrightarrow> - a) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
   692   for a :: "'a::topological_group_add"
   693   by (drule tendsto_minus) simp
   694 
   695 lemma tendsto_minus_cancel_left:
   696   "(f \<longlongrightarrow> - (y::_::topological_group_add)) F \<longleftrightarrow> ((\<lambda>x. - f x) \<longlongrightarrow> y) F"
   697   using tendsto_minus_cancel[of f "- y" F]  tendsto_minus[of f "- y" F]
   698   by auto
   699 
   700 lemma tendsto_diff [tendsto_intros]:
   701   fixes a b :: "'a::topological_group_add"
   702   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> a - b) F"
   703   using tendsto_add [of f a F "\<lambda>x. - g x" "- b"] by (simp add: tendsto_minus)
   704 
   705 lemma continuous_diff [continuous_intros]:
   706   fixes f g :: "'a::t2_space \<Rightarrow> 'b::topological_group_add"
   707   shows "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x - g x)"
   708   unfolding continuous_def by (rule tendsto_diff)
   709 
   710 lemma continuous_on_diff [continuous_intros]:
   711   fixes f g :: "_ \<Rightarrow> 'b::topological_group_add"
   712   shows "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x - g x)"
   713   unfolding continuous_on_def by (auto intro: tendsto_diff)
   714 
   715 lemma continuous_on_op_minus: "continuous_on (s::'a::topological_group_add set) (op - x)"
   716   by (rule continuous_intros | simp)+
   717 
   718 instance real_normed_vector < topological_ab_group_add
   719 proof
   720   fix a b :: 'a
   721   show "((\<lambda>x. fst x + snd x) \<longlongrightarrow> a + b) (nhds a \<times>\<^sub>F nhds b)"
   722     unfolding tendsto_Zfun_iff add_diff_add
   723     using tendsto_fst[OF filterlim_ident, of "(a,b)"] tendsto_snd[OF filterlim_ident, of "(a,b)"]
   724     by (intro Zfun_add)
   725        (auto simp add: tendsto_Zfun_iff[symmetric] nhds_prod[symmetric] intro!: tendsto_fst)
   726   show "(uminus \<longlongrightarrow> - a) (nhds a)"
   727     unfolding tendsto_Zfun_iff minus_diff_minus
   728     using filterlim_ident[of "nhds a"]
   729     by (intro Zfun_minus) (simp add: tendsto_Zfun_iff)
   730 qed
   731 
   732 lemmas real_tendsto_sandwich = tendsto_sandwich[where 'a=real]
   733 
   734 
   735 subsubsection \<open>Linear operators and multiplication\<close>
   736 
   737 lemma linear_times: "linear (\<lambda>x. c * x)"
   738   for c :: "'a::real_algebra"
   739   by (auto simp: linearI distrib_left)
   740 
   741 lemma (in bounded_linear) tendsto: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> f a) F"
   742   by (simp only: tendsto_Zfun_iff diff [symmetric] Zfun)
   743 
   744 lemma (in bounded_linear) continuous: "continuous F g \<Longrightarrow> continuous F (\<lambda>x. f (g x))"
   745   using tendsto[of g _ F] by (auto simp: continuous_def)
   746 
   747 lemma (in bounded_linear) continuous_on: "continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f (g x))"
   748   using tendsto[of g] by (auto simp: continuous_on_def)
   749 
   750 lemma (in bounded_linear) tendsto_zero: "(g \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f (g x)) \<longlongrightarrow> 0) F"
   751   by (drule tendsto) (simp only: zero)
   752 
   753 lemma (in bounded_bilinear) tendsto:
   754   "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> ((\<lambda>x. f x ** g x) \<longlongrightarrow> a ** b) F"
   755   by (simp only: tendsto_Zfun_iff prod_diff_prod Zfun_add Zfun Zfun_left Zfun_right)
   756 
   757 lemma (in bounded_bilinear) continuous:
   758   "continuous F f \<Longrightarrow> continuous F g \<Longrightarrow> continuous F (\<lambda>x. f x ** g x)"
   759   using tendsto[of f _ F g] by (auto simp: continuous_def)
   760 
   761 lemma (in bounded_bilinear) continuous_on:
   762   "continuous_on s f \<Longrightarrow> continuous_on s g \<Longrightarrow> continuous_on s (\<lambda>x. f x ** g x)"
   763   using tendsto[of f _ _ g] by (auto simp: continuous_on_def)
   764 
   765 lemma (in bounded_bilinear) tendsto_zero:
   766   assumes f: "(f \<longlongrightarrow> 0) F"
   767     and g: "(g \<longlongrightarrow> 0) F"
   768   shows "((\<lambda>x. f x ** g x) \<longlongrightarrow> 0) F"
   769   using tendsto [OF f g] by (simp add: zero_left)
   770 
   771 lemma (in bounded_bilinear) tendsto_left_zero:
   772   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. f x ** c) \<longlongrightarrow> 0) F"
   773   by (rule bounded_linear.tendsto_zero [OF bounded_linear_left])
   774 
   775 lemma (in bounded_bilinear) tendsto_right_zero:
   776   "(f \<longlongrightarrow> 0) F \<Longrightarrow> ((\<lambda>x. c ** f x) \<longlongrightarrow> 0) F"
   777   by (rule bounded_linear.tendsto_zero [OF bounded_linear_right])
   778 
   779 lemmas tendsto_of_real [tendsto_intros] =
   780   bounded_linear.tendsto [OF bounded_linear_of_real]
   781 
   782 lemmas tendsto_scaleR [tendsto_intros] =
   783   bounded_bilinear.tendsto [OF bounded_bilinear_scaleR]
   784 
   785 lemmas tendsto_mult [tendsto_intros] =
   786   bounded_bilinear.tendsto [OF bounded_bilinear_mult]
   787 
   788 lemma tendsto_mult_left: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. c * (f x)) \<longlongrightarrow> c * l) F"
   789   for c :: "'a::real_normed_algebra"
   790   by (rule tendsto_mult [OF tendsto_const])
   791 
   792 lemma tendsto_mult_right: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. (f x) * c) \<longlongrightarrow> l * c) F"
   793   for c :: "'a::real_normed_algebra"
   794   by (rule tendsto_mult [OF _ tendsto_const])
   795 
   796 lemmas continuous_of_real [continuous_intros] =
   797   bounded_linear.continuous [OF bounded_linear_of_real]
   798 
   799 lemmas continuous_scaleR [continuous_intros] =
   800   bounded_bilinear.continuous [OF bounded_bilinear_scaleR]
   801 
   802 lemmas continuous_mult [continuous_intros] =
   803   bounded_bilinear.continuous [OF bounded_bilinear_mult]
   804 
   805 lemmas continuous_on_of_real [continuous_intros] =
   806   bounded_linear.continuous_on [OF bounded_linear_of_real]
   807 
   808 lemmas continuous_on_scaleR [continuous_intros] =
   809   bounded_bilinear.continuous_on [OF bounded_bilinear_scaleR]
   810 
   811 lemmas continuous_on_mult [continuous_intros] =
   812   bounded_bilinear.continuous_on [OF bounded_bilinear_mult]
   813 
   814 lemmas tendsto_mult_zero =
   815   bounded_bilinear.tendsto_zero [OF bounded_bilinear_mult]
   816 
   817 lemmas tendsto_mult_left_zero =
   818   bounded_bilinear.tendsto_left_zero [OF bounded_bilinear_mult]
   819 
   820 lemmas tendsto_mult_right_zero =
   821   bounded_bilinear.tendsto_right_zero [OF bounded_bilinear_mult]
   822 
   823 lemma tendsto_power [tendsto_intros]: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> a ^ n) F"
   824   for f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra}"
   825   by (induct n) (simp_all add: tendsto_mult)
   826 
   827 lemma tendsto_null_power: "\<lbrakk>(f \<longlongrightarrow> 0) F; 0 < n\<rbrakk> \<Longrightarrow> ((\<lambda>x. f x ^ n) \<longlongrightarrow> 0) F"
   828     for f :: "'a \<Rightarrow> 'b::{power,real_normed_algebra_1}"
   829   using tendsto_power [of f 0 F n] by (simp add: power_0_left)
   830 
   831 lemma continuous_power [continuous_intros]: "continuous F f \<Longrightarrow> continuous F (\<lambda>x. (f x)^n)"
   832   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
   833   unfolding continuous_def by (rule tendsto_power)
   834 
   835 lemma continuous_on_power [continuous_intros]:
   836   fixes f :: "_ \<Rightarrow> 'b::{power,real_normed_algebra}"
   837   shows "continuous_on s f \<Longrightarrow> continuous_on s (\<lambda>x. (f x)^n)"
   838   unfolding continuous_on_def by (auto intro: tendsto_power)
   839 
   840 lemma tendsto_prod [tendsto_intros]:
   841   fixes f :: "'a \<Rightarrow> 'b \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   842   shows "(\<And>i. i \<in> S \<Longrightarrow> (f i \<longlongrightarrow> L i) F) \<Longrightarrow> ((\<lambda>x. \<Prod>i\<in>S. f i x) \<longlongrightarrow> (\<Prod>i\<in>S. L i)) F"
   843   by (induct S rule: infinite_finite_induct) (simp_all add: tendsto_mult)
   844 
   845 lemma continuous_prod [continuous_intros]:
   846   fixes f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   847   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous F (f i)) \<Longrightarrow> continuous F (\<lambda>x. \<Prod>i\<in>S. f i x)"
   848   unfolding continuous_def by (rule tendsto_prod)
   849 
   850 lemma continuous_on_prod [continuous_intros]:
   851   fixes f :: "'a \<Rightarrow> _ \<Rightarrow> 'c::{real_normed_algebra,comm_ring_1}"
   852   shows "(\<And>i. i \<in> S \<Longrightarrow> continuous_on s (f i)) \<Longrightarrow> continuous_on s (\<lambda>x. \<Prod>i\<in>S. f i x)"
   853   unfolding continuous_on_def by (auto intro: tendsto_prod)
   854 
   855 lemma tendsto_of_real_iff:
   856   "((\<lambda>x. of_real (f x) :: 'a::real_normed_div_algebra) \<longlongrightarrow> of_real c) F \<longleftrightarrow> (f \<longlongrightarrow> c) F"
   857   unfolding tendsto_iff by simp
   858 
   859 lemma tendsto_add_const_iff:
   860   "((\<lambda>x. c + f x :: 'a::real_normed_vector) \<longlongrightarrow> c + d) F \<longleftrightarrow> (f \<longlongrightarrow> d) F"
   861   using tendsto_add[OF tendsto_const[of c], of f d]
   862     and tendsto_add[OF tendsto_const[of "-c"], of "\<lambda>x. c + f x" "c + d"] by auto
   863 
   864 
   865 subsubsection \<open>Inverse and division\<close>
   866 
   867 lemma (in bounded_bilinear) Zfun_prod_Bfun:
   868   assumes f: "Zfun f F"
   869     and g: "Bfun g F"
   870   shows "Zfun (\<lambda>x. f x ** g x) F"
   871 proof -
   872   obtain K where K: "0 \<le> K"
   873     and norm_le: "\<And>x y. norm (x ** y) \<le> norm x * norm y * K"
   874     using nonneg_bounded by blast
   875   obtain B where B: "0 < B"
   876     and norm_g: "eventually (\<lambda>x. norm (g x) \<le> B) F"
   877     using g by (rule BfunE)
   878   have "eventually (\<lambda>x. norm (f x ** g x) \<le> norm (f x) * (B * K)) F"
   879   using norm_g proof eventually_elim
   880     case (elim x)
   881     have "norm (f x ** g x) \<le> norm (f x) * norm (g x) * K"
   882       by (rule norm_le)
   883     also have "\<dots> \<le> norm (f x) * B * K"
   884       by (intro mult_mono' order_refl norm_g norm_ge_zero mult_nonneg_nonneg K elim)
   885     also have "\<dots> = norm (f x) * (B * K)"
   886       by (rule mult.assoc)
   887     finally show "norm (f x ** g x) \<le> norm (f x) * (B * K)" .
   888   qed
   889   with f show ?thesis
   890     by (rule Zfun_imp_Zfun)
   891 qed
   892 
   893 lemma (in bounded_bilinear) Bfun_prod_Zfun:
   894   assumes f: "Bfun f F"
   895     and g: "Zfun g F"
   896   shows "Zfun (\<lambda>x. f x ** g x) F"
   897   using flip g f by (rule bounded_bilinear.Zfun_prod_Bfun)
   898 
   899 lemma Bfun_inverse_lemma:
   900   fixes x :: "'a::real_normed_div_algebra"
   901   shows "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
   902   apply (subst nonzero_norm_inverse)
   903   apply clarsimp
   904   apply (erule (1) le_imp_inverse_le)
   905   done
   906 
   907 lemma Bfun_inverse:
   908   fixes a :: "'a::real_normed_div_algebra"
   909   assumes f: "(f \<longlongrightarrow> a) F"
   910   assumes a: "a \<noteq> 0"
   911   shows "Bfun (\<lambda>x. inverse (f x)) F"
   912 proof -
   913   from a have "0 < norm a" by simp
   914   then have "\<exists>r>0. r < norm a" by (rule dense)
   915   then obtain r where r1: "0 < r" and r2: "r < norm a"
   916     by blast
   917   have "eventually (\<lambda>x. dist (f x) a < r) F"
   918     using tendstoD [OF f r1] by blast
   919   then have "eventually (\<lambda>x. norm (inverse (f x)) \<le> inverse (norm a - r)) F"
   920   proof eventually_elim
   921     case (elim x)
   922     then have 1: "norm (f x - a) < r"
   923       by (simp add: dist_norm)
   924     then have 2: "f x \<noteq> 0" using r2 by auto
   925     then have "norm (inverse (f x)) = inverse (norm (f x))"
   926       by (rule nonzero_norm_inverse)
   927     also have "\<dots> \<le> inverse (norm a - r)"
   928     proof (rule le_imp_inverse_le)
   929       show "0 < norm a - r"
   930         using r2 by simp
   931       have "norm a - norm (f x) \<le> norm (a - f x)"
   932         by (rule norm_triangle_ineq2)
   933       also have "\<dots> = norm (f x - a)"
   934         by (rule norm_minus_commute)
   935       also have "\<dots> < r" using 1 .
   936       finally show "norm a - r \<le> norm (f x)"
   937         by simp
   938     qed
   939     finally show "norm (inverse (f x)) \<le> inverse (norm a - r)" .
   940   qed
   941   then show ?thesis by (rule BfunI)
   942 qed
   943 
   944 lemma tendsto_inverse [tendsto_intros]:
   945   fixes a :: "'a::real_normed_div_algebra"
   946   assumes f: "(f \<longlongrightarrow> a) F"
   947     and a: "a \<noteq> 0"
   948   shows "((\<lambda>x. inverse (f x)) \<longlongrightarrow> inverse a) F"
   949 proof -
   950   from a have "0 < norm a" by simp
   951   with f have "eventually (\<lambda>x. dist (f x) a < norm a) F"
   952     by (rule tendstoD)
   953   then have "eventually (\<lambda>x. f x \<noteq> 0) F"
   954     unfolding dist_norm by (auto elim!: eventually_mono)
   955   with a have "eventually (\<lambda>x. inverse (f x) - inverse a =
   956     - (inverse (f x) * (f x - a) * inverse a)) F"
   957     by (auto elim!: eventually_mono simp: inverse_diff_inverse)
   958   moreover have "Zfun (\<lambda>x. - (inverse (f x) * (f x - a) * inverse a)) F"
   959     by (intro Zfun_minus Zfun_mult_left
   960       bounded_bilinear.Bfun_prod_Zfun [OF bounded_bilinear_mult]
   961       Bfun_inverse [OF f a] f [unfolded tendsto_Zfun_iff])
   962   ultimately show ?thesis
   963     unfolding tendsto_Zfun_iff by (rule Zfun_ssubst)
   964 qed
   965 
   966 lemma continuous_inverse:
   967   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   968   assumes "continuous F f"
   969     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
   970   shows "continuous F (\<lambda>x. inverse (f x))"
   971   using assms unfolding continuous_def by (rule tendsto_inverse)
   972 
   973 lemma continuous_at_within_inverse[continuous_intros]:
   974   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   975   assumes "continuous (at a within s) f"
   976     and "f a \<noteq> 0"
   977   shows "continuous (at a within s) (\<lambda>x. inverse (f x))"
   978   using assms unfolding continuous_within by (rule tendsto_inverse)
   979 
   980 lemma isCont_inverse[continuous_intros, simp]:
   981   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_div_algebra"
   982   assumes "isCont f a"
   983     and "f a \<noteq> 0"
   984   shows "isCont (\<lambda>x. inverse (f x)) a"
   985   using assms unfolding continuous_at by (rule tendsto_inverse)
   986 
   987 lemma continuous_on_inverse[continuous_intros]:
   988   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_div_algebra"
   989   assumes "continuous_on s f"
   990     and "\<forall>x\<in>s. f x \<noteq> 0"
   991   shows "continuous_on s (\<lambda>x. inverse (f x))"
   992   using assms unfolding continuous_on_def by (blast intro: tendsto_inverse)
   993 
   994 lemma tendsto_divide [tendsto_intros]:
   995   fixes a b :: "'a::real_normed_field"
   996   shows "(f \<longlongrightarrow> a) F \<Longrightarrow> (g \<longlongrightarrow> b) F \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> ((\<lambda>x. f x / g x) \<longlongrightarrow> a / b) F"
   997   by (simp add: tendsto_mult tendsto_inverse divide_inverse)
   998 
   999 lemma continuous_divide:
  1000   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1001   assumes "continuous F f"
  1002     and "continuous F g"
  1003     and "g (Lim F (\<lambda>x. x)) \<noteq> 0"
  1004   shows "continuous F (\<lambda>x. (f x) / (g x))"
  1005   using assms unfolding continuous_def by (rule tendsto_divide)
  1006 
  1007 lemma continuous_at_within_divide[continuous_intros]:
  1008   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1009   assumes "continuous (at a within s) f" "continuous (at a within s) g"
  1010     and "g a \<noteq> 0"
  1011   shows "continuous (at a within s) (\<lambda>x. (f x) / (g x))"
  1012   using assms unfolding continuous_within by (rule tendsto_divide)
  1013 
  1014 lemma isCont_divide[continuous_intros, simp]:
  1015   fixes f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_field"
  1016   assumes "isCont f a" "isCont g a" "g a \<noteq> 0"
  1017   shows "isCont (\<lambda>x. (f x) / g x) a"
  1018   using assms unfolding continuous_at by (rule tendsto_divide)
  1019 
  1020 lemma continuous_on_divide[continuous_intros]:
  1021   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_field"
  1022   assumes "continuous_on s f" "continuous_on s g"
  1023     and "\<forall>x\<in>s. g x \<noteq> 0"
  1024   shows "continuous_on s (\<lambda>x. (f x) / (g x))"
  1025   using assms unfolding continuous_on_def by (blast intro: tendsto_divide)
  1026 
  1027 lemma tendsto_sgn [tendsto_intros]: "(f \<longlongrightarrow> l) F \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> ((\<lambda>x. sgn (f x)) \<longlongrightarrow> sgn l) F"
  1028   for l :: "'a::real_normed_vector"
  1029   unfolding sgn_div_norm by (simp add: tendsto_intros)
  1030 
  1031 lemma continuous_sgn:
  1032   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1033   assumes "continuous F f"
  1034     and "f (Lim F (\<lambda>x. x)) \<noteq> 0"
  1035   shows "continuous F (\<lambda>x. sgn (f x))"
  1036   using assms unfolding continuous_def by (rule tendsto_sgn)
  1037 
  1038 lemma continuous_at_within_sgn[continuous_intros]:
  1039   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1040   assumes "continuous (at a within s) f"
  1041     and "f a \<noteq> 0"
  1042   shows "continuous (at a within s) (\<lambda>x. sgn (f x))"
  1043   using assms unfolding continuous_within by (rule tendsto_sgn)
  1044 
  1045 lemma isCont_sgn[continuous_intros]:
  1046   fixes f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  1047   assumes "isCont f a"
  1048     and "f a \<noteq> 0"
  1049   shows "isCont (\<lambda>x. sgn (f x)) a"
  1050   using assms unfolding continuous_at by (rule tendsto_sgn)
  1051 
  1052 lemma continuous_on_sgn[continuous_intros]:
  1053   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  1054   assumes "continuous_on s f"
  1055     and "\<forall>x\<in>s. f x \<noteq> 0"
  1056   shows "continuous_on s (\<lambda>x. sgn (f x))"
  1057   using assms unfolding continuous_on_def by (blast intro: tendsto_sgn)
  1058 
  1059 lemma filterlim_at_infinity:
  1060   fixes f :: "_ \<Rightarrow> 'a::real_normed_vector"
  1061   assumes "0 \<le> c"
  1062   shows "(LIM x F. f x :> at_infinity) \<longleftrightarrow> (\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F)"
  1063   unfolding filterlim_iff eventually_at_infinity
  1064 proof safe
  1065   fix P :: "'a \<Rightarrow> bool"
  1066   fix b
  1067   assume *: "\<forall>r>c. eventually (\<lambda>x. r \<le> norm (f x)) F"
  1068   assume P: "\<forall>x. b \<le> norm x \<longrightarrow> P x"
  1069   have "max b (c + 1) > c" by auto
  1070   with * have "eventually (\<lambda>x. max b (c + 1) \<le> norm (f x)) F"
  1071     by auto
  1072   then show "eventually (\<lambda>x. P (f x)) F"
  1073   proof eventually_elim
  1074     case (elim x)
  1075     with P show "P (f x)" by auto
  1076   qed
  1077 qed force
  1078 
  1079 lemma not_tendsto_and_filterlim_at_infinity:
  1080   fixes c :: "'a::real_normed_vector"
  1081   assumes "F \<noteq> bot"
  1082     and "(f \<longlongrightarrow> c) F"
  1083     and "filterlim f at_infinity F"
  1084   shows False
  1085 proof -
  1086   from tendstoD[OF assms(2), of "1/2"]
  1087   have "eventually (\<lambda>x. dist (f x) c < 1/2) F"
  1088     by simp
  1089   moreover
  1090   from filterlim_at_infinity[of "norm c" f F] assms(3)
  1091   have "eventually (\<lambda>x. norm (f x) \<ge> norm c + 1) F" by simp
  1092   ultimately have "eventually (\<lambda>x. False) F"
  1093   proof eventually_elim
  1094     fix x
  1095     assume A: "dist (f x) c < 1/2"
  1096     assume "norm (f x) \<ge> norm c + 1"
  1097     also have "norm (f x) = dist (f x) 0" by simp
  1098     also have "\<dots> \<le> dist (f x) c + dist c 0" by (rule dist_triangle)
  1099     finally show False using A by simp
  1100   qed
  1101   with assms show False by simp
  1102 qed
  1103 
  1104 lemma filterlim_at_infinity_imp_not_convergent:
  1105   assumes "filterlim f at_infinity sequentially"
  1106   shows "\<not> convergent f"
  1107   by (rule notI, rule not_tendsto_and_filterlim_at_infinity[OF _ _ assms])
  1108      (simp_all add: convergent_LIMSEQ_iff)
  1109 
  1110 lemma filterlim_at_infinity_imp_eventually_ne:
  1111   assumes "filterlim f at_infinity F"
  1112   shows "eventually (\<lambda>z. f z \<noteq> c) F"
  1113 proof -
  1114   have "norm c + 1 > 0"
  1115     by (intro add_nonneg_pos) simp_all
  1116   with filterlim_at_infinity[OF order.refl, of f F] assms
  1117   have "eventually (\<lambda>z. norm (f z) \<ge> norm c + 1) F"
  1118     by blast
  1119   then show ?thesis
  1120     by eventually_elim auto
  1121 qed
  1122 
  1123 lemma tendsto_of_nat [tendsto_intros]:
  1124   "filterlim (of_nat :: nat \<Rightarrow> 'a::real_normed_algebra_1) at_infinity sequentially"
  1125 proof (subst filterlim_at_infinity[OF order.refl], intro allI impI)
  1126   fix r :: real
  1127   assume r: "r > 0"
  1128   define n where "n = nat \<lceil>r\<rceil>"
  1129   from r have n: "\<forall>m\<ge>n. of_nat m \<ge> r"
  1130     unfolding n_def by linarith
  1131   from eventually_ge_at_top[of n] show "eventually (\<lambda>m. norm (of_nat m :: 'a) \<ge> r) sequentially"
  1132     by eventually_elim (use n in simp_all)
  1133 qed
  1134 
  1135 
  1136 subsection \<open>Relate @{const at}, @{const at_left} and @{const at_right}\<close>
  1137 
  1138 text \<open>
  1139   This lemmas are useful for conversion between @{term "at x"} to @{term "at_left x"} and
  1140   @{term "at_right x"} and also @{term "at_right 0"}.
  1141 \<close>
  1142 
  1143 lemmas filterlim_split_at_real = filterlim_split_at[where 'a=real]
  1144 
  1145 lemma filtermap_nhds_shift: "filtermap (\<lambda>x. x - d) (nhds a) = nhds (a - d)"
  1146   for a d :: "'a::real_normed_vector"
  1147   by (rule filtermap_fun_inverse[where g="\<lambda>x. x + d"])
  1148     (auto intro!: tendsto_eq_intros filterlim_ident)
  1149 
  1150 lemma filtermap_nhds_minus: "filtermap (\<lambda>x. - x) (nhds a) = nhds (- a)"
  1151   for a :: "'a::real_normed_vector"
  1152   by (rule filtermap_fun_inverse[where g=uminus])
  1153     (auto intro!: tendsto_eq_intros filterlim_ident)
  1154 
  1155 lemma filtermap_at_shift: "filtermap (\<lambda>x. x - d) (at a) = at (a - d)"
  1156   for a d :: "'a::real_normed_vector"
  1157   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1158 
  1159 lemma filtermap_at_right_shift: "filtermap (\<lambda>x. x - d) (at_right a) = at_right (a - d)"
  1160   for a d :: "real"
  1161   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_shift[symmetric])
  1162 
  1163 lemma at_right_to_0: "at_right a = filtermap (\<lambda>x. x + a) (at_right 0)"
  1164   for a :: real
  1165   using filtermap_at_right_shift[of "-a" 0] by simp
  1166 
  1167 lemma filterlim_at_right_to_0:
  1168   "filterlim f F (at_right a) \<longleftrightarrow> filterlim (\<lambda>x. f (x + a)) F (at_right 0)"
  1169   for a :: real
  1170   unfolding filterlim_def filtermap_filtermap at_right_to_0[of a] ..
  1171 
  1172 lemma eventually_at_right_to_0:
  1173   "eventually P (at_right a) \<longleftrightarrow> eventually (\<lambda>x. P (x + a)) (at_right 0)"
  1174   for a :: real
  1175   unfolding at_right_to_0[of a] by (simp add: eventually_filtermap)
  1176 
  1177 lemma filtermap_at_minus: "filtermap (\<lambda>x. - x) (at a) = at (- a)"
  1178   for a :: "'a::real_normed_vector"
  1179   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1180 
  1181 lemma at_left_minus: "at_left a = filtermap (\<lambda>x. - x) (at_right (- a))"
  1182   for a :: real
  1183   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1184 
  1185 lemma at_right_minus: "at_right a = filtermap (\<lambda>x. - x) (at_left (- a))"
  1186   for a :: real
  1187   by (simp add: filter_eq_iff eventually_filtermap eventually_at_filter filtermap_nhds_minus[symmetric])
  1188 
  1189 lemma filterlim_at_left_to_right:
  1190   "filterlim f F (at_left a) \<longleftrightarrow> filterlim (\<lambda>x. f (- x)) F (at_right (-a))"
  1191   for a :: real
  1192   unfolding filterlim_def filtermap_filtermap at_left_minus[of a] ..
  1193 
  1194 lemma eventually_at_left_to_right:
  1195   "eventually P (at_left a) \<longleftrightarrow> eventually (\<lambda>x. P (- x)) (at_right (-a))"
  1196   for a :: real
  1197   unfolding at_left_minus[of a] by (simp add: eventually_filtermap)
  1198 
  1199 lemma filterlim_uminus_at_top_at_bot: "LIM x at_bot. - x :: real :> at_top"
  1200   unfolding filterlim_at_top eventually_at_bot_dense
  1201   by (metis leI minus_less_iff order_less_asym)
  1202 
  1203 lemma filterlim_uminus_at_bot_at_top: "LIM x at_top. - x :: real :> at_bot"
  1204   unfolding filterlim_at_bot eventually_at_top_dense
  1205   by (metis leI less_minus_iff order_less_asym)
  1206 
  1207 lemma at_top_mirror: "at_top = filtermap uminus (at_bot :: real filter)"
  1208   by (rule filtermap_fun_inverse[symmetric, of uminus])
  1209      (auto intro: filterlim_uminus_at_bot_at_top filterlim_uminus_at_top_at_bot)
  1210 
  1211 lemma at_bot_mirror: "at_bot = filtermap uminus (at_top :: real filter)"
  1212   unfolding at_top_mirror filtermap_filtermap by (simp add: filtermap_ident)
  1213 
  1214 lemma filterlim_at_top_mirror: "(LIM x at_top. f x :> F) \<longleftrightarrow> (LIM x at_bot. f (-x::real) :> F)"
  1215   unfolding filterlim_def at_top_mirror filtermap_filtermap ..
  1216 
  1217 lemma filterlim_at_bot_mirror: "(LIM x at_bot. f x :> F) \<longleftrightarrow> (LIM x at_top. f (-x::real) :> F)"
  1218   unfolding filterlim_def at_bot_mirror filtermap_filtermap ..
  1219 
  1220 lemma filterlim_uminus_at_top: "(LIM x F. f x :> at_top) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_bot)"
  1221   using filterlim_compose[OF filterlim_uminus_at_bot_at_top, of f F]
  1222     and filterlim_compose[OF filterlim_uminus_at_top_at_bot, of "\<lambda>x. - f x" F]
  1223   by auto
  1224 
  1225 lemma filterlim_uminus_at_bot: "(LIM x F. f x :> at_bot) \<longleftrightarrow> (LIM x F. - (f x) :: real :> at_top)"
  1226   unfolding filterlim_uminus_at_top by simp
  1227 
  1228 lemma filterlim_inverse_at_top_right: "LIM x at_right (0::real). inverse x :> at_top"
  1229   unfolding filterlim_at_top_gt[where c=0] eventually_at_filter
  1230 proof safe
  1231   fix Z :: real
  1232   assume [arith]: "0 < Z"
  1233   then have "eventually (\<lambda>x. x < inverse Z) (nhds 0)"
  1234     by (auto simp add: eventually_nhds_metric dist_real_def intro!: exI[of _ "\<bar>inverse Z\<bar>"])
  1235   then show "eventually (\<lambda>x. x \<noteq> 0 \<longrightarrow> x \<in> {0<..} \<longrightarrow> Z \<le> inverse x) (nhds 0)"
  1236     by (auto elim!: eventually_mono simp: inverse_eq_divide field_simps)
  1237 qed
  1238 
  1239 lemma tendsto_inverse_0:
  1240   fixes x :: "_ \<Rightarrow> 'a::real_normed_div_algebra"
  1241   shows "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1242   unfolding tendsto_Zfun_iff diff_0_right Zfun_def eventually_at_infinity
  1243 proof safe
  1244   fix r :: real
  1245   assume "0 < r"
  1246   show "\<exists>b. \<forall>x. b \<le> norm x \<longrightarrow> norm (inverse x :: 'a) < r"
  1247   proof (intro exI[of _ "inverse (r / 2)"] allI impI)
  1248     fix x :: 'a
  1249     from \<open>0 < r\<close> have "0 < inverse (r / 2)" by simp
  1250     also assume *: "inverse (r / 2) \<le> norm x"
  1251     finally show "norm (inverse x) < r"
  1252       using * \<open>0 < r\<close>
  1253       by (subst nonzero_norm_inverse) (simp_all add: inverse_eq_divide field_simps)
  1254   qed
  1255 qed
  1256 
  1257 lemma tendsto_add_filterlim_at_infinity:
  1258   fixes c :: "'b::real_normed_vector"
  1259     and F :: "'a filter"
  1260   assumes "(f \<longlongrightarrow> c) F"
  1261     and "filterlim g at_infinity F"
  1262   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1263 proof (subst filterlim_at_infinity[OF order_refl], safe)
  1264   fix r :: real
  1265   assume r: "r > 0"
  1266   from assms(1) have "((\<lambda>x. norm (f x)) \<longlongrightarrow> norm c) F"
  1267     by (rule tendsto_norm)
  1268   then have "eventually (\<lambda>x. norm (f x) < norm c + 1) F"
  1269     by (rule order_tendstoD) simp_all
  1270   moreover from r have "r + norm c + 1 > 0"
  1271     by (intro add_pos_nonneg) simp_all
  1272   with assms(2) have "eventually (\<lambda>x. norm (g x) \<ge> r + norm c + 1) F"
  1273     unfolding filterlim_at_infinity[OF order_refl]
  1274     by (elim allE[of _ "r + norm c + 1"]) simp_all
  1275   ultimately show "eventually (\<lambda>x. norm (f x + g x) \<ge> r) F"
  1276   proof eventually_elim
  1277     fix x :: 'a
  1278     assume A: "norm (f x) < norm c + 1" and B: "r + norm c + 1 \<le> norm (g x)"
  1279     from A B have "r \<le> norm (g x) - norm (f x)"
  1280       by simp
  1281     also have "norm (g x) - norm (f x) \<le> norm (g x + f x)"
  1282       by (rule norm_diff_ineq)
  1283     finally show "r \<le> norm (f x + g x)"
  1284       by (simp add: add_ac)
  1285   qed
  1286 qed
  1287 
  1288 lemma tendsto_add_filterlim_at_infinity':
  1289   fixes c :: "'b::real_normed_vector"
  1290     and F :: "'a filter"
  1291   assumes "filterlim f at_infinity F"
  1292     and "(g \<longlongrightarrow> c) F"
  1293   shows "filterlim (\<lambda>x. f x + g x) at_infinity F"
  1294   by (subst add.commute) (rule tendsto_add_filterlim_at_infinity assms)+
  1295 
  1296 lemma filterlim_inverse_at_right_top: "LIM x at_top. inverse x :> at_right (0::real)"
  1297   unfolding filterlim_at
  1298   by (auto simp: eventually_at_top_dense)
  1299      (metis tendsto_inverse_0 filterlim_mono at_top_le_at_infinity order_refl)
  1300 
  1301 lemma filterlim_inverse_at_top:
  1302   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. 0 < f x) F \<Longrightarrow> LIM x F. inverse (f x) :> at_top"
  1303   by (intro filterlim_compose[OF filterlim_inverse_at_top_right])
  1304      (simp add: filterlim_def eventually_filtermap eventually_mono at_within_def le_principal)
  1305 
  1306 lemma filterlim_inverse_at_bot_neg:
  1307   "LIM x (at_left (0::real)). inverse x :> at_bot"
  1308   by (simp add: filterlim_inverse_at_top_right filterlim_uminus_at_bot filterlim_at_left_to_right)
  1309 
  1310 lemma filterlim_inverse_at_bot:
  1311   "(f \<longlongrightarrow> (0 :: real)) F \<Longrightarrow> eventually (\<lambda>x. f x < 0) F \<Longrightarrow> LIM x F. inverse (f x) :> at_bot"
  1312   unfolding filterlim_uminus_at_bot inverse_minus_eq[symmetric]
  1313   by (rule filterlim_inverse_at_top) (simp_all add: tendsto_minus_cancel_left[symmetric])
  1314 
  1315 lemma at_right_to_top: "(at_right (0::real)) = filtermap inverse at_top"
  1316   by (intro filtermap_fun_inverse[symmetric, where g=inverse])
  1317      (auto intro: filterlim_inverse_at_top_right filterlim_inverse_at_right_top)
  1318 
  1319 lemma eventually_at_right_to_top:
  1320   "eventually P (at_right (0::real)) \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) at_top"
  1321   unfolding at_right_to_top eventually_filtermap ..
  1322 
  1323 lemma filterlim_at_right_to_top:
  1324   "filterlim f F (at_right (0::real)) \<longleftrightarrow> (LIM x at_top. f (inverse x) :> F)"
  1325   unfolding filterlim_def at_right_to_top filtermap_filtermap ..
  1326 
  1327 lemma at_top_to_right: "at_top = filtermap inverse (at_right (0::real))"
  1328   unfolding at_right_to_top filtermap_filtermap inverse_inverse_eq filtermap_ident ..
  1329 
  1330 lemma eventually_at_top_to_right:
  1331   "eventually P at_top \<longleftrightarrow> eventually (\<lambda>x. P (inverse x)) (at_right (0::real))"
  1332   unfolding at_top_to_right eventually_filtermap ..
  1333 
  1334 lemma filterlim_at_top_to_right:
  1335   "filterlim f F at_top \<longleftrightarrow> (LIM x (at_right (0::real)). f (inverse x) :> F)"
  1336   unfolding filterlim_def at_top_to_right filtermap_filtermap ..
  1337 
  1338 lemma filterlim_inverse_at_infinity:
  1339   fixes x :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1340   shows "filterlim inverse at_infinity (at (0::'a))"
  1341   unfolding filterlim_at_infinity[OF order_refl]
  1342 proof safe
  1343   fix r :: real
  1344   assume "0 < r"
  1345   then show "eventually (\<lambda>x::'a. r \<le> norm (inverse x)) (at 0)"
  1346     unfolding eventually_at norm_inverse
  1347     by (intro exI[of _ "inverse r"])
  1348        (auto simp: norm_conv_dist[symmetric] field_simps inverse_eq_divide)
  1349 qed
  1350 
  1351 lemma filterlim_inverse_at_iff:
  1352   fixes g :: "'a \<Rightarrow> 'b::{real_normed_div_algebra, division_ring}"
  1353   shows "(LIM x F. inverse (g x) :> at 0) \<longleftrightarrow> (LIM x F. g x :> at_infinity)"
  1354   unfolding filterlim_def filtermap_filtermap[symmetric]
  1355 proof
  1356   assume "filtermap g F \<le> at_infinity"
  1357   then have "filtermap inverse (filtermap g F) \<le> filtermap inverse at_infinity"
  1358     by (rule filtermap_mono)
  1359   also have "\<dots> \<le> at 0"
  1360     using tendsto_inverse_0[where 'a='b]
  1361     by (auto intro!: exI[of _ 1]
  1362         simp: le_principal eventually_filtermap filterlim_def at_within_def eventually_at_infinity)
  1363   finally show "filtermap inverse (filtermap g F) \<le> at 0" .
  1364 next
  1365   assume "filtermap inverse (filtermap g F) \<le> at 0"
  1366   then have "filtermap inverse (filtermap inverse (filtermap g F)) \<le> filtermap inverse (at 0)"
  1367     by (rule filtermap_mono)
  1368   with filterlim_inverse_at_infinity show "filtermap g F \<le> at_infinity"
  1369     by (auto intro: order_trans simp: filterlim_def filtermap_filtermap)
  1370 qed
  1371 
  1372 lemma tendsto_mult_filterlim_at_infinity:
  1373   fixes c :: "'a::real_normed_field"
  1374   assumes  "(f \<longlongrightarrow> c) F" "c \<noteq> 0"
  1375   assumes "filterlim g at_infinity F"
  1376   shows "filterlim (\<lambda>x. f x * g x) at_infinity F"
  1377 proof -
  1378   have "((\<lambda>x. inverse (f x) * inverse (g x)) \<longlongrightarrow> inverse c * 0) F"
  1379     by (intro tendsto_mult tendsto_inverse assms filterlim_compose[OF tendsto_inverse_0])
  1380   then have "filterlim (\<lambda>x. inverse (f x) * inverse (g x)) (at (inverse c * 0)) F"
  1381     unfolding filterlim_at
  1382     using assms
  1383     by (auto intro: filterlim_at_infinity_imp_eventually_ne tendsto_imp_eventually_ne eventually_conj)
  1384   then show ?thesis
  1385     by (subst filterlim_inverse_at_iff[symmetric]) simp_all
  1386 qed  
  1387 
  1388 lemma tendsto_inverse_0_at_top: "LIM x F. f x :> at_top \<Longrightarrow> ((\<lambda>x. inverse (f x) :: real) \<longlongrightarrow> 0) F"
  1389  by (metis filterlim_at filterlim_mono[OF _ at_top_le_at_infinity order_refl] filterlim_inverse_at_iff)
  1390 
  1391 lemma real_tendsto_divide_at_top:
  1392   fixes c::"real"
  1393   assumes "(f \<longlongrightarrow> c) F"
  1394   assumes "filterlim g at_top F"
  1395   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1396   by (auto simp: divide_inverse_commute
  1397       intro!: tendsto_mult[THEN tendsto_eq_rhs] tendsto_inverse_0_at_top assms)
  1398 
  1399 lemma mult_nat_left_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. c * x) at_top sequentially"
  1400   for c :: nat
  1401   by (rule filterlim_subseq) (auto simp: strict_mono_def)
  1402 
  1403 lemma mult_nat_right_at_top: "c > 0 \<Longrightarrow> filterlim (\<lambda>x. x * c) at_top sequentially"
  1404   for c :: nat
  1405   by (rule filterlim_subseq) (auto simp: strict_mono_def)
  1406 
  1407 lemma at_to_infinity: "(at (0::'a::{real_normed_field,field})) = filtermap inverse at_infinity"
  1408 proof (rule antisym)
  1409   have "(inverse \<longlongrightarrow> (0::'a)) at_infinity"
  1410     by (fact tendsto_inverse_0)
  1411   then show "filtermap inverse at_infinity \<le> at (0::'a)"
  1412     apply (simp add: le_principal eventually_filtermap eventually_at_infinity filterlim_def at_within_def)
  1413     apply (rule_tac x="1" in exI)
  1414     apply auto
  1415     done
  1416 next
  1417   have "filtermap inverse (filtermap inverse (at (0::'a))) \<le> filtermap inverse at_infinity"
  1418     using filterlim_inverse_at_infinity unfolding filterlim_def
  1419     by (rule filtermap_mono)
  1420   then show "at (0::'a) \<le> filtermap inverse at_infinity"
  1421     by (simp add: filtermap_ident filtermap_filtermap)
  1422 qed
  1423 
  1424 lemma lim_at_infinity_0:
  1425   fixes l :: "'a::{real_normed_field,field}"
  1426   shows "(f \<longlongrightarrow> l) at_infinity \<longleftrightarrow> ((f \<circ> inverse) \<longlongrightarrow> l) (at (0::'a))"
  1427   by (simp add: tendsto_compose_filtermap at_to_infinity filtermap_filtermap)
  1428 
  1429 lemma lim_zero_infinity:
  1430   fixes l :: "'a::{real_normed_field,field}"
  1431   shows "((\<lambda>x. f(1 / x)) \<longlongrightarrow> l) (at (0::'a)) \<Longrightarrow> (f \<longlongrightarrow> l) at_infinity"
  1432   by (simp add: inverse_eq_divide lim_at_infinity_0 comp_def)
  1433 
  1434 
  1435 text \<open>
  1436   We only show rules for multiplication and addition when the functions are either against a real
  1437   value or against infinity. Further rules are easy to derive by using @{thm
  1438   filterlim_uminus_at_top}.
  1439 \<close>
  1440 
  1441 lemma filterlim_tendsto_pos_mult_at_top:
  1442   assumes f: "(f \<longlongrightarrow> c) F"
  1443     and c: "0 < c"
  1444     and g: "LIM x F. g x :> at_top"
  1445   shows "LIM x F. (f x * g x :: real) :> at_top"
  1446   unfolding filterlim_at_top_gt[where c=0]
  1447 proof safe
  1448   fix Z :: real
  1449   assume "0 < Z"
  1450   from f \<open>0 < c\<close> have "eventually (\<lambda>x. c / 2 < f x) F"
  1451     by (auto dest!: tendstoD[where e="c / 2"] elim!: eventually_mono
  1452         simp: dist_real_def abs_real_def split: if_split_asm)
  1453   moreover from g have "eventually (\<lambda>x. (Z / c * 2) \<le> g x) F"
  1454     unfolding filterlim_at_top by auto
  1455   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1456   proof eventually_elim
  1457     case (elim x)
  1458     with \<open>0 < Z\<close> \<open>0 < c\<close> have "c / 2 * (Z / c * 2) \<le> f x * g x"
  1459       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1460     with \<open>0 < c\<close> show "Z \<le> f x * g x"
  1461        by simp
  1462   qed
  1463 qed
  1464 
  1465 lemma filterlim_at_top_mult_at_top:
  1466   assumes f: "LIM x F. f x :> at_top"
  1467     and g: "LIM x F. g x :> at_top"
  1468   shows "LIM x F. (f x * g x :: real) :> at_top"
  1469   unfolding filterlim_at_top_gt[where c=0]
  1470 proof safe
  1471   fix Z :: real
  1472   assume "0 < Z"
  1473   from f have "eventually (\<lambda>x. 1 \<le> f x) F"
  1474     unfolding filterlim_at_top by auto
  1475   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1476     unfolding filterlim_at_top by auto
  1477   ultimately show "eventually (\<lambda>x. Z \<le> f x * g x) F"
  1478   proof eventually_elim
  1479     case (elim x)
  1480     with \<open>0 < Z\<close> have "1 * Z \<le> f x * g x"
  1481       by (intro mult_mono) (auto simp: zero_le_divide_iff)
  1482     then show "Z \<le> f x * g x"
  1483        by simp
  1484   qed
  1485 qed
  1486 
  1487 lemma filterlim_at_top_mult_tendsto_pos:
  1488   assumes f: "(f \<longlongrightarrow> c) F"
  1489     and c: "0 < c"
  1490     and g: "LIM x F. g x :> at_top"
  1491   shows "LIM x F. (g x * f x:: real) :> at_top"
  1492   by (auto simp: mult.commute intro!: filterlim_tendsto_pos_mult_at_top f c g)
  1493 
  1494 lemma filterlim_tendsto_pos_mult_at_bot:
  1495   fixes c :: real
  1496   assumes "(f \<longlongrightarrow> c) F" "0 < c" "filterlim g at_bot F"
  1497   shows "LIM x F. f x * g x :> at_bot"
  1498   using filterlim_tendsto_pos_mult_at_top[OF assms(1,2), of "\<lambda>x. - g x"] assms(3)
  1499   unfolding filterlim_uminus_at_bot by simp
  1500 
  1501 lemma filterlim_tendsto_neg_mult_at_bot:
  1502   fixes c :: real
  1503   assumes c: "(f \<longlongrightarrow> c) F" "c < 0" and g: "filterlim g at_top F"
  1504   shows "LIM x F. f x * g x :> at_bot"
  1505   using c filterlim_tendsto_pos_mult_at_top[of "\<lambda>x. - f x" "- c" F, OF _ _ g]
  1506   unfolding filterlim_uminus_at_bot tendsto_minus_cancel_left by simp
  1507 
  1508 lemma filterlim_pow_at_top:
  1509   fixes f :: "'a \<Rightarrow> real"
  1510   assumes "0 < n"
  1511     and f: "LIM x F. f x :> at_top"
  1512   shows "LIM x F. (f x)^n :: real :> at_top"
  1513   using \<open>0 < n\<close>
  1514 proof (induct n)
  1515   case 0
  1516   then show ?case by simp
  1517 next
  1518   case (Suc n) with f show ?case
  1519     by (cases "n = 0") (auto intro!: filterlim_at_top_mult_at_top)
  1520 qed
  1521 
  1522 lemma filterlim_pow_at_bot_even:
  1523   fixes f :: "real \<Rightarrow> real"
  1524   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> even n \<Longrightarrow> LIM x F. (f x)^n :> at_top"
  1525   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_top)
  1526 
  1527 lemma filterlim_pow_at_bot_odd:
  1528   fixes f :: "real \<Rightarrow> real"
  1529   shows "0 < n \<Longrightarrow> LIM x F. f x :> at_bot \<Longrightarrow> odd n \<Longrightarrow> LIM x F. (f x)^n :> at_bot"
  1530   using filterlim_pow_at_top[of n "\<lambda>x. - f x" F] by (simp add: filterlim_uminus_at_bot)
  1531 
  1532 lemma filterlim_tendsto_add_at_top:
  1533   assumes f: "(f \<longlongrightarrow> c) F"
  1534     and g: "LIM x F. g x :> at_top"
  1535   shows "LIM x F. (f x + g x :: real) :> at_top"
  1536   unfolding filterlim_at_top_gt[where c=0]
  1537 proof safe
  1538   fix Z :: real
  1539   assume "0 < Z"
  1540   from f have "eventually (\<lambda>x. c - 1 < f x) F"
  1541     by (auto dest!: tendstoD[where e=1] elim!: eventually_mono simp: dist_real_def)
  1542   moreover from g have "eventually (\<lambda>x. Z - (c - 1) \<le> g x) F"
  1543     unfolding filterlim_at_top by auto
  1544   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1545     by eventually_elim simp
  1546 qed
  1547 
  1548 lemma LIM_at_top_divide:
  1549   fixes f g :: "'a \<Rightarrow> real"
  1550   assumes f: "(f \<longlongrightarrow> a) F" "0 < a"
  1551     and g: "(g \<longlongrightarrow> 0) F" "eventually (\<lambda>x. 0 < g x) F"
  1552   shows "LIM x F. f x / g x :> at_top"
  1553   unfolding divide_inverse
  1554   by (rule filterlim_tendsto_pos_mult_at_top[OF f]) (rule filterlim_inverse_at_top[OF g])
  1555 
  1556 lemma filterlim_at_top_add_at_top:
  1557   assumes f: "LIM x F. f x :> at_top"
  1558     and g: "LIM x F. g x :> at_top"
  1559   shows "LIM x F. (f x + g x :: real) :> at_top"
  1560   unfolding filterlim_at_top_gt[where c=0]
  1561 proof safe
  1562   fix Z :: real
  1563   assume "0 < Z"
  1564   from f have "eventually (\<lambda>x. 0 \<le> f x) F"
  1565     unfolding filterlim_at_top by auto
  1566   moreover from g have "eventually (\<lambda>x. Z \<le> g x) F"
  1567     unfolding filterlim_at_top by auto
  1568   ultimately show "eventually (\<lambda>x. Z \<le> f x + g x) F"
  1569     by eventually_elim simp
  1570 qed
  1571 
  1572 lemma tendsto_divide_0:
  1573   fixes f :: "_ \<Rightarrow> 'a::{real_normed_div_algebra, division_ring}"
  1574   assumes f: "(f \<longlongrightarrow> c) F"
  1575     and g: "LIM x F. g x :> at_infinity"
  1576   shows "((\<lambda>x. f x / g x) \<longlongrightarrow> 0) F"
  1577   using tendsto_mult[OF f filterlim_compose[OF tendsto_inverse_0 g]]
  1578   by (simp add: divide_inverse)
  1579 
  1580 lemma linear_plus_1_le_power:
  1581   fixes x :: real
  1582   assumes x: "0 \<le> x"
  1583   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1584 proof (induct n)
  1585   case 0
  1586   then show ?case by simp
  1587 next
  1588   case (Suc n)
  1589   from x have "real (Suc n) * x + 1 \<le> (x + 1) * (real n * x + 1)"
  1590     by (simp add: field_simps)
  1591   also have "\<dots> \<le> (x + 1)^Suc n"
  1592     using Suc x by (simp add: mult_left_mono)
  1593   finally show ?case .
  1594 qed
  1595 
  1596 lemma filterlim_realpow_sequentially_gt1:
  1597   fixes x :: "'a :: real_normed_div_algebra"
  1598   assumes x[arith]: "1 < norm x"
  1599   shows "LIM n sequentially. x ^ n :> at_infinity"
  1600 proof (intro filterlim_at_infinity[THEN iffD2] allI impI)
  1601   fix y :: real
  1602   assume "0 < y"
  1603   have "0 < norm x - 1" by simp
  1604   then obtain N :: nat where "y < real N * (norm x - 1)"
  1605     by (blast dest: reals_Archimedean3)
  1606   also have "\<dots> \<le> real N * (norm x - 1) + 1"
  1607     by simp
  1608   also have "\<dots> \<le> (norm x - 1 + 1) ^ N"
  1609     by (rule linear_plus_1_le_power) simp
  1610   also have "\<dots> = norm x ^ N"
  1611     by simp
  1612   finally have "\<forall>n\<ge>N. y \<le> norm x ^ n"
  1613     by (metis order_less_le_trans power_increasing order_less_imp_le x)
  1614   then show "eventually (\<lambda>n. y \<le> norm (x ^ n)) sequentially"
  1615     unfolding eventually_sequentially
  1616     by (auto simp: norm_power)
  1617 qed simp
  1618 
  1619 
  1620 lemma filterlim_divide_at_infinity:
  1621   fixes f g :: "'a \<Rightarrow> 'a :: real_normed_field"
  1622   assumes "filterlim f (nhds c) F" "filterlim g (at 0) F" "c \<noteq> 0"
  1623   shows   "filterlim (\<lambda>x. f x / g x) at_infinity F"
  1624 proof -
  1625   have "filterlim (\<lambda>x. f x * inverse (g x)) at_infinity F"
  1626     by (intro tendsto_mult_filterlim_at_infinity[OF assms(1,3)]
  1627           filterlim_compose [OF filterlim_inverse_at_infinity assms(2)])
  1628   thus ?thesis by (simp add: field_simps)
  1629 qed
  1630 
  1631 subsection \<open>Floor and Ceiling\<close>
  1632 
  1633 lemma eventually_floor_less:
  1634   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1635   assumes f: "(f \<longlongrightarrow> l) F"
  1636     and l: "l \<notin> \<int>"
  1637   shows "\<forall>\<^sub>F x in F. of_int (floor l) < f x"
  1638   by (intro order_tendstoD[OF f]) (metis Ints_of_int antisym_conv2 floor_correct l)
  1639 
  1640 lemma eventually_less_ceiling:
  1641   fixes f :: "'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1642   assumes f: "(f \<longlongrightarrow> l) F"
  1643     and l: "l \<notin> \<int>"
  1644   shows "\<forall>\<^sub>F x in F. f x < of_int (ceiling l)"
  1645   by (intro order_tendstoD[OF f]) (metis Ints_of_int l le_of_int_ceiling less_le)
  1646 
  1647 lemma eventually_floor_eq:
  1648   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1649   assumes f: "(f \<longlongrightarrow> l) F"
  1650     and l: "l \<notin> \<int>"
  1651   shows "\<forall>\<^sub>F x in F. floor (f x) = floor l"
  1652   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
  1653   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
  1654 
  1655 lemma eventually_ceiling_eq:
  1656   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1657   assumes f: "(f \<longlongrightarrow> l) F"
  1658     and l: "l \<notin> \<int>"
  1659   shows "\<forall>\<^sub>F x in F. ceiling (f x) = ceiling l"
  1660   using eventually_floor_less[OF assms] eventually_less_ceiling[OF assms]
  1661   by eventually_elim (meson floor_less_iff less_ceiling_iff not_less_iff_gr_or_eq)
  1662 
  1663 lemma tendsto_of_int_floor:
  1664   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1665   assumes "(f \<longlongrightarrow> l) F"
  1666     and "l \<notin> \<int>"
  1667   shows "((\<lambda>x. of_int (floor (f x)) :: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (floor l)) F"
  1668   using eventually_floor_eq[OF assms]
  1669   by (simp add: eventually_mono topological_tendstoI)
  1670 
  1671 lemma tendsto_of_int_ceiling:
  1672   fixes f::"'a \<Rightarrow> 'b::{order_topology,floor_ceiling}"
  1673   assumes "(f \<longlongrightarrow> l) F"
  1674     and "l \<notin> \<int>"
  1675   shows "((\<lambda>x. of_int (ceiling (f x)):: 'c::{ring_1,topological_space}) \<longlongrightarrow> of_int (ceiling l)) F"
  1676   using eventually_ceiling_eq[OF assms]
  1677   by (simp add: eventually_mono topological_tendstoI)
  1678 
  1679 lemma continuous_on_of_int_floor:
  1680   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
  1681     (\<lambda>x. of_int (floor x)::'b::{ring_1, topological_space})"
  1682   unfolding continuous_on_def
  1683   by (auto intro!: tendsto_of_int_floor)
  1684 
  1685 lemma continuous_on_of_int_ceiling:
  1686   "continuous_on (UNIV - \<int>::'a::{order_topology, floor_ceiling} set)
  1687     (\<lambda>x. of_int (ceiling x)::'b::{ring_1, topological_space})"
  1688   unfolding continuous_on_def
  1689   by (auto intro!: tendsto_of_int_ceiling)
  1690 
  1691 
  1692 subsection \<open>Limits of Sequences\<close>
  1693 
  1694 lemma [trans]: "X = Y \<Longrightarrow> Y \<longlonglongrightarrow> z \<Longrightarrow> X \<longlonglongrightarrow> z"
  1695   by simp
  1696 
  1697 lemma LIMSEQ_iff:
  1698   fixes L :: "'a::real_normed_vector"
  1699   shows "(X \<longlonglongrightarrow> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
  1700 unfolding lim_sequentially dist_norm ..
  1701 
  1702 lemma LIMSEQ_I: "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1703   for L :: "'a::real_normed_vector"
  1704   by (simp add: LIMSEQ_iff)
  1705 
  1706 lemma LIMSEQ_D: "X \<longlonglongrightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
  1707   for L :: "'a::real_normed_vector"
  1708   by (simp add: LIMSEQ_iff)
  1709 
  1710 lemma LIMSEQ_linear: "X \<longlonglongrightarrow> x \<Longrightarrow> l > 0 \<Longrightarrow> (\<lambda> n. X (n * l)) \<longlonglongrightarrow> x"
  1711   unfolding tendsto_def eventually_sequentially
  1712   by (metis div_le_dividend div_mult_self1_is_m le_trans mult.commute)
  1713 
  1714 lemma norm_inverse_le_norm: "r \<le> norm x \<Longrightarrow> 0 < r \<Longrightarrow> norm (inverse x) \<le> inverse r"
  1715   for x :: "'a::real_normed_div_algebra"
  1716   apply (subst nonzero_norm_inverse, clarsimp)
  1717   apply (erule (1) le_imp_inverse_le)
  1718   done
  1719 
  1720 lemma Bseq_inverse: "X \<longlonglongrightarrow> a \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
  1721   for a :: "'a::real_normed_div_algebra"
  1722   by (rule Bfun_inverse)
  1723 
  1724 
  1725 text \<open>Transformation of limit.\<close>
  1726 
  1727 lemma Lim_transform: "(g \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F"
  1728   for a b :: "'a::real_normed_vector"
  1729   using tendsto_add [of g a F "\<lambda>x. f x - g x" 0] by simp
  1730 
  1731 lemma Lim_transform2: "(f \<longlongrightarrow> a) F \<Longrightarrow> ((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (g \<longlongrightarrow> a) F"
  1732   for a b :: "'a::real_normed_vector"
  1733   by (erule Lim_transform) (simp add: tendsto_minus_cancel)
  1734 
  1735 proposition Lim_transform_eq: "((\<lambda>x. f x - g x) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> a) F \<longleftrightarrow> (g \<longlongrightarrow> a) F"
  1736   for a :: "'a::real_normed_vector"
  1737   using Lim_transform Lim_transform2 by blast
  1738 
  1739 lemma Lim_transform_eventually:
  1740   "eventually (\<lambda>x. f x = g x) net \<Longrightarrow> (f \<longlongrightarrow> l) net \<Longrightarrow> (g \<longlongrightarrow> l) net"
  1741   apply (rule topological_tendstoI)
  1742   apply (drule (2) topological_tendstoD)
  1743   apply (erule (1) eventually_elim2)
  1744   apply simp
  1745   done
  1746 
  1747 lemma Lim_transform_within:
  1748   assumes "(f \<longlongrightarrow> l) (at x within S)"
  1749     and "0 < d"
  1750     and "\<And>x'. x'\<in>S \<Longrightarrow> 0 < dist x' x \<Longrightarrow> dist x' x < d \<Longrightarrow> f x' = g x'"
  1751   shows "(g \<longlongrightarrow> l) (at x within S)"
  1752 proof (rule Lim_transform_eventually)
  1753   show "eventually (\<lambda>x. f x = g x) (at x within S)"
  1754     using assms by (auto simp: eventually_at)
  1755   show "(f \<longlongrightarrow> l) (at x within S)"
  1756     by fact
  1757 qed
  1758 
  1759 text \<open>Common case assuming being away from some crucial point like 0.\<close>
  1760 lemma Lim_transform_away_within:
  1761   fixes a b :: "'a::t1_space"
  1762   assumes "a \<noteq> b"
  1763     and "\<forall>x\<in>S. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1764     and "(f \<longlongrightarrow> l) (at a within S)"
  1765   shows "(g \<longlongrightarrow> l) (at a within S)"
  1766 proof (rule Lim_transform_eventually)
  1767   show "(f \<longlongrightarrow> l) (at a within S)"
  1768     by fact
  1769   show "eventually (\<lambda>x. f x = g x) (at a within S)"
  1770     unfolding eventually_at_topological
  1771     by (rule exI [where x="- {b}"]) (simp add: open_Compl assms)
  1772 qed
  1773 
  1774 lemma Lim_transform_away_at:
  1775   fixes a b :: "'a::t1_space"
  1776   assumes ab: "a \<noteq> b"
  1777     and fg: "\<forall>x. x \<noteq> a \<and> x \<noteq> b \<longrightarrow> f x = g x"
  1778     and fl: "(f \<longlongrightarrow> l) (at a)"
  1779   shows "(g \<longlongrightarrow> l) (at a)"
  1780   using Lim_transform_away_within[OF ab, of UNIV f g l] fg fl by simp
  1781 
  1782 text \<open>Alternatively, within an open set.\<close>
  1783 lemma Lim_transform_within_open:
  1784   assumes "(f \<longlongrightarrow> l) (at a within T)"
  1785     and "open s" and "a \<in> s"
  1786     and "\<And>x. x\<in>s \<Longrightarrow> x \<noteq> a \<Longrightarrow> f x = g x"
  1787   shows "(g \<longlongrightarrow> l) (at a within T)"
  1788 proof (rule Lim_transform_eventually)
  1789   show "eventually (\<lambda>x. f x = g x) (at a within T)"
  1790     unfolding eventually_at_topological
  1791     using assms by auto
  1792   show "(f \<longlongrightarrow> l) (at a within T)" by fact
  1793 qed
  1794 
  1795 
  1796 text \<open>A congruence rule allowing us to transform limits assuming not at point.\<close>
  1797 
  1798 (* FIXME: Only one congruence rule for tendsto can be used at a time! *)
  1799 
  1800 lemma Lim_cong_within(*[cong add]*):
  1801   assumes "a = b"
  1802     and "x = y"
  1803     and "S = T"
  1804     and "\<And>x. x \<noteq> b \<Longrightarrow> x \<in> T \<Longrightarrow> f x = g x"
  1805   shows "(f \<longlongrightarrow> x) (at a within S) \<longleftrightarrow> (g \<longlongrightarrow> y) (at b within T)"
  1806   unfolding tendsto_def eventually_at_topological
  1807   using assms by simp
  1808 
  1809 lemma Lim_cong_at(*[cong add]*):
  1810   assumes "a = b" "x = y"
  1811     and "\<And>x. x \<noteq> a \<Longrightarrow> f x = g x"
  1812   shows "((\<lambda>x. f x) \<longlongrightarrow> x) (at a) \<longleftrightarrow> ((g \<longlongrightarrow> y) (at a))"
  1813   unfolding tendsto_def eventually_at_topological
  1814   using assms by simp
  1815 
  1816 text \<open>An unbounded sequence's inverse tends to 0.\<close>
  1817 lemma LIMSEQ_inverse_zero:
  1818   assumes "\<And>r::real. \<exists>N. \<forall>n\<ge>N. r < X n"
  1819   shows "(\<lambda>n. inverse (X n)) \<longlonglongrightarrow> 0"
  1820   apply (rule filterlim_compose[OF tendsto_inverse_0])
  1821   apply (simp add: filterlim_at_infinity[OF order_refl] eventually_sequentially)
  1822   apply (metis assms abs_le_D1 linorder_le_cases linorder_not_le)
  1823   done
  1824 
  1825 text \<open>The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity.\<close>
  1826 lemma LIMSEQ_inverse_real_of_nat: "(\<lambda>n. inverse (real (Suc n))) \<longlonglongrightarrow> 0"
  1827   by (metis filterlim_compose tendsto_inverse_0 filterlim_mono order_refl filterlim_Suc
  1828       filterlim_compose[OF filterlim_real_sequentially] at_top_le_at_infinity)
  1829 
  1830 text \<open>
  1831   The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
  1832   infinity is now easily proved.
  1833 \<close>
  1834 
  1835 lemma LIMSEQ_inverse_real_of_nat_add: "(\<lambda>n. r + inverse (real (Suc n))) \<longlonglongrightarrow> r"
  1836   using tendsto_add [OF tendsto_const LIMSEQ_inverse_real_of_nat] by auto
  1837 
  1838 lemma LIMSEQ_inverse_real_of_nat_add_minus: "(\<lambda>n. r + -inverse (real (Suc n))) \<longlonglongrightarrow> r"
  1839   using tendsto_add [OF tendsto_const tendsto_minus [OF LIMSEQ_inverse_real_of_nat]]
  1840   by auto
  1841 
  1842 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult: "(\<lambda>n. r * (1 + - inverse (real (Suc n)))) \<longlonglongrightarrow> r"
  1843   using tendsto_mult [OF tendsto_const LIMSEQ_inverse_real_of_nat_add_minus [of 1]]
  1844   by auto
  1845 
  1846 lemma lim_inverse_n: "((\<lambda>n. inverse(of_nat n)) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  1847   using lim_1_over_n by (simp add: inverse_eq_divide)
  1848 
  1849 lemma LIMSEQ_Suc_n_over_n: "(\<lambda>n. of_nat (Suc n) / of_nat n :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1850 proof (rule Lim_transform_eventually)
  1851   show "eventually (\<lambda>n. 1 + inverse (of_nat n :: 'a) = of_nat (Suc n) / of_nat n) sequentially"
  1852     using eventually_gt_at_top[of "0::nat"]
  1853     by eventually_elim (simp add: field_simps)
  1854   have "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1 + 0"
  1855     by (intro tendsto_add tendsto_const lim_inverse_n)
  1856   then show "(\<lambda>n. 1 + inverse (of_nat n) :: 'a) \<longlonglongrightarrow> 1"
  1857     by simp
  1858 qed
  1859 
  1860 lemma LIMSEQ_n_over_Suc_n: "(\<lambda>n. of_nat n / of_nat (Suc n) :: 'a :: real_normed_field) \<longlonglongrightarrow> 1"
  1861 proof (rule Lim_transform_eventually)
  1862   show "eventually (\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a) =
  1863       of_nat n / of_nat (Suc n)) sequentially"
  1864     using eventually_gt_at_top[of "0::nat"]
  1865     by eventually_elim (simp add: field_simps del: of_nat_Suc)
  1866   have "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> inverse 1"
  1867     by (intro tendsto_inverse LIMSEQ_Suc_n_over_n) simp_all
  1868   then show "(\<lambda>n. inverse (of_nat (Suc n) / of_nat n :: 'a)) \<longlonglongrightarrow> 1"
  1869     by simp
  1870 qed
  1871 
  1872 
  1873 subsection \<open>Convergence on sequences\<close>
  1874 
  1875 lemma convergent_cong:
  1876   assumes "eventually (\<lambda>x. f x = g x) sequentially"
  1877   shows "convergent f \<longleftrightarrow> convergent g"
  1878   unfolding convergent_def
  1879   by (subst filterlim_cong[OF refl refl assms]) (rule refl)
  1880 
  1881 lemma convergent_Suc_iff: "convergent (\<lambda>n. f (Suc n)) \<longleftrightarrow> convergent f"
  1882   by (auto simp: convergent_def LIMSEQ_Suc_iff)
  1883 
  1884 lemma convergent_ignore_initial_segment: "convergent (\<lambda>n. f (n + m)) = convergent f"
  1885 proof (induct m arbitrary: f)
  1886   case 0
  1887   then show ?case by simp
  1888 next
  1889   case (Suc m)
  1890   have "convergent (\<lambda>n. f (n + Suc m)) \<longleftrightarrow> convergent (\<lambda>n. f (Suc n + m))"
  1891     by simp
  1892   also have "\<dots> \<longleftrightarrow> convergent (\<lambda>n. f (n + m))"
  1893     by (rule convergent_Suc_iff)
  1894   also have "\<dots> \<longleftrightarrow> convergent f"
  1895     by (rule Suc)
  1896   finally show ?case .
  1897 qed
  1898 
  1899 lemma convergent_add:
  1900   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1901   assumes "convergent (\<lambda>n. X n)"
  1902     and "convergent (\<lambda>n. Y n)"
  1903   shows "convergent (\<lambda>n. X n + Y n)"
  1904   using assms unfolding convergent_def by (blast intro: tendsto_add)
  1905 
  1906 lemma convergent_sum:
  1907   fixes X :: "'a \<Rightarrow> nat \<Rightarrow> 'b::real_normed_vector"
  1908   shows "(\<And>i. i \<in> A \<Longrightarrow> convergent (\<lambda>n. X i n)) \<Longrightarrow> convergent (\<lambda>n. \<Sum>i\<in>A. X i n)"
  1909   by (induct A rule: infinite_finite_induct) (simp_all add: convergent_const convergent_add)
  1910 
  1911 lemma (in bounded_linear) convergent:
  1912   assumes "convergent (\<lambda>n. X n)"
  1913   shows "convergent (\<lambda>n. f (X n))"
  1914   using assms unfolding convergent_def by (blast intro: tendsto)
  1915 
  1916 lemma (in bounded_bilinear) convergent:
  1917   assumes "convergent (\<lambda>n. X n)"
  1918     and "convergent (\<lambda>n. Y n)"
  1919   shows "convergent (\<lambda>n. X n ** Y n)"
  1920   using assms unfolding convergent_def by (blast intro: tendsto)
  1921 
  1922 lemma convergent_minus_iff: "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
  1923   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1924   apply (simp add: convergent_def)
  1925   apply (auto dest: tendsto_minus)
  1926   apply (drule tendsto_minus)
  1927   apply auto
  1928   done
  1929 
  1930 lemma convergent_diff:
  1931   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_vector"
  1932   assumes "convergent (\<lambda>n. X n)"
  1933   assumes "convergent (\<lambda>n. Y n)"
  1934   shows "convergent (\<lambda>n. X n - Y n)"
  1935   using assms unfolding convergent_def by (blast intro: tendsto_diff)
  1936 
  1937 lemma convergent_norm:
  1938   assumes "convergent f"
  1939   shows "convergent (\<lambda>n. norm (f n))"
  1940 proof -
  1941   from assms have "f \<longlonglongrightarrow> lim f"
  1942     by (simp add: convergent_LIMSEQ_iff)
  1943   then have "(\<lambda>n. norm (f n)) \<longlonglongrightarrow> norm (lim f)"
  1944     by (rule tendsto_norm)
  1945   then show ?thesis
  1946     by (auto simp: convergent_def)
  1947 qed
  1948 
  1949 lemma convergent_of_real:
  1950   "convergent f \<Longrightarrow> convergent (\<lambda>n. of_real (f n) :: 'a::real_normed_algebra_1)"
  1951   unfolding convergent_def by (blast intro!: tendsto_of_real)
  1952 
  1953 lemma convergent_add_const_iff:
  1954   "convergent (\<lambda>n. c + f n :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1955 proof
  1956   assume "convergent (\<lambda>n. c + f n)"
  1957   from convergent_diff[OF this convergent_const[of c]] show "convergent f"
  1958     by simp
  1959 next
  1960   assume "convergent f"
  1961   from convergent_add[OF convergent_const[of c] this] show "convergent (\<lambda>n. c + f n)"
  1962     by simp
  1963 qed
  1964 
  1965 lemma convergent_add_const_right_iff:
  1966   "convergent (\<lambda>n. f n + c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1967   using convergent_add_const_iff[of c f] by (simp add: add_ac)
  1968 
  1969 lemma convergent_diff_const_right_iff:
  1970   "convergent (\<lambda>n. f n - c :: 'a::real_normed_vector) \<longleftrightarrow> convergent f"
  1971   using convergent_add_const_right_iff[of f "-c"] by (simp add: add_ac)
  1972 
  1973 lemma convergent_mult:
  1974   fixes X Y :: "nat \<Rightarrow> 'a::real_normed_field"
  1975   assumes "convergent (\<lambda>n. X n)"
  1976     and "convergent (\<lambda>n. Y n)"
  1977   shows "convergent (\<lambda>n. X n * Y n)"
  1978   using assms unfolding convergent_def by (blast intro: tendsto_mult)
  1979 
  1980 lemma convergent_mult_const_iff:
  1981   assumes "c \<noteq> 0"
  1982   shows "convergent (\<lambda>n. c * f n :: 'a::real_normed_field) \<longleftrightarrow> convergent f"
  1983 proof
  1984   assume "convergent (\<lambda>n. c * f n)"
  1985   from assms convergent_mult[OF this convergent_const[of "inverse c"]]
  1986     show "convergent f" by (simp add: field_simps)
  1987 next
  1988   assume "convergent f"
  1989   from convergent_mult[OF convergent_const[of c] this] show "convergent (\<lambda>n. c * f n)"
  1990     by simp
  1991 qed
  1992 
  1993 lemma convergent_mult_const_right_iff:
  1994   fixes c :: "'a::real_normed_field"
  1995   assumes "c \<noteq> 0"
  1996   shows "convergent (\<lambda>n. f n * c) \<longleftrightarrow> convergent f"
  1997   using convergent_mult_const_iff[OF assms, of f] by (simp add: mult_ac)
  1998 
  1999 lemma convergent_imp_Bseq: "convergent f \<Longrightarrow> Bseq f"
  2000   by (simp add: Cauchy_Bseq convergent_Cauchy)
  2001 
  2002 
  2003 text \<open>A monotone sequence converges to its least upper bound.\<close>
  2004 
  2005 lemma LIMSEQ_incseq_SUP:
  2006   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder,linorder_topology}"
  2007   assumes u: "bdd_above (range X)"
  2008     and X: "incseq X"
  2009   shows "X \<longlonglongrightarrow> (SUP i. X i)"
  2010   by (rule order_tendstoI)
  2011     (auto simp: eventually_sequentially u less_cSUP_iff
  2012       intro: X[THEN incseqD] less_le_trans cSUP_lessD[OF u])
  2013 
  2014 lemma LIMSEQ_decseq_INF:
  2015   fixes X :: "nat \<Rightarrow> 'a::{conditionally_complete_linorder, linorder_topology}"
  2016   assumes u: "bdd_below (range X)"
  2017     and X: "decseq X"
  2018   shows "X \<longlonglongrightarrow> (INF i. X i)"
  2019   by (rule order_tendstoI)
  2020      (auto simp: eventually_sequentially u cINF_less_iff
  2021        intro: X[THEN decseqD] le_less_trans less_cINF_D[OF u])
  2022 
  2023 text \<open>Main monotonicity theorem.\<close>
  2024 
  2025 lemma Bseq_monoseq_convergent: "Bseq X \<Longrightarrow> monoseq X \<Longrightarrow> convergent X"
  2026   for X :: "nat \<Rightarrow> real"
  2027   by (auto simp: monoseq_iff convergent_def intro: LIMSEQ_decseq_INF LIMSEQ_incseq_SUP
  2028       dest: Bseq_bdd_above Bseq_bdd_below)
  2029 
  2030 lemma Bseq_mono_convergent: "Bseq X \<Longrightarrow> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n) \<Longrightarrow> convergent X"
  2031   for X :: "nat \<Rightarrow> real"
  2032   by (auto intro!: Bseq_monoseq_convergent incseq_imp_monoseq simp: incseq_def)
  2033 
  2034 lemma monoseq_imp_convergent_iff_Bseq: "monoseq f \<Longrightarrow> convergent f \<longleftrightarrow> Bseq f"
  2035   for f :: "nat \<Rightarrow> real"
  2036   using Bseq_monoseq_convergent[of f] convergent_imp_Bseq[of f] by blast
  2037 
  2038 lemma Bseq_monoseq_convergent'_inc:
  2039   fixes f :: "nat \<Rightarrow> real"
  2040   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<le> f n) \<Longrightarrow> convergent f"
  2041   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  2042      (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  2043 
  2044 lemma Bseq_monoseq_convergent'_dec:
  2045   fixes f :: "nat \<Rightarrow> real"
  2046   shows "Bseq (\<lambda>n. f (n + M)) \<Longrightarrow> (\<And>m n. M \<le> m \<Longrightarrow> m \<le> n \<Longrightarrow> f m \<ge> f n) \<Longrightarrow> convergent f"
  2047   by (subst convergent_ignore_initial_segment [symmetric, of _ M])
  2048     (auto intro!: Bseq_monoseq_convergent simp: monoseq_def)
  2049 
  2050 lemma Cauchy_iff: "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  2051   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2052   unfolding Cauchy_def dist_norm ..
  2053 
  2054 lemma CauchyI: "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  2055   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2056   by (simp add: Cauchy_iff)
  2057 
  2058 lemma CauchyD: "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  2059   for X :: "nat \<Rightarrow> 'a::real_normed_vector"
  2060   by (simp add: Cauchy_iff)
  2061 
  2062 lemma incseq_convergent:
  2063   fixes X :: "nat \<Rightarrow> real"
  2064   assumes "incseq X"
  2065     and "\<forall>i. X i \<le> B"
  2066   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. X i \<le> L"
  2067 proof atomize_elim
  2068   from incseq_bounded[OF assms] \<open>incseq X\<close> Bseq_monoseq_convergent[of X]
  2069   obtain L where "X \<longlonglongrightarrow> L"
  2070     by (auto simp: convergent_def monoseq_def incseq_def)
  2071   with \<open>incseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. X i \<le> L)"
  2072     by (auto intro!: exI[of _ L] incseq_le)
  2073 qed
  2074 
  2075 lemma decseq_convergent:
  2076   fixes X :: "nat \<Rightarrow> real"
  2077   assumes "decseq X"
  2078     and "\<forall>i. B \<le> X i"
  2079   obtains L where "X \<longlonglongrightarrow> L" "\<forall>i. L \<le> X i"
  2080 proof atomize_elim
  2081   from decseq_bounded[OF assms] \<open>decseq X\<close> Bseq_monoseq_convergent[of X]
  2082   obtain L where "X \<longlonglongrightarrow> L"
  2083     by (auto simp: convergent_def monoseq_def decseq_def)
  2084   with \<open>decseq X\<close> show "\<exists>L. X \<longlonglongrightarrow> L \<and> (\<forall>i. L \<le> X i)"
  2085     by (auto intro!: exI[of _ L] decseq_le)
  2086 qed
  2087 
  2088 
  2089 subsection \<open>Power Sequences\<close>
  2090 
  2091 text \<open>
  2092   The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  2093   "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  2094   also fact that bounded and monotonic sequence converges.
  2095 \<close>
  2096 
  2097 lemma Bseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> Bseq (\<lambda>n. x ^ n)"
  2098   for x :: real
  2099   apply (simp add: Bseq_def)
  2100   apply (rule_tac x = 1 in exI)
  2101   apply (simp add: power_abs)
  2102   apply (auto dest: power_mono)
  2103   done
  2104 
  2105 lemma monoseq_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> monoseq (\<lambda>n. x ^ n)"
  2106   for x :: real
  2107   apply (clarify intro!: mono_SucI2)
  2108   apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing)
  2109      apply auto
  2110   done
  2111 
  2112 lemma convergent_realpow: "0 \<le> x \<Longrightarrow> x \<le> 1 \<Longrightarrow> convergent (\<lambda>n. x ^ n)"
  2113   for x :: real
  2114   by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  2115 
  2116 lemma LIMSEQ_inverse_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) \<longlonglongrightarrow> 0"
  2117   for x :: real
  2118   by (rule filterlim_compose[OF tendsto_inverse_0 filterlim_realpow_sequentially_gt1]) simp
  2119 
  2120 lemma LIMSEQ_realpow_zero:
  2121   fixes x :: real
  2122   assumes "0 \<le> x" "x < 1"
  2123   shows "(\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  2124 proof (cases "x = 0")
  2125   case False
  2126   with \<open>0 \<le> x\<close> have x0: "0 < x" by simp
  2127   then have "1 < inverse x"
  2128     using \<open>x < 1\<close> by (rule one_less_inverse)
  2129   then have "(\<lambda>n. inverse (inverse x ^ n)) \<longlonglongrightarrow> 0"
  2130     by (rule LIMSEQ_inverse_realpow_zero)
  2131   then show ?thesis by (simp add: power_inverse)
  2132 next
  2133   case True
  2134   show ?thesis
  2135     by (rule LIMSEQ_imp_Suc) (simp add: True)
  2136 qed
  2137 
  2138 lemma LIMSEQ_power_zero: "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) \<longlonglongrightarrow> 0"
  2139   for x :: "'a::real_normed_algebra_1"
  2140   apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  2141   apply (simp only: tendsto_Zfun_iff, erule Zfun_le)
  2142   apply (simp add: power_abs norm_power_ineq)
  2143   done
  2144 
  2145 lemma LIMSEQ_divide_realpow_zero: "1 < x \<Longrightarrow> (\<lambda>n. a / (x ^ n) :: real) \<longlonglongrightarrow> 0"
  2146   by (rule tendsto_divide_0 [OF tendsto_const filterlim_realpow_sequentially_gt1]) simp
  2147 
  2148 lemma
  2149   tendsto_power_zero:
  2150   fixes x::"'a::real_normed_algebra_1"
  2151   assumes "filterlim f at_top F"
  2152   assumes "norm x < 1"
  2153   shows "((\<lambda>y. x ^ (f y)) \<longlongrightarrow> 0) F"
  2154 proof (rule tendstoI)
  2155   fix e::real assume "0 < e"
  2156   from tendstoD[OF LIMSEQ_power_zero[OF \<open>norm x < 1\<close>] \<open>0 < e\<close>]
  2157   have "\<forall>\<^sub>F xa in sequentially. norm (x ^ xa) < e"
  2158     by simp
  2159   then obtain N where N: "norm (x ^ n) < e" if "n \<ge> N" for n
  2160     by (auto simp: eventually_sequentially)
  2161   have "\<forall>\<^sub>F i in F. f i \<ge> N"
  2162     using \<open>filterlim f sequentially F\<close>
  2163     by (simp add: filterlim_at_top)
  2164   then show "\<forall>\<^sub>F i in F. dist (x ^ f i) 0 < e"
  2165     by (eventually_elim) (auto simp: N)
  2166 qed
  2167 
  2168 text \<open>Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}.\<close>
  2169 
  2170 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. \<bar>c\<bar> ^ n :: real) \<longlonglongrightarrow> 0"
  2171   by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  2172 
  2173 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < 1 \<Longrightarrow> (\<lambda>n. c ^ n :: real) \<longlonglongrightarrow> 0"
  2174   by (rule LIMSEQ_power_zero) simp
  2175 
  2176 
  2177 subsection \<open>Limits of Functions\<close>
  2178 
  2179 lemma LIM_eq: "f \<midarrow>a\<rightarrow> L = (\<forall>r>0. \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r)"
  2180   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2181   by (simp add: LIM_def dist_norm)
  2182 
  2183 lemma LIM_I:
  2184   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r) \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  2185   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2186   by (simp add: LIM_eq)
  2187 
  2188 lemma LIM_D: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>s>0.\<forall>x. x \<noteq> a \<and> norm (x - a) < s \<longrightarrow> norm (f x - L) < r"
  2189   for a :: "'a::real_normed_vector" and L :: "'b::real_normed_vector"
  2190   by (simp add: LIM_eq)
  2191 
  2192 lemma LIM_offset: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>x. f (x + k)) \<midarrow>(a - k)\<rightarrow> L"
  2193   for a :: "'a::real_normed_vector"
  2194   by (simp add: filtermap_at_shift[symmetric, of a k] filterlim_def filtermap_filtermap)
  2195 
  2196 lemma LIM_offset_zero: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  2197   for a :: "'a::real_normed_vector"
  2198   by (drule LIM_offset [where k = a]) (simp add: add.commute)
  2199 
  2200 lemma LIM_offset_zero_cancel: "(\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  2201   for a :: "'a::real_normed_vector"
  2202   by (drule LIM_offset [where k = "- a"]) simp
  2203 
  2204 lemma LIM_offset_zero_iff: "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> L"
  2205   for f :: "'a :: real_normed_vector \<Rightarrow> _"
  2206   using LIM_offset_zero_cancel[of f a L] LIM_offset_zero[of f L a] by auto
  2207 
  2208 lemma LIM_zero: "(f \<longlongrightarrow> l) F \<Longrightarrow> ((\<lambda>x. f x - l) \<longlongrightarrow> 0) F"
  2209   for f :: "'a \<Rightarrow> 'b::real_normed_vector"
  2210   unfolding tendsto_iff dist_norm by simp
  2211 
  2212 lemma LIM_zero_cancel:
  2213   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
  2214   shows "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F \<Longrightarrow> (f \<longlongrightarrow> l) F"
  2215 unfolding tendsto_iff dist_norm by simp
  2216 
  2217 lemma LIM_zero_iff: "((\<lambda>x. f x - l) \<longlongrightarrow> 0) F = (f \<longlongrightarrow> l) F"
  2218   for f :: "'a \<Rightarrow> 'b::real_normed_vector"
  2219   unfolding tendsto_iff dist_norm by simp
  2220 
  2221 lemma LIM_imp_LIM:
  2222   fixes f :: "'a::topological_space \<Rightarrow> 'b::real_normed_vector"
  2223   fixes g :: "'a::topological_space \<Rightarrow> 'c::real_normed_vector"
  2224   assumes f: "f \<midarrow>a\<rightarrow> l"
  2225     and le: "\<And>x. x \<noteq> a \<Longrightarrow> norm (g x - m) \<le> norm (f x - l)"
  2226   shows "g \<midarrow>a\<rightarrow> m"
  2227   by (rule metric_LIM_imp_LIM [OF f]) (simp add: dist_norm le)
  2228 
  2229 lemma LIM_equal2:
  2230   fixes f g :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2231   assumes "0 < R"
  2232     and "\<And>x. x \<noteq> a \<Longrightarrow> norm (x - a) < R \<Longrightarrow> f x = g x"
  2233   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  2234   by (rule metric_LIM_equal2 [OF assms]) (simp_all add: dist_norm)
  2235 
  2236 lemma LIM_compose2:
  2237   fixes a :: "'a::real_normed_vector"
  2238   assumes f: "f \<midarrow>a\<rightarrow> b"
  2239     and g: "g \<midarrow>b\<rightarrow> c"
  2240     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> b"
  2241   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  2242   by (rule metric_LIM_compose2 [OF f g inj [folded dist_norm]])
  2243 
  2244 lemma real_LIM_sandwich_zero:
  2245   fixes f g :: "'a::topological_space \<Rightarrow> real"
  2246   assumes f: "f \<midarrow>a\<rightarrow> 0"
  2247     and 1: "\<And>x. x \<noteq> a \<Longrightarrow> 0 \<le> g x"
  2248     and 2: "\<And>x. x \<noteq> a \<Longrightarrow> g x \<le> f x"
  2249   shows "g \<midarrow>a\<rightarrow> 0"
  2250 proof (rule LIM_imp_LIM [OF f]) (* FIXME: use tendsto_sandwich *)
  2251   fix x
  2252   assume x: "x \<noteq> a"
  2253   with 1 have "norm (g x - 0) = g x" by simp
  2254   also have "g x \<le> f x" by (rule 2 [OF x])
  2255   also have "f x \<le> \<bar>f x\<bar>" by (rule abs_ge_self)
  2256   also have "\<bar>f x\<bar> = norm (f x - 0)" by simp
  2257   finally show "norm (g x - 0) \<le> norm (f x - 0)" .
  2258 qed
  2259 
  2260 
  2261 subsection \<open>Continuity\<close>
  2262 
  2263 lemma LIM_isCont_iff: "(f \<midarrow>a\<rightarrow> f a) = ((\<lambda>h. f (a + h)) \<midarrow>0\<rightarrow> f a)"
  2264   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2265   by (rule iffI [OF LIM_offset_zero LIM_offset_zero_cancel])
  2266 
  2267 lemma isCont_iff: "isCont f x = (\<lambda>h. f (x + h)) \<midarrow>0\<rightarrow> f x"
  2268   for f :: "'a::real_normed_vector \<Rightarrow> 'b::topological_space"
  2269   by (simp add: isCont_def LIM_isCont_iff)
  2270 
  2271 lemma isCont_LIM_compose2:
  2272   fixes a :: "'a::real_normed_vector"
  2273   assumes f [unfolded isCont_def]: "isCont f a"
  2274     and g: "g \<midarrow>f a\<rightarrow> l"
  2275     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> norm (x - a) < d \<longrightarrow> f x \<noteq> f a"
  2276   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  2277   by (rule LIM_compose2 [OF f g inj])
  2278 
  2279 lemma isCont_norm [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. norm (f x)) a"
  2280   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2281   by (fact continuous_norm)
  2282 
  2283 lemma isCont_rabs [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. \<bar>f x\<bar>) a"
  2284   for f :: "'a::t2_space \<Rightarrow> real"
  2285   by (fact continuous_rabs)
  2286 
  2287 lemma isCont_add [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x + g x) a"
  2288   for f :: "'a::t2_space \<Rightarrow> 'b::topological_monoid_add"
  2289   by (fact continuous_add)
  2290 
  2291 lemma isCont_minus [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. - f x) a"
  2292   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2293   by (fact continuous_minus)
  2294 
  2295 lemma isCont_diff [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x - g x) a"
  2296   for f :: "'a::t2_space \<Rightarrow> 'b::real_normed_vector"
  2297   by (fact continuous_diff)
  2298 
  2299 lemma isCont_mult [simp]: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x * g x) a"
  2300   for f g :: "'a::t2_space \<Rightarrow> 'b::real_normed_algebra"
  2301   by (fact continuous_mult)
  2302 
  2303 lemma (in bounded_linear) isCont: "isCont g a \<Longrightarrow> isCont (\<lambda>x. f (g x)) a"
  2304   by (fact continuous)
  2305 
  2306 lemma (in bounded_bilinear) isCont: "isCont f a \<Longrightarrow> isCont g a \<Longrightarrow> isCont (\<lambda>x. f x ** g x) a"
  2307   by (fact continuous)
  2308 
  2309 lemmas isCont_scaleR [simp] =
  2310   bounded_bilinear.isCont [OF bounded_bilinear_scaleR]
  2311 
  2312 lemmas isCont_of_real [simp] =
  2313   bounded_linear.isCont [OF bounded_linear_of_real]
  2314 
  2315 lemma isCont_power [simp]: "isCont f a \<Longrightarrow> isCont (\<lambda>x. f x ^ n) a"
  2316   for f :: "'a::t2_space \<Rightarrow> 'b::{power,real_normed_algebra}"
  2317   by (fact continuous_power)
  2318 
  2319 lemma isCont_sum [simp]: "\<forall>i\<in>A. isCont (f i) a \<Longrightarrow> isCont (\<lambda>x. \<Sum>i\<in>A. f i x) a"
  2320   for f :: "'a \<Rightarrow> 'b::t2_space \<Rightarrow> 'c::topological_comm_monoid_add"
  2321   by (auto intro: continuous_sum)
  2322 
  2323 
  2324 subsection \<open>Uniform Continuity\<close>
  2325 
  2326 lemma uniformly_continuous_on_def:
  2327   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2328   shows "uniformly_continuous_on s f \<longleftrightarrow>
  2329     (\<forall>e>0. \<exists>d>0. \<forall>x\<in>s. \<forall>x'\<in>s. dist x' x < d \<longrightarrow> dist (f x') (f x) < e)"
  2330   unfolding uniformly_continuous_on_uniformity
  2331     uniformity_dist filterlim_INF filterlim_principal eventually_inf_principal
  2332   by (force simp: Ball_def uniformity_dist[symmetric] eventually_uniformity_metric)
  2333 
  2334 abbreviation isUCont :: "['a::metric_space \<Rightarrow> 'b::metric_space] \<Rightarrow> bool"
  2335   where "isUCont f \<equiv> uniformly_continuous_on UNIV f"
  2336 
  2337 lemma isUCont_def: "isUCont f \<longleftrightarrow> (\<forall>r>0. \<exists>s>0. \<forall>x y. dist x y < s \<longrightarrow> dist (f x) (f y) < r)"
  2338   by (auto simp: uniformly_continuous_on_def dist_commute)
  2339 
  2340 lemma isUCont_isCont: "isUCont f \<Longrightarrow> isCont f x"
  2341   by (drule uniformly_continuous_imp_continuous) (simp add: continuous_on_eq_continuous_at)
  2342 
  2343 lemma uniformly_continuous_on_Cauchy:
  2344   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2345   assumes "uniformly_continuous_on S f" "Cauchy X" "\<And>n. X n \<in> S"
  2346   shows "Cauchy (\<lambda>n. f (X n))"
  2347   using assms
  2348   apply (simp only: uniformly_continuous_on_def)
  2349   apply (rule metric_CauchyI)
  2350   apply (drule_tac x=e in spec)
  2351   apply safe
  2352   apply (drule_tac e=d in metric_CauchyD)
  2353    apply safe
  2354   apply (rule_tac x=M in exI)
  2355   apply simp
  2356   done
  2357 
  2358 lemma isUCont_Cauchy: "isUCont f \<Longrightarrow> Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2359   by (rule uniformly_continuous_on_Cauchy[where S=UNIV and f=f]) simp_all
  2360   
  2361 lemma uniformly_continuous_imp_Cauchy_continuous:
  2362   fixes f :: "'a::metric_space \<Rightarrow> 'b::metric_space"
  2363   shows "\<lbrakk>uniformly_continuous_on S f; Cauchy \<sigma>; \<And>n. (\<sigma> n) \<in> S\<rbrakk> \<Longrightarrow> Cauchy(f o \<sigma>)"
  2364   by (simp add: uniformly_continuous_on_def Cauchy_def) meson
  2365 
  2366 lemma (in bounded_linear) isUCont: "isUCont f"
  2367   unfolding isUCont_def dist_norm
  2368 proof (intro allI impI)
  2369   fix r :: real
  2370   assume r: "0 < r"
  2371   obtain K where K: "0 < K" and norm_le: "norm (f x) \<le> norm x * K" for x
  2372     using pos_bounded by blast
  2373   show "\<exists>s>0. \<forall>x y. norm (x - y) < s \<longrightarrow> norm (f x - f y) < r"
  2374   proof (rule exI, safe)
  2375     from r K show "0 < r / K" by simp
  2376   next
  2377     fix x y :: 'a
  2378     assume xy: "norm (x - y) < r / K"
  2379     have "norm (f x - f y) = norm (f (x - y))" by (simp only: diff)
  2380     also have "\<dots> \<le> norm (x - y) * K" by (rule norm_le)
  2381     also from K xy have "\<dots> < r" by (simp only: pos_less_divide_eq)
  2382     finally show "norm (f x - f y) < r" .
  2383   qed
  2384 qed
  2385 
  2386 lemma (in bounded_linear) Cauchy: "Cauchy X \<Longrightarrow> Cauchy (\<lambda>n. f (X n))"
  2387   by (rule isUCont [THEN isUCont_Cauchy])
  2388 
  2389 lemma LIM_less_bound:
  2390   fixes f :: "real \<Rightarrow> real"
  2391   assumes ev: "b < x" "\<forall> x' \<in> { b <..< x}. 0 \<le> f x'" and "isCont f x"
  2392   shows "0 \<le> f x"
  2393 proof (rule tendsto_lowerbound)
  2394   show "(f \<longlongrightarrow> f x) (at_left x)"
  2395     using \<open>isCont f x\<close> by (simp add: filterlim_at_split isCont_def)
  2396   show "eventually (\<lambda>x. 0 \<le> f x) (at_left x)"
  2397     using ev by (auto simp: eventually_at dist_real_def intro!: exI[of _ "x - b"])
  2398 qed simp
  2399 
  2400 
  2401 subsection \<open>Nested Intervals and Bisection -- Needed for Compactness\<close>
  2402 
  2403 lemma nested_sequence_unique:
  2404   assumes "\<forall>n. f n \<le> f (Suc n)" "\<forall>n. g (Suc n) \<le> g n" "\<forall>n. f n \<le> g n" "(\<lambda>n. f n - g n) \<longlonglongrightarrow> 0"
  2405   shows "\<exists>l::real. ((\<forall>n. f n \<le> l) \<and> f \<longlonglongrightarrow> l) \<and> ((\<forall>n. l \<le> g n) \<and> g \<longlonglongrightarrow> l)"
  2406 proof -
  2407   have "incseq f" unfolding incseq_Suc_iff by fact
  2408   have "decseq g" unfolding decseq_Suc_iff by fact
  2409   have "f n \<le> g 0" for n
  2410   proof -
  2411     from \<open>decseq g\<close> have "g n \<le> g 0"
  2412       by (rule decseqD) simp
  2413     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
  2414       by auto
  2415   qed
  2416   then obtain u where "f \<longlonglongrightarrow> u" "\<forall>i. f i \<le> u"
  2417     using incseq_convergent[OF \<open>incseq f\<close>] by auto
  2418   moreover have "f 0 \<le> g n" for n
  2419   proof -
  2420     from \<open>incseq f\<close> have "f 0 \<le> f n" by (rule incseqD) simp
  2421     with \<open>\<forall>n. f n \<le> g n\<close>[THEN spec, of n] show ?thesis
  2422       by simp
  2423   qed
  2424   then obtain l where "g \<longlonglongrightarrow> l" "\<forall>i. l \<le> g i"
  2425     using decseq_convergent[OF \<open>decseq g\<close>] by auto
  2426   moreover note LIMSEQ_unique[OF assms(4) tendsto_diff[OF \<open>f \<longlonglongrightarrow> u\<close> \<open>g \<longlonglongrightarrow> l\<close>]]
  2427   ultimately show ?thesis by auto
  2428 qed
  2429 
  2430 lemma Bolzano[consumes 1, case_names trans local]:
  2431   fixes P :: "real \<Rightarrow> real \<Rightarrow> bool"
  2432   assumes [arith]: "a \<le> b"
  2433     and trans: "\<And>a b c. P a b \<Longrightarrow> P b c \<Longrightarrow> a \<le> b \<Longrightarrow> b \<le> c \<Longrightarrow> P a c"
  2434     and local: "\<And>x. a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> \<exists>d>0. \<forall>a b. a \<le> x \<and> x \<le> b \<and> b - a < d \<longrightarrow> P a b"
  2435   shows "P a b"
  2436 proof -
  2437   define bisect where "bisect =
  2438     rec_nat (a, b) (\<lambda>n (x, y). if P x ((x+y) / 2) then ((x+y)/2, y) else (x, (x+y)/2))"
  2439   define l u where "l n = fst (bisect n)" and "u n = snd (bisect n)" for n
  2440   have l[simp]: "l 0 = a" "\<And>n. l (Suc n) = (if P (l n) ((l n + u n) / 2) then (l n + u n) / 2 else l n)"
  2441     and u[simp]: "u 0 = b" "\<And>n. u (Suc n) = (if P (l n) ((l n + u n) / 2) then u n else (l n + u n) / 2)"
  2442     by (simp_all add: l_def u_def bisect_def split: prod.split)
  2443 
  2444   have [simp]: "l n \<le> u n" for n by (induct n) auto
  2445 
  2446   have "\<exists>x. ((\<forall>n. l n \<le> x) \<and> l \<longlonglongrightarrow> x) \<and> ((\<forall>n. x \<le> u n) \<and> u \<longlonglongrightarrow> x)"
  2447   proof (safe intro!: nested_sequence_unique)
  2448     show "l n \<le> l (Suc n)" "u (Suc n) \<le> u n" for n
  2449       by (induct n) auto
  2450   next
  2451     have "l n - u n = (a - b) / 2^n" for n
  2452       by (induct n) (auto simp: field_simps)
  2453     then show "(\<lambda>n. l n - u n) \<longlonglongrightarrow> 0"
  2454       by (simp add: LIMSEQ_divide_realpow_zero)
  2455   qed fact
  2456   then obtain x where x: "\<And>n. l n \<le> x" "\<And>n. x \<le> u n" and "l \<longlonglongrightarrow> x" "u \<longlonglongrightarrow> x"
  2457     by auto
  2458   obtain d where "0 < d" and d: "a \<le> x \<Longrightarrow> x \<le> b \<Longrightarrow> b - a < d \<Longrightarrow> P a b" for a b
  2459     using \<open>l 0 \<le> x\<close> \<open>x \<le> u 0\<close> local[of x] by auto
  2460 
  2461   show "P a b"
  2462   proof (rule ccontr)
  2463     assume "\<not> P a b"
  2464     have "\<not> P (l n) (u n)" for n
  2465     proof (induct n)
  2466       case 0
  2467       then show ?case
  2468         by (simp add: \<open>\<not> P a b\<close>)
  2469     next
  2470       case (Suc n)
  2471       with trans[of "l n" "(l n + u n) / 2" "u n"] show ?case
  2472         by auto
  2473     qed
  2474     moreover
  2475     {
  2476       have "eventually (\<lambda>n. x - d / 2 < l n) sequentially"
  2477         using \<open>0 < d\<close> \<open>l \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2478       moreover have "eventually (\<lambda>n. u n < x + d / 2) sequentially"
  2479         using \<open>0 < d\<close> \<open>u \<longlonglongrightarrow> x\<close> by (intro order_tendstoD[of _ x]) auto
  2480       ultimately have "eventually (\<lambda>n. P (l n) (u n)) sequentially"
  2481       proof eventually_elim
  2482         case (elim n)
  2483         from add_strict_mono[OF this] have "u n - l n < d" by simp
  2484         with x show "P (l n) (u n)" by (rule d)
  2485       qed
  2486     }
  2487     ultimately show False by simp
  2488   qed
  2489 qed
  2490 
  2491 lemma compact_Icc[simp, intro]: "compact {a .. b::real}"
  2492 proof (cases "a \<le> b", rule compactI)
  2493   fix C
  2494   assume C: "a \<le> b" "\<forall>t\<in>C. open t" "{a..b} \<subseteq> \<Union>C"
  2495   define T where "T = {a .. b}"
  2496   from C(1,3) show "\<exists>C'\<subseteq>C. finite C' \<and> {a..b} \<subseteq> \<Union>C'"
  2497   proof (induct rule: Bolzano)
  2498     case (trans a b c)
  2499     then have *: "{a..c} = {a..b} \<union> {b..c}"
  2500       by auto
  2501     with trans obtain C1 C2
  2502       where "C1\<subseteq>C" "finite C1" "{a..b} \<subseteq> \<Union>C1" "C2\<subseteq>C" "finite C2" "{b..c} \<subseteq> \<Union>C2"
  2503       by auto
  2504     with trans show ?case
  2505       unfolding * by (intro exI[of _ "C1 \<union> C2"]) auto
  2506   next
  2507     case (local x)
  2508     with C have "x \<in> \<Union>C" by auto
  2509     with C(2) obtain c where "x \<in> c" "open c" "c \<in> C"
  2510       by auto
  2511     then obtain e where "0 < e" "{x - e <..< x + e} \<subseteq> c"
  2512       by (auto simp: open_dist dist_real_def subset_eq Ball_def abs_less_iff)
  2513     with \<open>c \<in> C\<close> show ?case
  2514       by (safe intro!: exI[of _ "e/2"] exI[of _ "{c}"]) auto
  2515   qed
  2516 qed simp
  2517 
  2518 
  2519 lemma continuous_image_closed_interval:
  2520   fixes a b and f :: "real \<Rightarrow> real"
  2521   defines "S \<equiv> {a..b}"
  2522   assumes "a \<le> b" and f: "continuous_on S f"
  2523   shows "\<exists>c d. f`S = {c..d} \<and> c \<le> d"
  2524 proof -
  2525   have S: "compact S" "S \<noteq> {}"
  2526     using \<open>a \<le> b\<close> by (auto simp: S_def)
  2527   obtain c where "c \<in> S" "\<forall>d\<in>S. f d \<le> f c"
  2528     using continuous_attains_sup[OF S f] by auto
  2529   moreover obtain d where "d \<in> S" "\<forall>c\<in>S. f d \<le> f c"
  2530     using continuous_attains_inf[OF S f] by auto
  2531   moreover have "connected (f`S)"
  2532     using connected_continuous_image[OF f] connected_Icc by (auto simp: S_def)
  2533   ultimately have "f ` S = {f d .. f c} \<and> f d \<le> f c"
  2534     by (auto simp: connected_iff_interval)
  2535   then show ?thesis
  2536     by auto
  2537 qed
  2538 
  2539 lemma open_Collect_positive:
  2540   fixes f :: "'a::t2_space \<Rightarrow> real"
  2541   assumes f: "continuous_on s f"
  2542   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. 0 < f x}"
  2543   using continuous_on_open_invariant[THEN iffD1, OF f, rule_format, of "{0 <..}"]
  2544   by (auto simp: Int_def field_simps)
  2545 
  2546 lemma open_Collect_less_Int:
  2547   fixes f g :: "'a::t2_space \<Rightarrow> real"
  2548   assumes f: "continuous_on s f"
  2549     and g: "continuous_on s g"
  2550   shows "\<exists>A. open A \<and> A \<inter> s = {x\<in>s. f x < g x}"
  2551   using open_Collect_positive[OF continuous_on_diff[OF g f]] by (simp add: field_simps)
  2552 
  2553 
  2554 subsection \<open>Boundedness of continuous functions\<close>
  2555 
  2556 text\<open>By bisection, function continuous on closed interval is bounded above\<close>
  2557 
  2558 lemma isCont_eq_Ub:
  2559   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2560   shows "a \<le> b \<Longrightarrow> \<forall>x::real. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2561     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2562   using continuous_attains_sup[of "{a..b}" f]
  2563   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2564 
  2565 lemma isCont_eq_Lb:
  2566   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2567   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2568     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> M \<le> f x) \<and> (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = M)"
  2569   using continuous_attains_inf[of "{a..b}" f]
  2570   by (auto simp add: continuous_at_imp_continuous_on Ball_def Bex_def)
  2571 
  2572 lemma isCont_bounded:
  2573   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2574   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow> \<exists>M. \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M"
  2575   using isCont_eq_Ub[of a b f] by auto
  2576 
  2577 lemma isCont_has_Ub:
  2578   fixes f :: "real \<Rightarrow> 'a::linorder_topology"
  2579   shows "a \<le> b \<Longrightarrow> \<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x \<Longrightarrow>
  2580     \<exists>M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> M) \<and> (\<forall>N. N < M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> N < f x))"
  2581   using isCont_eq_Ub[of a b f] by auto
  2582 
  2583 (*HOL style here: object-level formulations*)
  2584 lemma IVT_objl:
  2585   "(f a \<le> y \<and> y \<le> f b \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
  2586     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
  2587   for a y :: real
  2588   by (blast intro: IVT)
  2589 
  2590 lemma IVT2_objl:
  2591   "(f b \<le> y \<and> y \<le> f a \<and> a \<le> b \<and> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x)) \<longrightarrow>
  2592     (\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y)"
  2593   for b y :: real
  2594   by (blast intro: IVT2)
  2595 
  2596 lemma isCont_Lb_Ub:
  2597   fixes f :: "real \<Rightarrow> real"
  2598   assumes "a \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x"
  2599   shows "\<exists>L M. (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> L \<le> f x \<and> f x \<le> M) \<and>
  2600     (\<forall>y. L \<le> y \<and> y \<le> M \<longrightarrow> (\<exists>x. a \<le> x \<and> x \<le> b \<and> (f x = y)))"
  2601 proof -
  2602   obtain M where M: "a \<le> M" "M \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f x \<le> f M"
  2603     using isCont_eq_Ub[OF assms] by auto
  2604   obtain L where L: "a \<le> L" "L \<le> b" "\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> f L \<le> f x"
  2605     using isCont_eq_Lb[OF assms] by auto
  2606   show ?thesis
  2607     using IVT[of f L _ M] IVT2[of f L _ M] M L assms
  2608     apply (rule_tac x="f L" in exI)
  2609     apply (rule_tac x="f M" in exI)
  2610     apply (cases "L \<le> M")
  2611      apply simp
  2612      apply (metis order_trans)
  2613     apply simp
  2614     apply (metis order_trans)
  2615     done
  2616 qed
  2617 
  2618 
  2619 text \<open>Continuity of inverse function.\<close>
  2620 
  2621 lemma isCont_inverse_function:
  2622   fixes f g :: "real \<Rightarrow> real"
  2623   assumes d: "0 < d"
  2624     and inj: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> g (f z) = z"
  2625     and cont: "\<forall>z. \<bar>z-x\<bar> \<le> d \<longrightarrow> isCont f z"
  2626   shows "isCont g (f x)"
  2627 proof -
  2628   let ?A = "f (x - d)"
  2629   let ?B = "f (x + d)"
  2630   let ?D = "{x - d..x + d}"
  2631 
  2632   have f: "continuous_on ?D f"
  2633     using cont by (intro continuous_at_imp_continuous_on ballI) auto
  2634   then have g: "continuous_on (f`?D) g"
  2635     using inj by (intro continuous_on_inv) auto
  2636 
  2637   from d f have "{min ?A ?B <..< max ?A ?B} \<subseteq> f ` ?D"
  2638     by (intro connected_contains_Ioo connected_continuous_image) (auto split: split_min split_max)
  2639   with g have "continuous_on {min ?A ?B <..< max ?A ?B} g"
  2640     by (rule continuous_on_subset)
  2641   moreover
  2642   have "(?A < f x \<and> f x < ?B) \<or> (?B < f x \<and> f x < ?A)"
  2643     using d inj by (intro continuous_inj_imp_mono[OF _ _ f] inj_on_imageI2[of g, OF inj_onI]) auto
  2644   then have "f x \<in> {min ?A ?B <..< max ?A ?B}"
  2645     by auto
  2646   ultimately
  2647   show ?thesis
  2648     by (simp add: continuous_on_eq_continuous_at)
  2649 qed
  2650 
  2651 lemma isCont_inverse_function2:
  2652   fixes f g :: "real \<Rightarrow> real"
  2653   shows
  2654     "a < x \<Longrightarrow> x < b \<Longrightarrow>
  2655       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> g (f z) = z \<Longrightarrow>
  2656       \<forall>z. a \<le> z \<and> z \<le> b \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
  2657   apply (rule isCont_inverse_function [where f=f and d="min (x - a) (b - x)"])
  2658   apply (simp_all add: abs_le_iff)
  2659   done
  2660 
  2661 (* need to rename second isCont_inverse *)
  2662 lemma isCont_inv_fun:
  2663   fixes f g :: "real \<Rightarrow> real"
  2664   shows "0 < d \<Longrightarrow> (\<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> g (f z) = z) \<Longrightarrow>
  2665     \<forall>z. \<bar>z - x\<bar> \<le> d \<longrightarrow> isCont f z \<Longrightarrow> isCont g (f x)"
  2666   by (rule isCont_inverse_function)
  2667 
  2668 text \<open>Bartle/Sherbert: Introduction to Real Analysis, Theorem 4.2.9, p. 110.\<close>
  2669 lemma LIM_fun_gt_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> 0 < l \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> 0 < f x)"
  2670   for f :: "real \<Rightarrow> real"
  2671   apply (drule (1) LIM_D)
  2672   apply clarify
  2673   apply (rule_tac x = s in exI)
  2674   apply (simp add: abs_less_iff)
  2675   done
  2676 
  2677 lemma LIM_fun_less_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l < 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x < 0)"
  2678   for f :: "real \<Rightarrow> real"
  2679   apply (drule LIM_D [where r="-l"])
  2680    apply simp
  2681   apply clarify
  2682   apply (rule_tac x = s in exI)
  2683   apply (simp add: abs_less_iff)
  2684   done
  2685 
  2686 lemma LIM_fun_not_zero: "f \<midarrow>c\<rightarrow> l \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> \<exists>r. 0 < r \<and> (\<forall>x. x \<noteq> c \<and> \<bar>c - x\<bar> < r \<longrightarrow> f x \<noteq> 0)"
  2687   for f :: "real \<Rightarrow> real"
  2688   using LIM_fun_gt_zero[of f l c] LIM_fun_less_zero[of f l c] by (auto simp add: neq_iff)
  2689 
  2690 end