src/HOL/Real_Vector_Spaces.thy
author wenzelm
Tue Sep 26 20:54:40 2017 +0200 (22 months ago)
changeset 66695 91500c024c7f
parent 66422 2891f33ed4c8
child 66793 deabce3ccf1f
permissions -rw-r--r--
tuned;
     1 (*  Title:      HOL/Real_Vector_Spaces.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 section \<open>Vector Spaces and Algebras over the Reals\<close>
     7 
     8 theory Real_Vector_Spaces
     9 imports Real Topological_Spaces
    10 begin
    11 
    12 subsection \<open>Locale for additive functions\<close>
    13 
    14 locale additive =
    15   fixes f :: "'a::ab_group_add \<Rightarrow> 'b::ab_group_add"
    16   assumes add: "f (x + y) = f x + f y"
    17 begin
    18 
    19 lemma zero: "f 0 = 0"
    20 proof -
    21   have "f 0 = f (0 + 0)" by simp
    22   also have "\<dots> = f 0 + f 0" by (rule add)
    23   finally show "f 0 = 0" by simp
    24 qed
    25 
    26 lemma minus: "f (- x) = - f x"
    27 proof -
    28   have "f (- x) + f x = f (- x + x)" by (rule add [symmetric])
    29   also have "\<dots> = - f x + f x" by (simp add: zero)
    30   finally show "f (- x) = - f x" by (rule add_right_imp_eq)
    31 qed
    32 
    33 lemma diff: "f (x - y) = f x - f y"
    34   using add [of x "- y"] by (simp add: minus)
    35 
    36 lemma sum: "f (sum g A) = (\<Sum>x\<in>A. f (g x))"
    37   by (induct A rule: infinite_finite_induct) (simp_all add: zero add)
    38 
    39 end
    40 
    41 
    42 subsection \<open>Vector spaces\<close>
    43 
    44 locale vector_space =
    45   fixes scale :: "'a::field \<Rightarrow> 'b::ab_group_add \<Rightarrow> 'b"
    46   assumes scale_right_distrib [algebra_simps]: "scale a (x + y) = scale a x + scale a y"
    47     and scale_left_distrib [algebra_simps]: "scale (a + b) x = scale a x + scale b x"
    48     and scale_scale [simp]: "scale a (scale b x) = scale (a * b) x"
    49     and scale_one [simp]: "scale 1 x = x"
    50 begin
    51 
    52 lemma scale_left_commute: "scale a (scale b x) = scale b (scale a x)"
    53   by (simp add: mult.commute)
    54 
    55 lemma scale_zero_left [simp]: "scale 0 x = 0"
    56   and scale_minus_left [simp]: "scale (- a) x = - (scale a x)"
    57   and scale_left_diff_distrib [algebra_simps]: "scale (a - b) x = scale a x - scale b x"
    58   and scale_sum_left: "scale (sum f A) x = (\<Sum>a\<in>A. scale (f a) x)"
    59 proof -
    60   interpret s: additive "\<lambda>a. scale a x"
    61     by standard (rule scale_left_distrib)
    62   show "scale 0 x = 0" by (rule s.zero)
    63   show "scale (- a) x = - (scale a x)" by (rule s.minus)
    64   show "scale (a - b) x = scale a x - scale b x" by (rule s.diff)
    65   show "scale (sum f A) x = (\<Sum>a\<in>A. scale (f a) x)" by (rule s.sum)
    66 qed
    67 
    68 lemma scale_zero_right [simp]: "scale a 0 = 0"
    69   and scale_minus_right [simp]: "scale a (- x) = - (scale a x)"
    70   and scale_right_diff_distrib [algebra_simps]: "scale a (x - y) = scale a x - scale a y"
    71   and scale_sum_right: "scale a (sum f A) = (\<Sum>x\<in>A. scale a (f x))"
    72 proof -
    73   interpret s: additive "\<lambda>x. scale a x"
    74     by standard (rule scale_right_distrib)
    75   show "scale a 0 = 0" by (rule s.zero)
    76   show "scale a (- x) = - (scale a x)" by (rule s.minus)
    77   show "scale a (x - y) = scale a x - scale a y" by (rule s.diff)
    78   show "scale a (sum f A) = (\<Sum>x\<in>A. scale a (f x))" by (rule s.sum)
    79 qed
    80 
    81 lemma scale_eq_0_iff [simp]: "scale a x = 0 \<longleftrightarrow> a = 0 \<or> x = 0"
    82 proof (cases "a = 0")
    83   case True
    84   then show ?thesis by simp
    85 next
    86   case False
    87   have "x = 0" if "scale a x = 0"
    88   proof -
    89     from False that have "scale (inverse a) (scale a x) = 0" by simp
    90     with False show ?thesis by simp
    91   qed
    92   then show ?thesis by force
    93 qed
    94 
    95 lemma scale_left_imp_eq:
    96   assumes nonzero: "a \<noteq> 0"
    97     and scale: "scale a x = scale a y"
    98   shows "x = y"
    99 proof -
   100   from scale have "scale a (x - y) = 0"
   101      by (simp add: scale_right_diff_distrib)
   102   with nonzero have "x - y = 0" by simp
   103   then show "x = y" by (simp only: right_minus_eq)
   104 qed
   105 
   106 lemma scale_right_imp_eq:
   107   assumes nonzero: "x \<noteq> 0"
   108     and scale: "scale a x = scale b x"
   109   shows "a = b"
   110 proof -
   111   from scale have "scale (a - b) x = 0"
   112      by (simp add: scale_left_diff_distrib)
   113   with nonzero have "a - b = 0" by simp
   114   then show "a = b" by (simp only: right_minus_eq)
   115 qed
   116 
   117 lemma scale_cancel_left [simp]: "scale a x = scale a y \<longleftrightarrow> x = y \<or> a = 0"
   118   by (auto intro: scale_left_imp_eq)
   119 
   120 lemma scale_cancel_right [simp]: "scale a x = scale b x \<longleftrightarrow> a = b \<or> x = 0"
   121   by (auto intro: scale_right_imp_eq)
   122 
   123 end
   124 
   125 
   126 subsection \<open>Real vector spaces\<close>
   127 
   128 class scaleR =
   129   fixes scaleR :: "real \<Rightarrow> 'a \<Rightarrow> 'a" (infixr "*\<^sub>R" 75)
   130 begin
   131 
   132 abbreviation divideR :: "'a \<Rightarrow> real \<Rightarrow> 'a"  (infixl "'/\<^sub>R" 70)
   133   where "x /\<^sub>R r \<equiv> scaleR (inverse r) x"
   134 
   135 end
   136 
   137 class real_vector = scaleR + ab_group_add +
   138   assumes scaleR_add_right: "scaleR a (x + y) = scaleR a x + scaleR a y"
   139   and scaleR_add_left: "scaleR (a + b) x = scaleR a x + scaleR b x"
   140   and scaleR_scaleR: "scaleR a (scaleR b x) = scaleR (a * b) x"
   141   and scaleR_one: "scaleR 1 x = x"
   142 
   143 interpretation real_vector: vector_space "scaleR :: real \<Rightarrow> 'a \<Rightarrow> 'a::real_vector"
   144   apply unfold_locales
   145      apply (rule scaleR_add_right)
   146     apply (rule scaleR_add_left)
   147    apply (rule scaleR_scaleR)
   148   apply (rule scaleR_one)
   149   done
   150 
   151 text \<open>Recover original theorem names\<close>
   152 
   153 lemmas scaleR_left_commute = real_vector.scale_left_commute
   154 lemmas scaleR_zero_left = real_vector.scale_zero_left
   155 lemmas scaleR_minus_left = real_vector.scale_minus_left
   156 lemmas scaleR_diff_left = real_vector.scale_left_diff_distrib
   157 lemmas scaleR_sum_left = real_vector.scale_sum_left
   158 lemmas scaleR_zero_right = real_vector.scale_zero_right
   159 lemmas scaleR_minus_right = real_vector.scale_minus_right
   160 lemmas scaleR_diff_right = real_vector.scale_right_diff_distrib
   161 lemmas scaleR_sum_right = real_vector.scale_sum_right
   162 lemmas scaleR_eq_0_iff = real_vector.scale_eq_0_iff
   163 lemmas scaleR_left_imp_eq = real_vector.scale_left_imp_eq
   164 lemmas scaleR_right_imp_eq = real_vector.scale_right_imp_eq
   165 lemmas scaleR_cancel_left = real_vector.scale_cancel_left
   166 lemmas scaleR_cancel_right = real_vector.scale_cancel_right
   167 
   168 text \<open>Legacy names\<close>
   169 
   170 lemmas scaleR_left_distrib = scaleR_add_left
   171 lemmas scaleR_right_distrib = scaleR_add_right
   172 lemmas scaleR_left_diff_distrib = scaleR_diff_left
   173 lemmas scaleR_right_diff_distrib = scaleR_diff_right
   174 
   175 lemma scaleR_minus1_left [simp]: "scaleR (-1) x = - x"
   176   for x :: "'a::real_vector"
   177   using scaleR_minus_left [of 1 x] by simp
   178 
   179 lemma scaleR_2:
   180   fixes x :: "'a::real_vector"
   181   shows "scaleR 2 x = x + x"
   182   unfolding one_add_one [symmetric] scaleR_left_distrib by simp
   183 
   184 lemma scaleR_half_double [simp]:
   185   fixes a :: "'a::real_vector"
   186   shows "(1 / 2) *\<^sub>R (a + a) = a"
   187 proof -
   188   have "\<And>r. r *\<^sub>R (a + a) = (r * 2) *\<^sub>R a"
   189     by (metis scaleR_2 scaleR_scaleR)
   190   then show ?thesis
   191     by simp
   192 qed
   193 
   194 class real_algebra = real_vector + ring +
   195   assumes mult_scaleR_left [simp]: "scaleR a x * y = scaleR a (x * y)"
   196     and mult_scaleR_right [simp]: "x * scaleR a y = scaleR a (x * y)"
   197 
   198 class real_algebra_1 = real_algebra + ring_1
   199 
   200 class real_div_algebra = real_algebra_1 + division_ring
   201 
   202 class real_field = real_div_algebra + field
   203 
   204 instantiation real :: real_field
   205 begin
   206 
   207 definition real_scaleR_def [simp]: "scaleR a x = a * x"
   208 
   209 instance
   210   by standard (simp_all add: algebra_simps)
   211 
   212 end
   213 
   214 interpretation scaleR_left: additive "(\<lambda>a. scaleR a x :: 'a::real_vector)"
   215   by standard (rule scaleR_left_distrib)
   216 
   217 interpretation scaleR_right: additive "(\<lambda>x. scaleR a x :: 'a::real_vector)"
   218   by standard (rule scaleR_right_distrib)
   219 
   220 lemma nonzero_inverse_scaleR_distrib:
   221   "a \<noteq> 0 \<Longrightarrow> x \<noteq> 0 \<Longrightarrow> inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   222   for x :: "'a::real_div_algebra"
   223   by (rule inverse_unique) simp
   224 
   225 lemma inverse_scaleR_distrib: "inverse (scaleR a x) = scaleR (inverse a) (inverse x)"
   226   for x :: "'a::{real_div_algebra,division_ring}"
   227   apply (cases "a = 0")
   228    apply simp
   229   apply (cases "x = 0")
   230    apply simp
   231   apply (erule (1) nonzero_inverse_scaleR_distrib)
   232   done
   233 
   234 lemma sum_constant_scaleR: "(\<Sum>x\<in>A. y) = of_nat (card A) *\<^sub>R y"
   235   for y :: "'a::real_vector"
   236   by (induct A rule: infinite_finite_induct) (simp_all add: algebra_simps)
   237 
   238 named_theorems vector_add_divide_simps "to simplify sums of scaled vectors"
   239 
   240 lemma [vector_add_divide_simps]:
   241   "v + (b / z) *\<^sub>R w = (if z = 0 then v else (z *\<^sub>R v + b *\<^sub>R w) /\<^sub>R z)"
   242   "a *\<^sub>R v + (b / z) *\<^sub>R w = (if z = 0 then a *\<^sub>R v else ((a * z) *\<^sub>R v + b *\<^sub>R w) /\<^sub>R z)"
   243   "(a / z) *\<^sub>R v + w = (if z = 0 then w else (a *\<^sub>R v + z *\<^sub>R w) /\<^sub>R z)"
   244   "(a / z) *\<^sub>R v + b *\<^sub>R w = (if z = 0 then b *\<^sub>R w else (a *\<^sub>R v + (b * z) *\<^sub>R w) /\<^sub>R z)"
   245   "v - (b / z) *\<^sub>R w = (if z = 0 then v else (z *\<^sub>R v - b *\<^sub>R w) /\<^sub>R z)"
   246   "a *\<^sub>R v - (b / z) *\<^sub>R w = (if z = 0 then a *\<^sub>R v else ((a * z) *\<^sub>R v - b *\<^sub>R w) /\<^sub>R z)"
   247   "(a / z) *\<^sub>R v - w = (if z = 0 then -w else (a *\<^sub>R v - z *\<^sub>R w) /\<^sub>R z)"
   248   "(a / z) *\<^sub>R v - b *\<^sub>R w = (if z = 0 then -b *\<^sub>R w else (a *\<^sub>R v - (b * z) *\<^sub>R w) /\<^sub>R z)"
   249   for v :: "'a :: real_vector"
   250   by (simp_all add: divide_inverse_commute scaleR_add_right real_vector.scale_right_diff_distrib)
   251 
   252 
   253 lemma eq_vector_fraction_iff [vector_add_divide_simps]:
   254   fixes x :: "'a :: real_vector"
   255   shows "(x = (u / v) *\<^sub>R a) \<longleftrightarrow> (if v=0 then x = 0 else v *\<^sub>R x = u *\<^sub>R a)"
   256 by auto (metis (no_types) divide_eq_1_iff divide_inverse_commute scaleR_one scaleR_scaleR)
   257 
   258 lemma vector_fraction_eq_iff [vector_add_divide_simps]:
   259   fixes x :: "'a :: real_vector"
   260   shows "((u / v) *\<^sub>R a = x) \<longleftrightarrow> (if v=0 then x = 0 else u *\<^sub>R a = v *\<^sub>R x)"
   261 by (metis eq_vector_fraction_iff)
   262 
   263 lemma real_vector_affinity_eq:
   264   fixes x :: "'a :: real_vector"
   265   assumes m0: "m \<noteq> 0"
   266   shows "m *\<^sub>R x + c = y \<longleftrightarrow> x = inverse m *\<^sub>R y - (inverse m *\<^sub>R c)"
   267     (is "?lhs \<longleftrightarrow> ?rhs")
   268 proof
   269   assume ?lhs
   270   then have "m *\<^sub>R x = y - c" by (simp add: field_simps)
   271   then have "inverse m *\<^sub>R (m *\<^sub>R x) = inverse m *\<^sub>R (y - c)" by simp
   272   then show "x = inverse m *\<^sub>R y - (inverse m *\<^sub>R c)"
   273     using m0
   274   by (simp add: real_vector.scale_right_diff_distrib)
   275 next
   276   assume ?rhs
   277   with m0 show "m *\<^sub>R x + c = y"
   278     by (simp add: real_vector.scale_right_diff_distrib)
   279 qed
   280 
   281 lemma real_vector_eq_affinity: "m \<noteq> 0 \<Longrightarrow> y = m *\<^sub>R x + c \<longleftrightarrow> inverse m *\<^sub>R y - (inverse m *\<^sub>R c) = x"
   282   for x :: "'a::real_vector"
   283   using real_vector_affinity_eq[where m=m and x=x and y=y and c=c]
   284   by metis
   285 
   286 lemma scaleR_eq_iff [simp]: "b + u *\<^sub>R a = a + u *\<^sub>R b \<longleftrightarrow> a = b \<or> u = 1"
   287   for a :: "'a::real_vector"
   288 proof (cases "u = 1")
   289   case True
   290   then show ?thesis by auto
   291 next
   292   case False
   293   have "a = b" if "b + u *\<^sub>R a = a + u *\<^sub>R b"
   294   proof -
   295     from that have "(u - 1) *\<^sub>R a = (u - 1) *\<^sub>R b"
   296       by (simp add: algebra_simps)
   297     with False show ?thesis
   298       by auto
   299   qed
   300   then show ?thesis by auto
   301 qed
   302 
   303 lemma scaleR_collapse [simp]: "(1 - u) *\<^sub>R a + u *\<^sub>R a = a"
   304   for a :: "'a::real_vector"
   305   by (simp add: algebra_simps)
   306 
   307 
   308 subsection \<open>Embedding of the Reals into any \<open>real_algebra_1\<close>: \<open>of_real\<close>\<close>
   309 
   310 definition of_real :: "real \<Rightarrow> 'a::real_algebra_1"
   311   where "of_real r = scaleR r 1"
   312 
   313 lemma scaleR_conv_of_real: "scaleR r x = of_real r * x"
   314   by (simp add: of_real_def)
   315 
   316 lemma of_real_0 [simp]: "of_real 0 = 0"
   317   by (simp add: of_real_def)
   318 
   319 lemma of_real_1 [simp]: "of_real 1 = 1"
   320   by (simp add: of_real_def)
   321 
   322 lemma of_real_add [simp]: "of_real (x + y) = of_real x + of_real y"
   323   by (simp add: of_real_def scaleR_left_distrib)
   324 
   325 lemma of_real_minus [simp]: "of_real (- x) = - of_real x"
   326   by (simp add: of_real_def)
   327 
   328 lemma of_real_diff [simp]: "of_real (x - y) = of_real x - of_real y"
   329   by (simp add: of_real_def scaleR_left_diff_distrib)
   330 
   331 lemma of_real_mult [simp]: "of_real (x * y) = of_real x * of_real y"
   332   by (simp add: of_real_def mult.commute)
   333 
   334 lemma of_real_sum[simp]: "of_real (sum f s) = (\<Sum>x\<in>s. of_real (f x))"
   335   by (induct s rule: infinite_finite_induct) auto
   336 
   337 lemma of_real_prod[simp]: "of_real (prod f s) = (\<Prod>x\<in>s. of_real (f x))"
   338   by (induct s rule: infinite_finite_induct) auto
   339 
   340 lemma nonzero_of_real_inverse:
   341   "x \<noteq> 0 \<Longrightarrow> of_real (inverse x) = inverse (of_real x :: 'a::real_div_algebra)"
   342   by (simp add: of_real_def nonzero_inverse_scaleR_distrib)
   343 
   344 lemma of_real_inverse [simp]:
   345   "of_real (inverse x) = inverse (of_real x :: 'a::{real_div_algebra,division_ring})"
   346   by (simp add: of_real_def inverse_scaleR_distrib)
   347 
   348 lemma nonzero_of_real_divide:
   349   "y \<noteq> 0 \<Longrightarrow> of_real (x / y) = (of_real x / of_real y :: 'a::real_field)"
   350   by (simp add: divide_inverse nonzero_of_real_inverse)
   351 
   352 lemma of_real_divide [simp]:
   353   "of_real (x / y) = (of_real x / of_real y :: 'a::real_div_algebra)"
   354   by (simp add: divide_inverse)
   355 
   356 lemma of_real_power [simp]:
   357   "of_real (x ^ n) = (of_real x :: 'a::{real_algebra_1}) ^ n"
   358   by (induct n) simp_all
   359 
   360 lemma of_real_eq_iff [simp]: "of_real x = of_real y \<longleftrightarrow> x = y"
   361   by (simp add: of_real_def)
   362 
   363 lemma inj_of_real: "inj of_real"
   364   by (auto intro: injI)
   365 
   366 lemmas of_real_eq_0_iff [simp] = of_real_eq_iff [of _ 0, simplified]
   367 lemmas of_real_eq_1_iff [simp] = of_real_eq_iff [of _ 1, simplified]
   368 
   369 lemma of_real_eq_id [simp]: "of_real = (id :: real \<Rightarrow> real)"
   370   by (rule ext) (simp add: of_real_def)
   371 
   372 text \<open>Collapse nested embeddings.\<close>
   373 lemma of_real_of_nat_eq [simp]: "of_real (of_nat n) = of_nat n"
   374   by (induct n) auto
   375 
   376 lemma of_real_of_int_eq [simp]: "of_real (of_int z) = of_int z"
   377   by (cases z rule: int_diff_cases) simp
   378 
   379 lemma of_real_numeral [simp]: "of_real (numeral w) = numeral w"
   380   using of_real_of_int_eq [of "numeral w"] by simp
   381 
   382 lemma of_real_neg_numeral [simp]: "of_real (- numeral w) = - numeral w"
   383   using of_real_of_int_eq [of "- numeral w"] by simp
   384 
   385 text \<open>Every real algebra has characteristic zero.\<close>
   386 instance real_algebra_1 < ring_char_0
   387 proof
   388   from inj_of_real inj_of_nat have "inj (of_real \<circ> of_nat)"
   389     by (rule inj_comp)
   390   then show "inj (of_nat :: nat \<Rightarrow> 'a)"
   391     by (simp add: comp_def)
   392 qed
   393 
   394 lemma fraction_scaleR_times [simp]:
   395   fixes a :: "'a::real_algebra_1"
   396   shows "(numeral u / numeral v) *\<^sub>R (numeral w * a) = (numeral u * numeral w / numeral v) *\<^sub>R a"
   397 by (metis (no_types, lifting) of_real_numeral scaleR_conv_of_real scaleR_scaleR times_divide_eq_left)
   398 
   399 lemma inverse_scaleR_times [simp]:
   400   fixes a :: "'a::real_algebra_1"
   401   shows "(1 / numeral v) *\<^sub>R (numeral w * a) = (numeral w / numeral v) *\<^sub>R a"
   402 by (metis divide_inverse_commute inverse_eq_divide of_real_numeral scaleR_conv_of_real scaleR_scaleR)
   403 
   404 lemma scaleR_times [simp]:
   405   fixes a :: "'a::real_algebra_1"
   406   shows "(numeral u) *\<^sub>R (numeral w * a) = (numeral u * numeral w) *\<^sub>R a"
   407 by (simp add: scaleR_conv_of_real)
   408 
   409 instance real_field < field_char_0 ..
   410 
   411 
   412 subsection \<open>The Set of Real Numbers\<close>
   413 
   414 definition Reals :: "'a::real_algebra_1 set"  ("\<real>")
   415   where "\<real> = range of_real"
   416 
   417 lemma Reals_of_real [simp]: "of_real r \<in> \<real>"
   418   by (simp add: Reals_def)
   419 
   420 lemma Reals_of_int [simp]: "of_int z \<in> \<real>"
   421   by (subst of_real_of_int_eq [symmetric], rule Reals_of_real)
   422 
   423 lemma Reals_of_nat [simp]: "of_nat n \<in> \<real>"
   424   by (subst of_real_of_nat_eq [symmetric], rule Reals_of_real)
   425 
   426 lemma Reals_numeral [simp]: "numeral w \<in> \<real>"
   427   by (subst of_real_numeral [symmetric], rule Reals_of_real)
   428 
   429 lemma Reals_0 [simp]: "0 \<in> \<real>"
   430   apply (unfold Reals_def)
   431   apply (rule range_eqI)
   432   apply (rule of_real_0 [symmetric])
   433   done
   434 
   435 lemma Reals_1 [simp]: "1 \<in> \<real>"
   436   apply (unfold Reals_def)
   437   apply (rule range_eqI)
   438   apply (rule of_real_1 [symmetric])
   439   done
   440 
   441 lemma Reals_add [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a + b \<in> \<real>"
   442   apply (auto simp add: Reals_def)
   443   apply (rule range_eqI)
   444   apply (rule of_real_add [symmetric])
   445   done
   446 
   447 lemma Reals_minus [simp]: "a \<in> \<real> \<Longrightarrow> - a \<in> \<real>"
   448   apply (auto simp add: Reals_def)
   449   apply (rule range_eqI)
   450   apply (rule of_real_minus [symmetric])
   451   done
   452 
   453 lemma Reals_diff [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a - b \<in> \<real>"
   454   apply (auto simp add: Reals_def)
   455   apply (rule range_eqI)
   456   apply (rule of_real_diff [symmetric])
   457   done
   458 
   459 lemma Reals_mult [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a * b \<in> \<real>"
   460   apply (auto simp add: Reals_def)
   461   apply (rule range_eqI)
   462   apply (rule of_real_mult [symmetric])
   463   done
   464 
   465 lemma nonzero_Reals_inverse: "a \<in> \<real> \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> inverse a \<in> \<real>"
   466   for a :: "'a::real_div_algebra"
   467   apply (auto simp add: Reals_def)
   468   apply (rule range_eqI)
   469   apply (erule nonzero_of_real_inverse [symmetric])
   470   done
   471 
   472 lemma Reals_inverse: "a \<in> \<real> \<Longrightarrow> inverse a \<in> \<real>"
   473   for a :: "'a::{real_div_algebra,division_ring}"
   474   apply (auto simp add: Reals_def)
   475   apply (rule range_eqI)
   476   apply (rule of_real_inverse [symmetric])
   477   done
   478 
   479 lemma Reals_inverse_iff [simp]: "inverse x \<in> \<real> \<longleftrightarrow> x \<in> \<real>"
   480   for x :: "'a::{real_div_algebra,division_ring}"
   481   by (metis Reals_inverse inverse_inverse_eq)
   482 
   483 lemma nonzero_Reals_divide: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> b \<noteq> 0 \<Longrightarrow> a / b \<in> \<real>"
   484   for a b :: "'a::real_field"
   485   apply (auto simp add: Reals_def)
   486   apply (rule range_eqI)
   487   apply (erule nonzero_of_real_divide [symmetric])
   488   done
   489 
   490 lemma Reals_divide [simp]: "a \<in> \<real> \<Longrightarrow> b \<in> \<real> \<Longrightarrow> a / b \<in> \<real>"
   491   for a b :: "'a::{real_field,field}"
   492   apply (auto simp add: Reals_def)
   493   apply (rule range_eqI)
   494   apply (rule of_real_divide [symmetric])
   495   done
   496 
   497 lemma Reals_power [simp]: "a \<in> \<real> \<Longrightarrow> a ^ n \<in> \<real>"
   498   for a :: "'a::real_algebra_1"
   499   apply (auto simp add: Reals_def)
   500   apply (rule range_eqI)
   501   apply (rule of_real_power [symmetric])
   502   done
   503 
   504 lemma Reals_cases [cases set: Reals]:
   505   assumes "q \<in> \<real>"
   506   obtains (of_real) r where "q = of_real r"
   507   unfolding Reals_def
   508 proof -
   509   from \<open>q \<in> \<real>\<close> have "q \<in> range of_real" unfolding Reals_def .
   510   then obtain r where "q = of_real r" ..
   511   then show thesis ..
   512 qed
   513 
   514 lemma sum_in_Reals [intro,simp]: "(\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>) \<Longrightarrow> sum f s \<in> \<real>"
   515 proof (induct s rule: infinite_finite_induct)
   516   case infinite
   517   then show ?case by (metis Reals_0 sum.infinite)
   518 qed simp_all
   519 
   520 lemma prod_in_Reals [intro,simp]: "(\<And>i. i \<in> s \<Longrightarrow> f i \<in> \<real>) \<Longrightarrow> prod f s \<in> \<real>"
   521 proof (induct s rule: infinite_finite_induct)
   522   case infinite
   523   then show ?case by (metis Reals_1 prod.infinite)
   524 qed simp_all
   525 
   526 lemma Reals_induct [case_names of_real, induct set: Reals]:
   527   "q \<in> \<real> \<Longrightarrow> (\<And>r. P (of_real r)) \<Longrightarrow> P q"
   528   by (rule Reals_cases) auto
   529 
   530 
   531 subsection \<open>Ordered real vector spaces\<close>
   532 
   533 class ordered_real_vector = real_vector + ordered_ab_group_add +
   534   assumes scaleR_left_mono: "x \<le> y \<Longrightarrow> 0 \<le> a \<Longrightarrow> a *\<^sub>R x \<le> a *\<^sub>R y"
   535     and scaleR_right_mono: "a \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R x"
   536 begin
   537 
   538 lemma scaleR_mono: "a \<le> b \<Longrightarrow> x \<le> y \<Longrightarrow> 0 \<le> b \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> b *\<^sub>R y"
   539   apply (erule scaleR_right_mono [THEN order_trans])
   540    apply assumption
   541   apply (erule scaleR_left_mono)
   542   apply assumption
   543   done
   544 
   545 lemma scaleR_mono': "a \<le> b \<Longrightarrow> c \<le> d \<Longrightarrow> 0 \<le> a \<Longrightarrow> 0 \<le> c \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R d"
   546   by (rule scaleR_mono) (auto intro: order.trans)
   547 
   548 lemma pos_le_divideRI:
   549   assumes "0 < c"
   550     and "c *\<^sub>R a \<le> b"
   551   shows "a \<le> b /\<^sub>R c"
   552 proof -
   553   from scaleR_left_mono[OF assms(2)] assms(1)
   554   have "c *\<^sub>R a /\<^sub>R c \<le> b /\<^sub>R c"
   555     by simp
   556   with assms show ?thesis
   557     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   558 qed
   559 
   560 lemma pos_le_divideR_eq:
   561   assumes "0 < c"
   562   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> c *\<^sub>R a \<le> b"
   563     (is "?lhs \<longleftrightarrow> ?rhs")
   564 proof
   565   assume ?lhs
   566   from scaleR_left_mono[OF this] assms have "c *\<^sub>R a \<le> c *\<^sub>R (b /\<^sub>R c)"
   567     by simp
   568   with assms show ?rhs
   569     by (simp add: scaleR_one scaleR_scaleR inverse_eq_divide)
   570 next
   571   assume ?rhs
   572   with assms show ?lhs by (rule pos_le_divideRI)
   573 qed
   574 
   575 lemma scaleR_image_atLeastAtMost: "c > 0 \<Longrightarrow> scaleR c ` {x..y} = {c *\<^sub>R x..c *\<^sub>R y}"
   576   apply (auto intro!: scaleR_left_mono)
   577   apply (rule_tac x = "inverse c *\<^sub>R xa" in image_eqI)
   578    apply (simp_all add: pos_le_divideR_eq[symmetric] scaleR_scaleR scaleR_one)
   579   done
   580 
   581 end
   582 
   583 lemma neg_le_divideR_eq:
   584   fixes a :: "'a :: ordered_real_vector"
   585   assumes "c < 0"
   586   shows "a \<le> b /\<^sub>R c \<longleftrightarrow> b \<le> c *\<^sub>R a"
   587   using pos_le_divideR_eq [of "-c" a "-b"] assms by simp
   588 
   589 lemma scaleR_nonneg_nonneg: "0 \<le> a \<Longrightarrow> 0 \<le> x \<Longrightarrow> 0 \<le> a *\<^sub>R x"
   590   for x :: "'a::ordered_real_vector"
   591   using scaleR_left_mono [of 0 x a] by simp
   592 
   593 lemma scaleR_nonneg_nonpos: "0 \<le> a \<Longrightarrow> x \<le> 0 \<Longrightarrow> a *\<^sub>R x \<le> 0"
   594   for x :: "'a::ordered_real_vector"
   595   using scaleR_left_mono [of x 0 a] by simp
   596 
   597 lemma scaleR_nonpos_nonneg: "a \<le> 0 \<Longrightarrow> 0 \<le> x \<Longrightarrow> a *\<^sub>R x \<le> 0"
   598   for x :: "'a::ordered_real_vector"
   599   using scaleR_right_mono [of a 0 x] by simp
   600 
   601 lemma split_scaleR_neg_le: "(0 \<le> a \<and> x \<le> 0) \<or> (a \<le> 0 \<and> 0 \<le> x) \<Longrightarrow> a *\<^sub>R x \<le> 0"
   602   for x :: "'a::ordered_real_vector"
   603   by (auto simp add: scaleR_nonneg_nonpos scaleR_nonpos_nonneg)
   604 
   605 lemma le_add_iff1: "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> (a - b) *\<^sub>R e + c \<le> d"
   606   for c d e :: "'a::ordered_real_vector"
   607   by (simp add: algebra_simps)
   608 
   609 lemma le_add_iff2: "a *\<^sub>R e + c \<le> b *\<^sub>R e + d \<longleftrightarrow> c \<le> (b - a) *\<^sub>R e + d"
   610   for c d e :: "'a::ordered_real_vector"
   611   by (simp add: algebra_simps)
   612 
   613 lemma scaleR_left_mono_neg: "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b"
   614   for a b :: "'a::ordered_real_vector"
   615   apply (drule scaleR_left_mono [of _ _ "- c"])
   616    apply simp_all
   617   done
   618 
   619 lemma scaleR_right_mono_neg: "b \<le> a \<Longrightarrow> c \<le> 0 \<Longrightarrow> a *\<^sub>R c \<le> b *\<^sub>R c"
   620   for c :: "'a::ordered_real_vector"
   621   apply (drule scaleR_right_mono [of _ _ "- c"])
   622    apply simp_all
   623   done
   624 
   625 lemma scaleR_nonpos_nonpos: "a \<le> 0 \<Longrightarrow> b \<le> 0 \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   626   for b :: "'a::ordered_real_vector"
   627   using scaleR_right_mono_neg [of a 0 b] by simp
   628 
   629 lemma split_scaleR_pos_le: "(0 \<le> a \<and> 0 \<le> b) \<or> (a \<le> 0 \<and> b \<le> 0) \<Longrightarrow> 0 \<le> a *\<^sub>R b"
   630   for b :: "'a::ordered_real_vector"
   631   by (auto simp add: scaleR_nonneg_nonneg scaleR_nonpos_nonpos)
   632 
   633 lemma zero_le_scaleR_iff:
   634   fixes b :: "'a::ordered_real_vector"
   635   shows "0 \<le> a *\<^sub>R b \<longleftrightarrow> 0 < a \<and> 0 \<le> b \<or> a < 0 \<and> b \<le> 0 \<or> a = 0"
   636     (is "?lhs = ?rhs")
   637 proof (cases "a = 0")
   638   case True
   639   then show ?thesis by simp
   640 next
   641   case False
   642   show ?thesis
   643   proof
   644     assume ?lhs
   645     from \<open>a \<noteq> 0\<close> consider "a > 0" | "a < 0" by arith
   646     then show ?rhs
   647     proof cases
   648       case 1
   649       with \<open>?lhs\<close> have "inverse a *\<^sub>R 0 \<le> inverse a *\<^sub>R (a *\<^sub>R b)"
   650         by (intro scaleR_mono) auto
   651       with 1 show ?thesis
   652         by simp
   653     next
   654       case 2
   655       with \<open>?lhs\<close> have "- inverse a *\<^sub>R 0 \<le> - inverse a *\<^sub>R (a *\<^sub>R b)"
   656         by (intro scaleR_mono) auto
   657       with 2 show ?thesis
   658         by simp
   659     qed
   660   next
   661     assume ?rhs
   662     then show ?lhs
   663       by (auto simp: not_le \<open>a \<noteq> 0\<close> intro!: split_scaleR_pos_le)
   664   qed
   665 qed
   666 
   667 lemma scaleR_le_0_iff: "a *\<^sub>R b \<le> 0 \<longleftrightarrow> 0 < a \<and> b \<le> 0 \<or> a < 0 \<and> 0 \<le> b \<or> a = 0"
   668   for b::"'a::ordered_real_vector"
   669   by (insert zero_le_scaleR_iff [of "-a" b]) force
   670 
   671 lemma scaleR_le_cancel_left: "c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> (0 < c \<longrightarrow> a \<le> b) \<and> (c < 0 \<longrightarrow> b \<le> a)"
   672   for b :: "'a::ordered_real_vector"
   673   by (auto simp add: neq_iff scaleR_left_mono scaleR_left_mono_neg
   674       dest: scaleR_left_mono[where a="inverse c"] scaleR_left_mono_neg[where c="inverse c"])
   675 
   676 lemma scaleR_le_cancel_left_pos: "0 < c \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> a \<le> b"
   677   for b :: "'a::ordered_real_vector"
   678   by (auto simp: scaleR_le_cancel_left)
   679 
   680 lemma scaleR_le_cancel_left_neg: "c < 0 \<Longrightarrow> c *\<^sub>R a \<le> c *\<^sub>R b \<longleftrightarrow> b \<le> a"
   681   for b :: "'a::ordered_real_vector"
   682   by (auto simp: scaleR_le_cancel_left)
   683 
   684 lemma scaleR_left_le_one_le: "0 \<le> x \<Longrightarrow> a \<le> 1 \<Longrightarrow> a *\<^sub>R x \<le> x"
   685   for x :: "'a::ordered_real_vector" and a :: real
   686   using scaleR_right_mono[of a 1 x] by simp
   687 
   688 
   689 subsection \<open>Real normed vector spaces\<close>
   690 
   691 class dist =
   692   fixes dist :: "'a \<Rightarrow> 'a \<Rightarrow> real"
   693 
   694 class norm =
   695   fixes norm :: "'a \<Rightarrow> real"
   696 
   697 class sgn_div_norm = scaleR + norm + sgn +
   698   assumes sgn_div_norm: "sgn x = x /\<^sub>R norm x"
   699 
   700 class dist_norm = dist + norm + minus +
   701   assumes dist_norm: "dist x y = norm (x - y)"
   702 
   703 class uniformity_dist = dist + uniformity +
   704   assumes uniformity_dist: "uniformity = (INF e:{0 <..}. principal {(x, y). dist x y < e})"
   705 begin
   706 
   707 lemma eventually_uniformity_metric:
   708   "eventually P uniformity \<longleftrightarrow> (\<exists>e>0. \<forall>x y. dist x y < e \<longrightarrow> P (x, y))"
   709   unfolding uniformity_dist
   710   by (subst eventually_INF_base)
   711      (auto simp: eventually_principal subset_eq intro: bexI[of _ "min _ _"])
   712 
   713 end
   714 
   715 class real_normed_vector = real_vector + sgn_div_norm + dist_norm + uniformity_dist + open_uniformity +
   716   assumes norm_eq_zero [simp]: "norm x = 0 \<longleftrightarrow> x = 0"
   717     and norm_triangle_ineq: "norm (x + y) \<le> norm x + norm y"
   718     and norm_scaleR [simp]: "norm (scaleR a x) = \<bar>a\<bar> * norm x"
   719 begin
   720 
   721 lemma norm_ge_zero [simp]: "0 \<le> norm x"
   722 proof -
   723   have "0 = norm (x + -1 *\<^sub>R x)"
   724     using scaleR_add_left[of 1 "-1" x] norm_scaleR[of 0 x] by (simp add: scaleR_one)
   725   also have "\<dots> \<le> norm x + norm (-1 *\<^sub>R x)" by (rule norm_triangle_ineq)
   726   finally show ?thesis by simp
   727 qed
   728 
   729 end
   730 
   731 class real_normed_algebra = real_algebra + real_normed_vector +
   732   assumes norm_mult_ineq: "norm (x * y) \<le> norm x * norm y"
   733 
   734 class real_normed_algebra_1 = real_algebra_1 + real_normed_algebra +
   735   assumes norm_one [simp]: "norm 1 = 1"
   736 
   737 lemma (in real_normed_algebra_1) scaleR_power [simp]: "(scaleR x y) ^ n = scaleR (x^n) (y^n)"
   738   by (induct n) (simp_all add: scaleR_one scaleR_scaleR mult_ac)
   739 
   740 class real_normed_div_algebra = real_div_algebra + real_normed_vector +
   741   assumes norm_mult: "norm (x * y) = norm x * norm y"
   742 
   743 class real_normed_field = real_field + real_normed_div_algebra
   744 
   745 instance real_normed_div_algebra < real_normed_algebra_1
   746 proof
   747   show "norm (x * y) \<le> norm x * norm y" for x y :: 'a
   748     by (simp add: norm_mult)
   749 next
   750   have "norm (1 * 1::'a) = norm (1::'a) * norm (1::'a)"
   751     by (rule norm_mult)
   752   then show "norm (1::'a) = 1" by simp
   753 qed
   754 
   755 lemma norm_zero [simp]: "norm (0::'a::real_normed_vector) = 0"
   756   by simp
   757 
   758 lemma zero_less_norm_iff [simp]: "norm x > 0 \<longleftrightarrow> x \<noteq> 0"
   759   for x :: "'a::real_normed_vector"
   760   by (simp add: order_less_le)
   761 
   762 lemma norm_not_less_zero [simp]: "\<not> norm x < 0"
   763   for x :: "'a::real_normed_vector"
   764   by (simp add: linorder_not_less)
   765 
   766 lemma norm_le_zero_iff [simp]: "norm x \<le> 0 \<longleftrightarrow> x = 0"
   767   for x :: "'a::real_normed_vector"
   768   by (simp add: order_le_less)
   769 
   770 lemma norm_minus_cancel [simp]: "norm (- x) = norm x"
   771   for x :: "'a::real_normed_vector"
   772 proof -
   773   have "norm (- x) = norm (scaleR (- 1) x)"
   774     by (simp only: scaleR_minus_left scaleR_one)
   775   also have "\<dots> = \<bar>- 1\<bar> * norm x"
   776     by (rule norm_scaleR)
   777   finally show ?thesis by simp
   778 qed
   779 
   780 lemma norm_minus_commute: "norm (a - b) = norm (b - a)"
   781   for a b :: "'a::real_normed_vector"
   782 proof -
   783   have "norm (- (b - a)) = norm (b - a)"
   784     by (rule norm_minus_cancel)
   785   then show ?thesis by simp
   786 qed
   787 
   788 lemma dist_add_cancel [simp]: "dist (a + b) (a + c) = dist b c"
   789   for a :: "'a::real_normed_vector"
   790   by (simp add: dist_norm)
   791 
   792 lemma dist_add_cancel2 [simp]: "dist (b + a) (c + a) = dist b c"
   793   for a :: "'a::real_normed_vector"
   794   by (simp add: dist_norm)
   795 
   796 lemma dist_scaleR [simp]: "dist (x *\<^sub>R a) (y *\<^sub>R a) = \<bar>x - y\<bar> * norm a"
   797   for a :: "'a::real_normed_vector"
   798   by (metis dist_norm norm_scaleR scaleR_left.diff)
   799 
   800 lemma norm_uminus_minus: "norm (- x - y :: 'a :: real_normed_vector) = norm (x + y)"
   801   by (subst (2) norm_minus_cancel[symmetric], subst minus_add_distrib) simp
   802 
   803 lemma norm_triangle_ineq2: "norm a - norm b \<le> norm (a - b)"
   804   for a b :: "'a::real_normed_vector"
   805 proof -
   806   have "norm (a - b + b) \<le> norm (a - b) + norm b"
   807     by (rule norm_triangle_ineq)
   808   then show ?thesis by simp
   809 qed
   810 
   811 lemma norm_triangle_ineq3: "\<bar>norm a - norm b\<bar> \<le> norm (a - b)"
   812   for a b :: "'a::real_normed_vector"
   813   apply (subst abs_le_iff)
   814   apply auto
   815    apply (rule norm_triangle_ineq2)
   816   apply (subst norm_minus_commute)
   817   apply (rule norm_triangle_ineq2)
   818   done
   819 
   820 lemma norm_triangle_ineq4: "norm (a - b) \<le> norm a + norm b"
   821   for a b :: "'a::real_normed_vector"
   822 proof -
   823   have "norm (a + - b) \<le> norm a + norm (- b)"
   824     by (rule norm_triangle_ineq)
   825   then show ?thesis by simp
   826 qed
   827 
   828 lemma norm_triangle_le_diff:
   829   fixes x y :: "'a::real_normed_vector"
   830   shows "norm x + norm y \<le> e \<Longrightarrow> norm (x - y) \<le> e"
   831     by (meson norm_triangle_ineq4 order_trans)
   832 
   833 lemma norm_diff_ineq: "norm a - norm b \<le> norm (a + b)"
   834   for a b :: "'a::real_normed_vector"
   835 proof -
   836   have "norm a - norm (- b) \<le> norm (a - - b)"
   837     by (rule norm_triangle_ineq2)
   838   then show ?thesis by simp
   839 qed
   840 
   841 lemma norm_add_leD: "norm (a + b) \<le> c \<Longrightarrow> norm b \<le> norm a + c"
   842   for a b :: "'a::real_normed_vector"
   843   by (metis add.commute diff_le_eq norm_diff_ineq order.trans)
   844 
   845 lemma norm_diff_triangle_ineq: "norm ((a + b) - (c + d)) \<le> norm (a - c) + norm (b - d)"
   846   for a b c d :: "'a::real_normed_vector"
   847 proof -
   848   have "norm ((a + b) - (c + d)) = norm ((a - c) + (b - d))"
   849     by (simp add: algebra_simps)
   850   also have "\<dots> \<le> norm (a - c) + norm (b - d)"
   851     by (rule norm_triangle_ineq)
   852   finally show ?thesis .
   853 qed
   854 
   855 lemma norm_diff_triangle_le:
   856   fixes x y z :: "'a::real_normed_vector"
   857   assumes "norm (x - y) \<le> e1"  "norm (y - z) \<le> e2"
   858   shows "norm (x - z) \<le> e1 + e2"
   859   using norm_diff_triangle_ineq [of x y y z] assms by simp
   860 
   861 lemma norm_diff_triangle_less:
   862   fixes x y z :: "'a::real_normed_vector"
   863   assumes "norm (x - y) < e1"  "norm (y - z) < e2"
   864   shows "norm (x - z) < e1 + e2"
   865   using norm_diff_triangle_ineq [of x y y z] assms by simp
   866 
   867 lemma norm_triangle_mono:
   868   fixes a b :: "'a::real_normed_vector"
   869   shows "norm a \<le> r \<Longrightarrow> norm b \<le> s \<Longrightarrow> norm (a + b) \<le> r + s"
   870   by (metis add_mono_thms_linordered_semiring(1) norm_triangle_ineq order.trans)
   871 
   872 lemma norm_sum:
   873   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   874   shows "norm (sum f A) \<le> (\<Sum>i\<in>A. norm (f i))"
   875   by (induct A rule: infinite_finite_induct) (auto intro: norm_triangle_mono)
   876 
   877 lemma sum_norm_le:
   878   fixes f :: "'a \<Rightarrow> 'b::real_normed_vector"
   879   assumes fg: "\<And>x. x \<in> S \<Longrightarrow> norm (f x) \<le> g x"
   880   shows "norm (sum f S) \<le> sum g S"
   881   by (rule order_trans [OF norm_sum sum_mono]) (simp add: fg)
   882 
   883 lemma abs_norm_cancel [simp]: "\<bar>norm a\<bar> = norm a"
   884   for a :: "'a::real_normed_vector"
   885   by (rule abs_of_nonneg [OF norm_ge_zero])
   886 
   887 lemma norm_add_less: "norm x < r \<Longrightarrow> norm y < s \<Longrightarrow> norm (x + y) < r + s"
   888   for x y :: "'a::real_normed_vector"
   889   by (rule order_le_less_trans [OF norm_triangle_ineq add_strict_mono])
   890 
   891 lemma norm_mult_less: "norm x < r \<Longrightarrow> norm y < s \<Longrightarrow> norm (x * y) < r * s"
   892   for x y :: "'a::real_normed_algebra"
   893   by (rule order_le_less_trans [OF norm_mult_ineq]) (simp add: mult_strict_mono')
   894 
   895 lemma norm_of_real [simp]: "norm (of_real r :: 'a::real_normed_algebra_1) = \<bar>r\<bar>"
   896   by (simp add: of_real_def)
   897 
   898 lemma norm_numeral [simp]: "norm (numeral w::'a::real_normed_algebra_1) = numeral w"
   899   by (subst of_real_numeral [symmetric], subst norm_of_real, simp)
   900 
   901 lemma norm_neg_numeral [simp]: "norm (- numeral w::'a::real_normed_algebra_1) = numeral w"
   902   by (subst of_real_neg_numeral [symmetric], subst norm_of_real, simp)
   903 
   904 lemma norm_of_real_add1 [simp]: "norm (of_real x + 1 :: 'a :: real_normed_div_algebra) = \<bar>x + 1\<bar>"
   905   by (metis norm_of_real of_real_1 of_real_add)
   906 
   907 lemma norm_of_real_addn [simp]:
   908   "norm (of_real x + numeral b :: 'a :: real_normed_div_algebra) = \<bar>x + numeral b\<bar>"
   909   by (metis norm_of_real of_real_add of_real_numeral)
   910 
   911 lemma norm_of_int [simp]: "norm (of_int z::'a::real_normed_algebra_1) = \<bar>of_int z\<bar>"
   912   by (subst of_real_of_int_eq [symmetric], rule norm_of_real)
   913 
   914 lemma norm_of_nat [simp]: "norm (of_nat n::'a::real_normed_algebra_1) = of_nat n"
   915   apply (subst of_real_of_nat_eq [symmetric])
   916   apply (subst norm_of_real, simp)
   917   done
   918 
   919 lemma nonzero_norm_inverse: "a \<noteq> 0 \<Longrightarrow> norm (inverse a) = inverse (norm a)"
   920   for a :: "'a::real_normed_div_algebra"
   921   apply (rule inverse_unique [symmetric])
   922   apply (simp add: norm_mult [symmetric])
   923   done
   924 
   925 lemma norm_inverse: "norm (inverse a) = inverse (norm a)"
   926   for a :: "'a::{real_normed_div_algebra,division_ring}"
   927   apply (cases "a = 0")
   928    apply simp
   929   apply (erule nonzero_norm_inverse)
   930   done
   931 
   932 lemma nonzero_norm_divide: "b \<noteq> 0 \<Longrightarrow> norm (a / b) = norm a / norm b"
   933   for a b :: "'a::real_normed_field"
   934   by (simp add: divide_inverse norm_mult nonzero_norm_inverse)
   935 
   936 lemma norm_divide: "norm (a / b) = norm a / norm b"
   937   for a b :: "'a::{real_normed_field,field}"
   938   by (simp add: divide_inverse norm_mult norm_inverse)
   939 
   940 lemma norm_power_ineq: "norm (x ^ n) \<le> norm x ^ n"
   941   for x :: "'a::real_normed_algebra_1"
   942 proof (induct n)
   943   case 0
   944   show "norm (x ^ 0) \<le> norm x ^ 0" by simp
   945 next
   946   case (Suc n)
   947   have "norm (x * x ^ n) \<le> norm x * norm (x ^ n)"
   948     by (rule norm_mult_ineq)
   949   also from Suc have "\<dots> \<le> norm x * norm x ^ n"
   950     using norm_ge_zero by (rule mult_left_mono)
   951   finally show "norm (x ^ Suc n) \<le> norm x ^ Suc n"
   952     by simp
   953 qed
   954 
   955 lemma norm_power: "norm (x ^ n) = norm x ^ n"
   956   for x :: "'a::real_normed_div_algebra"
   957   by (induct n) (simp_all add: norm_mult)
   958 
   959 lemma power_eq_imp_eq_norm:
   960   fixes w :: "'a::real_normed_div_algebra"
   961   assumes eq: "w ^ n = z ^ n" and "n > 0"
   962     shows "norm w = norm z"
   963 proof -
   964   have "norm w ^ n = norm z ^ n"
   965     by (metis (no_types) eq norm_power)
   966   then show ?thesis
   967     using assms by (force intro: power_eq_imp_eq_base)
   968 qed
   969 
   970 lemma norm_mult_numeral1 [simp]: "norm (numeral w * a) = numeral w * norm a"
   971   for a b :: "'a::{real_normed_field,field}"
   972   by (simp add: norm_mult)
   973 
   974 lemma norm_mult_numeral2 [simp]: "norm (a * numeral w) = norm a * numeral w"
   975   for a b :: "'a::{real_normed_field,field}"
   976   by (simp add: norm_mult)
   977 
   978 lemma norm_divide_numeral [simp]: "norm (a / numeral w) = norm a / numeral w"
   979   for a b :: "'a::{real_normed_field,field}"
   980   by (simp add: norm_divide)
   981 
   982 lemma norm_of_real_diff [simp]:
   983   "norm (of_real b - of_real a :: 'a::real_normed_algebra_1) \<le> \<bar>b - a\<bar>"
   984   by (metis norm_of_real of_real_diff order_refl)
   985 
   986 text \<open>Despite a superficial resemblance, \<open>norm_eq_1\<close> is not relevant.\<close>
   987 lemma square_norm_one:
   988   fixes x :: "'a::real_normed_div_algebra"
   989   assumes "x\<^sup>2 = 1"
   990   shows "norm x = 1"
   991   by (metis assms norm_minus_cancel norm_one power2_eq_1_iff)
   992 
   993 lemma norm_less_p1: "norm x < norm (of_real (norm x) + 1 :: 'a)"
   994   for x :: "'a::real_normed_algebra_1"
   995 proof -
   996   have "norm x < norm (of_real (norm x + 1) :: 'a)"
   997     by (simp add: of_real_def)
   998   then show ?thesis
   999     by simp
  1000 qed
  1001 
  1002 lemma prod_norm: "prod (\<lambda>x. norm (f x)) A = norm (prod f A)"
  1003   for f :: "'a \<Rightarrow> 'b::{comm_semiring_1,real_normed_div_algebra}"
  1004   by (induct A rule: infinite_finite_induct) (auto simp: norm_mult)
  1005 
  1006 lemma norm_prod_le:
  1007   "norm (prod f A) \<le> (\<Prod>a\<in>A. norm (f a :: 'a :: {real_normed_algebra_1,comm_monoid_mult}))"
  1008 proof (induct A rule: infinite_finite_induct)
  1009   case empty
  1010   then show ?case by simp
  1011 next
  1012   case (insert a A)
  1013   then have "norm (prod f (insert a A)) \<le> norm (f a) * norm (prod f A)"
  1014     by (simp add: norm_mult_ineq)
  1015   also have "norm (prod f A) \<le> (\<Prod>a\<in>A. norm (f a))"
  1016     by (rule insert)
  1017   finally show ?case
  1018     by (simp add: insert mult_left_mono)
  1019 next
  1020   case infinite
  1021   then show ?case by simp
  1022 qed
  1023 
  1024 lemma norm_prod_diff:
  1025   fixes z w :: "'i \<Rightarrow> 'a::{real_normed_algebra_1, comm_monoid_mult}"
  1026   shows "(\<And>i. i \<in> I \<Longrightarrow> norm (z i) \<le> 1) \<Longrightarrow> (\<And>i. i \<in> I \<Longrightarrow> norm (w i) \<le> 1) \<Longrightarrow>
  1027     norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))"
  1028 proof (induction I rule: infinite_finite_induct)
  1029   case empty
  1030   then show ?case by simp
  1031 next
  1032   case (insert i I)
  1033   note insert.hyps[simp]
  1034 
  1035   have "norm ((\<Prod>i\<in>insert i I. z i) - (\<Prod>i\<in>insert i I. w i)) =
  1036     norm ((\<Prod>i\<in>I. z i) * (z i - w i) + ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * w i)"
  1037     (is "_ = norm (?t1 + ?t2)")
  1038     by (auto simp add: field_simps)
  1039   also have "\<dots> \<le> norm ?t1 + norm ?t2"
  1040     by (rule norm_triangle_ineq)
  1041   also have "norm ?t1 \<le> norm (\<Prod>i\<in>I. z i) * norm (z i - w i)"
  1042     by (rule norm_mult_ineq)
  1043   also have "\<dots> \<le> (\<Prod>i\<in>I. norm (z i)) * norm(z i - w i)"
  1044     by (rule mult_right_mono) (auto intro: norm_prod_le)
  1045   also have "(\<Prod>i\<in>I. norm (z i)) \<le> (\<Prod>i\<in>I. 1)"
  1046     by (intro prod_mono) (auto intro!: insert)
  1047   also have "norm ?t2 \<le> norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) * norm (w i)"
  1048     by (rule norm_mult_ineq)
  1049   also have "norm (w i) \<le> 1"
  1050     by (auto intro: insert)
  1051   also have "norm ((\<Prod>i\<in>I. z i) - (\<Prod>i\<in>I. w i)) \<le> (\<Sum>i\<in>I. norm (z i - w i))"
  1052     using insert by auto
  1053   finally show ?case
  1054     by (auto simp add: ac_simps mult_right_mono mult_left_mono)
  1055 next
  1056   case infinite
  1057   then show ?case by simp
  1058 qed
  1059 
  1060 lemma norm_power_diff:
  1061   fixes z w :: "'a::{real_normed_algebra_1, comm_monoid_mult}"
  1062   assumes "norm z \<le> 1" "norm w \<le> 1"
  1063   shows "norm (z^m - w^m) \<le> m * norm (z - w)"
  1064 proof -
  1065   have "norm (z^m - w^m) = norm ((\<Prod> i < m. z) - (\<Prod> i < m. w))"
  1066     by (simp add: prod_constant)
  1067   also have "\<dots> \<le> (\<Sum>i<m. norm (z - w))"
  1068     by (intro norm_prod_diff) (auto simp add: assms)
  1069   also have "\<dots> = m * norm (z - w)"
  1070     by simp
  1071   finally show ?thesis .
  1072 qed
  1073 
  1074 
  1075 subsection \<open>Metric spaces\<close>
  1076 
  1077 class metric_space = uniformity_dist + open_uniformity +
  1078   assumes dist_eq_0_iff [simp]: "dist x y = 0 \<longleftrightarrow> x = y"
  1079     and dist_triangle2: "dist x y \<le> dist x z + dist y z"
  1080 begin
  1081 
  1082 lemma dist_self [simp]: "dist x x = 0"
  1083   by simp
  1084 
  1085 lemma zero_le_dist [simp]: "0 \<le> dist x y"
  1086   using dist_triangle2 [of x x y] by simp
  1087 
  1088 lemma zero_less_dist_iff: "0 < dist x y \<longleftrightarrow> x \<noteq> y"
  1089   by (simp add: less_le)
  1090 
  1091 lemma dist_not_less_zero [simp]: "\<not> dist x y < 0"
  1092   by (simp add: not_less)
  1093 
  1094 lemma dist_le_zero_iff [simp]: "dist x y \<le> 0 \<longleftrightarrow> x = y"
  1095   by (simp add: le_less)
  1096 
  1097 lemma dist_commute: "dist x y = dist y x"
  1098 proof (rule order_antisym)
  1099   show "dist x y \<le> dist y x"
  1100     using dist_triangle2 [of x y x] by simp
  1101   show "dist y x \<le> dist x y"
  1102     using dist_triangle2 [of y x y] by simp
  1103 qed
  1104 
  1105 lemma dist_commute_lessI: "dist y x < e \<Longrightarrow> dist x y < e"
  1106   by (simp add: dist_commute)
  1107 
  1108 lemma dist_triangle: "dist x z \<le> dist x y + dist y z"
  1109   using dist_triangle2 [of x z y] by (simp add: dist_commute)
  1110 
  1111 lemma dist_triangle3: "dist x y \<le> dist a x + dist a y"
  1112   using dist_triangle2 [of x y a] by (simp add: dist_commute)
  1113 
  1114 lemma dist_pos_lt: "x \<noteq> y \<Longrightarrow> 0 < dist x y"
  1115   by (simp add: zero_less_dist_iff)
  1116 
  1117 lemma dist_nz: "x \<noteq> y \<longleftrightarrow> 0 < dist x y"
  1118   by (simp add: zero_less_dist_iff)
  1119 
  1120 declare dist_nz [symmetric, simp]
  1121 
  1122 lemma dist_triangle_le: "dist x z + dist y z \<le> e \<Longrightarrow> dist x y \<le> e"
  1123   by (rule order_trans [OF dist_triangle2])
  1124 
  1125 lemma dist_triangle_lt: "dist x z + dist y z < e \<Longrightarrow> dist x y < e"
  1126   by (rule le_less_trans [OF dist_triangle2])
  1127 
  1128 lemma dist_triangle_less_add: "dist x1 y < e1 \<Longrightarrow> dist x2 y < e2 \<Longrightarrow> dist x1 x2 < e1 + e2"
  1129   by (rule dist_triangle_lt [where z=y]) simp
  1130 
  1131 lemma dist_triangle_half_l: "dist x1 y < e / 2 \<Longrightarrow> dist x2 y < e / 2 \<Longrightarrow> dist x1 x2 < e"
  1132   by (rule dist_triangle_lt [where z=y]) simp
  1133 
  1134 lemma dist_triangle_half_r: "dist y x1 < e / 2 \<Longrightarrow> dist y x2 < e / 2 \<Longrightarrow> dist x1 x2 < e"
  1135   by (rule dist_triangle_half_l) (simp_all add: dist_commute)
  1136 
  1137 lemma dist_triangle_third:
  1138   assumes "dist x1 x2 < e/3" "dist x2 x3 < e/3" "dist x3 x4 < e/3"
  1139   shows "dist x1 x4 < e"
  1140 proof -
  1141   have "dist x1 x3 < e/3 + e/3"
  1142     by (metis assms(1) assms(2) dist_commute dist_triangle_less_add)
  1143   then have "dist x1 x4 < (e/3 + e/3) + e/3"
  1144     by (metis assms(3) dist_commute dist_triangle_less_add)
  1145   then show ?thesis
  1146     by simp
  1147 qed
  1148 
  1149 subclass uniform_space
  1150 proof
  1151   fix E x
  1152   assume "eventually E uniformity"
  1153   then obtain e where E: "0 < e" "\<And>x y. dist x y < e \<Longrightarrow> E (x, y)"
  1154     by (auto simp: eventually_uniformity_metric)
  1155   then show "E (x, x)" "\<forall>\<^sub>F (x, y) in uniformity. E (y, x)"
  1156     by (auto simp: eventually_uniformity_metric dist_commute)
  1157   show "\<exists>D. eventually D uniformity \<and> (\<forall>x y z. D (x, y) \<longrightarrow> D (y, z) \<longrightarrow> E (x, z))"
  1158     using E dist_triangle_half_l[where e=e]
  1159     unfolding eventually_uniformity_metric
  1160     by (intro exI[of _ "\<lambda>(x, y). dist x y < e / 2"] exI[of _ "e/2"] conjI)
  1161       (auto simp: dist_commute)
  1162 qed
  1163 
  1164 lemma open_dist: "open S \<longleftrightarrow> (\<forall>x\<in>S. \<exists>e>0. \<forall>y. dist y x < e \<longrightarrow> y \<in> S)"
  1165   by (simp add: dist_commute open_uniformity eventually_uniformity_metric)
  1166 
  1167 lemma open_ball: "open {y. dist x y < d}"
  1168   unfolding open_dist
  1169 proof (intro ballI)
  1170   fix y
  1171   assume *: "y \<in> {y. dist x y < d}"
  1172   then show "\<exists>e>0. \<forall>z. dist z y < e \<longrightarrow> z \<in> {y. dist x y < d}"
  1173     by (auto intro!: exI[of _ "d - dist x y"] simp: field_simps dist_triangle_lt)
  1174 qed
  1175 
  1176 subclass first_countable_topology
  1177 proof
  1178   fix x
  1179   show "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1180   proof (safe intro!: exI[of _ "\<lambda>n. {y. dist x y < inverse (Suc n)}"])
  1181     fix S
  1182     assume "open S" "x \<in> S"
  1183     then obtain e where e: "0 < e" and "{y. dist x y < e} \<subseteq> S"
  1184       by (auto simp: open_dist subset_eq dist_commute)
  1185     moreover
  1186     from e obtain i where "inverse (Suc i) < e"
  1187       by (auto dest!: reals_Archimedean)
  1188     then have "{y. dist x y < inverse (Suc i)} \<subseteq> {y. dist x y < e}"
  1189       by auto
  1190     ultimately show "\<exists>i. {y. dist x y < inverse (Suc i)} \<subseteq> S"
  1191       by blast
  1192   qed (auto intro: open_ball)
  1193 qed
  1194 
  1195 end
  1196 
  1197 instance metric_space \<subseteq> t2_space
  1198 proof
  1199   fix x y :: "'a::metric_space"
  1200   assume xy: "x \<noteq> y"
  1201   let ?U = "{y'. dist x y' < dist x y / 2}"
  1202   let ?V = "{x'. dist y x' < dist x y / 2}"
  1203   have *: "d x z \<le> d x y + d y z \<Longrightarrow> d y z = d z y \<Longrightarrow> \<not> (d x y * 2 < d x z \<and> d z y * 2 < d x z)"
  1204     for d :: "'a \<Rightarrow> 'a \<Rightarrow> real" and x y z :: 'a
  1205     by arith
  1206   have "open ?U \<and> open ?V \<and> x \<in> ?U \<and> y \<in> ?V \<and> ?U \<inter> ?V = {}"
  1207     using dist_pos_lt[OF xy] *[of dist, OF dist_triangle dist_commute]
  1208     using open_ball[of _ "dist x y / 2"] by auto
  1209   then show "\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
  1210     by blast
  1211 qed
  1212 
  1213 text \<open>Every normed vector space is a metric space.\<close>
  1214 instance real_normed_vector < metric_space
  1215 proof
  1216   fix x y z :: 'a
  1217   show "dist x y = 0 \<longleftrightarrow> x = y"
  1218     by (simp add: dist_norm)
  1219   show "dist x y \<le> dist x z + dist y z"
  1220     using norm_triangle_ineq4 [of "x - z" "y - z"] by (simp add: dist_norm)
  1221 qed
  1222 
  1223 
  1224 subsection \<open>Class instances for real numbers\<close>
  1225 
  1226 instantiation real :: real_normed_field
  1227 begin
  1228 
  1229 definition dist_real_def: "dist x y = \<bar>x - y\<bar>"
  1230 
  1231 definition uniformity_real_def [code del]:
  1232   "(uniformity :: (real \<times> real) filter) = (INF e:{0 <..}. principal {(x, y). dist x y < e})"
  1233 
  1234 definition open_real_def [code del]:
  1235   "open (U :: real set) \<longleftrightarrow> (\<forall>x\<in>U. eventually (\<lambda>(x', y). x' = x \<longrightarrow> y \<in> U) uniformity)"
  1236 
  1237 definition real_norm_def [simp]: "norm r = \<bar>r\<bar>"
  1238 
  1239 instance
  1240   apply intro_classes
  1241          apply (unfold real_norm_def real_scaleR_def)
  1242          apply (rule dist_real_def)
  1243         apply (simp add: sgn_real_def)
  1244        apply (rule uniformity_real_def)
  1245       apply (rule open_real_def)
  1246      apply (rule abs_eq_0)
  1247     apply (rule abs_triangle_ineq)
  1248    apply (rule abs_mult)
  1249   apply (rule abs_mult)
  1250   done
  1251 
  1252 end
  1253 
  1254 declare uniformity_Abort[where 'a=real, code]
  1255 
  1256 lemma dist_of_real [simp]: "dist (of_real x :: 'a) (of_real y) = dist x y"
  1257   for a :: "'a::real_normed_div_algebra"
  1258   by (metis dist_norm norm_of_real of_real_diff real_norm_def)
  1259 
  1260 declare [[code abort: "open :: real set \<Rightarrow> bool"]]
  1261 
  1262 instance real :: linorder_topology
  1263 proof
  1264   show "(open :: real set \<Rightarrow> bool) = generate_topology (range lessThan \<union> range greaterThan)"
  1265   proof (rule ext, safe)
  1266     fix S :: "real set"
  1267     assume "open S"
  1268     then obtain f where "\<forall>x\<in>S. 0 < f x \<and> (\<forall>y. dist y x < f x \<longrightarrow> y \<in> S)"
  1269       unfolding open_dist bchoice_iff ..
  1270     then have *: "S = (\<Union>x\<in>S. {x - f x <..} \<inter> {..< x + f x})"
  1271       by (fastforce simp: dist_real_def)
  1272     show "generate_topology (range lessThan \<union> range greaterThan) S"
  1273       apply (subst *)
  1274       apply (intro generate_topology_Union generate_topology.Int)
  1275        apply (auto intro: generate_topology.Basis)
  1276       done
  1277   next
  1278     fix S :: "real set"
  1279     assume "generate_topology (range lessThan \<union> range greaterThan) S"
  1280     moreover have "\<And>a::real. open {..<a}"
  1281       unfolding open_dist dist_real_def
  1282     proof clarify
  1283       fix x a :: real
  1284       assume "x < a"
  1285       then have "0 < a - x \<and> (\<forall>y. \<bar>y - x\<bar> < a - x \<longrightarrow> y \<in> {..<a})" by auto
  1286       then show "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {..<a}" ..
  1287     qed
  1288     moreover have "\<And>a::real. open {a <..}"
  1289       unfolding open_dist dist_real_def
  1290     proof clarify
  1291       fix x a :: real
  1292       assume "a < x"
  1293       then have "0 < x - a \<and> (\<forall>y. \<bar>y - x\<bar> < x - a \<longrightarrow> y \<in> {a<..})" by auto
  1294       then show "\<exists>e>0. \<forall>y. \<bar>y - x\<bar> < e \<longrightarrow> y \<in> {a<..}" ..
  1295     qed
  1296     ultimately show "open S"
  1297       by induct auto
  1298   qed
  1299 qed
  1300 
  1301 instance real :: linear_continuum_topology ..
  1302 
  1303 lemmas open_real_greaterThan = open_greaterThan[where 'a=real]
  1304 lemmas open_real_lessThan = open_lessThan[where 'a=real]
  1305 lemmas open_real_greaterThanLessThan = open_greaterThanLessThan[where 'a=real]
  1306 lemmas closed_real_atMost = closed_atMost[where 'a=real]
  1307 lemmas closed_real_atLeast = closed_atLeast[where 'a=real]
  1308 lemmas closed_real_atLeastAtMost = closed_atLeastAtMost[where 'a=real]
  1309 
  1310 
  1311 subsection \<open>Extra type constraints\<close>
  1312 
  1313 text \<open>Only allow @{term "open"} in class \<open>topological_space\<close>.\<close>
  1314 setup \<open>Sign.add_const_constraint
  1315   (@{const_name "open"}, SOME @{typ "'a::topological_space set \<Rightarrow> bool"})\<close>
  1316 
  1317 text \<open>Only allow @{term "uniformity"} in class \<open>uniform_space\<close>.\<close>
  1318 setup \<open>Sign.add_const_constraint
  1319   (@{const_name "uniformity"}, SOME @{typ "('a::uniformity \<times> 'a) filter"})\<close>
  1320 
  1321 text \<open>Only allow @{term dist} in class \<open>metric_space\<close>.\<close>
  1322 setup \<open>Sign.add_const_constraint
  1323   (@{const_name dist}, SOME @{typ "'a::metric_space \<Rightarrow> 'a \<Rightarrow> real"})\<close>
  1324 
  1325 text \<open>Only allow @{term norm} in class \<open>real_normed_vector\<close>.\<close>
  1326 setup \<open>Sign.add_const_constraint
  1327   (@{const_name norm}, SOME @{typ "'a::real_normed_vector \<Rightarrow> real"})\<close>
  1328 
  1329 
  1330 subsection \<open>Sign function\<close>
  1331 
  1332 lemma norm_sgn: "norm (sgn x) = (if x = 0 then 0 else 1)"
  1333   for x :: "'a::real_normed_vector"
  1334   by (simp add: sgn_div_norm)
  1335 
  1336 lemma sgn_zero [simp]: "sgn (0::'a::real_normed_vector) = 0"
  1337   by (simp add: sgn_div_norm)
  1338 
  1339 lemma sgn_zero_iff: "sgn x = 0 \<longleftrightarrow> x = 0"
  1340   for x :: "'a::real_normed_vector"
  1341   by (simp add: sgn_div_norm)
  1342 
  1343 lemma sgn_minus: "sgn (- x) = - sgn x"
  1344   for x :: "'a::real_normed_vector"
  1345   by (simp add: sgn_div_norm)
  1346 
  1347 lemma sgn_scaleR: "sgn (scaleR r x) = scaleR (sgn r) (sgn x)"
  1348   for x :: "'a::real_normed_vector"
  1349   by (simp add: sgn_div_norm ac_simps)
  1350 
  1351 lemma sgn_one [simp]: "sgn (1::'a::real_normed_algebra_1) = 1"
  1352   by (simp add: sgn_div_norm)
  1353 
  1354 lemma sgn_of_real: "sgn (of_real r :: 'a::real_normed_algebra_1) = of_real (sgn r)"
  1355   unfolding of_real_def by (simp only: sgn_scaleR sgn_one)
  1356 
  1357 lemma sgn_mult: "sgn (x * y) = sgn x * sgn y"
  1358   for x y :: "'a::real_normed_div_algebra"
  1359   by (simp add: sgn_div_norm norm_mult mult.commute)
  1360 
  1361 hide_fact (open) sgn_mult
  1362 
  1363 lemma real_sgn_eq: "sgn x = x / \<bar>x\<bar>"
  1364   for x :: real
  1365   by (simp add: sgn_div_norm divide_inverse)
  1366 
  1367 lemma zero_le_sgn_iff [simp]: "0 \<le> sgn x \<longleftrightarrow> 0 \<le> x"
  1368   for x :: real
  1369   by (cases "0::real" x rule: linorder_cases) simp_all
  1370 
  1371 lemma sgn_le_0_iff [simp]: "sgn x \<le> 0 \<longleftrightarrow> x \<le> 0"
  1372   for x :: real
  1373   by (cases "0::real" x rule: linorder_cases) simp_all
  1374 
  1375 lemma norm_conv_dist: "norm x = dist x 0"
  1376   unfolding dist_norm by simp
  1377 
  1378 declare norm_conv_dist [symmetric, simp]
  1379 
  1380 lemma dist_0_norm [simp]: "dist 0 x = norm x"
  1381   for x :: "'a::real_normed_vector"
  1382   by (simp add: dist_norm)
  1383 
  1384 lemma dist_diff [simp]: "dist a (a - b) = norm b"  "dist (a - b) a = norm b"
  1385   by (simp_all add: dist_norm)
  1386 
  1387 lemma dist_of_int: "dist (of_int m) (of_int n :: 'a :: real_normed_algebra_1) = of_int \<bar>m - n\<bar>"
  1388 proof -
  1389   have "dist (of_int m) (of_int n :: 'a) = dist (of_int m :: 'a) (of_int m - (of_int (m - n)))"
  1390     by simp
  1391   also have "\<dots> = of_int \<bar>m - n\<bar>" by (subst dist_diff, subst norm_of_int) simp
  1392   finally show ?thesis .
  1393 qed
  1394 
  1395 lemma dist_of_nat:
  1396   "dist (of_nat m) (of_nat n :: 'a :: real_normed_algebra_1) = of_int \<bar>int m - int n\<bar>"
  1397   by (subst (1 2) of_int_of_nat_eq [symmetric]) (rule dist_of_int)
  1398 
  1399 
  1400 subsection \<open>Bounded Linear and Bilinear Operators\<close>
  1401 
  1402 locale linear = additive f for f :: "'a::real_vector \<Rightarrow> 'b::real_vector" +
  1403   assumes scaleR: "f (scaleR r x) = scaleR r (f x)"
  1404 
  1405 lemma linear_imp_scaleR:
  1406   assumes "linear D"
  1407   obtains d where "D = (\<lambda>x. x *\<^sub>R d)"
  1408   by (metis assms linear.scaleR mult.commute mult.left_neutral real_scaleR_def)
  1409 
  1410 corollary real_linearD:
  1411   fixes f :: "real \<Rightarrow> real"
  1412   assumes "linear f" obtains c where "f = op* c"
  1413   by (rule linear_imp_scaleR [OF assms]) (force simp: scaleR_conv_of_real)
  1414 
  1415 lemma linear_times_of_real: "linear (\<lambda>x. a * of_real x)"
  1416   apply (simp add: linear_def Real_Vector_Spaces.additive_def linear_axioms_def)
  1417   by (metis distrib_left mult_scaleR_right scaleR_conv_of_real)
  1418 
  1419 lemma linearI:
  1420   assumes "\<And>x y. f (x + y) = f x + f y"
  1421     and "\<And>c x. f (c *\<^sub>R x) = c *\<^sub>R f x"
  1422   shows "linear f"
  1423   by standard (rule assms)+
  1424 
  1425 locale bounded_linear = linear f for f :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector" +
  1426   assumes bounded: "\<exists>K. \<forall>x. norm (f x) \<le> norm x * K"
  1427 begin
  1428 
  1429 lemma pos_bounded: "\<exists>K>0. \<forall>x. norm (f x) \<le> norm x * K"
  1430 proof -
  1431   obtain K where K: "\<And>x. norm (f x) \<le> norm x * K"
  1432     using bounded by blast
  1433   show ?thesis
  1434   proof (intro exI impI conjI allI)
  1435     show "0 < max 1 K"
  1436       by (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1437   next
  1438     fix x
  1439     have "norm (f x) \<le> norm x * K" using K .
  1440     also have "\<dots> \<le> norm x * max 1 K"
  1441       by (rule mult_left_mono [OF max.cobounded2 norm_ge_zero])
  1442     finally show "norm (f x) \<le> norm x * max 1 K" .
  1443   qed
  1444 qed
  1445 
  1446 lemma nonneg_bounded: "\<exists>K\<ge>0. \<forall>x. norm (f x) \<le> norm x * K"
  1447   using pos_bounded by (auto intro: order_less_imp_le)
  1448 
  1449 lemma linear: "linear f"
  1450   by (fact local.linear_axioms)
  1451 
  1452 end
  1453 
  1454 lemma bounded_linear_intro:
  1455   assumes "\<And>x y. f (x + y) = f x + f y"
  1456     and "\<And>r x. f (scaleR r x) = scaleR r (f x)"
  1457     and "\<And>x. norm (f x) \<le> norm x * K"
  1458   shows "bounded_linear f"
  1459   by standard (blast intro: assms)+
  1460 
  1461 locale bounded_bilinear =
  1462   fixes prod :: "'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector \<Rightarrow> 'c::real_normed_vector"
  1463     (infixl "**" 70)
  1464   assumes add_left: "prod (a + a') b = prod a b + prod a' b"
  1465     and add_right: "prod a (b + b') = prod a b + prod a b'"
  1466     and scaleR_left: "prod (scaleR r a) b = scaleR r (prod a b)"
  1467     and scaleR_right: "prod a (scaleR r b) = scaleR r (prod a b)"
  1468     and bounded: "\<exists>K. \<forall>a b. norm (prod a b) \<le> norm a * norm b * K"
  1469 begin
  1470 
  1471 lemma pos_bounded: "\<exists>K>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1472   apply (insert bounded)
  1473   apply (erule exE)
  1474   apply (rule_tac x="max 1 K" in exI)
  1475   apply safe
  1476    apply (rule order_less_le_trans [OF zero_less_one max.cobounded1])
  1477   apply (drule spec)
  1478   apply (drule spec)
  1479   apply (erule order_trans)
  1480   apply (rule mult_left_mono [OF max.cobounded2])
  1481   apply (intro mult_nonneg_nonneg norm_ge_zero)
  1482   done
  1483 
  1484 lemma nonneg_bounded: "\<exists>K\<ge>0. \<forall>a b. norm (a ** b) \<le> norm a * norm b * K"
  1485   using pos_bounded by (auto intro: order_less_imp_le)
  1486 
  1487 lemma additive_right: "additive (\<lambda>b. prod a b)"
  1488   by (rule additive.intro, rule add_right)
  1489 
  1490 lemma additive_left: "additive (\<lambda>a. prod a b)"
  1491   by (rule additive.intro, rule add_left)
  1492 
  1493 lemma zero_left: "prod 0 b = 0"
  1494   by (rule additive.zero [OF additive_left])
  1495 
  1496 lemma zero_right: "prod a 0 = 0"
  1497   by (rule additive.zero [OF additive_right])
  1498 
  1499 lemma minus_left: "prod (- a) b = - prod a b"
  1500   by (rule additive.minus [OF additive_left])
  1501 
  1502 lemma minus_right: "prod a (- b) = - prod a b"
  1503   by (rule additive.minus [OF additive_right])
  1504 
  1505 lemma diff_left: "prod (a - a') b = prod a b - prod a' b"
  1506   by (rule additive.diff [OF additive_left])
  1507 
  1508 lemma diff_right: "prod a (b - b') = prod a b - prod a b'"
  1509   by (rule additive.diff [OF additive_right])
  1510 
  1511 lemma sum_left: "prod (sum g S) x = sum ((\<lambda>i. prod (g i) x)) S"
  1512   by (rule additive.sum [OF additive_left])
  1513 
  1514 lemma sum_right: "prod x (sum g S) = sum ((\<lambda>i. (prod x (g i)))) S"
  1515   by (rule additive.sum [OF additive_right])
  1516 
  1517 
  1518 lemma bounded_linear_left: "bounded_linear (\<lambda>a. a ** b)"
  1519   apply (insert bounded)
  1520   apply safe
  1521   apply (rule_tac K="norm b * K" in bounded_linear_intro)
  1522     apply (rule add_left)
  1523    apply (rule scaleR_left)
  1524   apply (simp add: ac_simps)
  1525   done
  1526 
  1527 lemma bounded_linear_right: "bounded_linear (\<lambda>b. a ** b)"
  1528   apply (insert bounded)
  1529   apply safe
  1530   apply (rule_tac K="norm a * K" in bounded_linear_intro)
  1531     apply (rule add_right)
  1532    apply (rule scaleR_right)
  1533   apply (simp add: ac_simps)
  1534   done
  1535 
  1536 lemma prod_diff_prod: "(x ** y - a ** b) = (x - a) ** (y - b) + (x - a) ** b + a ** (y - b)"
  1537   by (simp add: diff_left diff_right)
  1538 
  1539 lemma flip: "bounded_bilinear (\<lambda>x y. y ** x)"
  1540   apply standard
  1541       apply (rule add_right)
  1542      apply (rule add_left)
  1543     apply (rule scaleR_right)
  1544    apply (rule scaleR_left)
  1545   apply (subst mult.commute)
  1546   apply (insert bounded)
  1547   apply blast
  1548   done
  1549 
  1550 lemma comp1:
  1551   assumes "bounded_linear g"
  1552   shows "bounded_bilinear (\<lambda>x. op ** (g x))"
  1553 proof unfold_locales
  1554   interpret g: bounded_linear g by fact
  1555   show "\<And>a a' b. g (a + a') ** b = g a ** b + g a' ** b"
  1556     "\<And>a b b'. g a ** (b + b') = g a ** b + g a ** b'"
  1557     "\<And>r a b. g (r *\<^sub>R a) ** b = r *\<^sub>R (g a ** b)"
  1558     "\<And>a r b. g a ** (r *\<^sub>R b) = r *\<^sub>R (g a ** b)"
  1559     by (auto simp: g.add add_left add_right g.scaleR scaleR_left scaleR_right)
  1560   from g.nonneg_bounded nonneg_bounded obtain K L
  1561     where nn: "0 \<le> K" "0 \<le> L"
  1562       and K: "\<And>x. norm (g x) \<le> norm x * K"
  1563       and L: "\<And>a b. norm (a ** b) \<le> norm a * norm b * L"
  1564     by auto
  1565   have "norm (g a ** b) \<le> norm a * K * norm b * L" for a b
  1566     by (auto intro!:  order_trans[OF K] order_trans[OF L] mult_mono simp: nn)
  1567   then show "\<exists>K. \<forall>a b. norm (g a ** b) \<le> norm a * norm b * K"
  1568     by (auto intro!: exI[where x="K * L"] simp: ac_simps)
  1569 qed
  1570 
  1571 lemma comp: "bounded_linear f \<Longrightarrow> bounded_linear g \<Longrightarrow> bounded_bilinear (\<lambda>x y. f x ** g y)"
  1572   by (rule bounded_bilinear.flip[OF bounded_bilinear.comp1[OF bounded_bilinear.flip[OF comp1]]])
  1573 
  1574 end
  1575 
  1576 lemma bounded_linear_ident[simp]: "bounded_linear (\<lambda>x. x)"
  1577   by standard (auto intro!: exI[of _ 1])
  1578 
  1579 lemma bounded_linear_zero[simp]: "bounded_linear (\<lambda>x. 0)"
  1580   by standard (auto intro!: exI[of _ 1])
  1581 
  1582 lemma bounded_linear_add:
  1583   assumes "bounded_linear f"
  1584     and "bounded_linear g"
  1585   shows "bounded_linear (\<lambda>x. f x + g x)"
  1586 proof -
  1587   interpret f: bounded_linear f by fact
  1588   interpret g: bounded_linear g by fact
  1589   show ?thesis
  1590   proof
  1591     from f.bounded obtain Kf where Kf: "norm (f x) \<le> norm x * Kf" for x
  1592       by blast
  1593     from g.bounded obtain Kg where Kg: "norm (g x) \<le> norm x * Kg" for x
  1594       by blast
  1595     show "\<exists>K. \<forall>x. norm (f x + g x) \<le> norm x * K"
  1596       using add_mono[OF Kf Kg]
  1597       by (intro exI[of _ "Kf + Kg"]) (auto simp: field_simps intro: norm_triangle_ineq order_trans)
  1598   qed (simp_all add: f.add g.add f.scaleR g.scaleR scaleR_right_distrib)
  1599 qed
  1600 
  1601 lemma bounded_linear_minus:
  1602   assumes "bounded_linear f"
  1603   shows "bounded_linear (\<lambda>x. - f x)"
  1604 proof -
  1605   interpret f: bounded_linear f by fact
  1606   show ?thesis
  1607     apply unfold_locales
  1608       apply (simp add: f.add)
  1609      apply (simp add: f.scaleR)
  1610     apply (simp add: f.bounded)
  1611     done
  1612 qed
  1613 
  1614 lemma bounded_linear_sub: "bounded_linear f \<Longrightarrow> bounded_linear g \<Longrightarrow> bounded_linear (\<lambda>x. f x - g x)"
  1615   using bounded_linear_add[of f "\<lambda>x. - g x"] bounded_linear_minus[of g]
  1616   by (auto simp add: algebra_simps)
  1617 
  1618 lemma bounded_linear_sum:
  1619   fixes f :: "'i \<Rightarrow> 'a::real_normed_vector \<Rightarrow> 'b::real_normed_vector"
  1620   shows "(\<And>i. i \<in> I \<Longrightarrow> bounded_linear (f i)) \<Longrightarrow> bounded_linear (\<lambda>x. \<Sum>i\<in>I. f i x)"
  1621   by (induct I rule: infinite_finite_induct) (auto intro!: bounded_linear_add)
  1622 
  1623 lemma bounded_linear_compose:
  1624   assumes "bounded_linear f"
  1625     and "bounded_linear g"
  1626   shows "bounded_linear (\<lambda>x. f (g x))"
  1627 proof -
  1628   interpret f: bounded_linear f by fact
  1629   interpret g: bounded_linear g by fact
  1630   show ?thesis
  1631   proof unfold_locales
  1632     show "f (g (x + y)) = f (g x) + f (g y)" for x y
  1633       by (simp only: f.add g.add)
  1634     show "f (g (scaleR r x)) = scaleR r (f (g x))" for r x
  1635       by (simp only: f.scaleR g.scaleR)
  1636     from f.pos_bounded obtain Kf where f: "\<And>x. norm (f x) \<le> norm x * Kf" and Kf: "0 < Kf"
  1637       by blast
  1638     from g.pos_bounded obtain Kg where g: "\<And>x. norm (g x) \<le> norm x * Kg"
  1639       by blast
  1640     show "\<exists>K. \<forall>x. norm (f (g x)) \<le> norm x * K"
  1641     proof (intro exI allI)
  1642       fix x
  1643       have "norm (f (g x)) \<le> norm (g x) * Kf"
  1644         using f .
  1645       also have "\<dots> \<le> (norm x * Kg) * Kf"
  1646         using g Kf [THEN order_less_imp_le] by (rule mult_right_mono)
  1647       also have "(norm x * Kg) * Kf = norm x * (Kg * Kf)"
  1648         by (rule mult.assoc)
  1649       finally show "norm (f (g x)) \<le> norm x * (Kg * Kf)" .
  1650     qed
  1651   qed
  1652 qed
  1653 
  1654 lemma bounded_bilinear_mult: "bounded_bilinear (op * :: 'a \<Rightarrow> 'a \<Rightarrow> 'a::real_normed_algebra)"
  1655   apply (rule bounded_bilinear.intro)
  1656       apply (rule distrib_right)
  1657      apply (rule distrib_left)
  1658     apply (rule mult_scaleR_left)
  1659    apply (rule mult_scaleR_right)
  1660   apply (rule_tac x="1" in exI)
  1661   apply (simp add: norm_mult_ineq)
  1662   done
  1663 
  1664 lemma bounded_linear_mult_left: "bounded_linear (\<lambda>x::'a::real_normed_algebra. x * y)"
  1665   using bounded_bilinear_mult
  1666   by (rule bounded_bilinear.bounded_linear_left)
  1667 
  1668 lemma bounded_linear_mult_right: "bounded_linear (\<lambda>y::'a::real_normed_algebra. x * y)"
  1669   using bounded_bilinear_mult
  1670   by (rule bounded_bilinear.bounded_linear_right)
  1671 
  1672 lemmas bounded_linear_mult_const =
  1673   bounded_linear_mult_left [THEN bounded_linear_compose]
  1674 
  1675 lemmas bounded_linear_const_mult =
  1676   bounded_linear_mult_right [THEN bounded_linear_compose]
  1677 
  1678 lemma bounded_linear_divide: "bounded_linear (\<lambda>x. x / y)"
  1679   for y :: "'a::real_normed_field"
  1680   unfolding divide_inverse by (rule bounded_linear_mult_left)
  1681 
  1682 lemma bounded_bilinear_scaleR: "bounded_bilinear scaleR"
  1683   apply (rule bounded_bilinear.intro)
  1684       apply (rule scaleR_left_distrib)
  1685      apply (rule scaleR_right_distrib)
  1686     apply simp
  1687    apply (rule scaleR_left_commute)
  1688   apply (rule_tac x="1" in exI)
  1689   apply simp
  1690   done
  1691 
  1692 lemma bounded_linear_scaleR_left: "bounded_linear (\<lambda>r. scaleR r x)"
  1693   using bounded_bilinear_scaleR
  1694   by (rule bounded_bilinear.bounded_linear_left)
  1695 
  1696 lemma bounded_linear_scaleR_right: "bounded_linear (\<lambda>x. scaleR r x)"
  1697   using bounded_bilinear_scaleR
  1698   by (rule bounded_bilinear.bounded_linear_right)
  1699 
  1700 lemmas bounded_linear_scaleR_const =
  1701   bounded_linear_scaleR_left[THEN bounded_linear_compose]
  1702 
  1703 lemmas bounded_linear_const_scaleR =
  1704   bounded_linear_scaleR_right[THEN bounded_linear_compose]
  1705 
  1706 lemma bounded_linear_of_real: "bounded_linear (\<lambda>r. of_real r)"
  1707   unfolding of_real_def by (rule bounded_linear_scaleR_left)
  1708 
  1709 lemma real_bounded_linear: "bounded_linear f \<longleftrightarrow> (\<exists>c::real. f = (\<lambda>x. x * c))"
  1710   for f :: "real \<Rightarrow> real"
  1711 proof -
  1712   {
  1713     fix x
  1714     assume "bounded_linear f"
  1715     then interpret bounded_linear f .
  1716     from scaleR[of x 1] have "f x = x * f 1"
  1717       by simp
  1718   }
  1719   then show ?thesis
  1720     by (auto intro: exI[of _ "f 1"] bounded_linear_mult_left)
  1721 qed
  1722 
  1723 lemma bij_linear_imp_inv_linear: "linear f \<Longrightarrow> bij f \<Longrightarrow> linear (inv f)"
  1724   by (auto simp: linear_def linear_axioms_def additive_def bij_is_surj bij_is_inj surj_f_inv_f
  1725       intro!:  Hilbert_Choice.inv_f_eq)
  1726 
  1727 instance real_normed_algebra_1 \<subseteq> perfect_space
  1728 proof
  1729   show "\<not> open {x}" for x :: 'a
  1730     apply (simp only: open_dist dist_norm)
  1731     apply clarsimp
  1732     apply (rule_tac x = "x + of_real (e/2)" in exI)
  1733     apply simp
  1734     done
  1735 qed
  1736 
  1737 
  1738 subsection \<open>Filters and Limits on Metric Space\<close>
  1739 
  1740 lemma (in metric_space) nhds_metric: "nhds x = (INF e:{0 <..}. principal {y. dist y x < e})"
  1741   unfolding nhds_def
  1742 proof (safe intro!: INF_eq)
  1743   fix S
  1744   assume "open S" "x \<in> S"
  1745   then obtain e where "{y. dist y x < e} \<subseteq> S" "0 < e"
  1746     by (auto simp: open_dist subset_eq)
  1747   then show "\<exists>e\<in>{0<..}. principal {y. dist y x < e} \<le> principal S"
  1748     by auto
  1749 qed (auto intro!: exI[of _ "{y. dist x y < e}" for e] open_ball simp: dist_commute)
  1750 
  1751 lemma (in metric_space) tendsto_iff: "(f \<longlongrightarrow> l) F \<longleftrightarrow> (\<forall>e>0. eventually (\<lambda>x. dist (f x) l < e) F)"
  1752   unfolding nhds_metric filterlim_INF filterlim_principal by auto
  1753 
  1754 lemma (in metric_space) tendstoI [intro?]:
  1755   "(\<And>e. 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F) \<Longrightarrow> (f \<longlongrightarrow> l) F"
  1756   by (auto simp: tendsto_iff)
  1757 
  1758 lemma (in metric_space) tendstoD: "(f \<longlongrightarrow> l) F \<Longrightarrow> 0 < e \<Longrightarrow> eventually (\<lambda>x. dist (f x) l < e) F"
  1759   by (auto simp: tendsto_iff)
  1760 
  1761 lemma (in metric_space) eventually_nhds_metric:
  1762   "eventually P (nhds a) \<longleftrightarrow> (\<exists>d>0. \<forall>x. dist x a < d \<longrightarrow> P x)"
  1763   unfolding nhds_metric
  1764   by (subst eventually_INF_base)
  1765      (auto simp: eventually_principal Bex_def subset_eq intro: exI[of _ "min a b" for a b])
  1766 
  1767 lemma eventually_at: "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a < d \<longrightarrow> P x)"
  1768   for a :: "'a :: metric_space"
  1769   by (auto simp: eventually_at_filter eventually_nhds_metric)
  1770 
  1771 lemma eventually_at_le: "eventually P (at a within S) \<longleftrightarrow> (\<exists>d>0. \<forall>x\<in>S. x \<noteq> a \<and> dist x a \<le> d \<longrightarrow> P x)"
  1772   for a :: "'a::metric_space"
  1773   apply (simp only: eventually_at_filter eventually_nhds_metric)
  1774   apply auto
  1775   apply (rule_tac x="d / 2" in exI)
  1776   apply auto
  1777   done
  1778 
  1779 lemma eventually_at_left_real: "a > (b :: real) \<Longrightarrow> eventually (\<lambda>x. x \<in> {b<..<a}) (at_left a)"
  1780   by (subst eventually_at, rule exI[of _ "a - b"]) (force simp: dist_real_def)
  1781 
  1782 lemma eventually_at_right_real: "a < (b :: real) \<Longrightarrow> eventually (\<lambda>x. x \<in> {a<..<b}) (at_right a)"
  1783   by (subst eventually_at, rule exI[of _ "b - a"]) (force simp: dist_real_def)
  1784 
  1785 lemma metric_tendsto_imp_tendsto:
  1786   fixes a :: "'a :: metric_space"
  1787     and b :: "'b :: metric_space"
  1788   assumes f: "(f \<longlongrightarrow> a) F"
  1789     and le: "eventually (\<lambda>x. dist (g x) b \<le> dist (f x) a) F"
  1790   shows "(g \<longlongrightarrow> b) F"
  1791 proof (rule tendstoI)
  1792   fix e :: real
  1793   assume "0 < e"
  1794   with f have "eventually (\<lambda>x. dist (f x) a < e) F" by (rule tendstoD)
  1795   with le show "eventually (\<lambda>x. dist (g x) b < e) F"
  1796     using le_less_trans by (rule eventually_elim2)
  1797 qed
  1798 
  1799 lemma filterlim_real_sequentially: "LIM x sequentially. real x :> at_top"
  1800   apply (simp only: filterlim_at_top)
  1801   apply (intro allI)
  1802   apply (rule_tac c="nat \<lceil>Z + 1\<rceil>" in eventually_sequentiallyI)
  1803   apply linarith
  1804   done
  1805 
  1806 lemma filterlim_nat_sequentially: "filterlim nat sequentially at_top"
  1807   unfolding filterlim_at_top
  1808   apply (rule allI)
  1809   subgoal for Z by (auto intro!: eventually_at_top_linorderI[where c="int Z"])
  1810   done
  1811 
  1812 lemma filterlim_floor_sequentially: "filterlim floor at_top at_top"
  1813   unfolding filterlim_at_top
  1814   apply (rule allI)
  1815   subgoal for Z by (auto simp: le_floor_iff intro!: eventually_at_top_linorderI[where c="of_int Z"])
  1816   done
  1817 
  1818 lemma filterlim_sequentially_iff_filterlim_real:
  1819   "filterlim f sequentially F \<longleftrightarrow> filterlim (\<lambda>x. real (f x)) at_top F"
  1820   apply (rule iffI)
  1821   subgoal using filterlim_compose filterlim_real_sequentially by blast
  1822   subgoal premises prems
  1823   proof -
  1824     have "filterlim (\<lambda>x. nat (floor (real (f x)))) sequentially F"
  1825       by (intro filterlim_compose[OF filterlim_nat_sequentially]
  1826           filterlim_compose[OF filterlim_floor_sequentially] prems)
  1827     then show ?thesis by simp
  1828   qed
  1829   done
  1830 
  1831 
  1832 subsubsection \<open>Limits of Sequences\<close>
  1833 
  1834 lemma lim_sequentially: "X \<longlonglongrightarrow> L \<longleftrightarrow> (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
  1835   for L :: "'a::metric_space"
  1836   unfolding tendsto_iff eventually_sequentially ..
  1837 
  1838 lemmas LIMSEQ_def = lim_sequentially  (*legacy binding*)
  1839 
  1840 lemma LIMSEQ_iff_nz: "X \<longlonglongrightarrow> L \<longleftrightarrow> (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
  1841   for L :: "'a::metric_space"
  1842   unfolding lim_sequentially by (metis Suc_leD zero_less_Suc)
  1843 
  1844 lemma metric_LIMSEQ_I: "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X \<longlonglongrightarrow> L"
  1845   for L :: "'a::metric_space"
  1846   by (simp add: lim_sequentially)
  1847 
  1848 lemma metric_LIMSEQ_D: "X \<longlonglongrightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
  1849   for L :: "'a::metric_space"
  1850   by (simp add: lim_sequentially)
  1851 
  1852 
  1853 subsubsection \<open>Limits of Functions\<close>
  1854 
  1855 lemma LIM_def: "f \<midarrow>a\<rightarrow> L \<longleftrightarrow> (\<forall>r > 0. \<exists>s > 0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r)"
  1856   for a :: "'a::metric_space" and L :: "'b::metric_space"
  1857   unfolding tendsto_iff eventually_at by simp
  1858 
  1859 lemma metric_LIM_I:
  1860   "(\<And>r. 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r) \<Longrightarrow> f \<midarrow>a\<rightarrow> L"
  1861   for a :: "'a::metric_space" and L :: "'b::metric_space"
  1862   by (simp add: LIM_def)
  1863 
  1864 lemma metric_LIM_D: "f \<midarrow>a\<rightarrow> L \<Longrightarrow> 0 < r \<Longrightarrow> \<exists>s>0. \<forall>x. x \<noteq> a \<and> dist x a < s \<longrightarrow> dist (f x) L < r"
  1865   for a :: "'a::metric_space" and L :: "'b::metric_space"
  1866   by (simp add: LIM_def)
  1867 
  1868 lemma metric_LIM_imp_LIM:
  1869   fixes l :: "'a::metric_space"
  1870     and m :: "'b::metric_space"
  1871   assumes f: "f \<midarrow>a\<rightarrow> l"
  1872     and le: "\<And>x. x \<noteq> a \<Longrightarrow> dist (g x) m \<le> dist (f x) l"
  1873   shows "g \<midarrow>a\<rightarrow> m"
  1874   by (rule metric_tendsto_imp_tendsto [OF f]) (auto simp add: eventually_at_topological le)
  1875 
  1876 lemma metric_LIM_equal2:
  1877   fixes a :: "'a::metric_space"
  1878   assumes "0 < R"
  1879     and "\<And>x. x \<noteq> a \<Longrightarrow> dist x a < R \<Longrightarrow> f x = g x"
  1880   shows "g \<midarrow>a\<rightarrow> l \<Longrightarrow> f \<midarrow>a\<rightarrow> l"
  1881   apply (rule topological_tendstoI)
  1882   apply (drule (2) topological_tendstoD)
  1883   apply (simp add: eventually_at)
  1884   apply safe
  1885   apply (rule_tac x="min d R" in exI)
  1886   apply safe
  1887    apply (simp add: assms(1))
  1888   apply (simp add: assms(2))
  1889   done
  1890 
  1891 lemma metric_LIM_compose2:
  1892   fixes a :: "'a::metric_space"
  1893   assumes f: "f \<midarrow>a\<rightarrow> b"
  1894     and g: "g \<midarrow>b\<rightarrow> c"
  1895     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> b"
  1896   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> c"
  1897   using inj by (intro tendsto_compose_eventually[OF g f]) (auto simp: eventually_at)
  1898 
  1899 lemma metric_isCont_LIM_compose2:
  1900   fixes f :: "'a :: metric_space \<Rightarrow> _"
  1901   assumes f [unfolded isCont_def]: "isCont f a"
  1902     and g: "g \<midarrow>f a\<rightarrow> l"
  1903     and inj: "\<exists>d>0. \<forall>x. x \<noteq> a \<and> dist x a < d \<longrightarrow> f x \<noteq> f a"
  1904   shows "(\<lambda>x. g (f x)) \<midarrow>a\<rightarrow> l"
  1905   by (rule metric_LIM_compose2 [OF f g inj])
  1906 
  1907 
  1908 subsection \<open>Complete metric spaces\<close>
  1909 
  1910 subsection \<open>Cauchy sequences\<close>
  1911 
  1912 lemma (in metric_space) Cauchy_def: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e)"
  1913 proof -
  1914   have *: "eventually P (INF M. principal {(X m, X n) | n m. m \<ge> M \<and> n \<ge> M}) \<longleftrightarrow>
  1915     (\<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. P (X m, X n))" for P
  1916     apply (subst eventually_INF_base)
  1917     subgoal by simp
  1918     subgoal for a b
  1919       by (intro bexI[of _ "max a b"]) (auto simp: eventually_principal subset_eq)
  1920     subgoal by (auto simp: eventually_principal, blast)
  1921     done
  1922   have "Cauchy X \<longleftrightarrow> (INF M. principal {(X m, X n) | n m. m \<ge> M \<and> n \<ge> M}) \<le> uniformity"
  1923     unfolding Cauchy_uniform_iff le_filter_def * ..
  1924   also have "\<dots> = (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e)"
  1925     unfolding uniformity_dist le_INF_iff by (auto simp: * le_principal)
  1926   finally show ?thesis .
  1927 qed
  1928 
  1929 lemma (in metric_space) Cauchy_altdef: "Cauchy f \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n>m. dist (f m) (f n) < e)"
  1930   (is "?lhs \<longleftrightarrow> ?rhs")
  1931 proof
  1932   assume ?rhs
  1933   show ?lhs
  1934     unfolding Cauchy_def
  1935   proof (intro allI impI)
  1936     fix e :: real assume e: "e > 0"
  1937     with \<open>?rhs\<close> obtain M where M: "m \<ge> M \<Longrightarrow> n > m \<Longrightarrow> dist (f m) (f n) < e" for m n
  1938       by blast
  1939     have "dist (f m) (f n) < e" if "m \<ge> M" "n \<ge> M" for m n
  1940       using M[of m n] M[of n m] e that by (cases m n rule: linorder_cases) (auto simp: dist_commute)
  1941     then show "\<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (f m) (f n) < e"
  1942       by blast
  1943   qed
  1944 next
  1945   assume ?lhs
  1946   show ?rhs
  1947   proof (intro allI impI)
  1948     fix e :: real
  1949     assume e: "e > 0"
  1950     with \<open>Cauchy f\<close> obtain M where "\<And>m n. m \<ge> M \<Longrightarrow> n \<ge> M \<Longrightarrow> dist (f m) (f n) < e"
  1951       unfolding Cauchy_def by blast
  1952     then show "\<exists>M. \<forall>m\<ge>M. \<forall>n>m. dist (f m) (f n) < e"
  1953       by (intro exI[of _ M]) force
  1954   qed
  1955 qed
  1956 
  1957 lemma (in metric_space) Cauchy_altdef2: "Cauchy s \<longleftrightarrow> (\<forall>e>0. \<exists>N::nat. \<forall>n\<ge>N. dist(s n)(s N) < e)" (is "?lhs = ?rhs")
  1958 proof 
  1959   assume "Cauchy s"
  1960   then show ?rhs by (force simp add: Cauchy_def)
  1961 next
  1962     assume ?rhs
  1963     {
  1964       fix e::real
  1965       assume "e>0"
  1966       with \<open>?rhs\<close> obtain N where N: "\<forall>n\<ge>N. dist (s n) (s N) < e/2"
  1967         by (erule_tac x="e/2" in allE) auto
  1968       {
  1969         fix n m
  1970         assume nm: "N \<le> m \<and> N \<le> n"
  1971         then have "dist (s m) (s n) < e" using N
  1972           using dist_triangle_half_l[of "s m" "s N" "e" "s n"]
  1973           by blast
  1974       }
  1975       then have "\<exists>N. \<forall>m n. N \<le> m \<and> N \<le> n \<longrightarrow> dist (s m) (s n) < e"
  1976         by blast
  1977     }
  1978     then have ?lhs
  1979       unfolding Cauchy_def by blast
  1980   then show ?lhs
  1981     by blast
  1982 qed
  1983 
  1984 lemma (in metric_space) metric_CauchyI:
  1985   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1986   by (simp add: Cauchy_def)
  1987 
  1988 lemma (in metric_space) CauchyI':
  1989   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n>m. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1990   unfolding Cauchy_altdef by blast
  1991 
  1992 lemma (in metric_space) metric_CauchyD:
  1993   "Cauchy X \<Longrightarrow> 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1994   by (simp add: Cauchy_def)
  1995 
  1996 lemma (in metric_space) metric_Cauchy_iff2:
  1997   "Cauchy X = (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < inverse(real (Suc j))))"
  1998   apply (simp add: Cauchy_def)
  1999   apply auto
  2000   apply (drule reals_Archimedean)
  2001   apply safe
  2002   apply (drule_tac x = n in spec)
  2003   apply auto
  2004   apply (rule_tac x = M in exI)
  2005   apply auto
  2006   apply (drule_tac x = m in spec)
  2007   apply simp
  2008   apply (drule_tac x = na in spec)
  2009   apply auto
  2010   done
  2011 
  2012 lemma Cauchy_iff2: "Cauchy X \<longleftrightarrow> (\<forall>j. (\<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. \<bar>X m - X n\<bar> < inverse (real (Suc j))))"
  2013   by (simp only: metric_Cauchy_iff2 dist_real_def)
  2014 
  2015 lemma lim_1_over_n: "((\<lambda>n. 1 / of_nat n) \<longlongrightarrow> (0::'a::real_normed_field)) sequentially"
  2016 proof (subst lim_sequentially, intro allI impI exI)
  2017   fix e :: real
  2018   assume e: "e > 0"
  2019   fix n :: nat
  2020   assume n: "n \<ge> nat \<lceil>inverse e + 1\<rceil>"
  2021   have "inverse e < of_nat (nat \<lceil>inverse e + 1\<rceil>)" by linarith
  2022   also note n
  2023   finally show "dist (1 / of_nat n :: 'a) 0 < e"
  2024     using e by (simp add: divide_simps mult.commute norm_divide)
  2025 qed
  2026 
  2027 lemma (in metric_space) complete_def:
  2028   shows "complete S = (\<forall>f. (\<forall>n. f n \<in> S) \<and> Cauchy f \<longrightarrow> (\<exists>l\<in>S. f \<longlonglongrightarrow> l))"
  2029   unfolding complete_uniform
  2030 proof safe
  2031   fix f :: "nat \<Rightarrow> 'a"
  2032   assume f: "\<forall>n. f n \<in> S" "Cauchy f"
  2033     and *: "\<forall>F\<le>principal S. F \<noteq> bot \<longrightarrow> cauchy_filter F \<longrightarrow> (\<exists>x\<in>S. F \<le> nhds x)"
  2034   then show "\<exists>l\<in>S. f \<longlonglongrightarrow> l"
  2035     unfolding filterlim_def using f
  2036     by (intro *[rule_format])
  2037        (auto simp: filtermap_sequentually_ne_bot le_principal eventually_filtermap Cauchy_uniform)
  2038 next
  2039   fix F :: "'a filter"
  2040   assume "F \<le> principal S" "F \<noteq> bot" "cauchy_filter F"
  2041   assume seq: "\<forall>f. (\<forall>n. f n \<in> S) \<and> Cauchy f \<longrightarrow> (\<exists>l\<in>S. f \<longlonglongrightarrow> l)"
  2042 
  2043   from \<open>F \<le> principal S\<close> \<open>cauchy_filter F\<close>
  2044   have FF_le: "F \<times>\<^sub>F F \<le> uniformity_on S"
  2045     by (simp add: cauchy_filter_def principal_prod_principal[symmetric] prod_filter_mono)
  2046 
  2047   let ?P = "\<lambda>P e. eventually P F \<and> (\<forall>x. P x \<longrightarrow> x \<in> S) \<and> (\<forall>x y. P x \<longrightarrow> P y \<longrightarrow> dist x y < e)"
  2048   have P: "\<exists>P. ?P P \<epsilon>" if "0 < \<epsilon>" for \<epsilon> :: real
  2049   proof -
  2050     from that have "eventually (\<lambda>(x, y). x \<in> S \<and> y \<in> S \<and> dist x y < \<epsilon>) (uniformity_on S)"
  2051       by (auto simp: eventually_inf_principal eventually_uniformity_metric)
  2052     from filter_leD[OF FF_le this] show ?thesis
  2053       by (auto simp: eventually_prod_same)
  2054   qed
  2055 
  2056   have "\<exists>P. \<forall>n. ?P (P n) (1 / Suc n) \<and> P (Suc n) \<le> P n"
  2057   proof (rule dependent_nat_choice)
  2058     show "\<exists>P. ?P P (1 / Suc 0)"
  2059       using P[of 1] by auto
  2060   next
  2061     fix P n assume "?P P (1/Suc n)"
  2062     moreover obtain Q where "?P Q (1 / Suc (Suc n))"
  2063       using P[of "1/Suc (Suc n)"] by auto
  2064     ultimately show "\<exists>Q. ?P Q (1 / Suc (Suc n)) \<and> Q \<le> P"
  2065       by (intro exI[of _ "\<lambda>x. P x \<and> Q x"]) (auto simp: eventually_conj_iff)
  2066   qed
  2067   then obtain P where P: "eventually (P n) F" "P n x \<Longrightarrow> x \<in> S"
  2068     "P n x \<Longrightarrow> P n y \<Longrightarrow> dist x y < 1 / Suc n" "P (Suc n) \<le> P n"
  2069     for n x y
  2070     by metis
  2071   have "antimono P"
  2072     using P(4) unfolding decseq_Suc_iff le_fun_def by blast
  2073 
  2074   obtain X where X: "P n (X n)" for n
  2075     using P(1)[THEN eventually_happens'[OF \<open>F \<noteq> bot\<close>]] by metis
  2076   have "Cauchy X"
  2077     unfolding metric_Cauchy_iff2 inverse_eq_divide
  2078   proof (intro exI allI impI)
  2079     fix j m n :: nat
  2080     assume "j \<le> m" "j \<le> n"
  2081     with \<open>antimono P\<close> X have "P j (X m)" "P j (X n)"
  2082       by (auto simp: antimono_def)
  2083     then show "dist (X m) (X n) < 1 / Suc j"
  2084       by (rule P)
  2085   qed
  2086   moreover have "\<forall>n. X n \<in> S"
  2087     using P(2) X by auto
  2088   ultimately obtain x where "X \<longlonglongrightarrow> x" "x \<in> S"
  2089     using seq by blast
  2090 
  2091   show "\<exists>x\<in>S. F \<le> nhds x"
  2092   proof (rule bexI)
  2093     have "eventually (\<lambda>y. dist y x < e) F" if "0 < e" for e :: real
  2094     proof -
  2095       from that have "(\<lambda>n. 1 / Suc n :: real) \<longlonglongrightarrow> 0 \<and> 0 < e / 2"
  2096         by (subst LIMSEQ_Suc_iff) (auto intro!: lim_1_over_n)
  2097       then have "\<forall>\<^sub>F n in sequentially. dist (X n) x < e / 2 \<and> 1 / Suc n < e / 2"
  2098         using \<open>X \<longlonglongrightarrow> x\<close>
  2099         unfolding tendsto_iff order_tendsto_iff[where 'a=real] eventually_conj_iff
  2100         by blast
  2101       then obtain n where "dist x (X n) < e / 2" "1 / Suc n < e / 2"
  2102         by (auto simp: eventually_sequentially dist_commute)
  2103       show ?thesis
  2104         using \<open>eventually (P n) F\<close>
  2105       proof eventually_elim
  2106         case (elim y)
  2107         then have "dist y (X n) < 1 / Suc n"
  2108           by (intro X P)
  2109         also have "\<dots> < e / 2" by fact
  2110         finally show "dist y x < e"
  2111           by (rule dist_triangle_half_l) fact
  2112       qed
  2113     qed
  2114     then show "F \<le> nhds x"
  2115       unfolding nhds_metric le_INF_iff le_principal by auto
  2116   qed fact
  2117 qed
  2118 
  2119 lemma (in metric_space) totally_bounded_metric:
  2120   "totally_bounded S \<longleftrightarrow> (\<forall>e>0. \<exists>k. finite k \<and> S \<subseteq> (\<Union>x\<in>k. {y. dist x y < e}))"
  2121   apply (simp only: totally_bounded_def eventually_uniformity_metric imp_ex)
  2122   apply (subst all_comm)
  2123   apply (intro arg_cong[where f=All] ext)
  2124   apply safe
  2125   subgoal for e
  2126     apply (erule allE[of _ "\<lambda>(x, y). dist x y < e"])
  2127     apply auto
  2128     done
  2129   subgoal for e P k
  2130     apply (intro exI[of _ k])
  2131     apply (force simp: subset_eq)
  2132     done
  2133   done
  2134 
  2135 
  2136 subsubsection \<open>Cauchy Sequences are Convergent\<close>
  2137 
  2138 (* TODO: update to uniform_space *)
  2139 class complete_space = metric_space +
  2140   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  2141 
  2142 lemma Cauchy_convergent_iff: "Cauchy X \<longleftrightarrow> convergent X"
  2143   for X :: "nat \<Rightarrow> 'a::complete_space"
  2144   by (blast intro: Cauchy_convergent convergent_Cauchy)
  2145 
  2146 
  2147 subsection \<open>The set of real numbers is a complete metric space\<close>
  2148 
  2149 text \<open>
  2150   Proof that Cauchy sequences converge based on the one from
  2151   \<^url>\<open>http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html\<close>
  2152 \<close>
  2153 
  2154 text \<open>
  2155   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  2156   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  2157 \<close>
  2158 lemma increasing_LIMSEQ:
  2159   fixes f :: "nat \<Rightarrow> real"
  2160   assumes inc: "\<And>n. f n \<le> f (Suc n)"
  2161     and bdd: "\<And>n. f n \<le> l"
  2162     and en: "\<And>e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
  2163   shows "f \<longlonglongrightarrow> l"
  2164 proof (rule increasing_tendsto)
  2165   fix x
  2166   assume "x < l"
  2167   with dense[of 0 "l - x"] obtain e where "0 < e" "e < l - x"
  2168     by auto
  2169   from en[OF \<open>0 < e\<close>] obtain n where "l - e \<le> f n"
  2170     by (auto simp: field_simps)
  2171   with \<open>e < l - x\<close> \<open>0 < e\<close> have "x < f n"
  2172     by simp
  2173   with incseq_SucI[of f, OF inc] show "eventually (\<lambda>n. x < f n) sequentially"
  2174     by (auto simp: eventually_sequentially incseq_def intro: less_le_trans)
  2175 qed (use bdd in auto)
  2176 
  2177 lemma real_Cauchy_convergent:
  2178   fixes X :: "nat \<Rightarrow> real"
  2179   assumes X: "Cauchy X"
  2180   shows "convergent X"
  2181 proof -
  2182   define S :: "real set" where "S = {x. \<exists>N. \<forall>n\<ge>N. x < X n}"
  2183   then have mem_S: "\<And>N x. \<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  2184     by auto
  2185 
  2186   have bound_isUb: "y \<le> x" if N: "\<forall>n\<ge>N. X n < x" and "y \<in> S" for N and x y :: real
  2187   proof -
  2188     from that have "\<exists>M. \<forall>n\<ge>M. y < X n"
  2189       by (simp add: S_def)
  2190     then obtain M where "\<forall>n\<ge>M. y < X n" ..
  2191     then have "y < X (max M N)" by simp
  2192     also have "\<dots> < x" using N by simp
  2193     finally show ?thesis by (rule order_less_imp_le)
  2194   qed
  2195 
  2196   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < 1"
  2197     using X[THEN metric_CauchyD, OF zero_less_one] by auto
  2198   then have N: "\<forall>n\<ge>N. dist (X n) (X N) < 1" by simp
  2199   have [simp]: "S \<noteq> {}"
  2200   proof (intro exI ex_in_conv[THEN iffD1])
  2201     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  2202       by (simp add: abs_diff_less_iff dist_real_def)
  2203     then show "X N - 1 \<in> S" by (rule mem_S)
  2204   qed
  2205   have [simp]: "bdd_above S"
  2206   proof
  2207     from N have "\<forall>n\<ge>N. X n < X N + 1"
  2208       by (simp add: abs_diff_less_iff dist_real_def)
  2209     then show "\<And>s. s \<in> S \<Longrightarrow>  s \<le> X N + 1"
  2210       by (rule bound_isUb)
  2211   qed
  2212   have "X \<longlonglongrightarrow> Sup S"
  2213   proof (rule metric_LIMSEQ_I)
  2214     fix r :: real
  2215     assume "0 < r"
  2216     then have r: "0 < r/2" by simp
  2217     obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. dist (X n) (X m) < r/2"
  2218       using metric_CauchyD [OF X r] by auto
  2219     then have "\<forall>n\<ge>N. dist (X n) (X N) < r/2" by simp
  2220     then have N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  2221       by (simp only: dist_real_def abs_diff_less_iff)
  2222 
  2223     from N have "\<forall>n\<ge>N. X N - r/2 < X n" by blast
  2224     then have "X N - r/2 \<in> S" by (rule mem_S)
  2225     then have 1: "X N - r/2 \<le> Sup S" by (simp add: cSup_upper)
  2226 
  2227     from N have "\<forall>n\<ge>N. X n < X N + r/2" by blast
  2228     from bound_isUb[OF this]
  2229     have 2: "Sup S \<le> X N + r/2"
  2230       by (intro cSup_least) simp_all
  2231 
  2232     show "\<exists>N. \<forall>n\<ge>N. dist (X n) (Sup S) < r"
  2233     proof (intro exI allI impI)
  2234       fix n
  2235       assume n: "N \<le> n"
  2236       from N n have "X n < X N + r/2" and "X N - r/2 < X n"
  2237         by simp_all
  2238       then show "dist (X n) (Sup S) < r" using 1 2
  2239         by (simp add: abs_diff_less_iff dist_real_def)
  2240     qed
  2241   qed
  2242   then show ?thesis by (auto simp: convergent_def)
  2243 qed
  2244 
  2245 instance real :: complete_space
  2246   by intro_classes (rule real_Cauchy_convergent)
  2247 
  2248 class banach = real_normed_vector + complete_space
  2249 
  2250 instance real :: banach ..
  2251 
  2252 lemma tendsto_at_topI_sequentially:
  2253   fixes f :: "real \<Rightarrow> 'b::first_countable_topology"
  2254   assumes *: "\<And>X. filterlim X at_top sequentially \<Longrightarrow> (\<lambda>n. f (X n)) \<longlonglongrightarrow> y"
  2255   shows "(f \<longlongrightarrow> y) at_top"
  2256 proof -
  2257   obtain A where A: "decseq A" "open (A n)" "y \<in> A n" "nhds y = (INF n. principal (A n))" for n
  2258     by (rule nhds_countable[of y]) (rule that)
  2259 
  2260   have "\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m"
  2261   proof (rule ccontr)
  2262     assume "\<not> (\<forall>m. \<exists>k. \<forall>x\<ge>k. f x \<in> A m)"
  2263     then obtain m where "\<And>k. \<exists>x\<ge>k. f x \<notin> A m"
  2264       by auto
  2265     then have "\<exists>X. \<forall>n. (f (X n) \<notin> A m) \<and> max n (X n) + 1 \<le> X (Suc n)"
  2266       by (intro dependent_nat_choice) (auto simp del: max.bounded_iff)
  2267     then obtain X where X: "\<And>n. f (X n) \<notin> A m" "\<And>n. max n (X n) + 1 \<le> X (Suc n)"
  2268       by auto
  2269     have "1 \<le> n \<Longrightarrow> real n \<le> X n" for n
  2270       using X[of "n - 1"] by auto
  2271     then have "filterlim X at_top sequentially"
  2272       by (force intro!: filterlim_at_top_mono[OF filterlim_real_sequentially]
  2273           simp: eventually_sequentially)
  2274     from topological_tendstoD[OF *[OF this] A(2, 3), of m] X(1) show False
  2275       by auto
  2276   qed
  2277   then obtain k where "k m \<le> x \<Longrightarrow> f x \<in> A m" for m x
  2278     by metis
  2279   then show ?thesis
  2280     unfolding at_top_def A by (intro filterlim_base[where i=k]) auto
  2281 qed
  2282 
  2283 lemma tendsto_at_topI_sequentially_real:
  2284   fixes f :: "real \<Rightarrow> real"
  2285   assumes mono: "mono f"
  2286     and limseq: "(\<lambda>n. f (real n)) \<longlonglongrightarrow> y"
  2287   shows "(f \<longlongrightarrow> y) at_top"
  2288 proof (rule tendstoI)
  2289   fix e :: real
  2290   assume "0 < e"
  2291   with limseq obtain N :: nat where N: "N \<le> n \<Longrightarrow> \<bar>f (real n) - y\<bar> < e" for n
  2292     by (auto simp: lim_sequentially dist_real_def)
  2293   have le: "f x \<le> y" for x :: real
  2294   proof -
  2295     obtain n where "x \<le> real_of_nat n"
  2296       using real_arch_simple[of x] ..
  2297     note monoD[OF mono this]
  2298     also have "f (real_of_nat n) \<le> y"
  2299       by (rule LIMSEQ_le_const[OF limseq]) (auto intro!: exI[of _ n] monoD[OF mono])
  2300     finally show ?thesis .
  2301   qed
  2302   have "eventually (\<lambda>x. real N \<le> x) at_top"
  2303     by (rule eventually_ge_at_top)
  2304   then show "eventually (\<lambda>x. dist (f x) y < e) at_top"
  2305   proof eventually_elim
  2306     case (elim x)
  2307     with N[of N] le have "y - f (real N) < e" by auto
  2308     moreover note monoD[OF mono elim]
  2309     ultimately show "dist (f x) y < e"
  2310       using le[of x] by (auto simp: dist_real_def field_simps)
  2311   qed
  2312 qed
  2313 
  2314 end