src/ZF/arith_data.ML
author wenzelm
Sat Mar 11 21:23:10 2006 +0100 (2006-03-11)
changeset 19250 932a50e2332f
parent 18678 dd0c569fa43d
child 20044 92cc2f4c7335
permissions -rw-r--r--
got rid of type Sign.sg;
     1 (*  Title:      ZF/arith_data.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   2000  University of Cambridge
     5 
     6 Arithmetic simplification: cancellation of common terms
     7 *)
     8 
     9 signature ARITH_DATA =
    10 sig
    11   (*the main outcome*)
    12   val nat_cancel: simproc list
    13   (*tools for use in similar applications*)
    14   val gen_trans_tac: thm -> thm option -> tactic
    15   val prove_conv: string -> tactic list -> theory ->
    16                   thm list -> string list -> term * term -> thm option
    17   val simplify_meta_eq: thm list -> simpset -> thm -> thm
    18   (*debugging*)
    19   structure EqCancelNumeralsData   : CANCEL_NUMERALS_DATA
    20   structure LessCancelNumeralsData : CANCEL_NUMERALS_DATA
    21   structure DiffCancelNumeralsData : CANCEL_NUMERALS_DATA
    22 end;
    23 
    24 
    25 structure ArithData: ARITH_DATA =
    26 struct
    27 
    28 val iT = Ind_Syntax.iT;
    29 
    30 val zero = Const("0", iT);
    31 val succ = Const("succ", iT --> iT);
    32 fun mk_succ t = succ $ t;
    33 val one = mk_succ zero;
    34 
    35 val mk_plus = FOLogic.mk_binop "Arith.add";
    36 
    37 (*Thus mk_sum[t] yields t+#0; longer sums don't have a trailing zero*)
    38 fun mk_sum []        = zero
    39   | mk_sum [t,u]     = mk_plus (t, u)
    40   | mk_sum (t :: ts) = mk_plus (t, mk_sum ts);
    41 
    42 (*this version ALWAYS includes a trailing zero*)
    43 fun long_mk_sum []        = zero
    44   | long_mk_sum (t :: ts) = mk_plus (t, mk_sum ts);
    45 
    46 val dest_plus = FOLogic.dest_bin "Arith.add" iT;
    47 
    48 (* dest_sum *)
    49 
    50 fun dest_sum (Const("0",_)) = []
    51   | dest_sum (Const("succ",_) $ t) = one :: dest_sum t
    52   | dest_sum (Const("Arith.add",_) $ t $ u) = dest_sum t @ dest_sum u
    53   | dest_sum tm = [tm];
    54 
    55 (*Apply the given rewrite (if present) just once*)
    56 fun gen_trans_tac th2 NONE      = all_tac
    57   | gen_trans_tac th2 (SOME th) = ALLGOALS (rtac (th RS th2));
    58 
    59 (*Use <-> or = depending on the type of t*)
    60 fun mk_eq_iff(t,u) =
    61   if fastype_of t = iT then FOLogic.mk_eq(t,u)
    62                        else FOLogic.mk_iff(t,u);
    63 
    64 (*We remove equality assumptions because they confuse the simplifier and
    65   because only type-checking assumptions are necessary.*)
    66 fun is_eq_thm th =
    67     can FOLogic.dest_eq (FOLogic.dest_Trueprop (#prop (rep_thm th)));
    68 
    69 fun add_chyps chyps ct = Drule.list_implies (map cprop_of chyps, ct);
    70 
    71 fun prove_conv name tacs sg hyps xs (t,u) =
    72   if t aconv u then NONE
    73   else
    74   let val hyps' = List.filter (not o is_eq_thm) hyps
    75       val goal = Logic.list_implies (map (#prop o Thm.rep_thm) hyps',
    76         FOLogic.mk_Trueprop (mk_eq_iff (t, u)));
    77   in SOME (hyps' MRS Goal.prove sg xs [] goal (K (EVERY tacs)))
    78       handle ERROR msg =>
    79         (warning (msg ^ "\nCancellation failed: no typing information? (" ^ name ^ ")"); NONE)
    80   end;
    81 
    82 fun prep_simproc (name, pats, proc) =
    83   Simplifier.simproc (Theory.sign_of (the_context ())) name pats proc;
    84 
    85 
    86 (*** Use CancelNumerals simproc without binary numerals,
    87      just for cancellation ***)
    88 
    89 val mk_times = FOLogic.mk_binop "Arith.mult";
    90 
    91 fun mk_prod [] = one
    92   | mk_prod [t] = t
    93   | mk_prod (t :: ts) = if t = one then mk_prod ts
    94                         else mk_times (t, mk_prod ts);
    95 
    96 val dest_times = FOLogic.dest_bin "Arith.mult" iT;
    97 
    98 fun dest_prod t =
    99       let val (t,u) = dest_times t
   100       in  dest_prod t @ dest_prod u  end
   101       handle TERM _ => [t];
   102 
   103 (*Dummy version: the only arguments are 0 and 1*)
   104 fun mk_coeff (0: IntInf.int, t) = zero
   105   | mk_coeff (1, t) = t
   106   | mk_coeff _       = raise TERM("mk_coeff", []);
   107 
   108 (*Dummy version: the "coefficient" is always 1.
   109   In the result, the factors are sorted terms*)
   110 fun dest_coeff t = (1 : IntInf.int, mk_prod (sort Term.term_ord (dest_prod t)));
   111 
   112 (*Find first coefficient-term THAT MATCHES u*)
   113 fun find_first_coeff past u [] = raise TERM("find_first_coeff", [])
   114   | find_first_coeff past u (t::terms) =
   115         let val (n,u') = dest_coeff t
   116         in  if u aconv u' then (n, rev past @ terms)
   117                           else find_first_coeff (t::past) u terms
   118         end
   119         handle TERM _ => find_first_coeff (t::past) u terms;
   120 
   121 
   122 (*Simplify #1*n and n*#1 to n*)
   123 val add_0s = [add_0_natify, add_0_right_natify];
   124 val add_succs = [add_succ, add_succ_right];
   125 val mult_1s = [mult_1_natify, mult_1_right_natify];
   126 val tc_rules = [natify_in_nat, add_type, diff_type, mult_type];
   127 val natifys = [natify_0, natify_ident, add_natify1, add_natify2,
   128                diff_natify1, diff_natify2];
   129 
   130 (*Final simplification: cancel + and **)
   131 fun simplify_meta_eq rules =
   132   let val ss0 =
   133     FOL_ss addeqcongs [eq_cong2, iff_cong2]
   134       delsimps iff_simps (*these could erase the whole rule!*)
   135       addsimps rules
   136   in fn ss => mk_meta_eq o simplify (Simplifier.inherit_context ss ss0) end;
   137 
   138 val final_rules = add_0s @ mult_1s @ [mult_0, mult_0_right];
   139 
   140 structure CancelNumeralsCommon =
   141   struct
   142   val mk_sum            = (fn T:typ => mk_sum)
   143   val dest_sum          = dest_sum
   144   val mk_coeff          = mk_coeff
   145   val dest_coeff        = dest_coeff
   146   val find_first_coeff  = find_first_coeff []
   147 
   148   val norm_ss1 = ZF_ss addsimps add_0s @ add_succs @ mult_1s @ add_ac
   149   val norm_ss2 = ZF_ss addsimps add_0s @ mult_1s @ add_ac @ mult_ac @ tc_rules @ natifys
   150   fun norm_tac ss =
   151     ALLGOALS (asm_simp_tac (Simplifier.inherit_context ss norm_ss1))
   152     THEN ALLGOALS (asm_simp_tac (Simplifier.inherit_context ss norm_ss2))
   153   val numeral_simp_ss = ZF_ss addsimps add_0s @ tc_rules @ natifys
   154   fun numeral_simp_tac ss =
   155     ALLGOALS (asm_simp_tac (Simplifier.inherit_context ss numeral_simp_ss))
   156   val simplify_meta_eq  = simplify_meta_eq final_rules
   157   end;
   158 
   159 (** The functor argumnets are declared as separate structures
   160     so that they can be exported to ease debugging. **)
   161 
   162 structure EqCancelNumeralsData =
   163   struct
   164   open CancelNumeralsCommon
   165   val prove_conv = prove_conv "nateq_cancel_numerals"
   166   val mk_bal   = FOLogic.mk_eq
   167   val dest_bal = FOLogic.dest_eq
   168   val bal_add1 = eq_add_iff RS iff_trans
   169   val bal_add2 = eq_add_iff RS iff_trans
   170   fun trans_tac _ = gen_trans_tac iff_trans
   171   end;
   172 
   173 structure EqCancelNumerals = CancelNumeralsFun(EqCancelNumeralsData);
   174 
   175 structure LessCancelNumeralsData =
   176   struct
   177   open CancelNumeralsCommon
   178   val prove_conv = prove_conv "natless_cancel_numerals"
   179   val mk_bal   = FOLogic.mk_binrel "Ordinal.lt"
   180   val dest_bal = FOLogic.dest_bin "Ordinal.lt" iT
   181   val bal_add1 = less_add_iff RS iff_trans
   182   val bal_add2 = less_add_iff RS iff_trans
   183   fun trans_tac _ = gen_trans_tac iff_trans
   184   end;
   185 
   186 structure LessCancelNumerals = CancelNumeralsFun(LessCancelNumeralsData);
   187 
   188 structure DiffCancelNumeralsData =
   189   struct
   190   open CancelNumeralsCommon
   191   val prove_conv = prove_conv "natdiff_cancel_numerals"
   192   val mk_bal   = FOLogic.mk_binop "Arith.diff"
   193   val dest_bal = FOLogic.dest_bin "Arith.diff" iT
   194   val bal_add1 = diff_add_eq RS trans
   195   val bal_add2 = diff_add_eq RS trans
   196   fun trans_tac _ = gen_trans_tac trans
   197   end;
   198 
   199 structure DiffCancelNumerals = CancelNumeralsFun(DiffCancelNumeralsData);
   200 
   201 
   202 val nat_cancel =
   203   map prep_simproc
   204    [("nateq_cancel_numerals",
   205      ["l #+ m = n", "l = m #+ n",
   206       "l #* m = n", "l = m #* n",
   207       "succ(m) = n", "m = succ(n)"],
   208      EqCancelNumerals.proc),
   209     ("natless_cancel_numerals",
   210      ["l #+ m < n", "l < m #+ n",
   211       "l #* m < n", "l < m #* n",
   212       "succ(m) < n", "m < succ(n)"],
   213      LessCancelNumerals.proc),
   214     ("natdiff_cancel_numerals",
   215      ["(l #+ m) #- n", "l #- (m #+ n)",
   216       "(l #* m) #- n", "l #- (m #* n)",
   217       "succ(m) #- n", "m #- succ(n)"],
   218      DiffCancelNumerals.proc)];
   219 
   220 end;
   221 
   222 Addsimprocs ArithData.nat_cancel;
   223 
   224 
   225 (*examples:
   226 print_depth 22;
   227 set timing;
   228 set trace_simp;
   229 fun test s = (Goal s; by (Asm_simp_tac 1));
   230 
   231 test "x #+ y = x #+ z";
   232 test "y #+ x = x #+ z";
   233 test "x #+ y #+ z = x #+ z";
   234 test "y #+ (z #+ x) = z #+ x";
   235 test "x #+ y #+ z = (z #+ y) #+ (x #+ w)";
   236 test "x#*y #+ z = (z #+ y) #+ (y#*x #+ w)";
   237 
   238 test "x #+ succ(y) = x #+ z";
   239 test "x #+ succ(y) = succ(z #+ x)";
   240 test "succ(x) #+ succ(y) #+ z = succ(z #+ y) #+ succ(x #+ w)";
   241 
   242 test "(x #+ y) #- (x #+ z) = w";
   243 test "(y #+ x) #- (x #+ z) = dd";
   244 test "(x #+ y #+ z) #- (x #+ z) = dd";
   245 test "(y #+ (z #+ x)) #- (z #+ x) = dd";
   246 test "(x #+ y #+ z) #- ((z #+ y) #+ (x #+ w)) = dd";
   247 test "(x#*y #+ z) #- ((z #+ y) #+ (y#*x #+ w)) = dd";
   248 
   249 (*BAD occurrence of natify*)
   250 test "(x #+ succ(y)) #- (x #+ z) = dd";
   251 
   252 test "x #* y2 #+ y #* x2 = y #* x2 #+ x #* y2";
   253 
   254 test "(x #+ succ(y)) #- (succ(z #+ x)) = dd";
   255 test "(succ(x) #+ succ(y) #+ z) #- (succ(z #+ y) #+ succ(x #+ w)) = dd";
   256 
   257 (*use of typing information*)
   258 test "x : nat ==> x #+ y = x";
   259 test "x : nat --> x #+ y = x";
   260 test "x : nat ==> x #+ y < x";
   261 test "x : nat ==> x < y#+x";
   262 test "x : nat ==> x le succ(x)";
   263 
   264 (*fails: no typing information isn't visible*)
   265 test "x #+ y = x";
   266 
   267 test "x #+ y < x #+ z";
   268 test "y #+ x < x #+ z";
   269 test "x #+ y #+ z < x #+ z";
   270 test "y #+ z #+ x < x #+ z";
   271 test "y #+ (z #+ x) < z #+ x";
   272 test "x #+ y #+ z < (z #+ y) #+ (x #+ w)";
   273 test "x#*y #+ z < (z #+ y) #+ (y#*x #+ w)";
   274 
   275 test "x #+ succ(y) < x #+ z";
   276 test "x #+ succ(y) < succ(z #+ x)";
   277 test "succ(x) #+ succ(y) #+ z < succ(z #+ y) #+ succ(x #+ w)";
   278 
   279 test "x #+ succ(y) le succ(z #+ x)";
   280 *)