src/Pure/theory.ML
author wenzelm
Thu Sep 20 20:56:34 2007 +0200 (2007-09-20)
changeset 24666 9885a86f14a8
parent 24626 85eceef2edc7
child 24708 d9b00117365e
permissions -rw-r--r--
tuned signature;
moved generic interpretation to interpretation.ML;
added abstract at_begin/end wrappers;
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 Logical theory content: axioms, definitions, oracles.
     6 *)
     7 
     8 signature BASIC_THEORY =
     9 sig
    10   val eq_thy: theory * theory -> bool
    11   val subthy: theory * theory -> bool
    12 end
    13 
    14 signature THEORY =
    15 sig
    16   include BASIC_THEORY
    17   include SIGN_THEORY
    18   val assert_super: theory -> theory -> theory
    19   val parents_of: theory -> theory list
    20   val ancestors_of: theory -> theory list
    21   val check_thy: theory -> theory_ref
    22   val deref: theory_ref -> theory
    23   val merge: theory * theory -> theory
    24   val merge_refs: theory_ref * theory_ref -> theory_ref
    25   val merge_list: theory list -> theory
    26   val checkpoint: theory -> theory
    27   val copy: theory -> theory
    28   val requires: theory -> string -> string -> unit
    29   val axiom_space: theory -> NameSpace.T
    30   val axiom_table: theory -> term Symtab.table
    31   val oracle_space: theory -> NameSpace.T
    32   val oracle_table: theory -> ((theory * Object.T -> term) * stamp) Symtab.table
    33   val axioms_of: theory -> (string * term) list
    34   val all_axioms_of: theory -> (string * term) list
    35   val defs_of: theory -> Defs.T
    36   val at_begin: (theory -> theory option) -> theory -> theory
    37   val at_end: (theory -> theory option) -> theory -> theory
    38   val begin_theory: string -> theory list -> theory
    39   val end_theory: theory -> theory
    40   val cert_axm: theory -> string * term -> string * term
    41   val read_axm: theory -> string * string -> string * term
    42   val add_axioms: (bstring * string) list -> theory -> theory
    43   val add_axioms_i: (bstring * term) list -> theory -> theory
    44   val add_deps: string -> string * typ -> (string * typ) list -> theory -> theory
    45   val add_defs: bool -> bool -> (bstring * string) list -> theory -> theory
    46   val add_defs_i: bool -> bool -> (bstring * term) list -> theory -> theory
    47   val add_finals: bool -> string list -> theory -> theory
    48   val add_finals_i: bool -> term list -> theory -> theory
    49   val add_oracle: bstring * (theory * Object.T -> term) -> theory -> theory
    50 end
    51 
    52 structure Theory: THEORY =
    53 struct
    54 
    55 
    56 (** theory context operations **)
    57 
    58 val eq_thy = Context.eq_thy;
    59 val subthy = Context.subthy;
    60 
    61 fun assert_super thy1 thy2 =
    62   if subthy (thy1, thy2) then thy2
    63   else raise THEORY ("Not a super theory", [thy1, thy2]);
    64 
    65 val parents_of = Context.parents_of;
    66 val ancestors_of = Context.ancestors_of;
    67 
    68 val check_thy = Context.check_thy;
    69 val deref = Context.deref;
    70 
    71 val merge = Context.merge;
    72 val merge_refs = Context.merge_refs;
    73 
    74 fun merge_list [] = raise THEORY ("Empty merge of theories", [])
    75   | merge_list (thy :: thys) = Library.foldl merge (thy, thys);
    76 
    77 val checkpoint = Context.checkpoint_thy;
    78 val copy = Context.copy_thy;
    79 
    80 fun requires thy name what =
    81   if Context.exists_name name thy then ()
    82   else error ("Require theory " ^ quote name ^ " as an ancestor for " ^ what);
    83 
    84 
    85 
    86 (** theory wrappers **)
    87 
    88 type wrapper = (theory -> theory option) * stamp;
    89 
    90 fun apply_wrappers (wrappers: wrapper list) =
    91   let
    92     fun app [] res = res
    93       | app ((f, _) :: fs) (changed, thy) =
    94           (case f thy of
    95             NONE => app fs (changed, thy)
    96           | SOME thy' => app fs (true, thy'));
    97     fun app_fixpoint thy =
    98       (case app wrappers (false, thy) of
    99         (false, _) => thy
   100       | (true, thy') => app_fixpoint thy');
   101   in app_fixpoint end;
   102 
   103 
   104 
   105 (** datatype thy **)
   106 
   107 datatype thy = Thy of
   108  {axioms: term NameSpace.table,
   109   defs: Defs.T,
   110   oracles: ((theory * Object.T -> term) * stamp) NameSpace.table,
   111   wrappers: wrapper list * wrapper list};
   112 
   113 fun make_thy (axioms, defs, oracles, wrappers) =
   114   Thy {axioms = axioms, defs = defs, oracles = oracles, wrappers = wrappers};
   115 
   116 fun err_dup_axm dup = error ("Duplicate axiom: " ^ quote dup);
   117 fun err_dup_ora dup = error ("Duplicate oracle: " ^ quote dup);
   118 
   119 structure ThyData = TheoryDataFun
   120 (
   121   type T = thy;
   122   val empty = make_thy (NameSpace.empty_table, Defs.empty, NameSpace.empty_table, ([], []));
   123   val copy = I;
   124 
   125   fun extend (Thy {axioms, defs, oracles, wrappers}) =
   126     make_thy (NameSpace.empty_table, defs, oracles, wrappers);
   127 
   128   fun merge pp (thy1, thy2) =
   129     let
   130       val Thy {axioms = _, defs = defs1, oracles = oracles1, wrappers = (bgs1, ens1)} = thy1;
   131       val Thy {axioms = _, defs = defs2, oracles = oracles2, wrappers = (bgs2, ens2)} = thy2;
   132 
   133       val axioms' = NameSpace.empty_table;
   134       val defs' = Defs.merge pp (defs1, defs2);
   135       val oracles' = NameSpace.merge_tables (eq_snd (op =)) (oracles1, oracles2)
   136         handle Symtab.DUP dup => err_dup_ora dup;
   137       val bgs' = Library.merge (eq_snd op =) (bgs1, bgs2);
   138       val ens' = Library.merge (eq_snd op =) (ens1, ens2);
   139     in make_thy (axioms', defs', oracles', (bgs', ens')) end;
   140 );
   141 
   142 fun rep_theory thy = ThyData.get thy |> (fn Thy args => args);
   143 
   144 fun map_thy f = ThyData.map (fn (Thy {axioms, defs, oracles, wrappers}) =>
   145   make_thy (f (axioms, defs, oracles, wrappers)));
   146 
   147 
   148 fun map_axioms f = map_thy
   149   (fn (axioms, defs, oracles, wrappers) => (f axioms, defs, oracles, wrappers));
   150 
   151 fun map_defs f = map_thy
   152   (fn (axioms, defs, oracles, wrappers) => (axioms, f defs, oracles, wrappers));
   153 
   154 fun map_oracles f = map_thy
   155   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, f oracles, wrappers));
   156 
   157 fun map_wrappers f = map_thy
   158   (fn (axioms, defs, oracles, wrappers) => (axioms, defs, oracles, f wrappers));
   159 
   160 
   161 (* basic operations *)
   162 
   163 val axiom_space = #1 o #axioms o rep_theory;
   164 val axiom_table = #2 o #axioms o rep_theory;
   165 
   166 val oracle_space = #1 o #oracles o rep_theory;
   167 val oracle_table = #2 o #oracles o rep_theory;
   168 
   169 val axioms_of = Symtab.dest o #2 o #axioms o rep_theory;
   170 fun all_axioms_of thy = maps axioms_of (thy :: ancestors_of thy);
   171 
   172 val defs_of = #defs o rep_theory;
   173 
   174 
   175 (* begin/end theory *)
   176 
   177 val begin_wrappers = rev o #1 o #wrappers o rep_theory;
   178 val end_wrappers = rev o #2 o #wrappers o rep_theory;
   179 
   180 fun at_begin f = map_wrappers (apfst (cons (f, stamp ())));
   181 fun at_end f = map_wrappers (apsnd (cons (f, stamp ())));
   182 
   183 fun begin_theory name imports =
   184   let
   185     val thy = Context.begin_thy Sign.pp name imports;
   186     val wrappers = begin_wrappers thy;
   187   in thy |> Sign.local_path |> apply_wrappers wrappers end;
   188 
   189 fun end_theory thy =
   190   thy |> apply_wrappers (end_wrappers thy) |> Context.finish_thy;
   191 
   192 
   193 (* signature operations *)
   194 
   195 structure SignTheory: SIGN_THEORY = Sign;
   196 open SignTheory;
   197 
   198 
   199 
   200 (** add axioms **)
   201 
   202 (* prepare axioms *)
   203 
   204 fun err_in_axm msg name =
   205   cat_error msg ("The error(s) above occurred in axiom " ^ quote name);
   206 
   207 fun cert_axm thy (name, raw_tm) =
   208   let
   209     val (t, T, _) = Sign.certify_prop thy raw_tm
   210       handle TYPE (msg, _, _) => error msg
   211         | TERM (msg, _) => error msg;
   212   in
   213     Term.no_dummy_patterns t handle TERM (msg, _) => error msg;
   214     (name, Sign.no_vars (Sign.pp thy) t)
   215   end;
   216 
   217 fun read_axm thy (name, str) =
   218   cert_axm thy (name, Sign.read_prop thy str)
   219     handle ERROR msg => err_in_axm msg name;
   220 
   221 
   222 (* add_axioms(_i) *)
   223 
   224 local
   225 
   226 fun gen_add_axioms prep_axm raw_axms thy = thy |> map_axioms (fn axioms =>
   227   let
   228     val axms = map (apsnd (Compress.term thy o Logic.varify) o prep_axm thy) raw_axms;
   229     val axioms' = NameSpace.extend_table (Sign.naming_of thy) axms axioms
   230       handle Symtab.DUP dup => err_dup_axm dup;
   231   in axioms' end);
   232 
   233 in
   234 
   235 val add_axioms = gen_add_axioms read_axm;
   236 val add_axioms_i = gen_add_axioms cert_axm;
   237 
   238 end;
   239 
   240 
   241 
   242 (** add constant definitions **)
   243 
   244 (* dependencies *)
   245 
   246 fun dependencies thy unchecked is_def name lhs rhs =
   247   let
   248     val pp = Sign.pp thy;
   249     val consts = Sign.consts_of thy;
   250     fun prep const =
   251       let val Const (c, T) = Sign.no_vars pp (Const const)
   252       in (c, Consts.typargs consts (c, Compress.typ thy (Logic.varifyT T))) end;
   253 
   254     val lhs_vars = Term.add_tfreesT (#2 lhs) [];
   255     val rhs_extras = fold (#2 #> Term.fold_atyps (fn TFree v =>
   256       if member (op =) lhs_vars v then I else insert (op =) v | _ => I)) rhs [];
   257     val _ =
   258       if null rhs_extras then ()
   259       else error ("Specification depends on extra type variables: " ^
   260         commas_quote (map (Pretty.string_of_typ pp o TFree) rhs_extras) ^
   261         "\nThe error(s) above occurred in " ^ quote name);
   262   in Defs.define pp unchecked is_def name (prep lhs) (map prep rhs) end;
   263 
   264 fun add_deps a raw_lhs raw_rhs thy =
   265   let
   266     val lhs :: rhs = map (dest_Const o Sign.cert_term thy o Const) (raw_lhs :: raw_rhs);
   267     val name = if a = "" then (#1 lhs ^ " axiom") else a;
   268   in thy |> map_defs (dependencies thy false false name lhs rhs) end;
   269 
   270 
   271 (* check_overloading *)
   272 
   273 fun check_overloading thy overloaded (c, T) =
   274   let
   275     val declT =
   276       (case Sign.const_constraint thy c of
   277         NONE => error ("Undeclared constant " ^ quote c)
   278       | SOME declT => declT);
   279     val T' = Logic.varifyT T;
   280 
   281     fun message txt =
   282       [Pretty.block [Pretty.str "Specification of constant ",
   283         Pretty.str c, Pretty.str " ::", Pretty.brk 1, Pretty.quote (Sign.pretty_typ thy T)],
   284         Pretty.str txt] |> Pretty.chunks |> Pretty.string_of;
   285   in
   286     if Sign.typ_instance thy (declT, T') then ()
   287     else if Type.raw_instance (declT, T') then
   288       error (Library.setmp show_sorts true
   289         message "imposes additional sort constraints on the constant declaration")
   290     else if overloaded then ()
   291     else warning (message "is strictly less general than the declared type");
   292     (c, T)
   293   end;
   294 
   295 
   296 (* check_def *)
   297 
   298 fun check_def thy unchecked overloaded (bname, tm) defs =
   299   let
   300     val name = Sign.full_name thy bname;
   301     val (lhs_const, rhs) = Sign.cert_def (Sign.pp thy) tm;
   302     val rhs_consts = fold_aterms (fn Const const => insert (op =) const | _ => I) rhs [];
   303     val _ = check_overloading thy overloaded lhs_const;
   304   in defs |> dependencies thy unchecked true name lhs_const rhs_consts end
   305   handle ERROR msg => cat_error msg (Pretty.string_of (Pretty.block
   306    [Pretty.str ("The error(s) above occurred in definition " ^ quote bname ^ ":"),
   307     Pretty.fbrk, Pretty.quote (Sign.pretty_term thy tm)]));
   308 
   309 
   310 (* add_defs(_i) *)
   311 
   312 local
   313 
   314 fun gen_add_defs prep_axm unchecked overloaded raw_axms thy =
   315   let val axms = map (prep_axm thy) raw_axms in
   316     thy
   317     |> map_defs (fold (check_def thy unchecked overloaded) axms)
   318     |> add_axioms_i axms
   319   end;
   320 
   321 in
   322 
   323 val add_defs_i = gen_add_defs cert_axm;
   324 val add_defs = gen_add_defs read_axm;
   325 
   326 end;
   327 
   328 
   329 (* add_finals(_i) *)
   330 
   331 local
   332 
   333 fun gen_add_finals prep_term overloaded args thy =
   334   let
   335     fun const_of (Const const) = const
   336       | const_of (Free _) = error "Attempt to finalize variable (or undeclared constant)"
   337       | const_of _ = error "Attempt to finalize non-constant term";
   338     fun specify (c, T) = dependencies thy false false (c ^ " axiom") (c, T) [];
   339     val finalize = specify o check_overloading thy overloaded o const_of o prep_term thy;
   340   in thy |> map_defs (fold finalize args) end;
   341 
   342 in
   343 
   344 val add_finals = gen_add_finals Sign.read_term;
   345 val add_finals_i = gen_add_finals Sign.cert_term;
   346 
   347 end;
   348 
   349 
   350 
   351 (** add oracle **)
   352 
   353 fun add_oracle (bname, oracle) thy = thy |> map_oracles (fn oracles =>
   354   NameSpace.extend_table (Sign.naming_of thy) [(bname, (oracle, stamp ()))] oracles
   355     handle Symtab.DUP dup => err_dup_ora dup);
   356 
   357 end;
   358 
   359 structure BasicTheory: BASIC_THEORY = Theory;
   360 open BasicTheory;