src/HOL/Tools/hologic.ML
author haftmann
Sun Jun 21 08:38:57 2009 +0200 (2009-06-21)
changeset 31736 926ebca5a145
parent 31463 c5681ed50eab
child 32264 0be31453f698
permissions -rw-r--r--
more appropriate mk_typerep
     1 (*  Title:      HOL/hologic.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Abstract syntax operations for HOL.
     5 *)
     6 
     7 signature HOLOGIC =
     8 sig
     9   val typeS: sort
    10   val typeT: typ
    11   val boolN: string
    12   val boolT: typ
    13   val Trueprop: term
    14   val mk_Trueprop: term -> term
    15   val dest_Trueprop: term -> term
    16   val true_const: term
    17   val false_const: term
    18   val mk_setT: typ -> typ
    19   val dest_setT: typ -> typ
    20   val Collect_const: typ -> term
    21   val mk_Collect: string * typ * term -> term
    22   val mk_mem: term * term -> term
    23   val dest_mem: term -> term * term
    24   val mk_set: typ -> term list -> term
    25   val dest_set: term -> term list
    26   val mk_UNIV: typ -> term
    27   val conj_intr: thm -> thm -> thm
    28   val conj_elim: thm -> thm * thm
    29   val conj_elims: thm -> thm list
    30   val conj: term
    31   val disj: term
    32   val imp: term
    33   val Not: term
    34   val mk_conj: term * term -> term
    35   val mk_disj: term * term -> term
    36   val mk_imp: term * term -> term
    37   val mk_not: term -> term
    38   val dest_conj: term -> term list
    39   val dest_disj: term -> term list
    40   val disjuncts: term -> term list
    41   val dest_imp: term -> term * term
    42   val dest_not: term -> term
    43   val eq_const: typ -> term
    44   val mk_eq: term * term -> term
    45   val dest_eq: term -> term * term
    46   val all_const: typ -> term
    47   val mk_all: string * typ * term -> term
    48   val list_all: (string * typ) list * term -> term
    49   val exists_const: typ -> term
    50   val mk_exists: string * typ * term -> term
    51   val choice_const: typ -> term
    52   val class_eq: string
    53   val mk_binop: string -> term * term -> term
    54   val mk_binrel: string -> term * term -> term
    55   val dest_bin: string -> typ -> term -> term * term
    56   val unitT: typ
    57   val is_unitT: typ -> bool
    58   val unit: term
    59   val is_unit: term -> bool
    60   val mk_prodT: typ * typ -> typ
    61   val dest_prodT: typ -> typ * typ
    62   val pair_const: typ -> typ -> term
    63   val mk_prod: term * term -> term
    64   val dest_prod: term -> term * term
    65   val mk_fst: term -> term
    66   val mk_snd: term -> term
    67   val split_const: typ * typ * typ -> term
    68   val mk_split: term -> term
    69   val prodT_factors: typ -> typ list
    70   val mk_tuple: typ -> term list -> term
    71   val dest_tuple: term -> term list
    72   val ap_split: typ -> typ -> term -> term
    73   val prod_factors: term -> int list list
    74   val dest_tuple': int list list -> term -> term list
    75   val prodT_factors': int list list -> typ -> typ list
    76   val ap_split': int list list -> typ -> typ -> term -> term
    77   val mk_tuple': int list list -> typ -> term list -> term
    78   val mk_tupleT: int list list -> typ list -> typ
    79   val strip_split: term -> term * typ list * int list list
    80   val natT: typ
    81   val zero: term
    82   val is_zero: term -> bool
    83   val mk_Suc: term -> term
    84   val dest_Suc: term -> term
    85   val Suc_zero: term
    86   val mk_nat: int -> term
    87   val dest_nat: term -> int
    88   val class_size: string
    89   val size_const: typ -> term
    90   val code_numeralT: typ
    91   val intT: typ
    92   val pls_const: term
    93   val min_const: term
    94   val bit0_const: term
    95   val bit1_const: term
    96   val mk_bit: int -> term
    97   val dest_bit: term -> int
    98   val mk_numeral: int -> term
    99   val dest_numeral: term -> int
   100   val number_of_const: typ -> term
   101   val add_numerals: term -> (term * typ) list -> (term * typ) list
   102   val mk_number: typ -> int -> term
   103   val dest_number: term -> typ * int
   104   val realT: typ
   105   val nibbleT: typ
   106   val mk_nibble: int -> term
   107   val dest_nibble: term -> int
   108   val charT: typ
   109   val mk_char: int -> term
   110   val dest_char: term -> int
   111   val listT: typ -> typ
   112   val nil_const: typ -> term
   113   val cons_const: typ -> term
   114   val mk_list: typ -> term list -> term
   115   val dest_list: term -> term list
   116   val stringT: typ
   117   val mk_string: string -> term
   118   val dest_string: term -> string
   119   val literalT: typ
   120   val mk_literal: string -> term
   121   val dest_literal: term -> string
   122   val mk_typerep: typ -> term
   123   val mk_term_of: typ -> term -> term
   124   val reflect_term: term -> term
   125   val mk_valtermify_app: string -> (string * typ) list -> typ -> term
   126   val mk_return: typ -> typ -> term -> term
   127   val mk_ST: ((term * typ) * (string * typ) option)  list -> term -> typ -> typ option * typ -> term
   128   val mk_random: typ -> term -> term
   129 end;
   130 
   131 structure HOLogic: HOLOGIC =
   132 struct
   133 
   134 (* HOL syntax *)
   135 
   136 val typeS: sort = ["HOL.type"];
   137 val typeT = TypeInfer.anyT typeS;
   138 
   139 
   140 (* bool and set *)
   141 
   142 val boolN = "bool";
   143 val boolT = Type (boolN, []);
   144 
   145 val true_const =  Const ("True", boolT);
   146 val false_const = Const ("False", boolT);
   147 
   148 fun mk_setT T = T --> boolT;
   149 
   150 fun dest_setT (Type ("fun", [T, Type ("bool", [])])) = T
   151   | dest_setT T = raise TYPE ("dest_setT: set type expected", [T], []);
   152 
   153 fun mk_set T ts =
   154   let
   155     val sT = mk_setT T;
   156     val empty = Const ("Set.empty", sT);
   157     fun insert t u = Const ("Set.insert", T --> sT --> sT) $ t $ u;
   158   in fold_rev insert ts empty end;
   159 
   160 fun mk_UNIV T = Const ("Set.UNIV", mk_setT T);
   161 
   162 fun dest_set (Const ("Set.empty", _)) = []
   163   | dest_set (Const ("Set.insert", _) $ t $ u) = t :: dest_set u
   164   | dest_set t = raise TERM ("dest_set", [t]);
   165 
   166 fun Collect_const T = Const ("Collect", (T --> boolT) --> mk_setT T);
   167 fun mk_Collect (a, T, t) = Collect_const T $ absfree (a, T, t);
   168 
   169 fun mk_mem (x, A) =
   170   let val setT = fastype_of A in
   171     Const ("op :", dest_setT setT --> setT --> boolT) $ x $ A
   172   end;
   173 
   174 fun dest_mem (Const ("op :", _) $ x $ A) = (x, A)
   175   | dest_mem t = raise TERM ("dest_mem", [t]);
   176 
   177 
   178 (* logic *)
   179 
   180 val Trueprop = Const ("Trueprop", boolT --> propT);
   181 
   182 fun mk_Trueprop P = Trueprop $ P;
   183 
   184 fun dest_Trueprop (Const ("Trueprop", _) $ P) = P
   185   | dest_Trueprop t = raise TERM ("dest_Trueprop", [t]);
   186 
   187 fun conj_intr thP thQ =
   188   let
   189     val (P, Q) = pairself (ObjectLogic.dest_judgment o Thm.cprop_of) (thP, thQ)
   190       handle CTERM (msg, _) => raise THM (msg, 0, [thP, thQ]);
   191     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   192   in Drule.implies_elim_list (inst @{thm conjI}) [thP, thQ] end;
   193 
   194 fun conj_elim thPQ =
   195   let
   196     val (P, Q) = Thm.dest_binop (ObjectLogic.dest_judgment (Thm.cprop_of thPQ))
   197       handle CTERM (msg, _) => raise THM (msg, 0, [thPQ]);
   198     val inst = Thm.instantiate ([], [(@{cpat "?P::bool"}, P), (@{cpat "?Q::bool"}, Q)]);
   199     val thP = Thm.implies_elim (inst @{thm conjunct1}) thPQ;
   200     val thQ = Thm.implies_elim (inst @{thm conjunct2}) thPQ;
   201   in (thP, thQ) end;
   202 
   203 fun conj_elims th =
   204   let val (th1, th2) = conj_elim th
   205   in conj_elims th1 @ conj_elims th2 end handle THM _ => [th];
   206 
   207 val conj = @{term "op &"}
   208 and disj = @{term "op |"}
   209 and imp = @{term "op -->"}
   210 and Not = @{term "Not"};
   211 
   212 fun mk_conj (t1, t2) = conj $ t1 $ t2
   213 and mk_disj (t1, t2) = disj $ t1 $ t2
   214 and mk_imp (t1, t2) = imp $ t1 $ t2
   215 and mk_not t = Not $ t;
   216 
   217 fun dest_conj (Const ("op &", _) $ t $ t') = t :: dest_conj t'
   218   | dest_conj t = [t];
   219 
   220 fun dest_disj (Const ("op |", _) $ t $ t') = t :: dest_disj t'
   221   | dest_disj t = [t];
   222 
   223 (*Like dest_disj, but flattens disjunctions however nested*)
   224 fun disjuncts_aux (Const ("op |", _) $ t $ t') disjs = disjuncts_aux t (disjuncts_aux t' disjs)
   225   | disjuncts_aux t disjs = t::disjs;
   226 
   227 fun disjuncts t = disjuncts_aux t [];
   228 
   229 fun dest_imp (Const("op -->",_) $ A $ B) = (A, B)
   230   | dest_imp  t = raise TERM ("dest_imp", [t]);
   231 
   232 fun dest_not (Const ("Not", _) $ t) = t
   233   | dest_not t = raise TERM ("dest_not", [t]);
   234 
   235 fun eq_const T = Const ("op =", [T, T] ---> boolT);
   236 fun mk_eq (t, u) = eq_const (fastype_of t) $ t $ u;
   237 
   238 fun dest_eq (Const ("op =", _) $ lhs $ rhs) = (lhs, rhs)
   239   | dest_eq t = raise TERM ("dest_eq", [t])
   240 
   241 fun all_const T = Const ("All", [T --> boolT] ---> boolT);
   242 fun mk_all (x, T, P) = all_const T $ absfree (x, T, P);
   243 fun list_all (xs, t) = fold_rev (fn (x, T) => fn P => all_const T $ Abs (x, T, P)) xs t;
   244 
   245 fun exists_const T = Const ("Ex", [T --> boolT] ---> boolT);
   246 fun mk_exists (x, T, P) = exists_const T $ absfree (x, T, P);
   247 
   248 fun choice_const T = Const("Hilbert_Choice.Eps", (T --> boolT) --> T);
   249 
   250 val class_eq = "HOL.eq";
   251 
   252 
   253 (* binary operations and relations *)
   254 
   255 fun mk_binop c (t, u) =
   256   let val T = fastype_of t in
   257     Const (c, [T, T] ---> T) $ t $ u
   258   end;
   259 
   260 fun mk_binrel c (t, u) =
   261   let val T = fastype_of t in
   262     Const (c, [T, T] ---> boolT) $ t $ u
   263   end;
   264 
   265 (*destruct the application of a binary operator. The dummyT case is a crude
   266   way of handling polymorphic operators.*)
   267 fun dest_bin c T (tm as Const (c', Type ("fun", [T', _])) $ t $ u) =
   268       if c = c' andalso (T=T' orelse T=dummyT) then (t, u)
   269       else raise TERM ("dest_bin " ^ c, [tm])
   270   | dest_bin c _ tm = raise TERM ("dest_bin " ^ c, [tm]);
   271 
   272 
   273 (* unit *)
   274 
   275 val unitT = Type ("Product_Type.unit", []);
   276 
   277 fun is_unitT (Type ("Product_Type.unit", [])) = true
   278   | is_unitT _ = false;
   279 
   280 val unit = Const ("Product_Type.Unity", unitT);
   281 
   282 fun is_unit (Const ("Product_Type.Unity", _)) = true
   283   | is_unit _ = false;
   284 
   285 
   286 (* prod *)
   287 
   288 fun mk_prodT (T1, T2) = Type ("*", [T1, T2]);
   289 
   290 fun dest_prodT (Type ("*", [T1, T2])) = (T1, T2)
   291   | dest_prodT T = raise TYPE ("dest_prodT", [T], []);
   292 
   293 fun pair_const T1 T2 = Const ("Pair", [T1, T2] ---> mk_prodT (T1, T2));
   294 
   295 fun mk_prod (t1, t2) =
   296   let val T1 = fastype_of t1 and T2 = fastype_of t2 in
   297     pair_const T1 T2 $ t1 $ t2
   298   end;
   299 
   300 fun dest_prod (Const ("Pair", _) $ t1 $ t2) = (t1, t2)
   301   | dest_prod t = raise TERM ("dest_prod", [t]);
   302 
   303 fun mk_fst p =
   304   let val pT = fastype_of p in
   305     Const ("fst", pT --> fst (dest_prodT pT)) $ p
   306   end;
   307 
   308 fun mk_snd p =
   309   let val pT = fastype_of p in
   310     Const ("snd", pT --> snd (dest_prodT pT)) $ p
   311   end;
   312 
   313 fun split_const (A, B, C) =
   314   Const ("split", (A --> B --> C) --> mk_prodT (A, B) --> C);
   315 
   316 fun mk_split t =
   317   (case Term.fastype_of t of
   318     T as (Type ("fun", [A, Type ("fun", [B, C])])) =>
   319       Const ("split", T --> mk_prodT (A, B) --> C) $ t
   320   | _ => raise TERM ("mk_split: bad body type", [t]));
   321 
   322 (*Maps the type T1 * ... * Tn to [T1, ..., Tn], however nested*)
   323 fun prodT_factors (Type ("*", [T1, T2])) = prodT_factors T1 @ prodT_factors T2
   324   | prodT_factors T = [T];
   325 
   326 (*Makes a nested tuple from a list, following the product type structure*)
   327 fun mk_tuple (Type ("*", [T1, T2])) tms =
   328         mk_prod (mk_tuple T1 tms,
   329                  mk_tuple T2 (Library.drop (length (prodT_factors T1), tms)))
   330   | mk_tuple T (t::_) = t;
   331 
   332 fun dest_tuple (Const ("Pair", _) $ t $ u) = dest_tuple t @ dest_tuple u
   333   | dest_tuple t = [t];
   334 
   335 (*In ap_split S T u, term u expects separate arguments for the factors of S,
   336   with result type T.  The call creates a new term expecting one argument
   337   of type S.*)
   338 fun ap_split T T3 u =
   339   let
   340     fun ap (T :: Ts) =
   341           (case T of
   342              Type ("*", [T1, T2]) =>
   343                split_const (T1, T2, Ts ---> T3) $ ap (T1 :: T2 :: Ts)
   344            | _ => Abs ("x", T, ap Ts))
   345       | ap [] =
   346           let val k = length (prodT_factors T)
   347           in list_comb (incr_boundvars k u, map Bound (k - 1 downto 0)) end
   348   in ap [T] end;
   349 
   350 
   351 (* operations on tuples with specific arities *)
   352 (*
   353   an "arity" of a tuple is a list of lists of integers
   354   ("factors"), denoting paths to subterms that are pairs
   355 *)
   356 
   357 fun prod_err s = raise TERM (s ^ ": inconsistent use of products", []);
   358 
   359 fun prod_factors t =
   360   let
   361     fun factors p (Const ("Pair", _) $ t $ u) =
   362           p :: factors (1::p) t @ factors (2::p) u
   363       | factors p _ = []
   364   in factors [] t end;
   365 
   366 fun dest_tuple' ps =
   367   let
   368     fun dest p t = if p mem ps then (case t of
   369         Const ("Pair", _) $ t $ u =>
   370           dest (1::p) t @ dest (2::p) u
   371       | _ => prod_err "dest_tuple'") else [t]
   372   in dest [] end;
   373 
   374 fun prodT_factors' ps =
   375   let
   376     fun factors p T = if p mem ps then (case T of
   377         Type ("*", [T1, T2]) =>
   378           factors (1::p) T1 @ factors (2::p) T2
   379       | _ => prod_err "prodT_factors'") else [T]
   380   in factors [] end;
   381 
   382 (*In ap_split' ps S T u, term u expects separate arguments for the factors of S,
   383   with result type T.  The call creates a new term expecting one argument
   384   of type S.*)
   385 fun ap_split' ps T T3 u =
   386   let
   387     fun ap ((p, T) :: pTs) =
   388           if p mem ps then (case T of
   389               Type ("*", [T1, T2]) =>
   390                 split_const (T1, T2, map snd pTs ---> T3) $
   391                   ap ((1::p, T1) :: (2::p, T2) :: pTs)
   392             | _ => prod_err "ap_split'")
   393           else Abs ("x", T, ap pTs)
   394       | ap [] =
   395           let val k = length ps
   396           in list_comb (incr_boundvars (k + 1) u, map Bound (k downto 0)) end
   397   in ap [([], T)] end;
   398 
   399 fun mk_tuple' ps =
   400   let
   401     fun mk p T ts =
   402       if p mem ps then (case T of
   403           Type ("*", [T1, T2]) =>
   404             let
   405               val (t, ts') = mk (1::p) T1 ts;
   406               val (u, ts'') = mk (2::p) T2 ts'
   407             in (pair_const T1 T2 $ t $ u, ts'') end
   408         | _ => prod_err "mk_tuple'")
   409       else (hd ts, tl ts)
   410   in fst oo mk [] end;
   411 
   412 fun mk_tupleT ps =
   413   let
   414     fun mk p Ts =
   415       if p mem ps then
   416         let
   417           val (T, Ts') = mk (1::p) Ts;
   418           val (U, Ts'') = mk (2::p) Ts'
   419         in (mk_prodT (T, U), Ts'') end
   420       else (hd Ts, tl Ts)
   421   in fst o mk [] end;
   422 
   423 fun strip_split t =
   424   let
   425     fun strip [] qs Ts t = (t, Ts, qs)
   426       | strip (p :: ps) qs Ts (Const ("split", _) $ t) =
   427           strip ((1 :: p) :: (2 :: p) :: ps) (p :: qs) Ts t
   428       | strip (p :: ps) qs Ts (Abs (s, T, t)) = strip ps qs (T :: Ts) t
   429       | strip (p :: ps) qs Ts t = strip ps qs
   430           (hd (binder_types (fastype_of1 (Ts, t))) :: Ts)
   431           (incr_boundvars 1 t $ Bound 0)
   432   in strip [[]] [] [] t end;
   433 
   434 
   435 (* nat *)
   436 
   437 val natT = Type ("nat", []);
   438 
   439 val zero = Const ("HOL.zero_class.zero", natT);
   440 
   441 fun is_zero (Const ("HOL.zero_class.zero", _)) = true
   442   | is_zero _ = false;
   443 
   444 fun mk_Suc t = Const ("Suc", natT --> natT) $ t;
   445 
   446 fun dest_Suc (Const ("Suc", _) $ t) = t
   447   | dest_Suc t = raise TERM ("dest_Suc", [t]);
   448 
   449 val Suc_zero = mk_Suc zero;
   450 
   451 fun mk_nat n =
   452   let
   453     fun mk 0 = zero
   454       | mk n = mk_Suc (mk (n - 1));
   455   in if n < 0 then raise TERM ("mk_nat: negative number", []) else mk n end;
   456 
   457 fun dest_nat (Const ("HOL.zero_class.zero", _)) = 0
   458   | dest_nat (Const ("Suc", _) $ t) = dest_nat t + 1
   459   | dest_nat t = raise TERM ("dest_nat", [t]);
   460 
   461 val class_size = "Nat.size";
   462 
   463 fun size_const T = Const ("Nat.size_class.size", T --> natT);
   464 
   465 
   466 (* code numeral *)
   467 
   468 val code_numeralT = Type ("Code_Numeral.code_numeral", []);
   469 
   470 
   471 (* binary numerals and int -- non-unique representation due to leading zeros/ones! *)
   472 
   473 val intT = Type ("Int.int", []);
   474 
   475 val pls_const = Const ("Int.Pls", intT)
   476 and min_const = Const ("Int.Min", intT)
   477 and bit0_const = Const ("Int.Bit0", intT --> intT)
   478 and bit1_const = Const ("Int.Bit1", intT --> intT);
   479 
   480 fun mk_bit 0 = bit0_const
   481   | mk_bit 1 = bit1_const
   482   | mk_bit _ = raise TERM ("mk_bit", []);
   483 
   484 fun dest_bit (Const ("Int.Bit0", _)) = 0
   485   | dest_bit (Const ("Int.Bit1", _)) = 1
   486   | dest_bit t = raise TERM ("dest_bit", [t]);
   487 
   488 fun mk_numeral 0 = pls_const
   489   | mk_numeral ~1 = min_const
   490   | mk_numeral i =
   491       let val (q, r) = Integer.div_mod i 2;
   492       in mk_bit r $ mk_numeral q end;
   493 
   494 fun dest_numeral (Const ("Int.Pls", _)) = 0
   495   | dest_numeral (Const ("Int.Min", _)) = ~1
   496   | dest_numeral (Const ("Int.Bit0", _) $ bs) = 2 * dest_numeral bs
   497   | dest_numeral (Const ("Int.Bit1", _) $ bs) = 2 * dest_numeral bs + 1
   498   | dest_numeral t = raise TERM ("dest_numeral", [t]);
   499 
   500 fun number_of_const T = Const ("Int.number_class.number_of", intT --> T);
   501 
   502 fun add_numerals (Const ("Int.number_class.number_of", Type (_, [_, T])) $ t) = cons (t, T)
   503   | add_numerals (t $ u) = add_numerals t #> add_numerals u
   504   | add_numerals (Abs (_, _, t)) = add_numerals t
   505   | add_numerals _ = I;
   506 
   507 fun mk_number T 0 = Const ("HOL.zero_class.zero", T)
   508   | mk_number T 1 = Const ("HOL.one_class.one", T)
   509   | mk_number T i = number_of_const T $ mk_numeral i;
   510 
   511 fun dest_number (Const ("HOL.zero_class.zero", T)) = (T, 0)
   512   | dest_number (Const ("HOL.one_class.one", T)) = (T, 1)
   513   | dest_number (Const ("Int.number_class.number_of", Type ("fun", [_, T])) $ t) =
   514       (T, dest_numeral t)
   515   | dest_number t = raise TERM ("dest_number", [t]);
   516 
   517 
   518 (* real *)
   519 
   520 val realT = Type ("RealDef.real", []);
   521 
   522 
   523 (* list *)
   524 
   525 fun listT T = Type ("List.list", [T]);
   526 
   527 fun nil_const T = Const ("List.list.Nil", listT T);
   528 
   529 fun cons_const T =
   530   let val lT = listT T
   531   in Const ("List.list.Cons", T --> lT --> lT) end;
   532 
   533 fun mk_list T ts =
   534   let
   535     val lT = listT T;
   536     val Nil = Const ("List.list.Nil", lT);
   537     fun Cons t u = Const ("List.list.Cons", T --> lT --> lT) $ t $ u;
   538   in fold_rev Cons ts Nil end;
   539 
   540 fun dest_list (Const ("List.list.Nil", _)) = []
   541   | dest_list (Const ("List.list.Cons", _) $ t $ u) = t :: dest_list u
   542   | dest_list t = raise TERM ("dest_list", [t]);
   543 
   544 
   545 (* nibble *)
   546 
   547 val nibbleT = Type ("String.nibble", []);
   548 
   549 fun mk_nibble n =
   550   let val s =
   551     if 0 <= n andalso n <= 9 then chr (n + ord "0")
   552     else if 10 <= n andalso n <= 15 then chr (n + ord "A" - 10)
   553     else raise TERM ("mk_nibble", [])
   554   in Const ("String.nibble.Nibble" ^ s, nibbleT) end;
   555 
   556 fun dest_nibble t =
   557   let fun err () = raise TERM ("dest_nibble", [t]) in
   558     (case try (unprefix "String.nibble.Nibble" o fst o Term.dest_Const) t of
   559       NONE => err ()
   560     | SOME c =>
   561         if size c <> 1 then err ()
   562         else if "0" <= c andalso c <= "9" then ord c - ord "0"
   563         else if "A" <= c andalso c <= "F" then ord c - ord "A" + 10
   564         else err ())
   565   end;
   566 
   567 
   568 (* char *)
   569 
   570 val charT = Type ("String.char", []);
   571 
   572 fun mk_char n =
   573   if 0 <= n andalso n <= 255 then
   574     Const ("String.char.Char", nibbleT --> nibbleT --> charT) $
   575       mk_nibble (n div 16) $ mk_nibble (n mod 16)
   576   else raise TERM ("mk_char", []);
   577 
   578 fun dest_char (Const ("String.char.Char", _) $ t $ u) =
   579       dest_nibble t * 16 + dest_nibble u
   580   | dest_char t = raise TERM ("dest_char", [t]);
   581 
   582 
   583 (* string *)
   584 
   585 val stringT = Type ("String.string", []);
   586 
   587 val mk_string = mk_list charT o map (mk_char o ord) o explode;
   588 val dest_string = implode o map (chr o dest_char) o dest_list;
   589 
   590 
   591 (* literal *)
   592 
   593 val literalT = Type ("String.literal", []);
   594 
   595 fun mk_literal s = Const ("String.literal.STR", stringT --> literalT)
   596       $ mk_string s;
   597 fun dest_literal (Const ("String.literal.STR", _) $ t) =
   598       dest_string t
   599   | dest_literal t = raise TERM ("dest_literal", [t]);
   600 
   601 
   602 (* typerep and term *)
   603 
   604 val typerepT = Type ("Typerep.typerep", []);
   605 
   606 fun mk_typerep (Type (tyco, Ts)) = Const ("Typerep.typerep.Typerep",
   607       literalT --> listT typerepT --> typerepT) $ mk_literal tyco
   608         $ mk_list typerepT (map mk_typerep Ts)
   609   | mk_typerep (T as TFree _) = Const ("Typerep.typerep_class.typerep",
   610       Term.itselfT T --> typerepT) $ Logic.mk_type T;
   611 
   612 val termT = Type ("Code_Eval.term", []);
   613 
   614 fun mk_term_of T t = Const ("Code_Eval.term_of_class.term_of", T --> termT) $ t;
   615 
   616 fun reflect_term (Const (c, T)) =
   617       Const ("Code_Eval.Const", literalT --> typerepT --> termT)
   618         $ mk_literal c $ mk_typerep T
   619   | reflect_term (t1 $ t2) =
   620       Const ("Code_Eval.App", termT --> termT --> termT)
   621         $ reflect_term t1 $ reflect_term t2
   622   | reflect_term (Abs (v, _, t)) = Abs (v, termT, reflect_term t)
   623   | reflect_term t = t;
   624 
   625 fun mk_valtermify_app c vs T =
   626   let
   627     fun termifyT T = mk_prodT (T, unitT --> termT);
   628     fun valapp T T' = Const ("Code_Eval.valapp",
   629       termifyT (T --> T') --> termifyT T --> termifyT T');
   630     fun mk_fTs [] _ = []
   631       | mk_fTs (_ :: Ts) T = (Ts ---> T) :: mk_fTs Ts T;
   632     val Ts = map snd vs;
   633     val t = Const (c, Ts ---> T);
   634     val tt = mk_prod (t, Abs ("u", unitT, reflect_term t));
   635     fun app (t, (fT, (v, T))) = valapp T fT $ t $ Free (v, termifyT T);
   636   in Library.foldl app (tt, mk_fTs Ts T ~~ vs) end;
   637 
   638 
   639 (* open state monads *)
   640 
   641 fun mk_return T U x = pair_const T U $ x;
   642 
   643 fun mk_ST clauses t U (someT, V) =
   644   let
   645     val R = case someT of SOME T => mk_prodT (T, V) | NONE => V
   646     fun mk_clause ((t, U), SOME (v, T)) (t', U') =
   647           (Const ("Product_Type.scomp", (U --> mk_prodT (T, U')) --> (T --> U' --> R) --> U --> R)
   648             $ t $ lambda (Free (v, T)) t', U)
   649       | mk_clause ((t, U), NONE) (t', U') =
   650           (Const ("Product_Type.fcomp", (U --> U') --> (U' --> R) --> U --> R)
   651             $ t $ t', U)
   652   in fold_rev mk_clause clauses (t, U) |> fst end;
   653 
   654 val code_numeralT = Type ("Code_Numeral.code_numeral", []);
   655 val random_seedT = mk_prodT (code_numeralT, code_numeralT);
   656 
   657 fun mk_random T t = Const ("Quickcheck.random_class.random", code_numeralT
   658   --> random_seedT --> mk_prodT (mk_prodT (T, unitT --> termT), random_seedT)) $ t;
   659 
   660 end;