src/HOL/Nat.thy
author krauss
Thu Jul 17 15:21:52 2008 +0200 (2008-07-17)
changeset 27627 93016de79b02
parent 27625 3a45b555001a
child 27679 6392b92c3536
permissions -rw-r--r--
simplified proofs
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Inductive Ring_and_Field
    13 uses
    14   "~~/src/Tools/rat.ML"
    15   "~~/src/Provers/Arith/cancel_sums.ML"
    16   ("arith_data.ML")
    17   "~~/src/Provers/Arith/fast_lin_arith.ML"
    18   ("Tools/lin_arith.ML")
    19 begin
    20 
    21 subsection {* Type @{text ind} *}
    22 
    23 typedecl ind
    24 
    25 axiomatization
    26   Zero_Rep :: ind and
    27   Suc_Rep :: "ind => ind"
    28 where
    29   -- {* the axiom of infinity in 2 parts *}
    30   inj_Suc_Rep:          "inj Suc_Rep" and
    31   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    32 
    33 
    34 subsection {* Type nat *}
    35 
    36 text {* Type definition *}
    37 
    38 inductive Nat :: "ind \<Rightarrow> bool"
    39 where
    40     Zero_RepI: "Nat Zero_Rep"
    41   | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = Nat
    47   by (rule exI, unfold mem_def, rule Nat.Zero_RepI)
    48 
    49 constdefs
    50   Suc ::   "nat => nat"
    51   Suc_def: "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    52 
    53 local
    54 
    55 instantiation nat :: zero
    56 begin
    57 
    58 definition Zero_nat_def [code func del]:
    59   "0 = Abs_Nat Zero_Rep"
    60 
    61 instance ..
    62 
    63 end
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   apply (simp add: Zero_nat_def Suc_def Abs_Nat_inject [unfolded mem_def]
    67     Rep_Nat [unfolded mem_def] Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def])
    68   done
    69 
    70 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    71   by (rule not_sym, rule Suc_not_Zero not_sym)
    72 
    73 rep_datatype "0 \<Colon> nat" Suc
    74   apply (unfold Zero_nat_def Suc_def)
    75      apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    76      apply (erule Rep_Nat [unfolded mem_def, THEN Nat.induct])
    77      apply (iprover elim: Abs_Nat_inverse [unfolded mem_def, THEN subst])
    78     apply (simp_all add: Abs_Nat_inject [unfolded mem_def] Rep_Nat [unfolded mem_def]
    79       Suc_RepI Zero_RepI Suc_Rep_not_Zero_Rep [unfolded mem_def]
    80       Suc_Rep_not_Zero_Rep [unfolded mem_def, symmetric]
    81       inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject)
    82   done
    83 
    84 lemma nat_induct [case_names 0 Suc, induct type: nat]:
    85   -- {* for backward compatibility -- naming of variables differs *}
    86   fixes n
    87   assumes "P 0"
    88     and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    89   shows "P n"
    90   using assms by (rule nat.induct) 
    91 
    92 declare nat.exhaust [case_names 0 Suc, cases type: nat]
    93 
    94 lemmas nat_rec_0 = nat.recs(1)
    95   and nat_rec_Suc = nat.recs(2)
    96 
    97 lemmas nat_case_0 = nat.cases(1)
    98   and nat_case_Suc = nat.cases(2)
    99    
   100 
   101 text {* Injectiveness and distinctness lemmas *}
   102 
   103 lemma inj_Suc[simp]: "inj_on Suc N"
   104   by (simp add: inj_on_def)
   105 
   106 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   107 by (rule notE, rule Suc_not_Zero)
   108 
   109 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   110 by (rule Suc_neq_Zero, erule sym)
   111 
   112 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   113 by (rule inj_Suc [THEN injD])
   114 
   115 lemma n_not_Suc_n: "n \<noteq> Suc n"
   116 by (induct n) simp_all
   117 
   118 lemma Suc_n_not_n: "Suc n \<noteq> n"
   119 by (rule not_sym, rule n_not_Suc_n)
   120 
   121 text {* A special form of induction for reasoning
   122   about @{term "m < n"} and @{term "m - n"} *}
   123 
   124 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   125     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   126   apply (rule_tac x = m in spec)
   127   apply (induct n)
   128   prefer 2
   129   apply (rule allI)
   130   apply (induct_tac x, iprover+)
   131   done
   132 
   133 
   134 subsection {* Arithmetic operators *}
   135 
   136 instantiation nat :: "{minus, comm_monoid_add}"
   137 begin
   138 
   139 primrec plus_nat
   140 where
   141   add_0:      "0 + n = (n\<Colon>nat)"
   142   | add_Suc:  "Suc m + n = Suc (m + n)"
   143 
   144 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   145   by (induct m) simp_all
   146 
   147 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   148   by (induct m) simp_all
   149 
   150 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   151   by simp
   152 
   153 primrec minus_nat
   154 where
   155   diff_0:     "m - 0 = (m\<Colon>nat)"
   156   | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   157 
   158 declare diff_Suc [simp del, code del]
   159 
   160 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   161   by (induct n) (simp_all add: diff_Suc)
   162 
   163 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   164   by (induct n) (simp_all add: diff_Suc)
   165 
   166 instance proof
   167   fix n m q :: nat
   168   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   169   show "n + m = m + n" by (induct n) simp_all
   170   show "0 + n = n" by simp
   171 qed
   172 
   173 end
   174 
   175 instantiation nat :: comm_semiring_1_cancel
   176 begin
   177 
   178 definition
   179   One_nat_def [simp]: "1 = Suc 0"
   180 
   181 primrec times_nat
   182 where
   183   mult_0:     "0 * n = (0\<Colon>nat)"
   184   | mult_Suc: "Suc m * n = n + (m * n)"
   185 
   186 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   187   by (induct m) simp_all
   188 
   189 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   190   by (induct m) (simp_all add: add_left_commute)
   191 
   192 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   193   by (induct m) (simp_all add: add_assoc)
   194 
   195 instance proof
   196   fix n m q :: nat
   197   show "0 \<noteq> (1::nat)" by simp
   198   show "1 * n = n" by simp
   199   show "n * m = m * n" by (induct n) simp_all
   200   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   201   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   202   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   203 qed
   204 
   205 end
   206 
   207 subsubsection {* Addition *}
   208 
   209 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   210   by (rule add_assoc)
   211 
   212 lemma nat_add_commute: "m + n = n + (m::nat)"
   213   by (rule add_commute)
   214 
   215 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   216   by (rule add_left_commute)
   217 
   218 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   219   by (rule add_left_cancel)
   220 
   221 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   222   by (rule add_right_cancel)
   223 
   224 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   225 
   226 lemma add_is_0 [iff]:
   227   fixes m n :: nat
   228   shows "(m + n = 0) = (m = 0 & n = 0)"
   229   by (cases m) simp_all
   230 
   231 lemma add_is_1:
   232   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   233   by (cases m) simp_all
   234 
   235 lemma one_is_add:
   236   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   237   by (rule trans, rule eq_commute, rule add_is_1)
   238 
   239 lemma add_eq_self_zero:
   240   fixes m n :: nat
   241   shows "m + n = m \<Longrightarrow> n = 0"
   242   by (induct m) simp_all
   243 
   244 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   245   apply (induct k)
   246    apply simp
   247   apply(drule comp_inj_on[OF _ inj_Suc])
   248   apply (simp add:o_def)
   249   done
   250 
   251 
   252 subsubsection {* Difference *}
   253 
   254 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   255   by (induct m) simp_all
   256 
   257 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   258   by (induct i j rule: diff_induct) simp_all
   259 
   260 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   261   by (simp add: diff_diff_left)
   262 
   263 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   264   by (simp add: diff_diff_left add_commute)
   265 
   266 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   267   by (induct n) simp_all
   268 
   269 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   270   by (simp add: diff_add_inverse add_commute [of m n])
   271 
   272 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   273   by (induct k) simp_all
   274 
   275 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   276   by (simp add: diff_cancel add_commute)
   277 
   278 lemma diff_add_0: "n - (n + m) = (0::nat)"
   279   by (induct n) simp_all
   280 
   281 text {* Difference distributes over multiplication *}
   282 
   283 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   284 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   285 
   286 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   287 by (simp add: diff_mult_distrib mult_commute [of k])
   288   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   289 
   290 
   291 subsubsection {* Multiplication *}
   292 
   293 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   294   by (rule mult_assoc)
   295 
   296 lemma nat_mult_commute: "m * n = n * (m::nat)"
   297   by (rule mult_commute)
   298 
   299 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   300   by (rule right_distrib)
   301 
   302 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   303   by (induct m) auto
   304 
   305 lemmas nat_distrib =
   306   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   307 
   308 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   309   apply (induct m)
   310    apply simp
   311   apply (induct n)
   312    apply auto
   313   done
   314 
   315 lemma one_eq_mult_iff [simp,noatp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   316   apply (rule trans)
   317   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   318   done
   319 
   320 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   321 proof -
   322   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   323   proof (induct n arbitrary: m)
   324     case 0 then show "m = 0" by simp
   325   next
   326     case (Suc n) then show "m = Suc n"
   327       by (cases m) (simp_all add: eq_commute [of "0"])
   328   qed
   329   then show ?thesis by auto
   330 qed
   331 
   332 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   333   by (simp add: mult_commute)
   334 
   335 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   336   by (subst mult_cancel1) simp
   337 
   338 
   339 subsection {* Orders on @{typ nat} *}
   340 
   341 subsubsection {* Operation definition *}
   342 
   343 instantiation nat :: linorder
   344 begin
   345 
   346 primrec less_eq_nat where
   347   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   348   | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   349 
   350 declare less_eq_nat.simps [simp del, code del]
   351 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by (simp add: less_eq_nat.simps)
   352 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   353 
   354 definition less_nat where
   355   less_eq_Suc_le [code func del]: "n < m \<longleftrightarrow> Suc n \<le> m"
   356 
   357 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   358   by (simp add: less_eq_nat.simps(2))
   359 
   360 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   361   unfolding less_eq_Suc_le ..
   362 
   363 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   364   by (induct n) (simp_all add: less_eq_nat.simps(2))
   365 
   366 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   367   by (simp add: less_eq_Suc_le)
   368 
   369 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   370   by simp
   371 
   372 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   373   by (simp add: less_eq_Suc_le)
   374 
   375 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   376   by (simp add: less_eq_Suc_le)
   377 
   378 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   379   by (induct m arbitrary: n)
   380     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   381 
   382 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   383   by (cases n) (auto intro: le_SucI)
   384 
   385 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   386   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   387 
   388 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   389   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   390 
   391 instance
   392 proof
   393   fix n m :: nat
   394   have less_imp_le: "n < m \<Longrightarrow> n \<le> m"
   395     unfolding less_eq_Suc_le by (erule Suc_leD)
   396   have irrefl: "\<not> m < m" by (induct m) auto
   397   have strict: "n \<le> m \<Longrightarrow> n \<noteq> m \<Longrightarrow> n < m"
   398   proof (induct n arbitrary: m)
   399     case 0 then show ?case
   400       by (cases m) (simp_all add: less_eq_Suc_le)
   401   next
   402     case (Suc n) then show ?case
   403       by (cases m) (simp_all add: less_eq_Suc_le)
   404   qed
   405   show "n < m \<longleftrightarrow> n \<le> m \<and> n \<noteq> m"
   406     by (auto simp add: irrefl intro: less_imp_le strict)
   407 next
   408   fix n :: nat show "n \<le> n" by (induct n) simp_all
   409 next
   410   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   411   then show "n = m"
   412     by (induct n arbitrary: m)
   413       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   414 next
   415   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   416   then show "n \<le> q"
   417   proof (induct n arbitrary: m q)
   418     case 0 show ?case by simp
   419   next
   420     case (Suc n) then show ?case
   421       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   422         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   423         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   424   qed
   425 next
   426   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   427     by (induct n arbitrary: m)
   428       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   429 qed
   430 
   431 end
   432 
   433 subsubsection {* Introduction properties *}
   434 
   435 lemma lessI [iff]: "n < Suc n"
   436   by (simp add: less_Suc_eq_le)
   437 
   438 lemma zero_less_Suc [iff]: "0 < Suc n"
   439   by (simp add: less_Suc_eq_le)
   440 
   441 
   442 subsubsection {* Elimination properties *}
   443 
   444 lemma less_not_refl: "~ n < (n::nat)"
   445   by (rule order_less_irrefl)
   446 
   447 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   448   by (rule not_sym) (rule less_imp_neq) 
   449 
   450 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   451   by (rule less_imp_neq)
   452 
   453 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   454   by (rule notE, rule less_not_refl)
   455 
   456 lemma less_zeroE: "(n::nat) < 0 ==> R"
   457   by (rule notE) (rule not_less0)
   458 
   459 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   460   unfolding less_Suc_eq_le le_less ..
   461 
   462 lemma less_one [iff, noatp]: "(n < (1::nat)) = (n = 0)"
   463   by (simp add: less_Suc_eq)
   464 
   465 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   466   by (simp add: less_Suc_eq)
   467 
   468 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   469   by simp
   470 
   471 text {* "Less than" is antisymmetric, sort of *}
   472 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   473   unfolding not_less less_Suc_eq_le by (rule antisym)
   474 
   475 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   476   by (rule linorder_neq_iff)
   477 
   478 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   479   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   480   shows "P n m"
   481   apply (rule less_linear [THEN disjE])
   482   apply (erule_tac [2] disjE)
   483   apply (erule lessCase)
   484   apply (erule sym [THEN eqCase])
   485   apply (erule major)
   486   done
   487 
   488 
   489 subsubsection {* Inductive (?) properties *}
   490 
   491 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   492   unfolding less_eq_Suc_le [of m] le_less by simp 
   493 
   494 lemma lessE:
   495   assumes major: "i < k"
   496   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   497   shows P
   498 proof -
   499   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   500     unfolding less_eq_Suc_le by (induct k) simp_all
   501   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   502     by (clarsimp simp add: less_le)
   503   with p1 p2 show P by auto
   504 qed
   505 
   506 lemma less_SucE: assumes major: "m < Suc n"
   507   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   508   apply (rule major [THEN lessE])
   509   apply (rule eq, blast)
   510   apply (rule less, blast)
   511   done
   512 
   513 lemma Suc_lessE: assumes major: "Suc i < k"
   514   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   515   apply (rule major [THEN lessE])
   516   apply (erule lessI [THEN minor])
   517   apply (erule Suc_lessD [THEN minor], assumption)
   518   done
   519 
   520 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   521   by simp
   522 
   523 lemma less_trans_Suc:
   524   assumes le: "i < j" shows "j < k ==> Suc i < k"
   525   apply (induct k, simp_all)
   526   apply (insert le)
   527   apply (simp add: less_Suc_eq)
   528   apply (blast dest: Suc_lessD)
   529   done
   530 
   531 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   532 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   533   unfolding not_less less_Suc_eq_le ..
   534 
   535 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   536   unfolding not_le Suc_le_eq ..
   537 
   538 text {* Properties of "less than or equal" *}
   539 
   540 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   541   unfolding less_Suc_eq_le .
   542 
   543 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   544   unfolding not_le less_Suc_eq_le ..
   545 
   546 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   547   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   548 
   549 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   550   by (drule le_Suc_eq [THEN iffD1], iprover+)
   551 
   552 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   553   unfolding Suc_le_eq .
   554 
   555 text {* Stronger version of @{text Suc_leD} *}
   556 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   557   unfolding Suc_le_eq .
   558 
   559 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   560   unfolding less_eq_Suc_le by (rule Suc_leD)
   561 
   562 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   563 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   564 
   565 
   566 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   567 
   568 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   569   unfolding le_less .
   570 
   571 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   572   by (rule le_less)
   573 
   574 text {* Useful with @{text blast}. *}
   575 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   576   by auto
   577 
   578 lemma le_refl: "n \<le> (n::nat)"
   579   by simp
   580 
   581 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   582   by (rule order_trans)
   583 
   584 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   585   by (rule antisym)
   586 
   587 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   588   by (rule less_le)
   589 
   590 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   591   unfolding less_le ..
   592 
   593 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   594   by (rule linear)
   595 
   596 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   597 
   598 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   599   unfolding less_Suc_eq_le by auto
   600 
   601 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   602   unfolding not_less by (rule le_less_Suc_eq)
   603 
   604 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   605 
   606 text {* These two rules ease the use of primitive recursion.
   607 NOTE USE OF @{text "=="} *}
   608 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   609 by simp
   610 
   611 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   612 by simp
   613 
   614 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   615 by (cases n) simp_all
   616 
   617 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   618 by (cases n) simp_all
   619 
   620 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   621 by (cases n) simp_all
   622 
   623 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   624 by (cases n) simp_all
   625 
   626 text {* This theorem is useful with @{text blast} *}
   627 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   628 by (rule neq0_conv[THEN iffD1], iprover)
   629 
   630 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   631 by (fast intro: not0_implies_Suc)
   632 
   633 lemma not_gr0 [iff,noatp]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   634 using neq0_conv by blast
   635 
   636 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   637 by (induct m') simp_all
   638 
   639 text {* Useful in certain inductive arguments *}
   640 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   641 by (cases m) simp_all
   642 
   643 
   644 subsubsection {* @{term min} and @{term max} *}
   645 
   646 lemma mono_Suc: "mono Suc"
   647 by (rule monoI) simp
   648 
   649 lemma min_0L [simp]: "min 0 n = (0::nat)"
   650 by (rule min_leastL) simp
   651 
   652 lemma min_0R [simp]: "min n 0 = (0::nat)"
   653 by (rule min_leastR) simp
   654 
   655 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   656 by (simp add: mono_Suc min_of_mono)
   657 
   658 lemma min_Suc1:
   659    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   660 by (simp split: nat.split)
   661 
   662 lemma min_Suc2:
   663    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   664 by (simp split: nat.split)
   665 
   666 lemma max_0L [simp]: "max 0 n = (n::nat)"
   667 by (rule max_leastL) simp
   668 
   669 lemma max_0R [simp]: "max n 0 = (n::nat)"
   670 by (rule max_leastR) simp
   671 
   672 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   673 by (simp add: mono_Suc max_of_mono)
   674 
   675 lemma max_Suc1:
   676    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   677 by (simp split: nat.split)
   678 
   679 lemma max_Suc2:
   680    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   681 by (simp split: nat.split)
   682 
   683 
   684 subsubsection {* Monotonicity of Addition *}
   685 
   686 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   687 by (simp add: diff_Suc split: nat.split)
   688 
   689 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   690 by (induct k) simp_all
   691 
   692 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   693 by (induct k) simp_all
   694 
   695 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   696 by(auto dest:gr0_implies_Suc)
   697 
   698 text {* strict, in 1st argument *}
   699 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   700 by (induct k) simp_all
   701 
   702 text {* strict, in both arguments *}
   703 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   704   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   705   apply (induct j, simp_all)
   706   done
   707 
   708 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   709 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   710   apply (induct n)
   711   apply (simp_all add: order_le_less)
   712   apply (blast elim!: less_SucE
   713                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   714   done
   715 
   716 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   717 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   718 apply(auto simp: gr0_conv_Suc)
   719 apply (induct_tac m)
   720 apply (simp_all add: add_less_mono)
   721 done
   722 
   723 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   724 instance nat :: ordered_semidom
   725 proof
   726   fix i j k :: nat
   727   show "0 < (1::nat)" by simp
   728   show "i \<le> j ==> k + i \<le> k + j" by simp
   729   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   730 qed
   731 
   732 lemma nat_mult_1: "(1::nat) * n = n"
   733 by simp
   734 
   735 lemma nat_mult_1_right: "n * (1::nat) = n"
   736 by simp
   737 
   738 
   739 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   740 
   741 text {* Complete induction, aka course-of-values induction *}
   742 
   743 lemma less_induct [case_names less]:
   744   fixes P :: "nat \<Rightarrow> bool"
   745   assumes step: "\<And>x. (\<And>y. y < x \<Longrightarrow> P y) \<Longrightarrow> P x"
   746   shows "P a"
   747 proof - 
   748   have "\<And>z. z\<le>a \<Longrightarrow> P z"
   749   proof (induct a)
   750     case (0 z)
   751     have "P 0" by (rule step) auto
   752     thus ?case using 0 by auto
   753   next
   754     case (Suc x z)
   755     then have "z \<le> x \<or> z = Suc x" by (simp add: le_Suc_eq)
   756     thus ?case
   757     proof
   758       assume "z \<le> x" thus "P z" by (rule Suc(1))
   759     next
   760       assume z: "z = Suc x"
   761       show "P z"
   762         by (rule step) (rule Suc(1), simp add: z le_simps)
   763     qed
   764   qed
   765   thus ?thesis by auto
   766 qed
   767 
   768 lemma nat_less_induct:
   769   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   770   using assms less_induct by blast
   771 
   772 lemma measure_induct_rule [case_names less]:
   773   fixes f :: "'a \<Rightarrow> nat"
   774   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   775   shows "P a"
   776 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   777 
   778 text {* old style induction rules: *}
   779 lemma measure_induct:
   780   fixes f :: "'a \<Rightarrow> nat"
   781   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   782   by (rule measure_induct_rule [of f P a]) iprover
   783 
   784 lemma full_nat_induct:
   785   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   786   shows "P n"
   787   by (rule less_induct) (auto intro: step simp:le_simps)
   788 
   789 text{*An induction rule for estabilishing binary relations*}
   790 lemma less_Suc_induct:
   791   assumes less:  "i < j"
   792      and  step:  "!!i. P i (Suc i)"
   793      and  trans: "!!i j k. P i j ==> P j k ==> P i k"
   794   shows "P i j"
   795 proof -
   796   from less obtain k where j: "j = Suc(i+k)" by (auto dest: less_imp_Suc_add)
   797   have "P i (Suc (i + k))"
   798   proof (induct k)
   799     case 0
   800     show ?case by (simp add: step)
   801   next
   802     case (Suc k)
   803     thus ?case by (auto intro: assms)
   804   qed
   805   thus "P i j" by (simp add: j)
   806 qed
   807 
   808 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   809   apply (rule nat_less_induct)
   810   apply (case_tac n)
   811   apply (case_tac [2] nat)
   812   apply (blast intro: less_trans)+
   813   done
   814 
   815 text {* The method of infinite descent, frequently used in number theory.
   816 Provided by Roelof Oosterhuis.
   817 $P(n)$ is true for all $n\in\mathbb{N}$ if
   818 \begin{itemize}
   819   \item case ``0'': given $n=0$ prove $P(n)$,
   820   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   821         a smaller integer $m$ such that $\neg P(m)$.
   822 \end{itemize} *}
   823 
   824 text{* A compact version without explicit base case: *}
   825 lemma infinite_descent:
   826   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   827 by (induct n rule: less_induct, auto)
   828 
   829 lemma infinite_descent0[case_names 0 smaller]: 
   830   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   831 by (rule infinite_descent) (case_tac "n>0", auto)
   832 
   833 text {*
   834 Infinite descent using a mapping to $\mathbb{N}$:
   835 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   836 \begin{itemize}
   837 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   838 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   839 \end{itemize}
   840 NB: the proof also shows how to use the previous lemma. *}
   841 
   842 corollary infinite_descent0_measure [case_names 0 smaller]:
   843   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   844     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   845   shows "P x"
   846 proof -
   847   obtain n where "n = V x" by auto
   848   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   849   proof (induct n rule: infinite_descent0)
   850     case 0 -- "i.e. $V(x) = 0$"
   851     with A0 show "P x" by auto
   852   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   853     case (smaller n)
   854     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   855     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   856     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   857     then show ?case by auto
   858   qed
   859   ultimately show "P x" by auto
   860 qed
   861 
   862 text{* Again, without explicit base case: *}
   863 lemma infinite_descent_measure:
   864 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   865 proof -
   866   from assms obtain n where "n = V x" by auto
   867   moreover have "!!x. V x = n \<Longrightarrow> P x"
   868   proof (induct n rule: infinite_descent, auto)
   869     fix x assume "\<not> P x"
   870     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
   871   qed
   872   ultimately show "P x" by auto
   873 qed
   874 
   875 text {* A [clumsy] way of lifting @{text "<"}
   876   monotonicity to @{text "\<le>"} monotonicity *}
   877 lemma less_mono_imp_le_mono:
   878   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
   879 by (simp add: order_le_less) (blast)
   880 
   881 
   882 text {* non-strict, in 1st argument *}
   883 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   884 by (rule add_right_mono)
   885 
   886 text {* non-strict, in both arguments *}
   887 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   888 by (rule add_mono)
   889 
   890 lemma le_add2: "n \<le> ((m + n)::nat)"
   891 by (insert add_right_mono [of 0 m n], simp)
   892 
   893 lemma le_add1: "n \<le> ((n + m)::nat)"
   894 by (simp add: add_commute, rule le_add2)
   895 
   896 lemma less_add_Suc1: "i < Suc (i + m)"
   897 by (rule le_less_trans, rule le_add1, rule lessI)
   898 
   899 lemma less_add_Suc2: "i < Suc (m + i)"
   900 by (rule le_less_trans, rule le_add2, rule lessI)
   901 
   902 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   903 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   904 
   905 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   906 by (rule le_trans, assumption, rule le_add1)
   907 
   908 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   909 by (rule le_trans, assumption, rule le_add2)
   910 
   911 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   912 by (rule less_le_trans, assumption, rule le_add1)
   913 
   914 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   915 by (rule less_le_trans, assumption, rule le_add2)
   916 
   917 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   918 apply (rule le_less_trans [of _ "i+j"])
   919 apply (simp_all add: le_add1)
   920 done
   921 
   922 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   923 apply (rule notI)
   924 apply (drule add_lessD1)
   925 apply (erule less_irrefl [THEN notE])
   926 done
   927 
   928 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   929 by (simp add: add_commute)
   930 
   931 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   932 apply (rule order_trans [of _ "m+k"])
   933 apply (simp_all add: le_add1)
   934 done
   935 
   936 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   937 apply (simp add: add_commute)
   938 apply (erule add_leD1)
   939 done
   940 
   941 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   942 by (blast dest: add_leD1 add_leD2)
   943 
   944 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   945 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   946 by (force simp del: add_Suc_right
   947     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   948 
   949 
   950 subsubsection {* More results about difference *}
   951 
   952 text {* Addition is the inverse of subtraction:
   953   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   954 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   955 by (induct m n rule: diff_induct) simp_all
   956 
   957 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   958 by (simp add: add_diff_inverse linorder_not_less)
   959 
   960 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   961 by (simp add: add_commute)
   962 
   963 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   964 by (induct m n rule: diff_induct) simp_all
   965 
   966 lemma diff_less_Suc: "m - n < Suc m"
   967 apply (induct m n rule: diff_induct)
   968 apply (erule_tac [3] less_SucE)
   969 apply (simp_all add: less_Suc_eq)
   970 done
   971 
   972 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   973 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   974 
   975 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
   976   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
   977 
   978 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   979 by (rule le_less_trans, rule diff_le_self)
   980 
   981 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   982 by (cases n) (auto simp add: le_simps)
   983 
   984 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   985 by (induct j k rule: diff_induct) simp_all
   986 
   987 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   988 by (simp add: add_commute diff_add_assoc)
   989 
   990 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   991 by (auto simp add: diff_add_inverse2)
   992 
   993 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   994 by (induct m n rule: diff_induct) simp_all
   995 
   996 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   997 by (rule iffD2, rule diff_is_0_eq)
   998 
   999 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1000 by (induct m n rule: diff_induct) simp_all
  1001 
  1002 lemma less_imp_add_positive:
  1003   assumes "i < j"
  1004   shows "\<exists>k::nat. 0 < k & i + k = j"
  1005 proof
  1006   from assms show "0 < j - i & i + (j - i) = j"
  1007     by (simp add: order_less_imp_le)
  1008 qed
  1009 
  1010 text {* a nice rewrite for bounded subtraction *}
  1011 lemma nat_minus_add_max:
  1012   fixes n m :: nat
  1013   shows "n - m + m = max n m"
  1014     by (simp add: max_def not_le order_less_imp_le)
  1015 
  1016 lemma nat_diff_split:
  1017   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1018     -- {* elimination of @{text -} on @{text nat} *}
  1019 by (cases "a < b")
  1020   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1021     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1022 
  1023 lemma nat_diff_split_asm:
  1024   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1025     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1026 by (auto split: nat_diff_split)
  1027 
  1028 
  1029 subsubsection {* Monotonicity of Multiplication *}
  1030 
  1031 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1032 by (simp add: mult_right_mono)
  1033 
  1034 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1035 by (simp add: mult_left_mono)
  1036 
  1037 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1038 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1039 by (simp add: mult_mono)
  1040 
  1041 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1042 by (simp add: mult_strict_right_mono)
  1043 
  1044 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1045       there are no negative numbers.*}
  1046 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1047   apply (induct m)
  1048    apply simp
  1049   apply (case_tac n)
  1050    apply simp_all
  1051   done
  1052 
  1053 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
  1054   apply (induct m)
  1055    apply simp
  1056   apply (case_tac n)
  1057    apply simp_all
  1058   done
  1059 
  1060 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1061   apply (safe intro!: mult_less_mono1)
  1062   apply (case_tac k, auto)
  1063   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1064   apply (blast intro: mult_le_mono1)
  1065   done
  1066 
  1067 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1068 by (simp add: mult_commute [of k])
  1069 
  1070 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1071 by (simp add: linorder_not_less [symmetric], auto)
  1072 
  1073 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1074 by (simp add: linorder_not_less [symmetric], auto)
  1075 
  1076 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1077 by (subst mult_less_cancel1) simp
  1078 
  1079 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1080 by (subst mult_le_cancel1) simp
  1081 
  1082 lemma le_square: "m \<le> m * (m::nat)"
  1083   by (cases m) (auto intro: le_add1)
  1084 
  1085 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1086   by (cases m) (auto intro: le_add1)
  1087 
  1088 text {* Lemma for @{text gcd} *}
  1089 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1090   apply (drule sym)
  1091   apply (rule disjCI)
  1092   apply (rule nat_less_cases, erule_tac [2] _)
  1093    apply (drule_tac [2] mult_less_mono2)
  1094     apply (auto)
  1095   done
  1096 
  1097 text {* the lattice order on @{typ nat} *}
  1098 
  1099 instantiation nat :: distrib_lattice
  1100 begin
  1101 
  1102 definition
  1103   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1104 
  1105 definition
  1106   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1107 
  1108 instance by intro_classes
  1109   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1110     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1111 
  1112 end
  1113 
  1114 
  1115 subsection {* Embedding of the Naturals into any
  1116   @{text semiring_1}: @{term of_nat} *}
  1117 
  1118 context semiring_1
  1119 begin
  1120 
  1121 primrec
  1122   of_nat :: "nat \<Rightarrow> 'a"
  1123 where
  1124   of_nat_0:     "of_nat 0 = 0"
  1125   | of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1126 
  1127 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1128   by simp
  1129 
  1130 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1131   by (induct m) (simp_all add: add_ac)
  1132 
  1133 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1134   by (induct m) (simp_all add: add_ac left_distrib)
  1135 
  1136 definition
  1137   of_nat_aux :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1138 where
  1139   [code func del]: "of_nat_aux n i = of_nat n + i"
  1140 
  1141 lemma of_nat_aux_code [code]:
  1142   "of_nat_aux 0 i = i"
  1143   "of_nat_aux (Suc n) i = of_nat_aux n (i + 1)" -- {* tail recursive *}
  1144   by (simp_all add: of_nat_aux_def add_ac)
  1145 
  1146 lemma of_nat_code [code]:
  1147   "of_nat n = of_nat_aux n 0"
  1148   by (simp add: of_nat_aux_def)
  1149 
  1150 end
  1151 
  1152 text{*Class for unital semirings with characteristic zero.
  1153  Includes non-ordered rings like the complex numbers.*}
  1154 
  1155 class semiring_char_0 = semiring_1 +
  1156   assumes of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1157 begin
  1158 
  1159 text{*Special cases where either operand is zero*}
  1160 
  1161 lemma of_nat_0_eq_iff [simp, noatp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1162   by (rule of_nat_eq_iff [of 0, simplified])
  1163 
  1164 lemma of_nat_eq_0_iff [simp, noatp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1165   by (rule of_nat_eq_iff [of _ 0, simplified])
  1166 
  1167 lemma inj_of_nat: "inj of_nat"
  1168   by (simp add: inj_on_def)
  1169 
  1170 end
  1171 
  1172 context ordered_semidom
  1173 begin
  1174 
  1175 lemma zero_le_imp_of_nat: "0 \<le> of_nat m"
  1176   apply (induct m, simp_all)
  1177   apply (erule order_trans)
  1178   apply (rule ord_le_eq_trans [OF _ add_commute])
  1179   apply (rule less_add_one [THEN less_imp_le])
  1180   done
  1181 
  1182 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1183   apply (induct m n rule: diff_induct, simp_all)
  1184   apply (insert add_less_le_mono [OF zero_less_one zero_le_imp_of_nat], force)
  1185   done
  1186 
  1187 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1188   apply (induct m n rule: diff_induct, simp_all)
  1189   apply (insert zero_le_imp_of_nat)
  1190   apply (force simp add: not_less [symmetric])
  1191   done
  1192 
  1193 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1194   by (blast intro: of_nat_less_imp_less less_imp_of_nat_less)
  1195 
  1196 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1197   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1198 
  1199 text{*Every @{text ordered_semidom} has characteristic zero.*}
  1200 
  1201 subclass semiring_char_0
  1202   by unfold_locales (simp add: eq_iff order_eq_iff)
  1203 
  1204 text{*Special cases where either operand is zero*}
  1205 
  1206 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1207   by (rule of_nat_le_iff [of 0, simplified])
  1208 
  1209 lemma of_nat_le_0_iff [simp, noatp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1210   by (rule of_nat_le_iff [of _ 0, simplified])
  1211 
  1212 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1213   by (rule of_nat_less_iff [of 0, simplified])
  1214 
  1215 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1216   by (rule of_nat_less_iff [of _ 0, simplified])
  1217 
  1218 end
  1219 
  1220 context ring_1
  1221 begin
  1222 
  1223 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1224   by (simp add: compare_rls of_nat_add [symmetric])
  1225 
  1226 end
  1227 
  1228 context ordered_idom
  1229 begin
  1230 
  1231 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1232   unfolding abs_if by auto
  1233 
  1234 end
  1235 
  1236 lemma of_nat_id [simp]: "of_nat n = n"
  1237   by (induct n) auto
  1238 
  1239 lemma of_nat_eq_id [simp]: "of_nat = id"
  1240   by (auto simp add: expand_fun_eq)
  1241 
  1242 
  1243 subsection {* The Set of Natural Numbers *}
  1244 
  1245 context semiring_1
  1246 begin
  1247 
  1248 definition
  1249   Nats  :: "'a set" where
  1250   [code func del]: "Nats = range of_nat"
  1251 
  1252 notation (xsymbols)
  1253   Nats  ("\<nat>")
  1254 
  1255 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1256   by (simp add: Nats_def)
  1257 
  1258 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1259 apply (simp add: Nats_def)
  1260 apply (rule range_eqI)
  1261 apply (rule of_nat_0 [symmetric])
  1262 done
  1263 
  1264 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1265 apply (simp add: Nats_def)
  1266 apply (rule range_eqI)
  1267 apply (rule of_nat_1 [symmetric])
  1268 done
  1269 
  1270 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1271 apply (auto simp add: Nats_def)
  1272 apply (rule range_eqI)
  1273 apply (rule of_nat_add [symmetric])
  1274 done
  1275 
  1276 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1277 apply (auto simp add: Nats_def)
  1278 apply (rule range_eqI)
  1279 apply (rule of_nat_mult [symmetric])
  1280 done
  1281 
  1282 end
  1283 
  1284 
  1285 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1286 
  1287 lemma subst_equals:
  1288   assumes 1: "t = s" and 2: "u = t"
  1289   shows "u = s"
  1290   using 2 1 by (rule trans)
  1291 
  1292 use "arith_data.ML"
  1293 declaration {* K ArithData.setup *}
  1294 
  1295 use "Tools/lin_arith.ML"
  1296 declaration {* K LinArith.setup *}
  1297 
  1298 lemmas [arith_split] = nat_diff_split split_min split_max
  1299 
  1300 
  1301 context order
  1302 begin
  1303 
  1304 lemma lift_Suc_mono_le:
  1305   assumes mono: "!!n. f n \<le> f(Suc n)" and "n\<le>n'"
  1306   shows "f n \<le> f n'"
  1307 proof (cases "n < n'")
  1308   case True
  1309   thus ?thesis
  1310     by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1311 qed (insert `n \<le> n'`, auto) -- {*trivial for @{prop "n = n'"} *}
  1312 
  1313 lemma lift_Suc_mono_less:
  1314   assumes mono: "!!n. f n < f(Suc n)" and "n < n'"
  1315   shows "f n < f n'"
  1316 using `n < n'`
  1317 by (induct n n' rule: less_Suc_induct[consumes 1]) (auto intro: mono)
  1318 
  1319 end
  1320 
  1321 
  1322 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1323 
  1324 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1325 by arith
  1326 
  1327 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1328 by arith
  1329 
  1330 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1331 by arith
  1332 
  1333 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1334 by arith
  1335 
  1336 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1337 by arith
  1338 
  1339 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1340 by arith
  1341 
  1342 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1343   second premise n\<le>m*)
  1344 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1345 by arith
  1346 
  1347 text {* Simplification of relational expressions involving subtraction *}
  1348 
  1349 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1350 by (simp split add: nat_diff_split)
  1351 
  1352 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1353 by (auto split add: nat_diff_split)
  1354 
  1355 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1356 by (auto split add: nat_diff_split)
  1357 
  1358 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1359 by (auto split add: nat_diff_split)
  1360 
  1361 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1362 
  1363 (* Monotonicity of subtraction in first argument *)
  1364 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1365 by (simp split add: nat_diff_split)
  1366 
  1367 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1368 by (simp split add: nat_diff_split)
  1369 
  1370 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1371 by (simp split add: nat_diff_split)
  1372 
  1373 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1374 by (simp split add: nat_diff_split)
  1375 
  1376 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1377 unfolding min_def by auto
  1378 
  1379 lemma inj_on_diff_nat: 
  1380   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1381   shows "inj_on (\<lambda>n. n - k) N"
  1382 proof (rule inj_onI)
  1383   fix x y
  1384   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1385   with k_le_n have "x - k + k = y - k + k" by auto
  1386   with a k_le_n show "x = y" by auto
  1387 qed
  1388 
  1389 text{*Rewriting to pull differences out*}
  1390 
  1391 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1392 by arith
  1393 
  1394 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1395 by arith
  1396 
  1397 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1398 by arith
  1399 
  1400 text{*Lemmas for ex/Factorization*}
  1401 
  1402 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1403 by (cases m) auto
  1404 
  1405 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1406 by (cases m) auto
  1407 
  1408 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1409 by (cases m) auto
  1410 
  1411 text {* Specialized induction principles that work "backwards": *}
  1412 
  1413 lemma inc_induct[consumes 1, case_names base step]:
  1414   assumes less: "i <= j"
  1415   assumes base: "P j"
  1416   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1417   shows "P i"
  1418   using less
  1419 proof (induct d=="j - i" arbitrary: i)
  1420   case (0 i)
  1421   hence "i = j" by simp
  1422   with base show ?case by simp
  1423 next
  1424   case (Suc d i)
  1425   hence "i < j" "P (Suc i)"
  1426     by simp_all
  1427   thus "P i" by (rule step)
  1428 qed
  1429 
  1430 lemma strict_inc_induct[consumes 1, case_names base step]:
  1431   assumes less: "i < j"
  1432   assumes base: "!!i. j = Suc i ==> P i"
  1433   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1434   shows "P i"
  1435   using less
  1436 proof (induct d=="j - i - 1" arbitrary: i)
  1437   case (0 i)
  1438   with `i < j` have "j = Suc i" by simp
  1439   with base show ?case by simp
  1440 next
  1441   case (Suc d i)
  1442   hence "i < j" "P (Suc i)"
  1443     by simp_all
  1444   thus "P i" by (rule step)
  1445 qed
  1446 
  1447 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1448   using inc_induct[of "k - i" k P, simplified] by blast
  1449 
  1450 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1451   using inc_induct[of 0 k P] by blast
  1452 
  1453 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
  1454   by auto
  1455 
  1456 (*The others are
  1457       i - j - k = i - (j + k),
  1458       k \<le> j ==> j - k + i = j + i - k,
  1459       k \<le> j ==> i + (j - k) = i + j - k *)
  1460 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1461 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1462 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1463 
  1464 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1465 Least_Suc}, since there appears to be no need.*}
  1466 
  1467 
  1468 subsection {* size of a datatype value *}
  1469 
  1470 class size = type +
  1471   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1472 
  1473 end