src/HOL/Relation.thy
author wenzelm
Tue Sep 26 20:54:40 2017 +0200 (22 months ago)
changeset 66695 91500c024c7f
parent 66441 b9468503742a
child 67399 eab6ce8368fa
permissions -rw-r--r--
tuned;
     1 (*  Title:      HOL/Relation.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer, TU Muenchen
     4 *)
     5 
     6 section \<open>Relations -- as sets of pairs, and binary predicates\<close>
     7 
     8 theory Relation
     9   imports Finite_Set
    10 begin
    11 
    12 text \<open>A preliminary: classical rules for reasoning on predicates\<close>
    13 
    14 declare predicate1I [Pure.intro!, intro!]
    15 declare predicate1D [Pure.dest, dest]
    16 declare predicate2I [Pure.intro!, intro!]
    17 declare predicate2D [Pure.dest, dest]
    18 declare bot1E [elim!]
    19 declare bot2E [elim!]
    20 declare top1I [intro!]
    21 declare top2I [intro!]
    22 declare inf1I [intro!]
    23 declare inf2I [intro!]
    24 declare inf1E [elim!]
    25 declare inf2E [elim!]
    26 declare sup1I1 [intro?]
    27 declare sup2I1 [intro?]
    28 declare sup1I2 [intro?]
    29 declare sup2I2 [intro?]
    30 declare sup1E [elim!]
    31 declare sup2E [elim!]
    32 declare sup1CI [intro!]
    33 declare sup2CI [intro!]
    34 declare Inf1_I [intro!]
    35 declare INF1_I [intro!]
    36 declare Inf2_I [intro!]
    37 declare INF2_I [intro!]
    38 declare Inf1_D [elim]
    39 declare INF1_D [elim]
    40 declare Inf2_D [elim]
    41 declare INF2_D [elim]
    42 declare Inf1_E [elim]
    43 declare INF1_E [elim]
    44 declare Inf2_E [elim]
    45 declare INF2_E [elim]
    46 declare Sup1_I [intro]
    47 declare SUP1_I [intro]
    48 declare Sup2_I [intro]
    49 declare SUP2_I [intro]
    50 declare Sup1_E [elim!]
    51 declare SUP1_E [elim!]
    52 declare Sup2_E [elim!]
    53 declare SUP2_E [elim!]
    54 
    55 
    56 subsection \<open>Fundamental\<close>
    57 
    58 subsubsection \<open>Relations as sets of pairs\<close>
    59 
    60 type_synonym 'a rel = "('a \<times> 'a) set"
    61 
    62 lemma subrelI: "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (x, y) \<in> s) \<Longrightarrow> r \<subseteq> s"
    63   \<comment> \<open>Version of @{thm [source] subsetI} for binary relations\<close>
    64   by auto
    65 
    66 lemma lfp_induct2:
    67   "(a, b) \<in> lfp f \<Longrightarrow> mono f \<Longrightarrow>
    68     (\<And>a b. (a, b) \<in> f (lfp f \<inter> {(x, y). P x y}) \<Longrightarrow> P a b) \<Longrightarrow> P a b"
    69   \<comment> \<open>Version of @{thm [source] lfp_induct} for binary relations\<close>
    70   using lfp_induct_set [of "(a, b)" f "case_prod P"] by auto
    71 
    72 
    73 subsubsection \<open>Conversions between set and predicate relations\<close>
    74 
    75 lemma pred_equals_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) = (\<lambda>x. x \<in> S) \<longleftrightarrow> R = S"
    76   by (simp add: set_eq_iff fun_eq_iff)
    77 
    78 lemma pred_equals_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) = (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R = S"
    79   by (simp add: set_eq_iff fun_eq_iff)
    80 
    81 lemma pred_subset_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<le> (\<lambda>x. x \<in> S) \<longleftrightarrow> R \<subseteq> S"
    82   by (simp add: subset_iff le_fun_def)
    83 
    84 lemma pred_subset_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<le> (\<lambda>x y. (x, y) \<in> S) \<longleftrightarrow> R \<subseteq> S"
    85   by (simp add: subset_iff le_fun_def)
    86 
    87 lemma bot_empty_eq [pred_set_conv]: "\<bottom> = (\<lambda>x. x \<in> {})"
    88   by (auto simp add: fun_eq_iff)
    89 
    90 lemma bot_empty_eq2 [pred_set_conv]: "\<bottom> = (\<lambda>x y. (x, y) \<in> {})"
    91   by (auto simp add: fun_eq_iff)
    92 
    93 lemma top_empty_eq [pred_set_conv]: "\<top> = (\<lambda>x. x \<in> UNIV)"
    94   by (auto simp add: fun_eq_iff)
    95 
    96 lemma top_empty_eq2 [pred_set_conv]: "\<top> = (\<lambda>x y. (x, y) \<in> UNIV)"
    97   by (auto simp add: fun_eq_iff)
    98 
    99 lemma inf_Int_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<sqinter> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<inter> S)"
   100   by (simp add: inf_fun_def)
   101 
   102 lemma inf_Int_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<sqinter> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<inter> S)"
   103   by (simp add: inf_fun_def)
   104 
   105 lemma sup_Un_eq [pred_set_conv]: "(\<lambda>x. x \<in> R) \<squnion> (\<lambda>x. x \<in> S) = (\<lambda>x. x \<in> R \<union> S)"
   106   by (simp add: sup_fun_def)
   107 
   108 lemma sup_Un_eq2 [pred_set_conv]: "(\<lambda>x y. (x, y) \<in> R) \<squnion> (\<lambda>x y. (x, y) \<in> S) = (\<lambda>x y. (x, y) \<in> R \<union> S)"
   109   by (simp add: sup_fun_def)
   110 
   111 lemma INF_INT_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Inter>i\<in>S. r i))"
   112   by (simp add: fun_eq_iff)
   113 
   114 lemma INF_INT_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Inter>i\<in>S. r i))"
   115   by (simp add: fun_eq_iff)
   116 
   117 lemma SUP_UN_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> r i)) = (\<lambda>x. x \<in> (\<Union>i\<in>S. r i))"
   118   by (simp add: fun_eq_iff)
   119 
   120 lemma SUP_UN_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> r i)) = (\<lambda>x y. (x, y) \<in> (\<Union>i\<in>S. r i))"
   121   by (simp add: fun_eq_iff)
   122 
   123 lemma Inf_INT_eq [pred_set_conv]: "\<Sqinter>S = (\<lambda>x. x \<in> INTER S Collect)"
   124   by (simp add: fun_eq_iff)
   125 
   126 lemma INF_Int_eq [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Inter>S)"
   127   by (simp add: fun_eq_iff)
   128 
   129 lemma Inf_INT_eq2 [pred_set_conv]: "\<Sqinter>S = (\<lambda>x y. (x, y) \<in> INTER (case_prod ` S) Collect)"
   130   by (simp add: fun_eq_iff)
   131 
   132 lemma INF_Int_eq2 [pred_set_conv]: "(\<Sqinter>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Inter>S)"
   133   by (simp add: fun_eq_iff)
   134 
   135 lemma Sup_SUP_eq [pred_set_conv]: "\<Squnion>S = (\<lambda>x. x \<in> UNION S Collect)"
   136   by (simp add: fun_eq_iff)
   137 
   138 lemma SUP_Sup_eq [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x. x \<in> i)) = (\<lambda>x. x \<in> \<Union>S)"
   139   by (simp add: fun_eq_iff)
   140 
   141 lemma Sup_SUP_eq2 [pred_set_conv]: "\<Squnion>S = (\<lambda>x y. (x, y) \<in> UNION (case_prod ` S) Collect)"
   142   by (simp add: fun_eq_iff)
   143 
   144 lemma SUP_Sup_eq2 [pred_set_conv]: "(\<Squnion>i\<in>S. (\<lambda>x y. (x, y) \<in> i)) = (\<lambda>x y. (x, y) \<in> \<Union>S)"
   145   by (simp add: fun_eq_iff)
   146 
   147 
   148 subsection \<open>Properties of relations\<close>
   149 
   150 subsubsection \<open>Reflexivity\<close>
   151 
   152 definition refl_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   153   where "refl_on A r \<longleftrightarrow> r \<subseteq> A \<times> A \<and> (\<forall>x\<in>A. (x, x) \<in> r)"
   154 
   155 abbreviation refl :: "'a rel \<Rightarrow> bool" \<comment> \<open>reflexivity over a type\<close>
   156   where "refl \<equiv> refl_on UNIV"
   157 
   158 definition reflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   159   where "reflp r \<longleftrightarrow> (\<forall>x. r x x)"
   160 
   161 lemma reflp_refl_eq [pred_set_conv]: "reflp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> refl r"
   162   by (simp add: refl_on_def reflp_def)
   163 
   164 lemma refl_onI [intro?]: "r \<subseteq> A \<times> A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> (x, x) \<in> r) \<Longrightarrow> refl_on A r"
   165   unfolding refl_on_def by (iprover intro!: ballI)
   166 
   167 lemma refl_onD: "refl_on A r \<Longrightarrow> a \<in> A \<Longrightarrow> (a, a) \<in> r"
   168   unfolding refl_on_def by blast
   169 
   170 lemma refl_onD1: "refl_on A r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> x \<in> A"
   171   unfolding refl_on_def by blast
   172 
   173 lemma refl_onD2: "refl_on A r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> y \<in> A"
   174   unfolding refl_on_def by blast
   175 
   176 lemma reflpI [intro?]: "(\<And>x. r x x) \<Longrightarrow> reflp r"
   177   by (auto intro: refl_onI simp add: reflp_def)
   178 
   179 lemma reflpE:
   180   assumes "reflp r"
   181   obtains "r x x"
   182   using assms by (auto dest: refl_onD simp add: reflp_def)
   183 
   184 lemma reflpD [dest?]:
   185   assumes "reflp r"
   186   shows "r x x"
   187   using assms by (auto elim: reflpE)
   188 
   189 lemma refl_on_Int: "refl_on A r \<Longrightarrow> refl_on B s \<Longrightarrow> refl_on (A \<inter> B) (r \<inter> s)"
   190   unfolding refl_on_def by blast
   191 
   192 lemma reflp_inf: "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<sqinter> s)"
   193   by (auto intro: reflpI elim: reflpE)
   194 
   195 lemma refl_on_Un: "refl_on A r \<Longrightarrow> refl_on B s \<Longrightarrow> refl_on (A \<union> B) (r \<union> s)"
   196   unfolding refl_on_def by blast
   197 
   198 lemma reflp_sup: "reflp r \<Longrightarrow> reflp s \<Longrightarrow> reflp (r \<squnion> s)"
   199   by (auto intro: reflpI elim: reflpE)
   200 
   201 lemma refl_on_INTER: "\<forall>x\<in>S. refl_on (A x) (r x) \<Longrightarrow> refl_on (INTER S A) (INTER S r)"
   202   unfolding refl_on_def by fast
   203 
   204 lemma refl_on_UNION: "\<forall>x\<in>S. refl_on (A x) (r x) \<Longrightarrow> refl_on (UNION S A) (UNION S r)"
   205   unfolding refl_on_def by blast
   206 
   207 lemma refl_on_empty [simp]: "refl_on {} {}"
   208   by (simp add: refl_on_def)
   209 
   210 lemma refl_on_singleton [simp]: "refl_on {x} {(x, x)}"
   211 by (blast intro: refl_onI)
   212 
   213 lemma refl_on_def' [nitpick_unfold, code]:
   214   "refl_on A r \<longleftrightarrow> (\<forall>(x, y) \<in> r. x \<in> A \<and> y \<in> A) \<and> (\<forall>x \<in> A. (x, x) \<in> r)"
   215   by (auto intro: refl_onI dest: refl_onD refl_onD1 refl_onD2)
   216 
   217 lemma reflp_equality [simp]: "reflp op ="
   218   by (simp add: reflp_def)
   219 
   220 lemma reflp_mono: "reflp R \<Longrightarrow> (\<And>x y. R x y \<longrightarrow> Q x y) \<Longrightarrow> reflp Q"
   221   by (auto intro: reflpI dest: reflpD)
   222 
   223 
   224 subsubsection \<open>Irreflexivity\<close>
   225 
   226 definition irrefl :: "'a rel \<Rightarrow> bool"
   227   where "irrefl r \<longleftrightarrow> (\<forall>a. (a, a) \<notin> r)"
   228 
   229 definition irreflp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   230   where "irreflp R \<longleftrightarrow> (\<forall>a. \<not> R a a)"
   231 
   232 lemma irreflp_irrefl_eq [pred_set_conv]: "irreflp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> irrefl R"
   233   by (simp add: irrefl_def irreflp_def)
   234 
   235 lemma irreflI [intro?]: "(\<And>a. (a, a) \<notin> R) \<Longrightarrow> irrefl R"
   236   by (simp add: irrefl_def)
   237 
   238 lemma irreflpI [intro?]: "(\<And>a. \<not> R a a) \<Longrightarrow> irreflp R"
   239   by (fact irreflI [to_pred])
   240 
   241 lemma irrefl_distinct [code]: "irrefl r \<longleftrightarrow> (\<forall>(a, b) \<in> r. a \<noteq> b)"
   242   by (auto simp add: irrefl_def)
   243 
   244 
   245 subsubsection \<open>Asymmetry\<close>
   246 
   247 inductive asym :: "'a rel \<Rightarrow> bool"
   248   where asymI: "irrefl R \<Longrightarrow> (\<And>a b. (a, b) \<in> R \<Longrightarrow> (b, a) \<notin> R) \<Longrightarrow> asym R"
   249 
   250 inductive asymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   251   where asympI: "irreflp R \<Longrightarrow> (\<And>a b. R a b \<Longrightarrow> \<not> R b a) \<Longrightarrow> asymp R"
   252 
   253 lemma asymp_asym_eq [pred_set_conv]: "asymp (\<lambda>a b. (a, b) \<in> R) \<longleftrightarrow> asym R"
   254   by (auto intro!: asymI asympI elim: asym.cases asymp.cases simp add: irreflp_irrefl_eq)
   255 
   256 
   257 subsubsection \<open>Symmetry\<close>
   258 
   259 definition sym :: "'a rel \<Rightarrow> bool"
   260   where "sym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r)"
   261 
   262 definition symp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   263   where "symp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x)"
   264 
   265 lemma symp_sym_eq [pred_set_conv]: "symp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> sym r"
   266   by (simp add: sym_def symp_def)
   267 
   268 lemma symI [intro?]: "(\<And>a b. (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r) \<Longrightarrow> sym r"
   269   by (unfold sym_def) iprover
   270 
   271 lemma sympI [intro?]: "(\<And>a b. r a b \<Longrightarrow> r b a) \<Longrightarrow> symp r"
   272   by (fact symI [to_pred])
   273 
   274 lemma symE:
   275   assumes "sym r" and "(b, a) \<in> r"
   276   obtains "(a, b) \<in> r"
   277   using assms by (simp add: sym_def)
   278 
   279 lemma sympE:
   280   assumes "symp r" and "r b a"
   281   obtains "r a b"
   282   using assms by (rule symE [to_pred])
   283 
   284 lemma symD [dest?]:
   285   assumes "sym r" and "(b, a) \<in> r"
   286   shows "(a, b) \<in> r"
   287   using assms by (rule symE)
   288 
   289 lemma sympD [dest?]:
   290   assumes "symp r" and "r b a"
   291   shows "r a b"
   292   using assms by (rule symD [to_pred])
   293 
   294 lemma sym_Int: "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<inter> s)"
   295   by (fast intro: symI elim: symE)
   296 
   297 lemma symp_inf: "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<sqinter> s)"
   298   by (fact sym_Int [to_pred])
   299 
   300 lemma sym_Un: "sym r \<Longrightarrow> sym s \<Longrightarrow> sym (r \<union> s)"
   301   by (fast intro: symI elim: symE)
   302 
   303 lemma symp_sup: "symp r \<Longrightarrow> symp s \<Longrightarrow> symp (r \<squnion> s)"
   304   by (fact sym_Un [to_pred])
   305 
   306 lemma sym_INTER: "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (INTER S r)"
   307   by (fast intro: symI elim: symE)
   308 
   309 lemma symp_INF: "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (INFIMUM S r)"
   310   by (fact sym_INTER [to_pred])
   311 
   312 lemma sym_UNION: "\<forall>x\<in>S. sym (r x) \<Longrightarrow> sym (UNION S r)"
   313   by (fast intro: symI elim: symE)
   314 
   315 lemma symp_SUP: "\<forall>x\<in>S. symp (r x) \<Longrightarrow> symp (SUPREMUM S r)"
   316   by (fact sym_UNION [to_pred])
   317 
   318 
   319 subsubsection \<open>Antisymmetry\<close>
   320 
   321 definition antisym :: "'a rel \<Rightarrow> bool"
   322   where "antisym r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (y, x) \<in> r \<longrightarrow> x = y)"
   323 
   324 definition antisymp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   325   where "antisymp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> r y x \<longrightarrow> x = y)"
   326 
   327 lemma antisymp_antisym_eq [pred_set_conv]: "antisymp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> antisym r"
   328   by (simp add: antisym_def antisymp_def)
   329 
   330 lemma antisymI [intro?]:
   331   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (y, x) \<in> r \<Longrightarrow> x = y) \<Longrightarrow> antisym r"
   332   unfolding antisym_def by iprover
   333 
   334 lemma antisympI [intro?]:
   335   "(\<And>x y. r x y \<Longrightarrow> r y x \<Longrightarrow> x = y) \<Longrightarrow> antisymp r"
   336   by (fact antisymI [to_pred])
   337     
   338 lemma antisymD [dest?]:
   339   "antisym r \<Longrightarrow> (a, b) \<in> r \<Longrightarrow> (b, a) \<in> r \<Longrightarrow> a = b"
   340   unfolding antisym_def by iprover
   341 
   342 lemma antisympD [dest?]:
   343   "antisymp r \<Longrightarrow> r a b \<Longrightarrow> r b a \<Longrightarrow> a = b"
   344   by (fact antisymD [to_pred])
   345 
   346 lemma antisym_subset:
   347   "r \<subseteq> s \<Longrightarrow> antisym s \<Longrightarrow> antisym r"
   348   unfolding antisym_def by blast
   349 
   350 lemma antisymp_less_eq:
   351   "r \<le> s \<Longrightarrow> antisymp s \<Longrightarrow> antisymp r"
   352   by (fact antisym_subset [to_pred])
   353     
   354 lemma antisym_empty [simp]:
   355   "antisym {}"
   356   unfolding antisym_def by blast
   357 
   358 lemma antisym_bot [simp]:
   359   "antisymp \<bottom>"
   360   by (fact antisym_empty [to_pred])
   361     
   362 lemma antisymp_equality [simp]:
   363   "antisymp HOL.eq"
   364   by (auto intro: antisympI)
   365 
   366 lemma antisym_singleton [simp]:
   367   "antisym {x}"
   368   by (blast intro: antisymI)
   369 
   370 
   371 subsubsection \<open>Transitivity\<close>
   372 
   373 definition trans :: "'a rel \<Rightarrow> bool"
   374   where "trans r \<longleftrightarrow> (\<forall>x y z. (x, y) \<in> r \<longrightarrow> (y, z) \<in> r \<longrightarrow> (x, z) \<in> r)"
   375 
   376 definition transp :: "('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> bool"
   377   where "transp r \<longleftrightarrow> (\<forall>x y z. r x y \<longrightarrow> r y z \<longrightarrow> r x z)"
   378 
   379 lemma transp_trans_eq [pred_set_conv]: "transp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> trans r"
   380   by (simp add: trans_def transp_def)
   381 
   382 lemma transI [intro?]: "(\<And>x y z. (x, y) \<in> r \<Longrightarrow> (y, z) \<in> r \<Longrightarrow> (x, z) \<in> r) \<Longrightarrow> trans r"
   383   by (unfold trans_def) iprover
   384 
   385 lemma transpI [intro?]: "(\<And>x y z. r x y \<Longrightarrow> r y z \<Longrightarrow> r x z) \<Longrightarrow> transp r"
   386   by (fact transI [to_pred])
   387 
   388 lemma transE:
   389   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   390   obtains "(x, z) \<in> r"
   391   using assms by (unfold trans_def) iprover
   392 
   393 lemma transpE:
   394   assumes "transp r" and "r x y" and "r y z"
   395   obtains "r x z"
   396   using assms by (rule transE [to_pred])
   397 
   398 lemma transD [dest?]:
   399   assumes "trans r" and "(x, y) \<in> r" and "(y, z) \<in> r"
   400   shows "(x, z) \<in> r"
   401   using assms by (rule transE)
   402 
   403 lemma transpD [dest?]:
   404   assumes "transp r" and "r x y" and "r y z"
   405   shows "r x z"
   406   using assms by (rule transD [to_pred])
   407 
   408 lemma trans_Int: "trans r \<Longrightarrow> trans s \<Longrightarrow> trans (r \<inter> s)"
   409   by (fast intro: transI elim: transE)
   410 
   411 lemma transp_inf: "transp r \<Longrightarrow> transp s \<Longrightarrow> transp (r \<sqinter> s)"
   412   by (fact trans_Int [to_pred])
   413 
   414 lemma trans_INTER: "\<forall>x\<in>S. trans (r x) \<Longrightarrow> trans (INTER S r)"
   415   by (fast intro: transI elim: transD)
   416 
   417 lemma transp_INF: "\<forall>x\<in>S. transp (r x) \<Longrightarrow> transp (INFIMUM S r)"
   418   by (fact trans_INTER [to_pred])
   419     
   420 lemma trans_join [code]: "trans r \<longleftrightarrow> (\<forall>(x, y1) \<in> r. \<forall>(y2, z) \<in> r. y1 = y2 \<longrightarrow> (x, z) \<in> r)"
   421   by (auto simp add: trans_def)
   422 
   423 lemma transp_trans: "transp r \<longleftrightarrow> trans {(x, y). r x y}"
   424   by (simp add: trans_def transp_def)
   425 
   426 lemma transp_equality [simp]: "transp op ="
   427   by (auto intro: transpI)
   428 
   429 lemma trans_empty [simp]: "trans {}"
   430   by (blast intro: transI)
   431 
   432 lemma transp_empty [simp]: "transp (\<lambda>x y. False)"
   433   using trans_empty[to_pred] by (simp add: bot_fun_def)
   434 
   435 lemma trans_singleton [simp]: "trans {(a, a)}"
   436   by (blast intro: transI)
   437 
   438 lemma transp_singleton [simp]: "transp (\<lambda>x y. x = a \<and> y = a)"
   439   by (simp add: transp_def)
   440 
   441 context preorder
   442 begin
   443 
   444 lemma transp_le[simp]: "transp (op \<le>)"
   445 by(auto simp add: transp_def intro: order_trans)
   446 
   447 lemma transp_less[simp]: "transp (op <)"
   448 by(auto simp add: transp_def intro: less_trans)
   449 
   450 lemma transp_ge[simp]: "transp (op \<ge>)"
   451 by(auto simp add: transp_def intro: order_trans)
   452 
   453 lemma transp_gr[simp]: "transp (op >)"
   454 by(auto simp add: transp_def intro: less_trans)
   455 
   456 end
   457 
   458 subsubsection \<open>Totality\<close>
   459 
   460 definition total_on :: "'a set \<Rightarrow> 'a rel \<Rightarrow> bool"
   461   where "total_on A r \<longleftrightarrow> (\<forall>x\<in>A. \<forall>y\<in>A. x \<noteq> y \<longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r)"
   462 
   463 lemma total_onI [intro?]:
   464   "(\<And>x y. \<lbrakk>x \<in> A; y \<in> A; x \<noteq> y\<rbrakk> \<Longrightarrow> (x, y) \<in> r \<or> (y, x) \<in> r) \<Longrightarrow> total_on A r"
   465   unfolding total_on_def by blast
   466 
   467 abbreviation "total \<equiv> total_on UNIV"
   468 
   469 lemma total_on_empty [simp]: "total_on {} r"
   470   by (simp add: total_on_def)
   471 
   472 lemma total_on_singleton [simp]: "total_on {x} {(x, x)}"
   473   unfolding total_on_def by blast
   474 
   475 
   476 subsubsection \<open>Single valued relations\<close>
   477 
   478 definition single_valued :: "('a \<times> 'b) set \<Rightarrow> bool"
   479   where "single_valued r \<longleftrightarrow> (\<forall>x y. (x, y) \<in> r \<longrightarrow> (\<forall>z. (x, z) \<in> r \<longrightarrow> y = z))"
   480 
   481 definition single_valuedp :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> bool"
   482   where "single_valuedp r \<longleftrightarrow> (\<forall>x y. r x y \<longrightarrow> (\<forall>z. r x z \<longrightarrow> y = z))"
   483 
   484 lemma single_valuedp_single_valued_eq [pred_set_conv]:
   485   "single_valuedp (\<lambda>x y. (x, y) \<in> r) \<longleftrightarrow> single_valued r"
   486   by (simp add: single_valued_def single_valuedp_def)
   487 
   488 lemma single_valuedI:
   489   "(\<And>x y. (x, y) \<in> r \<Longrightarrow> (\<And>z. (x, z) \<in> r \<Longrightarrow> y = z)) \<Longrightarrow> single_valued r"
   490   unfolding single_valued_def by blast
   491 
   492 lemma single_valuedpI:
   493   "(\<And>x y. r x y \<Longrightarrow> (\<And>z. r x z \<Longrightarrow> y = z)) \<Longrightarrow> single_valuedp r"
   494   by (fact single_valuedI [to_pred])
   495 
   496 lemma single_valuedD:
   497   "single_valued r \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (x, z) \<in> r \<Longrightarrow> y = z"
   498   by (simp add: single_valued_def)
   499 
   500 lemma single_valuedpD:
   501   "single_valuedp r \<Longrightarrow> r x y \<Longrightarrow> r x z \<Longrightarrow> y = z"
   502   by (fact single_valuedD [to_pred])
   503 
   504 lemma single_valued_empty [simp]:
   505   "single_valued {}"
   506   by (simp add: single_valued_def)
   507 
   508 lemma single_valuedp_bot [simp]:
   509   "single_valuedp \<bottom>"
   510   by (fact single_valued_empty [to_pred])
   511 
   512 lemma single_valued_subset:
   513   "r \<subseteq> s \<Longrightarrow> single_valued s \<Longrightarrow> single_valued r"
   514   unfolding single_valued_def by blast
   515 
   516 lemma single_valuedp_less_eq:
   517   "r \<le> s \<Longrightarrow> single_valuedp s \<Longrightarrow> single_valuedp r"
   518   by (fact single_valued_subset [to_pred])
   519 
   520 
   521 subsection \<open>Relation operations\<close>
   522 
   523 subsubsection \<open>The identity relation\<close>
   524 
   525 definition Id :: "'a rel"
   526   where [code del]: "Id = {p. \<exists>x. p = (x, x)}"
   527 
   528 lemma IdI [intro]: "(a, a) \<in> Id"
   529   by (simp add: Id_def)
   530 
   531 lemma IdE [elim!]: "p \<in> Id \<Longrightarrow> (\<And>x. p = (x, x) \<Longrightarrow> P) \<Longrightarrow> P"
   532   unfolding Id_def by (iprover elim: CollectE)
   533 
   534 lemma pair_in_Id_conv [iff]: "(a, b) \<in> Id \<longleftrightarrow> a = b"
   535   unfolding Id_def by blast
   536 
   537 lemma refl_Id: "refl Id"
   538   by (simp add: refl_on_def)
   539 
   540 lemma antisym_Id: "antisym Id"
   541   \<comment> \<open>A strange result, since \<open>Id\<close> is also symmetric.\<close>
   542   by (simp add: antisym_def)
   543 
   544 lemma sym_Id: "sym Id"
   545   by (simp add: sym_def)
   546 
   547 lemma trans_Id: "trans Id"
   548   by (simp add: trans_def)
   549 
   550 lemma single_valued_Id [simp]: "single_valued Id"
   551   by (unfold single_valued_def) blast
   552 
   553 lemma irrefl_diff_Id [simp]: "irrefl (r - Id)"
   554   by (simp add: irrefl_def)
   555 
   556 lemma trans_diff_Id: "trans r \<Longrightarrow> antisym r \<Longrightarrow> trans (r - Id)"
   557   unfolding antisym_def trans_def by blast
   558 
   559 lemma total_on_diff_Id [simp]: "total_on A (r - Id) = total_on A r"
   560   by (simp add: total_on_def)
   561 
   562 lemma Id_fstsnd_eq: "Id = {x. fst x = snd x}"
   563   by force
   564 
   565 
   566 subsubsection \<open>Diagonal: identity over a set\<close>
   567 
   568 definition Id_on :: "'a set \<Rightarrow> 'a rel"
   569   where "Id_on A = (\<Union>x\<in>A. {(x, x)})"
   570 
   571 lemma Id_on_empty [simp]: "Id_on {} = {}"
   572   by (simp add: Id_on_def)
   573 
   574 lemma Id_on_eqI: "a = b \<Longrightarrow> a \<in> A \<Longrightarrow> (a, b) \<in> Id_on A"
   575   by (simp add: Id_on_def)
   576 
   577 lemma Id_onI [intro!]: "a \<in> A \<Longrightarrow> (a, a) \<in> Id_on A"
   578   by (rule Id_on_eqI) (rule refl)
   579 
   580 lemma Id_onE [elim!]: "c \<in> Id_on A \<Longrightarrow> (\<And>x. x \<in> A \<Longrightarrow> c = (x, x) \<Longrightarrow> P) \<Longrightarrow> P"
   581   \<comment> \<open>The general elimination rule.\<close>
   582   unfolding Id_on_def by (iprover elim!: UN_E singletonE)
   583 
   584 lemma Id_on_iff: "(x, y) \<in> Id_on A \<longleftrightarrow> x = y \<and> x \<in> A"
   585   by blast
   586 
   587 lemma Id_on_def' [nitpick_unfold]: "Id_on {x. A x} = Collect (\<lambda>(x, y). x = y \<and> A x)"
   588   by auto
   589 
   590 lemma Id_on_subset_Times: "Id_on A \<subseteq> A \<times> A"
   591   by blast
   592 
   593 lemma refl_on_Id_on: "refl_on A (Id_on A)"
   594   by (rule refl_onI [OF Id_on_subset_Times Id_onI])
   595 
   596 lemma antisym_Id_on [simp]: "antisym (Id_on A)"
   597   unfolding antisym_def by blast
   598 
   599 lemma sym_Id_on [simp]: "sym (Id_on A)"
   600   by (rule symI) clarify
   601 
   602 lemma trans_Id_on [simp]: "trans (Id_on A)"
   603   by (fast intro: transI elim: transD)
   604 
   605 lemma single_valued_Id_on [simp]: "single_valued (Id_on A)"
   606   unfolding single_valued_def by blast
   607 
   608 
   609 subsubsection \<open>Composition\<close>
   610 
   611 inductive_set relcomp  :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'c) set \<Rightarrow> ('a \<times> 'c) set"  (infixr "O" 75)
   612   for r :: "('a \<times> 'b) set" and s :: "('b \<times> 'c) set"
   613   where relcompI [intro]: "(a, b) \<in> r \<Longrightarrow> (b, c) \<in> s \<Longrightarrow> (a, c) \<in> r O s"
   614 
   615 notation relcompp (infixr "OO" 75)
   616 
   617 lemmas relcomppI = relcompp.intros
   618 
   619 text \<open>
   620   For historic reasons, the elimination rules are not wholly corresponding.
   621   Feel free to consolidate this.
   622 \<close>
   623 
   624 inductive_cases relcompEpair: "(a, c) \<in> r O s"
   625 inductive_cases relcomppE [elim!]: "(r OO s) a c"
   626 
   627 lemma relcompE [elim!]: "xz \<in> r O s \<Longrightarrow>
   628   (\<And>x y z. xz = (x, z) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> (y, z) \<in> s  \<Longrightarrow> P) \<Longrightarrow> P"
   629   apply (cases xz)
   630   apply simp
   631   apply (erule relcompEpair)
   632   apply iprover
   633   done
   634 
   635 lemma R_O_Id [simp]: "R O Id = R"
   636   by fast
   637 
   638 lemma Id_O_R [simp]: "Id O R = R"
   639   by fast
   640 
   641 lemma relcomp_empty1 [simp]: "{} O R = {}"
   642   by blast
   643 
   644 lemma relcompp_bot1 [simp]: "\<bottom> OO R = \<bottom>"
   645   by (fact relcomp_empty1 [to_pred])
   646 
   647 lemma relcomp_empty2 [simp]: "R O {} = {}"
   648   by blast
   649 
   650 lemma relcompp_bot2 [simp]: "R OO \<bottom> = \<bottom>"
   651   by (fact relcomp_empty2 [to_pred])
   652 
   653 lemma O_assoc: "(R O S) O T = R O (S O T)"
   654   by blast
   655 
   656 lemma relcompp_assoc: "(r OO s) OO t = r OO (s OO t)"
   657   by (fact O_assoc [to_pred])
   658 
   659 lemma trans_O_subset: "trans r \<Longrightarrow> r O r \<subseteq> r"
   660   by (unfold trans_def) blast
   661 
   662 lemma transp_relcompp_less_eq: "transp r \<Longrightarrow> r OO r \<le> r "
   663   by (fact trans_O_subset [to_pred])
   664 
   665 lemma relcomp_mono: "r' \<subseteq> r \<Longrightarrow> s' \<subseteq> s \<Longrightarrow> r' O s' \<subseteq> r O s"
   666   by blast
   667 
   668 lemma relcompp_mono: "r' \<le> r \<Longrightarrow> s' \<le> s \<Longrightarrow> r' OO s' \<le> r OO s "
   669   by (fact relcomp_mono [to_pred])
   670 
   671 lemma relcomp_subset_Sigma: "r \<subseteq> A \<times> B \<Longrightarrow> s \<subseteq> B \<times> C \<Longrightarrow> r O s \<subseteq> A \<times> C"
   672   by blast
   673 
   674 lemma relcomp_distrib [simp]: "R O (S \<union> T) = (R O S) \<union> (R O T)"
   675   by auto
   676 
   677 lemma relcompp_distrib [simp]: "R OO (S \<squnion> T) = R OO S \<squnion> R OO T"
   678   by (fact relcomp_distrib [to_pred])
   679 
   680 lemma relcomp_distrib2 [simp]: "(S \<union> T) O R = (S O R) \<union> (T O R)"
   681   by auto
   682 
   683 lemma relcompp_distrib2 [simp]: "(S \<squnion> T) OO R = S OO R \<squnion> T OO R"
   684   by (fact relcomp_distrib2 [to_pred])
   685 
   686 lemma relcomp_UNION_distrib: "s O UNION I r = (\<Union>i\<in>I. s O r i) "
   687   by auto
   688 
   689 lemma relcompp_SUP_distrib: "s OO SUPREMUM I r = (\<Squnion>i\<in>I. s OO r i)"
   690   by (fact relcomp_UNION_distrib [to_pred])
   691     
   692 lemma relcomp_UNION_distrib2: "UNION I r O s = (\<Union>i\<in>I. r i O s) "
   693   by auto
   694 
   695 lemma relcompp_SUP_distrib2: "SUPREMUM I r OO s = (\<Squnion>i\<in>I. r i OO s)"
   696   by (fact relcomp_UNION_distrib2 [to_pred])
   697     
   698 lemma single_valued_relcomp: "single_valued r \<Longrightarrow> single_valued s \<Longrightarrow> single_valued (r O s)"
   699   unfolding single_valued_def by blast
   700 
   701 lemma relcomp_unfold: "r O s = {(x, z). \<exists>y. (x, y) \<in> r \<and> (y, z) \<in> s}"
   702   by (auto simp add: set_eq_iff)
   703 
   704 lemma relcompp_apply: "(R OO S) a c \<longleftrightarrow> (\<exists>b. R a b \<and> S b c)"
   705   unfolding relcomp_unfold [to_pred] ..
   706 
   707 lemma eq_OO: "op = OO R = R"
   708   by blast
   709 
   710 lemma OO_eq: "R OO op = = R"
   711   by blast
   712 
   713 
   714 subsubsection \<open>Converse\<close>
   715 
   716 inductive_set converse :: "('a \<times> 'b) set \<Rightarrow> ('b \<times> 'a) set"  ("(_\<inverse>)" [1000] 999)
   717   for r :: "('a \<times> 'b) set"
   718   where "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   719 
   720 notation conversep  ("(_\<inverse>\<inverse>)" [1000] 1000)
   721 
   722 notation (ASCII)
   723   converse  ("(_^-1)" [1000] 999) and
   724   conversep ("(_^--1)" [1000] 1000)
   725 
   726 lemma converseI [sym]: "(a, b) \<in> r \<Longrightarrow> (b, a) \<in> r\<inverse>"
   727   by (fact converse.intros)
   728 
   729 lemma conversepI (* CANDIDATE [sym] *): "r a b \<Longrightarrow> r\<inverse>\<inverse> b a"
   730   by (fact conversep.intros)
   731 
   732 lemma converseD [sym]: "(a, b) \<in> r\<inverse> \<Longrightarrow> (b, a) \<in> r"
   733   by (erule converse.cases) iprover
   734 
   735 lemma conversepD (* CANDIDATE [sym] *): "r\<inverse>\<inverse> b a \<Longrightarrow> r a b"
   736   by (fact converseD [to_pred])
   737 
   738 lemma converseE [elim!]: "yx \<in> r\<inverse> \<Longrightarrow> (\<And>x y. yx = (y, x) \<Longrightarrow> (x, y) \<in> r \<Longrightarrow> P) \<Longrightarrow> P"
   739   \<comment> \<open>More general than \<open>converseD\<close>, as it ``splits'' the member of the relation.\<close>
   740   apply (cases yx)
   741   apply simp
   742   apply (erule converse.cases)
   743   apply iprover
   744   done
   745 
   746 lemmas conversepE [elim!] = conversep.cases
   747 
   748 lemma converse_iff [iff]: "(a, b) \<in> r\<inverse> \<longleftrightarrow> (b, a) \<in> r"
   749   by (auto intro: converseI)
   750 
   751 lemma conversep_iff [iff]: "r\<inverse>\<inverse> a b = r b a"
   752   by (fact converse_iff [to_pred])
   753 
   754 lemma converse_converse [simp]: "(r\<inverse>)\<inverse> = r"
   755   by (simp add: set_eq_iff)
   756 
   757 lemma conversep_conversep [simp]: "(r\<inverse>\<inverse>)\<inverse>\<inverse> = r"
   758   by (fact converse_converse [to_pred])
   759 
   760 lemma converse_empty[simp]: "{}\<inverse> = {}"
   761   by auto
   762 
   763 lemma converse_UNIV[simp]: "UNIV\<inverse> = UNIV"
   764   by auto
   765 
   766 lemma converse_relcomp: "(r O s)\<inverse> = s\<inverse> O r\<inverse>"
   767   by blast
   768 
   769 lemma converse_relcompp: "(r OO s)\<inverse>\<inverse> = s\<inverse>\<inverse> OO r\<inverse>\<inverse>"
   770   by (iprover intro: order_antisym conversepI relcomppI elim: relcomppE dest: conversepD)
   771 
   772 lemma converse_Int: "(r \<inter> s)\<inverse> = r\<inverse> \<inter> s\<inverse>"
   773   by blast
   774 
   775 lemma converse_meet: "(r \<sqinter> s)\<inverse>\<inverse> = r\<inverse>\<inverse> \<sqinter> s\<inverse>\<inverse>"
   776   by (simp add: inf_fun_def) (iprover intro: conversepI ext dest: conversepD)
   777 
   778 lemma converse_Un: "(r \<union> s)\<inverse> = r\<inverse> \<union> s\<inverse>"
   779   by blast
   780 
   781 lemma converse_join: "(r \<squnion> s)\<inverse>\<inverse> = r\<inverse>\<inverse> \<squnion> s\<inverse>\<inverse>"
   782   by (simp add: sup_fun_def) (iprover intro: conversepI ext dest: conversepD)
   783 
   784 lemma converse_INTER: "(INTER S r)\<inverse> = (INT x:S. (r x)\<inverse>)"
   785   by fast
   786 
   787 lemma converse_UNION: "(UNION S r)\<inverse> = (UN x:S. (r x)\<inverse>)"
   788   by blast
   789 
   790 lemma converse_mono[simp]: "r\<inverse> \<subseteq> s \<inverse> \<longleftrightarrow> r \<subseteq> s"
   791   by auto
   792 
   793 lemma conversep_mono[simp]: "r\<inverse>\<inverse> \<le> s \<inverse>\<inverse> \<longleftrightarrow> r \<le> s"
   794   by (fact converse_mono[to_pred])
   795 
   796 lemma converse_inject[simp]: "r\<inverse> = s \<inverse> \<longleftrightarrow> r = s"
   797   by auto
   798 
   799 lemma conversep_inject[simp]: "r\<inverse>\<inverse> = s \<inverse>\<inverse> \<longleftrightarrow> r = s"
   800   by (fact converse_inject[to_pred])
   801 
   802 lemma converse_subset_swap: "r \<subseteq> s \<inverse> \<longleftrightarrow> r \<inverse> \<subseteq> s"
   803   by auto
   804 
   805 lemma conversep_le_swap: "r \<le> s \<inverse>\<inverse> \<longleftrightarrow> r \<inverse>\<inverse> \<le> s"
   806   by (fact converse_subset_swap[to_pred])
   807 
   808 lemma converse_Id [simp]: "Id\<inverse> = Id"
   809   by blast
   810 
   811 lemma converse_Id_on [simp]: "(Id_on A)\<inverse> = Id_on A"
   812   by blast
   813 
   814 lemma refl_on_converse [simp]: "refl_on A (converse r) = refl_on A r"
   815   by (auto simp: refl_on_def)
   816 
   817 lemma sym_converse [simp]: "sym (converse r) = sym r"
   818   unfolding sym_def by blast
   819 
   820 lemma antisym_converse [simp]: "antisym (converse r) = antisym r"
   821   unfolding antisym_def by blast
   822 
   823 lemma trans_converse [simp]: "trans (converse r) = trans r"
   824   unfolding trans_def by blast
   825 
   826 lemma sym_conv_converse_eq: "sym r \<longleftrightarrow> r\<inverse> = r"
   827   unfolding sym_def by fast
   828 
   829 lemma sym_Un_converse: "sym (r \<union> r\<inverse>)"
   830   unfolding sym_def by blast
   831 
   832 lemma sym_Int_converse: "sym (r \<inter> r\<inverse>)"
   833   unfolding sym_def by blast
   834 
   835 lemma total_on_converse [simp]: "total_on A (r\<inverse>) = total_on A r"
   836   by (auto simp: total_on_def)
   837 
   838 lemma finite_converse [iff]: "finite (r\<inverse>) = finite r"
   839   unfolding converse_def conversep_iff using [[simproc add: finite_Collect]]
   840   by (auto elim: finite_imageD simp: inj_on_def)
   841 
   842 lemma conversep_noteq [simp]: "(op \<noteq>)\<inverse>\<inverse> = op \<noteq>"
   843   by (auto simp add: fun_eq_iff)
   844 
   845 lemma conversep_eq [simp]: "(op =)\<inverse>\<inverse> = op ="
   846   by (auto simp add: fun_eq_iff)
   847 
   848 lemma converse_unfold [code]: "r\<inverse> = {(y, x). (x, y) \<in> r}"
   849   by (simp add: set_eq_iff)
   850 
   851 
   852 subsubsection \<open>Domain, range and field\<close>
   853 
   854 inductive_set Domain :: "('a \<times> 'b) set \<Rightarrow> 'a set" for r :: "('a \<times> 'b) set"
   855   where DomainI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> Domain r"
   856 
   857 lemmas DomainPI = Domainp.DomainI
   858 
   859 inductive_cases DomainE [elim!]: "a \<in> Domain r"
   860 inductive_cases DomainpE [elim!]: "Domainp r a"
   861 
   862 inductive_set Range :: "('a \<times> 'b) set \<Rightarrow> 'b set" for r :: "('a \<times> 'b) set"
   863   where RangeI [intro]: "(a, b) \<in> r \<Longrightarrow> b \<in> Range r"
   864 
   865 lemmas RangePI = Rangep.RangeI
   866 
   867 inductive_cases RangeE [elim!]: "b \<in> Range r"
   868 inductive_cases RangepE [elim!]: "Rangep r b"
   869 
   870 definition Field :: "'a rel \<Rightarrow> 'a set"
   871   where "Field r = Domain r \<union> Range r"
   872 
   873 lemma FieldI1: "(i, j) \<in> R \<Longrightarrow> i \<in> Field R"
   874   unfolding Field_def by blast
   875 
   876 lemma FieldI2: "(i, j) \<in> R \<Longrightarrow> j \<in> Field R"
   877   unfolding Field_def by auto
   878 
   879 lemma Domain_fst [code]: "Domain r = fst ` r"
   880   by force
   881 
   882 lemma Range_snd [code]: "Range r = snd ` r"
   883   by force
   884 
   885 lemma fst_eq_Domain: "fst ` R = Domain R"
   886   by force
   887 
   888 lemma snd_eq_Range: "snd ` R = Range R"
   889   by force
   890 
   891 lemma range_fst [simp]: "range fst = UNIV"
   892   by (auto simp: fst_eq_Domain)
   893 
   894 lemma range_snd [simp]: "range snd = UNIV"
   895   by (auto simp: snd_eq_Range)
   896 
   897 lemma Domain_empty [simp]: "Domain {} = {}"
   898   by auto
   899 
   900 lemma Range_empty [simp]: "Range {} = {}"
   901   by auto
   902 
   903 lemma Field_empty [simp]: "Field {} = {}"
   904   by (simp add: Field_def)
   905 
   906 lemma Domain_empty_iff: "Domain r = {} \<longleftrightarrow> r = {}"
   907   by auto
   908 
   909 lemma Range_empty_iff: "Range r = {} \<longleftrightarrow> r = {}"
   910   by auto
   911 
   912 lemma Domain_insert [simp]: "Domain (insert (a, b) r) = insert a (Domain r)"
   913   by blast
   914 
   915 lemma Range_insert [simp]: "Range (insert (a, b) r) = insert b (Range r)"
   916   by blast
   917 
   918 lemma Field_insert [simp]: "Field (insert (a, b) r) = {a, b} \<union> Field r"
   919   by (auto simp add: Field_def)
   920 
   921 lemma Domain_iff: "a \<in> Domain r \<longleftrightarrow> (\<exists>y. (a, y) \<in> r)"
   922   by blast
   923 
   924 lemma Range_iff: "a \<in> Range r \<longleftrightarrow> (\<exists>y. (y, a) \<in> r)"
   925   by blast
   926 
   927 lemma Domain_Id [simp]: "Domain Id = UNIV"
   928   by blast
   929 
   930 lemma Range_Id [simp]: "Range Id = UNIV"
   931   by blast
   932 
   933 lemma Domain_Id_on [simp]: "Domain (Id_on A) = A"
   934   by blast
   935 
   936 lemma Range_Id_on [simp]: "Range (Id_on A) = A"
   937   by blast
   938 
   939 lemma Domain_Un_eq: "Domain (A \<union> B) = Domain A \<union> Domain B"
   940   by blast
   941 
   942 lemma Range_Un_eq: "Range (A \<union> B) = Range A \<union> Range B"
   943   by blast
   944 
   945 lemma Field_Un [simp]: "Field (r \<union> s) = Field r \<union> Field s"
   946   by (auto simp: Field_def)
   947 
   948 lemma Domain_Int_subset: "Domain (A \<inter> B) \<subseteq> Domain A \<inter> Domain B"
   949   by blast
   950 
   951 lemma Range_Int_subset: "Range (A \<inter> B) \<subseteq> Range A \<inter> Range B"
   952   by blast
   953 
   954 lemma Domain_Diff_subset: "Domain A - Domain B \<subseteq> Domain (A - B)"
   955   by blast
   956 
   957 lemma Range_Diff_subset: "Range A - Range B \<subseteq> Range (A - B)"
   958   by blast
   959 
   960 lemma Domain_Union: "Domain (\<Union>S) = (\<Union>A\<in>S. Domain A)"
   961   by blast
   962 
   963 lemma Range_Union: "Range (\<Union>S) = (\<Union>A\<in>S. Range A)"
   964   by blast
   965 
   966 lemma Field_Union [simp]: "Field (\<Union>R) = \<Union>(Field ` R)"
   967   by (auto simp: Field_def)
   968 
   969 lemma Domain_converse [simp]: "Domain (r\<inverse>) = Range r"
   970   by auto
   971 
   972 lemma Range_converse [simp]: "Range (r\<inverse>) = Domain r"
   973   by blast
   974 
   975 lemma Field_converse [simp]: "Field (r\<inverse>) = Field r"
   976   by (auto simp: Field_def)
   977 
   978 lemma Domain_Collect_case_prod [simp]: "Domain {(x, y). P x y} = {x. \<exists>y. P x y}"
   979   by auto
   980 
   981 lemma Range_Collect_case_prod [simp]: "Range {(x, y). P x y} = {y. \<exists>x. P x y}"
   982   by auto
   983 
   984 lemma finite_Domain: "finite r \<Longrightarrow> finite (Domain r)"
   985   by (induct set: finite) auto
   986 
   987 lemma finite_Range: "finite r \<Longrightarrow> finite (Range r)"
   988   by (induct set: finite) auto
   989 
   990 lemma finite_Field: "finite r \<Longrightarrow> finite (Field r)"
   991   by (simp add: Field_def finite_Domain finite_Range)
   992 
   993 lemma Domain_mono: "r \<subseteq> s \<Longrightarrow> Domain r \<subseteq> Domain s"
   994   by blast
   995 
   996 lemma Range_mono: "r \<subseteq> s \<Longrightarrow> Range r \<subseteq> Range s"
   997   by blast
   998 
   999 lemma mono_Field: "r \<subseteq> s \<Longrightarrow> Field r \<subseteq> Field s"
  1000   by (auto simp: Field_def Domain_def Range_def)
  1001 
  1002 lemma Domain_unfold: "Domain r = {x. \<exists>y. (x, y) \<in> r}"
  1003   by blast
  1004 
  1005 lemma Field_square [simp]: "Field (x \<times> x) = x"
  1006   unfolding Field_def by blast
  1007 
  1008 
  1009 subsubsection \<open>Image of a set under a relation\<close>
  1010 
  1011 definition Image :: "('a \<times> 'b) set \<Rightarrow> 'a set \<Rightarrow> 'b set"  (infixr "``" 90)
  1012   where "r `` s = {y. \<exists>x\<in>s. (x, y) \<in> r}"
  1013 
  1014 lemma Image_iff: "b \<in> r``A \<longleftrightarrow> (\<exists>x\<in>A. (x, b) \<in> r)"
  1015   by (simp add: Image_def)
  1016 
  1017 lemma Image_singleton: "r``{a} = {b. (a, b) \<in> r}"
  1018   by (simp add: Image_def)
  1019 
  1020 lemma Image_singleton_iff [iff]: "b \<in> r``{a} \<longleftrightarrow> (a, b) \<in> r"
  1021   by (rule Image_iff [THEN trans]) simp
  1022 
  1023 lemma ImageI [intro]: "(a, b) \<in> r \<Longrightarrow> a \<in> A \<Longrightarrow> b \<in> r``A"
  1024   unfolding Image_def by blast
  1025 
  1026 lemma ImageE [elim!]: "b \<in> r `` A \<Longrightarrow> (\<And>x. (x, b) \<in> r \<Longrightarrow> x \<in> A \<Longrightarrow> P) \<Longrightarrow> P"
  1027   unfolding Image_def by (iprover elim!: CollectE bexE)
  1028 
  1029 lemma rev_ImageI: "a \<in> A \<Longrightarrow> (a, b) \<in> r \<Longrightarrow> b \<in> r `` A"
  1030   \<comment> \<open>This version's more effective when we already have the required \<open>a\<close>\<close>
  1031   by blast
  1032 
  1033 lemma Image_empty [simp]: "R``{} = {}"
  1034   by blast
  1035 
  1036 lemma Image_Id [simp]: "Id `` A = A"
  1037   by blast
  1038 
  1039 lemma Image_Id_on [simp]: "Id_on A `` B = A \<inter> B"
  1040   by blast
  1041 
  1042 lemma Image_Int_subset: "R `` (A \<inter> B) \<subseteq> R `` A \<inter> R `` B"
  1043   by blast
  1044 
  1045 lemma Image_Int_eq: "single_valued (converse R) \<Longrightarrow> R `` (A \<inter> B) = R `` A \<inter> R `` B"
  1046   by (auto simp: single_valued_def)
  1047 
  1048 lemma Image_Un: "R `` (A \<union> B) = R `` A \<union> R `` B"
  1049   by blast
  1050 
  1051 lemma Un_Image: "(R \<union> S) `` A = R `` A \<union> S `` A"
  1052   by blast
  1053 
  1054 lemma Image_subset: "r \<subseteq> A \<times> B \<Longrightarrow> r``C \<subseteq> B"
  1055   by (iprover intro!: subsetI elim!: ImageE dest!: subsetD SigmaD2)
  1056 
  1057 lemma Image_eq_UN: "r``B = (\<Union>y\<in> B. r``{y})"
  1058   \<comment> \<open>NOT suitable for rewriting\<close>
  1059   by blast
  1060 
  1061 lemma Image_mono: "r' \<subseteq> r \<Longrightarrow> A' \<subseteq> A \<Longrightarrow> (r' `` A') \<subseteq> (r `` A)"
  1062   by blast
  1063 
  1064 lemma Image_UN: "(r `` (UNION A B)) = (\<Union>x\<in>A. r `` (B x))"
  1065   by blast
  1066 
  1067 lemma UN_Image: "(\<Union>i\<in>I. X i) `` S = (\<Union>i\<in>I. X i `` S)"
  1068   by auto
  1069 
  1070 lemma Image_INT_subset: "(r `` INTER A B) \<subseteq> (\<Inter>x\<in>A. r `` (B x))"
  1071   by blast
  1072 
  1073 text \<open>Converse inclusion requires some assumptions\<close>
  1074 lemma Image_INT_eq: "single_valued (r\<inverse>) \<Longrightarrow> A \<noteq> {} \<Longrightarrow> r `` INTER A B = (\<Inter>x\<in>A. r `` B x)"
  1075   apply (rule equalityI)
  1076    apply (rule Image_INT_subset)
  1077   apply (auto simp add: single_valued_def)
  1078   apply blast
  1079   done
  1080 
  1081 lemma Image_subset_eq: "r``A \<subseteq> B \<longleftrightarrow> A \<subseteq> - ((r\<inverse>) `` (- B))"
  1082   by blast
  1083 
  1084 lemma Image_Collect_case_prod [simp]: "{(x, y). P x y} `` A = {y. \<exists>x\<in>A. P x y}"
  1085   by auto
  1086 
  1087 lemma Sigma_Image: "(SIGMA x:A. B x) `` X = (\<Union>x\<in>X \<inter> A. B x)"
  1088   by auto
  1089 
  1090 lemma relcomp_Image: "(X O Y) `` Z = Y `` (X `` Z)"
  1091   by auto
  1092 
  1093 
  1094 subsubsection \<open>Inverse image\<close>
  1095 
  1096 definition inv_image :: "'b rel \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a rel"
  1097   where "inv_image r f = {(x, y). (f x, f y) \<in> r}"
  1098 
  1099 definition inv_imagep :: "('b \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> bool"
  1100   where "inv_imagep r f = (\<lambda>x y. r (f x) (f y))"
  1101 
  1102 lemma [pred_set_conv]: "inv_imagep (\<lambda>x y. (x, y) \<in> r) f = (\<lambda>x y. (x, y) \<in> inv_image r f)"
  1103   by (simp add: inv_image_def inv_imagep_def)
  1104 
  1105 lemma sym_inv_image: "sym r \<Longrightarrow> sym (inv_image r f)"
  1106   unfolding sym_def inv_image_def by blast
  1107 
  1108 lemma trans_inv_image: "trans r \<Longrightarrow> trans (inv_image r f)"
  1109   unfolding trans_def inv_image_def
  1110   apply (simp (no_asm))
  1111   apply blast
  1112   done
  1113 
  1114 lemma in_inv_image[simp]: "(x, y) \<in> inv_image r f \<longleftrightarrow> (f x, f y) \<in> r"
  1115   by (auto simp:inv_image_def)
  1116 
  1117 lemma converse_inv_image[simp]: "(inv_image R f)\<inverse> = inv_image (R\<inverse>) f"
  1118   unfolding inv_image_def converse_unfold by auto
  1119 
  1120 lemma in_inv_imagep [simp]: "inv_imagep r f x y = r (f x) (f y)"
  1121   by (simp add: inv_imagep_def)
  1122 
  1123 
  1124 subsubsection \<open>Powerset\<close>
  1125 
  1126 definition Powp :: "('a \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> bool"
  1127   where "Powp A = (\<lambda>B. \<forall>x \<in> B. A x)"
  1128 
  1129 lemma Powp_Pow_eq [pred_set_conv]: "Powp (\<lambda>x. x \<in> A) = (\<lambda>x. x \<in> Pow A)"
  1130   by (auto simp add: Powp_def fun_eq_iff)
  1131 
  1132 lemmas Powp_mono [mono] = Pow_mono [to_pred]
  1133 
  1134 
  1135 subsubsection \<open>Expressing relation operations via @{const Finite_Set.fold}\<close>
  1136 
  1137 lemma Id_on_fold:
  1138   assumes "finite A"
  1139   shows "Id_on A = Finite_Set.fold (\<lambda>x. Set.insert (Pair x x)) {} A"
  1140 proof -
  1141   interpret comp_fun_commute "\<lambda>x. Set.insert (Pair x x)"
  1142     by standard auto
  1143   from assms show ?thesis
  1144     unfolding Id_on_def by (induct A) simp_all
  1145 qed
  1146 
  1147 lemma comp_fun_commute_Image_fold:
  1148   "comp_fun_commute (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1149 proof -
  1150   interpret comp_fun_idem Set.insert
  1151     by (fact comp_fun_idem_insert)
  1152   show ?thesis
  1153     by standard (auto simp: fun_eq_iff comp_fun_commute split: prod.split)
  1154 qed
  1155 
  1156 lemma Image_fold:
  1157   assumes "finite R"
  1158   shows "R `` S = Finite_Set.fold (\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A) {} R"
  1159 proof -
  1160   interpret comp_fun_commute "(\<lambda>(x,y) A. if x \<in> S then Set.insert y A else A)"
  1161     by (rule comp_fun_commute_Image_fold)
  1162   have *: "\<And>x F. Set.insert x F `` S = (if fst x \<in> S then Set.insert (snd x) (F `` S) else (F `` S))"
  1163     by (force intro: rev_ImageI)
  1164   show ?thesis
  1165     using assms by (induct R) (auto simp: *)
  1166 qed
  1167 
  1168 lemma insert_relcomp_union_fold:
  1169   assumes "finite S"
  1170   shows "{x} O S \<union> X = Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') X S"
  1171 proof -
  1172   interpret comp_fun_commute "\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A'"
  1173   proof -
  1174     interpret comp_fun_idem Set.insert
  1175       by (fact comp_fun_idem_insert)
  1176     show "comp_fun_commute (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A')"
  1177       by standard (auto simp add: fun_eq_iff split: prod.split)
  1178   qed
  1179   have *: "{x} O S = {(x', z). x' = fst x \<and> (snd x, z) \<in> S}"
  1180     by (auto simp: relcomp_unfold intro!: exI)
  1181   show ?thesis
  1182     unfolding * using \<open>finite S\<close> by (induct S) (auto split: prod.split)
  1183 qed
  1184 
  1185 lemma insert_relcomp_fold:
  1186   assumes "finite S"
  1187   shows "Set.insert x R O S =
  1188     Finite_Set.fold (\<lambda>(w,z) A'. if snd x = w then Set.insert (fst x,z) A' else A') (R O S) S"
  1189 proof -
  1190   have "Set.insert x R O S = ({x} O S) \<union> (R O S)"
  1191     by auto
  1192   then show ?thesis
  1193     by (auto simp: insert_relcomp_union_fold [OF assms])
  1194 qed
  1195 
  1196 lemma comp_fun_commute_relcomp_fold:
  1197   assumes "finite S"
  1198   shows "comp_fun_commute (\<lambda>(x,y) A.
  1199     Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S)"
  1200 proof -
  1201   have *: "\<And>a b A.
  1202     Finite_Set.fold (\<lambda>(w, z) A'. if b = w then Set.insert (a, z) A' else A') A S = {(a,b)} O S \<union> A"
  1203     by (auto simp: insert_relcomp_union_fold[OF assms] cong: if_cong)
  1204   show ?thesis
  1205     by standard (auto simp: *)
  1206 qed
  1207 
  1208 lemma relcomp_fold:
  1209   assumes "finite R" "finite S"
  1210   shows "R O S = Finite_Set.fold
  1211     (\<lambda>(x,y) A. Finite_Set.fold (\<lambda>(w,z) A'. if y = w then Set.insert (x,z) A' else A') A S) {} R"
  1212   using assms
  1213   by (induct R)
  1214     (auto simp: comp_fun_commute.fold_insert comp_fun_commute_relcomp_fold insert_relcomp_fold
  1215       cong: if_cong)
  1216 
  1217 end