src/HOL/Topological_Spaces.thy
author hoelzl
Thu Apr 25 10:35:56 2013 +0200 (2013-04-25)
changeset 51774 916271d52466
parent 51773 9328c6681f3c
child 51775 408d937c9486
permissions -rw-r--r--
renamed linear_continuum_topology to connected_linorder_topology (and mention in NEWS)
     1 (*  Title:      HOL/Basic_Topology.thy
     2     Author:     Brian Huffman
     3     Author:     Johannes Hölzl
     4 *)
     5 
     6 header {* Topological Spaces *}
     7 
     8 theory Topological_Spaces
     9 imports Main Conditionally_Complete_Lattices
    10 begin
    11 
    12 subsection {* Topological space *}
    13 
    14 class "open" =
    15   fixes "open" :: "'a set \<Rightarrow> bool"
    16 
    17 class topological_space = "open" +
    18   assumes open_UNIV [simp, intro]: "open UNIV"
    19   assumes open_Int [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<inter> T)"
    20   assumes open_Union [intro]: "\<forall>S\<in>K. open S \<Longrightarrow> open (\<Union> K)"
    21 begin
    22 
    23 definition
    24   closed :: "'a set \<Rightarrow> bool" where
    25   "closed S \<longleftrightarrow> open (- S)"
    26 
    27 lemma open_empty [intro, simp]: "open {}"
    28   using open_Union [of "{}"] by simp
    29 
    30 lemma open_Un [intro]: "open S \<Longrightarrow> open T \<Longrightarrow> open (S \<union> T)"
    31   using open_Union [of "{S, T}"] by simp
    32 
    33 lemma open_UN [intro]: "\<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Union>x\<in>A. B x)"
    34   unfolding SUP_def by (rule open_Union) auto
    35 
    36 lemma open_Inter [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. open T \<Longrightarrow> open (\<Inter>S)"
    37   by (induct set: finite) auto
    38 
    39 lemma open_INT [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. open (B x) \<Longrightarrow> open (\<Inter>x\<in>A. B x)"
    40   unfolding INF_def by (rule open_Inter) auto
    41 
    42 lemma openI:
    43   assumes "\<And>x. x \<in> S \<Longrightarrow> \<exists>T. open T \<and> x \<in> T \<and> T \<subseteq> S"
    44   shows "open S"
    45 proof -
    46   have "open (\<Union>{T. open T \<and> T \<subseteq> S})" by auto
    47   moreover have "\<Union>{T. open T \<and> T \<subseteq> S} = S" by (auto dest!: assms)
    48   ultimately show "open S" by simp
    49 qed
    50 
    51 lemma closed_empty [intro, simp]:  "closed {}"
    52   unfolding closed_def by simp
    53 
    54 lemma closed_Un [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<union> T)"
    55   unfolding closed_def by auto
    56 
    57 lemma closed_UNIV [intro, simp]: "closed UNIV"
    58   unfolding closed_def by simp
    59 
    60 lemma closed_Int [intro]: "closed S \<Longrightarrow> closed T \<Longrightarrow> closed (S \<inter> T)"
    61   unfolding closed_def by auto
    62 
    63 lemma closed_INT [intro]: "\<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Inter>x\<in>A. B x)"
    64   unfolding closed_def by auto
    65 
    66 lemma closed_Inter [intro]: "\<forall>S\<in>K. closed S \<Longrightarrow> closed (\<Inter> K)"
    67   unfolding closed_def uminus_Inf by auto
    68 
    69 lemma closed_Union [intro]: "finite S \<Longrightarrow> \<forall>T\<in>S. closed T \<Longrightarrow> closed (\<Union>S)"
    70   by (induct set: finite) auto
    71 
    72 lemma closed_UN [intro]: "finite A \<Longrightarrow> \<forall>x\<in>A. closed (B x) \<Longrightarrow> closed (\<Union>x\<in>A. B x)"
    73   unfolding SUP_def by (rule closed_Union) auto
    74 
    75 lemma open_closed: "open S \<longleftrightarrow> closed (- S)"
    76   unfolding closed_def by simp
    77 
    78 lemma closed_open: "closed S \<longleftrightarrow> open (- S)"
    79   unfolding closed_def by simp
    80 
    81 lemma open_Diff [intro]: "open S \<Longrightarrow> closed T \<Longrightarrow> open (S - T)"
    82   unfolding closed_open Diff_eq by (rule open_Int)
    83 
    84 lemma closed_Diff [intro]: "closed S \<Longrightarrow> open T \<Longrightarrow> closed (S - T)"
    85   unfolding open_closed Diff_eq by (rule closed_Int)
    86 
    87 lemma open_Compl [intro]: "closed S \<Longrightarrow> open (- S)"
    88   unfolding closed_open .
    89 
    90 lemma closed_Compl [intro]: "open S \<Longrightarrow> closed (- S)"
    91   unfolding open_closed .
    92 
    93 end
    94 
    95 subsection{* Hausdorff and other separation properties *}
    96 
    97 class t0_space = topological_space +
    98   assumes t0_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> \<not> (x \<in> U \<longleftrightarrow> y \<in> U)"
    99 
   100 class t1_space = topological_space +
   101   assumes t1_space: "x \<noteq> y \<Longrightarrow> \<exists>U. open U \<and> x \<in> U \<and> y \<notin> U"
   102 
   103 instance t1_space \<subseteq> t0_space
   104 proof qed (fast dest: t1_space)
   105 
   106 lemma separation_t1:
   107   fixes x y :: "'a::t1_space"
   108   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> x \<in> U \<and> y \<notin> U)"
   109   using t1_space[of x y] by blast
   110 
   111 lemma closed_singleton:
   112   fixes a :: "'a::t1_space"
   113   shows "closed {a}"
   114 proof -
   115   let ?T = "\<Union>{S. open S \<and> a \<notin> S}"
   116   have "open ?T" by (simp add: open_Union)
   117   also have "?T = - {a}"
   118     by (simp add: set_eq_iff separation_t1, auto)
   119   finally show "closed {a}" unfolding closed_def .
   120 qed
   121 
   122 lemma closed_insert [simp]:
   123   fixes a :: "'a::t1_space"
   124   assumes "closed S" shows "closed (insert a S)"
   125 proof -
   126   from closed_singleton assms
   127   have "closed ({a} \<union> S)" by (rule closed_Un)
   128   thus "closed (insert a S)" by simp
   129 qed
   130 
   131 lemma finite_imp_closed:
   132   fixes S :: "'a::t1_space set"
   133   shows "finite S \<Longrightarrow> closed S"
   134 by (induct set: finite, simp_all)
   135 
   136 text {* T2 spaces are also known as Hausdorff spaces. *}
   137 
   138 class t2_space = topological_space +
   139   assumes hausdorff: "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   140 
   141 instance t2_space \<subseteq> t1_space
   142 proof qed (fast dest: hausdorff)
   143 
   144 lemma separation_t2:
   145   fixes x y :: "'a::t2_space"
   146   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {})"
   147   using hausdorff[of x y] by blast
   148 
   149 lemma separation_t0:
   150   fixes x y :: "'a::t0_space"
   151   shows "x \<noteq> y \<longleftrightarrow> (\<exists>U. open U \<and> ~(x\<in>U \<longleftrightarrow> y\<in>U))"
   152   using t0_space[of x y] by blast
   153 
   154 text {* A perfect space is a topological space with no isolated points. *}
   155 
   156 class perfect_space = topological_space +
   157   assumes not_open_singleton: "\<not> open {x}"
   158 
   159 
   160 subsection {* Generators for toplogies *}
   161 
   162 inductive generate_topology for S where
   163   UNIV: "generate_topology S UNIV"
   164 | Int: "generate_topology S a \<Longrightarrow> generate_topology S b \<Longrightarrow> generate_topology S (a \<inter> b)"
   165 | UN: "(\<And>k. k \<in> K \<Longrightarrow> generate_topology S k) \<Longrightarrow> generate_topology S (\<Union>K)"
   166 | Basis: "s \<in> S \<Longrightarrow> generate_topology S s"
   167 
   168 hide_fact (open) UNIV Int UN Basis 
   169 
   170 lemma generate_topology_Union: 
   171   "(\<And>k. k \<in> I \<Longrightarrow> generate_topology S (K k)) \<Longrightarrow> generate_topology S (\<Union>k\<in>I. K k)"
   172   unfolding SUP_def by (intro generate_topology.UN) auto
   173 
   174 lemma topological_space_generate_topology:
   175   "class.topological_space (generate_topology S)"
   176   by default (auto intro: generate_topology.intros)
   177 
   178 subsection {* Order topologies *}
   179 
   180 class order_topology = order + "open" +
   181   assumes open_generated_order: "open = generate_topology (range (\<lambda>a. {..< a}) \<union> range (\<lambda>a. {a <..}))"
   182 begin
   183 
   184 subclass topological_space
   185   unfolding open_generated_order
   186   by (rule topological_space_generate_topology)
   187 
   188 lemma open_greaterThan [simp]: "open {a <..}"
   189   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   190 
   191 lemma open_lessThan [simp]: "open {..< a}"
   192   unfolding open_generated_order by (auto intro: generate_topology.Basis)
   193 
   194 lemma open_greaterThanLessThan [simp]: "open {a <..< b}"
   195    unfolding greaterThanLessThan_eq by (simp add: open_Int)
   196 
   197 end
   198 
   199 class linorder_topology = linorder + order_topology
   200 
   201 lemma closed_atMost [simp]: "closed {.. a::'a::linorder_topology}"
   202   by (simp add: closed_open)
   203 
   204 lemma closed_atLeast [simp]: "closed {a::'a::linorder_topology ..}"
   205   by (simp add: closed_open)
   206 
   207 lemma closed_atLeastAtMost [simp]: "closed {a::'a::linorder_topology .. b}"
   208 proof -
   209   have "{a .. b} = {a ..} \<inter> {.. b}"
   210     by auto
   211   then show ?thesis
   212     by (simp add: closed_Int)
   213 qed
   214 
   215 lemma (in linorder) less_separate:
   216   assumes "x < y"
   217   shows "\<exists>a b. x \<in> {..< a} \<and> y \<in> {b <..} \<and> {..< a} \<inter> {b <..} = {}"
   218 proof cases
   219   assume "\<exists>z. x < z \<and> z < y"
   220   then guess z ..
   221   then have "x \<in> {..< z} \<and> y \<in> {z <..} \<and> {z <..} \<inter> {..< z} = {}"
   222     by auto
   223   then show ?thesis by blast
   224 next
   225   assume "\<not> (\<exists>z. x < z \<and> z < y)"
   226   with `x < y` have "x \<in> {..< y} \<and> y \<in> {x <..} \<and> {x <..} \<inter> {..< y} = {}"
   227     by auto
   228   then show ?thesis by blast
   229 qed
   230 
   231 instance linorder_topology \<subseteq> t2_space
   232 proof
   233   fix x y :: 'a
   234   from less_separate[of x y] less_separate[of y x]
   235   show "x \<noteq> y \<Longrightarrow> \<exists>U V. open U \<and> open V \<and> x \<in> U \<and> y \<in> V \<and> U \<inter> V = {}"
   236     by (elim neqE) (metis open_lessThan open_greaterThan Int_commute)+
   237 qed
   238 
   239 lemma (in linorder_topology) open_right:
   240   assumes "open S" "x \<in> S" and gt_ex: "x < y" shows "\<exists>b>x. {x ..< b} \<subseteq> S"
   241   using assms unfolding open_generated_order
   242 proof induction
   243   case (Int A B)
   244   then obtain a b where "a > x" "{x ..< a} \<subseteq> A"  "b > x" "{x ..< b} \<subseteq> B" by auto
   245   then show ?case by (auto intro!: exI[of _ "min a b"])
   246 next
   247   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] gt_ex)
   248 qed blast+
   249 
   250 lemma (in linorder_topology) open_left:
   251   assumes "open S" "x \<in> S" and lt_ex: "y < x" shows "\<exists>b<x. {b <.. x} \<subseteq> S"
   252   using assms unfolding open_generated_order
   253 proof induction
   254   case (Int A B)
   255   then obtain a b where "a < x" "{a <.. x} \<subseteq> A"  "b < x" "{b <.. x} \<subseteq> B" by auto
   256   then show ?case by (auto intro!: exI[of _ "max a b"])
   257 next
   258   case (Basis S) then show ?case by (fastforce intro: exI[of _ y] lt_ex)
   259 qed blast+
   260 
   261 subsection {* Filters *}
   262 
   263 text {*
   264   This definition also allows non-proper filters.
   265 *}
   266 
   267 locale is_filter =
   268   fixes F :: "('a \<Rightarrow> bool) \<Rightarrow> bool"
   269   assumes True: "F (\<lambda>x. True)"
   270   assumes conj: "F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x) \<Longrightarrow> F (\<lambda>x. P x \<and> Q x)"
   271   assumes mono: "\<forall>x. P x \<longrightarrow> Q x \<Longrightarrow> F (\<lambda>x. P x) \<Longrightarrow> F (\<lambda>x. Q x)"
   272 
   273 typedef 'a filter = "{F :: ('a \<Rightarrow> bool) \<Rightarrow> bool. is_filter F}"
   274 proof
   275   show "(\<lambda>x. True) \<in> ?filter" by (auto intro: is_filter.intro)
   276 qed
   277 
   278 lemma is_filter_Rep_filter: "is_filter (Rep_filter F)"
   279   using Rep_filter [of F] by simp
   280 
   281 lemma Abs_filter_inverse':
   282   assumes "is_filter F" shows "Rep_filter (Abs_filter F) = F"
   283   using assms by (simp add: Abs_filter_inverse)
   284 
   285 
   286 subsubsection {* Eventually *}
   287 
   288 definition eventually :: "('a \<Rightarrow> bool) \<Rightarrow> 'a filter \<Rightarrow> bool"
   289   where "eventually P F \<longleftrightarrow> Rep_filter F P"
   290 
   291 lemma eventually_Abs_filter:
   292   assumes "is_filter F" shows "eventually P (Abs_filter F) = F P"
   293   unfolding eventually_def using assms by (simp add: Abs_filter_inverse)
   294 
   295 lemma filter_eq_iff:
   296   shows "F = F' \<longleftrightarrow> (\<forall>P. eventually P F = eventually P F')"
   297   unfolding Rep_filter_inject [symmetric] fun_eq_iff eventually_def ..
   298 
   299 lemma eventually_True [simp]: "eventually (\<lambda>x. True) F"
   300   unfolding eventually_def
   301   by (rule is_filter.True [OF is_filter_Rep_filter])
   302 
   303 lemma always_eventually: "\<forall>x. P x \<Longrightarrow> eventually P F"
   304 proof -
   305   assume "\<forall>x. P x" hence "P = (\<lambda>x. True)" by (simp add: ext)
   306   thus "eventually P F" by simp
   307 qed
   308 
   309 lemma eventually_mono:
   310   "(\<forall>x. P x \<longrightarrow> Q x) \<Longrightarrow> eventually P F \<Longrightarrow> eventually Q F"
   311   unfolding eventually_def
   312   by (rule is_filter.mono [OF is_filter_Rep_filter])
   313 
   314 lemma eventually_conj:
   315   assumes P: "eventually (\<lambda>x. P x) F"
   316   assumes Q: "eventually (\<lambda>x. Q x) F"
   317   shows "eventually (\<lambda>x. P x \<and> Q x) F"
   318   using assms unfolding eventually_def
   319   by (rule is_filter.conj [OF is_filter_Rep_filter])
   320 
   321 lemma eventually_Ball_finite:
   322   assumes "finite A" and "\<forall>y\<in>A. eventually (\<lambda>x. P x y) net"
   323   shows "eventually (\<lambda>x. \<forall>y\<in>A. P x y) net"
   324 using assms by (induct set: finite, simp, simp add: eventually_conj)
   325 
   326 lemma eventually_all_finite:
   327   fixes P :: "'a \<Rightarrow> 'b::finite \<Rightarrow> bool"
   328   assumes "\<And>y. eventually (\<lambda>x. P x y) net"
   329   shows "eventually (\<lambda>x. \<forall>y. P x y) net"
   330 using eventually_Ball_finite [of UNIV P] assms by simp
   331 
   332 lemma eventually_mp:
   333   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   334   assumes "eventually (\<lambda>x. P x) F"
   335   shows "eventually (\<lambda>x. Q x) F"
   336 proof (rule eventually_mono)
   337   show "\<forall>x. (P x \<longrightarrow> Q x) \<and> P x \<longrightarrow> Q x" by simp
   338   show "eventually (\<lambda>x. (P x \<longrightarrow> Q x) \<and> P x) F"
   339     using assms by (rule eventually_conj)
   340 qed
   341 
   342 lemma eventually_rev_mp:
   343   assumes "eventually (\<lambda>x. P x) F"
   344   assumes "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   345   shows "eventually (\<lambda>x. Q x) F"
   346 using assms(2) assms(1) by (rule eventually_mp)
   347 
   348 lemma eventually_conj_iff:
   349   "eventually (\<lambda>x. P x \<and> Q x) F \<longleftrightarrow> eventually P F \<and> eventually Q F"
   350   by (auto intro: eventually_conj elim: eventually_rev_mp)
   351 
   352 lemma eventually_elim1:
   353   assumes "eventually (\<lambda>i. P i) F"
   354   assumes "\<And>i. P i \<Longrightarrow> Q i"
   355   shows "eventually (\<lambda>i. Q i) F"
   356   using assms by (auto elim!: eventually_rev_mp)
   357 
   358 lemma eventually_elim2:
   359   assumes "eventually (\<lambda>i. P i) F"
   360   assumes "eventually (\<lambda>i. Q i) F"
   361   assumes "\<And>i. P i \<Longrightarrow> Q i \<Longrightarrow> R i"
   362   shows "eventually (\<lambda>i. R i) F"
   363   using assms by (auto elim!: eventually_rev_mp)
   364 
   365 lemma eventually_subst:
   366   assumes "eventually (\<lambda>n. P n = Q n) F"
   367   shows "eventually P F = eventually Q F" (is "?L = ?R")
   368 proof -
   369   from assms have "eventually (\<lambda>x. P x \<longrightarrow> Q x) F"
   370       and "eventually (\<lambda>x. Q x \<longrightarrow> P x) F"
   371     by (auto elim: eventually_elim1)
   372   then show ?thesis by (auto elim: eventually_elim2)
   373 qed
   374 
   375 ML {*
   376   fun eventually_elim_tac ctxt thms thm =
   377     let
   378       val thy = Proof_Context.theory_of ctxt
   379       val mp_thms = thms RL [@{thm eventually_rev_mp}]
   380       val raw_elim_thm =
   381         (@{thm allI} RS @{thm always_eventually})
   382         |> fold (fn thm1 => fn thm2 => thm2 RS thm1) mp_thms
   383         |> fold (fn _ => fn thm => @{thm impI} RS thm) thms
   384       val cases_prop = prop_of (raw_elim_thm RS thm)
   385       val cases = (Rule_Cases.make_common (thy, cases_prop) [(("elim", []), [])])
   386     in
   387       CASES cases (rtac raw_elim_thm 1) thm
   388     end
   389 *}
   390 
   391 method_setup eventually_elim = {*
   392   Scan.succeed (fn ctxt => METHOD_CASES (eventually_elim_tac ctxt))
   393 *} "elimination of eventually quantifiers"
   394 
   395 
   396 subsubsection {* Finer-than relation *}
   397 
   398 text {* @{term "F \<le> F'"} means that filter @{term F} is finer than
   399 filter @{term F'}. *}
   400 
   401 instantiation filter :: (type) complete_lattice
   402 begin
   403 
   404 definition le_filter_def:
   405   "F \<le> F' \<longleftrightarrow> (\<forall>P. eventually P F' \<longrightarrow> eventually P F)"
   406 
   407 definition
   408   "(F :: 'a filter) < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   409 
   410 definition
   411   "top = Abs_filter (\<lambda>P. \<forall>x. P x)"
   412 
   413 definition
   414   "bot = Abs_filter (\<lambda>P. True)"
   415 
   416 definition
   417   "sup F F' = Abs_filter (\<lambda>P. eventually P F \<and> eventually P F')"
   418 
   419 definition
   420   "inf F F' = Abs_filter
   421       (\<lambda>P. \<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   422 
   423 definition
   424   "Sup S = Abs_filter (\<lambda>P. \<forall>F\<in>S. eventually P F)"
   425 
   426 definition
   427   "Inf S = Sup {F::'a filter. \<forall>F'\<in>S. F \<le> F'}"
   428 
   429 lemma eventually_top [simp]: "eventually P top \<longleftrightarrow> (\<forall>x. P x)"
   430   unfolding top_filter_def
   431   by (rule eventually_Abs_filter, rule is_filter.intro, auto)
   432 
   433 lemma eventually_bot [simp]: "eventually P bot"
   434   unfolding bot_filter_def
   435   by (subst eventually_Abs_filter, rule is_filter.intro, auto)
   436 
   437 lemma eventually_sup:
   438   "eventually P (sup F F') \<longleftrightarrow> eventually P F \<and> eventually P F'"
   439   unfolding sup_filter_def
   440   by (rule eventually_Abs_filter, rule is_filter.intro)
   441      (auto elim!: eventually_rev_mp)
   442 
   443 lemma eventually_inf:
   444   "eventually P (inf F F') \<longleftrightarrow>
   445    (\<exists>Q R. eventually Q F \<and> eventually R F' \<and> (\<forall>x. Q x \<and> R x \<longrightarrow> P x))"
   446   unfolding inf_filter_def
   447   apply (rule eventually_Abs_filter, rule is_filter.intro)
   448   apply (fast intro: eventually_True)
   449   apply clarify
   450   apply (intro exI conjI)
   451   apply (erule (1) eventually_conj)
   452   apply (erule (1) eventually_conj)
   453   apply simp
   454   apply auto
   455   done
   456 
   457 lemma eventually_Sup:
   458   "eventually P (Sup S) \<longleftrightarrow> (\<forall>F\<in>S. eventually P F)"
   459   unfolding Sup_filter_def
   460   apply (rule eventually_Abs_filter, rule is_filter.intro)
   461   apply (auto intro: eventually_conj elim!: eventually_rev_mp)
   462   done
   463 
   464 instance proof
   465   fix F F' F'' :: "'a filter" and S :: "'a filter set"
   466   { show "F < F' \<longleftrightarrow> F \<le> F' \<and> \<not> F' \<le> F"
   467     by (rule less_filter_def) }
   468   { show "F \<le> F"
   469     unfolding le_filter_def by simp }
   470   { assume "F \<le> F'" and "F' \<le> F''" thus "F \<le> F''"
   471     unfolding le_filter_def by simp }
   472   { assume "F \<le> F'" and "F' \<le> F" thus "F = F'"
   473     unfolding le_filter_def filter_eq_iff by fast }
   474   { show "F \<le> top"
   475     unfolding le_filter_def eventually_top by (simp add: always_eventually) }
   476   { show "bot \<le> F"
   477     unfolding le_filter_def by simp }
   478   { show "F \<le> sup F F'" and "F' \<le> sup F F'"
   479     unfolding le_filter_def eventually_sup by simp_all }
   480   { assume "F \<le> F''" and "F' \<le> F''" thus "sup F F' \<le> F''"
   481     unfolding le_filter_def eventually_sup by simp }
   482   { show "inf F F' \<le> F" and "inf F F' \<le> F'"
   483     unfolding le_filter_def eventually_inf by (auto intro: eventually_True) }
   484   { assume "F \<le> F'" and "F \<le> F''" thus "F \<le> inf F' F''"
   485     unfolding le_filter_def eventually_inf
   486     by (auto elim!: eventually_mono intro: eventually_conj) }
   487   { assume "F \<in> S" thus "F \<le> Sup S"
   488     unfolding le_filter_def eventually_Sup by simp }
   489   { assume "\<And>F. F \<in> S \<Longrightarrow> F \<le> F'" thus "Sup S \<le> F'"
   490     unfolding le_filter_def eventually_Sup by simp }
   491   { assume "F'' \<in> S" thus "Inf S \<le> F''"
   492     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   493   { assume "\<And>F'. F' \<in> S \<Longrightarrow> F \<le> F'" thus "F \<le> Inf S"
   494     unfolding le_filter_def Inf_filter_def eventually_Sup Ball_def by simp }
   495 qed
   496 
   497 end
   498 
   499 lemma filter_leD:
   500   "F \<le> F' \<Longrightarrow> eventually P F' \<Longrightarrow> eventually P F"
   501   unfolding le_filter_def by simp
   502 
   503 lemma filter_leI:
   504   "(\<And>P. eventually P F' \<Longrightarrow> eventually P F) \<Longrightarrow> F \<le> F'"
   505   unfolding le_filter_def by simp
   506 
   507 lemma eventually_False:
   508   "eventually (\<lambda>x. False) F \<longleftrightarrow> F = bot"
   509   unfolding filter_eq_iff by (auto elim: eventually_rev_mp)
   510 
   511 abbreviation (input) trivial_limit :: "'a filter \<Rightarrow> bool"
   512   where "trivial_limit F \<equiv> F = bot"
   513 
   514 lemma trivial_limit_def: "trivial_limit F \<longleftrightarrow> eventually (\<lambda>x. False) F"
   515   by (rule eventually_False [symmetric])
   516 
   517 lemma eventually_const: "\<not> trivial_limit net \<Longrightarrow> eventually (\<lambda>x. P) net \<longleftrightarrow> P"
   518   by (cases P) (simp_all add: eventually_False)
   519 
   520 
   521 subsubsection {* Map function for filters *}
   522 
   523 definition filtermap :: "('a \<Rightarrow> 'b) \<Rightarrow> 'a filter \<Rightarrow> 'b filter"
   524   where "filtermap f F = Abs_filter (\<lambda>P. eventually (\<lambda>x. P (f x)) F)"
   525 
   526 lemma eventually_filtermap:
   527   "eventually P (filtermap f F) = eventually (\<lambda>x. P (f x)) F"
   528   unfolding filtermap_def
   529   apply (rule eventually_Abs_filter)
   530   apply (rule is_filter.intro)
   531   apply (auto elim!: eventually_rev_mp)
   532   done
   533 
   534 lemma filtermap_ident: "filtermap (\<lambda>x. x) F = F"
   535   by (simp add: filter_eq_iff eventually_filtermap)
   536 
   537 lemma filtermap_filtermap:
   538   "filtermap f (filtermap g F) = filtermap (\<lambda>x. f (g x)) F"
   539   by (simp add: filter_eq_iff eventually_filtermap)
   540 
   541 lemma filtermap_mono: "F \<le> F' \<Longrightarrow> filtermap f F \<le> filtermap f F'"
   542   unfolding le_filter_def eventually_filtermap by simp
   543 
   544 lemma filtermap_bot [simp]: "filtermap f bot = bot"
   545   by (simp add: filter_eq_iff eventually_filtermap)
   546 
   547 lemma filtermap_sup: "filtermap f (sup F1 F2) = sup (filtermap f F1) (filtermap f F2)"
   548   by (auto simp: filter_eq_iff eventually_filtermap eventually_sup)
   549 
   550 subsubsection {* Order filters *}
   551 
   552 definition at_top :: "('a::order) filter"
   553   where "at_top = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   554 
   555 lemma eventually_at_top_linorder: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::linorder. \<forall>n\<ge>N. P n)"
   556   unfolding at_top_def
   557 proof (rule eventually_Abs_filter, rule is_filter.intro)
   558   fix P Q :: "'a \<Rightarrow> bool"
   559   assume "\<exists>i. \<forall>n\<ge>i. P n" and "\<exists>j. \<forall>n\<ge>j. Q n"
   560   then obtain i j where "\<forall>n\<ge>i. P n" and "\<forall>n\<ge>j. Q n" by auto
   561   then have "\<forall>n\<ge>max i j. P n \<and> Q n" by simp
   562   then show "\<exists>k. \<forall>n\<ge>k. P n \<and> Q n" ..
   563 qed auto
   564 
   565 lemma eventually_ge_at_top:
   566   "eventually (\<lambda>x. (c::_::linorder) \<le> x) at_top"
   567   unfolding eventually_at_top_linorder by auto
   568 
   569 lemma eventually_at_top_dense: "eventually P at_top \<longleftrightarrow> (\<exists>N::'a::dense_linorder. \<forall>n>N. P n)"
   570   unfolding eventually_at_top_linorder
   571 proof safe
   572   fix N assume "\<forall>n\<ge>N. P n" then show "\<exists>N. \<forall>n>N. P n" by (auto intro!: exI[of _ N])
   573 next
   574   fix N assume "\<forall>n>N. P n"
   575   moreover from gt_ex[of N] guess y ..
   576   ultimately show "\<exists>N. \<forall>n\<ge>N. P n" by (auto intro!: exI[of _ y])
   577 qed
   578 
   579 lemma eventually_gt_at_top:
   580   "eventually (\<lambda>x. (c::_::dense_linorder) < x) at_top"
   581   unfolding eventually_at_top_dense by auto
   582 
   583 definition at_bot :: "('a::order) filter"
   584   where "at_bot = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<le>k. P n)"
   585 
   586 lemma eventually_at_bot_linorder:
   587   fixes P :: "'a::linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n\<le>N. P n)"
   588   unfolding at_bot_def
   589 proof (rule eventually_Abs_filter, rule is_filter.intro)
   590   fix P Q :: "'a \<Rightarrow> bool"
   591   assume "\<exists>i. \<forall>n\<le>i. P n" and "\<exists>j. \<forall>n\<le>j. Q n"
   592   then obtain i j where "\<forall>n\<le>i. P n" and "\<forall>n\<le>j. Q n" by auto
   593   then have "\<forall>n\<le>min i j. P n \<and> Q n" by simp
   594   then show "\<exists>k. \<forall>n\<le>k. P n \<and> Q n" ..
   595 qed auto
   596 
   597 lemma eventually_le_at_bot:
   598   "eventually (\<lambda>x. x \<le> (c::_::linorder)) at_bot"
   599   unfolding eventually_at_bot_linorder by auto
   600 
   601 lemma eventually_at_bot_dense:
   602   fixes P :: "'a::dense_linorder \<Rightarrow> bool" shows "eventually P at_bot \<longleftrightarrow> (\<exists>N. \<forall>n<N. P n)"
   603   unfolding eventually_at_bot_linorder
   604 proof safe
   605   fix N assume "\<forall>n\<le>N. P n" then show "\<exists>N. \<forall>n<N. P n" by (auto intro!: exI[of _ N])
   606 next
   607   fix N assume "\<forall>n<N. P n" 
   608   moreover from lt_ex[of N] guess y ..
   609   ultimately show "\<exists>N. \<forall>n\<le>N. P n" by (auto intro!: exI[of _ y])
   610 qed
   611 
   612 lemma eventually_gt_at_bot:
   613   "eventually (\<lambda>x. x < (c::_::dense_linorder)) at_bot"
   614   unfolding eventually_at_bot_dense by auto
   615 
   616 subsection {* Sequentially *}
   617 
   618 abbreviation sequentially :: "nat filter"
   619   where "sequentially == at_top"
   620 
   621 lemma sequentially_def: "sequentially = Abs_filter (\<lambda>P. \<exists>k. \<forall>n\<ge>k. P n)"
   622   unfolding at_top_def by simp
   623 
   624 lemma eventually_sequentially:
   625   "eventually P sequentially \<longleftrightarrow> (\<exists>N. \<forall>n\<ge>N. P n)"
   626   by (rule eventually_at_top_linorder)
   627 
   628 lemma sequentially_bot [simp, intro]: "sequentially \<noteq> bot"
   629   unfolding filter_eq_iff eventually_sequentially by auto
   630 
   631 lemmas trivial_limit_sequentially = sequentially_bot
   632 
   633 lemma eventually_False_sequentially [simp]:
   634   "\<not> eventually (\<lambda>n. False) sequentially"
   635   by (simp add: eventually_False)
   636 
   637 lemma le_sequentially:
   638   "F \<le> sequentially \<longleftrightarrow> (\<forall>N. eventually (\<lambda>n. N \<le> n) F)"
   639   unfolding le_filter_def eventually_sequentially
   640   by (safe, fast, drule_tac x=N in spec, auto elim: eventually_rev_mp)
   641 
   642 lemma eventually_sequentiallyI:
   643   assumes "\<And>x. c \<le> x \<Longrightarrow> P x"
   644   shows "eventually P sequentially"
   645 using assms by (auto simp: eventually_sequentially)
   646 
   647 lemma eventually_sequentially_seg:
   648   "eventually (\<lambda>n. P (n + k)) sequentially \<longleftrightarrow> eventually P sequentially"
   649   unfolding eventually_sequentially
   650   apply safe
   651    apply (rule_tac x="N + k" in exI)
   652    apply rule
   653    apply (erule_tac x="n - k" in allE)
   654    apply auto []
   655   apply (rule_tac x=N in exI)
   656   apply auto []
   657   done
   658 
   659 subsubsection {* Standard filters *}
   660 
   661 definition principal :: "'a set \<Rightarrow> 'a filter" where
   662   "principal S = Abs_filter (\<lambda>P. \<forall>x\<in>S. P x)"
   663 
   664 lemma eventually_principal: "eventually P (principal S) \<longleftrightarrow> (\<forall>x\<in>S. P x)"
   665   unfolding principal_def
   666   by (rule eventually_Abs_filter, rule is_filter.intro) auto
   667 
   668 lemma eventually_inf_principal: "eventually P (inf F (principal s)) \<longleftrightarrow> eventually (\<lambda>x. x \<in> s \<longrightarrow> P x) F"
   669   unfolding eventually_inf eventually_principal by (auto elim: eventually_elim1)
   670 
   671 lemma principal_UNIV[simp]: "principal UNIV = top"
   672   by (auto simp: filter_eq_iff eventually_principal)
   673 
   674 lemma principal_empty[simp]: "principal {} = bot"
   675   by (auto simp: filter_eq_iff eventually_principal)
   676 
   677 lemma principal_le_iff[iff]: "principal A \<le> principal B \<longleftrightarrow> A \<subseteq> B"
   678   by (auto simp: le_filter_def eventually_principal)
   679 
   680 lemma le_principal: "F \<le> principal A \<longleftrightarrow> eventually (\<lambda>x. x \<in> A) F"
   681   unfolding le_filter_def eventually_principal
   682   apply safe
   683   apply (erule_tac x="\<lambda>x. x \<in> A" in allE)
   684   apply (auto elim: eventually_elim1)
   685   done
   686 
   687 lemma principal_inject[iff]: "principal A = principal B \<longleftrightarrow> A = B"
   688   unfolding eq_iff by simp
   689 
   690 lemma sup_principal[simp]: "sup (principal A) (principal B) = principal (A \<union> B)"
   691   unfolding filter_eq_iff eventually_sup eventually_principal by auto
   692 
   693 lemma inf_principal[simp]: "inf (principal A) (principal B) = principal (A \<inter> B)"
   694   unfolding filter_eq_iff eventually_inf eventually_principal
   695   by (auto intro: exI[of _ "\<lambda>x. x \<in> A"] exI[of _ "\<lambda>x. x \<in> B"])
   696 
   697 lemma SUP_principal[simp]: "(SUP i : I. principal (A i)) = principal (\<Union>i\<in>I. A i)"
   698   unfolding filter_eq_iff eventually_Sup SUP_def by (auto simp: eventually_principal)
   699 
   700 lemma filtermap_principal[simp]: "filtermap f (principal A) = principal (f ` A)"
   701   unfolding filter_eq_iff eventually_filtermap eventually_principal by simp
   702 
   703 subsubsection {* Topological filters *}
   704 
   705 definition (in topological_space) nhds :: "'a \<Rightarrow> 'a filter"
   706   where "nhds a = Abs_filter (\<lambda>P. \<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   707 
   708 definition (in topological_space) at_within :: "'a \<Rightarrow> 'a set \<Rightarrow> 'a filter" ("at (_) within (_)" [1000, 60] 60)
   709   where "at a within s = inf (nhds a) (principal (s - {a}))"
   710 
   711 abbreviation (in topological_space) at :: "'a \<Rightarrow> 'a filter" ("at") where
   712   "at x \<equiv> at x within (CONST UNIV)"
   713 
   714 abbreviation (in order_topology) at_right :: "'a \<Rightarrow> 'a filter" where
   715   "at_right x \<equiv> at x within {x <..}"
   716 
   717 abbreviation (in order_topology) at_left :: "'a \<Rightarrow> 'a filter" where
   718   "at_left x \<equiv> at x within {..< x}"
   719 
   720 lemma (in topological_space) eventually_nhds:
   721   "eventually P (nhds a) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x))"
   722   unfolding nhds_def
   723 proof (rule eventually_Abs_filter, rule is_filter.intro)
   724   have "open UNIV \<and> a \<in> UNIV \<and> (\<forall>x\<in>UNIV. True)" by simp
   725   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. True)" ..
   726 next
   727   fix P Q
   728   assume "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   729      and "\<exists>T. open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)"
   730   then obtain S T where
   731     "open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x)"
   732     "open T \<and> a \<in> T \<and> (\<forall>x\<in>T. Q x)" by auto
   733   hence "open (S \<inter> T) \<and> a \<in> S \<inter> T \<and> (\<forall>x\<in>(S \<inter> T). P x \<and> Q x)"
   734     by (simp add: open_Int)
   735   thus "\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. P x \<and> Q x)" ..
   736 qed auto
   737 
   738 lemma nhds_neq_bot [simp]: "nhds a \<noteq> bot"
   739   unfolding trivial_limit_def eventually_nhds by simp
   740 
   741 lemma eventually_at_filter:
   742   "eventually P (at a within s) \<longleftrightarrow> eventually (\<lambda>x. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x) (nhds a)"
   743   unfolding at_within_def eventually_inf_principal by (simp add: imp_conjL[symmetric] conj_commute)
   744 
   745 lemma at_le: "s \<subseteq> t \<Longrightarrow> at x within s \<le> at x within t"
   746   unfolding at_within_def by (intro inf_mono) auto
   747 
   748 lemma eventually_at_topological:
   749   "eventually P (at a within s) \<longleftrightarrow> (\<exists>S. open S \<and> a \<in> S \<and> (\<forall>x\<in>S. x \<noteq> a \<longrightarrow> x \<in> s \<longrightarrow> P x))"
   750   unfolding eventually_nhds eventually_at_filter by simp
   751 
   752 lemma at_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> at a within S = at a"
   753   unfolding filter_eq_iff eventually_at_topological by (metis open_Int Int_iff UNIV_I)
   754 
   755 lemma at_eq_bot_iff: "at a = bot \<longleftrightarrow> open {a}"
   756   unfolding trivial_limit_def eventually_at_topological
   757   by (safe, case_tac "S = {a}", simp, fast, fast)
   758 
   759 lemma at_neq_bot [simp]: "at (a::'a::perfect_space) \<noteq> bot"
   760   by (simp add: at_eq_bot_iff not_open_singleton)
   761 
   762 lemma eventually_at_right:
   763   fixes x :: "'a :: {no_top, linorder_topology}"
   764   shows "eventually P (at_right x) \<longleftrightarrow> (\<exists>b. x < b \<and> (\<forall>z. x < z \<and> z < b \<longrightarrow> P z))"
   765   unfolding eventually_at_topological
   766 proof safe
   767   from gt_ex[of x] guess y ..
   768   moreover fix S assume "open S" "x \<in> S" note open_right[OF this, of y]
   769   moreover note gt_ex[of x]
   770   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {x<..} \<longrightarrow> P s"
   771   ultimately show "\<exists>b>x. \<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   772     by (auto simp: subset_eq Ball_def)
   773 next
   774   fix b assume "x < b" "\<forall>z. x < z \<and> z < b \<longrightarrow> P z"
   775   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>xa\<in>S. xa \<noteq> x \<longrightarrow> xa \<in> {x<..} \<longrightarrow> P xa)"
   776     by (intro exI[of _ "{..< b}"]) auto
   777 qed
   778 
   779 lemma eventually_at_left:
   780   fixes x :: "'a :: {no_bot, linorder_topology}"
   781   shows "eventually P (at_left x) \<longleftrightarrow> (\<exists>b. x > b \<and> (\<forall>z. b < z \<and> z < x \<longrightarrow> P z))"
   782   unfolding eventually_at_topological
   783 proof safe
   784   from lt_ex[of x] guess y ..
   785   moreover fix S assume "open S" "x \<in> S" note open_left[OF this, of y]
   786   moreover assume "\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s"
   787   ultimately show "\<exists>b<x. \<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   788     by (auto simp: subset_eq Ball_def)
   789 next
   790   fix b assume "b < x" "\<forall>z. b < z \<and> z < x \<longrightarrow> P z"
   791   then show "\<exists>S. open S \<and> x \<in> S \<and> (\<forall>s\<in>S. s \<noteq> x \<longrightarrow> s \<in> {..<x} \<longrightarrow> P s)"
   792     by (intro exI[of _ "{b <..}"]) auto
   793 qed
   794 
   795 lemma trivial_limit_at_left_real [simp]:
   796   "\<not> trivial_limit (at_left (x::'a::{no_bot, dense_linorder, linorder_topology}))"
   797   unfolding trivial_limit_def eventually_at_left by (auto dest: dense)
   798 
   799 lemma trivial_limit_at_right_real [simp]:
   800   "\<not> trivial_limit (at_right (x::'a::{no_top, dense_linorder, linorder_topology}))"
   801   unfolding trivial_limit_def eventually_at_right by (auto dest: dense)
   802 
   803 lemma at_eq_sup_left_right: "at (x::'a::linorder_topology) = sup (at_left x) (at_right x)"
   804   by (auto simp: eventually_at_filter filter_eq_iff eventually_sup 
   805            elim: eventually_elim2 eventually_elim1)
   806 
   807 lemma eventually_at_split:
   808   "eventually P (at (x::'a::linorder_topology)) \<longleftrightarrow> eventually P (at_left x) \<and> eventually P (at_right x)"
   809   by (subst at_eq_sup_left_right) (simp add: eventually_sup)
   810 
   811 subsection {* Limits *}
   812 
   813 definition filterlim :: "('a \<Rightarrow> 'b) \<Rightarrow> 'b filter \<Rightarrow> 'a filter \<Rightarrow> bool" where
   814   "filterlim f F2 F1 \<longleftrightarrow> filtermap f F1 \<le> F2"
   815 
   816 syntax
   817   "_LIM" :: "pttrns \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> 'a \<Rightarrow> bool" ("(3LIM (_)/ (_)./ (_) :> (_))" [1000, 10, 0, 10] 10)
   818 
   819 translations
   820   "LIM x F1. f :> F2"   == "CONST filterlim (%x. f) F2 F1"
   821 
   822 lemma filterlim_iff:
   823   "(LIM x F1. f x :> F2) \<longleftrightarrow> (\<forall>P. eventually P F2 \<longrightarrow> eventually (\<lambda>x. P (f x)) F1)"
   824   unfolding filterlim_def le_filter_def eventually_filtermap ..
   825 
   826 lemma filterlim_compose:
   827   "filterlim g F3 F2 \<Longrightarrow> filterlim f F2 F1 \<Longrightarrow> filterlim (\<lambda>x. g (f x)) F3 F1"
   828   unfolding filterlim_def filtermap_filtermap[symmetric] by (metis filtermap_mono order_trans)
   829 
   830 lemma filterlim_mono:
   831   "filterlim f F2 F1 \<Longrightarrow> F2 \<le> F2' \<Longrightarrow> F1' \<le> F1 \<Longrightarrow> filterlim f F2' F1'"
   832   unfolding filterlim_def by (metis filtermap_mono order_trans)
   833 
   834 lemma filterlim_ident: "LIM x F. x :> F"
   835   by (simp add: filterlim_def filtermap_ident)
   836 
   837 lemma filterlim_cong:
   838   "F1 = F1' \<Longrightarrow> F2 = F2' \<Longrightarrow> eventually (\<lambda>x. f x = g x) F2 \<Longrightarrow> filterlim f F1 F2 = filterlim g F1' F2'"
   839   by (auto simp: filterlim_def le_filter_def eventually_filtermap elim: eventually_elim2)
   840 
   841 lemma filterlim_principal:
   842   "(LIM x F. f x :> principal S) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> S) F)"
   843   unfolding filterlim_def eventually_filtermap le_principal ..
   844 
   845 lemma filterlim_inf:
   846   "(LIM x F1. f x :> inf F2 F3) \<longleftrightarrow> ((LIM x F1. f x :> F2) \<and> (LIM x F1. f x :> F3))"
   847   unfolding filterlim_def by simp
   848 
   849 lemma filterlim_filtermap: "filterlim f F1 (filtermap g F2) = filterlim (\<lambda>x. f (g x)) F1 F2"
   850   unfolding filterlim_def filtermap_filtermap ..
   851 
   852 lemma filterlim_sup:
   853   "filterlim f F F1 \<Longrightarrow> filterlim f F F2 \<Longrightarrow> filterlim f F (sup F1 F2)"
   854   unfolding filterlim_def filtermap_sup by auto
   855 
   856 lemma filterlim_Suc: "filterlim Suc sequentially sequentially"
   857   by (simp add: filterlim_iff eventually_sequentially) (metis le_Suc_eq)
   858 
   859 subsubsection {* Tendsto *}
   860 
   861 abbreviation (in topological_space)
   862   tendsto :: "('b \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'b filter \<Rightarrow> bool" (infixr "--->" 55) where
   863   "(f ---> l) F \<equiv> filterlim f (nhds l) F"
   864 
   865 definition (in t2_space) Lim :: "'f filter \<Rightarrow> ('f \<Rightarrow> 'a) \<Rightarrow> 'a" where
   866   "Lim A f = (THE l. (f ---> l) A)"
   867 
   868 lemma tendsto_eq_rhs: "(f ---> x) F \<Longrightarrow> x = y \<Longrightarrow> (f ---> y) F"
   869   by simp
   870 
   871 ML {*
   872 
   873 structure Tendsto_Intros = Named_Thms
   874 (
   875   val name = @{binding tendsto_intros}
   876   val description = "introduction rules for tendsto"
   877 )
   878 
   879 *}
   880 
   881 setup {*
   882   Tendsto_Intros.setup #>
   883   Global_Theory.add_thms_dynamic (@{binding tendsto_eq_intros},
   884     map_filter (try (fn thm => @{thm tendsto_eq_rhs} OF [thm])) o Tendsto_Intros.get o Context.proof_of);
   885 *}
   886 
   887 lemma (in topological_space) tendsto_def:
   888    "(f ---> l) F \<longleftrightarrow> (\<forall>S. open S \<longrightarrow> l \<in> S \<longrightarrow> eventually (\<lambda>x. f x \<in> S) F)"
   889   unfolding filterlim_def
   890 proof safe
   891   fix S assume "open S" "l \<in> S" "filtermap f F \<le> nhds l"
   892   then show "eventually (\<lambda>x. f x \<in> S) F"
   893     unfolding eventually_nhds eventually_filtermap le_filter_def
   894     by (auto elim!: allE[of _ "\<lambda>x. x \<in> S"] eventually_rev_mp)
   895 qed (auto elim!: eventually_rev_mp simp: eventually_nhds eventually_filtermap le_filter_def)
   896 
   897 lemma tendsto_mono: "F \<le> F' \<Longrightarrow> (f ---> l) F' \<Longrightarrow> (f ---> l) F"
   898   unfolding tendsto_def le_filter_def by fast
   899 
   900 lemma tendsto_within_subset: "(f ---> l) (at x within S) \<Longrightarrow> T \<subseteq> S \<Longrightarrow> (f ---> l) (at x within T)"
   901   by (blast intro: tendsto_mono at_le)
   902 
   903 lemma filterlim_at:
   904   "(LIM x F. f x :> at b within s) \<longleftrightarrow> (eventually (\<lambda>x. f x \<in> s \<and> f x \<noteq> b) F \<and> (f ---> b) F)"
   905   by (simp add: at_within_def filterlim_inf filterlim_principal conj_commute)
   906 
   907 lemma (in topological_space) topological_tendstoI:
   908   "(\<And>S. open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F) \<Longrightarrow> (f ---> l) F"
   909   unfolding tendsto_def by auto
   910 
   911 lemma (in topological_space) topological_tendstoD:
   912   "(f ---> l) F \<Longrightarrow> open S \<Longrightarrow> l \<in> S \<Longrightarrow> eventually (\<lambda>x. f x \<in> S) F"
   913   unfolding tendsto_def by auto
   914 
   915 lemma order_tendstoI:
   916   fixes y :: "_ :: order_topology"
   917   assumes "\<And>a. a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   918   assumes "\<And>a. y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   919   shows "(f ---> y) F"
   920 proof (rule topological_tendstoI)
   921   fix S assume "open S" "y \<in> S"
   922   then show "eventually (\<lambda>x. f x \<in> S) F"
   923     unfolding open_generated_order
   924   proof induct
   925     case (UN K)
   926     then obtain k where "y \<in> k" "k \<in> K" by auto
   927     with UN(2)[of k] show ?case
   928       by (auto elim: eventually_elim1)
   929   qed (insert assms, auto elim: eventually_elim2)
   930 qed
   931 
   932 lemma order_tendstoD:
   933   fixes y :: "_ :: order_topology"
   934   assumes y: "(f ---> y) F"
   935   shows "a < y \<Longrightarrow> eventually (\<lambda>x. a < f x) F"
   936     and "y < a \<Longrightarrow> eventually (\<lambda>x. f x < a) F"
   937   using topological_tendstoD[OF y, of "{..< a}"] topological_tendstoD[OF y, of "{a <..}"] by auto
   938 
   939 lemma order_tendsto_iff: 
   940   fixes f :: "_ \<Rightarrow> 'a :: order_topology"
   941   shows "(f ---> x) F \<longleftrightarrow>(\<forall>l<x. eventually (\<lambda>x. l < f x) F) \<and> (\<forall>u>x. eventually (\<lambda>x. f x < u) F)"
   942   by (metis order_tendstoI order_tendstoD)
   943 
   944 lemma tendsto_bot [simp]: "(f ---> a) bot"
   945   unfolding tendsto_def by simp
   946 
   947 lemma tendsto_ident_at [tendsto_intros]: "((\<lambda>x. x) ---> a) (at a within s)"
   948   unfolding tendsto_def eventually_at_topological by auto
   949 
   950 lemma (in topological_space) tendsto_const [tendsto_intros]: "((\<lambda>x. k) ---> k) F"
   951   by (simp add: tendsto_def)
   952 
   953 lemma (in t2_space) tendsto_unique:
   954   assumes "\<not> trivial_limit F" and "(f ---> a) F" and "(f ---> b) F"
   955   shows "a = b"
   956 proof (rule ccontr)
   957   assume "a \<noteq> b"
   958   obtain U V where "open U" "open V" "a \<in> U" "b \<in> V" "U \<inter> V = {}"
   959     using hausdorff [OF `a \<noteq> b`] by fast
   960   have "eventually (\<lambda>x. f x \<in> U) F"
   961     using `(f ---> a) F` `open U` `a \<in> U` by (rule topological_tendstoD)
   962   moreover
   963   have "eventually (\<lambda>x. f x \<in> V) F"
   964     using `(f ---> b) F` `open V` `b \<in> V` by (rule topological_tendstoD)
   965   ultimately
   966   have "eventually (\<lambda>x. False) F"
   967   proof eventually_elim
   968     case (elim x)
   969     hence "f x \<in> U \<inter> V" by simp
   970     with `U \<inter> V = {}` show ?case by simp
   971   qed
   972   with `\<not> trivial_limit F` show "False"
   973     by (simp add: trivial_limit_def)
   974 qed
   975 
   976 lemma (in t2_space) tendsto_const_iff:
   977   assumes "\<not> trivial_limit F" shows "((\<lambda>x. a :: 'a) ---> b) F \<longleftrightarrow> a = b"
   978   by (safe intro!: tendsto_const tendsto_unique [OF assms tendsto_const])
   979 
   980 lemma increasing_tendsto:
   981   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   982   assumes bdd: "eventually (\<lambda>n. f n \<le> l) F"
   983       and en: "\<And>x. x < l \<Longrightarrow> eventually (\<lambda>n. x < f n) F"
   984   shows "(f ---> l) F"
   985   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
   986 
   987 lemma decreasing_tendsto:
   988   fixes f :: "_ \<Rightarrow> 'a::order_topology"
   989   assumes bdd: "eventually (\<lambda>n. l \<le> f n) F"
   990       and en: "\<And>x. l < x \<Longrightarrow> eventually (\<lambda>n. f n < x) F"
   991   shows "(f ---> l) F"
   992   using assms by (intro order_tendstoI) (auto elim!: eventually_elim1)
   993 
   994 lemma tendsto_sandwich:
   995   fixes f g h :: "'a \<Rightarrow> 'b::order_topology"
   996   assumes ev: "eventually (\<lambda>n. f n \<le> g n) net" "eventually (\<lambda>n. g n \<le> h n) net"
   997   assumes lim: "(f ---> c) net" "(h ---> c) net"
   998   shows "(g ---> c) net"
   999 proof (rule order_tendstoI)
  1000   fix a show "a < c \<Longrightarrow> eventually (\<lambda>x. a < g x) net"
  1001     using order_tendstoD[OF lim(1), of a] ev by (auto elim: eventually_elim2)
  1002 next
  1003   fix a show "c < a \<Longrightarrow> eventually (\<lambda>x. g x < a) net"
  1004     using order_tendstoD[OF lim(2), of a] ev by (auto elim: eventually_elim2)
  1005 qed
  1006 
  1007 lemma tendsto_le:
  1008   fixes f g :: "'a \<Rightarrow> 'b::linorder_topology"
  1009   assumes F: "\<not> trivial_limit F"
  1010   assumes x: "(f ---> x) F" and y: "(g ---> y) F"
  1011   assumes ev: "eventually (\<lambda>x. g x \<le> f x) F"
  1012   shows "y \<le> x"
  1013 proof (rule ccontr)
  1014   assume "\<not> y \<le> x"
  1015   with less_separate[of x y] obtain a b where xy: "x < a" "b < y" "{..<a} \<inter> {b<..} = {}"
  1016     by (auto simp: not_le)
  1017   then have "eventually (\<lambda>x. f x < a) F" "eventually (\<lambda>x. b < g x) F"
  1018     using x y by (auto intro: order_tendstoD)
  1019   with ev have "eventually (\<lambda>x. False) F"
  1020     by eventually_elim (insert xy, fastforce)
  1021   with F show False
  1022     by (simp add: eventually_False)
  1023 qed
  1024 
  1025 lemma tendsto_le_const:
  1026   fixes f :: "'a \<Rightarrow> 'b::linorder_topology"
  1027   assumes F: "\<not> trivial_limit F"
  1028   assumes x: "(f ---> x) F" and a: "eventually (\<lambda>x. a \<le> f x) F"
  1029   shows "a \<le> x"
  1030   using F x tendsto_const a by (rule tendsto_le)
  1031 
  1032 subsubsection {* Rules about @{const Lim} *}
  1033 
  1034 lemma (in t2_space) tendsto_Lim:
  1035   "\<not>(trivial_limit net) \<Longrightarrow> (f ---> l) net \<Longrightarrow> Lim net f = l"
  1036   unfolding Lim_def using tendsto_unique[of net f] by auto
  1037 
  1038 lemma Lim_ident_at: "\<not> trivial_limit (at x within s) \<Longrightarrow> Lim (at x within s) (\<lambda>x. x) = x"
  1039   by (rule tendsto_Lim[OF _ tendsto_ident_at]) auto
  1040 
  1041 subsection {* Limits to @{const at_top} and @{const at_bot} *}
  1042 
  1043 lemma filterlim_at_top:
  1044   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1045   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z \<le> f x) F)"
  1046   by (auto simp: filterlim_iff eventually_at_top_linorder elim!: eventually_elim1)
  1047 
  1048 lemma filterlim_at_top_dense:
  1049   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)"
  1050   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. Z < f x) F)"
  1051   by (metis eventually_elim1[of _ F] eventually_gt_at_top order_less_imp_le
  1052             filterlim_at_top[of f F] filterlim_iff[of f at_top F])
  1053 
  1054 lemma filterlim_at_top_ge:
  1055   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1056   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1057   unfolding filterlim_at_top
  1058 proof safe
  1059   fix Z assume *: "\<forall>Z\<ge>c. eventually (\<lambda>x. Z \<le> f x) F"
  1060   with *[THEN spec, of "max Z c"] show "eventually (\<lambda>x. Z \<le> f x) F"
  1061     by (auto elim!: eventually_elim1)
  1062 qed simp
  1063 
  1064 lemma filterlim_at_top_at_top:
  1065   fixes f :: "'a::linorder \<Rightarrow> 'b::linorder"
  1066   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1067   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1068   assumes Q: "eventually Q at_top"
  1069   assumes P: "eventually P at_top"
  1070   shows "filterlim f at_top at_top"
  1071 proof -
  1072   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1073     unfolding eventually_at_top_linorder by auto
  1074   show ?thesis
  1075   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1076     fix z assume "x \<le> z"
  1077     with x have "P z" by auto
  1078     have "eventually (\<lambda>x. g z \<le> x) at_top"
  1079       by (rule eventually_ge_at_top)
  1080     with Q show "eventually (\<lambda>x. z \<le> f x) at_top"
  1081       by eventually_elim (metis mono bij `P z`)
  1082   qed
  1083 qed
  1084 
  1085 lemma filterlim_at_top_gt:
  1086   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1087   shows "(LIM x F. f x :> at_top) \<longleftrightarrow> (\<forall>Z>c. eventually (\<lambda>x. Z \<le> f x) F)"
  1088   by (metis filterlim_at_top order_less_le_trans gt_ex filterlim_at_top_ge)
  1089 
  1090 lemma filterlim_at_bot: 
  1091   fixes f :: "'a \<Rightarrow> ('b::linorder)"
  1092   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z. eventually (\<lambda>x. f x \<le> Z) F)"
  1093   by (auto simp: filterlim_iff eventually_at_bot_linorder elim!: eventually_elim1)
  1094 
  1095 lemma filterlim_at_bot_le:
  1096   fixes f :: "'a \<Rightarrow> ('b::linorder)" and c :: "'b"
  1097   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1098   unfolding filterlim_at_bot
  1099 proof safe
  1100   fix Z assume *: "\<forall>Z\<le>c. eventually (\<lambda>x. Z \<ge> f x) F"
  1101   with *[THEN spec, of "min Z c"] show "eventually (\<lambda>x. Z \<ge> f x) F"
  1102     by (auto elim!: eventually_elim1)
  1103 qed simp
  1104 
  1105 lemma filterlim_at_bot_lt:
  1106   fixes f :: "'a \<Rightarrow> ('b::dense_linorder)" and c :: "'b"
  1107   shows "(LIM x F. f x :> at_bot) \<longleftrightarrow> (\<forall>Z<c. eventually (\<lambda>x. Z \<ge> f x) F)"
  1108   by (metis filterlim_at_bot filterlim_at_bot_le lt_ex order_le_less_trans)
  1109 
  1110 lemma filterlim_at_bot_at_right:
  1111   fixes f :: "'a::{no_top, linorder_topology} \<Rightarrow> 'b::linorder"
  1112   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1113   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1114   assumes Q: "eventually Q (at_right a)" and bound: "\<And>b. Q b \<Longrightarrow> a < b"
  1115   assumes P: "eventually P at_bot"
  1116   shows "filterlim f at_bot (at_right a)"
  1117 proof -
  1118   from P obtain x where x: "\<And>y. y \<le> x \<Longrightarrow> P y"
  1119     unfolding eventually_at_bot_linorder by auto
  1120   show ?thesis
  1121   proof (intro filterlim_at_bot_le[THEN iffD2] allI impI)
  1122     fix z assume "z \<le> x"
  1123     with x have "P z" by auto
  1124     have "eventually (\<lambda>x. x \<le> g z) (at_right a)"
  1125       using bound[OF bij(2)[OF `P z`]]
  1126       unfolding eventually_at_right by (auto intro!: exI[of _ "g z"])
  1127     with Q show "eventually (\<lambda>x. f x \<le> z) (at_right a)"
  1128       by eventually_elim (metis bij `P z` mono)
  1129   qed
  1130 qed
  1131 
  1132 lemma filterlim_at_top_at_left:
  1133   fixes f :: "'a::{no_bot, linorder_topology} \<Rightarrow> 'b::linorder"
  1134   assumes mono: "\<And>x y. Q x \<Longrightarrow> Q y \<Longrightarrow> x \<le> y \<Longrightarrow> f x \<le> f y"
  1135   assumes bij: "\<And>x. P x \<Longrightarrow> f (g x) = x" "\<And>x. P x \<Longrightarrow> Q (g x)"
  1136   assumes Q: "eventually Q (at_left a)" and bound: "\<And>b. Q b \<Longrightarrow> b < a"
  1137   assumes P: "eventually P at_top"
  1138   shows "filterlim f at_top (at_left a)"
  1139 proof -
  1140   from P obtain x where x: "\<And>y. x \<le> y \<Longrightarrow> P y"
  1141     unfolding eventually_at_top_linorder by auto
  1142   show ?thesis
  1143   proof (intro filterlim_at_top_ge[THEN iffD2] allI impI)
  1144     fix z assume "x \<le> z"
  1145     with x have "P z" by auto
  1146     have "eventually (\<lambda>x. g z \<le> x) (at_left a)"
  1147       using bound[OF bij(2)[OF `P z`]]
  1148       unfolding eventually_at_left by (auto intro!: exI[of _ "g z"])
  1149     with Q show "eventually (\<lambda>x. z \<le> f x) (at_left a)"
  1150       by eventually_elim (metis bij `P z` mono)
  1151   qed
  1152 qed
  1153 
  1154 lemma filterlim_split_at:
  1155   "filterlim f F (at_left x) \<Longrightarrow> filterlim f F (at_right x) \<Longrightarrow> filterlim f F (at (x::'a::linorder_topology))"
  1156   by (subst at_eq_sup_left_right) (rule filterlim_sup)
  1157 
  1158 lemma filterlim_at_split:
  1159   "filterlim f F (at (x::'a::linorder_topology)) \<longleftrightarrow> filterlim f F (at_left x) \<and> filterlim f F (at_right x)"
  1160   by (subst at_eq_sup_left_right) (simp add: filterlim_def filtermap_sup)
  1161 
  1162 
  1163 subsection {* Limits on sequences *}
  1164 
  1165 abbreviation (in topological_space)
  1166   LIMSEQ :: "[nat \<Rightarrow> 'a, 'a] \<Rightarrow> bool"
  1167     ("((_)/ ----> (_))" [60, 60] 60) where
  1168   "X ----> L \<equiv> (X ---> L) sequentially"
  1169 
  1170 abbreviation (in t2_space) lim :: "(nat \<Rightarrow> 'a) \<Rightarrow> 'a" where
  1171   "lim X \<equiv> Lim sequentially X"
  1172 
  1173 definition (in topological_space) convergent :: "(nat \<Rightarrow> 'a) \<Rightarrow> bool" where
  1174   "convergent X = (\<exists>L. X ----> L)"
  1175 
  1176 lemma lim_def: "lim X = (THE L. X ----> L)"
  1177   unfolding Lim_def ..
  1178 
  1179 subsubsection {* Monotone sequences and subsequences *}
  1180 
  1181 definition
  1182   monoseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1183     --{*Definition of monotonicity.
  1184         The use of disjunction here complicates proofs considerably.
  1185         One alternative is to add a Boolean argument to indicate the direction.
  1186         Another is to develop the notions of increasing and decreasing first.*}
  1187   "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
  1188 
  1189 definition
  1190   incseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1191     --{*Increasing sequence*}
  1192   "incseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
  1193 
  1194 definition
  1195   decseq :: "(nat \<Rightarrow> 'a::order) \<Rightarrow> bool" where
  1196     --{*Decreasing sequence*}
  1197   "decseq X \<longleftrightarrow> (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
  1198 
  1199 definition
  1200   subseq :: "(nat \<Rightarrow> nat) \<Rightarrow> bool" where
  1201     --{*Definition of subsequence*}
  1202   "subseq f \<longleftrightarrow> (\<forall>m. \<forall>n>m. f m < f n)"
  1203 
  1204 lemma incseq_mono: "mono f \<longleftrightarrow> incseq f"
  1205   unfolding mono_def incseq_def by auto
  1206 
  1207 lemma incseq_SucI:
  1208   "(\<And>n. X n \<le> X (Suc n)) \<Longrightarrow> incseq X"
  1209   using lift_Suc_mono_le[of X]
  1210   by (auto simp: incseq_def)
  1211 
  1212 lemma incseqD: "\<And>i j. incseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f i \<le> f j"
  1213   by (auto simp: incseq_def)
  1214 
  1215 lemma incseq_SucD: "incseq A \<Longrightarrow> A i \<le> A (Suc i)"
  1216   using incseqD[of A i "Suc i"] by auto
  1217 
  1218 lemma incseq_Suc_iff: "incseq f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1219   by (auto intro: incseq_SucI dest: incseq_SucD)
  1220 
  1221 lemma incseq_const[simp, intro]: "incseq (\<lambda>x. k)"
  1222   unfolding incseq_def by auto
  1223 
  1224 lemma decseq_SucI:
  1225   "(\<And>n. X (Suc n) \<le> X n) \<Longrightarrow> decseq X"
  1226   using order.lift_Suc_mono_le[OF dual_order, of X]
  1227   by (auto simp: decseq_def)
  1228 
  1229 lemma decseqD: "\<And>i j. decseq f \<Longrightarrow> i \<le> j \<Longrightarrow> f j \<le> f i"
  1230   by (auto simp: decseq_def)
  1231 
  1232 lemma decseq_SucD: "decseq A \<Longrightarrow> A (Suc i) \<le> A i"
  1233   using decseqD[of A i "Suc i"] by auto
  1234 
  1235 lemma decseq_Suc_iff: "decseq f \<longleftrightarrow> (\<forall>n. f (Suc n) \<le> f n)"
  1236   by (auto intro: decseq_SucI dest: decseq_SucD)
  1237 
  1238 lemma decseq_const[simp, intro]: "decseq (\<lambda>x. k)"
  1239   unfolding decseq_def by auto
  1240 
  1241 lemma monoseq_iff: "monoseq X \<longleftrightarrow> incseq X \<or> decseq X"
  1242   unfolding monoseq_def incseq_def decseq_def ..
  1243 
  1244 lemma monoseq_Suc:
  1245   "monoseq X \<longleftrightarrow> (\<forall>n. X n \<le> X (Suc n)) \<or> (\<forall>n. X (Suc n) \<le> X n)"
  1246   unfolding monoseq_iff incseq_Suc_iff decseq_Suc_iff ..
  1247 
  1248 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
  1249 by (simp add: monoseq_def)
  1250 
  1251 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
  1252 by (simp add: monoseq_def)
  1253 
  1254 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
  1255 by (simp add: monoseq_Suc)
  1256 
  1257 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
  1258 by (simp add: monoseq_Suc)
  1259 
  1260 lemma monoseq_minus:
  1261   fixes a :: "nat \<Rightarrow> 'a::ordered_ab_group_add"
  1262   assumes "monoseq a"
  1263   shows "monoseq (\<lambda> n. - a n)"
  1264 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
  1265   case True
  1266   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
  1267   thus ?thesis by (rule monoI2)
  1268 next
  1269   case False
  1270   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
  1271   thus ?thesis by (rule monoI1)
  1272 qed
  1273 
  1274 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
  1275 
  1276 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
  1277 apply (simp add: subseq_def)
  1278 apply (auto dest!: less_imp_Suc_add)
  1279 apply (induct_tac k)
  1280 apply (auto intro: less_trans)
  1281 done
  1282 
  1283 text{* for any sequence, there is a monotonic subsequence *}
  1284 lemma seq_monosub:
  1285   fixes s :: "nat => 'a::linorder"
  1286   shows "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
  1287 proof cases
  1288   let "?P p n" = "p > n \<and> (\<forall>m\<ge>p. s m \<le> s p)"
  1289   assume *: "\<forall>n. \<exists>p. ?P p n"
  1290   def f \<equiv> "nat_rec (SOME p. ?P p 0) (\<lambda>_ n. SOME p. ?P p n)"
  1291   have f_0: "f 0 = (SOME p. ?P p 0)" unfolding f_def by simp
  1292   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
  1293   have P_0: "?P (f 0) 0" unfolding f_0 using *[rule_format] by (rule someI2_ex) auto
  1294   have P_Suc: "\<And>i. ?P (f (Suc i)) (f i)" unfolding f_Suc using *[rule_format] by (rule someI2_ex) auto
  1295   then have "subseq f" unfolding subseq_Suc_iff by auto
  1296   moreover have "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc
  1297   proof (intro disjI2 allI)
  1298     fix n show "s (f (Suc n)) \<le> s (f n)"
  1299     proof (cases n)
  1300       case 0 with P_Suc[of 0] P_0 show ?thesis by auto
  1301     next
  1302       case (Suc m)
  1303       from P_Suc[of n] Suc have "f (Suc m) \<le> f (Suc (Suc m))" by simp
  1304       with P_Suc Suc show ?thesis by simp
  1305     qed
  1306   qed
  1307   ultimately show ?thesis by auto
  1308 next
  1309   let "?P p m" = "m < p \<and> s m < s p"
  1310   assume "\<not> (\<forall>n. \<exists>p>n. (\<forall>m\<ge>p. s m \<le> s p))"
  1311   then obtain N where N: "\<And>p. p > N \<Longrightarrow> \<exists>m>p. s p < s m" by (force simp: not_le le_less)
  1312   def f \<equiv> "nat_rec (SOME p. ?P p (Suc N)) (\<lambda>_ n. SOME p. ?P p n)"
  1313   have f_0: "f 0 = (SOME p. ?P p (Suc N))" unfolding f_def by simp
  1314   have f_Suc: "\<And>i. f (Suc i) = (SOME p. ?P p (f i))" unfolding f_def nat_rec_Suc ..
  1315   have P_0: "?P (f 0) (Suc N)"
  1316     unfolding f_0 some_eq_ex[of "\<lambda>p. ?P p (Suc N)"] using N[of "Suc N"] by auto
  1317   { fix i have "N < f i \<Longrightarrow> ?P (f (Suc i)) (f i)"
  1318       unfolding f_Suc some_eq_ex[of "\<lambda>p. ?P p (f i)"] using N[of "f i"] . }
  1319   note P' = this
  1320   { fix i have "N < f i \<and> ?P (f (Suc i)) (f i)"
  1321       by (induct i) (insert P_0 P', auto) }
  1322   then have "subseq f" "monoseq (\<lambda>x. s (f x))"
  1323     unfolding subseq_Suc_iff monoseq_Suc by (auto simp: not_le intro: less_imp_le)
  1324   then show ?thesis by auto
  1325 qed
  1326 
  1327 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
  1328 proof(induct n)
  1329   case 0 thus ?case by simp
  1330 next
  1331   case (Suc n)
  1332   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
  1333   have "n < f (Suc n)" by arith
  1334   thus ?case by arith
  1335 qed
  1336 
  1337 lemma eventually_subseq:
  1338   "subseq r \<Longrightarrow> eventually P sequentially \<Longrightarrow> eventually (\<lambda>n. P (r n)) sequentially"
  1339   unfolding eventually_sequentially by (metis seq_suble le_trans)
  1340 
  1341 lemma not_eventually_sequentiallyD:
  1342   assumes P: "\<not> eventually P sequentially"
  1343   shows "\<exists>r. subseq r \<and> (\<forall>n. \<not> P (r n))"
  1344 proof -
  1345   from P have "\<forall>n. \<exists>m\<ge>n. \<not> P m"
  1346     unfolding eventually_sequentially by (simp add: not_less)
  1347   then obtain r where "\<And>n. r n \<ge> n" "\<And>n. \<not> P (r n)"
  1348     by (auto simp: choice_iff)
  1349   then show ?thesis
  1350     by (auto intro!: exI[of _ "\<lambda>n. r (((Suc \<circ> r) ^^ Suc n) 0)"]
  1351              simp: less_eq_Suc_le subseq_Suc_iff)
  1352 qed
  1353 
  1354 lemma filterlim_subseq: "subseq f \<Longrightarrow> filterlim f sequentially sequentially"
  1355   unfolding filterlim_iff by (metis eventually_subseq)
  1356 
  1357 lemma subseq_o: "subseq r \<Longrightarrow> subseq s \<Longrightarrow> subseq (r \<circ> s)"
  1358   unfolding subseq_def by simp
  1359 
  1360 lemma subseq_mono: assumes "subseq r" "m < n" shows "r m < r n"
  1361   using assms by (auto simp: subseq_def)
  1362 
  1363 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
  1364   by (simp add: incseq_def monoseq_def)
  1365 
  1366 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
  1367   by (simp add: decseq_def monoseq_def)
  1368 
  1369 lemma decseq_eq_incseq:
  1370   fixes X :: "nat \<Rightarrow> 'a::ordered_ab_group_add" shows "decseq X = incseq (\<lambda>n. - X n)" 
  1371   by (simp add: decseq_def incseq_def)
  1372 
  1373 lemma INT_decseq_offset:
  1374   assumes "decseq F"
  1375   shows "(\<Inter>i. F i) = (\<Inter>i\<in>{n..}. F i)"
  1376 proof safe
  1377   fix x i assume x: "x \<in> (\<Inter>i\<in>{n..}. F i)"
  1378   show "x \<in> F i"
  1379   proof cases
  1380     from x have "x \<in> F n" by auto
  1381     also assume "i \<le> n" with `decseq F` have "F n \<subseteq> F i"
  1382       unfolding decseq_def by simp
  1383     finally show ?thesis .
  1384   qed (insert x, simp)
  1385 qed auto
  1386 
  1387 lemma LIMSEQ_const_iff:
  1388   fixes k l :: "'a::t2_space"
  1389   shows "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
  1390   using trivial_limit_sequentially by (rule tendsto_const_iff)
  1391 
  1392 lemma LIMSEQ_SUP:
  1393   "incseq X \<Longrightarrow> X ----> (SUP i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1394   by (intro increasing_tendsto)
  1395      (auto simp: SUP_upper less_SUP_iff incseq_def eventually_sequentially intro: less_le_trans)
  1396 
  1397 lemma LIMSEQ_INF:
  1398   "decseq X \<Longrightarrow> X ----> (INF i. X i :: 'a :: {complete_linorder, linorder_topology})"
  1399   by (intro decreasing_tendsto)
  1400      (auto simp: INF_lower INF_less_iff decseq_def eventually_sequentially intro: le_less_trans)
  1401 
  1402 lemma LIMSEQ_ignore_initial_segment:
  1403   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
  1404   unfolding tendsto_def
  1405   by (subst eventually_sequentially_seg[where k=k])
  1406 
  1407 lemma LIMSEQ_offset:
  1408   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
  1409   unfolding tendsto_def
  1410   by (subst (asm) eventually_sequentially_seg[where k=k])
  1411 
  1412 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
  1413 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
  1414 
  1415 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
  1416 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
  1417 
  1418 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
  1419 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
  1420 
  1421 lemma LIMSEQ_unique:
  1422   fixes a b :: "'a::t2_space"
  1423   shows "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
  1424   using trivial_limit_sequentially by (rule tendsto_unique)
  1425 
  1426 lemma LIMSEQ_le_const:
  1427   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
  1428   using tendsto_le_const[of sequentially X x a] by (simp add: eventually_sequentially)
  1429 
  1430 lemma LIMSEQ_le:
  1431   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::'a::linorder_topology)"
  1432   using tendsto_le[of sequentially Y y X x] by (simp add: eventually_sequentially)
  1433 
  1434 lemma LIMSEQ_le_const2:
  1435   "\<lbrakk>X ----> (x::'a::linorder_topology); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
  1436   by (rule LIMSEQ_le[of X x "\<lambda>n. a"]) (auto simp: tendsto_const)
  1437 
  1438 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
  1439 by (simp add: convergent_def)
  1440 
  1441 lemma convergentI: "(X ----> L) ==> convergent X"
  1442 by (auto simp add: convergent_def)
  1443 
  1444 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
  1445 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
  1446 
  1447 lemma convergent_const: "convergent (\<lambda>n. c)"
  1448   by (rule convergentI, rule tendsto_const)
  1449 
  1450 lemma monoseq_le:
  1451   "monoseq a \<Longrightarrow> a ----> (x::'a::linorder_topology) \<Longrightarrow>
  1452     ((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
  1453   by (metis LIMSEQ_le_const LIMSEQ_le_const2 decseq_def incseq_def monoseq_iff)
  1454 
  1455 lemma LIMSEQ_subseq_LIMSEQ:
  1456   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
  1457   unfolding comp_def by (rule filterlim_compose[of X, OF _ filterlim_subseq])
  1458 
  1459 lemma convergent_subseq_convergent:
  1460   "\<lbrakk>convergent X; subseq f\<rbrakk> \<Longrightarrow> convergent (X o f)"
  1461   unfolding convergent_def by (auto intro: LIMSEQ_subseq_LIMSEQ)
  1462 
  1463 lemma limI: "X ----> L ==> lim X = L"
  1464 apply (simp add: lim_def)
  1465 apply (blast intro: LIMSEQ_unique)
  1466 done
  1467 
  1468 lemma lim_le: "convergent f \<Longrightarrow> (\<And>n. f n \<le> (x::'a::linorder_topology)) \<Longrightarrow> lim f \<le> x"
  1469   using LIMSEQ_le_const2[of f "lim f" x] by (simp add: convergent_LIMSEQ_iff)
  1470 
  1471 subsubsection{*Increasing and Decreasing Series*}
  1472 
  1473 lemma incseq_le: "incseq X \<Longrightarrow> X ----> L \<Longrightarrow> X n \<le> (L::'a::linorder_topology)"
  1474   by (metis incseq_def LIMSEQ_le_const)
  1475 
  1476 lemma decseq_le: "decseq X \<Longrightarrow> X ----> L \<Longrightarrow> (L::'a::linorder_topology) \<le> X n"
  1477   by (metis decseq_def LIMSEQ_le_const2)
  1478 
  1479 subsection {* First countable topologies *}
  1480 
  1481 class first_countable_topology = topological_space +
  1482   assumes first_countable_basis:
  1483     "\<exists>A::nat \<Rightarrow> 'a set. (\<forall>i. x \<in> A i \<and> open (A i)) \<and> (\<forall>S. open S \<and> x \<in> S \<longrightarrow> (\<exists>i. A i \<subseteq> S))"
  1484 
  1485 lemma (in first_countable_topology) countable_basis_at_decseq:
  1486   obtains A :: "nat \<Rightarrow> 'a set" where
  1487     "\<And>i. open (A i)" "\<And>i. x \<in> (A i)"
  1488     "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially"
  1489 proof atomize_elim
  1490   from first_countable_basis[of x] obtain A :: "nat \<Rightarrow> 'a set" where
  1491     nhds: "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1492     and incl: "\<And>S. open S \<Longrightarrow> x \<in> S \<Longrightarrow> \<exists>i. A i \<subseteq> S"  by auto
  1493   def F \<equiv> "\<lambda>n. \<Inter>i\<le>n. A i"
  1494   show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and>
  1495       (\<forall>S. open S \<longrightarrow> x \<in> S \<longrightarrow> eventually (\<lambda>i. A i \<subseteq> S) sequentially)"
  1496   proof (safe intro!: exI[of _ F])
  1497     fix i
  1498     show "open (F i)" using nhds(1) by (auto simp: F_def)
  1499     show "x \<in> F i" using nhds(2) by (auto simp: F_def)
  1500   next
  1501     fix S assume "open S" "x \<in> S"
  1502     from incl[OF this] obtain i where "F i \<subseteq> S" unfolding F_def by auto
  1503     moreover have "\<And>j. i \<le> j \<Longrightarrow> F j \<subseteq> F i"
  1504       by (auto simp: F_def)
  1505     ultimately show "eventually (\<lambda>i. F i \<subseteq> S) sequentially"
  1506       by (auto simp: eventually_sequentially)
  1507   qed
  1508 qed
  1509 
  1510 lemma (in first_countable_topology) countable_basis:
  1511   obtains A :: "nat \<Rightarrow> 'a set" where
  1512     "\<And>i. open (A i)" "\<And>i. x \<in> A i"
  1513     "\<And>F. (\<forall>n. F n \<in> A n) \<Longrightarrow> F ----> x"
  1514 proof atomize_elim
  1515   from countable_basis_at_decseq[of x] guess A . note A = this
  1516   { fix F S assume "\<forall>n. F n \<in> A n" "open S" "x \<in> S"
  1517     with A(3)[of S] have "eventually (\<lambda>n. F n \<in> S) sequentially"
  1518       by (auto elim: eventually_elim1 simp: subset_eq) }
  1519   with A show "\<exists>A. (\<forall>i. open (A i)) \<and> (\<forall>i. x \<in> A i) \<and> (\<forall>F. (\<forall>n. F n \<in> A n) \<longrightarrow> F ----> x)"
  1520     by (intro exI[of _ A]) (auto simp: tendsto_def)
  1521 qed
  1522 
  1523 lemma (in first_countable_topology) sequentially_imp_eventually_nhds_within:
  1524   assumes "\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially"
  1525   shows "eventually P (inf (nhds a) (principal s))"
  1526 proof (rule ccontr)
  1527   from countable_basis[of a] guess A . note A = this
  1528   assume "\<not> eventually P (inf (nhds a) (principal s))"
  1529   with A have P: "\<exists>F. \<forall>n. F n \<in> s \<and> F n \<in> A n \<and> \<not> P (F n)"
  1530     unfolding eventually_inf_principal eventually_nhds by (intro choice) fastforce
  1531   then guess F ..
  1532   hence F0: "\<forall>n. F n \<in> s" and F2: "\<forall>n. F n \<in> A n" and F3: "\<forall>n. \<not> P (F n)"
  1533     by fast+
  1534   with A have "F ----> a" by auto
  1535   hence "eventually (\<lambda>n. P (F n)) sequentially"
  1536     using assms F0 by simp
  1537   thus "False" by (simp add: F3)
  1538 qed
  1539 
  1540 lemma (in first_countable_topology) eventually_nhds_within_iff_sequentially:
  1541   "eventually P (inf (nhds a) (principal s)) \<longleftrightarrow> 
  1542     (\<forall>f. (\<forall>n. f n \<in> s) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1543 proof (safe intro!: sequentially_imp_eventually_nhds_within)
  1544   assume "eventually P (inf (nhds a) (principal s))" 
  1545   then obtain S where "open S" "a \<in> S" "\<forall>x\<in>S. x \<in> s \<longrightarrow> P x"
  1546     by (auto simp: eventually_inf_principal eventually_nhds)
  1547   moreover fix f assume "\<forall>n. f n \<in> s" "f ----> a"
  1548   ultimately show "eventually (\<lambda>n. P (f n)) sequentially"
  1549     by (auto dest!: topological_tendstoD elim: eventually_elim1)
  1550 qed
  1551 
  1552 lemma (in first_countable_topology) eventually_nhds_iff_sequentially:
  1553   "eventually P (nhds a) \<longleftrightarrow> (\<forall>f. f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially)"
  1554   using eventually_nhds_within_iff_sequentially[of P a UNIV] by simp
  1555 
  1556 subsection {* Function limit at a point *}
  1557 
  1558 abbreviation
  1559   LIM :: "('a::topological_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> 'b \<Rightarrow> bool"
  1560         ("((_)/ -- (_)/ --> (_))" [60, 0, 60] 60) where
  1561   "f -- a --> L \<equiv> (f ---> L) (at a)"
  1562 
  1563 lemma tendsto_within_open: "a \<in> S \<Longrightarrow> open S \<Longrightarrow> (f ---> l) (at a within S) \<longleftrightarrow> (f -- a --> l)"
  1564   unfolding tendsto_def by (simp add: at_within_open[where S=S])
  1565 
  1566 lemma LIM_const_not_eq[tendsto_intros]:
  1567   fixes a :: "'a::perfect_space"
  1568   fixes k L :: "'b::t2_space"
  1569   shows "k \<noteq> L \<Longrightarrow> \<not> (\<lambda>x. k) -- a --> L"
  1570   by (simp add: tendsto_const_iff)
  1571 
  1572 lemmas LIM_not_zero = LIM_const_not_eq [where L = 0]
  1573 
  1574 lemma LIM_const_eq:
  1575   fixes a :: "'a::perfect_space"
  1576   fixes k L :: "'b::t2_space"
  1577   shows "(\<lambda>x. k) -- a --> L \<Longrightarrow> k = L"
  1578   by (simp add: tendsto_const_iff)
  1579 
  1580 lemma LIM_unique:
  1581   fixes a :: "'a::perfect_space" and L M :: "'b::t2_space"
  1582   shows "f -- a --> L \<Longrightarrow> f -- a --> M \<Longrightarrow> L = M"
  1583   using at_neq_bot by (rule tendsto_unique)
  1584 
  1585 text {* Limits are equal for functions equal except at limit point *}
  1586 
  1587 lemma LIM_equal: "\<forall>x. x \<noteq> a --> (f x = g x) \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- a --> l)"
  1588   unfolding tendsto_def eventually_at_topological by simp
  1589 
  1590 lemma LIM_cong: "a = b \<Longrightarrow> (\<And>x. x \<noteq> b \<Longrightarrow> f x = g x) \<Longrightarrow> l = m \<Longrightarrow> (f -- a --> l) \<longleftrightarrow> (g -- b --> m)"
  1591   by (simp add: LIM_equal)
  1592 
  1593 lemma LIM_cong_limit: "f -- x --> L \<Longrightarrow> K = L \<Longrightarrow> f -- x --> K"
  1594   by simp
  1595 
  1596 lemma tendsto_at_iff_tendsto_nhds:
  1597   "g -- l --> g l \<longleftrightarrow> (g ---> g l) (nhds l)"
  1598   unfolding tendsto_def eventually_at_filter
  1599   by (intro ext all_cong imp_cong) (auto elim!: eventually_elim1)
  1600 
  1601 lemma tendsto_compose:
  1602   "g -- l --> g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1603   unfolding tendsto_at_iff_tendsto_nhds by (rule filterlim_compose[of g])
  1604 
  1605 lemma LIM_o: "\<lbrakk>g -- l --> g l; f -- a --> l\<rbrakk> \<Longrightarrow> (g \<circ> f) -- a --> g l"
  1606   unfolding o_def by (rule tendsto_compose)
  1607 
  1608 lemma tendsto_compose_eventually:
  1609   "g -- l --> m \<Longrightarrow> (f ---> l) F \<Longrightarrow> eventually (\<lambda>x. f x \<noteq> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> m) F"
  1610   by (rule filterlim_compose[of g _ "at l"]) (auto simp add: filterlim_at)
  1611 
  1612 lemma LIM_compose_eventually:
  1613   assumes f: "f -- a --> b"
  1614   assumes g: "g -- b --> c"
  1615   assumes inj: "eventually (\<lambda>x. f x \<noteq> b) (at a)"
  1616   shows "(\<lambda>x. g (f x)) -- a --> c"
  1617   using g f inj by (rule tendsto_compose_eventually)
  1618 
  1619 subsubsection {* Relation of LIM and LIMSEQ *}
  1620 
  1621 lemma (in first_countable_topology) sequentially_imp_eventually_within:
  1622   "(\<forall>f. (\<forall>n. f n \<in> s \<and> f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow>
  1623     eventually P (at a within s)"
  1624   unfolding at_within_def
  1625   by (intro sequentially_imp_eventually_nhds_within) auto
  1626 
  1627 lemma (in first_countable_topology) sequentially_imp_eventually_at:
  1628   "(\<forall>f. (\<forall>n. f n \<noteq> a) \<and> f ----> a \<longrightarrow> eventually (\<lambda>n. P (f n)) sequentially) \<Longrightarrow> eventually P (at a)"
  1629   using assms sequentially_imp_eventually_within [where s=UNIV] by simp
  1630 
  1631 lemma LIMSEQ_SEQ_conv1:
  1632   fixes f :: "'a::topological_space \<Rightarrow> 'b::topological_space"
  1633   assumes f: "f -- a --> l"
  1634   shows "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1635   using tendsto_compose_eventually [OF f, where F=sequentially] by simp
  1636 
  1637 lemma LIMSEQ_SEQ_conv2:
  1638   fixes f :: "'a::first_countable_topology \<Rightarrow> 'b::topological_space"
  1639   assumes "\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> a \<longrightarrow> (\<lambda>n. f (S n)) ----> l"
  1640   shows "f -- a --> l"
  1641   using assms unfolding tendsto_def [where l=l] by (simp add: sequentially_imp_eventually_at)
  1642 
  1643 lemma LIMSEQ_SEQ_conv:
  1644   "(\<forall>S. (\<forall>n. S n \<noteq> a) \<and> S ----> (a::'a::first_countable_topology) \<longrightarrow> (\<lambda>n. X (S n)) ----> L) =
  1645    (X -- a --> (L::'b::topological_space))"
  1646   using LIMSEQ_SEQ_conv2 LIMSEQ_SEQ_conv1 ..
  1647 
  1648 subsection {* Continuity *}
  1649 
  1650 subsubsection {* Continuity on a set *}
  1651 
  1652 definition continuous_on :: "'a set \<Rightarrow> ('a :: topological_space \<Rightarrow> 'b :: topological_space) \<Rightarrow> bool" where
  1653   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. (f ---> f x) (at x within s))"
  1654 
  1655 lemma continuous_on_cong [cong]:
  1656   "s = t \<Longrightarrow> (\<And>x. x \<in> t \<Longrightarrow> f x = g x) \<Longrightarrow> continuous_on s f \<longleftrightarrow> continuous_on t g"
  1657   unfolding continuous_on_def by (intro ball_cong filterlim_cong) (auto simp: eventually_at_filter)
  1658 
  1659 lemma continuous_on_topological:
  1660   "continuous_on s f \<longleftrightarrow>
  1661     (\<forall>x\<in>s. \<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1662   unfolding continuous_on_def tendsto_def eventually_at_topological by metis
  1663 
  1664 lemma continuous_on_open_invariant:
  1665   "continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s))"
  1666 proof safe
  1667   fix B :: "'b set" assume "continuous_on s f" "open B"
  1668   then have "\<forall>x\<in>f -` B \<inter> s. (\<exists>A. open A \<and> x \<in> A \<and> s \<inter> A \<subseteq> f -` B)"
  1669     by (auto simp: continuous_on_topological subset_eq Ball_def imp_conjL)
  1670   then guess A unfolding bchoice_iff ..
  1671   then show "\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s"
  1672     by (intro exI[of _ "\<Union>x\<in>f -` B \<inter> s. A x"]) auto
  1673 next
  1674   assume B: "\<forall>B. open B \<longrightarrow> (\<exists>A. open A \<and> A \<inter> s = f -` B \<inter> s)"
  1675   show "continuous_on s f"
  1676     unfolding continuous_on_topological
  1677   proof safe
  1678     fix x B assume "x \<in> s" "open B" "f x \<in> B"
  1679     with B obtain A where A: "open A" "A \<inter> s = f -` B \<inter> s" by auto
  1680     with `x \<in> s` `f x \<in> B` show "\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)"
  1681       by (intro exI[of _ A]) auto
  1682   qed
  1683 qed
  1684 
  1685 lemma continuous_on_open_vimage:
  1686   "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. open B \<longrightarrow> open (f -` B \<inter> s))"
  1687   unfolding continuous_on_open_invariant
  1688   by (metis open_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1689 
  1690 lemma continuous_on_closed_invariant:
  1691   "continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> (\<exists>A. closed A \<and> A \<inter> s = f -` B \<inter> s))"
  1692 proof -
  1693   have *: "\<And>P Q::'b set\<Rightarrow>bool. (\<And>A. P A \<longleftrightarrow> Q (- A)) \<Longrightarrow> (\<forall>A. P A) \<longleftrightarrow> (\<forall>A. Q A)"
  1694     by (metis double_compl)
  1695   show ?thesis
  1696     unfolding continuous_on_open_invariant by (intro *) (auto simp: open_closed[symmetric])
  1697 qed
  1698 
  1699 lemma continuous_on_closed_vimage:
  1700   "closed s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>B. closed B \<longrightarrow> closed (f -` B \<inter> s))"
  1701   unfolding continuous_on_closed_invariant
  1702   by (metis closed_Int Int_absorb Int_commute[of s] Int_assoc[of _ _ s])
  1703 
  1704 lemma continuous_on_open_Union:
  1705   "(\<And>s. s \<in> S \<Longrightarrow> open s) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on s f) \<Longrightarrow> continuous_on (\<Union>S) f"
  1706   unfolding continuous_on_def by safe (metis open_Union at_within_open UnionI)
  1707 
  1708 lemma continuous_on_open_UN:
  1709   "(\<And>s. s \<in> S \<Longrightarrow> open (A s)) \<Longrightarrow> (\<And>s. s \<in> S \<Longrightarrow> continuous_on (A s) f) \<Longrightarrow> continuous_on (\<Union>s\<in>S. A s) f"
  1710   unfolding Union_image_eq[symmetric] by (rule continuous_on_open_Union) auto
  1711 
  1712 lemma continuous_on_closed_Un:
  1713   "closed s \<Longrightarrow> closed t \<Longrightarrow> continuous_on s f \<Longrightarrow> continuous_on t f \<Longrightarrow> continuous_on (s \<union> t) f"
  1714   by (auto simp add: continuous_on_closed_vimage closed_Un Int_Un_distrib)
  1715 
  1716 lemma continuous_on_If:
  1717   assumes closed: "closed s" "closed t" and cont: "continuous_on s f" "continuous_on t g"
  1718     and P: "\<And>x. x \<in> s \<Longrightarrow> \<not> P x \<Longrightarrow> f x = g x" "\<And>x. x \<in> t \<Longrightarrow> P x \<Longrightarrow> f x = g x"
  1719   shows "continuous_on (s \<union> t) (\<lambda>x. if P x then f x else g x)" (is "continuous_on _ ?h")
  1720 proof-
  1721   from P have "\<forall>x\<in>s. f x = ?h x" "\<forall>x\<in>t. g x = ?h x"
  1722     by auto
  1723   with cont have "continuous_on s ?h" "continuous_on t ?h"
  1724     by simp_all
  1725   with closed show ?thesis
  1726     by (rule continuous_on_closed_Un)
  1727 qed
  1728 
  1729 ML {*
  1730 
  1731 structure Continuous_On_Intros = Named_Thms
  1732 (
  1733   val name = @{binding continuous_on_intros}
  1734   val description = "Structural introduction rules for setwise continuity"
  1735 )
  1736 
  1737 *}
  1738 
  1739 setup Continuous_On_Intros.setup
  1740 
  1741 lemma continuous_on_id[continuous_on_intros]: "continuous_on s (\<lambda>x. x)"
  1742   unfolding continuous_on_def by (fast intro: tendsto_ident_at)
  1743 
  1744 lemma continuous_on_const[continuous_on_intros]: "continuous_on s (\<lambda>x. c)"
  1745   unfolding continuous_on_def by (auto intro: tendsto_const)
  1746 
  1747 lemma continuous_on_compose[continuous_on_intros]:
  1748   "continuous_on s f \<Longrightarrow> continuous_on (f ` s) g \<Longrightarrow> continuous_on s (g o f)"
  1749   unfolding continuous_on_topological by simp metis
  1750 
  1751 lemma continuous_on_compose2:
  1752   "continuous_on t g \<Longrightarrow> continuous_on s f \<Longrightarrow> t = f ` s \<Longrightarrow> continuous_on s (\<lambda>x. g (f x))"
  1753   using continuous_on_compose[of s f g] by (simp add: comp_def)
  1754 
  1755 subsubsection {* Continuity at a point *}
  1756 
  1757 definition continuous :: "'a::t2_space filter \<Rightarrow> ('a \<Rightarrow> 'b::topological_space) \<Rightarrow> bool" where
  1758   "continuous F f \<longleftrightarrow> (f ---> f (Lim F (\<lambda>x. x))) F"
  1759 
  1760 ML {*
  1761 
  1762 structure Continuous_Intros = Named_Thms
  1763 (
  1764   val name = @{binding continuous_intros}
  1765   val description = "Structural introduction rules for pointwise continuity"
  1766 )
  1767 
  1768 *}
  1769 
  1770 setup Continuous_Intros.setup
  1771 
  1772 lemma continuous_bot[continuous_intros, simp]: "continuous bot f"
  1773   unfolding continuous_def by auto
  1774 
  1775 lemma continuous_trivial_limit: "trivial_limit net \<Longrightarrow> continuous net f"
  1776   by simp
  1777 
  1778 lemma continuous_within: "continuous (at x within s) f \<longleftrightarrow> (f ---> f x) (at x within s)"
  1779   by (cases "trivial_limit (at x within s)") (auto simp add: Lim_ident_at continuous_def)
  1780 
  1781 lemma continuous_within_topological:
  1782   "continuous (at x within s) f \<longleftrightarrow>
  1783     (\<forall>B. open B \<longrightarrow> f x \<in> B \<longrightarrow> (\<exists>A. open A \<and> x \<in> A \<and> (\<forall>y\<in>s. y \<in> A \<longrightarrow> f y \<in> B)))"
  1784   unfolding continuous_within tendsto_def eventually_at_topological by metis
  1785 
  1786 lemma continuous_within_compose[continuous_intros]:
  1787   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1788   continuous (at x within s) (g o f)"
  1789   by (simp add: continuous_within_topological) metis
  1790 
  1791 lemma continuous_within_compose2:
  1792   "continuous (at x within s) f \<Longrightarrow> continuous (at (f x) within f ` s) g \<Longrightarrow>
  1793   continuous (at x within s) (\<lambda>x. g (f x))"
  1794   using continuous_within_compose[of x s f g] by (simp add: comp_def)
  1795 
  1796 lemma continuous_at: "continuous (at x) f \<longleftrightarrow> f -- x --> f x"
  1797   using continuous_within[of x UNIV f] by simp
  1798 
  1799 lemma continuous_ident[continuous_intros, simp]: "continuous (at x within S) (\<lambda>x. x)"
  1800   unfolding continuous_within by (rule tendsto_ident_at)
  1801 
  1802 lemma continuous_const[continuous_intros, simp]: "continuous F (\<lambda>x. c)"
  1803   unfolding continuous_def by (rule tendsto_const)
  1804 
  1805 lemma continuous_on_eq_continuous_within:
  1806   "continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. continuous (at x within s) f)"
  1807   unfolding continuous_on_def continuous_within ..
  1808 
  1809 abbreviation isCont :: "('a::t2_space \<Rightarrow> 'b::topological_space) \<Rightarrow> 'a \<Rightarrow> bool" where
  1810   "isCont f a \<equiv> continuous (at a) f"
  1811 
  1812 lemma isCont_def: "isCont f a \<longleftrightarrow> f -- a --> f a"
  1813   by (rule continuous_at)
  1814 
  1815 lemma continuous_at_within: "isCont f x \<Longrightarrow> continuous (at x within s) f"
  1816   by (auto intro: tendsto_mono at_le simp: continuous_at continuous_within)
  1817 
  1818 lemma continuous_on_eq_continuous_at: "open s \<Longrightarrow> continuous_on s f \<longleftrightarrow> (\<forall>x\<in>s. isCont f x)"
  1819   by (simp add: continuous_on_def continuous_at at_within_open[of _ s])
  1820 
  1821 lemma continuous_on_subset: "continuous_on s f \<Longrightarrow> t \<subseteq> s \<Longrightarrow> continuous_on t f"
  1822   unfolding continuous_on_def by (metis subset_eq tendsto_within_subset)
  1823 
  1824 lemma continuous_at_imp_continuous_on: "\<forall>x\<in>s. isCont f x \<Longrightarrow> continuous_on s f"
  1825   by (auto intro: continuous_at_within simp: continuous_on_eq_continuous_within)
  1826 
  1827 lemma isContI_continuous: "continuous (at x within UNIV) f \<Longrightarrow> isCont f x"
  1828   by simp
  1829 
  1830 lemma isCont_ident[continuous_intros, simp]: "isCont (\<lambda>x. x) a"
  1831   using continuous_ident by (rule isContI_continuous)
  1832 
  1833 lemmas isCont_const = continuous_const
  1834 
  1835 lemma isCont_o2: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (\<lambda>x. g (f x)) a"
  1836   unfolding isCont_def by (rule tendsto_compose)
  1837 
  1838 lemma isCont_o[continuous_intros]: "isCont f a \<Longrightarrow> isCont g (f a) \<Longrightarrow> isCont (g \<circ> f) a"
  1839   unfolding o_def by (rule isCont_o2)
  1840 
  1841 lemma isCont_tendsto_compose: "isCont g l \<Longrightarrow> (f ---> l) F \<Longrightarrow> ((\<lambda>x. g (f x)) ---> g l) F"
  1842   unfolding isCont_def by (rule tendsto_compose)
  1843 
  1844 lemma continuous_within_compose3:
  1845   "isCont g (f x) \<Longrightarrow> continuous (at x within s) f \<Longrightarrow> continuous (at x within s) (\<lambda>x. g (f x))"
  1846   using continuous_within_compose2[of x s f g] by (simp add: continuous_at_within)
  1847 
  1848 subsubsection{* Open-cover compactness *}
  1849 
  1850 context topological_space
  1851 begin
  1852 
  1853 definition compact :: "'a set \<Rightarrow> bool" where
  1854   compact_eq_heine_borel: -- "This name is used for backwards compatibility"
  1855     "compact S \<longleftrightarrow> (\<forall>C. (\<forall>c\<in>C. open c) \<and> S \<subseteq> \<Union>C \<longrightarrow> (\<exists>D\<subseteq>C. finite D \<and> S \<subseteq> \<Union>D))"
  1856 
  1857 lemma compactI:
  1858   assumes "\<And>C. \<forall>t\<in>C. open t \<Longrightarrow> s \<subseteq> \<Union> C \<Longrightarrow> \<exists>C'. C' \<subseteq> C \<and> finite C' \<and> s \<subseteq> \<Union> C'"
  1859   shows "compact s"
  1860   unfolding compact_eq_heine_borel using assms by metis
  1861 
  1862 lemma compact_empty[simp]: "compact {}"
  1863   by (auto intro!: compactI)
  1864 
  1865 lemma compactE:
  1866   assumes "compact s" and "\<forall>t\<in>C. open t" and "s \<subseteq> \<Union>C"
  1867   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> \<Union>C'"
  1868   using assms unfolding compact_eq_heine_borel by metis
  1869 
  1870 lemma compactE_image:
  1871   assumes "compact s" and "\<forall>t\<in>C. open (f t)" and "s \<subseteq> (\<Union>c\<in>C. f c)"
  1872   obtains C' where "C' \<subseteq> C" and "finite C'" and "s \<subseteq> (\<Union>c\<in>C'. f c)"
  1873   using assms unfolding ball_simps[symmetric] SUP_def
  1874   by (metis (lifting) finite_subset_image compact_eq_heine_borel[of s])
  1875 
  1876 lemma compact_inter_closed [intro]:
  1877   assumes "compact s" and "closed t"
  1878   shows "compact (s \<inter> t)"
  1879 proof (rule compactI)
  1880   fix C assume C: "\<forall>c\<in>C. open c" and cover: "s \<inter> t \<subseteq> \<Union>C"
  1881   from C `closed t` have "\<forall>c\<in>C \<union> {-t}. open c" by auto
  1882   moreover from cover have "s \<subseteq> \<Union>(C \<union> {-t})" by auto
  1883   ultimately have "\<exists>D\<subseteq>C \<union> {-t}. finite D \<and> s \<subseteq> \<Union>D"
  1884     using `compact s` unfolding compact_eq_heine_borel by auto
  1885   then guess D ..
  1886   then show "\<exists>D\<subseteq>C. finite D \<and> s \<inter> t \<subseteq> \<Union>D"
  1887     by (intro exI[of _ "D - {-t}"]) auto
  1888 qed
  1889 
  1890 end
  1891 
  1892 lemma (in t2_space) compact_imp_closed:
  1893   assumes "compact s" shows "closed s"
  1894 unfolding closed_def
  1895 proof (rule openI)
  1896   fix y assume "y \<in> - s"
  1897   let ?C = "\<Union>x\<in>s. {u. open u \<and> x \<in> u \<and> eventually (\<lambda>y. y \<notin> u) (nhds y)}"
  1898   note `compact s`
  1899   moreover have "\<forall>u\<in>?C. open u" by simp
  1900   moreover have "s \<subseteq> \<Union>?C"
  1901   proof
  1902     fix x assume "x \<in> s"
  1903     with `y \<in> - s` have "x \<noteq> y" by clarsimp
  1904     hence "\<exists>u v. open u \<and> open v \<and> x \<in> u \<and> y \<in> v \<and> u \<inter> v = {}"
  1905       by (rule hausdorff)
  1906     with `x \<in> s` show "x \<in> \<Union>?C"
  1907       unfolding eventually_nhds by auto
  1908   qed
  1909   ultimately obtain D where "D \<subseteq> ?C" and "finite D" and "s \<subseteq> \<Union>D"
  1910     by (rule compactE)
  1911   from `D \<subseteq> ?C` have "\<forall>x\<in>D. eventually (\<lambda>y. y \<notin> x) (nhds y)" by auto
  1912   with `finite D` have "eventually (\<lambda>y. y \<notin> \<Union>D) (nhds y)"
  1913     by (simp add: eventually_Ball_finite)
  1914   with `s \<subseteq> \<Union>D` have "eventually (\<lambda>y. y \<notin> s) (nhds y)"
  1915     by (auto elim!: eventually_mono [rotated])
  1916   thus "\<exists>t. open t \<and> y \<in> t \<and> t \<subseteq> - s"
  1917     by (simp add: eventually_nhds subset_eq)
  1918 qed
  1919 
  1920 lemma compact_continuous_image:
  1921   assumes f: "continuous_on s f" and s: "compact s"
  1922   shows "compact (f ` s)"
  1923 proof (rule compactI)
  1924   fix C assume "\<forall>c\<in>C. open c" and cover: "f`s \<subseteq> \<Union>C"
  1925   with f have "\<forall>c\<in>C. \<exists>A. open A \<and> A \<inter> s = f -` c \<inter> s"
  1926     unfolding continuous_on_open_invariant by blast
  1927   then guess A unfolding bchoice_iff .. note A = this
  1928   with cover have "\<forall>c\<in>C. open (A c)" "s \<subseteq> (\<Union>c\<in>C. A c)"
  1929     by (fastforce simp add: subset_eq set_eq_iff)+
  1930   from compactE_image[OF s this] obtain D where "D \<subseteq> C" "finite D" "s \<subseteq> (\<Union>c\<in>D. A c)" .
  1931   with A show "\<exists>D \<subseteq> C. finite D \<and> f`s \<subseteq> \<Union>D"
  1932     by (intro exI[of _ D]) (fastforce simp add: subset_eq set_eq_iff)+
  1933 qed
  1934 
  1935 lemma continuous_on_inv:
  1936   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1937   assumes "continuous_on s f"  "compact s"  "\<forall>x\<in>s. g (f x) = x"
  1938   shows "continuous_on (f ` s) g"
  1939 unfolding continuous_on_topological
  1940 proof (clarsimp simp add: assms(3))
  1941   fix x :: 'a and B :: "'a set"
  1942   assume "x \<in> s" and "open B" and "x \<in> B"
  1943   have 1: "\<forall>x\<in>s. f x \<in> f ` (s - B) \<longleftrightarrow> x \<in> s - B"
  1944     using assms(3) by (auto, metis)
  1945   have "continuous_on (s - B) f"
  1946     using `continuous_on s f` Diff_subset
  1947     by (rule continuous_on_subset)
  1948   moreover have "compact (s - B)"
  1949     using `open B` and `compact s`
  1950     unfolding Diff_eq by (intro compact_inter_closed closed_Compl)
  1951   ultimately have "compact (f ` (s - B))"
  1952     by (rule compact_continuous_image)
  1953   hence "closed (f ` (s - B))"
  1954     by (rule compact_imp_closed)
  1955   hence "open (- f ` (s - B))"
  1956     by (rule open_Compl)
  1957   moreover have "f x \<in> - f ` (s - B)"
  1958     using `x \<in> s` and `x \<in> B` by (simp add: 1)
  1959   moreover have "\<forall>y\<in>s. f y \<in> - f ` (s - B) \<longrightarrow> y \<in> B"
  1960     by (simp add: 1)
  1961   ultimately show "\<exists>A. open A \<and> f x \<in> A \<and> (\<forall>y\<in>s. f y \<in> A \<longrightarrow> y \<in> B)"
  1962     by fast
  1963 qed
  1964 
  1965 lemma continuous_on_inv_into:
  1966   fixes f :: "'a::topological_space \<Rightarrow> 'b::t2_space"
  1967   assumes s: "continuous_on s f" "compact s" and f: "inj_on f s"
  1968   shows "continuous_on (f ` s) (the_inv_into s f)"
  1969   by (rule continuous_on_inv[OF s]) (auto simp: the_inv_into_f_f[OF f])
  1970 
  1971 lemma (in linorder_topology) compact_attains_sup:
  1972   assumes "compact S" "S \<noteq> {}"
  1973   shows "\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s"
  1974 proof (rule classical)
  1975   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. t \<le> s)"
  1976   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. s < t s"
  1977     by (metis not_le)
  1978   then have "\<forall>s\<in>S. open {..< t s}" "S \<subseteq> (\<Union>s\<in>S. {..< t s})"
  1979     by auto
  1980   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {..< t s})"
  1981     by (erule compactE_image)
  1982   with `S \<noteq> {}` have Max: "Max (t`C) \<in> t`C" and "\<forall>s\<in>t`C. s \<le> Max (t`C)"
  1983     by (auto intro!: Max_in)
  1984   with C have "S \<subseteq> {..< Max (t`C)}"
  1985     by (auto intro: less_le_trans simp: subset_eq)
  1986   with t Max `C \<subseteq> S` show ?thesis
  1987     by fastforce
  1988 qed
  1989 
  1990 lemma (in linorder_topology) compact_attains_inf:
  1991   assumes "compact S" "S \<noteq> {}"
  1992   shows "\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t"
  1993 proof (rule classical)
  1994   assume "\<not> (\<exists>s\<in>S. \<forall>t\<in>S. s \<le> t)"
  1995   then obtain t where t: "\<forall>s\<in>S. t s \<in> S" and "\<forall>s\<in>S. t s < s"
  1996     by (metis not_le)
  1997   then have "\<forall>s\<in>S. open {t s <..}" "S \<subseteq> (\<Union>s\<in>S. {t s <..})"
  1998     by auto
  1999   with `compact S` obtain C where "C \<subseteq> S" "finite C" and C: "S \<subseteq> (\<Union>s\<in>C. {t s <..})"
  2000     by (erule compactE_image)
  2001   with `S \<noteq> {}` have Min: "Min (t`C) \<in> t`C" and "\<forall>s\<in>t`C. Min (t`C) \<le> s"
  2002     by (auto intro!: Min_in)
  2003   with C have "S \<subseteq> {Min (t`C) <..}"
  2004     by (auto intro: le_less_trans simp: subset_eq)
  2005   with t Min `C \<subseteq> S` show ?thesis
  2006     by fastforce
  2007 qed
  2008 
  2009 lemma continuous_attains_sup:
  2010   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2011   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s.  f y \<le> f x)"
  2012   using compact_attains_sup[of "f ` s"] compact_continuous_image[of s f] by auto
  2013 
  2014 lemma continuous_attains_inf:
  2015   fixes f :: "'a::topological_space \<Rightarrow> 'b::linorder_topology"
  2016   shows "compact s \<Longrightarrow> s \<noteq> {} \<Longrightarrow> continuous_on s f \<Longrightarrow> (\<exists>x\<in>s. \<forall>y\<in>s. f x \<le> f y)"
  2017   using compact_attains_inf[of "f ` s"] compact_continuous_image[of s f] by auto
  2018 
  2019 
  2020 subsection {* Connectedness *}
  2021 
  2022 context topological_space
  2023 begin
  2024 
  2025 definition "connected S \<longleftrightarrow>
  2026   \<not> (\<exists>A B. open A \<and> open B \<and> S \<subseteq> A \<union> B \<and> A \<inter> B \<inter> S = {} \<and> A \<inter> S \<noteq> {} \<and> B \<inter> S \<noteq> {})"
  2027 
  2028 lemma connectedI:
  2029   "(\<And>A B. open A \<Longrightarrow> open B \<Longrightarrow> A \<inter> U \<noteq> {} \<Longrightarrow> B \<inter> U \<noteq> {} \<Longrightarrow> A \<inter> B \<inter> U = {} \<Longrightarrow> U \<subseteq> A \<union> B \<Longrightarrow> False)
  2030   \<Longrightarrow> connected U"
  2031   by (auto simp: connected_def)
  2032 
  2033 lemma connected_empty[simp]: "connected {}"
  2034   by (auto intro!: connectedI)
  2035 
  2036 end
  2037 
  2038 lemma (in linorder_topology) connectedD_interval:
  2039   assumes "connected U" and xy: "x \<in> U" "y \<in> U" and "x \<le> z" "z \<le> y"
  2040   shows "z \<in> U"
  2041 proof -
  2042   have eq: "{..<z} \<union> {z<..} = - {z}"
  2043     by auto
  2044   { assume "z \<notin> U" "x < z" "z < y"
  2045     with xy have "\<not> connected U"
  2046       unfolding connected_def simp_thms
  2047       apply (rule_tac exI[of _ "{..< z}"])
  2048       apply (rule_tac exI[of _ "{z <..}"])
  2049       apply (auto simp add: eq)
  2050       done }
  2051   with assms show "z \<in> U"
  2052     by (metis less_le)
  2053 qed
  2054 
  2055 lemma connected_continuous_image:
  2056   assumes *: "continuous_on s f"
  2057   assumes "connected s"
  2058   shows "connected (f ` s)"
  2059 proof (rule connectedI)
  2060   fix A B assume A: "open A" "A \<inter> f ` s \<noteq> {}" and B: "open B" "B \<inter> f ` s \<noteq> {}" and
  2061     AB: "A \<inter> B \<inter> f ` s = {}" "f ` s \<subseteq> A \<union> B"
  2062   obtain A' where A': "open A'" "f -` A \<inter> s = A' \<inter> s"
  2063     using * `open A` unfolding continuous_on_open_invariant by metis
  2064   obtain B' where B': "open B'" "f -` B \<inter> s = B' \<inter> s"
  2065     using * `open B` unfolding continuous_on_open_invariant by metis
  2066 
  2067   have "\<exists>A B. open A \<and> open B \<and> s \<subseteq> A \<union> B \<and> A \<inter> B \<inter> s = {} \<and> A \<inter> s \<noteq> {} \<and> B \<inter> s \<noteq> {}"
  2068   proof (rule exI[of _ A'], rule exI[of _ B'], intro conjI)
  2069     have "s \<subseteq> (f -` A \<inter> s) \<union> (f -` B \<inter> s)" using AB by auto
  2070     then show "s \<subseteq> A' \<union> B'" using A' B' by auto
  2071   next
  2072     have "(f -` A \<inter> s) \<inter> (f -` B \<inter> s) = {}" using AB by auto
  2073     then show "A' \<inter> B' \<inter> s = {}" using A' B' by auto
  2074   qed (insert A' B' A B, auto)
  2075   with `connected s` show False
  2076     unfolding connected_def by blast
  2077 qed
  2078 
  2079 
  2080 section {* Connectedness *}
  2081 
  2082 class connected_linorder_topology = linorder_topology + conditionally_complete_linorder + inner_dense_linorder
  2083 begin
  2084 
  2085 lemma Inf_notin_open:
  2086   assumes A: "open A" and bnd: "\<forall>a\<in>A. x < a"
  2087   shows "Inf A \<notin> A"
  2088 proof
  2089   assume "Inf A \<in> A"
  2090   then obtain b where "b < Inf A" "{b <.. Inf A} \<subseteq> A"
  2091     using open_left[of A "Inf A" x] assms by auto
  2092   with dense[of b "Inf A"] obtain c where "c < Inf A" "c \<in> A"
  2093     by (auto simp: subset_eq)
  2094   then show False
  2095     using cInf_lower[OF `c \<in> A`, of x] bnd by (metis less_imp_le not_le)
  2096 qed
  2097 
  2098 lemma Sup_notin_open:
  2099   assumes A: "open A" and bnd: "\<forall>a\<in>A. a < x"
  2100   shows "Sup A \<notin> A"
  2101 proof
  2102   assume "Sup A \<in> A"
  2103   then obtain b where "Sup A < b" "{Sup A ..< b} \<subseteq> A"
  2104     using open_right[of A "Sup A" x] assms by auto
  2105   with dense[of "Sup A" b] obtain c where "Sup A < c" "c \<in> A"
  2106     by (auto simp: subset_eq)
  2107   then show False
  2108     using cSup_upper[OF `c \<in> A`, of x] bnd by (metis less_imp_le not_le)
  2109 qed
  2110 
  2111 end
  2112 
  2113 lemma connectedI_interval:
  2114   fixes U :: "'a :: connected_linorder_topology set"
  2115   assumes *: "\<And>x y z. x \<in> U \<Longrightarrow> y \<in> U \<Longrightarrow> x \<le> z \<Longrightarrow> z \<le> y \<Longrightarrow> z \<in> U"
  2116   shows "connected U"
  2117 proof (rule connectedI)
  2118   { fix A B assume "open A" "open B" "A \<inter> B \<inter> U = {}" "U \<subseteq> A \<union> B"
  2119     fix x y assume "x < y" "x \<in> A" "y \<in> B" "x \<in> U" "y \<in> U"
  2120 
  2121     let ?z = "Inf (B \<inter> {x <..})"
  2122 
  2123     have "x \<le> ?z" "?z \<le> y"
  2124       using `y \<in> B` `x < y` by (auto intro: cInf_lower[where z=x] cInf_greatest)
  2125     with `x \<in> U` `y \<in> U` have "?z \<in> U"
  2126       by (rule *)
  2127     moreover have "?z \<notin> B \<inter> {x <..}"
  2128       using `open B` by (intro Inf_notin_open) auto
  2129     ultimately have "?z \<in> A"
  2130       using `x \<le> ?z` `A \<inter> B \<inter> U = {}` `x \<in> A` `U \<subseteq> A \<union> B` by auto
  2131 
  2132     { assume "?z < y"
  2133       obtain a where "?z < a" "{?z ..< a} \<subseteq> A"
  2134         using open_right[OF `open A` `?z \<in> A` `?z < y`] by auto
  2135       moreover obtain b where "b \<in> B" "x < b" "b < min a y"
  2136         using cInf_less_iff[of "B \<inter> {x <..}" x "min a y"] `?z < a` `?z < y` `x < y` `y \<in> B`
  2137         by (auto intro: less_imp_le)
  2138       moreover then have "?z \<le> b"
  2139         by (intro cInf_lower[where z=x]) auto
  2140       moreover have "b \<in> U"
  2141         using `x \<le> ?z` `?z \<le> b` `b < min a y`
  2142         by (intro *[OF `x \<in> U` `y \<in> U`]) (auto simp: less_imp_le)
  2143       ultimately have "\<exists>b\<in>B. b \<in> A \<and> b \<in> U"
  2144         by (intro bexI[of _ b]) auto }
  2145     then have False
  2146       using `?z \<le> y` `?z \<in> A` `y \<in> B` `y \<in> U` `A \<inter> B \<inter> U = {}` unfolding le_less by blast }
  2147   note not_disjoint = this
  2148 
  2149   fix A B assume AB: "open A" "open B" "U \<subseteq> A \<union> B" "A \<inter> B \<inter> U = {}"
  2150   moreover assume "A \<inter> U \<noteq> {}" then obtain x where x: "x \<in> U" "x \<in> A" by auto
  2151   moreover assume "B \<inter> U \<noteq> {}" then obtain y where y: "y \<in> U" "y \<in> B" by auto
  2152   moreover note not_disjoint[of B A y x] not_disjoint[of A B x y]
  2153   ultimately show False by (cases x y rule: linorder_cases) auto
  2154 qed
  2155 
  2156 lemma connected_iff_interval:
  2157   fixes U :: "'a :: connected_linorder_topology set"
  2158   shows "connected U \<longleftrightarrow> (\<forall>x\<in>U. \<forall>y\<in>U. \<forall>z. x \<le> z \<longrightarrow> z \<le> y \<longrightarrow> z \<in> U)"
  2159   by (auto intro: connectedI_interval dest: connectedD_interval)
  2160 
  2161 lemma connected_UNIV[simp]: "connected (UNIV::'a::connected_linorder_topology set)"
  2162   unfolding connected_iff_interval by auto
  2163 
  2164 lemma connected_Ioi[simp]: "connected {a::'a::connected_linorder_topology <..}"
  2165   unfolding connected_iff_interval by auto
  2166 
  2167 lemma connected_Ici[simp]: "connected {a::'a::connected_linorder_topology ..}"
  2168   unfolding connected_iff_interval by auto
  2169 
  2170 lemma connected_Iio[simp]: "connected {..< a::'a::connected_linorder_topology}"
  2171   unfolding connected_iff_interval by auto
  2172 
  2173 lemma connected_Iic[simp]: "connected {.. a::'a::connected_linorder_topology}"
  2174   unfolding connected_iff_interval by auto
  2175 
  2176 lemma connected_Ioo[simp]: "connected {a <..< b::'a::connected_linorder_topology}"
  2177   unfolding connected_iff_interval by auto
  2178 
  2179 lemma connected_Ioc[simp]: "connected {a <.. b::'a::connected_linorder_topology}"
  2180   unfolding connected_iff_interval by auto
  2181 
  2182 lemma connected_Ico[simp]: "connected {a ..< b::'a::connected_linorder_topology}"
  2183   unfolding connected_iff_interval by auto
  2184 
  2185 lemma connected_Icc[simp]: "connected {a .. b::'a::connected_linorder_topology}"
  2186   unfolding connected_iff_interval by auto
  2187 
  2188 lemma connected_contains_Ioo: 
  2189   fixes A :: "'a :: linorder_topology set"
  2190   assumes A: "connected A" "a \<in> A" "b \<in> A" shows "{a <..< b} \<subseteq> A"
  2191   using connectedD_interval[OF A] by (simp add: subset_eq Ball_def less_imp_le)
  2192 
  2193 subsection {* Intermediate Value Theorem *}
  2194 
  2195 lemma IVT':
  2196   fixes f :: "'a :: connected_linorder_topology \<Rightarrow> 'b :: linorder_topology"
  2197   assumes y: "f a \<le> y" "y \<le> f b" "a \<le> b"
  2198   assumes *: "continuous_on {a .. b} f"
  2199   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2200 proof -
  2201   have "connected {a..b}"
  2202     unfolding connected_iff_interval by auto
  2203   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f a" "f b" y] y
  2204   show ?thesis
  2205     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2206 qed
  2207 
  2208 lemma IVT2':
  2209   fixes f :: "'a :: connected_linorder_topology \<Rightarrow> 'b :: linorder_topology"
  2210   assumes y: "f b \<le> y" "y \<le> f a" "a \<le> b"
  2211   assumes *: "continuous_on {a .. b} f"
  2212   shows "\<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2213 proof -
  2214   have "connected {a..b}"
  2215     unfolding connected_iff_interval by auto
  2216   from connected_continuous_image[OF * this, THEN connectedD_interval, of "f b" "f a" y] y
  2217   show ?thesis
  2218     by (auto simp add: atLeastAtMost_def atLeast_def atMost_def)
  2219 qed
  2220 
  2221 lemma IVT:
  2222   fixes f :: "'a :: connected_linorder_topology \<Rightarrow> 'b :: linorder_topology"
  2223   shows "f a \<le> y \<Longrightarrow> y \<le> f b \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2224   by (rule IVT') (auto intro: continuous_at_imp_continuous_on)
  2225 
  2226 lemma IVT2:
  2227   fixes f :: "'a :: connected_linorder_topology \<Rightarrow> 'b :: linorder_topology"
  2228   shows "f b \<le> y \<Longrightarrow> y \<le> f a \<Longrightarrow> a \<le> b \<Longrightarrow> (\<forall>x. a \<le> x \<and> x \<le> b \<longrightarrow> isCont f x) \<Longrightarrow> \<exists>x. a \<le> x \<and> x \<le> b \<and> f x = y"
  2229   by (rule IVT2') (auto intro: continuous_at_imp_continuous_on)
  2230 
  2231 lemma continuous_inj_imp_mono:
  2232   fixes f :: "'a::connected_linorder_topology \<Rightarrow> 'b :: linorder_topology"
  2233   assumes x: "a < x" "x < b"
  2234   assumes cont: "continuous_on {a..b} f"
  2235   assumes inj: "inj_on f {a..b}"
  2236   shows "(f a < f x \<and> f x < f b) \<or> (f b < f x \<and> f x < f a)"
  2237 proof -
  2238   note I = inj_on_iff[OF inj]
  2239   { assume "f x < f a" "f x < f b"
  2240     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f x < f s"
  2241       using IVT'[of f x "min (f a) (f b)" b] IVT2'[of f x "min (f a) (f b)" a] x
  2242       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2243     with x I have False by auto }
  2244   moreover
  2245   { assume "f a < f x" "f b < f x"
  2246     then obtain s t where "x \<le> s" "s \<le> b" "a \<le> t" "t \<le> x" "f s = f t" "f s < f x"
  2247       using IVT'[of f a "max (f a) (f b)" x] IVT2'[of f b "max (f a) (f b)" x] x
  2248       by (auto simp: continuous_on_subset[OF cont] less_imp_le)
  2249     with x I have False by auto }
  2250   ultimately show ?thesis
  2251     using I[of a x] I[of x b] x less_trans[OF x] by (auto simp add: le_less less_imp_neq neq_iff)
  2252 qed
  2253 
  2254 end
  2255