src/Pure/display.ML
author wenzelm
Tue Mar 24 21:24:53 2009 +0100 (2009-03-24)
changeset 30711 952fdbee1b48
parent 30409 6037cac149a1
child 30723 a3adc9a96a16
permissions -rw-r--r--
display derivation status of thms;
     1 (*  Title:      Pure/display.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1993  University of Cambridge
     4 
     5 Printing of theorems, goals, results etc.
     6 *)
     7 
     8 signature BASIC_DISPLAY =
     9 sig
    10   val goals_limit: int ref
    11   val show_hyps: bool ref
    12   val show_tags: bool ref
    13   val show_consts: bool ref
    14 end;
    15 
    16 signature DISPLAY =
    17 sig
    18   include BASIC_DISPLAY
    19   val pretty_flexpair: Pretty.pp -> term * term -> Pretty.T
    20   val pretty_thm_aux: Pretty.pp -> bool -> bool -> term list -> thm -> Pretty.T
    21   val pretty_thm: thm -> Pretty.T
    22   val string_of_thm: thm -> string
    23   val pretty_thms: thm list -> Pretty.T
    24   val pretty_thm_sg: theory -> thm -> Pretty.T
    25   val pretty_thms_sg: theory -> thm list -> Pretty.T
    26   val print_thm: thm -> unit
    27   val print_thms: thm list -> unit
    28   val prth: thm -> thm
    29   val prthq: thm Seq.seq -> thm Seq.seq
    30   val prths: thm list -> thm list
    31   val pretty_ctyp: ctyp -> Pretty.T
    32   val string_of_ctyp: ctyp -> string
    33   val print_ctyp: ctyp -> unit
    34   val pretty_cterm: cterm -> Pretty.T
    35   val string_of_cterm: cterm -> string
    36   val print_cterm: cterm -> unit
    37   val print_syntax: theory -> unit
    38   val pretty_full_theory: bool -> theory -> Pretty.T list
    39   val pretty_goals_aux: Pretty.pp -> Markup.T -> bool * bool -> int -> thm -> Pretty.T list
    40   val pretty_goals: int -> thm -> Pretty.T list
    41   val print_goals: int -> thm -> unit
    42 end;
    43 
    44 structure Display: DISPLAY =
    45 struct
    46 
    47 
    48 (** print thm **)
    49 
    50 val goals_limit = ref 10;       (*max number of goals to print*)
    51 val show_hyps = ref false;      (*false: print meta-hypotheses as dots*)
    52 val show_tags = ref false;      (*false: suppress tags*)
    53 
    54 fun pretty_tag (name, arg) = Pretty.strs [name, quote arg];
    55 val pretty_tags = Pretty.list "[" "]" o map pretty_tag;
    56 
    57 fun pretty_flexpair pp (t, u) = Pretty.block
    58   [Pretty.term pp t, Pretty.str " =?=", Pretty.brk 1, Pretty.term pp u];
    59 
    60 fun display_status th =
    61   let
    62     val {oracle = oracle0, unfinished, failed} = Thm.status_of th;
    63     val oracle = oracle0 andalso (not (! quick_and_dirty) orelse ! show_hyps);
    64   in
    65     if failed then "!!"
    66     else if oracle andalso unfinished then "!?"
    67     else if oracle then "!"
    68     else if unfinished then "?"
    69     else ""
    70   end;
    71 
    72 fun pretty_thm_aux pp quote show_hyps' asms raw_th =
    73   let
    74     val th = Thm.strip_shyps raw_th;
    75     val {hyps, tpairs, prop, ...} = Thm.rep_thm th;
    76     val xshyps = Thm.extra_shyps th;
    77     val tags = Thm.get_tags th;
    78 
    79     val q = if quote then Pretty.quote else I;
    80     val prt_term = q o Pretty.term pp;
    81 
    82     val hyps' = if ! show_hyps then hyps else subtract (op aconv) asms hyps;
    83     val status = display_status th;
    84 
    85     val hlen = length xshyps + length hyps' + length tpairs;
    86     val hsymbs =
    87       if hlen = 0 andalso status = "" then []
    88       else if ! show_hyps orelse show_hyps' then
    89         [Pretty.brk 2, Pretty.list "[" "]"
    90           (map (q o pretty_flexpair pp) tpairs @ map prt_term hyps' @
    91            map (Pretty.sort pp) xshyps @
    92             (if status = "" then [] else [Pretty.str status]))]
    93       else [Pretty.brk 2, Pretty.str ("[" ^ implode (replicate hlen ".") ^ status ^ "]")];
    94     val tsymbs =
    95       if null tags orelse not (! show_tags) then []
    96       else [Pretty.brk 1, pretty_tags tags];
    97   in Pretty.block (prt_term prop :: (hsymbs @ tsymbs)) end;
    98 
    99 fun pretty_thm th =
   100   pretty_thm_aux (Syntax.pp_global (Thm.theory_of_thm th)) true false [] th;
   101 
   102 val string_of_thm = Pretty.string_of o pretty_thm;
   103 
   104 fun pretty_thms [th] = pretty_thm th
   105   | pretty_thms ths = Pretty.block (Pretty.fbreaks (map pretty_thm ths));
   106 
   107 val pretty_thm_sg = pretty_thm oo Thm.transfer;
   108 val pretty_thms_sg = pretty_thms oo (map o Thm.transfer);
   109 
   110 
   111 (* top-level commands for printing theorems *)
   112 
   113 val print_thm = Pretty.writeln o pretty_thm;
   114 val print_thms = Pretty.writeln o pretty_thms;
   115 
   116 fun prth th = (print_thm th; th);
   117 fun prthq thq = (Seq.print (K print_thm) 100000 thq; thq);
   118 fun prths ths = (prthq (Seq.of_list ths); ths);
   119 
   120 
   121 (* other printing commands *)
   122 
   123 fun pretty_ctyp cT = Syntax.pretty_typ_global (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   124 fun string_of_ctyp cT = Syntax.string_of_typ_global (Thm.theory_of_ctyp cT) (Thm.typ_of cT);
   125 val print_ctyp = writeln o string_of_ctyp;
   126 
   127 fun pretty_cterm ct = Syntax.pretty_term_global (Thm.theory_of_cterm ct) (Thm.term_of ct);
   128 fun string_of_cterm ct = Syntax.string_of_term_global (Thm.theory_of_cterm ct) (Thm.term_of ct);
   129 val print_cterm = writeln o string_of_cterm;
   130 
   131 
   132 
   133 (** print theory **)
   134 
   135 val print_syntax = Syntax.print_syntax o Sign.syn_of;
   136 
   137 
   138 (* pretty_full_theory *)
   139 
   140 fun pretty_full_theory verbose thy =
   141   let
   142     val ctxt = ProofContext.init thy;
   143 
   144     fun prt_cls c = Syntax.pretty_sort ctxt [c];
   145     fun prt_sort S = Syntax.pretty_sort ctxt S;
   146     fun prt_arity t (c, (_, Ss)) = Syntax.pretty_arity ctxt (t, Ss, [c]);
   147     fun prt_typ ty = Pretty.quote (Syntax.pretty_typ ctxt ty);
   148     val prt_typ_no_tvars = prt_typ o Logic.unvarifyT;
   149     fun prt_term t = Pretty.quote (Syntax.pretty_term ctxt t);
   150     val prt_term_no_vars = prt_term o Logic.unvarify;
   151     fun prt_const (c, ty) = [Pretty.str c, Pretty.str " ::", Pretty.brk 1, prt_typ_no_tvars ty];
   152     val prt_const' = Defs.pretty_const (Syntax.pp ctxt);
   153 
   154     fun pretty_classrel (c, []) = prt_cls c
   155       | pretty_classrel (c, cs) = Pretty.block
   156           (prt_cls c :: Pretty.str " <" :: Pretty.brk 1 ::
   157             Pretty.commas (map prt_cls cs));
   158 
   159     fun pretty_default S = Pretty.block
   160       [Pretty.str "default sort:", Pretty.brk 1, prt_sort S];
   161 
   162     val tfrees = map (fn v => TFree (v, []));
   163     fun pretty_type syn (t, ((Type.LogicalType n, _), _)) =
   164           if syn then NONE
   165           else SOME (prt_typ (Type (t, tfrees (Name.invents Name.context Name.aT n))))
   166       | pretty_type syn (t, ((Type.Abbreviation (vs, U, syn'), _), _)) =
   167           if syn <> syn' then NONE
   168           else SOME (Pretty.block
   169             [prt_typ (Type (t, tfrees vs)), Pretty.str " =", Pretty.brk 1, prt_typ U])
   170       | pretty_type syn (t, ((Type.Nonterminal, _), _)) =
   171           if not syn then NONE
   172           else SOME (prt_typ (Type (t, [])));
   173 
   174     val pretty_arities = maps (fn (t, ars) => map (prt_arity t) ars);
   175 
   176     fun pretty_abbrev (c, (ty, t)) = Pretty.block
   177       (prt_const (c, ty) @ [Pretty.str " ==", Pretty.brk 1, prt_term_no_vars t]);
   178 
   179     fun pretty_axm (a, t) = Pretty.block [Pretty.str (a ^ ":"), Pretty.brk 1, prt_term_no_vars t];
   180 
   181     fun pretty_finals reds = Pretty.block
   182       (Pretty.str "final:" :: Pretty.brk 1 :: Pretty.commas (map (prt_const' o fst) reds));
   183 
   184     fun pretty_reduct (lhs, rhs) = Pretty.block
   185       ([prt_const' lhs, Pretty.str "  ->", Pretty.brk 2] @
   186         Pretty.commas (map prt_const' (sort_wrt #1 rhs)));
   187 
   188     fun pretty_restrict (const, name) =
   189       Pretty.block ([prt_const' const, Pretty.brk 2, Pretty.str ("(from " ^ quote name ^ ")")]);
   190 
   191     val axioms = (Theory.axiom_space thy, Theory.axiom_table thy);
   192     val defs = Theory.defs_of thy;
   193     val {restricts, reducts} = Defs.dest defs;
   194     val {naming, syn = _, tsig, consts} = Sign.rep_sg thy;
   195     val {constants, constraints} = Consts.dest consts;
   196     val extern_const = NameSpace.extern (#1 constants);
   197     val {classes, default, types, ...} = Type.rep_tsig tsig;
   198     val (class_space, class_algebra) = classes;
   199     val {classes, arities} = Sorts.rep_algebra class_algebra;
   200 
   201     val clsses = NameSpace.dest_table (class_space, Symtab.make (Graph.dest classes));
   202     val tdecls = NameSpace.dest_table types;
   203     val arties = NameSpace.dest_table (Sign.type_space thy, arities);
   204 
   205     fun prune_const c = not verbose andalso
   206       member (op =) (Consts.the_tags consts c) Markup.property_internal;
   207     val cnsts = NameSpace.extern_table (#1 constants,
   208       Symtab.make (filter_out (prune_const o fst) (Symtab.dest (#2 constants))));
   209 
   210     val log_cnsts = map_filter (fn (c, (ty, NONE)) => SOME (c, ty) | _ => NONE) cnsts;
   211     val abbrevs = map_filter (fn (c, (ty, SOME t)) => SOME (c, (ty, t)) | _ => NONE) cnsts;
   212     val cnstrs = NameSpace.extern_table constraints;
   213 
   214     val axms = NameSpace.extern_table axioms;
   215 
   216     val (reds0, (reds1, reds2)) = filter_out (prune_const o fst o fst) reducts
   217       |> map (fn (lhs, rhs) =>
   218         (apfst extern_const lhs, map (apfst extern_const) (filter_out (prune_const o fst) rhs)))
   219       |> sort_wrt (#1 o #1)
   220       |> List.partition (null o #2)
   221       ||> List.partition (Defs.plain_args o #2 o #1);
   222     val rests = restricts |> map (apfst (apfst extern_const)) |> sort_wrt (#1 o #1);
   223   in
   224     [Pretty.strs ("names:" :: Context.display_names thy)] @
   225     [Pretty.big_list "classes:" (map pretty_classrel clsses),
   226       pretty_default default,
   227       Pretty.big_list "syntactic types:" (map_filter (pretty_type true) tdecls),
   228       Pretty.big_list "logical types:" (map_filter (pretty_type false) tdecls),
   229       Pretty.big_list "type arities:" (pretty_arities arties),
   230       Pretty.big_list "logical consts:" (map (Pretty.block o prt_const) log_cnsts),
   231       Pretty.big_list "abbreviations:" (map pretty_abbrev abbrevs),
   232       Pretty.big_list "constraints:" (map (Pretty.block o prt_const) cnstrs),
   233       Pretty.big_list "axioms:" (map pretty_axm axms),
   234       Pretty.strs ("oracles:" :: Thm.extern_oracles thy),
   235       Pretty.big_list "definitions:"
   236         [pretty_finals reds0,
   237          Pretty.big_list "non-overloaded:" (map pretty_reduct reds1),
   238          Pretty.big_list "overloaded:" (map pretty_reduct reds2),
   239          Pretty.big_list "pattern restrictions:" (map pretty_restrict rests)]]
   240   end;
   241 
   242 
   243 
   244 (** print_goals **)
   245 
   246 (* print_goals etc. *)
   247 
   248 val show_consts = ref false;  (*true: show consts with types in proof state output*)
   249 
   250 
   251 (*print thm A1,...,An/B in "goal style" -- premises as numbered subgoals*)
   252 
   253 local
   254 
   255 fun ins_entry (x, y) =
   256   AList.default (op =) (x, []) #>
   257   AList.map_entry (op =) x (insert (op =) y);
   258 
   259 val add_consts = Term.fold_aterms
   260   (fn Const (c, T) => ins_entry (T, (c, T))
   261     | _ => I);
   262 
   263 val add_vars = Term.fold_aterms
   264   (fn Free (x, T) => ins_entry (T, (x, ~1))
   265     | Var (xi, T) => ins_entry (T, xi)
   266     | _ => I);
   267 
   268 val add_varsT = Term.fold_atyps
   269   (fn TFree (x, S) => ins_entry (S, (x, ~1))
   270     | TVar (xi, S) => ins_entry (S, xi)
   271     | _ => I);
   272 
   273 fun sort_idxs vs = map (apsnd (sort (prod_ord string_ord int_ord))) vs;
   274 fun sort_cnsts cs = map (apsnd (sort_wrt fst)) cs;
   275 
   276 fun consts_of t = sort_cnsts (add_consts t []);
   277 fun vars_of t = sort_idxs (add_vars t []);
   278 fun varsT_of t = rev (sort_idxs (Term.fold_types add_varsT t []));
   279 
   280 in
   281 
   282 fun pretty_goals_aux pp markup (msg, main) maxgoals state =
   283   let
   284     fun prt_atoms prt prtT (X, xs) = Pretty.block
   285       [Pretty.block (Pretty.commas (map prt xs)), Pretty.str " ::",
   286         Pretty.brk 1, prtT X];
   287 
   288     fun prt_var (x, ~1) = Pretty.term pp (Syntax.free x)
   289       | prt_var xi = Pretty.term pp (Syntax.var xi);
   290 
   291     fun prt_varT (x, ~1) = Pretty.typ pp (TFree (x, []))
   292       | prt_varT xi = Pretty.typ pp (TVar (xi, []));
   293 
   294     val prt_consts = prt_atoms (Pretty.term pp o Const) (Pretty.typ pp);
   295     val prt_vars = prt_atoms prt_var (Pretty.typ pp);
   296     val prt_varsT = prt_atoms prt_varT (Pretty.sort pp);
   297 
   298 
   299     fun pretty_list _ _ [] = []
   300       | pretty_list name prt lst = [Pretty.big_list name (map prt lst)];
   301 
   302     fun pretty_subgoal (n, A) = Pretty.markup markup
   303       [Pretty.str (" " ^ string_of_int n ^ ". "), Pretty.term pp A];
   304     fun pretty_subgoals As = map pretty_subgoal (1 upto length As ~~ As);
   305 
   306     val pretty_ffpairs = pretty_list "flex-flex pairs:" (pretty_flexpair pp);
   307 
   308     val pretty_consts = pretty_list "constants:" prt_consts o consts_of;
   309     val pretty_vars = pretty_list "variables:" prt_vars o vars_of;
   310     val pretty_varsT = pretty_list "type variables:" prt_varsT o varsT_of;
   311 
   312 
   313     val {prop, tpairs, ...} = Thm.rep_thm state;
   314     val (As, B) = Logic.strip_horn prop;
   315     val ngoals = length As;
   316 
   317     fun pretty_gs (types, sorts) =
   318       (if main then [Pretty.term pp B] else []) @
   319        (if ngoals = 0 then [Pretty.str "No subgoals!"]
   320         else if ngoals > maxgoals then
   321           pretty_subgoals (Library.take (maxgoals, As)) @
   322           (if msg then [Pretty.str ("A total of " ^ string_of_int ngoals ^ " subgoals...")]
   323            else [])
   324         else pretty_subgoals As) @
   325       pretty_ffpairs tpairs @
   326       (if ! show_consts then pretty_consts prop else []) @
   327       (if types then pretty_vars prop else []) @
   328       (if sorts then pretty_varsT prop else []);
   329   in
   330     setmp show_no_free_types true
   331       (setmp show_types (! show_types orelse ! show_sorts orelse ! show_all_types)
   332         (setmp show_sorts false pretty_gs))
   333    (! show_types orelse ! show_sorts orelse ! show_all_types, ! show_sorts)
   334   end;
   335 
   336 fun pretty_goals n th =
   337   pretty_goals_aux (Syntax.pp_global (Thm.theory_of_thm th)) Markup.none (true, true) n th;
   338 
   339 val print_goals = (Pretty.writeln o Pretty.chunks) oo pretty_goals;
   340 
   341 end;
   342 
   343 
   344 end;
   345 
   346 structure BasicDisplay: BASIC_DISPLAY = Display;
   347 open BasicDisplay;