src/Pure/context.ML
author wenzelm
Tue Jun 24 19:43:17 2008 +0200 (2008-06-24)
changeset 27341 97e2ccba3b64
parent 26957 e3f04fdd994d
child 28122 3d099ce624e7
permissions -rw-r--r--
added pprint_thy_ref;
     1 (*  Title:      Pure/context.ML
     2     ID:         $Id$
     3     Author:     Markus Wenzel, TU Muenchen
     4 
     5 Generic theory contexts with unique identity, arbitrarily typed data,
     6 monotonic development graph and history support.  Generic proof
     7 contexts with arbitrarily typed data.
     8 *)
     9 
    10 signature BASIC_CONTEXT =
    11 sig
    12   type theory
    13   type theory_ref
    14   exception THEORY of string * theory list
    15 end;
    16 
    17 signature CONTEXT =
    18 sig
    19   include BASIC_CONTEXT
    20   (*theory context*)
    21   val theory_name: theory -> string
    22   val parents_of: theory -> theory list
    23   val ancestors_of: theory -> theory list
    24   val is_stale: theory -> bool
    25   val PureN: string
    26   val is_draft: theory -> bool
    27   val exists_name: string -> theory -> bool
    28   val names_of: theory -> string list
    29   val pretty_thy: theory -> Pretty.T
    30   val string_of_thy: theory -> string
    31   val pprint_thy: theory -> pprint_args -> unit
    32   val pprint_thy_ref: theory_ref -> pprint_args -> unit
    33   val pretty_abbrev_thy: theory -> Pretty.T
    34   val str_of_thy: theory -> string
    35   val deref: theory_ref -> theory
    36   val check_thy: theory -> theory_ref
    37   val eq_thy: theory * theory -> bool
    38   val subthy: theory * theory -> bool
    39   val joinable: theory * theory -> bool
    40   val merge: theory * theory -> theory
    41   val merge_refs: theory_ref * theory_ref -> theory_ref
    42   val copy_thy: theory -> theory
    43   val checkpoint_thy: theory -> theory
    44   val finish_thy: theory -> theory
    45   val begin_thy: (theory -> Pretty.pp) -> string -> theory list -> theory
    46   (*proof context*)
    47   type proof
    48   val theory_of_proof: proof -> theory
    49   val transfer_proof: theory -> proof -> proof
    50   val init_proof: theory -> proof
    51   (*generic context*)
    52   datatype generic = Theory of theory | Proof of proof
    53   val cases: (theory -> 'a) -> (proof -> 'a) -> generic -> 'a
    54   val mapping: (theory -> theory) -> (proof -> proof) -> generic -> generic
    55   val mapping_result: (theory -> 'a * theory) -> (proof -> 'a * proof) -> generic -> 'a * generic
    56   val the_theory: generic -> theory
    57   val the_proof: generic -> proof
    58   val map_theory: (theory -> theory) -> generic -> generic
    59   val map_proof: (proof -> proof) -> generic -> generic
    60   val map_theory_result: (theory -> 'a * theory) -> generic -> 'a * generic
    61   val map_proof_result: (proof -> 'a * proof) -> generic -> 'a * generic
    62   val theory_map: (generic -> generic) -> theory -> theory
    63   val proof_map: (generic -> generic) -> proof -> proof
    64   val theory_of: generic -> theory   (*total*)
    65   val proof_of: generic -> proof     (*total*)
    66   (*thread data*)
    67   val thread_data: unit -> generic option
    68   val the_thread_data: unit -> generic
    69   val set_thread_data: generic option -> unit
    70   val setmp_thread_data: generic option -> ('a -> 'b) -> 'a -> 'b
    71   val >> : (generic -> generic) -> unit
    72   val >>> : (generic -> 'a * generic) -> 'a
    73 end;
    74 
    75 signature PRIVATE_CONTEXT =
    76 sig
    77   include CONTEXT
    78   structure TheoryData:
    79   sig
    80     val declare: Object.T -> (Object.T -> Object.T) -> (Object.T -> Object.T) ->
    81       (Pretty.pp -> Object.T * Object.T -> Object.T) -> serial
    82     val get: serial -> (Object.T -> 'a) -> theory -> 'a
    83     val put: serial -> ('a -> Object.T) -> 'a -> theory -> theory
    84   end
    85   structure ProofData:
    86   sig
    87     val declare: (theory -> Object.T) -> serial
    88     val get: serial -> (Object.T -> 'a) -> proof -> 'a
    89     val put: serial -> ('a -> Object.T) -> 'a -> proof -> proof
    90   end
    91 end;
    92 
    93 structure Context: PRIVATE_CONTEXT =
    94 struct
    95 
    96 (*** theory context ***)
    97 
    98 (** theory data **)
    99 
   100 (* data kinds and access methods *)
   101 
   102 (*private copy avoids potential conflict of table exceptions*)
   103 structure Datatab = TableFun(type key = int val ord = int_ord);
   104 
   105 local
   106 
   107 type kind =
   108  {empty: Object.T,
   109   copy: Object.T -> Object.T,
   110   extend: Object.T -> Object.T,
   111   merge: Pretty.pp -> Object.T * Object.T -> Object.T};
   112 
   113 val kinds = ref (Datatab.empty: kind Datatab.table);
   114 
   115 fun invoke f k =
   116   (case Datatab.lookup (! kinds) k of
   117     SOME kind => f kind
   118   | NONE => sys_error "Invalid theory data identifier");
   119 
   120 in
   121 
   122 fun invoke_empty k   = invoke (K o #empty) k ();
   123 val invoke_copy      = invoke #copy;
   124 val invoke_extend    = invoke #extend;
   125 fun invoke_merge pp  = invoke (fn kind => #merge kind pp);
   126 
   127 fun declare_theory_data empty copy extend merge =
   128   let
   129     val k = serial ();
   130     val kind = {empty = empty, copy = copy, extend = extend, merge = merge};
   131     val _ = CRITICAL (fn () => change kinds (Datatab.update (k, kind)));
   132   in k end;
   133 
   134 val copy_data = Datatab.map' invoke_copy;
   135 val extend_data = Datatab.map' invoke_extend;
   136 fun merge_data pp = Datatab.join (invoke_merge pp) o pairself extend_data;
   137 
   138 end;
   139 
   140 
   141 
   142 (** datatype theory **)
   143 
   144 datatype theory =
   145   Theory of
   146    (*identity*)
   147    {self: theory ref option,            (*dynamic self reference -- follows theory changes*)
   148     id: serial * string,                (*identifier of this theory*)
   149     ids: string Inttab.table,           (*identifiers of ancestors*)
   150     iids: string Inttab.table} *        (*identifiers of intermediate checkpoints*)
   151    (*data*)
   152    Object.T Datatab.table *
   153    (*ancestry*)
   154    {parents: theory list,               (*immediate predecessors*)
   155     ancestors: theory list} *           (*all predecessors*)
   156    (*history*)
   157    {name: string,                       (*prospective name of finished theory*)
   158     version: int,                       (*checkpoint counter*)
   159     intermediates: theory list};        (*intermediate checkpoints*)
   160 
   161 exception THEORY of string * theory list;
   162 
   163 fun rep_theory (Theory args) = args;
   164 
   165 val identity_of = #1 o rep_theory;
   166 val data_of     = #2 o rep_theory;
   167 val ancestry_of = #3 o rep_theory;
   168 val history_of  = #4 o rep_theory;
   169 
   170 fun make_identity self id ids iids = {self = self, id = id, ids = ids, iids = iids};
   171 fun make_ancestry parents ancestors = {parents = parents, ancestors = ancestors};
   172 fun make_history name vers ints = {name = name, version = vers, intermediates = ints};
   173 
   174 val the_self = the o #self o identity_of;
   175 val parents_of = #parents o ancestry_of;
   176 val ancestors_of = #ancestors o ancestry_of;
   177 val theory_name = #name o history_of;
   178 
   179 
   180 (* staleness *)
   181 
   182 fun eq_id ((i: int, _), (j, _)) = (i = j);
   183 
   184 fun is_stale
   185     (Theory ({self = SOME (ref (Theory ({id = id', ...}, _, _, _))), id, ...}, _, _, _)) =
   186       not (eq_id (id, id'))
   187   | is_stale (Theory ({self = NONE, ...}, _, _, _)) = true;
   188 
   189 fun vitalize (thy as Theory ({self = SOME r, ...}, _, _, _)) = (r := thy; thy)
   190   | vitalize (thy as Theory ({self = NONE, id, ids, iids}, data, ancestry, history)) =
   191       let
   192         val r = ref thy;
   193         val thy' = Theory (make_identity (SOME r) id ids iids, data, ancestry, history);
   194       in r := thy'; thy' end;
   195 
   196 
   197 (* names *)
   198 
   199 val PureN = "Pure";
   200 
   201 val draftN = "#";
   202 fun draft_id (_, name) = (name = draftN);
   203 val is_draft = draft_id o #id o identity_of;
   204 
   205 fun exists_name name (thy as Theory ({id, ids, iids, ...}, _, _, _)) =
   206   name = theory_name thy orelse
   207   name = #2 id orelse
   208   Inttab.exists (equal name o #2) ids orelse
   209   Inttab.exists (equal name o #2) iids;
   210 
   211 fun names_of (Theory ({id, ids, ...}, _, _, _)) =
   212   rev (#2 id :: Inttab.fold (cons o #2) ids []);
   213 
   214 fun pretty_thy thy =
   215   Pretty.str_list "{" "}" (names_of thy @ (if is_stale thy then ["!"] else []));
   216 
   217 val string_of_thy = Pretty.string_of o pretty_thy;
   218 val pprint_thy = Pretty.pprint o pretty_thy;
   219 
   220 fun pretty_abbrev_thy thy =
   221   let
   222     val names = names_of thy;
   223     val n = length names;
   224     val abbrev = if n > 5 then "..." :: List.drop (names, n - 5) else names;
   225   in Pretty.str_list "{" "}" abbrev end;
   226 
   227 val str_of_thy = Pretty.str_of o pretty_abbrev_thy;
   228 
   229 
   230 (* theory references *)
   231 
   232 (*theory_ref provides a safe way to store dynamic references to a
   233   theory in external data structures -- a plain theory value would
   234   become stale as the self reference moves on*)
   235 
   236 datatype theory_ref = TheoryRef of theory ref;
   237 
   238 fun deref (TheoryRef (ref thy)) = thy;
   239 
   240 fun check_thy thy =  (*thread-safe version*)
   241   let val thy_ref = TheoryRef (the_self thy) in
   242     if is_stale thy then error ("Stale theory encountered:\n" ^ string_of_thy thy)
   243     else thy_ref
   244   end;
   245 
   246 val pprint_thy_ref = Pretty.pprint o pretty_thy o deref;
   247 
   248 
   249 (* consistency *)
   250 
   251 fun check_ins id ids =
   252   if draft_id id orelse Inttab.defined ids (#1 id) then ids
   253   else if Inttab.exists (equal (#2 id) o #2) ids then
   254     error ("Different versions of theory component " ^ quote (#2 id))
   255   else Inttab.update id ids;
   256 
   257 fun check_insert intermediate id (ids, iids) =
   258   let val ids' = check_ins id ids and iids' = check_ins id iids
   259   in if intermediate then (ids, iids') else (ids', iids) end;
   260 
   261 fun check_merge
   262     (Theory ({id = id1, ids = ids1, iids = iids1, ...}, _, _, history1))
   263     (Theory ({id = id2, ids = ids2, iids = iids2, ...}, _, _, history2)) =
   264   (Inttab.fold check_ins ids2 ids1, Inttab.fold check_ins iids2 iids1)
   265   |> check_insert (#version history1 > 0) id1
   266   |> check_insert (#version history2 > 0) id2;
   267 
   268 
   269 (* equality and inclusion *)
   270 
   271 val eq_thy = eq_id o pairself (#id o identity_of);
   272 
   273 fun proper_subthy
   274     (Theory ({id = (i, _), ...}, _, _, _), Theory ({ids, iids, ...}, _, _, _)) =
   275   Inttab.defined ids i orelse Inttab.defined iids i;
   276 
   277 fun subthy thys = eq_thy thys orelse proper_subthy thys;
   278 
   279 fun joinable (thy1, thy2) = subthy (thy1, thy2) orelse subthy (thy2, thy1);
   280 
   281 
   282 (* trivial merge *)
   283 
   284 fun merge (thy1, thy2) =
   285   if eq_thy (thy1, thy2) then thy1
   286   else if proper_subthy (thy2, thy1) then thy1
   287   else if proper_subthy (thy1, thy2) then thy2
   288   else (check_merge thy1 thy2;
   289     error (cat_lines ["Attempt to perform non-trivial merge of theories:",
   290       str_of_thy thy1, str_of_thy thy2]));
   291 
   292 fun merge_refs (ref1, ref2) =
   293   if ref1 = ref2 then ref1
   294   else check_thy (merge (deref ref1, deref ref2));
   295 
   296 
   297 
   298 (** build theories **)
   299 
   300 (* primitives *)
   301 
   302 fun create_thy name self id ids iids data ancestry history =
   303   let
   304     val {version, name = _, intermediates = _} = history;
   305     val intermediate = version > 0;
   306     val (ids', iids') = check_insert intermediate id (ids, iids);
   307     val id' = (serial (), name);
   308     val _ = check_insert intermediate id' (ids', iids');
   309     val identity' = make_identity self id' ids' iids';
   310   in vitalize (Theory (identity', data, ancestry, history)) end;
   311 
   312 fun change_thy name f thy =
   313   let
   314     val Theory ({self, id, ids, iids}, data, ancestry, history) = thy;
   315     val (self', data', ancestry') =
   316       if is_draft thy then (self, data, ancestry)    (*destructive change!*)
   317       else if #version history > 0
   318       then (NONE, copy_data data, ancestry)
   319       else (NONE, extend_data data, make_ancestry [thy] (thy :: #ancestors ancestry));
   320     val data'' = f data';
   321     val thy' = NAMED_CRITICAL "theory" (fn () =>
   322       (check_thy thy; create_thy name self' id ids iids data'' ancestry' history));
   323   in thy' end;
   324 
   325 fun name_thy name = change_thy name I;
   326 val modify_thy = change_thy draftN;
   327 val extend_thy = modify_thy I;
   328 
   329 fun copy_thy thy =
   330   let
   331     val Theory ({id, ids, iids, ...}, data, ancestry, history) = thy;
   332     val data' = copy_data data;
   333     val thy' = NAMED_CRITICAL "theory" (fn () =>
   334       (check_thy thy; create_thy draftN NONE id ids iids data' ancestry history));
   335   in thy' end;
   336 
   337 val pre_pure_thy = create_thy draftN NONE (serial (), draftN) Inttab.empty Inttab.empty
   338   Datatab.empty (make_ancestry [] []) (make_history PureN 0 []);
   339 
   340 
   341 (* named theory nodes *)
   342 
   343 fun merge_thys pp (thy1, thy2) =
   344   let
   345     val (ids, iids) = check_merge thy1 thy2;
   346     val data = merge_data (pp thy1) (data_of thy1, data_of thy2);
   347     val ancestry = make_ancestry [] [];
   348     val history = make_history "" 0 [];
   349     val thy' = NAMED_CRITICAL "theory" (fn () =>
   350      (check_thy thy1; check_thy thy2;
   351       create_thy draftN NONE (serial (), draftN) ids iids data ancestry history))
   352   in thy' end;
   353 
   354 fun maximal_thys thys =
   355   thys |> filter (fn thy => not (exists (fn thy' => proper_subthy (thy, thy')) thys));
   356 
   357 fun begin_thy pp name imports =
   358   if name = draftN then error ("Illegal theory name: " ^ quote draftN)
   359   else
   360     let
   361       val parents = maximal_thys (distinct eq_thy imports);
   362       val ancestors = distinct eq_thy (parents @ maps ancestors_of parents);
   363       val Theory ({id, ids, iids, ...}, data, _, _) =
   364         (case parents of
   365           [] => error "No parent theories"
   366         | [thy] => extend_thy thy
   367         | thy :: thys => Library.foldl (merge_thys pp) (thy, thys));
   368       val ancestry = make_ancestry parents ancestors;
   369       val history = make_history name 0 [];
   370       val thy' = NAMED_CRITICAL "theory" (fn () =>
   371         (map check_thy imports; create_thy draftN NONE id ids iids data ancestry history));
   372     in thy' end;
   373 
   374 
   375 (* undoable checkpoints *)
   376 
   377 fun checkpoint_thy thy =
   378   if not (is_draft thy) then thy
   379   else
   380     let
   381       val {name, version, intermediates} = history_of thy;
   382       val thy' as Theory (identity', data', ancestry', _) =
   383         name_thy (name ^ ":" ^ string_of_int version) thy;
   384       val history' = make_history name (version + 1) (thy' :: intermediates);
   385       val thy'' = NAMED_CRITICAL "theory" (fn () =>
   386         (check_thy thy'; vitalize (Theory (identity', data', ancestry', history'))));
   387     in thy'' end;
   388 
   389 fun finish_thy thy = NAMED_CRITICAL "theory" (fn () =>
   390   let
   391     val {name, version, intermediates} = history_of thy;
   392     val rs = map ((fn TheoryRef r => r) o check_thy) intermediates;
   393     val thy' as Theory ({self, id, ids, ...}, data', ancestry', _) = name_thy name thy;
   394     val identity' = make_identity self id ids Inttab.empty;
   395     val history' = make_history name 0 [];
   396     val thy'' = vitalize (Theory (identity', data', ancestry', history'));
   397     val _ = List.app (fn r => r := thy'') rs;
   398   in thy'' end);
   399 
   400 
   401 (* theory data *)
   402 
   403 structure TheoryData =
   404 struct
   405 
   406 val declare = declare_theory_data;
   407 
   408 fun get k dest thy =
   409   dest ((case Datatab.lookup (data_of thy) k of
   410     SOME x => x
   411   | NONE => invoke_copy k (invoke_empty k)));   (*adhoc value*)
   412 
   413 fun put k mk x = modify_thy (Datatab.update (k, mk x));
   414 
   415 end;
   416 
   417 
   418 
   419 (*** proof context ***)
   420 
   421 (* datatype proof *)
   422 
   423 datatype proof = Prf of Object.T Datatab.table * theory_ref;
   424 
   425 fun theory_of_proof (Prf (_, thy_ref)) = deref thy_ref;
   426 fun data_of_proof (Prf (data, _)) = data;
   427 fun map_prf f (Prf (data, thy_ref)) = Prf (f data, thy_ref);
   428 
   429 
   430 (* proof data kinds *)
   431 
   432 local
   433 
   434 val kinds = ref (Datatab.empty: (theory -> Object.T) Datatab.table);
   435 
   436 fun invoke_init k =
   437   (case Datatab.lookup (! kinds) k of
   438     SOME init => init
   439   | NONE => sys_error "Invalid proof data identifier");
   440 
   441 fun init_data thy =
   442   Datatab.map' (fn k => fn _ => invoke_init k thy) (! kinds);
   443 
   444 fun init_new_data data thy =
   445   Datatab.merge (K true) (data, init_data thy);
   446 
   447 in
   448 
   449 fun init_proof thy = Prf (init_data thy, check_thy thy);
   450 
   451 fun transfer_proof thy' (prf as Prf (data, thy_ref)) =
   452   let
   453     val thy = deref thy_ref;
   454     val _ = subthy (thy, thy') orelse error "transfer proof context: not a super theory";
   455     val _ = check_thy thy;
   456     val data' = init_new_data data thy';
   457     val thy_ref' = check_thy thy';
   458   in Prf (data', thy_ref') end;
   459 
   460 
   461 structure ProofData =
   462 struct
   463 
   464 fun declare init =
   465   let
   466     val k = serial ();
   467     val _ = CRITICAL (fn () => change kinds (Datatab.update (k, init)));
   468   in k end;
   469 
   470 fun get k dest prf =
   471   dest (case Datatab.lookup (data_of_proof prf) k of
   472     SOME x => x
   473   | NONE => invoke_init k (theory_of_proof prf));   (*adhoc value*)
   474 
   475 fun put k mk x = map_prf (Datatab.update (k, mk x));
   476 
   477 end;
   478 
   479 end;
   480 
   481 
   482 
   483 (*** generic context ***)
   484 
   485 datatype generic = Theory of theory | Proof of proof;
   486 
   487 fun cases f _ (Theory thy) = f thy
   488   | cases _ g (Proof prf) = g prf;
   489 
   490 fun mapping f g = cases (Theory o f) (Proof o g);
   491 fun mapping_result f g = cases (apsnd Theory o f) (apsnd Proof o g);
   492 
   493 val the_theory = cases I (fn _ => error "Ill-typed context: theory expected");
   494 val the_proof = cases (fn _ => error "Ill-typed context: proof expected") I;
   495 
   496 fun map_theory f = Theory o f o the_theory;
   497 fun map_proof f = Proof o f o the_proof;
   498 
   499 fun map_theory_result f = apsnd Theory o f o the_theory;
   500 fun map_proof_result f = apsnd Proof o f o the_proof;
   501 
   502 fun theory_map f = the_theory o f o Theory;
   503 fun proof_map f = the_proof o f o Proof;
   504 
   505 val theory_of = cases I theory_of_proof;
   506 val proof_of = cases init_proof I;
   507 
   508 
   509 
   510 (** thread data **)
   511 
   512 local val tag = Universal.tag () : generic option Universal.tag in
   513 
   514 fun thread_data () =
   515   (case Multithreading.get_data tag of
   516     SOME (SOME context) => SOME context
   517   | _ => NONE);
   518 
   519 fun the_thread_data () =
   520   (case thread_data () of
   521     SOME context => context
   522   | _ => error "Unknown context");
   523 
   524 fun set_thread_data context = Multithreading.put_data (tag, context);
   525 fun setmp_thread_data context = Library.setmp_thread_data tag (thread_data ()) context;
   526 
   527 end;
   528 
   529 fun >>> f =
   530   let
   531     val (res, context') = f (the_thread_data ());
   532     val _ = set_thread_data (SOME context');
   533   in res end;
   534 
   535 nonfix >>;
   536 fun >> f = >>> (fn context => ((), f context));
   537 
   538 val _ = set_thread_data (SOME (Theory pre_pure_thy));
   539 
   540 end;
   541 
   542 structure BasicContext: BASIC_CONTEXT = Context;
   543 open BasicContext;
   544 
   545 
   546 
   547 (*** type-safe interfaces for data declarations ***)
   548 
   549 (** theory data **)
   550 
   551 signature THEORY_DATA_ARGS =
   552 sig
   553   type T
   554   val empty: T
   555   val copy: T -> T
   556   val extend: T -> T
   557   val merge: Pretty.pp -> T * T -> T
   558 end;
   559 
   560 signature THEORY_DATA =
   561 sig
   562   type T
   563   val get: theory -> T
   564   val put: T -> theory -> theory
   565   val map: (T -> T) -> theory -> theory
   566   val init: theory -> theory
   567 end;
   568 
   569 functor TheoryDataFun(Data: THEORY_DATA_ARGS): THEORY_DATA =
   570 struct
   571 
   572 structure TheoryData = Context.TheoryData;
   573 
   574 type T = Data.T;
   575 exception Data of T;
   576 
   577 val kind = TheoryData.declare
   578   (Data Data.empty)
   579   (fn Data x => Data (Data.copy x))
   580   (fn Data x => Data (Data.extend x))
   581   (fn pp => fn (Data x1, Data x2) => Data (Data.merge pp (x1, x2)));
   582 
   583 val get = TheoryData.get kind (fn Data x => x);
   584 val put = TheoryData.put kind Data;
   585 fun map f thy = put (f (get thy)) thy;
   586 
   587 fun init thy = map I thy;
   588 
   589 end;
   590 
   591 
   592 
   593 (** proof data **)
   594 
   595 signature PROOF_DATA_ARGS =
   596 sig
   597   type T
   598   val init: theory -> T
   599 end;
   600 
   601 signature PROOF_DATA =
   602 sig
   603   type T
   604   val get: Context.proof -> T
   605   val put: T -> Context.proof -> Context.proof
   606   val map: (T -> T) -> Context.proof -> Context.proof
   607 end;
   608 
   609 functor ProofDataFun(Data: PROOF_DATA_ARGS): PROOF_DATA =
   610 struct
   611 
   612 structure ProofData = Context.ProofData;
   613 
   614 type T = Data.T;
   615 exception Data of T;
   616 
   617 val kind = ProofData.declare (Data o Data.init);
   618 
   619 val get = ProofData.get kind (fn Data x => x);
   620 val put = ProofData.put kind Data;
   621 fun map f prf = put (f (get prf)) prf;
   622 
   623 end;
   624 
   625 
   626 
   627 (** generic data **)
   628 
   629 signature GENERIC_DATA_ARGS =
   630 sig
   631   type T
   632   val empty: T
   633   val extend: T -> T
   634   val merge: Pretty.pp -> T * T -> T
   635 end;
   636 
   637 signature GENERIC_DATA =
   638 sig
   639   type T
   640   val get: Context.generic -> T
   641   val put: T -> Context.generic -> Context.generic
   642   val map: (T -> T) -> Context.generic -> Context.generic
   643 end;
   644 
   645 functor GenericDataFun(Data: GENERIC_DATA_ARGS): GENERIC_DATA =
   646 struct
   647 
   648 structure ThyData = TheoryDataFun(open Data val copy = I);
   649 structure PrfData = ProofDataFun(type T = Data.T val init = ThyData.get);
   650 
   651 type T = Data.T;
   652 
   653 fun get (Context.Theory thy) = ThyData.get thy
   654   | get (Context.Proof prf) = PrfData.get prf;
   655 
   656 fun put x (Context.Theory thy) = Context.Theory (ThyData.put x thy)
   657   | put x (Context.Proof prf) = Context.Proof (PrfData.put x prf);
   658 
   659 fun map f ctxt = put (f (get ctxt)) ctxt;
   660 
   661 end;
   662 
   663 (*hide private interface*)
   664 structure Context: CONTEXT = Context;
   665 
   666 (*fake predeclarations*)
   667 structure Proof = struct type context = Context.proof end;
   668 structure ProofContext =
   669 struct val theory_of = Context.theory_of_proof val init = Context.init_proof end;