src/HOL/Quickcheck.thy
author haftmann
Fri Nov 27 08:41:10 2009 +0100 (2009-11-27)
changeset 33963 977b94b64905
parent 33562 b1e2830ee31a
child 34968 ceeffca32eb0
permissions -rw-r--r--
renamed former datatype.ML to datatype_data.ML; datatype.ML provides uniform view on datatype.ML and datatype_rep_proofs.ML
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* A simple counterexample generator *}
     4 
     5 theory Quickcheck
     6 imports Random Code_Evaluation
     7 uses ("Tools/quickcheck_generators.ML")
     8 begin
     9 
    10 notation fcomp (infixl "o>" 60)
    11 notation scomp (infixl "o\<rightarrow>" 60)
    12 
    13 
    14 subsection {* The @{text random} class *}
    15 
    16 class random = typerep +
    17   fixes random :: "code_numeral \<Rightarrow> Random.seed \<Rightarrow> ('a \<times> (unit \<Rightarrow> term)) \<times> Random.seed"
    18 
    19 
    20 subsection {* Fundamental and numeric types*}
    21 
    22 instantiation bool :: random
    23 begin
    24 
    25 definition
    26   "random i = Random.range 2 o\<rightarrow>
    27     (\<lambda>k. Pair (if k = 0 then Code_Evaluation.valtermify False else Code_Evaluation.valtermify True))"
    28 
    29 instance ..
    30 
    31 end
    32 
    33 instantiation itself :: (typerep) random
    34 begin
    35 
    36 definition random_itself :: "code_numeral \<Rightarrow> Random.seed \<Rightarrow> ('a itself \<times> (unit \<Rightarrow> term)) \<times> Random.seed" where
    37   "random_itself _ = Pair (Code_Evaluation.valtermify TYPE('a))"
    38 
    39 instance ..
    40 
    41 end
    42 
    43 instantiation char :: random
    44 begin
    45 
    46 definition
    47   "random _ = Random.select chars o\<rightarrow> (\<lambda>c. Pair (c, \<lambda>u. Code_Evaluation.term_of c))"
    48 
    49 instance ..
    50 
    51 end
    52 
    53 instantiation String.literal :: random
    54 begin
    55 
    56 definition 
    57   "random _ = Pair (STR '''', \<lambda>u. Code_Evaluation.term_of (STR ''''))"
    58 
    59 instance ..
    60 
    61 end
    62 
    63 instantiation nat :: random
    64 begin
    65 
    66 definition random_nat :: "code_numeral \<Rightarrow> Random.seed \<Rightarrow> (nat \<times> (unit \<Rightarrow> Code_Evaluation.term)) \<times> Random.seed" where
    67   "random_nat i = Random.range (i + 1) o\<rightarrow> (\<lambda>k. Pair (
    68      let n = Code_Numeral.nat_of k
    69      in (n, \<lambda>_. Code_Evaluation.term_of n)))"
    70 
    71 instance ..
    72 
    73 end
    74 
    75 instantiation int :: random
    76 begin
    77 
    78 definition
    79   "random i = Random.range (2 * i + 1) o\<rightarrow> (\<lambda>k. Pair (
    80      let j = (if k \<ge> i then Code_Numeral.int_of (k - i) else - Code_Numeral.int_of (i - k))
    81      in (j, \<lambda>_. Code_Evaluation.term_of j)))"
    82 
    83 instance ..
    84 
    85 end
    86 
    87 
    88 subsection {* Complex generators *}
    89 
    90 text {* Towards @{typ "'a \<Rightarrow> 'b"} *}
    91 
    92 axiomatization random_fun_aux :: "typerep \<Rightarrow> typerep \<Rightarrow> ('a \<Rightarrow> 'a \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> term)
    93   \<Rightarrow> (Random.seed \<Rightarrow> ('b \<times> (unit \<Rightarrow> term)) \<times> Random.seed) \<Rightarrow> (Random.seed \<Rightarrow> Random.seed \<times> Random.seed)
    94   \<Rightarrow> Random.seed \<Rightarrow> (('a \<Rightarrow> 'b) \<times> (unit \<Rightarrow> term)) \<times> Random.seed"
    95 
    96 definition random_fun_lift :: "(Random.seed \<Rightarrow> ('b \<times> (unit \<Rightarrow> term)) \<times> Random.seed)
    97   \<Rightarrow> Random.seed \<Rightarrow> (('a\<Colon>term_of \<Rightarrow> 'b\<Colon>typerep) \<times> (unit \<Rightarrow> term)) \<times> Random.seed" where
    98   "random_fun_lift f = random_fun_aux TYPEREP('a) TYPEREP('b) (op =) Code_Evaluation.term_of f Random.split_seed"
    99 
   100 instantiation "fun" :: ("{eq, term_of}", random) random
   101 begin
   102 
   103 definition random_fun :: "code_numeral \<Rightarrow> Random.seed \<Rightarrow> (('a \<Rightarrow> 'b) \<times> (unit \<Rightarrow> term)) \<times> Random.seed" where
   104   "random i = random_fun_lift (random i)"
   105 
   106 instance ..
   107 
   108 end
   109 
   110 text {* Towards type copies and datatypes *}
   111 
   112 definition collapse :: "('a \<Rightarrow> ('a \<Rightarrow> 'b \<times> 'a) \<times> 'a) \<Rightarrow> 'a \<Rightarrow> 'b \<times> 'a" where
   113   "collapse f = (f o\<rightarrow> id)"
   114 
   115 definition beyond :: "code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral" where
   116   "beyond k l = (if l > k then l else 0)"
   117 
   118 lemma beyond_zero:
   119   "beyond k 0 = 0"
   120   by (simp add: beyond_def)
   121 
   122 lemma random_aux_rec:
   123   fixes random_aux :: "code_numeral \<Rightarrow> 'a"
   124   assumes "random_aux 0 = rhs 0"
   125     and "\<And>k. random_aux (Suc_code_numeral k) = rhs (Suc_code_numeral k)"
   126   shows "random_aux k = rhs k"
   127   using assms by (rule code_numeral.induct)
   128 
   129 setup {* Quickcheck.setup *}
   130 
   131 subsection {* the Random-Predicate Monad *} 
   132 
   133 types 'a randompred = "Random.seed \<Rightarrow> ('a Predicate.pred \<times> Random.seed)"
   134 
   135 definition empty :: "'a randompred"
   136   where "empty = Pair (bot_class.bot)"
   137 
   138 definition single :: "'a => 'a randompred"
   139   where "single x = Pair (Predicate.single x)"
   140 
   141 definition bind :: "'a randompred \<Rightarrow> ('a \<Rightarrow> 'b randompred) \<Rightarrow> 'b randompred"
   142   where
   143     "bind R f = (\<lambda>s. let
   144        (P, s') = R s;
   145        (s1, s2) = Random.split_seed s'
   146      in (Predicate.bind P (%a. fst (f a s1)), s2))"
   147 
   148 definition union :: "'a randompred \<Rightarrow> 'a randompred \<Rightarrow> 'a randompred"
   149 where
   150   "union R1 R2 = (\<lambda>s. let
   151      (P1, s') = R1 s; (P2, s'') = R2 s'
   152    in (upper_semilattice_class.sup P1 P2, s''))"
   153 
   154 definition if_randompred :: "bool \<Rightarrow> unit randompred"
   155 where
   156   "if_randompred b = (if b then single () else empty)"
   157 
   158 definition not_randompred :: "unit randompred \<Rightarrow> unit randompred"
   159 where
   160   "not_randompred P = (\<lambda>s. let
   161      (P', s') = P s
   162    in if Predicate.eval P' () then (Orderings.bot, s') else (Predicate.single (), s'))"
   163 
   164 definition Random :: "(Random.seed \<Rightarrow> ('a \<times> (unit \<Rightarrow> term)) \<times> Random.seed) \<Rightarrow> 'a randompred"
   165   where "Random g = scomp g (Pair o (Predicate.single o fst))"
   166 
   167 definition map :: "('a \<Rightarrow> 'b) \<Rightarrow> ('a randompred \<Rightarrow> 'b randompred)"
   168   where "map f P = bind P (single o f)"
   169 
   170 subsection {* Code setup *}
   171 
   172 use "Tools/quickcheck_generators.ML"
   173 setup {* Quickcheck_Generators.setup *}
   174 
   175 code_const random_fun_aux (Quickcheck "Quickcheck'_Generators.random'_fun")
   176   -- {* With enough criminal energy this can be abused to derive @{prop False};
   177   for this reason we use a distinguished target @{text Quickcheck}
   178   not spoiling the regular trusted code generation *}
   179 
   180 code_reserved Quickcheck Quickcheck_Generators
   181 
   182 hide (open) fact empty_def single_def bind_def union_def if_randompred_def not_randompred_def Random_def map_def
   183 hide (open) type randompred
   184 hide (open) const random collapse beyond random_fun_aux random_fun_lift
   185   empty single bind union if_randompred not_randompred Random map
   186 
   187 no_notation fcomp (infixl "o>" 60)
   188 no_notation scomp (infixl "o\<rightarrow>" 60)
   189 
   190 end