src/Pure/assumption.ML
author wenzelm
Fri Dec 13 20:20:15 2013 +0100 (2013-12-13)
changeset 54740 91f54d386680
parent 54567 cfe53047dc16
child 54883 dd04a8b654fc
permissions -rw-r--r--
maintain morphism names for diagnostic purposes;
     1 (*  Title:      Pure/assumption.ML
     2     Author:     Makarius
     3 
     4 Context assumptions, parameterized by export rules.
     5 *)
     6 
     7 signature ASSUMPTION =
     8 sig
     9   type export = bool -> cterm list -> (thm -> thm) * (term -> term)
    10   val assume_export: export
    11   val presume_export: export
    12   val assume: cterm -> thm
    13   val all_assms_of: Proof.context -> cterm list
    14   val all_prems_of: Proof.context -> thm list
    15   val check_hyps: Proof.context -> thm -> thm
    16   val local_assms_of: Proof.context -> Proof.context -> cterm list
    17   val local_prems_of: Proof.context -> Proof.context -> thm list
    18   val add_assms: export -> cterm list -> Proof.context -> thm list * Proof.context
    19   val add_assumes: cterm list -> Proof.context -> thm list * Proof.context
    20   val export: bool -> Proof.context -> Proof.context -> thm -> thm
    21   val export_term: Proof.context -> Proof.context -> term -> term
    22   val export_morphism: Proof.context -> Proof.context -> morphism
    23 end;
    24 
    25 structure Assumption: ASSUMPTION =
    26 struct
    27 
    28 (** basic rules **)
    29 
    30 type export = bool -> cterm list -> (thm -> thm) * (term -> term);
    31 
    32 (*
    33     [A]
    34      :
    35      B
    36   --------
    37   #A ==> B
    38 *)
    39 fun assume_export is_goal asms =
    40   (if is_goal then Drule.implies_intr_protected asms else Drule.implies_intr_list asms, fn t => t);
    41 
    42 (*
    43     [A]
    44      :
    45      B
    46   -------
    47   A ==> B
    48 *)
    49 fun presume_export _ = assume_export false;
    50 
    51 val assume = Raw_Simplifier.norm_hhf o Thm.assume;
    52 
    53 
    54 
    55 (** local context data **)
    56 
    57 datatype data = Data of
    58  {assms: (export * cterm list) list,    (*assumes: A ==> _*)
    59   prems: thm list};                     (*prems: A |- norm_hhf A*)
    60 
    61 fun make_data (assms, prems) = Data {assms = assms, prems = prems};
    62 
    63 structure Data = Proof_Data
    64 (
    65   type T = data;
    66   fun init _ = make_data ([], []);
    67 );
    68 
    69 fun map_data f = Data.map (fn Data {assms, prems} => make_data (f (assms, prems)));
    70 fun rep_data ctxt = Data.get ctxt |> (fn Data rep => rep);
    71 
    72 
    73 (* all assumptions *)
    74 
    75 val all_assumptions_of = #assms o rep_data;
    76 val all_assms_of = maps #2 o all_assumptions_of;
    77 val all_prems_of = #prems o rep_data;
    78 
    79 fun check_hyps ctxt th =
    80   let
    81     val extra_hyps = subtract (op aconv) (map Thm.term_of (all_assms_of ctxt)) (Thm.hyps_of th);
    82     val _ = null extra_hyps orelse
    83       error ("Additional hypotheses:\n" ^ cat_lines (map (Syntax.string_of_term ctxt) extra_hyps));
    84   in th end;
    85 
    86 
    87 (* local assumptions *)
    88 
    89 fun local_assumptions_of inner outer =
    90   drop (length (all_assumptions_of outer)) (all_assumptions_of inner);
    91 
    92 val local_assms_of = maps #2 oo local_assumptions_of;
    93 
    94 fun local_prems_of inner outer =
    95   drop (length (all_prems_of outer)) (all_prems_of inner);
    96 
    97 
    98 (* add assumptions *)
    99 
   100 fun add_assms export new_asms =
   101   let val new_prems = map assume new_asms in
   102     map_data (fn (asms, prems) => (asms @ [(export, new_asms)], prems @ new_prems)) #>
   103     pair new_prems
   104   end;
   105 
   106 val add_assumes = add_assms assume_export;
   107 
   108 
   109 (* export *)
   110 
   111 fun export is_goal inner outer =
   112   Raw_Simplifier.norm_hhf_protect #>
   113   fold_rev (fn (e, As) => #1 (e is_goal As)) (local_assumptions_of inner outer) #>
   114   Raw_Simplifier.norm_hhf_protect;
   115 
   116 fun export_term inner outer =
   117   fold_rev (fn (e, As) => #2 (e false As)) (local_assumptions_of inner outer);
   118 
   119 fun export_morphism inner outer =
   120   let
   121     val thm = export false inner outer;
   122     val term = export_term inner outer;
   123     val typ = Logic.type_map term;
   124   in
   125     Morphism.morphism "Assumption.export"
   126       {binding = [], typ = [typ], term = [term], fact = [map thm]}
   127   end;
   128 
   129 end;