src/Pure/sign.ML
author wenzelm
Mon Mar 15 21:59:28 2010 +0100 (2010-03-15)
changeset 35801 952308389b8b
parent 35800 76b2a53a199d
child 35845 e5980f0ad025
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/sign.ML
     2     Author:     Lawrence C Paulson and Markus Wenzel
     3 
     4 Logical signature content: naming conventions, concrete syntax, type
     5 signature, polymorphic constants.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   val rep_sg: theory ->
    11    {naming: Name_Space.naming,
    12     syn: Syntax.syntax,
    13     tsig: Type.tsig,
    14     consts: Consts.T}
    15   val map_naming: (Name_Space.naming -> Name_Space.naming) -> theory -> theory
    16   val naming_of: theory -> Name_Space.naming
    17   val full_name: theory -> binding -> string
    18   val full_name_path: theory -> string -> binding -> string
    19   val full_bname: theory -> bstring -> string
    20   val full_bname_path: theory -> string -> bstring -> string
    21   val syn_of: theory -> Syntax.syntax
    22   val tsig_of: theory -> Type.tsig
    23   val classes_of: theory -> Sorts.algebra
    24   val all_classes: theory -> class list
    25   val super_classes: theory -> class -> class list
    26   val minimize_sort: theory -> sort -> sort
    27   val complete_sort: theory -> sort -> sort
    28   val defaultS: theory -> sort
    29   val subsort: theory -> sort * sort -> bool
    30   val of_sort: theory -> typ * sort -> bool
    31   val witness_sorts: theory -> (typ * sort) list -> sort list -> (typ * sort) list
    32   val is_logtype: theory -> string -> bool
    33   val typ_instance: theory -> typ * typ -> bool
    34   val typ_equiv: theory -> typ * typ -> bool
    35   val typ_match: theory -> typ * typ -> Type.tyenv -> Type.tyenv
    36   val typ_unify: theory -> typ * typ -> Type.tyenv * int -> Type.tyenv * int
    37   val consts_of: theory -> Consts.T
    38   val the_const_constraint: theory -> string -> typ
    39   val const_type: theory -> string -> typ option
    40   val the_const_type: theory -> string -> typ
    41   val declared_tyname: theory -> string -> bool
    42   val declared_const: theory -> string -> bool
    43   val const_monomorphic: theory -> string -> bool
    44   val const_typargs: theory -> string * typ -> typ list
    45   val const_instance: theory -> string * typ list -> typ
    46   val mk_const: theory -> string * typ list -> term
    47   val class_space: theory -> Name_Space.T
    48   val type_space: theory -> Name_Space.T
    49   val const_space: theory -> Name_Space.T
    50   val class_alias: binding -> class -> theory -> theory
    51   val type_alias: binding -> string -> theory -> theory
    52   val const_alias: binding -> string -> theory -> theory
    53   val intern_class: theory -> xstring -> string
    54   val extern_class: theory -> string -> xstring
    55   val intern_type: theory -> xstring -> string
    56   val extern_type: theory -> string -> xstring
    57   val intern_const: theory -> xstring -> string
    58   val extern_const: theory -> string -> xstring
    59   val arity_number: theory -> string -> int
    60   val arity_sorts: theory -> string -> sort -> sort list
    61   val certify_class: theory -> class -> class
    62   val certify_sort: theory -> sort -> sort
    63   val certify_typ: theory -> typ -> typ
    64   val certify_typ_mode: Type.mode -> theory -> typ -> typ
    65   val certify': bool -> Pretty.pp -> bool -> Consts.T -> theory -> term -> term * typ * int
    66   val certify_term: theory -> term -> term * typ * int
    67   val cert_term: theory -> term -> term
    68   val cert_prop: theory -> term -> term
    69   val no_frees: Pretty.pp -> term -> term
    70   val no_vars: Pretty.pp -> term -> term
    71   val cert_def: Proof.context -> term -> (string * typ) * term
    72   val add_defsort: string -> theory -> theory
    73   val add_defsort_i: sort -> theory -> theory
    74   val add_types: (binding * int * mixfix) list -> theory -> theory
    75   val add_nonterminals: binding list -> theory -> theory
    76   val add_tyabbrs: (binding * string list * string * mixfix) list -> theory -> theory
    77   val add_tyabbrs_i: (binding * string list * typ * mixfix) list -> theory -> theory
    78   val add_syntax: (string * string * mixfix) list -> theory -> theory
    79   val add_syntax_i: (string * typ * mixfix) list -> theory -> theory
    80   val add_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    81   val add_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    82   val del_modesyntax: Syntax.mode -> (string * string * mixfix) list -> theory -> theory
    83   val del_modesyntax_i: Syntax.mode -> (string * typ * mixfix) list -> theory -> theory
    84   val type_notation: bool -> Syntax.mode -> (typ * mixfix) list -> theory -> theory
    85   val notation: bool -> Syntax.mode -> (term * mixfix) list -> theory -> theory
    86   val declare_const: (binding * typ) * mixfix -> theory -> term * theory
    87   val add_consts: (binding * string * mixfix) list -> theory -> theory
    88   val add_consts_i: (binding * typ * mixfix) list -> theory -> theory
    89   val add_abbrev: string -> binding * term -> theory -> (term * term) * theory
    90   val revert_abbrev: string -> string -> theory -> theory
    91   val add_const_constraint: string * typ option -> theory -> theory
    92   val primitive_class: binding * class list -> theory -> theory
    93   val primitive_classrel: class * class -> theory -> theory
    94   val primitive_arity: arity -> theory -> theory
    95   val add_trfuns:
    96     (string * (ast list -> ast)) list *
    97     (string * (term list -> term)) list *
    98     (string * (term list -> term)) list *
    99     (string * (ast list -> ast)) list -> theory -> theory
   100   val add_trfunsT:
   101     (string * (bool -> typ -> term list -> term)) list -> theory -> theory
   102   val add_advanced_trfuns:
   103     (string * (Proof.context -> ast list -> ast)) list *
   104     (string * (Proof.context -> term list -> term)) list *
   105     (string * (Proof.context -> term list -> term)) list *
   106     (string * (Proof.context -> ast list -> ast)) list -> theory -> theory
   107   val add_advanced_trfunsT:
   108     (string * (Proof.context -> bool -> typ -> term list -> term)) list -> theory -> theory
   109   val add_tokentrfuns:
   110     (string * string * (Proof.context -> string -> Pretty.T)) list -> theory -> theory
   111   val add_mode_tokentrfuns: string -> (string * (Proof.context -> string -> Pretty.T)) list
   112     -> theory -> theory
   113   val add_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   114   val del_trrules: (xstring * string) Syntax.trrule list -> theory -> theory
   115   val add_trrules_i: ast Syntax.trrule list -> theory -> theory
   116   val del_trrules_i: ast Syntax.trrule list -> theory -> theory
   117   val new_group: theory -> theory
   118   val reset_group: theory -> theory
   119   val add_path: string -> theory -> theory
   120   val root_path: theory -> theory
   121   val parent_path: theory -> theory
   122   val mandatory_path: string -> theory -> theory
   123   val qualified_path: bool -> binding -> theory -> theory
   124   val local_path: theory -> theory
   125   val restore_naming: theory -> theory -> theory
   126   val hide_class: bool -> string -> theory -> theory
   127   val hide_type: bool -> string -> theory -> theory
   128   val hide_const: bool -> string -> theory -> theory
   129 end
   130 
   131 structure Sign: SIGN =
   132 struct
   133 
   134 (** datatype sign **)
   135 
   136 datatype sign = Sign of
   137  {naming: Name_Space.naming,    (*common naming conventions*)
   138   syn: Syntax.syntax,           (*concrete syntax for terms, types, sorts*)
   139   tsig: Type.tsig,              (*order-sorted signature of types*)
   140   consts: Consts.T};            (*polymorphic constants*)
   141 
   142 fun make_sign (naming, syn, tsig, consts) =
   143   Sign {naming = naming, syn = syn, tsig = tsig, consts = consts};
   144 
   145 structure Data = Theory_Data_PP
   146 (
   147   type T = sign;
   148   fun extend (Sign {syn, tsig, consts, ...}) =
   149     make_sign (Name_Space.default_naming, syn, tsig, consts);
   150 
   151   val empty =
   152     make_sign (Name_Space.default_naming, Syntax.basic_syntax, Type.empty_tsig, Consts.empty);
   153 
   154   fun merge pp (sign1, sign2) =
   155     let
   156       val Sign {naming = _, syn = syn1, tsig = tsig1, consts = consts1} = sign1;
   157       val Sign {naming = _, syn = syn2, tsig = tsig2, consts = consts2} = sign2;
   158 
   159       val naming = Name_Space.default_naming;
   160       val syn = Syntax.merge_syntaxes syn1 syn2;
   161       val tsig = Type.merge_tsigs pp (tsig1, tsig2);
   162       val consts = Consts.merge (consts1, consts2);
   163     in make_sign (naming, syn, tsig, consts) end;
   164 );
   165 
   166 fun rep_sg thy = Data.get thy |> (fn Sign args => args);
   167 
   168 fun map_sign f = Data.map (fn Sign {naming, syn, tsig, consts} =>
   169   make_sign (f (naming, syn, tsig, consts)));
   170 
   171 fun map_naming f = map_sign (fn (naming, syn, tsig, consts) => (f naming, syn, tsig, consts));
   172 fun map_syn f = map_sign (fn (naming, syn, tsig, consts) => (naming, f syn, tsig, consts));
   173 fun map_tsig f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, f tsig, consts));
   174 fun map_consts f = map_sign (fn (naming, syn, tsig, consts) => (naming, syn, tsig, f consts));
   175 
   176 
   177 (* naming *)
   178 
   179 val naming_of = #naming o rep_sg;
   180 
   181 val full_name = Name_Space.full_name o naming_of;
   182 fun full_name_path thy path = Name_Space.full_name (Name_Space.add_path path (naming_of thy));
   183 
   184 fun full_bname thy = Name_Space.full_name (naming_of thy) o Binding.name;
   185 fun full_bname_path thy path = full_name_path thy path o Binding.name;
   186 
   187 
   188 (* syntax *)
   189 
   190 val syn_of = #syn o rep_sg;
   191 
   192 
   193 (* type signature *)
   194 
   195 val tsig_of = #tsig o rep_sg;
   196 
   197 val classes_of = #2 o #classes o Type.rep_tsig o tsig_of;
   198 val all_classes = Sorts.all_classes o classes_of;
   199 val super_classes = Sorts.super_classes o classes_of;
   200 val minimize_sort = Sorts.minimize_sort o classes_of;
   201 val complete_sort = Sorts.complete_sort o classes_of;
   202 
   203 val defaultS = Type.defaultS o tsig_of;
   204 val subsort = Type.subsort o tsig_of;
   205 val of_sort = Type.of_sort o tsig_of;
   206 val witness_sorts = Type.witness_sorts o tsig_of;
   207 val is_logtype = member (op =) o Type.logical_types o tsig_of;
   208 
   209 val typ_instance = Type.typ_instance o tsig_of;
   210 fun typ_equiv thy (T, U) = typ_instance thy (T, U) andalso typ_instance thy (U, T);
   211 val typ_match = Type.typ_match o tsig_of;
   212 val typ_unify = Type.unify o tsig_of;
   213 
   214 
   215 (* polymorphic constants *)
   216 
   217 val consts_of = #consts o rep_sg;
   218 val the_const_constraint = Consts.the_constraint o consts_of;
   219 val the_const_type = Consts.the_type o consts_of;
   220 val const_type = try o the_const_type;
   221 val const_monomorphic = Consts.is_monomorphic o consts_of;
   222 val const_typargs = Consts.typargs o consts_of;
   223 val const_instance = Consts.instance o consts_of;
   224 
   225 fun mk_const thy (c, Ts) = Const (c, const_instance thy (c, Ts));
   226 
   227 val declared_tyname = Symtab.defined o #2 o #types o Type.rep_tsig o tsig_of;
   228 val declared_const = can o the_const_constraint;
   229 
   230 
   231 
   232 (** intern / extern names **)
   233 
   234 val class_space = Type.class_space o tsig_of;
   235 val type_space = Type.type_space o tsig_of;
   236 val const_space = Consts.space_of o consts_of;
   237 
   238 fun class_alias b c thy = map_tsig (Type.class_alias (naming_of thy) b c) thy;
   239 fun type_alias b c thy = map_tsig (Type.type_alias (naming_of thy) b c) thy;
   240 fun const_alias b c thy = map_consts (Consts.alias (naming_of thy) b c) thy;
   241 
   242 val intern_class = Name_Space.intern o class_space;
   243 val extern_class = Name_Space.extern o class_space;
   244 val intern_type = Name_Space.intern o type_space;
   245 val extern_type = Name_Space.extern o type_space;
   246 val intern_const = Name_Space.intern o const_space;
   247 val extern_const = Name_Space.extern o const_space;
   248 
   249 
   250 
   251 (** certify entities **)    (*exception TYPE*)
   252 
   253 (* certify wrt. type signature *)
   254 
   255 val arity_number = Type.arity_number o tsig_of;
   256 fun arity_sorts thy = Type.arity_sorts (Syntax.pp_global thy) (tsig_of thy);
   257 
   258 val certify_class         = Type.cert_class o tsig_of;
   259 val certify_sort          = Type.cert_sort o tsig_of;
   260 val certify_typ           = Type.cert_typ o tsig_of;
   261 fun certify_typ_mode mode = Type.cert_typ_mode mode o tsig_of;
   262 
   263 
   264 (* certify term/prop *)
   265 
   266 local
   267 
   268 fun type_check pp tm =
   269   let
   270     fun err_appl why bs t T u U =
   271       let
   272         val xs = map Free bs;           (*we do not rename here*)
   273         val t' = subst_bounds (xs, t);
   274         val u' = subst_bounds (xs, u);
   275         val msg = cat_lines
   276           (TypeInfer.appl_error (Syntax.pp_show_brackets pp) why t' T u' U);
   277       in raise TYPE (msg, [T, U], [t', u']) end;
   278 
   279     fun typ_of (_, Const (_, T)) = T
   280       | typ_of (_, Free  (_, T)) = T
   281       | typ_of (_, Var (_, T)) = T
   282       | typ_of (bs, Bound i) = snd (nth bs i handle Subscript =>
   283           raise TYPE ("Loose bound variable: B." ^ string_of_int i, [], [Bound i]))
   284       | typ_of (bs, Abs (x, T, body)) = T --> typ_of ((x, T) :: bs, body)
   285       | typ_of (bs, t $ u) =
   286           let val T = typ_of (bs, t) and U = typ_of (bs, u) in
   287             (case T of
   288               Type ("fun", [T1, T2]) =>
   289                 if T1 = U then T2 else err_appl "Incompatible operand type" bs t T u U
   290             | _ => err_appl "Operator not of function type" bs t T u U)
   291           end;
   292   in typ_of ([], tm) end;
   293 
   294 fun err msg = raise TYPE (msg, [], []);
   295 
   296 fun check_vars (t $ u) = (check_vars t; check_vars u)
   297   | check_vars (Abs (_, _, t)) = check_vars t
   298   | check_vars (Free (x, _)) =
   299       if Long_Name.is_qualified x then err ("Malformed variable: " ^ quote x) else ()
   300   | check_vars (Var (xi as (_, i), _)) =
   301       if i < 0 then err ("Malformed variable: " ^ quote (Term.string_of_vname xi)) else ()
   302   | check_vars _ = ();
   303 
   304 in
   305 
   306 fun certify' prop pp do_expand consts thy tm =
   307   let
   308     val _ = check_vars tm;
   309     val tm' = Term.map_types (certify_typ thy) tm;
   310     val T = type_check pp tm';
   311     val _ = if prop andalso T <> propT then err "Term not of type prop" else ();
   312     val tm'' = Consts.certify pp (tsig_of thy) do_expand consts tm';
   313   in (if tm = tm'' then tm else tm'', T, Term.maxidx_of_term tm'') end;
   314 
   315 fun certify_term thy = certify' false (Syntax.pp_global thy) true (consts_of thy) thy;
   316 fun cert_term_abbrev thy = #1 o certify' false (Syntax.pp_global thy) false (consts_of thy) thy;
   317 val cert_term = #1 oo certify_term;
   318 fun cert_prop thy = #1 o certify' true (Syntax.pp_global thy) true (consts_of thy) thy;
   319 
   320 end;
   321 
   322 
   323 (* specifications *)
   324 
   325 fun no_variables kind add addT mk mkT pp tm =
   326   (case (add tm [], addT tm []) of
   327     ([], []) => tm
   328   | (frees, tfrees) => error (Pretty.string_of (Pretty.block
   329       (Pretty.str ("Illegal " ^ kind ^ " variable(s) in term:") :: Pretty.brk 1 ::
   330        Pretty.commas (map (Pretty.term pp o mk) frees @ map (Pretty.typ pp o mkT) tfrees)))));
   331 
   332 val no_frees = no_variables "free" Term.add_frees Term.add_tfrees Free TFree;
   333 val no_vars = no_variables "schematic" Term.add_vars Term.add_tvars Var TVar;
   334 
   335 fun cert_def ctxt tm =
   336   let val ((lhs, rhs), _) = tm
   337     |> no_vars (Syntax.pp ctxt)
   338     |> Logic.strip_imp_concl
   339     |> Primitive_Defs.dest_def ctxt Term.is_Const (K false) (K false)
   340   in (Term.dest_Const (Term.head_of lhs), rhs) end
   341   handle TERM (msg, _) => error msg;
   342 
   343 
   344 
   345 (** signature extension functions **)  (*exception ERROR/TYPE*)
   346 
   347 (* add default sort *)
   348 
   349 fun gen_add_defsort prep_sort s thy =
   350   thy |> map_tsig (Type.set_defsort (prep_sort thy s));
   351 
   352 val add_defsort = gen_add_defsort Syntax.read_sort_global;
   353 val add_defsort_i = gen_add_defsort certify_sort;
   354 
   355 
   356 (* add type constructors *)
   357 
   358 val type_syntax = Syntax.mark_type oo full_name;
   359 
   360 fun add_types types thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   361   let
   362     val syn' =
   363       Syntax.update_type_gram true Syntax.mode_default
   364         (map (fn (a, n, mx) => (type_syntax thy a, Syntax.make_type n, mx)) types) syn;
   365     val decls = map (fn (a, n, _) => (a, n)) types;
   366     val tsig' = fold (Type.add_type naming) decls tsig;
   367   in (naming, syn', tsig', consts) end);
   368 
   369 
   370 (* add nonterminals *)
   371 
   372 fun add_nonterminals ns thy = thy |> map_sign (fn (naming, syn, tsig, consts) =>
   373   let
   374     val tsig' = fold (Type.add_nonterminal naming) ns tsig;
   375   in (naming, syn, tsig', consts) end);
   376 
   377 
   378 (* add type abbreviations *)
   379 
   380 fun gen_add_tyabbr parse_typ (b, vs, rhs, mx) thy =
   381   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   382     let
   383       val ctxt = ProofContext.init thy;
   384       val syn' =
   385         Syntax.update_type_gram true Syntax.mode_default
   386           [(type_syntax thy b, Syntax.make_type (length vs), mx)] syn;
   387       val abbr = (b, vs, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt rhs))
   388         handle ERROR msg => cat_error msg ("in type abbreviation " ^ quote (Binding.str_of b));
   389       val tsig' = Type.add_abbrev naming abbr tsig;
   390     in (naming, syn', tsig', consts) end);
   391 
   392 val add_tyabbrs = fold (gen_add_tyabbr Syntax.parse_typ);
   393 val add_tyabbrs_i = fold (gen_add_tyabbr (K I));
   394 
   395 
   396 (* modify syntax *)
   397 
   398 fun gen_syntax change_gram parse_typ mode args thy =
   399   let
   400     val ctxt = ProofContext.init thy;
   401     fun prep (c, T, mx) = (c, certify_typ_mode Type.mode_syntax thy (parse_typ ctxt T), mx)
   402       handle ERROR msg => cat_error msg ("in syntax declaration " ^ quote c);
   403   in thy |> map_syn (change_gram (is_logtype thy) mode (map prep args)) end;
   404 
   405 fun gen_add_syntax x = gen_syntax (Syntax.update_const_gram true) x;
   406 
   407 val add_modesyntax = gen_add_syntax Syntax.parse_typ;
   408 val add_modesyntax_i = gen_add_syntax (K I);
   409 val add_syntax = add_modesyntax Syntax.mode_default;
   410 val add_syntax_i = add_modesyntax_i Syntax.mode_default;
   411 val del_modesyntax = gen_syntax (Syntax.update_const_gram false) Syntax.parse_typ;
   412 val del_modesyntax_i = gen_syntax (Syntax.update_const_gram false) (K I);
   413 
   414 fun type_notation add mode args =
   415   let
   416     fun type_syntax (Type (c, args), mx) =
   417           SOME (Syntax.mark_type c, Syntax.make_type (length args), mx)
   418       | type_syntax _ = NONE;
   419   in map_syn (Syntax.update_type_gram add mode (map_filter type_syntax args)) end;
   420 
   421 fun notation add mode args thy =
   422   let
   423     fun const_syntax (Const (c, _), mx) =
   424           (case try (Consts.type_scheme (consts_of thy)) c of
   425             SOME T => SOME (Syntax.mark_const c, T, mx)
   426           | NONE => NONE)
   427       | const_syntax _ = NONE;
   428   in gen_syntax (Syntax.update_const_gram add) (K I) mode (map_filter const_syntax args) thy end;
   429 
   430 
   431 (* add constants *)
   432 
   433 local
   434 
   435 fun gen_add_consts parse_typ raw_args thy =
   436   let
   437     val ctxt = ProofContext.init thy;
   438     val prepT = Type.no_tvars o Term.no_dummyT o certify_typ thy o parse_typ ctxt;
   439     fun prep (b, raw_T, mx) =
   440       let
   441         val c = full_name thy b;
   442         val T = (prepT raw_T handle TYPE (msg, _, _) => error msg) handle ERROR msg =>
   443           cat_error msg ("in declaration of constant " ^ quote (Binding.str_of b));
   444         val T' = Logic.varifyT T;
   445       in ((b, T'), (Syntax.mark_const c, T', mx), Const (c, T)) end;
   446     val args = map prep raw_args;
   447   in
   448     thy
   449     |> map_consts (fold (Consts.declare (naming_of thy) o #1) args)
   450     |> add_syntax_i (map #2 args)
   451     |> pair (map #3 args)
   452   end;
   453 
   454 in
   455 
   456 fun add_consts args = snd o gen_add_consts Syntax.parse_typ args;
   457 fun add_consts_i args = snd o gen_add_consts (K I) args;
   458 
   459 fun declare_const ((b, T), mx) thy =
   460   let
   461     val pos = Binding.pos_of b;
   462     val ([const as Const (c, _)], thy') = gen_add_consts (K I) [(b, T, mx)] thy;
   463     val _ = Position.report (Markup.const_decl c) pos;
   464   in (const, thy') end;
   465 
   466 end;
   467 
   468 
   469 (* abbreviations *)
   470 
   471 fun add_abbrev mode (b, raw_t) thy =
   472   let
   473     val pp = Syntax.pp_global thy;
   474     val prep_tm = no_frees pp o Term.no_dummy_patterns o cert_term_abbrev thy;
   475     val t = (prep_tm raw_t handle TYPE (msg, _, _) => error msg | TERM (msg, _) => error msg)
   476       handle ERROR msg => cat_error msg ("in constant abbreviation " ^ quote (Binding.str_of b));
   477     val (res, consts') = consts_of thy
   478       |> Consts.abbreviate pp (tsig_of thy) (naming_of thy) mode (b, t);
   479   in (res, thy |> map_consts (K consts')) end;
   480 
   481 fun revert_abbrev mode c = map_consts (Consts.revert_abbrev mode c);
   482 
   483 
   484 (* add constraints *)
   485 
   486 fun add_const_constraint (c, opt_T) thy =
   487   let
   488     fun prepT raw_T =
   489       let val T = Logic.varifyT (Type.no_tvars (Term.no_dummyT (certify_typ thy raw_T)))
   490       in cert_term thy (Const (c, T)); T end
   491       handle TYPE (msg, _, _) => error msg;
   492   in thy |> map_consts (Consts.constrain (c, Option.map prepT opt_T)) end;
   493 
   494 
   495 (* primitive classes and arities *)
   496 
   497 fun primitive_class (bclass, classes) thy =
   498   thy |> map_sign (fn (naming, syn, tsig, consts) =>
   499     let
   500       val tsig' = Type.add_class (Syntax.pp_global thy) naming (bclass, classes) tsig;
   501     in (naming, syn, tsig', consts) end)
   502   |> add_consts_i [(Binding.map_name Logic.const_of_class bclass, Term.a_itselfT --> propT, NoSyn)];
   503 
   504 fun primitive_classrel arg thy = thy |> map_tsig (Type.add_classrel (Syntax.pp_global thy) arg);
   505 fun primitive_arity arg thy = thy |> map_tsig (Type.add_arity (Syntax.pp_global thy) arg);
   506 
   507 
   508 (* add translation functions *)
   509 
   510 local
   511 
   512 fun mk trs = map Syntax.mk_trfun trs;
   513 
   514 fun gen_add_trfuns ext non_typed (atrs, trs, tr's, atr's) =
   515   map_syn (ext (mk atrs, mk trs, mk (map (apsnd non_typed) tr's), mk atr's));
   516 
   517 fun gen_add_trfunsT ext tr's = map_syn (ext ([], [], mk tr's, []));
   518 
   519 in
   520 
   521 val add_trfuns = gen_add_trfuns Syntax.update_trfuns Syntax.non_typed_tr';
   522 val add_trfunsT = gen_add_trfunsT Syntax.update_trfuns;
   523 val add_advanced_trfuns = gen_add_trfuns Syntax.update_advanced_trfuns Syntax.non_typed_tr'';
   524 val add_advanced_trfunsT = gen_add_trfunsT Syntax.update_advanced_trfuns;
   525 
   526 end;
   527 
   528 val add_tokentrfuns = map_syn o Syntax.extend_tokentrfuns;
   529 fun add_mode_tokentrfuns m = add_tokentrfuns o map (fn (s, f) => (m, s, f));
   530 
   531 
   532 (* translation rules *)
   533 
   534 fun gen_trrules f args thy = thy |> map_syn (fn syn =>
   535   let val rules = map (Syntax.map_trrule (apfst (intern_type thy))) args
   536   in f (ProofContext.init thy) (is_logtype thy) syn rules syn end);
   537 
   538 val add_trrules = gen_trrules Syntax.update_trrules;
   539 val del_trrules = gen_trrules Syntax.remove_trrules;
   540 val add_trrules_i = map_syn o Syntax.update_trrules_i;
   541 val del_trrules_i = map_syn o Syntax.remove_trrules_i;
   542 
   543 
   544 (* naming *)
   545 
   546 val new_group = map_naming Name_Space.new_group;
   547 val reset_group = map_naming Name_Space.reset_group;
   548 
   549 val add_path = map_naming o Name_Space.add_path;
   550 val root_path = map_naming Name_Space.root_path;
   551 val parent_path = map_naming Name_Space.parent_path;
   552 val mandatory_path = map_naming o Name_Space.mandatory_path;
   553 val qualified_path = map_naming oo Name_Space.qualified_path;
   554 
   555 fun local_path thy = thy |> root_path |> add_path (Context.theory_name thy);
   556 
   557 val restore_naming = map_naming o K o naming_of;
   558 
   559 
   560 (* hide names *)
   561 
   562 val hide_class = map_tsig oo Type.hide_class;
   563 val hide_type = map_tsig oo Type.hide_type;
   564 val hide_const = map_consts oo Consts.hide;
   565 
   566 end;