src/Pure/pure_thy.ML
author wenzelm
Fri Mar 28 00:02:58 2008 +0100 (2008-03-28)
changeset 26457 9385d441cec6
parent 26436 dfd6947ab5c2
child 26463 9283b4185fdf
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/pure_thy.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Theorem storage.  Pure theory syntax and logical content.
     6 *)
     7 
     8 signature PURE_THY =
     9 sig
    10   val tag_rule: Markup.property -> thm -> thm
    11   val untag_rule: string -> thm -> thm
    12   val tag: Markup.property -> attribute
    13   val untag: string -> attribute
    14   val has_name_hint: thm -> bool
    15   val get_name_hint: thm -> string
    16   val put_name_hint: string -> thm -> thm
    17   val get_group: thm -> string option
    18   val put_group: string -> thm -> thm
    19   val group: string -> attribute
    20   val has_kind: thm -> bool
    21   val get_kind: thm -> string
    22   val kind_rule: string -> thm -> thm
    23   val kind: string -> attribute
    24   val kind_internal: attribute
    25   val has_internal: Markup.property list -> bool
    26   val is_internal: thm -> bool
    27   val get_fact: theory -> Facts.ref -> thm list
    28   val get_fact_silent: theory -> Facts.ref -> thm list
    29   val get_thms: theory -> xstring -> thm list
    30   val get_thm: theory -> xstring -> thm
    31   val theorems_of: theory -> thm list NameSpace.table
    32   val all_facts_of: theory -> Facts.T
    33   val thms_of: theory -> (string * thm) list
    34   val all_thms_of: theory -> (string * thm) list
    35   val hide_thms: bool -> string list -> theory -> theory
    36   val map_facts: ('a -> 'b) -> ('c * ('a list * 'd) list) list -> ('c * ('b list * 'd) list) list
    37   val burrow_fact: ('a list -> 'b list) -> ('a list * 'c) list -> ('b list * 'c) list
    38   val burrow_facts: ('a list -> 'b list) ->
    39     ('c * ('a list * 'd) list) list -> ('c * ('b list * 'd) list) list
    40   val name_multi: string -> 'a list -> (string * 'a) list
    41   val name_thm: bool -> bool -> string -> thm -> thm
    42   val name_thms: bool -> bool -> string -> thm list -> thm list
    43   val name_thmss: bool -> string -> (thm list * 'a) list -> (thm list * 'a) list
    44   val store_thm: (bstring * thm) * attribute list -> theory -> thm * theory
    45   val smart_store_thms: (bstring * thm list) -> thm list
    46   val smart_store_thms_open: (bstring * thm list) -> thm list
    47   val forall_elim_var: int -> thm -> thm
    48   val forall_elim_vars: int -> thm -> thm
    49   val add_thms_dynamic: bstring * (Context.generic -> thm list) -> theory -> theory
    50   val add_thms: ((bstring * thm) * attribute list) list -> theory -> thm list * theory
    51   val add_thmss: ((bstring * thm list) * attribute list) list -> theory -> thm list list * theory
    52   val note: string -> string * thm -> theory -> thm * theory
    53   val note_thmss: string -> ((bstring * attribute list) *
    54     (Facts.ref * attribute list) list) list -> theory -> (bstring * thm list) list * theory
    55   val note_thmss_i: string -> ((bstring * attribute list) *
    56     (thm list * attribute list) list) list -> theory -> (bstring * thm list) list * theory
    57   val note_thmss_grouped: string -> string -> ((bstring * attribute list) *
    58     (thm list * attribute list) list) list -> theory -> (bstring * thm list) list * theory
    59   val note_thmss_qualified: string -> string -> ((bstring * attribute list) *
    60     (thm list * attribute list) list) list -> theory -> (bstring * thm list) list * theory
    61   val add_axioms: ((bstring * string) * attribute list) list -> theory -> thm list * theory
    62   val add_axioms_i: ((bstring * term) * attribute list) list -> theory -> thm list * theory
    63   val add_axiomss: ((bstring * string list) * attribute list) list ->
    64     theory -> thm list list * theory
    65   val add_axiomss_i: ((bstring * term list) * attribute list) list ->
    66     theory -> thm list list * theory
    67   val add_defs: bool -> ((bstring * string) * attribute list) list ->
    68     theory -> thm list * theory
    69   val add_defs_i: bool -> ((bstring * term) * attribute list) list ->
    70     theory -> thm list * theory
    71   val add_defs_unchecked: bool -> ((bstring * string) * attribute list) list ->
    72     theory -> thm list * theory
    73   val add_defs_unchecked_i: bool -> ((bstring * term) * attribute list) list ->
    74     theory -> thm list * theory
    75 end;
    76 
    77 structure PureThy: PURE_THY =
    78 struct
    79 
    80 
    81 (*** theorem tags ***)
    82 
    83 (* add / delete tags *)
    84 
    85 fun tag_rule tg = Thm.map_tags (insert (op =) tg);
    86 fun untag_rule s = Thm.map_tags (filter_out (fn (s', _) => s = s'));
    87 
    88 fun tag tg x = Thm.rule_attribute (K (tag_rule tg)) x;
    89 fun untag s x = Thm.rule_attribute (K (untag_rule s)) x;
    90 
    91 
    92 (* unofficial theorem names *)
    93 
    94 fun the_name_hint thm = the (AList.lookup (op =) (Thm.get_tags thm) Markup.nameN);
    95 
    96 val has_name_hint = can the_name_hint;
    97 val get_name_hint = the_default "??.unknown" o try the_name_hint;
    98 
    99 fun put_name_hint name = untag_rule Markup.nameN #> tag_rule (Markup.nameN, name);
   100 
   101 
   102 (* theorem groups *)
   103 
   104 fun get_group thm = AList.lookup (op =) (Thm.get_tags thm) Markup.groupN;
   105 
   106 fun put_group name =
   107   if name = "" then I else Thm.map_tags (AList.update (op =) (Markup.groupN, name));
   108 
   109 fun group name = Thm.rule_attribute (K (put_group name));
   110 
   111 
   112 (* theorem kinds *)
   113 
   114 fun the_kind thm = the (AList.lookup (op =) (Thm.get_tags thm) Markup.kindN);
   115 
   116 val has_kind = can the_kind;
   117 val get_kind = the_default "" o try the_kind;
   118 
   119 fun kind_rule k = tag_rule (Markup.kindN, k) o untag_rule Markup.kindN;
   120 fun kind k x = if k = "" then x else Thm.rule_attribute (K (kind_rule k)) x;
   121 fun kind_internal x = kind Thm.internalK x;
   122 fun has_internal tags = exists (fn tg => tg = (Markup.kindN, Thm.internalK)) tags;
   123 val is_internal = has_internal o Thm.get_tags;
   124 
   125 
   126 
   127 (*** theorem database ***)
   128 
   129 (** dataype theorems **)
   130 
   131 datatype thms = Thms of
   132  {theorems: thm list NameSpace.table,   (* FIXME legacy *)
   133   all_facts: Facts.T};
   134 
   135 fun make_thms theorems all_facts = Thms {theorems = theorems, all_facts = all_facts};
   136 
   137 structure TheoremsData = TheoryDataFun
   138 (
   139   type T = thms ref;   (* FIXME legacy *)
   140   val empty = ref (make_thms NameSpace.empty_table Facts.empty);
   141   fun copy (ref x) = ref x;
   142   fun extend (ref (Thms {theorems = _, all_facts})) = ref (make_thms NameSpace.empty_table all_facts);
   143   fun merge _
   144      (ref (Thms {theorems = _, all_facts = all_facts1}),
   145       ref (Thms {theorems = _, all_facts = all_facts2})) =
   146     ref (make_thms NameSpace.empty_table (Facts.merge (all_facts1, all_facts2)));
   147 );
   148 
   149 val _ = Context.>> TheoremsData.init;
   150 
   151 val get_theorems_ref = TheoremsData.get;
   152 val get_theorems = (fn Thms args => args) o ! o get_theorems_ref;
   153 val theorems_of = #theorems o get_theorems;
   154 val all_facts_of = #all_facts o get_theorems;
   155 
   156 
   157 
   158 (** retrieve theorems **)
   159 
   160 local
   161 
   162 fun lookup_thms thy xname =
   163   let
   164     val (space, thms) = #theorems (get_theorems thy);
   165     val name = NameSpace.intern space xname;
   166   in Option.map (pair name) (Symtab.lookup thms name) end;
   167 
   168 fun lookup_fact thy xname =
   169   let
   170     val facts = all_facts_of thy;
   171     val name = NameSpace.intern (Facts.space_of facts) xname;
   172   in Option.map (pair name) (Facts.lookup (Context.Theory thy) facts name) end;
   173 
   174 fun show_result NONE = "none"
   175   | show_result (SOME (name, _)) = quote name;
   176 
   177 fun get silent theory thmref =
   178   let
   179     val name = Facts.name_of_ref thmref;
   180     val pos = Facts.pos_of_ref thmref;
   181     val new_res = lookup_fact theory name;
   182     val old_res = get_first (fn thy => lookup_thms thy name) (theory :: Theory.ancestors_of theory);
   183     val is_same =
   184       (case (new_res, old_res) of
   185         (NONE, NONE) => true
   186       | (SOME (_, ths1), SOME (_, ths2)) => Thm.eq_thms (ths1, ths2)
   187       | _ => false);
   188     val _ =
   189       if is_same orelse silent then ()
   190       else legacy_feature ("Fact lookup differs from old-style thm database:\n" ^
   191         show_result new_res ^ " vs " ^ show_result old_res ^ Position.str_of pos);
   192   in
   193     (case old_res of
   194       NONE => error ("Unknown theorem(s) " ^ quote name ^ Position.str_of pos)
   195     | SOME (_, ths) => Facts.select thmref (map (Thm.transfer theory) ths))
   196   end;
   197 
   198 in
   199 
   200 val get_fact_silent = get true;
   201 val get_fact = get false;
   202 
   203 fun get_thms thy = get_fact thy o Facts.named;
   204 fun get_thm thy name = Facts.the_single name (get_thms thy name);
   205 
   206 end;
   207 
   208 
   209 (* thms_of etc. *)
   210 
   211 fun thms_of thy =
   212   let val thms = #2 (theorems_of thy)
   213   in map (`(get_name_hint)) (maps snd (Symtab.dest thms)) end;
   214 
   215 fun all_thms_of thy = maps thms_of (thy :: Theory.ancestors_of thy);
   216 
   217 
   218 
   219 (** store theorems **)                    (*DESTRUCTIVE*)
   220 
   221 (* hiding -- affects current theory node only *)
   222 
   223 fun hide_thms fully names thy = CRITICAL (fn () =>
   224   let
   225     val r as ref (Thms {theorems = (space, thms), all_facts}) = get_theorems_ref thy;
   226     val space' = fold (NameSpace.hide fully) names space;
   227   in r := make_thms (space', thms) all_facts; thy end);
   228 
   229 
   230 (* fact specifications *)
   231 
   232 fun map_facts f = map (apsnd (map (apfst (map f))));
   233 fun burrow_fact f = split_list #>> burrow f #> op ~~;
   234 fun burrow_facts f = split_list ##> burrow (burrow_fact f) #> op ~~;
   235 
   236 
   237 (* naming *)
   238 
   239 fun name_multi name [x] = [(name, x)]
   240   | name_multi "" xs = map (pair "") xs
   241   | name_multi name xs = map_index (fn (i, x) => (name ^ "_" ^ string_of_int (i + 1), x)) xs;
   242 
   243 fun name_thm pre official name thm = thm
   244   |> (if Thm.get_name thm <> "" andalso pre orelse not official then I else Thm.put_name name)
   245   |> (if has_name_hint thm andalso pre orelse name = "" then I else put_name_hint name)
   246   |> Thm.map_tags (Position.default_properties (Position.thread_data ()));
   247 
   248 fun name_thms pre official name xs =
   249   map (uncurry (name_thm pre official)) (name_multi name xs);
   250 
   251 fun name_thmss official name fact =
   252   burrow_fact (name_thms true official name) fact;
   253 
   254 
   255 (* add_thms_dynamic *)
   256 
   257 fun add_thms_dynamic (bname, f) thy = CRITICAL (fn () =>
   258   let
   259     val name = Sign.full_name thy bname;
   260     val r as ref (Thms {theorems, all_facts}) = get_theorems_ref thy;
   261     val all_facts' = Facts.add_dynamic (Sign.naming_of thy) (name, f) all_facts;
   262     val _ = r := make_thms theorems all_facts';
   263   in thy end);
   264 
   265 
   266 (* enter_thms *)
   267 
   268 fun warn_overwrite name = warning ("Replaced old copy of theorems " ^ quote name);
   269 fun warn_same name = warning ("Theorem database already contains a copy of " ^ quote name);
   270 
   271 fun enter_thms _ _ app_att ("", thms) thy = app_att (thy, thms) |> swap
   272   | enter_thms pre_name post_name app_att (bname, thms) thy = CRITICAL (fn () =>
   273       let
   274         val name = Sign.full_name thy bname;
   275         val (thy', thms') = apsnd (post_name name) (app_att (thy, pre_name name thms));
   276         val r as ref (Thms {theorems = (space, theorems), all_facts}) = get_theorems_ref thy';
   277         val space' = Sign.declare_name thy' name space;
   278         val theorems' = Symtab.update (name, thms') theorems;
   279         val all_facts' = Facts.add_global (Sign.naming_of thy') (name, thms') all_facts;
   280       in
   281         (case Symtab.lookup theorems name of
   282           NONE => ()
   283         | SOME thms'' =>
   284             if Thm.eq_thms (thms', thms'') then warn_same name
   285             else warn_overwrite name);
   286         r := make_thms (space', theorems') all_facts';
   287         (thms', thy')
   288       end);
   289 
   290 
   291 (* add_thms(s) *)
   292 
   293 fun add_thms_atts pre_name ((bname, thms), atts) =
   294   enter_thms pre_name (name_thms false true)
   295     (foldl_map (Thm.theory_attributes atts)) (bname, thms);
   296 
   297 fun gen_add_thmss pre_name =
   298   fold_map (add_thms_atts pre_name);
   299 
   300 fun gen_add_thms pre_name args =
   301   apfst (map hd) o gen_add_thmss pre_name (map (apfst (apsnd single)) args);
   302 
   303 val add_thmss = gen_add_thmss (name_thms true true);
   304 val add_thms = gen_add_thms (name_thms true true);
   305 
   306 
   307 (* note_thmss(_i) *)
   308 
   309 local
   310 
   311 fun gen_note_thmss get tag = fold_map (fn ((bname, more_atts), ths_atts) => fn thy =>
   312   let
   313     fun app (x, (ths, atts)) = foldl_map (Thm.theory_attributes atts) (x, ths);
   314     val (thms, thy') = thy |> enter_thms
   315       (name_thmss true) (name_thms false true) (apsnd flat o foldl_map app)
   316       (bname, map (fn (ths, atts) => (get thy ths, surround tag (atts @ more_atts))) ths_atts);
   317   in ((bname, thms), thy') end);
   318 
   319 in
   320 
   321 fun note_thmss k = gen_note_thmss get_fact (kind k);
   322 fun note_thmss_i k = gen_note_thmss (K I) (kind k);
   323 fun note_thmss_grouped k g = gen_note_thmss (K I) (kind k #> group g);
   324 
   325 end;
   326 
   327 fun note kind (name, thm) =
   328   note_thmss_i kind [((name, []), [([thm], [])])]
   329   #>> (fn [(_, [thm])] => thm);
   330 
   331 fun note_thmss_qualified k path facts thy =
   332   thy
   333   |> Sign.add_path path
   334   |> Sign.no_base_names
   335   |> note_thmss_i k facts
   336   ||> Sign.restore_naming thy;
   337 
   338 
   339 (* store_thm *)
   340 
   341 fun store_thm ((bname, thm), atts) thy =
   342   let val ([th'], thy') = add_thms_atts (name_thms true true) ((bname, [thm]), atts) thy
   343   in (th', thy') end;
   344 
   345 
   346 (* smart_store_thms(_open) *)
   347 
   348 local
   349 
   350 fun smart_store _ (name, []) =
   351       error ("Cannot store empty list of theorems: " ^ quote name)
   352   | smart_store official (name, [thm]) =
   353       fst (enter_thms (name_thms true official) (name_thms false official) I (name, [thm])
   354         (Thm.theory_of_thm thm))
   355   | smart_store official (name, thms) =
   356       let val thy = Theory.merge_list (map Thm.theory_of_thm thms) in
   357         fst (enter_thms (name_thms true official) (name_thms false official) I (name, thms) thy)
   358       end;
   359 
   360 in
   361 
   362 val smart_store_thms = smart_store true;
   363 val smart_store_thms_open = smart_store false;
   364 
   365 end;
   366 
   367 
   368 (* forall_elim_var(s) -- belongs to drule.ML *)
   369 
   370 fun forall_elim_vars_aux strip_vars i th =
   371   let
   372     val {thy, tpairs, prop, ...} = Thm.rep_thm th;
   373     val add_used = Term.fold_aterms
   374       (fn Var ((x, j), _) => if i = j then insert (op =) x else I | _ => I);
   375     val used = fold (fn (t, u) => add_used t o add_used u) tpairs (add_used prop []);
   376     val vars = strip_vars prop;
   377     val cvars = (Name.variant_list used (map #1 vars), vars)
   378       |> ListPair.map (fn (x, (_, T)) => Thm.cterm_of thy (Var ((x, i), T)));
   379   in fold Thm.forall_elim cvars th end;
   380 
   381 val forall_elim_vars = forall_elim_vars_aux Term.strip_all_vars;
   382 
   383 fun forall_elim_var i th = forall_elim_vars_aux
   384   (fn Const ("all", _) $ Abs (a, T, _) => [(a, T)]
   385   | _ => raise THM ("forall_elim_vars", i, [th])) i th;
   386 
   387 
   388 (* store axioms as theorems *)
   389 
   390 local
   391   fun get_ax thy (name, _) = Thm.get_axiom_i thy (Sign.full_name thy name);
   392   fun get_axs thy named_axs = map (forall_elim_vars 0 o get_ax thy) named_axs;
   393   fun add_single add ((name, ax), atts) thy =
   394     let
   395       val named_ax = [(name, ax)];
   396       val thy' = add named_ax thy;
   397       val thm = hd (get_axs thy' named_ax);
   398     in apfst hd (gen_add_thms (K I) [((name, thm), atts)] thy') end;
   399   fun add_multi add ((name, axs), atts) thy =
   400     let
   401       val named_axs = name_multi name axs;
   402       val thy' = add named_axs thy;
   403       val thms = get_axs thy' named_axs;
   404     in apfst hd (gen_add_thmss (K I) [((name, thms), atts)] thy') end;
   405   fun add_singles add = fold_map (add_single add);
   406   fun add_multis add = fold_map (add_multi add);
   407 in
   408   val add_axioms           = add_singles Theory.add_axioms;
   409   val add_axioms_i         = add_singles Theory.add_axioms_i;
   410   val add_axiomss          = add_multis Theory.add_axioms;
   411   val add_axiomss_i        = add_multis Theory.add_axioms_i;
   412   val add_defs             = add_singles o Theory.add_defs false;
   413   val add_defs_i           = add_singles o Theory.add_defs_i false;
   414   val add_defs_unchecked   = add_singles o Theory.add_defs true;
   415   val add_defs_unchecked_i = add_singles o Theory.add_defs_i true;
   416 end;
   417 
   418 
   419 
   420 (*** Pure theory syntax and logical content ***)
   421 
   422 val typ = SimpleSyntax.read_typ;
   423 val term = SimpleSyntax.read_term;
   424 val prop = SimpleSyntax.read_prop;
   425 
   426 val _ = Context.>>
   427   (Sign.add_types
   428    [("fun", 2, NoSyn),
   429     ("prop", 0, NoSyn),
   430     ("itself", 1, NoSyn),
   431     ("dummy", 0, NoSyn)]
   432   #> Sign.add_nonterminals Syntax.basic_nonterms
   433   #> Sign.add_syntax_i
   434    [("_lambda",     typ "pttrns => 'a => logic",       Mixfix ("(3%_./ _)", [0, 3], 3)),
   435     ("_abs",        typ "'a",                          NoSyn),
   436     ("",            typ "'a => args",                  Delimfix "_"),
   437     ("_args",       typ "'a => args => args",          Delimfix "_,/ _"),
   438     ("",            typ "id => idt",                   Delimfix "_"),
   439     ("_idtdummy",   typ "idt",                         Delimfix "'_"),
   440     ("_idtyp",      typ "id => type => idt",           Mixfix ("_::_", [], 0)),
   441     ("_idtypdummy", typ "type => idt",                 Mixfix ("'_()::_", [], 0)),
   442     ("",            typ "idt => idt",                  Delimfix "'(_')"),
   443     ("",            typ "idt => idts",                 Delimfix "_"),
   444     ("_idts",       typ "idt => idts => idts",         Mixfix ("_/ _", [1, 0], 0)),
   445     ("",            typ "idt => pttrn",                Delimfix "_"),
   446     ("",            typ "pttrn => pttrns",             Delimfix "_"),
   447     ("_pttrns",     typ "pttrn => pttrns => pttrns",   Mixfix ("_/ _", [1, 0], 0)),
   448     ("",            typ "id => aprop",                 Delimfix "_"),
   449     ("",            typ "longid => aprop",             Delimfix "_"),
   450     ("",            typ "var => aprop",                Delimfix "_"),
   451     ("_DDDOT",      typ "aprop",                       Delimfix "..."),
   452     ("_aprop",      typ "aprop => prop",               Delimfix "PROP _"),
   453     ("_asm",        typ "prop => asms",                Delimfix "_"),
   454     ("_asms",       typ "prop => asms => asms",        Delimfix "_;/ _"),
   455     ("_bigimpl",    typ "asms => prop => prop",        Mixfix ("((3[| _ |])/ ==> _)", [0, 1], 1)),
   456     ("_ofclass",    typ "type => logic => prop",       Delimfix "(1OFCLASS/(1'(_,/ _')))"),
   457     ("_mk_ofclass", typ "dummy",                       NoSyn),
   458     ("_TYPE",       typ "type => logic",               Delimfix "(1TYPE/(1'(_')))"),
   459     ("",            typ "id => logic",                 Delimfix "_"),
   460     ("",            typ "longid => logic",             Delimfix "_"),
   461     ("",            typ "var => logic",                Delimfix "_"),
   462     ("_DDDOT",      typ "logic",                       Delimfix "..."),
   463     ("_constify",   typ "num => num_const",            Delimfix "_"),
   464     ("_indexnum",   typ "num_const => index",          Delimfix "\\<^sub>_"),
   465     ("_index",      typ "logic => index",              Delimfix "(00\\<^bsub>_\\<^esub>)"),
   466     ("_indexdefault", typ "index",                     Delimfix ""),
   467     ("_indexvar",   typ "index",                       Delimfix "'\\<index>"),
   468     ("_struct",     typ "index => logic",              Mixfix ("\\<struct>_", [1000], 1000)),
   469     ("==>",         typ "prop => prop => prop",        Delimfix "op ==>"),
   470     (Term.dummy_patternN, typ "aprop",                 Delimfix "'_"),
   471     ("_appl",       typ "('b => 'a) => args => logic", Mixfix ("(1_/(1'(_')))", [1000, 0], 1000)),
   472     ("_appl",       typ "('b => 'a) => args => aprop", Mixfix ("(1_/(1'(_')))", [1000, 0], 1000))]
   473   #> Sign.add_modesyntax_i (Symbol.xsymbolsN, true)
   474    [("fun",      typ "type => type => type",   Mixfix ("(_/ \\<Rightarrow> _)", [1, 0], 0)),
   475     ("_bracket", typ "types => type => type",  Mixfix ("([_]/ \\<Rightarrow> _)", [0, 0], 0)),
   476     ("_ofsort",  typ "tid => sort => type",    Mixfix ("_\\<Colon>_", [1000, 0], 1000)),
   477     ("_constrain", typ "'a => type => 'a",     Mixfix ("_\\<Colon>_", [4, 0], 3)),
   478     ("_idtyp",    typ "id => type => idt",     Mixfix ("_\\<Colon>_", [], 0)),
   479     ("_idtypdummy", typ "type => idt",         Mixfix ("'_()\\<Colon>_", [], 0)),
   480     ("_type_constraint_", typ "'a",            NoSyn),
   481     ("_lambda",  typ "pttrns => 'a => logic",  Mixfix ("(3\\<lambda>_./ _)", [0, 3], 3)),
   482     ("==",       typ "'a => 'a => prop",       InfixrName ("\\<equiv>", 2)),
   483     ("all_binder", typ "idts => prop => prop", Mixfix ("(3\\<And>_./ _)", [0, 0], 0)),
   484     ("==>",      typ "prop => prop => prop",   InfixrName ("\\<Longrightarrow>", 1)),
   485     ("_DDDOT",   typ "aprop",                  Delimfix "\\<dots>"),
   486     ("_bigimpl", typ "asms => prop => prop",   Mixfix ("((1\\<lbrakk>_\\<rbrakk>)/ \\<Longrightarrow> _)", [0, 1], 1)),
   487     ("_DDDOT",   typ "logic",                  Delimfix "\\<dots>")]
   488   #> Sign.add_modesyntax_i ("", false)
   489    [("prop", typ "prop => prop", Mixfix ("_", [0], 0)),
   490     ("Pure.term", typ "'a => prop", Delimfix "TERM _"),
   491     ("Pure.conjunction", typ "prop => prop => prop", InfixrName ("&&", 2))]
   492   #> Sign.add_modesyntax_i ("HTML", false)
   493    [("_lambda", typ "pttrns => 'a => logic", Mixfix ("(3\\<lambda>_./ _)", [0, 3], 3))]
   494   #> Sign.add_consts_i
   495    [("==", typ "'a => 'a => prop", InfixrName ("==", 2)),
   496     ("==>", typ "prop => prop => prop", Mixfix ("(_/ ==> _)", [2, 1], 1)),
   497     ("all", typ "('a => prop) => prop", Binder ("!!", 0, 0)),
   498     ("prop", typ "prop => prop", NoSyn),
   499     ("TYPE", typ "'a itself", NoSyn),
   500     (Term.dummy_patternN, typ "'a", Delimfix "'_")]
   501   #> Theory.add_deps "==" ("==", typ "'a => 'a => prop") []
   502   #> Theory.add_deps "==>" ("==>", typ "prop => prop => prop") []
   503   #> Theory.add_deps "all" ("all", typ "('a => prop) => prop") []
   504   #> Theory.add_deps "TYPE" ("TYPE", typ "'a itself") []
   505   #> Theory.add_deps Term.dummy_patternN (Term.dummy_patternN, typ "'a") []
   506   #> Sign.add_trfuns Syntax.pure_trfuns
   507   #> Sign.add_trfunsT Syntax.pure_trfunsT
   508   #> Sign.local_path
   509   #> Sign.add_consts_i
   510    [("term", typ "'a => prop", NoSyn),
   511     ("conjunction", typ "prop => prop => prop", NoSyn)]
   512   #> (add_defs_i false o map Thm.no_attributes)
   513    [("prop_def", prop "(CONST prop :: prop => prop) (A::prop) == A::prop"),
   514     ("term_def", prop "(CONST Pure.term :: 'a => prop) (x::'a) == (!!A::prop. A ==> A)"),
   515     ("conjunction_def", prop "(A && B) == (!!C::prop. (A ==> B ==> C) ==> C)")] #> snd
   516   #> Sign.hide_consts false ["conjunction", "term"]
   517   #> add_thmss [(("nothing", []), [])] #> snd
   518   #> Theory.add_axioms_i Proofterm.equality_axms);
   519 
   520 end;
   521