src/HOL/Library/Polynomial.thy
author haftmann
Sun Mar 18 08:57:45 2012 +0100 (2012-03-18)
changeset 47002 9435d419109a
parent 46031 ac6bae9fdc2f
child 47108 2a1953f0d20d
permissions -rw-r--r--
comments for uniformity
     1 (*  Title:      HOL/Library/Polynomial.thy
     2     Author:     Brian Huffman
     3     Author:     Clemens Ballarin
     4 *)
     5 
     6 header {* Univariate Polynomials *}
     7 
     8 theory Polynomial
     9 imports Main
    10 begin
    11 
    12 subsection {* Definition of type @{text poly} *}
    13 
    14 definition "Poly = {f::nat \<Rightarrow> 'a::zero. \<exists>n. \<forall>i>n. f i = 0}"
    15 
    16 typedef (open) 'a poly = "Poly :: (nat => 'a::zero) set"
    17   morphisms coeff Abs_poly
    18   unfolding Poly_def by auto
    19 
    20 (* FIXME should be named poly_eq_iff *)
    21 lemma expand_poly_eq: "p = q \<longleftrightarrow> (\<forall>n. coeff p n = coeff q n)"
    22   by (simp add: coeff_inject [symmetric] fun_eq_iff)
    23 
    24 (* FIXME should be named poly_eqI *)
    25 lemma poly_ext: "(\<And>n. coeff p n = coeff q n) \<Longrightarrow> p = q"
    26   by (simp add: expand_poly_eq)
    27 
    28 
    29 subsection {* Degree of a polynomial *}
    30 
    31 definition
    32   degree :: "'a::zero poly \<Rightarrow> nat" where
    33   "degree p = (LEAST n. \<forall>i>n. coeff p i = 0)"
    34 
    35 lemma coeff_eq_0: "degree p < n \<Longrightarrow> coeff p n = 0"
    36 proof -
    37   have "coeff p \<in> Poly"
    38     by (rule coeff)
    39   hence "\<exists>n. \<forall>i>n. coeff p i = 0"
    40     unfolding Poly_def by simp
    41   hence "\<forall>i>degree p. coeff p i = 0"
    42     unfolding degree_def by (rule LeastI_ex)
    43   moreover assume "degree p < n"
    44   ultimately show ?thesis by simp
    45 qed
    46 
    47 lemma le_degree: "coeff p n \<noteq> 0 \<Longrightarrow> n \<le> degree p"
    48   by (erule contrapos_np, rule coeff_eq_0, simp)
    49 
    50 lemma degree_le: "\<forall>i>n. coeff p i = 0 \<Longrightarrow> degree p \<le> n"
    51   unfolding degree_def by (erule Least_le)
    52 
    53 lemma less_degree_imp: "n < degree p \<Longrightarrow> \<exists>i>n. coeff p i \<noteq> 0"
    54   unfolding degree_def by (drule not_less_Least, simp)
    55 
    56 
    57 subsection {* The zero polynomial *}
    58 
    59 instantiation poly :: (zero) zero
    60 begin
    61 
    62 definition
    63   zero_poly_def: "0 = Abs_poly (\<lambda>n. 0)"
    64 
    65 instance ..
    66 end
    67 
    68 lemma coeff_0 [simp]: "coeff 0 n = 0"
    69   unfolding zero_poly_def
    70   by (simp add: Abs_poly_inverse Poly_def)
    71 
    72 lemma degree_0 [simp]: "degree 0 = 0"
    73   by (rule order_antisym [OF degree_le le0]) simp
    74 
    75 lemma leading_coeff_neq_0:
    76   assumes "p \<noteq> 0" shows "coeff p (degree p) \<noteq> 0"
    77 proof (cases "degree p")
    78   case 0
    79   from `p \<noteq> 0` have "\<exists>n. coeff p n \<noteq> 0"
    80     by (simp add: expand_poly_eq)
    81   then obtain n where "coeff p n \<noteq> 0" ..
    82   hence "n \<le> degree p" by (rule le_degree)
    83   with `coeff p n \<noteq> 0` and `degree p = 0`
    84   show "coeff p (degree p) \<noteq> 0" by simp
    85 next
    86   case (Suc n)
    87   from `degree p = Suc n` have "n < degree p" by simp
    88   hence "\<exists>i>n. coeff p i \<noteq> 0" by (rule less_degree_imp)
    89   then obtain i where "n < i" and "coeff p i \<noteq> 0" by fast
    90   from `degree p = Suc n` and `n < i` have "degree p \<le> i" by simp
    91   also from `coeff p i \<noteq> 0` have "i \<le> degree p" by (rule le_degree)
    92   finally have "degree p = i" .
    93   with `coeff p i \<noteq> 0` show "coeff p (degree p) \<noteq> 0" by simp
    94 qed
    95 
    96 lemma leading_coeff_0_iff [simp]: "coeff p (degree p) = 0 \<longleftrightarrow> p = 0"
    97   by (cases "p = 0", simp, simp add: leading_coeff_neq_0)
    98 
    99 
   100 subsection {* List-style constructor for polynomials *}
   101 
   102 definition
   103   pCons :: "'a::zero \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
   104 where
   105   "pCons a p = Abs_poly (nat_case a (coeff p))"
   106 
   107 syntax
   108   "_poly" :: "args \<Rightarrow> 'a poly"  ("[:(_):]")
   109 
   110 translations
   111   "[:x, xs:]" == "CONST pCons x [:xs:]"
   112   "[:x:]" == "CONST pCons x 0"
   113   "[:x:]" <= "CONST pCons x (_constrain 0 t)"
   114 
   115 lemma Poly_nat_case: "f \<in> Poly \<Longrightarrow> nat_case a f \<in> Poly"
   116   unfolding Poly_def by (auto split: nat.split)
   117 
   118 lemma coeff_pCons:
   119   "coeff (pCons a p) = nat_case a (coeff p)"
   120   unfolding pCons_def
   121   by (simp add: Abs_poly_inverse Poly_nat_case coeff)
   122 
   123 lemma coeff_pCons_0 [simp]: "coeff (pCons a p) 0 = a"
   124   by (simp add: coeff_pCons)
   125 
   126 lemma coeff_pCons_Suc [simp]: "coeff (pCons a p) (Suc n) = coeff p n"
   127   by (simp add: coeff_pCons)
   128 
   129 lemma degree_pCons_le: "degree (pCons a p) \<le> Suc (degree p)"
   130 by (rule degree_le, simp add: coeff_eq_0 coeff_pCons split: nat.split)
   131 
   132 lemma degree_pCons_eq:
   133   "p \<noteq> 0 \<Longrightarrow> degree (pCons a p) = Suc (degree p)"
   134 apply (rule order_antisym [OF degree_pCons_le])
   135 apply (rule le_degree, simp)
   136 done
   137 
   138 lemma degree_pCons_0: "degree (pCons a 0) = 0"
   139 apply (rule order_antisym [OF _ le0])
   140 apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   141 done
   142 
   143 lemma degree_pCons_eq_if [simp]:
   144   "degree (pCons a p) = (if p = 0 then 0 else Suc (degree p))"
   145 apply (cases "p = 0", simp_all)
   146 apply (rule order_antisym [OF _ le0])
   147 apply (rule degree_le, simp add: coeff_pCons split: nat.split)
   148 apply (rule order_antisym [OF degree_pCons_le])
   149 apply (rule le_degree, simp)
   150 done
   151 
   152 lemma pCons_0_0 [simp, code_post]: "pCons 0 0 = 0"
   153 by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   154 
   155 lemma pCons_eq_iff [simp]:
   156   "pCons a p = pCons b q \<longleftrightarrow> a = b \<and> p = q"
   157 proof (safe)
   158   assume "pCons a p = pCons b q"
   159   then have "coeff (pCons a p) 0 = coeff (pCons b q) 0" by simp
   160   then show "a = b" by simp
   161 next
   162   assume "pCons a p = pCons b q"
   163   then have "\<forall>n. coeff (pCons a p) (Suc n) =
   164                  coeff (pCons b q) (Suc n)" by simp
   165   then show "p = q" by (simp add: expand_poly_eq)
   166 qed
   167 
   168 lemma pCons_eq_0_iff [simp]: "pCons a p = 0 \<longleftrightarrow> a = 0 \<and> p = 0"
   169   using pCons_eq_iff [of a p 0 0] by simp
   170 
   171 lemma Poly_Suc: "f \<in> Poly \<Longrightarrow> (\<lambda>n. f (Suc n)) \<in> Poly"
   172   unfolding Poly_def
   173   by (clarify, rule_tac x=n in exI, simp)
   174 
   175 lemma pCons_cases [cases type: poly]:
   176   obtains (pCons) a q where "p = pCons a q"
   177 proof
   178   show "p = pCons (coeff p 0) (Abs_poly (\<lambda>n. coeff p (Suc n)))"
   179     by (rule poly_ext)
   180        (simp add: Abs_poly_inverse Poly_Suc coeff coeff_pCons
   181              split: nat.split)
   182 qed
   183 
   184 lemma pCons_induct [case_names 0 pCons, induct type: poly]:
   185   assumes zero: "P 0"
   186   assumes pCons: "\<And>a p. P p \<Longrightarrow> P (pCons a p)"
   187   shows "P p"
   188 proof (induct p rule: measure_induct_rule [where f=degree])
   189   case (less p)
   190   obtain a q where "p = pCons a q" by (rule pCons_cases)
   191   have "P q"
   192   proof (cases "q = 0")
   193     case True
   194     then show "P q" by (simp add: zero)
   195   next
   196     case False
   197     then have "degree (pCons a q) = Suc (degree q)"
   198       by (rule degree_pCons_eq)
   199     then have "degree q < degree p"
   200       using `p = pCons a q` by simp
   201     then show "P q"
   202       by (rule less.hyps)
   203   qed
   204   then have "P (pCons a q)"
   205     by (rule pCons)
   206   then show ?case
   207     using `p = pCons a q` by simp
   208 qed
   209 
   210 
   211 subsection {* Recursion combinator for polynomials *}
   212 
   213 function
   214   poly_rec :: "'b \<Rightarrow> ('a::zero \<Rightarrow> 'a poly \<Rightarrow> 'b \<Rightarrow> 'b) \<Rightarrow> 'a poly \<Rightarrow> 'b"
   215 where
   216   poly_rec_pCons_eq_if [simp del]:
   217     "poly_rec z f (pCons a p) = f a p (if p = 0 then z else poly_rec z f p)"
   218 by (case_tac x, rename_tac q, case_tac q, auto)
   219 
   220 termination poly_rec
   221 by (relation "measure (degree \<circ> snd \<circ> snd)", simp)
   222    (simp add: degree_pCons_eq)
   223 
   224 lemma poly_rec_0:
   225   "f 0 0 z = z \<Longrightarrow> poly_rec z f 0 = z"
   226   using poly_rec_pCons_eq_if [of z f 0 0] by simp
   227 
   228 lemma poly_rec_pCons:
   229   "f 0 0 z = z \<Longrightarrow> poly_rec z f (pCons a p) = f a p (poly_rec z f p)"
   230   by (simp add: poly_rec_pCons_eq_if poly_rec_0)
   231 
   232 
   233 subsection {* Monomials *}
   234 
   235 definition
   236   monom :: "'a \<Rightarrow> nat \<Rightarrow> 'a::zero poly" where
   237   "monom a m = Abs_poly (\<lambda>n. if m = n then a else 0)"
   238 
   239 lemma coeff_monom [simp]: "coeff (monom a m) n = (if m=n then a else 0)"
   240   unfolding monom_def
   241   by (subst Abs_poly_inverse, auto simp add: Poly_def)
   242 
   243 lemma monom_0: "monom a 0 = pCons a 0"
   244   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   245 
   246 lemma monom_Suc: "monom a (Suc n) = pCons 0 (monom a n)"
   247   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   248 
   249 lemma monom_eq_0 [simp]: "monom 0 n = 0"
   250   by (rule poly_ext) simp
   251 
   252 lemma monom_eq_0_iff [simp]: "monom a n = 0 \<longleftrightarrow> a = 0"
   253   by (simp add: expand_poly_eq)
   254 
   255 lemma monom_eq_iff [simp]: "monom a n = monom b n \<longleftrightarrow> a = b"
   256   by (simp add: expand_poly_eq)
   257 
   258 lemma degree_monom_le: "degree (monom a n) \<le> n"
   259   by (rule degree_le, simp)
   260 
   261 lemma degree_monom_eq: "a \<noteq> 0 \<Longrightarrow> degree (monom a n) = n"
   262   apply (rule order_antisym [OF degree_monom_le])
   263   apply (rule le_degree, simp)
   264   done
   265 
   266 
   267 subsection {* Addition and subtraction *}
   268 
   269 instantiation poly :: (comm_monoid_add) comm_monoid_add
   270 begin
   271 
   272 definition
   273   plus_poly_def:
   274     "p + q = Abs_poly (\<lambda>n. coeff p n + coeff q n)"
   275 
   276 lemma Poly_add:
   277   fixes f g :: "nat \<Rightarrow> 'a"
   278   shows "\<lbrakk>f \<in> Poly; g \<in> Poly\<rbrakk> \<Longrightarrow> (\<lambda>n. f n + g n) \<in> Poly"
   279   unfolding Poly_def
   280   apply (clarify, rename_tac m n)
   281   apply (rule_tac x="max m n" in exI, simp)
   282   done
   283 
   284 lemma coeff_add [simp]:
   285   "coeff (p + q) n = coeff p n + coeff q n"
   286   unfolding plus_poly_def
   287   by (simp add: Abs_poly_inverse coeff Poly_add)
   288 
   289 instance proof
   290   fix p q r :: "'a poly"
   291   show "(p + q) + r = p + (q + r)"
   292     by (simp add: expand_poly_eq add_assoc)
   293   show "p + q = q + p"
   294     by (simp add: expand_poly_eq add_commute)
   295   show "0 + p = p"
   296     by (simp add: expand_poly_eq)
   297 qed
   298 
   299 end
   300 
   301 instance poly :: (cancel_comm_monoid_add) cancel_comm_monoid_add
   302 proof
   303   fix p q r :: "'a poly"
   304   assume "p + q = p + r" thus "q = r"
   305     by (simp add: expand_poly_eq)
   306 qed
   307 
   308 instantiation poly :: (ab_group_add) ab_group_add
   309 begin
   310 
   311 definition
   312   uminus_poly_def:
   313     "- p = Abs_poly (\<lambda>n. - coeff p n)"
   314 
   315 definition
   316   minus_poly_def:
   317     "p - q = Abs_poly (\<lambda>n. coeff p n - coeff q n)"
   318 
   319 lemma Poly_minus:
   320   fixes f :: "nat \<Rightarrow> 'a"
   321   shows "f \<in> Poly \<Longrightarrow> (\<lambda>n. - f n) \<in> Poly"
   322   unfolding Poly_def by simp
   323 
   324 lemma Poly_diff:
   325   fixes f g :: "nat \<Rightarrow> 'a"
   326   shows "\<lbrakk>f \<in> Poly; g \<in> Poly\<rbrakk> \<Longrightarrow> (\<lambda>n. f n - g n) \<in> Poly"
   327   unfolding diff_minus by (simp add: Poly_add Poly_minus)
   328 
   329 lemma coeff_minus [simp]: "coeff (- p) n = - coeff p n"
   330   unfolding uminus_poly_def
   331   by (simp add: Abs_poly_inverse coeff Poly_minus)
   332 
   333 lemma coeff_diff [simp]:
   334   "coeff (p - q) n = coeff p n - coeff q n"
   335   unfolding minus_poly_def
   336   by (simp add: Abs_poly_inverse coeff Poly_diff)
   337 
   338 instance proof
   339   fix p q :: "'a poly"
   340   show "- p + p = 0"
   341     by (simp add: expand_poly_eq)
   342   show "p - q = p + - q"
   343     by (simp add: expand_poly_eq diff_minus)
   344 qed
   345 
   346 end
   347 
   348 lemma add_pCons [simp]:
   349   "pCons a p + pCons b q = pCons (a + b) (p + q)"
   350   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   351 
   352 lemma minus_pCons [simp]:
   353   "- pCons a p = pCons (- a) (- p)"
   354   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   355 
   356 lemma diff_pCons [simp]:
   357   "pCons a p - pCons b q = pCons (a - b) (p - q)"
   358   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   359 
   360 lemma degree_add_le_max: "degree (p + q) \<le> max (degree p) (degree q)"
   361   by (rule degree_le, auto simp add: coeff_eq_0)
   362 
   363 lemma degree_add_le:
   364   "\<lbrakk>degree p \<le> n; degree q \<le> n\<rbrakk> \<Longrightarrow> degree (p + q) \<le> n"
   365   by (auto intro: order_trans degree_add_le_max)
   366 
   367 lemma degree_add_less:
   368   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p + q) < n"
   369   by (auto intro: le_less_trans degree_add_le_max)
   370 
   371 lemma degree_add_eq_right:
   372   "degree p < degree q \<Longrightarrow> degree (p + q) = degree q"
   373   apply (cases "q = 0", simp)
   374   apply (rule order_antisym)
   375   apply (simp add: degree_add_le)
   376   apply (rule le_degree)
   377   apply (simp add: coeff_eq_0)
   378   done
   379 
   380 lemma degree_add_eq_left:
   381   "degree q < degree p \<Longrightarrow> degree (p + q) = degree p"
   382   using degree_add_eq_right [of q p]
   383   by (simp add: add_commute)
   384 
   385 lemma degree_minus [simp]: "degree (- p) = degree p"
   386   unfolding degree_def by simp
   387 
   388 lemma degree_diff_le_max: "degree (p - q) \<le> max (degree p) (degree q)"
   389   using degree_add_le [where p=p and q="-q"]
   390   by (simp add: diff_minus)
   391 
   392 lemma degree_diff_le:
   393   "\<lbrakk>degree p \<le> n; degree q \<le> n\<rbrakk> \<Longrightarrow> degree (p - q) \<le> n"
   394   by (simp add: diff_minus degree_add_le)
   395 
   396 lemma degree_diff_less:
   397   "\<lbrakk>degree p < n; degree q < n\<rbrakk> \<Longrightarrow> degree (p - q) < n"
   398   by (simp add: diff_minus degree_add_less)
   399 
   400 lemma add_monom: "monom a n + monom b n = monom (a + b) n"
   401   by (rule poly_ext) simp
   402 
   403 lemma diff_monom: "monom a n - monom b n = monom (a - b) n"
   404   by (rule poly_ext) simp
   405 
   406 lemma minus_monom: "- monom a n = monom (-a) n"
   407   by (rule poly_ext) simp
   408 
   409 lemma coeff_setsum: "coeff (\<Sum>x\<in>A. p x) i = (\<Sum>x\<in>A. coeff (p x) i)"
   410   by (cases "finite A", induct set: finite, simp_all)
   411 
   412 lemma monom_setsum: "monom (\<Sum>x\<in>A. a x) n = (\<Sum>x\<in>A. monom (a x) n)"
   413   by (rule poly_ext) (simp add: coeff_setsum)
   414 
   415 
   416 subsection {* Multiplication by a constant *}
   417 
   418 definition
   419   smult :: "'a::comm_semiring_0 \<Rightarrow> 'a poly \<Rightarrow> 'a poly" where
   420   "smult a p = Abs_poly (\<lambda>n. a * coeff p n)"
   421 
   422 lemma Poly_smult:
   423   fixes f :: "nat \<Rightarrow> 'a::comm_semiring_0"
   424   shows "f \<in> Poly \<Longrightarrow> (\<lambda>n. a * f n) \<in> Poly"
   425   unfolding Poly_def
   426   by (clarify, rule_tac x=n in exI, simp)
   427 
   428 lemma coeff_smult [simp]: "coeff (smult a p) n = a * coeff p n"
   429   unfolding smult_def
   430   by (simp add: Abs_poly_inverse Poly_smult coeff)
   431 
   432 lemma degree_smult_le: "degree (smult a p) \<le> degree p"
   433   by (rule degree_le, simp add: coeff_eq_0)
   434 
   435 lemma smult_smult [simp]: "smult a (smult b p) = smult (a * b) p"
   436   by (rule poly_ext, simp add: mult_assoc)
   437 
   438 lemma smult_0_right [simp]: "smult a 0 = 0"
   439   by (rule poly_ext, simp)
   440 
   441 lemma smult_0_left [simp]: "smult 0 p = 0"
   442   by (rule poly_ext, simp)
   443 
   444 lemma smult_1_left [simp]: "smult (1::'a::comm_semiring_1) p = p"
   445   by (rule poly_ext, simp)
   446 
   447 lemma smult_add_right:
   448   "smult a (p + q) = smult a p + smult a q"
   449   by (rule poly_ext, simp add: algebra_simps)
   450 
   451 lemma smult_add_left:
   452   "smult (a + b) p = smult a p + smult b p"
   453   by (rule poly_ext, simp add: algebra_simps)
   454 
   455 lemma smult_minus_right [simp]:
   456   "smult (a::'a::comm_ring) (- p) = - smult a p"
   457   by (rule poly_ext, simp)
   458 
   459 lemma smult_minus_left [simp]:
   460   "smult (- a::'a::comm_ring) p = - smult a p"
   461   by (rule poly_ext, simp)
   462 
   463 lemma smult_diff_right:
   464   "smult (a::'a::comm_ring) (p - q) = smult a p - smult a q"
   465   by (rule poly_ext, simp add: algebra_simps)
   466 
   467 lemma smult_diff_left:
   468   "smult (a - b::'a::comm_ring) p = smult a p - smult b p"
   469   by (rule poly_ext, simp add: algebra_simps)
   470 
   471 lemmas smult_distribs =
   472   smult_add_left smult_add_right
   473   smult_diff_left smult_diff_right
   474 
   475 lemma smult_pCons [simp]:
   476   "smult a (pCons b p) = pCons (a * b) (smult a p)"
   477   by (rule poly_ext, simp add: coeff_pCons split: nat.split)
   478 
   479 lemma smult_monom: "smult a (monom b n) = monom (a * b) n"
   480   by (induct n, simp add: monom_0, simp add: monom_Suc)
   481 
   482 lemma degree_smult_eq [simp]:
   483   fixes a :: "'a::idom"
   484   shows "degree (smult a p) = (if a = 0 then 0 else degree p)"
   485   by (cases "a = 0", simp, simp add: degree_def)
   486 
   487 lemma smult_eq_0_iff [simp]:
   488   fixes a :: "'a::idom"
   489   shows "smult a p = 0 \<longleftrightarrow> a = 0 \<or> p = 0"
   490   by (simp add: expand_poly_eq)
   491 
   492 
   493 subsection {* Multiplication of polynomials *}
   494 
   495 text {* TODO: move to SetInterval.thy *}
   496 lemma setsum_atMost_Suc_shift:
   497   fixes f :: "nat \<Rightarrow> 'a::comm_monoid_add"
   498   shows "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
   499 proof (induct n)
   500   case 0 show ?case by simp
   501 next
   502   case (Suc n) note IH = this
   503   have "(\<Sum>i\<le>Suc (Suc n). f i) = (\<Sum>i\<le>Suc n. f i) + f (Suc (Suc n))"
   504     by (rule setsum_atMost_Suc)
   505   also have "(\<Sum>i\<le>Suc n. f i) = f 0 + (\<Sum>i\<le>n. f (Suc i))"
   506     by (rule IH)
   507   also have "f 0 + (\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) =
   508              f 0 + ((\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)))"
   509     by (rule add_assoc)
   510   also have "(\<Sum>i\<le>n. f (Suc i)) + f (Suc (Suc n)) = (\<Sum>i\<le>Suc n. f (Suc i))"
   511     by (rule setsum_atMost_Suc [symmetric])
   512   finally show ?case .
   513 qed
   514 
   515 instantiation poly :: (comm_semiring_0) comm_semiring_0
   516 begin
   517 
   518 definition
   519   times_poly_def:
   520     "p * q = poly_rec 0 (\<lambda>a p pq. smult a q + pCons 0 pq) p"
   521 
   522 lemma mult_poly_0_left: "(0::'a poly) * q = 0"
   523   unfolding times_poly_def by (simp add: poly_rec_0)
   524 
   525 lemma mult_pCons_left [simp]:
   526   "pCons a p * q = smult a q + pCons 0 (p * q)"
   527   unfolding times_poly_def by (simp add: poly_rec_pCons)
   528 
   529 lemma mult_poly_0_right: "p * (0::'a poly) = 0"
   530   by (induct p, simp add: mult_poly_0_left, simp)
   531 
   532 lemma mult_pCons_right [simp]:
   533   "p * pCons a q = smult a p + pCons 0 (p * q)"
   534   by (induct p, simp add: mult_poly_0_left, simp add: algebra_simps)
   535 
   536 lemmas mult_poly_0 = mult_poly_0_left mult_poly_0_right
   537 
   538 lemma mult_smult_left [simp]: "smult a p * q = smult a (p * q)"
   539   by (induct p, simp add: mult_poly_0, simp add: smult_add_right)
   540 
   541 lemma mult_smult_right [simp]: "p * smult a q = smult a (p * q)"
   542   by (induct q, simp add: mult_poly_0, simp add: smult_add_right)
   543 
   544 lemma mult_poly_add_left:
   545   fixes p q r :: "'a poly"
   546   shows "(p + q) * r = p * r + q * r"
   547   by (induct r, simp add: mult_poly_0,
   548                 simp add: smult_distribs algebra_simps)
   549 
   550 instance proof
   551   fix p q r :: "'a poly"
   552   show 0: "0 * p = 0"
   553     by (rule mult_poly_0_left)
   554   show "p * 0 = 0"
   555     by (rule mult_poly_0_right)
   556   show "(p + q) * r = p * r + q * r"
   557     by (rule mult_poly_add_left)
   558   show "(p * q) * r = p * (q * r)"
   559     by (induct p, simp add: mult_poly_0, simp add: mult_poly_add_left)
   560   show "p * q = q * p"
   561     by (induct p, simp add: mult_poly_0, simp)
   562 qed
   563 
   564 end
   565 
   566 instance poly :: (comm_semiring_0_cancel) comm_semiring_0_cancel ..
   567 
   568 lemma coeff_mult:
   569   "coeff (p * q) n = (\<Sum>i\<le>n. coeff p i * coeff q (n-i))"
   570 proof (induct p arbitrary: n)
   571   case 0 show ?case by simp
   572 next
   573   case (pCons a p n) thus ?case
   574     by (cases n, simp, simp add: setsum_atMost_Suc_shift
   575                             del: setsum_atMost_Suc)
   576 qed
   577 
   578 lemma degree_mult_le: "degree (p * q) \<le> degree p + degree q"
   579 apply (rule degree_le)
   580 apply (induct p)
   581 apply simp
   582 apply (simp add: coeff_eq_0 coeff_pCons split: nat.split)
   583 done
   584 
   585 lemma mult_monom: "monom a m * monom b n = monom (a * b) (m + n)"
   586   by (induct m, simp add: monom_0 smult_monom, simp add: monom_Suc)
   587 
   588 
   589 subsection {* The unit polynomial and exponentiation *}
   590 
   591 instantiation poly :: (comm_semiring_1) comm_semiring_1
   592 begin
   593 
   594 definition
   595   one_poly_def:
   596     "1 = pCons 1 0"
   597 
   598 instance proof
   599   fix p :: "'a poly" show "1 * p = p"
   600     unfolding one_poly_def
   601     by simp
   602 next
   603   show "0 \<noteq> (1::'a poly)"
   604     unfolding one_poly_def by simp
   605 qed
   606 
   607 end
   608 
   609 instance poly :: (comm_semiring_1_cancel) comm_semiring_1_cancel ..
   610 
   611 lemma coeff_1 [simp]: "coeff 1 n = (if n = 0 then 1 else 0)"
   612   unfolding one_poly_def
   613   by (simp add: coeff_pCons split: nat.split)
   614 
   615 lemma degree_1 [simp]: "degree 1 = 0"
   616   unfolding one_poly_def
   617   by (rule degree_pCons_0)
   618 
   619 text {* Lemmas about divisibility *}
   620 
   621 lemma dvd_smult: "p dvd q \<Longrightarrow> p dvd smult a q"
   622 proof -
   623   assume "p dvd q"
   624   then obtain k where "q = p * k" ..
   625   then have "smult a q = p * smult a k" by simp
   626   then show "p dvd smult a q" ..
   627 qed
   628 
   629 lemma dvd_smult_cancel:
   630   fixes a :: "'a::field"
   631   shows "p dvd smult a q \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> p dvd q"
   632   by (drule dvd_smult [where a="inverse a"]) simp
   633 
   634 lemma dvd_smult_iff:
   635   fixes a :: "'a::field"
   636   shows "a \<noteq> 0 \<Longrightarrow> p dvd smult a q \<longleftrightarrow> p dvd q"
   637   by (safe elim!: dvd_smult dvd_smult_cancel)
   638 
   639 lemma smult_dvd_cancel:
   640   "smult a p dvd q \<Longrightarrow> p dvd q"
   641 proof -
   642   assume "smult a p dvd q"
   643   then obtain k where "q = smult a p * k" ..
   644   then have "q = p * smult a k" by simp
   645   then show "p dvd q" ..
   646 qed
   647 
   648 lemma smult_dvd:
   649   fixes a :: "'a::field"
   650   shows "p dvd q \<Longrightarrow> a \<noteq> 0 \<Longrightarrow> smult a p dvd q"
   651   by (rule smult_dvd_cancel [where a="inverse a"]) simp
   652 
   653 lemma smult_dvd_iff:
   654   fixes a :: "'a::field"
   655   shows "smult a p dvd q \<longleftrightarrow> (if a = 0 then q = 0 else p dvd q)"
   656   by (auto elim: smult_dvd smult_dvd_cancel)
   657 
   658 lemma degree_power_le: "degree (p ^ n) \<le> degree p * n"
   659 by (induct n, simp, auto intro: order_trans degree_mult_le)
   660 
   661 instance poly :: (comm_ring) comm_ring ..
   662 
   663 instance poly :: (comm_ring_1) comm_ring_1 ..
   664 
   665 instantiation poly :: (comm_ring_1) number_ring
   666 begin
   667 
   668 definition
   669   "number_of k = (of_int k :: 'a poly)"
   670 
   671 instance
   672   by default (rule number_of_poly_def)
   673 
   674 end
   675 
   676 
   677 subsection {* Polynomials form an integral domain *}
   678 
   679 lemma coeff_mult_degree_sum:
   680   "coeff (p * q) (degree p + degree q) =
   681    coeff p (degree p) * coeff q (degree q)"
   682   by (induct p, simp, simp add: coeff_eq_0)
   683 
   684 instance poly :: (idom) idom
   685 proof
   686   fix p q :: "'a poly"
   687   assume "p \<noteq> 0" and "q \<noteq> 0"
   688   have "coeff (p * q) (degree p + degree q) =
   689         coeff p (degree p) * coeff q (degree q)"
   690     by (rule coeff_mult_degree_sum)
   691   also have "coeff p (degree p) * coeff q (degree q) \<noteq> 0"
   692     using `p \<noteq> 0` and `q \<noteq> 0` by simp
   693   finally have "\<exists>n. coeff (p * q) n \<noteq> 0" ..
   694   thus "p * q \<noteq> 0" by (simp add: expand_poly_eq)
   695 qed
   696 
   697 lemma degree_mult_eq:
   698   fixes p q :: "'a::idom poly"
   699   shows "\<lbrakk>p \<noteq> 0; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree (p * q) = degree p + degree q"
   700 apply (rule order_antisym [OF degree_mult_le le_degree])
   701 apply (simp add: coeff_mult_degree_sum)
   702 done
   703 
   704 lemma dvd_imp_degree_le:
   705   fixes p q :: "'a::idom poly"
   706   shows "\<lbrakk>p dvd q; q \<noteq> 0\<rbrakk> \<Longrightarrow> degree p \<le> degree q"
   707   by (erule dvdE, simp add: degree_mult_eq)
   708 
   709 
   710 subsection {* Polynomials form an ordered integral domain *}
   711 
   712 definition
   713   pos_poly :: "'a::linordered_idom poly \<Rightarrow> bool"
   714 where
   715   "pos_poly p \<longleftrightarrow> 0 < coeff p (degree p)"
   716 
   717 lemma pos_poly_pCons:
   718   "pos_poly (pCons a p) \<longleftrightarrow> pos_poly p \<or> (p = 0 \<and> 0 < a)"
   719   unfolding pos_poly_def by simp
   720 
   721 lemma not_pos_poly_0 [simp]: "\<not> pos_poly 0"
   722   unfolding pos_poly_def by simp
   723 
   724 lemma pos_poly_add: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p + q)"
   725   apply (induct p arbitrary: q, simp)
   726   apply (case_tac q, force simp add: pos_poly_pCons add_pos_pos)
   727   done
   728 
   729 lemma pos_poly_mult: "\<lbrakk>pos_poly p; pos_poly q\<rbrakk> \<Longrightarrow> pos_poly (p * q)"
   730   unfolding pos_poly_def
   731   apply (subgoal_tac "p \<noteq> 0 \<and> q \<noteq> 0")
   732   apply (simp add: degree_mult_eq coeff_mult_degree_sum mult_pos_pos)
   733   apply auto
   734   done
   735 
   736 lemma pos_poly_total: "p = 0 \<or> pos_poly p \<or> pos_poly (- p)"
   737 by (induct p) (auto simp add: pos_poly_pCons)
   738 
   739 instantiation poly :: (linordered_idom) linordered_idom
   740 begin
   741 
   742 definition
   743   "x < y \<longleftrightarrow> pos_poly (y - x)"
   744 
   745 definition
   746   "x \<le> y \<longleftrightarrow> x = y \<or> pos_poly (y - x)"
   747 
   748 definition
   749   "abs (x::'a poly) = (if x < 0 then - x else x)"
   750 
   751 definition
   752   "sgn (x::'a poly) = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
   753 
   754 instance proof
   755   fix x y :: "'a poly"
   756   show "x < y \<longleftrightarrow> x \<le> y \<and> \<not> y \<le> x"
   757     unfolding less_eq_poly_def less_poly_def
   758     apply safe
   759     apply simp
   760     apply (drule (1) pos_poly_add)
   761     apply simp
   762     done
   763 next
   764   fix x :: "'a poly" show "x \<le> x"
   765     unfolding less_eq_poly_def by simp
   766 next
   767   fix x y z :: "'a poly"
   768   assume "x \<le> y" and "y \<le> z" thus "x \<le> z"
   769     unfolding less_eq_poly_def
   770     apply safe
   771     apply (drule (1) pos_poly_add)
   772     apply (simp add: algebra_simps)
   773     done
   774 next
   775   fix x y :: "'a poly"
   776   assume "x \<le> y" and "y \<le> x" thus "x = y"
   777     unfolding less_eq_poly_def
   778     apply safe
   779     apply (drule (1) pos_poly_add)
   780     apply simp
   781     done
   782 next
   783   fix x y z :: "'a poly"
   784   assume "x \<le> y" thus "z + x \<le> z + y"
   785     unfolding less_eq_poly_def
   786     apply safe
   787     apply (simp add: algebra_simps)
   788     done
   789 next
   790   fix x y :: "'a poly"
   791   show "x \<le> y \<or> y \<le> x"
   792     unfolding less_eq_poly_def
   793     using pos_poly_total [of "x - y"]
   794     by auto
   795 next
   796   fix x y z :: "'a poly"
   797   assume "x < y" and "0 < z"
   798   thus "z * x < z * y"
   799     unfolding less_poly_def
   800     by (simp add: right_diff_distrib [symmetric] pos_poly_mult)
   801 next
   802   fix x :: "'a poly"
   803   show "\<bar>x\<bar> = (if x < 0 then - x else x)"
   804     by (rule abs_poly_def)
   805 next
   806   fix x :: "'a poly"
   807   show "sgn x = (if x = 0 then 0 else if 0 < x then 1 else - 1)"
   808     by (rule sgn_poly_def)
   809 qed
   810 
   811 end
   812 
   813 text {* TODO: Simplification rules for comparisons *}
   814 
   815 
   816 subsection {* Long division of polynomials *}
   817 
   818 definition
   819   pdivmod_rel :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<Rightarrow> bool"
   820 where
   821   "pdivmod_rel x y q r \<longleftrightarrow>
   822     x = q * y + r \<and> (if y = 0 then q = 0 else r = 0 \<or> degree r < degree y)"
   823 
   824 lemma pdivmod_rel_0:
   825   "pdivmod_rel 0 y 0 0"
   826   unfolding pdivmod_rel_def by simp
   827 
   828 lemma pdivmod_rel_by_0:
   829   "pdivmod_rel x 0 0 x"
   830   unfolding pdivmod_rel_def by simp
   831 
   832 lemma eq_zero_or_degree_less:
   833   assumes "degree p \<le> n" and "coeff p n = 0"
   834   shows "p = 0 \<or> degree p < n"
   835 proof (cases n)
   836   case 0
   837   with `degree p \<le> n` and `coeff p n = 0`
   838   have "coeff p (degree p) = 0" by simp
   839   then have "p = 0" by simp
   840   then show ?thesis ..
   841 next
   842   case (Suc m)
   843   have "\<forall>i>n. coeff p i = 0"
   844     using `degree p \<le> n` by (simp add: coeff_eq_0)
   845   then have "\<forall>i\<ge>n. coeff p i = 0"
   846     using `coeff p n = 0` by (simp add: le_less)
   847   then have "\<forall>i>m. coeff p i = 0"
   848     using `n = Suc m` by (simp add: less_eq_Suc_le)
   849   then have "degree p \<le> m"
   850     by (rule degree_le)
   851   then have "degree p < n"
   852     using `n = Suc m` by (simp add: less_Suc_eq_le)
   853   then show ?thesis ..
   854 qed
   855 
   856 lemma pdivmod_rel_pCons:
   857   assumes rel: "pdivmod_rel x y q r"
   858   assumes y: "y \<noteq> 0"
   859   assumes b: "b = coeff (pCons a r) (degree y) / coeff y (degree y)"
   860   shows "pdivmod_rel (pCons a x) y (pCons b q) (pCons a r - smult b y)"
   861     (is "pdivmod_rel ?x y ?q ?r")
   862 proof -
   863   have x: "x = q * y + r" and r: "r = 0 \<or> degree r < degree y"
   864     using assms unfolding pdivmod_rel_def by simp_all
   865 
   866   have 1: "?x = ?q * y + ?r"
   867     using b x by simp
   868 
   869   have 2: "?r = 0 \<or> degree ?r < degree y"
   870   proof (rule eq_zero_or_degree_less)
   871     show "degree ?r \<le> degree y"
   872     proof (rule degree_diff_le)
   873       show "degree (pCons a r) \<le> degree y"
   874         using r by auto
   875       show "degree (smult b y) \<le> degree y"
   876         by (rule degree_smult_le)
   877     qed
   878   next
   879     show "coeff ?r (degree y) = 0"
   880       using `y \<noteq> 0` unfolding b by simp
   881   qed
   882 
   883   from 1 2 show ?thesis
   884     unfolding pdivmod_rel_def
   885     using `y \<noteq> 0` by simp
   886 qed
   887 
   888 lemma pdivmod_rel_exists: "\<exists>q r. pdivmod_rel x y q r"
   889 apply (cases "y = 0")
   890 apply (fast intro!: pdivmod_rel_by_0)
   891 apply (induct x)
   892 apply (fast intro!: pdivmod_rel_0)
   893 apply (fast intro!: pdivmod_rel_pCons)
   894 done
   895 
   896 lemma pdivmod_rel_unique:
   897   assumes 1: "pdivmod_rel x y q1 r1"
   898   assumes 2: "pdivmod_rel x y q2 r2"
   899   shows "q1 = q2 \<and> r1 = r2"
   900 proof (cases "y = 0")
   901   assume "y = 0" with assms show ?thesis
   902     by (simp add: pdivmod_rel_def)
   903 next
   904   assume [simp]: "y \<noteq> 0"
   905   from 1 have q1: "x = q1 * y + r1" and r1: "r1 = 0 \<or> degree r1 < degree y"
   906     unfolding pdivmod_rel_def by simp_all
   907   from 2 have q2: "x = q2 * y + r2" and r2: "r2 = 0 \<or> degree r2 < degree y"
   908     unfolding pdivmod_rel_def by simp_all
   909   from q1 q2 have q3: "(q1 - q2) * y = r2 - r1"
   910     by (simp add: algebra_simps)
   911   from r1 r2 have r3: "(r2 - r1) = 0 \<or> degree (r2 - r1) < degree y"
   912     by (auto intro: degree_diff_less)
   913 
   914   show "q1 = q2 \<and> r1 = r2"
   915   proof (rule ccontr)
   916     assume "\<not> (q1 = q2 \<and> r1 = r2)"
   917     with q3 have "q1 \<noteq> q2" and "r1 \<noteq> r2" by auto
   918     with r3 have "degree (r2 - r1) < degree y" by simp
   919     also have "degree y \<le> degree (q1 - q2) + degree y" by simp
   920     also have "\<dots> = degree ((q1 - q2) * y)"
   921       using `q1 \<noteq> q2` by (simp add: degree_mult_eq)
   922     also have "\<dots> = degree (r2 - r1)"
   923       using q3 by simp
   924     finally have "degree (r2 - r1) < degree (r2 - r1)" .
   925     then show "False" by simp
   926   qed
   927 qed
   928 
   929 lemma pdivmod_rel_0_iff: "pdivmod_rel 0 y q r \<longleftrightarrow> q = 0 \<and> r = 0"
   930 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_0)
   931 
   932 lemma pdivmod_rel_by_0_iff: "pdivmod_rel x 0 q r \<longleftrightarrow> q = 0 \<and> r = x"
   933 by (auto dest: pdivmod_rel_unique intro: pdivmod_rel_by_0)
   934 
   935 lemmas pdivmod_rel_unique_div = pdivmod_rel_unique [THEN conjunct1]
   936 
   937 lemmas pdivmod_rel_unique_mod = pdivmod_rel_unique [THEN conjunct2]
   938 
   939 instantiation poly :: (field) ring_div
   940 begin
   941 
   942 definition div_poly where
   943   "x div y = (THE q. \<exists>r. pdivmod_rel x y q r)"
   944 
   945 definition mod_poly where
   946   "x mod y = (THE r. \<exists>q. pdivmod_rel x y q r)"
   947 
   948 lemma div_poly_eq:
   949   "pdivmod_rel x y q r \<Longrightarrow> x div y = q"
   950 unfolding div_poly_def
   951 by (fast elim: pdivmod_rel_unique_div)
   952 
   953 lemma mod_poly_eq:
   954   "pdivmod_rel x y q r \<Longrightarrow> x mod y = r"
   955 unfolding mod_poly_def
   956 by (fast elim: pdivmod_rel_unique_mod)
   957 
   958 lemma pdivmod_rel:
   959   "pdivmod_rel x y (x div y) (x mod y)"
   960 proof -
   961   from pdivmod_rel_exists
   962     obtain q r where "pdivmod_rel x y q r" by fast
   963   thus ?thesis
   964     by (simp add: div_poly_eq mod_poly_eq)
   965 qed
   966 
   967 instance proof
   968   fix x y :: "'a poly"
   969   show "x div y * y + x mod y = x"
   970     using pdivmod_rel [of x y]
   971     by (simp add: pdivmod_rel_def)
   972 next
   973   fix x :: "'a poly"
   974   have "pdivmod_rel x 0 0 x"
   975     by (rule pdivmod_rel_by_0)
   976   thus "x div 0 = 0"
   977     by (rule div_poly_eq)
   978 next
   979   fix y :: "'a poly"
   980   have "pdivmod_rel 0 y 0 0"
   981     by (rule pdivmod_rel_0)
   982   thus "0 div y = 0"
   983     by (rule div_poly_eq)
   984 next
   985   fix x y z :: "'a poly"
   986   assume "y \<noteq> 0"
   987   hence "pdivmod_rel (x + z * y) y (z + x div y) (x mod y)"
   988     using pdivmod_rel [of x y]
   989     by (simp add: pdivmod_rel_def left_distrib)
   990   thus "(x + z * y) div y = z + x div y"
   991     by (rule div_poly_eq)
   992 next
   993   fix x y z :: "'a poly"
   994   assume "x \<noteq> 0"
   995   show "(x * y) div (x * z) = y div z"
   996   proof (cases "y \<noteq> 0 \<and> z \<noteq> 0")
   997     have "\<And>x::'a poly. pdivmod_rel x 0 0 x"
   998       by (rule pdivmod_rel_by_0)
   999     then have [simp]: "\<And>x::'a poly. x div 0 = 0"
  1000       by (rule div_poly_eq)
  1001     have "\<And>x::'a poly. pdivmod_rel 0 x 0 0"
  1002       by (rule pdivmod_rel_0)
  1003     then have [simp]: "\<And>x::'a poly. 0 div x = 0"
  1004       by (rule div_poly_eq)
  1005     case False then show ?thesis by auto
  1006   next
  1007     case True then have "y \<noteq> 0" and "z \<noteq> 0" by auto
  1008     with `x \<noteq> 0`
  1009     have "\<And>q r. pdivmod_rel y z q r \<Longrightarrow> pdivmod_rel (x * y) (x * z) q (x * r)"
  1010       by (auto simp add: pdivmod_rel_def algebra_simps)
  1011         (rule classical, simp add: degree_mult_eq)
  1012     moreover from pdivmod_rel have "pdivmod_rel y z (y div z) (y mod z)" .
  1013     ultimately have "pdivmod_rel (x * y) (x * z) (y div z) (x * (y mod z))" .
  1014     then show ?thesis by (simp add: div_poly_eq)
  1015   qed
  1016 qed
  1017 
  1018 end
  1019 
  1020 lemma degree_mod_less:
  1021   "y \<noteq> 0 \<Longrightarrow> x mod y = 0 \<or> degree (x mod y) < degree y"
  1022   using pdivmod_rel [of x y]
  1023   unfolding pdivmod_rel_def by simp
  1024 
  1025 lemma div_poly_less: "degree x < degree y \<Longrightarrow> x div y = 0"
  1026 proof -
  1027   assume "degree x < degree y"
  1028   hence "pdivmod_rel x y 0 x"
  1029     by (simp add: pdivmod_rel_def)
  1030   thus "x div y = 0" by (rule div_poly_eq)
  1031 qed
  1032 
  1033 lemma mod_poly_less: "degree x < degree y \<Longrightarrow> x mod y = x"
  1034 proof -
  1035   assume "degree x < degree y"
  1036   hence "pdivmod_rel x y 0 x"
  1037     by (simp add: pdivmod_rel_def)
  1038   thus "x mod y = x" by (rule mod_poly_eq)
  1039 qed
  1040 
  1041 lemma pdivmod_rel_smult_left:
  1042   "pdivmod_rel x y q r
  1043     \<Longrightarrow> pdivmod_rel (smult a x) y (smult a q) (smult a r)"
  1044   unfolding pdivmod_rel_def by (simp add: smult_add_right)
  1045 
  1046 lemma div_smult_left: "(smult a x) div y = smult a (x div y)"
  1047   by (rule div_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1048 
  1049 lemma mod_smult_left: "(smult a x) mod y = smult a (x mod y)"
  1050   by (rule mod_poly_eq, rule pdivmod_rel_smult_left, rule pdivmod_rel)
  1051 
  1052 lemma poly_div_minus_left [simp]:
  1053   fixes x y :: "'a::field poly"
  1054   shows "(- x) div y = - (x div y)"
  1055   using div_smult_left [of "- 1::'a"] by simp
  1056 
  1057 lemma poly_mod_minus_left [simp]:
  1058   fixes x y :: "'a::field poly"
  1059   shows "(- x) mod y = - (x mod y)"
  1060   using mod_smult_left [of "- 1::'a"] by simp
  1061 
  1062 lemma pdivmod_rel_smult_right:
  1063   "\<lbrakk>a \<noteq> 0; pdivmod_rel x y q r\<rbrakk>
  1064     \<Longrightarrow> pdivmod_rel x (smult a y) (smult (inverse a) q) r"
  1065   unfolding pdivmod_rel_def by simp
  1066 
  1067 lemma div_smult_right:
  1068   "a \<noteq> 0 \<Longrightarrow> x div (smult a y) = smult (inverse a) (x div y)"
  1069   by (rule div_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1070 
  1071 lemma mod_smult_right: "a \<noteq> 0 \<Longrightarrow> x mod (smult a y) = x mod y"
  1072   by (rule mod_poly_eq, erule pdivmod_rel_smult_right, rule pdivmod_rel)
  1073 
  1074 lemma poly_div_minus_right [simp]:
  1075   fixes x y :: "'a::field poly"
  1076   shows "x div (- y) = - (x div y)"
  1077   using div_smult_right [of "- 1::'a"]
  1078   by (simp add: nonzero_inverse_minus_eq)
  1079 
  1080 lemma poly_mod_minus_right [simp]:
  1081   fixes x y :: "'a::field poly"
  1082   shows "x mod (- y) = x mod y"
  1083   using mod_smult_right [of "- 1::'a"] by simp
  1084 
  1085 lemma pdivmod_rel_mult:
  1086   "\<lbrakk>pdivmod_rel x y q r; pdivmod_rel q z q' r'\<rbrakk>
  1087     \<Longrightarrow> pdivmod_rel x (y * z) q' (y * r' + r)"
  1088 apply (cases "z = 0", simp add: pdivmod_rel_def)
  1089 apply (cases "y = 0", simp add: pdivmod_rel_by_0_iff pdivmod_rel_0_iff)
  1090 apply (cases "r = 0")
  1091 apply (cases "r' = 0")
  1092 apply (simp add: pdivmod_rel_def)
  1093 apply (simp add: pdivmod_rel_def field_simps degree_mult_eq)
  1094 apply (cases "r' = 0")
  1095 apply (simp add: pdivmod_rel_def degree_mult_eq)
  1096 apply (simp add: pdivmod_rel_def field_simps)
  1097 apply (simp add: degree_mult_eq degree_add_less)
  1098 done
  1099 
  1100 lemma poly_div_mult_right:
  1101   fixes x y z :: "'a::field poly"
  1102   shows "x div (y * z) = (x div y) div z"
  1103   by (rule div_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1104 
  1105 lemma poly_mod_mult_right:
  1106   fixes x y z :: "'a::field poly"
  1107   shows "x mod (y * z) = y * (x div y mod z) + x mod y"
  1108   by (rule mod_poly_eq, rule pdivmod_rel_mult, (rule pdivmod_rel)+)
  1109 
  1110 lemma mod_pCons:
  1111   fixes a and x
  1112   assumes y: "y \<noteq> 0"
  1113   defines b: "b \<equiv> coeff (pCons a (x mod y)) (degree y) / coeff y (degree y)"
  1114   shows "(pCons a x) mod y = (pCons a (x mod y) - smult b y)"
  1115 unfolding b
  1116 apply (rule mod_poly_eq)
  1117 apply (rule pdivmod_rel_pCons [OF pdivmod_rel y refl])
  1118 done
  1119 
  1120 
  1121 subsection {* GCD of polynomials *}
  1122 
  1123 function
  1124   poly_gcd :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly" where
  1125   "poly_gcd x 0 = smult (inverse (coeff x (degree x))) x"
  1126 | "y \<noteq> 0 \<Longrightarrow> poly_gcd x y = poly_gcd y (x mod y)"
  1127 by auto
  1128 
  1129 termination poly_gcd
  1130 by (relation "measure (\<lambda>(x, y). if y = 0 then 0 else Suc (degree y))")
  1131    (auto dest: degree_mod_less)
  1132 
  1133 declare poly_gcd.simps [simp del]
  1134 
  1135 lemma poly_gcd_dvd1 [iff]: "poly_gcd x y dvd x"
  1136   and poly_gcd_dvd2 [iff]: "poly_gcd x y dvd y"
  1137   apply (induct x y rule: poly_gcd.induct)
  1138   apply (simp_all add: poly_gcd.simps)
  1139   apply (fastforce simp add: smult_dvd_iff dest: inverse_zero_imp_zero)
  1140   apply (blast dest: dvd_mod_imp_dvd)
  1141   done
  1142 
  1143 lemma poly_gcd_greatest: "k dvd x \<Longrightarrow> k dvd y \<Longrightarrow> k dvd poly_gcd x y"
  1144   by (induct x y rule: poly_gcd.induct)
  1145      (simp_all add: poly_gcd.simps dvd_mod dvd_smult)
  1146 
  1147 lemma dvd_poly_gcd_iff [iff]:
  1148   "k dvd poly_gcd x y \<longleftrightarrow> k dvd x \<and> k dvd y"
  1149   by (blast intro!: poly_gcd_greatest intro: dvd_trans)
  1150 
  1151 lemma poly_gcd_monic:
  1152   "coeff (poly_gcd x y) (degree (poly_gcd x y)) =
  1153     (if x = 0 \<and> y = 0 then 0 else 1)"
  1154   by (induct x y rule: poly_gcd.induct)
  1155      (simp_all add: poly_gcd.simps nonzero_imp_inverse_nonzero)
  1156 
  1157 lemma poly_gcd_zero_iff [simp]:
  1158   "poly_gcd x y = 0 \<longleftrightarrow> x = 0 \<and> y = 0"
  1159   by (simp only: dvd_0_left_iff [symmetric] dvd_poly_gcd_iff)
  1160 
  1161 lemma poly_gcd_0_0 [simp]: "poly_gcd 0 0 = 0"
  1162   by simp
  1163 
  1164 lemma poly_dvd_antisym:
  1165   fixes p q :: "'a::idom poly"
  1166   assumes coeff: "coeff p (degree p) = coeff q (degree q)"
  1167   assumes dvd1: "p dvd q" and dvd2: "q dvd p" shows "p = q"
  1168 proof (cases "p = 0")
  1169   case True with coeff show "p = q" by simp
  1170 next
  1171   case False with coeff have "q \<noteq> 0" by auto
  1172   have degree: "degree p = degree q"
  1173     using `p dvd q` `q dvd p` `p \<noteq> 0` `q \<noteq> 0`
  1174     by (intro order_antisym dvd_imp_degree_le)
  1175 
  1176   from `p dvd q` obtain a where a: "q = p * a" ..
  1177   with `q \<noteq> 0` have "a \<noteq> 0" by auto
  1178   with degree a `p \<noteq> 0` have "degree a = 0"
  1179     by (simp add: degree_mult_eq)
  1180   with coeff a show "p = q"
  1181     by (cases a, auto split: if_splits)
  1182 qed
  1183 
  1184 lemma poly_gcd_unique:
  1185   assumes dvd1: "d dvd x" and dvd2: "d dvd y"
  1186     and greatest: "\<And>k. k dvd x \<Longrightarrow> k dvd y \<Longrightarrow> k dvd d"
  1187     and monic: "coeff d (degree d) = (if x = 0 \<and> y = 0 then 0 else 1)"
  1188   shows "poly_gcd x y = d"
  1189 proof -
  1190   have "coeff (poly_gcd x y) (degree (poly_gcd x y)) = coeff d (degree d)"
  1191     by (simp_all add: poly_gcd_monic monic)
  1192   moreover have "poly_gcd x y dvd d"
  1193     using poly_gcd_dvd1 poly_gcd_dvd2 by (rule greatest)
  1194   moreover have "d dvd poly_gcd x y"
  1195     using dvd1 dvd2 by (rule poly_gcd_greatest)
  1196   ultimately show ?thesis
  1197     by (rule poly_dvd_antisym)
  1198 qed
  1199 
  1200 interpretation poly_gcd: abel_semigroup poly_gcd
  1201 proof
  1202   fix x y z :: "'a poly"
  1203   show "poly_gcd (poly_gcd x y) z = poly_gcd x (poly_gcd y z)"
  1204     by (rule poly_gcd_unique) (auto intro: dvd_trans simp add: poly_gcd_monic)
  1205   show "poly_gcd x y = poly_gcd y x"
  1206     by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1207 qed
  1208 
  1209 lemmas poly_gcd_assoc = poly_gcd.assoc
  1210 lemmas poly_gcd_commute = poly_gcd.commute
  1211 lemmas poly_gcd_left_commute = poly_gcd.left_commute
  1212 
  1213 lemmas poly_gcd_ac = poly_gcd_assoc poly_gcd_commute poly_gcd_left_commute
  1214 
  1215 lemma poly_gcd_1_left [simp]: "poly_gcd 1 y = 1"
  1216 by (rule poly_gcd_unique) simp_all
  1217 
  1218 lemma poly_gcd_1_right [simp]: "poly_gcd x 1 = 1"
  1219 by (rule poly_gcd_unique) simp_all
  1220 
  1221 lemma poly_gcd_minus_left [simp]: "poly_gcd (- x) y = poly_gcd x y"
  1222 by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1223 
  1224 lemma poly_gcd_minus_right [simp]: "poly_gcd x (- y) = poly_gcd x y"
  1225 by (rule poly_gcd_unique) (simp_all add: poly_gcd_monic)
  1226 
  1227 
  1228 subsection {* Evaluation of polynomials *}
  1229 
  1230 definition
  1231   poly :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a" where
  1232   "poly = poly_rec (\<lambda>x. 0) (\<lambda>a p f x. a + x * f x)"
  1233 
  1234 lemma poly_0 [simp]: "poly 0 x = 0"
  1235   unfolding poly_def by (simp add: poly_rec_0)
  1236 
  1237 lemma poly_pCons [simp]: "poly (pCons a p) x = a + x * poly p x"
  1238   unfolding poly_def by (simp add: poly_rec_pCons)
  1239 
  1240 lemma poly_1 [simp]: "poly 1 x = 1"
  1241   unfolding one_poly_def by simp
  1242 
  1243 lemma poly_monom:
  1244   fixes a x :: "'a::{comm_semiring_1}"
  1245   shows "poly (monom a n) x = a * x ^ n"
  1246   by (induct n, simp add: monom_0, simp add: monom_Suc power_Suc mult_ac)
  1247 
  1248 lemma poly_add [simp]: "poly (p + q) x = poly p x + poly q x"
  1249   apply (induct p arbitrary: q, simp)
  1250   apply (case_tac q, simp, simp add: algebra_simps)
  1251   done
  1252 
  1253 lemma poly_minus [simp]:
  1254   fixes x :: "'a::comm_ring"
  1255   shows "poly (- p) x = - poly p x"
  1256   by (induct p, simp_all)
  1257 
  1258 lemma poly_diff [simp]:
  1259   fixes x :: "'a::comm_ring"
  1260   shows "poly (p - q) x = poly p x - poly q x"
  1261   by (simp add: diff_minus)
  1262 
  1263 lemma poly_setsum: "poly (\<Sum>k\<in>A. p k) x = (\<Sum>k\<in>A. poly (p k) x)"
  1264   by (cases "finite A", induct set: finite, simp_all)
  1265 
  1266 lemma poly_smult [simp]: "poly (smult a p) x = a * poly p x"
  1267   by (induct p, simp, simp add: algebra_simps)
  1268 
  1269 lemma poly_mult [simp]: "poly (p * q) x = poly p x * poly q x"
  1270   by (induct p, simp_all, simp add: algebra_simps)
  1271 
  1272 lemma poly_power [simp]:
  1273   fixes p :: "'a::{comm_semiring_1} poly"
  1274   shows "poly (p ^ n) x = poly p x ^ n"
  1275   by (induct n, simp, simp add: power_Suc)
  1276 
  1277 
  1278 subsection {* Synthetic division *}
  1279 
  1280 text {*
  1281   Synthetic division is simply division by the
  1282   linear polynomial @{term "x - c"}.
  1283 *}
  1284 
  1285 definition
  1286   synthetic_divmod :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly \<times> 'a"
  1287 where
  1288   "synthetic_divmod p c =
  1289     poly_rec (0, 0) (\<lambda>a p (q, r). (pCons r q, a + c * r)) p"
  1290 
  1291 definition
  1292   synthetic_div :: "'a::comm_semiring_0 poly \<Rightarrow> 'a \<Rightarrow> 'a poly"
  1293 where
  1294   "synthetic_div p c = fst (synthetic_divmod p c)"
  1295 
  1296 lemma synthetic_divmod_0 [simp]:
  1297   "synthetic_divmod 0 c = (0, 0)"
  1298   unfolding synthetic_divmod_def
  1299   by (simp add: poly_rec_0)
  1300 
  1301 lemma synthetic_divmod_pCons [simp]:
  1302   "synthetic_divmod (pCons a p) c =
  1303     (\<lambda>(q, r). (pCons r q, a + c * r)) (synthetic_divmod p c)"
  1304   unfolding synthetic_divmod_def
  1305   by (simp add: poly_rec_pCons)
  1306 
  1307 lemma snd_synthetic_divmod: "snd (synthetic_divmod p c) = poly p c"
  1308   by (induct p, simp, simp add: split_def)
  1309 
  1310 lemma synthetic_div_0 [simp]: "synthetic_div 0 c = 0"
  1311   unfolding synthetic_div_def by simp
  1312 
  1313 lemma synthetic_div_pCons [simp]:
  1314   "synthetic_div (pCons a p) c = pCons (poly p c) (synthetic_div p c)"
  1315   unfolding synthetic_div_def
  1316   by (simp add: split_def snd_synthetic_divmod)
  1317 
  1318 lemma synthetic_div_eq_0_iff:
  1319   "synthetic_div p c = 0 \<longleftrightarrow> degree p = 0"
  1320   by (induct p, simp, case_tac p, simp)
  1321 
  1322 lemma degree_synthetic_div:
  1323   "degree (synthetic_div p c) = degree p - 1"
  1324   by (induct p, simp, simp add: synthetic_div_eq_0_iff)
  1325 
  1326 lemma synthetic_div_correct:
  1327   "p + smult c (synthetic_div p c) = pCons (poly p c) (synthetic_div p c)"
  1328   by (induct p) simp_all
  1329 
  1330 lemma synthetic_div_unique_lemma: "smult c p = pCons a p \<Longrightarrow> p = 0"
  1331 by (induct p arbitrary: a) simp_all
  1332 
  1333 lemma synthetic_div_unique:
  1334   "p + smult c q = pCons r q \<Longrightarrow> r = poly p c \<and> q = synthetic_div p c"
  1335 apply (induct p arbitrary: q r)
  1336 apply (simp, frule synthetic_div_unique_lemma, simp)
  1337 apply (case_tac q, force)
  1338 done
  1339 
  1340 lemma synthetic_div_correct':
  1341   fixes c :: "'a::comm_ring_1"
  1342   shows "[:-c, 1:] * synthetic_div p c + [:poly p c:] = p"
  1343   using synthetic_div_correct [of p c]
  1344   by (simp add: algebra_simps)
  1345 
  1346 lemma poly_eq_0_iff_dvd:
  1347   fixes c :: "'a::idom"
  1348   shows "poly p c = 0 \<longleftrightarrow> [:-c, 1:] dvd p"
  1349 proof
  1350   assume "poly p c = 0"
  1351   with synthetic_div_correct' [of c p]
  1352   have "p = [:-c, 1:] * synthetic_div p c" by simp
  1353   then show "[:-c, 1:] dvd p" ..
  1354 next
  1355   assume "[:-c, 1:] dvd p"
  1356   then obtain k where "p = [:-c, 1:] * k" by (rule dvdE)
  1357   then show "poly p c = 0" by simp
  1358 qed
  1359 
  1360 lemma dvd_iff_poly_eq_0:
  1361   fixes c :: "'a::idom"
  1362   shows "[:c, 1:] dvd p \<longleftrightarrow> poly p (-c) = 0"
  1363   by (simp add: poly_eq_0_iff_dvd)
  1364 
  1365 lemma poly_roots_finite:
  1366   fixes p :: "'a::idom poly"
  1367   shows "p \<noteq> 0 \<Longrightarrow> finite {x. poly p x = 0}"
  1368 proof (induct n \<equiv> "degree p" arbitrary: p)
  1369   case (0 p)
  1370   then obtain a where "a \<noteq> 0" and "p = [:a:]"
  1371     by (cases p, simp split: if_splits)
  1372   then show "finite {x. poly p x = 0}" by simp
  1373 next
  1374   case (Suc n p)
  1375   show "finite {x. poly p x = 0}"
  1376   proof (cases "\<exists>x. poly p x = 0")
  1377     case False
  1378     then show "finite {x. poly p x = 0}" by simp
  1379   next
  1380     case True
  1381     then obtain a where "poly p a = 0" ..
  1382     then have "[:-a, 1:] dvd p" by (simp only: poly_eq_0_iff_dvd)
  1383     then obtain k where k: "p = [:-a, 1:] * k" ..
  1384     with `p \<noteq> 0` have "k \<noteq> 0" by auto
  1385     with k have "degree p = Suc (degree k)"
  1386       by (simp add: degree_mult_eq del: mult_pCons_left)
  1387     with `Suc n = degree p` have "n = degree k" by simp
  1388     then have "finite {x. poly k x = 0}" using `k \<noteq> 0` by (rule Suc.hyps)
  1389     then have "finite (insert a {x. poly k x = 0})" by simp
  1390     then show "finite {x. poly p x = 0}"
  1391       by (simp add: k uminus_add_conv_diff Collect_disj_eq
  1392                del: mult_pCons_left)
  1393   qed
  1394 qed
  1395 
  1396 lemma poly_zero:
  1397   fixes p :: "'a::{idom,ring_char_0} poly"
  1398   shows "poly p = poly 0 \<longleftrightarrow> p = 0"
  1399 apply (cases "p = 0", simp_all)
  1400 apply (drule poly_roots_finite)
  1401 apply (auto simp add: infinite_UNIV_char_0)
  1402 done
  1403 
  1404 lemma poly_eq_iff:
  1405   fixes p q :: "'a::{idom,ring_char_0} poly"
  1406   shows "poly p = poly q \<longleftrightarrow> p = q"
  1407   using poly_zero [of "p - q"]
  1408   by (simp add: fun_eq_iff)
  1409 
  1410 
  1411 subsection {* Composition of polynomials *}
  1412 
  1413 definition
  1414   pcompose :: "'a::comm_semiring_0 poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly"
  1415 where
  1416   "pcompose p q = poly_rec 0 (\<lambda>a _ c. [:a:] + q * c) p"
  1417 
  1418 lemma pcompose_0 [simp]: "pcompose 0 q = 0"
  1419   unfolding pcompose_def by (simp add: poly_rec_0)
  1420 
  1421 lemma pcompose_pCons:
  1422   "pcompose (pCons a p) q = [:a:] + q * pcompose p q"
  1423   unfolding pcompose_def by (simp add: poly_rec_pCons)
  1424 
  1425 lemma poly_pcompose: "poly (pcompose p q) x = poly p (poly q x)"
  1426   by (induct p) (simp_all add: pcompose_pCons)
  1427 
  1428 lemma degree_pcompose_le:
  1429   "degree (pcompose p q) \<le> degree p * degree q"
  1430 apply (induct p, simp)
  1431 apply (simp add: pcompose_pCons, clarify)
  1432 apply (rule degree_add_le, simp)
  1433 apply (rule order_trans [OF degree_mult_le], simp)
  1434 done
  1435 
  1436 
  1437 subsection {* Order of polynomial roots *}
  1438 
  1439 definition
  1440   order :: "'a::idom \<Rightarrow> 'a poly \<Rightarrow> nat"
  1441 where
  1442   "order a p = (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)"
  1443 
  1444 lemma coeff_linear_power:
  1445   fixes a :: "'a::comm_semiring_1"
  1446   shows "coeff ([:a, 1:] ^ n) n = 1"
  1447 apply (induct n, simp_all)
  1448 apply (subst coeff_eq_0)
  1449 apply (auto intro: le_less_trans degree_power_le)
  1450 done
  1451 
  1452 lemma degree_linear_power:
  1453   fixes a :: "'a::comm_semiring_1"
  1454   shows "degree ([:a, 1:] ^ n) = n"
  1455 apply (rule order_antisym)
  1456 apply (rule ord_le_eq_trans [OF degree_power_le], simp)
  1457 apply (rule le_degree, simp add: coeff_linear_power)
  1458 done
  1459 
  1460 lemma order_1: "[:-a, 1:] ^ order a p dvd p"
  1461 apply (cases "p = 0", simp)
  1462 apply (cases "order a p", simp)
  1463 apply (subgoal_tac "nat < (LEAST n. \<not> [:-a, 1:] ^ Suc n dvd p)")
  1464 apply (drule not_less_Least, simp)
  1465 apply (fold order_def, simp)
  1466 done
  1467 
  1468 lemma order_2: "p \<noteq> 0 \<Longrightarrow> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1469 unfolding order_def
  1470 apply (rule LeastI_ex)
  1471 apply (rule_tac x="degree p" in exI)
  1472 apply (rule notI)
  1473 apply (drule (1) dvd_imp_degree_le)
  1474 apply (simp only: degree_linear_power)
  1475 done
  1476 
  1477 lemma order:
  1478   "p \<noteq> 0 \<Longrightarrow> [:-a, 1:] ^ order a p dvd p \<and> \<not> [:-a, 1:] ^ Suc (order a p) dvd p"
  1479 by (rule conjI [OF order_1 order_2])
  1480 
  1481 lemma order_degree:
  1482   assumes p: "p \<noteq> 0"
  1483   shows "order a p \<le> degree p"
  1484 proof -
  1485   have "order a p = degree ([:-a, 1:] ^ order a p)"
  1486     by (simp only: degree_linear_power)
  1487   also have "\<dots> \<le> degree p"
  1488     using order_1 p by (rule dvd_imp_degree_le)
  1489   finally show ?thesis .
  1490 qed
  1491 
  1492 lemma order_root: "poly p a = 0 \<longleftrightarrow> p = 0 \<or> order a p \<noteq> 0"
  1493 apply (cases "p = 0", simp_all)
  1494 apply (rule iffI)
  1495 apply (rule ccontr, simp)
  1496 apply (frule order_2 [where a=a], simp)
  1497 apply (simp add: poly_eq_0_iff_dvd)
  1498 apply (simp add: poly_eq_0_iff_dvd)
  1499 apply (simp only: order_def)
  1500 apply (drule not_less_Least, simp)
  1501 done
  1502 
  1503 
  1504 subsection {* Configuration of the code generator *}
  1505 
  1506 code_datatype "0::'a::zero poly" pCons
  1507 
  1508 quickcheck_generator poly constructors: "0::'a::zero poly", pCons
  1509 
  1510 instantiation poly :: ("{zero, equal}") equal
  1511 begin
  1512 
  1513 definition
  1514   "HOL.equal (p::'a poly) q \<longleftrightarrow> p = q"
  1515 
  1516 instance proof
  1517 qed (rule equal_poly_def)
  1518 
  1519 end
  1520 
  1521 lemma eq_poly_code [code]:
  1522   "HOL.equal (0::_ poly) (0::_ poly) \<longleftrightarrow> True"
  1523   "HOL.equal (0::_ poly) (pCons b q) \<longleftrightarrow> HOL.equal 0 b \<and> HOL.equal 0 q"
  1524   "HOL.equal (pCons a p) (0::_ poly) \<longleftrightarrow> HOL.equal a 0 \<and> HOL.equal p 0"
  1525   "HOL.equal (pCons a p) (pCons b q) \<longleftrightarrow> HOL.equal a b \<and> HOL.equal p q"
  1526   by (simp_all add: equal)
  1527 
  1528 lemma [code nbe]:
  1529   "HOL.equal (p :: _ poly) p \<longleftrightarrow> True"
  1530   by (fact equal_refl)
  1531 
  1532 lemmas coeff_code [code] =
  1533   coeff_0 coeff_pCons_0 coeff_pCons_Suc
  1534 
  1535 lemmas degree_code [code] =
  1536   degree_0 degree_pCons_eq_if
  1537 
  1538 lemmas monom_poly_code [code] =
  1539   monom_0 monom_Suc
  1540 
  1541 lemma add_poly_code [code]:
  1542   "0 + q = (q :: _ poly)"
  1543   "p + 0 = (p :: _ poly)"
  1544   "pCons a p + pCons b q = pCons (a + b) (p + q)"
  1545 by simp_all
  1546 
  1547 lemma minus_poly_code [code]:
  1548   "- 0 = (0 :: _ poly)"
  1549   "- pCons a p = pCons (- a) (- p)"
  1550 by simp_all
  1551 
  1552 lemma diff_poly_code [code]:
  1553   "0 - q = (- q :: _ poly)"
  1554   "p - 0 = (p :: _ poly)"
  1555   "pCons a p - pCons b q = pCons (a - b) (p - q)"
  1556 by simp_all
  1557 
  1558 lemmas smult_poly_code [code] =
  1559   smult_0_right smult_pCons
  1560 
  1561 lemma mult_poly_code [code]:
  1562   "0 * q = (0 :: _ poly)"
  1563   "pCons a p * q = smult a q + pCons 0 (p * q)"
  1564 by simp_all
  1565 
  1566 lemmas poly_code [code] =
  1567   poly_0 poly_pCons
  1568 
  1569 lemmas synthetic_divmod_code [code] =
  1570   synthetic_divmod_0 synthetic_divmod_pCons
  1571 
  1572 text {* code generator setup for div and mod *}
  1573 
  1574 definition
  1575   pdivmod :: "'a::field poly \<Rightarrow> 'a poly \<Rightarrow> 'a poly \<times> 'a poly"
  1576 where
  1577   "pdivmod x y = (x div y, x mod y)"
  1578 
  1579 lemma div_poly_code [code]: "x div y = fst (pdivmod x y)"
  1580   unfolding pdivmod_def by simp
  1581 
  1582 lemma mod_poly_code [code]: "x mod y = snd (pdivmod x y)"
  1583   unfolding pdivmod_def by simp
  1584 
  1585 lemma pdivmod_0 [code]: "pdivmod 0 y = (0, 0)"
  1586   unfolding pdivmod_def by simp
  1587 
  1588 lemma pdivmod_pCons [code]:
  1589   "pdivmod (pCons a x) y =
  1590     (if y = 0 then (0, pCons a x) else
  1591       (let (q, r) = pdivmod x y;
  1592            b = coeff (pCons a r) (degree y) / coeff y (degree y)
  1593         in (pCons b q, pCons a r - smult b y)))"
  1594 apply (simp add: pdivmod_def Let_def, safe)
  1595 apply (rule div_poly_eq)
  1596 apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1597 apply (rule mod_poly_eq)
  1598 apply (erule pdivmod_rel_pCons [OF pdivmod_rel _ refl])
  1599 done
  1600 
  1601 lemma poly_gcd_code [code]:
  1602   "poly_gcd x y =
  1603     (if y = 0 then smult (inverse (coeff x (degree x))) x
  1604               else poly_gcd y (x mod y))"
  1605   by (simp add: poly_gcd.simps)
  1606 
  1607 end