src/HOL/HOL.thy
author wenzelm
Mon May 12 17:17:32 2014 +0200 (2014-05-12)
changeset 56941 952833323c99
parent 56375 32e0da92c786
child 57512 cc97b347b301
permissions -rw-r--r--
tuned signature to make axiomatizations more easy to spot in the source, via "add_axioms" or "axiomatization";
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 keywords
    10   "try" "solve_direct" "quickcheck" "print_coercions" "print_claset"
    11     "print_induct_rules" :: diag and
    12   "quickcheck_params" :: thy_decl
    13 begin
    14 
    15 ML_file "~~/src/Tools/misc_legacy.ML"
    16 ML_file "~~/src/Tools/try.ML"
    17 ML_file "~~/src/Tools/quickcheck.ML"
    18 ML_file "~~/src/Tools/solve_direct.ML"
    19 ML_file "~~/src/Tools/IsaPlanner/zipper.ML"
    20 ML_file "~~/src/Tools/IsaPlanner/isand.ML"
    21 ML_file "~~/src/Tools/IsaPlanner/rw_inst.ML"
    22 ML_file "~~/src/Provers/hypsubst.ML"
    23 ML_file "~~/src/Provers/splitter.ML"
    24 ML_file "~~/src/Provers/classical.ML"
    25 ML_file "~~/src/Provers/blast.ML"
    26 ML_file "~~/src/Provers/clasimp.ML"
    27 ML_file "~~/src/Tools/eqsubst.ML"
    28 ML_file "~~/src/Provers/quantifier1.ML"
    29 ML_file "~~/src/Tools/atomize_elim.ML"
    30 ML_file "~~/src/Tools/induct.ML"
    31 ML_file "~~/src/Tools/cong_tac.ML"
    32 ML_file "~~/src/Tools/intuitionistic.ML"
    33 ML_file "~~/src/Tools/project_rule.ML"
    34 ML_file "~~/src/Tools/subtyping.ML"
    35 ML_file "~~/src/Tools/case_product.ML"
    36 
    37 setup {*
    38   Intuitionistic.method_setup @{binding iprover}
    39   #> Subtyping.setup
    40   #> Case_Product.setup
    41 *}
    42 
    43 subsection {* Primitive logic *}
    44 
    45 subsubsection {* Core syntax *}
    46 
    47 setup {* Axclass.class_axiomatization (@{binding type}, []) *}
    48 default_sort type
    49 setup {* Object_Logic.add_base_sort @{sort type} *}
    50 
    51 axiomatization where fun_arity: "OFCLASS('a \<Rightarrow> 'b, type_class)"
    52 instance "fun" :: (type, type) type by (rule fun_arity)
    53 
    54 axiomatization where itself_arity: "OFCLASS('a itself, type_class)"
    55 instance itself :: (type) type by (rule itself_arity)
    56 
    57 typedecl bool
    58 
    59 judgment
    60   Trueprop      :: "bool => prop"                   ("(_)" 5)
    61 
    62 axiomatization
    63   implies       :: "[bool, bool] => bool"           (infixr "-->" 25)  and
    64   eq            :: "['a, 'a] => bool"               (infixl "=" 50)  and
    65   The           :: "('a => bool) => 'a"
    66 
    67 consts
    68   True          :: bool
    69   False         :: bool
    70   Not           :: "bool => bool"                   ("~ _" [40] 40)
    71 
    72   conj          :: "[bool, bool] => bool"           (infixr "&" 35)
    73   disj          :: "[bool, bool] => bool"           (infixr "|" 30)
    74 
    75   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    76   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    77   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    78 
    79 
    80 subsubsection {* Additional concrete syntax *}
    81 
    82 notation (output)
    83   eq  (infix "=" 50)
    84 
    85 abbreviation
    86   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    87   "x ~= y == ~ (x = y)"
    88 
    89 notation (output)
    90   not_equal  (infix "~=" 50)
    91 
    92 notation (xsymbols)
    93   Not  ("\<not> _" [40] 40) and
    94   conj  (infixr "\<and>" 35) and
    95   disj  (infixr "\<or>" 30) and
    96   implies  (infixr "\<longrightarrow>" 25) and
    97   not_equal  (infixl "\<noteq>" 50)
    98 
    99 notation (xsymbols output)
   100   not_equal  (infix "\<noteq>" 50)
   101 
   102 notation (HTML output)
   103   Not  ("\<not> _" [40] 40) and
   104   conj  (infixr "\<and>" 35) and
   105   disj  (infixr "\<or>" 30) and
   106   not_equal  (infix "\<noteq>" 50)
   107 
   108 abbreviation (iff)
   109   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   110   "A <-> B == A = B"
   111 
   112 notation (xsymbols)
   113   iff  (infixr "\<longleftrightarrow>" 25)
   114 
   115 syntax "_The" :: "[pttrn, bool] => 'a"  ("(3THE _./ _)" [0, 10] 10)
   116 translations "THE x. P" == "CONST The (%x. P)"
   117 print_translation {*
   118   [(@{const_syntax The}, fn _ => fn [Abs abs] =>
   119       let val (x, t) = Syntax_Trans.atomic_abs_tr' abs
   120       in Syntax.const @{syntax_const "_The"} $ x $ t end)]
   121 *}  -- {* To avoid eta-contraction of body *}
   122 
   123 nonterminal letbinds and letbind
   124 syntax
   125   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   126   ""            :: "letbind => letbinds"                 ("_")
   127   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   128   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" [0, 10] 10)
   129 
   130 nonterminal case_syn and cases_syn
   131 syntax
   132   "_case_syntax" :: "['a, cases_syn] => 'b"  ("(case _ of/ _)" 10)
   133   "_case1" :: "['a, 'b] => case_syn"  ("(2_ =>/ _)" 10)
   134   "" :: "case_syn => cases_syn"  ("_")
   135   "_case2" :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   136 syntax (xsymbols)
   137   "_case1" :: "['a, 'b] => case_syn"  ("(2_ \<Rightarrow>/ _)" 10)
   138 
   139 notation (xsymbols)
   140   All  (binder "\<forall>" 10) and
   141   Ex  (binder "\<exists>" 10) and
   142   Ex1  (binder "\<exists>!" 10)
   143 
   144 notation (HTML output)
   145   All  (binder "\<forall>" 10) and
   146   Ex  (binder "\<exists>" 10) and
   147   Ex1  (binder "\<exists>!" 10)
   148 
   149 notation (HOL)
   150   All  (binder "! " 10) and
   151   Ex  (binder "? " 10) and
   152   Ex1  (binder "?! " 10)
   153 
   154 
   155 subsubsection {* Axioms and basic definitions *}
   156 
   157 axiomatization where
   158   refl: "t = (t::'a)" and
   159   subst: "s = t \<Longrightarrow> P s \<Longrightarrow> P t" and
   160   ext: "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   161     -- {*Extensionality is built into the meta-logic, and this rule expresses
   162          a related property.  It is an eta-expanded version of the traditional
   163          rule, and similar to the ABS rule of HOL*} and
   164 
   165   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   166 
   167 axiomatization where
   168   impI: "(P ==> Q) ==> P-->Q" and
   169   mp: "[| P-->Q;  P |] ==> Q" and
   170 
   171   iff: "(P-->Q) --> (Q-->P) --> (P=Q)" and
   172   True_or_False: "(P=True) | (P=False)"
   173 
   174 defs
   175   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   176   All_def:      "All(P)    == (P = (%x. True))"
   177   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   178   False_def:    "False     == (!P. P)"
   179   not_def:      "~ P       == P-->False"
   180   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   181   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   182   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   183 
   184 definition If :: "bool \<Rightarrow> 'a \<Rightarrow> 'a \<Rightarrow> 'a" ("(if (_)/ then (_)/ else (_))" [0, 0, 10] 10)
   185   where "If P x y \<equiv> (THE z::'a. (P=True --> z=x) & (P=False --> z=y))"
   186 
   187 definition Let :: "'a \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> 'b"
   188   where "Let s f \<equiv> f s"
   189 
   190 translations
   191   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   192   "let x = a in e"        == "CONST Let a (%x. e)"
   193 
   194 axiomatization undefined :: 'a
   195 
   196 class default = fixes default :: 'a
   197 
   198 
   199 subsection {* Fundamental rules *}
   200 
   201 subsubsection {* Equality *}
   202 
   203 lemma sym: "s = t ==> t = s"
   204   by (erule subst) (rule refl)
   205 
   206 lemma ssubst: "t = s ==> P s ==> P t"
   207   by (drule sym) (erule subst)
   208 
   209 lemma trans: "[| r=s; s=t |] ==> r=t"
   210   by (erule subst)
   211 
   212 lemma trans_sym [Pure.elim?]: "r = s ==> t = s ==> r = t"
   213   by (rule trans [OF _ sym])
   214 
   215 lemma meta_eq_to_obj_eq: 
   216   assumes meq: "A == B"
   217   shows "A = B"
   218   by (unfold meq) (rule refl)
   219 
   220 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   221      (* a = b
   222         |   |
   223         c = d   *)
   224 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   225 apply (rule trans)
   226 apply (rule trans)
   227 apply (rule sym)
   228 apply assumption+
   229 done
   230 
   231 text {* For calculational reasoning: *}
   232 
   233 lemma forw_subst: "a = b ==> P b ==> P a"
   234   by (rule ssubst)
   235 
   236 lemma back_subst: "P a ==> a = b ==> P b"
   237   by (rule subst)
   238 
   239 
   240 subsubsection {* Congruence rules for application *}
   241 
   242 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   243 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   244 apply (erule subst)
   245 apply (rule refl)
   246 done
   247 
   248 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   249 lemma arg_cong: "x=y ==> f(x)=f(y)"
   250 apply (erule subst)
   251 apply (rule refl)
   252 done
   253 
   254 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   255 apply (erule ssubst)+
   256 apply (rule refl)
   257 done
   258 
   259 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   260 apply (erule subst)+
   261 apply (rule refl)
   262 done
   263 
   264 ML {* val cong_tac = Cong_Tac.cong_tac @{thm cong} *}
   265 
   266 
   267 subsubsection {* Equality of booleans -- iff *}
   268 
   269 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   270   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   271 
   272 lemma iffD2: "[| P=Q; Q |] ==> P"
   273   by (erule ssubst)
   274 
   275 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   276   by (erule iffD2)
   277 
   278 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   279   by (drule sym) (rule iffD2)
   280 
   281 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   282   by (drule sym) (rule rev_iffD2)
   283 
   284 lemma iffE:
   285   assumes major: "P=Q"
   286     and minor: "[| P --> Q; Q --> P |] ==> R"
   287   shows R
   288   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   289 
   290 
   291 subsubsection {*True*}
   292 
   293 lemma TrueI: "True"
   294   unfolding True_def by (rule refl)
   295 
   296 lemma eqTrueI: "P ==> P = True"
   297   by (iprover intro: iffI TrueI)
   298 
   299 lemma eqTrueE: "P = True ==> P"
   300   by (erule iffD2) (rule TrueI)
   301 
   302 
   303 subsubsection {*Universal quantifier*}
   304 
   305 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   306   unfolding All_def by (iprover intro: ext eqTrueI assms)
   307 
   308 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   309 apply (unfold All_def)
   310 apply (rule eqTrueE)
   311 apply (erule fun_cong)
   312 done
   313 
   314 lemma allE:
   315   assumes major: "ALL x. P(x)"
   316     and minor: "P(x) ==> R"
   317   shows R
   318   by (iprover intro: minor major [THEN spec])
   319 
   320 lemma all_dupE:
   321   assumes major: "ALL x. P(x)"
   322     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   323   shows R
   324   by (iprover intro: minor major major [THEN spec])
   325 
   326 
   327 subsubsection {* False *}
   328 
   329 text {*
   330   Depends upon @{text spec}; it is impossible to do propositional
   331   logic before quantifiers!
   332 *}
   333 
   334 lemma FalseE: "False ==> P"
   335   apply (unfold False_def)
   336   apply (erule spec)
   337   done
   338 
   339 lemma False_neq_True: "False = True ==> P"
   340   by (erule eqTrueE [THEN FalseE])
   341 
   342 
   343 subsubsection {* Negation *}
   344 
   345 lemma notI:
   346   assumes "P ==> False"
   347   shows "~P"
   348   apply (unfold not_def)
   349   apply (iprover intro: impI assms)
   350   done
   351 
   352 lemma False_not_True: "False ~= True"
   353   apply (rule notI)
   354   apply (erule False_neq_True)
   355   done
   356 
   357 lemma True_not_False: "True ~= False"
   358   apply (rule notI)
   359   apply (drule sym)
   360   apply (erule False_neq_True)
   361   done
   362 
   363 lemma notE: "[| ~P;  P |] ==> R"
   364   apply (unfold not_def)
   365   apply (erule mp [THEN FalseE])
   366   apply assumption
   367   done
   368 
   369 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   370   by (erule notE [THEN notI]) (erule meta_mp)
   371 
   372 
   373 subsubsection {*Implication*}
   374 
   375 lemma impE:
   376   assumes "P-->Q" "P" "Q ==> R"
   377   shows "R"
   378 by (iprover intro: assms mp)
   379 
   380 (* Reduces Q to P-->Q, allowing substitution in P. *)
   381 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   382 by (iprover intro: mp)
   383 
   384 lemma contrapos_nn:
   385   assumes major: "~Q"
   386       and minor: "P==>Q"
   387   shows "~P"
   388 by (iprover intro: notI minor major [THEN notE])
   389 
   390 (*not used at all, but we already have the other 3 combinations *)
   391 lemma contrapos_pn:
   392   assumes major: "Q"
   393       and minor: "P ==> ~Q"
   394   shows "~P"
   395 by (iprover intro: notI minor major notE)
   396 
   397 lemma not_sym: "t ~= s ==> s ~= t"
   398   by (erule contrapos_nn) (erule sym)
   399 
   400 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   401   by (erule subst, erule ssubst, assumption)
   402 
   403 
   404 subsubsection {*Existential quantifier*}
   405 
   406 lemma exI: "P x ==> EX x::'a. P x"
   407 apply (unfold Ex_def)
   408 apply (iprover intro: allI allE impI mp)
   409 done
   410 
   411 lemma exE:
   412   assumes major: "EX x::'a. P(x)"
   413       and minor: "!!x. P(x) ==> Q"
   414   shows "Q"
   415 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   416 apply (iprover intro: impI [THEN allI] minor)
   417 done
   418 
   419 
   420 subsubsection {*Conjunction*}
   421 
   422 lemma conjI: "[| P; Q |] ==> P&Q"
   423 apply (unfold and_def)
   424 apply (iprover intro: impI [THEN allI] mp)
   425 done
   426 
   427 lemma conjunct1: "[| P & Q |] ==> P"
   428 apply (unfold and_def)
   429 apply (iprover intro: impI dest: spec mp)
   430 done
   431 
   432 lemma conjunct2: "[| P & Q |] ==> Q"
   433 apply (unfold and_def)
   434 apply (iprover intro: impI dest: spec mp)
   435 done
   436 
   437 lemma conjE:
   438   assumes major: "P&Q"
   439       and minor: "[| P; Q |] ==> R"
   440   shows "R"
   441 apply (rule minor)
   442 apply (rule major [THEN conjunct1])
   443 apply (rule major [THEN conjunct2])
   444 done
   445 
   446 lemma context_conjI:
   447   assumes "P" "P ==> Q" shows "P & Q"
   448 by (iprover intro: conjI assms)
   449 
   450 
   451 subsubsection {*Disjunction*}
   452 
   453 lemma disjI1: "P ==> P|Q"
   454 apply (unfold or_def)
   455 apply (iprover intro: allI impI mp)
   456 done
   457 
   458 lemma disjI2: "Q ==> P|Q"
   459 apply (unfold or_def)
   460 apply (iprover intro: allI impI mp)
   461 done
   462 
   463 lemma disjE:
   464   assumes major: "P|Q"
   465       and minorP: "P ==> R"
   466       and minorQ: "Q ==> R"
   467   shows "R"
   468 by (iprover intro: minorP minorQ impI
   469                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   470 
   471 
   472 subsubsection {*Classical logic*}
   473 
   474 lemma classical:
   475   assumes prem: "~P ==> P"
   476   shows "P"
   477 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   478 apply assumption
   479 apply (rule notI [THEN prem, THEN eqTrueI])
   480 apply (erule subst)
   481 apply assumption
   482 done
   483 
   484 lemmas ccontr = FalseE [THEN classical]
   485 
   486 (*notE with premises exchanged; it discharges ~R so that it can be used to
   487   make elimination rules*)
   488 lemma rev_notE:
   489   assumes premp: "P"
   490       and premnot: "~R ==> ~P"
   491   shows "R"
   492 apply (rule ccontr)
   493 apply (erule notE [OF premnot premp])
   494 done
   495 
   496 (*Double negation law*)
   497 lemma notnotD: "~~P ==> P"
   498 apply (rule classical)
   499 apply (erule notE)
   500 apply assumption
   501 done
   502 
   503 lemma contrapos_pp:
   504   assumes p1: "Q"
   505       and p2: "~P ==> ~Q"
   506   shows "P"
   507 by (iprover intro: classical p1 p2 notE)
   508 
   509 
   510 subsubsection {*Unique existence*}
   511 
   512 lemma ex1I:
   513   assumes "P a" "!!x. P(x) ==> x=a"
   514   shows "EX! x. P(x)"
   515 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   516 
   517 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   518 lemma ex_ex1I:
   519   assumes ex_prem: "EX x. P(x)"
   520       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   521   shows "EX! x. P(x)"
   522 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   523 
   524 lemma ex1E:
   525   assumes major: "EX! x. P(x)"
   526       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   527   shows "R"
   528 apply (rule major [unfolded Ex1_def, THEN exE])
   529 apply (erule conjE)
   530 apply (iprover intro: minor)
   531 done
   532 
   533 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   534 apply (erule ex1E)
   535 apply (rule exI)
   536 apply assumption
   537 done
   538 
   539 
   540 subsubsection {*THE: definite description operator*}
   541 
   542 lemma the_equality:
   543   assumes prema: "P a"
   544       and premx: "!!x. P x ==> x=a"
   545   shows "(THE x. P x) = a"
   546 apply (rule trans [OF _ the_eq_trivial])
   547 apply (rule_tac f = "The" in arg_cong)
   548 apply (rule ext)
   549 apply (rule iffI)
   550  apply (erule premx)
   551 apply (erule ssubst, rule prema)
   552 done
   553 
   554 lemma theI:
   555   assumes "P a" and "!!x. P x ==> x=a"
   556   shows "P (THE x. P x)"
   557 by (iprover intro: assms the_equality [THEN ssubst])
   558 
   559 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   560 apply (erule ex1E)
   561 apply (erule theI)
   562 apply (erule allE)
   563 apply (erule mp)
   564 apply assumption
   565 done
   566 
   567 (*Easier to apply than theI: only one occurrence of P*)
   568 lemma theI2:
   569   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   570   shows "Q (THE x. P x)"
   571 by (iprover intro: assms theI)
   572 
   573 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   574 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   575            elim:allE impE)
   576 
   577 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   578 apply (rule the_equality)
   579 apply  assumption
   580 apply (erule ex1E)
   581 apply (erule all_dupE)
   582 apply (drule mp)
   583 apply  assumption
   584 apply (erule ssubst)
   585 apply (erule allE)
   586 apply (erule mp)
   587 apply assumption
   588 done
   589 
   590 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   591 apply (rule the_equality)
   592 apply (rule refl)
   593 apply (erule sym)
   594 done
   595 
   596 
   597 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   598 
   599 lemma disjCI:
   600   assumes "~Q ==> P" shows "P|Q"
   601 apply (rule classical)
   602 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   603 done
   604 
   605 lemma excluded_middle: "~P | P"
   606 by (iprover intro: disjCI)
   607 
   608 text {*
   609   case distinction as a natural deduction rule.
   610   Note that @{term "~P"} is the second case, not the first
   611 *}
   612 lemma case_split [case_names True False]:
   613   assumes prem1: "P ==> Q"
   614       and prem2: "~P ==> Q"
   615   shows "Q"
   616 apply (rule excluded_middle [THEN disjE])
   617 apply (erule prem2)
   618 apply (erule prem1)
   619 done
   620 
   621 (*Classical implies (-->) elimination. *)
   622 lemma impCE:
   623   assumes major: "P-->Q"
   624       and minor: "~P ==> R" "Q ==> R"
   625   shows "R"
   626 apply (rule excluded_middle [of P, THEN disjE])
   627 apply (iprover intro: minor major [THEN mp])+
   628 done
   629 
   630 (*This version of --> elimination works on Q before P.  It works best for
   631   those cases in which P holds "almost everywhere".  Can't install as
   632   default: would break old proofs.*)
   633 lemma impCE':
   634   assumes major: "P-->Q"
   635       and minor: "Q ==> R" "~P ==> R"
   636   shows "R"
   637 apply (rule excluded_middle [of P, THEN disjE])
   638 apply (iprover intro: minor major [THEN mp])+
   639 done
   640 
   641 (*Classical <-> elimination. *)
   642 lemma iffCE:
   643   assumes major: "P=Q"
   644       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   645   shows "R"
   646 apply (rule major [THEN iffE])
   647 apply (iprover intro: minor elim: impCE notE)
   648 done
   649 
   650 lemma exCI:
   651   assumes "ALL x. ~P(x) ==> P(a)"
   652   shows "EX x. P(x)"
   653 apply (rule ccontr)
   654 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   655 done
   656 
   657 
   658 subsubsection {* Intuitionistic Reasoning *}
   659 
   660 lemma impE':
   661   assumes 1: "P --> Q"
   662     and 2: "Q ==> R"
   663     and 3: "P --> Q ==> P"
   664   shows R
   665 proof -
   666   from 3 and 1 have P .
   667   with 1 have Q by (rule impE)
   668   with 2 show R .
   669 qed
   670 
   671 lemma allE':
   672   assumes 1: "ALL x. P x"
   673     and 2: "P x ==> ALL x. P x ==> Q"
   674   shows Q
   675 proof -
   676   from 1 have "P x" by (rule spec)
   677   from this and 1 show Q by (rule 2)
   678 qed
   679 
   680 lemma notE':
   681   assumes 1: "~ P"
   682     and 2: "~ P ==> P"
   683   shows R
   684 proof -
   685   from 2 and 1 have P .
   686   with 1 show R by (rule notE)
   687 qed
   688 
   689 lemma TrueE: "True ==> P ==> P" .
   690 lemma notFalseE: "~ False ==> P ==> P" .
   691 
   692 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   693   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   694   and [Pure.elim 2] = allE notE' impE'
   695   and [Pure.intro] = exI disjI2 disjI1
   696 
   697 lemmas [trans] = trans
   698   and [sym] = sym not_sym
   699   and [Pure.elim?] = iffD1 iffD2 impE
   700 
   701 
   702 subsubsection {* Atomizing meta-level connectives *}
   703 
   704 axiomatization where
   705   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   706 
   707 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   708 proof
   709   assume "!!x. P x"
   710   then show "ALL x. P x" ..
   711 next
   712   assume "ALL x. P x"
   713   then show "!!x. P x" by (rule allE)
   714 qed
   715 
   716 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   717 proof
   718   assume r: "A ==> B"
   719   show "A --> B" by (rule impI) (rule r)
   720 next
   721   assume "A --> B" and A
   722   then show B by (rule mp)
   723 qed
   724 
   725 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   726 proof
   727   assume r: "A ==> False"
   728   show "~A" by (rule notI) (rule r)
   729 next
   730   assume "~A" and A
   731   then show False by (rule notE)
   732 qed
   733 
   734 lemma atomize_eq [atomize, code]: "(x == y) == Trueprop (x = y)"
   735 proof
   736   assume "x == y"
   737   show "x = y" by (unfold `x == y`) (rule refl)
   738 next
   739   assume "x = y"
   740   then show "x == y" by (rule eq_reflection)
   741 qed
   742 
   743 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   744 proof
   745   assume conj: "A &&& B"
   746   show "A & B"
   747   proof (rule conjI)
   748     from conj show A by (rule conjunctionD1)
   749     from conj show B by (rule conjunctionD2)
   750   qed
   751 next
   752   assume conj: "A & B"
   753   show "A &&& B"
   754   proof -
   755     from conj show A ..
   756     from conj show B ..
   757   qed
   758 qed
   759 
   760 lemmas [symmetric, rulify] = atomize_all atomize_imp
   761   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   762 
   763 
   764 subsubsection {* Atomizing elimination rules *}
   765 
   766 setup AtomizeElim.setup
   767 
   768 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   769   by rule iprover+
   770 
   771 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   772   by rule iprover+
   773 
   774 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   775   by rule iprover+
   776 
   777 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   778 
   779 
   780 subsection {* Package setup *}
   781 
   782 ML_file "Tools/hologic.ML"
   783 
   784 
   785 subsubsection {* Sledgehammer setup *}
   786 
   787 text {*
   788 Theorems blacklisted to Sledgehammer. These theorems typically produce clauses
   789 that are prolific (match too many equality or membership literals) and relate to
   790 seldom-used facts. Some duplicate other rules.
   791 *}
   792 
   793 ML {*
   794 structure No_ATPs = Named_Thms
   795 (
   796   val name = @{binding no_atp}
   797   val description = "theorems that should be filtered out by Sledgehammer"
   798 )
   799 *}
   800 
   801 setup {* No_ATPs.setup *}
   802 
   803 
   804 subsubsection {* Classical Reasoner setup *}
   805 
   806 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   807   by (rule classical) iprover
   808 
   809 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   810   by (rule classical) iprover
   811 
   812 lemma thin_refl:
   813   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   814 
   815 ML {*
   816 structure Hypsubst = Hypsubst
   817 (
   818   val dest_eq = HOLogic.dest_eq
   819   val dest_Trueprop = HOLogic.dest_Trueprop
   820   val dest_imp = HOLogic.dest_imp
   821   val eq_reflection = @{thm eq_reflection}
   822   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   823   val imp_intr = @{thm impI}
   824   val rev_mp = @{thm rev_mp}
   825   val subst = @{thm subst}
   826   val sym = @{thm sym}
   827   val thin_refl = @{thm thin_refl};
   828 );
   829 open Hypsubst;
   830 
   831 structure Classical = Classical
   832 (
   833   val imp_elim = @{thm imp_elim}
   834   val not_elim = @{thm notE}
   835   val swap = @{thm swap}
   836   val classical = @{thm classical}
   837   val sizef = Drule.size_of_thm
   838   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   839 );
   840 
   841 structure Basic_Classical: BASIC_CLASSICAL = Classical; 
   842 open Basic_Classical;
   843 *}
   844 
   845 setup Classical.setup
   846 
   847 setup {*
   848 let
   849   fun non_bool_eq (@{const_name HOL.eq}, Type (_, [T, _])) = T <> @{typ bool}
   850     | non_bool_eq _ = false;
   851   fun hyp_subst_tac' ctxt =
   852     SUBGOAL (fn (goal, i) =>
   853       if Term.exists_Const non_bool_eq goal
   854       then Hypsubst.hyp_subst_tac ctxt i
   855       else no_tac);
   856 in
   857   Hypsubst.hypsubst_setup
   858   (*prevent substitution on bool*)
   859   #> Context_Rules.addSWrapper (fn ctxt => fn tac => hyp_subst_tac' ctxt ORELSE' tac)
   860 end
   861 *}
   862 
   863 declare iffI [intro!]
   864   and notI [intro!]
   865   and impI [intro!]
   866   and disjCI [intro!]
   867   and conjI [intro!]
   868   and TrueI [intro!]
   869   and refl [intro!]
   870 
   871 declare iffCE [elim!]
   872   and FalseE [elim!]
   873   and impCE [elim!]
   874   and disjE [elim!]
   875   and conjE [elim!]
   876 
   877 declare ex_ex1I [intro!]
   878   and allI [intro!]
   879   and the_equality [intro]
   880   and exI [intro]
   881 
   882 declare exE [elim!]
   883   allE [elim]
   884 
   885 ML {* val HOL_cs = claset_of @{context} *}
   886 
   887 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   888   apply (erule swap)
   889   apply (erule (1) meta_mp)
   890   done
   891 
   892 declare ex_ex1I [rule del, intro! 2]
   893   and ex1I [intro]
   894 
   895 declare ext [intro]
   896 
   897 lemmas [intro?] = ext
   898   and [elim?] = ex1_implies_ex
   899 
   900 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   901 lemma alt_ex1E [elim!]:
   902   assumes major: "\<exists>!x. P x"
   903       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   904   shows R
   905 apply (rule ex1E [OF major])
   906 apply (rule prem)
   907 apply (tactic {* ares_tac @{thms allI} 1 *})+
   908 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   909 apply iprover
   910 done
   911 
   912 ML {*
   913   structure Blast = Blast
   914   (
   915     structure Classical = Classical
   916     val Trueprop_const = dest_Const @{const Trueprop}
   917     val equality_name = @{const_name HOL.eq}
   918     val not_name = @{const_name Not}
   919     val notE = @{thm notE}
   920     val ccontr = @{thm ccontr}
   921     val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   922   );
   923   val blast_tac = Blast.blast_tac;
   924 *}
   925 
   926 setup Blast.setup
   927 
   928 
   929 subsubsection {* Simplifier *}
   930 
   931 lemma eta_contract_eq: "(%s. f s) = f" ..
   932 
   933 lemma simp_thms:
   934   shows not_not: "(~ ~ P) = P"
   935   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   936   and
   937     "(P ~= Q) = (P = (~Q))"
   938     "(P | ~P) = True"    "(~P | P) = True"
   939     "(x = x) = True"
   940   and not_True_eq_False [code]: "(\<not> True) = False"
   941   and not_False_eq_True [code]: "(\<not> False) = True"
   942   and
   943     "(~P) ~= P"  "P ~= (~P)"
   944     "(True=P) = P"
   945   and eq_True: "(P = True) = P"
   946   and "(False=P) = (~P)"
   947   and eq_False: "(P = False) = (\<not> P)"
   948   and
   949     "(True --> P) = P"  "(False --> P) = True"
   950     "(P --> True) = True"  "(P --> P) = True"
   951     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   952     "(P & True) = P"  "(True & P) = P"
   953     "(P & False) = False"  "(False & P) = False"
   954     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   955     "(P & ~P) = False"    "(~P & P) = False"
   956     "(P | True) = True"  "(True | P) = True"
   957     "(P | False) = P"  "(False | P) = P"
   958     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   959     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   960   and
   961     "!!P. (EX x. x=t & P(x)) = P(t)"
   962     "!!P. (EX x. t=x & P(x)) = P(t)"
   963     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   964     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   965   by (blast, blast, blast, blast, blast, iprover+)
   966 
   967 lemma disj_absorb: "(A | A) = A"
   968   by blast
   969 
   970 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   971   by blast
   972 
   973 lemma conj_absorb: "(A & A) = A"
   974   by blast
   975 
   976 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   977   by blast
   978 
   979 lemma eq_ac:
   980   shows eq_commute: "(a=b) = (b=a)"
   981     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   982     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
   983 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
   984 
   985 lemma conj_comms:
   986   shows conj_commute: "(P&Q) = (Q&P)"
   987     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
   988 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
   989 
   990 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   991 
   992 lemma disj_comms:
   993   shows disj_commute: "(P|Q) = (Q|P)"
   994     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
   995 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
   996 
   997 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
   998 
   999 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1000 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1001 
  1002 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1003 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1004 
  1005 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1006 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1007 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1008 
  1009 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1010 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1011 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1012 
  1013 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1014 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1015 
  1016 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1017   by iprover
  1018 
  1019 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1020 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1021 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1022 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1023 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1024 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1025   by blast
  1026 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1027 
  1028 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1029 
  1030 
  1031 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1032   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1033   -- {* cases boil down to the same thing. *}
  1034   by blast
  1035 
  1036 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1037 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1038 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1039 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1040 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1041 
  1042 declare All_def [no_atp]
  1043 
  1044 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1045 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1046 
  1047 text {*
  1048   \medskip The @{text "&"} congruence rule: not included by default!
  1049   May slow rewrite proofs down by as much as 50\% *}
  1050 
  1051 lemma conj_cong:
  1052     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1053   by iprover
  1054 
  1055 lemma rev_conj_cong:
  1056     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1057   by iprover
  1058 
  1059 text {* The @{text "|"} congruence rule: not included by default! *}
  1060 
  1061 lemma disj_cong:
  1062     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1063   by blast
  1064 
  1065 
  1066 text {* \medskip if-then-else rules *}
  1067 
  1068 lemma if_True [code]: "(if True then x else y) = x"
  1069   by (unfold If_def) blast
  1070 
  1071 lemma if_False [code]: "(if False then x else y) = y"
  1072   by (unfold If_def) blast
  1073 
  1074 lemma if_P: "P ==> (if P then x else y) = x"
  1075   by (unfold If_def) blast
  1076 
  1077 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1078   by (unfold If_def) blast
  1079 
  1080 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1081   apply (rule case_split [of Q])
  1082    apply (simplesubst if_P)
  1083     prefer 3 apply (simplesubst if_not_P, blast+)
  1084   done
  1085 
  1086 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1087 by (simplesubst split_if, blast)
  1088 
  1089 lemmas if_splits [no_atp] = split_if split_if_asm
  1090 
  1091 lemma if_cancel: "(if c then x else x) = x"
  1092 by (simplesubst split_if, blast)
  1093 
  1094 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1095 by (simplesubst split_if, blast)
  1096 
  1097 lemma if_bool_eq_conj:
  1098 "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1099   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1100   by (rule split_if)
  1101 
  1102 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1103   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1104   apply (simplesubst split_if, blast)
  1105   done
  1106 
  1107 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1108 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1109 
  1110 text {* \medskip let rules for simproc *}
  1111 
  1112 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1113   by (unfold Let_def)
  1114 
  1115 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1116   by (unfold Let_def)
  1117 
  1118 text {*
  1119   The following copy of the implication operator is useful for
  1120   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1121   its premise.
  1122 *}
  1123 
  1124 definition simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1) where
  1125   "simp_implies \<equiv> op ==>"
  1126 
  1127 lemma simp_impliesI:
  1128   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1129   shows "PROP P =simp=> PROP Q"
  1130   apply (unfold simp_implies_def)
  1131   apply (rule PQ)
  1132   apply assumption
  1133   done
  1134 
  1135 lemma simp_impliesE:
  1136   assumes PQ: "PROP P =simp=> PROP Q"
  1137   and P: "PROP P"
  1138   and QR: "PROP Q \<Longrightarrow> PROP R"
  1139   shows "PROP R"
  1140   apply (rule QR)
  1141   apply (rule PQ [unfolded simp_implies_def])
  1142   apply (rule P)
  1143   done
  1144 
  1145 lemma simp_implies_cong:
  1146   assumes PP' :"PROP P == PROP P'"
  1147   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1148   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1149 proof (unfold simp_implies_def, rule equal_intr_rule)
  1150   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1151   and P': "PROP P'"
  1152   from PP' [symmetric] and P' have "PROP P"
  1153     by (rule equal_elim_rule1)
  1154   then have "PROP Q" by (rule PQ)
  1155   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1156 next
  1157   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1158   and P: "PROP P"
  1159   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1160   then have "PROP Q'" by (rule P'Q')
  1161   with P'QQ' [OF P', symmetric] show "PROP Q"
  1162     by (rule equal_elim_rule1)
  1163 qed
  1164 
  1165 lemma uncurry:
  1166   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1167   shows "P \<and> Q \<longrightarrow> R"
  1168   using assms by blast
  1169 
  1170 lemma iff_allI:
  1171   assumes "\<And>x. P x = Q x"
  1172   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1173   using assms by blast
  1174 
  1175 lemma iff_exI:
  1176   assumes "\<And>x. P x = Q x"
  1177   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1178   using assms by blast
  1179 
  1180 lemma all_comm:
  1181   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1182   by blast
  1183 
  1184 lemma ex_comm:
  1185   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1186   by blast
  1187 
  1188 ML_file "Tools/simpdata.ML"
  1189 ML {* open Simpdata *}
  1190 
  1191 setup {* map_theory_simpset (put_simpset HOL_basic_ss) *}
  1192 
  1193 simproc_setup defined_Ex ("EX x. P x") = {* fn _ => Quantifier1.rearrange_ex *}
  1194 simproc_setup defined_All ("ALL x. P x") = {* fn _ => Quantifier1.rearrange_all *}
  1195 
  1196 setup {*
  1197   Simplifier.method_setup Splitter.split_modifiers
  1198   #> Splitter.setup
  1199   #> clasimp_setup
  1200   #> EqSubst.setup
  1201 *}
  1202 
  1203 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1204 
  1205 simproc_setup neq ("x = y") = {* fn _ =>
  1206 let
  1207   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1208   fun is_neq eq lhs rhs thm =
  1209     (case Thm.prop_of thm of
  1210       _ $ (Not $ (eq' $ l' $ r')) =>
  1211         Not = HOLogic.Not andalso eq' = eq andalso
  1212         r' aconv lhs andalso l' aconv rhs
  1213     | _ => false);
  1214   fun proc ss ct =
  1215     (case Thm.term_of ct of
  1216       eq $ lhs $ rhs =>
  1217         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of ss) of
  1218           SOME thm => SOME (thm RS neq_to_EQ_False)
  1219         | NONE => NONE)
  1220      | _ => NONE);
  1221 in proc end;
  1222 *}
  1223 
  1224 simproc_setup let_simp ("Let x f") = {*
  1225 let
  1226   val (f_Let_unfold, x_Let_unfold) =
  1227     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1228     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1229   val (f_Let_folded, x_Let_folded) =
  1230     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1231     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1232   val g_Let_folded =
  1233     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1234     in cterm_of @{theory} g end;
  1235   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1236     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1237     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1238     | count_loose _ _ = 0;
  1239   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1240    case t
  1241     of Abs (_, _, t') => count_loose t' 0 <= 1
  1242      | _ => true;
  1243 in fn _ => fn ctxt => fn ct => if is_trivial_let (Thm.term_of ct)
  1244   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1245   else let (*Norbert Schirmer's case*)
  1246     val thy = Proof_Context.theory_of ctxt;
  1247     val t = Thm.term_of ct;
  1248     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1249   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1250     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1251       if is_Free x orelse is_Bound x orelse is_Const x
  1252       then SOME @{thm Let_def}
  1253       else
  1254         let
  1255           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1256           val cx = cterm_of thy x;
  1257           val {T = xT, ...} = rep_cterm cx;
  1258           val cf = cterm_of thy f;
  1259           val fx_g = Simplifier.rewrite ctxt (Thm.apply cf cx);
  1260           val (_ $ _ $ g) = prop_of fx_g;
  1261           val g' = abstract_over (x,g);
  1262           val abs_g'= Abs (n,xT,g');
  1263         in (if (g aconv g')
  1264              then
  1265                 let
  1266                   val rl =
  1267                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1268                 in SOME (rl OF [fx_g]) end
  1269              else if (Envir.beta_eta_contract f) aconv (Envir.beta_eta_contract abs_g') then NONE (*avoid identity conversion*)
  1270              else let
  1271                    val g'x = abs_g'$x;
  1272                    val g_g'x = Thm.symmetric (Thm.beta_conversion false (cterm_of thy g'x));
  1273                    val rl = cterm_instantiate
  1274                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1275                               (g_Let_folded, cterm_of thy abs_g')]
  1276                              @{thm Let_folded};
  1277                  in SOME (rl OF [Thm.transitive fx_g g_g'x])
  1278                  end)
  1279         end
  1280     | _ => NONE)
  1281   end
  1282 end *}
  1283 
  1284 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1285 proof
  1286   assume "True \<Longrightarrow> PROP P"
  1287   from this [OF TrueI] show "PROP P" .
  1288 next
  1289   assume "PROP P"
  1290   then show "PROP P" .
  1291 qed
  1292 
  1293 lemma ex_simps:
  1294   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1295   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1296   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1297   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1298   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1299   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1300   -- {* Miniscoping: pushing in existential quantifiers. *}
  1301   by (iprover | blast)+
  1302 
  1303 lemma all_simps:
  1304   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1305   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1306   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1307   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1308   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1309   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1310   -- {* Miniscoping: pushing in universal quantifiers. *}
  1311   by (iprover | blast)+
  1312 
  1313 lemmas [simp] =
  1314   triv_forall_equality (*prunes params*)
  1315   True_implies_equals  (*prune asms `True'*)
  1316   if_True
  1317   if_False
  1318   if_cancel
  1319   if_eq_cancel
  1320   imp_disjL
  1321   (*In general it seems wrong to add distributive laws by default: they
  1322     might cause exponential blow-up.  But imp_disjL has been in for a while
  1323     and cannot be removed without affecting existing proofs.  Moreover,
  1324     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1325     grounds that it allows simplification of R in the two cases.*)
  1326   conj_assoc
  1327   disj_assoc
  1328   de_Morgan_conj
  1329   de_Morgan_disj
  1330   imp_disj1
  1331   imp_disj2
  1332   not_imp
  1333   disj_not1
  1334   not_all
  1335   not_ex
  1336   cases_simp
  1337   the_eq_trivial
  1338   the_sym_eq_trivial
  1339   ex_simps
  1340   all_simps
  1341   simp_thms
  1342 
  1343 lemmas [cong] = imp_cong simp_implies_cong
  1344 lemmas [split] = split_if
  1345 
  1346 ML {* val HOL_ss = simpset_of @{context} *}
  1347 
  1348 text {* Simplifies x assuming c and y assuming ~c *}
  1349 lemma if_cong:
  1350   assumes "b = c"
  1351       and "c \<Longrightarrow> x = u"
  1352       and "\<not> c \<Longrightarrow> y = v"
  1353   shows "(if b then x else y) = (if c then u else v)"
  1354   using assms by simp
  1355 
  1356 text {* Prevents simplification of x and y:
  1357   faster and allows the execution of functional programs. *}
  1358 lemma if_weak_cong [cong]:
  1359   assumes "b = c"
  1360   shows "(if b then x else y) = (if c then x else y)"
  1361   using assms by (rule arg_cong)
  1362 
  1363 text {* Prevents simplification of t: much faster *}
  1364 lemma let_weak_cong:
  1365   assumes "a = b"
  1366   shows "(let x = a in t x) = (let x = b in t x)"
  1367   using assms by (rule arg_cong)
  1368 
  1369 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1370 lemma eq_cong2:
  1371   assumes "u = u'"
  1372   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1373   using assms by simp
  1374 
  1375 lemma if_distrib:
  1376   "f (if c then x else y) = (if c then f x else f y)"
  1377   by simp
  1378 
  1379 text{*As a simplification rule, it replaces all function equalities by
  1380   first-order equalities.*}
  1381 lemma fun_eq_iff: "f = g \<longleftrightarrow> (\<forall>x. f x = g x)"
  1382   by auto
  1383 
  1384 
  1385 subsubsection {* Generic cases and induction *}
  1386 
  1387 text {* Rule projections: *}
  1388 
  1389 ML {*
  1390 structure Project_Rule = Project_Rule
  1391 (
  1392   val conjunct1 = @{thm conjunct1}
  1393   val conjunct2 = @{thm conjunct2}
  1394   val mp = @{thm mp}
  1395 )
  1396 *}
  1397 
  1398 definition induct_forall where
  1399   "induct_forall P == \<forall>x. P x"
  1400 
  1401 definition induct_implies where
  1402   "induct_implies A B == A \<longrightarrow> B"
  1403 
  1404 definition induct_equal where
  1405   "induct_equal x y == x = y"
  1406 
  1407 definition induct_conj where
  1408   "induct_conj A B == A \<and> B"
  1409 
  1410 definition induct_true where
  1411   "induct_true == True"
  1412 
  1413 definition induct_false where
  1414   "induct_false == False"
  1415 
  1416 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1417   by (unfold atomize_all induct_forall_def)
  1418 
  1419 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1420   by (unfold atomize_imp induct_implies_def)
  1421 
  1422 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1423   by (unfold atomize_eq induct_equal_def)
  1424 
  1425 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1426   by (unfold atomize_conj induct_conj_def)
  1427 
  1428 lemmas induct_atomize' = induct_forall_eq induct_implies_eq induct_conj_eq
  1429 lemmas induct_atomize = induct_atomize' induct_equal_eq
  1430 lemmas induct_rulify' [symmetric] = induct_atomize'
  1431 lemmas induct_rulify [symmetric] = induct_atomize
  1432 lemmas induct_rulify_fallback =
  1433   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1434   induct_true_def induct_false_def
  1435 
  1436 
  1437 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1438     induct_conj (induct_forall A) (induct_forall B)"
  1439   by (unfold induct_forall_def induct_conj_def) iprover
  1440 
  1441 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1442     induct_conj (induct_implies C A) (induct_implies C B)"
  1443   by (unfold induct_implies_def induct_conj_def) iprover
  1444 
  1445 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1446 proof
  1447   assume r: "induct_conj A B ==> PROP C" and A B
  1448   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1449 next
  1450   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1451   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1452 qed
  1453 
  1454 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1455 
  1456 lemma induct_trueI: "induct_true"
  1457   by (simp add: induct_true_def)
  1458 
  1459 text {* Method setup. *}
  1460 
  1461 ML {*
  1462 structure Induct = Induct
  1463 (
  1464   val cases_default = @{thm case_split}
  1465   val atomize = @{thms induct_atomize}
  1466   val rulify = @{thms induct_rulify'}
  1467   val rulify_fallback = @{thms induct_rulify_fallback}
  1468   val equal_def = @{thm induct_equal_def}
  1469   fun dest_def (Const (@{const_name induct_equal}, _) $ t $ u) = SOME (t, u)
  1470     | dest_def _ = NONE
  1471   val trivial_tac = match_tac @{thms induct_trueI}
  1472 )
  1473 *}
  1474 
  1475 ML_file "~~/src/Tools/induction.ML"
  1476 
  1477 setup {*
  1478   Induct.setup #> Induction.setup #>
  1479   Context.theory_map (Induct.map_simpset (fn ss => ss
  1480     addsimprocs
  1481       [Simplifier.simproc_global @{theory} "swap_induct_false"
  1482          ["induct_false ==> PROP P ==> PROP Q"]
  1483          (fn _ =>
  1484             (fn _ $ (P as _ $ @{const induct_false}) $ (_ $ Q $ _) =>
  1485                   if P <> Q then SOME Drule.swap_prems_eq else NONE
  1486               | _ => NONE)),
  1487        Simplifier.simproc_global @{theory} "induct_equal_conj_curry"
  1488          ["induct_conj P Q ==> PROP R"]
  1489          (fn _ =>
  1490             (fn _ $ (_ $ P) $ _ =>
  1491                 let
  1492                   fun is_conj (@{const induct_conj} $ P $ Q) =
  1493                         is_conj P andalso is_conj Q
  1494                     | is_conj (Const (@{const_name induct_equal}, _) $ _ $ _) = true
  1495                     | is_conj @{const induct_true} = true
  1496                     | is_conj @{const induct_false} = true
  1497                     | is_conj _ = false
  1498                 in if is_conj P then SOME @{thm induct_conj_curry} else NONE end
  1499               | _ => NONE))]
  1500     |> Simplifier.set_mksimps (fn ctxt =>
  1501         Simpdata.mksimps Simpdata.mksimps_pairs ctxt #>
  1502         map (rewrite_rule ctxt (map Thm.symmetric @{thms induct_rulify_fallback})))))
  1503 *}
  1504 
  1505 text {* Pre-simplification of induction and cases rules *}
  1506 
  1507 lemma [induct_simp]: "(!!x. induct_equal x t ==> PROP P x) == PROP P t"
  1508   unfolding induct_equal_def
  1509 proof
  1510   assume R: "!!x. x = t ==> PROP P x"
  1511   show "PROP P t" by (rule R [OF refl])
  1512 next
  1513   fix x assume "PROP P t" "x = t"
  1514   then show "PROP P x" by simp
  1515 qed
  1516 
  1517 lemma [induct_simp]: "(!!x. induct_equal t x ==> PROP P x) == PROP P t"
  1518   unfolding induct_equal_def
  1519 proof
  1520   assume R: "!!x. t = x ==> PROP P x"
  1521   show "PROP P t" by (rule R [OF refl])
  1522 next
  1523   fix x assume "PROP P t" "t = x"
  1524   then show "PROP P x" by simp
  1525 qed
  1526 
  1527 lemma [induct_simp]: "(induct_false ==> P) == Trueprop induct_true"
  1528   unfolding induct_false_def induct_true_def
  1529   by (iprover intro: equal_intr_rule)
  1530 
  1531 lemma [induct_simp]: "(induct_true ==> PROP P) == PROP P"
  1532   unfolding induct_true_def
  1533 proof
  1534   assume R: "True \<Longrightarrow> PROP P"
  1535   from TrueI show "PROP P" by (rule R)
  1536 next
  1537   assume "PROP P"
  1538   then show "PROP P" .
  1539 qed
  1540 
  1541 lemma [induct_simp]: "(PROP P ==> induct_true) == Trueprop induct_true"
  1542   unfolding induct_true_def
  1543   by (iprover intro: equal_intr_rule)
  1544 
  1545 lemma [induct_simp]: "(!!x. induct_true) == Trueprop induct_true"
  1546   unfolding induct_true_def
  1547   by (iprover intro: equal_intr_rule)
  1548 
  1549 lemma [induct_simp]: "induct_implies induct_true P == P"
  1550   by (simp add: induct_implies_def induct_true_def)
  1551 
  1552 lemma [induct_simp]: "(x = x) = True" 
  1553   by (rule simp_thms)
  1554 
  1555 hide_const induct_forall induct_implies induct_equal induct_conj induct_true induct_false
  1556 
  1557 ML_file "~~/src/Tools/induct_tacs.ML"
  1558 setup Induct_Tacs.setup
  1559 
  1560 
  1561 subsubsection {* Coherent logic *}
  1562 
  1563 ML_file "~~/src/Tools/coherent.ML"
  1564 ML {*
  1565 structure Coherent = Coherent
  1566 (
  1567   val atomize_elimL = @{thm atomize_elimL};
  1568   val atomize_exL = @{thm atomize_exL};
  1569   val atomize_conjL = @{thm atomize_conjL};
  1570   val atomize_disjL = @{thm atomize_disjL};
  1571   val operator_names = [@{const_name HOL.disj}, @{const_name HOL.conj}, @{const_name Ex}];
  1572 );
  1573 *}
  1574 
  1575 
  1576 subsubsection {* Reorienting equalities *}
  1577 
  1578 ML {*
  1579 signature REORIENT_PROC =
  1580 sig
  1581   val add : (term -> bool) -> theory -> theory
  1582   val proc : morphism -> Proof.context -> cterm -> thm option
  1583 end;
  1584 
  1585 structure Reorient_Proc : REORIENT_PROC =
  1586 struct
  1587   structure Data = Theory_Data
  1588   (
  1589     type T = ((term -> bool) * stamp) list;
  1590     val empty = [];
  1591     val extend = I;
  1592     fun merge data : T = Library.merge (eq_snd op =) data;
  1593   );
  1594   fun add m = Data.map (cons (m, stamp ()));
  1595   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1596 
  1597   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1598   fun proc phi ctxt ct =
  1599     let
  1600       val thy = Proof_Context.theory_of ctxt;
  1601     in
  1602       case Thm.term_of ct of
  1603         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1604       | _ => NONE
  1605     end;
  1606 end;
  1607 *}
  1608 
  1609 
  1610 subsection {* Other simple lemmas and lemma duplicates *}
  1611 
  1612 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1613   by blast+
  1614 
  1615 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1616   apply (rule iffI)
  1617   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1618   apply (fast dest!: theI')
  1619   apply (fast intro: the1_equality [symmetric])
  1620   apply (erule ex1E)
  1621   apply (rule allI)
  1622   apply (rule ex1I)
  1623   apply (erule spec)
  1624   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1625   apply (erule impE)
  1626   apply (rule allI)
  1627   apply (case_tac "xa = x")
  1628   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1629   done
  1630 
  1631 lemmas eq_sym_conv = eq_commute
  1632 
  1633 lemma nnf_simps:
  1634   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1635   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1636   "(\<not> \<not>(P)) = P"
  1637 by blast+
  1638 
  1639 subsection {* Basic ML bindings *}
  1640 
  1641 ML {*
  1642 val FalseE = @{thm FalseE}
  1643 val Let_def = @{thm Let_def}
  1644 val TrueI = @{thm TrueI}
  1645 val allE = @{thm allE}
  1646 val allI = @{thm allI}
  1647 val all_dupE = @{thm all_dupE}
  1648 val arg_cong = @{thm arg_cong}
  1649 val box_equals = @{thm box_equals}
  1650 val ccontr = @{thm ccontr}
  1651 val classical = @{thm classical}
  1652 val conjE = @{thm conjE}
  1653 val conjI = @{thm conjI}
  1654 val conjunct1 = @{thm conjunct1}
  1655 val conjunct2 = @{thm conjunct2}
  1656 val disjCI = @{thm disjCI}
  1657 val disjE = @{thm disjE}
  1658 val disjI1 = @{thm disjI1}
  1659 val disjI2 = @{thm disjI2}
  1660 val eq_reflection = @{thm eq_reflection}
  1661 val ex1E = @{thm ex1E}
  1662 val ex1I = @{thm ex1I}
  1663 val ex1_implies_ex = @{thm ex1_implies_ex}
  1664 val exE = @{thm exE}
  1665 val exI = @{thm exI}
  1666 val excluded_middle = @{thm excluded_middle}
  1667 val ext = @{thm ext}
  1668 val fun_cong = @{thm fun_cong}
  1669 val iffD1 = @{thm iffD1}
  1670 val iffD2 = @{thm iffD2}
  1671 val iffI = @{thm iffI}
  1672 val impE = @{thm impE}
  1673 val impI = @{thm impI}
  1674 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1675 val mp = @{thm mp}
  1676 val notE = @{thm notE}
  1677 val notI = @{thm notI}
  1678 val not_all = @{thm not_all}
  1679 val not_ex = @{thm not_ex}
  1680 val not_iff = @{thm not_iff}
  1681 val not_not = @{thm not_not}
  1682 val not_sym = @{thm not_sym}
  1683 val refl = @{thm refl}
  1684 val rev_mp = @{thm rev_mp}
  1685 val spec = @{thm spec}
  1686 val ssubst = @{thm ssubst}
  1687 val subst = @{thm subst}
  1688 val sym = @{thm sym}
  1689 val trans = @{thm trans}
  1690 *}
  1691 
  1692 ML_file "Tools/cnf.ML"
  1693 
  1694 
  1695 subsection {* Code generator setup *}
  1696 
  1697 subsubsection {* Generic code generator preprocessor setup *}
  1698 
  1699 lemma conj_left_cong:
  1700   "P \<longleftrightarrow> Q \<Longrightarrow> P \<and> R \<longleftrightarrow> Q \<and> R"
  1701   by (fact arg_cong)
  1702 
  1703 lemma disj_left_cong:
  1704   "P \<longleftrightarrow> Q \<Longrightarrow> P \<or> R \<longleftrightarrow> Q \<or> R"
  1705   by (fact arg_cong)
  1706 
  1707 setup {*
  1708   Code_Preproc.map_pre (put_simpset HOL_basic_ss)
  1709   #> Code_Preproc.map_post (put_simpset HOL_basic_ss)
  1710   #> Code_Simp.map_ss (put_simpset HOL_basic_ss
  1711     #> Simplifier.add_cong @{thm conj_left_cong} #> Simplifier.add_cong @{thm disj_left_cong})
  1712 *}
  1713 
  1714 
  1715 subsubsection {* Equality *}
  1716 
  1717 class equal =
  1718   fixes equal :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1719   assumes equal_eq: "equal x y \<longleftrightarrow> x = y"
  1720 begin
  1721 
  1722 lemma equal: "equal = (op =)"
  1723   by (rule ext equal_eq)+
  1724 
  1725 lemma equal_refl: "equal x x \<longleftrightarrow> True"
  1726   unfolding equal by rule+
  1727 
  1728 lemma eq_equal: "(op =) \<equiv> equal"
  1729   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule equal_eq)
  1730 
  1731 end
  1732 
  1733 declare eq_equal [symmetric, code_post]
  1734 declare eq_equal [code]
  1735 
  1736 setup {*
  1737   Code_Preproc.map_pre (fn ctxt =>
  1738     ctxt addsimprocs [Simplifier.simproc_global_i @{theory} "equal" [@{term HOL.eq}]
  1739       (fn _ => fn Const (_, Type ("fun", [Type _, _])) => SOME @{thm eq_equal} | _ => NONE)])
  1740 *}
  1741 
  1742 
  1743 subsubsection {* Generic code generator foundation *}
  1744 
  1745 text {* Datatype @{typ bool} *}
  1746 
  1747 code_datatype True False
  1748 
  1749 lemma [code]:
  1750   shows "False \<and> P \<longleftrightarrow> False"
  1751     and "True \<and> P \<longleftrightarrow> P"
  1752     and "P \<and> False \<longleftrightarrow> False"
  1753     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1754 
  1755 lemma [code]:
  1756   shows "False \<or> P \<longleftrightarrow> P"
  1757     and "True \<or> P \<longleftrightarrow> True"
  1758     and "P \<or> False \<longleftrightarrow> P"
  1759     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1760 
  1761 lemma [code]:
  1762   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1763     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1764     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1765     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1766 
  1767 text {* More about @{typ prop} *}
  1768 
  1769 lemma [code nbe]:
  1770   shows "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q" 
  1771     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True"
  1772     and "(P \<Longrightarrow> R) \<equiv> Trueprop (P \<longrightarrow> R)" by (auto intro!: equal_intr_rule)
  1773 
  1774 lemma Trueprop_code [code]:
  1775   "Trueprop True \<equiv> Code_Generator.holds"
  1776   by (auto intro!: equal_intr_rule holds)
  1777 
  1778 declare Trueprop_code [symmetric, code_post]
  1779 
  1780 text {* Equality *}
  1781 
  1782 declare simp_thms(6) [code nbe]
  1783 
  1784 instantiation itself :: (type) equal
  1785 begin
  1786 
  1787 definition equal_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1788   "equal_itself x y \<longleftrightarrow> x = y"
  1789 
  1790 instance proof
  1791 qed (fact equal_itself_def)
  1792 
  1793 end
  1794 
  1795 lemma equal_itself_code [code]:
  1796   "equal TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1797   by (simp add: equal)
  1798 
  1799 setup {*
  1800   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"})
  1801 *}
  1802 
  1803 lemma equal_alias_cert: "OFCLASS('a, equal_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> equal)" (is "?ofclass \<equiv> ?equal")
  1804 proof
  1805   assume "PROP ?ofclass"
  1806   show "PROP ?equal"
  1807     by (tactic {* ALLGOALS (rtac (Thm.unconstrainT @{thm eq_equal})) *})
  1808       (fact `PROP ?ofclass`)
  1809 next
  1810   assume "PROP ?equal"
  1811   show "PROP ?ofclass" proof
  1812   qed (simp add: `PROP ?equal`)
  1813 qed
  1814   
  1815 setup {*
  1816   Sign.add_const_constraint (@{const_name equal}, SOME @{typ "'a\<Colon>equal \<Rightarrow> 'a \<Rightarrow> bool"})
  1817 *}
  1818 
  1819 setup {*
  1820   Nbe.add_const_alias @{thm equal_alias_cert}
  1821 *}
  1822 
  1823 text {* Cases *}
  1824 
  1825 lemma Let_case_cert:
  1826   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1827   shows "CASE x \<equiv> f x"
  1828   using assms by simp_all
  1829 
  1830 setup {*
  1831   Code.add_case @{thm Let_case_cert}
  1832   #> Code.add_undefined @{const_name undefined}
  1833 *}
  1834 
  1835 declare [[code abort: undefined]]
  1836 
  1837 
  1838 subsubsection {* Generic code generator target languages *}
  1839 
  1840 text {* type @{typ bool} *}
  1841 
  1842 code_printing
  1843   type_constructor bool \<rightharpoonup>
  1844     (SML) "bool" and (OCaml) "bool" and (Haskell) "Bool" and (Scala) "Boolean"
  1845 | constant True \<rightharpoonup>
  1846     (SML) "true" and (OCaml) "true" and (Haskell) "True" and (Scala) "true"
  1847 | constant False \<rightharpoonup>
  1848     (SML) "false" and (OCaml) "false" and (Haskell) "False" and (Scala) "false" 
  1849 
  1850 code_reserved SML
  1851   bool true false
  1852 
  1853 code_reserved OCaml
  1854   bool
  1855 
  1856 code_reserved Scala
  1857   Boolean
  1858 
  1859 code_printing
  1860   constant Not \<rightharpoonup>
  1861     (SML) "not" and (OCaml) "not" and (Haskell) "not" and (Scala) "'! _"
  1862 | constant HOL.conj \<rightharpoonup>
  1863     (SML) infixl 1 "andalso" and (OCaml) infixl 3 "&&" and (Haskell) infixr 3 "&&" and (Scala) infixl 3 "&&"
  1864 | constant HOL.disj \<rightharpoonup>
  1865     (SML) infixl 0 "orelse" and (OCaml) infixl 2 "||" and (Haskell) infixl 2 "||" and (Scala) infixl 1 "||"
  1866 | constant HOL.implies \<rightharpoonup>
  1867     (SML) "!(if (_)/ then (_)/ else true)"
  1868     and (OCaml) "!(if (_)/ then (_)/ else true)"
  1869     and (Haskell) "!(if (_)/ then (_)/ else True)"
  1870     and (Scala) "!(if ((_))/ (_)/ else true)"
  1871 | constant If \<rightharpoonup>
  1872     (SML) "!(if (_)/ then (_)/ else (_))"
  1873     and (OCaml) "!(if (_)/ then (_)/ else (_))"
  1874     and (Haskell) "!(if (_)/ then (_)/ else (_))"
  1875     and (Scala) "!(if ((_))/ (_)/ else (_))"
  1876 
  1877 code_reserved SML
  1878   not
  1879 
  1880 code_reserved OCaml
  1881   not
  1882 
  1883 code_identifier
  1884   code_module Pure \<rightharpoonup>
  1885     (SML) HOL and (OCaml) HOL and (Haskell) HOL and (Scala) HOL
  1886 
  1887 text {* using built-in Haskell equality *}
  1888 
  1889 code_printing
  1890   type_class equal \<rightharpoonup> (Haskell) "Eq"
  1891 | constant HOL.equal \<rightharpoonup> (Haskell) infix 4 "=="
  1892 | constant HOL.eq \<rightharpoonup> (Haskell) infix 4 "=="
  1893 
  1894 text {* undefined *}
  1895 
  1896 code_printing
  1897   constant undefined \<rightharpoonup>
  1898     (SML) "!(raise/ Fail/ \"undefined\")"
  1899     and (OCaml) "failwith/ \"undefined\""
  1900     and (Haskell) "error/ \"undefined\""
  1901     and (Scala) "!sys.error(\"undefined\")"
  1902 
  1903 
  1904 subsubsection {* Evaluation and normalization by evaluation *}
  1905 
  1906 method_setup eval = {*
  1907 let
  1908   fun eval_tac ctxt =
  1909     let val conv = Code_Runtime.dynamic_holds_conv ctxt
  1910     in CONVERSION (Conv.params_conv ~1 (K (Conv.concl_conv ~1 conv)) ctxt) THEN' rtac TrueI end
  1911 in
  1912   Scan.succeed (SIMPLE_METHOD' o eval_tac)
  1913 end
  1914 *} "solve goal by evaluation"
  1915 
  1916 method_setup normalization = {*
  1917   Scan.succeed (fn ctxt =>
  1918     SIMPLE_METHOD'
  1919       (CHANGED_PROP o
  1920         (CONVERSION (Nbe.dynamic_conv ctxt)
  1921           THEN_ALL_NEW (TRY o rtac TrueI))))
  1922 *} "solve goal by normalization"
  1923 
  1924 
  1925 subsection {* Counterexample Search Units *}
  1926 
  1927 subsubsection {* Quickcheck *}
  1928 
  1929 quickcheck_params [size = 5, iterations = 50]
  1930 
  1931 
  1932 subsubsection {* Nitpick setup *}
  1933 
  1934 ML {*
  1935 structure Nitpick_Unfolds = Named_Thms
  1936 (
  1937   val name = @{binding nitpick_unfold}
  1938   val description = "alternative definitions of constants as needed by Nitpick"
  1939 )
  1940 structure Nitpick_Simps = Named_Thms
  1941 (
  1942   val name = @{binding nitpick_simp}
  1943   val description = "equational specification of constants as needed by Nitpick"
  1944 )
  1945 structure Nitpick_Psimps = Named_Thms
  1946 (
  1947   val name = @{binding nitpick_psimp}
  1948   val description = "partial equational specification of constants as needed by Nitpick"
  1949 )
  1950 structure Nitpick_Choice_Specs = Named_Thms
  1951 (
  1952   val name = @{binding nitpick_choice_spec}
  1953   val description = "choice specification of constants as needed by Nitpick"
  1954 )
  1955 *}
  1956 
  1957 setup {*
  1958   Nitpick_Unfolds.setup
  1959   #> Nitpick_Simps.setup
  1960   #> Nitpick_Psimps.setup
  1961   #> Nitpick_Choice_Specs.setup
  1962 *}
  1963 
  1964 declare if_bool_eq_conj [nitpick_unfold, no_atp]
  1965         if_bool_eq_disj [no_atp]
  1966 
  1967 
  1968 subsection {* Preprocessing for the predicate compiler *}
  1969 
  1970 ML {*
  1971 structure Predicate_Compile_Alternative_Defs = Named_Thms
  1972 (
  1973   val name = @{binding code_pred_def}
  1974   val description = "alternative definitions of constants for the Predicate Compiler"
  1975 )
  1976 structure Predicate_Compile_Inline_Defs = Named_Thms
  1977 (
  1978   val name = @{binding code_pred_inline}
  1979   val description = "inlining definitions for the Predicate Compiler"
  1980 )
  1981 structure Predicate_Compile_Simps = Named_Thms
  1982 (
  1983   val name = @{binding code_pred_simp}
  1984   val description = "simplification rules for the optimisations in the Predicate Compiler"
  1985 )
  1986 *}
  1987 
  1988 setup {*
  1989   Predicate_Compile_Alternative_Defs.setup
  1990   #> Predicate_Compile_Inline_Defs.setup
  1991   #> Predicate_Compile_Simps.setup
  1992 *}
  1993 
  1994 
  1995 subsection {* Legacy tactics and ML bindings *}
  1996 
  1997 ML {*
  1998 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  1999 local
  2000   fun wrong_prem (Const (@{const_name All}, _) $ Abs (_, _, t)) = wrong_prem t
  2001     | wrong_prem (Bound _) = true
  2002     | wrong_prem _ = false;
  2003   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2004 in
  2005   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2006   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2007 end;
  2008 
  2009 local
  2010   val nnf_ss =
  2011     simpset_of (put_simpset HOL_basic_ss @{context} addsimps @{thms simp_thms nnf_simps});
  2012 in
  2013   fun nnf_conv ctxt = Simplifier.rewrite (put_simpset nnf_ss ctxt);
  2014 end
  2015 *}
  2016 
  2017 hide_const (open) eq equal
  2018 
  2019 end