src/HOL/Int.thy
author haftmann
Fri Oct 20 07:46:10 2017 +0200 (21 months ago)
changeset 66886 960509bfd47e
parent 66836 4eb431c3f974
child 66912 a99a7cbf0fb5
permissions -rw-r--r--
added lemmas and tuned proofs
     1 (*  Title:      HOL/Int.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Tobias Nipkow, Florian Haftmann, TU Muenchen
     4 *)
     5 
     6 section \<open>The Integers as Equivalence Classes over Pairs of Natural Numbers\<close>
     7 
     8 theory Int
     9   imports Equiv_Relations Power Quotient Fun_Def
    10 begin
    11 
    12 subsection \<open>Definition of integers as a quotient type\<close>
    13 
    14 definition intrel :: "(nat \<times> nat) \<Rightarrow> (nat \<times> nat) \<Rightarrow> bool"
    15   where "intrel = (\<lambda>(x, y) (u, v). x + v = u + y)"
    16 
    17 lemma intrel_iff [simp]: "intrel (x, y) (u, v) \<longleftrightarrow> x + v = u + y"
    18   by (simp add: intrel_def)
    19 
    20 quotient_type int = "nat \<times> nat" / "intrel"
    21   morphisms Rep_Integ Abs_Integ
    22 proof (rule equivpI)
    23   show "reflp intrel" by (auto simp: reflp_def)
    24   show "symp intrel" by (auto simp: symp_def)
    25   show "transp intrel" by (auto simp: transp_def)
    26 qed
    27 
    28 lemma eq_Abs_Integ [case_names Abs_Integ, cases type: int]:
    29   "(\<And>x y. z = Abs_Integ (x, y) \<Longrightarrow> P) \<Longrightarrow> P"
    30   by (induct z) auto
    31 
    32 
    33 subsection \<open>Integers form a commutative ring\<close>
    34 
    35 instantiation int :: comm_ring_1
    36 begin
    37 
    38 lift_definition zero_int :: "int" is "(0, 0)" .
    39 
    40 lift_definition one_int :: "int" is "(1, 0)" .
    41 
    42 lift_definition plus_int :: "int \<Rightarrow> int \<Rightarrow> int"
    43   is "\<lambda>(x, y) (u, v). (x + u, y + v)"
    44   by clarsimp
    45 
    46 lift_definition uminus_int :: "int \<Rightarrow> int"
    47   is "\<lambda>(x, y). (y, x)"
    48   by clarsimp
    49 
    50 lift_definition minus_int :: "int \<Rightarrow> int \<Rightarrow> int"
    51   is "\<lambda>(x, y) (u, v). (x + v, y + u)"
    52   by clarsimp
    53 
    54 lift_definition times_int :: "int \<Rightarrow> int \<Rightarrow> int"
    55   is "\<lambda>(x, y) (u, v). (x*u + y*v, x*v + y*u)"
    56 proof (clarsimp)
    57   fix s t u v w x y z :: nat
    58   assume "s + v = u + t" and "w + z = y + x"
    59   then have "(s + v) * w + (u + t) * x + u * (w + z) + v * (y + x) =
    60     (u + t) * w + (s + v) * x + u * (y + x) + v * (w + z)"
    61     by simp
    62   then show "(s * w + t * x) + (u * z + v * y) = (u * y + v * z) + (s * x + t * w)"
    63     by (simp add: algebra_simps)
    64 qed
    65 
    66 instance
    67   by standard (transfer; clarsimp simp: algebra_simps)+
    68 
    69 end
    70 
    71 abbreviation int :: "nat \<Rightarrow> int"
    72   where "int \<equiv> of_nat"
    73 
    74 lemma int_def: "int n = Abs_Integ (n, 0)"
    75   by (induct n) (simp add: zero_int.abs_eq, simp add: one_int.abs_eq plus_int.abs_eq)
    76 
    77 lemma int_transfer [transfer_rule]: "(rel_fun (op =) pcr_int) (\<lambda>n. (n, 0)) int"
    78   by (simp add: rel_fun_def int.pcr_cr_eq cr_int_def int_def)
    79 
    80 lemma int_diff_cases: obtains (diff) m n where "z = int m - int n"
    81   by transfer clarsimp
    82 
    83 
    84 subsection \<open>Integers are totally ordered\<close>
    85 
    86 instantiation int :: linorder
    87 begin
    88 
    89 lift_definition less_eq_int :: "int \<Rightarrow> int \<Rightarrow> bool"
    90   is "\<lambda>(x, y) (u, v). x + v \<le> u + y"
    91   by auto
    92 
    93 lift_definition less_int :: "int \<Rightarrow> int \<Rightarrow> bool"
    94   is "\<lambda>(x, y) (u, v). x + v < u + y"
    95   by auto
    96 
    97 instance
    98   by standard (transfer, force)+
    99 
   100 end
   101 
   102 instantiation int :: distrib_lattice
   103 begin
   104 
   105 definition "(inf :: int \<Rightarrow> int \<Rightarrow> int) = min"
   106 
   107 definition "(sup :: int \<Rightarrow> int \<Rightarrow> int) = max"
   108 
   109 instance
   110   by standard (auto simp add: inf_int_def sup_int_def max_min_distrib2)
   111 
   112 end
   113 
   114 
   115 subsection \<open>Ordering properties of arithmetic operations\<close>
   116 
   117 instance int :: ordered_cancel_ab_semigroup_add
   118 proof
   119   fix i j k :: int
   120   show "i \<le> j \<Longrightarrow> k + i \<le> k + j"
   121     by transfer clarsimp
   122 qed
   123 
   124 text \<open>Strict Monotonicity of Multiplication.\<close>
   125 
   126 text \<open>Strict, in 1st argument; proof is by induction on \<open>k > 0\<close>.\<close>
   127 lemma zmult_zless_mono2_lemma: "i < j \<Longrightarrow> 0 < k \<Longrightarrow> int k * i < int k * j"
   128   for i j :: int
   129 proof (induct k)
   130   case 0
   131   then show ?case by simp
   132 next
   133   case (Suc k)
   134   then show ?case
   135     by (cases "k = 0") (simp_all add: distrib_right add_strict_mono)
   136 qed
   137 
   138 lemma zero_le_imp_eq_int: "0 \<le> k \<Longrightarrow> \<exists>n. k = int n"
   139   for k :: int
   140   apply transfer
   141   apply clarsimp
   142   apply (rule_tac x="a - b" in exI)
   143   apply simp
   144   done
   145 
   146 lemma zero_less_imp_eq_int: "0 < k \<Longrightarrow> \<exists>n>0. k = int n"
   147   for k :: int
   148   apply transfer
   149   apply clarsimp
   150   apply (rule_tac x="a - b" in exI)
   151   apply simp
   152   done
   153 
   154 lemma zmult_zless_mono2: "i < j \<Longrightarrow> 0 < k \<Longrightarrow> k * i < k * j"
   155   for i j k :: int
   156   by (drule zero_less_imp_eq_int) (auto simp add: zmult_zless_mono2_lemma)
   157 
   158 
   159 text \<open>The integers form an ordered integral domain.\<close>
   160 
   161 instantiation int :: linordered_idom
   162 begin
   163 
   164 definition zabs_def: "\<bar>i::int\<bar> = (if i < 0 then - i else i)"
   165 
   166 definition zsgn_def: "sgn (i::int) = (if i = 0 then 0 else if 0 < i then 1 else - 1)"
   167 
   168 instance
   169 proof
   170   fix i j k :: int
   171   show "i < j \<Longrightarrow> 0 < k \<Longrightarrow> k * i < k * j"
   172     by (rule zmult_zless_mono2)
   173   show "\<bar>i\<bar> = (if i < 0 then -i else i)"
   174     by (simp only: zabs_def)
   175   show "sgn (i::int) = (if i=0 then 0 else if 0<i then 1 else - 1)"
   176     by (simp only: zsgn_def)
   177 qed
   178 
   179 end
   180 
   181 lemma zless_imp_add1_zle: "w < z \<Longrightarrow> w + 1 \<le> z"
   182   for w z :: int
   183   by transfer clarsimp
   184 
   185 lemma zless_iff_Suc_zadd: "w < z \<longleftrightarrow> (\<exists>n. z = w + int (Suc n))"
   186   for w z :: int
   187   apply transfer
   188   apply auto
   189   apply (rename_tac a b c d)
   190   apply (rule_tac x="c+b - Suc(a+d)" in exI)
   191   apply arith
   192   done
   193 
   194 lemma zabs_less_one_iff [simp]: "\<bar>z\<bar> < 1 \<longleftrightarrow> z = 0" (is "?lhs \<longleftrightarrow> ?rhs")
   195   for z :: int
   196 proof
   197   assume ?rhs
   198   then show ?lhs by simp
   199 next
   200   assume ?lhs
   201   with zless_imp_add1_zle [of "\<bar>z\<bar>" 1] have "\<bar>z\<bar> + 1 \<le> 1" by simp
   202   then have "\<bar>z\<bar> \<le> 0" by simp
   203   then show ?rhs by simp
   204 qed
   205 
   206 lemmas int_distrib =
   207   distrib_right [of z1 z2 w]
   208   distrib_left [of w z1 z2]
   209   left_diff_distrib [of z1 z2 w]
   210   right_diff_distrib [of w z1 z2]
   211   for z1 z2 w :: int
   212 
   213 
   214 subsection \<open>Embedding of the Integers into any \<open>ring_1\<close>: \<open>of_int\<close>\<close>
   215 
   216 context ring_1
   217 begin
   218 
   219 lift_definition of_int :: "int \<Rightarrow> 'a"
   220   is "\<lambda>(i, j). of_nat i - of_nat j"
   221   by (clarsimp simp add: diff_eq_eq eq_diff_eq diff_add_eq
   222       of_nat_add [symmetric] simp del: of_nat_add)
   223 
   224 lemma of_int_0 [simp]: "of_int 0 = 0"
   225   by transfer simp
   226 
   227 lemma of_int_1 [simp]: "of_int 1 = 1"
   228   by transfer simp
   229 
   230 lemma of_int_add [simp]: "of_int (w + z) = of_int w + of_int z"
   231   by transfer (clarsimp simp add: algebra_simps)
   232 
   233 lemma of_int_minus [simp]: "of_int (- z) = - (of_int z)"
   234   by (transfer fixing: uminus) clarsimp
   235 
   236 lemma of_int_diff [simp]: "of_int (w - z) = of_int w - of_int z"
   237   using of_int_add [of w "- z"] by simp
   238 
   239 lemma of_int_mult [simp]: "of_int (w*z) = of_int w * of_int z"
   240   by (transfer fixing: times) (clarsimp simp add: algebra_simps)
   241 
   242 lemma mult_of_int_commute: "of_int x * y = y * of_int x"
   243   by (transfer fixing: times) (auto simp: algebra_simps mult_of_nat_commute)
   244 
   245 text \<open>Collapse nested embeddings.\<close>
   246 lemma of_int_of_nat_eq [simp]: "of_int (int n) = of_nat n"
   247   by (induct n) auto
   248 
   249 lemma of_int_numeral [simp, code_post]: "of_int (numeral k) = numeral k"
   250   by (simp add: of_nat_numeral [symmetric] of_int_of_nat_eq [symmetric])
   251 
   252 lemma of_int_neg_numeral [code_post]: "of_int (- numeral k) = - numeral k"
   253   by simp
   254 
   255 lemma of_int_power [simp]: "of_int (z ^ n) = of_int z ^ n"
   256   by (induct n) simp_all
   257 
   258 lemma of_int_of_bool [simp]:
   259   "of_int (of_bool P) = of_bool P"
   260   by auto
   261 
   262 end
   263 
   264 context ring_char_0
   265 begin
   266 
   267 lemma of_int_eq_iff [simp]: "of_int w = of_int z \<longleftrightarrow> w = z"
   268   by transfer (clarsimp simp add: algebra_simps of_nat_add [symmetric] simp del: of_nat_add)
   269 
   270 text \<open>Special cases where either operand is zero.\<close>
   271 lemma of_int_eq_0_iff [simp]: "of_int z = 0 \<longleftrightarrow> z = 0"
   272   using of_int_eq_iff [of z 0] by simp
   273 
   274 lemma of_int_0_eq_iff [simp]: "0 = of_int z \<longleftrightarrow> z = 0"
   275   using of_int_eq_iff [of 0 z] by simp
   276 
   277 lemma of_int_eq_1_iff [iff]: "of_int z = 1 \<longleftrightarrow> z = 1"
   278   using of_int_eq_iff [of z 1] by simp
   279 
   280 end
   281 
   282 context linordered_idom
   283 begin
   284 
   285 text \<open>Every \<open>linordered_idom\<close> has characteristic zero.\<close>
   286 subclass ring_char_0 ..
   287 
   288 lemma of_int_le_iff [simp]: "of_int w \<le> of_int z \<longleftrightarrow> w \<le> z"
   289   by (transfer fixing: less_eq)
   290     (clarsimp simp add: algebra_simps of_nat_add [symmetric] simp del: of_nat_add)
   291 
   292 lemma of_int_less_iff [simp]: "of_int w < of_int z \<longleftrightarrow> w < z"
   293   by (simp add: less_le order_less_le)
   294 
   295 lemma of_int_0_le_iff [simp]: "0 \<le> of_int z \<longleftrightarrow> 0 \<le> z"
   296   using of_int_le_iff [of 0 z] by simp
   297 
   298 lemma of_int_le_0_iff [simp]: "of_int z \<le> 0 \<longleftrightarrow> z \<le> 0"
   299   using of_int_le_iff [of z 0] by simp
   300 
   301 lemma of_int_0_less_iff [simp]: "0 < of_int z \<longleftrightarrow> 0 < z"
   302   using of_int_less_iff [of 0 z] by simp
   303 
   304 lemma of_int_less_0_iff [simp]: "of_int z < 0 \<longleftrightarrow> z < 0"
   305   using of_int_less_iff [of z 0] by simp
   306 
   307 lemma of_int_1_le_iff [simp]: "1 \<le> of_int z \<longleftrightarrow> 1 \<le> z"
   308   using of_int_le_iff [of 1 z] by simp
   309 
   310 lemma of_int_le_1_iff [simp]: "of_int z \<le> 1 \<longleftrightarrow> z \<le> 1"
   311   using of_int_le_iff [of z 1] by simp
   312 
   313 lemma of_int_1_less_iff [simp]: "1 < of_int z \<longleftrightarrow> 1 < z"
   314   using of_int_less_iff [of 1 z] by simp
   315 
   316 lemma of_int_less_1_iff [simp]: "of_int z < 1 \<longleftrightarrow> z < 1"
   317   using of_int_less_iff [of z 1] by simp
   318 
   319 lemma of_int_pos: "z > 0 \<Longrightarrow> of_int z > 0"
   320   by simp
   321 
   322 lemma of_int_nonneg: "z \<ge> 0 \<Longrightarrow> of_int z \<ge> 0"
   323   by simp
   324 
   325 lemma of_int_abs [simp]: "of_int \<bar>x\<bar> = \<bar>of_int x\<bar>"
   326   by (auto simp add: abs_if)
   327 
   328 lemma of_int_lessD:
   329   assumes "\<bar>of_int n\<bar> < x"
   330   shows "n = 0 \<or> x > 1"
   331 proof (cases "n = 0")
   332   case True
   333   then show ?thesis by simp
   334 next
   335   case False
   336   then have "\<bar>n\<bar> \<noteq> 0" by simp
   337   then have "\<bar>n\<bar> > 0" by simp
   338   then have "\<bar>n\<bar> \<ge> 1"
   339     using zless_imp_add1_zle [of 0 "\<bar>n\<bar>"] by simp
   340   then have "\<bar>of_int n\<bar> \<ge> 1"
   341     unfolding of_int_1_le_iff [of "\<bar>n\<bar>", symmetric] by simp
   342   then have "1 < x" using assms by (rule le_less_trans)
   343   then show ?thesis ..
   344 qed
   345 
   346 lemma of_int_leD:
   347   assumes "\<bar>of_int n\<bar> \<le> x"
   348   shows "n = 0 \<or> 1 \<le> x"
   349 proof (cases "n = 0")
   350   case True
   351   then show ?thesis by simp
   352 next
   353   case False
   354   then have "\<bar>n\<bar> \<noteq> 0" by simp
   355   then have "\<bar>n\<bar> > 0" by simp
   356   then have "\<bar>n\<bar> \<ge> 1"
   357     using zless_imp_add1_zle [of 0 "\<bar>n\<bar>"] by simp
   358   then have "\<bar>of_int n\<bar> \<ge> 1"
   359     unfolding of_int_1_le_iff [of "\<bar>n\<bar>", symmetric] by simp
   360   then have "1 \<le> x" using assms by (rule order_trans)
   361   then show ?thesis ..
   362 qed
   363 
   364 end
   365 
   366 text \<open>Comparisons involving @{term of_int}.\<close>
   367 
   368 lemma of_int_eq_numeral_iff [iff]: "of_int z = (numeral n :: 'a::ring_char_0) \<longleftrightarrow> z = numeral n"
   369   using of_int_eq_iff by fastforce
   370 
   371 lemma of_int_le_numeral_iff [simp]:
   372   "of_int z \<le> (numeral n :: 'a::linordered_idom) \<longleftrightarrow> z \<le> numeral n"
   373   using of_int_le_iff [of z "numeral n"] by simp
   374 
   375 lemma of_int_numeral_le_iff [simp]:
   376   "(numeral n :: 'a::linordered_idom) \<le> of_int z \<longleftrightarrow> numeral n \<le> z"
   377   using of_int_le_iff [of "numeral n"] by simp
   378 
   379 lemma of_int_less_numeral_iff [simp]:
   380   "of_int z < (numeral n :: 'a::linordered_idom) \<longleftrightarrow> z < numeral n"
   381   using of_int_less_iff [of z "numeral n"] by simp
   382 
   383 lemma of_int_numeral_less_iff [simp]:
   384   "(numeral n :: 'a::linordered_idom) < of_int z \<longleftrightarrow> numeral n < z"
   385   using of_int_less_iff [of "numeral n" z] by simp
   386 
   387 lemma of_nat_less_of_int_iff: "(of_nat n::'a::linordered_idom) < of_int x \<longleftrightarrow> int n < x"
   388   by (metis of_int_of_nat_eq of_int_less_iff)
   389 
   390 lemma of_int_eq_id [simp]: "of_int = id"
   391 proof
   392   show "of_int z = id z" for z
   393     by (cases z rule: int_diff_cases) simp
   394 qed
   395 
   396 instance int :: no_top
   397   apply standard
   398   apply (rule_tac x="x + 1" in exI)
   399   apply simp
   400   done
   401 
   402 instance int :: no_bot
   403   apply standard
   404   apply (rule_tac x="x - 1" in exI)
   405   apply simp
   406   done
   407 
   408 
   409 subsection \<open>Magnitude of an Integer, as a Natural Number: \<open>nat\<close>\<close>
   410 
   411 lift_definition nat :: "int \<Rightarrow> nat" is "\<lambda>(x, y). x - y"
   412   by auto
   413 
   414 lemma nat_int [simp]: "nat (int n) = n"
   415   by transfer simp
   416 
   417 lemma int_nat_eq [simp]: "int (nat z) = (if 0 \<le> z then z else 0)"
   418   by transfer clarsimp
   419 
   420 lemma nat_0_le: "0 \<le> z \<Longrightarrow> int (nat z) = z"
   421   by simp
   422 
   423 lemma nat_le_0 [simp]: "z \<le> 0 \<Longrightarrow> nat z = 0"
   424   by transfer clarsimp
   425 
   426 lemma nat_le_eq_zle: "0 < w \<or> 0 \<le> z \<Longrightarrow> nat w \<le> nat z \<longleftrightarrow> w \<le> z"
   427   by transfer (clarsimp, arith)
   428 
   429 text \<open>An alternative condition is @{term "0 \<le> w"}.\<close>
   430 lemma nat_mono_iff: "0 < z \<Longrightarrow> nat w < nat z \<longleftrightarrow> w < z"
   431   by (simp add: nat_le_eq_zle linorder_not_le [symmetric])
   432 
   433 lemma nat_less_eq_zless: "0 \<le> w \<Longrightarrow> nat w < nat z \<longleftrightarrow> w < z"
   434   by (simp add: nat_le_eq_zle linorder_not_le [symmetric])
   435 
   436 lemma zless_nat_conj [simp]: "nat w < nat z \<longleftrightarrow> 0 < z \<and> w < z"
   437   by transfer (clarsimp, arith)
   438 
   439 lemma nonneg_int_cases:
   440   assumes "0 \<le> k"
   441   obtains n where "k = int n"
   442 proof -
   443   from assms have "k = int (nat k)"
   444     by simp
   445   then show thesis
   446     by (rule that)
   447 qed
   448 
   449 lemma pos_int_cases:
   450   assumes "0 < k"
   451   obtains n where "k = int n" and "n > 0"
   452 proof -
   453   from assms have "0 \<le> k"
   454     by simp
   455   then obtain n where "k = int n"
   456     by (rule nonneg_int_cases)
   457   moreover have "n > 0"
   458     using \<open>k = int n\<close> assms by simp
   459   ultimately show thesis
   460     by (rule that)
   461 qed
   462 
   463 lemma nonpos_int_cases:
   464   assumes "k \<le> 0"
   465   obtains n where "k = - int n"
   466 proof -
   467   from assms have "- k \<ge> 0"
   468     by simp
   469   then obtain n where "- k = int n"
   470     by (rule nonneg_int_cases)
   471   then have "k = - int n"
   472     by simp
   473   then show thesis
   474     by (rule that)
   475 qed
   476 
   477 lemma neg_int_cases:
   478   assumes "k < 0"
   479   obtains n where "k = - int n" and "n > 0"
   480 proof -
   481   from assms have "- k > 0"
   482     by simp
   483   then obtain n where "- k = int n" and "- k > 0"
   484     by (blast elim: pos_int_cases)
   485   then have "k = - int n" and "n > 0"
   486     by simp_all
   487   then show thesis
   488     by (rule that)
   489 qed
   490 
   491 lemma nat_eq_iff: "nat w = m \<longleftrightarrow> (if 0 \<le> w then w = int m else m = 0)"
   492   by transfer (clarsimp simp add: le_imp_diff_is_add)
   493 
   494 lemma nat_eq_iff2: "m = nat w \<longleftrightarrow> (if 0 \<le> w then w = int m else m = 0)"
   495   using nat_eq_iff [of w m] by auto
   496 
   497 lemma nat_0 [simp]: "nat 0 = 0"
   498   by (simp add: nat_eq_iff)
   499 
   500 lemma nat_1 [simp]: "nat 1 = Suc 0"
   501   by (simp add: nat_eq_iff)
   502 
   503 lemma nat_numeral [simp]: "nat (numeral k) = numeral k"
   504   by (simp add: nat_eq_iff)
   505 
   506 lemma nat_neg_numeral [simp]: "nat (- numeral k) = 0"
   507   by simp
   508 
   509 lemma nat_2: "nat 2 = Suc (Suc 0)"
   510   by simp
   511 
   512 lemma nat_less_iff: "0 \<le> w \<Longrightarrow> nat w < m \<longleftrightarrow> w < of_nat m"
   513   by transfer (clarsimp, arith)
   514 
   515 lemma nat_le_iff: "nat x \<le> n \<longleftrightarrow> x \<le> int n"
   516   by transfer (clarsimp simp add: le_diff_conv)
   517 
   518 lemma nat_mono: "x \<le> y \<Longrightarrow> nat x \<le> nat y"
   519   by transfer auto
   520 
   521 lemma nat_0_iff[simp]: "nat i = 0 \<longleftrightarrow> i \<le> 0"
   522   for i :: int
   523   by transfer clarsimp
   524 
   525 lemma int_eq_iff: "of_nat m = z \<longleftrightarrow> m = nat z \<and> 0 \<le> z"
   526   by (auto simp add: nat_eq_iff2)
   527 
   528 lemma zero_less_nat_eq [simp]: "0 < nat z \<longleftrightarrow> 0 < z"
   529   using zless_nat_conj [of 0] by auto
   530 
   531 lemma nat_add_distrib: "0 \<le> z \<Longrightarrow> 0 \<le> z' \<Longrightarrow> nat (z + z') = nat z + nat z'"
   532   by transfer clarsimp
   533 
   534 lemma nat_diff_distrib': "0 \<le> x \<Longrightarrow> 0 \<le> y \<Longrightarrow> nat (x - y) = nat x - nat y"
   535   by transfer clarsimp
   536 
   537 lemma nat_diff_distrib: "0 \<le> z' \<Longrightarrow> z' \<le> z \<Longrightarrow> nat (z - z') = nat z - nat z'"
   538   by (rule nat_diff_distrib') auto
   539 
   540 lemma nat_zminus_int [simp]: "nat (- int n) = 0"
   541   by transfer simp
   542 
   543 lemma le_nat_iff: "k \<ge> 0 \<Longrightarrow> n \<le> nat k \<longleftrightarrow> int n \<le> k"
   544   by transfer auto
   545 
   546 lemma zless_nat_eq_int_zless: "m < nat z \<longleftrightarrow> int m < z"
   547   by transfer (clarsimp simp add: less_diff_conv)
   548 
   549 lemma (in ring_1) of_nat_nat [simp]: "0 \<le> z \<Longrightarrow> of_nat (nat z) = of_int z"
   550   by transfer (clarsimp simp add: of_nat_diff)
   551 
   552 lemma diff_nat_numeral [simp]: "(numeral v :: nat) - numeral v' = nat (numeral v - numeral v')"
   553   by (simp only: nat_diff_distrib' zero_le_numeral nat_numeral)
   554 
   555 lemma nat_abs_triangle_ineq:
   556   "nat \<bar>k + l\<bar> \<le> nat \<bar>k\<bar> + nat \<bar>l\<bar>"
   557   by (simp add: nat_add_distrib [symmetric] nat_le_eq_zle abs_triangle_ineq)
   558 
   559 lemma nat_of_bool [simp]:
   560   "nat (of_bool P) = of_bool P"
   561   by auto
   562 
   563 lemma split_nat [arith_split]: "P (nat i) \<longleftrightarrow> ((\<forall>n. i = int n \<longrightarrow> P n) \<and> (i < 0 \<longrightarrow> P 0))"
   564   (is "?P = (?L \<and> ?R)")
   565   for i :: int
   566 proof (cases "i < 0")
   567   case True
   568   then show ?thesis
   569     by auto
   570 next
   571   case False
   572   have "?P = ?L"
   573   proof
   574     assume ?P
   575     then show ?L using False by auto
   576   next
   577     assume ?L
   578     moreover from False have "int (nat i) = i"
   579       by (simp add: not_less)
   580     ultimately show ?P
   581       by simp
   582   qed
   583   with False show ?thesis by simp
   584 qed
   585 
   586 lemma all_nat: "(\<forall>x. P x) \<longleftrightarrow> (\<forall>x\<ge>0. P (nat x))"
   587   by (auto split: split_nat)
   588 
   589 lemma ex_nat: "(\<exists>x. P x) \<longleftrightarrow> (\<exists>x. 0 \<le> x \<and> P (nat x))"
   590 proof
   591   assume "\<exists>x. P x"
   592   then obtain x where "P x" ..
   593   then have "int x \<ge> 0 \<and> P (nat (int x))" by simp
   594   then show "\<exists>x\<ge>0. P (nat x)" ..
   595 next
   596   assume "\<exists>x\<ge>0. P (nat x)"
   597   then show "\<exists>x. P x" by auto
   598 qed
   599 
   600 
   601 text \<open>For termination proofs:\<close>
   602 lemma measure_function_int[measure_function]: "is_measure (nat \<circ> abs)" ..
   603 
   604 
   605 subsection \<open>Lemmas about the Function @{term of_nat} and Orderings\<close>
   606 
   607 lemma negative_zless_0: "- (int (Suc n)) < (0 :: int)"
   608   by (simp add: order_less_le del: of_nat_Suc)
   609 
   610 lemma negative_zless [iff]: "- (int (Suc n)) < int m"
   611   by (rule negative_zless_0 [THEN order_less_le_trans], simp)
   612 
   613 lemma negative_zle_0: "- int n \<le> 0"
   614   by (simp add: minus_le_iff)
   615 
   616 lemma negative_zle [iff]: "- int n \<le> int m"
   617   by (rule order_trans [OF negative_zle_0 of_nat_0_le_iff])
   618 
   619 lemma not_zle_0_negative [simp]: "\<not> 0 \<le> - int (Suc n)"
   620   by (subst le_minus_iff) (simp del: of_nat_Suc)
   621 
   622 lemma int_zle_neg: "int n \<le> - int m \<longleftrightarrow> n = 0 \<and> m = 0"
   623   by transfer simp
   624 
   625 lemma not_int_zless_negative [simp]: "\<not> int n < - int m"
   626   by (simp add: linorder_not_less)
   627 
   628 lemma negative_eq_positive [simp]: "- int n = of_nat m \<longleftrightarrow> n = 0 \<and> m = 0"
   629   by (force simp add: order_eq_iff [of "- of_nat n"] int_zle_neg)
   630 
   631 lemma zle_iff_zadd: "w \<le> z \<longleftrightarrow> (\<exists>n. z = w + int n)"
   632   (is "?lhs \<longleftrightarrow> ?rhs")
   633 proof
   634   assume ?rhs
   635   then show ?lhs by auto
   636 next
   637   assume ?lhs
   638   then have "0 \<le> z - w" by simp
   639   then obtain n where "z - w = int n"
   640     using zero_le_imp_eq_int [of "z - w"] by blast
   641   then have "z = w + int n" by simp
   642   then show ?rhs ..
   643 qed
   644 
   645 lemma zadd_int_left: "int m + (int n + z) = int (m + n) + z"
   646   by simp
   647 
   648 text \<open>
   649   This version is proved for all ordered rings, not just integers!
   650   It is proved here because attribute \<open>arith_split\<close> is not available
   651   in theory \<open>Rings\<close>.
   652   But is it really better than just rewriting with \<open>abs_if\<close>?
   653 \<close>
   654 lemma abs_split [arith_split, no_atp]: "P \<bar>a\<bar> \<longleftrightarrow> (0 \<le> a \<longrightarrow> P a) \<and> (a < 0 \<longrightarrow> P (- a))"
   655   for a :: "'a::linordered_idom"
   656   by (force dest: order_less_le_trans simp add: abs_if linorder_not_less)
   657 
   658 lemma negD: "x < 0 \<Longrightarrow> \<exists>n. x = - (int (Suc n))"
   659   apply transfer
   660   apply clarsimp
   661   apply (rule_tac x="b - Suc a" in exI)
   662   apply arith
   663   done
   664 
   665 
   666 subsection \<open>Cases and induction\<close>
   667 
   668 text \<open>
   669   Now we replace the case analysis rule by a more conventional one:
   670   whether an integer is negative or not.
   671 \<close>
   672 
   673 text \<open>This version is symmetric in the two subgoals.\<close>
   674 lemma int_cases2 [case_names nonneg nonpos, cases type: int]:
   675   "(\<And>n. z = int n \<Longrightarrow> P) \<Longrightarrow> (\<And>n. z = - (int n) \<Longrightarrow> P) \<Longrightarrow> P"
   676   by (cases "z < 0") (auto simp add: linorder_not_less dest!: negD nat_0_le [THEN sym])
   677 
   678 text \<open>This is the default, with a negative case.\<close>
   679 lemma int_cases [case_names nonneg neg, cases type: int]:
   680   "(\<And>n. z = int n \<Longrightarrow> P) \<Longrightarrow> (\<And>n. z = - (int (Suc n)) \<Longrightarrow> P) \<Longrightarrow> P"
   681   apply (cases "z < 0")
   682    apply (blast dest!: negD)
   683   apply (simp add: linorder_not_less del: of_nat_Suc)
   684   apply auto
   685   apply (blast dest: nat_0_le [THEN sym])
   686   done
   687 
   688 lemma int_cases3 [case_names zero pos neg]:
   689   fixes k :: int
   690   assumes "k = 0 \<Longrightarrow> P" and "\<And>n. k = int n \<Longrightarrow> n > 0 \<Longrightarrow> P"
   691     and "\<And>n. k = - int n \<Longrightarrow> n > 0 \<Longrightarrow> P"
   692   shows "P"
   693 proof (cases k "0::int" rule: linorder_cases)
   694   case equal
   695   with assms(1) show P by simp
   696 next
   697   case greater
   698   then have *: "nat k > 0" by simp
   699   moreover from * have "k = int (nat k)" by auto
   700   ultimately show P using assms(2) by blast
   701 next
   702   case less
   703   then have *: "nat (- k) > 0" by simp
   704   moreover from * have "k = - int (nat (- k))" by auto
   705   ultimately show P using assms(3) by blast
   706 qed
   707 
   708 lemma int_of_nat_induct [case_names nonneg neg, induct type: int]:
   709   "(\<And>n. P (int n)) \<Longrightarrow> (\<And>n. P (- (int (Suc n)))) \<Longrightarrow> P z"
   710   by (cases z) auto
   711 
   712 lemma Let_numeral [simp]: "Let (numeral v) f = f (numeral v)"
   713   \<comment> \<open>Unfold all \<open>let\<close>s involving constants\<close>
   714   by (fact Let_numeral) \<comment> \<open>FIXME drop\<close>
   715 
   716 lemma Let_neg_numeral [simp]: "Let (- numeral v) f = f (- numeral v)"
   717   \<comment> \<open>Unfold all \<open>let\<close>s involving constants\<close>
   718   by (fact Let_neg_numeral) \<comment> \<open>FIXME drop\<close>
   719 
   720 lemma sgn_mult_dvd_iff [simp]:
   721   "sgn r * l dvd k \<longleftrightarrow> l dvd k \<and> (r = 0 \<longrightarrow> k = 0)" for k l r :: int
   722   by (cases r rule: int_cases3) auto
   723 
   724 lemma mult_sgn_dvd_iff [simp]:
   725   "l * sgn r dvd k \<longleftrightarrow> l dvd k \<and> (r = 0 \<longrightarrow> k = 0)" for k l r :: int
   726   using sgn_mult_dvd_iff [of r l k] by (simp add: ac_simps)
   727 
   728 lemma dvd_sgn_mult_iff [simp]:
   729   "l dvd sgn r * k \<longleftrightarrow> l dvd k \<or> r = 0" for k l r :: int
   730   by (cases r rule: int_cases3) simp_all
   731 
   732 lemma dvd_mult_sgn_iff [simp]:
   733   "l dvd k * sgn r \<longleftrightarrow> l dvd k \<or> r = 0" for k l r :: int
   734   using dvd_sgn_mult_iff [of l r k] by (simp add: ac_simps)
   735 
   736 lemma int_sgnE:
   737   fixes k :: int
   738   obtains n and l where "k = sgn l * int n"
   739 proof -
   740   have "k = sgn k * int (nat \<bar>k\<bar>)"
   741     by (simp add: sgn_mult_abs)
   742   then show ?thesis ..
   743 qed
   744 
   745 text \<open>Unfold \<open>min\<close> and \<open>max\<close> on numerals.\<close>
   746 
   747 lemmas max_number_of [simp] =
   748   max_def [of "numeral u" "numeral v"]
   749   max_def [of "numeral u" "- numeral v"]
   750   max_def [of "- numeral u" "numeral v"]
   751   max_def [of "- numeral u" "- numeral v"] for u v
   752 
   753 lemmas min_number_of [simp] =
   754   min_def [of "numeral u" "numeral v"]
   755   min_def [of "numeral u" "- numeral v"]
   756   min_def [of "- numeral u" "numeral v"]
   757   min_def [of "- numeral u" "- numeral v"] for u v
   758 
   759 
   760 subsubsection \<open>Binary comparisons\<close>
   761 
   762 text \<open>Preliminaries\<close>
   763 
   764 lemma le_imp_0_less:
   765   fixes z :: int
   766   assumes le: "0 \<le> z"
   767   shows "0 < 1 + z"
   768 proof -
   769   have "0 \<le> z" by fact
   770   also have "\<dots> < z + 1" by (rule less_add_one)
   771   also have "\<dots> = 1 + z" by (simp add: ac_simps)
   772   finally show "0 < 1 + z" .
   773 qed
   774 
   775 lemma odd_less_0_iff: "1 + z + z < 0 \<longleftrightarrow> z < 0"
   776   for z :: int
   777 proof (cases z)
   778   case (nonneg n)
   779   then show ?thesis
   780     by (simp add: linorder_not_less add.assoc add_increasing le_imp_0_less [THEN order_less_imp_le])
   781 next
   782   case (neg n)
   783   then show ?thesis
   784     by (simp del: of_nat_Suc of_nat_add of_nat_1
   785         add: algebra_simps of_nat_1 [where 'a=int, symmetric] of_nat_add [symmetric])
   786 qed
   787 
   788 
   789 subsubsection \<open>Comparisons, for Ordered Rings\<close>
   790 
   791 lemmas double_eq_0_iff = double_zero
   792 
   793 lemma odd_nonzero: "1 + z + z \<noteq> 0"
   794   for z :: int
   795 proof (cases z)
   796   case (nonneg n)
   797   have le: "0 \<le> z + z"
   798     by (simp add: nonneg add_increasing)
   799   then show ?thesis
   800     using  le_imp_0_less [OF le] by (auto simp: add.assoc)
   801 next
   802   case (neg n)
   803   show ?thesis
   804   proof
   805     assume eq: "1 + z + z = 0"
   806     have "0 < 1 + (int n + int n)"
   807       by (simp add: le_imp_0_less add_increasing)
   808     also have "\<dots> = - (1 + z + z)"
   809       by (simp add: neg add.assoc [symmetric])
   810     also have "\<dots> = 0" by (simp add: eq)
   811     finally have "0<0" ..
   812     then show False by blast
   813   qed
   814 qed
   815 
   816 
   817 subsection \<open>The Set of Integers\<close>
   818 
   819 context ring_1
   820 begin
   821 
   822 definition Ints :: "'a set"  ("\<int>")
   823   where "\<int> = range of_int"
   824 
   825 lemma Ints_of_int [simp]: "of_int z \<in> \<int>"
   826   by (simp add: Ints_def)
   827 
   828 lemma Ints_of_nat [simp]: "of_nat n \<in> \<int>"
   829   using Ints_of_int [of "of_nat n"] by simp
   830 
   831 lemma Ints_0 [simp]: "0 \<in> \<int>"
   832   using Ints_of_int [of "0"] by simp
   833 
   834 lemma Ints_1 [simp]: "1 \<in> \<int>"
   835   using Ints_of_int [of "1"] by simp
   836 
   837 lemma Ints_numeral [simp]: "numeral n \<in> \<int>"
   838   by (subst of_nat_numeral [symmetric], rule Ints_of_nat)
   839 
   840 lemma Ints_add [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a + b \<in> \<int>"
   841   apply (auto simp add: Ints_def)
   842   apply (rule range_eqI)
   843   apply (rule of_int_add [symmetric])
   844   done
   845 
   846 lemma Ints_minus [simp]: "a \<in> \<int> \<Longrightarrow> -a \<in> \<int>"
   847   apply (auto simp add: Ints_def)
   848   apply (rule range_eqI)
   849   apply (rule of_int_minus [symmetric])
   850   done
   851 
   852 lemma Ints_diff [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a - b \<in> \<int>"
   853   apply (auto simp add: Ints_def)
   854   apply (rule range_eqI)
   855   apply (rule of_int_diff [symmetric])
   856   done
   857 
   858 lemma Ints_mult [simp]: "a \<in> \<int> \<Longrightarrow> b \<in> \<int> \<Longrightarrow> a * b \<in> \<int>"
   859   apply (auto simp add: Ints_def)
   860   apply (rule range_eqI)
   861   apply (rule of_int_mult [symmetric])
   862   done
   863 
   864 lemma Ints_power [simp]: "a \<in> \<int> \<Longrightarrow> a ^ n \<in> \<int>"
   865   by (induct n) simp_all
   866 
   867 lemma Ints_cases [cases set: Ints]:
   868   assumes "q \<in> \<int>"
   869   obtains (of_int) z where "q = of_int z"
   870   unfolding Ints_def
   871 proof -
   872   from \<open>q \<in> \<int>\<close> have "q \<in> range of_int" unfolding Ints_def .
   873   then obtain z where "q = of_int z" ..
   874   then show thesis ..
   875 qed
   876 
   877 lemma Ints_induct [case_names of_int, induct set: Ints]:
   878   "q \<in> \<int> \<Longrightarrow> (\<And>z. P (of_int z)) \<Longrightarrow> P q"
   879   by (rule Ints_cases) auto
   880 
   881 lemma Nats_subset_Ints: "\<nat> \<subseteq> \<int>"
   882   unfolding Nats_def Ints_def
   883   by (rule subsetI, elim imageE, hypsubst, subst of_int_of_nat_eq[symmetric], rule imageI) simp_all
   884 
   885 lemma Nats_altdef1: "\<nat> = {of_int n |n. n \<ge> 0}"
   886 proof (intro subsetI equalityI)
   887   fix x :: 'a
   888   assume "x \<in> {of_int n |n. n \<ge> 0}"
   889   then obtain n where "x = of_int n" "n \<ge> 0"
   890     by (auto elim!: Ints_cases)
   891   then have "x = of_nat (nat n)"
   892     by (subst of_nat_nat) simp_all
   893   then show "x \<in> \<nat>"
   894     by simp
   895 next
   896   fix x :: 'a
   897   assume "x \<in> \<nat>"
   898   then obtain n where "x = of_nat n"
   899     by (auto elim!: Nats_cases)
   900   then have "x = of_int (int n)" by simp
   901   also have "int n \<ge> 0" by simp
   902   then have "of_int (int n) \<in> {of_int n |n. n \<ge> 0}" by blast
   903   finally show "x \<in> {of_int n |n. n \<ge> 0}" .
   904 qed
   905 
   906 end
   907 
   908 lemma (in linordered_idom) Ints_abs [simp]:
   909   shows "a \<in> \<int> \<Longrightarrow> abs a \<in> \<int>"
   910   by (auto simp: abs_if)
   911 
   912 lemma (in linordered_idom) Nats_altdef2: "\<nat> = {n \<in> \<int>. n \<ge> 0}"
   913 proof (intro subsetI equalityI)
   914   fix x :: 'a
   915   assume "x \<in> {n \<in> \<int>. n \<ge> 0}"
   916   then obtain n where "x = of_int n" "n \<ge> 0"
   917     by (auto elim!: Ints_cases)
   918   then have "x = of_nat (nat n)"
   919     by (subst of_nat_nat) simp_all
   920   then show "x \<in> \<nat>"
   921     by simp
   922 qed (auto elim!: Nats_cases)
   923 
   924 lemma (in idom_divide) of_int_divide_in_Ints: 
   925   "of_int a div of_int b \<in> \<int>" if "b dvd a"
   926 proof -
   927   from that obtain c where "a = b * c" ..
   928   then show ?thesis
   929     by (cases "of_int b = 0") simp_all
   930 qed
   931 
   932 text \<open>The premise involving @{term Ints} prevents @{term "a = 1/2"}.\<close>
   933 
   934 lemma Ints_double_eq_0_iff:
   935   fixes a :: "'a::ring_char_0"
   936   assumes in_Ints: "a \<in> \<int>"
   937   shows "a + a = 0 \<longleftrightarrow> a = 0"
   938     (is "?lhs \<longleftrightarrow> ?rhs")
   939 proof -
   940   from in_Ints have "a \<in> range of_int"
   941     unfolding Ints_def [symmetric] .
   942   then obtain z where a: "a = of_int z" ..
   943   show ?thesis
   944   proof
   945     assume ?rhs
   946     then show ?lhs by simp
   947   next
   948     assume ?lhs
   949     with a have "of_int (z + z) = (of_int 0 :: 'a)" by simp
   950     then have "z + z = 0" by (simp only: of_int_eq_iff)
   951     then have "z = 0" by (simp only: double_eq_0_iff)
   952     with a show ?rhs by simp
   953   qed
   954 qed
   955 
   956 lemma Ints_odd_nonzero:
   957   fixes a :: "'a::ring_char_0"
   958   assumes in_Ints: "a \<in> \<int>"
   959   shows "1 + a + a \<noteq> 0"
   960 proof -
   961   from in_Ints have "a \<in> range of_int"
   962     unfolding Ints_def [symmetric] .
   963   then obtain z where a: "a = of_int z" ..
   964   show ?thesis
   965   proof
   966     assume "1 + a + a = 0"
   967     with a have "of_int (1 + z + z) = (of_int 0 :: 'a)" by simp
   968     then have "1 + z + z = 0" by (simp only: of_int_eq_iff)
   969     with odd_nonzero show False by blast
   970   qed
   971 qed
   972 
   973 lemma Nats_numeral [simp]: "numeral w \<in> \<nat>"
   974   using of_nat_in_Nats [of "numeral w"] by simp
   975 
   976 lemma Ints_odd_less_0:
   977   fixes a :: "'a::linordered_idom"
   978   assumes in_Ints: "a \<in> \<int>"
   979   shows "1 + a + a < 0 \<longleftrightarrow> a < 0"
   980 proof -
   981   from in_Ints have "a \<in> range of_int"
   982     unfolding Ints_def [symmetric] .
   983   then obtain z where a: "a = of_int z" ..
   984   with a have "1 + a + a < 0 \<longleftrightarrow> of_int (1 + z + z) < (of_int 0 :: 'a)"
   985     by simp
   986   also have "\<dots> \<longleftrightarrow> z < 0"
   987     by (simp only: of_int_less_iff odd_less_0_iff)
   988   also have "\<dots> \<longleftrightarrow> a < 0"
   989     by (simp add: a)
   990   finally show ?thesis .
   991 qed
   992 
   993 
   994 subsection \<open>@{term sum} and @{term prod}\<close>
   995 
   996 lemma of_nat_sum [simp]: "of_nat (sum f A) = (\<Sum>x\<in>A. of_nat(f x))"
   997   by (induct A rule: infinite_finite_induct) auto
   998 
   999 lemma of_int_sum [simp]: "of_int (sum f A) = (\<Sum>x\<in>A. of_int(f x))"
  1000   by (induct A rule: infinite_finite_induct) auto
  1001 
  1002 lemma of_nat_prod [simp]: "of_nat (prod f A) = (\<Prod>x\<in>A. of_nat(f x))"
  1003   by (induct A rule: infinite_finite_induct) auto
  1004 
  1005 lemma of_int_prod [simp]: "of_int (prod f A) = (\<Prod>x\<in>A. of_int(f x))"
  1006   by (induct A rule: infinite_finite_induct) auto
  1007 
  1008 
  1009 text \<open>Legacy theorems\<close>
  1010 
  1011 lemmas int_sum = of_nat_sum [where 'a=int]
  1012 lemmas int_prod = of_nat_prod [where 'a=int]
  1013 lemmas zle_int = of_nat_le_iff [where 'a=int]
  1014 lemmas int_int_eq = of_nat_eq_iff [where 'a=int]
  1015 lemmas nonneg_eq_int = nonneg_int_cases
  1016 
  1017 
  1018 subsection \<open>Setting up simplification procedures\<close>
  1019 
  1020 lemmas of_int_simps =
  1021   of_int_0 of_int_1 of_int_add of_int_mult
  1022 
  1023 ML_file "Tools/int_arith.ML"
  1024 declaration \<open>K Int_Arith.setup\<close>
  1025 
  1026 simproc_setup fast_arith
  1027   ("(m::'a::linordered_idom) < n" |
  1028     "(m::'a::linordered_idom) \<le> n" |
  1029     "(m::'a::linordered_idom) = n") =
  1030   \<open>K Lin_Arith.simproc\<close>
  1031 
  1032 
  1033 subsection\<open>More Inequality Reasoning\<close>
  1034 
  1035 lemma zless_add1_eq: "w < z + 1 \<longleftrightarrow> w < z \<or> w = z"
  1036   for w z :: int
  1037   by arith
  1038 
  1039 lemma add1_zle_eq: "w + 1 \<le> z \<longleftrightarrow> w < z"
  1040   for w z :: int
  1041   by arith
  1042 
  1043 lemma zle_diff1_eq [simp]: "w \<le> z - 1 \<longleftrightarrow> w < z"
  1044   for w z :: int
  1045   by arith
  1046 
  1047 lemma zle_add1_eq_le [simp]: "w < z + 1 \<longleftrightarrow> w \<le> z"
  1048   for w z :: int
  1049   by arith
  1050 
  1051 lemma int_one_le_iff_zero_less: "1 \<le> z \<longleftrightarrow> 0 < z"
  1052   for z :: int
  1053   by arith
  1054 
  1055 lemma Ints_nonzero_abs_ge1:
  1056   fixes x:: "'a :: linordered_idom"
  1057     assumes "x \<in> Ints" "x \<noteq> 0"
  1058     shows "1 \<le> abs x"
  1059 proof (rule Ints_cases [OF \<open>x \<in> Ints\<close>])
  1060   fix z::int
  1061   assume "x = of_int z"
  1062     with \<open>x \<noteq> 0\<close> 
  1063   show "1 \<le> \<bar>x\<bar>"
  1064     apply (auto simp add: abs_if)
  1065     by (metis diff_0 of_int_1 of_int_le_iff of_int_minus zle_diff1_eq)
  1066 qed
  1067   
  1068 lemma Ints_nonzero_abs_less1:
  1069   fixes x:: "'a :: linordered_idom"
  1070   shows "\<lbrakk>x \<in> Ints; abs x < 1\<rbrakk> \<Longrightarrow> x = 0"
  1071     using Ints_nonzero_abs_ge1 [of x] by auto
  1072     
  1073 
  1074 subsection \<open>The functions @{term nat} and @{term int}\<close>
  1075 
  1076 text \<open>Simplify the term @{term "w + - z"}.\<close>
  1077 
  1078 lemma one_less_nat_eq [simp]: "Suc 0 < nat z \<longleftrightarrow> 1 < z"
  1079   using zless_nat_conj [of 1 z] by auto
  1080 
  1081 text \<open>
  1082   This simplifies expressions of the form @{term "int n = z"} where
  1083   \<open>z\<close> is an integer literal.
  1084 \<close>
  1085 lemmas int_eq_iff_numeral [simp] = int_eq_iff [of _ "numeral v"] for v
  1086 
  1087 lemma nat_abs_int_diff: "nat \<bar>int a - int b\<bar> = (if a \<le> b then b - a else a - b)"
  1088   by auto
  1089 
  1090 lemma nat_int_add: "nat (int a + int b) = a + b"
  1091   by auto
  1092 
  1093 context ring_1
  1094 begin
  1095 
  1096 lemma of_int_of_nat [nitpick_simp]:
  1097   "of_int k = (if k < 0 then - of_nat (nat (- k)) else of_nat (nat k))"
  1098 proof (cases "k < 0")
  1099   case True
  1100   then have "0 \<le> - k" by simp
  1101   then have "of_nat (nat (- k)) = of_int (- k)" by (rule of_nat_nat)
  1102   with True show ?thesis by simp
  1103 next
  1104   case False
  1105   then show ?thesis by (simp add: not_less)
  1106 qed
  1107 
  1108 end
  1109 
  1110 lemma transfer_rule_of_int:
  1111   fixes R :: "'a::ring_1 \<Rightarrow> 'b::ring_1 \<Rightarrow> bool"
  1112   assumes [transfer_rule]: "R 0 0" "R 1 1"
  1113     "rel_fun R (rel_fun R R) plus plus"
  1114     "rel_fun R R uminus uminus"
  1115   shows "rel_fun HOL.eq R of_int of_int"
  1116 proof -
  1117   note transfer_rule_of_nat [transfer_rule]
  1118   have [transfer_rule]: "rel_fun HOL.eq R of_nat of_nat"
  1119     by transfer_prover
  1120   show ?thesis
  1121     by (unfold of_int_of_nat [abs_def]) transfer_prover
  1122 qed
  1123 
  1124 lemma nat_mult_distrib:
  1125   fixes z z' :: int
  1126   assumes "0 \<le> z"
  1127   shows "nat (z * z') = nat z * nat z'"
  1128 proof (cases "0 \<le> z'")
  1129   case False
  1130   with assms have "z * z' \<le> 0"
  1131     by (simp add: not_le mult_le_0_iff)
  1132   then have "nat (z * z') = 0" by simp
  1133   moreover from False have "nat z' = 0" by simp
  1134   ultimately show ?thesis by simp
  1135 next
  1136   case True
  1137   with assms have ge_0: "z * z' \<ge> 0" by (simp add: zero_le_mult_iff)
  1138   show ?thesis
  1139     by (rule injD [of "of_nat :: nat \<Rightarrow> int", OF inj_of_nat])
  1140       (simp only: of_nat_mult of_nat_nat [OF True]
  1141          of_nat_nat [OF assms] of_nat_nat [OF ge_0], simp)
  1142 qed
  1143 
  1144 lemma nat_mult_distrib_neg: "z \<le> 0 \<Longrightarrow> nat (z * z') = nat (- z) * nat (- z')"
  1145   for z z' :: int
  1146   apply (rule trans)
  1147    apply (rule_tac [2] nat_mult_distrib)
  1148    apply auto
  1149   done
  1150 
  1151 lemma nat_abs_mult_distrib: "nat \<bar>w * z\<bar> = nat \<bar>w\<bar> * nat \<bar>z\<bar>"
  1152   by (cases "z = 0 \<or> w = 0")
  1153     (auto simp add: abs_if nat_mult_distrib [symmetric]
  1154       nat_mult_distrib_neg [symmetric] mult_less_0_iff)
  1155 
  1156 lemma int_in_range_abs [simp]: "int n \<in> range abs"
  1157 proof (rule range_eqI)
  1158   show "int n = \<bar>int n\<bar>" by simp
  1159 qed
  1160 
  1161 lemma range_abs_Nats [simp]: "range abs = (\<nat> :: int set)"
  1162 proof -
  1163   have "\<bar>k\<bar> \<in> \<nat>" for k :: int
  1164     by (cases k) simp_all
  1165   moreover have "k \<in> range abs" if "k \<in> \<nat>" for k :: int
  1166     using that by induct simp
  1167   ultimately show ?thesis by blast
  1168 qed
  1169 
  1170 lemma Suc_nat_eq_nat_zadd1: "0 \<le> z \<Longrightarrow> Suc (nat z) = nat (1 + z)"
  1171   for z :: int
  1172   by (rule sym) (simp add: nat_eq_iff)
  1173 
  1174 lemma diff_nat_eq_if:
  1175   "nat z - nat z' =
  1176     (if z' < 0 then nat z
  1177      else
  1178       let d = z - z'
  1179       in if d < 0 then 0 else nat d)"
  1180   by (simp add: Let_def nat_diff_distrib [symmetric])
  1181 
  1182 lemma nat_numeral_diff_1 [simp]: "numeral v - (1::nat) = nat (numeral v - 1)"
  1183   using diff_nat_numeral [of v Num.One] by simp
  1184 
  1185 
  1186 subsection \<open>Induction principles for int\<close>
  1187 
  1188 text \<open>Well-founded segments of the integers.\<close>
  1189 
  1190 definition int_ge_less_than :: "int \<Rightarrow> (int \<times> int) set"
  1191   where "int_ge_less_than d = {(z', z). d \<le> z' \<and> z' < z}"
  1192 
  1193 lemma wf_int_ge_less_than: "wf (int_ge_less_than d)"
  1194 proof -
  1195   have "int_ge_less_than d \<subseteq> measure (\<lambda>z. nat (z - d))"
  1196     by (auto simp add: int_ge_less_than_def)
  1197   then show ?thesis
  1198     by (rule wf_subset [OF wf_measure])
  1199 qed
  1200 
  1201 text \<open>
  1202   This variant looks odd, but is typical of the relations suggested
  1203   by RankFinder.\<close>
  1204 
  1205 definition int_ge_less_than2 :: "int \<Rightarrow> (int \<times> int) set"
  1206   where "int_ge_less_than2 d = {(z',z). d \<le> z \<and> z' < z}"
  1207 
  1208 lemma wf_int_ge_less_than2: "wf (int_ge_less_than2 d)"
  1209 proof -
  1210   have "int_ge_less_than2 d \<subseteq> measure (\<lambda>z. nat (1 + z - d))"
  1211     by (auto simp add: int_ge_less_than2_def)
  1212   then show ?thesis
  1213     by (rule wf_subset [OF wf_measure])
  1214 qed
  1215 
  1216 (* `set:int': dummy construction *)
  1217 theorem int_ge_induct [case_names base step, induct set: int]:
  1218   fixes i :: int
  1219   assumes ge: "k \<le> i"
  1220     and base: "P k"
  1221     and step: "\<And>i. k \<le> i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
  1222   shows "P i"
  1223 proof -
  1224   have "\<And>i::int. n = nat (i - k) \<Longrightarrow> k \<le> i \<Longrightarrow> P i" for n
  1225   proof (induct n)
  1226     case 0
  1227     then have "i = k" by arith
  1228     with base show "P i" by simp
  1229   next
  1230     case (Suc n)
  1231     then have "n = nat ((i - 1) - k)" by arith
  1232     moreover have k: "k \<le> i - 1" using Suc.prems by arith
  1233     ultimately have "P (i - 1)" by (rule Suc.hyps)
  1234     from step [OF k this] show ?case by simp
  1235   qed
  1236   with ge show ?thesis by fast
  1237 qed
  1238 
  1239 (* `set:int': dummy construction *)
  1240 theorem int_gr_induct [case_names base step, induct set: int]:
  1241   fixes i k :: int
  1242   assumes gr: "k < i"
  1243     and base: "P (k + 1)"
  1244     and step: "\<And>i. k < i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
  1245   shows "P i"
  1246   apply (rule int_ge_induct[of "k + 1"])
  1247   using gr apply arith
  1248    apply (rule base)
  1249   apply (rule step)
  1250    apply simp_all
  1251   done
  1252 
  1253 theorem int_le_induct [consumes 1, case_names base step]:
  1254   fixes i k :: int
  1255   assumes le: "i \<le> k"
  1256     and base: "P k"
  1257     and step: "\<And>i. i \<le> k \<Longrightarrow> P i \<Longrightarrow> P (i - 1)"
  1258   shows "P i"
  1259 proof -
  1260   have "\<And>i::int. n = nat(k-i) \<Longrightarrow> i \<le> k \<Longrightarrow> P i" for n
  1261   proof (induct n)
  1262     case 0
  1263     then have "i = k" by arith
  1264     with base show "P i" by simp
  1265   next
  1266     case (Suc n)
  1267     then have "n = nat (k - (i + 1))" by arith
  1268     moreover have k: "i + 1 \<le> k" using Suc.prems by arith
  1269     ultimately have "P (i + 1)" by (rule Suc.hyps)
  1270     from step[OF k this] show ?case by simp
  1271   qed
  1272   with le show ?thesis by fast
  1273 qed
  1274 
  1275 theorem int_less_induct [consumes 1, case_names base step]:
  1276   fixes i k :: int
  1277   assumes less: "i < k"
  1278     and base: "P (k - 1)"
  1279     and step: "\<And>i. i < k \<Longrightarrow> P i \<Longrightarrow> P (i - 1)"
  1280   shows "P i"
  1281   apply (rule int_le_induct[of _ "k - 1"])
  1282   using less apply arith
  1283    apply (rule base)
  1284   apply (rule step)
  1285    apply simp_all
  1286   done
  1287 
  1288 theorem int_induct [case_names base step1 step2]:
  1289   fixes k :: int
  1290   assumes base: "P k"
  1291     and step1: "\<And>i. k \<le> i \<Longrightarrow> P i \<Longrightarrow> P (i + 1)"
  1292     and step2: "\<And>i. k \<ge> i \<Longrightarrow> P i \<Longrightarrow> P (i - 1)"
  1293   shows "P i"
  1294 proof -
  1295   have "i \<le> k \<or> i \<ge> k" by arith
  1296   then show ?thesis
  1297   proof
  1298     assume "i \<ge> k"
  1299     then show ?thesis
  1300       using base by (rule int_ge_induct) (fact step1)
  1301   next
  1302     assume "i \<le> k"
  1303     then show ?thesis
  1304       using base by (rule int_le_induct) (fact step2)
  1305   qed
  1306 qed
  1307 
  1308 
  1309 subsection \<open>Intermediate value theorems\<close>
  1310 
  1311 lemma int_val_lemma: "(\<forall>i<n. \<bar>f (i + 1) - f i\<bar> \<le> 1) \<longrightarrow> f 0 \<le> k \<longrightarrow> k \<le> f n \<longrightarrow> (\<exists>i \<le> n. f i = k)"
  1312   for n :: nat and k :: int
  1313   unfolding One_nat_def
  1314   apply (induct n)
  1315    apply simp
  1316   apply (intro strip)
  1317   apply (erule impE)
  1318    apply simp
  1319   apply (erule_tac x = n in allE)
  1320   apply simp
  1321   apply (case_tac "k = f (Suc n)")
  1322    apply force
  1323   apply (erule impE)
  1324    apply (simp add: abs_if split: if_split_asm)
  1325   apply (blast intro: le_SucI)
  1326   done
  1327 
  1328 lemmas nat0_intermed_int_val = int_val_lemma [rule_format (no_asm)]
  1329 
  1330 lemma nat_intermed_int_val:
  1331   "\<forall>i. m \<le> i \<and> i < n \<longrightarrow> \<bar>f (i + 1) - f i\<bar> \<le> 1 \<Longrightarrow> m < n \<Longrightarrow>
  1332     f m \<le> k \<Longrightarrow> k \<le> f n \<Longrightarrow> \<exists>i. m \<le> i \<and> i \<le> n \<and> f i = k"
  1333     for f :: "nat \<Rightarrow> int" and k :: int
  1334   apply (cut_tac n = "n-m" and f = "\<lambda>i. f (i + m)" and k = k in int_val_lemma)
  1335   unfolding One_nat_def
  1336   apply simp
  1337   apply (erule exE)
  1338   apply (rule_tac x = "i+m" in exI)
  1339   apply arith
  1340   done
  1341 
  1342 
  1343 subsection \<open>Products and 1, by T. M. Rasmussen\<close>
  1344 
  1345 lemma abs_zmult_eq_1:
  1346   fixes m n :: int
  1347   assumes mn: "\<bar>m * n\<bar> = 1"
  1348   shows "\<bar>m\<bar> = 1"
  1349 proof -
  1350   from mn have 0: "m \<noteq> 0" "n \<noteq> 0" by auto
  1351   have "\<not> 2 \<le> \<bar>m\<bar>"
  1352   proof
  1353     assume "2 \<le> \<bar>m\<bar>"
  1354     then have "2 * \<bar>n\<bar> \<le> \<bar>m\<bar> * \<bar>n\<bar>" by (simp add: mult_mono 0)
  1355     also have "\<dots> = \<bar>m * n\<bar>" by (simp add: abs_mult)
  1356     also from mn have "\<dots> = 1" by simp
  1357     finally have "2 * \<bar>n\<bar> \<le> 1" .
  1358     with 0 show "False" by arith
  1359   qed
  1360   with 0 show ?thesis by auto
  1361 qed
  1362 
  1363 lemma pos_zmult_eq_1_iff_lemma: "m * n = 1 \<Longrightarrow> m = 1 \<or> m = - 1"
  1364   for m n :: int
  1365   using abs_zmult_eq_1 [of m n] by arith
  1366 
  1367 lemma pos_zmult_eq_1_iff:
  1368   fixes m n :: int
  1369   assumes "0 < m"
  1370   shows "m * n = 1 \<longleftrightarrow> m = 1 \<and> n = 1"
  1371 proof -
  1372   from assms have "m * n = 1 \<Longrightarrow> m = 1"
  1373     by (auto dest: pos_zmult_eq_1_iff_lemma)
  1374   then show ?thesis
  1375     by (auto dest: pos_zmult_eq_1_iff_lemma)
  1376 qed
  1377 
  1378 lemma zmult_eq_1_iff: "m * n = 1 \<longleftrightarrow> (m = 1 \<and> n = 1) \<or> (m = - 1 \<and> n = - 1)"
  1379   for m n :: int
  1380   apply (rule iffI)
  1381    apply (frule pos_zmult_eq_1_iff_lemma)
  1382    apply (simp add: mult.commute [of m])
  1383    apply (frule pos_zmult_eq_1_iff_lemma)
  1384    apply auto
  1385   done
  1386 
  1387 lemma infinite_UNIV_int: "\<not> finite (UNIV::int set)"
  1388 proof
  1389   assume "finite (UNIV::int set)"
  1390   moreover have "inj (\<lambda>i::int. 2 * i)"
  1391     by (rule injI) simp
  1392   ultimately have "surj (\<lambda>i::int. 2 * i)"
  1393     by (rule finite_UNIV_inj_surj)
  1394   then obtain i :: int where "1 = 2 * i" by (rule surjE)
  1395   then show False by (simp add: pos_zmult_eq_1_iff)
  1396 qed
  1397 
  1398 
  1399 subsection \<open>Further theorems on numerals\<close>
  1400 
  1401 subsubsection \<open>Special Simplification for Constants\<close>
  1402 
  1403 text \<open>These distributive laws move literals inside sums and differences.\<close>
  1404 
  1405 lemmas distrib_right_numeral [simp] = distrib_right [of _ _ "numeral v"] for v
  1406 lemmas distrib_left_numeral [simp] = distrib_left [of "numeral v"] for v
  1407 lemmas left_diff_distrib_numeral [simp] = left_diff_distrib [of _ _ "numeral v"] for v
  1408 lemmas right_diff_distrib_numeral [simp] = right_diff_distrib [of "numeral v"] for v
  1409 
  1410 text \<open>These are actually for fields, like real: but where else to put them?\<close>
  1411 
  1412 lemmas zero_less_divide_iff_numeral [simp, no_atp] = zero_less_divide_iff [of "numeral w"] for w
  1413 lemmas divide_less_0_iff_numeral [simp, no_atp] = divide_less_0_iff [of "numeral w"] for w
  1414 lemmas zero_le_divide_iff_numeral [simp, no_atp] = zero_le_divide_iff [of "numeral w"] for w
  1415 lemmas divide_le_0_iff_numeral [simp, no_atp] = divide_le_0_iff [of "numeral w"] for w
  1416 
  1417 
  1418 text \<open>Replaces \<open>inverse #nn\<close> by \<open>1/#nn\<close>.  It looks
  1419   strange, but then other simprocs simplify the quotient.\<close>
  1420 
  1421 lemmas inverse_eq_divide_numeral [simp] =
  1422   inverse_eq_divide [of "numeral w"] for w
  1423 
  1424 lemmas inverse_eq_divide_neg_numeral [simp] =
  1425   inverse_eq_divide [of "- numeral w"] for w
  1426 
  1427 text \<open>These laws simplify inequalities, moving unary minus from a term
  1428   into the literal.\<close>
  1429 
  1430 lemmas equation_minus_iff_numeral [no_atp] =
  1431   equation_minus_iff [of "numeral v"] for v
  1432 
  1433 lemmas minus_equation_iff_numeral [no_atp] =
  1434   minus_equation_iff [of _ "numeral v"] for v
  1435 
  1436 lemmas le_minus_iff_numeral [no_atp] =
  1437   le_minus_iff [of "numeral v"] for v
  1438 
  1439 lemmas minus_le_iff_numeral [no_atp] =
  1440   minus_le_iff [of _ "numeral v"] for v
  1441 
  1442 lemmas less_minus_iff_numeral [no_atp] =
  1443   less_minus_iff [of "numeral v"] for v
  1444 
  1445 lemmas minus_less_iff_numeral [no_atp] =
  1446   minus_less_iff [of _ "numeral v"] for v
  1447 
  1448 (* FIXME maybe simproc *)
  1449 
  1450 
  1451 text \<open>Cancellation of constant factors in comparisons (\<open><\<close> and \<open>\<le>\<close>)\<close>
  1452 
  1453 lemmas mult_less_cancel_left_numeral [simp, no_atp] = mult_less_cancel_left [of "numeral v"] for v
  1454 lemmas mult_less_cancel_right_numeral [simp, no_atp] = mult_less_cancel_right [of _ "numeral v"] for v
  1455 lemmas mult_le_cancel_left_numeral [simp, no_atp] = mult_le_cancel_left [of "numeral v"] for v
  1456 lemmas mult_le_cancel_right_numeral [simp, no_atp] = mult_le_cancel_right [of _ "numeral v"] for v
  1457 
  1458 
  1459 text \<open>Multiplying out constant divisors in comparisons (\<open><\<close>, \<open>\<le>\<close> and \<open>=\<close>)\<close>
  1460 
  1461 named_theorems divide_const_simps "simplification rules to simplify comparisons involving constant divisors"
  1462 
  1463 lemmas le_divide_eq_numeral1 [simp,divide_const_simps] =
  1464   pos_le_divide_eq [of "numeral w", OF zero_less_numeral]
  1465   neg_le_divide_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1466 
  1467 lemmas divide_le_eq_numeral1 [simp,divide_const_simps] =
  1468   pos_divide_le_eq [of "numeral w", OF zero_less_numeral]
  1469   neg_divide_le_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1470 
  1471 lemmas less_divide_eq_numeral1 [simp,divide_const_simps] =
  1472   pos_less_divide_eq [of "numeral w", OF zero_less_numeral]
  1473   neg_less_divide_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1474 
  1475 lemmas divide_less_eq_numeral1 [simp,divide_const_simps] =
  1476   pos_divide_less_eq [of "numeral w", OF zero_less_numeral]
  1477   neg_divide_less_eq [of "- numeral w", OF neg_numeral_less_zero] for w
  1478 
  1479 lemmas eq_divide_eq_numeral1 [simp,divide_const_simps] =
  1480   eq_divide_eq [of _ _ "numeral w"]
  1481   eq_divide_eq [of _ _ "- numeral w"] for w
  1482 
  1483 lemmas divide_eq_eq_numeral1 [simp,divide_const_simps] =
  1484   divide_eq_eq [of _ "numeral w"]
  1485   divide_eq_eq [of _ "- numeral w"] for w
  1486 
  1487 
  1488 subsubsection \<open>Optional Simplification Rules Involving Constants\<close>
  1489 
  1490 text \<open>Simplify quotients that are compared with a literal constant.\<close>
  1491 
  1492 lemmas le_divide_eq_numeral [divide_const_simps] =
  1493   le_divide_eq [of "numeral w"]
  1494   le_divide_eq [of "- numeral w"] for w
  1495 
  1496 lemmas divide_le_eq_numeral [divide_const_simps] =
  1497   divide_le_eq [of _ _ "numeral w"]
  1498   divide_le_eq [of _ _ "- numeral w"] for w
  1499 
  1500 lemmas less_divide_eq_numeral [divide_const_simps] =
  1501   less_divide_eq [of "numeral w"]
  1502   less_divide_eq [of "- numeral w"] for w
  1503 
  1504 lemmas divide_less_eq_numeral [divide_const_simps] =
  1505   divide_less_eq [of _ _ "numeral w"]
  1506   divide_less_eq [of _ _ "- numeral w"] for w
  1507 
  1508 lemmas eq_divide_eq_numeral [divide_const_simps] =
  1509   eq_divide_eq [of "numeral w"]
  1510   eq_divide_eq [of "- numeral w"] for w
  1511 
  1512 lemmas divide_eq_eq_numeral [divide_const_simps] =
  1513   divide_eq_eq [of _ _ "numeral w"]
  1514   divide_eq_eq [of _ _ "- numeral w"] for w
  1515 
  1516 
  1517 text \<open>Not good as automatic simprules because they cause case splits.\<close>
  1518 lemmas [divide_const_simps] =
  1519   le_divide_eq_1 divide_le_eq_1 less_divide_eq_1 divide_less_eq_1
  1520 
  1521 
  1522 subsection \<open>The divides relation\<close>
  1523 
  1524 lemma zdvd_antisym_nonneg: "0 \<le> m \<Longrightarrow> 0 \<le> n \<Longrightarrow> m dvd n \<Longrightarrow> n dvd m \<Longrightarrow> m = n"
  1525   for m n :: int
  1526   by (auto simp add: dvd_def mult.assoc zero_le_mult_iff zmult_eq_1_iff)
  1527 
  1528 lemma zdvd_antisym_abs:
  1529   fixes a b :: int
  1530   assumes "a dvd b" and "b dvd a"
  1531   shows "\<bar>a\<bar> = \<bar>b\<bar>"
  1532 proof (cases "a = 0")
  1533   case True
  1534   with assms show ?thesis by simp
  1535 next
  1536   case False
  1537   from \<open>a dvd b\<close> obtain k where k: "b = a * k"
  1538     unfolding dvd_def by blast
  1539   from \<open>b dvd a\<close> obtain k' where k': "a = b * k'"
  1540     unfolding dvd_def by blast
  1541   from k k' have "a = a * k * k'" by simp
  1542   with mult_cancel_left1[where c="a" and b="k*k'"] have kk': "k * k' = 1"
  1543     using \<open>a \<noteq> 0\<close> by (simp add: mult.assoc)
  1544   then have "k = 1 \<and> k' = 1 \<or> k = -1 \<and> k' = -1"
  1545     by (simp add: zmult_eq_1_iff)
  1546   with k k' show ?thesis by auto
  1547 qed
  1548 
  1549 lemma zdvd_zdiffD: "k dvd m - n \<Longrightarrow> k dvd n \<Longrightarrow> k dvd m"
  1550   for k m n :: int
  1551   using dvd_add_right_iff [of k "- n" m] by simp
  1552 
  1553 lemma zdvd_reduce: "k dvd n + k * m \<longleftrightarrow> k dvd n"
  1554   for k m n :: int
  1555   using dvd_add_times_triv_right_iff [of k n m] by (simp add: ac_simps)
  1556 
  1557 lemma dvd_imp_le_int:
  1558   fixes d i :: int
  1559   assumes "i \<noteq> 0" and "d dvd i"
  1560   shows "\<bar>d\<bar> \<le> \<bar>i\<bar>"
  1561 proof -
  1562   from \<open>d dvd i\<close> obtain k where "i = d * k" ..
  1563   with \<open>i \<noteq> 0\<close> have "k \<noteq> 0" by auto
  1564   then have "1 \<le> \<bar>k\<bar>" and "0 \<le> \<bar>d\<bar>" by auto
  1565   then have "\<bar>d\<bar> * 1 \<le> \<bar>d\<bar> * \<bar>k\<bar>" by (rule mult_left_mono)
  1566   with \<open>i = d * k\<close> show ?thesis by (simp add: abs_mult)
  1567 qed
  1568 
  1569 lemma zdvd_not_zless:
  1570   fixes m n :: int
  1571   assumes "0 < m" and "m < n"
  1572   shows "\<not> n dvd m"
  1573 proof
  1574   from assms have "0 < n" by auto
  1575   assume "n dvd m" then obtain k where k: "m = n * k" ..
  1576   with \<open>0 < m\<close> have "0 < n * k" by auto
  1577   with \<open>0 < n\<close> have "0 < k" by (simp add: zero_less_mult_iff)
  1578   with k \<open>0 < n\<close> \<open>m < n\<close> have "n * k < n * 1" by simp
  1579   with \<open>0 < n\<close> \<open>0 < k\<close> show False unfolding mult_less_cancel_left by auto
  1580 qed
  1581 
  1582 lemma zdvd_mult_cancel:
  1583   fixes k m n :: int
  1584   assumes d: "k * m dvd k * n"
  1585     and "k \<noteq> 0"
  1586   shows "m dvd n"
  1587 proof -
  1588   from d obtain h where h: "k * n = k * m * h"
  1589     unfolding dvd_def by blast
  1590   have "n = m * h"
  1591   proof (rule ccontr)
  1592     assume "\<not> ?thesis"
  1593     with \<open>k \<noteq> 0\<close> have "k * n \<noteq> k * (m * h)" by simp
  1594     with h show False
  1595       by (simp add: mult.assoc)
  1596   qed
  1597   then show ?thesis by simp
  1598 qed
  1599 
  1600 theorem zdvd_int: "x dvd y \<longleftrightarrow> int x dvd int y"
  1601 proof -
  1602   have "x dvd y" if "int y = int x * k" for k
  1603   proof (cases k)
  1604     case (nonneg n)
  1605     with that have "y = x * n"
  1606       by (simp del: of_nat_mult add: of_nat_mult [symmetric])
  1607     then show ?thesis ..
  1608   next
  1609     case (neg n)
  1610     with that have "int y = int x * (- int (Suc n))"
  1611       by simp
  1612     also have "\<dots> = - (int x * int (Suc n))"
  1613       by (simp only: mult_minus_right)
  1614     also have "\<dots> = - int (x * Suc n)"
  1615       by (simp only: of_nat_mult [symmetric])
  1616     finally have "- int (x * Suc n) = int y" ..
  1617     then show ?thesis
  1618       by (simp only: negative_eq_positive) auto
  1619   qed
  1620   then show ?thesis
  1621     by (auto elim!: dvdE simp only: dvd_triv_left of_nat_mult)
  1622 qed
  1623 
  1624 lemma zdvd1_eq[simp]: "x dvd 1 \<longleftrightarrow> \<bar>x\<bar> = 1"
  1625   (is "?lhs \<longleftrightarrow> ?rhs")
  1626   for x :: int
  1627 proof
  1628   assume ?lhs
  1629   then have "int (nat \<bar>x\<bar>) dvd int (nat 1)" by simp
  1630   then have "nat \<bar>x\<bar> dvd 1" by (simp add: zdvd_int)
  1631   then have "nat \<bar>x\<bar> = 1" by simp
  1632   then show ?rhs by (cases "x < 0") auto
  1633 next
  1634   assume ?rhs
  1635   then have "x = 1 \<or> x = - 1" by auto
  1636   then show ?lhs by (auto intro: dvdI)
  1637 qed
  1638 
  1639 lemma zdvd_mult_cancel1:
  1640   fixes m :: int
  1641   assumes mp: "m \<noteq> 0"
  1642   shows "m * n dvd m \<longleftrightarrow> \<bar>n\<bar> = 1"
  1643     (is "?lhs \<longleftrightarrow> ?rhs")
  1644 proof
  1645   assume ?rhs
  1646   then show ?lhs
  1647     by (cases "n > 0") (auto simp add: minus_equation_iff)
  1648 next
  1649   assume ?lhs
  1650   then have "m * n dvd m * 1" by simp
  1651   from zdvd_mult_cancel[OF this mp] show ?rhs
  1652     by (simp only: zdvd1_eq)
  1653 qed
  1654 
  1655 lemma int_dvd_iff: "int m dvd z \<longleftrightarrow> m dvd nat \<bar>z\<bar>"
  1656   by (cases "z \<ge> 0") (simp_all add: zdvd_int)
  1657 
  1658 lemma dvd_int_iff: "z dvd int m \<longleftrightarrow> nat \<bar>z\<bar> dvd m"
  1659   by (cases "z \<ge> 0") (simp_all add: zdvd_int)
  1660 
  1661 lemma dvd_int_unfold_dvd_nat: "k dvd l \<longleftrightarrow> nat \<bar>k\<bar> dvd nat \<bar>l\<bar>"
  1662   by (simp add: dvd_int_iff [symmetric])
  1663 
  1664 lemma nat_dvd_iff: "nat z dvd m \<longleftrightarrow> (if 0 \<le> z then z dvd int m else m = 0)"
  1665   by (auto simp add: dvd_int_iff)
  1666 
  1667 lemma eq_nat_nat_iff: "0 \<le> z \<Longrightarrow> 0 \<le> z' \<Longrightarrow> nat z = nat z' \<longleftrightarrow> z = z'"
  1668   by (auto elim!: nonneg_eq_int)
  1669 
  1670 lemma nat_power_eq: "0 \<le> z \<Longrightarrow> nat (z ^ n) = nat z ^ n"
  1671   by (induct n) (simp_all add: nat_mult_distrib)
  1672 
  1673 lemma zdvd_imp_le: "z dvd n \<Longrightarrow> 0 < n \<Longrightarrow> z \<le> n"
  1674   for n z :: int
  1675   apply (cases n)
  1676    apply (auto simp add: dvd_int_iff)
  1677   apply (cases z)
  1678    apply (auto simp add: dvd_imp_le)
  1679   done
  1680 
  1681 lemma zdvd_period:
  1682   fixes a d :: int
  1683   assumes "a dvd d"
  1684   shows "a dvd (x + t) \<longleftrightarrow> a dvd ((x + c * d) + t)"
  1685     (is "?lhs \<longleftrightarrow> ?rhs")
  1686 proof -
  1687   from assms have "a dvd (x + t) \<longleftrightarrow> a dvd ((x + t) + c * d)"
  1688     by (simp add: dvd_add_left_iff)
  1689   then show ?thesis
  1690     by (simp add: ac_simps)
  1691 qed
  1692 
  1693 
  1694 subsection \<open>Finiteness of intervals\<close>
  1695 
  1696 lemma finite_interval_int1 [iff]: "finite {i :: int. a \<le> i \<and> i \<le> b}"
  1697 proof (cases "a \<le> b")
  1698   case True
  1699   then show ?thesis
  1700   proof (induct b rule: int_ge_induct)
  1701     case base
  1702     have "{i. a \<le> i \<and> i \<le> a} = {a}" by auto
  1703     then show ?case by simp
  1704   next
  1705     case (step b)
  1706     then have "{i. a \<le> i \<and> i \<le> b + 1} = {i. a \<le> i \<and> i \<le> b} \<union> {b + 1}" by auto
  1707     with step show ?case by simp
  1708   qed
  1709 next
  1710   case False
  1711   then show ?thesis
  1712     by (metis (lifting, no_types) Collect_empty_eq finite.emptyI order_trans)
  1713 qed
  1714 
  1715 lemma finite_interval_int2 [iff]: "finite {i :: int. a \<le> i \<and> i < b}"
  1716   by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
  1717 
  1718 lemma finite_interval_int3 [iff]: "finite {i :: int. a < i \<and> i \<le> b}"
  1719   by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
  1720 
  1721 lemma finite_interval_int4 [iff]: "finite {i :: int. a < i \<and> i < b}"
  1722   by (rule rev_finite_subset[OF finite_interval_int1[of "a" "b"]]) auto
  1723 
  1724 
  1725 subsection \<open>Configuration of the code generator\<close>
  1726 
  1727 text \<open>Constructors\<close>
  1728 
  1729 definition Pos :: "num \<Rightarrow> int"
  1730   where [simp, code_abbrev]: "Pos = numeral"
  1731 
  1732 definition Neg :: "num \<Rightarrow> int"
  1733   where [simp, code_abbrev]: "Neg n = - (Pos n)"
  1734 
  1735 code_datatype "0::int" Pos Neg
  1736 
  1737 
  1738 text \<open>Auxiliary operations.\<close>
  1739 
  1740 definition dup :: "int \<Rightarrow> int"
  1741   where [simp]: "dup k = k + k"
  1742 
  1743 lemma dup_code [code]:
  1744   "dup 0 = 0"
  1745   "dup (Pos n) = Pos (Num.Bit0 n)"
  1746   "dup (Neg n) = Neg (Num.Bit0 n)"
  1747   by (simp_all add: numeral_Bit0)
  1748 
  1749 definition sub :: "num \<Rightarrow> num \<Rightarrow> int"
  1750   where [simp]: "sub m n = numeral m - numeral n"
  1751 
  1752 lemma sub_code [code]:
  1753   "sub Num.One Num.One = 0"
  1754   "sub (Num.Bit0 m) Num.One = Pos (Num.BitM m)"
  1755   "sub (Num.Bit1 m) Num.One = Pos (Num.Bit0 m)"
  1756   "sub Num.One (Num.Bit0 n) = Neg (Num.BitM n)"
  1757   "sub Num.One (Num.Bit1 n) = Neg (Num.Bit0 n)"
  1758   "sub (Num.Bit0 m) (Num.Bit0 n) = dup (sub m n)"
  1759   "sub (Num.Bit1 m) (Num.Bit1 n) = dup (sub m n)"
  1760   "sub (Num.Bit1 m) (Num.Bit0 n) = dup (sub m n) + 1"
  1761   "sub (Num.Bit0 m) (Num.Bit1 n) = dup (sub m n) - 1"
  1762   by (simp_all only: sub_def dup_def numeral.simps Pos_def Neg_def numeral_BitM)
  1763 
  1764 text \<open>Implementations.\<close>
  1765 
  1766 lemma one_int_code [code]: "1 = Pos Num.One"
  1767   by simp
  1768 
  1769 lemma plus_int_code [code]:
  1770   "k + 0 = k"
  1771   "0 + l = l"
  1772   "Pos m + Pos n = Pos (m + n)"
  1773   "Pos m + Neg n = sub m n"
  1774   "Neg m + Pos n = sub n m"
  1775   "Neg m + Neg n = Neg (m + n)"
  1776   for k l :: int
  1777   by simp_all
  1778 
  1779 lemma uminus_int_code [code]:
  1780   "uminus 0 = (0::int)"
  1781   "uminus (Pos m) = Neg m"
  1782   "uminus (Neg m) = Pos m"
  1783   by simp_all
  1784 
  1785 lemma minus_int_code [code]:
  1786   "k - 0 = k"
  1787   "0 - l = uminus l"
  1788   "Pos m - Pos n = sub m n"
  1789   "Pos m - Neg n = Pos (m + n)"
  1790   "Neg m - Pos n = Neg (m + n)"
  1791   "Neg m - Neg n = sub n m"
  1792   for k l :: int
  1793   by simp_all
  1794 
  1795 lemma times_int_code [code]:
  1796   "k * 0 = 0"
  1797   "0 * l = 0"
  1798   "Pos m * Pos n = Pos (m * n)"
  1799   "Pos m * Neg n = Neg (m * n)"
  1800   "Neg m * Pos n = Neg (m * n)"
  1801   "Neg m * Neg n = Pos (m * n)"
  1802   for k l :: int
  1803   by simp_all
  1804 
  1805 instantiation int :: equal
  1806 begin
  1807 
  1808 definition "HOL.equal k l \<longleftrightarrow> k = (l::int)"
  1809 
  1810 instance
  1811   by standard (rule equal_int_def)
  1812 
  1813 end
  1814 
  1815 lemma equal_int_code [code]:
  1816   "HOL.equal 0 (0::int) \<longleftrightarrow> True"
  1817   "HOL.equal 0 (Pos l) \<longleftrightarrow> False"
  1818   "HOL.equal 0 (Neg l) \<longleftrightarrow> False"
  1819   "HOL.equal (Pos k) 0 \<longleftrightarrow> False"
  1820   "HOL.equal (Pos k) (Pos l) \<longleftrightarrow> HOL.equal k l"
  1821   "HOL.equal (Pos k) (Neg l) \<longleftrightarrow> False"
  1822   "HOL.equal (Neg k) 0 \<longleftrightarrow> False"
  1823   "HOL.equal (Neg k) (Pos l) \<longleftrightarrow> False"
  1824   "HOL.equal (Neg k) (Neg l) \<longleftrightarrow> HOL.equal k l"
  1825   by (auto simp add: equal)
  1826 
  1827 lemma equal_int_refl [code nbe]: "HOL.equal k k \<longleftrightarrow> True"
  1828   for k :: int
  1829   by (fact equal_refl)
  1830 
  1831 lemma less_eq_int_code [code]:
  1832   "0 \<le> (0::int) \<longleftrightarrow> True"
  1833   "0 \<le> Pos l \<longleftrightarrow> True"
  1834   "0 \<le> Neg l \<longleftrightarrow> False"
  1835   "Pos k \<le> 0 \<longleftrightarrow> False"
  1836   "Pos k \<le> Pos l \<longleftrightarrow> k \<le> l"
  1837   "Pos k \<le> Neg l \<longleftrightarrow> False"
  1838   "Neg k \<le> 0 \<longleftrightarrow> True"
  1839   "Neg k \<le> Pos l \<longleftrightarrow> True"
  1840   "Neg k \<le> Neg l \<longleftrightarrow> l \<le> k"
  1841   by simp_all
  1842 
  1843 lemma less_int_code [code]:
  1844   "0 < (0::int) \<longleftrightarrow> False"
  1845   "0 < Pos l \<longleftrightarrow> True"
  1846   "0 < Neg l \<longleftrightarrow> False"
  1847   "Pos k < 0 \<longleftrightarrow> False"
  1848   "Pos k < Pos l \<longleftrightarrow> k < l"
  1849   "Pos k < Neg l \<longleftrightarrow> False"
  1850   "Neg k < 0 \<longleftrightarrow> True"
  1851   "Neg k < Pos l \<longleftrightarrow> True"
  1852   "Neg k < Neg l \<longleftrightarrow> l < k"
  1853   by simp_all
  1854 
  1855 lemma nat_code [code]:
  1856   "nat (Int.Neg k) = 0"
  1857   "nat 0 = 0"
  1858   "nat (Int.Pos k) = nat_of_num k"
  1859   by (simp_all add: nat_of_num_numeral)
  1860 
  1861 lemma (in ring_1) of_int_code [code]:
  1862   "of_int (Int.Neg k) = - numeral k"
  1863   "of_int 0 = 0"
  1864   "of_int (Int.Pos k) = numeral k"
  1865   by simp_all
  1866 
  1867 
  1868 text \<open>Serializer setup.\<close>
  1869 
  1870 code_identifier
  1871   code_module Int \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1872 
  1873 quickcheck_params [default_type = int]
  1874 
  1875 hide_const (open) Pos Neg sub dup
  1876 
  1877 
  1878 text \<open>De-register \<open>int\<close> as a quotient type:\<close>
  1879 
  1880 lifting_update int.lifting
  1881 lifting_forget int.lifting
  1882 
  1883 end