src/HOL/Tools/inductive.ML
author wenzelm
Sun Nov 27 14:20:31 2011 +0100 (2011-11-27)
changeset 45647 96af0578571c
parent 45592 8baa0b7f3f66
child 45648 7654f750fb43
permissions -rw-r--r--
misc tuning;
     1 (*  Title:      HOL/Tools/inductive.ML
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Author:     Stefan Berghofer and Markus Wenzel, TU Muenchen
     4 
     5 (Co)Inductive Definition module for HOL.
     6 
     7 Features:
     8   * least or greatest fixedpoints
     9   * mutually recursive definitions
    10   * definitions involving arbitrary monotone operators
    11   * automatically proves introduction and elimination rules
    12 
    13   Introduction rules have the form
    14   [| M Pj ti, ..., Q x, ... |] ==> Pk t
    15   where M is some monotone operator (usually the identity)
    16   Q x is any side condition on the free variables
    17   ti, t are any terms
    18   Pj, Pk are two of the predicates being defined in mutual recursion
    19 *)
    20 
    21 signature BASIC_INDUCTIVE =
    22 sig
    23   type inductive_result =
    24     {preds: term list, elims: thm list, raw_induct: thm,
    25      induct: thm, inducts: thm list, intrs: thm list, eqs: thm list}
    26   val transform_result: morphism -> inductive_result -> inductive_result
    27   type inductive_info = {names: string list, coind: bool} * inductive_result
    28   val the_inductive: Proof.context -> string -> inductive_info
    29   val print_inductives: Proof.context -> unit
    30   val mono_add: attribute
    31   val mono_del: attribute
    32   val get_monos: Proof.context -> thm list
    33   val mk_cases: Proof.context -> term -> thm
    34   val inductive_forall_def: thm
    35   val rulify: thm -> thm
    36   val inductive_cases: (Attrib.binding * string list) list -> local_theory ->
    37     thm list list * local_theory
    38   val inductive_cases_i: (Attrib.binding * term list) list -> local_theory ->
    39     thm list list * local_theory
    40   type inductive_flags =
    41     {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
    42       no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool}
    43   val add_inductive_i:
    44     inductive_flags -> ((binding * typ) * mixfix) list ->
    45     (string * typ) list -> (Attrib.binding * term) list -> thm list -> local_theory ->
    46     inductive_result * local_theory
    47   val add_inductive: bool -> bool ->
    48     (binding * string option * mixfix) list ->
    49     (binding * string option * mixfix) list ->
    50     (Attrib.binding * string) list ->
    51     (Facts.ref * Attrib.src list) list ->
    52     bool -> local_theory -> inductive_result * local_theory
    53   val add_inductive_global: inductive_flags ->
    54     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    55     thm list -> theory -> inductive_result * theory
    56   val arities_of: thm -> (string * int) list
    57   val params_of: thm -> term list
    58   val partition_rules: thm -> thm list -> (string * thm list) list
    59   val partition_rules': thm -> (thm * 'a) list -> (string * (thm * 'a) list) list
    60   val unpartition_rules: thm list -> (string * 'a list) list -> 'a list
    61   val infer_intro_vars: thm -> int -> thm list -> term list list
    62   val setup: theory -> theory
    63 end;
    64 
    65 signature INDUCTIVE =
    66 sig
    67   include BASIC_INDUCTIVE
    68   type add_ind_def =
    69     inductive_flags ->
    70     term list -> (Attrib.binding * term) list -> thm list ->
    71     term list -> (binding * mixfix) list ->
    72     local_theory -> inductive_result * local_theory
    73   val declare_rules: binding -> bool -> bool -> string list -> term list ->
    74     thm list -> binding list -> Attrib.src list list -> (thm * string list * int) list ->
    75     thm list -> thm -> local_theory -> thm list * thm list * thm list * thm * thm list * local_theory
    76   val add_ind_def: add_ind_def
    77   val gen_add_inductive_i: add_ind_def -> inductive_flags ->
    78     ((binding * typ) * mixfix) list -> (string * typ) list -> (Attrib.binding * term) list ->
    79     thm list -> local_theory -> inductive_result * local_theory
    80   val gen_add_inductive: add_ind_def -> bool -> bool ->
    81     (binding * string option * mixfix) list ->
    82     (binding * string option * mixfix) list ->
    83     (Attrib.binding * string) list -> (Facts.ref * Attrib.src list) list ->
    84     bool -> local_theory -> inductive_result * local_theory
    85   val gen_ind_decl: add_ind_def -> bool -> (bool -> local_theory -> local_theory) parser
    86 end;
    87 
    88 structure Inductive: INDUCTIVE =
    89 struct
    90 
    91 
    92 (** theory context references **)
    93 
    94 val inductive_forall_def = @{thm induct_forall_def};
    95 val inductive_conj_name = "HOL.induct_conj";
    96 val inductive_conj_def = @{thm induct_conj_def};
    97 val inductive_conj = @{thms induct_conj};
    98 val inductive_atomize = @{thms induct_atomize};
    99 val inductive_rulify = @{thms induct_rulify};
   100 val inductive_rulify_fallback = @{thms induct_rulify_fallback};
   101 
   102 val notTrueE = TrueI RSN (2, notE);
   103 val notFalseI = Seq.hd (atac 1 notI);
   104 
   105 val simp_thms' = map mk_meta_eq
   106   @{lemma "(~True) = False" "(~False) = True"
   107       "(True --> P) = P" "(False --> P) = True"
   108       "(P & True) = P" "(True & P) = P"
   109     by (fact simp_thms)+};
   110 
   111 val simp_thms'' = map mk_meta_eq [@{thm inf_fun_def}, @{thm inf_bool_def}] @ simp_thms';
   112 
   113 val simp_thms''' = map mk_meta_eq
   114   [@{thm le_fun_def}, @{thm le_bool_def}, @{thm sup_fun_def}, @{thm sup_bool_def}];
   115 
   116 
   117 
   118 (** context data **)
   119 
   120 type inductive_result =
   121   {preds: term list, elims: thm list, raw_induct: thm,
   122    induct: thm, inducts: thm list, intrs: thm list, eqs: thm list};
   123 
   124 fun transform_result phi {preds, elims, raw_induct: thm, induct, inducts, intrs, eqs} =
   125   let
   126     val term = Morphism.term phi;
   127     val thm = Morphism.thm phi;
   128     val fact = Morphism.fact phi;
   129   in
   130    {preds = map term preds, elims = fact elims, raw_induct = thm raw_induct,
   131     induct = thm induct, inducts = fact inducts, intrs = fact intrs, eqs = fact eqs}
   132   end;
   133 
   134 type inductive_info =
   135   {names: string list, coind: bool} * inductive_result;
   136 
   137 structure Data = Generic_Data
   138 (
   139   type T = inductive_info Symtab.table * thm list;
   140   val empty = (Symtab.empty, []);
   141   val extend = I;
   142   fun merge ((tab1, monos1), (tab2, monos2)) : T =
   143     (Symtab.merge (K true) (tab1, tab2), Thm.merge_thms (monos1, monos2));
   144 );
   145 
   146 val get_inductives = Data.get o Context.Proof;
   147 
   148 fun print_inductives ctxt =
   149   let
   150     val (tab, monos) = get_inductives ctxt;
   151     val space = Consts.space_of (Proof_Context.consts_of ctxt);
   152   in
   153     [Pretty.strs ("(co)inductives:" :: map #1 (Name_Space.extern_table ctxt (space, tab))),
   154      Pretty.big_list "monotonicity rules:" (map (Display.pretty_thm ctxt) monos)]
   155     |> Pretty.chunks |> Pretty.writeln
   156   end;
   157 
   158 
   159 (* get and put data *)
   160 
   161 fun the_inductive ctxt name =
   162   (case Symtab.lookup (#1 (get_inductives ctxt)) name of
   163     NONE => error ("Unknown (co)inductive predicate " ^ quote name)
   164   | SOME info => info);
   165 
   166 fun put_inductives names info =
   167   Data.map (apfst (fold (fn name => Symtab.update (name, info)) names));
   168 
   169 
   170 
   171 (** monotonicity rules **)
   172 
   173 val get_monos = #2 o get_inductives;
   174 val map_monos = Data.map o apsnd;
   175 
   176 fun mk_mono ctxt thm =
   177   let
   178     fun eq2mono thm' = thm' RS (thm' RS eq_to_mono);
   179     fun dest_less_concl thm = dest_less_concl (thm RS @{thm le_funD})
   180       handle THM _ => thm RS @{thm le_boolD}
   181   in
   182     (case concl_of thm of
   183       Const ("==", _) $ _ $ _ => eq2mono (thm RS meta_eq_to_obj_eq)
   184     | _ $ (Const (@{const_name HOL.eq}, _) $ _ $ _) => eq2mono thm
   185     | _ $ (Const (@{const_name Orderings.less_eq}, _) $ _ $ _) =>
   186       dest_less_concl (Seq.hd (REPEAT (FIRSTGOAL
   187         (resolve_tac [@{thm le_funI}, @{thm le_boolI'}])) thm))
   188     | _ => thm)
   189   end handle THM _ => error ("Bad monotonicity theorem:\n" ^ Display.string_of_thm ctxt thm);
   190 
   191 val mono_add =
   192   Thm.declaration_attribute (fn thm => fn context =>
   193     map_monos (Thm.add_thm (mk_mono (Context.proof_of context) thm)) context);
   194 
   195 val mono_del =
   196   Thm.declaration_attribute (fn thm => fn context =>
   197     map_monos (Thm.del_thm (mk_mono (Context.proof_of context) thm)) context);
   198 
   199 
   200 
   201 (** equations **)
   202 
   203 structure Equation_Data = Generic_Data   (* FIXME just one data slot per module *)
   204 (
   205   type T = thm Item_Net.T;
   206   val empty = Item_Net.init (op aconv o pairself Thm.prop_of)
   207     (single o fst o HOLogic.dest_eq o HOLogic.dest_Trueprop o Thm.prop_of);
   208   val extend = I;
   209   val merge = Item_Net.merge;
   210 );
   211 
   212 val add_equation = Thm.declaration_attribute (Equation_Data.map o Item_Net.update)
   213 
   214 
   215 
   216 (** misc utilities **)
   217 
   218 fun message quiet_mode s = if quiet_mode then () else writeln s;
   219 fun clean_message quiet_mode s = if ! quick_and_dirty then () else message quiet_mode s;
   220 
   221 fun coind_prefix true = "co"
   222   | coind_prefix false = "";
   223 
   224 fun log (b:int) m n = if m >= n then 0 else 1 + log b (b * m) n;
   225 
   226 fun make_bool_args f g [] i = []
   227   | make_bool_args f g (x :: xs) i =
   228       (if i mod 2 = 0 then f x else g x) :: make_bool_args f g xs (i div 2);
   229 
   230 fun make_bool_args' xs =
   231   make_bool_args (K HOLogic.false_const) (K HOLogic.true_const) xs;
   232 
   233 fun arg_types_of k c = drop k (binder_types (fastype_of c));
   234 
   235 fun find_arg T x [] = raise Fail "find_arg"
   236   | find_arg T x ((p as (_, (SOME _, _))) :: ps) =
   237       apsnd (cons p) (find_arg T x ps)
   238   | find_arg T x ((p as (U, (NONE, y))) :: ps) =
   239       if (T: typ) = U then (y, (U, (SOME x, y)) :: ps)
   240       else apsnd (cons p) (find_arg T x ps);
   241 
   242 fun make_args Ts xs =
   243   map (fn (T, (NONE, ())) => Const (@{const_name undefined}, T) | (_, (SOME t, ())) => t)
   244     (fold (fn (t, T) => snd o find_arg T t) xs (map (rpair (NONE, ())) Ts));
   245 
   246 fun make_args' Ts xs Us =
   247   fst (fold_map (fn T => find_arg T ()) Us (Ts ~~ map (pair NONE) xs));
   248 
   249 fun dest_predicate cs params t =
   250   let
   251     val k = length params;
   252     val (c, ts) = strip_comb t;
   253     val (xs, ys) = chop k ts;
   254     val i = find_index (fn c' => c' = c) cs;
   255   in
   256     if xs = params andalso i >= 0 then
   257       SOME (c, i, ys, chop (length ys) (arg_types_of k c))
   258     else NONE
   259   end;
   260 
   261 fun mk_names a 0 = []
   262   | mk_names a 1 = [a]
   263   | mk_names a n = map (fn i => a ^ string_of_int i) (1 upto n);
   264 
   265 fun select_disj 1 1 = []
   266   | select_disj _ 1 = [rtac disjI1]
   267   | select_disj n i = rtac disjI2 :: select_disj (n - 1) (i - 1);
   268 
   269 
   270 
   271 (** process rules **)
   272 
   273 local
   274 
   275 fun err_in_rule ctxt name t msg =
   276   error (cat_lines ["Ill-formed introduction rule " ^ Binding.print name,
   277     Syntax.string_of_term ctxt t, msg]);
   278 
   279 fun err_in_prem ctxt name t p msg =
   280   error (cat_lines ["Ill-formed premise", Syntax.string_of_term ctxt p,
   281     "in introduction rule " ^ Binding.print name, Syntax.string_of_term ctxt t, msg]);
   282 
   283 val bad_concl = "Conclusion of introduction rule must be an inductive predicate";
   284 
   285 val bad_ind_occ = "Inductive predicate occurs in argument of inductive predicate";
   286 
   287 val bad_app = "Inductive predicate must be applied to parameter(s) ";
   288 
   289 fun atomize_term thy = Raw_Simplifier.rewrite_term thy inductive_atomize [];
   290 
   291 in
   292 
   293 fun check_rule ctxt cs params ((binding, att), rule) =
   294   let
   295     val params' = Term.variant_frees rule (Logic.strip_params rule);
   296     val frees = rev (map Free params');
   297     val concl = subst_bounds (frees, Logic.strip_assums_concl rule);
   298     val prems = map (curry subst_bounds frees) (Logic.strip_assums_hyp rule);
   299     val rule' = Logic.list_implies (prems, concl);
   300     val aprems = map (atomize_term (Proof_Context.theory_of ctxt)) prems;
   301     val arule = list_all_free (params', Logic.list_implies (aprems, concl));
   302 
   303     fun check_ind err t =
   304       (case dest_predicate cs params t of
   305         NONE => err (bad_app ^
   306           commas (map (Syntax.string_of_term ctxt) params))
   307       | SOME (_, _, ys, _) =>
   308           if exists (fn c => exists (fn t => Logic.occs (c, t)) ys) cs
   309           then err bad_ind_occ else ());
   310 
   311     fun check_prem' prem t =
   312       if member (op =) cs (head_of t) then
   313         check_ind (err_in_prem ctxt binding rule prem) t
   314       else
   315         (case t of
   316           Abs (_, _, t) => check_prem' prem t
   317         | t $ u => (check_prem' prem t; check_prem' prem u)
   318         | _ => ());
   319 
   320     fun check_prem (prem, aprem) =
   321       if can HOLogic.dest_Trueprop aprem then check_prem' prem prem
   322       else err_in_prem ctxt binding rule prem "Non-atomic premise";
   323 
   324     val _ =
   325       (case concl of
   326         Const (@{const_name Trueprop}, _) $ t =>
   327           if member (op =) cs (head_of t) then
   328            (check_ind (err_in_rule ctxt binding rule') t;
   329             List.app check_prem (prems ~~ aprems))
   330           else err_in_rule ctxt binding rule' bad_concl
   331        | _ => err_in_rule ctxt binding rule' bad_concl);
   332   in
   333     ((binding, att), arule)
   334   end;
   335 
   336 val rulify =
   337   hol_simplify inductive_conj
   338   #> hol_simplify inductive_rulify
   339   #> hol_simplify inductive_rulify_fallback
   340   #> Simplifier.norm_hhf;
   341 
   342 end;
   343 
   344 
   345 
   346 (** proofs for (co)inductive predicates **)
   347 
   348 (* prove monotonicity *)
   349 
   350 fun prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos ctxt =
   351  (message (quiet_mode orelse skip_mono andalso !quick_and_dirty orelse fork_mono)
   352     "  Proving monotonicity ...";
   353   (if skip_mono then Skip_Proof.prove else if fork_mono then Goal.prove_future else Goal.prove) ctxt
   354     [] []
   355     (HOLogic.mk_Trueprop
   356       (Const (@{const_name Orderings.mono}, (predT --> predT) --> HOLogic.boolT) $ fp_fun))
   357     (fn _ => EVERY [rtac @{thm monoI} 1,
   358       REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI'}] 1),
   359       REPEAT (FIRST
   360         [atac 1,
   361          resolve_tac (map (mk_mono ctxt) monos @ get_monos ctxt) 1,
   362          etac @{thm le_funE} 1, dtac @{thm le_boolD} 1])]));
   363 
   364 
   365 (* prove introduction rules *)
   366 
   367 fun prove_intrs quiet_mode coind mono fp_def k intr_ts rec_preds_defs ctxt ctxt' =
   368   let
   369     val _ = clean_message quiet_mode "  Proving the introduction rules ...";
   370 
   371     val unfold = funpow k (fn th => th RS fun_cong)
   372       (mono RS (fp_def RS
   373         (if coind then @{thm def_gfp_unfold} else @{thm def_lfp_unfold})));
   374 
   375     val rules = [refl, TrueI, notFalseI, exI, conjI];
   376 
   377     val intrs = map_index (fn (i, intr) =>
   378       Skip_Proof.prove ctxt [] [] intr (fn _ => EVERY
   379        [rewrite_goals_tac rec_preds_defs,
   380         rtac (unfold RS iffD2) 1,
   381         EVERY1 (select_disj (length intr_ts) (i + 1)),
   382         (*Not ares_tac, since refl must be tried before any equality assumptions;
   383           backtracking may occur if the premises have extra variables!*)
   384         DEPTH_SOLVE_1 (resolve_tac rules 1 APPEND assume_tac 1)])
   385        |> singleton (Proof_Context.export ctxt ctxt')) intr_ts
   386 
   387   in (intrs, unfold) end;
   388 
   389 
   390 (* prove elimination rules *)
   391 
   392 fun prove_elims quiet_mode cs params intr_ts intr_names unfold rec_preds_defs ctxt ctxt''' =
   393   let
   394     val _ = clean_message quiet_mode "  Proving the elimination rules ...";
   395 
   396     val ([pname], ctxt') = Variable.variant_fixes ["P"] ctxt;
   397     val P = HOLogic.mk_Trueprop (Free (pname, HOLogic.boolT));
   398 
   399     fun dest_intr r =
   400       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   401        Logic.strip_assums_hyp r, Logic.strip_params r);
   402 
   403     val intrs = map dest_intr intr_ts ~~ intr_names;
   404 
   405     val rules1 = [disjE, exE, FalseE];
   406     val rules2 = [conjE, FalseE, notTrueE];
   407 
   408     fun prove_elim c =
   409       let
   410         val Ts = arg_types_of (length params) c;
   411         val (anames, ctxt'') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt';
   412         val frees = map Free (anames ~~ Ts);
   413 
   414         fun mk_elim_prem ((_, _, us, _), ts, params') =
   415           list_all (params',
   416             Logic.list_implies (map (HOLogic.mk_Trueprop o HOLogic.mk_eq)
   417               (frees ~~ us) @ ts, P));
   418         val c_intrs = filter (equal c o #1 o #1 o #1) intrs;
   419         val prems = HOLogic.mk_Trueprop (list_comb (c, params @ frees)) ::
   420            map mk_elim_prem (map #1 c_intrs)
   421       in
   422         (Skip_Proof.prove ctxt'' [] prems P
   423           (fn {prems, ...} => EVERY
   424             [cut_facts_tac [hd prems] 1,
   425              rewrite_goals_tac rec_preds_defs,
   426              dtac (unfold RS iffD1) 1,
   427              REPEAT (FIRSTGOAL (eresolve_tac rules1)),
   428              REPEAT (FIRSTGOAL (eresolve_tac rules2)),
   429              EVERY (map (fn prem =>
   430                DEPTH_SOLVE_1 (ares_tac [rewrite_rule rec_preds_defs prem, conjI] 1)) (tl prems))])
   431           |> singleton (Proof_Context.export ctxt'' ctxt'''),
   432          map #2 c_intrs, length Ts)
   433       end
   434 
   435    in map prove_elim cs end;
   436 
   437 
   438 (* prove simplification equations *)
   439 
   440 fun prove_eqs quiet_mode cs params intr_ts intrs
   441     (elims: (thm * bstring list * int) list) ctxt ctxt'' =  (* FIXME ctxt'' ?? *)
   442   let
   443     val _ = clean_message quiet_mode "  Proving the simplification rules ...";
   444 
   445     fun dest_intr r =
   446       (the (dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r))),
   447        Logic.strip_assums_hyp r, Logic.strip_params r);
   448     val intr_ts' = map dest_intr intr_ts;
   449 
   450     fun prove_eq c (elim: thm * 'a * 'b) =
   451       let
   452         val Ts = arg_types_of (length params) c;
   453         val (anames, ctxt') = Variable.variant_fixes (mk_names "a" (length Ts)) ctxt;
   454         val frees = map Free (anames ~~ Ts);
   455         val c_intrs = filter (equal c o #1 o #1 o #1) (intr_ts' ~~ intrs);
   456         fun mk_intr_conj (((_, _, us, _), ts, params'), _) =
   457           let
   458             fun list_ex ([], t) = t
   459               | list_ex ((a, T) :: vars, t) =
   460                   HOLogic.exists_const T $ Abs (a, T, list_ex (vars, t));
   461             val conjs = map2 (curry HOLogic.mk_eq) frees us @ (map HOLogic.dest_Trueprop ts);
   462           in
   463             list_ex (params', if null conjs then @{term True} else foldr1 HOLogic.mk_conj conjs)
   464           end;
   465         val lhs = list_comb (c, params @ frees);
   466         val rhs =
   467           if null c_intrs then @{term False}
   468           else foldr1 HOLogic.mk_disj (map mk_intr_conj c_intrs);
   469         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (lhs, rhs));
   470         fun prove_intr1 (i, _) = Subgoal.FOCUS_PREMS (fn {params, prems, ...} =>
   471             let
   472               val (prems', last_prem) = split_last prems;
   473             in
   474               EVERY1 (select_disj (length c_intrs) (i + 1)) THEN
   475               EVERY (replicate (length params) (rtac @{thm exI} 1)) THEN
   476               EVERY (map (fn prem => (rtac @{thm conjI} 1 THEN rtac prem 1)) prems') THEN
   477               rtac last_prem 1
   478             end) ctxt' 1;
   479         fun prove_intr2 (((_, _, us, _), ts, params'), intr) =
   480           EVERY (replicate (length params') (etac @{thm exE} 1)) THEN
   481           EVERY (replicate (length ts + length us - 1) (etac @{thm conjE} 1)) THEN
   482           Subgoal.FOCUS_PREMS (fn {params, prems, ...} =>
   483             let
   484               val (eqs, prems') = chop (length us) prems;
   485               val rew_thms = map (fn th => th RS @{thm eq_reflection}) eqs;
   486             in
   487               rewrite_goal_tac rew_thms 1 THEN
   488               rtac intr 1 THEN
   489               EVERY (map (fn p => rtac p 1) prems')
   490             end) ctxt' 1;
   491       in
   492         Skip_Proof.prove ctxt' [] [] eq (fn _ =>
   493           rtac @{thm iffI} 1 THEN etac (#1 elim) 1 THEN
   494           EVERY (map_index prove_intr1 c_intrs) THEN
   495           (if null c_intrs then etac @{thm FalseE} 1
   496            else
   497             let val (c_intrs', last_c_intr) = split_last c_intrs in
   498               EVERY (map (fn ci => etac @{thm disjE} 1 THEN prove_intr2 ci) c_intrs') THEN
   499               prove_intr2 last_c_intr
   500             end))
   501         |> rulify
   502         |> singleton (Proof_Context.export ctxt' ctxt'')
   503       end;
   504   in
   505     map2 prove_eq cs elims
   506   end;
   507 
   508 
   509 (* derivation of simplified elimination rules *)
   510 
   511 local
   512 
   513 (*delete needless equality assumptions*)
   514 val refl_thin = Goal.prove_global @{theory HOL} [] [] @{prop "!!P. a = a ==> P ==> P"}
   515   (fn _ => assume_tac 1);
   516 val elim_rls = [asm_rl, FalseE, refl_thin, conjE, exE];
   517 val elim_tac = REPEAT o Tactic.eresolve_tac elim_rls;
   518 
   519 fun simp_case_tac ss i =
   520   EVERY' [elim_tac, asm_full_simp_tac ss, elim_tac, REPEAT o bound_hyp_subst_tac] i;
   521 
   522 in
   523 
   524 fun mk_cases ctxt prop =
   525   let
   526     val thy = Proof_Context.theory_of ctxt;
   527     val ss = simpset_of ctxt;
   528 
   529     fun err msg =
   530       error (Pretty.string_of (Pretty.block
   531         [Pretty.str msg, Pretty.fbrk, Syntax.pretty_term ctxt prop]));
   532 
   533     val elims = Induct.find_casesP ctxt prop;
   534 
   535     val cprop = Thm.cterm_of thy prop;
   536     val tac = ALLGOALS (simp_case_tac ss) THEN prune_params_tac;
   537     fun mk_elim rl =
   538       Thm.implies_intr cprop (Tactic.rule_by_tactic ctxt tac (Thm.assume cprop RS rl))
   539       |> singleton (Variable.export (Variable.auto_fixes prop ctxt) ctxt);
   540   in
   541     (case get_first (try mk_elim) elims of
   542       SOME r => r
   543     | NONE => err "Proposition not an inductive predicate:")
   544   end;
   545 
   546 end;
   547 
   548 
   549 (* inductive_cases *)
   550 
   551 fun gen_inductive_cases prep_att prep_prop args lthy =
   552   let
   553     val thy = Proof_Context.theory_of lthy;
   554     val facts = args |> Par_List.map (fn ((a, atts), props) =>
   555       ((a, map (prep_att thy) atts),
   556         Par_List.map (Thm.no_attributes o single o mk_cases lthy o prep_prop lthy) props));
   557   in lthy |> Local_Theory.notes facts |>> map snd end;
   558 
   559 val inductive_cases = gen_inductive_cases Attrib.intern_src Syntax.read_prop;
   560 val inductive_cases_i = gen_inductive_cases (K I) Syntax.check_prop;
   561 
   562 
   563 val ind_cases_setup =
   564   Method.setup @{binding ind_cases}
   565     (Scan.lift (Scan.repeat1 Args.name_source --
   566       Scan.optional (Args.$$$ "for" |-- Scan.repeat1 Args.binding) []) >>
   567       (fn (raw_props, fixes) => fn ctxt =>
   568         let
   569           val (_, ctxt') = Variable.add_fixes_binding fixes ctxt;
   570           val props = Syntax.read_props ctxt' raw_props;
   571           val ctxt'' = fold Variable.declare_term props ctxt';
   572           val rules = Proof_Context.export ctxt'' ctxt (map (mk_cases ctxt'') props)
   573         in Method.erule 0 rules end))
   574     "dynamic case analysis on predicates";
   575 
   576 
   577 (* derivation of simplified equation *)
   578 
   579 fun mk_simp_eq ctxt prop =
   580   let
   581     val thy = Proof_Context.theory_of ctxt;
   582     val ctxt' = Variable.auto_fixes prop ctxt;
   583     val lhs_of = fst o HOLogic.dest_eq o HOLogic.dest_Trueprop o Thm.prop_of;
   584     val substs =
   585       Item_Net.retrieve (Equation_Data.get (Context.Proof ctxt)) (HOLogic.dest_Trueprop prop)
   586       |> map_filter
   587         (fn eq => SOME (Pattern.match thy (lhs_of eq, HOLogic.dest_Trueprop prop)
   588             (Vartab.empty, Vartab.empty), eq)
   589           handle Pattern.MATCH => NONE);
   590     val (subst, eq) =
   591       (case substs of
   592         [s] => s
   593       | _ => error
   594         ("equations matching pattern " ^ Syntax.string_of_term ctxt prop ^ " is not unique"));
   595     val inst =
   596       map (fn v => (cterm_of thy (Var v), cterm_of thy (Envir.subst_term subst (Var v))))
   597         (Term.add_vars (lhs_of eq) []);
   598   in
   599     cterm_instantiate inst eq
   600     |> Conv.fconv_rule (Conv.arg_conv (Conv.arg_conv (Simplifier.full_rewrite (simpset_of ctxt))))
   601     |> singleton (Variable.export ctxt' ctxt)
   602   end
   603 
   604 
   605 (* inductive simps *)
   606 
   607 fun gen_inductive_simps prep_att prep_prop args lthy =
   608   let
   609     val thy = Proof_Context.theory_of lthy;
   610     val facts = args |> map (fn ((a, atts), props) =>
   611       ((a, map (prep_att thy) atts),
   612         map (Thm.no_attributes o single o mk_simp_eq lthy o prep_prop lthy) props));
   613   in lthy |> Local_Theory.notes facts |>> map snd end;
   614 
   615 val inductive_simps = gen_inductive_simps Attrib.intern_src Syntax.read_prop;
   616 val inductive_simps_i = gen_inductive_simps (K I) Syntax.check_prop;
   617 
   618 
   619 (* prove induction rule *)
   620 
   621 fun prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono
   622     fp_def rec_preds_defs ctxt ctxt''' =  (* FIXME ctxt''' ?? *)
   623   let
   624     val _ = clean_message quiet_mode "  Proving the induction rule ...";
   625 
   626     (* predicates for induction rule *)
   627 
   628     val (pnames, ctxt') = Variable.variant_fixes (mk_names "P" (length cs)) ctxt;
   629     val preds =
   630       map2 (curry Free) pnames
   631         (map (fn c => arg_types_of (length params) c ---> HOLogic.boolT) cs);
   632 
   633     (* transform an introduction rule into a premise for induction rule *)
   634 
   635     fun mk_ind_prem r =
   636       let
   637         fun subst s =
   638           (case dest_predicate cs params s of
   639             SOME (_, i, ys, (_, Ts)) =>
   640               let
   641                 val k = length Ts;
   642                 val bs = map Bound (k - 1 downto 0);
   643                 val P = list_comb (nth preds i, map (incr_boundvars k) ys @ bs);
   644                 val Q = list_abs (mk_names "x" k ~~ Ts,
   645                   HOLogic.mk_binop inductive_conj_name
   646                     (list_comb (incr_boundvars k s, bs), P));
   647               in (Q, case Ts of [] => SOME (s, P) | _ => NONE) end
   648           | NONE =>
   649               (case s of
   650                 t $ u => (fst (subst t) $ fst (subst u), NONE)
   651               | Abs (a, T, t) => (Abs (a, T, fst (subst t)), NONE)
   652               | _ => (s, NONE)));
   653 
   654         fun mk_prem s prems =
   655           (case subst s of
   656             (_, SOME (t, u)) => t :: u :: prems
   657           | (t, _) => t :: prems);
   658 
   659         val SOME (_, i, ys, _) =
   660           dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   661       in
   662         list_all_free (Logic.strip_params r,
   663           Logic.list_implies (map HOLogic.mk_Trueprop (fold_rev mk_prem
   664             (map HOLogic.dest_Trueprop (Logic.strip_assums_hyp r)) []),
   665               HOLogic.mk_Trueprop (list_comb (nth preds i, ys))))
   666       end;
   667 
   668     val ind_prems = map mk_ind_prem intr_ts;
   669 
   670 
   671     (* make conclusions for induction rules *)
   672 
   673     val Tss = map (binder_types o fastype_of) preds;
   674     val (xnames, ctxt'') = Variable.variant_fixes (mk_names "x" (length (flat Tss))) ctxt';
   675     val mutual_ind_concl =
   676       HOLogic.mk_Trueprop (foldr1 HOLogic.mk_conj
   677         (map (fn (((xnames, Ts), c), P) =>
   678           let val frees = map Free (xnames ~~ Ts)
   679           in HOLogic.mk_imp (list_comb (c, params @ frees), list_comb (P, frees)) end)
   680         (unflat Tss xnames ~~ Tss ~~ cs ~~ preds)));
   681 
   682 
   683     (* make predicate for instantiation of abstract induction rule *)
   684 
   685     val ind_pred =
   686       fold_rev lambda (bs @ xs) (foldr1 HOLogic.mk_conj
   687         (map_index (fn (i, P) => fold_rev (curry HOLogic.mk_imp)
   688            (make_bool_args HOLogic.mk_not I bs i)
   689            (list_comb (P, make_args' argTs xs (binder_types (fastype_of P))))) preds));
   690 
   691     val ind_concl =
   692       HOLogic.mk_Trueprop
   693         (HOLogic.mk_binrel @{const_name Orderings.less_eq} (rec_const, ind_pred));
   694 
   695     val raw_fp_induct = mono RS (fp_def RS @{thm def_lfp_induct});
   696 
   697     val induct = Skip_Proof.prove ctxt'' [] ind_prems ind_concl
   698       (fn {prems, ...} => EVERY
   699         [rewrite_goals_tac [inductive_conj_def],
   700          DETERM (rtac raw_fp_induct 1),
   701          REPEAT (resolve_tac [@{thm le_funI}, @{thm le_boolI}] 1),
   702          rewrite_goals_tac simp_thms'',
   703          (*This disjE separates out the introduction rules*)
   704          REPEAT (FIRSTGOAL (eresolve_tac [disjE, exE, FalseE])),
   705          (*Now break down the individual cases.  No disjE here in case
   706            some premise involves disjunction.*)
   707          REPEAT (FIRSTGOAL (etac conjE ORELSE' bound_hyp_subst_tac)),
   708          REPEAT (FIRSTGOAL
   709            (resolve_tac [conjI, impI] ORELSE' (etac notE THEN' atac))),
   710          EVERY (map (fn prem => DEPTH_SOLVE_1 (ares_tac [rewrite_rule
   711              (inductive_conj_def :: rec_preds_defs @ simp_thms'') prem,
   712            conjI, refl] 1)) prems)]);
   713 
   714     val lemma = Skip_Proof.prove ctxt'' [] []
   715       (Logic.mk_implies (ind_concl, mutual_ind_concl)) (fn _ => EVERY
   716         [rewrite_goals_tac rec_preds_defs,
   717          REPEAT (EVERY
   718            [REPEAT (resolve_tac [conjI, impI] 1),
   719             REPEAT (eresolve_tac [@{thm le_funE}, @{thm le_boolE}] 1),
   720             atac 1,
   721             rewrite_goals_tac simp_thms',
   722             atac 1])]);
   723 
   724   in singleton (Proof_Context.export ctxt'' ctxt''') (induct RS lemma) end;
   725 
   726 
   727 
   728 (** specification of (co)inductive predicates **)
   729 
   730 fun mk_ind_def quiet_mode skip_mono fork_mono alt_name coind
   731     cs intr_ts monos params cnames_syn lthy =
   732   let
   733     val fp_name = if coind then @{const_name Inductive.gfp} else @{const_name Inductive.lfp};
   734 
   735     val argTs = fold (combine (op =) o arg_types_of (length params)) cs [];
   736     val k = log 2 1 (length cs);
   737     val predT = replicate k HOLogic.boolT ---> argTs ---> HOLogic.boolT;
   738     val p :: xs =
   739       map Free (Variable.variant_frees lthy intr_ts
   740         (("p", predT) :: (mk_names "x" (length argTs) ~~ argTs)));
   741     val bs =
   742       map Free (Variable.variant_frees lthy (p :: xs @ intr_ts)
   743         (map (rpair HOLogic.boolT) (mk_names "b" k)));
   744 
   745     fun subst t =
   746       (case dest_predicate cs params t of
   747         SOME (_, i, ts, (Ts, Us)) =>
   748           let
   749             val l = length Us;
   750             val zs = map Bound (l - 1 downto 0);
   751           in
   752             list_abs (map (pair "z") Us, list_comb (p,
   753               make_bool_args' bs i @ make_args argTs
   754                 ((map (incr_boundvars l) ts ~~ Ts) @ (zs ~~ Us))))
   755           end
   756       | NONE =>
   757           (case t of
   758             t1 $ t2 => subst t1 $ subst t2
   759           | Abs (x, T, u) => Abs (x, T, subst u)
   760           | _ => t));
   761 
   762     (* transform an introduction rule into a conjunction  *)
   763     (*   [| p_i t; ... |] ==> p_j u                       *)
   764     (* is transformed into                                *)
   765     (*   b_j & x_j = u & p b_j t & ...                    *)
   766 
   767     fun transform_rule r =
   768       let
   769         val SOME (_, i, ts, (Ts, _)) =
   770           dest_predicate cs params (HOLogic.dest_Trueprop (Logic.strip_assums_concl r));
   771         val ps =
   772           make_bool_args HOLogic.mk_not I bs i @
   773           map HOLogic.mk_eq (make_args' argTs xs Ts ~~ ts) @
   774           map (subst o HOLogic.dest_Trueprop) (Logic.strip_assums_hyp r);
   775       in
   776         fold_rev (fn (x, T) => fn P => HOLogic.exists_const T $ Abs (x, T, P))
   777           (Logic.strip_params r)
   778           (if null ps then HOLogic.true_const else foldr1 HOLogic.mk_conj ps)
   779       end;
   780 
   781     (* make a disjunction of all introduction rules *)
   782 
   783     val fp_fun =
   784       fold_rev lambda (p :: bs @ xs)
   785         (if null intr_ts then HOLogic.false_const
   786          else foldr1 HOLogic.mk_disj (map transform_rule intr_ts));
   787 
   788     (* add definiton of recursive predicates to theory *)
   789 
   790     val rec_name =
   791       if Binding.is_empty alt_name then
   792         Binding.name (space_implode "_" (map (Binding.name_of o fst) cnames_syn))
   793       else alt_name;
   794 
   795     val ((rec_const, (_, fp_def)), lthy') = lthy
   796       |> Local_Theory.conceal
   797       |> Local_Theory.define
   798         ((rec_name, case cnames_syn of [(_, syn)] => syn | _ => NoSyn),
   799          ((Binding.empty, @{attributes [nitpick_unfold]}),
   800            fold_rev lambda params
   801              (Const (fp_name, (predT --> predT) --> predT) $ fp_fun)))
   802       ||> Local_Theory.restore_naming lthy;
   803     val fp_def' =
   804       Simplifier.rewrite (HOL_basic_ss addsimps [fp_def])
   805         (cterm_of (Proof_Context.theory_of lthy') (list_comb (rec_const, params)));
   806     val specs =
   807       if length cs < 2 then []
   808       else
   809         map_index (fn (i, (name_mx, c)) =>
   810           let
   811             val Ts = arg_types_of (length params) c;
   812             val xs =
   813               map Free (Variable.variant_frees lthy intr_ts (mk_names "x" (length Ts) ~~ Ts));
   814           in
   815             (name_mx, (apfst Binding.conceal Attrib.empty_binding, fold_rev lambda (params @ xs)
   816               (list_comb (rec_const, params @ make_bool_args' bs i @
   817                 make_args argTs (xs ~~ Ts)))))
   818           end) (cnames_syn ~~ cs);
   819     val (consts_defs, lthy'') = lthy'
   820       |> fold_map Local_Theory.define specs;
   821     val preds = (case cs of [_] => [rec_const] | _ => map #1 consts_defs);
   822 
   823     val (_, lthy''') = Variable.add_fixes (map (fst o dest_Free) params) lthy'';
   824     val mono = prove_mono quiet_mode skip_mono fork_mono predT fp_fun monos lthy''';
   825     val (_, lthy'''') =
   826       Local_Theory.note (apfst Binding.conceal Attrib.empty_binding,
   827         Proof_Context.export lthy''' lthy'' [mono]) lthy'';
   828 
   829   in (lthy'''', lthy''', rec_name, mono, fp_def', map (#2 o #2) consts_defs,
   830     list_comb (rec_const, params), preds, argTs, bs, xs)
   831   end;
   832 
   833 fun declare_rules rec_binding coind no_ind cnames
   834     preds intrs intr_bindings intr_atts elims eqs raw_induct lthy =
   835   let
   836     val rec_name = Binding.name_of rec_binding;
   837     fun rec_qualified qualified = Binding.qualify qualified rec_name;
   838     val intr_names = map Binding.name_of intr_bindings;
   839     val ind_case_names = Rule_Cases.case_names intr_names;
   840     val induct =
   841       if coind then
   842         (raw_induct, [Rule_Cases.case_names [rec_name],
   843           Rule_Cases.case_conclusion (rec_name, intr_names),
   844           Rule_Cases.consumes 1, Induct.coinduct_pred (hd cnames)])
   845       else if no_ind orelse length cnames > 1 then
   846         (raw_induct, [ind_case_names, Rule_Cases.consumes 0])
   847       else (raw_induct RSN (2, rev_mp), [ind_case_names, Rule_Cases.consumes 1]);
   848 
   849     val (intrs', lthy1) =
   850       lthy |>
   851       Spec_Rules.add
   852         (if coind then Spec_Rules.Co_Inductive else Spec_Rules.Inductive) (preds, intrs) |>
   853       Local_Theory.notes
   854         (map (rec_qualified false) intr_bindings ~~ intr_atts ~~
   855           map (fn th => [([th],
   856            [Attrib.internal (K (Context_Rules.intro_query NONE))])]) intrs) |>>
   857       map (hd o snd);
   858     val (((_, elims'), (_, [induct'])), lthy2) =
   859       lthy1 |>
   860       Local_Theory.note ((rec_qualified true (Binding.name "intros"), []), intrs') ||>>
   861       fold_map (fn (name, (elim, cases, k)) =>
   862         Local_Theory.note
   863           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "cases"),
   864             [Attrib.internal (K (Rule_Cases.case_names cases)),
   865              Attrib.internal (K (Rule_Cases.consumes 1)),
   866              Attrib.internal (K (Rule_Cases.constraints k)),
   867              Attrib.internal (K (Induct.cases_pred name)),
   868              Attrib.internal (K (Context_Rules.elim_query NONE))]), [elim]) #>
   869         apfst (hd o snd)) (if null elims then [] else cnames ~~ elims) ||>>
   870       Local_Theory.note
   871         ((rec_qualified true (Binding.name (coind_prefix coind ^ "induct")),
   872           map (Attrib.internal o K) (#2 induct)), [rulify (#1 induct)]);
   873 
   874     val (eqs', lthy3) = lthy2 |>
   875       fold_map (fn (name, eq) => Local_Theory.note
   876           ((Binding.qualify true (Long_Name.base_name name) (Binding.name "simps"),
   877             [Attrib.internal (K add_equation)]), [eq])
   878           #> apfst (hd o snd))
   879         (if null eqs then [] else (cnames ~~ eqs))
   880     val (inducts, lthy4) =
   881       if no_ind orelse coind then ([], lthy3)
   882       else
   883         let val inducts = cnames ~~ Project_Rule.projects lthy3 (1 upto length cnames) induct' in
   884           lthy3 |>
   885           Local_Theory.notes [((rec_qualified true (Binding.name "inducts"), []),
   886             inducts |> map (fn (name, th) => ([th],
   887               [Attrib.internal (K ind_case_names),
   888                Attrib.internal (K (Rule_Cases.consumes 1)),
   889                Attrib.internal (K (Induct.induct_pred name))])))] |>> snd o hd
   890         end;
   891   in (intrs', elims', eqs', induct', inducts, lthy4) end;
   892 
   893 type inductive_flags =
   894   {quiet_mode: bool, verbose: bool, alt_name: binding, coind: bool,
   895     no_elim: bool, no_ind: bool, skip_mono: bool, fork_mono: bool};
   896 
   897 type add_ind_def =
   898   inductive_flags ->
   899   term list -> (Attrib.binding * term) list -> thm list ->
   900   term list -> (binding * mixfix) list ->
   901   local_theory -> inductive_result * local_theory;
   902 
   903 fun add_ind_def {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono}
   904     cs intros monos params cnames_syn lthy =
   905   let
   906     val _ = null cnames_syn andalso error "No inductive predicates given";
   907     val names = map (Binding.name_of o fst) cnames_syn;
   908     val _ = message (quiet_mode andalso not verbose)
   909       ("Proofs for " ^ coind_prefix coind ^ "inductive predicate(s) " ^ commas_quote names);
   910 
   911     val cnames = map (Local_Theory.full_name lthy o #1) cnames_syn;  (* FIXME *)
   912     val ((intr_names, intr_atts), intr_ts) =
   913       apfst split_list (split_list (map (check_rule lthy cs params) intros));
   914 
   915     val (lthy1, lthy2, rec_name, mono, fp_def, rec_preds_defs, rec_const, preds,
   916       argTs, bs, xs) = mk_ind_def quiet_mode skip_mono fork_mono alt_name coind cs intr_ts
   917         monos params cnames_syn lthy;
   918 
   919     val (intrs, unfold) = prove_intrs quiet_mode coind mono fp_def (length bs + length xs)
   920       intr_ts rec_preds_defs lthy2 lthy1;
   921     val elims =
   922       if no_elim then []
   923       else
   924         prove_elims quiet_mode cs params intr_ts (map Binding.name_of intr_names)
   925           unfold rec_preds_defs lthy2 lthy1;
   926     val raw_induct = zero_var_indexes
   927       (if no_ind then Drule.asm_rl
   928        else if coind then
   929          singleton (Proof_Context.export lthy2 lthy1)
   930            (rotate_prems ~1 (Object_Logic.rulify
   931              (fold_rule rec_preds_defs
   932                (rewrite_rule simp_thms'''
   933                 (mono RS (fp_def RS @{thm def_coinduct}))))))
   934        else
   935          prove_indrule quiet_mode cs argTs bs xs rec_const params intr_ts mono fp_def
   936            rec_preds_defs lthy2 lthy1);
   937     val eqs =
   938       if no_elim then [] else prove_eqs quiet_mode cs params intr_ts intrs elims lthy2 lthy1;
   939 
   940     val elims' = map (fn (th, ns, i) => (rulify th, ns, i)) elims;
   941     val intrs' = map rulify intrs;
   942 
   943     val (intrs'', elims'', eqs', induct, inducts, lthy3) =
   944       declare_rules rec_name coind no_ind
   945         cnames preds intrs' intr_names intr_atts elims' eqs raw_induct lthy1;
   946 
   947     val result =
   948       {preds = preds,
   949        intrs = intrs'',
   950        elims = elims'',
   951        raw_induct = rulify raw_induct,
   952        induct = induct,
   953        inducts = inducts,
   954        eqs = eqs'};
   955 
   956     val lthy4 = lthy3
   957       |> Local_Theory.declaration {syntax = false, pervasive = false} (fn phi =>
   958         let val result' = transform_result phi result;
   959         in put_inductives cnames (*global names!?*) ({names = cnames, coind = coind}, result') end);
   960   in (result, lthy4) end;
   961 
   962 
   963 (* external interfaces *)
   964 
   965 fun gen_add_inductive_i mk_def
   966     (flags as {quiet_mode, verbose, alt_name, coind, no_elim, no_ind, skip_mono, fork_mono})
   967     cnames_syn pnames spec monos lthy =
   968   let
   969     val thy = Proof_Context.theory_of lthy;
   970     val _ = Theory.requires thy "Inductive" (coind_prefix coind ^ "inductive definitions");
   971 
   972 
   973     (* abbrevs *)
   974 
   975     val (_, ctxt1) = Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn) lthy;
   976 
   977     fun get_abbrev ((name, atts), t) =
   978       if can (Logic.strip_assums_concl #> Logic.dest_equals) t then
   979         let
   980           val _ = Binding.is_empty name andalso null atts orelse
   981             error "Abbreviations may not have names or attributes";
   982           val ((x, T), rhs) = Local_Defs.abs_def (snd (Local_Defs.cert_def ctxt1 t));
   983           val var =
   984             (case find_first (fn ((c, _), _) => Binding.name_of c = x) cnames_syn of
   985               NONE => error ("Undeclared head of abbreviation " ^ quote x)
   986             | SOME ((b, T'), mx) =>
   987                 if T <> T' then error ("Bad type specification for abbreviation " ^ quote x)
   988                 else (b, mx));
   989         in SOME (var, rhs) end
   990       else NONE;
   991 
   992     val abbrevs = map_filter get_abbrev spec;
   993     val bs = map (Binding.name_of o fst o fst) abbrevs;
   994 
   995 
   996     (* predicates *)
   997 
   998     val pre_intros = filter_out (is_some o get_abbrev) spec;
   999     val cnames_syn' = filter_out (member (op =) bs o Binding.name_of o fst o fst) cnames_syn;
  1000     val cs = map (Free o apfst Binding.name_of o fst) cnames_syn';
  1001     val ps = map Free pnames;
  1002 
  1003     val (_, ctxt2) = lthy |> Variable.add_fixes (map (Binding.name_of o fst o fst) cnames_syn');
  1004     val _ = map (fn abbr => Local_Defs.fixed_abbrev abbr ctxt2) abbrevs;
  1005     val ctxt3 = ctxt2 |> fold (snd oo Local_Defs.fixed_abbrev) abbrevs;
  1006     val expand = Assumption.export_term ctxt3 lthy #> Proof_Context.cert_term lthy;
  1007 
  1008     fun close_rule r = list_all_free (rev (fold_aterms
  1009       (fn t as Free (v as (s, _)) =>
  1010           if Variable.is_fixed ctxt1 s orelse
  1011             member (op =) ps t then I else insert (op =) v
  1012         | _ => I) r []), r);
  1013 
  1014     val intros = map (apsnd (Syntax.check_term lthy #> close_rule #> expand)) pre_intros;
  1015     val preds = map (fn ((c, _), mx) => (c, mx)) cnames_syn';
  1016   in
  1017     lthy
  1018     |> mk_def flags cs intros monos ps preds
  1019     ||> fold (snd oo Local_Theory.abbrev Syntax.mode_default) abbrevs
  1020   end;
  1021 
  1022 fun gen_add_inductive mk_def verbose coind cnames_syn pnames_syn intro_srcs raw_monos int lthy =
  1023   let
  1024     val ((vars, intrs), _) = lthy
  1025       |> Proof_Context.set_mode Proof_Context.mode_abbrev
  1026       |> Specification.read_spec (cnames_syn @ pnames_syn) intro_srcs;
  1027     val (cs, ps) = chop (length cnames_syn) vars;
  1028     val monos = Attrib.eval_thms lthy raw_monos;
  1029     val flags = {quiet_mode = false, verbose = verbose, alt_name = Binding.empty,
  1030       coind = coind, no_elim = false, no_ind = false, skip_mono = false, fork_mono = not int};
  1031   in
  1032     lthy
  1033     |> gen_add_inductive_i mk_def flags cs (map (apfst Binding.name_of o fst) ps) intrs monos
  1034   end;
  1035 
  1036 val add_inductive_i = gen_add_inductive_i add_ind_def;
  1037 val add_inductive = gen_add_inductive add_ind_def;
  1038 
  1039 fun add_inductive_global flags cnames_syn pnames pre_intros monos thy =
  1040   let
  1041     val name = Sign.full_name thy (fst (fst (hd cnames_syn)));
  1042     val ctxt' = thy
  1043       |> Named_Target.theory_init
  1044       |> add_inductive_i flags cnames_syn pnames pre_intros monos |> snd
  1045       |> Local_Theory.exit;
  1046     val info = #2 (the_inductive ctxt' name);
  1047   in (info, Proof_Context.theory_of ctxt') end;
  1048 
  1049 
  1050 (* read off arities of inductive predicates from raw induction rule *)
  1051 fun arities_of induct =
  1052   map (fn (_ $ t $ u) =>
  1053       (fst (dest_Const (head_of t)), length (snd (strip_comb u))))
  1054     (HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct)));
  1055 
  1056 (* read off parameters of inductive predicate from raw induction rule *)
  1057 fun params_of induct =
  1058   let
  1059     val (_ $ t $ u :: _) = HOLogic.dest_conj (HOLogic.dest_Trueprop (concl_of induct));
  1060     val (_, ts) = strip_comb t;
  1061     val (_, us) = strip_comb u;
  1062   in
  1063     List.take (ts, length ts - length us)
  1064   end;
  1065 
  1066 val pname_of_intr =
  1067   concl_of #> HOLogic.dest_Trueprop #> head_of #> dest_Const #> fst;
  1068 
  1069 (* partition introduction rules according to predicate name *)
  1070 fun gen_partition_rules f induct intros =
  1071   fold_rev (fn r => AList.map_entry op = (pname_of_intr (f r)) (cons r)) intros
  1072     (map (rpair [] o fst) (arities_of induct));
  1073 
  1074 val partition_rules = gen_partition_rules I;
  1075 fun partition_rules' induct = gen_partition_rules fst induct;
  1076 
  1077 fun unpartition_rules intros xs =
  1078   fold_map (fn r => AList.map_entry_yield op = (pname_of_intr r)
  1079     (fn x :: xs => (x, xs)) #>> the) intros xs |> fst;
  1080 
  1081 (* infer order of variables in intro rules from order of quantifiers in elim rule *)
  1082 fun infer_intro_vars elim arity intros =
  1083   let
  1084     val thy = theory_of_thm elim;
  1085     val _ :: cases = prems_of elim;
  1086     val used = map (fst o fst) (Term.add_vars (prop_of elim) []);
  1087     fun mtch (t, u) =
  1088       let
  1089         val params = Logic.strip_params t;
  1090         val vars =
  1091           map (Var o apfst (rpair 0))
  1092             (Name.variant_list used (map fst params) ~~ map snd params);
  1093         val ts =
  1094           map (curry subst_bounds (rev vars))
  1095             (List.drop (Logic.strip_assums_hyp t, arity));
  1096         val us = Logic.strip_imp_prems u;
  1097         val tab =
  1098           fold (Pattern.first_order_match thy) (ts ~~ us) (Vartab.empty, Vartab.empty);
  1099       in
  1100         map (Envir.subst_term tab) vars
  1101       end
  1102   in
  1103     map (mtch o apsnd prop_of) (cases ~~ intros)
  1104   end;
  1105 
  1106 
  1107 
  1108 (** package setup **)
  1109 
  1110 (* setup theory *)
  1111 
  1112 val setup =
  1113   ind_cases_setup #>
  1114   Attrib.setup @{binding mono} (Attrib.add_del mono_add mono_del)
  1115     "declaration of monotonicity rule";
  1116 
  1117 
  1118 (* outer syntax *)
  1119 
  1120 val _ = Keyword.keyword "monos";
  1121 
  1122 fun gen_ind_decl mk_def coind =
  1123   Parse.fixes -- Parse.for_fixes --
  1124   Scan.optional Parse_Spec.where_alt_specs [] --
  1125   Scan.optional (Parse.$$$ "monos" |-- Parse.!!! Parse_Spec.xthms1) []
  1126   >> (fn (((preds, params), specs), monos) =>
  1127       (snd oo gen_add_inductive mk_def true coind preds params specs monos));
  1128 
  1129 val ind_decl = gen_ind_decl add_ind_def;
  1130 
  1131 val _ =
  1132   Outer_Syntax.local_theory' "inductive" "define inductive predicates" Keyword.thy_decl
  1133     (ind_decl false);
  1134 
  1135 val _ =
  1136   Outer_Syntax.local_theory' "coinductive" "define coinductive predicates" Keyword.thy_decl
  1137     (ind_decl true);
  1138 
  1139 val _ =
  1140   Outer_Syntax.local_theory "inductive_cases"
  1141     "create simplified instances of elimination rules (improper)" Keyword.thy_script
  1142     (Parse.and_list1 Parse_Spec.specs >> (snd oo inductive_cases));
  1143 
  1144 val _ =
  1145   Outer_Syntax.local_theory "inductive_simps"
  1146     "create simplification rules for inductive predicates" Keyword.thy_script
  1147     (Parse.and_list1 Parse_Spec.specs >> (snd oo inductive_simps));
  1148 
  1149 end;