src/Pure/theory.ML
author wenzelm
Sun Apr 15 14:31:56 2007 +0200 (2007-04-15)
changeset 22697 92f8e9a8df78
parent 22689 b800228434a8
child 22846 fb79144af9a3
permissions -rw-r--r--
removed obsolete inferT_axm;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   val eq_thy: theory * theory -> bool
    11   val subthy: theory * theory -> bool
    12 end
    13 
    14 signature THEORY =
    15 sig
    16   include BASIC_THEORY
    17   include SIGN_THEORY
    18   val parents_of: theory -> theory list
    19   val ancestors_of: theory -> theory list
    20   val begin_theory: string -> theory list -> theory
    21   val end_theory: theory -> theory
    22   val checkpoint: theory -> theory
    23   val copy: theory -> theory
    24   val init_data: theory -> theory
    25   val rep_theory: theory ->
    26    {axioms: term NameSpace.table,
    27     defs: Defs.T,
    28     oracles: ((theory * Object.T -> term) * stamp) NameSpace.table}
    29   val axiom_space: theory -> NameSpace.T
    30   val axiom_table: theory -> term Symtab.table
    31   val oracle_space: theory -> NameSpace.T
    32   val oracle_table: theory -> ((theory * Object.T -> term) * stamp) Symtab.table
    33   val axioms_of: theory -> (string * term) list
    34   val all_axioms_of: theory -> (string * term) list
    35   val defs_of : theory -> Defs.T
    36   val self_ref: theory -> theory_ref
    37   val deref: theory_ref -> theory
    38   val merge: theory * theory -> theory                     (*exception TERM*)
    39   val merge_refs: theory_ref * theory_ref -> theory_ref    (*exception TERM*)
    40   val merge_list: theory list -> theory                    (*exception TERM*)
    41   val requires: theory -> string -> string -> unit
    42   val assert_super: theory -> theory -> theory
    43   val cert_axm: theory -> string * term -> string * term
    44   val read_axm: theory -> string * string -> string * term
    45   val add_axioms: (bstring * string) list -> theory -> theory
    46   val add_axioms_i: (bstring * term) list -> theory -> theory
    47   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    48   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    49   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    50   val add_finals: bool -> string list -> theory -> theory
    51   val add_finals_i: bool -> term list -> theory -> theory
    52   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    53 end
    54 
    55 structure Theory: THEORY =
    56 struct
    57 
    58 
    59 (** type theory **)
    60 
    61 (* context operations *)
    62 
    63 val eq_thy = Context.eq_thy;
    64 val subthy = Context.subthy;
    65 
    66 val parents_of = Context.parents_of;
    67 val ancestors_of = Context.ancestors_of;
    68 
    69 val self_ref = Context.self_ref;
    70 val deref = Context.deref;
    71 val merge = Context.merge;
    72 val merge_refs = Context.merge_refs;
    73 
    74 fun merge_list [] = raise TERM ("Empty merge of theories", [])
    75   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    76 
    77 val begin_theory = Sign.local_path oo Context.begin_thy Sign.pp;
    78 val end_theory = Context.finish_thy;
    79 val checkpoint = Context.checkpoint_thy;
    80 val copy = Context.copy_thy;
    81 
    82 
    83 (* signature operations *)
    84 
    85 structure SignTheory: SIGN_THEORY = Sign;
    86 open SignTheory;
    87 
    88 
    89 
    90 (** datatype thy **)
    91 
    92 datatype thy = Thy of
    93  {axioms: term NameSpace.table,
    94   defs: Defs.T,
    95   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table};
    96 
    97 fun make_thy (axioms, defs, oracles) =
    98   Thy {axioms = axioms, defs = defs, oracles = oracles};
    99 
   100 fun err_dup_axms dups = error ("Duplicate axiom(s): " ^ commas_quote dups);
   101 fun err_dup_oras dups = error ("Duplicate oracle(s): " ^ commas_quote dups);
   102 
   103 structure ThyData = TheoryDataFun
   104 (struct
   105   val name = "Pure/theory";
   106   type T = thy;
   107   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table);
   108   val copy = I;
   109 
   110   fun extend (Thy {axioms, defs, oracles}) = make_thy (NameSpace.empty_table, defs, oracles);
   111 
   112   fun merge pp (thy1, thy2) =
   113     let
   114       val Thy {axioms = _, defs = defs1, oracles = oracles1} = thy1;
   115       val Thy {axioms = _, defs = defs2, oracles = oracles2} = thy2;
   116 
   117       val axioms = NameSpace.empty_table;
   118       val defs = Defs.merge pp (defs1, defs2);
   119       val oracles = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   120         handle Symtab.DUPS dups => err_dup_oras dups;
   121     in make_thy (axioms, defs, oracles) end;
   122 
   123   fun print _ _ = ();
   124 end);
   125 
   126 val init_data = ThyData.init;
   127 
   128 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   129 
   130 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles}) =>
   131   make_thy (f (axioms, defs, oracles)));
   132 
   133 fun map_axioms f = map_thy (fn (axioms, defs, oracles) => (f axioms, defs, oracles));
   134 fun map_defs f = map_thy (fn (axioms, defs, oracles) => (axioms, f defs, oracles));
   135 fun map_oracles f = map_thy (fn (axioms, defs, oracles) => (axioms, defs, f oracles));
   136 
   137 
   138 (* basic operations *)
   139 
   140 val axiom_space = #1 o #axioms o rep_theory;
   141 val axiom_table = #2 o #axioms o rep_theory;
   142 
   143 val oracle_space = #1 o #oracles o rep_theory;
   144 val oracle_table = #2 o #oracles o rep_theory;
   145 
   146 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   147 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   148 
   149 val defs_of = #defs o rep_theory;
   150 
   151 fun requires thy name what =
   152   if Context.exists_name name thy then ()
   153   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
   154 
   155 fun assert_super thy1 thy2 =
   156   if subthy (thy1, thy2) then thy2
   157   else raise THEORY ("Not a super theory", [thy1, thy2]);
   158 
   159 
   160 
   161 (** add axioms **)
   162 
   163 (* prepare axioms *)
   164 
   165 fun err_in_axm msg name =
   166   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   167 
   168 fun cert_axm thy (name, raw_tm) =
   169   let
   170     val (t, T, _) = Sign.certify_prop thy raw_tm
   171       handle TYPE (msg, _, _) => error msg
   172         | TERM (msg, _) => error msg;
   173   in
   174     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   175     (name, Sign.no_vars (Sign.pp thy) t)
   176   end;
   177 
   178 fun read_axm thy (name, str) =
   179   cert_axm thy (name, Sign.read_prop thy str)
   180     handle ERROR msg => err_in_axm msg name;
   181 
   182 
   183 (* add_axioms(_i) *)
   184 
   185 local
   186 
   187 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   188   let
   189     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   190     val axioms' = NameSpace.extend_table (Sign.naming_of thy) (axioms, axms)
   191       handle Symtab.DUPS dups => err_dup_axms dups;
   192   in axioms' end);
   193 
   194 in
   195 
   196 val add_axioms = gen_add_axioms read_axm;
   197 val add_axioms_i = gen_add_axioms cert_axm;
   198 
   199 end;
   200 
   201 
   202 
   203 (** add constant definitions **)
   204 
   205 (* dependencies *)
   206 
   207 fun dependencies thy unchecked is_def name lhs rhs =
   208   let
   209     val pp = Sign.pp thy;
   210     val consts = Sign.consts_of thy;
   211     fun prep const =
   212       let val Const (c, T) = Sign.no_vars pp (Const const)
   213       in (c, Consts.typargs consts (c, Compress.typ thy (Logic.varifyT T))) end;
   214 
   215     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   216     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   217       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   218     val _ =
   219       if null rhs_extras then ()
   220       else error ("Specification depends on extra type variables: " ^
   221         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   222         "\nThe error(s) above occurred in " ^ quote name);
   223   in Defs.define pp unchecked is_def (Context.theory_name thy) name (prep lhs) (map prep rhs) end;
   224 
   225 fun add_deps a raw_lhs raw_rhs thy =
   226   let
   227     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   228     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   229   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   230 
   231 
   232 (* check_overloading *)
   233 
   234 fun check_overloading thy overloaded (c, T) =
   235   let
   236     val declT =
   237       (case Sign.const_constraint thy c of
   238         NONE => error ("Undeclared constant " ^ quote c)
   239       | SOME declT => declT);
   240     val T' = Logic.varifyT T;
   241 
   242     fun message txt =
   243       [Pretty.block [Pretty.str "Specification of constant ",
   244         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   245         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   246   in
   247     if Sign.typ_instance thy (declT, T') then ()
   248     else if Type.raw_instance (declT, T') then
   249       error (Library.setmp show_sorts true
   250         message "imposes additional sort constraints on the constant declaration")
   251     else if overloaded then ()
   252     else warning (message "is strictly less general than the declared type");
   253     (c, T)
   254   end;
   255 
   256 
   257 (* check_def *)
   258 
   259 fun check_def thy unchecked overloaded (bname, tm) defs =
   260   let
   261     val name = Sign.full_name thy bname;
   262     val (lhs_const, rhs) = Sign.cert_def (Sign.pp thy) tm;
   263     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   264     val _ = check_overloading thy overloaded lhs_const;
   265   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   266   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   267    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   268     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   269 
   270 
   271 (* add_defs(_i) *)
   272 
   273 local
   274 
   275 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   276   let val axms = map (prep_axm thy) raw_axms in
   277     thy
   278     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   279     |> add_axioms_i axms
   280   end;
   281 
   282 in
   283 
   284 val add_defs_i = gen_add_defs cert_axm;
   285 val add_defs = gen_add_defs read_axm;
   286 
   287 end;
   288 
   289 
   290 (* add_finals(_i) *)
   291 
   292 local
   293 
   294 fun gen_add_finals prep_term overloaded args thy =
   295   let
   296     fun const_of (Const const) = const
   297       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   298       | const_of _ = error "Attempt to finalize non-constant term";
   299     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   300     val finalize = specify o check_overloading thy overloaded o const_of o prep_term thy;
   301   in thy |> map_defs (fold finalize args) end;
   302 
   303 in
   304 
   305 val add_finals = gen_add_finals Sign.read_term;
   306 val add_finals_i = gen_add_finals Sign.cert_term;
   307 
   308 end;
   309 
   310 
   311 
   312 (** add oracle **)
   313 
   314 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   315   NameSpace.extend_table (Sign.naming_of thy) (oracles, [(bname, (oracle, stamp ()))])
   316     handle Symtab.DUPS dups => err_dup_oras dups);
   317 
   318 end;
   319 
   320 structure BasicTheory: BASIC_THEORY = Theory;
   321 open BasicTheory;