src/Pure/term.ML
author wenzelm
Sun Jul 15 17:53:47 2012 +0200 (2012-07-15)
changeset 48263 94a7dc2276e4
parent 46219 426ed18eba43
child 49674 dbadb4d03cbc
permissions -rw-r--r--
prefer canonical fold_rev;
     1 (*  Title:      Pure/term.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Makarius
     4 
     5 Simply typed lambda-calculus: types, terms, and basic operations.
     6 *)
     7 
     8 infix 9 $;
     9 infixr 5 -->;
    10 infixr --->;
    11 infix aconv;
    12 
    13 signature BASIC_TERM =
    14 sig
    15   type indexname = string * int
    16   type class = string
    17   type sort = class list
    18   type arity = string * sort list * sort
    19   datatype typ =
    20     Type  of string * typ list |
    21     TFree of string * sort |
    22     TVar  of indexname * sort
    23   datatype term =
    24     Const of string * typ |
    25     Free of string * typ |
    26     Var of indexname * typ |
    27     Bound of int |
    28     Abs of string * typ * term |
    29     $ of term * term
    30   exception TYPE of string * typ list * term list
    31   exception TERM of string * term list
    32   val dummyS: sort
    33   val dummyT: typ
    34   val no_dummyT: typ -> typ
    35   val --> : typ * typ -> typ
    36   val ---> : typ list * typ -> typ
    37   val dest_Type: typ -> string * typ list
    38   val dest_TVar: typ -> indexname * sort
    39   val dest_TFree: typ -> string * sort
    40   val is_Bound: term -> bool
    41   val is_Const: term -> bool
    42   val is_Free: term -> bool
    43   val is_Var: term -> bool
    44   val is_TVar: typ -> bool
    45   val dest_Const: term -> string * typ
    46   val dest_Free: term -> string * typ
    47   val dest_Var: term -> indexname * typ
    48   val dest_comb: term -> term * term
    49   val domain_type: typ -> typ
    50   val range_type: typ -> typ
    51   val dest_funT: typ -> typ * typ
    52   val binder_types: typ -> typ list
    53   val body_type: typ -> typ
    54   val strip_type: typ -> typ list * typ
    55   val type_of1: typ list * term -> typ
    56   val type_of: term -> typ
    57   val fastype_of1: typ list * term -> typ
    58   val fastype_of: term -> typ
    59   val strip_abs: term -> (string * typ) list * term
    60   val strip_abs_body: term -> term
    61   val strip_abs_vars: term -> (string * typ) list
    62   val strip_qnt_body: string -> term -> term
    63   val strip_qnt_vars: string -> term -> (string * typ) list
    64   val list_comb: term * term list -> term
    65   val strip_comb: term -> term * term list
    66   val head_of: term -> term
    67   val size_of_term: term -> int
    68   val size_of_typ: typ -> int
    69   val map_atyps: (typ -> typ) -> typ -> typ
    70   val map_aterms: (term -> term) -> term -> term
    71   val map_type_tvar: (indexname * sort -> typ) -> typ -> typ
    72   val map_type_tfree: (string * sort -> typ) -> typ -> typ
    73   val map_types: (typ -> typ) -> term -> term
    74   val fold_atyps: (typ -> 'a -> 'a) -> typ -> 'a -> 'a
    75   val fold_atyps_sorts: (typ * sort -> 'a -> 'a) -> typ -> 'a -> 'a
    76   val fold_aterms: (term -> 'a -> 'a) -> term -> 'a -> 'a
    77   val fold_term_types: (term -> typ -> 'a -> 'a) -> term -> 'a -> 'a
    78   val fold_types: (typ -> 'a -> 'a) -> term -> 'a -> 'a
    79   val burrow_types: (typ list -> typ list) -> term list -> term list
    80   val aconv: term * term -> bool
    81   val propT: typ
    82   val strip_all_body: term -> term
    83   val strip_all_vars: term -> (string * typ) list
    84   val incr_bv: int * int * term -> term
    85   val incr_boundvars: int -> term -> term
    86   val add_loose_bnos: term * int * int list -> int list
    87   val loose_bnos: term -> int list
    88   val loose_bvar: term * int -> bool
    89   val loose_bvar1: term * int -> bool
    90   val subst_bounds: term list * term -> term
    91   val subst_bound: term * term -> term
    92   val betapply: term * term -> term
    93   val betapplys: term * term list -> term
    94   val subst_free: (term * term) list -> term -> term
    95   val abstract_over: term * term -> term
    96   val lambda: term -> term -> term
    97   val absfree: string * typ -> term -> term
    98   val absdummy: typ -> term -> term
    99   val subst_atomic: (term * term) list -> term -> term
   100   val typ_subst_atomic: (typ * typ) list -> typ -> typ
   101   val subst_atomic_types: (typ * typ) list -> term -> term
   102   val typ_subst_TVars: (indexname * typ) list -> typ -> typ
   103   val subst_TVars: (indexname * typ) list -> term -> term
   104   val subst_Vars: (indexname * term) list -> term -> term
   105   val subst_vars: (indexname * typ) list * (indexname * term) list -> term -> term
   106   val is_first_order: string list -> term -> bool
   107   val maxidx_of_typ: typ -> int
   108   val maxidx_of_typs: typ list -> int
   109   val maxidx_of_term: term -> int
   110   val exists_subtype: (typ -> bool) -> typ -> bool
   111   val exists_type: (typ -> bool) -> term -> bool
   112   val exists_subterm: (term -> bool) -> term -> bool
   113   val exists_Const: (string * typ -> bool) -> term -> bool
   114 end;
   115 
   116 signature TERM =
   117 sig
   118   include BASIC_TERM
   119   val aT: sort -> typ
   120   val itselfT: typ -> typ
   121   val a_itselfT: typ
   122   val argument_type_of: term -> int -> typ
   123   val abs: string * typ -> term -> term
   124   val add_tvar_namesT: typ -> indexname list -> indexname list
   125   val add_tvar_names: term -> indexname list -> indexname list
   126   val add_tvarsT: typ -> (indexname * sort) list -> (indexname * sort) list
   127   val add_tvars: term -> (indexname * sort) list -> (indexname * sort) list
   128   val add_var_names: term -> indexname list -> indexname list
   129   val add_vars: term -> (indexname * typ) list -> (indexname * typ) list
   130   val add_tfree_namesT: typ -> string list -> string list
   131   val add_tfree_names: term -> string list -> string list
   132   val add_tfreesT: typ -> (string * sort) list -> (string * sort) list
   133   val add_tfrees: term -> (string * sort) list -> (string * sort) list
   134   val add_free_names: term -> string list -> string list
   135   val add_frees: term -> (string * typ) list -> (string * typ) list
   136   val add_const_names: term -> string list -> string list
   137   val add_consts: term -> (string * typ) list -> (string * typ) list
   138   val hidden_polymorphism: term -> (indexname * sort) list
   139   val declare_typ_names: typ -> Name.context -> Name.context
   140   val declare_term_names: term -> Name.context -> Name.context
   141   val declare_term_frees: term -> Name.context -> Name.context
   142   val variant_frees: term -> (string * 'a) list -> (string * 'a) list
   143   val rename_wrt_term: term -> (string * 'a) list -> (string * 'a) list
   144   val eq_ix: indexname * indexname -> bool
   145   val eq_tvar: (indexname * sort) * (indexname * sort) -> bool
   146   val eq_var: (indexname * typ) * (indexname * typ) -> bool
   147   val aconv_untyped: term * term -> bool
   148   val could_unify: term * term -> bool
   149   val strip_abs_eta: int -> term -> (string * typ) list * term
   150   val match_bvars: (term * term) -> (string * string) list -> (string * string) list
   151   val map_abs_vars: (string -> string) -> term -> term
   152   val rename_abs: term -> term -> term -> term option
   153   val is_open: term -> bool
   154   val is_dependent: term -> bool
   155   val lambda_name: string * term -> term -> term
   156   val close_schematic_term: term -> term
   157   val maxidx_typ: typ -> int -> int
   158   val maxidx_typs: typ list -> int -> int
   159   val maxidx_term: term -> int -> int
   160   val has_abs: term -> bool
   161   val dest_abs: string * typ * term -> string * term
   162   val dummy_patternN: string
   163   val dummy_pattern: typ -> term
   164   val dummy: term
   165   val dummy_prop: term
   166   val is_dummy_pattern: term -> bool
   167   val free_dummy_patterns: term -> Name.context -> term * Name.context
   168   val no_dummy_patterns: term -> term
   169   val replace_dummy_patterns: term -> int -> term * int
   170   val is_replaced_dummy_pattern: indexname -> bool
   171   val show_dummy_patterns: term -> term
   172   val string_of_vname: indexname -> string
   173   val string_of_vname': indexname -> string
   174 end;
   175 
   176 structure Term: TERM =
   177 struct
   178 
   179 (*Indexnames can be quickly renamed by adding an offset to the integer part,
   180   for resolution.*)
   181 type indexname = string * int;
   182 
   183 (* Types are classified by sorts. *)
   184 type class = string;
   185 type sort  = class list;
   186 type arity = string * sort list * sort;
   187 
   188 (* The sorts attached to TFrees and TVars specify the sort of that variable *)
   189 datatype typ = Type  of string * typ list
   190              | TFree of string * sort
   191              | TVar  of indexname * sort;
   192 
   193 (*Terms.  Bound variables are indicated by depth number.
   194   Free variables, (scheme) variables and constants have names.
   195   An term is "closed" if every bound variable of level "lev"
   196   is enclosed by at least "lev" abstractions.
   197 
   198   It is possible to create meaningless terms containing loose bound vars
   199   or type mismatches.  But such terms are not allowed in rules. *)
   200 
   201 datatype term =
   202     Const of string * typ
   203   | Free  of string * typ
   204   | Var   of indexname * typ
   205   | Bound of int
   206   | Abs   of string*typ*term
   207   | op $  of term*term;
   208 
   209 (*Errors involving type mismatches*)
   210 exception TYPE of string * typ list * term list;
   211 
   212 (*Errors errors involving terms*)
   213 exception TERM of string * term list;
   214 
   215 (*Note variable naming conventions!
   216     a,b,c: string
   217     f,g,h: functions (including terms of function type)
   218     i,j,m,n: int
   219     t,u: term
   220     v,w: indexnames
   221     x,y: any
   222     A,B,C: term (denoting formulae)
   223     T,U: typ
   224 *)
   225 
   226 
   227 (** Types **)
   228 
   229 (*dummies for type-inference etc.*)
   230 val dummyS = [""];
   231 val dummyT = Type ("dummy", []);
   232 
   233 fun no_dummyT typ =
   234   let
   235     fun check (T as Type ("dummy", _)) =
   236           raise TYPE ("Illegal occurrence of '_' dummy type", [T], [])
   237       | check (Type (_, Ts)) = List.app check Ts
   238       | check _ = ();
   239   in check typ; typ end;
   240 
   241 fun S --> T = Type("fun",[S,T]);
   242 
   243 (*handy for multiple args: [T1,...,Tn]--->T  gives  T1-->(T2--> ... -->T)*)
   244 val op ---> = Library.foldr (op -->);
   245 
   246 fun dest_Type (Type x) = x
   247   | dest_Type T = raise TYPE ("dest_Type", [T], []);
   248 fun dest_TVar (TVar x) = x
   249   | dest_TVar T = raise TYPE ("dest_TVar", [T], []);
   250 fun dest_TFree (TFree x) = x
   251   | dest_TFree T = raise TYPE ("dest_TFree", [T], []);
   252 
   253 
   254 (** Discriminators **)
   255 
   256 fun is_Bound (Bound _) = true
   257   | is_Bound _         = false;
   258 
   259 fun is_Const (Const _) = true
   260   | is_Const _ = false;
   261 
   262 fun is_Free (Free _) = true
   263   | is_Free _ = false;
   264 
   265 fun is_Var (Var _) = true
   266   | is_Var _ = false;
   267 
   268 fun is_TVar (TVar _) = true
   269   | is_TVar _ = false;
   270 
   271 
   272 (** Destructors **)
   273 
   274 fun dest_Const (Const x) =  x
   275   | dest_Const t = raise TERM("dest_Const", [t]);
   276 
   277 fun dest_Free (Free x) =  x
   278   | dest_Free t = raise TERM("dest_Free", [t]);
   279 
   280 fun dest_Var (Var x) =  x
   281   | dest_Var t = raise TERM("dest_Var", [t]);
   282 
   283 fun dest_comb (t1 $ t2) = (t1, t2)
   284   | dest_comb t = raise TERM("dest_comb", [t]);
   285 
   286 
   287 fun domain_type (Type ("fun", [T, _])) = T;
   288 
   289 fun range_type (Type ("fun", [_, U])) = U;
   290 
   291 fun dest_funT (Type ("fun", [T, U])) = (T, U)
   292   | dest_funT T = raise TYPE ("dest_funT", [T], []);
   293 
   294 
   295 (* maps  [T1,...,Tn]--->T  to the list  [T1,T2,...,Tn]*)
   296 fun binder_types (Type ("fun", [T, U])) = T :: binder_types U
   297   | binder_types _ = [];
   298 
   299 (* maps  [T1,...,Tn]--->T  to T*)
   300 fun body_type (Type ("fun", [_, U])) = body_type U
   301   | body_type T = T;
   302 
   303 (* maps  [T1,...,Tn]--->T  to   ([T1,T2,...,Tn], T)  *)
   304 fun strip_type T = (binder_types T, body_type T);
   305 
   306 
   307 (*Compute the type of the term, checking that combinations are well-typed
   308   Ts = [T0,T1,...] holds types of bound variables 0, 1, ...*)
   309 fun type_of1 (Ts, Const (_,T)) = T
   310   | type_of1 (Ts, Free  (_,T)) = T
   311   | type_of1 (Ts, Bound i) = (nth Ts i
   312         handle General.Subscript => raise TYPE("type_of: bound variable", [], [Bound i]))
   313   | type_of1 (Ts, Var (_,T)) = T
   314   | type_of1 (Ts, Abs (_,T,body)) = T --> type_of1(T::Ts, body)
   315   | type_of1 (Ts, f$u) =
   316       let val U = type_of1(Ts,u)
   317           and T = type_of1(Ts,f)
   318       in case T of
   319             Type("fun",[T1,T2]) =>
   320               if T1=U then T2  else raise TYPE
   321                     ("type_of: type mismatch in application", [T1,U], [f$u])
   322           | _ => raise TYPE
   323                     ("type_of: function type is expected in application",
   324                      [T,U], [f$u])
   325       end;
   326 
   327 fun type_of t : typ = type_of1 ([],t);
   328 
   329 (*Determines the type of a term, with minimal checking*)
   330 fun fastype_of1 (Ts, f$u) =
   331     (case fastype_of1 (Ts,f) of
   332         Type("fun",[_,T]) => T
   333         | _ => raise TERM("fastype_of: expected function type", [f$u]))
   334   | fastype_of1 (_, Const (_,T)) = T
   335   | fastype_of1 (_, Free (_,T)) = T
   336   | fastype_of1 (Ts, Bound i) = (nth Ts i
   337          handle General.Subscript => raise TERM("fastype_of: Bound", [Bound i]))
   338   | fastype_of1 (_, Var (_,T)) = T
   339   | fastype_of1 (Ts, Abs (_,T,u)) = T --> fastype_of1 (T::Ts, u);
   340 
   341 fun fastype_of t : typ = fastype_of1 ([],t);
   342 
   343 (*Determine the argument type of a function*)
   344 fun argument_type_of tm k =
   345   let
   346     fun argT i (Type ("fun", [T, U])) = if i = 0 then T else argT (i - 1) U
   347       | argT _ T = raise TYPE ("argument_type_of", [T], []);
   348 
   349     fun arg 0 _ (Abs (_, T, _)) = T
   350       | arg i Ts (Abs (_, T, t)) = arg (i - 1) (T :: Ts) t
   351       | arg i Ts (t $ _) = arg (i + 1) Ts t
   352       | arg i Ts a = argT i (fastype_of1 (Ts, a));
   353   in arg k [] tm end;
   354 
   355 
   356 fun abs (x, T) t = Abs (x, T, t);
   357 
   358 fun strip_abs (Abs (a, T, t)) =
   359       let val (a', t') = strip_abs t
   360       in ((a, T) :: a', t') end
   361   | strip_abs t = ([], t);
   362 
   363 (* maps  (x1,...,xn)t   to   t  *)
   364 fun strip_abs_body (Abs(_,_,t))  =  strip_abs_body t
   365   | strip_abs_body u  =  u;
   366 
   367 (* maps  (x1,...,xn)t   to   [x1, ..., xn]  *)
   368 fun strip_abs_vars (Abs(a,T,t))  =  (a,T) :: strip_abs_vars t
   369   | strip_abs_vars u  =  [] : (string*typ) list;
   370 
   371 
   372 fun strip_qnt_body qnt =
   373 let fun strip(tm as Const(c,_)$Abs(_,_,t)) = if c=qnt then strip t else tm
   374       | strip t = t
   375 in strip end;
   376 
   377 fun strip_qnt_vars qnt =
   378 let fun strip(Const(c,_)$Abs(a,T,t)) = if c=qnt then (a,T)::strip t else []
   379       | strip t  =  [] : (string*typ) list
   380 in strip end;
   381 
   382 
   383 (* maps   (f, [t1,...,tn])  to  f(t1,...,tn) *)
   384 val list_comb : term * term list -> term = Library.foldl (op $);
   385 
   386 
   387 (* maps   f(t1,...,tn)  to  (f, [t1,...,tn]) ; naturally tail-recursive*)
   388 fun strip_comb u : term * term list =
   389     let fun stripc (f$t, ts) = stripc (f, t::ts)
   390         |   stripc  x =  x
   391     in  stripc(u,[])  end;
   392 
   393 
   394 (* maps   f(t1,...,tn)  to  f , which is never a combination *)
   395 fun head_of (f$t) = head_of f
   396   | head_of u = u;
   397 
   398 (*number of atoms and abstractions in a term*)
   399 fun size_of_term tm =
   400   let
   401     fun add_size (t $ u) n = add_size t (add_size u n)
   402       | add_size (Abs (_ ,_, t)) n = add_size t (n + 1)
   403       | add_size _ n = n + 1;
   404   in add_size tm 0 end;
   405 
   406 (*number of atoms and constructors in a type*)
   407 fun size_of_typ ty =
   408   let
   409     fun add_size (Type (_, tys)) n = fold add_size tys (n + 1)
   410       | add_size _ n = n + 1;
   411   in add_size ty 0 end;
   412 
   413 fun map_atyps f (Type (a, Ts)) = Type (a, map (map_atyps f) Ts)
   414   | map_atyps f T = f T;
   415 
   416 fun map_aterms f (t $ u) = map_aterms f t $ map_aterms f u
   417   | map_aterms f (Abs (a, T, t)) = Abs (a, T, map_aterms f t)
   418   | map_aterms f t = f t;
   419 
   420 fun map_type_tvar f = map_atyps (fn TVar x => f x | T => T);
   421 fun map_type_tfree f = map_atyps (fn TFree x => f x | T => T);
   422 
   423 fun map_types f =
   424   let
   425     fun map_aux (Const (a, T)) = Const (a, f T)
   426       | map_aux (Free (a, T)) = Free (a, f T)
   427       | map_aux (Var (v, T)) = Var (v, f T)
   428       | map_aux (Bound i) = Bound i
   429       | map_aux (Abs (a, T, t)) = Abs (a, f T, map_aux t)
   430       | map_aux (t $ u) = map_aux t $ map_aux u;
   431   in map_aux end;
   432 
   433 
   434 (* fold types and terms *)
   435 
   436 fun fold_atyps f (Type (_, Ts)) = fold (fold_atyps f) Ts
   437   | fold_atyps f T = f T;
   438 
   439 fun fold_atyps_sorts f =
   440   fold_atyps (fn T as TFree (_, S) => f (T, S) | T as TVar (_, S) => f (T, S));
   441 
   442 fun fold_aterms f (t $ u) = fold_aterms f t #> fold_aterms f u
   443   | fold_aterms f (Abs (_, _, t)) = fold_aterms f t
   444   | fold_aterms f a = f a;
   445 
   446 fun fold_term_types f (t as Const (_, T)) = f t T
   447   | fold_term_types f (t as Free (_, T)) = f t T
   448   | fold_term_types f (t as Var (_, T)) = f t T
   449   | fold_term_types f (Bound _) = I
   450   | fold_term_types f (t as Abs (_, T, b)) = f t T #> fold_term_types f b
   451   | fold_term_types f (t $ u) = fold_term_types f t #> fold_term_types f u;
   452 
   453 fun fold_types f = fold_term_types (K f);
   454 
   455 fun replace_types (Const (c, _)) (T :: Ts) = (Const (c, T), Ts)
   456   | replace_types (Free (x, _)) (T :: Ts) = (Free (x, T), Ts)
   457   | replace_types (Var (xi, _)) (T :: Ts) = (Var (xi, T), Ts)
   458   | replace_types (Bound i) Ts = (Bound i, Ts)
   459   | replace_types (Abs (x, _, b)) (T :: Ts) =
   460       let val (b', Ts') = replace_types b Ts
   461       in (Abs (x, T, b'), Ts') end
   462   | replace_types (t $ u) Ts =
   463       let
   464         val (t', Ts') = replace_types t Ts;
   465         val (u', Ts'') = replace_types u Ts';
   466       in (t' $ u', Ts'') end;
   467 
   468 fun burrow_types f ts =
   469   let
   470     val Ts = rev (fold (fold_types cons) ts []);
   471     val Ts' = f Ts;
   472     val (ts', []) = fold_map replace_types ts Ts';
   473   in ts' end;
   474 
   475 (*collect variables*)
   476 val add_tvar_namesT = fold_atyps (fn TVar (xi, _) => insert (op =) xi | _ => I);
   477 val add_tvar_names = fold_types add_tvar_namesT;
   478 val add_tvarsT = fold_atyps (fn TVar v => insert (op =) v | _ => I);
   479 val add_tvars = fold_types add_tvarsT;
   480 val add_var_names = fold_aterms (fn Var (xi, _) => insert (op =) xi | _ => I);
   481 val add_vars = fold_aterms (fn Var v => insert (op =) v | _ => I);
   482 val add_tfree_namesT = fold_atyps (fn TFree (a, _) => insert (op =) a | _ => I);
   483 val add_tfree_names = fold_types add_tfree_namesT;
   484 val add_tfreesT = fold_atyps (fn TFree v => insert (op =) v | _ => I);
   485 val add_tfrees = fold_types add_tfreesT;
   486 val add_free_names = fold_aterms (fn Free (x, _) => insert (op =) x | _ => I);
   487 val add_frees = fold_aterms (fn Free v => insert (op =) v | _ => I);
   488 val add_const_names = fold_aterms (fn Const (c, _) => insert (op =) c | _ => I);
   489 val add_consts = fold_aterms (fn Const c => insert (op =) c | _ => I);
   490 
   491 (*extra type variables in a term, not covered by its type*)
   492 fun hidden_polymorphism t =
   493   let
   494     val T = fastype_of t;
   495     val tvarsT = add_tvarsT T [];
   496     val extra_tvars = fold_types (fold_atyps
   497       (fn TVar v => if member (op =) tvarsT v then I else insert (op =) v | _ => I)) t [];
   498   in extra_tvars end;
   499 
   500 
   501 (* renaming variables *)
   502 
   503 val declare_typ_names = fold_atyps (fn TFree (a, _) => Name.declare a | _ => I);
   504 
   505 fun declare_term_names tm =
   506   fold_aterms
   507     (fn Const (a, _) => Name.declare (Long_Name.base_name a)
   508       | Free (a, _) => Name.declare a
   509       | _ => I) tm #>
   510   fold_types declare_typ_names tm;
   511 
   512 val declare_term_frees = fold_aterms (fn Free (x, _) => Name.declare x | _ => I);
   513 
   514 fun variant_frees t frees =
   515   fst (fold_map Name.variant (map fst frees) (declare_term_names t Name.context)) ~~
   516     map snd frees;
   517 
   518 fun rename_wrt_term t frees = rev (variant_frees t frees);  (*reversed result!*)
   519 
   520 
   521 
   522 (** Comparing terms **)
   523 
   524 (* variables *)
   525 
   526 fun eq_ix ((x, i): indexname, (y, j)) = i = j andalso x = y;
   527 
   528 fun eq_tvar ((xi, S: sort), (xi', S')) = eq_ix (xi, xi') andalso S = S';
   529 fun eq_var ((xi, T: typ), (xi', T')) = eq_ix (xi, xi') andalso T = T';
   530 
   531 
   532 (* alpha equivalence *)
   533 
   534 fun tm1 aconv tm2 =
   535   pointer_eq (tm1, tm2) orelse
   536     (case (tm1, tm2) of
   537       (t1 $ u1, t2 $ u2) => t1 aconv t2 andalso u1 aconv u2
   538     | (Abs (_, T1, t1), Abs (_, T2, t2)) => t1 aconv t2 andalso T1 = T2
   539     | (a1, a2) => a1 = a2);
   540 
   541 fun aconv_untyped (tm1, tm2) =
   542   pointer_eq (tm1, tm2) orelse
   543     (case (tm1, tm2) of
   544       (t1 $ u1, t2 $ u2) => aconv_untyped (t1, t2) andalso aconv_untyped (u1, u2)
   545     | (Abs (_, _, t1), Abs (_, _, t2)) => aconv_untyped (t1, t2)
   546     | (Const (a, _), Const (b, _)) => a = b
   547     | (Free (x, _), Free (y, _)) => x = y
   548     | (Var (xi, _), Var (yj, _)) => xi = yj
   549     | (Bound i, Bound j) => i = j
   550     | _ => false);
   551 
   552 
   553 (*A fast unification filter: true unless the two terms cannot be unified.
   554   Terms must be NORMAL.  Treats all Vars as distinct. *)
   555 fun could_unify (t, u) =
   556   let
   557     fun matchrands (f $ t) (g $ u) = could_unify (t, u) andalso matchrands f g
   558       | matchrands _ _ = true;
   559   in
   560     case (head_of t, head_of u) of
   561       (_, Var _) => true
   562     | (Var _, _) => true
   563     | (Const (a, _), Const (b, _)) => a = b andalso matchrands t u
   564     | (Free (a, _), Free (b, _)) => a = b andalso matchrands t u
   565     | (Bound i, Bound j) => i = j andalso matchrands t u
   566     | (Abs _, _) => true   (*because of possible eta equality*)
   567     | (_, Abs _) => true
   568     | _ => false
   569   end;
   570 
   571 
   572 
   573 (** Connectives of higher order logic **)
   574 
   575 fun aT S = TFree (Name.aT, S);
   576 
   577 fun itselfT ty = Type ("itself", [ty]);
   578 val a_itselfT = itselfT (TFree (Name.aT, []));
   579 
   580 val propT : typ = Type ("prop",[]);
   581 
   582 (* maps  !!x1...xn. t   to   t  *)
   583 fun strip_all_body (Const("all",_)$Abs(_,_,t))  =  strip_all_body t
   584   | strip_all_body t  =  t;
   585 
   586 (* maps  !!x1...xn. t   to   [x1, ..., xn]  *)
   587 fun strip_all_vars (Const("all",_)$Abs(a,T,t))  =
   588                 (a,T) :: strip_all_vars t
   589   | strip_all_vars t  =  [] : (string*typ) list;
   590 
   591 (*increments a term's non-local bound variables
   592   required when moving a term within abstractions
   593      inc is  increment for bound variables
   594      lev is  level at which a bound variable is considered 'loose'*)
   595 fun incr_bv (inc, lev, u as Bound i) = if i>=lev then Bound(i+inc) else u
   596   | incr_bv (inc, lev, Abs(a,T,body)) =
   597         Abs(a, T, incr_bv(inc,lev+1,body))
   598   | incr_bv (inc, lev, f$t) =
   599       incr_bv(inc,lev,f) $ incr_bv(inc,lev,t)
   600   | incr_bv (inc, lev, u) = u;
   601 
   602 fun incr_boundvars  0  t = t
   603   | incr_boundvars inc t = incr_bv(inc,0,t);
   604 
   605 (*Scan a pair of terms; while they are similar,
   606   accumulate corresponding bound vars in "al"*)
   607 fun match_bvs(Abs(x,_,s),Abs(y,_,t), al) =
   608       match_bvs(s, t, if x="" orelse y="" then al
   609                                           else (x,y)::al)
   610   | match_bvs(f$s, g$t, al) = match_bvs(f,g,match_bvs(s,t,al))
   611   | match_bvs(_,_,al) = al;
   612 
   613 (* strip abstractions created by parameters *)
   614 fun match_bvars (s,t) al = match_bvs(strip_abs_body s, strip_abs_body t, al);
   615 
   616 fun map_abs_vars f (t $ u) = map_abs_vars f t $ map_abs_vars f u
   617   | map_abs_vars f (Abs (a, T, t)) = Abs (f a, T, map_abs_vars f t)
   618   | map_abs_vars f t = t;
   619 
   620 fun rename_abs pat obj t =
   621   let
   622     val ren = match_bvs (pat, obj, []);
   623     fun ren_abs (Abs (x, T, b)) =
   624           Abs (the_default x (AList.lookup (op =) ren x), T, ren_abs b)
   625       | ren_abs (f $ t) = ren_abs f $ ren_abs t
   626       | ren_abs t = t
   627   in if null ren then NONE else SOME (ren_abs t) end;
   628 
   629 (*Accumulate all 'loose' bound vars referring to level 'lev' or beyond.
   630    (Bound 0) is loose at level 0 *)
   631 fun add_loose_bnos (Bound i, lev, js) =
   632         if i<lev then js else insert (op =) (i - lev) js
   633   | add_loose_bnos (Abs (_,_,t), lev, js) = add_loose_bnos (t, lev+1, js)
   634   | add_loose_bnos (f$t, lev, js) =
   635         add_loose_bnos (f, lev, add_loose_bnos (t, lev, js))
   636   | add_loose_bnos (_, _, js) = js;
   637 
   638 fun loose_bnos t = add_loose_bnos (t, 0, []);
   639 
   640 (* loose_bvar(t,k) iff t contains a 'loose' bound variable referring to
   641    level k or beyond. *)
   642 fun loose_bvar(Bound i,k) = i >= k
   643   | loose_bvar(f$t, k) = loose_bvar(f,k) orelse loose_bvar(t,k)
   644   | loose_bvar(Abs(_,_,t),k) = loose_bvar(t,k+1)
   645   | loose_bvar _ = false;
   646 
   647 fun loose_bvar1(Bound i,k) = i = k
   648   | loose_bvar1(f$t, k) = loose_bvar1(f,k) orelse loose_bvar1(t,k)
   649   | loose_bvar1(Abs(_,_,t),k) = loose_bvar1(t,k+1)
   650   | loose_bvar1 _ = false;
   651 
   652 fun is_open t = loose_bvar (t, 0);
   653 fun is_dependent t = loose_bvar1 (t, 0);
   654 
   655 (*Substitute arguments for loose bound variables.
   656   Beta-reduction of arg(n-1)...arg0 into t replacing (Bound i) with (argi).
   657   Note that for ((%x y. c) a b), the bound vars in c are x=1 and y=0
   658         and the appropriate call is  subst_bounds([b,a], c) .
   659   Loose bound variables >=n are reduced by "n" to
   660      compensate for the disappearance of lambdas.
   661 *)
   662 fun subst_bounds (args: term list, t) : term =
   663   let
   664     val n = length args;
   665     fun subst (t as Bound i, lev) =
   666          (if i < lev then raise Same.SAME   (*var is locally bound*)
   667           else incr_boundvars lev (nth args (i - lev))
   668             handle General.Subscript => Bound (i - n))  (*loose: change it*)
   669       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   670       | subst (f $ t, lev) =
   671           (subst (f, lev) $ (subst (t, lev) handle Same.SAME => t)
   672             handle Same.SAME => f $ subst (t, lev))
   673       | subst _ = raise Same.SAME;
   674   in case args of [] => t | _ => (subst (t, 0) handle Same.SAME => t) end;
   675 
   676 (*Special case: one argument*)
   677 fun subst_bound (arg, t) : term =
   678   let
   679     fun subst (Bound i, lev) =
   680           if i < lev then raise Same.SAME   (*var is locally bound*)
   681           else if i = lev then incr_boundvars lev arg
   682           else Bound (i - 1)   (*loose: change it*)
   683       | subst (Abs (a, T, body), lev) = Abs (a, T, subst (body, lev + 1))
   684       | subst (f $ t, lev) =
   685           (subst (f, lev) $ (subst (t, lev) handle Same.SAME => t)
   686             handle Same.SAME => f $ subst (t, lev))
   687       | subst _ = raise Same.SAME;
   688   in subst (t, 0) handle Same.SAME => t end;
   689 
   690 (*beta-reduce if possible, else form application*)
   691 fun betapply (Abs(_,_,t), u) = subst_bound (u,t)
   692   | betapply (f,u) = f$u;
   693 
   694 val betapplys = Library.foldl betapply;
   695 
   696 
   697 (*unfolding abstractions with substitution
   698   of bound variables and implicit eta-expansion*)
   699 fun strip_abs_eta k t =
   700   let
   701     val used = fold_aterms declare_term_frees t Name.context;
   702     fun strip_abs t (0, used) = (([], t), (0, used))
   703       | strip_abs (Abs (v, T, t)) (k, used) =
   704           let
   705             val (v', used') = Name.variant v used;
   706             val t' = subst_bound (Free (v', T), t);
   707             val ((vs, t''), (k', used'')) = strip_abs t' (k - 1, used');
   708           in (((v', T) :: vs, t''), (k', used'')) end
   709       | strip_abs t (k, used) = (([], t), (k, used));
   710     fun expand_eta [] t _ = ([], t)
   711       | expand_eta (T::Ts) t used =
   712           let
   713             val (v, used') = Name.variant "" used;
   714             val (vs, t') = expand_eta Ts (t $ Free (v, T)) used';
   715           in ((v, T) :: vs, t') end;
   716     val ((vs1, t'), (k', used')) = strip_abs t (k, used);
   717     val Ts = fst (chop k' (binder_types (fastype_of t')));
   718     val (vs2, t'') = expand_eta Ts t' used';
   719   in (vs1 @ vs2, t'') end;
   720 
   721 
   722 (*Substitute new for free occurrences of old in a term*)
   723 fun subst_free [] = I
   724   | subst_free pairs =
   725       let fun substf u =
   726             case AList.lookup (op aconv) pairs u of
   727                 SOME u' => u'
   728               | NONE => (case u of Abs(a,T,t) => Abs(a, T, substf t)
   729                                  | t$u' => substf t $ substf u'
   730                                  | _ => u)
   731       in  substf  end;
   732 
   733 (*Abstraction of the term "body" over its occurrences of v,
   734     which must contain no loose bound variables.
   735   The resulting term is ready to become the body of an Abs.*)
   736 fun abstract_over (v, body) =
   737   let
   738     fun abs lev tm =
   739       if v aconv tm then Bound lev
   740       else
   741         (case tm of
   742           Abs (a, T, t) => Abs (a, T, abs (lev + 1) t)
   743         | t $ u =>
   744             (abs lev t $ (abs lev u handle Same.SAME => u)
   745               handle Same.SAME => t $ abs lev u)
   746         | _ => raise Same.SAME);
   747   in abs 0 body handle Same.SAME => body end;
   748 
   749 fun term_name (Const (x, _)) = Long_Name.base_name x
   750   | term_name (Free (x, _)) = x
   751   | term_name (Var ((x, _), _)) = x
   752   | term_name _ = Name.uu;
   753 
   754 fun lambda_name (x, v) t =
   755   Abs (if x = "" then term_name v else x, fastype_of v, abstract_over (v, t));
   756 
   757 fun lambda v t = lambda_name ("", v) t;
   758 
   759 fun absfree (a, T) body = Abs (a, T, abstract_over (Free (a, T), body));
   760 fun absdummy T body = Abs (Name.uu_, T, body);
   761 
   762 (*Replace the ATOMIC term ti by ui;    inst = [(t1,u1), ..., (tn,un)].
   763   A simultaneous substitution:  [ (a,b), (b,a) ] swaps a and b.  *)
   764 fun subst_atomic [] tm = tm
   765   | subst_atomic inst tm =
   766       let
   767         fun subst (Abs (a, T, body)) = Abs (a, T, subst body)
   768           | subst (t $ u) = subst t $ subst u
   769           | subst t = the_default t (AList.lookup (op aconv) inst t);
   770       in subst tm end;
   771 
   772 (*Replace the ATOMIC type Ti by Ui;    inst = [(T1,U1), ..., (Tn,Un)].*)
   773 fun typ_subst_atomic [] ty = ty
   774   | typ_subst_atomic inst ty =
   775       let
   776         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   777           | subst T = the_default T (AList.lookup (op = : typ * typ -> bool) inst T);
   778       in subst ty end;
   779 
   780 fun subst_atomic_types [] tm = tm
   781   | subst_atomic_types inst tm = map_types (typ_subst_atomic inst) tm;
   782 
   783 fun typ_subst_TVars [] ty = ty
   784   | typ_subst_TVars inst ty =
   785       let
   786         fun subst (Type (a, Ts)) = Type (a, map subst Ts)
   787           | subst (T as TVar (xi, _)) = the_default T (AList.lookup (op =) inst xi)
   788           | subst T = T;
   789       in subst ty end;
   790 
   791 fun subst_TVars [] tm = tm
   792   | subst_TVars inst tm = map_types (typ_subst_TVars inst) tm;
   793 
   794 fun subst_Vars [] tm = tm
   795   | subst_Vars inst tm =
   796       let
   797         fun subst (t as Var (xi, _)) = the_default t (AList.lookup (op =) inst xi)
   798           | subst (Abs (a, T, t)) = Abs (a, T, subst t)
   799           | subst (t $ u) = subst t $ subst u
   800           | subst t = t;
   801       in subst tm end;
   802 
   803 fun subst_vars ([], []) tm = tm
   804   | subst_vars ([], inst) tm = subst_Vars inst tm
   805   | subst_vars (instT, inst) tm =
   806       let
   807         fun subst (Const (a, T)) = Const (a, typ_subst_TVars instT T)
   808           | subst (Free (a, T)) = Free (a, typ_subst_TVars instT T)
   809           | subst (Var (xi, T)) =
   810               (case AList.lookup (op =) inst xi of
   811                 NONE => Var (xi, typ_subst_TVars instT T)
   812               | SOME t => t)
   813           | subst (t as Bound _) = t
   814           | subst (Abs (a, T, t)) = Abs (a, typ_subst_TVars instT T, subst t)
   815           | subst (t $ u) = subst t $ subst u;
   816       in subst tm end;
   817 
   818 fun close_schematic_term t =
   819   let
   820     val extra_types = map (fn v => Const ("TYPE", itselfT (TVar v))) (hidden_polymorphism t);
   821     val extra_terms = map Var (add_vars t []);
   822   in fold lambda (extra_terms @ extra_types) t end;
   823 
   824 
   825 
   826 (** Identifying first-order terms **)
   827 
   828 (*Differs from proofterm/is_fun in its treatment of TVar*)
   829 fun is_funtype (Type ("fun", [_, _])) = true
   830   | is_funtype _ = false;
   831 
   832 (*Argument Ts is a reverse list of binder types, needed if term t contains Bound vars*)
   833 fun has_not_funtype Ts t = not (is_funtype (fastype_of1 (Ts, t)));
   834 
   835 (*First order means in all terms of the form f(t1,...,tn) no argument has a
   836   function type. The supplied quantifiers are excluded: their argument always
   837   has a function type through a recursive call into its body.*)
   838 fun is_first_order quants =
   839   let fun first_order1 Ts (Abs (_,T,body)) = first_order1 (T::Ts) body
   840         | first_order1 Ts (Const(q,_) $ Abs(a,T,body)) =
   841             member (op =) quants q  andalso   (*it is a known quantifier*)
   842             not (is_funtype T)   andalso first_order1 (T::Ts) body
   843         | first_order1 Ts t =
   844             case strip_comb t of
   845                  (Var _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
   846                | (Free _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
   847                | (Const _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
   848                | (Bound _, ts) => forall (first_order1 Ts andf has_not_funtype Ts) ts
   849                | (Abs _, ts) => false (*not in beta-normal form*)
   850                | _ => error "first_order: unexpected case"
   851     in  first_order1 []  end;
   852 
   853 
   854 (* maximum index of typs and terms *)
   855 
   856 fun maxidx_typ (TVar ((_, j), _)) i = Int.max (i, j)
   857   | maxidx_typ (Type (_, Ts)) i = maxidx_typs Ts i
   858   | maxidx_typ (TFree _) i = i
   859 and maxidx_typs [] i = i
   860   | maxidx_typs (T :: Ts) i = maxidx_typs Ts (maxidx_typ T i);
   861 
   862 fun maxidx_term (Var ((_, j), T)) i = maxidx_typ T (Int.max (i, j))
   863   | maxidx_term (Const (_, T)) i = maxidx_typ T i
   864   | maxidx_term (Free (_, T)) i = maxidx_typ T i
   865   | maxidx_term (Bound _) i = i
   866   | maxidx_term (Abs (_, T, t)) i = maxidx_term t (maxidx_typ T i)
   867   | maxidx_term (t $ u) i = maxidx_term u (maxidx_term t i);
   868 
   869 fun maxidx_of_typ T = maxidx_typ T ~1;
   870 fun maxidx_of_typs Ts = maxidx_typs Ts ~1;
   871 fun maxidx_of_term t = maxidx_term t ~1;
   872 
   873 
   874 
   875 (** misc syntax operations **)
   876 
   877 (* substructure *)
   878 
   879 fun exists_subtype P =
   880   let
   881     fun ex ty = P ty orelse
   882       (case ty of Type (_, Ts) => exists ex Ts | _ => false);
   883   in ex end;
   884 
   885 fun exists_type P =
   886   let
   887     fun ex (Const (_, T)) = P T
   888       | ex (Free (_, T)) = P T
   889       | ex (Var (_, T)) = P T
   890       | ex (Bound _) = false
   891       | ex (Abs (_, T, t)) = P T orelse ex t
   892       | ex (t $ u) = ex t orelse ex u;
   893   in ex end;
   894 
   895 fun exists_subterm P =
   896   let
   897     fun ex tm = P tm orelse
   898       (case tm of
   899         t $ u => ex t orelse ex u
   900       | Abs (_, _, t) => ex t
   901       | _ => false);
   902   in ex end;
   903 
   904 fun exists_Const P = exists_subterm (fn Const c => P c | _ => false);
   905 
   906 fun has_abs (Abs _) = true
   907   | has_abs (t $ u) = has_abs t orelse has_abs u
   908   | has_abs _ = false;
   909 
   910 
   911 (* dest abstraction *)
   912 
   913 fun dest_abs (x, T, body) =
   914   let
   915     fun name_clash (Free (y, _)) = (x = y)
   916       | name_clash (t $ u) = name_clash t orelse name_clash u
   917       | name_clash (Abs (_, _, t)) = name_clash t
   918       | name_clash _ = false;
   919   in
   920     if name_clash body then
   921       dest_abs (singleton (Name.variant_list [x]) x, T, body)    (*potentially slow*)
   922     else (x, subst_bound (Free (x, T), body))
   923   end;
   924 
   925 
   926 (* dummy patterns *)
   927 
   928 val dummy_patternN = "dummy_pattern";
   929 
   930 fun dummy_pattern T = Const (dummy_patternN, T);
   931 val dummy = dummy_pattern dummyT;
   932 val dummy_prop = dummy_pattern propT;
   933 
   934 fun is_dummy_pattern (Const ("dummy_pattern", _)) = true
   935   | is_dummy_pattern _ = false;
   936 
   937 fun no_dummy_patterns tm =
   938   if not (fold_aterms (fn t => fn b => b orelse is_dummy_pattern t) tm false) then tm
   939   else raise TERM ("Illegal occurrence of '_' dummy pattern", [tm]);
   940 
   941 fun free_dummy_patterns (Const ("dummy_pattern", T)) used =
   942       let val [x] = Name.invent used Name.uu 1
   943       in (Free (Name.internal x, T), Name.declare x used) end
   944   | free_dummy_patterns (Abs (x, T, b)) used =
   945       let val (b', used') = free_dummy_patterns b used
   946       in (Abs (x, T, b'), used') end
   947   | free_dummy_patterns (t $ u) used =
   948       let
   949         val (t', used') = free_dummy_patterns t used;
   950         val (u', used'') = free_dummy_patterns u used';
   951       in (t' $ u', used'') end
   952   | free_dummy_patterns a used = (a, used);
   953 
   954 fun replace_dummy Ts (Const ("dummy_pattern", T)) i =
   955       (list_comb (Var (("_dummy_", i), Ts ---> T), map_range Bound (length Ts)), i + 1)
   956   | replace_dummy Ts (Abs (x, T, t)) i =
   957       let val (t', i') = replace_dummy (T :: Ts) t i
   958       in (Abs (x, T, t'), i') end
   959   | replace_dummy Ts (t $ u) i =
   960       let
   961         val (t', i') = replace_dummy Ts t i;
   962         val (u', i'') = replace_dummy Ts u i';
   963       in (t' $ u', i'') end
   964   | replace_dummy _ a i = (a, i);
   965 
   966 val replace_dummy_patterns = replace_dummy [];
   967 
   968 fun is_replaced_dummy_pattern ("_dummy_", _) = true
   969   | is_replaced_dummy_pattern _ = false;
   970 
   971 fun show_dummy_patterns (Var (("_dummy_", _), T)) = dummy_pattern T
   972   | show_dummy_patterns (t $ u) = show_dummy_patterns t $ show_dummy_patterns u
   973   | show_dummy_patterns (Abs (x, T, t)) = Abs (x, T, show_dummy_patterns t)
   974   | show_dummy_patterns a = a;
   975 
   976 
   977 (* display variables *)
   978 
   979 fun string_of_vname (x, i) =
   980   let
   981     val idx = string_of_int i;
   982     val dot =
   983       (case rev (Symbol.explode x) of
   984         _ :: "\\<^isub>" :: _ => false
   985       | _ :: "\\<^isup>" :: _ => false
   986       | c :: _ => Symbol.is_digit c
   987       | _ => true);
   988   in
   989     if dot then "?" ^ x ^ "." ^ idx
   990     else if i <> 0 then "?" ^ x ^ idx
   991     else "?" ^ x
   992   end;
   993 
   994 fun string_of_vname' (x, ~1) = x
   995   | string_of_vname' xi = string_of_vname xi;
   996 
   997 end;
   998 
   999 structure Basic_Term: BASIC_TERM = Term;
  1000 open Basic_Term;