src/HOL/Fun_Def.thy
author blanchet
Fri Mar 07 14:21:15 2014 +0100 (2014-03-07)
changeset 55968 94242fa87638
parent 55466 786edc984c98
child 56248 67dc9549fa15
permissions -rw-r--r--
tuning
     1 (*  Title:      HOL/Fun_Def.thy
     2     Author:     Alexander Krauss, TU Muenchen
     3 *)
     4 
     5 header {* Function Definitions and Termination Proofs *}
     6 
     7 theory Fun_Def
     8 imports Partial_Function SAT
     9 keywords "function" "termination" :: thy_goal and "fun" "fun_cases" :: thy_decl
    10 begin
    11 
    12 subsection {* Definitions with default value *}
    13 
    14 definition
    15   THE_default :: "'a \<Rightarrow> ('a \<Rightarrow> bool) \<Rightarrow> 'a" where
    16   "THE_default d P = (if (\<exists>!x. P x) then (THE x. P x) else d)"
    17 
    18 lemma THE_defaultI': "\<exists>!x. P x \<Longrightarrow> P (THE_default d P)"
    19   by (simp add: theI' THE_default_def)
    20 
    21 lemma THE_default1_equality:
    22     "\<lbrakk>\<exists>!x. P x; P a\<rbrakk> \<Longrightarrow> THE_default d P = a"
    23   by (simp add: the1_equality THE_default_def)
    24 
    25 lemma THE_default_none:
    26     "\<not>(\<exists>!x. P x) \<Longrightarrow> THE_default d P = d"
    27   by (simp add:THE_default_def)
    28 
    29 
    30 lemma fundef_ex1_existence:
    31   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    32   assumes ex1: "\<exists>!y. G x y"
    33   shows "G x (f x)"
    34   apply (simp only: f_def)
    35   apply (rule THE_defaultI')
    36   apply (rule ex1)
    37   done
    38 
    39 lemma fundef_ex1_uniqueness:
    40   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    41   assumes ex1: "\<exists>!y. G x y"
    42   assumes elm: "G x (h x)"
    43   shows "h x = f x"
    44   apply (simp only: f_def)
    45   apply (rule THE_default1_equality [symmetric])
    46    apply (rule ex1)
    47   apply (rule elm)
    48   done
    49 
    50 lemma fundef_ex1_iff:
    51   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    52   assumes ex1: "\<exists>!y. G x y"
    53   shows "(G x y) = (f x = y)"
    54   apply (auto simp:ex1 f_def THE_default1_equality)
    55   apply (rule THE_defaultI')
    56   apply (rule ex1)
    57   done
    58 
    59 lemma fundef_default_value:
    60   assumes f_def: "f == (\<lambda>x::'a. THE_default (d x) (\<lambda>y. G x y))"
    61   assumes graph: "\<And>x y. G x y \<Longrightarrow> D x"
    62   assumes "\<not> D x"
    63   shows "f x = d x"
    64 proof -
    65   have "\<not>(\<exists>y. G x y)"
    66   proof
    67     assume "\<exists>y. G x y"
    68     hence "D x" using graph ..
    69     with `\<not> D x` show False ..
    70   qed
    71   hence "\<not>(\<exists>!y. G x y)" by blast
    72 
    73   thus ?thesis
    74     unfolding f_def
    75     by (rule THE_default_none)
    76 qed
    77 
    78 definition in_rel_def[simp]:
    79   "in_rel R x y == (x, y) \<in> R"
    80 
    81 lemma wf_in_rel:
    82   "wf R \<Longrightarrow> wfP (in_rel R)"
    83   by (simp add: wfP_def)
    84 
    85 ML_file "Tools/Function/function_core.ML"
    86 ML_file "Tools/Function/mutual.ML"
    87 ML_file "Tools/Function/pattern_split.ML"
    88 ML_file "Tools/Function/relation.ML"
    89 ML_file "Tools/Function/function_elims.ML"
    90 
    91 method_setup relation = {*
    92   Args.term >> (fn t => fn ctxt => SIMPLE_METHOD' (Function_Relation.relation_infer_tac ctxt t))
    93 *} "prove termination using a user-specified wellfounded relation"
    94 
    95 ML_file "Tools/Function/function.ML"
    96 ML_file "Tools/Function/pat_completeness.ML"
    97 
    98 method_setup pat_completeness = {*
    99   Scan.succeed (SIMPLE_METHOD' o Pat_Completeness.pat_completeness_tac)
   100 *} "prove completeness of datatype patterns"
   101 
   102 ML_file "Tools/Function/fun.ML"
   103 ML_file "Tools/Function/induction_schema.ML"
   104 
   105 method_setup induction_schema = {*
   106   Scan.succeed (RAW_METHOD o Induction_Schema.induction_schema_tac)
   107 *} "prove an induction principle"
   108 
   109 setup {*
   110   Function.setup
   111   #> Function_Fun.setup
   112 *}
   113 
   114 subsection {* Measure Functions *}
   115 
   116 inductive is_measure :: "('a \<Rightarrow> nat) \<Rightarrow> bool"
   117 where is_measure_trivial: "is_measure f"
   118 
   119 ML_file "Tools/Function/measure_functions.ML"
   120 setup MeasureFunctions.setup
   121 
   122 lemma measure_size[measure_function]: "is_measure size"
   123 by (rule is_measure_trivial)
   124 
   125 lemma measure_fst[measure_function]: "is_measure f \<Longrightarrow> is_measure (\<lambda>p. f (fst p))"
   126 by (rule is_measure_trivial)
   127 lemma measure_snd[measure_function]: "is_measure f \<Longrightarrow> is_measure (\<lambda>p. f (snd p))"
   128 by (rule is_measure_trivial)
   129 
   130 ML_file "Tools/Function/lexicographic_order.ML"
   131 
   132 method_setup lexicographic_order = {*
   133   Method.sections clasimp_modifiers >>
   134   (K (SIMPLE_METHOD o Lexicographic_Order.lexicographic_order_tac false))
   135 *} "termination prover for lexicographic orderings"
   136 
   137 setup Lexicographic_Order.setup
   138 
   139 
   140 subsection {* Congruence Rules *}
   141 
   142 lemma let_cong [fundef_cong]:
   143   "M = N \<Longrightarrow> (\<And>x. x = N \<Longrightarrow> f x = g x) \<Longrightarrow> Let M f = Let N g"
   144   unfolding Let_def by blast
   145 
   146 lemmas [fundef_cong] =
   147   if_cong image_cong INT_cong UN_cong
   148   bex_cong ball_cong imp_cong map_option_cong Option.bind_cong
   149 
   150 lemma split_cong [fundef_cong]:
   151   "(\<And>x y. (x, y) = q \<Longrightarrow> f x y = g x y) \<Longrightarrow> p = q
   152     \<Longrightarrow> split f p = split g q"
   153   by (auto simp: split_def)
   154 
   155 lemma comp_cong [fundef_cong]:
   156   "f (g x) = f' (g' x') \<Longrightarrow> (f o g) x = (f' o g') x'"
   157   unfolding o_apply .
   158 
   159 subsection {* Simp rules for termination proofs *}
   160 
   161 lemma termination_basic_simps[termination_simp]:
   162   "x < (y::nat) \<Longrightarrow> x < y + z"
   163   "x < z \<Longrightarrow> x < y + z"
   164   "x \<le> y \<Longrightarrow> x \<le> y + (z::nat)"
   165   "x \<le> z \<Longrightarrow> x \<le> y + (z::nat)"
   166   "x < y \<Longrightarrow> x \<le> (y::nat)"
   167 by arith+
   168 
   169 declare le_imp_less_Suc[termination_simp]
   170 
   171 lemma prod_size_simp[termination_simp]:
   172   "prod_size f g p = f (fst p) + g (snd p) + Suc 0"
   173 by (induct p) auto
   174 
   175 subsection {* Decomposition *}
   176 
   177 lemma less_by_empty:
   178   "A = {} \<Longrightarrow> A \<subseteq> B"
   179 and  union_comp_emptyL:
   180   "\<lbrakk> A O C = {}; B O C = {} \<rbrakk> \<Longrightarrow> (A \<union> B) O C = {}"
   181 and union_comp_emptyR:
   182   "\<lbrakk> A O B = {}; A O C = {} \<rbrakk> \<Longrightarrow> A O (B \<union> C) = {}"
   183 and wf_no_loop:
   184   "R O R = {} \<Longrightarrow> wf R"
   185 by (auto simp add: wf_comp_self[of R])
   186 
   187 
   188 subsection {* Reduction Pairs *}
   189 
   190 definition
   191   "reduction_pair P = (wf (fst P) \<and> fst P O snd P \<subseteq> fst P)"
   192 
   193 lemma reduction_pairI[intro]: "wf R \<Longrightarrow> R O S \<subseteq> R \<Longrightarrow> reduction_pair (R, S)"
   194 unfolding reduction_pair_def by auto
   195 
   196 lemma reduction_pair_lemma:
   197   assumes rp: "reduction_pair P"
   198   assumes "R \<subseteq> fst P"
   199   assumes "S \<subseteq> snd P"
   200   assumes "wf S"
   201   shows "wf (R \<union> S)"
   202 proof -
   203   from rp `S \<subseteq> snd P` have "wf (fst P)" "fst P O S \<subseteq> fst P"
   204     unfolding reduction_pair_def by auto
   205   with `wf S` have "wf (fst P \<union> S)"
   206     by (auto intro: wf_union_compatible)
   207   moreover from `R \<subseteq> fst P` have "R \<union> S \<subseteq> fst P \<union> S" by auto
   208   ultimately show ?thesis by (rule wf_subset)
   209 qed
   210 
   211 definition
   212   "rp_inv_image = (\<lambda>(R,S) f. (inv_image R f, inv_image S f))"
   213 
   214 lemma rp_inv_image_rp:
   215   "reduction_pair P \<Longrightarrow> reduction_pair (rp_inv_image P f)"
   216   unfolding reduction_pair_def rp_inv_image_def split_def
   217   by force
   218 
   219 
   220 subsection {* Concrete orders for SCNP termination proofs *}
   221 
   222 definition "pair_less = less_than <*lex*> less_than"
   223 definition "pair_leq = pair_less^="
   224 definition "max_strict = max_ext pair_less"
   225 definition "max_weak = max_ext pair_leq \<union> {({}, {})}"
   226 definition "min_strict = min_ext pair_less"
   227 definition "min_weak = min_ext pair_leq \<union> {({}, {})}"
   228 
   229 lemma wf_pair_less[simp]: "wf pair_less"
   230   by (auto simp: pair_less_def)
   231 
   232 text {* Introduction rules for @{text pair_less}/@{text pair_leq} *}
   233 lemma pair_leqI1: "a < b \<Longrightarrow> ((a, s), (b, t)) \<in> pair_leq"
   234   and pair_leqI2: "a \<le> b \<Longrightarrow> s \<le> t \<Longrightarrow> ((a, s), (b, t)) \<in> pair_leq"
   235   and pair_lessI1: "a < b  \<Longrightarrow> ((a, s), (b, t)) \<in> pair_less"
   236   and pair_lessI2: "a \<le> b \<Longrightarrow> s < t \<Longrightarrow> ((a, s), (b, t)) \<in> pair_less"
   237   unfolding pair_leq_def pair_less_def by auto
   238 
   239 text {* Introduction rules for max *}
   240 lemma smax_emptyI:
   241   "finite Y \<Longrightarrow> Y \<noteq> {} \<Longrightarrow> ({}, Y) \<in> max_strict"
   242   and smax_insertI:
   243   "\<lbrakk>y \<in> Y; (x, y) \<in> pair_less; (X, Y) \<in> max_strict\<rbrakk> \<Longrightarrow> (insert x X, Y) \<in> max_strict"
   244   and wmax_emptyI:
   245   "finite X \<Longrightarrow> ({}, X) \<in> max_weak"
   246   and wmax_insertI:
   247   "\<lbrakk>y \<in> YS; (x, y) \<in> pair_leq; (XS, YS) \<in> max_weak\<rbrakk> \<Longrightarrow> (insert x XS, YS) \<in> max_weak"
   248 unfolding max_strict_def max_weak_def by (auto elim!: max_ext.cases)
   249 
   250 text {* Introduction rules for min *}
   251 lemma smin_emptyI:
   252   "X \<noteq> {} \<Longrightarrow> (X, {}) \<in> min_strict"
   253   and smin_insertI:
   254   "\<lbrakk>x \<in> XS; (x, y) \<in> pair_less; (XS, YS) \<in> min_strict\<rbrakk> \<Longrightarrow> (XS, insert y YS) \<in> min_strict"
   255   and wmin_emptyI:
   256   "(X, {}) \<in> min_weak"
   257   and wmin_insertI:
   258   "\<lbrakk>x \<in> XS; (x, y) \<in> pair_leq; (XS, YS) \<in> min_weak\<rbrakk> \<Longrightarrow> (XS, insert y YS) \<in> min_weak"
   259 by (auto simp: min_strict_def min_weak_def min_ext_def)
   260 
   261 text {* Reduction Pairs *}
   262 
   263 lemma max_ext_compat:
   264   assumes "R O S \<subseteq> R"
   265   shows "max_ext R O (max_ext S \<union> {({},{})}) \<subseteq> max_ext R"
   266 using assms
   267 apply auto
   268 apply (elim max_ext.cases)
   269 apply rule
   270 apply auto[3]
   271 apply (drule_tac x=xa in meta_spec)
   272 apply simp
   273 apply (erule bexE)
   274 apply (drule_tac x=xb in meta_spec)
   275 by auto
   276 
   277 lemma max_rpair_set: "reduction_pair (max_strict, max_weak)"
   278   unfolding max_strict_def max_weak_def
   279 apply (intro reduction_pairI max_ext_wf)
   280 apply simp
   281 apply (rule max_ext_compat)
   282 by (auto simp: pair_less_def pair_leq_def)
   283 
   284 lemma min_ext_compat:
   285   assumes "R O S \<subseteq> R"
   286   shows "min_ext R O  (min_ext S \<union> {({},{})}) \<subseteq> min_ext R"
   287 using assms
   288 apply (auto simp: min_ext_def)
   289 apply (drule_tac x=ya in bspec, assumption)
   290 apply (erule bexE)
   291 apply (drule_tac x=xc in bspec)
   292 apply assumption
   293 by auto
   294 
   295 lemma min_rpair_set: "reduction_pair (min_strict, min_weak)"
   296   unfolding min_strict_def min_weak_def
   297 apply (intro reduction_pairI min_ext_wf)
   298 apply simp
   299 apply (rule min_ext_compat)
   300 by (auto simp: pair_less_def pair_leq_def)
   301 
   302 
   303 subsection {* Tool setup *}
   304 
   305 ML_file "Tools/Function/termination.ML"
   306 ML_file "Tools/Function/scnp_solve.ML"
   307 ML_file "Tools/Function/scnp_reconstruct.ML"
   308 ML_file "Tools/Function/fun_cases.ML"
   309 
   310 setup ScnpReconstruct.setup
   311 
   312 ML_val -- "setup inactive"
   313 {*
   314   Context.theory_map (Function_Common.set_termination_prover
   315     (ScnpReconstruct.decomp_scnp_tac [ScnpSolve.MAX, ScnpSolve.MIN, ScnpSolve.MS]))
   316 *}
   317 
   318 end