src/HOL/Divides.thy
author huffman
Tue Mar 27 15:27:49 2012 +0200 (2012-03-27)
changeset 47159 978c00c20a59
parent 47142 d64fa2ca54b8
child 47160 8ada79014cb2
permissions -rw-r--r--
generalize some theorems about div/mod
     1 (*  Title:      HOL/Divides.thy
     2     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     3     Copyright   1999  University of Cambridge
     4 *)
     5 
     6 header {* The division operators div and mod *}
     7 
     8 theory Divides
     9 imports Nat_Numeral Nat_Transfer
    10 uses "~~/src/Provers/Arith/cancel_div_mod.ML"
    11 begin
    12 
    13 subsection {* Syntactic division operations *}
    14 
    15 class div = dvd +
    16   fixes div :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "div" 70)
    17     and mod :: "'a \<Rightarrow> 'a \<Rightarrow> 'a" (infixl "mod" 70)
    18 
    19 
    20 subsection {* Abstract division in commutative semirings. *}
    21 
    22 class semiring_div = comm_semiring_1_cancel + no_zero_divisors + div +
    23   assumes mod_div_equality: "a div b * b + a mod b = a"
    24     and div_by_0 [simp]: "a div 0 = 0"
    25     and div_0 [simp]: "0 div a = 0"
    26     and div_mult_self1 [simp]: "b \<noteq> 0 \<Longrightarrow> (a + c * b) div b = c + a div b"
    27     and div_mult_mult1 [simp]: "c \<noteq> 0 \<Longrightarrow> (c * a) div (c * b) = a div b"
    28 begin
    29 
    30 text {* @{const div} and @{const mod} *}
    31 
    32 lemma mod_div_equality2: "b * (a div b) + a mod b = a"
    33   unfolding mult_commute [of b]
    34   by (rule mod_div_equality)
    35 
    36 lemma mod_div_equality': "a mod b + a div b * b = a"
    37   using mod_div_equality [of a b]
    38   by (simp only: add_ac)
    39 
    40 lemma div_mod_equality: "((a div b) * b + a mod b) + c = a + c"
    41   by (simp add: mod_div_equality)
    42 
    43 lemma div_mod_equality2: "(b * (a div b) + a mod b) + c = a + c"
    44   by (simp add: mod_div_equality2)
    45 
    46 lemma mod_by_0 [simp]: "a mod 0 = a"
    47   using mod_div_equality [of a zero] by simp
    48 
    49 lemma mod_0 [simp]: "0 mod a = 0"
    50   using mod_div_equality [of zero a] div_0 by simp
    51 
    52 lemma div_mult_self2 [simp]:
    53   assumes "b \<noteq> 0"
    54   shows "(a + b * c) div b = c + a div b"
    55   using assms div_mult_self1 [of b a c] by (simp add: mult_commute)
    56 
    57 lemma mod_mult_self1 [simp]: "(a + c * b) mod b = a mod b"
    58 proof (cases "b = 0")
    59   case True then show ?thesis by simp
    60 next
    61   case False
    62   have "a + c * b = (a + c * b) div b * b + (a + c * b) mod b"
    63     by (simp add: mod_div_equality)
    64   also from False div_mult_self1 [of b a c] have
    65     "\<dots> = (c + a div b) * b + (a + c * b) mod b"
    66       by (simp add: algebra_simps)
    67   finally have "a = a div b * b + (a + c * b) mod b"
    68     by (simp add: add_commute [of a] add_assoc left_distrib)
    69   then have "a div b * b + (a + c * b) mod b = a div b * b + a mod b"
    70     by (simp add: mod_div_equality)
    71   then show ?thesis by simp
    72 qed
    73 
    74 lemma mod_mult_self2 [simp]: "(a + b * c) mod b = a mod b"
    75   by (simp add: mult_commute [of b])
    76 
    77 lemma div_mult_self1_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> b * a div b = a"
    78   using div_mult_self2 [of b 0 a] by simp
    79 
    80 lemma div_mult_self2_is_id [simp]: "b \<noteq> 0 \<Longrightarrow> a * b div b = a"
    81   using div_mult_self1 [of b 0 a] by simp
    82 
    83 lemma mod_mult_self1_is_0 [simp]: "b * a mod b = 0"
    84   using mod_mult_self2 [of 0 b a] by simp
    85 
    86 lemma mod_mult_self2_is_0 [simp]: "a * b mod b = 0"
    87   using mod_mult_self1 [of 0 a b] by simp
    88 
    89 lemma div_by_1 [simp]: "a div 1 = a"
    90   using div_mult_self2_is_id [of 1 a] zero_neq_one by simp
    91 
    92 lemma mod_by_1 [simp]: "a mod 1 = 0"
    93 proof -
    94   from mod_div_equality [of a one] div_by_1 have "a + a mod 1 = a" by simp
    95   then have "a + a mod 1 = a + 0" by simp
    96   then show ?thesis by (rule add_left_imp_eq)
    97 qed
    98 
    99 lemma mod_self [simp]: "a mod a = 0"
   100   using mod_mult_self2_is_0 [of 1] by simp
   101 
   102 lemma div_self [simp]: "a \<noteq> 0 \<Longrightarrow> a div a = 1"
   103   using div_mult_self2_is_id [of _ 1] by simp
   104 
   105 lemma div_add_self1 [simp]:
   106   assumes "b \<noteq> 0"
   107   shows "(b + a) div b = a div b + 1"
   108   using assms div_mult_self1 [of b a 1] by (simp add: add_commute)
   109 
   110 lemma div_add_self2 [simp]:
   111   assumes "b \<noteq> 0"
   112   shows "(a + b) div b = a div b + 1"
   113   using assms div_add_self1 [of b a] by (simp add: add_commute)
   114 
   115 lemma mod_add_self1 [simp]:
   116   "(b + a) mod b = a mod b"
   117   using mod_mult_self1 [of a 1 b] by (simp add: add_commute)
   118 
   119 lemma mod_add_self2 [simp]:
   120   "(a + b) mod b = a mod b"
   121   using mod_mult_self1 [of a 1 b] by simp
   122 
   123 lemma mod_div_decomp:
   124   fixes a b
   125   obtains q r where "q = a div b" and "r = a mod b"
   126     and "a = q * b + r"
   127 proof -
   128   from mod_div_equality have "a = a div b * b + a mod b" by simp
   129   moreover have "a div b = a div b" ..
   130   moreover have "a mod b = a mod b" ..
   131   note that ultimately show thesis by blast
   132 qed
   133 
   134 lemma dvd_eq_mod_eq_0 [code]: "a dvd b \<longleftrightarrow> b mod a = 0"
   135 proof
   136   assume "b mod a = 0"
   137   with mod_div_equality [of b a] have "b div a * a = b" by simp
   138   then have "b = a * (b div a)" unfolding mult_commute ..
   139   then have "\<exists>c. b = a * c" ..
   140   then show "a dvd b" unfolding dvd_def .
   141 next
   142   assume "a dvd b"
   143   then have "\<exists>c. b = a * c" unfolding dvd_def .
   144   then obtain c where "b = a * c" ..
   145   then have "b mod a = a * c mod a" by simp
   146   then have "b mod a = c * a mod a" by (simp add: mult_commute)
   147   then show "b mod a = 0" by simp
   148 qed
   149 
   150 lemma mod_div_trivial [simp]: "a mod b div b = 0"
   151 proof (cases "b = 0")
   152   assume "b = 0"
   153   thus ?thesis by simp
   154 next
   155   assume "b \<noteq> 0"
   156   hence "a div b + a mod b div b = (a mod b + a div b * b) div b"
   157     by (rule div_mult_self1 [symmetric])
   158   also have "\<dots> = a div b"
   159     by (simp only: mod_div_equality')
   160   also have "\<dots> = a div b + 0"
   161     by simp
   162   finally show ?thesis
   163     by (rule add_left_imp_eq)
   164 qed
   165 
   166 lemma mod_mod_trivial [simp]: "a mod b mod b = a mod b"
   167 proof -
   168   have "a mod b mod b = (a mod b + a div b * b) mod b"
   169     by (simp only: mod_mult_self1)
   170   also have "\<dots> = a mod b"
   171     by (simp only: mod_div_equality')
   172   finally show ?thesis .
   173 qed
   174 
   175 lemma dvd_imp_mod_0: "a dvd b \<Longrightarrow> b mod a = 0"
   176 by (rule dvd_eq_mod_eq_0[THEN iffD1])
   177 
   178 lemma dvd_div_mult_self: "a dvd b \<Longrightarrow> (b div a) * a = b"
   179 by (subst (2) mod_div_equality [of b a, symmetric]) (simp add:dvd_imp_mod_0)
   180 
   181 lemma dvd_mult_div_cancel: "a dvd b \<Longrightarrow> a * (b div a) = b"
   182 by (drule dvd_div_mult_self) (simp add: mult_commute)
   183 
   184 lemma dvd_div_mult: "a dvd b \<Longrightarrow> (b div a) * c = b * c div a"
   185 apply (cases "a = 0")
   186  apply simp
   187 apply (auto simp: dvd_def mult_assoc)
   188 done
   189 
   190 lemma div_dvd_div[simp]:
   191   "a dvd b \<Longrightarrow> a dvd c \<Longrightarrow> (b div a dvd c div a) = (b dvd c)"
   192 apply (cases "a = 0")
   193  apply simp
   194 apply (unfold dvd_def)
   195 apply auto
   196  apply(blast intro:mult_assoc[symmetric])
   197 apply(fastforce simp add: mult_assoc)
   198 done
   199 
   200 lemma dvd_mod_imp_dvd: "[| k dvd m mod n;  k dvd n |] ==> k dvd m"
   201   apply (subgoal_tac "k dvd (m div n) *n + m mod n")
   202    apply (simp add: mod_div_equality)
   203   apply (simp only: dvd_add dvd_mult)
   204   done
   205 
   206 text {* Addition respects modular equivalence. *}
   207 
   208 lemma mod_add_left_eq: "(a + b) mod c = (a mod c + b) mod c"
   209 proof -
   210   have "(a + b) mod c = (a div c * c + a mod c + b) mod c"
   211     by (simp only: mod_div_equality)
   212   also have "\<dots> = (a mod c + b + a div c * c) mod c"
   213     by (simp only: add_ac)
   214   also have "\<dots> = (a mod c + b) mod c"
   215     by (rule mod_mult_self1)
   216   finally show ?thesis .
   217 qed
   218 
   219 lemma mod_add_right_eq: "(a + b) mod c = (a + b mod c) mod c"
   220 proof -
   221   have "(a + b) mod c = (a + (b div c * c + b mod c)) mod c"
   222     by (simp only: mod_div_equality)
   223   also have "\<dots> = (a + b mod c + b div c * c) mod c"
   224     by (simp only: add_ac)
   225   also have "\<dots> = (a + b mod c) mod c"
   226     by (rule mod_mult_self1)
   227   finally show ?thesis .
   228 qed
   229 
   230 lemma mod_add_eq: "(a + b) mod c = (a mod c + b mod c) mod c"
   231 by (rule trans [OF mod_add_left_eq mod_add_right_eq])
   232 
   233 lemma mod_add_cong:
   234   assumes "a mod c = a' mod c"
   235   assumes "b mod c = b' mod c"
   236   shows "(a + b) mod c = (a' + b') mod c"
   237 proof -
   238   have "(a mod c + b mod c) mod c = (a' mod c + b' mod c) mod c"
   239     unfolding assms ..
   240   thus ?thesis
   241     by (simp only: mod_add_eq [symmetric])
   242 qed
   243 
   244 lemma div_add [simp]: "z dvd x \<Longrightarrow> z dvd y
   245   \<Longrightarrow> (x + y) div z = x div z + y div z"
   246 by (cases "z = 0", simp, unfold dvd_def, auto simp add: algebra_simps)
   247 
   248 text {* Multiplication respects modular equivalence. *}
   249 
   250 lemma mod_mult_left_eq: "(a * b) mod c = ((a mod c) * b) mod c"
   251 proof -
   252   have "(a * b) mod c = ((a div c * c + a mod c) * b) mod c"
   253     by (simp only: mod_div_equality)
   254   also have "\<dots> = (a mod c * b + a div c * b * c) mod c"
   255     by (simp only: algebra_simps)
   256   also have "\<dots> = (a mod c * b) mod c"
   257     by (rule mod_mult_self1)
   258   finally show ?thesis .
   259 qed
   260 
   261 lemma mod_mult_right_eq: "(a * b) mod c = (a * (b mod c)) mod c"
   262 proof -
   263   have "(a * b) mod c = (a * (b div c * c + b mod c)) mod c"
   264     by (simp only: mod_div_equality)
   265   also have "\<dots> = (a * (b mod c) + a * (b div c) * c) mod c"
   266     by (simp only: algebra_simps)
   267   also have "\<dots> = (a * (b mod c)) mod c"
   268     by (rule mod_mult_self1)
   269   finally show ?thesis .
   270 qed
   271 
   272 lemma mod_mult_eq: "(a * b) mod c = ((a mod c) * (b mod c)) mod c"
   273 by (rule trans [OF mod_mult_left_eq mod_mult_right_eq])
   274 
   275 lemma mod_mult_cong:
   276   assumes "a mod c = a' mod c"
   277   assumes "b mod c = b' mod c"
   278   shows "(a * b) mod c = (a' * b') mod c"
   279 proof -
   280   have "(a mod c * (b mod c)) mod c = (a' mod c * (b' mod c)) mod c"
   281     unfolding assms ..
   282   thus ?thesis
   283     by (simp only: mod_mult_eq [symmetric])
   284 qed
   285 
   286 lemma mod_mod_cancel:
   287   assumes "c dvd b"
   288   shows "a mod b mod c = a mod c"
   289 proof -
   290   from `c dvd b` obtain k where "b = c * k"
   291     by (rule dvdE)
   292   have "a mod b mod c = a mod (c * k) mod c"
   293     by (simp only: `b = c * k`)
   294   also have "\<dots> = (a mod (c * k) + a div (c * k) * k * c) mod c"
   295     by (simp only: mod_mult_self1)
   296   also have "\<dots> = (a div (c * k) * (c * k) + a mod (c * k)) mod c"
   297     by (simp only: add_ac mult_ac)
   298   also have "\<dots> = a mod c"
   299     by (simp only: mod_div_equality)
   300   finally show ?thesis .
   301 qed
   302 
   303 lemma div_mult_div_if_dvd:
   304   "y dvd x \<Longrightarrow> z dvd w \<Longrightarrow> (x div y) * (w div z) = (x * w) div (y * z)"
   305   apply (cases "y = 0", simp)
   306   apply (cases "z = 0", simp)
   307   apply (auto elim!: dvdE simp add: algebra_simps)
   308   apply (subst mult_assoc [symmetric])
   309   apply (simp add: no_zero_divisors)
   310   done
   311 
   312 lemma div_mult_swap:
   313   assumes "c dvd b"
   314   shows "a * (b div c) = (a * b) div c"
   315 proof -
   316   from assms have "b div c * (a div 1) = b * a div (c * 1)"
   317     by (simp only: div_mult_div_if_dvd one_dvd)
   318   then show ?thesis by (simp add: mult_commute)
   319 qed
   320    
   321 lemma div_mult_mult2 [simp]:
   322   "c \<noteq> 0 \<Longrightarrow> (a * c) div (b * c) = a div b"
   323   by (drule div_mult_mult1) (simp add: mult_commute)
   324 
   325 lemma div_mult_mult1_if [simp]:
   326   "(c * a) div (c * b) = (if c = 0 then 0 else a div b)"
   327   by simp_all
   328 
   329 lemma mod_mult_mult1:
   330   "(c * a) mod (c * b) = c * (a mod b)"
   331 proof (cases "c = 0")
   332   case True then show ?thesis by simp
   333 next
   334   case False
   335   from mod_div_equality
   336   have "((c * a) div (c * b)) * (c * b) + (c * a) mod (c * b) = c * a" .
   337   with False have "c * ((a div b) * b + a mod b) + (c * a) mod (c * b)
   338     = c * a + c * (a mod b)" by (simp add: algebra_simps)
   339   with mod_div_equality show ?thesis by simp 
   340 qed
   341   
   342 lemma mod_mult_mult2:
   343   "(a * c) mod (b * c) = (a mod b) * c"
   344   using mod_mult_mult1 [of c a b] by (simp add: mult_commute)
   345 
   346 lemma mult_mod_left: "(a mod b) * c = (a * c) mod (b * c)"
   347   by (fact mod_mult_mult2 [symmetric])
   348 
   349 lemma mult_mod_right: "c * (a mod b) = (c * a) mod (c * b)"
   350   by (fact mod_mult_mult1 [symmetric])
   351 
   352 lemma dvd_mod: "k dvd m \<Longrightarrow> k dvd n \<Longrightarrow> k dvd (m mod n)"
   353   unfolding dvd_def by (auto simp add: mod_mult_mult1)
   354 
   355 lemma dvd_mod_iff: "k dvd n \<Longrightarrow> k dvd (m mod n) \<longleftrightarrow> k dvd m"
   356 by (blast intro: dvd_mod_imp_dvd dvd_mod)
   357 
   358 lemma div_power:
   359   "y dvd x \<Longrightarrow> (x div y) ^ n = x ^ n div y ^ n"
   360 apply (induct n)
   361  apply simp
   362 apply(simp add: div_mult_div_if_dvd dvd_power_same)
   363 done
   364 
   365 lemma dvd_div_eq_mult:
   366   assumes "a \<noteq> 0" and "a dvd b"  
   367   shows "b div a = c \<longleftrightarrow> b = c * a"
   368 proof
   369   assume "b = c * a"
   370   then show "b div a = c" by (simp add: assms)
   371 next
   372   assume "b div a = c"
   373   then have "b div a * a = c * a" by simp
   374   moreover from `a dvd b` have "b div a * a = b" by (simp add: dvd_div_mult_self)
   375   ultimately show "b = c * a" by simp
   376 qed
   377    
   378 lemma dvd_div_div_eq_mult:
   379   assumes "a \<noteq> 0" "c \<noteq> 0" and "a dvd b" "c dvd d"
   380   shows "b div a = d div c \<longleftrightarrow> b * c = a * d"
   381   using assms by (auto simp add: mult_commute [of _ a] dvd_div_mult_self dvd_div_eq_mult div_mult_swap intro: sym)
   382 
   383 end
   384 
   385 class ring_div = semiring_div + comm_ring_1
   386 begin
   387 
   388 subclass ring_1_no_zero_divisors ..
   389 
   390 text {* Negation respects modular equivalence. *}
   391 
   392 lemma mod_minus_eq: "(- a) mod b = (- (a mod b)) mod b"
   393 proof -
   394   have "(- a) mod b = (- (a div b * b + a mod b)) mod b"
   395     by (simp only: mod_div_equality)
   396   also have "\<dots> = (- (a mod b) + - (a div b) * b) mod b"
   397     by (simp only: minus_add_distrib minus_mult_left add_ac)
   398   also have "\<dots> = (- (a mod b)) mod b"
   399     by (rule mod_mult_self1)
   400   finally show ?thesis .
   401 qed
   402 
   403 lemma mod_minus_cong:
   404   assumes "a mod b = a' mod b"
   405   shows "(- a) mod b = (- a') mod b"
   406 proof -
   407   have "(- (a mod b)) mod b = (- (a' mod b)) mod b"
   408     unfolding assms ..
   409   thus ?thesis
   410     by (simp only: mod_minus_eq [symmetric])
   411 qed
   412 
   413 text {* Subtraction respects modular equivalence. *}
   414 
   415 lemma mod_diff_left_eq: "(a - b) mod c = (a mod c - b) mod c"
   416   unfolding diff_minus
   417   by (intro mod_add_cong mod_minus_cong) simp_all
   418 
   419 lemma mod_diff_right_eq: "(a - b) mod c = (a - b mod c) mod c"
   420   unfolding diff_minus
   421   by (intro mod_add_cong mod_minus_cong) simp_all
   422 
   423 lemma mod_diff_eq: "(a - b) mod c = (a mod c - b mod c) mod c"
   424   unfolding diff_minus
   425   by (intro mod_add_cong mod_minus_cong) simp_all
   426 
   427 lemma mod_diff_cong:
   428   assumes "a mod c = a' mod c"
   429   assumes "b mod c = b' mod c"
   430   shows "(a - b) mod c = (a' - b') mod c"
   431   unfolding diff_minus using assms
   432   by (intro mod_add_cong mod_minus_cong)
   433 
   434 lemma dvd_neg_div: "y dvd x \<Longrightarrow> -x div y = - (x div y)"
   435 apply (case_tac "y = 0") apply simp
   436 apply (auto simp add: dvd_def)
   437 apply (subgoal_tac "-(y * k) = y * - k")
   438  apply (erule ssubst)
   439  apply (erule div_mult_self1_is_id)
   440 apply simp
   441 done
   442 
   443 lemma dvd_div_neg: "y dvd x \<Longrightarrow> x div -y = - (x div y)"
   444 apply (case_tac "y = 0") apply simp
   445 apply (auto simp add: dvd_def)
   446 apply (subgoal_tac "y * k = -y * -k")
   447  apply (erule ssubst)
   448  apply (rule div_mult_self1_is_id)
   449  apply simp
   450 apply simp
   451 done
   452 
   453 lemma div_minus_minus [simp]: "(-a) div (-b) = a div b"
   454   using div_mult_mult1 [of "- 1" a b]
   455   unfolding neg_equal_0_iff_equal by simp
   456 
   457 lemma mod_minus_minus [simp]: "(-a) mod (-b) = - (a mod b)"
   458   using mod_mult_mult1 [of "- 1" a b] by simp
   459 
   460 lemma div_minus_right: "a div (-b) = (-a) div b"
   461   using div_minus_minus [of "-a" b] by simp
   462 
   463 lemma mod_minus_right: "a mod (-b) = - ((-a) mod b)"
   464   using mod_minus_minus [of "-a" b] by simp
   465 
   466 end
   467 
   468 
   469 subsection {* Division on @{typ nat} *}
   470 
   471 text {*
   472   We define @{const div} and @{const mod} on @{typ nat} by means
   473   of a characteristic relation with two input arguments
   474   @{term "m\<Colon>nat"}, @{term "n\<Colon>nat"} and two output arguments
   475   @{term "q\<Colon>nat"}(uotient) and @{term "r\<Colon>nat"}(emainder).
   476 *}
   477 
   478 definition divmod_nat_rel :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat \<Rightarrow> bool" where
   479   "divmod_nat_rel m n qr \<longleftrightarrow>
   480     m = fst qr * n + snd qr \<and>
   481       (if n = 0 then fst qr = 0 else if n > 0 then 0 \<le> snd qr \<and> snd qr < n else n < snd qr \<and> snd qr \<le> 0)"
   482 
   483 text {* @{const divmod_nat_rel} is total: *}
   484 
   485 lemma divmod_nat_rel_ex:
   486   obtains q r where "divmod_nat_rel m n (q, r)"
   487 proof (cases "n = 0")
   488   case True  with that show thesis
   489     by (auto simp add: divmod_nat_rel_def)
   490 next
   491   case False
   492   have "\<exists>q r. m = q * n + r \<and> r < n"
   493   proof (induct m)
   494     case 0 with `n \<noteq> 0`
   495     have "(0\<Colon>nat) = 0 * n + 0 \<and> 0 < n" by simp
   496     then show ?case by blast
   497   next
   498     case (Suc m) then obtain q' r'
   499       where m: "m = q' * n + r'" and n: "r' < n" by auto
   500     then show ?case proof (cases "Suc r' < n")
   501       case True
   502       from m n have "Suc m = q' * n + Suc r'" by simp
   503       with True show ?thesis by blast
   504     next
   505       case False then have "n \<le> Suc r'" by auto
   506       moreover from n have "Suc r' \<le> n" by auto
   507       ultimately have "n = Suc r'" by auto
   508       with m have "Suc m = Suc q' * n + 0" by simp
   509       with `n \<noteq> 0` show ?thesis by blast
   510     qed
   511   qed
   512   with that show thesis
   513     using `n \<noteq> 0` by (auto simp add: divmod_nat_rel_def)
   514 qed
   515 
   516 text {* @{const divmod_nat_rel} is injective: *}
   517 
   518 lemma divmod_nat_rel_unique:
   519   assumes "divmod_nat_rel m n qr"
   520     and "divmod_nat_rel m n qr'"
   521   shows "qr = qr'"
   522 proof (cases "n = 0")
   523   case True with assms show ?thesis
   524     by (cases qr, cases qr')
   525       (simp add: divmod_nat_rel_def)
   526 next
   527   case False
   528   have aux: "\<And>q r q' r'. q' * n + r' = q * n + r \<Longrightarrow> r < n \<Longrightarrow> q' \<le> (q\<Colon>nat)"
   529   apply (rule leI)
   530   apply (subst less_iff_Suc_add)
   531   apply (auto simp add: add_mult_distrib)
   532   done
   533   from `n \<noteq> 0` assms have "fst qr = fst qr'"
   534     by (auto simp add: divmod_nat_rel_def intro: order_antisym dest: aux sym)
   535   moreover from this assms have "snd qr = snd qr'"
   536     by (simp add: divmod_nat_rel_def)
   537   ultimately show ?thesis by (cases qr, cases qr') simp
   538 qed
   539 
   540 text {*
   541   We instantiate divisibility on the natural numbers by
   542   means of @{const divmod_nat_rel}:
   543 *}
   544 
   545 definition divmod_nat :: "nat \<Rightarrow> nat \<Rightarrow> nat \<times> nat" where
   546   "divmod_nat m n = (THE qr. divmod_nat_rel m n qr)"
   547 
   548 lemma divmod_nat_rel_divmod_nat:
   549   "divmod_nat_rel m n (divmod_nat m n)"
   550 proof -
   551   from divmod_nat_rel_ex
   552     obtain qr where rel: "divmod_nat_rel m n qr" .
   553   then show ?thesis
   554   by (auto simp add: divmod_nat_def intro: theI elim: divmod_nat_rel_unique)
   555 qed
   556 
   557 lemma divmod_nat_unique:
   558   assumes "divmod_nat_rel m n qr" 
   559   shows "divmod_nat m n = qr"
   560   using assms by (auto intro: divmod_nat_rel_unique divmod_nat_rel_divmod_nat)
   561 
   562 instantiation nat :: semiring_div
   563 begin
   564 
   565 definition div_nat where
   566   "m div n = fst (divmod_nat m n)"
   567 
   568 lemma fst_divmod_nat [simp]:
   569   "fst (divmod_nat m n) = m div n"
   570   by (simp add: div_nat_def)
   571 
   572 definition mod_nat where
   573   "m mod n = snd (divmod_nat m n)"
   574 
   575 lemma snd_divmod_nat [simp]:
   576   "snd (divmod_nat m n) = m mod n"
   577   by (simp add: mod_nat_def)
   578 
   579 lemma divmod_nat_div_mod:
   580   "divmod_nat m n = (m div n, m mod n)"
   581   by (simp add: prod_eq_iff)
   582 
   583 lemma div_nat_unique:
   584   assumes "divmod_nat_rel m n (q, r)" 
   585   shows "m div n = q"
   586   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   587 
   588 lemma mod_nat_unique:
   589   assumes "divmod_nat_rel m n (q, r)" 
   590   shows "m mod n = r"
   591   using assms by (auto dest!: divmod_nat_unique simp add: prod_eq_iff)
   592 
   593 lemma divmod_nat_rel: "divmod_nat_rel m n (m div n, m mod n)"
   594   using divmod_nat_rel_divmod_nat by (simp add: divmod_nat_div_mod)
   595 
   596 lemma divmod_nat_zero: "divmod_nat m 0 = (0, m)"
   597   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   598 
   599 lemma divmod_nat_zero_left: "divmod_nat 0 n = (0, 0)"
   600   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   601 
   602 lemma divmod_nat_base: "m < n \<Longrightarrow> divmod_nat m n = (0, m)"
   603   by (simp add: divmod_nat_unique divmod_nat_rel_def)
   604 
   605 lemma divmod_nat_step:
   606   assumes "0 < n" and "n \<le> m"
   607   shows "divmod_nat m n = (Suc ((m - n) div n), (m - n) mod n)"
   608 proof (rule divmod_nat_unique)
   609   have "divmod_nat_rel (m - n) n ((m - n) div n, (m - n) mod n)"
   610     by (rule divmod_nat_rel)
   611   thus "divmod_nat_rel m n (Suc ((m - n) div n), (m - n) mod n)"
   612     unfolding divmod_nat_rel_def using assms by auto
   613 qed
   614 
   615 text {* The ''recursion'' equations for @{const div} and @{const mod} *}
   616 
   617 lemma div_less [simp]:
   618   fixes m n :: nat
   619   assumes "m < n"
   620   shows "m div n = 0"
   621   using assms divmod_nat_base by (simp add: prod_eq_iff)
   622 
   623 lemma le_div_geq:
   624   fixes m n :: nat
   625   assumes "0 < n" and "n \<le> m"
   626   shows "m div n = Suc ((m - n) div n)"
   627   using assms divmod_nat_step by (simp add: prod_eq_iff)
   628 
   629 lemma mod_less [simp]:
   630   fixes m n :: nat
   631   assumes "m < n"
   632   shows "m mod n = m"
   633   using assms divmod_nat_base by (simp add: prod_eq_iff)
   634 
   635 lemma le_mod_geq:
   636   fixes m n :: nat
   637   assumes "n \<le> m"
   638   shows "m mod n = (m - n) mod n"
   639   using assms divmod_nat_step by (cases "n = 0") (simp_all add: prod_eq_iff)
   640 
   641 instance proof
   642   fix m n :: nat
   643   show "m div n * n + m mod n = m"
   644     using divmod_nat_rel [of m n] by (simp add: divmod_nat_rel_def)
   645 next
   646   fix m n q :: nat
   647   assume "n \<noteq> 0"
   648   then show "(q + m * n) div n = m + q div n"
   649     by (induct m) (simp_all add: le_div_geq)
   650 next
   651   fix m n q :: nat
   652   assume "m \<noteq> 0"
   653   hence "\<And>a b. divmod_nat_rel n q (a, b) \<Longrightarrow> divmod_nat_rel (m * n) (m * q) (a, m * b)"
   654     unfolding divmod_nat_rel_def
   655     by (auto split: split_if_asm, simp_all add: algebra_simps)
   656   moreover from divmod_nat_rel have "divmod_nat_rel n q (n div q, n mod q)" .
   657   ultimately have "divmod_nat_rel (m * n) (m * q) (n div q, m * (n mod q))" .
   658   thus "(m * n) div (m * q) = n div q" by (rule div_nat_unique)
   659 next
   660   fix n :: nat show "n div 0 = 0"
   661     by (simp add: div_nat_def divmod_nat_zero)
   662 next
   663   fix n :: nat show "0 div n = 0"
   664     by (simp add: div_nat_def divmod_nat_zero_left)
   665 qed
   666 
   667 end
   668 
   669 lemma divmod_nat_if [code]: "divmod_nat m n = (if n = 0 \<or> m < n then (0, m) else
   670   let (q, r) = divmod_nat (m - n) n in (Suc q, r))"
   671   by (simp add: prod_eq_iff prod_case_beta not_less le_div_geq le_mod_geq)
   672 
   673 text {* Simproc for cancelling @{const div} and @{const mod} *}
   674 
   675 ML {*
   676 structure Cancel_Div_Mod_Nat = Cancel_Div_Mod
   677 (
   678   val div_name = @{const_name div};
   679   val mod_name = @{const_name mod};
   680   val mk_binop = HOLogic.mk_binop;
   681   val mk_sum = Nat_Arith.mk_sum;
   682   val dest_sum = Nat_Arith.dest_sum;
   683 
   684   val div_mod_eqs = map mk_meta_eq [@{thm div_mod_equality}, @{thm div_mod_equality2}];
   685 
   686   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac
   687     (@{thm add_0_left} :: @{thm add_0_right} :: @{thms add_ac}))
   688 )
   689 *}
   690 
   691 simproc_setup cancel_div_mod_nat ("(m::nat) + n") = {* K Cancel_Div_Mod_Nat.proc *}
   692 
   693 
   694 subsubsection {* Quotient *}
   695 
   696 lemma div_geq: "0 < n \<Longrightarrow>  \<not> m < n \<Longrightarrow> m div n = Suc ((m - n) div n)"
   697 by (simp add: le_div_geq linorder_not_less)
   698 
   699 lemma div_if: "0 < n \<Longrightarrow> m div n = (if m < n then 0 else Suc ((m - n) div n))"
   700 by (simp add: div_geq)
   701 
   702 lemma div_mult_self_is_m [simp]: "0<n ==> (m*n) div n = (m::nat)"
   703 by simp
   704 
   705 lemma div_mult_self1_is_m [simp]: "0<n ==> (n*m) div n = (m::nat)"
   706 by simp
   707 
   708 
   709 subsubsection {* Remainder *}
   710 
   711 lemma mod_less_divisor [simp]:
   712   fixes m n :: nat
   713   assumes "n > 0"
   714   shows "m mod n < (n::nat)"
   715   using assms divmod_nat_rel [of m n] unfolding divmod_nat_rel_def by auto
   716 
   717 lemma mod_less_eq_dividend [simp]:
   718   fixes m n :: nat
   719   shows "m mod n \<le> m"
   720 proof (rule add_leD2)
   721   from mod_div_equality have "m div n * n + m mod n = m" .
   722   then show "m div n * n + m mod n \<le> m" by auto
   723 qed
   724 
   725 lemma mod_geq: "\<not> m < (n\<Colon>nat) \<Longrightarrow> m mod n = (m - n) mod n"
   726 by (simp add: le_mod_geq linorder_not_less)
   727 
   728 lemma mod_if: "m mod (n\<Colon>nat) = (if m < n then m else (m - n) mod n)"
   729 by (simp add: le_mod_geq)
   730 
   731 lemma mod_1 [simp]: "m mod Suc 0 = 0"
   732 by (induct m) (simp_all add: mod_geq)
   733 
   734 (* a simple rearrangement of mod_div_equality: *)
   735 lemma mult_div_cancel: "(n::nat) * (m div n) = m - (m mod n)"
   736   using mod_div_equality2 [of n m] by arith
   737 
   738 lemma mod_le_divisor[simp]: "0 < n \<Longrightarrow> m mod n \<le> (n::nat)"
   739   apply (drule mod_less_divisor [where m = m])
   740   apply simp
   741   done
   742 
   743 subsubsection {* Quotient and Remainder *}
   744 
   745 lemma divmod_nat_rel_mult1_eq:
   746   "divmod_nat_rel b c (q, r)
   747    \<Longrightarrow> divmod_nat_rel (a * b) c (a * q + a * r div c, a * r mod c)"
   748 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   749 
   750 lemma div_mult1_eq:
   751   "(a * b) div c = a * (b div c) + a * (b mod c) div (c::nat)"
   752 by (blast intro: divmod_nat_rel_mult1_eq [THEN div_nat_unique] divmod_nat_rel)
   753 
   754 lemma divmod_nat_rel_add1_eq:
   755   "divmod_nat_rel a c (aq, ar) \<Longrightarrow> divmod_nat_rel b c (bq, br)
   756    \<Longrightarrow> divmod_nat_rel (a + b) c (aq + bq + (ar + br) div c, (ar + br) mod c)"
   757 by (auto simp add: split_ifs divmod_nat_rel_def algebra_simps)
   758 
   759 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
   760 lemma div_add1_eq:
   761   "(a+b) div (c::nat) = a div c + b div c + ((a mod c + b mod c) div c)"
   762 by (blast intro: divmod_nat_rel_add1_eq [THEN div_nat_unique] divmod_nat_rel)
   763 
   764 lemma mod_lemma: "[| (0::nat) < c; r < b |] ==> b * (q mod c) + r < b * c"
   765   apply (cut_tac m = q and n = c in mod_less_divisor)
   766   apply (drule_tac [2] m = "q mod c" in less_imp_Suc_add, auto)
   767   apply (erule_tac P = "%x. ?lhs < ?rhs x" in ssubst)
   768   apply (simp add: add_mult_distrib2)
   769   done
   770 
   771 lemma divmod_nat_rel_mult2_eq:
   772   "divmod_nat_rel a b (q, r)
   773    \<Longrightarrow> divmod_nat_rel a (b * c) (q div c, b *(q mod c) + r)"
   774 by (auto simp add: mult_ac divmod_nat_rel_def add_mult_distrib2 [symmetric] mod_lemma)
   775 
   776 lemma div_mult2_eq: "a div (b*c) = (a div b) div (c::nat)"
   777 by (force simp add: divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN div_nat_unique])
   778 
   779 lemma mod_mult2_eq: "a mod (b*c) = b*(a div b mod c) + a mod (b::nat)"
   780 by (auto simp add: mult_commute divmod_nat_rel [THEN divmod_nat_rel_mult2_eq, THEN mod_nat_unique])
   781 
   782 
   783 subsubsection {* Further Facts about Quotient and Remainder *}
   784 
   785 lemma div_1 [simp]: "m div Suc 0 = m"
   786 by (induct m) (simp_all add: div_geq)
   787 
   788 (* Monotonicity of div in first argument *)
   789 lemma div_le_mono [rule_format (no_asm)]:
   790     "\<forall>m::nat. m \<le> n --> (m div k) \<le> (n div k)"
   791 apply (case_tac "k=0", simp)
   792 apply (induct "n" rule: nat_less_induct, clarify)
   793 apply (case_tac "n<k")
   794 (* 1  case n<k *)
   795 apply simp
   796 (* 2  case n >= k *)
   797 apply (case_tac "m<k")
   798 (* 2.1  case m<k *)
   799 apply simp
   800 (* 2.2  case m>=k *)
   801 apply (simp add: div_geq diff_le_mono)
   802 done
   803 
   804 (* Antimonotonicity of div in second argument *)
   805 lemma div_le_mono2: "!!m::nat. [| 0<m; m\<le>n |] ==> (k div n) \<le> (k div m)"
   806 apply (subgoal_tac "0<n")
   807  prefer 2 apply simp
   808 apply (induct_tac k rule: nat_less_induct)
   809 apply (rename_tac "k")
   810 apply (case_tac "k<n", simp)
   811 apply (subgoal_tac "~ (k<m) ")
   812  prefer 2 apply simp
   813 apply (simp add: div_geq)
   814 apply (subgoal_tac "(k-n) div n \<le> (k-m) div n")
   815  prefer 2
   816  apply (blast intro: div_le_mono diff_le_mono2)
   817 apply (rule le_trans, simp)
   818 apply (simp)
   819 done
   820 
   821 lemma div_le_dividend [simp]: "m div n \<le> (m::nat)"
   822 apply (case_tac "n=0", simp)
   823 apply (subgoal_tac "m div n \<le> m div 1", simp)
   824 apply (rule div_le_mono2)
   825 apply (simp_all (no_asm_simp))
   826 done
   827 
   828 (* Similar for "less than" *)
   829 lemma div_less_dividend [simp]:
   830   "\<lbrakk>(1::nat) < n; 0 < m\<rbrakk> \<Longrightarrow> m div n < m"
   831 apply (induct m rule: nat_less_induct)
   832 apply (rename_tac "m")
   833 apply (case_tac "m<n", simp)
   834 apply (subgoal_tac "0<n")
   835  prefer 2 apply simp
   836 apply (simp add: div_geq)
   837 apply (case_tac "n<m")
   838  apply (subgoal_tac "(m-n) div n < (m-n) ")
   839   apply (rule impI less_trans_Suc)+
   840 apply assumption
   841   apply (simp_all)
   842 done
   843 
   844 text{*A fact for the mutilated chess board*}
   845 lemma mod_Suc: "Suc(m) mod n = (if Suc(m mod n) = n then 0 else Suc(m mod n))"
   846 apply (case_tac "n=0", simp)
   847 apply (induct "m" rule: nat_less_induct)
   848 apply (case_tac "Suc (na) <n")
   849 (* case Suc(na) < n *)
   850 apply (frule lessI [THEN less_trans], simp add: less_not_refl3)
   851 (* case n \<le> Suc(na) *)
   852 apply (simp add: linorder_not_less le_Suc_eq mod_geq)
   853 apply (auto simp add: Suc_diff_le le_mod_geq)
   854 done
   855 
   856 lemma mod_eq_0_iff: "(m mod d = 0) = (\<exists>q::nat. m = d*q)"
   857 by (auto simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
   858 
   859 lemmas mod_eq_0D [dest!] = mod_eq_0_iff [THEN iffD1]
   860 
   861 (*Loses information, namely we also have r<d provided d is nonzero*)
   862 lemma mod_eqD: "(m mod d = r) ==> \<exists>q::nat. m = r + q*d"
   863   apply (cut_tac a = m in mod_div_equality)
   864   apply (simp only: add_ac)
   865   apply (blast intro: sym)
   866   done
   867 
   868 lemma split_div:
   869  "P(n div k :: nat) =
   870  ((k = 0 \<longrightarrow> P 0) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P i)))"
   871  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   872 proof
   873   assume P: ?P
   874   show ?Q
   875   proof (cases)
   876     assume "k = 0"
   877     with P show ?Q by simp
   878   next
   879     assume not0: "k \<noteq> 0"
   880     thus ?Q
   881     proof (simp, intro allI impI)
   882       fix i j
   883       assume n: "n = k*i + j" and j: "j < k"
   884       show "P i"
   885       proof (cases)
   886         assume "i = 0"
   887         with n j P show "P i" by simp
   888       next
   889         assume "i \<noteq> 0"
   890         with not0 n j P show "P i" by(simp add:add_ac)
   891       qed
   892     qed
   893   qed
   894 next
   895   assume Q: ?Q
   896   show ?P
   897   proof (cases)
   898     assume "k = 0"
   899     with Q show ?P by simp
   900   next
   901     assume not0: "k \<noteq> 0"
   902     with Q have R: ?R by simp
   903     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   904     show ?P by simp
   905   qed
   906 qed
   907 
   908 lemma split_div_lemma:
   909   assumes "0 < n"
   910   shows "n * q \<le> m \<and> m < n * Suc q \<longleftrightarrow> q = ((m\<Colon>nat) div n)" (is "?lhs \<longleftrightarrow> ?rhs")
   911 proof
   912   assume ?rhs
   913   with mult_div_cancel have nq: "n * q = m - (m mod n)" by simp
   914   then have A: "n * q \<le> m" by simp
   915   have "n - (m mod n) > 0" using mod_less_divisor assms by auto
   916   then have "m < m + (n - (m mod n))" by simp
   917   then have "m < n + (m - (m mod n))" by simp
   918   with nq have "m < n + n * q" by simp
   919   then have B: "m < n * Suc q" by simp
   920   from A B show ?lhs ..
   921 next
   922   assume P: ?lhs
   923   then have "divmod_nat_rel m n (q, m - n * q)"
   924     unfolding divmod_nat_rel_def by (auto simp add: mult_ac)
   925   with divmod_nat_rel_unique divmod_nat_rel [of m n]
   926   have "(q, m - n * q) = (m div n, m mod n)" by auto
   927   then show ?rhs by simp
   928 qed
   929 
   930 theorem split_div':
   931   "P ((m::nat) div n) = ((n = 0 \<and> P 0) \<or>
   932    (\<exists>q. (n * q \<le> m \<and> m < n * (Suc q)) \<and> P q))"
   933   apply (case_tac "0 < n")
   934   apply (simp only: add: split_div_lemma)
   935   apply simp_all
   936   done
   937 
   938 lemma split_mod:
   939  "P(n mod k :: nat) =
   940  ((k = 0 \<longrightarrow> P n) \<and> (k \<noteq> 0 \<longrightarrow> (!i. !j<k. n = k*i + j \<longrightarrow> P j)))"
   941  (is "?P = ?Q" is "_ = (_ \<and> (_ \<longrightarrow> ?R))")
   942 proof
   943   assume P: ?P
   944   show ?Q
   945   proof (cases)
   946     assume "k = 0"
   947     with P show ?Q by simp
   948   next
   949     assume not0: "k \<noteq> 0"
   950     thus ?Q
   951     proof (simp, intro allI impI)
   952       fix i j
   953       assume "n = k*i + j" "j < k"
   954       thus "P j" using not0 P by(simp add:add_ac mult_ac)
   955     qed
   956   qed
   957 next
   958   assume Q: ?Q
   959   show ?P
   960   proof (cases)
   961     assume "k = 0"
   962     with Q show ?P by simp
   963   next
   964     assume not0: "k \<noteq> 0"
   965     with Q have R: ?R by simp
   966     from not0 R[THEN spec,of "n div k",THEN spec, of "n mod k"]
   967     show ?P by simp
   968   qed
   969 qed
   970 
   971 theorem mod_div_equality': "(m::nat) mod n = m - (m div n) * n"
   972   using mod_div_equality [of m n] by arith
   973 
   974 lemma div_mod_equality': "(m::nat) div n * n = m - m mod n"
   975   using mod_div_equality [of m n] by arith
   976 (* FIXME: very similar to mult_div_cancel *)
   977 
   978 
   979 subsubsection {* An ``induction'' law for modulus arithmetic. *}
   980 
   981 lemma mod_induct_0:
   982   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
   983   and base: "P i" and i: "i<p"
   984   shows "P 0"
   985 proof (rule ccontr)
   986   assume contra: "\<not>(P 0)"
   987   from i have p: "0<p" by simp
   988   have "\<forall>k. 0<k \<longrightarrow> \<not> P (p-k)" (is "\<forall>k. ?A k")
   989   proof
   990     fix k
   991     show "?A k"
   992     proof (induct k)
   993       show "?A 0" by simp  -- "by contradiction"
   994     next
   995       fix n
   996       assume ih: "?A n"
   997       show "?A (Suc n)"
   998       proof (clarsimp)
   999         assume y: "P (p - Suc n)"
  1000         have n: "Suc n < p"
  1001         proof (rule ccontr)
  1002           assume "\<not>(Suc n < p)"
  1003           hence "p - Suc n = 0"
  1004             by simp
  1005           with y contra show "False"
  1006             by simp
  1007         qed
  1008         hence n2: "Suc (p - Suc n) = p-n" by arith
  1009         from p have "p - Suc n < p" by arith
  1010         with y step have z: "P ((Suc (p - Suc n)) mod p)"
  1011           by blast
  1012         show "False"
  1013         proof (cases "n=0")
  1014           case True
  1015           with z n2 contra show ?thesis by simp
  1016         next
  1017           case False
  1018           with p have "p-n < p" by arith
  1019           with z n2 False ih show ?thesis by simp
  1020         qed
  1021       qed
  1022     qed
  1023   qed
  1024   moreover
  1025   from i obtain k where "0<k \<and> i+k=p"
  1026     by (blast dest: less_imp_add_positive)
  1027   hence "0<k \<and> i=p-k" by auto
  1028   moreover
  1029   note base
  1030   ultimately
  1031   show "False" by blast
  1032 qed
  1033 
  1034 lemma mod_induct:
  1035   assumes step: "\<forall>i<p. P i \<longrightarrow> P ((Suc i) mod p)"
  1036   and base: "P i" and i: "i<p" and j: "j<p"
  1037   shows "P j"
  1038 proof -
  1039   have "\<forall>j<p. P j"
  1040   proof
  1041     fix j
  1042     show "j<p \<longrightarrow> P j" (is "?A j")
  1043     proof (induct j)
  1044       from step base i show "?A 0"
  1045         by (auto elim: mod_induct_0)
  1046     next
  1047       fix k
  1048       assume ih: "?A k"
  1049       show "?A (Suc k)"
  1050       proof
  1051         assume suc: "Suc k < p"
  1052         hence k: "k<p" by simp
  1053         with ih have "P k" ..
  1054         with step k have "P (Suc k mod p)"
  1055           by blast
  1056         moreover
  1057         from suc have "Suc k mod p = Suc k"
  1058           by simp
  1059         ultimately
  1060         show "P (Suc k)" by simp
  1061       qed
  1062     qed
  1063   qed
  1064   with j show ?thesis by blast
  1065 qed
  1066 
  1067 lemma div2_Suc_Suc [simp]: "Suc (Suc m) div 2 = Suc (m div 2)"
  1068   by (simp add: numeral_2_eq_2 le_div_geq)
  1069 
  1070 lemma mod2_Suc_Suc [simp]: "Suc (Suc m) mod 2 = m mod 2"
  1071   by (simp add: numeral_2_eq_2 le_mod_geq)
  1072 
  1073 lemma add_self_div_2 [simp]: "(m + m) div 2 = (m::nat)"
  1074 by (simp add: nat_mult_2 [symmetric])
  1075 
  1076 lemma mod2_gr_0 [simp]: "0 < (m\<Colon>nat) mod 2 \<longleftrightarrow> m mod 2 = 1"
  1077 proof -
  1078   { fix n :: nat have  "(n::nat) < 2 \<Longrightarrow> n = 0 \<or> n = 1" by (cases n) simp_all }
  1079   moreover have "m mod 2 < 2" by simp
  1080   ultimately have "m mod 2 = 0 \<or> m mod 2 = 1" .
  1081   then show ?thesis by auto
  1082 qed
  1083 
  1084 text{*These lemmas collapse some needless occurrences of Suc:
  1085     at least three Sucs, since two and fewer are rewritten back to Suc again!
  1086     We already have some rules to simplify operands smaller than 3.*}
  1087 
  1088 lemma div_Suc_eq_div_add3 [simp]: "m div (Suc (Suc (Suc n))) = m div (3+n)"
  1089 by (simp add: Suc3_eq_add_3)
  1090 
  1091 lemma mod_Suc_eq_mod_add3 [simp]: "m mod (Suc (Suc (Suc n))) = m mod (3+n)"
  1092 by (simp add: Suc3_eq_add_3)
  1093 
  1094 lemma Suc_div_eq_add3_div: "(Suc (Suc (Suc m))) div n = (3+m) div n"
  1095 by (simp add: Suc3_eq_add_3)
  1096 
  1097 lemma Suc_mod_eq_add3_mod: "(Suc (Suc (Suc m))) mod n = (3+m) mod n"
  1098 by (simp add: Suc3_eq_add_3)
  1099 
  1100 lemmas Suc_div_eq_add3_div_numeral [simp] = Suc_div_eq_add3_div [of _ "numeral v"] for v
  1101 lemmas Suc_mod_eq_add3_mod_numeral [simp] = Suc_mod_eq_add3_mod [of _ "numeral v"] for v
  1102 
  1103 
  1104 lemma Suc_times_mod_eq: "1<k ==> Suc (k * m) mod k = 1" 
  1105 apply (induct "m")
  1106 apply (simp_all add: mod_Suc)
  1107 done
  1108 
  1109 declare Suc_times_mod_eq [of "numeral w", simp] for w
  1110 
  1111 lemma Suc_div_le_mono [simp]: "n div k \<le> (Suc n) div k"
  1112 by (simp add: div_le_mono)
  1113 
  1114 lemma Suc_n_div_2_gt_zero [simp]: "(0::nat) < n ==> 0 < (n + 1) div 2"
  1115 by (cases n) simp_all
  1116 
  1117 lemma div_2_gt_zero [simp]: assumes A: "(1::nat) < n" shows "0 < n div 2"
  1118 proof -
  1119   from A have B: "0 < n - 1" and C: "n - 1 + 1 = n" by simp_all
  1120   from Suc_n_div_2_gt_zero [OF B] C show ?thesis by simp 
  1121 qed
  1122 
  1123   (* Potential use of algebra : Equality modulo n*)
  1124 lemma mod_mult_self3 [simp]: "(k*n + m) mod n = m mod (n::nat)"
  1125 by (simp add: mult_ac add_ac)
  1126 
  1127 lemma mod_mult_self4 [simp]: "Suc (k*n + m) mod n = Suc m mod n"
  1128 proof -
  1129   have "Suc (k * n + m) mod n = (k * n + Suc m) mod n" by simp
  1130   also have "... = Suc m mod n" by (rule mod_mult_self3) 
  1131   finally show ?thesis .
  1132 qed
  1133 
  1134 lemma mod_Suc_eq_Suc_mod: "Suc m mod n = Suc (m mod n) mod n"
  1135 apply (subst mod_Suc [of m]) 
  1136 apply (subst mod_Suc [of "m mod n"], simp) 
  1137 done
  1138 
  1139 lemma mod_2_not_eq_zero_eq_one_nat:
  1140   fixes n :: nat
  1141   shows "n mod 2 \<noteq> 0 \<longleftrightarrow> n mod 2 = 1"
  1142   by simp
  1143 
  1144 
  1145 subsection {* Division on @{typ int} *}
  1146 
  1147 definition divmod_int_rel :: "int \<Rightarrow> int \<Rightarrow> int \<times> int \<Rightarrow> bool" where
  1148     --{*definition of quotient and remainder*}
  1149   "divmod_int_rel a b = (\<lambda>(q, r). a = b * q + r \<and>
  1150     (if 0 < b then 0 \<le> r \<and> r < b else if b < 0 then b < r \<and> r \<le> 0 else q = 0))"
  1151 
  1152 definition adjust :: "int \<Rightarrow> int \<times> int \<Rightarrow> int \<times> int" where
  1153     --{*for the division algorithm*}
  1154     "adjust b = (\<lambda>(q, r). if 0 \<le> r - b then (2 * q + 1, r - b)
  1155                          else (2 * q, r))"
  1156 
  1157 text{*algorithm for the case @{text "a\<ge>0, b>0"}*}
  1158 function posDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1159   "posDivAlg a b = (if a < b \<or>  b \<le> 0 then (0, a)
  1160      else adjust b (posDivAlg a (2 * b)))"
  1161 by auto
  1162 termination by (relation "measure (\<lambda>(a, b). nat (a - b + 1))")
  1163   (auto simp add: mult_2)
  1164 
  1165 text{*algorithm for the case @{text "a<0, b>0"}*}
  1166 function negDivAlg :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1167   "negDivAlg a b = (if 0 \<le>a + b \<or> b \<le> 0  then (-1, a + b)
  1168      else adjust b (negDivAlg a (2 * b)))"
  1169 by auto
  1170 termination by (relation "measure (\<lambda>(a, b). nat (- a - b))")
  1171   (auto simp add: mult_2)
  1172 
  1173 text{*algorithm for the general case @{term "b\<noteq>0"}*}
  1174 
  1175 definition divmod_int :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  1176     --{*The full division algorithm considers all possible signs for a, b
  1177        including the special case @{text "a=0, b<0"} because 
  1178        @{term negDivAlg} requires @{term "a<0"}.*}
  1179   "divmod_int a b = (if 0 \<le> a then if 0 \<le> b then posDivAlg a b
  1180                   else if a = 0 then (0, 0)
  1181                        else apsnd uminus (negDivAlg (-a) (-b))
  1182                else 
  1183                   if 0 < b then negDivAlg a b
  1184                   else apsnd uminus (posDivAlg (-a) (-b)))"
  1185 
  1186 instantiation int :: Divides.div
  1187 begin
  1188 
  1189 definition div_int where
  1190   "a div b = fst (divmod_int a b)"
  1191 
  1192 lemma fst_divmod_int [simp]:
  1193   "fst (divmod_int a b) = a div b"
  1194   by (simp add: div_int_def)
  1195 
  1196 definition mod_int where
  1197   "a mod b = snd (divmod_int a b)"
  1198 
  1199 lemma snd_divmod_int [simp]:
  1200   "snd (divmod_int a b) = a mod b"
  1201   by (simp add: mod_int_def)
  1202 
  1203 instance ..
  1204 
  1205 end
  1206 
  1207 lemma divmod_int_mod_div:
  1208   "divmod_int p q = (p div q, p mod q)"
  1209   by (simp add: prod_eq_iff)
  1210 
  1211 text{*
  1212 Here is the division algorithm in ML:
  1213 
  1214 \begin{verbatim}
  1215     fun posDivAlg (a,b) =
  1216       if a<b then (0,a)
  1217       else let val (q,r) = posDivAlg(a, 2*b)
  1218                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1219            end
  1220 
  1221     fun negDivAlg (a,b) =
  1222       if 0\<le>a+b then (~1,a+b)
  1223       else let val (q,r) = negDivAlg(a, 2*b)
  1224                in  if 0\<le>r-b then (2*q+1, r-b) else (2*q, r)
  1225            end;
  1226 
  1227     fun negateSnd (q,r:int) = (q,~r);
  1228 
  1229     fun divmod (a,b) = if 0\<le>a then 
  1230                           if b>0 then posDivAlg (a,b) 
  1231                            else if a=0 then (0,0)
  1232                                 else negateSnd (negDivAlg (~a,~b))
  1233                        else 
  1234                           if 0<b then negDivAlg (a,b)
  1235                           else        negateSnd (posDivAlg (~a,~b));
  1236 \end{verbatim}
  1237 *}
  1238 
  1239 
  1240 subsubsection {* Uniqueness and Monotonicity of Quotients and Remainders *}
  1241 
  1242 lemma unique_quotient_lemma:
  1243      "[| b*q' + r'  \<le> b*q + r;  0 \<le> r';  r' < b;  r < b |]  
  1244       ==> q' \<le> (q::int)"
  1245 apply (subgoal_tac "r' + b * (q'-q) \<le> r")
  1246  prefer 2 apply (simp add: right_diff_distrib)
  1247 apply (subgoal_tac "0 < b * (1 + q - q') ")
  1248 apply (erule_tac [2] order_le_less_trans)
  1249  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1250 apply (subgoal_tac "b * q' < b * (1 + q) ")
  1251  prefer 2 apply (simp add: right_diff_distrib right_distrib)
  1252 apply (simp add: mult_less_cancel_left)
  1253 done
  1254 
  1255 lemma unique_quotient_lemma_neg:
  1256      "[| b*q' + r' \<le> b*q + r;  r \<le> 0;  b < r;  b < r' |]  
  1257       ==> q \<le> (q'::int)"
  1258 by (rule_tac b = "-b" and r = "-r'" and r' = "-r" in unique_quotient_lemma, 
  1259     auto)
  1260 
  1261 lemma unique_quotient:
  1262      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1263       ==> q = q'"
  1264 apply (simp add: divmod_int_rel_def linorder_neq_iff split: split_if_asm)
  1265 apply (blast intro: order_antisym
  1266              dest: order_eq_refl [THEN unique_quotient_lemma] 
  1267              order_eq_refl [THEN unique_quotient_lemma_neg] sym)+
  1268 done
  1269 
  1270 
  1271 lemma unique_remainder:
  1272      "[| divmod_int_rel a b (q, r); divmod_int_rel a b (q', r') |]  
  1273       ==> r = r'"
  1274 apply (subgoal_tac "q = q'")
  1275  apply (simp add: divmod_int_rel_def)
  1276 apply (blast intro: unique_quotient)
  1277 done
  1278 
  1279 
  1280 subsubsection {* Correctness of @{term posDivAlg}, the Algorithm for Non-Negative Dividends *}
  1281 
  1282 text{*And positive divisors*}
  1283 
  1284 lemma adjust_eq [simp]:
  1285      "adjust b (q, r) = 
  1286       (let diff = r - b in  
  1287         if 0 \<le> diff then (2 * q + 1, diff)   
  1288                      else (2*q, r))"
  1289   by (simp add: Let_def adjust_def)
  1290 
  1291 declare posDivAlg.simps [simp del]
  1292 
  1293 text{*use with a simproc to avoid repeatedly proving the premise*}
  1294 lemma posDivAlg_eqn:
  1295      "0 < b ==>  
  1296       posDivAlg a b = (if a<b then (0,a) else adjust b (posDivAlg a (2*b)))"
  1297 by (rule posDivAlg.simps [THEN trans], simp)
  1298 
  1299 text{*Correctness of @{term posDivAlg}: it computes quotients correctly*}
  1300 theorem posDivAlg_correct:
  1301   assumes "0 \<le> a" and "0 < b"
  1302   shows "divmod_int_rel a b (posDivAlg a b)"
  1303   using assms
  1304   apply (induct a b rule: posDivAlg.induct)
  1305   apply auto
  1306   apply (simp add: divmod_int_rel_def)
  1307   apply (subst posDivAlg_eqn, simp add: right_distrib)
  1308   apply (case_tac "a < b")
  1309   apply simp_all
  1310   apply (erule splitE)
  1311   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1312   done
  1313 
  1314 
  1315 subsubsection {* Correctness of @{term negDivAlg}, the Algorithm for Negative Dividends *}
  1316 
  1317 text{*And positive divisors*}
  1318 
  1319 declare negDivAlg.simps [simp del]
  1320 
  1321 text{*use with a simproc to avoid repeatedly proving the premise*}
  1322 lemma negDivAlg_eqn:
  1323      "0 < b ==>  
  1324       negDivAlg a b =       
  1325        (if 0\<le>a+b then (-1,a+b) else adjust b (negDivAlg a (2*b)))"
  1326 by (rule negDivAlg.simps [THEN trans], simp)
  1327 
  1328 (*Correctness of negDivAlg: it computes quotients correctly
  1329   It doesn't work if a=0 because the 0/b equals 0, not -1*)
  1330 lemma negDivAlg_correct:
  1331   assumes "a < 0" and "b > 0"
  1332   shows "divmod_int_rel a b (negDivAlg a b)"
  1333   using assms
  1334   apply (induct a b rule: negDivAlg.induct)
  1335   apply (auto simp add: linorder_not_le)
  1336   apply (simp add: divmod_int_rel_def)
  1337   apply (subst negDivAlg_eqn, assumption)
  1338   apply (case_tac "a + b < (0\<Colon>int)")
  1339   apply simp_all
  1340   apply (erule splitE)
  1341   apply (auto simp add: right_distrib Let_def mult_ac mult_2_right)
  1342   done
  1343 
  1344 
  1345 subsubsection {* Existence Shown by Proving the Division Algorithm to be Correct *}
  1346 
  1347 (*the case a=0*)
  1348 lemma divmod_int_rel_0: "divmod_int_rel 0 b (0, 0)"
  1349 by (auto simp add: divmod_int_rel_def linorder_neq_iff)
  1350 
  1351 lemma posDivAlg_0 [simp]: "posDivAlg 0 b = (0, 0)"
  1352 by (subst posDivAlg.simps, auto)
  1353 
  1354 lemma posDivAlg_0_right [simp]: "posDivAlg a 0 = (0, a)"
  1355 by (subst posDivAlg.simps, auto)
  1356 
  1357 lemma negDivAlg_minus1 [simp]: "negDivAlg -1 b = (-1, b - 1)"
  1358 by (subst negDivAlg.simps, auto)
  1359 
  1360 lemma divmod_int_rel_neg: "divmod_int_rel (-a) (-b) qr ==> divmod_int_rel a b (apsnd uminus qr)"
  1361 by (auto simp add: divmod_int_rel_def)
  1362 
  1363 lemma divmod_int_correct: "divmod_int_rel a b (divmod_int a b)"
  1364 apply (cases "b = 0", simp add: divmod_int_def divmod_int_rel_def)
  1365 by (force simp add: linorder_neq_iff divmod_int_rel_0 divmod_int_def divmod_int_rel_neg
  1366                     posDivAlg_correct negDivAlg_correct)
  1367 
  1368 lemma divmod_int_unique:
  1369   assumes "divmod_int_rel a b qr" 
  1370   shows "divmod_int a b = qr"
  1371   using assms divmod_int_correct [of a b]
  1372   using unique_quotient [of a b] unique_remainder [of a b]
  1373   by (metis pair_collapse)
  1374 
  1375 lemma divmod_int_rel_div_mod: "divmod_int_rel a b (a div b, a mod b)"
  1376   using divmod_int_correct by (simp add: divmod_int_mod_div)
  1377 
  1378 lemma div_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a div b = q"
  1379   by (simp add: divmod_int_rel_div_mod [THEN unique_quotient])
  1380 
  1381 lemma mod_int_unique: "divmod_int_rel a b (q, r) \<Longrightarrow> a mod b = r"
  1382   by (simp add: divmod_int_rel_div_mod [THEN unique_remainder])
  1383 
  1384 instance int :: ring_div
  1385 proof
  1386   fix a b :: int
  1387   show "a div b * b + a mod b = a"
  1388     using divmod_int_rel_div_mod [of a b]
  1389     unfolding divmod_int_rel_def by (simp add: mult_commute)
  1390 next
  1391   fix a b c :: int
  1392   assume "b \<noteq> 0"
  1393   hence "divmod_int_rel (a + c * b) b (c + a div b, a mod b)"
  1394     using divmod_int_rel_div_mod [of a b]
  1395     unfolding divmod_int_rel_def by (auto simp: algebra_simps)
  1396   thus "(a + c * b) div b = c + a div b"
  1397     by (rule div_int_unique)
  1398 next
  1399   fix a b c :: int
  1400   assume "c \<noteq> 0"
  1401   hence "\<And>q r. divmod_int_rel a b (q, r)
  1402     \<Longrightarrow> divmod_int_rel (c * a) (c * b) (q, c * r)"
  1403     unfolding divmod_int_rel_def
  1404     by - (rule linorder_cases [of 0 b], auto simp: algebra_simps
  1405       mult_less_0_iff zero_less_mult_iff mult_strict_right_mono
  1406       mult_strict_right_mono_neg zero_le_mult_iff mult_le_0_iff)
  1407   hence "divmod_int_rel (c * a) (c * b) (a div b, c * (a mod b))"
  1408     using divmod_int_rel_div_mod [of a b] .
  1409   thus "(c * a) div (c * b) = a div b"
  1410     by (rule div_int_unique)
  1411 next
  1412   fix a :: int show "a div 0 = 0"
  1413     by (rule div_int_unique, simp add: divmod_int_rel_def)
  1414 next
  1415   fix a :: int show "0 div a = 0"
  1416     by (rule div_int_unique, auto simp add: divmod_int_rel_def)
  1417 qed
  1418 
  1419 text{*Basic laws about division and remainder*}
  1420 
  1421 lemma zmod_zdiv_equality: "(a::int) = b * (a div b) + (a mod b)"
  1422   by (fact mod_div_equality2 [symmetric])
  1423 
  1424 lemma zdiv_zmod_equality: "(b * (a div b) + (a mod b)) + k = (a::int)+k"
  1425   by (fact div_mod_equality2)
  1426 
  1427 lemma zdiv_zmod_equality2: "((a div b) * b + (a mod b)) + k = (a::int)+k"
  1428   by (fact div_mod_equality)
  1429 
  1430 text {* Tool setup *}
  1431 
  1432 (* FIXME: Theorem list add_0s doesn't exist, because Numeral0 has gone. *)
  1433 lemmas add_0s = add_0_left add_0_right
  1434 
  1435 ML {*
  1436 structure Cancel_Div_Mod_Int = Cancel_Div_Mod
  1437 (
  1438   val div_name = @{const_name div};
  1439   val mod_name = @{const_name mod};
  1440   val mk_binop = HOLogic.mk_binop;
  1441   val mk_sum = Arith_Data.mk_sum HOLogic.intT;
  1442   val dest_sum = Arith_Data.dest_sum;
  1443 
  1444   val div_mod_eqs = map mk_meta_eq [@{thm zdiv_zmod_equality}, @{thm zdiv_zmod_equality2}];
  1445 
  1446   val prove_eq_sums = Arith_Data.prove_conv2 all_tac (Arith_Data.simp_all_tac 
  1447     (@{thm diff_minus} :: @{thms add_0s} @ @{thms add_ac}))
  1448 )
  1449 *}
  1450 
  1451 simproc_setup cancel_div_mod_int ("(k::int) + l") = {* K Cancel_Div_Mod_Int.proc *}
  1452 
  1453 lemma pos_mod_conj: "(0::int) < b \<Longrightarrow> 0 \<le> a mod b \<and> a mod b < b"
  1454   using divmod_int_correct [of a b]
  1455   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1456 
  1457 lemmas pos_mod_sign [simp] = pos_mod_conj [THEN conjunct1]
  1458    and pos_mod_bound [simp] = pos_mod_conj [THEN conjunct2]
  1459 
  1460 lemma neg_mod_conj: "b < (0::int) \<Longrightarrow> a mod b \<le> 0 \<and> b < a mod b"
  1461   using divmod_int_correct [of a b]
  1462   by (auto simp add: divmod_int_rel_def prod_eq_iff)
  1463 
  1464 lemmas neg_mod_sign [simp] = neg_mod_conj [THEN conjunct1]
  1465    and neg_mod_bound [simp] = neg_mod_conj [THEN conjunct2]
  1466 
  1467 
  1468 subsubsection {* General Properties of div and mod *}
  1469 
  1470 lemma div_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a div b = 0"
  1471 apply (rule div_int_unique)
  1472 apply (auto simp add: divmod_int_rel_def)
  1473 done
  1474 
  1475 lemma div_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a div b = 0"
  1476 apply (rule div_int_unique)
  1477 apply (auto simp add: divmod_int_rel_def)
  1478 done
  1479 
  1480 lemma div_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a div b = -1"
  1481 apply (rule div_int_unique)
  1482 apply (auto simp add: divmod_int_rel_def)
  1483 done
  1484 
  1485 (*There is no div_neg_pos_trivial because  0 div b = 0 would supersede it*)
  1486 
  1487 lemma mod_pos_pos_trivial: "[| (0::int) \<le> a;  a < b |] ==> a mod b = a"
  1488 apply (rule_tac q = 0 in mod_int_unique)
  1489 apply (auto simp add: divmod_int_rel_def)
  1490 done
  1491 
  1492 lemma mod_neg_neg_trivial: "[| a \<le> (0::int);  b < a |] ==> a mod b = a"
  1493 apply (rule_tac q = 0 in mod_int_unique)
  1494 apply (auto simp add: divmod_int_rel_def)
  1495 done
  1496 
  1497 lemma mod_pos_neg_trivial: "[| (0::int) < a;  a+b \<le> 0 |] ==> a mod b = a+b"
  1498 apply (rule_tac q = "-1" in mod_int_unique)
  1499 apply (auto simp add: divmod_int_rel_def)
  1500 done
  1501 
  1502 text{*There is no @{text mod_neg_pos_trivial}.*}
  1503 
  1504 
  1505 subsubsection {* Laws for div and mod with Unary Minus *}
  1506 
  1507 lemma zminus1_lemma:
  1508      "divmod_int_rel a b (q, r) ==> b \<noteq> 0
  1509       ==> divmod_int_rel (-a) b (if r=0 then -q else -q - 1,  
  1510                           if r=0 then 0 else b-r)"
  1511 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_diff_distrib)
  1512 
  1513 
  1514 lemma zdiv_zminus1_eq_if:
  1515      "b \<noteq> (0::int)  
  1516       ==> (-a) div b =  
  1517           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1518 by (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN div_int_unique])
  1519 
  1520 lemma zmod_zminus1_eq_if:
  1521      "(-a::int) mod b = (if a mod b = 0 then 0 else  b - (a mod b))"
  1522 apply (case_tac "b = 0", simp)
  1523 apply (blast intro: divmod_int_rel_div_mod [THEN zminus1_lemma, THEN mod_int_unique])
  1524 done
  1525 
  1526 lemma zmod_zminus1_not_zero:
  1527   fixes k l :: int
  1528   shows "- k mod l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1529   unfolding zmod_zminus1_eq_if by auto
  1530 
  1531 lemma zdiv_zminus2_eq_if:
  1532      "b \<noteq> (0::int)  
  1533       ==> a div (-b) =  
  1534           (if a mod b = 0 then - (a div b) else  - (a div b) - 1)"
  1535 by (simp add: zdiv_zminus1_eq_if div_minus_right)
  1536 
  1537 lemma zmod_zminus2_eq_if:
  1538      "a mod (-b::int) = (if a mod b = 0 then 0 else  (a mod b) - b)"
  1539 by (simp add: zmod_zminus1_eq_if mod_minus_right)
  1540 
  1541 lemma zmod_zminus2_not_zero:
  1542   fixes k l :: int
  1543   shows "k mod - l \<noteq> 0 \<Longrightarrow> k mod l \<noteq> 0"
  1544   unfolding zmod_zminus2_eq_if by auto 
  1545 
  1546 
  1547 subsubsection {* Computation of Division and Remainder *}
  1548 
  1549 lemma div_eq_minus1: "(0::int) < b ==> -1 div b = -1"
  1550 by (simp add: div_int_def divmod_int_def)
  1551 
  1552 lemma zmod_minus1: "(0::int) < b ==> -1 mod b = b - 1"
  1553 by (simp add: mod_int_def divmod_int_def)
  1554 
  1555 text{*a positive, b positive *}
  1556 
  1557 lemma div_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a div b = fst (posDivAlg a b)"
  1558 by (simp add: div_int_def divmod_int_def)
  1559 
  1560 lemma mod_pos_pos: "[| 0 < a;  0 \<le> b |] ==> a mod b = snd (posDivAlg a b)"
  1561 by (simp add: mod_int_def divmod_int_def)
  1562 
  1563 text{*a negative, b positive *}
  1564 
  1565 lemma div_neg_pos: "[| a < 0;  0 < b |] ==> a div b = fst (negDivAlg a b)"
  1566 by (simp add: div_int_def divmod_int_def)
  1567 
  1568 lemma mod_neg_pos: "[| a < 0;  0 < b |] ==> a mod b = snd (negDivAlg a b)"
  1569 by (simp add: mod_int_def divmod_int_def)
  1570 
  1571 text{*a positive, b negative *}
  1572 
  1573 lemma div_pos_neg:
  1574      "[| 0 < a;  b < 0 |] ==> a div b = fst (apsnd uminus (negDivAlg (-a) (-b)))"
  1575 by (simp add: div_int_def divmod_int_def)
  1576 
  1577 lemma mod_pos_neg:
  1578      "[| 0 < a;  b < 0 |] ==> a mod b = snd (apsnd uminus (negDivAlg (-a) (-b)))"
  1579 by (simp add: mod_int_def divmod_int_def)
  1580 
  1581 text{*a negative, b negative *}
  1582 
  1583 lemma div_neg_neg:
  1584      "[| a < 0;  b \<le> 0 |] ==> a div b = fst (apsnd uminus (posDivAlg (-a) (-b)))"
  1585 by (simp add: div_int_def divmod_int_def)
  1586 
  1587 lemma mod_neg_neg:
  1588      "[| a < 0;  b \<le> 0 |] ==> a mod b = snd (apsnd uminus (posDivAlg (-a) (-b)))"
  1589 by (simp add: mod_int_def divmod_int_def)
  1590 
  1591 text {*Simplify expresions in which div and mod combine numerical constants*}
  1592 
  1593 lemma int_div_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a div b = q"
  1594   by (rule div_int_unique [of a b q r]) (simp add: divmod_int_rel_def)
  1595 
  1596 lemma int_div_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a div b = q"
  1597   by (rule div_int_unique [of a b q r],
  1598     simp add: divmod_int_rel_def)
  1599 
  1600 lemma int_mod_pos_eq: "\<lbrakk>(a::int) = b * q + r; 0 \<le> r; r < b\<rbrakk> \<Longrightarrow> a mod b = r"
  1601   by (rule mod_int_unique [of a b q r],
  1602     simp add: divmod_int_rel_def)
  1603 
  1604 lemma int_mod_neg_eq: "\<lbrakk>(a::int) = b * q + r; r \<le> 0; b < r\<rbrakk> \<Longrightarrow> a mod b = r"
  1605   by (rule mod_int_unique [of a b q r],
  1606     simp add: divmod_int_rel_def)
  1607 
  1608 (* simprocs adapted from HOL/ex/Binary.thy *)
  1609 ML {*
  1610 local
  1611   val mk_number = HOLogic.mk_number HOLogic.intT
  1612   val plus = @{term "plus :: int \<Rightarrow> int \<Rightarrow> int"}
  1613   val times = @{term "times :: int \<Rightarrow> int \<Rightarrow> int"}
  1614   val zero = @{term "0 :: int"}
  1615   val less = @{term "op < :: int \<Rightarrow> int \<Rightarrow> bool"}
  1616   val le = @{term "op \<le> :: int \<Rightarrow> int \<Rightarrow> bool"}
  1617   val simps = @{thms arith_simps} @ @{thms rel_simps} @
  1618     map (fn th => th RS sym) [@{thm numeral_1_eq_1}]
  1619   fun prove ctxt goal = Goal.prove ctxt [] [] (HOLogic.mk_Trueprop goal)
  1620     (K (ALLGOALS (full_simp_tac (HOL_basic_ss addsimps simps))));
  1621   fun binary_proc proc ss ct =
  1622     (case Thm.term_of ct of
  1623       _ $ t $ u =>
  1624       (case try (pairself (`(snd o HOLogic.dest_number))) (t, u) of
  1625         SOME args => proc (Simplifier.the_context ss) args
  1626       | NONE => NONE)
  1627     | _ => NONE);
  1628 in
  1629   fun divmod_proc posrule negrule =
  1630     binary_proc (fn ctxt => fn ((a, t), (b, u)) =>
  1631       if b = 0 then NONE else let
  1632         val (q, r) = pairself mk_number (Integer.div_mod a b)
  1633         val goal1 = HOLogic.mk_eq (t, plus $ (times $ u $ q) $ r)
  1634         val (goal2, goal3, rule) = if b > 0
  1635           then (le $ zero $ r, less $ r $ u, posrule RS eq_reflection)
  1636           else (le $ r $ zero, less $ u $ r, negrule RS eq_reflection)
  1637       in SOME (rule OF map (prove ctxt) [goal1, goal2, goal3]) end)
  1638 end
  1639 *}
  1640 
  1641 simproc_setup binary_int_div
  1642   ("numeral m div numeral n :: int" |
  1643    "numeral m div neg_numeral n :: int" |
  1644    "neg_numeral m div numeral n :: int" |
  1645    "neg_numeral m div neg_numeral n :: int") =
  1646   {* K (divmod_proc @{thm int_div_pos_eq} @{thm int_div_neg_eq}) *}
  1647 
  1648 simproc_setup binary_int_mod
  1649   ("numeral m mod numeral n :: int" |
  1650    "numeral m mod neg_numeral n :: int" |
  1651    "neg_numeral m mod numeral n :: int" |
  1652    "neg_numeral m mod neg_numeral n :: int") =
  1653   {* K (divmod_proc @{thm int_mod_pos_eq} @{thm int_mod_neg_eq}) *}
  1654 
  1655 lemmas posDivAlg_eqn_numeral [simp] =
  1656     posDivAlg_eqn [of "numeral v" "numeral w", OF zero_less_numeral] for v w
  1657 
  1658 lemmas negDivAlg_eqn_numeral [simp] =
  1659     negDivAlg_eqn [of "numeral v" "neg_numeral w", OF zero_less_numeral] for v w
  1660 
  1661 
  1662 text{*Special-case simplification *}
  1663 
  1664 lemma zmod_minus1_right [simp]: "a mod (-1::int) = 0"
  1665 apply (cut_tac a = a and b = "-1" in neg_mod_sign)
  1666 apply (cut_tac [2] a = a and b = "-1" in neg_mod_bound)
  1667 apply (auto simp del: neg_mod_sign neg_mod_bound)
  1668 done (* FIXME: generalize *)
  1669 
  1670 lemma zdiv_minus1_right [simp]: "a div (-1::int) = -a"
  1671 by (cut_tac a = a and b = "-1" in zmod_zdiv_equality, auto)
  1672 (* FIXME: generalize *)
  1673 
  1674 (** The last remaining special cases for constant arithmetic:
  1675     1 div z and 1 mod z **)
  1676 
  1677 lemmas div_pos_pos_1_numeral [simp] =
  1678   div_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1679 
  1680 lemmas div_pos_neg_1_numeral [simp] =
  1681   div_pos_neg [OF zero_less_one, of "neg_numeral w",
  1682   OF neg_numeral_less_zero] for w
  1683 
  1684 lemmas mod_pos_pos_1_numeral [simp] =
  1685   mod_pos_pos [OF zero_less_one, of "numeral w", OF zero_le_numeral] for w
  1686 
  1687 lemmas mod_pos_neg_1_numeral [simp] =
  1688   mod_pos_neg [OF zero_less_one, of "neg_numeral w",
  1689   OF neg_numeral_less_zero] for w
  1690 
  1691 lemmas posDivAlg_eqn_1_numeral [simp] =
  1692     posDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1693 
  1694 lemmas negDivAlg_eqn_1_numeral [simp] =
  1695     negDivAlg_eqn [of concl: 1 "numeral w", OF zero_less_numeral] for w
  1696 
  1697 
  1698 subsubsection {* Monotonicity in the First Argument (Dividend) *}
  1699 
  1700 lemma zdiv_mono1: "[| a \<le> a';  0 < (b::int) |] ==> a div b \<le> a' div b"
  1701 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1702 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1703 apply (rule unique_quotient_lemma)
  1704 apply (erule subst)
  1705 apply (erule subst, simp_all)
  1706 done
  1707 
  1708 lemma zdiv_mono1_neg: "[| a \<le> a';  (b::int) < 0 |] ==> a' div b \<le> a div b"
  1709 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1710 apply (cut_tac a = a' and b = b in zmod_zdiv_equality)
  1711 apply (rule unique_quotient_lemma_neg)
  1712 apply (erule subst)
  1713 apply (erule subst, simp_all)
  1714 done
  1715 
  1716 
  1717 subsubsection {* Monotonicity in the Second Argument (Divisor) *}
  1718 
  1719 lemma q_pos_lemma:
  1720      "[| 0 \<le> b'*q' + r'; r' < b';  0 < b' |] ==> 0 \<le> (q'::int)"
  1721 apply (subgoal_tac "0 < b'* (q' + 1) ")
  1722  apply (simp add: zero_less_mult_iff)
  1723 apply (simp add: right_distrib)
  1724 done
  1725 
  1726 lemma zdiv_mono2_lemma:
  1727      "[| b*q + r = b'*q' + r';  0 \<le> b'*q' + r';   
  1728          r' < b';  0 \<le> r;  0 < b';  b' \<le> b |]   
  1729       ==> q \<le> (q'::int)"
  1730 apply (frule q_pos_lemma, assumption+) 
  1731 apply (subgoal_tac "b*q < b* (q' + 1) ")
  1732  apply (simp add: mult_less_cancel_left)
  1733 apply (subgoal_tac "b*q = r' - r + b'*q'")
  1734  prefer 2 apply simp
  1735 apply (simp (no_asm_simp) add: right_distrib)
  1736 apply (subst add_commute, rule add_less_le_mono, arith)
  1737 apply (rule mult_right_mono, auto)
  1738 done
  1739 
  1740 lemma zdiv_mono2:
  1741      "[| (0::int) \<le> a;  0 < b';  b' \<le> b |] ==> a div b \<le> a div b'"
  1742 apply (subgoal_tac "b \<noteq> 0")
  1743  prefer 2 apply arith
  1744 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1745 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1746 apply (rule zdiv_mono2_lemma)
  1747 apply (erule subst)
  1748 apply (erule subst, simp_all)
  1749 done
  1750 
  1751 lemma q_neg_lemma:
  1752      "[| b'*q' + r' < 0;  0 \<le> r';  0 < b' |] ==> q' \<le> (0::int)"
  1753 apply (subgoal_tac "b'*q' < 0")
  1754  apply (simp add: mult_less_0_iff, arith)
  1755 done
  1756 
  1757 lemma zdiv_mono2_neg_lemma:
  1758      "[| b*q + r = b'*q' + r';  b'*q' + r' < 0;   
  1759          r < b;  0 \<le> r';  0 < b';  b' \<le> b |]   
  1760       ==> q' \<le> (q::int)"
  1761 apply (frule q_neg_lemma, assumption+) 
  1762 apply (subgoal_tac "b*q' < b* (q + 1) ")
  1763  apply (simp add: mult_less_cancel_left)
  1764 apply (simp add: right_distrib)
  1765 apply (subgoal_tac "b*q' \<le> b'*q'")
  1766  prefer 2 apply (simp add: mult_right_mono_neg, arith)
  1767 done
  1768 
  1769 lemma zdiv_mono2_neg:
  1770      "[| a < (0::int);  0 < b';  b' \<le> b |] ==> a div b' \<le> a div b"
  1771 apply (cut_tac a = a and b = b in zmod_zdiv_equality)
  1772 apply (cut_tac a = a and b = b' in zmod_zdiv_equality)
  1773 apply (rule zdiv_mono2_neg_lemma)
  1774 apply (erule subst)
  1775 apply (erule subst, simp_all)
  1776 done
  1777 
  1778 
  1779 subsubsection {* More Algebraic Laws for div and mod *}
  1780 
  1781 text{*proving (a*b) div c = a * (b div c) + a * (b mod c) *}
  1782 
  1783 lemma zmult1_lemma:
  1784      "[| divmod_int_rel b c (q, r) |]  
  1785       ==> divmod_int_rel (a * b) c (a*q + a*r div c, a*r mod c)"
  1786 by (auto simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib mult_ac)
  1787 
  1788 lemma zdiv_zmult1_eq: "(a*b) div c = a*(b div c) + a*(b mod c) div (c::int)"
  1789 apply (case_tac "c = 0", simp)
  1790 apply (blast intro: divmod_int_rel_div_mod [THEN zmult1_lemma, THEN div_int_unique])
  1791 done
  1792 
  1793 lemma zmod_zmult1_eq: "(a*b) mod c = a*(b mod c) mod (c::int)"
  1794   by (fact mod_mult_right_eq) (* FIXME: delete *)
  1795 
  1796 text{*proving (a+b) div c = a div c + b div c + ((a mod c + b mod c) div c) *}
  1797 
  1798 lemma zadd1_lemma:
  1799      "[| divmod_int_rel a c (aq, ar);  divmod_int_rel b c (bq, br) |]  
  1800       ==> divmod_int_rel (a+b) c (aq + bq + (ar+br) div c, (ar+br) mod c)"
  1801 by (force simp add: split_ifs divmod_int_rel_def linorder_neq_iff right_distrib)
  1802 
  1803 (*NOT suitable for rewriting: the RHS has an instance of the LHS*)
  1804 lemma zdiv_zadd1_eq:
  1805      "(a+b) div (c::int) = a div c + b div c + ((a mod c + b mod c) div c)"
  1806 apply (case_tac "c = 0", simp)
  1807 apply (blast intro: zadd1_lemma [OF divmod_int_rel_div_mod divmod_int_rel_div_mod] div_int_unique)
  1808 done
  1809 
  1810 lemma posDivAlg_div_mod:
  1811   assumes "k \<ge> 0"
  1812   and "l \<ge> 0"
  1813   shows "posDivAlg k l = (k div l, k mod l)"
  1814 proof (cases "l = 0")
  1815   case True then show ?thesis by (simp add: posDivAlg.simps)
  1816 next
  1817   case False with assms posDivAlg_correct
  1818     have "divmod_int_rel k l (fst (posDivAlg k l), snd (posDivAlg k l))"
  1819     by simp
  1820   from div_int_unique [OF this] mod_int_unique [OF this]
  1821   show ?thesis by simp
  1822 qed
  1823 
  1824 lemma negDivAlg_div_mod:
  1825   assumes "k < 0"
  1826   and "l > 0"
  1827   shows "negDivAlg k l = (k div l, k mod l)"
  1828 proof -
  1829   from assms have "l \<noteq> 0" by simp
  1830   from assms negDivAlg_correct
  1831     have "divmod_int_rel k l (fst (negDivAlg k l), snd (negDivAlg k l))"
  1832     by simp
  1833   from div_int_unique [OF this] mod_int_unique [OF this]
  1834   show ?thesis by simp
  1835 qed
  1836 
  1837 lemma zmod_eq_0_iff: "(m mod d = 0) = (EX q::int. m = d*q)"
  1838 by (simp add: dvd_eq_mod_eq_0 [symmetric] dvd_def)
  1839 
  1840 (* REVISIT: should this be generalized to all semiring_div types? *)
  1841 lemmas zmod_eq_0D [dest!] = zmod_eq_0_iff [THEN iffD1]
  1842 
  1843 lemma zmod_zdiv_equality':
  1844   "(m\<Colon>int) mod n = m - (m div n) * n"
  1845   using mod_div_equality [of m n] by arith
  1846 
  1847 
  1848 subsubsection {* Proving  @{term "a div (b*c) = (a div b) div c"} *}
  1849 
  1850 (*The condition c>0 seems necessary.  Consider that 7 div ~6 = ~2 but
  1851   7 div 2 div ~3 = 3 div ~3 = ~1.  The subcase (a div b) mod c = 0 seems
  1852   to cause particular problems.*)
  1853 
  1854 text{*first, four lemmas to bound the remainder for the cases b<0 and b>0 *}
  1855 
  1856 lemma zmult2_lemma_aux1: "[| (0::int) < c;  b < r;  r \<le> 0 |] ==> b*c < b*(q mod c) + r"
  1857 apply (subgoal_tac "b * (c - q mod c) < r * 1")
  1858  apply (simp add: algebra_simps)
  1859 apply (rule order_le_less_trans)
  1860  apply (erule_tac [2] mult_strict_right_mono)
  1861  apply (rule mult_left_mono_neg)
  1862   using add1_zle_eq[of "q mod c"]apply(simp add: algebra_simps)
  1863  apply (simp)
  1864 apply (simp)
  1865 done
  1866 
  1867 lemma zmult2_lemma_aux2:
  1868      "[| (0::int) < c;   b < r;  r \<le> 0 |] ==> b * (q mod c) + r \<le> 0"
  1869 apply (subgoal_tac "b * (q mod c) \<le> 0")
  1870  apply arith
  1871 apply (simp add: mult_le_0_iff)
  1872 done
  1873 
  1874 lemma zmult2_lemma_aux3: "[| (0::int) < c;  0 \<le> r;  r < b |] ==> 0 \<le> b * (q mod c) + r"
  1875 apply (subgoal_tac "0 \<le> b * (q mod c) ")
  1876 apply arith
  1877 apply (simp add: zero_le_mult_iff)
  1878 done
  1879 
  1880 lemma zmult2_lemma_aux4: "[| (0::int) < c; 0 \<le> r; r < b |] ==> b * (q mod c) + r < b * c"
  1881 apply (subgoal_tac "r * 1 < b * (c - q mod c) ")
  1882  apply (simp add: right_diff_distrib)
  1883 apply (rule order_less_le_trans)
  1884  apply (erule mult_strict_right_mono)
  1885  apply (rule_tac [2] mult_left_mono)
  1886   apply simp
  1887  using add1_zle_eq[of "q mod c"] apply (simp add: algebra_simps)
  1888 apply simp
  1889 done
  1890 
  1891 lemma zmult2_lemma: "[| divmod_int_rel a b (q, r); 0 < c |]  
  1892       ==> divmod_int_rel a (b * c) (q div c, b*(q mod c) + r)"
  1893 by (auto simp add: mult_ac divmod_int_rel_def linorder_neq_iff
  1894                    zero_less_mult_iff right_distrib [symmetric] 
  1895                    zmult2_lemma_aux1 zmult2_lemma_aux2 zmult2_lemma_aux3 zmult2_lemma_aux4 mult_less_0_iff split: split_if_asm)
  1896 
  1897 lemma zdiv_zmult2_eq: "(0::int) < c ==> a div (b*c) = (a div b) div c"
  1898 apply (case_tac "b = 0", simp)
  1899 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN div_int_unique])
  1900 done
  1901 
  1902 lemma zmod_zmult2_eq:
  1903      "(0::int) < c ==> a mod (b*c) = b*(a div b mod c) + a mod b"
  1904 apply (case_tac "b = 0", simp)
  1905 apply (force simp add: divmod_int_rel_div_mod [THEN zmult2_lemma, THEN mod_int_unique])
  1906 done
  1907 
  1908 lemma div_pos_geq:
  1909   fixes k l :: int
  1910   assumes "0 < l" and "l \<le> k"
  1911   shows "k div l = (k - l) div l + 1"
  1912 proof -
  1913   have "k = (k - l) + l" by simp
  1914   then obtain j where k: "k = j + l" ..
  1915   with assms show ?thesis by simp
  1916 qed
  1917 
  1918 lemma mod_pos_geq:
  1919   fixes k l :: int
  1920   assumes "0 < l" and "l \<le> k"
  1921   shows "k mod l = (k - l) mod l"
  1922 proof -
  1923   have "k = (k - l) + l" by simp
  1924   then obtain j where k: "k = j + l" ..
  1925   with assms show ?thesis by simp
  1926 qed
  1927 
  1928 
  1929 subsubsection {* Splitting Rules for div and mod *}
  1930 
  1931 text{*The proofs of the two lemmas below are essentially identical*}
  1932 
  1933 lemma split_pos_lemma:
  1934  "0<k ==> 
  1935     P(n div k :: int)(n mod k) = (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i j)"
  1936 apply (rule iffI, clarify)
  1937  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1938  apply (subst mod_add_eq) 
  1939  apply (subst zdiv_zadd1_eq) 
  1940  apply (simp add: div_pos_pos_trivial mod_pos_pos_trivial)  
  1941 txt{*converse direction*}
  1942 apply (drule_tac x = "n div k" in spec) 
  1943 apply (drule_tac x = "n mod k" in spec, simp)
  1944 done
  1945 
  1946 lemma split_neg_lemma:
  1947  "k<0 ==>
  1948     P(n div k :: int)(n mod k) = (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i j)"
  1949 apply (rule iffI, clarify)
  1950  apply (erule_tac P="P ?x ?y" in rev_mp)  
  1951  apply (subst mod_add_eq) 
  1952  apply (subst zdiv_zadd1_eq) 
  1953  apply (simp add: div_neg_neg_trivial mod_neg_neg_trivial)  
  1954 txt{*converse direction*}
  1955 apply (drule_tac x = "n div k" in spec) 
  1956 apply (drule_tac x = "n mod k" in spec, simp)
  1957 done
  1958 
  1959 lemma split_zdiv:
  1960  "P(n div k :: int) =
  1961   ((k = 0 --> P 0) & 
  1962    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P i)) & 
  1963    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P i)))"
  1964 apply (case_tac "k=0", simp)
  1965 apply (simp only: linorder_neq_iff)
  1966 apply (erule disjE) 
  1967  apply (simp_all add: split_pos_lemma [of concl: "%x y. P x"] 
  1968                       split_neg_lemma [of concl: "%x y. P x"])
  1969 done
  1970 
  1971 lemma split_zmod:
  1972  "P(n mod k :: int) =
  1973   ((k = 0 --> P n) & 
  1974    (0<k --> (\<forall>i j. 0\<le>j & j<k & n = k*i + j --> P j)) & 
  1975    (k<0 --> (\<forall>i j. k<j & j\<le>0 & n = k*i + j --> P j)))"
  1976 apply (case_tac "k=0", simp)
  1977 apply (simp only: linorder_neq_iff)
  1978 apply (erule disjE) 
  1979  apply (simp_all add: split_pos_lemma [of concl: "%x y. P y"] 
  1980                       split_neg_lemma [of concl: "%x y. P y"])
  1981 done
  1982 
  1983 text {* Enable (lin)arith to deal with @{const div} and @{const mod}
  1984   when these are applied to some constant that is of the form
  1985   @{term "numeral k"}: *}
  1986 declare split_zdiv [of _ _ "numeral k", arith_split] for k
  1987 declare split_zmod [of _ _ "numeral k", arith_split] for k
  1988 
  1989 
  1990 subsubsection {* Speeding up the Division Algorithm with Shifting *}
  1991 
  1992 text{*computing div by shifting *}
  1993 
  1994 lemma pos_zdiv_mult_2: "(0::int) \<le> a ==> (1 + 2*b) div (2*a) = b div a"
  1995 proof cases
  1996   assume "a=0"
  1997     thus ?thesis by simp
  1998 next
  1999   assume "a\<noteq>0" and le_a: "0\<le>a"   
  2000   hence a_pos: "1 \<le> a" by arith
  2001   hence one_less_a2: "1 < 2 * a" by arith
  2002   hence le_2a: "2 * (1 + b mod a) \<le> 2 * a"
  2003     unfolding mult_le_cancel_left
  2004     by (simp add: add1_zle_eq add_commute [of 1])
  2005   with a_pos have "0 \<le> b mod a" by simp
  2006   hence le_addm: "0 \<le> 1 mod (2*a) + 2*(b mod a)"
  2007     by (simp add: mod_pos_pos_trivial one_less_a2)
  2008   with  le_2a
  2009   have "(1 mod (2*a) + 2*(b mod a)) div (2*a) = 0"
  2010     by (simp add: div_pos_pos_trivial le_addm mod_pos_pos_trivial one_less_a2
  2011                   right_distrib) 
  2012   thus ?thesis
  2013     by (subst zdiv_zadd1_eq,
  2014         simp add: mod_mult_mult1 one_less_a2
  2015                   div_pos_pos_trivial)
  2016 qed
  2017 
  2018 lemma neg_zdiv_mult_2: 
  2019   assumes A: "a \<le> (0::int)" shows "(1 + 2*b) div (2*a) = (b+1) div a"
  2020 proof -
  2021   have R: "1 + - (2 * (b + 1)) = - (1 + 2 * b)" by simp
  2022   have "(1 + 2 * (-b - 1)) div (2 * (-a)) = (-b - 1) div (-a)"
  2023     by (rule pos_zdiv_mult_2, simp add: A)
  2024   thus ?thesis
  2025     by (simp only: R div_minus_minus diff_minus
  2026       minus_add_distrib [symmetric] mult_minus_right)
  2027 qed
  2028 
  2029 (* FIXME: add rules for negative numerals *)
  2030 lemma zdiv_numeral_Bit0 [simp]:
  2031   "numeral (Num.Bit0 v) div numeral (Num.Bit0 w) =
  2032     numeral v div (numeral w :: int)"
  2033   unfolding numeral.simps unfolding mult_2 [symmetric]
  2034   by (rule div_mult_mult1, simp)
  2035 
  2036 lemma zdiv_numeral_Bit1 [simp]:
  2037   "numeral (Num.Bit1 v) div numeral (Num.Bit0 w) =  
  2038     (numeral v div (numeral w :: int))"
  2039   unfolding numeral.simps
  2040   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2041   by (rule pos_zdiv_mult_2, simp)
  2042 
  2043 
  2044 subsubsection {* Computing mod by Shifting (proofs resemble those for div) *}
  2045 
  2046 lemma pos_zmod_mult_2:
  2047   fixes a b :: int
  2048   assumes "0 \<le> a"
  2049   shows "(1 + 2 * b) mod (2 * a) = 1 + 2 * (b mod a)"
  2050 proof (cases "0 < a")
  2051   case False with assms show ?thesis by simp
  2052 next
  2053   case True
  2054   then have "b mod a < a" by (rule pos_mod_bound)
  2055   then have "1 + b mod a \<le> a" by simp
  2056   then have A: "2 * (1 + b mod a) \<le> 2 * a" by simp
  2057   from `0 < a` have "0 \<le> b mod a" by (rule pos_mod_sign)
  2058   then have B: "0 \<le> 1 + 2 * (b mod a)" by simp
  2059   have "((1\<Colon>int) mod ((2\<Colon>int) * a) + (2\<Colon>int) * b mod ((2\<Colon>int) * a)) mod ((2\<Colon>int) * a) = (1\<Colon>int) + (2\<Colon>int) * (b mod a)"
  2060     using `0 < a` and A
  2061     by (auto simp add: mod_mult_mult1 mod_pos_pos_trivial ring_distribs intro!: mod_pos_pos_trivial B)
  2062   then show ?thesis by (subst mod_add_eq)
  2063 qed
  2064 
  2065 lemma neg_zmod_mult_2:
  2066   fixes a b :: int
  2067   assumes "a \<le> 0"
  2068   shows "(1 + 2 * b) mod (2 * a) = 2 * ((b + 1) mod a) - 1"
  2069 proof -
  2070   from assms have "0 \<le> - a" by auto
  2071   then have "(1 + 2 * (- b - 1)) mod (2 * (- a)) = 1 + 2 * ((- b - 1) mod (- a))"
  2072     by (rule pos_zmod_mult_2)
  2073   then show ?thesis by (simp add: mod_minus_right algebra_simps)
  2074      (simp add: diff_minus add_ac)
  2075 qed
  2076 
  2077 (* FIXME: add rules for negative numerals *)
  2078 lemma zmod_numeral_Bit0 [simp]:
  2079   "numeral (Num.Bit0 v) mod numeral (Num.Bit0 w) =  
  2080     (2::int) * (numeral v mod numeral w)"
  2081   unfolding numeral_Bit0 [of v] numeral_Bit0 [of w]
  2082   unfolding mult_2 [symmetric] by (rule mod_mult_mult1)
  2083 
  2084 lemma zmod_numeral_Bit1 [simp]:
  2085   "numeral (Num.Bit1 v) mod numeral (Num.Bit0 w) =
  2086     2 * (numeral v mod numeral w) + (1::int)"
  2087   unfolding numeral_Bit1 [of v] numeral_Bit0 [of w]
  2088   unfolding mult_2 [symmetric] add_commute [of _ 1]
  2089   by (rule pos_zmod_mult_2, simp)
  2090 
  2091 lemma zdiv_eq_0_iff:
  2092  "(i::int) div k = 0 \<longleftrightarrow> k=0 \<or> 0\<le>i \<and> i<k \<or> i\<le>0 \<and> k<i" (is "?L = ?R")
  2093 proof
  2094   assume ?L
  2095   have "?L \<longrightarrow> ?R" by (rule split_zdiv[THEN iffD2]) simp
  2096   with `?L` show ?R by blast
  2097 next
  2098   assume ?R thus ?L
  2099     by(auto simp: div_pos_pos_trivial div_neg_neg_trivial)
  2100 qed
  2101 
  2102 
  2103 subsubsection {* Quotients of Signs *}
  2104 
  2105 lemma div_neg_pos_less0: "[| a < (0::int);  0 < b |] ==> a div b < 0"
  2106 apply (subgoal_tac "a div b \<le> -1", force)
  2107 apply (rule order_trans)
  2108 apply (rule_tac a' = "-1" in zdiv_mono1)
  2109 apply (auto simp add: div_eq_minus1)
  2110 done
  2111 
  2112 lemma div_nonneg_neg_le0: "[| (0::int) \<le> a; b < 0 |] ==> a div b \<le> 0"
  2113 by (drule zdiv_mono1_neg, auto)
  2114 
  2115 lemma div_nonpos_pos_le0: "[| (a::int) \<le> 0; b > 0 |] ==> a div b \<le> 0"
  2116 by (drule zdiv_mono1, auto)
  2117 
  2118 text{* Now for some equivalences of the form @{text"a div b >=< 0 \<longleftrightarrow> \<dots>"}
  2119 conditional upon the sign of @{text a} or @{text b}. There are many more.
  2120 They should all be simp rules unless that causes too much search. *}
  2121 
  2122 lemma pos_imp_zdiv_nonneg_iff: "(0::int) < b ==> (0 \<le> a div b) = (0 \<le> a)"
  2123 apply auto
  2124 apply (drule_tac [2] zdiv_mono1)
  2125 apply (auto simp add: linorder_neq_iff)
  2126 apply (simp (no_asm_use) add: linorder_not_less [symmetric])
  2127 apply (blast intro: div_neg_pos_less0)
  2128 done
  2129 
  2130 lemma neg_imp_zdiv_nonneg_iff:
  2131   "b < (0::int) ==> (0 \<le> a div b) = (a \<le> (0::int))"
  2132 apply (subst div_minus_minus [symmetric])
  2133 apply (subst pos_imp_zdiv_nonneg_iff, auto)
  2134 done
  2135 
  2136 (*But not (a div b \<le> 0 iff a\<le>0); consider a=1, b=2 when a div b = 0.*)
  2137 lemma pos_imp_zdiv_neg_iff: "(0::int) < b ==> (a div b < 0) = (a < 0)"
  2138 by (simp add: linorder_not_le [symmetric] pos_imp_zdiv_nonneg_iff)
  2139 
  2140 lemma pos_imp_zdiv_pos_iff:
  2141   "0<k \<Longrightarrow> 0 < (i::int) div k \<longleftrightarrow> k \<le> i"
  2142 using pos_imp_zdiv_nonneg_iff[of k i] zdiv_eq_0_iff[of i k]
  2143 by arith
  2144 
  2145 (*Again the law fails for \<le>: consider a = -1, b = -2 when a div b = 0*)
  2146 lemma neg_imp_zdiv_neg_iff: "b < (0::int) ==> (a div b < 0) = (0 < a)"
  2147 by (simp add: linorder_not_le [symmetric] neg_imp_zdiv_nonneg_iff)
  2148 
  2149 lemma nonneg1_imp_zdiv_pos_iff:
  2150   "(0::int) <= a \<Longrightarrow> (a div b > 0) = (a >= b & b>0)"
  2151 apply rule
  2152  apply rule
  2153   using div_pos_pos_trivial[of a b]apply arith
  2154  apply(cases "b=0")apply simp
  2155  using div_nonneg_neg_le0[of a b]apply arith
  2156 using int_one_le_iff_zero_less[of "a div b"] zdiv_mono1[of b a b]apply simp
  2157 done
  2158 
  2159 lemma zmod_le_nonneg_dividend: "(m::int) \<ge> 0 ==> m mod k \<le> m"
  2160 apply (rule split_zmod[THEN iffD2])
  2161 apply(fastforce dest: q_pos_lemma intro: split_mult_pos_le)
  2162 done
  2163 
  2164 
  2165 subsubsection {* The Divides Relation *}
  2166 
  2167 lemmas zdvd_iff_zmod_eq_0_numeral [simp] =
  2168   dvd_eq_mod_eq_0 [of "numeral x::int" "numeral y::int"]
  2169   dvd_eq_mod_eq_0 [of "numeral x::int" "neg_numeral y::int"]
  2170   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "numeral y::int"]
  2171   dvd_eq_mod_eq_0 [of "neg_numeral x::int" "neg_numeral y::int"] for x y
  2172 
  2173 lemma zdvd_zmod: "f dvd m ==> f dvd (n::int) ==> f dvd m mod n"
  2174   by (rule dvd_mod) (* TODO: remove *)
  2175 
  2176 lemma zdvd_zmod_imp_zdvd: "k dvd m mod n ==> k dvd n ==> k dvd (m::int)"
  2177   by (rule dvd_mod_imp_dvd) (* TODO: remove *)
  2178 
  2179 lemmas dvd_eq_mod_eq_0_numeral [simp] =
  2180   dvd_eq_mod_eq_0 [of "numeral x" "numeral y"] for x y
  2181 
  2182 
  2183 subsubsection {* Further properties *}
  2184 
  2185 lemma zmult_div_cancel: "(n::int) * (m div n) = m - (m mod n)"
  2186   using zmod_zdiv_equality[where a="m" and b="n"]
  2187   by (simp add: algebra_simps) (* FIXME: generalize *)
  2188 
  2189 lemma zpower_zmod: "((x::int) mod m)^y mod m = x^y mod m"
  2190 apply (induct "y", auto)
  2191 apply (rule mod_mult_right_eq [THEN trans])
  2192 apply (simp (no_asm_simp))
  2193 apply (rule mod_mult_eq [symmetric])
  2194 done (* FIXME: generalize *)
  2195 
  2196 lemma zdiv_int: "int (a div b) = (int a) div (int b)"
  2197 apply (subst split_div, auto)
  2198 apply (subst split_zdiv, auto)
  2199 apply (rule_tac a="int (b * i) + int j" and b="int b" and r="int j" and r'=ja in unique_quotient)
  2200 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2201 done
  2202 
  2203 lemma zmod_int: "int (a mod b) = (int a) mod (int b)"
  2204 apply (subst split_mod, auto)
  2205 apply (subst split_zmod, auto)
  2206 apply (rule_tac a="int (b * i) + int j" and b="int b" and q="int i" and q'=ia 
  2207        in unique_remainder)
  2208 apply (auto simp add: divmod_int_rel_def of_nat_mult)
  2209 done
  2210 
  2211 lemma abs_div: "(y::int) dvd x \<Longrightarrow> abs (x div y) = abs x div abs y"
  2212 by (unfold dvd_def, cases "y=0", auto simp add: abs_mult)
  2213 
  2214 lemma zdvd_mult_div_cancel:"(n::int) dvd m \<Longrightarrow> n * (m div n) = m"
  2215 apply (subgoal_tac "m mod n = 0")
  2216  apply (simp add: zmult_div_cancel)
  2217 apply (simp only: dvd_eq_mod_eq_0)
  2218 done
  2219 
  2220 text{*Suggested by Matthias Daum*}
  2221 lemma int_power_div_base:
  2222      "\<lbrakk>0 < m; 0 < k\<rbrakk> \<Longrightarrow> k ^ m div k = (k::int) ^ (m - Suc 0)"
  2223 apply (subgoal_tac "k ^ m = k ^ ((m - Suc 0) + Suc 0)")
  2224  apply (erule ssubst)
  2225  apply (simp only: power_add)
  2226  apply simp_all
  2227 done
  2228 
  2229 text {* by Brian Huffman *}
  2230 lemma zminus_zmod: "- ((x::int) mod m) mod m = - x mod m"
  2231 by (rule mod_minus_eq [symmetric])
  2232 
  2233 lemma zdiff_zmod_left: "(x mod m - y) mod m = (x - y) mod (m::int)"
  2234 by (rule mod_diff_left_eq [symmetric])
  2235 
  2236 lemma zdiff_zmod_right: "(x - y mod m) mod m = (x - y) mod (m::int)"
  2237 by (rule mod_diff_right_eq [symmetric])
  2238 
  2239 lemmas zmod_simps =
  2240   mod_add_left_eq  [symmetric]
  2241   mod_add_right_eq [symmetric]
  2242   mod_mult_right_eq[symmetric]
  2243   mod_mult_left_eq [symmetric]
  2244   zpower_zmod
  2245   zminus_zmod zdiff_zmod_left zdiff_zmod_right
  2246 
  2247 text {* Distributive laws for function @{text nat}. *}
  2248 
  2249 lemma nat_div_distrib: "0 \<le> x \<Longrightarrow> nat (x div y) = nat x div nat y"
  2250 apply (rule linorder_cases [of y 0])
  2251 apply (simp add: div_nonneg_neg_le0)
  2252 apply simp
  2253 apply (simp add: nat_eq_iff pos_imp_zdiv_nonneg_iff zdiv_int)
  2254 done
  2255 
  2256 (*Fails if y<0: the LHS collapses to (nat z) but the RHS doesn't*)
  2257 lemma nat_mod_distrib:
  2258   "\<lbrakk>0 \<le> x; 0 \<le> y\<rbrakk> \<Longrightarrow> nat (x mod y) = nat x mod nat y"
  2259 apply (case_tac "y = 0", simp)
  2260 apply (simp add: nat_eq_iff zmod_int)
  2261 done
  2262 
  2263 text  {* transfer setup *}
  2264 
  2265 lemma transfer_nat_int_functions:
  2266     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) div (nat y) = nat (x div y)"
  2267     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> (nat x) mod (nat y) = nat (x mod y)"
  2268   by (auto simp add: nat_div_distrib nat_mod_distrib)
  2269 
  2270 lemma transfer_nat_int_function_closures:
  2271     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x div y >= 0"
  2272     "(x::int) >= 0 \<Longrightarrow> y >= 0 \<Longrightarrow> x mod y >= 0"
  2273   apply (cases "y = 0")
  2274   apply (auto simp add: pos_imp_zdiv_nonneg_iff)
  2275   apply (cases "y = 0")
  2276   apply auto
  2277 done
  2278 
  2279 declare transfer_morphism_nat_int [transfer add return:
  2280   transfer_nat_int_functions
  2281   transfer_nat_int_function_closures
  2282 ]
  2283 
  2284 lemma transfer_int_nat_functions:
  2285     "(int x) div (int y) = int (x div y)"
  2286     "(int x) mod (int y) = int (x mod y)"
  2287   by (auto simp add: zdiv_int zmod_int)
  2288 
  2289 lemma transfer_int_nat_function_closures:
  2290     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x div y)"
  2291     "is_nat x \<Longrightarrow> is_nat y \<Longrightarrow> is_nat (x mod y)"
  2292   by (simp_all only: is_nat_def transfer_nat_int_function_closures)
  2293 
  2294 declare transfer_morphism_int_nat [transfer add return:
  2295   transfer_int_nat_functions
  2296   transfer_int_nat_function_closures
  2297 ]
  2298 
  2299 text{*Suggested by Matthias Daum*}
  2300 lemma int_div_less_self: "\<lbrakk>0 < x; 1 < k\<rbrakk> \<Longrightarrow> x div k < (x::int)"
  2301 apply (subgoal_tac "nat x div nat k < nat x")
  2302  apply (simp add: nat_div_distrib [symmetric])
  2303 apply (rule Divides.div_less_dividend, simp_all)
  2304 done
  2305 
  2306 lemma zmod_eq_dvd_iff: "(x::int) mod n = y mod n \<longleftrightarrow> n dvd x - y"
  2307 proof
  2308   assume H: "x mod n = y mod n"
  2309   hence "x mod n - y mod n = 0" by simp
  2310   hence "(x mod n - y mod n) mod n = 0" by simp 
  2311   hence "(x - y) mod n = 0" by (simp add: mod_diff_eq[symmetric])
  2312   thus "n dvd x - y" by (simp add: dvd_eq_mod_eq_0)
  2313 next
  2314   assume H: "n dvd x - y"
  2315   then obtain k where k: "x-y = n*k" unfolding dvd_def by blast
  2316   hence "x = n*k + y" by simp
  2317   hence "x mod n = (n*k + y) mod n" by simp
  2318   thus "x mod n = y mod n" by (simp add: mod_add_left_eq)
  2319 qed
  2320 
  2321 lemma nat_mod_eq_lemma: assumes xyn: "(x::nat) mod n = y  mod n" and xy:"y \<le> x"
  2322   shows "\<exists>q. x = y + n * q"
  2323 proof-
  2324   from xy have th: "int x - int y = int (x - y)" by simp 
  2325   from xyn have "int x mod int n = int y mod int n" 
  2326     by (simp add: zmod_int [symmetric])
  2327   hence "int n dvd int x - int y" by (simp only: zmod_eq_dvd_iff[symmetric]) 
  2328   hence "n dvd x - y" by (simp add: th zdvd_int)
  2329   then show ?thesis using xy unfolding dvd_def apply clarsimp apply (rule_tac x="k" in exI) by arith
  2330 qed
  2331 
  2332 lemma nat_mod_eq_iff: "(x::nat) mod n = y mod n \<longleftrightarrow> (\<exists>q1 q2. x + n * q1 = y + n * q2)" 
  2333   (is "?lhs = ?rhs")
  2334 proof
  2335   assume H: "x mod n = y mod n"
  2336   {assume xy: "x \<le> y"
  2337     from H have th: "y mod n = x mod n" by simp
  2338     from nat_mod_eq_lemma[OF th xy] have ?rhs 
  2339       apply clarify  apply (rule_tac x="q" in exI) by (rule exI[where x="0"], simp)}
  2340   moreover
  2341   {assume xy: "y \<le> x"
  2342     from nat_mod_eq_lemma[OF H xy] have ?rhs 
  2343       apply clarify  apply (rule_tac x="0" in exI) by (rule_tac x="q" in exI, simp)}
  2344   ultimately  show ?rhs using linear[of x y] by blast  
  2345 next
  2346   assume ?rhs then obtain q1 q2 where q12: "x + n * q1 = y + n * q2" by blast
  2347   hence "(x + n * q1) mod n = (y + n * q2) mod n" by simp
  2348   thus  ?lhs by simp
  2349 qed
  2350 
  2351 lemma div_nat_numeral [simp]:
  2352   "(numeral v :: nat) div numeral v' = nat (numeral v div numeral v')"
  2353   by (simp add: nat_div_distrib)
  2354 
  2355 lemma one_div_nat_numeral [simp]:
  2356   "Suc 0 div numeral v' = nat (1 div numeral v')"
  2357   by (subst nat_div_distrib, simp_all)
  2358 
  2359 lemma mod_nat_numeral [simp]:
  2360   "(numeral v :: nat) mod numeral v' = nat (numeral v mod numeral v')"
  2361   by (simp add: nat_mod_distrib)
  2362 
  2363 lemma one_mod_nat_numeral [simp]:
  2364   "Suc 0 mod numeral v' = nat (1 mod numeral v')"
  2365   by (subst nat_mod_distrib) simp_all
  2366 
  2367 lemma mod_2_not_eq_zero_eq_one_int:
  2368   fixes k :: int
  2369   shows "k mod 2 \<noteq> 0 \<longleftrightarrow> k mod 2 = 1"
  2370   by auto
  2371 
  2372 
  2373 subsubsection {* Tools setup *}
  2374 
  2375 text {* Nitpick *}
  2376 
  2377 lemmas [nitpick_unfold] = dvd_eq_mod_eq_0 mod_div_equality' zmod_zdiv_equality'
  2378 
  2379 
  2380 subsubsection {* Code generation *}
  2381 
  2382 definition pdivmod :: "int \<Rightarrow> int \<Rightarrow> int \<times> int" where
  2383   "pdivmod k l = (\<bar>k\<bar> div \<bar>l\<bar>, \<bar>k\<bar> mod \<bar>l\<bar>)"
  2384 
  2385 lemma pdivmod_posDivAlg [code]:
  2386   "pdivmod k l = (if l = 0 then (0, \<bar>k\<bar>) else posDivAlg \<bar>k\<bar> \<bar>l\<bar>)"
  2387 by (subst posDivAlg_div_mod) (simp_all add: pdivmod_def)
  2388 
  2389 lemma divmod_int_pdivmod: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2390   apsnd ((op *) (sgn l)) (if 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0
  2391     then pdivmod k l
  2392     else (let (r, s) = pdivmod k l in
  2393        if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2394 proof -
  2395   have aux: "\<And>q::int. - k = l * q \<longleftrightarrow> k = l * - q" by auto
  2396   show ?thesis
  2397     by (simp add: divmod_int_mod_div pdivmod_def)
  2398       (auto simp add: aux not_less not_le zdiv_zminus1_eq_if
  2399       zmod_zminus1_eq_if zdiv_zminus2_eq_if zmod_zminus2_eq_if)
  2400 qed
  2401 
  2402 lemma divmod_int_code [code]: "divmod_int k l = (if k = 0 then (0, 0) else if l = 0 then (0, k) else
  2403   apsnd ((op *) (sgn l)) (if sgn k = sgn l
  2404     then pdivmod k l
  2405     else (let (r, s) = pdivmod k l in
  2406       if s = 0 then (- r, 0) else (- r - 1, \<bar>l\<bar> - s))))"
  2407 proof -
  2408   have "k \<noteq> 0 \<Longrightarrow> l \<noteq> 0 \<Longrightarrow> 0 < l \<and> 0 \<le> k \<or> l < 0 \<and> k < 0 \<longleftrightarrow> sgn k = sgn l"
  2409     by (auto simp add: not_less sgn_if)
  2410   then show ?thesis by (simp add: divmod_int_pdivmod)
  2411 qed
  2412 
  2413 code_modulename SML
  2414   Divides Arith
  2415 
  2416 code_modulename OCaml
  2417   Divides Arith
  2418 
  2419 code_modulename Haskell
  2420   Divides Arith
  2421 
  2422 end