src/HOL/Presburger.thy
author wenzelm
Tue Sep 26 20:54:40 2017 +0200 (21 months ago)
changeset 66695 91500c024c7f
parent 66630 034cabc4fda5
child 67091 1393c2340eec
permissions -rw-r--r--
tuned;
     1 (* Title:      HOL/Presburger.thy
     2    Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 section \<open>Decision Procedure for Presburger Arithmetic\<close>
     6 
     7 theory Presburger
     8 imports Groebner_Basis Set_Interval
     9 keywords "try0" :: diag
    10 begin
    11 
    12 ML_file "Tools/Qelim/qelim.ML"
    13 ML_file "Tools/Qelim/cooper_procedure.ML"
    14 
    15 subsection\<open>The \<open>-\<infinity>\<close> and \<open>+\<infinity>\<close> Properties\<close>
    16 
    17 lemma minf:
    18   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x<z. P x = P' x; \<exists>z.\<forall>x<z. Q x = Q' x\<rbrakk> 
    19      \<Longrightarrow> \<exists>z.\<forall>x<z. (P x \<and> Q x) = (P' x \<and> Q' x)"
    20   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x<z. P x = P' x; \<exists>z.\<forall>x<z. Q x = Q' x\<rbrakk> 
    21      \<Longrightarrow> \<exists>z.\<forall>x<z. (P x \<or> Q x) = (P' x \<or> Q' x)"
    22   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x = t) = False"
    23   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<noteq> t) = True"
    24   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x < t) = True"
    25   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<le> t) = True"
    26   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x > t) = False"
    27   "\<exists>(z ::'a::{linorder}).\<forall>x<z.(x \<ge> t) = False"
    28   "\<exists>z.\<forall>(x::'b::{linorder,plus,Rings.dvd})<z. (d dvd x + s) = (d dvd x + s)"
    29   "\<exists>z.\<forall>(x::'b::{linorder,plus,Rings.dvd})<z. (\<not> d dvd x + s) = (\<not> d dvd x + s)"
    30   "\<exists>z.\<forall>x<z. F = F"
    31   by ((erule exE, erule exE,rule_tac x="min z za" in exI,simp)+, (rule_tac x="t" in exI,fastforce)+) simp_all
    32 
    33 lemma pinf:
    34   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x>z. P x = P' x; \<exists>z.\<forall>x>z. Q x = Q' x\<rbrakk> 
    35      \<Longrightarrow> \<exists>z.\<forall>x>z. (P x \<and> Q x) = (P' x \<and> Q' x)"
    36   "\<lbrakk>\<exists>(z ::'a::linorder).\<forall>x>z. P x = P' x; \<exists>z.\<forall>x>z. Q x = Q' x\<rbrakk> 
    37      \<Longrightarrow> \<exists>z.\<forall>x>z. (P x \<or> Q x) = (P' x \<or> Q' x)"
    38   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x = t) = False"
    39   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<noteq> t) = True"
    40   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x < t) = False"
    41   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<le> t) = False"
    42   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x > t) = True"
    43   "\<exists>(z ::'a::{linorder}).\<forall>x>z.(x \<ge> t) = True"
    44   "\<exists>z.\<forall>(x::'b::{linorder,plus,Rings.dvd})>z. (d dvd x + s) = (d dvd x + s)"
    45   "\<exists>z.\<forall>(x::'b::{linorder,plus,Rings.dvd})>z. (\<not> d dvd x + s) = (\<not> d dvd x + s)"
    46   "\<exists>z.\<forall>x>z. F = F"
    47   by ((erule exE, erule exE,rule_tac x="max z za" in exI,simp)+,(rule_tac x="t" in exI,fastforce)+) simp_all
    48 
    49 lemma inf_period:
    50   "\<lbrakk>\<forall>x k. P x = P (x - k*D); \<forall>x k. Q x = Q (x - k*D)\<rbrakk> 
    51     \<Longrightarrow> \<forall>x k. (P x \<and> Q x) = (P (x - k*D) \<and> Q (x - k*D))"
    52   "\<lbrakk>\<forall>x k. P x = P (x - k*D); \<forall>x k. Q x = Q (x - k*D)\<rbrakk> 
    53     \<Longrightarrow> \<forall>x k. (P x \<or> Q x) = (P (x - k*D) \<or> Q (x - k*D))"
    54   "(d::'a::{comm_ring,Rings.dvd}) dvd D \<Longrightarrow> \<forall>x k. (d dvd x + t) = (d dvd (x - k*D) + t)"
    55   "(d::'a::{comm_ring,Rings.dvd}) dvd D \<Longrightarrow> \<forall>x k. (\<not>d dvd x + t) = (\<not>d dvd (x - k*D) + t)"
    56   "\<forall>x k. F = F"
    57 apply (auto elim!: dvdE simp add: algebra_simps)
    58 unfolding mult.assoc [symmetric] distrib_right [symmetric] left_diff_distrib [symmetric]
    59 unfolding dvd_def mult.commute [of d] 
    60 by auto
    61 
    62 subsection\<open>The A and B sets\<close>
    63 lemma bset:
    64   "\<lbrakk>\<forall>x.(\<forall>j \<in> {1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> P x \<longrightarrow> P(x - D) ;
    65      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> Q x \<longrightarrow> Q(x - D)\<rbrakk> \<Longrightarrow> 
    66   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j) \<longrightarrow> (P x \<and> Q x) \<longrightarrow> (P(x - D) \<and> Q (x - D))"
    67   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> P x \<longrightarrow> P(x - D) ;
    68      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> Q x \<longrightarrow> Q(x - D)\<rbrakk> \<Longrightarrow> 
    69   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (P x \<or> Q x) \<longrightarrow> (P(x - D) \<or> Q (x - D))"
    70   "\<lbrakk>D>0; t - 1\<in> B\<rbrakk> \<Longrightarrow> (\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x = t) \<longrightarrow> (x - D = t))"
    71   "\<lbrakk>D>0 ; t \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x - D \<noteq> t))"
    72   "D>0 \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x < t) \<longrightarrow> (x - D < t))"
    73   "D>0 \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x - D \<le> t))"
    74   "\<lbrakk>D>0 ; t \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x > t) \<longrightarrow> (x - D > t))"
    75   "\<lbrakk>D>0 ; t - 1 \<in> B\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x - D \<ge> t))"
    76   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x - D) + t))"
    77   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not> d dvd (x - D) + t))"
    78   "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j) \<longrightarrow> F \<longrightarrow> F"
    79 proof (blast, blast)
    80   assume dp: "D > 0" and tB: "t - 1\<in> B"
    81   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x = t) \<longrightarrow> (x - D = t))" 
    82     apply (rule allI, rule impI,erule ballE[where x="1"],erule ballE[where x="t - 1"]) 
    83     apply algebra using dp tB by simp_all
    84 next
    85   assume dp: "D > 0" and tB: "t \<in> B"
    86   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x - D \<noteq> t))" 
    87     apply (rule allI, rule impI,erule ballE[where x="D"],erule ballE[where x="t"])
    88     apply algebra
    89     using dp tB by simp_all
    90 next
    91   assume dp: "D > 0" thus "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x < t) \<longrightarrow> (x - D < t))" by arith
    92 next
    93   assume dp: "D > 0" thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x - D \<le> t)" by arith
    94 next
    95   assume dp: "D > 0" and tB:"t \<in> B"
    96   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j" and g: "x > t" and ng: "\<not> (x - D) > t"
    97     hence "x -t \<le> D" and "1 \<le> x - t" by simp+
    98       hence "\<exists>j \<in> {1 .. D}. x - t = j" by auto
    99       hence "\<exists>j \<in> {1 .. D}. x = t + j" by (simp add: algebra_simps)
   100       with nob tB have "False" by simp}
   101   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x > t) \<longrightarrow> (x - D > t)" by blast
   102 next
   103   assume dp: "D > 0" and tB:"t - 1\<in> B"
   104   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j" and g: "x \<ge> t" and ng: "\<not> (x - D) \<ge> t"
   105     hence "x - (t - 1) \<le> D" and "1 \<le> x - (t - 1)" by simp+
   106       hence "\<exists>j \<in> {1 .. D}. x - (t - 1) = j" by auto
   107       hence "\<exists>j \<in> {1 .. D}. x = (t - 1) + j" by (simp add: algebra_simps)
   108       with nob tB have "False" by simp}
   109   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x - D \<ge> t)" by blast
   110 next
   111   assume d: "d dvd D"
   112   {fix x assume H: "d dvd x + t" with d have "d dvd (x - D) + t" by algebra}
   113   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x - D) + t)" by simp
   114 next
   115   assume d: "d dvd D"
   116   {fix x assume H: "\<not>(d dvd x + t)" with d have "\<not> d dvd (x - D) + t"
   117       by (clarsimp simp add: dvd_def,erule_tac x= "ka + k" in allE,simp add: algebra_simps)}
   118   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>B. x \<noteq> b + j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not>d dvd (x - D) + t)" by auto
   119 qed blast
   120 
   121 lemma aset:
   122   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> P x \<longrightarrow> P(x + D) ;
   123      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> Q x \<longrightarrow> Q(x + D)\<rbrakk> \<Longrightarrow> 
   124   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j) \<longrightarrow> (P x \<and> Q x) \<longrightarrow> (P(x + D) \<and> Q (x + D))"
   125   "\<lbrakk>\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> P x \<longrightarrow> P(x + D) ;
   126      \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> Q x \<longrightarrow> Q(x + D)\<rbrakk> \<Longrightarrow> 
   127   \<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (P x \<or> Q x) \<longrightarrow> (P(x + D) \<or> Q (x + D))"
   128   "\<lbrakk>D>0; t + 1\<in> A\<rbrakk> \<Longrightarrow> (\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x = t) \<longrightarrow> (x + D = t))"
   129   "\<lbrakk>D>0 ; t \<in> A\<rbrakk> \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x + D \<noteq> t))"
   130   "\<lbrakk>D>0; t\<in> A\<rbrakk> \<Longrightarrow>(\<forall>(x::int). (\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x < t) \<longrightarrow> (x + D < t))"
   131   "\<lbrakk>D>0; t + 1 \<in> A\<rbrakk> \<Longrightarrow> (\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x + D \<le> t))"
   132   "D>0 \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x > t) \<longrightarrow> (x + D > t))"
   133   "D>0 \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x + D \<ge> t))"
   134   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x + D) + t))"
   135   "d dvd D \<Longrightarrow>(\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not> d dvd (x + D) + t))"
   136   "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j) \<longrightarrow> F \<longrightarrow> F"
   137 proof (blast, blast)
   138   assume dp: "D > 0" and tA: "t + 1 \<in> A"
   139   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x = t) \<longrightarrow> (x + D = t))" 
   140     apply (rule allI, rule impI,erule ballE[where x="1"],erule ballE[where x="t + 1"])
   141     using dp tA by simp_all
   142 next
   143   assume dp: "D > 0" and tA: "t \<in> A"
   144   show "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<noteq> t) \<longrightarrow> (x + D \<noteq> t))" 
   145     apply (rule allI, rule impI,erule ballE[where x="D"],erule ballE[where x="t"])
   146     using dp tA by simp_all
   147 next
   148   assume dp: "D > 0" thus "(\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x > t) \<longrightarrow> (x + D > t))" by arith
   149 next
   150   assume dp: "D > 0" thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<ge> t) \<longrightarrow> (x + D \<ge> t)" by arith
   151 next
   152   assume dp: "D > 0" and tA:"t \<in> A"
   153   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j" and g: "x < t" and ng: "\<not> (x + D) < t"
   154     hence "t - x \<le> D" and "1 \<le> t - x" by simp+
   155       hence "\<exists>j \<in> {1 .. D}. t - x = j" by auto
   156       hence "\<exists>j \<in> {1 .. D}. x = t - j" by (auto simp add: algebra_simps) 
   157       with nob tA have "False" by simp}
   158   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x < t) \<longrightarrow> (x + D < t)" by blast
   159 next
   160   assume dp: "D > 0" and tA:"t + 1\<in> A"
   161   {fix x assume nob: "\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j" and g: "x \<le> t" and ng: "\<not> (x + D) \<le> t"
   162     hence "(t + 1) - x \<le> D" and "1 \<le> (t + 1) - x" by (simp_all add: algebra_simps)
   163       hence "\<exists>j \<in> {1 .. D}. (t + 1) - x = j" by auto
   164       hence "\<exists>j \<in> {1 .. D}. x = (t + 1) - j" by (auto simp add: algebra_simps)
   165       with nob tA have "False" by simp}
   166   thus "\<forall>x.(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (x \<le> t) \<longrightarrow> (x + D \<le> t)" by blast
   167 next
   168   assume d: "d dvd D"
   169   {fix x assume H: "d dvd x + t" with d have "d dvd (x + D) + t"
   170       by (clarsimp simp add: dvd_def,rule_tac x= "ka + k" in exI,simp add: algebra_simps)}
   171   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (d dvd x+t) \<longrightarrow> (d dvd (x + D) + t)" by simp
   172 next
   173   assume d: "d dvd D"
   174   {fix x assume H: "\<not>(d dvd x + t)" with d have "\<not>d dvd (x + D) + t"
   175       by (clarsimp simp add: dvd_def,erule_tac x= "ka - k" in allE,simp add: algebra_simps)}
   176   thus "\<forall>(x::int).(\<forall>j\<in>{1 .. D}. \<forall>b\<in>A. x \<noteq> b - j)\<longrightarrow> (\<not>d dvd x+t) \<longrightarrow> (\<not>d dvd (x + D) + t)" by auto
   177 qed blast
   178 
   179 subsection\<open>Cooper's Theorem \<open>-\<infinity>\<close> and \<open>+\<infinity>\<close> Version\<close>
   180 
   181 subsubsection\<open>First some trivial facts about periodic sets or predicates\<close>
   182 lemma periodic_finite_ex:
   183   assumes dpos: "(0::int) < d" and modd: "ALL x k. P x = P(x - k*d)"
   184   shows "(EX x. P x) = (EX j : {1..d}. P j)"
   185   (is "?LHS = ?RHS")
   186 proof
   187   assume ?LHS
   188   then obtain x where P: "P x" ..
   189   have "x mod d = x - (x div d)*d" by(simp add:mult_div_mod_eq [symmetric] ac_simps eq_diff_eq)
   190   hence Pmod: "P x = P(x mod d)" using modd by simp
   191   show ?RHS
   192   proof (cases)
   193     assume "x mod d = 0"
   194     hence "P 0" using P Pmod by simp
   195     moreover have "P 0 = P(0 - (-1)*d)" using modd by blast
   196     ultimately have "P d" by simp
   197     moreover have "d : {1..d}" using dpos by simp
   198     ultimately show ?RHS ..
   199   next
   200     assume not0: "x mod d \<noteq> 0"
   201     have "P(x mod d)" using dpos P Pmod by simp
   202     moreover have "x mod d : {1..d}"
   203     proof -
   204       from dpos have "0 \<le> x mod d" by(rule pos_mod_sign)
   205       moreover from dpos have "x mod d < d" by(rule pos_mod_bound)
   206       ultimately show ?thesis using not0 by simp
   207     qed
   208     ultimately show ?RHS ..
   209   qed
   210 qed auto
   211 
   212 subsubsection\<open>The \<open>-\<infinity>\<close> Version\<close>
   213 
   214 lemma decr_lemma: "0 < (d::int) \<Longrightarrow> x - (\<bar>x - z\<bar> + 1) * d < z"
   215   by (induct rule: int_gr_induct) (simp_all add: int_distrib)
   216 
   217 lemma incr_lemma: "0 < (d::int) \<Longrightarrow> z < x + (\<bar>x - z\<bar> + 1) * d"
   218   by (induct rule: int_gr_induct) (simp_all add: int_distrib)
   219 
   220 lemma decr_mult_lemma:
   221   assumes dpos: "(0::int) < d" and minus: "\<forall>x. P x \<longrightarrow> P(x - d)" and knneg: "0 <= k"
   222   shows "ALL x. P x \<longrightarrow> P(x - k*d)"
   223 using knneg
   224 proof (induct rule:int_ge_induct)
   225   case base thus ?case by simp
   226 next
   227   case (step i)
   228   {fix x
   229     have "P x \<longrightarrow> P (x - i * d)" using step.hyps by blast
   230     also have "\<dots> \<longrightarrow> P(x - (i + 1) * d)" using minus[THEN spec, of "x - i * d"]
   231       by (simp add: algebra_simps)
   232     ultimately have "P x \<longrightarrow> P(x - (i + 1) * d)" by blast}
   233   thus ?case ..
   234 qed
   235 
   236 lemma  minusinfinity:
   237   assumes dpos: "0 < d" and
   238     P1eqP1: "ALL x k. P1 x = P1(x - k*d)" and ePeqP1: "EX z::int. ALL x. x < z \<longrightarrow> (P x = P1 x)"
   239   shows "(EX x. P1 x) \<longrightarrow> (EX x. P x)"
   240 proof
   241   assume eP1: "EX x. P1 x"
   242   then obtain x where P1: "P1 x" ..
   243   from ePeqP1 obtain z where P1eqP: "ALL x. x < z \<longrightarrow> (P x = P1 x)" ..
   244   let ?w = "x - (\<bar>x - z\<bar> + 1) * d"
   245   from dpos have w: "?w < z" by(rule decr_lemma)
   246   have "P1 x = P1 ?w" using P1eqP1 by blast
   247   also have "\<dots> = P(?w)" using w P1eqP by blast
   248   finally have "P ?w" using P1 by blast
   249   thus "EX x. P x" ..
   250 qed
   251 
   252 lemma cpmi: 
   253   assumes dp: "0 < D" and p1:"\<exists>z. \<forall> x< z. P x = P' x"
   254   and nb:"\<forall>x.(\<forall> j\<in> {1..D}. \<forall>(b::int) \<in> B. x \<noteq> b+j) --> P (x) --> P (x - D)"
   255   and pd: "\<forall> x k. P' x = P' (x-k*D)"
   256   shows "(\<exists>x. P x) = ((\<exists> j\<in> {1..D} . P' j) | (\<exists> j \<in> {1..D}.\<exists> b\<in> B. P (b+j)))" 
   257          (is "?L = (?R1 \<or> ?R2)")
   258 proof-
   259  {assume "?R2" hence "?L"  by blast}
   260  moreover
   261  {assume H:"?R1" hence "?L" using minusinfinity[OF dp pd p1] periodic_finite_ex[OF dp pd] by simp}
   262  moreover 
   263  { fix x
   264    assume P: "P x" and H: "\<not> ?R2"
   265    {fix y assume "\<not> (\<exists>j\<in>{1..D}. \<exists>b\<in>B. P (b + j))" and P: "P y"
   266      hence "~(EX (j::int) : {1..D}. EX (b::int) : B. y = b+j)" by auto
   267      with nb P  have "P (y - D)" by auto }
   268    hence "ALL x.~(EX (j::int) : {1..D}. EX (b::int) : B. P(b+j)) --> P (x) --> P (x - D)" by blast
   269    with H P have th: " \<forall>x. P x \<longrightarrow> P (x - D)" by auto
   270    from p1 obtain z where z: "ALL x. x < z --> (P x = P' x)" by blast
   271    let ?y = "x - (\<bar>x - z\<bar> + 1)*D"
   272    have zp: "0 <= (\<bar>x - z\<bar> + 1)" by arith
   273    from dp have yz: "?y < z" using decr_lemma[OF dp] by simp   
   274    from z[rule_format, OF yz] decr_mult_lemma[OF dp th zp, rule_format, OF P] have th2: " P' ?y" by auto
   275    with periodic_finite_ex[OF dp pd]
   276    have "?R1" by blast}
   277  ultimately show ?thesis by blast
   278 qed
   279 
   280 subsubsection \<open>The \<open>+\<infinity>\<close> Version\<close>
   281 
   282 lemma  plusinfinity:
   283   assumes dpos: "(0::int) < d" and
   284     P1eqP1: "\<forall>x k. P' x = P'(x - k*d)" and ePeqP1: "\<exists> z. \<forall> x>z. P x = P' x"
   285   shows "(\<exists> x. P' x) \<longrightarrow> (\<exists> x. P x)"
   286 proof
   287   assume eP1: "EX x. P' x"
   288   then obtain x where P1: "P' x" ..
   289   from ePeqP1 obtain z where P1eqP: "\<forall>x>z. P x = P' x" ..
   290   let ?w' = "x + (\<bar>x - z\<bar> + 1) * d"
   291   let ?w = "x - (- (\<bar>x - z\<bar> + 1)) * d"
   292   have ww'[simp]: "?w = ?w'" by (simp add: algebra_simps)
   293   from dpos have w: "?w > z" by(simp only: ww' incr_lemma)
   294   hence "P' x = P' ?w" using P1eqP1 by blast
   295   also have "\<dots> = P(?w)" using w P1eqP by blast
   296   finally have "P ?w" using P1 by blast
   297   thus "EX x. P x" ..
   298 qed
   299 
   300 lemma incr_mult_lemma:
   301   assumes dpos: "(0::int) < d" and plus: "ALL x::int. P x \<longrightarrow> P(x + d)" and knneg: "0 <= k"
   302   shows "ALL x. P x \<longrightarrow> P(x + k*d)"
   303 using knneg
   304 proof (induct rule:int_ge_induct)
   305   case base thus ?case by simp
   306 next
   307   case (step i)
   308   {fix x
   309     have "P x \<longrightarrow> P (x + i * d)" using step.hyps by blast
   310     also have "\<dots> \<longrightarrow> P(x + (i + 1) * d)" using plus[THEN spec, of "x + i * d"]
   311       by (simp add:int_distrib ac_simps)
   312     ultimately have "P x \<longrightarrow> P(x + (i + 1) * d)" by blast}
   313   thus ?case ..
   314 qed
   315 
   316 lemma cppi: 
   317   assumes dp: "0 < D" and p1:"\<exists>z. \<forall> x> z. P x = P' x"
   318   and nb:"\<forall>x.(\<forall> j\<in> {1..D}. \<forall>(b::int) \<in> A. x \<noteq> b - j) --> P (x) --> P (x + D)"
   319   and pd: "\<forall> x k. P' x= P' (x-k*D)"
   320   shows "(\<exists>x. P x) = ((\<exists> j\<in> {1..D} . P' j) | (\<exists> j \<in> {1..D}.\<exists> b\<in> A. P (b - j)))" (is "?L = (?R1 \<or> ?R2)")
   321 proof-
   322  {assume "?R2" hence "?L"  by blast}
   323  moreover
   324  {assume H:"?R1" hence "?L" using plusinfinity[OF dp pd p1] periodic_finite_ex[OF dp pd] by simp}
   325  moreover 
   326  { fix x
   327    assume P: "P x" and H: "\<not> ?R2"
   328    {fix y assume "\<not> (\<exists>j\<in>{1..D}. \<exists>b\<in>A. P (b - j))" and P: "P y"
   329      hence "~(EX (j::int) : {1..D}. EX (b::int) : A. y = b - j)" by auto
   330      with nb P  have "P (y + D)" by auto }
   331    hence "ALL x.~(EX (j::int) : {1..D}. EX (b::int) : A. P(b-j)) --> P (x) --> P (x + D)" by blast
   332    with H P have th: " \<forall>x. P x \<longrightarrow> P (x + D)" by auto
   333    from p1 obtain z where z: "ALL x. x > z --> (P x = P' x)" by blast
   334    let ?y = "x + (\<bar>x - z\<bar> + 1)*D"
   335    have zp: "0 <= (\<bar>x - z\<bar> + 1)" by arith
   336    from dp have yz: "?y > z" using incr_lemma[OF dp] by simp
   337    from z[rule_format, OF yz] incr_mult_lemma[OF dp th zp, rule_format, OF P] have th2: " P' ?y" by auto
   338    with periodic_finite_ex[OF dp pd]
   339    have "?R1" by blast}
   340  ultimately show ?thesis by blast
   341 qed
   342 
   343 lemma simp_from_to: "{i..j::int} = (if j < i then {} else insert i {i+1..j})"
   344 apply(simp add:atLeastAtMost_def atLeast_def atMost_def)
   345 apply(fastforce)
   346 done
   347 
   348 theorem unity_coeff_ex: "(\<exists>(x::'a::{semiring_0,Rings.dvd}). P (l * x)) \<equiv> (\<exists>x. l dvd (x + 0) \<and> P x)"
   349   apply (rule eq_reflection [symmetric])
   350   apply (rule iffI)
   351   defer
   352   apply (erule exE)
   353   apply (rule_tac x = "l * x" in exI)
   354   apply (simp add: dvd_def)
   355   apply (rule_tac x = x in exI, simp)
   356   apply (erule exE)
   357   apply (erule conjE)
   358   apply simp
   359   apply (erule dvdE)
   360   apply (rule_tac x = k in exI)
   361   apply simp
   362   done
   363 
   364 lemma zdvd_mono:
   365   fixes k m t :: int
   366   assumes "k \<noteq> 0"
   367   shows "m dvd t \<equiv> k * m dvd k * t" 
   368   using assms by simp
   369 
   370 lemma uminus_dvd_conv:
   371   fixes d t :: int
   372   shows "d dvd t \<equiv> - d dvd t" and "d dvd t \<equiv> d dvd - t"
   373   by simp_all
   374 
   375 text \<open>\bigskip Theorems for transforming predicates on nat to predicates on \<open>int\<close>\<close>
   376 
   377 lemma zdiff_int_split: "P (int (x - y)) =
   378   ((y \<le> x \<longrightarrow> P (int x - int y)) \<and> (x < y \<longrightarrow> P 0))"
   379   by (cases "y \<le> x") (simp_all add: of_nat_diff)
   380 
   381 text \<open>
   382   \medskip Specific instances of congruence rules, to prevent
   383   simplifier from looping.\<close>
   384 
   385 theorem imp_le_cong:
   386   "\<lbrakk>x = x'; 0 \<le> x' \<Longrightarrow> P = P'\<rbrakk> \<Longrightarrow> (0 \<le> (x::int) \<longrightarrow> P) = (0 \<le> x' \<longrightarrow> P')"
   387   by simp
   388 
   389 theorem conj_le_cong:
   390   "\<lbrakk>x = x'; 0 \<le> x' \<Longrightarrow> P = P'\<rbrakk> \<Longrightarrow> (0 \<le> (x::int) \<and> P) = (0 \<le> x' \<and> P')"
   391   by (simp cong: conj_cong)
   392 
   393 ML_file "Tools/Qelim/cooper.ML"
   394 
   395 method_setup presburger = \<open>
   396   let
   397     fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   398     fun simple_keyword k = Scan.lift (Args.$$$ k) >> K ()
   399     val addN = "add"
   400     val delN = "del"
   401     val elimN = "elim"
   402     val any_keyword = keyword addN || keyword delN || simple_keyword elimN
   403     val thms = Scan.repeats (Scan.unless any_keyword Attrib.multi_thm)
   404   in
   405     Scan.optional (simple_keyword elimN >> K false) true --
   406     Scan.optional (keyword addN |-- thms) [] --
   407     Scan.optional (keyword delN |-- thms) [] >>
   408     (fn ((elim, add_ths), del_ths) => fn ctxt =>
   409       SIMPLE_METHOD' (Cooper.tac elim add_ths del_ths ctxt))
   410   end
   411 \<close> "Cooper's algorithm for Presburger arithmetic"
   412 
   413 declare mod_eq_0_iff_dvd [presburger]
   414 declare mod_by_Suc_0 [presburger] 
   415 declare mod_0 [presburger]
   416 declare mod_by_1 [presburger]
   417 declare mod_self [presburger]
   418 declare div_by_0 [presburger]
   419 declare mod_by_0 [presburger]
   420 declare mod_div_trivial [presburger]
   421 declare mult_div_mod_eq [presburger]
   422 declare div_mult_mod_eq [presburger]
   423 declare mod_mult_self1 [presburger]
   424 declare mod_mult_self2 [presburger]
   425 declare mod2_Suc_Suc [presburger]
   426 declare not_mod_2_eq_0_eq_1 [presburger] 
   427 declare nat_zero_less_power_iff [presburger]
   428 
   429 lemma [presburger, algebra]: "m mod 2 = (1::nat) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   430 lemma [presburger, algebra]: "m mod 2 = Suc 0 \<longleftrightarrow> \<not> 2 dvd m " by presburger
   431 lemma [presburger, algebra]: "m mod (Suc (Suc 0)) = (1::nat) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   432 lemma [presburger, algebra]: "m mod (Suc (Suc 0)) = Suc 0 \<longleftrightarrow> \<not> 2 dvd m " by presburger
   433 lemma [presburger, algebra]: "m mod 2 = (1::int) \<longleftrightarrow> \<not> 2 dvd m " by presburger
   434 
   435 context semiring_parity
   436 begin
   437 
   438 declare even_times_iff [presburger]
   439 
   440 declare even_power [presburger]
   441 
   442 lemma [presburger]:
   443   "even (a + b) \<longleftrightarrow> even a \<and> even b \<or> odd a \<and> odd b"
   444   by auto
   445 
   446 end
   447 
   448 context ring_parity
   449 begin
   450 
   451 declare even_minus [presburger]
   452 
   453 end
   454 
   455 context linordered_idom
   456 begin
   457 
   458 declare zero_le_power_eq [presburger]
   459 
   460 declare zero_less_power_eq [presburger]
   461 
   462 declare power_less_zero_eq [presburger]
   463   
   464 declare power_le_zero_eq [presburger]
   465 
   466 end
   467 
   468 declare even_Suc [presburger]
   469 
   470 lemma [presburger]:
   471   "Suc n div Suc (Suc 0) = n div Suc (Suc 0) \<longleftrightarrow> even n"
   472   by presburger
   473 
   474 declare even_diff_nat [presburger]
   475 
   476 lemma [presburger]:
   477   fixes k :: int
   478   shows "(k + 1) div 2 = k div 2 \<longleftrightarrow> even k"
   479   by presburger
   480 
   481 lemma [presburger]:
   482   fixes k :: int
   483   shows "(k + 1) div 2 = k div 2 + 1 \<longleftrightarrow> odd k"
   484   by presburger
   485 
   486 lemma [presburger]:
   487   "even n \<longleftrightarrow> even (int n)"
   488   by simp
   489   
   490 
   491 subsection \<open>Nice facts about division by @{term 4}\<close>  
   492 
   493 lemma even_even_mod_4_iff:
   494   "even (n::nat) \<longleftrightarrow> even (n mod 4)"
   495   by presburger
   496 
   497 lemma odd_mod_4_div_2:
   498   "n mod 4 = (3::nat) \<Longrightarrow> odd ((n - 1) div 2)"
   499   by presburger
   500 
   501 lemma even_mod_4_div_2:
   502   "n mod 4 = (1::nat) \<Longrightarrow> even ((n - 1) div 2)"
   503   by presburger
   504 
   505 
   506 subsection \<open>Try0\<close>
   507 
   508 ML_file "Tools/try0.ML"
   509 
   510 end