src/HOL/Code_Numeral.thy
author haftmann
Tue May 19 16:54:55 2009 +0200 (2009-05-19)
changeset 31205 98370b26c2ce
parent 31203 src/HOL/Code_Index.thy@5c8fb4fd67e0
child 31266 55e70b6d812e
permissions -rw-r--r--
String.literal replaces message_string, code_numeral replaces (code_)index
     1 (* Author: Florian Haftmann, TU Muenchen *)
     2 
     3 header {* Type of target language numerals *}
     4 
     5 theory Code_Numeral
     6 imports Nat_Numeral
     7 begin
     8 
     9 text {*
    10   Code numerals are isomorphic to HOL @{typ nat} but
    11   mapped to target-language builtin numerals.
    12 *}
    13 
    14 subsection {* Datatype of target language numerals *}
    15 
    16 typedef (open) code_numeral = "UNIV \<Colon> nat set"
    17   morphisms nat_of of_nat by rule
    18 
    19 lemma of_nat_nat_of [simp]:
    20   "of_nat (nat_of k) = k"
    21   by (rule nat_of_inverse)
    22 
    23 lemma nat_of_of_nat [simp]:
    24   "nat_of (of_nat n) = n"
    25   by (rule of_nat_inverse) (rule UNIV_I)
    26 
    27 lemma [measure_function]:
    28   "is_measure nat_of" by (rule is_measure_trivial)
    29 
    30 lemma code_numeral:
    31   "(\<And>n\<Colon>code_numeral. PROP P n) \<equiv> (\<And>n\<Colon>nat. PROP P (of_nat n))"
    32 proof
    33   fix n :: nat
    34   assume "\<And>n\<Colon>code_numeral. PROP P n"
    35   then show "PROP P (of_nat n)" .
    36 next
    37   fix n :: code_numeral
    38   assume "\<And>n\<Colon>nat. PROP P (of_nat n)"
    39   then have "PROP P (of_nat (nat_of n))" .
    40   then show "PROP P n" by simp
    41 qed
    42 
    43 lemma code_numeral_case:
    44   assumes "\<And>n. k = of_nat n \<Longrightarrow> P"
    45   shows P
    46   by (rule assms [of "nat_of k"]) simp
    47 
    48 lemma code_numeral_induct_raw:
    49   assumes "\<And>n. P (of_nat n)"
    50   shows "P k"
    51 proof -
    52   from assms have "P (of_nat (nat_of k))" .
    53   then show ?thesis by simp
    54 qed
    55 
    56 lemma nat_of_inject [simp]:
    57   "nat_of k = nat_of l \<longleftrightarrow> k = l"
    58   by (rule nat_of_inject)
    59 
    60 lemma of_nat_inject [simp]:
    61   "of_nat n = of_nat m \<longleftrightarrow> n = m"
    62   by (rule of_nat_inject) (rule UNIV_I)+
    63 
    64 instantiation code_numeral :: zero
    65 begin
    66 
    67 definition [simp, code del]:
    68   "0 = of_nat 0"
    69 
    70 instance ..
    71 
    72 end
    73 
    74 definition [simp]:
    75   "Suc_code_numeral k = of_nat (Suc (nat_of k))"
    76 
    77 rep_datatype "0 \<Colon> code_numeral" Suc_code_numeral
    78 proof -
    79   fix P :: "code_numeral \<Rightarrow> bool"
    80   fix k :: code_numeral
    81   assume "P 0" then have init: "P (of_nat 0)" by simp
    82   assume "\<And>k. P k \<Longrightarrow> P (Suc_code_numeral k)"
    83     then have "\<And>n. P (of_nat n) \<Longrightarrow> P (Suc_code_numeral (of_nat n))" .
    84     then have step: "\<And>n. P (of_nat n) \<Longrightarrow> P (of_nat (Suc n))" by simp
    85   from init step have "P (of_nat (nat_of k))"
    86     by (induct "nat_of k") simp_all
    87   then show "P k" by simp
    88 qed simp_all
    89 
    90 declare code_numeral_case [case_names nat, cases type: code_numeral]
    91 declare code_numeral.induct [case_names nat, induct type: code_numeral]
    92 
    93 lemma code_numeral_decr [termination_simp]:
    94   "k \<noteq> of_nat 0 \<Longrightarrow> nat_of k - Suc 0 < nat_of k"
    95   by (cases k) simp
    96 
    97 lemma [simp, code]:
    98   "code_numeral_size = nat_of"
    99 proof (rule ext)
   100   fix k
   101   have "code_numeral_size k = nat_size (nat_of k)"
   102     by (induct k rule: code_numeral.induct) (simp_all del: zero_code_numeral_def Suc_code_numeral_def, simp_all)
   103   also have "nat_size (nat_of k) = nat_of k" by (induct "nat_of k") simp_all
   104   finally show "code_numeral_size k = nat_of k" .
   105 qed
   106 
   107 lemma [simp, code]:
   108   "size = nat_of"
   109 proof (rule ext)
   110   fix k
   111   show "size k = nat_of k"
   112   by (induct k) (simp_all del: zero_code_numeral_def Suc_code_numeral_def, simp_all)
   113 qed
   114 
   115 lemmas [code del] = code_numeral.recs code_numeral.cases
   116 
   117 lemma [code]:
   118   "eq_class.eq k l \<longleftrightarrow> eq_class.eq (nat_of k) (nat_of l)"
   119   by (cases k, cases l) (simp add: eq)
   120 
   121 lemma [code nbe]:
   122   "eq_class.eq (k::code_numeral) k \<longleftrightarrow> True"
   123   by (rule HOL.eq_refl)
   124 
   125 
   126 subsection {* Indices as datatype of ints *}
   127 
   128 instantiation code_numeral :: number
   129 begin
   130 
   131 definition
   132   "number_of = of_nat o nat"
   133 
   134 instance ..
   135 
   136 end
   137 
   138 lemma nat_of_number [simp]:
   139   "nat_of (number_of k) = number_of k"
   140   by (simp add: number_of_code_numeral_def nat_number_of_def number_of_is_id)
   141 
   142 code_datatype "number_of \<Colon> int \<Rightarrow> code_numeral"
   143 
   144 
   145 subsection {* Basic arithmetic *}
   146 
   147 instantiation code_numeral :: "{minus, ordered_semidom, semiring_div, linorder}"
   148 begin
   149 
   150 definition [simp, code del]:
   151   "(1\<Colon>code_numeral) = of_nat 1"
   152 
   153 definition [simp, code del]:
   154   "n + m = of_nat (nat_of n + nat_of m)"
   155 
   156 definition [simp, code del]:
   157   "n - m = of_nat (nat_of n - nat_of m)"
   158 
   159 definition [simp, code del]:
   160   "n * m = of_nat (nat_of n * nat_of m)"
   161 
   162 definition [simp, code del]:
   163   "n div m = of_nat (nat_of n div nat_of m)"
   164 
   165 definition [simp, code del]:
   166   "n mod m = of_nat (nat_of n mod nat_of m)"
   167 
   168 definition [simp, code del]:
   169   "n \<le> m \<longleftrightarrow> nat_of n \<le> nat_of m"
   170 
   171 definition [simp, code del]:
   172   "n < m \<longleftrightarrow> nat_of n < nat_of m"
   173 
   174 instance proof
   175 qed (auto simp add: code_numeral left_distrib div_mult_self1)
   176 
   177 end
   178 
   179 lemma zero_code_numeral_code [code inline, code]:
   180   "(0\<Colon>code_numeral) = Numeral0"
   181   by (simp add: number_of_code_numeral_def Pls_def)
   182 lemma [code post]: "Numeral0 = (0\<Colon>code_numeral)"
   183   using zero_code_numeral_code ..
   184 
   185 lemma one_code_numeral_code [code inline, code]:
   186   "(1\<Colon>code_numeral) = Numeral1"
   187   by (simp add: number_of_code_numeral_def Pls_def Bit1_def)
   188 lemma [code post]: "Numeral1 = (1\<Colon>code_numeral)"
   189   using one_code_numeral_code ..
   190 
   191 lemma plus_code_numeral_code [code nbe]:
   192   "of_nat n + of_nat m = of_nat (n + m)"
   193   by simp
   194 
   195 definition subtract_code_numeral :: "code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral" where
   196   [simp, code del]: "subtract_code_numeral = op -"
   197 
   198 lemma subtract_code_numeral_code [code nbe]:
   199   "subtract_code_numeral (of_nat n) (of_nat m) = of_nat (n - m)"
   200   by simp
   201 
   202 lemma minus_code_numeral_code [code]:
   203   "n - m = subtract_code_numeral n m"
   204   by simp
   205 
   206 lemma times_code_numeral_code [code nbe]:
   207   "of_nat n * of_nat m = of_nat (n * m)"
   208   by simp
   209 
   210 lemma less_eq_code_numeral_code [code nbe]:
   211   "of_nat n \<le> of_nat m \<longleftrightarrow> n \<le> m"
   212   by simp
   213 
   214 lemma less_code_numeral_code [code nbe]:
   215   "of_nat n < of_nat m \<longleftrightarrow> n < m"
   216   by simp
   217 
   218 lemma Suc_code_numeral_minus_one: "Suc_code_numeral n - 1 = n" by simp
   219 
   220 lemma of_nat_code [code]:
   221   "of_nat = Nat.of_nat"
   222 proof
   223   fix n :: nat
   224   have "Nat.of_nat n = of_nat n"
   225     by (induct n) simp_all
   226   then show "of_nat n = Nat.of_nat n"
   227     by (rule sym)
   228 qed
   229 
   230 lemma code_numeral_not_eq_zero: "i \<noteq> of_nat 0 \<longleftrightarrow> i \<ge> 1"
   231   by (cases i) auto
   232 
   233 definition nat_of_aux :: "code_numeral \<Rightarrow> nat \<Rightarrow> nat" where
   234   "nat_of_aux i n = nat_of i + n"
   235 
   236 lemma nat_of_aux_code [code]:
   237   "nat_of_aux i n = (if i = 0 then n else nat_of_aux (i - 1) (Suc n))"
   238   by (auto simp add: nat_of_aux_def code_numeral_not_eq_zero)
   239 
   240 lemma nat_of_code [code]:
   241   "nat_of i = nat_of_aux i 0"
   242   by (simp add: nat_of_aux_def)
   243 
   244 definition div_mod_code_numeral ::  "code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral \<times> code_numeral" where
   245   [code del]: "div_mod_code_numeral n m = (n div m, n mod m)"
   246 
   247 lemma [code]:
   248   "div_mod_code_numeral n m = (if m = 0 then (0, n) else (n div m, n mod m))"
   249   unfolding div_mod_code_numeral_def by auto
   250 
   251 lemma [code]:
   252   "n div m = fst (div_mod_code_numeral n m)"
   253   unfolding div_mod_code_numeral_def by simp
   254 
   255 lemma [code]:
   256   "n mod m = snd (div_mod_code_numeral n m)"
   257   unfolding div_mod_code_numeral_def by simp
   258 
   259 definition int_of :: "code_numeral \<Rightarrow> int" where
   260   "int_of = Nat.of_nat o nat_of"
   261 
   262 lemma int_of_code [code]:
   263   "int_of k = (if k = 0 then 0
   264     else (if k mod 2 = 0 then 2 * int_of (k div 2) else 2 * int_of (k div 2) + 1))"
   265   by (auto simp add: int_of_def mod_div_equality')
   266 
   267 hide (open) const of_nat nat_of int_of
   268 
   269 
   270 subsection {* Code generator setup *}
   271 
   272 text {* Implementation of indices by bounded integers *}
   273 
   274 code_type code_numeral
   275   (SML "int")
   276   (OCaml "int")
   277   (Haskell "Int")
   278 
   279 code_instance code_numeral :: eq
   280   (Haskell -)
   281 
   282 setup {*
   283   fold (Numeral.add_code @{const_name number_code_numeral_inst.number_of_code_numeral}
   284     false false) ["SML", "OCaml", "Haskell"]
   285 *}
   286 
   287 code_reserved SML Int int
   288 code_reserved OCaml Pervasives int
   289 
   290 code_const "op + \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral"
   291   (SML "Int.+/ ((_),/ (_))")
   292   (OCaml "Pervasives.( + )")
   293   (Haskell infixl 6 "+")
   294 
   295 code_const "subtract_code_numeral \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral"
   296   (SML "Int.max/ (_/ -/ _,/ 0 : int)")
   297   (OCaml "Pervasives.max/ (_/ -/ _)/ (0 : int) ")
   298   (Haskell "max/ (_/ -/ _)/ (0 :: Int)")
   299 
   300 code_const "op * \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> code_numeral"
   301   (SML "Int.*/ ((_),/ (_))")
   302   (OCaml "Pervasives.( * )")
   303   (Haskell infixl 7 "*")
   304 
   305 code_const div_mod_code_numeral
   306   (SML "(fn n => fn m =>/ if m = 0/ then (0, n) else/ (n div m, n mod m))")
   307   (OCaml "(fun n -> fun m ->/ if m = 0/ then (0, n) else/ (n '/ m, n mod m))")
   308   (Haskell "divMod")
   309 
   310 code_const "eq_class.eq \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> bool"
   311   (SML "!((_ : Int.int) = _)")
   312   (OCaml "!((_ : int) = _)")
   313   (Haskell infixl 4 "==")
   314 
   315 code_const "op \<le> \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> bool"
   316   (SML "Int.<=/ ((_),/ (_))")
   317   (OCaml "!((_ : int) <= _)")
   318   (Haskell infix 4 "<=")
   319 
   320 code_const "op < \<Colon> code_numeral \<Rightarrow> code_numeral \<Rightarrow> bool"
   321   (SML "Int.</ ((_),/ (_))")
   322   (OCaml "!((_ : int) < _)")
   323   (Haskell infix 4 "<")
   324 
   325 end