src/Pure/library.ML
author wenzelm
Thu Apr 07 09:27:33 2005 +0200 (2005-04-07)
changeset 15670 963cd3f7976c
parent 15570 8d8c70b41bab
child 15696 1da4ce092c0b
permissions -rw-r--r--
invalidated former constructors None/OPTION to prevent accidental use as match-all patterns!
     1 (*  Title:      Pure/library.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Author:     Markus Wenzel, TU Munich
     5 
     6 Basic library: functions, options, pairs, booleans, lists, integers,
     7 rational numbers, strings, lists as sets, association lists, generic
     8 tables, balanced trees, orders, current directory, misc.
     9 *)
    10 
    11 infix |> |>> |>>> ~~ \ \\ ins ins_string ins_int orf andf prefix upto downto
    12   mem mem_int mem_string union union_int union_string inter inter_int
    13   inter_string subset subset_int subset_string;
    14 
    15 infix 3 oo ooo oooo;
    16 
    17 signature LIBRARY =
    18 sig
    19   (*functions*)
    20   val curry: ('a * 'b -> 'c) -> 'a -> 'b -> 'c
    21   val uncurry: ('a -> 'b -> 'c) -> 'a * 'b -> 'c
    22   val I: 'a -> 'a
    23   val K: 'a -> 'b -> 'a
    24   val |> : 'a * ('a -> 'b) -> 'b
    25   val |>> : ('a * 'b) * ('a -> 'c) -> 'c * 'b
    26   val |>>> : ('a * 'b) * ('a -> 'c * 'd) -> 'c * ('b * 'd)
    27   val apl: 'a * ('a * 'b -> 'c) -> 'b -> 'c
    28   val apr: ('a * 'b -> 'c) * 'b -> 'a -> 'c
    29   val funpow: int -> ('a -> 'a) -> 'a -> 'a
    30   val oo: ('a -> 'b) * ('c -> 'd -> 'a) -> 'c -> 'd -> 'b
    31   val ooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'a) -> 'c -> 'd -> 'e -> 'b
    32   val oooo: ('a -> 'b) * ('c -> 'd -> 'e -> 'f -> 'a) -> 'c -> 'd -> 'e -> 'f -> 'b
    33 
    34   (*stamps*)
    35   type stamp
    36   val stamp: unit -> stamp
    37 
    38   (*options*)
    39   val is_none: 'a option -> bool
    40 
    41   (*old options -- invalidated*)
    42   datatype invalid = None of invalid
    43   exception OPTION of invalid
    44 
    45   exception ERROR
    46   val try: ('a -> 'b) -> 'a -> 'b option
    47   val can: ('a -> 'b) -> 'a -> bool
    48   datatype 'a result = Result of 'a | Exn of exn
    49   val capture: ('a -> 'b) -> 'a -> 'b result
    50   val release: 'a result -> 'a
    51   val get_result: 'a result -> 'a option
    52   val get_exn: 'a result -> exn option
    53 
    54   (*pairs*)
    55   val pair: 'a -> 'b -> 'a * 'b
    56   val rpair: 'a -> 'b -> 'b * 'a
    57   val fst: 'a * 'b -> 'a
    58   val snd: 'a * 'b -> 'b
    59   val eq_fst: (''a * 'b) * (''a * 'c) -> bool
    60   val eq_snd: ('a * ''b) * ('c * ''b) -> bool
    61   val swap: 'a * 'b -> 'b * 'a
    62   val apfst: ('a -> 'b) -> 'a * 'c -> 'b * 'c
    63   val apsnd: ('a -> 'b) -> 'c * 'a -> 'c * 'b
    64   val pairself: ('a -> 'b) -> 'a * 'a -> 'b * 'b
    65 
    66   (*booleans*)
    67   val equal: ''a -> ''a -> bool
    68   val not_equal: ''a -> ''a -> bool
    69   val orf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    70   val andf: ('a -> bool) * ('a -> bool) -> 'a -> bool
    71   val exists: ('a -> bool) -> 'a list -> bool
    72   val forall: ('a -> bool) -> 'a list -> bool
    73   val set: bool ref -> bool
    74   val reset: bool ref -> bool
    75   val toggle: bool ref -> bool
    76   val change: 'a ref -> ('a -> 'a) -> unit
    77   val setmp: 'a ref -> 'a -> ('b -> 'c) -> 'b -> 'c
    78   val conditional: bool -> (unit -> unit) -> unit
    79 
    80   (*lists*)
    81   exception UnequalLengths
    82   val cons: 'a -> 'a list -> 'a list
    83   val single: 'a -> 'a list
    84   val append: 'a list -> 'a list -> 'a list
    85   val apply: ('a -> 'a) list -> 'a -> 'a
    86   val foldr1: ('a * 'a -> 'a) -> 'a list -> 'a
    87   val fold: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    88   val fold_rev: ('a -> 'b -> 'b) -> 'a list -> 'b -> 'b
    89   val foldl_map: ('a * 'b -> 'a * 'c) -> 'a * 'b list -> 'a * 'c list
    90   val foldln: ('a * int -> 'b -> 'b) -> 'a list -> 'b -> 'b
    91   val unflat: 'a list list -> 'b list -> 'b list list
    92   val splitAt: int * 'a list -> 'a list * 'a list
    93   val dropwhile: ('a -> bool) -> 'a list -> 'a list
    94   val map_nth_elem: int -> ('a -> 'a) -> 'a list -> 'a list
    95   val split_last: 'a list -> 'a list * 'a
    96   val nth_update: 'a -> int * 'a list -> 'a list
    97   val find_index: ('a -> bool) -> 'a list -> int
    98   val find_index_eq: ''a -> ''a list -> int
    99   val find_first: ('a -> bool) -> 'a list -> 'a option
   100   val get_first: ('a -> 'b option) -> 'a list -> 'b option
   101   val separate: 'a -> 'a list -> 'a list
   102   val replicate: int -> 'a -> 'a list
   103   val multiply: 'a list * 'a list list -> 'a list list
   104   val product: 'a list -> 'b list -> ('a * 'b) list
   105   val filter_out: ('a -> bool) -> 'a list -> 'a list
   106   val map2: ('a * 'b -> 'c) -> 'a list * 'b list -> 'c list
   107   val exists2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   108   val forall2: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   109   val seq2: ('a * 'b -> unit) -> 'a list * 'b list -> unit
   110   val ~~ : 'a list * 'b list -> ('a * 'b) list
   111   val split_list: ('a * 'b) list -> 'a list * 'b list
   112   val equal_lists: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   113   val prefix: ''a list * ''a list -> bool
   114   val take_prefix: ('a -> bool) -> 'a list -> 'a list * 'a list
   115   val take_suffix: ('a -> bool) -> 'a list -> 'a list * 'a list
   116   val prefixes1: 'a list -> 'a list list
   117   val suffixes1: 'a list -> 'a list list
   118 
   119   (*integers*)
   120   val gcd: int * int -> int
   121   val lcm: int * int -> int
   122   val inc: int ref -> int
   123   val dec: int ref -> int
   124   val upto: int * int -> int list
   125   val downto: int * int -> int list
   126   val downto0: int list * int -> bool
   127   val radixpand: int * int -> int list
   128   val radixstring: int * string * int -> string
   129   val string_of_int: int -> string
   130   val string_of_indexname: string * int -> string
   131   val read_radixint: int * string list -> int * string list
   132   val read_int: string list -> int * string list
   133   val oct_char: string -> string
   134 
   135   (*rational numbers*)
   136   type rat
   137   exception RAT of string
   138   val rep_rat: rat -> int * int
   139   val ratadd: rat * rat -> rat
   140   val ratmul: rat * rat -> rat
   141   val ratinv: rat -> rat
   142   val int_ratdiv: int * int -> rat
   143   val ratneg: rat -> rat
   144   val rat_of_int: int -> rat
   145 
   146   (*strings*)
   147   val nth_elem_string: int * string -> string
   148   val foldl_string: ('a * string -> 'a) -> 'a * string -> 'a
   149   val exists_string: (string -> bool) -> string -> bool
   150   val enclose: string -> string -> string -> string
   151   val unenclose: string -> string
   152   val quote: string -> string
   153   val space_implode: string -> string list -> string
   154   val commas: string list -> string
   155   val commas_quote: string list -> string
   156   val cat_lines: string list -> string
   157   val space_explode: string -> string -> string list
   158   val split_lines: string -> string list
   159   val prefix_lines: string -> string -> string
   160   val untabify: string list -> string list
   161   val suffix: string -> string -> string
   162   val unsuffix: string -> string -> string
   163   val unprefix: string -> string -> string
   164   val replicate_string: int -> string -> string
   165   val translate_string: (string -> string) -> string -> string
   166 
   167   (*lists as sets*)
   168   val mem: ''a * ''a list -> bool
   169   val mem_int: int * int list -> bool
   170   val mem_string: string * string list -> bool
   171   val gen_mem: ('a * 'b -> bool) -> 'a * 'b list -> bool
   172   val ins: ''a * ''a list -> ''a list
   173   val ins_int: int * int list -> int list
   174   val ins_string: string * string list -> string list
   175   val gen_ins: ('a * 'a -> bool) -> 'a * 'a list -> 'a list
   176   val union: ''a list * ''a list -> ''a list
   177   val union_int: int list * int list -> int list
   178   val union_string: string list * string list -> string list
   179   val gen_union: ('a * 'a -> bool) -> 'a list * 'a list -> 'a list
   180   val gen_inter: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   181   val inter: ''a list * ''a list -> ''a list
   182   val inter_int: int list * int list -> int list
   183   val inter_string: string list * string list -> string list
   184   val subset: ''a list * ''a list -> bool
   185   val subset_int: int list * int list -> bool
   186   val subset_string: string list * string list -> bool
   187   val eq_set: ''a list * ''a list -> bool
   188   val eq_set_string: string list * string list -> bool
   189   val gen_subset: ('a * 'b -> bool) -> 'a list * 'b list -> bool
   190   val \ : ''a list * ''a -> ''a list
   191   val \\ : ''a list * ''a list -> ''a list
   192   val gen_rem: ('a * 'b -> bool) -> 'a list * 'b -> 'a list
   193   val gen_rems: ('a * 'b -> bool) -> 'a list * 'b list -> 'a list
   194   val gen_distinct: ('a * 'a -> bool) -> 'a list -> 'a list
   195   val distinct: ''a list -> ''a list
   196   val findrep: ''a list -> ''a list
   197   val gen_duplicates: ('a * 'a -> bool) -> 'a list -> 'a list
   198   val duplicates: ''a list -> ''a list
   199 
   200   (*association lists*)
   201   val assoc: (''a * 'b) list * ''a -> 'b option
   202   val assoc_int: (int * 'a) list * int -> 'a option
   203   val assoc_string: (string * 'a) list * string -> 'a option
   204   val assoc_string_int: ((string * int) * 'a) list * (string * int) -> 'a option
   205   val assocs: (''a * 'b list) list -> ''a -> 'b list
   206   val assoc2: (''a * (''b * 'c) list) list * (''a * ''b) -> 'c option
   207   val gen_assoc: ('a * 'b -> bool) -> ('b * 'c) list * 'a -> 'c option
   208   val overwrite: (''a * 'b) list * (''a * 'b) -> (''a * 'b) list
   209   val gen_overwrite: ('a * 'a -> bool) -> ('a * 'b) list * ('a * 'b) -> ('a * 'b) list
   210 
   211   (*lists as tables*)
   212   val gen_merge_lists: ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   213   val gen_merge_lists': ('a * 'a -> bool) -> 'a list -> 'a list -> 'a list
   214   val merge_lists: ''a list -> ''a list -> ''a list
   215   val merge_lists': ''a list -> ''a list -> ''a list
   216   val merge_alists: (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   217   val merge_alists': (''a * 'b) list -> (''a * 'b) list -> (''a * 'b) list
   218 
   219   (*balanced trees*)
   220   exception Balance
   221   val fold_bal: ('a * 'a -> 'a) -> 'a list -> 'a
   222   val access_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> int -> 'a
   223   val accesses_bal: ('a -> 'a) * ('a -> 'a) * 'a -> int -> 'a list
   224 
   225   (*orders*)
   226   val rev_order: order -> order
   227   val make_ord: ('a * 'a -> bool) -> 'a * 'a -> order
   228   val int_ord: int * int -> order
   229   val string_ord: string * string -> order
   230   val prod_ord: ('a * 'b -> order) -> ('c * 'd -> order) -> ('a * 'c) * ('b * 'd) -> order
   231   val dict_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   232   val list_ord: ('a * 'b -> order) -> 'a list * 'b list -> order
   233   val sort: ('a * 'a -> order) -> 'a list -> 'a list
   234   val sort_strings: string list -> string list
   235   val sort_wrt: ('a -> string) -> 'a list -> 'a list
   236   val unique_strings: string list -> string list
   237 
   238   (*random numbers*)
   239   exception RANDOM
   240   val random: unit -> real
   241   val random_range: int -> int -> int
   242   val one_of: 'a list -> 'a
   243   val frequency: (int * 'a) list -> 'a
   244 
   245   (*current directory*)
   246   val cd: string -> unit
   247   val pwd: unit -> string
   248 
   249   (*misc*)
   250   val make_keylist: ('a -> 'b) -> 'a list -> ('a * 'b) list
   251   val keyfilter: ('a * ''b) list -> ''b -> 'a list
   252   val partition_eq: ('a * 'a -> bool) -> 'a list -> 'a list list
   253   val partition_list: (int -> 'a -> bool) -> int -> int -> 'a list -> 'a list list
   254   val gensym: string -> string
   255   val scanwords: (string -> bool) -> string list -> string list
   256 end;
   257 
   258 signature LIBRARY_CLOSED =
   259 sig
   260   include LIBRARY
   261 
   262   val the: 'a option -> 'a
   263   val if_none: 'a option -> 'a -> 'a
   264   val is_some: 'a option -> bool
   265   val apsome: ('a -> 'b) -> 'a option -> 'b option
   266 
   267   val rev_append: 'a list -> 'a list -> 'a list
   268   val foldl: ('a * 'b -> 'a) -> 'a * 'b list -> 'a
   269   val foldr: ('a * 'b -> 'b) -> 'a list * 'b -> 'b
   270   val take: int * 'a list -> 'a list
   271   val drop: int * 'a list -> 'a list
   272   val nth_elem: int * 'a list -> 'a
   273   val last_elem: 'a list -> 'a
   274   val flat: 'a list list -> 'a list
   275   val seq: ('a -> unit) -> 'a list -> unit
   276   val partition: ('a -> bool) -> 'a list -> 'a list * 'a list
   277   val filter: ('a -> bool) -> 'a list -> 'a list
   278   val mapfilter: ('a -> 'b option) -> 'a list -> 'b list
   279 end;
   280 
   281 structure Library: LIBRARY_CLOSED =
   282 struct
   283 
   284 
   285 (** functions **)
   286 
   287 (*handy combinators*)
   288 fun curry f x y = f (x, y);
   289 fun uncurry f (x, y) = f x y;
   290 fun I x = x;
   291 fun K x y = x;
   292 
   293 (*reverse apply*)
   294 fun (x |> f) = f x;
   295 fun ((x, y) |>> f) = (f x, y);
   296 fun ((x, y) |>>> f) = let val (x', z) = f x in (x', (y, z)) end;
   297 
   298 (*application of (infix) operator to its left or right argument*)
   299 fun apl (x, f) y = f (x, y);
   300 fun apr (f, y) x = f (x, y);
   301 
   302 (*function exponentiation: f(...(f x)...) with n applications of f*)
   303 fun funpow n f x =
   304   let fun rep (0, x) = x
   305         | rep (n, x) = rep (n - 1, f x)
   306   in rep (n, x) end;
   307 
   308 (*concatenation: 2 and 3 args*)
   309 fun (f oo g) x y = f (g x y);
   310 fun (f ooo g) x y z = f (g x y z);
   311 fun (f oooo g) x y z w = f (g x y z w);
   312 
   313 
   314 
   315 (** stamps **)
   316 
   317 type stamp = unit ref;
   318 val stamp: unit -> stamp = ref;
   319 
   320 
   321 
   322 (** options **)
   323 
   324 val the = valOf;
   325 fun if_none opt a = getOpt (opt, a);
   326 val is_some = isSome;
   327 fun is_none opt = not (isSome opt);
   328 val apsome = Option.map;
   329 
   330 (*invalidate former constructors to prevent accidental use as match-all patterns!*)
   331 datatype invalid = None of invalid;
   332 exception OPTION of invalid;
   333 
   334 
   335 (* exception handling *)
   336 
   337 exception ERROR;
   338 
   339 fun try f x = SOME (f x)
   340   handle Interrupt => raise Interrupt | ERROR => raise ERROR | _ => NONE;
   341 
   342 fun can f x = is_some (try f x);
   343 
   344 
   345 datatype 'a result =
   346   Result of 'a |
   347   Exn of exn;
   348 
   349 fun capture f x = Result (f x) handle e => Exn e;
   350 
   351 fun release (Result y) = y
   352   | release (Exn e) = raise e;
   353 
   354 fun get_result (Result x) = SOME x
   355   | get_result _ = NONE;
   356 
   357 fun get_exn (Exn exn) = SOME exn
   358   | get_exn _ = NONE;
   359 
   360 
   361 
   362 (** pairs **)
   363 
   364 fun pair x y = (x, y);
   365 fun rpair x y = (y, x);
   366 
   367 fun fst (x, y) = x;
   368 fun snd (x, y) = y;
   369 
   370 fun eq_fst ((x1, _), (x2, _)) = x1 = x2;
   371 fun eq_snd ((_, y1), (_, y2)) = y1 = y2;
   372 
   373 fun swap (x, y) = (y, x);
   374 
   375 (*apply function to components*)
   376 fun apfst f (x, y) = (f x, y);
   377 fun apsnd f (x, y) = (x, f y);
   378 fun pairself f (x, y) = (f x, f y);
   379 
   380 
   381 
   382 (** booleans **)
   383 
   384 (* equality *)
   385 
   386 fun equal x y = x = y;
   387 fun not_equal x y = x <> y;
   388 
   389 
   390 (* operators for combining predicates *)
   391 
   392 fun (p orf q) = fn x => p x orelse q x;
   393 fun (p andf q) = fn x => p x andalso q x;
   394 
   395 
   396 (* predicates on lists *)
   397 
   398 (*exists pred [x1, ..., xn] ===> pred x1 orelse ... orelse pred xn*)
   399 fun exists (pred: 'a -> bool) : 'a list -> bool =
   400   let fun boolf [] = false
   401         | boolf (x :: xs) = pred x orelse boolf xs
   402   in boolf end;
   403 
   404 (*forall pred [x1, ..., xn] ===> pred x1 andalso ... andalso pred xn*)
   405 fun forall (pred: 'a -> bool) : 'a list -> bool =
   406   let fun boolf [] = true
   407         | boolf (x :: xs) = pred x andalso boolf xs
   408   in boolf end;
   409 
   410 
   411 (* flags *)
   412 
   413 fun set flag = (flag := true; true);
   414 fun reset flag = (flag := false; false);
   415 fun toggle flag = (flag := not (! flag); ! flag);
   416 
   417 fun change r f = r := f (! r);
   418 
   419 (*temporarily set flag, handling exceptions*)
   420 fun setmp flag value f x =
   421   let
   422     val orig_value = ! flag;
   423     fun return y = (flag := orig_value; y);
   424   in
   425     flag := value;
   426     return (f x handle exn => (return (); raise exn))
   427   end;
   428 
   429 
   430 (* conditional execution *)
   431 
   432 fun conditional b f = if b then f () else ();
   433 
   434 
   435 
   436 (** lists **)
   437 
   438 exception UnequalLengths;
   439 
   440 fun cons x xs = x :: xs;
   441 fun single x = [x];
   442 
   443 fun append xs ys = xs @ ys;
   444 
   445 (* tail recursive version *)
   446 fun rev_append xs ys = List.revAppend(xs,ys);
   447 
   448 fun apply [] x = x
   449   | apply (f :: fs) x = apply fs (f x);
   450 
   451 
   452 (* fold *)
   453 
   454 (*the following versions of fold are designed to fit nicely with infixes*)
   455 
   456 (*  (op @) (e, [x1, ..., xn])  ===>  ((e @ x1) @ x2) ... @ xn
   457     for operators that associate to the left (TAIL RECURSIVE)*)
   458 fun foldl (f: 'a * 'b -> 'a) : 'a * 'b list -> 'a =
   459   let fun itl (e, [])  = e
   460         | itl (e, a::l) = itl (f(e, a), l)
   461   in  itl end;
   462 
   463 (*  (op @) ([x1, ..., xn], e)  ===>   x1 @ (x2 ... @ (xn @ e))
   464     for operators that associate to the right (not tail recursive)*)
   465 fun foldr f (l, e) =
   466   let fun itr [] = e
   467         | itr (a::l) = f(a, itr l)
   468   in  itr l  end;
   469 
   470 (*  (op @) [x1, ..., xn]  ===>   x1 @ (x2 ... @ (x[n-1] @ xn))
   471     for n > 0, operators that associate to the right (not tail recursive)*)
   472 fun foldr1 f l =
   473   let fun itr [x] = x
   474         | itr (x::l) = f(x, itr l)
   475   in  itr l  end;
   476 
   477 fun fold f xs y = foldl (fn (y', x) => f x y') (y, xs);
   478 fun fold_rev f xs y = foldr (fn (x, y') => f x y') (xs, y);
   479 
   480 fun foldl_map _ (x, []) = (x, [])
   481   | foldl_map f (x, y :: ys) =
   482       let
   483         val (x', y') = f (x, y);
   484         val (x'', ys') = foldl_map f (x', ys);
   485       in (x'', y' :: ys') end;
   486 
   487 fun foldln f xs e = fst (foldl (fn ((e,i), x) => (f (x,i) e, i+1)) ((e,1),xs));
   488 
   489 (* basic list functions *)
   490 
   491 (*take the first n elements from a list*)
   492 fun take (n, []) = []
   493   | take (n, x :: xs) =
   494       if n > 0 then x :: take (n - 1, xs) else [];
   495 
   496 (*drop the first n elements from a list*)
   497 fun drop (n, []) = []
   498   | drop (n, x :: xs) =
   499       if n > 0 then drop (n - 1, xs) else x :: xs;
   500 
   501 fun splitAt(n,[]) = ([],[])
   502   | splitAt(n,xs as x::ys) =
   503       if n>0 then let val (ps,qs) = splitAt(n-1,ys) in (x::ps,qs) end
   504       else ([],xs)
   505 
   506 fun dropwhile P [] = []
   507   | dropwhile P (ys as x::xs) = if P x then dropwhile P xs else ys;
   508 
   509 (*return nth element of a list, where 0 designates the first element;
   510   raise EXCEPTION if list too short*)
   511 fun nth_elem (i,xs) = List.nth(xs,i);
   512 
   513 fun map_nth_elem 0 f (x :: xs) = f x :: xs
   514   | map_nth_elem n f (x :: xs) = x :: map_nth_elem (n - 1) f xs
   515   | map_nth_elem _ _ [] = raise Subscript;
   516 
   517 (*last element of a list*)
   518 val last_elem = List.last;
   519 
   520 (*rear decomposition*)
   521 fun split_last [] = raise Empty
   522   | split_last [x] = ([], x)
   523   | split_last (x :: xs) = apfst (cons x) (split_last xs);
   524 
   525 (*update nth element*)
   526 fun nth_update x n_xs =
   527     (case splitAt n_xs of
   528       (_,[]) => raise Subscript
   529     | (prfx, _ :: sffx') => prfx @ (x :: sffx'))
   530 
   531 (*find the position of an element in a list*)
   532 fun find_index pred =
   533   let fun find _ [] = ~1
   534         | find n (x :: xs) = if pred x then n else find (n + 1) xs;
   535   in find 0 end;
   536 
   537 fun find_index_eq x = find_index (equal x);
   538 
   539 (*find first element satisfying predicate*)
   540 fun find_first _ [] = NONE
   541   | find_first pred (x :: xs) =
   542       if pred x then SOME x else find_first pred xs;
   543 
   544 (*get first element by lookup function*)
   545 fun get_first _ [] = NONE
   546   | get_first f (x :: xs) =
   547       (case f x of
   548         NONE => get_first f xs
   549       | some => some);
   550 
   551 (*flatten a list of lists to a list*)
   552 val flat = List.concat;
   553 
   554 fun unflat (xs :: xss) ys =
   555       let val (ps,qs) = splitAt(length xs,ys)
   556       in ps :: unflat xss qs end
   557   | unflat [] [] = []
   558   | unflat _ _ = raise UnequalLengths;
   559 
   560 (*like Lisp's MAPC -- seq proc [x1, ..., xn] evaluates
   561   (proc x1; ...; proc xn) for side effects*)
   562 val seq = List.app;
   563 
   564 (*separate s [x1, x2, ..., xn]  ===>  [x1, s, x2, s, ..., s, xn]*)
   565 fun separate s (x :: (xs as _ :: _)) = x :: s :: separate s xs
   566   | separate _ xs = xs;
   567 
   568 (*make the list [x, x, ..., x] of length n*)
   569 fun replicate n (x: 'a) : 'a list =
   570   let fun rep (0, xs) = xs
   571         | rep (n, xs) = rep (n - 1, x :: xs)
   572   in
   573     if n < 0 then raise Subscript
   574     else rep (n, [])
   575   end;
   576 
   577 fun translate_string f = String.translate (f o String.str);
   578 
   579 (*multiply [a, b, c, ...] * [xs, ys, zs, ...]*)
   580 fun multiply ([], _) = []
   581   | multiply (x :: xs, yss) = map (cons x) yss @ multiply (xs, yss);
   582 
   583 (*direct product*)
   584 fun product _ [] = []
   585   | product [] _ = []
   586   | product (x :: xs) ys = map (pair x) ys @ product xs ys;
   587 
   588 
   589 (* filter *)
   590 
   591 (*copy the list preserving elements that satisfy the predicate*)
   592 val filter = List.filter;
   593 fun filter_out f = filter (not o f);
   594 val mapfilter = List.mapPartial;
   595 
   596 
   597 (* lists of pairs *)
   598 
   599 exception UnequalLengths;
   600 
   601 fun map2 _ ([], []) = []
   602   | map2 f (x :: xs, y :: ys) = (f (x, y) :: map2 f (xs, ys))
   603   | map2 _ _ = raise UnequalLengths;
   604 
   605 fun exists2 _ ([], []) = false
   606   | exists2 pred (x :: xs, y :: ys) = pred (x, y) orelse exists2 pred (xs, ys)
   607   | exists2 _ _ = raise UnequalLengths;
   608 
   609 fun forall2 _ ([], []) = true
   610   | forall2 pred (x :: xs, y :: ys) = pred (x, y) andalso forall2 pred (xs, ys)
   611   | forall2 _ _ = raise UnequalLengths;
   612 
   613 fun seq2 _ ([], []) = ()
   614   | seq2 f (x :: xs, y :: ys) = (f (x, y); seq2 f (xs, ys))
   615   | seq2 _ _ = raise UnequalLengths;
   616 
   617 (*combine two lists forming a list of pairs:
   618   [x1, ..., xn] ~~ [y1, ..., yn]  ===>  [(x1, y1), ..., (xn, yn)]*)
   619 fun [] ~~ [] = []
   620   | (x :: xs) ~~ (y :: ys) = (x, y) :: (xs ~~ ys)
   621   | _ ~~ _ = raise UnequalLengths;
   622 
   623 (*inverse of ~~; the old 'split':
   624   [(x1, y1), ..., (xn, yn)]  ===>  ([x1, ..., xn], [y1, ..., yn])*)
   625 val split_list = ListPair.unzip;
   626 
   627 fun equal_lists eq (xs, ys) = length xs = length ys andalso forall2 eq (xs, ys);
   628 
   629 
   630 (* prefixes, suffixes *)
   631 
   632 fun [] prefix _ = true
   633   | (x :: xs) prefix (y :: ys) = x = y andalso (xs prefix ys)
   634   | _ prefix _ = false;
   635 
   636 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., x(i-1)], [xi, ..., xn])
   637    where xi is the first element that does not satisfy the predicate*)
   638 fun take_prefix (pred : 'a -> bool)  (xs: 'a list) : 'a list * 'a list =
   639   let fun take (rxs, []) = (rev rxs, [])
   640         | take (rxs, x :: xs) =
   641             if  pred x  then  take(x :: rxs, xs)  else  (rev rxs, x :: xs)
   642   in  take([], xs)  end;
   643 
   644 (* [x1, ..., xi, ..., xn]  --->  ([x1, ..., xi], [x(i+1), ..., xn])
   645    where xi is the last element that does not satisfy the predicate*)
   646 fun take_suffix _ [] = ([], [])
   647   | take_suffix pred (x :: xs) =
   648       (case take_suffix pred xs of
   649         ([], sffx) => if pred x then ([], x :: sffx) else ([x], sffx)
   650       | (prfx, sffx) => (x :: prfx, sffx));
   651 
   652 fun prefixes1 [] = []
   653   | prefixes1 (x :: xs) = map (cons x) ([] :: prefixes1 xs);
   654 
   655 fun suffixes1 xs = map rev (prefixes1 (rev xs));
   656 
   657 
   658 
   659 (** integers **)
   660 
   661 fun gcd(x,y) =
   662   let fun gxd x y =
   663     if y = 0 then x else gxd y (x mod y)
   664   in if x < y then gxd y x else gxd x y end;
   665 
   666 fun lcm(x,y) = (x * y) div gcd(x,y);
   667 
   668 fun inc i = (i := ! i + 1; ! i);
   669 fun dec i = (i := ! i - 1; ! i);
   670 
   671 
   672 (* lists of integers *)
   673 
   674 (*make the list [from, from + 1, ..., to]*)
   675 fun (from upto to) =
   676   if from > to then [] else from :: ((from + 1) upto to);
   677 
   678 (*make the list [from, from - 1, ..., to]*)
   679 fun (from downto to) =
   680   if from < to then [] else from :: ((from - 1) downto to);
   681 
   682 (*predicate: downto0 (is, n) <=> is = [n, n - 1, ..., 0]*)
   683 fun downto0 (i :: is, n) = i = n andalso downto0 (is, n - 1)
   684   | downto0 ([], n) = n = ~1;
   685 
   686 
   687 (* convert integers to strings *)
   688 
   689 (*expand the number in the given base;
   690   example: radixpand (2, 8) gives [1, 0, 0, 0]*)
   691 fun radixpand (base, num) : int list =
   692   let
   693     fun radix (n, tail) =
   694       if n < base then n :: tail
   695       else radix (n div base, (n mod base) :: tail)
   696   in radix (num, []) end;
   697 
   698 (*expands a number into a string of characters starting from "zerochar";
   699   example: radixstring (2, "0", 8) gives "1000"*)
   700 fun radixstring (base, zerochar, num) =
   701   let val offset = ord zerochar;
   702       fun chrof n = chr (offset + n)
   703   in implode (map chrof (radixpand (base, num))) end;
   704 
   705 
   706 val string_of_int = Int.toString;
   707 
   708 fun string_of_indexname (a,0) = a
   709   | string_of_indexname (a,i) = a ^ "_" ^ Int.toString i;
   710 
   711 
   712 (* read integers *)
   713 
   714 fun read_radixint (radix: int, cs) : int * string list =
   715   let val zero = ord"0"
   716       val limit = zero+radix
   717       fun scan (num,[]) = (num,[])
   718         | scan (num, c::cs) =
   719               if  zero <= ord c  andalso  ord c < limit
   720               then scan(radix*num + ord c - zero, cs)
   721               else (num, c::cs)
   722   in  scan(0,cs)  end;
   723 
   724 fun read_int cs = read_radixint (10, cs);
   725 
   726 fun oct_char s = chr (#1 (read_radixint (8, explode s)));
   727 
   728 
   729 
   730 (** strings **)
   731 
   732 (*functions tuned for strings, avoiding explode*)
   733 
   734 fun nth_elem_string (i, str) =
   735   (case try String.substring (str, i, 1) of
   736     SOME s => s
   737   | NONE => raise Subscript);
   738 
   739 fun foldl_string f (x0, str) =
   740   let
   741     val n = size str;
   742     fun fold (x, i) =
   743       if i < n then fold (f (x, String.substring (str, i, 1)), i + 1) else x;
   744   in fold (x0, 0) end;
   745 
   746 fun exists_string pred str =
   747   let
   748     val n = size str;
   749     fun ex i = i < n andalso (pred (String.substring (str, i, 1)) orelse ex (i + 1));
   750   in ex 0 end;
   751 
   752 (*enclose in brackets*)
   753 fun enclose lpar rpar str = lpar ^ str ^ rpar;
   754 fun unenclose str = String.substring (str, 1, size str - 2);
   755 
   756 (*simple quoting (does not escape special chars)*)
   757 val quote = enclose "\"" "\"";
   758 
   759 (*space_implode "..." (explode "hello") = "h...e...l...l...o"*)
   760 fun space_implode a bs = implode (separate a bs);
   761 
   762 val commas = space_implode ", ";
   763 val commas_quote = commas o map quote;
   764 
   765 (*concatenate messages, one per line, into a string*)
   766 val cat_lines = space_implode "\n";
   767 
   768 (*space_explode "." "h.e..l.lo" = ["h", "e", "", "l", "lo"]*)
   769 fun space_explode _ "" = []
   770   | space_explode sep str =
   771       let
   772         fun expl chs =
   773           (case take_prefix (not_equal sep) chs of
   774             (cs, []) => [implode cs]
   775           | (cs, _ :: cs') => implode cs :: expl cs');
   776       in expl (explode str) end;
   777 
   778 val split_lines = space_explode "\n";
   779 
   780 fun prefix_lines "" txt = txt
   781   | prefix_lines prfx txt = txt |> split_lines |> map (fn s => prfx ^ s) |> cat_lines;
   782 
   783 (*untabify*)
   784 fun untabify chs =
   785   let
   786     val tab_width = 8;
   787 
   788     fun untab (_, "\n") = (0, ["\n"])
   789       | untab (pos, "\t") =
   790           let val d = tab_width - (pos mod tab_width) in (pos + d, replicate d " ") end
   791       | untab (pos, c) = (pos + 1, [c]);
   792   in
   793     if not (exists (equal "\t") chs) then chs
   794     else flat (#2 (foldl_map untab (0, chs)))
   795   end;
   796 
   797 (*append suffix*)
   798 fun suffix sfx s = s ^ sfx;
   799 
   800 (*remove suffix*)
   801 fun unsuffix sfx s =
   802   let
   803     val cs = explode s;
   804     val prfx_len = size s - size sfx;
   805   in
   806     if prfx_len >= 0 andalso implode (drop (prfx_len, cs)) = sfx then
   807       implode (take (prfx_len, cs))
   808     else raise Fail "unsuffix"
   809   end;
   810 
   811 (*remove prefix*)
   812 fun unprefix prfx s =
   813   let val (prfx', sfx) = splitAt (size prfx, explode s)
   814   in
   815     if implode prfx' = prfx then implode sfx
   816     else raise Fail "unprefix"
   817   end;
   818 
   819 fun replicate_string 0 _ = ""
   820   | replicate_string 1 a = a
   821   | replicate_string k a =
   822       if k mod 2 = 0 then replicate_string (k div 2) (a ^ a)
   823       else replicate_string (k div 2) (a ^ a) ^ a;
   824 
   825 
   826 
   827 (** lists as sets **)
   828 
   829 (*membership in a list*)
   830 fun x mem [] = false
   831   | x mem (y :: ys) = x = y orelse x mem ys;
   832 
   833 (*membership in a list, optimized version for ints*)
   834 fun (x:int) mem_int [] = false
   835   | x mem_int (y :: ys) = x = y orelse x mem_int ys;
   836 
   837 (*membership in a list, optimized version for strings*)
   838 fun (x:string) mem_string [] = false
   839   | x mem_string (y :: ys) = x = y orelse x mem_string ys;
   840 
   841 (*generalized membership test*)
   842 fun gen_mem eq (x, []) = false
   843   | gen_mem eq (x, y :: ys) = eq (x, y) orelse gen_mem eq (x, ys);
   844 
   845 
   846 (*insertion into list if not already there*)
   847 fun (x ins xs) = if x mem xs then xs else x :: xs;
   848 
   849 (*insertion into list, optimized version for ints*)
   850 fun (x ins_int xs) = if x mem_int xs then xs else x :: xs;
   851 
   852 (*insertion into list, optimized version for strings*)
   853 fun (x ins_string xs) = if x mem_string xs then xs else x :: xs;
   854 
   855 (*generalized insertion*)
   856 fun gen_ins eq (x, xs) = if gen_mem eq (x, xs) then xs else x :: xs;
   857 
   858 
   859 (*union of sets represented as lists: no repetitions*)
   860 fun xs union [] = xs
   861   | [] union ys = ys
   862   | (x :: xs) union ys = xs union (x ins ys);
   863 
   864 (*union of sets, optimized version for ints*)
   865 fun (xs:int list) union_int [] = xs
   866   | [] union_int ys = ys
   867   | (x :: xs) union_int ys = xs union_int (x ins_int ys);
   868 
   869 (*union of sets, optimized version for strings*)
   870 fun (xs:string list) union_string [] = xs
   871   | [] union_string ys = ys
   872   | (x :: xs) union_string ys = xs union_string (x ins_string ys);
   873 
   874 (*generalized union*)
   875 fun gen_union eq (xs, []) = xs
   876   | gen_union eq ([], ys) = ys
   877   | gen_union eq (x :: xs, ys) = gen_union eq (xs, gen_ins eq (x, ys));
   878 
   879 
   880 (*intersection*)
   881 fun [] inter ys = []
   882   | (x :: xs) inter ys =
   883       if x mem ys then x :: (xs inter ys) else xs inter ys;
   884 
   885 (*intersection, optimized version for ints*)
   886 fun ([]:int list) inter_int ys = []
   887   | (x :: xs) inter_int ys =
   888       if x mem_int ys then x :: (xs inter_int ys) else xs inter_int ys;
   889 
   890 (*intersection, optimized version for strings *)
   891 fun ([]:string list) inter_string ys = []
   892   | (x :: xs) inter_string ys =
   893       if x mem_string ys then x :: (xs inter_string ys) else xs inter_string ys;
   894 
   895 (*generalized intersection*)
   896 fun gen_inter eq ([], ys) = []
   897   | gen_inter eq (x::xs, ys) =
   898       if gen_mem eq (x,ys) then x :: gen_inter eq (xs, ys)
   899                            else      gen_inter eq (xs, ys);
   900 
   901 
   902 (*subset*)
   903 fun [] subset ys = true
   904   | (x :: xs) subset ys = x mem ys andalso xs subset ys;
   905 
   906 (*subset, optimized version for ints*)
   907 fun ([]:int list) subset_int ys = true
   908   | (x :: xs) subset_int ys = x mem_int ys andalso xs subset_int ys;
   909 
   910 (*subset, optimized version for strings*)
   911 fun ([]:string list) subset_string ys = true
   912   | (x :: xs) subset_string ys = x mem_string ys andalso xs subset_string ys;
   913 
   914 (*set equality*)
   915 fun eq_set (xs, ys) =
   916   xs = ys orelse (xs subset ys andalso ys subset xs);
   917 
   918 (*set equality for strings*)
   919 fun eq_set_string ((xs:string list), ys) =
   920   xs = ys orelse (xs subset_string ys andalso ys subset_string xs);
   921 
   922 fun gen_subset eq (xs, ys) = forall (fn x => gen_mem eq (x, ys)) xs;
   923 
   924 
   925 (*removing an element from a list WITHOUT duplicates*)
   926 fun (y :: ys) \ x = if x = y then ys else y :: (ys \ x)
   927   | [] \ x = [];
   928 
   929 fun ys \\ xs = foldl (op \) (ys,xs);
   930 
   931 (*removing an element from a list -- possibly WITH duplicates*)
   932 fun gen_rem eq (xs, y) = filter_out (fn x => eq (x, y)) xs;
   933 fun gen_rems eq (xs, ys) = filter_out (fn x => gen_mem eq (x, ys)) xs;
   934 
   935 
   936 (*makes a list of the distinct members of the input; preserves order, takes
   937   first of equal elements*)
   938 fun gen_distinct eq lst =
   939   let
   940     val memb = gen_mem eq;
   941 
   942     fun dist (rev_seen, []) = rev rev_seen
   943       | dist (rev_seen, x :: xs) =
   944           if memb (x, rev_seen) then dist (rev_seen, xs)
   945           else dist (x :: rev_seen, xs);
   946   in
   947     dist ([], lst)
   948   end;
   949 
   950 fun distinct l = gen_distinct (op =) l;
   951 
   952 
   953 (*returns the tail beginning with the first repeated element, or []*)
   954 fun findrep [] = []
   955   | findrep (x :: xs) = if x mem xs then x :: xs else findrep xs;
   956 
   957 
   958 (*returns a list containing all repeated elements exactly once; preserves
   959   order, takes first of equal elements*)
   960 fun gen_duplicates eq lst =
   961   let
   962     val memb = gen_mem eq;
   963 
   964     fun dups (rev_dups, []) = rev rev_dups
   965       | dups (rev_dups, x :: xs) =
   966           if memb (x, rev_dups) orelse not (memb (x, xs)) then
   967             dups (rev_dups, xs)
   968           else dups (x :: rev_dups, xs);
   969   in
   970     dups ([], lst)
   971   end;
   972 
   973 fun duplicates l = gen_duplicates (op =) l;
   974 
   975 
   976 
   977 (** association lists **)
   978 
   979 (*association list lookup*)
   980 fun assoc ([], key) = NONE
   981   | assoc ((keyi, xi) :: pairs, key) =
   982       if key = keyi then SOME xi else assoc (pairs, key);
   983 
   984 (*association list lookup, optimized version for ints*)
   985 fun assoc_int ([], (key:int)) = NONE
   986   | assoc_int ((keyi, xi) :: pairs, key) =
   987       if key = keyi then SOME xi else assoc_int (pairs, key);
   988 
   989 (*association list lookup, optimized version for strings*)
   990 fun assoc_string ([], (key:string)) = NONE
   991   | assoc_string ((keyi, xi) :: pairs, key) =
   992       if key = keyi then SOME xi else assoc_string (pairs, key);
   993 
   994 (*association list lookup, optimized version for string*ints*)
   995 fun assoc_string_int ([], (key:string*int)) = NONE
   996   | assoc_string_int ((keyi, xi) :: pairs, key) =
   997       if key = keyi then SOME xi else assoc_string_int (pairs, key);
   998 
   999 fun assocs ps x =
  1000   (case assoc (ps, x) of
  1001     NONE => []
  1002   | SOME ys => ys);
  1003 
  1004 (*two-fold association list lookup*)
  1005 fun assoc2 (aal, (key1, key2)) =
  1006   (case assoc (aal, key1) of
  1007     SOME al => assoc (al, key2)
  1008   | NONE => NONE);
  1009 
  1010 (*generalized association list lookup*)
  1011 fun gen_assoc eq ([], key) = NONE
  1012   | gen_assoc eq ((keyi, xi) :: pairs, key) =
  1013       if eq (key, keyi) then SOME xi else gen_assoc eq (pairs, key);
  1014 
  1015 (*association list update*)
  1016 fun overwrite (al, p as (key, _)) =
  1017   let fun over ((q as (keyi, _)) :: pairs) =
  1018             if keyi = key then p :: pairs else q :: (over pairs)
  1019         | over [] = [p]
  1020   in over al end;
  1021 
  1022 fun gen_overwrite eq (al, p as (key, _)) =
  1023   let fun over ((q as (keyi, _)) :: pairs) =
  1024             if eq (keyi, key) then p :: pairs else q :: (over pairs)
  1025         | over [] = [p]
  1026   in over al end;
  1027 
  1028 
  1029 (* lists as tables *)
  1030 
  1031 fun gen_merge_lists _ xs [] = xs
  1032   | gen_merge_lists _ [] ys = ys
  1033   | gen_merge_lists eq xs ys = xs @ gen_rems eq (ys, xs);
  1034 
  1035 fun gen_merge_lists' _ xs [] = xs
  1036   | gen_merge_lists' _ [] ys = ys
  1037   | gen_merge_lists' eq xs ys = gen_rems eq (ys, xs) @ xs;
  1038 
  1039 fun merge_lists xs ys = gen_merge_lists (op =) xs ys;
  1040 fun merge_lists' xs ys = gen_merge_lists' (op =) xs ys;
  1041 fun merge_alists al = gen_merge_lists eq_fst al;
  1042 fun merge_alists' al = gen_merge_lists' eq_fst al;
  1043 
  1044 
  1045 
  1046 (** balanced trees **)
  1047 
  1048 exception Balance;      (*indicates non-positive argument to balancing fun*)
  1049 
  1050 (*balanced folding; avoids deep nesting*)
  1051 fun fold_bal f [x] = x
  1052   | fold_bal f [] = raise Balance
  1053   | fold_bal f xs =
  1054       let val (ps,qs) = splitAt(length xs div 2, xs)
  1055       in  f (fold_bal f ps, fold_bal f qs)  end;
  1056 
  1057 (*construct something of the form f(...g(...(x)...)) for balanced access*)
  1058 fun access_bal (f, g, x) n i =
  1059   let fun acc n i =     (*1<=i<=n*)
  1060           if n=1 then x else
  1061           let val n2 = n div 2
  1062           in  if i<=n2 then f (acc n2 i)
  1063                        else g (acc (n-n2) (i-n2))
  1064           end
  1065   in  if 1<=i andalso i<=n then acc n i else raise Balance  end;
  1066 
  1067 (*construct ALL such accesses; could try harder to share recursive calls!*)
  1068 fun accesses_bal (f, g, x) n =
  1069   let fun acc n =
  1070           if n=1 then [x] else
  1071           let val n2 = n div 2
  1072               val acc2 = acc n2
  1073           in  if n-n2=n2 then map f acc2 @ map g acc2
  1074                          else map f acc2 @ map g (acc (n-n2)) end
  1075   in  if 1<=n then acc n else raise Balance  end;
  1076 
  1077 
  1078 
  1079 (** orders **)
  1080 
  1081 fun rev_order LESS = GREATER
  1082   | rev_order EQUAL = EQUAL
  1083   | rev_order GREATER = LESS;
  1084 
  1085 (*assume rel is a linear strict order*)
  1086 fun make_ord rel (x, y) =
  1087   if rel (x, y) then LESS
  1088   else if rel (y, x) then GREATER
  1089   else EQUAL;
  1090 
  1091 val int_ord = Int.compare;
  1092 val string_ord = String.compare;
  1093 
  1094 (*lexicographic product*)
  1095 fun prod_ord a_ord b_ord ((x, y), (x', y')) =
  1096   (case a_ord (x, x') of EQUAL => b_ord (y, y') | ord => ord);
  1097 
  1098 (*dictionary order -- in general NOT well-founded!*)
  1099 fun dict_ord _ ([], []) = EQUAL
  1100   | dict_ord _ ([], _ :: _) = LESS
  1101   | dict_ord _ (_ :: _, []) = GREATER
  1102   | dict_ord elem_ord (x :: xs, y :: ys) =
  1103       (case elem_ord (x, y) of EQUAL => dict_ord elem_ord (xs, ys) | ord => ord);
  1104 
  1105 (*lexicographic product of lists*)
  1106 fun list_ord elem_ord (xs, ys) =
  1107   prod_ord int_ord (dict_ord elem_ord) ((length xs, xs), (length ys, ys));
  1108 
  1109 
  1110 (* sorting *)
  1111 
  1112 (*quicksort (stable, i.e. does not reorder equal elements)*)
  1113 fun sort ord =
  1114   let
  1115     fun qsort xs =
  1116       let val len = length xs in
  1117         if len <= 1 then xs
  1118         else
  1119           let val (lts, eqs, gts) = part (nth_elem (len div 2, xs)) xs in
  1120             qsort lts @ eqs @ qsort gts
  1121           end
  1122       end
  1123     and part _ [] = ([], [], [])
  1124       | part pivot (x :: xs) = add (ord (x, pivot)) x (part pivot xs)
  1125     and add LESS x (lts, eqs, gts) = (x :: lts, eqs, gts)
  1126       | add EQUAL x (lts, eqs, gts) = (lts, x :: eqs, gts)
  1127       | add GREATER x (lts, eqs, gts) = (lts, eqs, x :: gts);
  1128   in qsort end;
  1129 
  1130 (*sort strings*)
  1131 val sort_strings = sort string_ord;
  1132 fun sort_wrt sel xs = sort (string_ord o pairself sel) xs;
  1133 
  1134 fun unique_strings ([]: string list) = []
  1135   | unique_strings [x] = [x]
  1136   | unique_strings (x :: y :: ys) =
  1137       if x = y then unique_strings (y :: ys)
  1138       else x :: unique_strings (y :: ys);
  1139 
  1140 
  1141 (** random numbers **)
  1142 
  1143 exception RANDOM;
  1144 
  1145 fun rmod x y = x - y * Real.realFloor (x / y);
  1146 
  1147 local
  1148   val a = 16807.0;
  1149   val m = 2147483647.0;
  1150   val random_seed = ref 1.0;
  1151 in
  1152 
  1153 fun random () =
  1154   let val r = rmod (a * !random_seed) m
  1155   in (random_seed := r; r) end;
  1156 
  1157 end;
  1158 
  1159 fun random_range l h =
  1160   if h < l orelse l < 0 then raise RANDOM
  1161   else l + Real.floor (rmod (random ()) (real (h - l + 1)));
  1162 
  1163 fun one_of xs = nth_elem (random_range 0 (length xs - 1), xs);
  1164 
  1165 fun frequency xs =
  1166   let
  1167     val sum = foldl op + (0, map fst xs);
  1168     fun pick n ((k, x) :: xs) =
  1169       if n <= k then x else pick (n - k) xs
  1170   in pick (random_range 1 sum) xs end;
  1171 
  1172 
  1173 (** current directory **)
  1174 
  1175 val cd = OS.FileSys.chDir;
  1176 val pwd = OS.FileSys.getDir;
  1177 
  1178 
  1179 
  1180 (** rational numbers **)
  1181 
  1182 datatype rat = Rat of bool * int * int
  1183 
  1184 exception RAT of string;
  1185 
  1186 fun rep_rat(Rat(a,p,q)) = (if a then p else ~p,q)
  1187 
  1188 fun ratnorm(a,p,q) = if p=0 then Rat(a,0,1) else
  1189   let val absp = abs p
  1190       val m = gcd(absp,q)
  1191   in Rat(a = (0 <= p), absp div m, q div m) end;
  1192 
  1193 fun ratadd(Rat(a,p,q),Rat(b,r,s)) =
  1194   let val den = lcm(q,s)
  1195       val p = p*(den div q) and r = r*(den div s)
  1196       val num = (if a then p else ~p) + (if b then r else ~r)
  1197   in ratnorm(true,num,den) end;
  1198 
  1199 fun ratmul(Rat(a,p,q),Rat(b,r,s)) = ratnorm(a=b,p*r,q*s)
  1200 
  1201 fun ratinv(Rat(a,p,q)) = if p=0 then raise RAT "ratinv" else Rat(a,q,p)
  1202 
  1203 fun int_ratdiv(p,q) =
  1204   if q=0 then raise RAT "int_ratdiv" else ratnorm(0<=q, p, abs q)
  1205 
  1206 fun ratneg(Rat(b,p,q)) = Rat(not b,p,q);
  1207 
  1208 fun rat_of_int i = if i < 0 then Rat(false,abs i,1) else Rat(true,i,1);
  1209 
  1210 
  1211 (** misc **)
  1212 
  1213 (*use the keyfun to make a list of (x, key) pairs*)
  1214 fun make_keylist (keyfun: 'a->'b) : 'a list -> ('a * 'b) list =
  1215   let fun keypair x = (x, keyfun x)
  1216   in map keypair end;
  1217 
  1218 (*given a list of (x, key) pairs and a searchkey
  1219   return the list of xs from each pair whose key equals searchkey*)
  1220 fun keyfilter [] searchkey = []
  1221   | keyfilter ((x, key) :: pairs) searchkey =
  1222       if key = searchkey then x :: keyfilter pairs searchkey
  1223       else keyfilter pairs searchkey;
  1224 
  1225 
  1226 (*Partition list into elements that satisfy predicate and those that don't.
  1227   Preserves order of elements in both lists.*)
  1228 val partition = List.partition;
  1229 
  1230 
  1231 fun partition_eq (eq:'a * 'a -> bool) =
  1232     let fun part [] = []
  1233           | part (x::ys) = let val (xs, xs') = partition (apl(x, eq)) ys
  1234                            in (x::xs)::(part xs') end
  1235     in part end;
  1236 
  1237 
  1238 (*Partition a list into buckets  [ bi, b(i+1), ..., bj ]
  1239    putting x in bk if p(k)(x) holds.  Preserve order of elements if possible.*)
  1240 fun partition_list p i j =
  1241   let fun part k xs =
  1242             if k>j then
  1243               (case xs of [] => []
  1244                          | _ => raise Fail "partition_list")
  1245             else
  1246             let val (ns, rest) = partition (p k) xs;
  1247             in  ns :: part(k+1)rest  end
  1248   in  part i end;
  1249 
  1250 
  1251 (* generating identifiers *)
  1252 
  1253 (** Freshly generated identifiers; supplied prefix MUST start with a letter **)
  1254 local
  1255 (*Maps 0-63 to A-Z, a-z, 0-9 or _ or ' for generating random identifiers*)
  1256 fun char i =      if i<26 then chr (ord "A" + i)
  1257              else if i<52 then chr (ord "a" + i - 26)
  1258              else if i<62 then chr (ord"0" + i - 52)
  1259              else if i=62 then "_"
  1260              else  (*i=63*)    "'";
  1261 
  1262 val charVec = Vector.tabulate (64, char);
  1263 
  1264 fun newid n =
  1265   let
  1266   in  implode (map (fn i => Vector.sub(charVec,i)) (radixpand (64,n)))  end;
  1267 
  1268 val seedr = ref 0;
  1269 
  1270 in
  1271 
  1272 fun gensym pre = pre ^ (#1(newid (!seedr), inc seedr));
  1273 
  1274 end;
  1275 
  1276 
  1277 (* lexical scanning *)
  1278 
  1279 (*scan a list of characters into "words" composed of "letters" (recognized by
  1280   is_let) and separated by any number of non-"letters"*)
  1281 fun scanwords is_let cs =
  1282   let fun scan1 [] = []
  1283         | scan1 cs =
  1284             let val (lets, rest) = take_prefix is_let cs
  1285             in implode lets :: scanwords is_let rest end;
  1286   in scan1 (#2 (take_prefix (not o is_let) cs)) end;
  1287 
  1288 
  1289 end;
  1290 
  1291 structure OpenLibrary: LIBRARY = Library;
  1292 open OpenLibrary;