src/HOL/SEQ.thy
author haftmann
Fri Nov 27 08:41:10 2009 +0100 (2009-11-27)
changeset 33963 977b94b64905
parent 33271 7be66dee1a5a
child 35216 7641e8d831d2
permissions -rw-r--r--
renamed former datatype.ML to datatype_data.ML; datatype.ML provides uniform view on datatype.ML and datatype_rep_proofs.ML
     1 (*  Title:      HOL/SEQ.thy
     2     Author:     Jacques D. Fleuriot, University of Cambridge
     3     Author:     Lawrence C Paulson
     4     Author:     Jeremy Avigad
     5     Author:     Brian Huffman
     6 
     7 Convergence of sequences and series.
     8 *)
     9 
    10 header {* Sequences and Convergence *}
    11 
    12 theory SEQ
    13 imports Limits
    14 begin
    15 
    16 definition
    17   Zseq :: "[nat \<Rightarrow> 'a::real_normed_vector] \<Rightarrow> bool" where
    18     --{*Standard definition of sequence converging to zero*}
    19   [code del]: "Zseq X = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. norm (X n) < r)"
    20 
    21 definition
    22   LIMSEQ :: "[nat \<Rightarrow> 'a::metric_space, 'a] \<Rightarrow> bool"
    23     ("((_)/ ----> (_))" [60, 60] 60) where
    24     --{*Standard definition of convergence of sequence*}
    25   [code del]: "X ----> L = (\<forall>r>0. \<exists>no. \<forall>n\<ge>no. dist (X n) L < r)"
    26 
    27 definition
    28   lim :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> 'a" where
    29     --{*Standard definition of limit using choice operator*}
    30   "lim X = (THE L. X ----> L)"
    31 
    32 definition
    33   convergent :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    34     --{*Standard definition of convergence*}
    35   "convergent X = (\<exists>L. X ----> L)"
    36 
    37 definition
    38   Bseq :: "(nat => 'a::real_normed_vector) => bool" where
    39     --{*Standard definition for bounded sequence*}
    40   [code del]: "Bseq X = (\<exists>K>0.\<forall>n. norm (X n) \<le> K)"
    41 
    42 definition
    43   monoseq :: "(nat=>real)=>bool" where
    44     --{*Definition of monotonicity. 
    45         The use of disjunction here complicates proofs considerably. 
    46         One alternative is to add a Boolean argument to indicate the direction. 
    47         Another is to develop the notions of increasing and decreasing first.*}
    48   [code del]: "monoseq X = ((\<forall>m. \<forall>n\<ge>m. X m \<le> X n) | (\<forall>m. \<forall>n\<ge>m. X n \<le> X m))"
    49 
    50 definition
    51   incseq :: "(nat=>real)=>bool" where
    52     --{*Increasing sequence*}
    53   [code del]: "incseq X = (\<forall>m. \<forall>n\<ge>m. X m \<le> X n)"
    54 
    55 definition
    56   decseq :: "(nat=>real)=>bool" where
    57     --{*Increasing sequence*}
    58   [code del]: "decseq X = (\<forall>m. \<forall>n\<ge>m. X n \<le> X m)"
    59 
    60 definition
    61   subseq :: "(nat => nat) => bool" where
    62     --{*Definition of subsequence*}
    63   [code del]:   "subseq f = (\<forall>m. \<forall>n>m. (f m) < (f n))"
    64 
    65 definition
    66   Cauchy :: "(nat \<Rightarrow> 'a::metric_space) \<Rightarrow> bool" where
    67     --{*Standard definition of the Cauchy condition*}
    68   [code del]: "Cauchy X = (\<forall>e>0. \<exists>M. \<forall>m \<ge> M. \<forall>n \<ge> M. dist (X m) (X n) < e)"
    69 
    70 
    71 subsection {* Bounded Sequences *}
    72 
    73 lemma BseqI': assumes K: "\<And>n. norm (X n) \<le> K" shows "Bseq X"
    74 unfolding Bseq_def
    75 proof (intro exI conjI allI)
    76   show "0 < max K 1" by simp
    77 next
    78   fix n::nat
    79   have "norm (X n) \<le> K" by (rule K)
    80   thus "norm (X n) \<le> max K 1" by simp
    81 qed
    82 
    83 lemma BseqE: "\<lbrakk>Bseq X; \<And>K. \<lbrakk>0 < K; \<forall>n. norm (X n) \<le> K\<rbrakk> \<Longrightarrow> Q\<rbrakk> \<Longrightarrow> Q"
    84 unfolding Bseq_def by auto
    85 
    86 lemma BseqI2': assumes K: "\<forall>n\<ge>N. norm (X n) \<le> K" shows "Bseq X"
    87 proof (rule BseqI')
    88   let ?A = "norm ` X ` {..N}"
    89   have 1: "finite ?A" by simp
    90   fix n::nat
    91   show "norm (X n) \<le> max K (Max ?A)"
    92   proof (cases rule: linorder_le_cases)
    93     assume "n \<ge> N"
    94     hence "norm (X n) \<le> K" using K by simp
    95     thus "norm (X n) \<le> max K (Max ?A)" by simp
    96   next
    97     assume "n \<le> N"
    98     hence "norm (X n) \<in> ?A" by simp
    99     with 1 have "norm (X n) \<le> Max ?A" by (rule Max_ge)
   100     thus "norm (X n) \<le> max K (Max ?A)" by simp
   101   qed
   102 qed
   103 
   104 lemma Bseq_ignore_initial_segment: "Bseq X \<Longrightarrow> Bseq (\<lambda>n. X (n + k))"
   105 unfolding Bseq_def by auto
   106 
   107 lemma Bseq_offset: "Bseq (\<lambda>n. X (n + k)) \<Longrightarrow> Bseq X"
   108 apply (erule BseqE)
   109 apply (rule_tac N="k" and K="K" in BseqI2')
   110 apply clarify
   111 apply (drule_tac x="n - k" in spec, simp)
   112 done
   113 
   114 lemma Bseq_conv_Bfun: "Bseq X \<longleftrightarrow> Bfun X sequentially"
   115 unfolding Bfun_def eventually_sequentially
   116 apply (rule iffI)
   117 apply (simp add: Bseq_def)
   118 apply (auto intro: BseqI2')
   119 done
   120 
   121 
   122 subsection {* Sequences That Converge to Zero *}
   123 
   124 lemma ZseqI:
   125   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r) \<Longrightarrow> Zseq X"
   126 unfolding Zseq_def by simp
   127 
   128 lemma ZseqD:
   129   "\<lbrakk>Zseq X; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n) < r"
   130 unfolding Zseq_def by simp
   131 
   132 lemma Zseq_conv_Zfun: "Zseq X \<longleftrightarrow> Zfun X sequentially"
   133 unfolding Zseq_def Zfun_def eventually_sequentially ..
   134 
   135 lemma Zseq_zero: "Zseq (\<lambda>n. 0)"
   136 unfolding Zseq_def by simp
   137 
   138 lemma Zseq_const_iff: "Zseq (\<lambda>n. k) = (k = 0)"
   139 unfolding Zseq_def by force
   140 
   141 lemma Zseq_norm_iff: "Zseq (\<lambda>n. norm (X n)) = Zseq (\<lambda>n. X n)"
   142 unfolding Zseq_def by simp
   143 
   144 lemma Zseq_imp_Zseq:
   145   assumes X: "Zseq X"
   146   assumes Y: "\<And>n. norm (Y n) \<le> norm (X n) * K"
   147   shows "Zseq (\<lambda>n. Y n)"
   148 using X Y Zfun_imp_Zfun [of X sequentially Y K]
   149 unfolding Zseq_conv_Zfun by simp
   150 
   151 lemma Zseq_le: "\<lbrakk>Zseq Y; \<forall>n. norm (X n) \<le> norm (Y n)\<rbrakk> \<Longrightarrow> Zseq X"
   152 by (erule_tac K="1" in Zseq_imp_Zseq, simp)
   153 
   154 lemma Zseq_add:
   155   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n + Y n)"
   156 unfolding Zseq_conv_Zfun by (rule Zfun_add)
   157 
   158 lemma Zseq_minus: "Zseq X \<Longrightarrow> Zseq (\<lambda>n. - X n)"
   159 unfolding Zseq_def by simp
   160 
   161 lemma Zseq_diff: "\<lbrakk>Zseq X; Zseq Y\<rbrakk> \<Longrightarrow> Zseq (\<lambda>n. X n - Y n)"
   162 by (simp only: diff_minus Zseq_add Zseq_minus)
   163 
   164 lemma (in bounded_linear) Zseq:
   165   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. f (X n))"
   166 unfolding Zseq_conv_Zfun by (rule Zfun)
   167 
   168 lemma (in bounded_bilinear) Zseq:
   169   "Zseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   170 unfolding Zseq_conv_Zfun by (rule Zfun)
   171 
   172 lemma (in bounded_bilinear) Zseq_prod_Bseq:
   173   "Zseq X \<Longrightarrow> Bseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   174 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   175 by (rule Zfun_prod_Bfun)
   176 
   177 lemma (in bounded_bilinear) Bseq_prod_Zseq:
   178   "Bseq X \<Longrightarrow> Zseq Y \<Longrightarrow> Zseq (\<lambda>n. X n ** Y n)"
   179 unfolding Zseq_conv_Zfun Bseq_conv_Bfun
   180 by (rule Bfun_prod_Zfun)
   181 
   182 lemma (in bounded_bilinear) Zseq_left:
   183   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. X n ** a)"
   184 by (rule bounded_linear_left [THEN bounded_linear.Zseq])
   185 
   186 lemma (in bounded_bilinear) Zseq_right:
   187   "Zseq X \<Longrightarrow> Zseq (\<lambda>n. a ** X n)"
   188 by (rule bounded_linear_right [THEN bounded_linear.Zseq])
   189 
   190 lemmas Zseq_mult = mult.Zseq
   191 lemmas Zseq_mult_right = mult.Zseq_right
   192 lemmas Zseq_mult_left = mult.Zseq_left
   193 
   194 
   195 subsection {* Limits of Sequences *}
   196 
   197 lemma [trans]: "X=Y ==> Y ----> z ==> X ----> z"
   198   by simp
   199 
   200 lemma LIMSEQ_conv_tendsto: "(X ----> L) \<longleftrightarrow> (X ---> L) sequentially"
   201 unfolding LIMSEQ_def tendsto_iff eventually_sequentially ..
   202 
   203 lemma LIMSEQ_iff:
   204   fixes L :: "'a::real_normed_vector"
   205   shows "(X ----> L) = (\<forall>r>0. \<exists>no. \<forall>n \<ge> no. norm (X n - L) < r)"
   206 unfolding LIMSEQ_def dist_norm ..
   207 
   208 lemma LIMSEQ_iff_nz: "X ----> L = (\<forall>r>0. \<exists>no>0. \<forall>n\<ge>no. dist (X n) L < r)"
   209   by (auto simp add: LIMSEQ_def) (metis Suc_leD zero_less_Suc)  
   210 
   211 lemma LIMSEQ_Zseq_iff: "((\<lambda>n. X n) ----> L) = Zseq (\<lambda>n. X n - L)"
   212 by (simp only: LIMSEQ_iff Zseq_def)
   213 
   214 lemma metric_LIMSEQ_I:
   215   "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r) \<Longrightarrow> X ----> L"
   216 by (simp add: LIMSEQ_def)
   217 
   218 lemma metric_LIMSEQ_D:
   219   "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. dist (X n) L < r"
   220 by (simp add: LIMSEQ_def)
   221 
   222 lemma LIMSEQ_I:
   223   fixes L :: "'a::real_normed_vector"
   224   shows "(\<And>r. 0 < r \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r) \<Longrightarrow> X ----> L"
   225 by (simp add: LIMSEQ_iff)
   226 
   227 lemma LIMSEQ_D:
   228   fixes L :: "'a::real_normed_vector"
   229   shows "\<lbrakk>X ----> L; 0 < r\<rbrakk> \<Longrightarrow> \<exists>no. \<forall>n\<ge>no. norm (X n - L) < r"
   230 by (simp add: LIMSEQ_iff)
   231 
   232 lemma LIMSEQ_const: "(\<lambda>n. k) ----> k"
   233 by (simp add: LIMSEQ_def)
   234 
   235 lemma LIMSEQ_const_iff: "(\<lambda>n. k) ----> l \<longleftrightarrow> k = l"
   236 apply (safe intro!: LIMSEQ_const)
   237 apply (rule ccontr)
   238 apply (drule_tac r="dist k l" in metric_LIMSEQ_D)
   239 apply (simp add: zero_less_dist_iff)
   240 apply auto
   241 done
   242 
   243 lemma LIMSEQ_norm:
   244   fixes a :: "'a::real_normed_vector"
   245   shows "X ----> a \<Longrightarrow> (\<lambda>n. norm (X n)) ----> norm a"
   246 unfolding LIMSEQ_conv_tendsto by (rule tendsto_norm)
   247 
   248 lemma LIMSEQ_ignore_initial_segment:
   249   "f ----> a \<Longrightarrow> (\<lambda>n. f (n + k)) ----> a"
   250 apply (rule metric_LIMSEQ_I)
   251 apply (drule (1) metric_LIMSEQ_D)
   252 apply (erule exE, rename_tac N)
   253 apply (rule_tac x=N in exI)
   254 apply simp
   255 done
   256 
   257 lemma LIMSEQ_offset:
   258   "(\<lambda>n. f (n + k)) ----> a \<Longrightarrow> f ----> a"
   259 apply (rule metric_LIMSEQ_I)
   260 apply (drule (1) metric_LIMSEQ_D)
   261 apply (erule exE, rename_tac N)
   262 apply (rule_tac x="N + k" in exI)
   263 apply clarify
   264 apply (drule_tac x="n - k" in spec)
   265 apply (simp add: le_diff_conv2)
   266 done
   267 
   268 lemma LIMSEQ_Suc: "f ----> l \<Longrightarrow> (\<lambda>n. f (Suc n)) ----> l"
   269 by (drule_tac k="Suc 0" in LIMSEQ_ignore_initial_segment, simp)
   270 
   271 lemma LIMSEQ_imp_Suc: "(\<lambda>n. f (Suc n)) ----> l \<Longrightarrow> f ----> l"
   272 by (rule_tac k="Suc 0" in LIMSEQ_offset, simp)
   273 
   274 lemma LIMSEQ_Suc_iff: "(\<lambda>n. f (Suc n)) ----> l = f ----> l"
   275 by (blast intro: LIMSEQ_imp_Suc LIMSEQ_Suc)
   276 
   277 lemma LIMSEQ_linear: "\<lbrakk> X ----> x ; l > 0 \<rbrakk> \<Longrightarrow> (\<lambda> n. X (n * l)) ----> x"
   278   unfolding LIMSEQ_def
   279   by (metis div_le_dividend div_mult_self1_is_m le_trans nat_mult_commute)
   280 
   281 lemma LIMSEQ_add:
   282   fixes a b :: "'a::real_normed_vector"
   283   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n + Y n) ----> a + b"
   284 unfolding LIMSEQ_conv_tendsto by (rule tendsto_add)
   285 
   286 lemma LIMSEQ_minus:
   287   fixes a :: "'a::real_normed_vector"
   288   shows "X ----> a \<Longrightarrow> (\<lambda>n. - X n) ----> - a"
   289 unfolding LIMSEQ_conv_tendsto by (rule tendsto_minus)
   290 
   291 lemma LIMSEQ_minus_cancel:
   292   fixes a :: "'a::real_normed_vector"
   293   shows "(\<lambda>n. - X n) ----> - a \<Longrightarrow> X ----> a"
   294 by (drule LIMSEQ_minus, simp)
   295 
   296 lemma LIMSEQ_diff:
   297   fixes a b :: "'a::real_normed_vector"
   298   shows "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n - Y n) ----> a - b"
   299 unfolding LIMSEQ_conv_tendsto by (rule tendsto_diff)
   300 
   301 lemma LIMSEQ_unique: "\<lbrakk>X ----> a; X ----> b\<rbrakk> \<Longrightarrow> a = b"
   302 apply (rule ccontr)
   303 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   304 apply (drule_tac r="dist a b / 2" in metric_LIMSEQ_D, simp add: zero_less_dist_iff)
   305 apply (clarify, rename_tac M N)
   306 apply (subgoal_tac "dist a b < dist a b / 2 + dist a b / 2", simp)
   307 apply (subgoal_tac "dist a b \<le> dist (X (max M N)) a + dist (X (max M N)) b")
   308 apply (erule le_less_trans, rule add_strict_mono, simp, simp)
   309 apply (subst dist_commute, rule dist_triangle)
   310 done
   311 
   312 lemma (in bounded_linear) LIMSEQ:
   313   "X ----> a \<Longrightarrow> (\<lambda>n. f (X n)) ----> f a"
   314 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   315 
   316 lemma (in bounded_bilinear) LIMSEQ:
   317   "\<lbrakk>X ----> a; Y ----> b\<rbrakk> \<Longrightarrow> (\<lambda>n. X n ** Y n) ----> a ** b"
   318 unfolding LIMSEQ_conv_tendsto by (rule tendsto)
   319 
   320 lemma LIMSEQ_mult:
   321   fixes a b :: "'a::real_normed_algebra"
   322   shows "[| X ----> a; Y ----> b |] ==> (%n. X n * Y n) ----> a * b"
   323 by (rule mult.LIMSEQ)
   324 
   325 lemma increasing_LIMSEQ:
   326   fixes f :: "nat \<Rightarrow> real"
   327   assumes inc: "!!n. f n \<le> f (Suc n)"
   328       and bdd: "!!n. f n \<le> l"
   329       and en: "!!e. 0 < e \<Longrightarrow> \<exists>n. l \<le> f n + e"
   330   shows "f ----> l"
   331 proof (auto simp add: LIMSEQ_def)
   332   fix e :: real
   333   assume e: "0 < e"
   334   then obtain N where "l \<le> f N + e/2"
   335     by (metis half_gt_zero e en that)
   336   hence N: "l < f N + e" using e
   337     by simp
   338   { fix k
   339     have [simp]: "!!n. \<bar>f n - l\<bar> = l - f n"
   340       by (simp add: bdd) 
   341     have "\<bar>f (N+k) - l\<bar> < e"
   342     proof (induct k)
   343       case 0 show ?case using N
   344         by simp   
   345     next
   346       case (Suc k) thus ?case using N inc [of "N+k"]
   347         by simp
   348     qed 
   349   } note 1 = this
   350   { fix n
   351     have "N \<le> n \<Longrightarrow> \<bar>f n - l\<bar> < e" using 1 [of "n-N"]
   352       by simp 
   353   } note [intro] = this
   354   show " \<exists>no. \<forall>n\<ge>no. dist (f n) l < e"
   355     by (auto simp add: dist_real_def) 
   356   qed
   357 
   358 lemma Bseq_inverse_lemma:
   359   fixes x :: "'a::real_normed_div_algebra"
   360   shows "\<lbrakk>r \<le> norm x; 0 < r\<rbrakk> \<Longrightarrow> norm (inverse x) \<le> inverse r"
   361 apply (subst nonzero_norm_inverse, clarsimp)
   362 apply (erule (1) le_imp_inverse_le)
   363 done
   364 
   365 lemma Bseq_inverse:
   366   fixes a :: "'a::real_normed_div_algebra"
   367   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> Bseq (\<lambda>n. inverse (X n))"
   368 unfolding LIMSEQ_conv_tendsto Bseq_conv_Bfun
   369 by (rule Bfun_inverse)
   370 
   371 lemma LIMSEQ_inverse:
   372   fixes a :: "'a::real_normed_div_algebra"
   373   shows "\<lbrakk>X ----> a; a \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> inverse a"
   374 unfolding LIMSEQ_conv_tendsto
   375 by (rule tendsto_inverse)
   376 
   377 lemma LIMSEQ_divide:
   378   fixes a b :: "'a::real_normed_field"
   379   shows "\<lbrakk>X ----> a; Y ----> b; b \<noteq> 0\<rbrakk> \<Longrightarrow> (\<lambda>n. X n / Y n) ----> a / b"
   380 by (simp add: LIMSEQ_mult LIMSEQ_inverse divide_inverse)
   381 
   382 lemma LIMSEQ_pow:
   383   fixes a :: "'a::{power, real_normed_algebra}"
   384   shows "X ----> a \<Longrightarrow> (\<lambda>n. (X n) ^ m) ----> a ^ m"
   385 by (induct m) (simp_all add: LIMSEQ_const LIMSEQ_mult)
   386 
   387 lemma LIMSEQ_setsum:
   388   fixes L :: "'a \<Rightarrow> 'b::real_normed_vector"
   389   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   390   shows "(\<lambda>m. \<Sum>n\<in>S. X n m) ----> (\<Sum>n\<in>S. L n)"
   391 using n unfolding LIMSEQ_conv_tendsto by (rule tendsto_setsum)
   392 
   393 lemma LIMSEQ_setprod:
   394   fixes L :: "'a \<Rightarrow> 'b::{real_normed_algebra,comm_ring_1}"
   395   assumes n: "\<And>n. n \<in> S \<Longrightarrow> X n ----> L n"
   396   shows "(\<lambda>m. \<Prod>n\<in>S. X n m) ----> (\<Prod>n\<in>S. L n)"
   397 proof (cases "finite S")
   398   case True
   399   thus ?thesis using n
   400   proof (induct)
   401     case empty
   402     show ?case
   403       by (simp add: LIMSEQ_const)
   404   next
   405     case insert
   406     thus ?case
   407       by (simp add: LIMSEQ_mult)
   408   qed
   409 next
   410   case False
   411   thus ?thesis
   412     by (simp add: setprod_def LIMSEQ_const)
   413 qed
   414 
   415 lemma LIMSEQ_add_const:
   416   fixes a :: "'a::real_normed_vector"
   417   shows "f ----> a ==> (%n.(f n + b)) ----> a + b"
   418 by (simp add: LIMSEQ_add LIMSEQ_const)
   419 
   420 (* FIXME: delete *)
   421 lemma LIMSEQ_add_minus:
   422   fixes a b :: "'a::real_normed_vector"
   423   shows "[| X ----> a; Y ----> b |] ==> (%n. X n + -Y n) ----> a + -b"
   424 by (simp only: LIMSEQ_add LIMSEQ_minus)
   425 
   426 lemma LIMSEQ_diff_const:
   427   fixes a b :: "'a::real_normed_vector"
   428   shows "f ----> a ==> (%n.(f n  - b)) ----> a - b"
   429 by (simp add: LIMSEQ_diff LIMSEQ_const)
   430 
   431 lemma LIMSEQ_diff_approach_zero:
   432   fixes L :: "'a::real_normed_vector"
   433   shows "g ----> L ==> (%x. f x - g x) ----> 0 ==> f ----> L"
   434 by (drule (1) LIMSEQ_add, simp)
   435 
   436 lemma LIMSEQ_diff_approach_zero2:
   437   fixes L :: "'a::real_normed_vector"
   438   shows "f ----> L ==> (%x. f x - g x) ----> 0 ==> g ----> L";
   439 by (drule (1) LIMSEQ_diff, simp)
   440 
   441 text{*A sequence tends to zero iff its abs does*}
   442 lemma LIMSEQ_norm_zero:
   443   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   444   shows "((\<lambda>n. norm (X n)) ----> 0) \<longleftrightarrow> (X ----> 0)"
   445 by (simp add: LIMSEQ_iff)
   446 
   447 lemma LIMSEQ_rabs_zero: "((%n. \<bar>f n\<bar>) ----> 0) = (f ----> (0::real))"
   448 by (simp add: LIMSEQ_iff)
   449 
   450 lemma LIMSEQ_imp_rabs: "f ----> (l::real) ==> (%n. \<bar>f n\<bar>) ----> \<bar>l\<bar>"
   451 by (drule LIMSEQ_norm, simp)
   452 
   453 text{*An unbounded sequence's inverse tends to 0*}
   454 
   455 lemma LIMSEQ_inverse_zero:
   456   "\<forall>r::real. \<exists>N. \<forall>n\<ge>N. r < X n \<Longrightarrow> (\<lambda>n. inverse (X n)) ----> 0"
   457 apply (rule LIMSEQ_I)
   458 apply (drule_tac x="inverse r" in spec, safe)
   459 apply (rule_tac x="N" in exI, safe)
   460 apply (drule_tac x="n" in spec, safe)
   461 apply (frule positive_imp_inverse_positive)
   462 apply (frule (1) less_imp_inverse_less)
   463 apply (subgoal_tac "0 < X n", simp)
   464 apply (erule (1) order_less_trans)
   465 done
   466 
   467 text{*The sequence @{term "1/n"} tends to 0 as @{term n} tends to infinity*}
   468 
   469 lemma LIMSEQ_inverse_real_of_nat: "(%n. inverse(real(Suc n))) ----> 0"
   470 apply (rule LIMSEQ_inverse_zero, safe)
   471 apply (cut_tac x = r in reals_Archimedean2)
   472 apply (safe, rule_tac x = n in exI)
   473 apply (auto simp add: real_of_nat_Suc)
   474 done
   475 
   476 text{*The sequence @{term "r + 1/n"} tends to @{term r} as @{term n} tends to
   477 infinity is now easily proved*}
   478 
   479 lemma LIMSEQ_inverse_real_of_nat_add:
   480      "(%n. r + inverse(real(Suc n))) ----> r"
   481 by (cut_tac LIMSEQ_add [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   482 
   483 lemma LIMSEQ_inverse_real_of_nat_add_minus:
   484      "(%n. r + -inverse(real(Suc n))) ----> r"
   485 by (cut_tac LIMSEQ_add_minus [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat], auto)
   486 
   487 lemma LIMSEQ_inverse_real_of_nat_add_minus_mult:
   488      "(%n. r*( 1 + -inverse(real(Suc n)))) ----> r"
   489 by (cut_tac b=1 in
   490         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_inverse_real_of_nat_add_minus], auto)
   491 
   492 lemma LIMSEQ_le_const:
   493   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. a \<le> X n\<rbrakk> \<Longrightarrow> a \<le> x"
   494 apply (rule ccontr, simp only: linorder_not_le)
   495 apply (drule_tac r="a - x" in LIMSEQ_D, simp)
   496 apply clarsimp
   497 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI1)
   498 apply (drule_tac x="max N no" in spec, drule mp, rule le_maxI2)
   499 apply simp
   500 done
   501 
   502 lemma LIMSEQ_le_const2:
   503   "\<lbrakk>X ----> (x::real); \<exists>N. \<forall>n\<ge>N. X n \<le> a\<rbrakk> \<Longrightarrow> x \<le> a"
   504 apply (subgoal_tac "- a \<le> - x", simp)
   505 apply (rule LIMSEQ_le_const)
   506 apply (erule LIMSEQ_minus)
   507 apply simp
   508 done
   509 
   510 lemma LIMSEQ_le:
   511   "\<lbrakk>X ----> x; Y ----> y; \<exists>N. \<forall>n\<ge>N. X n \<le> Y n\<rbrakk> \<Longrightarrow> x \<le> (y::real)"
   512 apply (subgoal_tac "0 \<le> y - x", simp)
   513 apply (rule LIMSEQ_le_const)
   514 apply (erule (1) LIMSEQ_diff)
   515 apply (simp add: le_diff_eq)
   516 done
   517 
   518 
   519 subsection {* Convergence *}
   520 
   521 lemma limI: "X ----> L ==> lim X = L"
   522 apply (simp add: lim_def)
   523 apply (blast intro: LIMSEQ_unique)
   524 done
   525 
   526 lemma convergentD: "convergent X ==> \<exists>L. (X ----> L)"
   527 by (simp add: convergent_def)
   528 
   529 lemma convergentI: "(X ----> L) ==> convergent X"
   530 by (auto simp add: convergent_def)
   531 
   532 lemma convergent_LIMSEQ_iff: "convergent X = (X ----> lim X)"
   533 by (auto intro: theI LIMSEQ_unique simp add: convergent_def lim_def)
   534 
   535 lemma convergent_minus_iff:
   536   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
   537   shows "convergent X \<longleftrightarrow> convergent (\<lambda>n. - X n)"
   538 apply (simp add: convergent_def)
   539 apply (auto dest: LIMSEQ_minus)
   540 apply (drule LIMSEQ_minus, auto)
   541 done
   542 
   543 lemma lim_le:
   544   fixes x :: real
   545   assumes f: "convergent f" and fn_le: "!!n. f n \<le> x"
   546   shows "lim f \<le> x"
   547 proof (rule classical)
   548   assume "\<not> lim f \<le> x"
   549   hence 0: "0 < lim f - x" by arith
   550   have 1: "f----> lim f"
   551     by (metis convergent_LIMSEQ_iff f) 
   552   thus ?thesis
   553     proof (simp add: LIMSEQ_iff)
   554       assume "\<forall>r>0. \<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < r"
   555       hence "\<exists>no. \<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   556         by (metis 0)
   557       from this obtain no where "\<forall>n\<ge>no. \<bar>f n - lim f\<bar> < lim f - x"
   558         by blast
   559       thus "lim f \<le> x"
   560         by (metis add_cancel_end add_minus_cancel diff_def linorder_linear 
   561                   linorder_not_le minus_diff_eq abs_diff_less_iff fn_le) 
   562     qed
   563 qed
   564 
   565 text{* Given a binary function @{text "f:: nat \<Rightarrow> 'a \<Rightarrow> 'a"}, its values are uniquely determined by a function g *}
   566 
   567 lemma nat_function_unique: "EX! g. g 0 = e \<and> (\<forall>n. g (Suc n) = f n (g n))"
   568   unfolding Ex1_def
   569   apply (rule_tac x="nat_rec e f" in exI)
   570   apply (rule conjI)+
   571 apply (rule def_nat_rec_0, simp)
   572 apply (rule allI, rule def_nat_rec_Suc, simp)
   573 apply (rule allI, rule impI, rule ext)
   574 apply (erule conjE)
   575 apply (induct_tac x)
   576 apply (simp add: nat_rec_0)
   577 apply (erule_tac x="n" in allE)
   578 apply (simp)
   579 done
   580 
   581 text{*Subsequence (alternative definition, (e.g. Hoskins)*}
   582 
   583 lemma subseq_Suc_iff: "subseq f = (\<forall>n. (f n) < (f (Suc n)))"
   584 apply (simp add: subseq_def)
   585 apply (auto dest!: less_imp_Suc_add)
   586 apply (induct_tac k)
   587 apply (auto intro: less_trans)
   588 done
   589 
   590 lemma monoseq_Suc:
   591    "monoseq X = ((\<forall>n. X n \<le> X (Suc n))
   592                  | (\<forall>n. X (Suc n) \<le> X n))"
   593 apply (simp add: monoseq_def)
   594 apply (auto dest!: le_imp_less_or_eq)
   595 apply (auto intro!: lessI [THEN less_imp_le] dest!: less_imp_Suc_add)
   596 apply (induct_tac "ka")
   597 apply (auto intro: order_trans)
   598 apply (erule contrapos_np)
   599 apply (induct_tac "k")
   600 apply (auto intro: order_trans)
   601 done
   602 
   603 lemma monoI1: "\<forall>m. \<forall> n \<ge> m. X m \<le> X n ==> monoseq X"
   604 by (simp add: monoseq_def)
   605 
   606 lemma monoI2: "\<forall>m. \<forall> n \<ge> m. X n \<le> X m ==> monoseq X"
   607 by (simp add: monoseq_def)
   608 
   609 lemma mono_SucI1: "\<forall>n. X n \<le> X (Suc n) ==> monoseq X"
   610 by (simp add: monoseq_Suc)
   611 
   612 lemma mono_SucI2: "\<forall>n. X (Suc n) \<le> X n ==> monoseq X"
   613 by (simp add: monoseq_Suc)
   614 
   615 lemma monoseq_minus: assumes "monoseq a"
   616   shows "monoseq (\<lambda> n. - a n)"
   617 proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   618   case True
   619   hence "\<forall> m. \<forall> n \<ge> m. - a n \<le> - a m" by auto
   620   thus ?thesis by (rule monoI2)
   621 next
   622   case False
   623   hence "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" using `monoseq a`[unfolded monoseq_def] by auto
   624   thus ?thesis by (rule monoI1)
   625 qed
   626 
   627 lemma monoseq_le: assumes "monoseq a" and "a ----> x"
   628   shows "((\<forall> n. a n \<le> x) \<and> (\<forall>m. \<forall>n\<ge>m. a m \<le> a n)) \<or> 
   629          ((\<forall> n. x \<le> a n) \<and> (\<forall>m. \<forall>n\<ge>m. a n \<le> a m))"
   630 proof -
   631   { fix x n fix a :: "nat \<Rightarrow> real"
   632     assume "a ----> x" and "\<forall> m. \<forall> n \<ge> m. a m \<le> a n"
   633     hence monotone: "\<And> m n. m \<le> n \<Longrightarrow> a m \<le> a n" by auto
   634     have "a n \<le> x"
   635     proof (rule ccontr)
   636       assume "\<not> a n \<le> x" hence "x < a n" by auto
   637       hence "0 < a n - x" by auto
   638       from `a ----> x`[THEN LIMSEQ_D, OF this]
   639       obtain no where "\<And>n'. no \<le> n' \<Longrightarrow> norm (a n' - x) < a n - x" by blast
   640       hence "norm (a (max no n) - x) < a n - x" by auto
   641       moreover
   642       { fix n' have "n \<le> n' \<Longrightarrow> x < a n'" using monotone[where m=n and n=n'] and `x < a n` by auto }
   643       hence "x < a (max no n)" by auto
   644       ultimately
   645       have "a (max no n) < a n" by auto
   646       with monotone[where m=n and n="max no n"]
   647       show False by (auto simp:max_def split:split_if_asm)
   648     qed
   649   } note top_down = this
   650   { fix x n m fix a :: "nat \<Rightarrow> real"
   651     assume "a ----> x" and "monoseq a" and "a m < x"
   652     have "a n \<le> x \<and> (\<forall> m. \<forall> n \<ge> m. a m \<le> a n)"
   653     proof (cases "\<forall> m. \<forall> n \<ge> m. a m \<le> a n")
   654       case True with top_down and `a ----> x` show ?thesis by auto
   655     next
   656       case False with `monoseq a`[unfolded monoseq_def] have "\<forall> m. \<forall> n \<ge> m. - a m \<le> - a n" by auto
   657       hence "- a m \<le> - x" using top_down[OF LIMSEQ_minus[OF `a ----> x`]] by blast
   658       hence False using `a m < x` by auto
   659       thus ?thesis ..
   660     qed
   661   } note when_decided = this
   662 
   663   show ?thesis
   664   proof (cases "\<exists> m. a m \<noteq> x")
   665     case True then obtain m where "a m \<noteq> x" by auto
   666     show ?thesis
   667     proof (cases "a m < x")
   668       case True with when_decided[OF `a ----> x` `monoseq a`, where m2=m]
   669       show ?thesis by blast
   670     next
   671       case False hence "- a m < - x" using `a m \<noteq> x` by auto
   672       with when_decided[OF LIMSEQ_minus[OF `a ----> x`] monoseq_minus[OF `monoseq a`], where m2=m]
   673       show ?thesis by auto
   674     qed
   675   qed auto
   676 qed
   677 
   678 text{* for any sequence, there is a mootonic subsequence *}
   679 lemma seq_monosub: "\<exists>f. subseq f \<and> monoseq (\<lambda> n. (s (f n)))"
   680 proof-
   681   {assume H: "\<forall>n. \<exists>p >n. \<forall> m\<ge>p. s m \<le> s p"
   682     let ?P = "\<lambda> p n. p > n \<and> (\<forall>m \<ge> p. s m \<le> s p)"
   683     from nat_function_unique[of "SOME p. ?P p 0" "\<lambda>p n. SOME p. ?P p n"]
   684     obtain f where f: "f 0 = (SOME p. ?P p 0)" "\<forall>n. f (Suc n) = (SOME p. ?P p (f n))" by blast
   685     have "?P (f 0) 0"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p 0"]
   686       using H apply - 
   687       apply (erule allE[where x=0], erule exE, rule_tac x="p" in exI) 
   688       unfolding order_le_less by blast 
   689     hence f0: "f 0 > 0" "\<forall>m \<ge> f 0. s m \<le> s (f 0)" by blast+
   690     {fix n
   691       have "?P (f (Suc n)) (f n)" 
   692         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   693         using H apply - 
   694       apply (erule allE[where x="f n"], erule exE, rule_tac x="p" in exI) 
   695       unfolding order_le_less by blast 
   696     hence "f (Suc n) > f n" "\<forall>m \<ge> f (Suc n). s m \<le> s (f (Suc n))" by blast+}
   697   note fSuc = this
   698     {fix p q assume pq: "p \<ge> f q"
   699       have "s p \<le> s(f(q))"  using f0(2)[rule_format, of p] pq fSuc
   700         by (cases q, simp_all) }
   701     note pqth = this
   702     {fix q
   703       have "f (Suc q) > f q" apply (induct q) 
   704         using f0(1) fSuc(1)[of 0] apply simp by (rule fSuc(1))}
   705     note fss = this
   706     from fss have th1: "subseq f" unfolding subseq_Suc_iff ..
   707     {fix a b 
   708       have "f a \<le> f (a + b)"
   709       proof(induct b)
   710         case 0 thus ?case by simp
   711       next
   712         case (Suc b)
   713         from fSuc(1)[of "a + b"] Suc.hyps show ?case by simp
   714       qed}
   715     note fmon0 = this
   716     have "monoseq (\<lambda>n. s (f n))" 
   717     proof-
   718       {fix n
   719         have "s (f n) \<ge> s (f (Suc n))" 
   720         proof(cases n)
   721           case 0
   722           assume n0: "n = 0"
   723           from fSuc(1)[of 0] have th0: "f 0 \<le> f (Suc 0)" by simp
   724           from f0(2)[rule_format, OF th0] show ?thesis  using n0 by simp
   725         next
   726           case (Suc m)
   727           assume m: "n = Suc m"
   728           from fSuc(1)[of n] m have th0: "f (Suc m) \<le> f (Suc (Suc m))" by simp
   729           from m fSuc(2)[rule_format, OF th0] show ?thesis by simp 
   730         qed}
   731       thus "monoseq (\<lambda>n. s (f n))" unfolding monoseq_Suc by blast 
   732     qed
   733     with th1 have ?thesis by blast}
   734   moreover
   735   {fix N assume N: "\<forall>p >N. \<exists> m\<ge>p. s m > s p"
   736     {fix p assume p: "p \<ge> Suc N" 
   737       hence pN: "p > N" by arith with N obtain m where m: "m \<ge> p" "s m > s p" by blast
   738       have "m \<noteq> p" using m(2) by auto 
   739       with m have "\<exists>m>p. s p < s m" by - (rule exI[where x=m], auto)}
   740     note th0 = this
   741     let ?P = "\<lambda>m x. m > x \<and> s x < s m"
   742     from nat_function_unique[of "SOME x. ?P x (Suc N)" "\<lambda>m x. SOME y. ?P y x"]
   743     obtain f where f: "f 0 = (SOME x. ?P x (Suc N))" 
   744       "\<forall>n. f (Suc n) = (SOME m. ?P m (f n))" by blast
   745     have "?P (f 0) (Suc N)"  unfolding f(1) some_eq_ex[of "\<lambda>p. ?P p (Suc N)"]
   746       using N apply - 
   747       apply (erule allE[where x="Suc N"], clarsimp)
   748       apply (rule_tac x="m" in exI)
   749       apply auto
   750       apply (subgoal_tac "Suc N \<noteq> m")
   751       apply simp
   752       apply (rule ccontr, simp)
   753       done
   754     hence f0: "f 0 > Suc N" "s (Suc N) < s (f 0)" by blast+
   755     {fix n
   756       have "f n > N \<and> ?P (f (Suc n)) (f n)"
   757         unfolding f(2)[rule_format, of n] some_eq_ex[of "\<lambda>p. ?P p (f n)"]
   758       proof (induct n)
   759         case 0 thus ?case
   760           using f0 N apply auto 
   761           apply (erule allE[where x="f 0"], clarsimp) 
   762           apply (rule_tac x="m" in exI, simp)
   763           by (subgoal_tac "f 0 \<noteq> m", auto)
   764       next
   765         case (Suc n)
   766         from Suc.hyps have Nfn: "N < f n" by blast
   767         from Suc.hyps obtain m where m: "m > f n" "s (f n) < s m" by blast
   768         with Nfn have mN: "m > N" by arith
   769         note key = Suc.hyps[unfolded some_eq_ex[of "\<lambda>p. ?P p (f n)", symmetric] f(2)[rule_format, of n, symmetric]]
   770         
   771         from key have th0: "f (Suc n) > N" by simp
   772         from N[rule_format, OF th0]
   773         obtain m' where m': "m' \<ge> f (Suc n)" "s (f (Suc n)) < s m'" by blast
   774         have "m' \<noteq> f (Suc (n))" apply (rule ccontr) using m'(2) by auto
   775         hence "m' > f (Suc n)" using m'(1) by simp
   776         with key m'(2) show ?case by auto
   777       qed}
   778     note fSuc = this
   779     {fix n
   780       have "f n \<ge> Suc N \<and> f(Suc n) > f n \<and> s(f n) < s(f(Suc n))" using fSuc[of n] by auto 
   781       hence "f n \<ge> Suc N" "f(Suc n) > f n" "s(f n) < s(f(Suc n))" by blast+}
   782     note thf = this
   783     have sqf: "subseq f" unfolding subseq_Suc_iff using thf by simp
   784     have "monoseq (\<lambda>n. s (f n))"  unfolding monoseq_Suc using thf
   785       apply -
   786       apply (rule disjI1)
   787       apply auto
   788       apply (rule order_less_imp_le)
   789       apply blast
   790       done
   791     then have ?thesis  using sqf by blast}
   792   ultimately show ?thesis unfolding linorder_not_less[symmetric] by blast
   793 qed
   794 
   795 lemma seq_suble: assumes sf: "subseq f" shows "n \<le> f n"
   796 proof(induct n)
   797   case 0 thus ?case by simp
   798 next
   799   case (Suc n)
   800   from sf[unfolded subseq_Suc_iff, rule_format, of n] Suc.hyps
   801   have "n < f (Suc n)" by arith 
   802   thus ?case by arith
   803 qed
   804 
   805 lemma LIMSEQ_subseq_LIMSEQ:
   806   "\<lbrakk> X ----> L; subseq f \<rbrakk> \<Longrightarrow> (X o f) ----> L"
   807 apply (auto simp add: LIMSEQ_def) 
   808 apply (drule_tac x=r in spec, clarify)  
   809 apply (rule_tac x=no in exI, clarify) 
   810 apply (blast intro: seq_suble le_trans dest!: spec) 
   811 done
   812 
   813 subsection {* Bounded Monotonic Sequences *}
   814 
   815 
   816 text{*Bounded Sequence*}
   817 
   818 lemma BseqD: "Bseq X ==> \<exists>K. 0 < K & (\<forall>n. norm (X n) \<le> K)"
   819 by (simp add: Bseq_def)
   820 
   821 lemma BseqI: "[| 0 < K; \<forall>n. norm (X n) \<le> K |] ==> Bseq X"
   822 by (auto simp add: Bseq_def)
   823 
   824 lemma lemma_NBseq_def:
   825      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) =
   826       (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   827 proof auto
   828   fix K :: real
   829   from reals_Archimedean2 obtain n :: nat where "K < real n" ..
   830   then have "K \<le> real (Suc n)" by auto
   831   assume "\<forall>m. norm (X m) \<le> K"
   832   have "\<forall>m. norm (X m) \<le> real (Suc n)"
   833   proof
   834     fix m :: 'a
   835     from `\<forall>m. norm (X m) \<le> K` have "norm (X m) \<le> K" ..
   836     with `K \<le> real (Suc n)` show "norm (X m) \<le> real (Suc n)" by auto
   837   qed
   838   then show "\<exists>N. \<forall>n. norm (X n) \<le> real (Suc N)" ..
   839 next
   840   fix N :: nat
   841   have "real (Suc N) > 0" by (simp add: real_of_nat_Suc)
   842   moreover assume "\<forall>n. norm (X n) \<le> real (Suc N)"
   843   ultimately show "\<exists>K>0. \<forall>n. norm (X n) \<le> K" by blast
   844 qed
   845 
   846 
   847 text{* alternative definition for Bseq *}
   848 lemma Bseq_iff: "Bseq X = (\<exists>N. \<forall>n. norm (X n) \<le> real(Suc N))"
   849 apply (simp add: Bseq_def)
   850 apply (simp (no_asm) add: lemma_NBseq_def)
   851 done
   852 
   853 lemma lemma_NBseq_def2:
   854      "(\<exists>K > 0. \<forall>n. norm (X n) \<le> K) = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   855 apply (subst lemma_NBseq_def, auto)
   856 apply (rule_tac x = "Suc N" in exI)
   857 apply (rule_tac [2] x = N in exI)
   858 apply (auto simp add: real_of_nat_Suc)
   859  prefer 2 apply (blast intro: order_less_imp_le)
   860 apply (drule_tac x = n in spec, simp)
   861 done
   862 
   863 (* yet another definition for Bseq *)
   864 lemma Bseq_iff1a: "Bseq X = (\<exists>N. \<forall>n. norm (X n) < real(Suc N))"
   865 by (simp add: Bseq_def lemma_NBseq_def2)
   866 
   867 subsubsection{*Upper Bounds and Lubs of Bounded Sequences*}
   868 
   869 lemma Bseq_isUb:
   870   "!!(X::nat=>real). Bseq X ==> \<exists>U. isUb (UNIV::real set) {x. \<exists>n. X n = x} U"
   871 by (auto intro: isUbI setleI simp add: Bseq_def abs_le_iff)
   872 
   873 
   874 text{* Use completeness of reals (supremum property)
   875    to show that any bounded sequence has a least upper bound*}
   876 
   877 lemma Bseq_isLub:
   878   "!!(X::nat=>real). Bseq X ==>
   879    \<exists>U. isLub (UNIV::real set) {x. \<exists>n. X n = x} U"
   880 by (blast intro: reals_complete Bseq_isUb)
   881 
   882 subsubsection{*A Bounded and Monotonic Sequence Converges*}
   883 
   884 lemma lemma_converg1:
   885      "!!(X::nat=>real). [| \<forall>m. \<forall> n \<ge> m. X m \<le> X n;
   886                   isLub (UNIV::real set) {x. \<exists>n. X n = x} (X ma)
   887                |] ==> \<forall>n \<ge> ma. X n = X ma"
   888 apply safe
   889 apply (drule_tac y = "X n" in isLubD2)
   890 apply (blast dest: order_antisym)+
   891 done
   892 
   893 text{* The best of both worlds: Easier to prove this result as a standard
   894    theorem and then use equivalence to "transfer" it into the
   895    equivalent nonstandard form if needed!*}
   896 
   897 lemma Bmonoseq_LIMSEQ: "\<forall>n. m \<le> n --> X n = X m ==> \<exists>L. (X ----> L)"
   898 apply (simp add: LIMSEQ_def)
   899 apply (rule_tac x = "X m" in exI, safe)
   900 apply (rule_tac x = m in exI, safe)
   901 apply (drule spec, erule impE, auto)
   902 done
   903 
   904 lemma lemma_converg2:
   905    "!!(X::nat=>real).
   906     [| \<forall>m. X m ~= U;  isLub UNIV {x. \<exists>n. X n = x} U |] ==> \<forall>m. X m < U"
   907 apply safe
   908 apply (drule_tac y = "X m" in isLubD2)
   909 apply (auto dest!: order_le_imp_less_or_eq)
   910 done
   911 
   912 lemma lemma_converg3: "!!(X ::nat=>real). \<forall>m. X m \<le> U ==> isUb UNIV {x. \<exists>n. X n = x} U"
   913 by (rule setleI [THEN isUbI], auto)
   914 
   915 text{* FIXME: @{term "U - T < U"} is redundant *}
   916 lemma lemma_converg4: "!!(X::nat=> real).
   917                [| \<forall>m. X m ~= U;
   918                   isLub UNIV {x. \<exists>n. X n = x} U;
   919                   0 < T;
   920                   U + - T < U
   921                |] ==> \<exists>m. U + -T < X m & X m < U"
   922 apply (drule lemma_converg2, assumption)
   923 apply (rule ccontr, simp)
   924 apply (simp add: linorder_not_less)
   925 apply (drule lemma_converg3)
   926 apply (drule isLub_le_isUb, assumption)
   927 apply (auto dest: order_less_le_trans)
   928 done
   929 
   930 text{*A standard proof of the theorem for monotone increasing sequence*}
   931 
   932 lemma Bseq_mono_convergent:
   933      "[| Bseq X; \<forall>m. \<forall>n \<ge> m. X m \<le> X n |] ==> convergent (X::nat=>real)"
   934 apply (simp add: convergent_def)
   935 apply (frule Bseq_isLub, safe)
   936 apply (case_tac "\<exists>m. X m = U", auto)
   937 apply (blast dest: lemma_converg1 Bmonoseq_LIMSEQ)
   938 (* second case *)
   939 apply (rule_tac x = U in exI)
   940 apply (subst LIMSEQ_iff, safe)
   941 apply (frule lemma_converg2, assumption)
   942 apply (drule lemma_converg4, auto)
   943 apply (rule_tac x = m in exI, safe)
   944 apply (subgoal_tac "X m \<le> X n")
   945  prefer 2 apply blast
   946 apply (drule_tac x=n and P="%m. X m < U" in spec, arith)
   947 done
   948 
   949 lemma Bseq_minus_iff: "Bseq (%n. -(X n)) = Bseq X"
   950 by (simp add: Bseq_def)
   951 
   952 text{*Main monotonicity theorem*}
   953 lemma Bseq_monoseq_convergent: "[| Bseq X; monoseq X |] ==> convergent X"
   954 apply (simp add: monoseq_def, safe)
   955 apply (rule_tac [2] convergent_minus_iff [THEN ssubst])
   956 apply (drule_tac [2] Bseq_minus_iff [THEN ssubst])
   957 apply (auto intro!: Bseq_mono_convergent)
   958 done
   959 
   960 subsubsection{*Increasing and Decreasing Series*}
   961 
   962 lemma incseq_imp_monoseq:  "incseq X \<Longrightarrow> monoseq X"
   963   by (simp add: incseq_def monoseq_def) 
   964 
   965 lemma incseq_le: assumes inc: "incseq X" and lim: "X ----> L" shows "X n \<le> L"
   966   using monoseq_le [OF incseq_imp_monoseq [OF inc] lim]
   967 proof
   968   assume "(\<forall>n. X n \<le> L) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X m \<le> X n)"
   969   thus ?thesis by simp
   970 next
   971   assume "(\<forall>n. L \<le> X n) \<and> (\<forall>m n. m \<le> n \<longrightarrow> X n \<le> X m)"
   972   hence const: "(!!m n. m \<le> n \<Longrightarrow> X n = X m)" using inc
   973     by (auto simp add: incseq_def intro: order_antisym)
   974   have X: "!!n. X n = X 0"
   975     by (blast intro: const [of 0]) 
   976   have "X = (\<lambda>n. X 0)"
   977     by (blast intro: ext X)
   978   hence "L = X 0" using LIMSEQ_const [of "X 0"]
   979     by (auto intro: LIMSEQ_unique lim) 
   980   thus ?thesis
   981     by (blast intro: eq_refl X)
   982 qed
   983 
   984 lemma decseq_imp_monoseq:  "decseq X \<Longrightarrow> monoseq X"
   985   by (simp add: decseq_def monoseq_def)
   986 
   987 lemma decseq_eq_incseq: "decseq X = incseq (\<lambda>n. - X n)" 
   988   by (simp add: decseq_def incseq_def)
   989 
   990 
   991 lemma decseq_le: assumes dec: "decseq X" and lim: "X ----> L" shows "L \<le> X n"
   992 proof -
   993   have inc: "incseq (\<lambda>n. - X n)" using dec
   994     by (simp add: decseq_eq_incseq)
   995   have "- X n \<le> - L" 
   996     by (blast intro: incseq_le [OF inc] LIMSEQ_minus lim) 
   997   thus ?thesis
   998     by simp
   999 qed
  1000 
  1001 subsubsection{*A Few More Equivalence Theorems for Boundedness*}
  1002 
  1003 text{*alternative formulation for boundedness*}
  1004 lemma Bseq_iff2: "Bseq X = (\<exists>k > 0. \<exists>x. \<forall>n. norm (X(n) + -x) \<le> k)"
  1005 apply (unfold Bseq_def, safe)
  1006 apply (rule_tac [2] x = "k + norm x" in exI)
  1007 apply (rule_tac x = K in exI, simp)
  1008 apply (rule exI [where x = 0], auto)
  1009 apply (erule order_less_le_trans, simp)
  1010 apply (drule_tac x=n in spec, fold diff_def)
  1011 apply (drule order_trans [OF norm_triangle_ineq2])
  1012 apply simp
  1013 done
  1014 
  1015 text{*alternative formulation for boundedness*}
  1016 lemma Bseq_iff3: "Bseq X = (\<exists>k > 0. \<exists>N. \<forall>n. norm(X(n) + -X(N)) \<le> k)"
  1017 apply safe
  1018 apply (simp add: Bseq_def, safe)
  1019 apply (rule_tac x = "K + norm (X N)" in exI)
  1020 apply auto
  1021 apply (erule order_less_le_trans, simp)
  1022 apply (rule_tac x = N in exI, safe)
  1023 apply (drule_tac x = n in spec)
  1024 apply (rule order_trans [OF norm_triangle_ineq], simp)
  1025 apply (auto simp add: Bseq_iff2)
  1026 done
  1027 
  1028 lemma BseqI2: "(\<forall>n. k \<le> f n & f n \<le> (K::real)) ==> Bseq f"
  1029 apply (simp add: Bseq_def)
  1030 apply (rule_tac x = " (\<bar>k\<bar> + \<bar>K\<bar>) + 1" in exI, auto)
  1031 apply (drule_tac x = n in spec, arith)
  1032 done
  1033 
  1034 
  1035 subsection {* Cauchy Sequences *}
  1036 
  1037 lemma metric_CauchyI:
  1038   "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e) \<Longrightarrow> Cauchy X"
  1039 by (simp add: Cauchy_def)
  1040 
  1041 lemma metric_CauchyD:
  1042   "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. dist (X m) (X n) < e"
  1043 by (simp add: Cauchy_def)
  1044 
  1045 lemma Cauchy_iff:
  1046   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1047   shows "Cauchy X \<longleftrightarrow> (\<forall>e>0. \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e)"
  1048 unfolding Cauchy_def dist_norm ..
  1049 
  1050 lemma CauchyI:
  1051   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1052   shows "(\<And>e. 0 < e \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e) \<Longrightarrow> Cauchy X"
  1053 by (simp add: Cauchy_iff)
  1054 
  1055 lemma CauchyD:
  1056   fixes X :: "nat \<Rightarrow> 'a::real_normed_vector"
  1057   shows "\<lbrakk>Cauchy X; 0 < e\<rbrakk> \<Longrightarrow> \<exists>M. \<forall>m\<ge>M. \<forall>n\<ge>M. norm (X m - X n) < e"
  1058 by (simp add: Cauchy_iff)
  1059 
  1060 lemma Cauchy_subseq_Cauchy:
  1061   "\<lbrakk> Cauchy X; subseq f \<rbrakk> \<Longrightarrow> Cauchy (X o f)"
  1062 apply (auto simp add: Cauchy_def)
  1063 apply (drule_tac x=e in spec, clarify)
  1064 apply (rule_tac x=M in exI, clarify)
  1065 apply (blast intro: le_trans [OF _ seq_suble] dest!: spec)
  1066 done
  1067 
  1068 subsubsection {* Cauchy Sequences are Bounded *}
  1069 
  1070 text{*A Cauchy sequence is bounded -- this is the standard
  1071   proof mechanization rather than the nonstandard proof*}
  1072 
  1073 lemma lemmaCauchy: "\<forall>n \<ge> M. norm (X M - X n) < (1::real)
  1074           ==>  \<forall>n \<ge> M. norm (X n :: 'a::real_normed_vector) < 1 + norm (X M)"
  1075 apply (clarify, drule spec, drule (1) mp)
  1076 apply (simp only: norm_minus_commute)
  1077 apply (drule order_le_less_trans [OF norm_triangle_ineq2])
  1078 apply simp
  1079 done
  1080 
  1081 lemma Cauchy_Bseq: "Cauchy X ==> Bseq X"
  1082 apply (simp add: Cauchy_iff)
  1083 apply (drule spec, drule mp, rule zero_less_one, safe)
  1084 apply (drule_tac x="M" in spec, simp)
  1085 apply (drule lemmaCauchy)
  1086 apply (rule_tac k="M" in Bseq_offset)
  1087 apply (simp add: Bseq_def)
  1088 apply (rule_tac x="1 + norm (X M)" in exI)
  1089 apply (rule conjI, rule order_less_le_trans [OF zero_less_one], simp)
  1090 apply (simp add: order_less_imp_le)
  1091 done
  1092 
  1093 subsubsection {* Cauchy Sequences are Convergent *}
  1094 
  1095 class complete_space =
  1096   assumes Cauchy_convergent: "Cauchy X \<Longrightarrow> convergent X"
  1097 
  1098 class banach = real_normed_vector + complete_space
  1099 
  1100 theorem LIMSEQ_imp_Cauchy:
  1101   assumes X: "X ----> a" shows "Cauchy X"
  1102 proof (rule metric_CauchyI)
  1103   fix e::real assume "0 < e"
  1104   hence "0 < e/2" by simp
  1105   with X have "\<exists>N. \<forall>n\<ge>N. dist (X n) a < e/2" by (rule metric_LIMSEQ_D)
  1106   then obtain N where N: "\<forall>n\<ge>N. dist (X n) a < e/2" ..
  1107   show "\<exists>N. \<forall>m\<ge>N. \<forall>n\<ge>N. dist (X m) (X n) < e"
  1108   proof (intro exI allI impI)
  1109     fix m assume "N \<le> m"
  1110     hence m: "dist (X m) a < e/2" using N by fast
  1111     fix n assume "N \<le> n"
  1112     hence n: "dist (X n) a < e/2" using N by fast
  1113     have "dist (X m) (X n) \<le> dist (X m) a + dist (X n) a"
  1114       by (rule dist_triangle2)
  1115     also from m n have "\<dots> < e" by simp
  1116     finally show "dist (X m) (X n) < e" .
  1117   qed
  1118 qed
  1119 
  1120 lemma convergent_Cauchy: "convergent X \<Longrightarrow> Cauchy X"
  1121 unfolding convergent_def
  1122 by (erule exE, erule LIMSEQ_imp_Cauchy)
  1123 
  1124 lemma Cauchy_convergent_iff:
  1125   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1126   shows "Cauchy X = convergent X"
  1127 by (fast intro: Cauchy_convergent convergent_Cauchy)
  1128 
  1129 lemma convergent_subseq_convergent:
  1130   fixes X :: "nat \<Rightarrow> 'a::complete_space"
  1131   shows "\<lbrakk> convergent X; subseq f \<rbrakk> \<Longrightarrow> convergent (X o f)"
  1132   by (simp add: Cauchy_subseq_Cauchy Cauchy_convergent_iff [symmetric])
  1133 
  1134 text {*
  1135 Proof that Cauchy sequences converge based on the one from
  1136 http://pirate.shu.edu/~wachsmut/ira/numseq/proofs/cauconv.html
  1137 *}
  1138 
  1139 text {*
  1140   If sequence @{term "X"} is Cauchy, then its limit is the lub of
  1141   @{term "{r::real. \<exists>N. \<forall>n\<ge>N. r < X n}"}
  1142 *}
  1143 
  1144 lemma isUb_UNIV_I: "(\<And>y. y \<in> S \<Longrightarrow> y \<le> u) \<Longrightarrow> isUb UNIV S u"
  1145 by (simp add: isUbI setleI)
  1146 
  1147 locale real_Cauchy =
  1148   fixes X :: "nat \<Rightarrow> real"
  1149   assumes X: "Cauchy X"
  1150   fixes S :: "real set"
  1151   defines S_def: "S \<equiv> {x::real. \<exists>N. \<forall>n\<ge>N. x < X n}"
  1152 
  1153 lemma real_CauchyI:
  1154   assumes "Cauchy X"
  1155   shows "real_Cauchy X"
  1156   proof qed (fact assms)
  1157 
  1158 lemma (in real_Cauchy) mem_S: "\<forall>n\<ge>N. x < X n \<Longrightarrow> x \<in> S"
  1159 by (unfold S_def, auto)
  1160 
  1161 lemma (in real_Cauchy) bound_isUb:
  1162   assumes N: "\<forall>n\<ge>N. X n < x"
  1163   shows "isUb UNIV S x"
  1164 proof (rule isUb_UNIV_I)
  1165   fix y::real assume "y \<in> S"
  1166   hence "\<exists>M. \<forall>n\<ge>M. y < X n"
  1167     by (simp add: S_def)
  1168   then obtain M where "\<forall>n\<ge>M. y < X n" ..
  1169   hence "y < X (max M N)" by simp
  1170   also have "\<dots> < x" using N by simp
  1171   finally show "y \<le> x"
  1172     by (rule order_less_imp_le)
  1173 qed
  1174 
  1175 lemma (in real_Cauchy) isLub_ex: "\<exists>u. isLub UNIV S u"
  1176 proof (rule reals_complete)
  1177   obtain N where "\<forall>m\<ge>N. \<forall>n\<ge>N. norm (X m - X n) < 1"
  1178     using CauchyD [OF X zero_less_one] by auto
  1179   hence N: "\<forall>n\<ge>N. norm (X n - X N) < 1" by simp
  1180   show "\<exists>x. x \<in> S"
  1181   proof
  1182     from N have "\<forall>n\<ge>N. X N - 1 < X n"
  1183       by (simp add: abs_diff_less_iff)
  1184     thus "X N - 1 \<in> S" by (rule mem_S)
  1185   qed
  1186   show "\<exists>u. isUb UNIV S u"
  1187   proof
  1188     from N have "\<forall>n\<ge>N. X n < X N + 1"
  1189       by (simp add: abs_diff_less_iff)
  1190     thus "isUb UNIV S (X N + 1)"
  1191       by (rule bound_isUb)
  1192   qed
  1193 qed
  1194 
  1195 lemma (in real_Cauchy) isLub_imp_LIMSEQ:
  1196   assumes x: "isLub UNIV S x"
  1197   shows "X ----> x"
  1198 proof (rule LIMSEQ_I)
  1199   fix r::real assume "0 < r"
  1200   hence r: "0 < r/2" by simp
  1201   obtain N where "\<forall>n\<ge>N. \<forall>m\<ge>N. norm (X n - X m) < r/2"
  1202     using CauchyD [OF X r] by auto
  1203   hence "\<forall>n\<ge>N. norm (X n - X N) < r/2" by simp
  1204   hence N: "\<forall>n\<ge>N. X N - r/2 < X n \<and> X n < X N + r/2"
  1205     by (simp only: real_norm_def abs_diff_less_iff)
  1206 
  1207   from N have "\<forall>n\<ge>N. X N - r/2 < X n" by fast
  1208   hence "X N - r/2 \<in> S" by (rule mem_S)
  1209   hence 1: "X N - r/2 \<le> x" using x isLub_isUb isUbD by fast
  1210 
  1211   from N have "\<forall>n\<ge>N. X n < X N + r/2" by fast
  1212   hence "isUb UNIV S (X N + r/2)" by (rule bound_isUb)
  1213   hence 2: "x \<le> X N + r/2" using x isLub_le_isUb by fast
  1214 
  1215   show "\<exists>N. \<forall>n\<ge>N. norm (X n - x) < r"
  1216   proof (intro exI allI impI)
  1217     fix n assume n: "N \<le> n"
  1218     from N n have "X n < X N + r/2" and "X N - r/2 < X n" by simp+
  1219     thus "norm (X n - x) < r" using 1 2
  1220       by (simp add: abs_diff_less_iff)
  1221   qed
  1222 qed
  1223 
  1224 lemma (in real_Cauchy) LIMSEQ_ex: "\<exists>x. X ----> x"
  1225 proof -
  1226   obtain x where "isLub UNIV S x"
  1227     using isLub_ex by fast
  1228   hence "X ----> x"
  1229     by (rule isLub_imp_LIMSEQ)
  1230   thus ?thesis ..
  1231 qed
  1232 
  1233 lemma real_Cauchy_convergent:
  1234   fixes X :: "nat \<Rightarrow> real"
  1235   shows "Cauchy X \<Longrightarrow> convergent X"
  1236 unfolding convergent_def
  1237 by (rule real_Cauchy.LIMSEQ_ex)
  1238  (rule real_CauchyI)
  1239 
  1240 instance real :: banach
  1241 by intro_classes (rule real_Cauchy_convergent)
  1242 
  1243 
  1244 subsection {* Power Sequences *}
  1245 
  1246 text{*The sequence @{term "x^n"} tends to 0 if @{term "0\<le>x"} and @{term
  1247 "x<1"}.  Proof will use (NS) Cauchy equivalence for convergence and
  1248   also fact that bounded and monotonic sequence converges.*}
  1249 
  1250 lemma Bseq_realpow: "[| 0 \<le> (x::real); x \<le> 1 |] ==> Bseq (%n. x ^ n)"
  1251 apply (simp add: Bseq_def)
  1252 apply (rule_tac x = 1 in exI)
  1253 apply (simp add: power_abs)
  1254 apply (auto dest: power_mono)
  1255 done
  1256 
  1257 lemma monoseq_realpow: "[| 0 \<le> x; x \<le> 1 |] ==> monoseq (%n. x ^ n)"
  1258 apply (clarify intro!: mono_SucI2)
  1259 apply (cut_tac n = n and N = "Suc n" and a = x in power_decreasing, auto)
  1260 done
  1261 
  1262 lemma convergent_realpow:
  1263   "[| 0 \<le> (x::real); x \<le> 1 |] ==> convergent (%n. x ^ n)"
  1264 by (blast intro!: Bseq_monoseq_convergent Bseq_realpow monoseq_realpow)
  1265 
  1266 lemma LIMSEQ_inverse_realpow_zero_lemma:
  1267   fixes x :: real
  1268   assumes x: "0 \<le> x"
  1269   shows "real n * x + 1 \<le> (x + 1) ^ n"
  1270 apply (induct n)
  1271 apply simp
  1272 apply simp
  1273 apply (rule order_trans)
  1274 prefer 2
  1275 apply (erule mult_left_mono)
  1276 apply (rule add_increasing [OF x], simp)
  1277 apply (simp add: real_of_nat_Suc)
  1278 apply (simp add: ring_distribs)
  1279 apply (simp add: mult_nonneg_nonneg x)
  1280 done
  1281 
  1282 lemma LIMSEQ_inverse_realpow_zero:
  1283   "1 < (x::real) \<Longrightarrow> (\<lambda>n. inverse (x ^ n)) ----> 0"
  1284 proof (rule LIMSEQ_inverse_zero [rule_format])
  1285   fix y :: real
  1286   assume x: "1 < x"
  1287   hence "0 < x - 1" by simp
  1288   hence "\<forall>y. \<exists>N::nat. y < real N * (x - 1)"
  1289     by (rule reals_Archimedean3)
  1290   hence "\<exists>N::nat. y < real N * (x - 1)" ..
  1291   then obtain N::nat where "y < real N * (x - 1)" ..
  1292   also have "\<dots> \<le> real N * (x - 1) + 1" by simp
  1293   also have "\<dots> \<le> (x - 1 + 1) ^ N"
  1294     by (rule LIMSEQ_inverse_realpow_zero_lemma, cut_tac x, simp)
  1295   also have "\<dots> = x ^ N" by simp
  1296   finally have "y < x ^ N" .
  1297   hence "\<forall>n\<ge>N. y < x ^ n"
  1298     apply clarify
  1299     apply (erule order_less_le_trans)
  1300     apply (erule power_increasing)
  1301     apply (rule order_less_imp_le [OF x])
  1302     done
  1303   thus "\<exists>N. \<forall>n\<ge>N. y < x ^ n" ..
  1304 qed
  1305 
  1306 lemma LIMSEQ_realpow_zero:
  1307   "\<lbrakk>0 \<le> (x::real); x < 1\<rbrakk> \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1308 proof (cases)
  1309   assume "x = 0"
  1310   hence "(\<lambda>n. x ^ Suc n) ----> 0" by (simp add: LIMSEQ_const)
  1311   thus ?thesis by (rule LIMSEQ_imp_Suc)
  1312 next
  1313   assume "0 \<le> x" and "x \<noteq> 0"
  1314   hence x0: "0 < x" by simp
  1315   assume x1: "x < 1"
  1316   from x0 x1 have "1 < inverse x"
  1317     by (rule real_inverse_gt_one)
  1318   hence "(\<lambda>n. inverse (inverse x ^ n)) ----> 0"
  1319     by (rule LIMSEQ_inverse_realpow_zero)
  1320   thus ?thesis by (simp add: power_inverse)
  1321 qed
  1322 
  1323 lemma LIMSEQ_power_zero:
  1324   fixes x :: "'a::{real_normed_algebra_1}"
  1325   shows "norm x < 1 \<Longrightarrow> (\<lambda>n. x ^ n) ----> 0"
  1326 apply (drule LIMSEQ_realpow_zero [OF norm_ge_zero])
  1327 apply (simp only: LIMSEQ_Zseq_iff, erule Zseq_le)
  1328 apply (simp add: power_abs norm_power_ineq)
  1329 done
  1330 
  1331 lemma LIMSEQ_divide_realpow_zero:
  1332   "1 < (x::real) ==> (%n. a / (x ^ n)) ----> 0"
  1333 apply (cut_tac a = a and x1 = "inverse x" in
  1334         LIMSEQ_mult [OF LIMSEQ_const LIMSEQ_realpow_zero])
  1335 apply (auto simp add: divide_inverse power_inverse)
  1336 apply (simp add: inverse_eq_divide pos_divide_less_eq)
  1337 done
  1338 
  1339 text{*Limit of @{term "c^n"} for @{term"\<bar>c\<bar> < 1"}*}
  1340 
  1341 lemma LIMSEQ_rabs_realpow_zero: "\<bar>c\<bar> < (1::real) ==> (%n. \<bar>c\<bar> ^ n) ----> 0"
  1342 by (rule LIMSEQ_realpow_zero [OF abs_ge_zero])
  1343 
  1344 lemma LIMSEQ_rabs_realpow_zero2: "\<bar>c\<bar> < (1::real) ==> (%n. c ^ n) ----> 0"
  1345 apply (rule LIMSEQ_rabs_zero [THEN iffD1])
  1346 apply (auto intro: LIMSEQ_rabs_realpow_zero simp add: power_abs)
  1347 done
  1348 
  1349 end