src/Pure/sign.ML
author wenzelm
Tue Sep 26 20:54:40 2017 +0200 (22 months ago)
changeset 66695 91500c024c7f
parent 66245 da3b0e848182
child 70364 b2bedb022a75
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val change_begin: theory -> theory
    11   val change_end: theory -> theory
    12   val change_end_local: Proof.context -> Proof.context
    13   val change_check: theory -> theory
    14   val syn_of: theory -> Syntax.syntax
    15   val tsig_of: theory -> Type.tsig
    16   val classes_of: theory -> Sorts.algebra
    17   val all_classes: theory -> class list
    18   val super_classes: theory -> class -> class list
    19   val minimize_sort: theory -> sort -> sort
    20   val complete_sort: theory -> sort -> sort
    21   val set_defsort: sort -> theory -> theory
    22   val defaultS: theory -> sort
    23   val subsort: theory -> sort * sort -> bool
    24   val of_sort: theory -> typ * sort -> bool
    25   val inter_sort: theory -> sort * sort -> sort
    26   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    27   val logical_types: theory -> string list
    28   val typ_instance: theory -> typ * typ -> bool
    29   val typ_equiv: theory -> typ * typ -> bool
    30   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    31   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    32   val consts_of: theory -> Consts.T
    33   val the_const_constraint: theory -> string -> typ
    34   val const_type: theory -> string -> typ option
    35   val the_const_type: theory -> string -> typ
    36   val declared_tyname: theory -> string -> bool
    37   val declared_const: theory -> string -> bool
    38   val naming_of: theory -> Name_Space.naming
    39   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    40   val restore_naming: theory -> theory -> theory
    41   val inherit_naming: theory -> Proof.context -> Context.generic
    42   val full_name: theory -> binding -> string
    43   val full_name_path: theory -> string -> binding -> string
    44   val full_bname: theory -> bstring -> string
    45   val full_bname_path: theory -> string -> bstring -> string
    46   val const_monomorphic: theory -> string -> bool
    47   val const_typargs: theory -> string * typ -> typ list
    48   val const_instance: theory -> string * typ list -> typ
    49   val mk_const: theory -> string * typ list -> term
    50   val class_space: theory -> Name_Space.T
    51   val type_space: theory -> Name_Space.T
    52   val const_space: theory -> Name_Space.T
    53   val intern_class: theory -> xstring -> string
    54   val intern_type: theory -> xstring -> string
    55   val intern_const: theory -> xstring -> string
    56   val type_alias: binding -> string -> theory -> theory
    57   val const_alias: binding -> string -> theory -> theory
    58   val arity_number: theory -> string -> int
    59   val arity_sorts: theory -> string -> sort -> sort list
    60   val certify_class: theory -> class -> class
    61   val certify_sort: theory -> sort -> sort
    62   val certify_typ: theory -> typ -> typ
    63   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    64   val certify': bool -> Context.generic -> bool -> Consts.T -> theory -> term -> term * typ * int
    65   val certify_term: theory -> term -> term * typ * int
    66   val cert_term: theory -> term -> term
    67   val cert_prop: theory -> term -> term
    68   val no_frees: Proof.context -> term -> term
    69   val no_vars: Proof.context -> term -> term
    70   val add_type: Proof.context -> binding * int * mixfix -> theory -> theory
    71   val add_types_global: (binding * int * mixfix) list -> theory -> theory
    72   val add_nonterminals: Proof.context -> binding list -> theory -> theory
    73   val add_nonterminals_global: binding list -> theory -> theory
    74   val add_type_abbrev: Proof.context -> binding * string list * typ -> theory -> theory
    75   val add_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    76   val add_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    77   val del_syntax: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    78   val del_syntax_cmd: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    79   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    80   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    81   val declare_const: Proof.context -> (binding * typ) * mixfix -> theory -> term * theory
    82   val declare_const_global: (binding * typ) * mixfix -> theory -> term * theory
    83   val add_consts: (binding * typ * mixfix) list -> theory -> theory
    84   val add_consts_cmd: (binding * string * mixfix) list -> theory -> theory
    85   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    86   val revert_abbrev: string -> string -> theory -> theory
    87   val add_const_constraint: string * typ option -> theory -> theory
    88   val primitive_class: binding * class list -> theory -> theory
    89   val primitive_classrel: class * class -> theory -> theory
    90   val primitive_arity: arity -> theory -> theory
    91   val parse_ast_translation:
    92     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
    93   val parse_translation:
    94     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    95   val print_translation:
    96     (string * (Proof.context -> term list -> term)) list -> theory -> theory
    97   val typed_print_translation:
    98     (string * (Proof.context -> typ -> term list -> term)) list -> theory -> theory
    99   val print_ast_translation:
   100     (string * (Proof.context -> Ast.ast list -> Ast.ast)) list -> theory -> theory
   101   val add_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   102   val del_trrules: Ast.ast Syntax.trrule list -> theory -> theory
   103   val get_scope: theory -> Binding.scope option
   104   val new_scope: theory -> Binding.scope * theory
   105   val new_group: theory -> theory
   106   val reset_group: theory -> theory
   107   val add_path: string -> theory -> theory
   108   val root_path: theory -> theory
   109   val parent_path: theory -> theory
   110   val mandatory_path: string -> theory -> theory
   111   val qualified_path: bool -> binding -> theory -> theory
   112   val local_path: theory -> theory
   113   val private_scope: Binding.scope -> theory -> theory
   114   val private: Position.T -> theory -> theory
   115   val qualified_scope: Binding.scope -> theory -> theory
   116   val qualified: Position.T -> theory -> theory
   117   val concealed: theory -> theory
   118   val hide_class: bool -> string -> theory -> theory
   119   val hide_type: bool -> string -> theory -> theory
   120   val hide_const: bool -> string -> theory -> theory
   121 end
   122 
   123 structure Sign: SIGN =
   124 struct
   125 
   126 (** datatype sign **)
   127 
   128 datatype sign = Sign of
   129  {syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   130   tsig: Type.tsig,              (*order-sorted signature of types*)
   131   consts: Consts.T};            (*polymorphic constants*)
   132 
   133 fun make_sign (syn, tsig, consts) = Sign {syn = syn, tsig = tsig, consts = consts};
   134 
   135 structure Data = Theory_Data'
   136 (
   137   type T = sign;
   138   fun extend (Sign {syn, tsig, consts, ...}) = make_sign (syn, tsig, consts);
   139 
   140   val empty = make_sign (Syntax.empty_syntax, Type.empty_tsig, Consts.empty);
   141 
   142   fun merge old_thys (sign1, sign2) =
   143     let
   144       val Sign {syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   145       val Sign {syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   146 
   147       val syn = Syntax.merge_syntax (syn1, syn2);
   148       val tsig = Type.merge_tsig (Context.Theory (fst old_thys)) (tsig1, tsig2);
   149       val consts = Consts.merge (consts1, consts2);
   150     in make_sign (syn, tsig, consts) end;
   151 );
   152 
   153 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   154 
   155 fun map_sign f = Data.map (fn Sign {syn, tsig, consts} => make_sign (f (syn, tsig, consts)));
   156 
   157 fun map_syn f = map_sign (fn (syn, tsig, consts) => (f syn, tsig, consts));
   158 fun map_tsig f = map_sign (fn (syn, tsig, consts) => (syn, f tsig, consts));
   159 fun map_consts f = map_sign (fn (syn, tsig, consts) => (syn, tsig, f consts));
   160 
   161 
   162 (* linear change discipline *)
   163 
   164 fun change_base begin = map_sign (fn (syn, tsig, consts) =>
   165   (syn, Type.change_base begin tsig, Consts.change_base begin consts));
   166 
   167 val change_begin = change_base true;
   168 val change_end = change_base false;
   169 
   170 fun change_end_local ctxt =
   171   Context.raw_transfer (change_end (Proof_Context.theory_of ctxt)) ctxt;
   172 
   173 fun change_check thy =
   174   if can change_end thy
   175   then raise Fail "Unfinished linear change of theory content" else thy;
   176 
   177 
   178 (* syntax *)
   179 
   180 val syn_of = #syn o rep_sg;
   181 
   182 
   183 (* type signature *)
   184 
   185 val tsig_of = #tsig o rep_sg;
   186 
   187 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   188 val all_classes = Sorts.all_classes o classes_of;
   189 val super_classes = Sorts.super_classes o classes_of;
   190 val minimize_sort = Sorts.minimize_sort o classes_of;
   191 val complete_sort = Sorts.complete_sort o classes_of;
   192 
   193 val set_defsort = map_tsig o Type.set_defsort;
   194 val defaultS = Type.defaultS o tsig_of;
   195 val subsort = Type.subsort o tsig_of;
   196 val of_sort = Type.of_sort o tsig_of;
   197 val inter_sort = Type.inter_sort o tsig_of;
   198 val witness_sorts = Type.witness_sorts o tsig_of;
   199 val logical_types = Type.logical_types o tsig_of;
   200 
   201 val typ_instance = Type.typ_instance o tsig_of;
   202 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   203 val typ_match = Type.typ_match o tsig_of;
   204 val typ_unify = Type.unify o tsig_of;
   205 
   206 
   207 (* polymorphic constants *)
   208 
   209 val consts_of = #consts o rep_sg;
   210 val the_const_constraint = Consts.the_constraint o consts_of;
   211 val the_const_type = #2 oo (Consts.the_const o consts_of);
   212 val const_type = try o the_const_type;
   213 val const_monomorphic = Consts.is_monomorphic o consts_of;
   214 val const_typargs = Consts.typargs o consts_of;
   215 val const_instance = Consts.instance o consts_of;
   216 
   217 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   218 
   219 fun declared_tyname ctxt c = can (Type.the_decl (tsig_of ctxt)) (c, Position.none);
   220 val declared_const = can o the_const_constraint;
   221 
   222 
   223 (* naming *)
   224 
   225 val naming_of = Name_Space.naming_of o Context.Theory;
   226 val map_naming = Context.theory_map o Name_Space.map_naming;
   227 val restore_naming = map_naming o K o naming_of;
   228 fun inherit_naming thy = Name_Space.map_naming (K (naming_of thy)) o Context.Proof;
   229 
   230 val full_name = Name_Space.full_name o naming_of;
   231 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   232 
   233 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   234 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   235 
   236 
   237 
   238 (** name spaces **)
   239 
   240 val class_space = Type.class_space o tsig_of;
   241 val type_space = Type.type_space o tsig_of;
   242 val const_space = Consts.space_of o consts_of;
   243 
   244 val intern_class = Name_Space.intern o class_space;
   245 val intern_type = Name_Space.intern o type_space;
   246 val intern_const = Name_Space.intern o const_space;
   247 
   248 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   249 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   250 
   251 
   252 
   253 (** certify entities **)    (*exception TYPE*)
   254 
   255 (* certify wrt. type signature *)
   256 
   257 val arity_number = Type.arity_number o tsig_of;
   258 fun arity_sorts thy = Type.arity_sorts (Context.Theory thy) (tsig_of thy);
   259 
   260 val certify_class = Type.cert_class o tsig_of;
   261 val certify_sort = Type.cert_sort o tsig_of;
   262 val certify_typ = Type.cert_typ o tsig_of;
   263 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   264 
   265 
   266 (* certify term/prop *)
   267 
   268 local
   269 
   270 fun type_check context tm =
   271   let
   272     fun err_appl bs t T u U =
   273       let
   274         val xs = map Free bs;           (*we do not rename here*)
   275         val t' = subst_bounds (xs, t);
   276         val u' = subst_bounds (xs, u);
   277         val msg = Type.appl_error (Syntax.init_pretty context) t' T u' U;
   278       in raise TYPE (msg, [T, U], [t', u']) end;
   279 
   280     fun typ_of (_, Const (_, T)) = T
   281       | typ_of (_, Free  (_, T)) = T
   282       | typ_of (_, Var (_, T)) = T
   283       | typ_of (bs, Bound i) = snd (nth bs i handle General.Subscript =>
   284           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   285       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   286       | typ_of (bs, t $ u) =
   287           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   288             (case T of
   289               Type ("fun", [T1, T2]) =>
   290                 if T1 = U then T2 else err_appl bs t T u U
   291             | _ => err_appl bs t T u U)
   292           end;
   293   in typ_of ([], tm) end;
   294 
   295 fun err msg = raise TYPE (msg, [], []);
   296 
   297 fun check_vars (t $ u) = (check_vars t; check_vars u)
   298   | check_vars (Abs (_, _, t)) = check_vars t
   299   | check_vars (Free (x, _)) =
   300       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   301   | check_vars (Var (xi as (_, i), _)) =
   302       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   303   | check_vars _ = ();
   304 
   305 in
   306 
   307 fun certify' prop context do_expand consts thy tm =
   308   let
   309     val _ = check_vars tm;
   310     val tm' = Term.map_types (certify_typ thy) tm;
   311     val T = type_check context tm';
   312     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   313     val tm'' = Consts.certify context (tsig_of thy) do_expand consts tm';
   314   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   315 
   316 fun certify_term thy = certify' false (Context.Theory thy) true (consts_of thy) thy;
   317 fun cert_term_abbrev thy = #1 o certify' false (Context.Theory thy) false (consts_of thy) thy;
   318 val cert_term = #1 oo certify_term;
   319 fun cert_prop thy = #1 o certify' true (Context.Theory thy) true (consts_of thy) thy;
   320 
   321 end;
   322 
   323 
   324 (* specifications *)
   325 
   326 fun no_variables kind add addT mk mkT ctxt tm =
   327   (case (add tm [], addT tm []) of
   328     ([], []) => tm
   329   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   330       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   331        Pretty.commas
   332         (map (Syntax.pretty_term ctxt o mk) frees @ map (Syntax.pretty_typ ctxt o mkT) tfrees)))));
   333 
   334 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   335 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   336 
   337 
   338 
   339 (** signature extension functions **)  (*exception ERROR/TYPE*)
   340 
   341 (* add type constructors *)
   342 
   343 fun add_type ctxt (b, n, mx) thy = thy |> map_sign (fn (syn, tsig, consts) =>
   344   let
   345     val type_syntax = (Lexicon.mark_type (full_name thy b), Mixfix.make_type n, mx);
   346     val syn' = Syntax.update_type_gram true Syntax.mode_default [type_syntax] syn;
   347     val tsig' = Type.add_type (inherit_naming thy ctxt) (b, n) tsig;
   348   in (syn', tsig', consts) end);
   349 
   350 fun add_types_global types thy =
   351   fold (add_type (Syntax.init_pretty_global thy)) types thy;
   352 
   353 
   354 (* add nonterminals *)
   355 
   356 fun add_nonterminals ctxt ns thy = thy |> map_sign (fn (syn, tsig, consts) =>
   357   (syn, fold (Type.add_nonterminal (inherit_naming thy ctxt)) ns tsig, consts));
   358 
   359 fun add_nonterminals_global ns thy =
   360   add_nonterminals (Syntax.init_pretty_global thy) ns thy;
   361 
   362 
   363 (* add type abbreviations *)
   364 
   365 fun add_type_abbrev ctxt abbr thy = thy |> map_sign (fn (syn, tsig, consts) =>
   366   (syn, Type.add_abbrev (inherit_naming thy ctxt) abbr tsig, consts));
   367 
   368 
   369 (* modify syntax *)
   370 
   371 fun gen_syntax change_gram parse_typ mode args thy =
   372   let
   373     val ctxt = Type.set_mode Type.mode_syntax (Proof_Context.init_global thy);
   374     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   375       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   376   in thy |> map_syn (change_gram (logical_types thy) mode (map prep args)) end;
   377 
   378 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   379 
   380 val add_syntax = gen_add_syntax (K I);
   381 val add_syntax_cmd = gen_add_syntax Syntax.read_typ;
   382 val del_syntax = gen_syntax (Syntax.update_const_gram false) (K I);
   383 val del_syntax_cmd = gen_syntax (Syntax.update_const_gram false) Syntax.read_typ;
   384 
   385 fun type_notation add mode args =
   386   let
   387     fun type_syntax (Type (c, args), mx) =
   388           SOME (Lexicon.mark_type c, Mixfix.make_type (length args), mx)
   389       | type_syntax _ = NONE;
   390   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   391 
   392 fun notation add mode args thy =
   393   let
   394     fun const_syntax (Const (c, _), mx) =
   395           (case try (Consts.type_scheme (consts_of thy)) c of
   396             SOME T => SOME (Lexicon.mark_const c, T, mx)
   397           | NONE => NONE)
   398       | const_syntax _ = NONE;
   399   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   400 
   401 
   402 (* add constants *)
   403 
   404 local
   405 
   406 fun gen_add_consts prep_typ ctxt raw_args thy =
   407   let
   408     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o prep_typ ctxt;
   409     fun prep (b, raw_T, mx) =
   410       let
   411         val c = full_name thy b;
   412         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   413           cat_error msg ("in declaration of constant " ^ Binding.print b);
   414         val T' = Logic.varifyT_global T;
   415       in ((b, T'), (Lexicon.mark_const c, T', mx), Const (c, T)) end;
   416     val args = map prep raw_args;
   417   in
   418     thy
   419     |> map_consts (fold (Consts.declare (inherit_naming thy ctxt) o #1) args)
   420     |> add_syntax Syntax.mode_default (map #2 args)
   421     |> pair (map #3 args)
   422   end;
   423 
   424 in
   425 
   426 fun add_consts args thy =
   427   #2 (gen_add_consts (K I) (Proof_Context.init_global thy) args thy);
   428 
   429 fun add_consts_cmd args thy =
   430   #2 (gen_add_consts Syntax.read_typ (Proof_Context.init_global thy) args thy);
   431 
   432 fun declare_const ctxt ((b, T), mx) = yield_singleton (gen_add_consts (K I) ctxt) (b, T, mx);
   433 fun declare_const_global arg thy = declare_const (Proof_Context.init_global thy) arg thy;
   434 
   435 end;
   436 
   437 
   438 (* abbreviations *)
   439 
   440 fun add_abbrev mode (b, raw_t) thy =  (* FIXME proper ctxt (?) *)
   441   let
   442     val ctxt = Syntax.init_pretty_global thy;
   443     val prep_tm = no_frees ctxt o Term.no_dummy_patterns o cert_term_abbrev thy;
   444     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   445       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ Binding.print b);
   446     val (res, consts') = consts_of thy
   447       |> Consts.abbreviate (inherit_naming thy ctxt) (tsig_of thy) mode (b, t);
   448   in (res, thy |> map_consts (K consts')) end;
   449 
   450 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   451 
   452 
   453 (* add constraints *)
   454 
   455 fun add_const_constraint (c, opt_T) thy =
   456   let
   457     fun prepT raw_T =
   458       let val T = Logic.varifyT_global (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   459       in cert_term thy (Const (c, T)); T end
   460       handle TYPE (msg, _, _) => error msg;
   461   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   462 
   463 
   464 (* primitive classes and arities *)
   465 
   466 fun primitive_class (bclass, classes) thy =
   467   thy
   468   |> map_sign (fn (syn, tsig, consts) =>
   469       let val tsig' = Type.add_class (Context.Theory thy) (bclass, classes) tsig;
   470       in (syn, tsig', consts) end)
   471   |> add_consts [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   472 
   473 fun primitive_classrel arg thy =
   474   thy |> map_tsig (Type.add_classrel (Context.Theory thy) arg);
   475 
   476 fun primitive_arity arg thy =
   477   thy |> map_tsig (Type.add_arity (Context.Theory thy) arg);
   478 
   479 
   480 (* add translation functions *)
   481 
   482 local
   483 
   484 fun mk trs = map Syntax_Ext.mk_trfun trs;
   485 
   486 in
   487 
   488 fun parse_ast_translation atrs = map_syn (Syntax.update_trfuns (mk atrs, [], [], []));
   489 fun parse_translation trs = map_syn (Syntax.update_trfuns ([], mk trs, [], []));
   490 fun print_translation tr's =
   491   map_syn (Syntax.update_trfuns ([], [], mk (map (apsnd Syntax_Trans.non_typed_tr') tr's), []));
   492 fun typed_print_translation tr's = map_syn (Syntax.update_trfuns ([], [], mk tr's, []));
   493 fun print_ast_translation atr's = map_syn (Syntax.update_trfuns ([], [], [], mk atr's));
   494 
   495 end;
   496 
   497 
   498 (* translation rules *)
   499 
   500 val add_trrules = map_syn o Syntax.update_trrules;
   501 val del_trrules = map_syn o Syntax.remove_trrules;
   502 
   503 
   504 (* naming *)
   505 
   506 val get_scope = Name_Space.get_scope o naming_of;
   507 
   508 fun new_scope thy =
   509   let
   510     val (scope, naming') = Name_Space.new_scope (naming_of thy);
   511     val thy' = map_naming (K naming') thy;
   512   in (scope, thy') end;
   513 
   514 val new_group = map_naming Name_Space.new_group;
   515 val reset_group = map_naming Name_Space.reset_group;
   516 
   517 val add_path = map_naming o Name_Space.add_path;
   518 val root_path = map_naming Name_Space.root_path;
   519 val parent_path = map_naming Name_Space.parent_path;
   520 val mandatory_path = map_naming o Name_Space.mandatory_path;
   521 val qualified_path = map_naming oo Name_Space.qualified_path;
   522 
   523 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   524 
   525 val private_scope = map_naming o Name_Space.private_scope;
   526 val private = map_naming o Name_Space.private;
   527 val qualified_scope = map_naming o Name_Space.qualified_scope;
   528 val qualified = map_naming o Name_Space.qualified;
   529 val concealed = map_naming Name_Space.concealed;
   530 
   531 
   532 (* hide names *)
   533 
   534 val hide_class = map_tsig oo Type.hide_class;
   535 val hide_type = map_tsig oo Type.hide_type;
   536 val hide_const = map_consts oo Consts.hide;
   537 
   538 end;