src/Pure/Isar/attrib.ML
author wenzelm
Sun Apr 17 21:17:45 2011 +0200 (2011-04-17)
changeset 42380 9371ea9f91fb
parent 42375 774df7c59508
child 42616 92715b528e78
permissions -rw-r--r--
markup attributes/methods via name space;
eliminated obsolete markup;
     1 (*  Title:      Pure/Isar/attrib.ML
     2     Author:     Markus Wenzel, TU Muenchen
     3 
     4 Symbolic representation of attributes -- with name and syntax.
     5 *)
     6 
     7 signature ATTRIB =
     8 sig
     9   type src = Args.src
    10   type binding = binding * src list
    11   val empty_binding: binding
    12   val print_attributes: theory -> unit
    13   val intern: theory -> xstring -> string
    14   val intern_src: theory -> src -> src
    15   val pretty_attribs: Proof.context -> src list -> Pretty.T list
    16   val defined: theory -> string -> bool
    17   val attribute: theory -> src -> attribute
    18   val attribute_i: theory -> src -> attribute
    19   val map_specs: ('a -> 'att) ->
    20     (('c * 'a list) * 'b) list -> (('c * 'att list) * 'b) list
    21   val map_facts: ('a -> 'att) ->
    22     (('c * 'a list) * ('d * 'a list) list) list ->
    23     (('c * 'att list) * ('d * 'att list) list) list
    24   val map_facts_refs: ('a -> 'att) -> ('b -> 'fact) ->
    25     (('c * 'a list) * ('b * 'a list) list) list ->
    26     (('c * 'att list) * ('fact * 'att list) list) list
    27   val eval_thms: Proof.context -> (Facts.ref * src list) list -> thm list
    28   val crude_closure: Proof.context -> src -> src
    29   val setup: Binding.binding -> attribute context_parser -> string -> theory -> theory
    30   val attribute_setup: bstring * Position.T -> Symbol_Pos.text * Position.T -> string ->
    31     theory -> theory
    32   val add_del: attribute -> attribute -> attribute context_parser
    33   val thm_sel: Facts.interval list parser
    34   val thm: thm context_parser
    35   val thms: thm list context_parser
    36   val multi_thm: thm list context_parser
    37   val print_configs: Proof.context -> unit
    38   val internal: (morphism -> attribute) -> src
    39   val config_bool: bstring -> (Context.generic -> bool) -> bool Config.T * (theory -> theory)
    40   val config_int: bstring -> (Context.generic -> int) -> int Config.T * (theory -> theory)
    41   val config_real: bstring -> (Context.generic -> real) -> real Config.T * (theory -> theory)
    42   val config_string: bstring -> (Context.generic -> string) -> string Config.T * (theory -> theory)
    43   val config_bool_global: bstring -> (Context.generic -> bool) -> bool Config.T * (theory -> theory)
    44   val config_int_global: bstring -> (Context.generic -> int) -> int Config.T * (theory -> theory)
    45   val config_real_global: bstring -> (Context.generic -> real) -> real Config.T * (theory -> theory)
    46   val config_string_global:
    47     bstring -> (Context.generic -> string) -> string Config.T * (theory -> theory)
    48 end;
    49 
    50 structure Attrib: ATTRIB =
    51 struct
    52 
    53 (* source and bindings *)
    54 
    55 type src = Args.src;
    56 
    57 type binding = binding * src list;
    58 val empty_binding: binding = (Binding.empty, []);
    59 
    60 
    61 
    62 (** named attributes **)
    63 
    64 (* theory data *)
    65 
    66 structure Attributes = Theory_Data
    67 (
    68   type T = ((src -> attribute) * string) Name_Space.table;
    69   val empty : T = Name_Space.empty_table "attribute";
    70   val extend = I;
    71   fun merge data : T = Name_Space.merge_tables data;
    72 );
    73 
    74 fun print_attributes thy =
    75   let
    76     val ctxt = Proof_Context.init_global thy;
    77     val attribs = Attributes.get thy;
    78     fun prt_attr (name, (_, comment)) = Pretty.block
    79       [Pretty.str (name ^ ":"), Pretty.brk 2, Pretty.str comment];
    80   in
    81     [Pretty.big_list "attributes:" (map prt_attr (Name_Space.extern_table ctxt attribs))]
    82     |> Pretty.chunks |> Pretty.writeln
    83   end;
    84 
    85 fun add_attribute name att comment thy = thy
    86   |> Attributes.map
    87     (Name_Space.define (Proof_Context.init_global thy) true (Sign.naming_of thy)
    88       (name, (att, comment)) #> snd);
    89 
    90 
    91 (* name space *)
    92 
    93 val intern = Name_Space.intern o #1 o Attributes.get;
    94 val intern_src = Args.map_name o intern;
    95 
    96 fun extern ctxt = Name_Space.extern ctxt (#1 (Attributes.get (Proof_Context.theory_of ctxt)));
    97 
    98 
    99 (* pretty printing *)
   100 
   101 fun pretty_attribs _ [] = []
   102   | pretty_attribs ctxt srcs =
   103       [Pretty.enum "," "[" "]" (map (Args.pretty_src ctxt o Args.map_name (extern ctxt)) srcs)];
   104 
   105 
   106 (* get attributes *)
   107 
   108 val defined = Symtab.defined o #2 o Attributes.get;
   109 
   110 fun attribute_i thy =
   111   let
   112     val (space, tab) = Attributes.get thy;
   113     fun attr src =
   114       let val ((name, _), pos) = Args.dest_src src in
   115         (case Symtab.lookup tab name of
   116           NONE => error ("Unknown attribute: " ^ quote name ^ Position.str_of pos)
   117         | SOME (att, _) => (Position.report pos (Name_Space.markup space name); att src))
   118       end;
   119   in attr end;
   120 
   121 fun attribute thy = attribute_i thy o intern_src thy;
   122 
   123 
   124 (* attributed declarations *)
   125 
   126 fun map_specs f = map (apfst (apsnd (map f)));
   127 
   128 fun map_facts f = map (apfst (apsnd (map f)) o apsnd (map (apsnd (map f))));
   129 fun map_facts_refs f g = map_facts f #> map (apsnd (map (apfst g)));
   130 
   131 
   132 (* fact expressions *)
   133 
   134 fun eval_thms ctxt srcs = ctxt
   135   |> Proof_Context.note_thmss ""
   136     (map_facts_refs (attribute (Proof_Context.theory_of ctxt)) (Proof_Context.get_fact ctxt)
   137       [((Binding.empty, []), srcs)])
   138   |> fst |> maps snd;
   139 
   140 
   141 (* crude_closure *)
   142 
   143 (*Produce closure without knowing facts in advance! The following
   144   works reasonably well for attribute parsers that do not peek at the
   145   thm structure.*)
   146 
   147 fun crude_closure ctxt src =
   148  (try (fn () => attribute_i (Proof_Context.theory_of ctxt) src
   149     (Context.Proof ctxt, Drule.asm_rl)) ();
   150   Args.closure src);
   151 
   152 
   153 (* attribute setup *)
   154 
   155 fun syntax scan = Args.syntax "attribute" scan;
   156 
   157 fun setup name scan =
   158   add_attribute name
   159     (fn src => fn (ctxt, th) => let val (a, ctxt') = syntax scan src ctxt in a (ctxt', th) end);
   160 
   161 fun attribute_setup name (txt, pos) cmt =
   162   Context.theory_map (ML_Context.expression pos
   163     "val (name, scan, comment): binding * attribute context_parser * string"
   164     "Context.map_theory (Attrib.setup name scan comment)"
   165     (ML_Lex.read Position.none ("(" ^ ML_Syntax.make_binding name ^ ", ") @
   166       ML_Lex.read pos txt @
   167       ML_Lex.read Position.none (", " ^ ML_Syntax.print_string cmt ^ ")")));
   168 
   169 
   170 (* add/del syntax *)
   171 
   172 fun add_del add del = Scan.lift (Args.add >> K add || Args.del >> K del || Scan.succeed add);
   173 
   174 
   175 
   176 (** parsing attributed theorems **)
   177 
   178 val thm_sel = Parse.$$$ "(" |-- Parse.list1
   179  (Parse.nat --| Parse.minus -- Parse.nat >> Facts.FromTo ||
   180   Parse.nat --| Parse.minus >> Facts.From ||
   181   Parse.nat >> Facts.Single) --| Parse.$$$ ")";
   182 
   183 local
   184 
   185 val fact_name = Args.internal_fact >> K "<fact>" || Args.name;
   186 
   187 fun gen_thm pick = Scan.depend (fn context =>
   188   let
   189     val thy = Context.theory_of context;
   190     val get = Context.cases (Global_Theory.get_fact context) Proof_Context.get_fact context;
   191     val get_fact = get o Facts.Fact;
   192     fun get_named pos name = get (Facts.Named ((name, pos), NONE));
   193   in
   194     Parse.$$$ "[" |-- Args.attribs (intern thy) --| Parse.$$$ "]" >> (fn srcs =>
   195       let
   196         val atts = map (attribute_i thy) srcs;
   197         val (context', th') = Library.apply atts (context, Drule.dummy_thm);
   198       in (context', pick "" [th']) end)
   199     ||
   200     (Scan.ahead Args.alt_name -- Args.named_fact get_fact
   201       >> (fn (s, fact) => ("", Facts.Fact s, fact)) ||
   202      Scan.ahead (Parse.position fact_name) :|-- (fn (name, pos) =>
   203       Args.named_fact (get_named pos) -- Scan.option thm_sel
   204         >> (fn (fact, sel) => (name, Facts.Named ((name, pos), sel), fact))))
   205     -- Args.opt_attribs (intern thy) >> (fn ((name, thmref, fact), srcs) =>
   206       let
   207         val ths = Facts.select thmref fact;
   208         val atts = map (attribute_i thy) srcs;
   209         val (context', ths') = Library.foldl_map (Library.apply atts) (context, ths);
   210       in (context', pick name ths') end)
   211   end);
   212 
   213 in
   214 
   215 val thm = gen_thm Facts.the_single;
   216 val multi_thm = gen_thm (K I);
   217 val thms = Scan.repeat multi_thm >> flat;
   218 
   219 end;
   220 
   221 
   222 
   223 (** basic attributes **)
   224 
   225 (* internal *)
   226 
   227 fun internal att = Args.src (("Pure.attribute", [Token.mk_attribute att]), Position.none);
   228 
   229 
   230 (* rule composition *)
   231 
   232 val COMP_att =
   233   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   234     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => Drule.compose_single (A, i, B)));
   235 
   236 val THEN_att =
   237   Scan.lift (Scan.optional (Args.bracks Parse.nat) 1) -- thm
   238     >> (fn (i, B) => Thm.rule_attribute (fn _ => fn A => A RSN (i, B)));
   239 
   240 val OF_att =
   241   thms >> (fn Bs => Thm.rule_attribute (fn _ => fn A => Bs MRS A));
   242 
   243 
   244 (* rename_abs *)
   245 
   246 fun rename_abs x = (Scan.repeat (Args.maybe Args.name) >> (apsnd o Drule.rename_bvars')) x;
   247 
   248 
   249 (* unfold / fold definitions *)
   250 
   251 fun unfolded_syntax rule =
   252   thms >> (fn ths => Thm.rule_attribute (fn context => rule (Context.proof_of context) ths));
   253 
   254 val unfolded = unfolded_syntax Local_Defs.unfold;
   255 val folded = unfolded_syntax Local_Defs.fold;
   256 
   257 
   258 (* rule format *)
   259 
   260 val rule_format = Args.mode "no_asm"
   261   >> (fn true => Object_Logic.rule_format_no_asm | false => Object_Logic.rule_format);
   262 
   263 val elim_format = Thm.rule_attribute (K Tactic.make_elim);
   264 
   265 
   266 (* misc rules *)
   267 
   268 val no_vars = Thm.rule_attribute (fn context => fn th =>
   269   let
   270     val ctxt = Variable.set_body false (Context.proof_of context);
   271     val ((_, [th']), _) = Variable.import true [th] ctxt;
   272   in th' end);
   273 
   274 val eta_long =
   275   Thm.rule_attribute (K (Conv.fconv_rule Drule.eta_long_conversion));
   276 
   277 val rotated = Scan.optional Parse.int 1 >> (fn n => Thm.rule_attribute (K (rotate_prems n)));
   278 
   279 
   280 (* theory setup *)
   281 
   282 val _ = Context.>> (Context.map_theory
   283  (setup (Binding.name "attribute") (Scan.lift Args.internal_attribute >> Morphism.form)
   284     "internal attribute" #>
   285   setup (Binding.name "tagged") (Scan.lift (Args.name -- Args.name) >> Thm.tag) "tagged theorem" #>
   286   setup (Binding.name "untagged") (Scan.lift Args.name >> Thm.untag) "untagged theorem" #>
   287   setup (Binding.name "kind") (Scan.lift Args.name >> Thm.kind) "theorem kind" #>
   288   setup (Binding.name "COMP") COMP_att "direct composition with rules (no lifting)" #>
   289   setup (Binding.name "THEN") THEN_att "resolution with rule" #>
   290   setup (Binding.name "OF") OF_att "rule applied to facts" #>
   291   setup (Binding.name "rename_abs") (Scan.lift rename_abs)
   292     "rename bound variables in abstractions" #>
   293   setup (Binding.name "unfolded") unfolded "unfolded definitions" #>
   294   setup (Binding.name "folded") folded "folded definitions" #>
   295   setup (Binding.name "consumes") (Scan.lift (Scan.optional Parse.nat 1) >> Rule_Cases.consumes)
   296     "number of consumed facts" #>
   297   setup (Binding.name "constraints") (Scan.lift Parse.nat >> Rule_Cases.constraints)
   298     "number of equality constraints" #>
   299   setup (Binding.name "case_names") (Scan.lift (Scan.repeat1 Args.name) >> Rule_Cases.case_names)
   300     "named rule cases" #>
   301   setup (Binding.name "case_conclusion")
   302     (Scan.lift (Args.name -- Scan.repeat Args.name) >> Rule_Cases.case_conclusion)
   303     "named conclusion of rule cases" #>
   304   setup (Binding.name "params")
   305     (Scan.lift (Parse.and_list1 (Scan.repeat Args.name)) >> Rule_Cases.params)
   306     "named rule parameters" #>
   307   setup (Binding.name "standard") (Scan.succeed (Thm.rule_attribute (K Drule.export_without_context)))
   308     "result put into standard form (legacy)" #>
   309   setup (Binding.name "rule_format") rule_format "result put into canonical rule format" #>
   310   setup (Binding.name "elim_format") (Scan.succeed elim_format)
   311     "destruct rule turned into elimination rule format" #>
   312   setup (Binding.name "no_vars") (Scan.succeed no_vars) "frozen schematic vars" #>
   313   setup (Binding.name "eta_long") (Scan.succeed eta_long)
   314     "put theorem into eta long beta normal form" #>
   315   setup (Binding.name "atomize") (Scan.succeed Object_Logic.declare_atomize)
   316     "declaration of atomize rule" #>
   317   setup (Binding.name "rulify") (Scan.succeed Object_Logic.declare_rulify)
   318     "declaration of rulify rule" #>
   319   setup (Binding.name "rotated") (Scan.lift rotated) "rotated theorem premises" #>
   320   setup (Binding.name "defn") (add_del Local_Defs.defn_add Local_Defs.defn_del)
   321     "declaration of definitional transformations" #>
   322   setup (Binding.name "abs_def") (Scan.succeed (Thm.rule_attribute (K Drule.abs_def)))
   323     "abstract over free variables of a definition"));
   324 
   325 
   326 
   327 (** configuration options **)
   328 
   329 (* naming *)
   330 
   331 structure Configs = Theory_Data
   332 (
   333   type T = Config.raw Symtab.table;
   334   val empty = Symtab.empty;
   335   val extend = I;
   336   fun merge data = Symtab.merge (K true) data;
   337 );
   338 
   339 fun print_configs ctxt =
   340   let
   341     val thy = Proof_Context.theory_of ctxt;
   342     fun prt (name, config) =
   343       let val value = Config.get ctxt config in
   344         Pretty.block [Pretty.str (name ^ ": " ^ Config.print_type value ^ " ="), Pretty.brk 1,
   345           Pretty.str (Config.print_value value)]
   346       end;
   347     val configs = Name_Space.extern_table ctxt (#1 (Attributes.get thy), Configs.get thy);
   348   in Pretty.writeln (Pretty.big_list "configuration options" (map prt configs)) end;
   349 
   350 
   351 (* concrete syntax *)
   352 
   353 local
   354 
   355 val equals = Parse.$$$ "=";
   356 
   357 fun scan_value (Config.Bool _) =
   358       equals -- Args.$$$ "false" >> K (Config.Bool false) ||
   359       equals -- Args.$$$ "true" >> K (Config.Bool true) ||
   360       Scan.succeed (Config.Bool true)
   361   | scan_value (Config.Int _) = equals |-- Parse.int >> Config.Int
   362   | scan_value (Config.Real _) = equals |-- Parse.real >> Config.Real
   363   | scan_value (Config.String _) = equals |-- Args.name >> Config.String;
   364 
   365 fun scan_config thy config =
   366   let val config_type = Config.get_global thy config
   367   in scan_value config_type >> (K o Thm.declaration_attribute o K o Config.put_generic config) end;
   368 
   369 in
   370 
   371 fun register_config config thy =
   372   let
   373     val bname = Config.name_of config;
   374     val name = Sign.full_bname thy bname;
   375   in
   376     thy
   377     |> setup (Binding.name bname) (Scan.lift (scan_config thy config) >> Morphism.form)
   378       "configuration option"
   379     |> Configs.map (Symtab.update (name, config))
   380   end;
   381 
   382 fun declare_config make coerce global name default =
   383   let
   384     val config_value = Config.declare_generic {global = global} name (make o default);
   385     val config = coerce config_value;
   386   in (config, register_config config_value) end;
   387 
   388 val config_bool = declare_config Config.Bool Config.bool false;
   389 val config_int = declare_config Config.Int Config.int false;
   390 val config_real = declare_config Config.Real Config.real false;
   391 val config_string = declare_config Config.String Config.string false;
   392 
   393 val config_bool_global = declare_config Config.Bool Config.bool true;
   394 val config_int_global = declare_config Config.Int Config.int true;
   395 val config_real_global = declare_config Config.Real Config.real true;
   396 val config_string_global = declare_config Config.String Config.string true;
   397 
   398 end;
   399 
   400 
   401 (* theory setup *)
   402 
   403 val _ = Context.>> (Context.map_theory
   404  (register_config Ast.trace_raw #>
   405   register_config Ast.stat_raw #>
   406   register_config Syntax.positions_raw #>
   407   register_config Printer.show_brackets_raw #>
   408   register_config Printer.show_sorts_raw #>
   409   register_config Printer.show_types_raw #>
   410   register_config Printer.show_structs_raw #>
   411   register_config Printer.show_question_marks_raw #>
   412   register_config Syntax.ambiguity_level_raw #>
   413   register_config Syntax_Trans.eta_contract_raw #>
   414   register_config Name_Space.long_names_raw #>
   415   register_config Name_Space.short_names_raw #>
   416   register_config Name_Space.unique_names_raw #>
   417   register_config ML_Context.trace_raw #>
   418   register_config Proof_Context.show_abbrevs_raw #>
   419   register_config Goal_Display.goals_limit_raw #>
   420   register_config Goal_Display.show_main_goal_raw #>
   421   register_config Goal_Display.show_consts_raw #>
   422   register_config Display.show_hyps_raw #>
   423   register_config Display.show_tags_raw #>
   424   register_config Unify.trace_bound_raw #>
   425   register_config Unify.search_bound_raw #>
   426   register_config Unify.trace_simp_raw #>
   427   register_config Unify.trace_types_raw #>
   428   register_config Raw_Simplifier.simp_depth_limit_raw #>
   429   register_config Raw_Simplifier.simp_trace_depth_limit_raw #>
   430   register_config Raw_Simplifier.simp_debug_raw #>
   431   register_config Raw_Simplifier.simp_trace_raw));
   432 
   433 end;