src/Pure/sign.ML
author wenzelm
Mon Nov 06 22:50:50 2000 +0100 (2000-11-06)
changeset 10404 93efbb62667c
parent 9504 8168600e88a5
child 10443 0a68dc9edba5
permissions -rw-r--r--
added typ_instance;
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 (*base names*)
     9 type bstring = string;
    10 type bclass = class;
    11 (*external forms -- partially qualified names*)
    12 type xstring = string;
    13 type xclass = class;
    14 type xsort = sort;
    15 type xtyp = typ;
    16 type xterm = term;
    17 
    18 signature SIGN =
    19 sig
    20   type sg
    21   type sg_ref
    22   type data
    23   val rep_sg: sg ->
    24    {self: sg_ref,
    25     tsig: Type.type_sig,
    26     const_tab: typ Symtab.table,
    27     syn: Syntax.syntax,
    28     path: string list,
    29     spaces: (string * NameSpace.T) list,
    30     data: data}
    31   val name_of: sg -> string
    32   val stamp_names_of: sg -> string list
    33   val tsig_of: sg -> Type.type_sig
    34   val deref: sg_ref -> sg
    35   val self_ref: sg -> sg_ref
    36   val subsig: sg * sg -> bool
    37   val joinable: sg * sg -> bool
    38   val eq_sg: sg * sg -> bool
    39   val same_sg: sg * sg -> bool
    40   val is_draft: sg -> bool
    41   val is_stale: sg -> bool
    42   val const_type: sg -> string -> typ option
    43   val classes: sg -> class list
    44   val defaultS: sg -> sort
    45   val subsort: sg -> sort * sort -> bool
    46   val nodup_vars: term -> term
    47   val norm_sort: sg -> sort -> sort
    48   val of_sort: sg -> typ * sort -> bool
    49   val witness_sorts: sg -> sort list -> sort list -> (typ * sort) list
    50   val univ_witness: sg -> (typ * sort) option
    51   val classK: string
    52   val typeK: string
    53   val constK: string
    54   val full_name: sg -> bstring -> string
    55   val full_name_path: sg -> string -> bstring -> string
    56   val base_name: string -> bstring
    57   val intern: sg -> string -> xstring -> string
    58   val extern: sg -> string -> string -> xstring
    59   val cond_extern: sg -> string -> string -> xstring
    60   val cond_extern_table: sg -> string -> 'a Symtab.table -> (xstring * 'a) list
    61   val intern_class: sg -> xclass -> class
    62   val intern_tycon: sg -> xstring -> string
    63   val intern_const: sg -> xstring -> string
    64   val intern_sort: sg -> xsort -> sort
    65   val intern_typ: sg -> xtyp -> typ
    66   val intern_term: sg -> xterm -> term
    67   val intern_tycons: sg -> xtyp -> typ
    68   val pretty_sg: sg -> Pretty.T
    69   val str_of_sg: sg -> string
    70   val pprint_sg: sg -> pprint_args -> unit
    71   val pretty_term: sg -> term -> Pretty.T
    72   val pretty_typ: sg -> typ -> Pretty.T
    73   val pretty_sort: sg -> sort -> Pretty.T
    74   val pretty_classrel: sg -> class * class -> Pretty.T
    75   val pretty_arity: sg -> string * sort list * sort -> Pretty.T
    76   val string_of_term: sg -> term -> string
    77   val string_of_typ: sg -> typ -> string
    78   val string_of_sort: sg -> sort -> string
    79   val str_of_sort: sg -> sort -> string
    80   val str_of_classrel: sg -> class * class -> string
    81   val str_of_arity: sg -> string * sort list * sort -> string
    82   val pprint_term: sg -> term -> pprint_args -> unit
    83   val pprint_typ: sg -> typ -> pprint_args -> unit
    84   val certify_class: sg -> class -> class
    85   val certify_sort: sg -> sort -> sort
    86   val certify_typ: sg -> typ -> typ
    87   val certify_typ_no_norm: sg -> typ -> typ
    88   val typ_instance: sg -> typ * typ -> bool
    89   val certify_term: sg -> term -> term * typ * int
    90   val read_sort: sg -> string -> sort
    91   val read_raw_typ: sg * (indexname -> sort option) -> string -> typ
    92   val read_typ: sg * (indexname -> sort option) -> string -> typ
    93   val read_typ_no_norm: sg * (indexname -> sort option) -> string -> typ
    94   val infer_types: sg -> (indexname -> typ option) ->
    95     (indexname -> sort option) -> string list -> bool
    96     -> xterm list * typ -> term * (indexname * typ) list
    97   val infer_types_simult: sg -> (indexname -> typ option) ->
    98     (indexname -> sort option) -> string list -> bool
    99     -> (xterm list * typ) list -> term list * (indexname * typ) list
   100   val read_def_terms:
   101     sg * (indexname -> typ option) * (indexname -> sort option) ->
   102     string list -> bool -> (string * typ) list -> term list * (indexname * typ) list
   103   val simple_read_term: sg -> typ -> string -> term
   104   val add_classes: (bclass * xclass list) list -> sg -> sg
   105   val add_classes_i: (bclass * class list) list -> sg -> sg
   106   val add_classrel: (xclass * xclass) list -> sg -> sg
   107   val add_classrel_i: (class * class) list -> sg -> sg
   108   val add_defsort: string -> sg -> sg
   109   val add_defsort_i: sort -> sg -> sg
   110   val add_types: (bstring * int * mixfix) list -> sg -> sg
   111   val add_nonterminals: bstring list -> sg -> sg
   112   val add_tyabbrs: (bstring * string list * string * mixfix) list -> sg -> sg
   113   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list -> sg -> sg
   114   val add_arities: (xstring * string list * string) list -> sg -> sg
   115   val add_arities_i: (string * sort list * sort) list -> sg -> sg
   116   val add_consts: (bstring * string * mixfix) list -> sg -> sg
   117   val add_consts_i: (bstring * typ * mixfix) list -> sg -> sg
   118   val add_syntax: (bstring * string * mixfix) list -> sg -> sg
   119   val add_syntax_i: (bstring * typ * mixfix) list -> sg -> sg
   120   val add_modesyntax: (string * bool) * (bstring * string * mixfix) list -> sg -> sg
   121   val add_modesyntax_i: (string * bool) * (bstring * typ * mixfix) list -> sg -> sg
   122   val add_trfuns:
   123     (string * (ast list -> ast)) list *
   124     (string * (term list -> term)) list *
   125     (string * (term list -> term)) list *
   126     (string * (ast list -> ast)) list -> sg -> sg
   127   val add_trfunsT:
   128     (string * (bool -> typ -> term list -> term)) list -> sg -> sg
   129   val add_tokentrfuns:
   130     (string * string * (string -> string * real)) list -> sg -> sg
   131   val add_trrules: (xstring * string) Syntax.trrule list -> sg -> sg
   132   val add_trrules_i: ast Syntax.trrule list -> sg -> sg
   133   val add_path: string -> sg -> sg
   134   val add_space: string * string list -> sg -> sg
   135   val hide_space: string * string list -> sg -> sg
   136   val hide_space_i: string * string list -> sg -> sg
   137   val add_name: string -> sg -> sg
   138   val data_kinds: data -> string list
   139   val merge_refs: sg_ref * sg_ref -> sg_ref
   140   val merge: sg * sg -> sg
   141   val prep_ext: sg -> sg
   142   val copy: sg -> sg
   143   val nontriv_merge: sg * sg -> sg
   144   val pre_pure: sg
   145   val const_of_class: class -> string
   146   val class_of_const: string -> class
   147 end;
   148 
   149 signature PRIVATE_SIGN =
   150 sig
   151   include SIGN
   152   val init_data: Object.kind * (Object.T * (Object.T -> Object.T) * (Object.T -> Object.T) *
   153     (Object.T * Object.T -> Object.T) * (sg -> Object.T -> unit)) -> sg -> sg
   154   val get_data: Object.kind -> (Object.T -> 'a) -> sg -> 'a
   155   val put_data: Object.kind -> ('a -> Object.T) -> 'a -> sg -> sg
   156   val print_data: Object.kind -> sg -> unit
   157 end;
   158 
   159 structure Sign: PRIVATE_SIGN =
   160 struct
   161 
   162 
   163 (** datatype sg **)
   164 
   165 (* types sg, data, sg_ref *)
   166 
   167 datatype sg =
   168   Sg of
   169    {id: string ref,                             (*id*)
   170     stamps: string ref list} *                  (*unique theory indentifier*)
   171    {self: sg_ref,                               (*mutable self reference*)
   172     tsig: Type.type_sig,                        (*order-sorted signature of types*)
   173     const_tab: typ Symtab.table,                (*type schemes of constants*)
   174     syn: Syntax.syntax,                         (*syntax for parsing and printing*)
   175     path: string list,                          (*current name space entry prefix*)
   176     spaces: (string * NameSpace.T) list,        (*name spaces for consts, types etc.*)
   177     data: data}                                 (*anytype data*)
   178 and data =
   179   Data of
   180     (Object.kind *                              (*kind (for authorization)*)
   181       (Object.T *                               (*value*)
   182         ((Object.T -> Object.T) *               (*prepare extend method*)
   183           (Object.T -> Object.T) *              (*copy method*)
   184           (Object.T * Object.T -> Object.T) *   (*merge and prepare extend method*)
   185           (sg -> Object.T -> unit))))           (*print method*)
   186     Symtab.table
   187 and sg_ref =
   188   SgRef of sg ref option;
   189 
   190 (*make signature*)
   191 fun make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps) =
   192   Sg ({id = id, stamps = stamps}, {self = self, tsig = tsig, const_tab = const_tab,
   193     syn = syn, path = path, spaces = spaces, data = data});
   194 
   195 
   196 (* basic operations *)
   197 
   198 fun rep_sg (Sg (_, args)) = args;
   199 
   200 (*show stamps*)
   201 fun stamp_names_of (Sg ({stamps, ...}, _)) = rev (map ! stamps);
   202 fun pretty_sg sg = Pretty.str_list "{" "}" (stamp_names_of sg);
   203 val str_of_sg = Pretty.str_of o pretty_sg;
   204 val pprint_sg = Pretty.pprint o pretty_sg;
   205 
   206 val tsig_of = #tsig o rep_sg;
   207 
   208 fun const_type (Sg (_, {const_tab, ...})) c = Symtab.lookup (const_tab, c);
   209 
   210 
   211 (* id and self *)
   212 
   213 fun check_stale (sg as Sg ({id, ...},
   214         {self = SgRef (Some (ref (Sg ({id = id', ...}, _)))), ...})) =
   215       if id = id' then sg
   216       else raise TERM ("Stale signature: " ^ str_of_sg sg, [])
   217   | check_stale _ = sys_error "Sign.check_stale";
   218 
   219 fun is_stale sg = (check_stale sg; false) handle TERM _ => true;
   220 
   221 fun self_ref (sg as Sg (_, {self, ...})) = (check_stale sg; self);
   222 
   223 fun deref (SgRef (Some (ref sg))) = sg
   224   | deref (SgRef None) = sys_error "Sign.deref";
   225 
   226 fun name_of (sg as Sg ({id = ref name, ...}, _)) =
   227   if name = "" orelse ord name = ord "#" then
   228     raise TERM ("Nameless signature " ^ str_of_sg sg, [])
   229   else name;
   230 
   231 
   232 (* inclusion and equality *)
   233 
   234 local
   235   (*avoiding polymorphic equality: factor 10 speedup*)
   236   fun mem_stamp (_:string ref, []) = false
   237     | mem_stamp (x, y :: ys) = x = y orelse mem_stamp (x, ys);
   238 
   239   fun subset_stamp ([], ys) = true
   240     | subset_stamp (x :: xs, ys) =
   241         mem_stamp (x, ys) andalso subset_stamp (xs, ys);
   242 
   243   (*fast partial test*)
   244   fun fast_sub ([]: string ref list, _) = true
   245     | fast_sub (_, []) = false
   246     | fast_sub (x :: xs, y :: ys) =
   247         if x = y then fast_sub (xs, ys)
   248         else fast_sub (x :: xs, ys);
   249 in
   250   fun eq_sg (sg1 as Sg ({id = id1, ...}, _), sg2 as Sg ({id = id2, ...}, _)) =
   251     (check_stale sg1; check_stale sg2; id1 = id2);
   252 
   253   fun subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   254     eq_sg (sg1, sg2) orelse subset_stamp (s1, s2);
   255 
   256   fun fast_subsig (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   257     eq_sg (sg1, sg2) orelse fast_sub (s1, s2);
   258 end;
   259 
   260 
   261 fun joinable (sg1, sg2) = subsig (sg1, sg2) orelse subsig (sg2, sg1);
   262 
   263 (*test if same theory names are contained in signatures' stamps,
   264   i.e. if signatures belong to same theory but not necessarily to the
   265   same version of it*)
   266 fun same_sg (sg1 as Sg ({stamps = s1, ...}, _), sg2 as Sg ({stamps = s2, ...}, _)) =
   267   eq_sg (sg1, sg2) orelse eq_set_string (pairself (map (op !)) (s1, s2));
   268 
   269 (*test for drafts*)
   270 fun is_draft (Sg ({stamps = ref name :: _, ...}, _)) = name = "" orelse ord name = ord "#";
   271 
   272 
   273 (* classes and sorts *)
   274 
   275 val classes = Type.classes o tsig_of;
   276 val defaultS = Type.defaultS o tsig_of;
   277 val subsort = Type.subsort o tsig_of;
   278 val norm_sort = Type.norm_sort o tsig_of;
   279 val of_sort = Type.of_sort o tsig_of;
   280 val witness_sorts = Type.witness_sorts o tsig_of;
   281 val univ_witness = Type.univ_witness o tsig_of;
   282 
   283 
   284 
   285 (** signature data **)
   286 
   287 (* errors *)
   288 
   289 fun of_theory sg = "\nof theory " ^ str_of_sg sg;
   290 
   291 fun err_inconsistent kinds =
   292   error ("Attempt to merge different versions of " ^ commas_quote kinds ^ " data");
   293 
   294 fun err_method name kind e =
   295   (writeln ("Error while invoking " ^ quote kind ^ " " ^ name ^ " method"); raise e);
   296 
   297 fun err_dup_init sg kind =
   298   error ("Duplicate initialization of " ^ quote kind ^ " data" ^ of_theory sg);
   299 
   300 fun err_uninit sg kind =
   301   error ("Tried to access uninitialized " ^ quote kind ^ " data" ^
   302          of_theory sg);
   303 
   304 (*Trying to access theory data using get / put operations from a different
   305   instance of the TheoryDataFun result.  Typical cure: re-load all files*)
   306 fun err_access sg kind =
   307   error ("Unauthorized access to " ^ quote kind ^ " data" ^ of_theory sg);
   308 
   309 
   310 (* prepare data *)
   311 
   312 val empty_data = Data Symtab.empty;
   313 
   314 fun merge_data (Data tab1, Data tab2) =
   315   let
   316     val data1 = map snd (Symtab.dest tab1);
   317     val data2 = map snd (Symtab.dest tab2);
   318     val all_data = data1 @ data2;
   319     val kinds = gen_distinct Object.eq_kind (map fst all_data);
   320 
   321    fun entry data kind =
   322      (case gen_assoc Object.eq_kind (data, kind) of
   323        None => []
   324      | Some x => [(kind, x)]);
   325 
   326     fun merge_entries [(kind, (e, mths as (_, ext, _, _)))] =
   327           (kind, (ext e handle exn => err_method "prep_ext" (Object.name_of_kind kind) exn, mths))
   328       | merge_entries [(kind, (e1, mths as (_, _, mrg, _))), (_, (e2, _))] =
   329           (kind, (mrg (e1, e2)
   330             handle exn => err_method "merge" (Object.name_of_kind kind) exn, mths))
   331       | merge_entries _ = sys_error "merge_entries";
   332 
   333     val data = map (fn k => merge_entries (entry data1 k @ entry data2 k)) kinds;
   334     val data_idx = map (fn (k, x) => (Object.name_of_kind k, (k, x))) data;
   335   in
   336     Data (Symtab.make data_idx)
   337       handle Symtab.DUPS dups => err_inconsistent dups
   338   end;
   339 
   340 fun prep_ext_data data = merge_data (data, empty_data);
   341 
   342 fun init_data_sg sg (Data tab) kind e cp ext mrg prt =
   343   let val name = Object.name_of_kind kind in
   344     Data (Symtab.update_new ((name, (kind, (e, (cp, ext, mrg, prt)))), tab))
   345       handle Symtab.DUP _ => err_dup_init sg name
   346   end;
   347 
   348 
   349 (* access data *)
   350 
   351 fun data_kinds (Data tab) = map fst (Symtab.dest tab);
   352 
   353 fun lookup_data sg tab kind =
   354   let val name = Object.name_of_kind kind in
   355     (case Symtab.lookup (tab, name) of
   356       Some (k, x) =>
   357         if Object.eq_kind (kind, k) then x
   358         else err_access sg name
   359     | None => err_uninit sg name)
   360   end;
   361 
   362 fun get_data kind f (sg as Sg (_, {data = Data tab, ...})) =
   363   let val x = fst (lookup_data sg tab kind)
   364   in f x handle Match => Object.kind_error kind end;
   365 
   366 fun print_data kind (sg as Sg (_, {data = Data tab, ...})) =
   367   let val (e, (_, _, _, prt)) = lookup_data sg tab kind
   368   in prt sg e handle exn => err_method ("print" ^ of_theory sg) (Object.name_of_kind kind) exn end;
   369 
   370 fun put_data_sg sg (Data tab) kind f x =
   371   Data (Symtab.update ((Object.name_of_kind kind,
   372     (kind, (f x, snd (lookup_data sg tab kind)))), tab));
   373 
   374 
   375 
   376 (** build signatures **)
   377 
   378 fun ext_stamps stamps (id as ref name) =
   379   let val stmps = (case stamps of ref "#" :: ss => ss | ss => ss) in
   380     if exists (equal name o !) stmps then
   381       error ("Theory already contains a " ^ quote name ^ " component")
   382     else id :: stmps
   383   end;
   384 
   385 fun create_sign self stamps name (syn, tsig, ctab, (path, spaces), data) =
   386   let
   387     val id = ref name;
   388     val sign =
   389       make_sign (id, self, tsig, ctab, syn, path, spaces, data, ext_stamps stamps id);
   390   in
   391     (case self of
   392       SgRef (Some r) => r := sign
   393     | _ => sys_error "Sign.create_sign");
   394     sign
   395   end;
   396 
   397 fun extend_sign keep extfun name decls
   398     (sg as Sg ({id = _, stamps}, {self, tsig, const_tab, syn, path, spaces, data})) =
   399   let
   400     val _ = check_stale sg;
   401     val (self', data') =
   402       if is_draft sg andalso keep then (self, data)
   403       else (SgRef (Some (ref sg)), prep_ext_data data);
   404   in
   405     create_sign self' stamps name
   406       (extfun (syn, tsig, const_tab, (path, spaces), data') decls)
   407   end;
   408 
   409 
   410 
   411 (** name spaces **)
   412 
   413 (* kinds *)
   414 
   415 val classK = "class";
   416 val typeK = "type";
   417 val constK = "const";
   418 
   419 
   420 (* declare and retrieve names *)
   421 
   422 fun space_of spaces kind =
   423   if_none (assoc (spaces, kind)) NameSpace.empty;
   424 
   425 (*input and output of qualified names*)
   426 fun intrn spaces kind = NameSpace.intern (space_of spaces kind);
   427 fun extrn spaces kind = NameSpace.extern (space_of spaces kind);
   428 fun cond_extrn spaces kind = NameSpace.cond_extern (space_of spaces kind);
   429 fun cond_extrn_table spaces kind tab = NameSpace.cond_extern_table (space_of spaces kind) tab;
   430 
   431 (*add / hide names*)
   432 fun change_space f spaces kind x = overwrite (spaces, (kind, f (space_of spaces kind, x)));
   433 fun add_names x = change_space NameSpace.extend x;
   434 fun hide_names x = change_space NameSpace.hide x;
   435 
   436 (*make full names*)
   437 fun full path name =
   438   if name = "" then error "Attempt to declare empty name \"\""
   439   else if NameSpace.is_qualified name then
   440     error ("Attempt to declare qualified name " ^ quote name)
   441   else NameSpace.pack (path @ [name]);
   442 
   443 (*base name*)
   444 val base_name = NameSpace.base;
   445 
   446 
   447 (* intern / extern names *)
   448 
   449 local
   450   (*prepare mapping of names*)
   451   fun mapping f add_xs t =
   452     let
   453       fun f' x = let val y = f x in if x = y then None else Some (x, y) end;
   454       val table = mapfilter f' (add_xs (t, []));
   455       fun lookup x = if_none (assoc (table, x)) x;
   456     in lookup end;
   457 
   458   (*intern / extern typ*)
   459   fun trn_typ trn T =
   460     T |> map_typ
   461       (mapping (trn classK) add_typ_classes T)
   462       (mapping (trn typeK) add_typ_tycons T);
   463 
   464   (*intern / extern term*)
   465   fun trn_term trn t =
   466     t |> map_term
   467       (mapping (trn classK) add_term_classes t)
   468       (mapping (trn typeK) add_term_tycons t)
   469       (mapping (trn constK) add_term_consts t);
   470 
   471   val spaces_of = #spaces o rep_sg;
   472 in
   473   fun intrn_class spaces = intrn spaces classK;
   474   fun extrn_class spaces = extrn spaces classK;
   475 
   476   val intrn_sort = map o intrn_class;
   477   val intrn_typ = trn_typ o intrn;
   478   val intrn_term = trn_term o intrn;
   479 
   480   val extrn_sort = map o extrn_class;
   481   val extrn_typ = trn_typ o extrn;
   482   val extrn_term = trn_term o extrn;
   483 
   484   fun intrn_tycons spaces T =
   485     map_typ I (mapping (intrn spaces typeK) add_typ_tycons T) T;
   486 
   487   val intern = intrn o spaces_of;
   488   val extern = extrn o spaces_of;
   489   val cond_extern = cond_extrn o spaces_of;
   490   fun cond_extern_table sg = cond_extrn_table (spaces_of sg);
   491 
   492   val intern_class = intrn_class o spaces_of;
   493   val intern_sort = intrn_sort o spaces_of;
   494   val intern_typ = intrn_typ o spaces_of;
   495   val intern_term = intrn_term o spaces_of;
   496 
   497   fun intern_tycon sg = intrn (spaces_of sg) typeK;
   498   fun intern_const sg = intrn (spaces_of sg) constK;
   499 
   500   val intern_tycons = intrn_tycons o spaces_of;
   501 
   502   val full_name = full o #path o rep_sg;
   503   fun full_name_path sg elems name =
   504     full (#path (rep_sg sg) @ NameSpace.unpack elems) name;
   505 end;
   506 
   507 
   508 
   509 (** pretty printing of terms, types etc. **)
   510 
   511 fun pretty_term (sg as Sg ({stamps, ...}, {syn, spaces, ...})) t =
   512   Syntax.pretty_term syn
   513     (exists (equal "CPure" o !) stamps)
   514     (if ! NameSpace.long_names then t else extrn_term spaces t);
   515 
   516 fun pretty_typ (Sg (_, {syn, spaces, ...})) T =
   517   Syntax.pretty_typ syn
   518     (if ! NameSpace.long_names then T else extrn_typ spaces T);
   519 
   520 fun pretty_sort (Sg (_, {syn, spaces, ...})) S =
   521   Syntax.pretty_sort syn
   522     (if ! NameSpace.long_names then S else extrn_sort spaces S);
   523 
   524 fun pretty_classrel sg (c1, c2) = Pretty.block
   525   [pretty_sort sg [c1], Pretty.str " <", Pretty.brk 1, pretty_sort sg [c2]];
   526 
   527 fun pretty_arity sg (t, Ss, S) =
   528   let
   529     val t' = cond_extern sg typeK t;
   530     val dom =
   531       if null Ss then []
   532       else [Pretty.list "(" ")" (map (pretty_sort sg) Ss), Pretty.brk 1];
   533   in
   534     Pretty.block
   535       ([Pretty.str (t' ^ " ::"), Pretty.brk 1] @ dom @ [pretty_sort sg S])
   536   end;
   537 
   538 fun string_of_term sg t = Pretty.string_of (pretty_term sg t);
   539 fun string_of_typ sg T = Pretty.string_of (pretty_typ sg T);
   540 fun string_of_sort sg S = Pretty.string_of (pretty_sort sg S);
   541 
   542 fun str_of_sort sg S = Pretty.str_of (pretty_sort sg S);
   543 fun str_of_classrel sg c1_c2 = Pretty.str_of (pretty_classrel sg c1_c2);
   544 fun str_of_arity sg ar = Pretty.str_of (pretty_arity sg ar);
   545 
   546 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   547 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   548 
   549 
   550 
   551 (** read sorts **)  (*exception ERROR*)
   552 
   553 fun err_in_sort s =
   554   error ("The error(s) above occurred in sort " ^ quote s);
   555 
   556 fun rd_sort syn tsig spaces str =
   557   let val S = intrn_sort spaces (Syntax.read_sort syn str handle ERROR => err_in_sort str)
   558   in Type.cert_sort tsig S handle TYPE (msg, _, _) => (error_msg msg; err_in_sort str) end;
   559 
   560 (*read and certify sort wrt a signature*)
   561 fun read_sort (sg as Sg (_, {tsig, syn, spaces, ...})) str =
   562   (check_stale sg; rd_sort syn tsig spaces str);
   563 
   564 fun cert_sort _ tsig _ = Type.cert_sort tsig;
   565 
   566 
   567 
   568 (** read types **)  (*exception ERROR*)
   569 
   570 fun err_in_type s =
   571   error ("The error(s) above occurred in type " ^ quote s);
   572 
   573 fun rd_raw_typ syn tsig spaces def_sort str =
   574   intrn_tycons spaces
   575     (Syntax.read_typ syn (Type.get_sort tsig def_sort (intrn_sort spaces)) str
   576       handle ERROR => err_in_type str);
   577 
   578 fun read_raw_typ (sg as Sg (_, {tsig, syn, spaces, ...}), def_sort) str =
   579   (check_stale sg; rd_raw_typ syn tsig spaces def_sort str);
   580 
   581 (*read and certify typ wrt a signature*)
   582 local
   583   fun read_typ_aux cert (sg, def_sort) str =
   584     (cert (tsig_of sg) (read_raw_typ (sg, def_sort) str)
   585         handle TYPE (msg, _, _) => (error_msg msg; err_in_type str));
   586 in
   587   val read_typ = read_typ_aux Type.cert_typ;
   588   val read_typ_no_norm = read_typ_aux Type.cert_typ_no_norm;
   589 end;
   590 
   591 
   592 
   593 (** certify classes, sorts, types and terms **)   (*exception TYPE*)
   594 
   595 val certify_class = Type.cert_class o tsig_of;
   596 val certify_sort = Type.cert_sort o tsig_of;
   597 val certify_typ = Type.cert_typ o tsig_of;
   598 val certify_typ_no_norm = Type.cert_typ_no_norm o tsig_of;
   599 fun typ_instance sg (T, U) = Type.typ_instance (tsig_of sg, T, U);
   600 
   601 
   602 (* certify_term *)
   603 
   604 (*check for duplicate occurrences of TFree/TVar with distinct sorts*)
   605 fun nodup_tvars (env, Type (_, Ts)) = nodup_tvars_list (env, Ts)
   606   | nodup_tvars (env as (tfrees, tvars), T as TFree (v as (a, S))) =
   607       (case assoc_string (tfrees, a) of
   608         Some S' =>
   609           if S = S' then env
   610           else raise TYPE ("Type variable " ^ quote a ^
   611             " has two distinct sorts", [TFree (a, S'), T], [])
   612       | None => (v :: tfrees, tvars))
   613   | nodup_tvars (env as (tfrees, tvars), T as TVar (v as (a, S))) =
   614       (case assoc_string_int (tvars, a) of
   615         Some S' =>
   616           if S = S' then env
   617           else raise TYPE ("Type variable " ^ quote (Syntax.string_of_vname a) ^
   618             " has two distinct sorts", [TVar (a, S'), T], [])
   619       | None => (tfrees, v :: tvars))
   620 (*equivalent to foldl nodup_tvars_list, but 3X faster under Poly/ML*)
   621 and nodup_tvars_list (env, []) = env
   622   | nodup_tvars_list (env, T :: Ts) = nodup_tvars_list (nodup_tvars (env, T), Ts);
   623 
   624 (*check for duplicate occurrences of Free/Var with distinct types*)
   625 fun nodup_vars tm =
   626   let
   627     fun nodups (envs as (env as (frees, vars), envT)) tm =
   628       (case tm of
   629         Const (c, T) => (env, nodup_tvars (envT, T))
   630       | Free (v as (a, T)) =>
   631           (case assoc_string (frees, a) of
   632             Some T' =>
   633               if T = T' then (env, nodup_tvars (envT, T))
   634               else raise TYPE ("Variable " ^ quote a ^
   635                 " has two distinct types", [T', T], [])
   636           | None => ((v :: frees, vars), nodup_tvars (envT, T)))
   637       | Var (v as (ixn, T)) =>
   638           (case assoc_string_int (vars, ixn) of
   639             Some T' =>
   640               if T = T' then (env, nodup_tvars (envT, T))
   641               else raise TYPE ("Variable " ^ quote (Syntax.string_of_vname ixn) ^
   642                 " has two distinct types", [T', T], [])
   643           | None => ((frees, v :: vars), nodup_tvars (envT, T)))
   644       | Bound _ => envs
   645       | Abs (_, T, t) => nodups (env, nodup_tvars (envT, T)) t
   646       | s $ t => nodups (nodups envs s) t)
   647   in nodups (([], []), ([], [])) tm; tm end;
   648 
   649 (*compute and check type of the term*)
   650 fun type_check sg tm =
   651   let
   652     val prt = setmp Syntax.show_brackets true (pretty_term sg);
   653     val prT = pretty_typ sg;
   654 
   655     fun err_appl why bs t T u U =
   656       let
   657         val xs = map Free bs;           (*we do not rename here*)
   658         val t' = subst_bounds (xs, t);
   659         val u' = subst_bounds (xs, u);
   660         val text = cat_lines (TypeInfer.appl_error prt prT why t' T u' U);
   661       in raise TYPE (text, [T, U], [t', u']) end;
   662 
   663     fun typ_of (_, Const (_, T)) = T
   664       | typ_of (_, Free  (_, T)) = T
   665       | typ_of (_, Var (_, T)) = T
   666       | typ_of (bs, Bound i) = snd (nth_elem (i, bs) handle LIST _ =>
   667           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   668       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   669       | typ_of (bs, t $ u) =
   670           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   671             (case T of
   672               Type ("fun", [T1, T2]) =>
   673                 if T1 = U then T2 else err_appl "Incompatible operand type." bs t T u U
   674             | _ => err_appl "Operator not of function type." bs t T u U)
   675           end;
   676 
   677   in typ_of ([], tm) end;
   678 
   679 
   680 fun certify_term sg tm =
   681   let
   682     val _ = check_stale sg;
   683     val tsig = tsig_of sg;
   684 
   685     fun show_const a T = quote a ^ " :: " ^ quote (string_of_typ sg T);
   686 
   687     fun atom_err (errs, Const (a, T)) =
   688         (case const_type sg a of
   689           None => ("Undeclared constant " ^ show_const a T) :: errs
   690         | Some U =>
   691             if typ_instance sg (T, U) then errs
   692             else ("Illegal type for constant " ^ show_const a T) :: errs)
   693       | atom_err (errs, Var ((x, i), _)) =
   694           if i < 0 then ("Negative index for Var " ^ quote x) :: errs else errs
   695       | atom_err (errs, _) = errs;
   696 
   697     val norm_tm =
   698       (case it_term_types (Type.typ_errors tsig) (tm, []) of
   699         [] => Type.norm_term tsig tm
   700       | errs => raise TYPE (cat_lines errs, [], [tm]));
   701     val _ = nodup_vars norm_tm;
   702   in
   703     (case foldl_aterms atom_err ([], norm_tm) of
   704       [] => (norm_tm, type_check sg norm_tm, maxidx_of_term norm_tm)
   705     | errs => raise TYPE (cat_lines errs, [], [norm_tm]))
   706   end;
   707 
   708 
   709 (** infer_types **)         (*exception ERROR*)
   710 
   711 (*
   712   def_type: partial map from indexnames to types (constrains Frees, Vars)
   713   def_sort: partial map from indexnames to sorts (constrains TFrees, TVars)
   714   used: list of already used type variables
   715   freeze: if true then generated parameters are turned into TFrees, else TVars
   716 
   717   termss: lists of alternative parses (only one combination should be type-correct)
   718   typs: expected types
   719 *)
   720 
   721 fun infer_types_simult sg def_type def_sort used freeze args =
   722   let
   723     val tsig = tsig_of sg;
   724     val prt = setmp Syntax.show_brackets true (pretty_term sg);
   725     val prT = pretty_typ sg;
   726 
   727     val termss = foldr multiply (map fst args, [[]]);
   728     val typs =
   729       map (fn (_, T) => certify_typ sg T handle TYPE (msg, _, _) => error msg) args;
   730 
   731     fun infer ts = OK
   732       (Type.infer_types prt prT tsig (const_type sg) def_type def_sort
   733         (intern_const sg) (intern_tycons sg) (intern_sort sg) used freeze typs ts)
   734       handle TYPE (msg, _, _) => Error msg;
   735 
   736     val err_results = map infer termss;
   737     val errs = mapfilter get_error err_results;
   738     val results = mapfilter get_ok err_results;
   739 
   740     val ambiguity = length termss;      (* FIXME !? *)
   741     (* FIXME to syntax.ML!? *)
   742     fun ambig_msg () =
   743       if ambiguity > 1 andalso ambiguity <= ! Syntax.ambiguity_level
   744       then
   745         error_msg "Got more than one parse tree.\n\
   746           \Retry with smaller Syntax.ambiguity_level for more information."
   747       else ();
   748   in
   749     if null results then (ambig_msg (); error (cat_lines errs))
   750     else if length results = 1 then
   751       (if ambiguity > ! Syntax.ambiguity_level then
   752         warning "Fortunately, only one parse tree is type correct.\n\
   753           \You may still want to disambiguate your grammar or your input."
   754       else (); hd results)
   755     else (ambig_msg (); error ("More than one term is type correct:\n" ^
   756       (cat_lines (map (Pretty.string_of o prt) (flat (map fst results))))))
   757   end;
   758 
   759 
   760 fun infer_types sg def_type def_sort used freeze tsT =
   761   apfst hd (infer_types_simult sg def_type def_sort used freeze [tsT]);
   762 
   763 
   764 (** read_def_terms **)
   765 
   766 (*read terms, infer types*)
   767 fun read_def_terms (sign, types, sorts) used freeze sTs =
   768   let
   769     val syn = #syn (rep_sg sign);
   770     fun read (s, T) =
   771       let val T' = certify_typ sign T handle TYPE (msg, _, _) => error msg
   772       in (Syntax.read syn T' s, T') end;
   773     val tsTs = map read sTs;
   774   in infer_types_simult sign types sorts used freeze tsTs end;
   775 
   776 fun simple_read_term sign T s =
   777   (read_def_terms (sign, K None, K None) [] true [(s, T)]
   778     handle ERROR => error ("The error(s) above occurred for " ^ s)) |> #1 |> hd;
   779 
   780 
   781 
   782 (** extend signature **)    (*exception ERROR*)
   783 
   784 (** signature extension functions **)  (*exception ERROR*)
   785 
   786 fun decls_of path name_of mfixs =
   787   map (fn (x, y, mx) => (full path (name_of x mx), y)) mfixs;
   788 
   789 fun no_read _ _ _ decl = decl;
   790 
   791 
   792 (* add default sort *)
   793 
   794 fun ext_defS prep_sort (syn, tsig, ctab, (path, spaces), data) S =
   795   (syn, Type.ext_tsig_defsort tsig (prep_sort syn tsig spaces S), ctab, (path, spaces), data);
   796 
   797 fun ext_defsort arg   = ext_defS rd_sort arg;
   798 fun ext_defsort_i arg = ext_defS cert_sort arg;
   799 
   800 
   801 (* add type constructors *)
   802 
   803 fun ext_types (syn, tsig, ctab, (path, spaces), data) types =
   804   let val decls = decls_of path Syntax.type_name types in
   805     (Syntax.extend_type_gram syn types,
   806       Type.ext_tsig_types tsig decls, ctab,
   807       (path, add_names spaces typeK (map fst decls)), data)
   808   end;
   809 
   810 fun ext_nonterminals sg nonterms =
   811   ext_types sg (map (fn n => (n, 0, Syntax.NoSyn)) nonterms);
   812 
   813 
   814 (* add type abbreviations *)
   815 
   816 fun read_abbr syn tsig spaces (t, vs, rhs_src) =
   817   (t, vs, rd_raw_typ syn tsig spaces (K None) rhs_src)
   818     handle ERROR => error ("in type abbreviation " ^ t);
   819 
   820 fun ext_abbrs rd_abbr (syn, tsig, ctab, (path, spaces), data) abbrs =
   821   let
   822     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   823     val syn' = Syntax.extend_type_gram syn (map mfix_of abbrs);
   824 
   825     val abbrs' =
   826       map (fn (t, vs, rhs, mx) =>
   827         (full path (Syntax.type_name t mx), vs, rhs)) abbrs;
   828     val spaces' = add_names spaces typeK (map #1 abbrs');
   829     val decls = map (rd_abbr syn' tsig spaces') abbrs';
   830   in
   831     (syn', Type.ext_tsig_abbrs tsig decls, ctab, (path, spaces'), data)
   832   end;
   833 
   834 fun ext_tyabbrs abbrs = ext_abbrs read_abbr abbrs;
   835 fun ext_tyabbrs_i abbrs = ext_abbrs no_read abbrs;
   836 
   837 
   838 (* add type arities *)
   839 
   840 fun ext_ars int prep_sort (syn, tsig, ctab, (path, spaces), data) arities =
   841   let
   842     val prepS = prep_sort syn tsig spaces;
   843     fun prep_arity (c, Ss, S) =
   844       (if int then intrn spaces typeK c else c, map prepS Ss, prepS S);
   845     val tsig' = Type.ext_tsig_arities tsig (map prep_arity arities);
   846     val log_types = Type.logical_types tsig';
   847   in
   848     (Syntax.extend_log_types syn log_types, tsig', ctab, (path, spaces), data)
   849   end;
   850 
   851 fun ext_arities arg   = ext_ars true rd_sort arg;
   852 fun ext_arities_i arg = ext_ars false cert_sort arg;
   853 
   854 
   855 (* add term constants and syntax *)
   856 
   857 fun const_name path c mx =
   858   full path (Syntax.const_name c mx);
   859 
   860 fun err_in_const c =
   861   error ("in declaration of constant " ^ quote c);
   862 
   863 fun err_dup_consts cs =
   864   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   865 
   866 
   867 fun read_const syn tsig (path, spaces) (c, ty_src, mx) =
   868   (c, rd_raw_typ syn tsig spaces (K None) ty_src, mx)
   869     handle ERROR => err_in_const (const_name path c mx);
   870 
   871 fun ext_cnsts rd_const syn_only prmode (syn, tsig, ctab, (path, spaces), data) raw_consts =
   872   let
   873     fun prep_const (c, ty, mx) =
   874       (c, compress_type (Type.varifyT (Type.cert_typ tsig (Type.no_tvars ty))), mx)
   875         handle TYPE (msg, _, _) =>
   876           (error_msg msg; err_in_const (const_name path c mx));
   877 
   878     val consts = map (prep_const o rd_const syn tsig (path, spaces)) raw_consts;
   879     val decls =
   880       if syn_only then []
   881       else decls_of path Syntax.const_name consts;
   882   in
   883     (Syntax.extend_const_gram syn prmode consts, tsig,
   884       Symtab.extend (ctab, decls)
   885         handle Symtab.DUPS cs => err_dup_consts cs,
   886       (path, add_names spaces constK (map fst decls)), data)
   887   end;
   888 
   889 fun ext_consts_i sg = ext_cnsts no_read false ("", true) sg;
   890 fun ext_consts sg = ext_cnsts read_const false ("", true) sg;
   891 fun ext_syntax_i sg = ext_cnsts no_read true ("", true) sg;
   892 fun ext_syntax sg = ext_cnsts read_const true ("", true) sg;
   893 fun ext_modesyntax_i sg (prmode, consts) = ext_cnsts no_read true prmode sg consts;
   894 fun ext_modesyntax sg (prmode, consts) = ext_cnsts read_const true prmode sg consts;
   895 
   896 
   897 (* add type classes *)
   898 
   899 fun const_of_class c = c ^ "_class";
   900 
   901 fun class_of_const c_class =
   902   let
   903     val c = implode (take (size c_class - size "_class", explode c_class));
   904   in
   905     if const_of_class c = c_class then c
   906     else raise TERM ("class_of_const: bad name " ^ quote c_class, [])
   907   end;
   908 
   909 
   910 fun ext_classes int (syn, tsig, ctab, (path, spaces), data) classes =
   911   let
   912     val names = map fst classes;
   913     val consts =
   914       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   915 
   916     val full_names = map (full path) names;
   917     val spaces' = add_names spaces classK full_names;
   918     val intrn = if int then map (intrn_class spaces') else I;
   919     val classes' =
   920       ListPair.map (fn (c, (_, cs)) => (c, intrn cs)) (full_names, classes);
   921   in
   922     ext_consts_i
   923       (Syntax.extend_consts syn names,
   924         Type.ext_tsig_classes tsig classes', ctab, (path, spaces'), data)
   925     consts
   926   end;
   927 
   928 
   929 (* add to classrel *)
   930 
   931 fun ext_classrel int (syn, tsig, ctab, (path, spaces), data) pairs =
   932   let val intrn = if int then map (pairself (intrn_class spaces)) else I in
   933     (syn, Type.ext_tsig_classrel tsig (intrn pairs), ctab, (path, spaces), data)
   934   end;
   935 
   936 
   937 (* add translation rules *)
   938 
   939 fun ext_trrules (syn, tsig, ctab, (path, spaces), data) args =
   940   (Syntax.extend_trrules syn
   941     (map (Syntax.map_trrule (fn (root, str) => (intrn spaces typeK root, str))) args),
   942       tsig, ctab, (path, spaces), data);
   943 
   944 
   945 (* add to syntax *)
   946 
   947 fun ext_syn extfun (syn, tsig, ctab, names, data) args =
   948   (extfun syn args, tsig, ctab, names, data);
   949 
   950 
   951 (* add to path *)
   952 
   953 fun ext_path (syn, tsig, ctab, (path, spaces), data) elems =
   954   let
   955     val path' =
   956       if elems = ".." andalso not (null path) then fst (split_last path)
   957       else if elems = "/" then []
   958       else path @ NameSpace.unpack elems;
   959   in
   960     (syn, tsig, ctab, (path', spaces), data)
   961   end;
   962 
   963 
   964 (* change name space *)
   965 
   966 fun ext_add_space (syn, tsig, ctab, (path, spaces), data) (kind, names) =
   967   (syn, tsig, ctab, (path, add_names spaces kind names), data);
   968 
   969 fun ext_hide_space (syn, tsig, ctab, (path, spaces), data) (kind, xnames) =
   970   (syn, tsig, ctab, (path, hide_names spaces kind (map (intrn spaces kind) xnames)), data);
   971 
   972 fun ext_hide_space_i (syn, tsig, ctab, (path, spaces), data) (kind, names) =
   973   (syn, tsig, ctab, (path, hide_names spaces kind names), data);
   974 
   975 
   976 (* signature data *)
   977 
   978 fun ext_init_data sg (syn, tsig, ctab, names, data) (kind, (e, cp, ext, mrg, prt)) =
   979   (syn, tsig, ctab, names, init_data_sg sg data kind e cp ext mrg prt);
   980 
   981 fun ext_put_data sg (syn, tsig, ctab, names, data) (kind, f, x) =
   982   (syn, tsig, ctab, names, put_data_sg sg data kind f x);
   983 
   984 
   985 fun copy_data (k, (e, mths as (cp, _, _, _))) =
   986   (k, (cp e handle exn => err_method "copy" (Object.name_of_kind k) exn, mths));
   987 
   988 fun copy (sg as Sg ({id = _, stamps}, {self, tsig, const_tab, syn, path, spaces, data})) =
   989   let
   990     val _ = check_stale sg;
   991     val self' = SgRef (Some (ref sg));
   992     val Data tab = data;
   993     val data' = Data (Symtab.map copy_data tab);
   994   in create_sign self' stamps "#" (syn, tsig, const_tab, (path, spaces), data') end;
   995 
   996 
   997 (* the external interfaces *)
   998 
   999 val add_classes       = extend_sign true (ext_classes true) "#";
  1000 val add_classes_i     = extend_sign true (ext_classes false) "#";
  1001 val add_classrel      = extend_sign true (ext_classrel true) "#";
  1002 val add_classrel_i    = extend_sign true (ext_classrel false) "#";
  1003 val add_defsort       = extend_sign true ext_defsort "#";
  1004 val add_defsort_i     = extend_sign true ext_defsort_i "#";
  1005 val add_types         = extend_sign true ext_types "#";
  1006 val add_nonterminals  = extend_sign true ext_nonterminals "#";
  1007 val add_tyabbrs       = extend_sign true ext_tyabbrs "#";
  1008 val add_tyabbrs_i     = extend_sign true ext_tyabbrs_i "#";
  1009 val add_arities       = extend_sign true ext_arities "#";
  1010 val add_arities_i     = extend_sign true ext_arities_i "#";
  1011 val add_consts        = extend_sign true ext_consts "#";
  1012 val add_consts_i      = extend_sign true ext_consts_i "#";
  1013 val add_syntax        = extend_sign true ext_syntax "#";
  1014 val add_syntax_i      = extend_sign true ext_syntax_i "#";
  1015 val add_modesyntax    = extend_sign true ext_modesyntax "#";
  1016 val add_modesyntax_i  = extend_sign true ext_modesyntax_i "#";
  1017 val add_trfuns        = extend_sign true (ext_syn Syntax.extend_trfuns) "#";
  1018 val add_trfunsT       = extend_sign true (ext_syn Syntax.extend_trfunsT) "#";
  1019 val add_tokentrfuns   = extend_sign true (ext_syn Syntax.extend_tokentrfuns) "#";
  1020 val add_trrules       = extend_sign true ext_trrules "#";
  1021 val add_trrules_i     = extend_sign true (ext_syn Syntax.extend_trrules_i) "#";
  1022 val add_path          = extend_sign true ext_path "#";
  1023 val add_space         = extend_sign true ext_add_space "#";
  1024 val hide_space        = extend_sign true ext_hide_space "#";
  1025 val hide_space_i      = extend_sign true ext_hide_space_i "#";
  1026 fun init_data arg sg  = extend_sign true (ext_init_data sg) "#" arg sg;
  1027 fun put_data k f x sg = extend_sign true (ext_put_data sg) "#" (k, f, x) sg;
  1028 fun add_name name sg  = extend_sign true K name () sg;
  1029 fun prep_ext sg       = extend_sign false K "#" () sg;
  1030 
  1031 
  1032 
  1033 (** merge signatures **)        (*exception TERM*)
  1034 
  1035 (* merge_stamps *)
  1036 
  1037 fun merge_stamps stamps1 stamps2 =
  1038   let val stamps = merge_rev_lists stamps1 stamps2 in
  1039     (case duplicates (map ! stamps) of
  1040       [] => stamps
  1041     | dups => raise TERM ("Attempt to merge different versions of theories "
  1042         ^ commas_quote dups, []))
  1043   end;
  1044 
  1045 
  1046 (* implicit merge -- trivial only *)
  1047 
  1048 fun merge_refs (sgr1 as SgRef (Some (ref (sg1 as Sg ({stamps = s1, ...}, _)))),
  1049         sgr2 as SgRef (Some (ref (sg2 as Sg ({stamps = s2, ...}, _))))) =
  1050       if fast_subsig (sg2, sg1) then sgr1
  1051       else if fast_subsig (sg1, sg2) then sgr2
  1052       else if subsig (sg2, sg1) then sgr1
  1053       else if subsig (sg1, sg2) then sgr2
  1054       else (merge_stamps s1 s2; (*check for different versions*)
  1055         raise TERM ("Attempt to do non-trivial merge of signatures", []))
  1056   | merge_refs _ = sys_error "Sign.merge_refs";
  1057 
  1058 val merge = deref o merge_refs o pairself self_ref;
  1059 
  1060 
  1061 (* proper merge *)              (*exception TERM/ERROR*)
  1062 
  1063 fun nontriv_merge (sg1, sg2) =
  1064   if subsig (sg2, sg1) then sg1
  1065   else if subsig (sg1, sg2) then sg2
  1066   else if is_draft sg1 orelse is_draft sg2 then
  1067     raise TERM ("Attempt to merge draft signatures", [])
  1068   else
  1069     (*neither is union already; must form union*)
  1070     let
  1071       val Sg ({id = _, stamps = stamps1}, {self = _, tsig = tsig1, const_tab = const_tab1,
  1072         syn = syn1, path = _, spaces = spaces1, data = data1}) = sg1;
  1073       val Sg ({id = _, stamps = stamps2}, {self = _, tsig = tsig2, const_tab = const_tab2,
  1074         syn = syn2, path = _, spaces = spaces2, data = data2}) = sg2;
  1075 
  1076       val id = ref "";
  1077       val self_ref = ref sg1;                   (*dummy value*)
  1078       val self = SgRef (Some self_ref);
  1079 
  1080       val stamps = merge_stamps stamps1 stamps2;
  1081       val tsig = Type.merge_tsigs (tsig1, tsig2);
  1082       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
  1083         handle Symtab.DUPS cs =>
  1084           raise TERM ("Incompatible types for constant(s) " ^ commas_quote cs, []);
  1085       val syn = Syntax.merge_syntaxes syn1 syn2;
  1086 
  1087       val path = [];
  1088       val kinds = distinct (map fst (spaces1 @ spaces2));
  1089       val spaces =
  1090         kinds ~~
  1091           ListPair.map NameSpace.merge
  1092             (map (space_of spaces1) kinds, map (space_of spaces2) kinds);
  1093 
  1094       val data = merge_data (data1, data2);
  1095 
  1096       val sign = make_sign (id, self, tsig, const_tab, syn, path, spaces, data, stamps);
  1097     in
  1098       self_ref := sign; sign
  1099     end;
  1100 
  1101 
  1102 
  1103 (** partial Pure signature **)
  1104 
  1105 val dummy_sg = make_sign (ref "", SgRef None, Type.tsig0,
  1106   Symtab.empty, Syntax.pure_syn, [], [], empty_data, []);
  1107 
  1108 val pre_pure =
  1109   create_sign (SgRef (Some (ref dummy_sg))) [] "#"
  1110     (Syntax.pure_syn, Type.tsig0, Symtab.empty, ([], []), empty_data);
  1111 
  1112 
  1113 end;