src/HOL/HOL.thy
author haftmann
Fri Nov 27 08:41:10 2009 +0100 (2009-11-27)
changeset 33963 977b94b64905
parent 33889 4328de748fb2
child 34028 1e6206763036
permissions -rw-r--r--
renamed former datatype.ML to datatype_data.ML; datatype.ML provides uniform view on datatype.ML and datatype_rep_proofs.ML
     1 (*  Title:      HOL/HOL.thy
     2     Author:     Tobias Nipkow, Markus Wenzel, and Larry Paulson
     3 *)
     4 
     5 header {* The basis of Higher-Order Logic *}
     6 
     7 theory HOL
     8 imports Pure "~~/src/Tools/Code_Generator"
     9 uses
    10   ("Tools/hologic.ML")
    11   "~~/src/Tools/IsaPlanner/zipper.ML"
    12   "~~/src/Tools/IsaPlanner/isand.ML"
    13   "~~/src/Tools/IsaPlanner/rw_tools.ML"
    14   "~~/src/Tools/IsaPlanner/rw_inst.ML"
    15   "~~/src/Tools/intuitionistic.ML"
    16   "~~/src/Tools/project_rule.ML"
    17   "~~/src/Tools/cong_tac.ML"
    18   "~~/src/Provers/hypsubst.ML"
    19   "~~/src/Provers/splitter.ML"
    20   "~~/src/Provers/classical.ML"
    21   "~~/src/Provers/blast.ML"
    22   "~~/src/Provers/clasimp.ML"
    23   "~~/src/Tools/coherent.ML"
    24   "~~/src/Tools/eqsubst.ML"
    25   "~~/src/Provers/quantifier1.ML"
    26   "Tools/res_blacklist.ML"
    27   ("Tools/simpdata.ML")
    28   "~~/src/Tools/random_word.ML"
    29   "~~/src/Tools/atomize_elim.ML"
    30   "~~/src/Tools/induct.ML"
    31   ("~~/src/Tools/induct_tacs.ML")
    32   ("Tools/recfun_codegen.ML")
    33   "~~/src/Tools/more_conv.ML"
    34 begin
    35 
    36 setup {* Intuitionistic.method_setup @{binding iprover} *}
    37 
    38 setup Res_Blacklist.setup
    39 
    40 
    41 subsection {* Primitive logic *}
    42 
    43 subsubsection {* Core syntax *}
    44 
    45 classes type
    46 defaultsort type
    47 setup {* ObjectLogic.add_base_sort @{sort type} *}
    48 
    49 arities
    50   "fun" :: (type, type) type
    51   itself :: (type) type
    52 
    53 global
    54 
    55 typedecl bool
    56 
    57 judgment
    58   Trueprop      :: "bool => prop"                   ("(_)" 5)
    59 
    60 consts
    61   Not           :: "bool => bool"                   ("~ _" [40] 40)
    62   True          :: bool
    63   False         :: bool
    64 
    65   The           :: "('a => bool) => 'a"
    66   All           :: "('a => bool) => bool"           (binder "ALL " 10)
    67   Ex            :: "('a => bool) => bool"           (binder "EX " 10)
    68   Ex1           :: "('a => bool) => bool"           (binder "EX! " 10)
    69   Let           :: "['a, 'a => 'b] => 'b"
    70 
    71   "op ="        :: "['a, 'a] => bool"               (infixl "=" 50)
    72   "op &"        :: "[bool, bool] => bool"           (infixr "&" 35)
    73   "op |"        :: "[bool, bool] => bool"           (infixr "|" 30)
    74   "op -->"      :: "[bool, bool] => bool"           (infixr "-->" 25)
    75 
    76 local
    77 
    78 consts
    79   If            :: "[bool, 'a, 'a] => 'a"           ("(if (_)/ then (_)/ else (_))" 10)
    80 
    81 
    82 subsubsection {* Additional concrete syntax *}
    83 
    84 notation (output)
    85   "op ="  (infix "=" 50)
    86 
    87 abbreviation
    88   not_equal :: "['a, 'a] => bool"  (infixl "~=" 50) where
    89   "x ~= y == ~ (x = y)"
    90 
    91 notation (output)
    92   not_equal  (infix "~=" 50)
    93 
    94 notation (xsymbols)
    95   Not  ("\<not> _" [40] 40) and
    96   "op &"  (infixr "\<and>" 35) and
    97   "op |"  (infixr "\<or>" 30) and
    98   "op -->"  (infixr "\<longrightarrow>" 25) and
    99   not_equal  (infix "\<noteq>" 50)
   100 
   101 notation (HTML output)
   102   Not  ("\<not> _" [40] 40) and
   103   "op &"  (infixr "\<and>" 35) and
   104   "op |"  (infixr "\<or>" 30) and
   105   not_equal  (infix "\<noteq>" 50)
   106 
   107 abbreviation (iff)
   108   iff :: "[bool, bool] => bool"  (infixr "<->" 25) where
   109   "A <-> B == A = B"
   110 
   111 notation (xsymbols)
   112   iff  (infixr "\<longleftrightarrow>" 25)
   113 
   114 nonterminals
   115   letbinds  letbind
   116   case_syn  cases_syn
   117 
   118 syntax
   119   "_The"        :: "[pttrn, bool] => 'a"                 ("(3THE _./ _)" [0, 10] 10)
   120 
   121   "_bind"       :: "[pttrn, 'a] => letbind"              ("(2_ =/ _)" 10)
   122   ""            :: "letbind => letbinds"                 ("_")
   123   "_binds"      :: "[letbind, letbinds] => letbinds"     ("_;/ _")
   124   "_Let"        :: "[letbinds, 'a] => 'a"                ("(let (_)/ in (_))" 10)
   125 
   126   "_case_syntax":: "['a, cases_syn] => 'b"               ("(case _ of/ _)" 10)
   127   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ =>/ _)" 10)
   128   ""            :: "case_syn => cases_syn"               ("_")
   129   "_case2"      :: "[case_syn, cases_syn] => cases_syn"  ("_/ | _")
   130 
   131 translations
   132   "THE x. P"              == "The (%x. P)"
   133   "_Let (_binds b bs) e"  == "_Let b (_Let bs e)"
   134   "let x = a in e"        == "Let a (%x. e)"
   135 
   136 print_translation {*
   137 (* To avoid eta-contraction of body: *)
   138 [("The", fn [Abs abs] =>
   139      let val (x,t) = atomic_abs_tr' abs
   140      in Syntax.const "_The" $ x $ t end)]
   141 *}
   142 
   143 syntax (xsymbols)
   144   "_case1"      :: "['a, 'b] => case_syn"                ("(2_ \<Rightarrow>/ _)" 10)
   145 
   146 notation (xsymbols)
   147   All  (binder "\<forall>" 10) and
   148   Ex  (binder "\<exists>" 10) and
   149   Ex1  (binder "\<exists>!" 10)
   150 
   151 notation (HTML output)
   152   All  (binder "\<forall>" 10) and
   153   Ex  (binder "\<exists>" 10) and
   154   Ex1  (binder "\<exists>!" 10)
   155 
   156 notation (HOL)
   157   All  (binder "! " 10) and
   158   Ex  (binder "? " 10) and
   159   Ex1  (binder "?! " 10)
   160 
   161 
   162 subsubsection {* Axioms and basic definitions *}
   163 
   164 axioms
   165   refl:           "t = (t::'a)"
   166   subst:          "s = t \<Longrightarrow> P s \<Longrightarrow> P t"
   167   ext:            "(!!x::'a. (f x ::'b) = g x) ==> (%x. f x) = (%x. g x)"
   168     -- {*Extensionality is built into the meta-logic, and this rule expresses
   169          a related property.  It is an eta-expanded version of the traditional
   170          rule, and similar to the ABS rule of HOL*}
   171 
   172   the_eq_trivial: "(THE x. x = a) = (a::'a)"
   173 
   174   impI:           "(P ==> Q) ==> P-->Q"
   175   mp:             "[| P-->Q;  P |] ==> Q"
   176 
   177 
   178 defs
   179   True_def:     "True      == ((%x::bool. x) = (%x. x))"
   180   All_def:      "All(P)    == (P = (%x. True))"
   181   Ex_def:       "Ex(P)     == !Q. (!x. P x --> Q) --> Q"
   182   False_def:    "False     == (!P. P)"
   183   not_def:      "~ P       == P-->False"
   184   and_def:      "P & Q     == !R. (P-->Q-->R) --> R"
   185   or_def:       "P | Q     == !R. (P-->R) --> (Q-->R) --> R"
   186   Ex1_def:      "Ex1(P)    == ? x. P(x) & (! y. P(y) --> y=x)"
   187 
   188 axioms
   189   iff:          "(P-->Q) --> (Q-->P) --> (P=Q)"
   190   True_or_False:  "(P=True) | (P=False)"
   191 
   192 defs
   193   Let_def [code]: "Let s f == f(s)"
   194   if_def:         "If P x y == THE z::'a. (P=True --> z=x) & (P=False --> z=y)"
   195 
   196 finalconsts
   197   "op ="
   198   "op -->"
   199   The
   200 
   201 axiomatization
   202   undefined :: 'a
   203 
   204 class default =
   205   fixes default :: 'a
   206 
   207 
   208 subsection {* Fundamental rules *}
   209 
   210 subsubsection {* Equality *}
   211 
   212 lemma sym: "s = t ==> t = s"
   213   by (erule subst) (rule refl)
   214 
   215 lemma ssubst: "t = s ==> P s ==> P t"
   216   by (drule sym) (erule subst)
   217 
   218 lemma trans: "[| r=s; s=t |] ==> r=t"
   219   by (erule subst)
   220 
   221 lemma meta_eq_to_obj_eq: 
   222   assumes meq: "A == B"
   223   shows "A = B"
   224   by (unfold meq) (rule refl)
   225 
   226 text {* Useful with @{text erule} for proving equalities from known equalities. *}
   227      (* a = b
   228         |   |
   229         c = d   *)
   230 lemma box_equals: "[| a=b;  a=c;  b=d |] ==> c=d"
   231 apply (rule trans)
   232 apply (rule trans)
   233 apply (rule sym)
   234 apply assumption+
   235 done
   236 
   237 text {* For calculational reasoning: *}
   238 
   239 lemma forw_subst: "a = b ==> P b ==> P a"
   240   by (rule ssubst)
   241 
   242 lemma back_subst: "P a ==> a = b ==> P b"
   243   by (rule subst)
   244 
   245 
   246 subsubsection {* Congruence rules for application *}
   247 
   248 text {* Similar to @{text AP_THM} in Gordon's HOL. *}
   249 lemma fun_cong: "(f::'a=>'b) = g ==> f(x)=g(x)"
   250 apply (erule subst)
   251 apply (rule refl)
   252 done
   253 
   254 text {* Similar to @{text AP_TERM} in Gordon's HOL and FOL's @{text subst_context}. *}
   255 lemma arg_cong: "x=y ==> f(x)=f(y)"
   256 apply (erule subst)
   257 apply (rule refl)
   258 done
   259 
   260 lemma arg_cong2: "\<lbrakk> a = b; c = d \<rbrakk> \<Longrightarrow> f a c = f b d"
   261 apply (erule ssubst)+
   262 apply (rule refl)
   263 done
   264 
   265 lemma cong: "[| f = g; (x::'a) = y |] ==> f x = g y"
   266 apply (erule subst)+
   267 apply (rule refl)
   268 done
   269 
   270 ML {* val cong_tac = Cong_Tac.cong_tac @{thm cong} *}
   271 
   272 
   273 subsubsection {* Equality of booleans -- iff *}
   274 
   275 lemma iffI: assumes "P ==> Q" and "Q ==> P" shows "P=Q"
   276   by (iprover intro: iff [THEN mp, THEN mp] impI assms)
   277 
   278 lemma iffD2: "[| P=Q; Q |] ==> P"
   279   by (erule ssubst)
   280 
   281 lemma rev_iffD2: "[| Q; P=Q |] ==> P"
   282   by (erule iffD2)
   283 
   284 lemma iffD1: "Q = P \<Longrightarrow> Q \<Longrightarrow> P"
   285   by (drule sym) (rule iffD2)
   286 
   287 lemma rev_iffD1: "Q \<Longrightarrow> Q = P \<Longrightarrow> P"
   288   by (drule sym) (rule rev_iffD2)
   289 
   290 lemma iffE:
   291   assumes major: "P=Q"
   292     and minor: "[| P --> Q; Q --> P |] ==> R"
   293   shows R
   294   by (iprover intro: minor impI major [THEN iffD2] major [THEN iffD1])
   295 
   296 
   297 subsubsection {*True*}
   298 
   299 lemma TrueI: "True"
   300   unfolding True_def by (rule refl)
   301 
   302 lemma eqTrueI: "P ==> P = True"
   303   by (iprover intro: iffI TrueI)
   304 
   305 lemma eqTrueE: "P = True ==> P"
   306   by (erule iffD2) (rule TrueI)
   307 
   308 
   309 subsubsection {*Universal quantifier*}
   310 
   311 lemma allI: assumes "!!x::'a. P(x)" shows "ALL x. P(x)"
   312   unfolding All_def by (iprover intro: ext eqTrueI assms)
   313 
   314 lemma spec: "ALL x::'a. P(x) ==> P(x)"
   315 apply (unfold All_def)
   316 apply (rule eqTrueE)
   317 apply (erule fun_cong)
   318 done
   319 
   320 lemma allE:
   321   assumes major: "ALL x. P(x)"
   322     and minor: "P(x) ==> R"
   323   shows R
   324   by (iprover intro: minor major [THEN spec])
   325 
   326 lemma all_dupE:
   327   assumes major: "ALL x. P(x)"
   328     and minor: "[| P(x); ALL x. P(x) |] ==> R"
   329   shows R
   330   by (iprover intro: minor major major [THEN spec])
   331 
   332 
   333 subsubsection {* False *}
   334 
   335 text {*
   336   Depends upon @{text spec}; it is impossible to do propositional
   337   logic before quantifiers!
   338 *}
   339 
   340 lemma FalseE: "False ==> P"
   341   apply (unfold False_def)
   342   apply (erule spec)
   343   done
   344 
   345 lemma False_neq_True: "False = True ==> P"
   346   by (erule eqTrueE [THEN FalseE])
   347 
   348 
   349 subsubsection {* Negation *}
   350 
   351 lemma notI:
   352   assumes "P ==> False"
   353   shows "~P"
   354   apply (unfold not_def)
   355   apply (iprover intro: impI assms)
   356   done
   357 
   358 lemma False_not_True: "False ~= True"
   359   apply (rule notI)
   360   apply (erule False_neq_True)
   361   done
   362 
   363 lemma True_not_False: "True ~= False"
   364   apply (rule notI)
   365   apply (drule sym)
   366   apply (erule False_neq_True)
   367   done
   368 
   369 lemma notE: "[| ~P;  P |] ==> R"
   370   apply (unfold not_def)
   371   apply (erule mp [THEN FalseE])
   372   apply assumption
   373   done
   374 
   375 lemma notI2: "(P \<Longrightarrow> \<not> Pa) \<Longrightarrow> (P \<Longrightarrow> Pa) \<Longrightarrow> \<not> P"
   376   by (erule notE [THEN notI]) (erule meta_mp)
   377 
   378 
   379 subsubsection {*Implication*}
   380 
   381 lemma impE:
   382   assumes "P-->Q" "P" "Q ==> R"
   383   shows "R"
   384 by (iprover intro: assms mp)
   385 
   386 (* Reduces Q to P-->Q, allowing substitution in P. *)
   387 lemma rev_mp: "[| P;  P --> Q |] ==> Q"
   388 by (iprover intro: mp)
   389 
   390 lemma contrapos_nn:
   391   assumes major: "~Q"
   392       and minor: "P==>Q"
   393   shows "~P"
   394 by (iprover intro: notI minor major [THEN notE])
   395 
   396 (*not used at all, but we already have the other 3 combinations *)
   397 lemma contrapos_pn:
   398   assumes major: "Q"
   399       and minor: "P ==> ~Q"
   400   shows "~P"
   401 by (iprover intro: notI minor major notE)
   402 
   403 lemma not_sym: "t ~= s ==> s ~= t"
   404   by (erule contrapos_nn) (erule sym)
   405 
   406 lemma eq_neq_eq_imp_neq: "[| x = a ; a ~= b; b = y |] ==> x ~= y"
   407   by (erule subst, erule ssubst, assumption)
   408 
   409 (*still used in HOLCF*)
   410 lemma rev_contrapos:
   411   assumes pq: "P ==> Q"
   412       and nq: "~Q"
   413   shows "~P"
   414 apply (rule nq [THEN contrapos_nn])
   415 apply (erule pq)
   416 done
   417 
   418 subsubsection {*Existential quantifier*}
   419 
   420 lemma exI: "P x ==> EX x::'a. P x"
   421 apply (unfold Ex_def)
   422 apply (iprover intro: allI allE impI mp)
   423 done
   424 
   425 lemma exE:
   426   assumes major: "EX x::'a. P(x)"
   427       and minor: "!!x. P(x) ==> Q"
   428   shows "Q"
   429 apply (rule major [unfolded Ex_def, THEN spec, THEN mp])
   430 apply (iprover intro: impI [THEN allI] minor)
   431 done
   432 
   433 
   434 subsubsection {*Conjunction*}
   435 
   436 lemma conjI: "[| P; Q |] ==> P&Q"
   437 apply (unfold and_def)
   438 apply (iprover intro: impI [THEN allI] mp)
   439 done
   440 
   441 lemma conjunct1: "[| P & Q |] ==> P"
   442 apply (unfold and_def)
   443 apply (iprover intro: impI dest: spec mp)
   444 done
   445 
   446 lemma conjunct2: "[| P & Q |] ==> Q"
   447 apply (unfold and_def)
   448 apply (iprover intro: impI dest: spec mp)
   449 done
   450 
   451 lemma conjE:
   452   assumes major: "P&Q"
   453       and minor: "[| P; Q |] ==> R"
   454   shows "R"
   455 apply (rule minor)
   456 apply (rule major [THEN conjunct1])
   457 apply (rule major [THEN conjunct2])
   458 done
   459 
   460 lemma context_conjI:
   461   assumes "P" "P ==> Q" shows "P & Q"
   462 by (iprover intro: conjI assms)
   463 
   464 
   465 subsubsection {*Disjunction*}
   466 
   467 lemma disjI1: "P ==> P|Q"
   468 apply (unfold or_def)
   469 apply (iprover intro: allI impI mp)
   470 done
   471 
   472 lemma disjI2: "Q ==> P|Q"
   473 apply (unfold or_def)
   474 apply (iprover intro: allI impI mp)
   475 done
   476 
   477 lemma disjE:
   478   assumes major: "P|Q"
   479       and minorP: "P ==> R"
   480       and minorQ: "Q ==> R"
   481   shows "R"
   482 by (iprover intro: minorP minorQ impI
   483                  major [unfolded or_def, THEN spec, THEN mp, THEN mp])
   484 
   485 
   486 subsubsection {*Classical logic*}
   487 
   488 lemma classical:
   489   assumes prem: "~P ==> P"
   490   shows "P"
   491 apply (rule True_or_False [THEN disjE, THEN eqTrueE])
   492 apply assumption
   493 apply (rule notI [THEN prem, THEN eqTrueI])
   494 apply (erule subst)
   495 apply assumption
   496 done
   497 
   498 lemmas ccontr = FalseE [THEN classical, standard]
   499 
   500 (*notE with premises exchanged; it discharges ~R so that it can be used to
   501   make elimination rules*)
   502 lemma rev_notE:
   503   assumes premp: "P"
   504       and premnot: "~R ==> ~P"
   505   shows "R"
   506 apply (rule ccontr)
   507 apply (erule notE [OF premnot premp])
   508 done
   509 
   510 (*Double negation law*)
   511 lemma notnotD: "~~P ==> P"
   512 apply (rule classical)
   513 apply (erule notE)
   514 apply assumption
   515 done
   516 
   517 lemma contrapos_pp:
   518   assumes p1: "Q"
   519       and p2: "~P ==> ~Q"
   520   shows "P"
   521 by (iprover intro: classical p1 p2 notE)
   522 
   523 
   524 subsubsection {*Unique existence*}
   525 
   526 lemma ex1I:
   527   assumes "P a" "!!x. P(x) ==> x=a"
   528   shows "EX! x. P(x)"
   529 by (unfold Ex1_def, iprover intro: assms exI conjI allI impI)
   530 
   531 text{*Sometimes easier to use: the premises have no shared variables.  Safe!*}
   532 lemma ex_ex1I:
   533   assumes ex_prem: "EX x. P(x)"
   534       and eq: "!!x y. [| P(x); P(y) |] ==> x=y"
   535   shows "EX! x. P(x)"
   536 by (iprover intro: ex_prem [THEN exE] ex1I eq)
   537 
   538 lemma ex1E:
   539   assumes major: "EX! x. P(x)"
   540       and minor: "!!x. [| P(x);  ALL y. P(y) --> y=x |] ==> R"
   541   shows "R"
   542 apply (rule major [unfolded Ex1_def, THEN exE])
   543 apply (erule conjE)
   544 apply (iprover intro: minor)
   545 done
   546 
   547 lemma ex1_implies_ex: "EX! x. P x ==> EX x. P x"
   548 apply (erule ex1E)
   549 apply (rule exI)
   550 apply assumption
   551 done
   552 
   553 
   554 subsubsection {*THE: definite description operator*}
   555 
   556 lemma the_equality:
   557   assumes prema: "P a"
   558       and premx: "!!x. P x ==> x=a"
   559   shows "(THE x. P x) = a"
   560 apply (rule trans [OF _ the_eq_trivial])
   561 apply (rule_tac f = "The" in arg_cong)
   562 apply (rule ext)
   563 apply (rule iffI)
   564  apply (erule premx)
   565 apply (erule ssubst, rule prema)
   566 done
   567 
   568 lemma theI:
   569   assumes "P a" and "!!x. P x ==> x=a"
   570   shows "P (THE x. P x)"
   571 by (iprover intro: assms the_equality [THEN ssubst])
   572 
   573 lemma theI': "EX! x. P x ==> P (THE x. P x)"
   574 apply (erule ex1E)
   575 apply (erule theI)
   576 apply (erule allE)
   577 apply (erule mp)
   578 apply assumption
   579 done
   580 
   581 (*Easier to apply than theI: only one occurrence of P*)
   582 lemma theI2:
   583   assumes "P a" "!!x. P x ==> x=a" "!!x. P x ==> Q x"
   584   shows "Q (THE x. P x)"
   585 by (iprover intro: assms theI)
   586 
   587 lemma the1I2: assumes "EX! x. P x" "\<And>x. P x \<Longrightarrow> Q x" shows "Q (THE x. P x)"
   588 by(iprover intro:assms(2) theI2[where P=P and Q=Q] ex1E[OF assms(1)]
   589            elim:allE impE)
   590 
   591 lemma the1_equality [elim?]: "[| EX!x. P x; P a |] ==> (THE x. P x) = a"
   592 apply (rule the_equality)
   593 apply  assumption
   594 apply (erule ex1E)
   595 apply (erule all_dupE)
   596 apply (drule mp)
   597 apply  assumption
   598 apply (erule ssubst)
   599 apply (erule allE)
   600 apply (erule mp)
   601 apply assumption
   602 done
   603 
   604 lemma the_sym_eq_trivial: "(THE y. x=y) = x"
   605 apply (rule the_equality)
   606 apply (rule refl)
   607 apply (erule sym)
   608 done
   609 
   610 
   611 subsubsection {*Classical intro rules for disjunction and existential quantifiers*}
   612 
   613 lemma disjCI:
   614   assumes "~Q ==> P" shows "P|Q"
   615 apply (rule classical)
   616 apply (iprover intro: assms disjI1 disjI2 notI elim: notE)
   617 done
   618 
   619 lemma excluded_middle: "~P | P"
   620 by (iprover intro: disjCI)
   621 
   622 text {*
   623   case distinction as a natural deduction rule.
   624   Note that @{term "~P"} is the second case, not the first
   625 *}
   626 lemma case_split [case_names True False]:
   627   assumes prem1: "P ==> Q"
   628       and prem2: "~P ==> Q"
   629   shows "Q"
   630 apply (rule excluded_middle [THEN disjE])
   631 apply (erule prem2)
   632 apply (erule prem1)
   633 done
   634 
   635 (*Classical implies (-->) elimination. *)
   636 lemma impCE:
   637   assumes major: "P-->Q"
   638       and minor: "~P ==> R" "Q ==> R"
   639   shows "R"
   640 apply (rule excluded_middle [of P, THEN disjE])
   641 apply (iprover intro: minor major [THEN mp])+
   642 done
   643 
   644 (*This version of --> elimination works on Q before P.  It works best for
   645   those cases in which P holds "almost everywhere".  Can't install as
   646   default: would break old proofs.*)
   647 lemma impCE':
   648   assumes major: "P-->Q"
   649       and minor: "Q ==> R" "~P ==> R"
   650   shows "R"
   651 apply (rule excluded_middle [of P, THEN disjE])
   652 apply (iprover intro: minor major [THEN mp])+
   653 done
   654 
   655 (*Classical <-> elimination. *)
   656 lemma iffCE:
   657   assumes major: "P=Q"
   658       and minor: "[| P; Q |] ==> R"  "[| ~P; ~Q |] ==> R"
   659   shows "R"
   660 apply (rule major [THEN iffE])
   661 apply (iprover intro: minor elim: impCE notE)
   662 done
   663 
   664 lemma exCI:
   665   assumes "ALL x. ~P(x) ==> P(a)"
   666   shows "EX x. P(x)"
   667 apply (rule ccontr)
   668 apply (iprover intro: assms exI allI notI notE [of "\<exists>x. P x"])
   669 done
   670 
   671 
   672 subsubsection {* Intuitionistic Reasoning *}
   673 
   674 lemma impE':
   675   assumes 1: "P --> Q"
   676     and 2: "Q ==> R"
   677     and 3: "P --> Q ==> P"
   678   shows R
   679 proof -
   680   from 3 and 1 have P .
   681   with 1 have Q by (rule impE)
   682   with 2 show R .
   683 qed
   684 
   685 lemma allE':
   686   assumes 1: "ALL x. P x"
   687     and 2: "P x ==> ALL x. P x ==> Q"
   688   shows Q
   689 proof -
   690   from 1 have "P x" by (rule spec)
   691   from this and 1 show Q by (rule 2)
   692 qed
   693 
   694 lemma notE':
   695   assumes 1: "~ P"
   696     and 2: "~ P ==> P"
   697   shows R
   698 proof -
   699   from 2 and 1 have P .
   700   with 1 show R by (rule notE)
   701 qed
   702 
   703 lemma TrueE: "True ==> P ==> P" .
   704 lemma notFalseE: "~ False ==> P ==> P" .
   705 
   706 lemmas [Pure.elim!] = disjE iffE FalseE conjE exE TrueE notFalseE
   707   and [Pure.intro!] = iffI conjI impI TrueI notI allI refl
   708   and [Pure.elim 2] = allE notE' impE'
   709   and [Pure.intro] = exI disjI2 disjI1
   710 
   711 lemmas [trans] = trans
   712   and [sym] = sym not_sym
   713   and [Pure.elim?] = iffD1 iffD2 impE
   714 
   715 use "Tools/hologic.ML"
   716 
   717 
   718 subsubsection {* Atomizing meta-level connectives *}
   719 
   720 axiomatization where
   721   eq_reflection: "x = y \<Longrightarrow> x \<equiv> y" (*admissible axiom*)
   722 
   723 lemma atomize_all [atomize]: "(!!x. P x) == Trueprop (ALL x. P x)"
   724 proof
   725   assume "!!x. P x"
   726   then show "ALL x. P x" ..
   727 next
   728   assume "ALL x. P x"
   729   then show "!!x. P x" by (rule allE)
   730 qed
   731 
   732 lemma atomize_imp [atomize]: "(A ==> B) == Trueprop (A --> B)"
   733 proof
   734   assume r: "A ==> B"
   735   show "A --> B" by (rule impI) (rule r)
   736 next
   737   assume "A --> B" and A
   738   then show B by (rule mp)
   739 qed
   740 
   741 lemma atomize_not: "(A ==> False) == Trueprop (~A)"
   742 proof
   743   assume r: "A ==> False"
   744   show "~A" by (rule notI) (rule r)
   745 next
   746   assume "~A" and A
   747   then show False by (rule notE)
   748 qed
   749 
   750 lemma atomize_eq [atomize]: "(x == y) == Trueprop (x = y)"
   751 proof
   752   assume "x == y"
   753   show "x = y" by (unfold `x == y`) (rule refl)
   754 next
   755   assume "x = y"
   756   then show "x == y" by (rule eq_reflection)
   757 qed
   758 
   759 lemma atomize_conj [atomize]: "(A &&& B) == Trueprop (A & B)"
   760 proof
   761   assume conj: "A &&& B"
   762   show "A & B"
   763   proof (rule conjI)
   764     from conj show A by (rule conjunctionD1)
   765     from conj show B by (rule conjunctionD2)
   766   qed
   767 next
   768   assume conj: "A & B"
   769   show "A &&& B"
   770   proof -
   771     from conj show A ..
   772     from conj show B ..
   773   qed
   774 qed
   775 
   776 lemmas [symmetric, rulify] = atomize_all atomize_imp
   777   and [symmetric, defn] = atomize_all atomize_imp atomize_eq
   778 
   779 
   780 subsubsection {* Atomizing elimination rules *}
   781 
   782 setup AtomizeElim.setup
   783 
   784 lemma atomize_exL[atomize_elim]: "(!!x. P x ==> Q) == ((EX x. P x) ==> Q)"
   785   by rule iprover+
   786 
   787 lemma atomize_conjL[atomize_elim]: "(A ==> B ==> C) == (A & B ==> C)"
   788   by rule iprover+
   789 
   790 lemma atomize_disjL[atomize_elim]: "((A ==> C) ==> (B ==> C) ==> C) == ((A | B ==> C) ==> C)"
   791   by rule iprover+
   792 
   793 lemma atomize_elimL[atomize_elim]: "(!!B. (A ==> B) ==> B) == Trueprop A" ..
   794 
   795 
   796 subsection {* Package setup *}
   797 
   798 subsubsection {* Classical Reasoner setup *}
   799 
   800 lemma imp_elim: "P --> Q ==> (~ R ==> P) ==> (Q ==> R) ==> R"
   801   by (rule classical) iprover
   802 
   803 lemma swap: "~ P ==> (~ R ==> P) ==> R"
   804   by (rule classical) iprover
   805 
   806 lemma thin_refl:
   807   "\<And>X. \<lbrakk> x=x; PROP W \<rbrakk> \<Longrightarrow> PROP W" .
   808 
   809 ML {*
   810 structure Hypsubst = HypsubstFun(
   811 struct
   812   structure Simplifier = Simplifier
   813   val dest_eq = HOLogic.dest_eq
   814   val dest_Trueprop = HOLogic.dest_Trueprop
   815   val dest_imp = HOLogic.dest_imp
   816   val eq_reflection = @{thm eq_reflection}
   817   val rev_eq_reflection = @{thm meta_eq_to_obj_eq}
   818   val imp_intr = @{thm impI}
   819   val rev_mp = @{thm rev_mp}
   820   val subst = @{thm subst}
   821   val sym = @{thm sym}
   822   val thin_refl = @{thm thin_refl};
   823   val prop_subst = @{lemma "PROP P t ==> PROP prop (x = t ==> PROP P x)"
   824                      by (unfold prop_def) (drule eq_reflection, unfold)}
   825 end);
   826 open Hypsubst;
   827 
   828 structure Classical = ClassicalFun(
   829 struct
   830   val imp_elim = @{thm imp_elim}
   831   val not_elim = @{thm notE}
   832   val swap = @{thm swap}
   833   val classical = @{thm classical}
   834   val sizef = Drule.size_of_thm
   835   val hyp_subst_tacs = [Hypsubst.hyp_subst_tac]
   836 end);
   837 
   838 structure Basic_Classical: BASIC_CLASSICAL = Classical; 
   839 open Basic_Classical;
   840 
   841 ML_Antiquote.value "claset"
   842   (Scan.succeed "Classical.claset_of (ML_Context.the_local_context ())");
   843 *}
   844 
   845 setup Classical.setup
   846 
   847 setup {*
   848 let
   849   (*prevent substitution on bool*)
   850   fun hyp_subst_tac' i thm = if i <= Thm.nprems_of thm andalso
   851     Term.exists_Const (fn ("op =", Type (_, [T, _])) => T <> Type ("bool", []) | _ => false)
   852       (nth (Thm.prems_of thm) (i - 1)) then Hypsubst.hyp_subst_tac i thm else no_tac thm;
   853 in
   854   Hypsubst.hypsubst_setup
   855   #> Context_Rules.addSWrapper (fn tac => hyp_subst_tac' ORELSE' tac)
   856 end
   857 *}
   858 
   859 declare iffI [intro!]
   860   and notI [intro!]
   861   and impI [intro!]
   862   and disjCI [intro!]
   863   and conjI [intro!]
   864   and TrueI [intro!]
   865   and refl [intro!]
   866 
   867 declare iffCE [elim!]
   868   and FalseE [elim!]
   869   and impCE [elim!]
   870   and disjE [elim!]
   871   and conjE [elim!]
   872   and conjE [elim!]
   873 
   874 declare ex_ex1I [intro!]
   875   and allI [intro!]
   876   and the_equality [intro]
   877   and exI [intro]
   878 
   879 declare exE [elim!]
   880   allE [elim]
   881 
   882 ML {* val HOL_cs = @{claset} *}
   883 
   884 lemma contrapos_np: "~ Q ==> (~ P ==> Q) ==> P"
   885   apply (erule swap)
   886   apply (erule (1) meta_mp)
   887   done
   888 
   889 declare ex_ex1I [rule del, intro! 2]
   890   and ex1I [intro]
   891 
   892 lemmas [intro?] = ext
   893   and [elim?] = ex1_implies_ex
   894 
   895 (*Better then ex1E for classical reasoner: needs no quantifier duplication!*)
   896 lemma alt_ex1E [elim!]:
   897   assumes major: "\<exists>!x. P x"
   898       and prem: "\<And>x. \<lbrakk> P x; \<forall>y y'. P y \<and> P y' \<longrightarrow> y = y' \<rbrakk> \<Longrightarrow> R"
   899   shows R
   900 apply (rule ex1E [OF major])
   901 apply (rule prem)
   902 apply (tactic {* ares_tac @{thms allI} 1 *})+
   903 apply (tactic {* etac (Classical.dup_elim @{thm allE}) 1 *})
   904 apply iprover
   905 done
   906 
   907 ML {*
   908 structure Blast = Blast
   909 (
   910   val thy = @{theory}
   911   type claset = Classical.claset
   912   val equality_name = @{const_name "op ="}
   913   val not_name = @{const_name Not}
   914   val notE = @{thm notE}
   915   val ccontr = @{thm ccontr}
   916   val contr_tac = Classical.contr_tac
   917   val dup_intr = Classical.dup_intr
   918   val hyp_subst_tac = Hypsubst.blast_hyp_subst_tac
   919   val rep_cs = Classical.rep_cs
   920   val cla_modifiers = Classical.cla_modifiers
   921   val cla_meth' = Classical.cla_meth'
   922 );
   923 val blast_tac = Blast.blast_tac;
   924 *}
   925 
   926 setup Blast.setup
   927 
   928 
   929 subsubsection {* Simplifier *}
   930 
   931 lemma eta_contract_eq: "(%s. f s) = f" ..
   932 
   933 lemma simp_thms:
   934   shows not_not: "(~ ~ P) = P"
   935   and Not_eq_iff: "((~P) = (~Q)) = (P = Q)"
   936   and
   937     "(P ~= Q) = (P = (~Q))"
   938     "(P | ~P) = True"    "(~P | P) = True"
   939     "(x = x) = True"
   940   and not_True_eq_False [code]: "(\<not> True) = False"
   941   and not_False_eq_True [code]: "(\<not> False) = True"
   942   and
   943     "(~P) ~= P"  "P ~= (~P)"
   944     "(True=P) = P"
   945   and eq_True: "(P = True) = P"
   946   and "(False=P) = (~P)"
   947   and eq_False: "(P = False) = (\<not> P)"
   948   and
   949     "(True --> P) = P"  "(False --> P) = True"
   950     "(P --> True) = True"  "(P --> P) = True"
   951     "(P --> False) = (~P)"  "(P --> ~P) = (~P)"
   952     "(P & True) = P"  "(True & P) = P"
   953     "(P & False) = False"  "(False & P) = False"
   954     "(P & P) = P"  "(P & (P & Q)) = (P & Q)"
   955     "(P & ~P) = False"    "(~P & P) = False"
   956     "(P | True) = True"  "(True | P) = True"
   957     "(P | False) = P"  "(False | P) = P"
   958     "(P | P) = P"  "(P | (P | Q)) = (P | Q)" and
   959     "(ALL x. P) = P"  "(EX x. P) = P"  "EX x. x=t"  "EX x. t=x"
   960   and
   961     "!!P. (EX x. x=t & P(x)) = P(t)"
   962     "!!P. (EX x. t=x & P(x)) = P(t)"
   963     "!!P. (ALL x. x=t --> P(x)) = P(t)"
   964     "!!P. (ALL x. t=x --> P(x)) = P(t)"
   965   by (blast, blast, blast, blast, blast, iprover+)
   966 
   967 lemma disj_absorb: "(A | A) = A"
   968   by blast
   969 
   970 lemma disj_left_absorb: "(A | (A | B)) = (A | B)"
   971   by blast
   972 
   973 lemma conj_absorb: "(A & A) = A"
   974   by blast
   975 
   976 lemma conj_left_absorb: "(A & (A & B)) = (A & B)"
   977   by blast
   978 
   979 lemma eq_ac:
   980   shows eq_commute: "(a=b) = (b=a)"
   981     and eq_left_commute: "(P=(Q=R)) = (Q=(P=R))"
   982     and eq_assoc: "((P=Q)=R) = (P=(Q=R))" by (iprover, blast+)
   983 lemma neq_commute: "(a~=b) = (b~=a)" by iprover
   984 
   985 lemma conj_comms:
   986   shows conj_commute: "(P&Q) = (Q&P)"
   987     and conj_left_commute: "(P&(Q&R)) = (Q&(P&R))" by iprover+
   988 lemma conj_assoc: "((P&Q)&R) = (P&(Q&R))" by iprover
   989 
   990 lemmas conj_ac = conj_commute conj_left_commute conj_assoc
   991 
   992 lemma disj_comms:
   993   shows disj_commute: "(P|Q) = (Q|P)"
   994     and disj_left_commute: "(P|(Q|R)) = (Q|(P|R))" by iprover+
   995 lemma disj_assoc: "((P|Q)|R) = (P|(Q|R))" by iprover
   996 
   997 lemmas disj_ac = disj_commute disj_left_commute disj_assoc
   998 
   999 lemma conj_disj_distribL: "(P&(Q|R)) = (P&Q | P&R)" by iprover
  1000 lemma conj_disj_distribR: "((P|Q)&R) = (P&R | Q&R)" by iprover
  1001 
  1002 lemma disj_conj_distribL: "(P|(Q&R)) = ((P|Q) & (P|R))" by iprover
  1003 lemma disj_conj_distribR: "((P&Q)|R) = ((P|R) & (Q|R))" by iprover
  1004 
  1005 lemma imp_conjR: "(P --> (Q&R)) = ((P-->Q) & (P-->R))" by iprover
  1006 lemma imp_conjL: "((P&Q) -->R)  = (P --> (Q --> R))" by iprover
  1007 lemma imp_disjL: "((P|Q) --> R) = ((P-->R)&(Q-->R))" by iprover
  1008 
  1009 text {* These two are specialized, but @{text imp_disj_not1} is useful in @{text "Auth/Yahalom"}. *}
  1010 lemma imp_disj_not1: "(P --> Q | R) = (~Q --> P --> R)" by blast
  1011 lemma imp_disj_not2: "(P --> Q | R) = (~R --> P --> Q)" by blast
  1012 
  1013 lemma imp_disj1: "((P-->Q)|R) = (P--> Q|R)" by blast
  1014 lemma imp_disj2: "(Q|(P-->R)) = (P--> Q|R)" by blast
  1015 
  1016 lemma imp_cong: "(P = P') ==> (P' ==> (Q = Q')) ==> ((P --> Q) = (P' --> Q'))"
  1017   by iprover
  1018 
  1019 lemma de_Morgan_disj: "(~(P | Q)) = (~P & ~Q)" by iprover
  1020 lemma de_Morgan_conj: "(~(P & Q)) = (~P | ~Q)" by blast
  1021 lemma not_imp: "(~(P --> Q)) = (P & ~Q)" by blast
  1022 lemma not_iff: "(P~=Q) = (P = (~Q))" by blast
  1023 lemma disj_not1: "(~P | Q) = (P --> Q)" by blast
  1024 lemma disj_not2: "(P | ~Q) = (Q --> P)"  -- {* changes orientation :-( *}
  1025   by blast
  1026 lemma imp_conv_disj: "(P --> Q) = ((~P) | Q)" by blast
  1027 
  1028 lemma iff_conv_conj_imp: "(P = Q) = ((P --> Q) & (Q --> P))" by iprover
  1029 
  1030 
  1031 lemma cases_simp: "((P --> Q) & (~P --> Q)) = Q"
  1032   -- {* Avoids duplication of subgoals after @{text split_if}, when the true and false *}
  1033   -- {* cases boil down to the same thing. *}
  1034   by blast
  1035 
  1036 lemma not_all: "(~ (! x. P(x))) = (? x.~P(x))" by blast
  1037 lemma imp_all: "((! x. P x) --> Q) = (? x. P x --> Q)" by blast
  1038 lemma not_ex: "(~ (? x. P(x))) = (! x.~P(x))" by iprover
  1039 lemma imp_ex: "((? x. P x) --> Q) = (! x. P x --> Q)" by iprover
  1040 lemma all_not_ex: "(ALL x. P x) = (~ (EX x. ~ P x ))" by blast
  1041 
  1042 declare All_def [noatp]
  1043 
  1044 lemma ex_disj_distrib: "(? x. P(x) | Q(x)) = ((? x. P(x)) | (? x. Q(x)))" by iprover
  1045 lemma all_conj_distrib: "(!x. P(x) & Q(x)) = ((! x. P(x)) & (! x. Q(x)))" by iprover
  1046 
  1047 text {*
  1048   \medskip The @{text "&"} congruence rule: not included by default!
  1049   May slow rewrite proofs down by as much as 50\% *}
  1050 
  1051 lemma conj_cong:
  1052     "(P = P') ==> (P' ==> (Q = Q')) ==> ((P & Q) = (P' & Q'))"
  1053   by iprover
  1054 
  1055 lemma rev_conj_cong:
  1056     "(Q = Q') ==> (Q' ==> (P = P')) ==> ((P & Q) = (P' & Q'))"
  1057   by iprover
  1058 
  1059 text {* The @{text "|"} congruence rule: not included by default! *}
  1060 
  1061 lemma disj_cong:
  1062     "(P = P') ==> (~P' ==> (Q = Q')) ==> ((P | Q) = (P' | Q'))"
  1063   by blast
  1064 
  1065 
  1066 text {* \medskip if-then-else rules *}
  1067 
  1068 lemma if_True [code]: "(if True then x else y) = x"
  1069   by (unfold if_def) blast
  1070 
  1071 lemma if_False [code]: "(if False then x else y) = y"
  1072   by (unfold if_def) blast
  1073 
  1074 lemma if_P: "P ==> (if P then x else y) = x"
  1075   by (unfold if_def) blast
  1076 
  1077 lemma if_not_P: "~P ==> (if P then x else y) = y"
  1078   by (unfold if_def) blast
  1079 
  1080 lemma split_if: "P (if Q then x else y) = ((Q --> P(x)) & (~Q --> P(y)))"
  1081   apply (rule case_split [of Q])
  1082    apply (simplesubst if_P)
  1083     prefer 3 apply (simplesubst if_not_P, blast+)
  1084   done
  1085 
  1086 lemma split_if_asm: "P (if Q then x else y) = (~((Q & ~P x) | (~Q & ~P y)))"
  1087 by (simplesubst split_if, blast)
  1088 
  1089 lemmas if_splits [noatp] = split_if split_if_asm
  1090 
  1091 lemma if_cancel: "(if c then x else x) = x"
  1092 by (simplesubst split_if, blast)
  1093 
  1094 lemma if_eq_cancel: "(if x = y then y else x) = x"
  1095 by (simplesubst split_if, blast)
  1096 
  1097 lemma if_bool_eq_conj: "(if P then Q else R) = ((P-->Q) & (~P-->R))"
  1098   -- {* This form is useful for expanding @{text "if"}s on the RIGHT of the @{text "==>"} symbol. *}
  1099   by (rule split_if)
  1100 
  1101 lemma if_bool_eq_disj: "(if P then Q else R) = ((P&Q) | (~P&R))"
  1102   -- {* And this form is useful for expanding @{text "if"}s on the LEFT. *}
  1103   apply (simplesubst split_if, blast)
  1104   done
  1105 
  1106 lemma Eq_TrueI: "P ==> P == True" by (unfold atomize_eq) iprover
  1107 lemma Eq_FalseI: "~P ==> P == False" by (unfold atomize_eq) iprover
  1108 
  1109 text {* \medskip let rules for simproc *}
  1110 
  1111 lemma Let_folded: "f x \<equiv> g x \<Longrightarrow>  Let x f \<equiv> Let x g"
  1112   by (unfold Let_def)
  1113 
  1114 lemma Let_unfold: "f x \<equiv> g \<Longrightarrow>  Let x f \<equiv> g"
  1115   by (unfold Let_def)
  1116 
  1117 text {*
  1118   The following copy of the implication operator is useful for
  1119   fine-tuning congruence rules.  It instructs the simplifier to simplify
  1120   its premise.
  1121 *}
  1122 
  1123 constdefs
  1124   simp_implies :: "[prop, prop] => prop"  (infixr "=simp=>" 1)
  1125   [code del]: "simp_implies \<equiv> op ==>"
  1126 
  1127 lemma simp_impliesI:
  1128   assumes PQ: "(PROP P \<Longrightarrow> PROP Q)"
  1129   shows "PROP P =simp=> PROP Q"
  1130   apply (unfold simp_implies_def)
  1131   apply (rule PQ)
  1132   apply assumption
  1133   done
  1134 
  1135 lemma simp_impliesE:
  1136   assumes PQ: "PROP P =simp=> PROP Q"
  1137   and P: "PROP P"
  1138   and QR: "PROP Q \<Longrightarrow> PROP R"
  1139   shows "PROP R"
  1140   apply (rule QR)
  1141   apply (rule PQ [unfolded simp_implies_def])
  1142   apply (rule P)
  1143   done
  1144 
  1145 lemma simp_implies_cong:
  1146   assumes PP' :"PROP P == PROP P'"
  1147   and P'QQ': "PROP P' ==> (PROP Q == PROP Q')"
  1148   shows "(PROP P =simp=> PROP Q) == (PROP P' =simp=> PROP Q')"
  1149 proof (unfold simp_implies_def, rule equal_intr_rule)
  1150   assume PQ: "PROP P \<Longrightarrow> PROP Q"
  1151   and P': "PROP P'"
  1152   from PP' [symmetric] and P' have "PROP P"
  1153     by (rule equal_elim_rule1)
  1154   then have "PROP Q" by (rule PQ)
  1155   with P'QQ' [OF P'] show "PROP Q'" by (rule equal_elim_rule1)
  1156 next
  1157   assume P'Q': "PROP P' \<Longrightarrow> PROP Q'"
  1158   and P: "PROP P"
  1159   from PP' and P have P': "PROP P'" by (rule equal_elim_rule1)
  1160   then have "PROP Q'" by (rule P'Q')
  1161   with P'QQ' [OF P', symmetric] show "PROP Q"
  1162     by (rule equal_elim_rule1)
  1163 qed
  1164 
  1165 lemma uncurry:
  1166   assumes "P \<longrightarrow> Q \<longrightarrow> R"
  1167   shows "P \<and> Q \<longrightarrow> R"
  1168   using assms by blast
  1169 
  1170 lemma iff_allI:
  1171   assumes "\<And>x. P x = Q x"
  1172   shows "(\<forall>x. P x) = (\<forall>x. Q x)"
  1173   using assms by blast
  1174 
  1175 lemma iff_exI:
  1176   assumes "\<And>x. P x = Q x"
  1177   shows "(\<exists>x. P x) = (\<exists>x. Q x)"
  1178   using assms by blast
  1179 
  1180 lemma all_comm:
  1181   "(\<forall>x y. P x y) = (\<forall>y x. P x y)"
  1182   by blast
  1183 
  1184 lemma ex_comm:
  1185   "(\<exists>x y. P x y) = (\<exists>y x. P x y)"
  1186   by blast
  1187 
  1188 use "Tools/simpdata.ML"
  1189 ML {* open Simpdata *}
  1190 
  1191 setup {*
  1192   Simplifier.method_setup Splitter.split_modifiers
  1193   #> Simplifier.map_simpset (K Simpdata.simpset_simprocs)
  1194   #> Splitter.setup
  1195   #> clasimp_setup
  1196   #> EqSubst.setup
  1197 *}
  1198 
  1199 text {* Simproc for proving @{text "(y = x) == False"} from premise @{text "~(x = y)"}: *}
  1200 
  1201 simproc_setup neq ("x = y") = {* fn _ =>
  1202 let
  1203   val neq_to_EQ_False = @{thm not_sym} RS @{thm Eq_FalseI};
  1204   fun is_neq eq lhs rhs thm =
  1205     (case Thm.prop_of thm of
  1206       _ $ (Not $ (eq' $ l' $ r')) =>
  1207         Not = HOLogic.Not andalso eq' = eq andalso
  1208         r' aconv lhs andalso l' aconv rhs
  1209     | _ => false);
  1210   fun proc ss ct =
  1211     (case Thm.term_of ct of
  1212       eq $ lhs $ rhs =>
  1213         (case find_first (is_neq eq lhs rhs) (Simplifier.prems_of_ss ss) of
  1214           SOME thm => SOME (thm RS neq_to_EQ_False)
  1215         | NONE => NONE)
  1216      | _ => NONE);
  1217 in proc end;
  1218 *}
  1219 
  1220 simproc_setup let_simp ("Let x f") = {*
  1221 let
  1222   val (f_Let_unfold, x_Let_unfold) =
  1223     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_unfold}
  1224     in (cterm_of @{theory} f, cterm_of @{theory} x) end
  1225   val (f_Let_folded, x_Let_folded) =
  1226     let val [(_ $ (f $ x) $ _)] = prems_of @{thm Let_folded}
  1227     in (cterm_of @{theory} f, cterm_of @{theory} x) end;
  1228   val g_Let_folded =
  1229     let val [(_ $ _ $ (g $ _))] = prems_of @{thm Let_folded}
  1230     in cterm_of @{theory} g end;
  1231   fun count_loose (Bound i) k = if i >= k then 1 else 0
  1232     | count_loose (s $ t) k = count_loose s k + count_loose t k
  1233     | count_loose (Abs (_, _, t)) k = count_loose  t (k + 1)
  1234     | count_loose _ _ = 0;
  1235   fun is_trivial_let (Const (@{const_name Let}, _) $ x $ t) =
  1236    case t
  1237     of Abs (_, _, t') => count_loose t' 0 <= 1
  1238      | _ => true;
  1239 in fn _ => fn ss => fn ct => if is_trivial_let (Thm.term_of ct)
  1240   then SOME @{thm Let_def} (*no or one ocurrence of bound variable*)
  1241   else let (*Norbert Schirmer's case*)
  1242     val ctxt = Simplifier.the_context ss;
  1243     val thy = ProofContext.theory_of ctxt;
  1244     val t = Thm.term_of ct;
  1245     val ([t'], ctxt') = Variable.import_terms false [t] ctxt;
  1246   in Option.map (hd o Variable.export ctxt' ctxt o single)
  1247     (case t' of Const (@{const_name Let},_) $ x $ f => (* x and f are already in normal form *)
  1248       if is_Free x orelse is_Bound x orelse is_Const x
  1249       then SOME @{thm Let_def}
  1250       else
  1251         let
  1252           val n = case f of (Abs (x, _, _)) => x | _ => "x";
  1253           val cx = cterm_of thy x;
  1254           val {T = xT, ...} = rep_cterm cx;
  1255           val cf = cterm_of thy f;
  1256           val fx_g = Simplifier.rewrite ss (Thm.capply cf cx);
  1257           val (_ $ _ $ g) = prop_of fx_g;
  1258           val g' = abstract_over (x,g);
  1259         in (if (g aconv g')
  1260              then
  1261                 let
  1262                   val rl =
  1263                     cterm_instantiate [(f_Let_unfold, cf), (x_Let_unfold, cx)] @{thm Let_unfold};
  1264                 in SOME (rl OF [fx_g]) end
  1265              else if Term.betapply (f, x) aconv g then NONE (*avoid identity conversion*)
  1266              else let
  1267                    val abs_g'= Abs (n,xT,g');
  1268                    val g'x = abs_g'$x;
  1269                    val g_g'x = symmetric (beta_conversion false (cterm_of thy g'x));
  1270                    val rl = cterm_instantiate
  1271                              [(f_Let_folded, cterm_of thy f), (x_Let_folded, cx),
  1272                               (g_Let_folded, cterm_of thy abs_g')]
  1273                              @{thm Let_folded};
  1274                  in SOME (rl OF [transitive fx_g g_g'x])
  1275                  end)
  1276         end
  1277     | _ => NONE)
  1278   end
  1279 end *}
  1280 
  1281 lemma True_implies_equals: "(True \<Longrightarrow> PROP P) \<equiv> PROP P"
  1282 proof
  1283   assume "True \<Longrightarrow> PROP P"
  1284   from this [OF TrueI] show "PROP P" .
  1285 next
  1286   assume "PROP P"
  1287   then show "PROP P" .
  1288 qed
  1289 
  1290 lemma ex_simps:
  1291   "!!P Q. (EX x. P x & Q)   = ((EX x. P x) & Q)"
  1292   "!!P Q. (EX x. P & Q x)   = (P & (EX x. Q x))"
  1293   "!!P Q. (EX x. P x | Q)   = ((EX x. P x) | Q)"
  1294   "!!P Q. (EX x. P | Q x)   = (P | (EX x. Q x))"
  1295   "!!P Q. (EX x. P x --> Q) = ((ALL x. P x) --> Q)"
  1296   "!!P Q. (EX x. P --> Q x) = (P --> (EX x. Q x))"
  1297   -- {* Miniscoping: pushing in existential quantifiers. *}
  1298   by (iprover | blast)+
  1299 
  1300 lemma all_simps:
  1301   "!!P Q. (ALL x. P x & Q)   = ((ALL x. P x) & Q)"
  1302   "!!P Q. (ALL x. P & Q x)   = (P & (ALL x. Q x))"
  1303   "!!P Q. (ALL x. P x | Q)   = ((ALL x. P x) | Q)"
  1304   "!!P Q. (ALL x. P | Q x)   = (P | (ALL x. Q x))"
  1305   "!!P Q. (ALL x. P x --> Q) = ((EX x. P x) --> Q)"
  1306   "!!P Q. (ALL x. P --> Q x) = (P --> (ALL x. Q x))"
  1307   -- {* Miniscoping: pushing in universal quantifiers. *}
  1308   by (iprover | blast)+
  1309 
  1310 lemmas [simp] =
  1311   triv_forall_equality (*prunes params*)
  1312   True_implies_equals  (*prune asms `True'*)
  1313   if_True
  1314   if_False
  1315   if_cancel
  1316   if_eq_cancel
  1317   imp_disjL
  1318   (*In general it seems wrong to add distributive laws by default: they
  1319     might cause exponential blow-up.  But imp_disjL has been in for a while
  1320     and cannot be removed without affecting existing proofs.  Moreover,
  1321     rewriting by "(P|Q --> R) = ((P-->R)&(Q-->R))" might be justified on the
  1322     grounds that it allows simplification of R in the two cases.*)
  1323   conj_assoc
  1324   disj_assoc
  1325   de_Morgan_conj
  1326   de_Morgan_disj
  1327   imp_disj1
  1328   imp_disj2
  1329   not_imp
  1330   disj_not1
  1331   not_all
  1332   not_ex
  1333   cases_simp
  1334   the_eq_trivial
  1335   the_sym_eq_trivial
  1336   ex_simps
  1337   all_simps
  1338   simp_thms
  1339 
  1340 lemmas [cong] = imp_cong simp_implies_cong
  1341 lemmas [split] = split_if
  1342 
  1343 ML {* val HOL_ss = @{simpset} *}
  1344 
  1345 text {* Simplifies x assuming c and y assuming ~c *}
  1346 lemma if_cong:
  1347   assumes "b = c"
  1348       and "c \<Longrightarrow> x = u"
  1349       and "\<not> c \<Longrightarrow> y = v"
  1350   shows "(if b then x else y) = (if c then u else v)"
  1351   unfolding if_def using assms by simp
  1352 
  1353 text {* Prevents simplification of x and y:
  1354   faster and allows the execution of functional programs. *}
  1355 lemma if_weak_cong [cong]:
  1356   assumes "b = c"
  1357   shows "(if b then x else y) = (if c then x else y)"
  1358   using assms by (rule arg_cong)
  1359 
  1360 text {* Prevents simplification of t: much faster *}
  1361 lemma let_weak_cong:
  1362   assumes "a = b"
  1363   shows "(let x = a in t x) = (let x = b in t x)"
  1364   using assms by (rule arg_cong)
  1365 
  1366 text {* To tidy up the result of a simproc.  Only the RHS will be simplified. *}
  1367 lemma eq_cong2:
  1368   assumes "u = u'"
  1369   shows "(t \<equiv> u) \<equiv> (t \<equiv> u')"
  1370   using assms by simp
  1371 
  1372 lemma if_distrib:
  1373   "f (if c then x else y) = (if c then f x else f y)"
  1374   by simp
  1375 
  1376 text {* This lemma restricts the effect of the rewrite rule u=v to the left-hand
  1377   side of an equality.  Used in @{text "{Integ,Real}/simproc.ML"} *}
  1378 lemma restrict_to_left:
  1379   assumes "x = y"
  1380   shows "(x = z) = (y = z)"
  1381   using assms by simp
  1382 
  1383 
  1384 subsubsection {* Generic cases and induction *}
  1385 
  1386 text {* Rule projections: *}
  1387 
  1388 ML {*
  1389 structure Project_Rule = Project_Rule
  1390 (
  1391   val conjunct1 = @{thm conjunct1}
  1392   val conjunct2 = @{thm conjunct2}
  1393   val mp = @{thm mp}
  1394 )
  1395 *}
  1396 
  1397 constdefs
  1398   induct_forall where "induct_forall P == \<forall>x. P x"
  1399   induct_implies where "induct_implies A B == A \<longrightarrow> B"
  1400   induct_equal where "induct_equal x y == x = y"
  1401   induct_conj where "induct_conj A B == A \<and> B"
  1402 
  1403 lemma induct_forall_eq: "(!!x. P x) == Trueprop (induct_forall (\<lambda>x. P x))"
  1404   by (unfold atomize_all induct_forall_def)
  1405 
  1406 lemma induct_implies_eq: "(A ==> B) == Trueprop (induct_implies A B)"
  1407   by (unfold atomize_imp induct_implies_def)
  1408 
  1409 lemma induct_equal_eq: "(x == y) == Trueprop (induct_equal x y)"
  1410   by (unfold atomize_eq induct_equal_def)
  1411 
  1412 lemma induct_conj_eq: "(A &&& B) == Trueprop (induct_conj A B)"
  1413   by (unfold atomize_conj induct_conj_def)
  1414 
  1415 lemmas induct_atomize = induct_forall_eq induct_implies_eq induct_equal_eq induct_conj_eq
  1416 lemmas induct_rulify [symmetric, standard] = induct_atomize
  1417 lemmas induct_rulify_fallback =
  1418   induct_forall_def induct_implies_def induct_equal_def induct_conj_def
  1419 
  1420 
  1421 lemma induct_forall_conj: "induct_forall (\<lambda>x. induct_conj (A x) (B x)) =
  1422     induct_conj (induct_forall A) (induct_forall B)"
  1423   by (unfold induct_forall_def induct_conj_def) iprover
  1424 
  1425 lemma induct_implies_conj: "induct_implies C (induct_conj A B) =
  1426     induct_conj (induct_implies C A) (induct_implies C B)"
  1427   by (unfold induct_implies_def induct_conj_def) iprover
  1428 
  1429 lemma induct_conj_curry: "(induct_conj A B ==> PROP C) == (A ==> B ==> PROP C)"
  1430 proof
  1431   assume r: "induct_conj A B ==> PROP C" and A B
  1432   show "PROP C" by (rule r) (simp add: induct_conj_def `A` `B`)
  1433 next
  1434   assume r: "A ==> B ==> PROP C" and "induct_conj A B"
  1435   show "PROP C" by (rule r) (simp_all add: `induct_conj A B` [unfolded induct_conj_def])
  1436 qed
  1437 
  1438 lemmas induct_conj = induct_forall_conj induct_implies_conj induct_conj_curry
  1439 
  1440 hide const induct_forall induct_implies induct_equal induct_conj
  1441 
  1442 text {* Method setup. *}
  1443 
  1444 ML {*
  1445 structure Induct = Induct
  1446 (
  1447   val cases_default = @{thm case_split}
  1448   val atomize = @{thms induct_atomize}
  1449   val rulify = @{thms induct_rulify}
  1450   val rulify_fallback = @{thms induct_rulify_fallback}
  1451 )
  1452 *}
  1453 
  1454 setup Induct.setup
  1455 
  1456 use "~~/src/Tools/induct_tacs.ML"
  1457 setup InductTacs.setup
  1458 
  1459 
  1460 subsubsection {* Coherent logic *}
  1461 
  1462 ML {*
  1463 structure Coherent = Coherent
  1464 (
  1465   val atomize_elimL = @{thm atomize_elimL}
  1466   val atomize_exL = @{thm atomize_exL}
  1467   val atomize_conjL = @{thm atomize_conjL}
  1468   val atomize_disjL = @{thm atomize_disjL}
  1469   val operator_names =
  1470     [@{const_name "op |"}, @{const_name "op &"}, @{const_name "Ex"}]
  1471 );
  1472 *}
  1473 
  1474 setup Coherent.setup
  1475 
  1476 
  1477 subsubsection {* Reorienting equalities *}
  1478 
  1479 ML {*
  1480 signature REORIENT_PROC =
  1481 sig
  1482   val add : (term -> bool) -> theory -> theory
  1483   val proc : morphism -> simpset -> cterm -> thm option
  1484 end;
  1485 
  1486 structure Reorient_Proc : REORIENT_PROC =
  1487 struct
  1488   structure Data = Theory_Data
  1489   (
  1490     type T = ((term -> bool) * stamp) list;
  1491     val empty = [];
  1492     val extend = I;
  1493     fun merge data : T = Library.merge (eq_snd op =) data;
  1494   );
  1495   fun add m = Data.map (cons (m, stamp ()));
  1496   fun matches thy t = exists (fn (m, _) => m t) (Data.get thy);
  1497 
  1498   val meta_reorient = @{thm eq_commute [THEN eq_reflection]};
  1499   fun proc phi ss ct =
  1500     let
  1501       val ctxt = Simplifier.the_context ss;
  1502       val thy = ProofContext.theory_of ctxt;
  1503     in
  1504       case Thm.term_of ct of
  1505         (_ $ t $ u) => if matches thy u then NONE else SOME meta_reorient
  1506       | _ => NONE
  1507     end;
  1508 end;
  1509 *}
  1510 
  1511 
  1512 subsection {* Other simple lemmas and lemma duplicates *}
  1513 
  1514 lemma ex1_eq [iff]: "EX! x. x = t" "EX! x. t = x"
  1515   by blast+
  1516 
  1517 lemma choice_eq: "(ALL x. EX! y. P x y) = (EX! f. ALL x. P x (f x))"
  1518   apply (rule iffI)
  1519   apply (rule_tac a = "%x. THE y. P x y" in ex1I)
  1520   apply (fast dest!: theI')
  1521   apply (fast intro: ext the1_equality [symmetric])
  1522   apply (erule ex1E)
  1523   apply (rule allI)
  1524   apply (rule ex1I)
  1525   apply (erule spec)
  1526   apply (erule_tac x = "%z. if z = x then y else f z" in allE)
  1527   apply (erule impE)
  1528   apply (rule allI)
  1529   apply (case_tac "xa = x")
  1530   apply (drule_tac [3] x = x in fun_cong, simp_all)
  1531   done
  1532 
  1533 lemmas eq_sym_conv = eq_commute
  1534 
  1535 lemma nnf_simps:
  1536   "(\<not>(P \<and> Q)) = (\<not> P \<or> \<not> Q)" "(\<not> (P \<or> Q)) = (\<not> P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)" 
  1537   "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not>(P = Q)) = ((P \<and> \<not> Q) \<or> (\<not>P \<and> Q))" 
  1538   "(\<not> \<not>(P)) = P"
  1539 by blast+
  1540 
  1541 
  1542 subsection {* Generic classes and algebraic operations *}
  1543 
  1544 class zero = 
  1545   fixes zero :: 'a  ("0")
  1546 
  1547 class one =
  1548   fixes one  :: 'a  ("1")
  1549 
  1550 lemma Let_0 [simp]: "Let 0 f = f 0"
  1551   unfolding Let_def ..
  1552 
  1553 lemma Let_1 [simp]: "Let 1 f = f 1"
  1554   unfolding Let_def ..
  1555 
  1556 setup {*
  1557   Reorient_Proc.add
  1558     (fn Const(@{const_name HOL.zero}, _) => true
  1559       | Const(@{const_name HOL.one}, _) => true
  1560       | _ => false)
  1561 *}
  1562 
  1563 simproc_setup reorient_zero ("0 = x") = Reorient_Proc.proc
  1564 simproc_setup reorient_one ("1 = x") = Reorient_Proc.proc
  1565 
  1566 typed_print_translation {*
  1567 let
  1568   fun tr' c = (c, fn show_sorts => fn T => fn ts =>
  1569     if (not o null) ts orelse T = dummyT
  1570       orelse not (! show_types) andalso can Term.dest_Type T
  1571     then raise Match
  1572     else Syntax.const Syntax.constrainC $ Syntax.const c $ Syntax.term_of_typ show_sorts T);
  1573 in map tr' [@{const_syntax HOL.one}, @{const_syntax HOL.zero}] end;
  1574 *} -- {* show types that are presumably too general *}
  1575 
  1576 hide (open) const zero one
  1577 
  1578 class plus =
  1579   fixes plus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "+" 65)
  1580 
  1581 class minus =
  1582   fixes minus :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "-" 65)
  1583 
  1584 class uminus =
  1585   fixes uminus :: "'a \<Rightarrow> 'a"  ("- _" [81] 80)
  1586 
  1587 class times =
  1588   fixes times :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "*" 70)
  1589 
  1590 class inverse =
  1591   fixes inverse :: "'a \<Rightarrow> 'a"
  1592     and divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"  (infixl "'/" 70)
  1593 
  1594 class abs =
  1595   fixes abs :: "'a \<Rightarrow> 'a"
  1596 begin
  1597 
  1598 notation (xsymbols)
  1599   abs  ("\<bar>_\<bar>")
  1600 
  1601 notation (HTML output)
  1602   abs  ("\<bar>_\<bar>")
  1603 
  1604 end
  1605 
  1606 class sgn =
  1607   fixes sgn :: "'a \<Rightarrow> 'a"
  1608 
  1609 class ord =
  1610   fixes less_eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1611     and less :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1612 begin
  1613 
  1614 notation
  1615   less_eq  ("op <=") and
  1616   less_eq  ("(_/ <= _)" [51, 51] 50) and
  1617   less  ("op <") and
  1618   less  ("(_/ < _)"  [51, 51] 50)
  1619   
  1620 notation (xsymbols)
  1621   less_eq  ("op \<le>") and
  1622   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
  1623 
  1624 notation (HTML output)
  1625   less_eq  ("op \<le>") and
  1626   less_eq  ("(_/ \<le> _)"  [51, 51] 50)
  1627 
  1628 abbreviation (input)
  1629   greater_eq  (infix ">=" 50) where
  1630   "x >= y \<equiv> y <= x"
  1631 
  1632 notation (input)
  1633   greater_eq  (infix "\<ge>" 50)
  1634 
  1635 abbreviation (input)
  1636   greater  (infix ">" 50) where
  1637   "x > y \<equiv> y < x"
  1638 
  1639 end
  1640 
  1641 syntax
  1642   "_index1"  :: index    ("\<^sub>1")
  1643 translations
  1644   (index) "\<^sub>1" => (index) "\<^bsub>\<struct>\<^esub>"
  1645 
  1646 lemma mk_left_commute:
  1647   fixes f (infix "\<otimes>" 60)
  1648   assumes a: "\<And>x y z. (x \<otimes> y) \<otimes> z = x \<otimes> (y \<otimes> z)" and
  1649           c: "\<And>x y. x \<otimes> y = y \<otimes> x"
  1650   shows "x \<otimes> (y \<otimes> z) = y \<otimes> (x \<otimes> z)"
  1651   by (rule trans [OF trans [OF c a] arg_cong [OF c, of "f y"]])
  1652 
  1653 
  1654 subsection {* Basic ML bindings *}
  1655 
  1656 ML {*
  1657 val FalseE = @{thm FalseE}
  1658 val Let_def = @{thm Let_def}
  1659 val TrueI = @{thm TrueI}
  1660 val allE = @{thm allE}
  1661 val allI = @{thm allI}
  1662 val all_dupE = @{thm all_dupE}
  1663 val arg_cong = @{thm arg_cong}
  1664 val box_equals = @{thm box_equals}
  1665 val ccontr = @{thm ccontr}
  1666 val classical = @{thm classical}
  1667 val conjE = @{thm conjE}
  1668 val conjI = @{thm conjI}
  1669 val conjunct1 = @{thm conjunct1}
  1670 val conjunct2 = @{thm conjunct2}
  1671 val disjCI = @{thm disjCI}
  1672 val disjE = @{thm disjE}
  1673 val disjI1 = @{thm disjI1}
  1674 val disjI2 = @{thm disjI2}
  1675 val eq_reflection = @{thm eq_reflection}
  1676 val ex1E = @{thm ex1E}
  1677 val ex1I = @{thm ex1I}
  1678 val ex1_implies_ex = @{thm ex1_implies_ex}
  1679 val exE = @{thm exE}
  1680 val exI = @{thm exI}
  1681 val excluded_middle = @{thm excluded_middle}
  1682 val ext = @{thm ext}
  1683 val fun_cong = @{thm fun_cong}
  1684 val iffD1 = @{thm iffD1}
  1685 val iffD2 = @{thm iffD2}
  1686 val iffI = @{thm iffI}
  1687 val impE = @{thm impE}
  1688 val impI = @{thm impI}
  1689 val meta_eq_to_obj_eq = @{thm meta_eq_to_obj_eq}
  1690 val mp = @{thm mp}
  1691 val notE = @{thm notE}
  1692 val notI = @{thm notI}
  1693 val not_all = @{thm not_all}
  1694 val not_ex = @{thm not_ex}
  1695 val not_iff = @{thm not_iff}
  1696 val not_not = @{thm not_not}
  1697 val not_sym = @{thm not_sym}
  1698 val refl = @{thm refl}
  1699 val rev_mp = @{thm rev_mp}
  1700 val spec = @{thm spec}
  1701 val ssubst = @{thm ssubst}
  1702 val subst = @{thm subst}
  1703 val sym = @{thm sym}
  1704 val trans = @{thm trans}
  1705 *}
  1706 
  1707 
  1708 subsection {* Code generator setup *}
  1709 
  1710 subsubsection {* SML code generator setup *}
  1711 
  1712 use "Tools/recfun_codegen.ML"
  1713 
  1714 setup {*
  1715   Codegen.setup
  1716   #> RecfunCodegen.setup
  1717   #> Codegen.map_unfold (K HOL_basic_ss)
  1718 *}
  1719 
  1720 types_code
  1721   "bool"  ("bool")
  1722 attach (term_of) {*
  1723 fun term_of_bool b = if b then HOLogic.true_const else HOLogic.false_const;
  1724 *}
  1725 attach (test) {*
  1726 fun gen_bool i =
  1727   let val b = one_of [false, true]
  1728   in (b, fn () => term_of_bool b) end;
  1729 *}
  1730   "prop"  ("bool")
  1731 attach (term_of) {*
  1732 fun term_of_prop b =
  1733   HOLogic.mk_Trueprop (if b then HOLogic.true_const else HOLogic.false_const);
  1734 *}
  1735 
  1736 consts_code
  1737   "Trueprop" ("(_)")
  1738   "True"    ("true")
  1739   "False"   ("false")
  1740   "Not"     ("Bool.not")
  1741   "op |"    ("(_ orelse/ _)")
  1742   "op &"    ("(_ andalso/ _)")
  1743   "If"      ("(if _/ then _/ else _)")
  1744 
  1745 setup {*
  1746 let
  1747 
  1748 fun eq_codegen thy defs dep thyname b t gr =
  1749     (case strip_comb t of
  1750        (Const ("op =", Type (_, [Type ("fun", _), _])), _) => NONE
  1751      | (Const ("op =", _), [t, u]) =>
  1752           let
  1753             val (pt, gr') = Codegen.invoke_codegen thy defs dep thyname false t gr;
  1754             val (pu, gr'') = Codegen.invoke_codegen thy defs dep thyname false u gr';
  1755             val (_, gr''') = Codegen.invoke_tycodegen thy defs dep thyname false HOLogic.boolT gr'';
  1756           in
  1757             SOME (Codegen.parens
  1758               (Pretty.block [pt, Codegen.str " =", Pretty.brk 1, pu]), gr''')
  1759           end
  1760      | (t as Const ("op =", _), ts) => SOME (Codegen.invoke_codegen
  1761          thy defs dep thyname b (Codegen.eta_expand t ts 2) gr)
  1762      | _ => NONE);
  1763 
  1764 in
  1765   Codegen.add_codegen "eq_codegen" eq_codegen
  1766 end
  1767 *}
  1768 
  1769 subsubsection {* Generic code generator preprocessor setup *}
  1770 
  1771 setup {*
  1772   Code_Preproc.map_pre (K HOL_basic_ss)
  1773   #> Code_Preproc.map_post (K HOL_basic_ss)
  1774 *}
  1775 
  1776 subsubsection {* Equality *}
  1777 
  1778 class eq =
  1779   fixes eq :: "'a \<Rightarrow> 'a \<Rightarrow> bool"
  1780   assumes eq_equals: "eq x y \<longleftrightarrow> x = y"
  1781 begin
  1782 
  1783 lemma eq [code_unfold, code_inline del]: "eq = (op =)"
  1784   by (rule ext eq_equals)+
  1785 
  1786 lemma eq_refl: "eq x x \<longleftrightarrow> True"
  1787   unfolding eq by rule+
  1788 
  1789 lemma equals_eq: "(op =) \<equiv> eq"
  1790   by (rule eq_reflection) (rule ext, rule ext, rule sym, rule eq_equals)
  1791 
  1792 declare equals_eq [symmetric, code_post]
  1793 
  1794 end
  1795 
  1796 declare equals_eq [code]
  1797 
  1798 setup {*
  1799   Code_Preproc.map_pre (fn simpset =>
  1800     simpset addsimprocs [Simplifier.simproc_i @{theory} "eq" [@{term "op ="}]
  1801       (fn thy => fn _ => fn t as Const (_, T) => case strip_type T
  1802         of ((T as Type _) :: _, _) => SOME @{thm equals_eq}
  1803          | _ => NONE)])
  1804 *}
  1805 
  1806 
  1807 subsubsection {* Generic code generator foundation *}
  1808 
  1809 text {* Datatypes *}
  1810 
  1811 code_datatype True False
  1812 
  1813 code_datatype "TYPE('a\<Colon>{})"
  1814 
  1815 code_datatype "prop" Trueprop
  1816 
  1817 text {* Code equations *}
  1818 
  1819 lemma [code]:
  1820   shows "(False \<Longrightarrow> P) \<equiv> Trueprop True" 
  1821     and "(True \<Longrightarrow> PROP Q) \<equiv> PROP Q" 
  1822     and "(P \<Longrightarrow> False) \<equiv> Trueprop (\<not> P)"
  1823     and "(PROP Q \<Longrightarrow> True) \<equiv> Trueprop True" by (auto intro!: equal_intr_rule)
  1824 
  1825 lemma [code]:
  1826   shows "False \<and> P \<longleftrightarrow> False"
  1827     and "True \<and> P \<longleftrightarrow> P"
  1828     and "P \<and> False \<longleftrightarrow> False"
  1829     and "P \<and> True \<longleftrightarrow> P" by simp_all
  1830 
  1831 lemma [code]:
  1832   shows "False \<or> P \<longleftrightarrow> P"
  1833     and "True \<or> P \<longleftrightarrow> True"
  1834     and "P \<or> False \<longleftrightarrow> P"
  1835     and "P \<or> True \<longleftrightarrow> True" by simp_all
  1836 
  1837 lemma [code]:
  1838   shows "(False \<longrightarrow> P) \<longleftrightarrow> True"
  1839     and "(True \<longrightarrow> P) \<longleftrightarrow> P"
  1840     and "(P \<longrightarrow> False) \<longleftrightarrow> \<not> P"
  1841     and "(P \<longrightarrow> True) \<longleftrightarrow> True" by simp_all
  1842 
  1843 instantiation itself :: (type) eq
  1844 begin
  1845 
  1846 definition eq_itself :: "'a itself \<Rightarrow> 'a itself \<Rightarrow> bool" where
  1847   "eq_itself x y \<longleftrightarrow> x = y"
  1848 
  1849 instance proof
  1850 qed (fact eq_itself_def)
  1851 
  1852 end
  1853 
  1854 lemma eq_itself_code [code]:
  1855   "eq_class.eq TYPE('a) TYPE('a) \<longleftrightarrow> True"
  1856   by (simp add: eq)
  1857 
  1858 text {* Equality *}
  1859 
  1860 declare simp_thms(6) [code nbe]
  1861 
  1862 setup {*
  1863   Sign.add_const_constraint (@{const_name eq}, SOME @{typ "'a\<Colon>type \<Rightarrow> 'a \<Rightarrow> bool"})
  1864 *}
  1865 
  1866 lemma equals_alias_cert: "OFCLASS('a, eq_class) \<equiv> ((op = :: 'a \<Rightarrow> 'a \<Rightarrow> bool) \<equiv> eq)" (is "?ofclass \<equiv> ?eq")
  1867 proof
  1868   assume "PROP ?ofclass"
  1869   show "PROP ?eq"
  1870     by (tactic {* ALLGOALS (rtac (Drule.unconstrainTs @{thm equals_eq})) *}) 
  1871       (fact `PROP ?ofclass`)
  1872 next
  1873   assume "PROP ?eq"
  1874   show "PROP ?ofclass" proof
  1875   qed (simp add: `PROP ?eq`)
  1876 qed
  1877   
  1878 setup {*
  1879   Sign.add_const_constraint (@{const_name eq}, SOME @{typ "'a\<Colon>eq \<Rightarrow> 'a \<Rightarrow> bool"})
  1880 *}
  1881 
  1882 setup {*
  1883   Nbe.add_const_alias @{thm equals_alias_cert}
  1884 *}
  1885 
  1886 hide (open) const eq
  1887 hide const eq
  1888 
  1889 text {* Cases *}
  1890 
  1891 lemma Let_case_cert:
  1892   assumes "CASE \<equiv> (\<lambda>x. Let x f)"
  1893   shows "CASE x \<equiv> f x"
  1894   using assms by simp_all
  1895 
  1896 lemma If_case_cert:
  1897   assumes "CASE \<equiv> (\<lambda>b. If b f g)"
  1898   shows "(CASE True \<equiv> f) &&& (CASE False \<equiv> g)"
  1899   using assms by simp_all
  1900 
  1901 setup {*
  1902   Code.add_case @{thm Let_case_cert}
  1903   #> Code.add_case @{thm If_case_cert}
  1904   #> Code.add_undefined @{const_name undefined}
  1905 *}
  1906 
  1907 code_abort undefined
  1908 
  1909 subsubsection {* Generic code generator target languages *}
  1910 
  1911 text {* type bool *}
  1912 
  1913 code_type bool
  1914   (SML "bool")
  1915   (OCaml "bool")
  1916   (Haskell "Bool")
  1917 
  1918 code_const True and False and Not and "op &" and "op |" and If
  1919   (SML "true" and "false" and "not"
  1920     and infixl 1 "andalso" and infixl 0 "orelse"
  1921     and "!(if (_)/ then (_)/ else (_))")
  1922   (OCaml "true" and "false" and "not"
  1923     and infixl 4 "&&" and infixl 2 "||"
  1924     and "!(if (_)/ then (_)/ else (_))")
  1925   (Haskell "True" and "False" and "not"
  1926     and infixl 3 "&&" and infixl 2 "||"
  1927     and "!(if (_)/ then (_)/ else (_))")
  1928 
  1929 code_reserved SML
  1930   bool true false not
  1931 
  1932 code_reserved OCaml
  1933   bool not
  1934 
  1935 text {* using built-in Haskell equality *}
  1936 
  1937 code_class eq
  1938   (Haskell "Eq")
  1939 
  1940 code_const "eq_class.eq"
  1941   (Haskell infixl 4 "==")
  1942 
  1943 code_const "op ="
  1944   (Haskell infixl 4 "==")
  1945 
  1946 text {* undefined *}
  1947 
  1948 code_const undefined
  1949   (SML "!(raise/ Fail/ \"undefined\")")
  1950   (OCaml "failwith/ \"undefined\"")
  1951   (Haskell "error/ \"undefined\"")
  1952 
  1953 subsubsection {* Evaluation and normalization by evaluation *}
  1954 
  1955 setup {*
  1956   Value.add_evaluator ("SML", Codegen.eval_term o ProofContext.theory_of)
  1957 *}
  1958 
  1959 ML {*
  1960 structure Eval_Method =
  1961 struct
  1962 
  1963 val eval_ref : (unit -> bool) option Unsynchronized.ref = Unsynchronized.ref NONE;
  1964 
  1965 end;
  1966 *}
  1967 
  1968 oracle eval_oracle = {* fn ct =>
  1969   let
  1970     val thy = Thm.theory_of_cterm ct;
  1971     val t = Thm.term_of ct;
  1972     val dummy = @{cprop True};
  1973   in case try HOLogic.dest_Trueprop t
  1974    of SOME t' => if Code_ML.eval NONE
  1975          ("Eval_Method.eval_ref", Eval_Method.eval_ref) (K I) thy t' [] 
  1976        then Thm.capply (Thm.capply @{cterm "op \<equiv> \<Colon> prop \<Rightarrow> prop \<Rightarrow> prop"} ct) dummy
  1977        else dummy
  1978     | NONE => dummy
  1979   end
  1980 *}
  1981 
  1982 ML {*
  1983 fun gen_eval_method conv ctxt = SIMPLE_METHOD'
  1984   (CONVERSION (Conv.params_conv (~1) (K (Conv.concl_conv (~1) conv)) ctxt)
  1985     THEN' rtac TrueI)
  1986 *}
  1987 
  1988 method_setup eval = {* Scan.succeed (gen_eval_method eval_oracle) *}
  1989   "solve goal by evaluation"
  1990 
  1991 method_setup evaluation = {* Scan.succeed (gen_eval_method Codegen.evaluation_conv) *}
  1992   "solve goal by evaluation"
  1993 
  1994 method_setup normalization = {*
  1995   Scan.succeed (K (SIMPLE_METHOD' (CONVERSION Nbe.norm_conv THEN' (fn k => TRY (rtac TrueI k)))))
  1996 *} "solve goal by normalization"
  1997 
  1998 
  1999 subsection {* Counterexample Search Units *}
  2000 
  2001 subsubsection {* Quickcheck *}
  2002 
  2003 quickcheck_params [size = 5, iterations = 50]
  2004 
  2005 
  2006 subsubsection {* Nitpick setup *}
  2007 
  2008 text {* This will be relocated once Nitpick is moved to HOL. *}
  2009 
  2010 ML {*
  2011 structure Nitpick_Defs = Named_Thms
  2012 (
  2013   val name = "nitpick_def"
  2014   val description = "alternative definitions of constants as needed by Nitpick"
  2015 )
  2016 structure Nitpick_Simps = Named_Thms
  2017 (
  2018   val name = "nitpick_simp"
  2019   val description = "equational specification of constants as needed by Nitpick"
  2020 )
  2021 structure Nitpick_Psimps = Named_Thms
  2022 (
  2023   val name = "nitpick_psimp"
  2024   val description = "partial equational specification of constants as needed by Nitpick"
  2025 )
  2026 structure Nitpick_Intros = Named_Thms
  2027 (
  2028   val name = "nitpick_intro"
  2029   val description = "introduction rules for (co)inductive predicates as needed by Nitpick"
  2030 )
  2031 *}
  2032 
  2033 setup {*
  2034   Nitpick_Defs.setup
  2035   #> Nitpick_Simps.setup
  2036   #> Nitpick_Psimps.setup
  2037   #> Nitpick_Intros.setup
  2038 *}
  2039 
  2040 
  2041 subsection {* Preprocessing for the predicate compiler *}
  2042 
  2043 ML {*
  2044 structure Predicate_Compile_Alternative_Defs = Named_Thms
  2045 (
  2046   val name = "code_pred_def"
  2047   val description = "alternative definitions of constants for the Predicate Compiler"
  2048 )
  2049 *}
  2050 
  2051 ML {*
  2052 structure Predicate_Compile_Inline_Defs = Named_Thms
  2053 (
  2054   val name = "code_pred_inline"
  2055   val description = "inlining definitions for the Predicate Compiler"
  2056 )
  2057 *}
  2058 
  2059 setup {*
  2060   Predicate_Compile_Alternative_Defs.setup
  2061   #> Predicate_Compile_Inline_Defs.setup
  2062 *}
  2063 
  2064 
  2065 subsection {* Legacy tactics and ML bindings *}
  2066 
  2067 ML {*
  2068 fun strip_tac i = REPEAT (resolve_tac [impI, allI] i);
  2069 
  2070 (* combination of (spec RS spec RS ...(j times) ... spec RS mp) *)
  2071 local
  2072   fun wrong_prem (Const ("All", _) $ (Abs (_, _, t))) = wrong_prem t
  2073     | wrong_prem (Bound _) = true
  2074     | wrong_prem _ = false;
  2075   val filter_right = filter (not o wrong_prem o HOLogic.dest_Trueprop o hd o Thm.prems_of);
  2076 in
  2077   fun smp i = funpow i (fn m => filter_right ([spec] RL m)) ([mp]);
  2078   fun smp_tac j = EVERY'[dresolve_tac (smp j), atac];
  2079 end;
  2080 
  2081 val all_conj_distrib = thm "all_conj_distrib";
  2082 val all_simps = thms "all_simps";
  2083 val atomize_not = thm "atomize_not";
  2084 val case_split = thm "case_split";
  2085 val cases_simp = thm "cases_simp";
  2086 val choice_eq = thm "choice_eq"
  2087 val cong = thm "cong"
  2088 val conj_comms = thms "conj_comms";
  2089 val conj_cong = thm "conj_cong";
  2090 val de_Morgan_conj = thm "de_Morgan_conj";
  2091 val de_Morgan_disj = thm "de_Morgan_disj";
  2092 val disj_assoc = thm "disj_assoc";
  2093 val disj_comms = thms "disj_comms";
  2094 val disj_cong = thm "disj_cong";
  2095 val eq_ac = thms "eq_ac";
  2096 val eq_cong2 = thm "eq_cong2"
  2097 val Eq_FalseI = thm "Eq_FalseI";
  2098 val Eq_TrueI = thm "Eq_TrueI";
  2099 val Ex1_def = thm "Ex1_def"
  2100 val ex_disj_distrib = thm "ex_disj_distrib";
  2101 val ex_simps = thms "ex_simps";
  2102 val if_cancel = thm "if_cancel";
  2103 val if_eq_cancel = thm "if_eq_cancel";
  2104 val if_False = thm "if_False";
  2105 val iff_conv_conj_imp = thm "iff_conv_conj_imp";
  2106 val iff = thm "iff"
  2107 val if_splits = thms "if_splits";
  2108 val if_True = thm "if_True";
  2109 val if_weak_cong = thm "if_weak_cong"
  2110 val imp_all = thm "imp_all";
  2111 val imp_cong = thm "imp_cong";
  2112 val imp_conjL = thm "imp_conjL";
  2113 val imp_conjR = thm "imp_conjR";
  2114 val imp_conv_disj = thm "imp_conv_disj";
  2115 val simp_implies_def = thm "simp_implies_def";
  2116 val simp_thms = thms "simp_thms";
  2117 val split_if = thm "split_if";
  2118 val the1_equality = thm "the1_equality"
  2119 val theI = thm "theI"
  2120 val theI' = thm "theI'"
  2121 val True_implies_equals = thm "True_implies_equals";
  2122 val nnf_conv = Simplifier.rewrite (HOL_basic_ss addsimps simp_thms @ @{thms "nnf_simps"})
  2123 
  2124 *}
  2125 
  2126 end