src/HOL/Transitive_Closure.thy
author haftmann
Fri Nov 27 08:41:10 2009 +0100 (2009-11-27)
changeset 33963 977b94b64905
parent 33878 85102f57b4a8
child 34909 a799687944af
permissions -rw-r--r--
renamed former datatype.ML to datatype_data.ML; datatype.ML provides uniform view on datatype.ML and datatype_rep_proofs.ML
     1 (*  Title:      HOL/Transitive_Closure.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1992  University of Cambridge
     4 *)
     5 
     6 header {* Reflexive and Transitive closure of a relation *}
     7 
     8 theory Transitive_Closure
     9 imports Predicate
    10 uses "~~/src/Provers/trancl.ML"
    11 begin
    12 
    13 text {*
    14   @{text rtrancl} is reflexive/transitive closure,
    15   @{text trancl} is transitive closure,
    16   @{text reflcl} is reflexive closure.
    17 
    18   These postfix operators have \emph{maximum priority}, forcing their
    19   operands to be atomic.
    20 *}
    21 
    22 inductive_set
    23   rtrancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"   ("(_^*)" [1000] 999)
    24   for r :: "('a \<times> 'a) set"
    25 where
    26     rtrancl_refl [intro!, Pure.intro!, simp]: "(a, a) : r^*"
    27   | rtrancl_into_rtrancl [Pure.intro]: "(a, b) : r^* ==> (b, c) : r ==> (a, c) : r^*"
    28 
    29 inductive_set
    30   trancl :: "('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"  ("(_^+)" [1000] 999)
    31   for r :: "('a \<times> 'a) set"
    32 where
    33     r_into_trancl [intro, Pure.intro]: "(a, b) : r ==> (a, b) : r^+"
    34   | trancl_into_trancl [Pure.intro]: "(a, b) : r^+ ==> (b, c) : r ==> (a, c) : r^+"
    35 
    36 declare rtrancl_def [nitpick_def del]
    37         rtranclp_def [nitpick_def del]
    38         trancl_def [nitpick_def del]
    39         tranclp_def [nitpick_def del]
    40 
    41 notation
    42   rtranclp  ("(_^**)" [1000] 1000) and
    43   tranclp  ("(_^++)" [1000] 1000)
    44 
    45 abbreviation
    46   reflclp :: "('a => 'a => bool) => 'a => 'a => bool"  ("(_^==)" [1000] 1000) where
    47   "r^== == sup r op ="
    48 
    49 abbreviation
    50   reflcl :: "('a \<times> 'a) set => ('a \<times> 'a) set"  ("(_^=)" [1000] 999) where
    51   "r^= == r \<union> Id"
    52 
    53 notation (xsymbols)
    54   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    55   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    56   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    57   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    58   trancl  ("(_\<^sup>+)" [1000] 999) and
    59   reflcl  ("(_\<^sup>=)" [1000] 999)
    60 
    61 notation (HTML output)
    62   rtranclp  ("(_\<^sup>*\<^sup>*)" [1000] 1000) and
    63   tranclp  ("(_\<^sup>+\<^sup>+)" [1000] 1000) and
    64   reflclp  ("(_\<^sup>=\<^sup>=)" [1000] 1000) and
    65   rtrancl  ("(_\<^sup>*)" [1000] 999) and
    66   trancl  ("(_\<^sup>+)" [1000] 999) and
    67   reflcl  ("(_\<^sup>=)" [1000] 999)
    68 
    69 
    70 subsection {* Reflexive closure *}
    71 
    72 lemma refl_reflcl[simp]: "refl(r^=)"
    73 by(simp add:refl_on_def)
    74 
    75 lemma antisym_reflcl[simp]: "antisym(r^=) = antisym r"
    76 by(simp add:antisym_def)
    77 
    78 lemma trans_reflclI[simp]: "trans r \<Longrightarrow> trans(r^=)"
    79 unfolding trans_def by blast
    80 
    81 
    82 subsection {* Reflexive-transitive closure *}
    83 
    84 lemma reflcl_set_eq [pred_set_conv]: "(sup (\<lambda>x y. (x, y) \<in> r) op =) = (\<lambda>x y. (x, y) \<in> r \<union> Id)"
    85   by (auto simp add: expand_fun_eq)
    86 
    87 lemma r_into_rtrancl [intro]: "!!p. p \<in> r ==> p \<in> r^*"
    88   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    89   apply (simp only: split_tupled_all)
    90   apply (erule rtrancl_refl [THEN rtrancl_into_rtrancl])
    91   done
    92 
    93 lemma r_into_rtranclp [intro]: "r x y ==> r^** x y"
    94   -- {* @{text rtrancl} of @{text r} contains @{text r} *}
    95   by (erule rtranclp.rtrancl_refl [THEN rtranclp.rtrancl_into_rtrancl])
    96 
    97 lemma rtranclp_mono: "r \<le> s ==> r^** \<le> s^**"
    98   -- {* monotonicity of @{text rtrancl} *}
    99   apply (rule predicate2I)
   100   apply (erule rtranclp.induct)
   101    apply (rule_tac [2] rtranclp.rtrancl_into_rtrancl, blast+)
   102   done
   103 
   104 lemmas rtrancl_mono = rtranclp_mono [to_set]
   105 
   106 theorem rtranclp_induct [consumes 1, case_names base step, induct set: rtranclp]:
   107   assumes a: "r^** a b"
   108     and cases: "P a" "!!y z. [| r^** a y; r y z; P y |] ==> P z"
   109   shows "P b"
   110 proof -
   111   from a have "a = a --> P b"
   112     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
   113   then show ?thesis by iprover
   114 qed
   115 
   116 lemmas rtrancl_induct [induct set: rtrancl] = rtranclp_induct [to_set]
   117 
   118 lemmas rtranclp_induct2 =
   119   rtranclp_induct[of _ "(ax,ay)" "(bx,by)", split_rule,
   120                  consumes 1, case_names refl step]
   121 
   122 lemmas rtrancl_induct2 =
   123   rtrancl_induct[of "(ax,ay)" "(bx,by)", split_format (complete),
   124                  consumes 1, case_names refl step]
   125 
   126 lemma refl_rtrancl: "refl (r^*)"
   127 by (unfold refl_on_def) fast
   128 
   129 text {* Transitivity of transitive closure. *}
   130 lemma trans_rtrancl: "trans (r^*)"
   131 proof (rule transI)
   132   fix x y z
   133   assume "(x, y) \<in> r\<^sup>*"
   134   assume "(y, z) \<in> r\<^sup>*"
   135   then show "(x, z) \<in> r\<^sup>*"
   136   proof induct
   137     case base
   138     show "(x, y) \<in> r\<^sup>*" by fact
   139   next
   140     case (step u v)
   141     from `(x, u) \<in> r\<^sup>*` and `(u, v) \<in> r`
   142     show "(x, v) \<in> r\<^sup>*" ..
   143   qed
   144 qed
   145 
   146 lemmas rtrancl_trans = trans_rtrancl [THEN transD, standard]
   147 
   148 lemma rtranclp_trans:
   149   assumes xy: "r^** x y"
   150   and yz: "r^** y z"
   151   shows "r^** x z" using yz xy
   152   by induct iprover+
   153 
   154 lemma rtranclE [cases set: rtrancl]:
   155   assumes major: "(a::'a, b) : r^*"
   156   obtains
   157     (base) "a = b"
   158   | (step) y where "(a, y) : r^*" and "(y, b) : r"
   159   -- {* elimination of @{text rtrancl} -- by induction on a special formula *}
   160   apply (subgoal_tac "(a::'a) = b | (EX y. (a,y) : r^* & (y,b) : r)")
   161    apply (rule_tac [2] major [THEN rtrancl_induct])
   162     prefer 2 apply blast
   163    prefer 2 apply blast
   164   apply (erule asm_rl exE disjE conjE base step)+
   165   done
   166 
   167 lemma rtrancl_Int_subset: "[| Id \<subseteq> s; (r^* \<inter> s) O r \<subseteq> s|] ==> r^* \<subseteq> s"
   168   apply (rule subsetI)
   169   apply (rule_tac p="x" in PairE, clarify)
   170   apply (erule rtrancl_induct, auto) 
   171   done
   172 
   173 lemma converse_rtranclp_into_rtranclp:
   174   "r a b \<Longrightarrow> r\<^sup>*\<^sup>* b c \<Longrightarrow> r\<^sup>*\<^sup>* a c"
   175   by (rule rtranclp_trans) iprover+
   176 
   177 lemmas converse_rtrancl_into_rtrancl = converse_rtranclp_into_rtranclp [to_set]
   178 
   179 text {*
   180   \medskip More @{term "r^*"} equations and inclusions.
   181 *}
   182 
   183 lemma rtranclp_idemp [simp]: "(r^**)^** = r^**"
   184   apply (auto intro!: order_antisym)
   185   apply (erule rtranclp_induct)
   186    apply (rule rtranclp.rtrancl_refl)
   187   apply (blast intro: rtranclp_trans)
   188   done
   189 
   190 lemmas rtrancl_idemp [simp] = rtranclp_idemp [to_set]
   191 
   192 lemma rtrancl_idemp_self_comp [simp]: "R^* O R^* = R^*"
   193   apply (rule set_ext)
   194   apply (simp only: split_tupled_all)
   195   apply (blast intro: rtrancl_trans)
   196   done
   197 
   198 lemma rtrancl_subset_rtrancl: "r \<subseteq> s^* ==> r^* \<subseteq> s^*"
   199   apply (drule rtrancl_mono)
   200   apply simp
   201   done
   202 
   203 lemma rtranclp_subset: "R \<le> S ==> S \<le> R^** ==> S^** = R^**"
   204   apply (drule rtranclp_mono)
   205   apply (drule rtranclp_mono)
   206   apply simp
   207   done
   208 
   209 lemmas rtrancl_subset = rtranclp_subset [to_set]
   210 
   211 lemma rtranclp_sup_rtranclp: "(sup (R^**) (S^**))^** = (sup R S)^**"
   212   by (blast intro!: rtranclp_subset intro: rtranclp_mono [THEN predicate2D])
   213 
   214 lemmas rtrancl_Un_rtrancl = rtranclp_sup_rtranclp [to_set]
   215 
   216 lemma rtranclp_reflcl [simp]: "(R^==)^** = R^**"
   217   by (blast intro!: rtranclp_subset)
   218 
   219 lemmas rtrancl_reflcl [simp] = rtranclp_reflcl [to_set]
   220 
   221 lemma rtrancl_r_diff_Id: "(r - Id)^* = r^*"
   222   apply (rule sym)
   223   apply (rule rtrancl_subset, blast, clarify)
   224   apply (rename_tac a b)
   225   apply (case_tac "a = b")
   226    apply blast
   227   apply (blast intro!: r_into_rtrancl)
   228   done
   229 
   230 lemma rtranclp_r_diff_Id: "(inf r op ~=)^** = r^**"
   231   apply (rule sym)
   232   apply (rule rtranclp_subset)
   233    apply blast+
   234   done
   235 
   236 theorem rtranclp_converseD:
   237   assumes r: "(r^--1)^** x y"
   238   shows "r^** y x"
   239 proof -
   240   from r show ?thesis
   241     by induct (iprover intro: rtranclp_trans dest!: conversepD)+
   242 qed
   243 
   244 lemmas rtrancl_converseD = rtranclp_converseD [to_set]
   245 
   246 theorem rtranclp_converseI:
   247   assumes "r^** y x"
   248   shows "(r^--1)^** x y"
   249   using assms
   250   by induct (iprover intro: rtranclp_trans conversepI)+
   251 
   252 lemmas rtrancl_converseI = rtranclp_converseI [to_set]
   253 
   254 lemma rtrancl_converse: "(r^-1)^* = (r^*)^-1"
   255   by (fast dest!: rtrancl_converseD intro!: rtrancl_converseI)
   256 
   257 lemma sym_rtrancl: "sym r ==> sym (r^*)"
   258   by (simp only: sym_conv_converse_eq rtrancl_converse [symmetric])
   259 
   260 theorem converse_rtranclp_induct[consumes 1]:
   261   assumes major: "r^** a b"
   262     and cases: "P b" "!!y z. [| r y z; r^** z b; P z |] ==> P y"
   263   shows "P a"
   264   using rtranclp_converseI [OF major]
   265   by induct (iprover intro: cases dest!: conversepD rtranclp_converseD)+
   266 
   267 lemmas converse_rtrancl_induct = converse_rtranclp_induct [to_set]
   268 
   269 lemmas converse_rtranclp_induct2 =
   270   converse_rtranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   271                  consumes 1, case_names refl step]
   272 
   273 lemmas converse_rtrancl_induct2 =
   274   converse_rtrancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   275                  consumes 1, case_names refl step]
   276 
   277 lemma converse_rtranclpE:
   278   assumes major: "r^** x z"
   279     and cases: "x=z ==> P"
   280       "!!y. [| r x y; r^** y z |] ==> P"
   281   shows P
   282   apply (subgoal_tac "x = z | (EX y. r x y & r^** y z)")
   283    apply (rule_tac [2] major [THEN converse_rtranclp_induct])
   284     prefer 2 apply iprover
   285    prefer 2 apply iprover
   286   apply (erule asm_rl exE disjE conjE cases)+
   287   done
   288 
   289 lemmas converse_rtranclE = converse_rtranclpE [to_set]
   290 
   291 lemmas converse_rtranclpE2 = converse_rtranclpE [of _ "(xa,xb)" "(za,zb)", split_rule]
   292 
   293 lemmas converse_rtranclE2 = converse_rtranclE [of "(xa,xb)" "(za,zb)", split_rule]
   294 
   295 lemma r_comp_rtrancl_eq: "r O r^* = r^* O r"
   296   by (blast elim: rtranclE converse_rtranclE
   297     intro: rtrancl_into_rtrancl converse_rtrancl_into_rtrancl)
   298 
   299 lemma rtrancl_unfold: "r^* = Id Un r^* O r"
   300   by (auto intro: rtrancl_into_rtrancl elim: rtranclE)
   301 
   302 lemma rtrancl_Un_separatorE:
   303   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (a,x) : P^* \<longrightarrow> (x,y) : Q \<longrightarrow> x=y \<Longrightarrow> (a,b) : P^*"
   304 apply (induct rule:rtrancl.induct)
   305  apply blast
   306 apply (blast intro:rtrancl_trans)
   307 done
   308 
   309 lemma rtrancl_Un_separator_converseE:
   310   "(a,b) : (P \<union> Q)^* \<Longrightarrow> \<forall>x y. (x,b) : P^* \<longrightarrow> (y,x) : Q \<longrightarrow> y=x \<Longrightarrow> (a,b) : P^*"
   311 apply (induct rule:converse_rtrancl_induct)
   312  apply blast
   313 apply (blast intro:rtrancl_trans)
   314 done
   315 
   316 
   317 subsection {* Transitive closure *}
   318 
   319 lemma trancl_mono: "!!p. p \<in> r^+ ==> r \<subseteq> s ==> p \<in> s^+"
   320   apply (simp add: split_tupled_all)
   321   apply (erule trancl.induct)
   322    apply (iprover dest: subsetD)+
   323   done
   324 
   325 lemma r_into_trancl': "!!p. p : r ==> p : r^+"
   326   by (simp only: split_tupled_all) (erule r_into_trancl)
   327 
   328 text {*
   329   \medskip Conversions between @{text trancl} and @{text rtrancl}.
   330 *}
   331 
   332 lemma tranclp_into_rtranclp: "r^++ a b ==> r^** a b"
   333   by (erule tranclp.induct) iprover+
   334 
   335 lemmas trancl_into_rtrancl = tranclp_into_rtranclp [to_set]
   336 
   337 lemma rtranclp_into_tranclp1: assumes r: "r^** a b"
   338   shows "!!c. r b c ==> r^++ a c" using r
   339   by induct iprover+
   340 
   341 lemmas rtrancl_into_trancl1 = rtranclp_into_tranclp1 [to_set]
   342 
   343 lemma rtranclp_into_tranclp2: "[| r a b; r^** b c |] ==> r^++ a c"
   344   -- {* intro rule from @{text r} and @{text rtrancl} *}
   345   apply (erule rtranclp.cases)
   346    apply iprover
   347   apply (rule rtranclp_trans [THEN rtranclp_into_tranclp1])
   348     apply (simp | rule r_into_rtranclp)+
   349   done
   350 
   351 lemmas rtrancl_into_trancl2 = rtranclp_into_tranclp2 [to_set]
   352 
   353 text {* Nice induction rule for @{text trancl} *}
   354 lemma tranclp_induct [consumes 1, case_names base step, induct pred: tranclp]:
   355   assumes "r^++ a b"
   356   and cases: "!!y. r a y ==> P y"
   357     "!!y z. r^++ a y ==> r y z ==> P y ==> P z"
   358   shows "P b"
   359 proof -
   360   from `r^++ a b` have "a = a --> P b"
   361     by (induct "%x y. x = a --> P y" a b) (iprover intro: cases)+
   362   then show ?thesis by iprover
   363 qed
   364 
   365 lemmas trancl_induct [induct set: trancl] = tranclp_induct [to_set]
   366 
   367 lemmas tranclp_induct2 =
   368   tranclp_induct [of _ "(ax,ay)" "(bx,by)", split_rule,
   369     consumes 1, case_names base step]
   370 
   371 lemmas trancl_induct2 =
   372   trancl_induct [of "(ax,ay)" "(bx,by)", split_format (complete),
   373     consumes 1, case_names base step]
   374 
   375 lemma tranclp_trans_induct:
   376   assumes major: "r^++ x y"
   377     and cases: "!!x y. r x y ==> P x y"
   378       "!!x y z. [| r^++ x y; P x y; r^++ y z; P y z |] ==> P x z"
   379   shows "P x y"
   380   -- {* Another induction rule for trancl, incorporating transitivity *}
   381   by (iprover intro: major [THEN tranclp_induct] cases)
   382 
   383 lemmas trancl_trans_induct = tranclp_trans_induct [to_set]
   384 
   385 lemma tranclE [cases set: trancl]:
   386   assumes "(a, b) : r^+"
   387   obtains
   388     (base) "(a, b) : r"
   389   | (step) c where "(a, c) : r^+" and "(c, b) : r"
   390   using assms by cases simp_all
   391 
   392 lemma trancl_Int_subset: "[| r \<subseteq> s; (r^+ \<inter> s) O r \<subseteq> s|] ==> r^+ \<subseteq> s"
   393   apply (rule subsetI)
   394   apply (rule_tac p = x in PairE)
   395   apply clarify
   396   apply (erule trancl_induct)
   397    apply auto
   398   done
   399 
   400 lemma trancl_unfold: "r^+ = r Un r^+ O r"
   401   by (auto intro: trancl_into_trancl elim: tranclE)
   402 
   403 text {* Transitivity of @{term "r^+"} *}
   404 lemma trans_trancl [simp]: "trans (r^+)"
   405 proof (rule transI)
   406   fix x y z
   407   assume "(x, y) \<in> r^+"
   408   assume "(y, z) \<in> r^+"
   409   then show "(x, z) \<in> r^+"
   410   proof induct
   411     case (base u)
   412     from `(x, y) \<in> r^+` and `(y, u) \<in> r`
   413     show "(x, u) \<in> r^+" ..
   414   next
   415     case (step u v)
   416     from `(x, u) \<in> r^+` and `(u, v) \<in> r`
   417     show "(x, v) \<in> r^+" ..
   418   qed
   419 qed
   420 
   421 lemmas trancl_trans = trans_trancl [THEN transD, standard]
   422 
   423 lemma tranclp_trans:
   424   assumes xy: "r^++ x y"
   425   and yz: "r^++ y z"
   426   shows "r^++ x z" using yz xy
   427   by induct iprover+
   428 
   429 lemma trancl_id [simp]: "trans r \<Longrightarrow> r^+ = r"
   430   apply auto
   431   apply (erule trancl_induct)
   432    apply assumption
   433   apply (unfold trans_def)
   434   apply blast
   435   done
   436 
   437 lemma rtranclp_tranclp_tranclp:
   438   assumes "r^** x y"
   439   shows "!!z. r^++ y z ==> r^++ x z" using assms
   440   by induct (iprover intro: tranclp_trans)+
   441 
   442 lemmas rtrancl_trancl_trancl = rtranclp_tranclp_tranclp [to_set]
   443 
   444 lemma tranclp_into_tranclp2: "r a b ==> r^++ b c ==> r^++ a c"
   445   by (erule tranclp_trans [OF tranclp.r_into_trancl])
   446 
   447 lemmas trancl_into_trancl2 = tranclp_into_tranclp2 [to_set]
   448 
   449 lemma trancl_insert:
   450   "(insert (y, x) r)^+ = r^+ \<union> {(a, b). (a, y) \<in> r^* \<and> (x, b) \<in> r^*}"
   451   -- {* primitive recursion for @{text trancl} over finite relations *}
   452   apply (rule equalityI)
   453    apply (rule subsetI)
   454    apply (simp only: split_tupled_all)
   455    apply (erule trancl_induct, blast)
   456    apply (blast intro: rtrancl_into_trancl1 trancl_into_rtrancl r_into_trancl trancl_trans)
   457   apply (rule subsetI)
   458   apply (blast intro: trancl_mono rtrancl_mono
   459     [THEN [2] rev_subsetD] rtrancl_trancl_trancl rtrancl_into_trancl2)
   460   done
   461 
   462 lemma tranclp_converseI: "(r^++)^--1 x y ==> (r^--1)^++ x y"
   463   apply (drule conversepD)
   464   apply (erule tranclp_induct)
   465   apply (iprover intro: conversepI tranclp_trans)+
   466   done
   467 
   468 lemmas trancl_converseI = tranclp_converseI [to_set]
   469 
   470 lemma tranclp_converseD: "(r^--1)^++ x y ==> (r^++)^--1 x y"
   471   apply (rule conversepI)
   472   apply (erule tranclp_induct)
   473   apply (iprover dest: conversepD intro: tranclp_trans)+
   474   done
   475 
   476 lemmas trancl_converseD = tranclp_converseD [to_set]
   477 
   478 lemma tranclp_converse: "(r^--1)^++ = (r^++)^--1"
   479   by (fastsimp simp add: expand_fun_eq
   480     intro!: tranclp_converseI dest!: tranclp_converseD)
   481 
   482 lemmas trancl_converse = tranclp_converse [to_set]
   483 
   484 lemma sym_trancl: "sym r ==> sym (r^+)"
   485   by (simp only: sym_conv_converse_eq trancl_converse [symmetric])
   486 
   487 lemma converse_tranclp_induct:
   488   assumes major: "r^++ a b"
   489     and cases: "!!y. r y b ==> P(y)"
   490       "!!y z.[| r y z;  r^++ z b;  P(z) |] ==> P(y)"
   491   shows "P a"
   492   apply (rule tranclp_induct [OF tranclp_converseI, OF conversepI, OF major])
   493    apply (rule cases)
   494    apply (erule conversepD)
   495   apply (blast intro: prems dest!: tranclp_converseD conversepD)
   496   done
   497 
   498 lemmas converse_trancl_induct = converse_tranclp_induct [to_set]
   499 
   500 lemma tranclpD: "R^++ x y ==> EX z. R x z \<and> R^** z y"
   501   apply (erule converse_tranclp_induct)
   502    apply auto
   503   apply (blast intro: rtranclp_trans)
   504   done
   505 
   506 lemmas tranclD = tranclpD [to_set]
   507 
   508 lemma converse_tranclpE:
   509   assumes major: "tranclp r x z"
   510   assumes base: "r x z ==> P"
   511   assumes step: "\<And> y. [| r x y; tranclp r y z |] ==> P"
   512   shows P
   513 proof -
   514   from tranclpD[OF major]
   515   obtain y where "r x y" and "rtranclp r y z" by iprover
   516   from this(2) show P
   517   proof (cases rule: rtranclp.cases)
   518     case rtrancl_refl
   519     with `r x y` base show P by iprover
   520   next
   521     case rtrancl_into_rtrancl
   522     from this have "tranclp r y z"
   523       by (iprover intro: rtranclp_into_tranclp1)
   524     with `r x y` step show P by iprover
   525   qed
   526 qed
   527 
   528 lemmas converse_tranclE = converse_tranclpE [to_set]
   529 
   530 lemma tranclD2:
   531   "(x, y) \<in> R\<^sup>+ \<Longrightarrow> \<exists>z. (x, z) \<in> R\<^sup>* \<and> (z, y) \<in> R"
   532   by (blast elim: tranclE intro: trancl_into_rtrancl)
   533 
   534 lemma irrefl_tranclI: "r^-1 \<inter> r^* = {} ==> (x, x) \<notin> r^+"
   535   by (blast elim: tranclE dest: trancl_into_rtrancl)
   536 
   537 lemma irrefl_trancl_rD: "!!X. ALL x. (x, x) \<notin> r^+ ==> (x, y) \<in> r ==> x \<noteq> y"
   538   by (blast dest: r_into_trancl)
   539 
   540 lemma trancl_subset_Sigma_aux:
   541     "(a, b) \<in> r^* ==> r \<subseteq> A \<times> A ==> a = b \<or> a \<in> A"
   542   by (induct rule: rtrancl_induct) auto
   543 
   544 lemma trancl_subset_Sigma: "r \<subseteq> A \<times> A ==> r^+ \<subseteq> A \<times> A"
   545   apply (rule subsetI)
   546   apply (simp only: split_tupled_all)
   547   apply (erule tranclE)
   548    apply (blast dest!: trancl_into_rtrancl trancl_subset_Sigma_aux)+
   549   done
   550 
   551 lemma reflcl_tranclp [simp]: "(r^++)^== = r^**"
   552   apply (safe intro!: order_antisym)
   553    apply (erule tranclp_into_rtranclp)
   554   apply (blast elim: rtranclp.cases dest: rtranclp_into_tranclp1)
   555   done
   556 
   557 lemmas reflcl_trancl [simp] = reflcl_tranclp [to_set]
   558 
   559 lemma trancl_reflcl [simp]: "(r^=)^+ = r^*"
   560   apply safe
   561    apply (drule trancl_into_rtrancl, simp)
   562   apply (erule rtranclE, safe)
   563    apply (rule r_into_trancl, simp)
   564   apply (rule rtrancl_into_trancl1)
   565    apply (erule rtrancl_reflcl [THEN equalityD2, THEN subsetD], fast)
   566   done
   567 
   568 lemma trancl_empty [simp]: "{}^+ = {}"
   569   by (auto elim: trancl_induct)
   570 
   571 lemma rtrancl_empty [simp]: "{}^* = Id"
   572   by (rule subst [OF reflcl_trancl]) simp
   573 
   574 lemma rtranclpD: "R^** a b ==> a = b \<or> a \<noteq> b \<and> R^++ a b"
   575   by (force simp add: reflcl_tranclp [symmetric] simp del: reflcl_tranclp)
   576 
   577 lemmas rtranclD = rtranclpD [to_set]
   578 
   579 lemma rtrancl_eq_or_trancl:
   580   "(x,y) \<in> R\<^sup>* = (x=y \<or> x\<noteq>y \<and> (x,y) \<in> R\<^sup>+)"
   581   by (fast elim: trancl_into_rtrancl dest: rtranclD)
   582 
   583 lemma trancl_unfold_right: "r^+ = r^* O r"
   584 by (auto dest: tranclD2 intro: rtrancl_into_trancl1)
   585 
   586 lemma trancl_unfold_left: "r^+ = r O r^*"
   587 by (auto dest: tranclD intro: rtrancl_into_trancl2)
   588 
   589 
   590 text {* Simplifying nested closures *}
   591 
   592 lemma rtrancl_trancl_absorb[simp]: "(R^*)^+ = R^*"
   593 by (simp add: trans_rtrancl)
   594 
   595 lemma trancl_rtrancl_absorb[simp]: "(R^+)^* = R^*"
   596 by (subst reflcl_trancl[symmetric]) simp
   597 
   598 lemma rtrancl_reflcl_absorb[simp]: "(R^*)^= = R^*"
   599 by auto
   600 
   601 
   602 text {* @{text Domain} and @{text Range} *}
   603 
   604 lemma Domain_rtrancl [simp]: "Domain (R^*) = UNIV"
   605   by blast
   606 
   607 lemma Range_rtrancl [simp]: "Range (R^*) = UNIV"
   608   by blast
   609 
   610 lemma rtrancl_Un_subset: "(R^* \<union> S^*) \<subseteq> (R Un S)^*"
   611   by (rule rtrancl_Un_rtrancl [THEN subst]) fast
   612 
   613 lemma in_rtrancl_UnI: "x \<in> R^* \<or> x \<in> S^* ==> x \<in> (R \<union> S)^*"
   614   by (blast intro: subsetD [OF rtrancl_Un_subset])
   615 
   616 lemma trancl_domain [simp]: "Domain (r^+) = Domain r"
   617   by (unfold Domain_def) (blast dest: tranclD)
   618 
   619 lemma trancl_range [simp]: "Range (r^+) = Range r"
   620 unfolding Range_def by(simp add: trancl_converse [symmetric])
   621 
   622 lemma Not_Domain_rtrancl:
   623     "x ~: Domain R ==> ((x, y) : R^*) = (x = y)"
   624   apply auto
   625   apply (erule rev_mp)
   626   apply (erule rtrancl_induct)
   627    apply auto
   628   done
   629 
   630 lemma trancl_subset_Field2: "r^+ <= Field r \<times> Field r"
   631   apply clarify
   632   apply (erule trancl_induct)
   633    apply (auto simp add: Field_def)
   634   done
   635 
   636 lemma finite_trancl: "finite (r^+) = finite r"
   637   apply auto
   638    prefer 2
   639    apply (rule trancl_subset_Field2 [THEN finite_subset])
   640    apply (rule finite_SigmaI)
   641     prefer 3
   642     apply (blast intro: r_into_trancl' finite_subset)
   643    apply (auto simp add: finite_Field)
   644   done
   645 
   646 text {* More about converse @{text rtrancl} and @{text trancl}, should
   647   be merged with main body. *}
   648 
   649 lemma single_valued_confluent:
   650   "\<lbrakk> single_valued r; (x,y) \<in> r^*; (x,z) \<in> r^* \<rbrakk>
   651   \<Longrightarrow> (y,z) \<in> r^* \<or> (z,y) \<in> r^*"
   652   apply (erule rtrancl_induct)
   653   apply simp
   654   apply (erule disjE)
   655    apply (blast elim:converse_rtranclE dest:single_valuedD)
   656   apply(blast intro:rtrancl_trans)
   657   done
   658 
   659 lemma r_r_into_trancl: "(a, b) \<in> R ==> (b, c) \<in> R ==> (a, c) \<in> R^+"
   660   by (fast intro: trancl_trans)
   661 
   662 lemma trancl_into_trancl [rule_format]:
   663     "(a, b) \<in> r\<^sup>+ ==> (b, c) \<in> r --> (a,c) \<in> r\<^sup>+"
   664   apply (erule trancl_induct)
   665    apply (fast intro: r_r_into_trancl)
   666   apply (fast intro: r_r_into_trancl trancl_trans)
   667   done
   668 
   669 lemma tranclp_rtranclp_tranclp:
   670     "r\<^sup>+\<^sup>+ a b ==> r\<^sup>*\<^sup>* b c ==> r\<^sup>+\<^sup>+ a c"
   671   apply (drule tranclpD)
   672   apply (elim exE conjE)
   673   apply (drule rtranclp_trans, assumption)
   674   apply (drule rtranclp_into_tranclp2, assumption, assumption)
   675   done
   676 
   677 lemmas trancl_rtrancl_trancl = tranclp_rtranclp_tranclp [to_set]
   678 
   679 lemmas transitive_closure_trans [trans] =
   680   r_r_into_trancl trancl_trans rtrancl_trans
   681   trancl.trancl_into_trancl trancl_into_trancl2
   682   rtrancl.rtrancl_into_rtrancl converse_rtrancl_into_rtrancl
   683   rtrancl_trancl_trancl trancl_rtrancl_trancl
   684 
   685 lemmas transitive_closurep_trans' [trans] =
   686   tranclp_trans rtranclp_trans
   687   tranclp.trancl_into_trancl tranclp_into_tranclp2
   688   rtranclp.rtrancl_into_rtrancl converse_rtranclp_into_rtranclp
   689   rtranclp_tranclp_tranclp tranclp_rtranclp_tranclp
   690 
   691 declare trancl_into_rtrancl [elim]
   692 
   693 subsection {* The power operation on relations *}
   694 
   695 text {* @{text "R ^^ n = R O ... O R"}, the n-fold composition of @{text R} *}
   696 
   697 overloading
   698   relpow == "compow :: nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set"
   699 begin
   700 
   701 primrec relpow :: "nat \<Rightarrow> ('a \<times> 'a) set \<Rightarrow> ('a \<times> 'a) set" where
   702     "relpow 0 R = Id"
   703   | "relpow (Suc n) R = (R ^^ n) O R"
   704 
   705 end
   706 
   707 lemma rel_pow_1 [simp]:
   708   fixes R :: "('a \<times> 'a) set"
   709   shows "R ^^ 1 = R"
   710   by simp
   711 
   712 lemma rel_pow_0_I: 
   713   "(x, x) \<in> R ^^ 0"
   714   by simp
   715 
   716 lemma rel_pow_Suc_I:
   717   "(x, y) \<in>  R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   718   by auto
   719 
   720 lemma rel_pow_Suc_I2:
   721   "(x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> (x, z) \<in> R ^^ Suc n"
   722   by (induct n arbitrary: z) (simp, fastsimp)
   723 
   724 lemma rel_pow_0_E:
   725   "(x, y) \<in> R ^^ 0 \<Longrightarrow> (x = y \<Longrightarrow> P) \<Longrightarrow> P"
   726   by simp
   727 
   728 lemma rel_pow_Suc_E:
   729   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R ^^ n \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P) \<Longrightarrow> P"
   730   by auto
   731 
   732 lemma rel_pow_E:
   733   "(x, z) \<in>  R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   734    \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in>  R ^^ m \<Longrightarrow> (y, z) \<in> R \<Longrightarrow> P)
   735    \<Longrightarrow> P"
   736   by (cases n) auto
   737 
   738 lemma rel_pow_Suc_D2:
   739   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<exists>y. (x, y) \<in> R \<and> (y, z) \<in> R ^^ n)"
   740   apply (induct n arbitrary: x z)
   741    apply (blast intro: rel_pow_0_I elim: rel_pow_0_E rel_pow_Suc_E)
   742   apply (blast intro: rel_pow_Suc_I elim: rel_pow_0_E rel_pow_Suc_E)
   743   done
   744 
   745 lemma rel_pow_Suc_E2:
   746   "(x, z) \<in> R ^^ Suc n \<Longrightarrow> (\<And>y. (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ n \<Longrightarrow> P) \<Longrightarrow> P"
   747   by (blast dest: rel_pow_Suc_D2)
   748 
   749 lemma rel_pow_Suc_D2':
   750   "\<forall>x y z. (x, y) \<in> R ^^ n \<and> (y, z) \<in> R \<longrightarrow> (\<exists>w. (x, w) \<in> R \<and> (w, z) \<in> R ^^ n)"
   751   by (induct n) (simp_all, blast)
   752 
   753 lemma rel_pow_E2:
   754   "(x, z) \<in> R ^^ n \<Longrightarrow>  (n = 0 \<Longrightarrow> x = z \<Longrightarrow> P)
   755      \<Longrightarrow> (\<And>y m. n = Suc m \<Longrightarrow> (x, y) \<in> R \<Longrightarrow> (y, z) \<in> R ^^ m \<Longrightarrow> P)
   756    \<Longrightarrow> P"
   757   apply (cases n, simp)
   758   apply (cut_tac n=nat and R=R in rel_pow_Suc_D2', simp, blast)
   759   done
   760 
   761 lemma rel_pow_add: "R ^^ (m+n) = R^^m O R^^n"
   762 by(induct n) auto
   763 
   764 lemma rel_pow_commute: "R O R ^^ n = R ^^ n O R"
   765 by (induct n) (simp, simp add: O_assoc [symmetric])
   766 
   767 lemma rtrancl_imp_UN_rel_pow:
   768   assumes "p \<in> R^*"
   769   shows "p \<in> (\<Union>n. R ^^ n)"
   770 proof (cases p)
   771   case (Pair x y)
   772   with assms have "(x, y) \<in> R^*" by simp
   773   then have "(x, y) \<in> (\<Union>n. R ^^ n)" proof induct
   774     case base show ?case by (blast intro: rel_pow_0_I)
   775   next
   776     case step then show ?case by (blast intro: rel_pow_Suc_I)
   777   qed
   778   with Pair show ?thesis by simp
   779 qed
   780 
   781 lemma rel_pow_imp_rtrancl:
   782   assumes "p \<in> R ^^ n"
   783   shows "p \<in> R^*"
   784 proof (cases p)
   785   case (Pair x y)
   786   with assms have "(x, y) \<in> R ^^ n" by simp
   787   then have "(x, y) \<in> R^*" proof (induct n arbitrary: x y)
   788     case 0 then show ?case by simp
   789   next
   790     case Suc then show ?case
   791       by (blast elim: rel_pow_Suc_E intro: rtrancl_into_rtrancl)
   792   qed
   793   with Pair show ?thesis by simp
   794 qed
   795 
   796 lemma rtrancl_is_UN_rel_pow:
   797   "R^* = (\<Union>n. R ^^ n)"
   798   by (blast intro: rtrancl_imp_UN_rel_pow rel_pow_imp_rtrancl)
   799 
   800 lemma rtrancl_power:
   801   "p \<in> R^* \<longleftrightarrow> (\<exists>n. p \<in> R ^^ n)"
   802   by (simp add: rtrancl_is_UN_rel_pow)
   803 
   804 lemma trancl_power:
   805   "p \<in> R^+ \<longleftrightarrow> (\<exists>n > 0. p \<in> R ^^ n)"
   806   apply (cases p)
   807   apply simp
   808   apply (rule iffI)
   809    apply (drule tranclD2)
   810    apply (clarsimp simp: rtrancl_is_UN_rel_pow)
   811    apply (rule_tac x="Suc n" in exI)
   812    apply (clarsimp simp: rel_comp_def)
   813    apply fastsimp
   814   apply clarsimp
   815   apply (case_tac n, simp)
   816   apply clarsimp
   817   apply (drule rel_pow_imp_rtrancl)
   818   apply (drule rtrancl_into_trancl1) apply auto
   819   done
   820 
   821 lemma rtrancl_imp_rel_pow:
   822   "p \<in> R^* \<Longrightarrow> \<exists>n. p \<in> R ^^ n"
   823   by (auto dest: rtrancl_imp_UN_rel_pow)
   824 
   825 lemma single_valued_rel_pow:
   826   fixes R :: "('a * 'a) set"
   827   shows "single_valued R \<Longrightarrow> single_valued (R ^^ n)"
   828   apply (induct n arbitrary: R)
   829   apply simp_all
   830   apply (rule single_valuedI)
   831   apply (fast dest: single_valuedD elim: rel_pow_Suc_E)
   832   done
   833 
   834 subsection {* Setup of transitivity reasoner *}
   835 
   836 ML {*
   837 
   838 structure Trancl_Tac = Trancl_Tac
   839 (
   840   val r_into_trancl = @{thm trancl.r_into_trancl};
   841   val trancl_trans  = @{thm trancl_trans};
   842   val rtrancl_refl = @{thm rtrancl.rtrancl_refl};
   843   val r_into_rtrancl = @{thm r_into_rtrancl};
   844   val trancl_into_rtrancl = @{thm trancl_into_rtrancl};
   845   val rtrancl_trancl_trancl = @{thm rtrancl_trancl_trancl};
   846   val trancl_rtrancl_trancl = @{thm trancl_rtrancl_trancl};
   847   val rtrancl_trans = @{thm rtrancl_trans};
   848 
   849   fun decomp (@{const Trueprop} $ t) =
   850     let fun dec (Const ("op :", _) $ (Const ("Pair", _) $ a $ b) $ rel ) =
   851         let fun decr (Const ("Transitive_Closure.rtrancl", _ ) $ r) = (r,"r*")
   852               | decr (Const ("Transitive_Closure.trancl", _ ) $ r)  = (r,"r+")
   853               | decr r = (r,"r");
   854             val (rel,r) = decr (Envir.beta_eta_contract rel);
   855         in SOME (a,b,rel,r) end
   856       | dec _ =  NONE
   857     in dec t end
   858     | decomp _ = NONE;
   859 );
   860 
   861 structure Tranclp_Tac = Trancl_Tac
   862 (
   863   val r_into_trancl = @{thm tranclp.r_into_trancl};
   864   val trancl_trans  = @{thm tranclp_trans};
   865   val rtrancl_refl = @{thm rtranclp.rtrancl_refl};
   866   val r_into_rtrancl = @{thm r_into_rtranclp};
   867   val trancl_into_rtrancl = @{thm tranclp_into_rtranclp};
   868   val rtrancl_trancl_trancl = @{thm rtranclp_tranclp_tranclp};
   869   val trancl_rtrancl_trancl = @{thm tranclp_rtranclp_tranclp};
   870   val rtrancl_trans = @{thm rtranclp_trans};
   871 
   872   fun decomp (@{const Trueprop} $ t) =
   873     let fun dec (rel $ a $ b) =
   874         let fun decr (Const ("Transitive_Closure.rtranclp", _ ) $ r) = (r,"r*")
   875               | decr (Const ("Transitive_Closure.tranclp", _ ) $ r)  = (r,"r+")
   876               | decr r = (r,"r");
   877             val (rel,r) = decr rel;
   878         in SOME (a, b, rel, r) end
   879       | dec _ =  NONE
   880     in dec t end
   881     | decomp _ = NONE;
   882 );
   883 *}
   884 
   885 declaration {* fn _ =>
   886   Simplifier.map_ss (fn ss => ss
   887     addSolver (mk_solver' "Trancl" (Trancl_Tac.trancl_tac o Simplifier.the_context))
   888     addSolver (mk_solver' "Rtrancl" (Trancl_Tac.rtrancl_tac o Simplifier.the_context))
   889     addSolver (mk_solver' "Tranclp" (Tranclp_Tac.trancl_tac o Simplifier.the_context))
   890     addSolver (mk_solver' "Rtranclp" (Tranclp_Tac.rtrancl_tac o Simplifier.the_context)))
   891 *}
   892 
   893 
   894 text {* Optional methods. *}
   895 
   896 method_setup trancl =
   897   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.trancl_tac) *}
   898   {* simple transitivity reasoner *}
   899 method_setup rtrancl =
   900   {* Scan.succeed (SIMPLE_METHOD' o Trancl_Tac.rtrancl_tac) *}
   901   {* simple transitivity reasoner *}
   902 method_setup tranclp =
   903   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.trancl_tac) *}
   904   {* simple transitivity reasoner (predicate version) *}
   905 method_setup rtranclp =
   906   {* Scan.succeed (SIMPLE_METHOD' o Tranclp_Tac.rtrancl_tac) *}
   907   {* simple transitivity reasoner (predicate version) *}
   908 
   909 end