src/HOL/Real/RealDef.thy
author haftmann
Thu Nov 29 17:08:26 2007 +0100 (2007-11-29)
changeset 25502 9200b36280c0
parent 25303 0699e20feabd
child 25546 4f8d7ac83c0b
permissions -rw-r--r--
instance command as rudimentary class target
     1 (*  Title       : Real/RealDef.thy
     2     ID          : $Id$
     3     Author      : Jacques D. Fleuriot
     4     Copyright   : 1998  University of Cambridge
     5     Conversion to Isar and new proofs by Lawrence C Paulson, 2003/4
     6     Additional contributions by Jeremy Avigad
     7 *)
     8 
     9 header{*Defining the Reals from the Positive Reals*}
    10 
    11 theory RealDef
    12 imports PReal
    13 uses ("real_arith.ML")
    14 begin
    15 
    16 definition
    17   realrel   ::  "((preal * preal) * (preal * preal)) set" where
    18   "realrel = {p. \<exists>x1 y1 x2 y2. p = ((x1,y1),(x2,y2)) & x1+y2 = x2+y1}"
    19 
    20 typedef (Real)  real = "UNIV//realrel"
    21   by (auto simp add: quotient_def)
    22 
    23 definition
    24   (** these don't use the overloaded "real" function: users don't see them **)
    25   real_of_preal :: "preal => real" where
    26   "real_of_preal m = Abs_Real(realrel``{(m + 1, 1)})"
    27 
    28 instance real :: zero
    29   real_zero_def: "0 == Abs_Real(realrel``{(1, 1)})" ..
    30 lemmas [code func del] = real_zero_def
    31 
    32 instance real :: one
    33   real_one_def: "1 == Abs_Real(realrel``{(1 + 1, 1)})" ..
    34 lemmas [code func del] = real_one_def
    35 
    36 instance real :: plus
    37   real_add_def: "z + w ==
    38        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    39 		 { Abs_Real(realrel``{(x+u, y+v)}) })" ..
    40 lemmas [code func del] = real_add_def
    41 
    42 instance real :: minus
    43   real_minus_def: "- r ==  contents (\<Union>(x,y) \<in> Rep_Real(r). { Abs_Real(realrel``{(y,x)}) })"
    44   real_diff_def: "r - (s::real) == r + - s" ..
    45 lemmas [code func del] = real_minus_def real_diff_def
    46 
    47 instance real :: times
    48   real_mult_def:
    49     "z * w ==
    50        contents (\<Union>(x,y) \<in> Rep_Real(z). \<Union>(u,v) \<in> Rep_Real(w).
    51 		 { Abs_Real(realrel``{(x*u + y*v, x*v + y*u)}) })" ..
    52 lemmas [code func del] = real_mult_def
    53 
    54 instance real :: inverse
    55   real_inverse_def: "inverse (R::real) == (THE S. (R = 0 & S = 0) | S * R = 1)"
    56   real_divide_def: "R / (S::real) == R * inverse S" ..
    57 lemmas [code func del] = real_inverse_def real_divide_def
    58 
    59 instance real :: ord
    60   real_le_def: "z \<le> (w::real) == 
    61     \<exists>x y u v. x+v \<le> u+y & (x,y) \<in> Rep_Real z & (u,v) \<in> Rep_Real w"
    62   real_less_def: "(x < (y::real)) == (x \<le> y & x \<noteq> y)" ..
    63 lemmas [code func del] = real_le_def real_less_def
    64 
    65 instance real :: abs
    66   real_abs_def:  "abs (r::real) == (if r < 0 then - r else r)" ..
    67 
    68 instance real :: sgn
    69   real_sgn_def: "sgn (x::real) == (if x=0 then 0 else if 0<x then 1 else - 1)" ..
    70 
    71 subsection {* Equivalence relation over positive reals *}
    72 
    73 lemma preal_trans_lemma:
    74   assumes "x + y1 = x1 + y"
    75       and "x + y2 = x2 + y"
    76   shows "x1 + y2 = x2 + (y1::preal)"
    77 proof -
    78   have "(x1 + y2) + x = (x + y2) + x1" by (simp add: add_ac)
    79   also have "... = (x2 + y) + x1"  by (simp add: prems)
    80   also have "... = x2 + (x1 + y)"  by (simp add: add_ac)
    81   also have "... = x2 + (x + y1)"  by (simp add: prems)
    82   also have "... = (x2 + y1) + x"  by (simp add: add_ac)
    83   finally have "(x1 + y2) + x = (x2 + y1) + x" .
    84   thus ?thesis by (rule add_right_imp_eq)
    85 qed
    86 
    87 
    88 lemma realrel_iff [simp]: "(((x1,y1),(x2,y2)) \<in> realrel) = (x1 + y2 = x2 + y1)"
    89 by (simp add: realrel_def)
    90 
    91 lemma equiv_realrel: "equiv UNIV realrel"
    92 apply (auto simp add: equiv_def refl_def sym_def trans_def realrel_def)
    93 apply (blast dest: preal_trans_lemma) 
    94 done
    95 
    96 text{*Reduces equality of equivalence classes to the @{term realrel} relation:
    97   @{term "(realrel `` {x} = realrel `` {y}) = ((x,y) \<in> realrel)"} *}
    98 lemmas equiv_realrel_iff = 
    99        eq_equiv_class_iff [OF equiv_realrel UNIV_I UNIV_I]
   100 
   101 declare equiv_realrel_iff [simp]
   102 
   103 
   104 lemma realrel_in_real [simp]: "realrel``{(x,y)}: Real"
   105 by (simp add: Real_def realrel_def quotient_def, blast)
   106 
   107 declare Abs_Real_inject [simp]
   108 declare Abs_Real_inverse [simp]
   109 
   110 
   111 text{*Case analysis on the representation of a real number as an equivalence
   112       class of pairs of positive reals.*}
   113 lemma eq_Abs_Real [case_names Abs_Real, cases type: real]: 
   114      "(!!x y. z = Abs_Real(realrel``{(x,y)}) ==> P) ==> P"
   115 apply (rule Rep_Real [of z, unfolded Real_def, THEN quotientE])
   116 apply (drule arg_cong [where f=Abs_Real])
   117 apply (auto simp add: Rep_Real_inverse)
   118 done
   119 
   120 
   121 subsection {* Addition and Subtraction *}
   122 
   123 lemma real_add_congruent2_lemma:
   124      "[|a + ba = aa + b; ab + bc = ac + bb|]
   125       ==> a + ab + (ba + bc) = aa + ac + (b + (bb::preal))"
   126 apply (simp add: add_assoc)
   127 apply (rule add_left_commute [of ab, THEN ssubst])
   128 apply (simp add: add_assoc [symmetric])
   129 apply (simp add: add_ac)
   130 done
   131 
   132 lemma real_add:
   133      "Abs_Real (realrel``{(x,y)}) + Abs_Real (realrel``{(u,v)}) =
   134       Abs_Real (realrel``{(x+u, y+v)})"
   135 proof -
   136   have "(\<lambda>z w. (\<lambda>(x,y). (\<lambda>(u,v). {Abs_Real (realrel `` {(x+u, y+v)})}) w) z)
   137         respects2 realrel"
   138     by (simp add: congruent2_def, blast intro: real_add_congruent2_lemma) 
   139   thus ?thesis
   140     by (simp add: real_add_def UN_UN_split_split_eq
   141                   UN_equiv_class2 [OF equiv_realrel equiv_realrel])
   142 qed
   143 
   144 lemma real_minus: "- Abs_Real(realrel``{(x,y)}) = Abs_Real(realrel `` {(y,x)})"
   145 proof -
   146   have "(\<lambda>(x,y). {Abs_Real (realrel``{(y,x)})}) respects realrel"
   147     by (simp add: congruent_def add_commute) 
   148   thus ?thesis
   149     by (simp add: real_minus_def UN_equiv_class [OF equiv_realrel])
   150 qed
   151 
   152 instance real :: ab_group_add
   153 proof
   154   fix x y z :: real
   155   show "(x + y) + z = x + (y + z)"
   156     by (cases x, cases y, cases z, simp add: real_add add_assoc)
   157   show "x + y = y + x"
   158     by (cases x, cases y, simp add: real_add add_commute)
   159   show "0 + x = x"
   160     by (cases x, simp add: real_add real_zero_def add_ac)
   161   show "- x + x = 0"
   162     by (cases x, simp add: real_minus real_add real_zero_def add_commute)
   163   show "x - y = x + - y"
   164     by (simp add: real_diff_def)
   165 qed
   166 
   167 
   168 subsection {* Multiplication *}
   169 
   170 lemma real_mult_congruent2_lemma:
   171      "!!(x1::preal). [| x1 + y2 = x2 + y1 |] ==>
   172           x * x1 + y * y1 + (x * y2 + y * x2) =
   173           x * x2 + y * y2 + (x * y1 + y * x1)"
   174 apply (simp add: add_left_commute add_assoc [symmetric])
   175 apply (simp add: add_assoc right_distrib [symmetric])
   176 apply (simp add: add_commute)
   177 done
   178 
   179 lemma real_mult_congruent2:
   180     "(%p1 p2.
   181         (%(x1,y1). (%(x2,y2). 
   182           { Abs_Real (realrel``{(x1*x2 + y1*y2, x1*y2+y1*x2)}) }) p2) p1)
   183      respects2 realrel"
   184 apply (rule congruent2_commuteI [OF equiv_realrel], clarify)
   185 apply (simp add: mult_commute add_commute)
   186 apply (auto simp add: real_mult_congruent2_lemma)
   187 done
   188 
   189 lemma real_mult:
   190       "Abs_Real((realrel``{(x1,y1)})) * Abs_Real((realrel``{(x2,y2)})) =
   191        Abs_Real(realrel `` {(x1*x2+y1*y2,x1*y2+y1*x2)})"
   192 by (simp add: real_mult_def UN_UN_split_split_eq
   193          UN_equiv_class2 [OF equiv_realrel equiv_realrel real_mult_congruent2])
   194 
   195 lemma real_mult_commute: "(z::real) * w = w * z"
   196 by (cases z, cases w, simp add: real_mult add_ac mult_ac)
   197 
   198 lemma real_mult_assoc: "((z1::real) * z2) * z3 = z1 * (z2 * z3)"
   199 apply (cases z1, cases z2, cases z3)
   200 apply (simp add: real_mult right_distrib add_ac mult_ac)
   201 done
   202 
   203 lemma real_mult_1: "(1::real) * z = z"
   204 apply (cases z)
   205 apply (simp add: real_mult real_one_def right_distrib
   206                   mult_1_right mult_ac add_ac)
   207 done
   208 
   209 lemma real_add_mult_distrib: "((z1::real) + z2) * w = (z1 * w) + (z2 * w)"
   210 apply (cases z1, cases z2, cases w)
   211 apply (simp add: real_add real_mult right_distrib add_ac mult_ac)
   212 done
   213 
   214 text{*one and zero are distinct*}
   215 lemma real_zero_not_eq_one: "0 \<noteq> (1::real)"
   216 proof -
   217   have "(1::preal) < 1 + 1"
   218     by (simp add: preal_self_less_add_left)
   219   thus ?thesis
   220     by (simp add: real_zero_def real_one_def)
   221 qed
   222 
   223 instance real :: comm_ring_1
   224 proof
   225   fix x y z :: real
   226   show "(x * y) * z = x * (y * z)" by (rule real_mult_assoc)
   227   show "x * y = y * x" by (rule real_mult_commute)
   228   show "1 * x = x" by (rule real_mult_1)
   229   show "(x + y) * z = x * z + y * z" by (rule real_add_mult_distrib)
   230   show "0 \<noteq> (1::real)" by (rule real_zero_not_eq_one)
   231 qed
   232 
   233 subsection {* Inverse and Division *}
   234 
   235 lemma real_zero_iff: "Abs_Real (realrel `` {(x, x)}) = 0"
   236 by (simp add: real_zero_def add_commute)
   237 
   238 text{*Instead of using an existential quantifier and constructing the inverse
   239 within the proof, we could define the inverse explicitly.*}
   240 
   241 lemma real_mult_inverse_left_ex: "x \<noteq> 0 ==> \<exists>y. y*x = (1::real)"
   242 apply (simp add: real_zero_def real_one_def, cases x)
   243 apply (cut_tac x = xa and y = y in linorder_less_linear)
   244 apply (auto dest!: less_add_left_Ex simp add: real_zero_iff)
   245 apply (rule_tac
   246         x = "Abs_Real (realrel``{(1, inverse (D) + 1)})"
   247        in exI)
   248 apply (rule_tac [2]
   249         x = "Abs_Real (realrel``{(inverse (D) + 1, 1)})" 
   250        in exI)
   251 apply (auto simp add: real_mult preal_mult_inverse_right ring_simps)
   252 done
   253 
   254 lemma real_mult_inverse_left: "x \<noteq> 0 ==> inverse(x)*x = (1::real)"
   255 apply (simp add: real_inverse_def)
   256 apply (drule real_mult_inverse_left_ex, safe)
   257 apply (rule theI, assumption, rename_tac z)
   258 apply (subgoal_tac "(z * x) * y = z * (x * y)")
   259 apply (simp add: mult_commute)
   260 apply (rule mult_assoc)
   261 done
   262 
   263 
   264 subsection{*The Real Numbers form a Field*}
   265 
   266 instance real :: field
   267 proof
   268   fix x y z :: real
   269   show "x \<noteq> 0 ==> inverse x * x = 1" by (rule real_mult_inverse_left)
   270   show "x / y = x * inverse y" by (simp add: real_divide_def)
   271 qed
   272 
   273 
   274 text{*Inverse of zero!  Useful to simplify certain equations*}
   275 
   276 lemma INVERSE_ZERO: "inverse 0 = (0::real)"
   277 by (simp add: real_inverse_def)
   278 
   279 instance real :: division_by_zero
   280 proof
   281   show "inverse 0 = (0::real)" by (rule INVERSE_ZERO)
   282 qed
   283 
   284 
   285 subsection{*The @{text "\<le>"} Ordering*}
   286 
   287 lemma real_le_refl: "w \<le> (w::real)"
   288 by (cases w, force simp add: real_le_def)
   289 
   290 text{*The arithmetic decision procedure is not set up for type preal.
   291   This lemma is currently unused, but it could simplify the proofs of the
   292   following two lemmas.*}
   293 lemma preal_eq_le_imp_le:
   294   assumes eq: "a+b = c+d" and le: "c \<le> a"
   295   shows "b \<le> (d::preal)"
   296 proof -
   297   have "c+d \<le> a+d" by (simp add: prems)
   298   hence "a+b \<le> a+d" by (simp add: prems)
   299   thus "b \<le> d" by simp
   300 qed
   301 
   302 lemma real_le_lemma:
   303   assumes l: "u1 + v2 \<le> u2 + v1"
   304       and "x1 + v1 = u1 + y1"
   305       and "x2 + v2 = u2 + y2"
   306   shows "x1 + y2 \<le> x2 + (y1::preal)"
   307 proof -
   308   have "(x1+v1) + (u2+y2) = (u1+y1) + (x2+v2)" by (simp add: prems)
   309   hence "(x1+y2) + (u2+v1) = (x2+y1) + (u1+v2)" by (simp add: add_ac)
   310   also have "... \<le> (x2+y1) + (u2+v1)" by (simp add: prems)
   311   finally show ?thesis by simp
   312 qed
   313 
   314 lemma real_le: 
   315      "(Abs_Real(realrel``{(x1,y1)}) \<le> Abs_Real(realrel``{(x2,y2)})) =  
   316       (x1 + y2 \<le> x2 + y1)"
   317 apply (simp add: real_le_def)
   318 apply (auto intro: real_le_lemma)
   319 done
   320 
   321 lemma real_le_anti_sym: "[| z \<le> w; w \<le> z |] ==> z = (w::real)"
   322 by (cases z, cases w, simp add: real_le)
   323 
   324 lemma real_trans_lemma:
   325   assumes "x + v \<le> u + y"
   326       and "u + v' \<le> u' + v"
   327       and "x2 + v2 = u2 + y2"
   328   shows "x + v' \<le> u' + (y::preal)"
   329 proof -
   330   have "(x+v') + (u+v) = (x+v) + (u+v')" by (simp add: add_ac)
   331   also have "... \<le> (u+y) + (u+v')" by (simp add: prems)
   332   also have "... \<le> (u+y) + (u'+v)" by (simp add: prems)
   333   also have "... = (u'+y) + (u+v)"  by (simp add: add_ac)
   334   finally show ?thesis by simp
   335 qed
   336 
   337 lemma real_le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::real)"
   338 apply (cases i, cases j, cases k)
   339 apply (simp add: real_le)
   340 apply (blast intro: real_trans_lemma)
   341 done
   342 
   343 (* Axiom 'order_less_le' of class 'order': *)
   344 lemma real_less_le: "((w::real) < z) = (w \<le> z & w \<noteq> z)"
   345 by (simp add: real_less_def)
   346 
   347 instance real :: order
   348 proof qed
   349  (assumption |
   350   rule real_le_refl real_le_trans real_le_anti_sym real_less_le)+
   351 
   352 (* Axiom 'linorder_linear' of class 'linorder': *)
   353 lemma real_le_linear: "(z::real) \<le> w | w \<le> z"
   354 apply (cases z, cases w)
   355 apply (auto simp add: real_le real_zero_def add_ac)
   356 done
   357 
   358 
   359 instance real :: linorder
   360   by (intro_classes, rule real_le_linear)
   361 
   362 
   363 lemma real_le_eq_diff: "(x \<le> y) = (x-y \<le> (0::real))"
   364 apply (cases x, cases y) 
   365 apply (auto simp add: real_le real_zero_def real_diff_def real_add real_minus
   366                       add_ac)
   367 apply (simp_all add: add_assoc [symmetric])
   368 done
   369 
   370 lemma real_add_left_mono: 
   371   assumes le: "x \<le> y" shows "z + x \<le> z + (y::real)"
   372 proof -
   373   have "z + x - (z + y) = (z + -z) + (x - y)"
   374     by (simp add: diff_minus add_ac) 
   375   with le show ?thesis 
   376     by (simp add: real_le_eq_diff[of x] real_le_eq_diff[of "z+x"] diff_minus)
   377 qed
   378 
   379 lemma real_sum_gt_zero_less: "(0 < S + (-W::real)) ==> (W < S)"
   380 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   381 
   382 lemma real_less_sum_gt_zero: "(W < S) ==> (0 < S + (-W::real))"
   383 by (simp add: linorder_not_le [symmetric] real_le_eq_diff [of S] diff_minus)
   384 
   385 lemma real_mult_order: "[| 0 < x; 0 < y |] ==> (0::real) < x * y"
   386 apply (cases x, cases y)
   387 apply (simp add: linorder_not_le [where 'a = real, symmetric] 
   388                  linorder_not_le [where 'a = preal] 
   389                   real_zero_def real_le real_mult)
   390   --{*Reduce to the (simpler) @{text "\<le>"} relation *}
   391 apply (auto dest!: less_add_left_Ex
   392      simp add: add_ac mult_ac
   393           right_distrib preal_self_less_add_left)
   394 done
   395 
   396 lemma real_mult_less_mono2: "[| (0::real) < z; x < y |] ==> z * x < z * y"
   397 apply (rule real_sum_gt_zero_less)
   398 apply (drule real_less_sum_gt_zero [of x y])
   399 apply (drule real_mult_order, assumption)
   400 apply (simp add: right_distrib)
   401 done
   402 
   403 instance real :: distrib_lattice
   404   "inf \<Colon> real \<Rightarrow> real \<Rightarrow> real \<equiv> min"
   405   "sup \<Colon> real \<Rightarrow> real \<Rightarrow> real \<equiv> max"
   406   by default (auto simp add: inf_real_def sup_real_def min_max.sup_inf_distrib1)
   407 
   408 
   409 subsection{*The Reals Form an Ordered Field*}
   410 
   411 instance real :: ordered_field
   412 proof
   413   fix x y z :: real
   414   show "x \<le> y ==> z + x \<le> z + y" by (rule real_add_left_mono)
   415   show "x < y ==> 0 < z ==> z * x < z * y" by (rule real_mult_less_mono2)
   416   show "\<bar>x\<bar> = (if x < 0 then -x else x)" by (simp only: real_abs_def)
   417   show "sgn x = (if x=0 then 0 else if 0<x then 1 else - 1)"
   418     by (simp only: real_sgn_def)
   419 qed
   420 
   421 instance real :: lordered_ab_group_add ..
   422 
   423 text{*The function @{term real_of_preal} requires many proofs, but it seems
   424 to be essential for proving completeness of the reals from that of the
   425 positive reals.*}
   426 
   427 lemma real_of_preal_add:
   428      "real_of_preal ((x::preal) + y) = real_of_preal x + real_of_preal y"
   429 by (simp add: real_of_preal_def real_add left_distrib add_ac)
   430 
   431 lemma real_of_preal_mult:
   432      "real_of_preal ((x::preal) * y) = real_of_preal x* real_of_preal y"
   433 by (simp add: real_of_preal_def real_mult right_distrib add_ac mult_ac)
   434 
   435 
   436 text{*Gleason prop 9-4.4 p 127*}
   437 lemma real_of_preal_trichotomy:
   438       "\<exists>m. (x::real) = real_of_preal m | x = 0 | x = -(real_of_preal m)"
   439 apply (simp add: real_of_preal_def real_zero_def, cases x)
   440 apply (auto simp add: real_minus add_ac)
   441 apply (cut_tac x = x and y = y in linorder_less_linear)
   442 apply (auto dest!: less_add_left_Ex simp add: add_assoc [symmetric])
   443 done
   444 
   445 lemma real_of_preal_leD:
   446       "real_of_preal m1 \<le> real_of_preal m2 ==> m1 \<le> m2"
   447 by (simp add: real_of_preal_def real_le)
   448 
   449 lemma real_of_preal_lessI: "m1 < m2 ==> real_of_preal m1 < real_of_preal m2"
   450 by (auto simp add: real_of_preal_leD linorder_not_le [symmetric])
   451 
   452 lemma real_of_preal_lessD:
   453       "real_of_preal m1 < real_of_preal m2 ==> m1 < m2"
   454 by (simp add: real_of_preal_def real_le linorder_not_le [symmetric])
   455 
   456 lemma real_of_preal_less_iff [simp]:
   457      "(real_of_preal m1 < real_of_preal m2) = (m1 < m2)"
   458 by (blast intro: real_of_preal_lessI real_of_preal_lessD)
   459 
   460 lemma real_of_preal_le_iff:
   461      "(real_of_preal m1 \<le> real_of_preal m2) = (m1 \<le> m2)"
   462 by (simp add: linorder_not_less [symmetric])
   463 
   464 lemma real_of_preal_zero_less: "0 < real_of_preal m"
   465 apply (insert preal_self_less_add_left [of 1 m])
   466 apply (auto simp add: real_zero_def real_of_preal_def
   467                       real_less_def real_le_def add_ac)
   468 apply (rule_tac x="m + 1" in exI, rule_tac x="1" in exI)
   469 apply (simp add: add_ac)
   470 done
   471 
   472 lemma real_of_preal_minus_less_zero: "- real_of_preal m < 0"
   473 by (simp add: real_of_preal_zero_less)
   474 
   475 lemma real_of_preal_not_minus_gt_zero: "~ 0 < - real_of_preal m"
   476 proof -
   477   from real_of_preal_minus_less_zero
   478   show ?thesis by (blast dest: order_less_trans)
   479 qed
   480 
   481 
   482 subsection{*Theorems About the Ordering*}
   483 
   484 lemma real_gt_zero_preal_Ex: "(0 < x) = (\<exists>y. x = real_of_preal y)"
   485 apply (auto simp add: real_of_preal_zero_less)
   486 apply (cut_tac x = x in real_of_preal_trichotomy)
   487 apply (blast elim!: real_of_preal_not_minus_gt_zero [THEN notE])
   488 done
   489 
   490 lemma real_gt_preal_preal_Ex:
   491      "real_of_preal z < x ==> \<exists>y. x = real_of_preal y"
   492 by (blast dest!: real_of_preal_zero_less [THEN order_less_trans]
   493              intro: real_gt_zero_preal_Ex [THEN iffD1])
   494 
   495 lemma real_ge_preal_preal_Ex:
   496      "real_of_preal z \<le> x ==> \<exists>y. x = real_of_preal y"
   497 by (blast dest: order_le_imp_less_or_eq real_gt_preal_preal_Ex)
   498 
   499 lemma real_less_all_preal: "y \<le> 0 ==> \<forall>x. y < real_of_preal x"
   500 by (auto elim: order_le_imp_less_or_eq [THEN disjE] 
   501             intro: real_of_preal_zero_less [THEN [2] order_less_trans] 
   502             simp add: real_of_preal_zero_less)
   503 
   504 lemma real_less_all_real2: "~ 0 < y ==> \<forall>x. y < real_of_preal x"
   505 by (blast intro!: real_less_all_preal linorder_not_less [THEN iffD1])
   506 
   507 
   508 subsection{*More Lemmas*}
   509 
   510 lemma real_mult_left_cancel: "(c::real) \<noteq> 0 ==> (c*a=c*b) = (a=b)"
   511 by auto
   512 
   513 lemma real_mult_right_cancel: "(c::real) \<noteq> 0 ==> (a*c=b*c) = (a=b)"
   514 by auto
   515 
   516 lemma real_mult_less_iff1 [simp]: "(0::real) < z ==> (x*z < y*z) = (x < y)"
   517   by (force elim: order_less_asym
   518             simp add: Ring_and_Field.mult_less_cancel_right)
   519 
   520 lemma real_mult_le_cancel_iff1 [simp]: "(0::real) < z ==> (x*z \<le> y*z) = (x\<le>y)"
   521 apply (simp add: mult_le_cancel_right)
   522 apply (blast intro: elim: order_less_asym)
   523 done
   524 
   525 lemma real_mult_le_cancel_iff2 [simp]: "(0::real) < z ==> (z*x \<le> z*y) = (x\<le>y)"
   526 by(simp add:mult_commute)
   527 
   528 lemma real_inverse_gt_one: "[| (0::real) < x; x < 1 |] ==> 1 < inverse x"
   529 by (simp add: one_less_inverse_iff) (* TODO: generalize/move *)
   530 
   531 
   532 subsection {* Embedding numbers into the Reals *}
   533 
   534 abbreviation
   535   real_of_nat :: "nat \<Rightarrow> real"
   536 where
   537   "real_of_nat \<equiv> of_nat"
   538 
   539 abbreviation
   540   real_of_int :: "int \<Rightarrow> real"
   541 where
   542   "real_of_int \<equiv> of_int"
   543 
   544 abbreviation
   545   real_of_rat :: "rat \<Rightarrow> real"
   546 where
   547   "real_of_rat \<equiv> of_rat"
   548 
   549 consts
   550   (*overloaded constant for injecting other types into "real"*)
   551   real :: "'a => real"
   552 
   553 defs (overloaded)
   554   real_of_nat_def [code inline]: "real == real_of_nat"
   555   real_of_int_def [code inline]: "real == real_of_int"
   556 
   557 lemma real_eq_of_nat: "real = of_nat"
   558   unfolding real_of_nat_def ..
   559 
   560 lemma real_eq_of_int: "real = of_int"
   561   unfolding real_of_int_def ..
   562 
   563 lemma real_of_int_zero [simp]: "real (0::int) = 0"  
   564 by (simp add: real_of_int_def) 
   565 
   566 lemma real_of_one [simp]: "real (1::int) = (1::real)"
   567 by (simp add: real_of_int_def) 
   568 
   569 lemma real_of_int_add [simp]: "real(x + y) = real (x::int) + real y"
   570 by (simp add: real_of_int_def) 
   571 
   572 lemma real_of_int_minus [simp]: "real(-x) = -real (x::int)"
   573 by (simp add: real_of_int_def) 
   574 
   575 lemma real_of_int_diff [simp]: "real(x - y) = real (x::int) - real y"
   576 by (simp add: real_of_int_def) 
   577 
   578 lemma real_of_int_mult [simp]: "real(x * y) = real (x::int) * real y"
   579 by (simp add: real_of_int_def) 
   580 
   581 lemma real_of_int_setsum [simp]: "real ((SUM x:A. f x)::int) = (SUM x:A. real(f x))"
   582   apply (subst real_eq_of_int)+
   583   apply (rule of_int_setsum)
   584 done
   585 
   586 lemma real_of_int_setprod [simp]: "real ((PROD x:A. f x)::int) = 
   587     (PROD x:A. real(f x))"
   588   apply (subst real_eq_of_int)+
   589   apply (rule of_int_setprod)
   590 done
   591 
   592 lemma real_of_int_zero_cancel [simp]: "(real x = 0) = (x = (0::int))"
   593 by (simp add: real_of_int_def) 
   594 
   595 lemma real_of_int_inject [iff]: "(real (x::int) = real y) = (x = y)"
   596 by (simp add: real_of_int_def) 
   597 
   598 lemma real_of_int_less_iff [iff]: "(real (x::int) < real y) = (x < y)"
   599 by (simp add: real_of_int_def) 
   600 
   601 lemma real_of_int_le_iff [simp]: "(real (x::int) \<le> real y) = (x \<le> y)"
   602 by (simp add: real_of_int_def) 
   603 
   604 lemma real_of_int_gt_zero_cancel_iff [simp]: "(0 < real (n::int)) = (0 < n)"
   605 by (simp add: real_of_int_def) 
   606 
   607 lemma real_of_int_ge_zero_cancel_iff [simp]: "(0 <= real (n::int)) = (0 <= n)"
   608 by (simp add: real_of_int_def) 
   609 
   610 lemma real_of_int_lt_zero_cancel_iff [simp]: "(real (n::int) < 0) = (n < 0)"
   611 by (simp add: real_of_int_def)
   612 
   613 lemma real_of_int_le_zero_cancel_iff [simp]: "(real (n::int) <= 0) = (n <= 0)"
   614 by (simp add: real_of_int_def)
   615 
   616 lemma real_of_int_abs [simp]: "real (abs x) = abs(real (x::int))"
   617 by (auto simp add: abs_if)
   618 
   619 lemma int_less_real_le: "((n::int) < m) = (real n + 1 <= real m)"
   620   apply (subgoal_tac "real n + 1 = real (n + 1)")
   621   apply (simp del: real_of_int_add)
   622   apply auto
   623 done
   624 
   625 lemma int_le_real_less: "((n::int) <= m) = (real n < real m + 1)"
   626   apply (subgoal_tac "real m + 1 = real (m + 1)")
   627   apply (simp del: real_of_int_add)
   628   apply simp
   629 done
   630 
   631 lemma real_of_int_div_aux: "d ~= 0 ==> (real (x::int)) / (real d) = 
   632     real (x div d) + (real (x mod d)) / (real d)"
   633 proof -
   634   assume "d ~= 0"
   635   have "x = (x div d) * d + x mod d"
   636     by auto
   637   then have "real x = real (x div d) * real d + real(x mod d)"
   638     by (simp only: real_of_int_mult [THEN sym] real_of_int_add [THEN sym])
   639   then have "real x / real d = ... / real d"
   640     by simp
   641   then show ?thesis
   642     by (auto simp add: add_divide_distrib ring_simps prems)
   643 qed
   644 
   645 lemma real_of_int_div: "(d::int) ~= 0 ==> d dvd n ==>
   646     real(n div d) = real n / real d"
   647   apply (frule real_of_int_div_aux [of d n])
   648   apply simp
   649   apply (simp add: zdvd_iff_zmod_eq_0)
   650 done
   651 
   652 lemma real_of_int_div2:
   653   "0 <= real (n::int) / real (x) - real (n div x)"
   654   apply (case_tac "x = 0")
   655   apply simp
   656   apply (case_tac "0 < x")
   657   apply (simp add: compare_rls)
   658   apply (subst real_of_int_div_aux)
   659   apply simp
   660   apply simp
   661   apply (subst zero_le_divide_iff)
   662   apply auto
   663   apply (simp add: compare_rls)
   664   apply (subst real_of_int_div_aux)
   665   apply simp
   666   apply simp
   667   apply (subst zero_le_divide_iff)
   668   apply auto
   669 done
   670 
   671 lemma real_of_int_div3:
   672   "real (n::int) / real (x) - real (n div x) <= 1"
   673   apply(case_tac "x = 0")
   674   apply simp
   675   apply (simp add: compare_rls)
   676   apply (subst real_of_int_div_aux)
   677   apply assumption
   678   apply simp
   679   apply (subst divide_le_eq)
   680   apply clarsimp
   681   apply (rule conjI)
   682   apply (rule impI)
   683   apply (rule order_less_imp_le)
   684   apply simp
   685   apply (rule impI)
   686   apply (rule order_less_imp_le)
   687   apply simp
   688 done
   689 
   690 lemma real_of_int_div4: "real (n div x) <= real (n::int) / real x" 
   691   by (insert real_of_int_div2 [of n x], simp)
   692 
   693 subsection{*Embedding the Naturals into the Reals*}
   694 
   695 lemma real_of_nat_zero [simp]: "real (0::nat) = 0"
   696 by (simp add: real_of_nat_def)
   697 
   698 lemma real_of_nat_one [simp]: "real (Suc 0) = (1::real)"
   699 by (simp add: real_of_nat_def)
   700 
   701 lemma real_of_nat_add [simp]: "real (m + n) = real (m::nat) + real n"
   702 by (simp add: real_of_nat_def)
   703 
   704 (*Not for addsimps: often the LHS is used to represent a positive natural*)
   705 lemma real_of_nat_Suc: "real (Suc n) = real n + (1::real)"
   706 by (simp add: real_of_nat_def)
   707 
   708 lemma real_of_nat_less_iff [iff]: 
   709      "(real (n::nat) < real m) = (n < m)"
   710 by (simp add: real_of_nat_def)
   711 
   712 lemma real_of_nat_le_iff [iff]: "(real (n::nat) \<le> real m) = (n \<le> m)"
   713 by (simp add: real_of_nat_def)
   714 
   715 lemma real_of_nat_ge_zero [iff]: "0 \<le> real (n::nat)"
   716 by (simp add: real_of_nat_def zero_le_imp_of_nat)
   717 
   718 lemma real_of_nat_Suc_gt_zero: "0 < real (Suc n)"
   719 by (simp add: real_of_nat_def del: of_nat_Suc)
   720 
   721 lemma real_of_nat_mult [simp]: "real (m * n) = real (m::nat) * real n"
   722 by (simp add: real_of_nat_def of_nat_mult)
   723 
   724 lemma real_of_nat_setsum [simp]: "real ((SUM x:A. f x)::nat) = 
   725     (SUM x:A. real(f x))"
   726   apply (subst real_eq_of_nat)+
   727   apply (rule of_nat_setsum)
   728 done
   729 
   730 lemma real_of_nat_setprod [simp]: "real ((PROD x:A. f x)::nat) = 
   731     (PROD x:A. real(f x))"
   732   apply (subst real_eq_of_nat)+
   733   apply (rule of_nat_setprod)
   734 done
   735 
   736 lemma real_of_card: "real (card A) = setsum (%x.1) A"
   737   apply (subst card_eq_setsum)
   738   apply (subst real_of_nat_setsum)
   739   apply simp
   740 done
   741 
   742 lemma real_of_nat_inject [iff]: "(real (n::nat) = real m) = (n = m)"
   743 by (simp add: real_of_nat_def)
   744 
   745 lemma real_of_nat_zero_iff [iff]: "(real (n::nat) = 0) = (n = 0)"
   746 by (simp add: real_of_nat_def)
   747 
   748 lemma real_of_nat_diff: "n \<le> m ==> real (m - n) = real (m::nat) - real n"
   749 by (simp add: add: real_of_nat_def of_nat_diff)
   750 
   751 lemma real_of_nat_gt_zero_cancel_iff [simp]: "(0 < real (n::nat)) = (0 < n)"
   752 by (auto simp: real_of_nat_def)
   753 
   754 lemma real_of_nat_le_zero_cancel_iff [simp]: "(real (n::nat) \<le> 0) = (n = 0)"
   755 by (simp add: add: real_of_nat_def)
   756 
   757 lemma not_real_of_nat_less_zero [simp]: "~ real (n::nat) < 0"
   758 by (simp add: add: real_of_nat_def)
   759 
   760 lemma real_of_nat_ge_zero_cancel_iff [simp]: "(0 \<le> real (n::nat))"
   761 by (simp add: add: real_of_nat_def)
   762 
   763 lemma nat_less_real_le: "((n::nat) < m) = (real n + 1 <= real m)"
   764   apply (subgoal_tac "real n + 1 = real (Suc n)")
   765   apply simp
   766   apply (auto simp add: real_of_nat_Suc)
   767 done
   768 
   769 lemma nat_le_real_less: "((n::nat) <= m) = (real n < real m + 1)"
   770   apply (subgoal_tac "real m + 1 = real (Suc m)")
   771   apply (simp add: less_Suc_eq_le)
   772   apply (simp add: real_of_nat_Suc)
   773 done
   774 
   775 lemma real_of_nat_div_aux: "0 < d ==> (real (x::nat)) / (real d) = 
   776     real (x div d) + (real (x mod d)) / (real d)"
   777 proof -
   778   assume "0 < d"
   779   have "x = (x div d) * d + x mod d"
   780     by auto
   781   then have "real x = real (x div d) * real d + real(x mod d)"
   782     by (simp only: real_of_nat_mult [THEN sym] real_of_nat_add [THEN sym])
   783   then have "real x / real d = \<dots> / real d"
   784     by simp
   785   then show ?thesis
   786     by (auto simp add: add_divide_distrib ring_simps prems)
   787 qed
   788 
   789 lemma real_of_nat_div: "0 < (d::nat) ==> d dvd n ==>
   790     real(n div d) = real n / real d"
   791   apply (frule real_of_nat_div_aux [of d n])
   792   apply simp
   793   apply (subst dvd_eq_mod_eq_0 [THEN sym])
   794   apply assumption
   795 done
   796 
   797 lemma real_of_nat_div2:
   798   "0 <= real (n::nat) / real (x) - real (n div x)"
   799 apply(case_tac "x = 0")
   800  apply (simp)
   801 apply (simp add: compare_rls)
   802 apply (subst real_of_nat_div_aux)
   803  apply simp
   804 apply simp
   805 apply (subst zero_le_divide_iff)
   806 apply simp
   807 done
   808 
   809 lemma real_of_nat_div3:
   810   "real (n::nat) / real (x) - real (n div x) <= 1"
   811 apply(case_tac "x = 0")
   812 apply (simp)
   813 apply (simp add: compare_rls)
   814 apply (subst real_of_nat_div_aux)
   815  apply simp
   816 apply simp
   817 done
   818 
   819 lemma real_of_nat_div4: "real (n div x) <= real (n::nat) / real x" 
   820   by (insert real_of_nat_div2 [of n x], simp)
   821 
   822 lemma real_of_int_real_of_nat: "real (int n) = real n"
   823 by (simp add: real_of_nat_def real_of_int_def int_eq_of_nat)
   824 
   825 lemma real_of_int_of_nat_eq [simp]: "real (of_nat n :: int) = real n"
   826 by (simp add: real_of_int_def real_of_nat_def)
   827 
   828 lemma real_nat_eq_real [simp]: "0 <= x ==> real(nat x) = real x"
   829   apply (subgoal_tac "real(int(nat x)) = real(nat x)")
   830   apply force
   831   apply (simp only: real_of_int_real_of_nat)
   832 done
   833 
   834 subsection{*Numerals and Arithmetic*}
   835 
   836 instance real :: number_ring
   837   real_number_of_def: "number_of w \<equiv> real_of_int w"
   838   by intro_classes (simp add: real_number_of_def)
   839 
   840 lemma [code, code unfold]:
   841   "number_of k = real_of_int (number_of k)"
   842   unfolding number_of_is_id real_number_of_def ..
   843 
   844 
   845 text{*Collapse applications of @{term real} to @{term number_of}*}
   846 lemma real_number_of [simp]: "real (number_of v :: int) = number_of v"
   847 by (simp add:  real_of_int_def of_int_number_of_eq)
   848 
   849 lemma real_of_nat_number_of [simp]:
   850      "real (number_of v :: nat) =  
   851         (if neg (number_of v :: int) then 0  
   852          else (number_of v :: real))"
   853 by (simp add: real_of_int_real_of_nat [symmetric] int_nat_number_of)
   854  
   855 
   856 use "real_arith.ML"
   857 declaration {* K real_arith_setup *}
   858 
   859 
   860 subsection{* Simprules combining x+y and 0: ARE THEY NEEDED?*}
   861 
   862 text{*Needed in this non-standard form by Hyperreal/Transcendental*}
   863 lemma real_0_le_divide_iff:
   864      "((0::real) \<le> x/y) = ((x \<le> 0 | 0 \<le> y) & (0 \<le> x | y \<le> 0))"
   865 by (simp add: real_divide_def zero_le_mult_iff, auto)
   866 
   867 lemma real_add_minus_iff [simp]: "(x + - a = (0::real)) = (x=a)" 
   868 by arith
   869 
   870 lemma real_add_eq_0_iff: "(x+y = (0::real)) = (y = -x)"
   871 by auto
   872 
   873 lemma real_add_less_0_iff: "(x+y < (0::real)) = (y < -x)"
   874 by auto
   875 
   876 lemma real_0_less_add_iff: "((0::real) < x+y) = (-x < y)"
   877 by auto
   878 
   879 lemma real_add_le_0_iff: "(x+y \<le> (0::real)) = (y \<le> -x)"
   880 by auto
   881 
   882 lemma real_0_le_add_iff: "((0::real) \<le> x+y) = (-x \<le> y)"
   883 by auto
   884 
   885 
   886 (*
   887 FIXME: we should have this, as for type int, but many proofs would break.
   888 It replaces x+-y by x-y.
   889 declare real_diff_def [symmetric, simp]
   890 *)
   891 
   892 
   893 subsubsection{*Density of the Reals*}
   894 
   895 lemma real_lbound_gt_zero:
   896      "[| (0::real) < d1; 0 < d2 |] ==> \<exists>e. 0 < e & e < d1 & e < d2"
   897 apply (rule_tac x = " (min d1 d2) /2" in exI)
   898 apply (simp add: min_def)
   899 done
   900 
   901 
   902 text{*Similar results are proved in @{text Ring_and_Field}*}
   903 lemma real_less_half_sum: "x < y ==> x < (x+y) / (2::real)"
   904   by auto
   905 
   906 lemma real_gt_half_sum: "x < y ==> (x+y)/(2::real) < y"
   907   by auto
   908 
   909 
   910 subsection{*Absolute Value Function for the Reals*}
   911 
   912 lemma abs_minus_add_cancel: "abs(x + (-y)) = abs (y + (-(x::real)))"
   913 by (simp add: abs_if)
   914 
   915 (* FIXME: redundant, but used by Integration/RealRandVar.thy in AFP *)
   916 lemma abs_le_interval_iff: "(abs x \<le> r) = (-r\<le>x & x\<le>(r::real))"
   917 by (force simp add: OrderedGroup.abs_le_iff)
   918 
   919 lemma abs_add_one_gt_zero [simp]: "(0::real) < 1 + abs(x)"
   920 by (simp add: abs_if)
   921 
   922 lemma abs_real_of_nat_cancel [simp]: "abs (real x) = real (x::nat)"
   923 by (rule abs_of_nonneg [OF real_of_nat_ge_zero])
   924 
   925 lemma abs_add_one_not_less_self [simp]: "~ abs(x) + (1::real) < x"
   926 by simp
   927  
   928 lemma abs_sum_triangle_ineq: "abs ((x::real) + y + (-l + -m)) \<le> abs(x + -l) + abs(y + -m)"
   929 by simp
   930 
   931 
   932 subsection {* Implementation of rational real numbers as pairs of integers *}
   933 
   934 definition
   935   Ratreal :: "int \<times> int \<Rightarrow> real"
   936 where
   937   "Ratreal = INum"
   938 
   939 code_datatype Ratreal
   940 
   941 lemma Ratreal_simp:
   942   "Ratreal (k, l) = real_of_int k / real_of_int l"
   943   unfolding Ratreal_def INum_def by simp
   944 
   945 lemma Ratreal_zero [simp]: "Ratreal 0\<^sub>N = 0"
   946   by (simp add: Ratreal_simp)
   947 
   948 lemma Ratreal_lit [simp]: "Ratreal i\<^sub>N = real_of_int i"
   949   by (simp add: Ratreal_simp)
   950 
   951 lemma zero_real_code [code, code unfold]:
   952   "0 = Ratreal 0\<^sub>N" by simp
   953 
   954 lemma one_real_code [code, code unfold]:
   955   "1 = Ratreal 1\<^sub>N" by simp
   956 
   957 instance real :: eq ..
   958 
   959 lemma real_eq_code [code]: "Ratreal x = Ratreal y \<longleftrightarrow> normNum x = normNum y"
   960   unfolding Ratreal_def INum_normNum_iff ..
   961 
   962 lemma real_less_eq_code [code]: "Ratreal x \<le> Ratreal y \<longleftrightarrow> normNum x \<le>\<^sub>N normNum y"
   963 proof -
   964   have "normNum x \<le>\<^sub>N normNum y \<longleftrightarrow> Ratreal (normNum x) \<le> Ratreal (normNum y)" 
   965     by (simp add: Ratreal_def del: normNum)
   966   also have "\<dots> = (Ratreal x \<le> Ratreal y)" by (simp add: Ratreal_def)
   967   finally show ?thesis by simp
   968 qed
   969 
   970 lemma real_less_code [code]: "Ratreal x < Ratreal y \<longleftrightarrow> normNum x <\<^sub>N normNum y"
   971 proof -
   972   have "normNum x <\<^sub>N normNum y \<longleftrightarrow> Ratreal (normNum x) < Ratreal (normNum y)" 
   973     by (simp add: Ratreal_def del: normNum)
   974   also have "\<dots> = (Ratreal x < Ratreal y)" by (simp add: Ratreal_def)
   975   finally show ?thesis by simp
   976 qed
   977 
   978 lemma real_add_code [code]: "Ratreal x + Ratreal y = Ratreal (x +\<^sub>N y)"
   979   unfolding Ratreal_def by simp
   980 
   981 lemma real_mul_code [code]: "Ratreal x * Ratreal y = Ratreal (x *\<^sub>N y)"
   982   unfolding Ratreal_def by simp
   983 
   984 lemma real_neg_code [code]: "- Ratreal x = Ratreal (~\<^sub>N x)"
   985   unfolding Ratreal_def by simp
   986 
   987 lemma real_sub_code [code]: "Ratreal x - Ratreal y = Ratreal (x -\<^sub>N y)"
   988   unfolding Ratreal_def by simp
   989 
   990 lemma real_inv_code [code]: "inverse (Ratreal x) = Ratreal (Ninv x)"
   991   unfolding Ratreal_def Ninv real_divide_def by simp
   992 
   993 lemma real_div_code [code]: "Ratreal x / Ratreal y = Ratreal (x \<div>\<^sub>N y)"
   994   unfolding Ratreal_def by simp
   995 
   996 text {* Setup for SML code generator *}
   997 
   998 types_code
   999   real ("(int */ int)")
  1000 attach (term_of) {*
  1001 fun term_of_real (p, q) =
  1002   let
  1003     val rT = HOLogic.realT
  1004   in
  1005     if q = 1 orelse p = 0 then HOLogic.mk_number rT p
  1006     else @{term "op / \<Colon> real \<Rightarrow> real \<Rightarrow> real"} $
  1007       HOLogic.mk_number rT p $ HOLogic.mk_number rT q
  1008   end;
  1009 *}
  1010 attach (test) {*
  1011 fun gen_real i =
  1012   let
  1013     val p = random_range 0 i;
  1014     val q = random_range 1 (i + 1);
  1015     val g = Integer.gcd p q;
  1016     val p' = p div g;
  1017     val q' = q div g;
  1018   in
  1019     (if one_of [true, false] then p' else ~ p',
  1020      if p' = 0 then 0 else q')
  1021   end;
  1022 *}
  1023 
  1024 consts_code
  1025   Ratreal ("(_)")
  1026 
  1027 consts_code
  1028   "of_int :: int \<Rightarrow> real" ("\<module>real'_of'_int")
  1029 attach {*
  1030 fun real_of_int 0 = (0, 0)
  1031   | real_of_int i = (i, 1);
  1032 *}
  1033 
  1034 declare real_of_int_of_nat_eq [symmetric, code]
  1035 
  1036 end