src/ZF/Constructible/WF_absolute.thy
author wenzelm
Mon Jul 29 00:57:16 2002 +0200 (2002-07-29)
changeset 13428 99e52e78eb65
parent 13418 7c0ba9dba978
child 13505 52a16cb7fefb
permissions -rw-r--r--
eliminate open locales and special ML code;
     1 header {*Absoluteness for Well-Founded Relations and Well-Founded Recursion*}
     2 
     3 theory WF_absolute = WFrec:
     4 
     5 subsection{*Every well-founded relation is a subset of some inverse image of
     6       an ordinal*}
     7 
     8 lemma wf_rvimage_Ord: "Ord(i) \<Longrightarrow> wf(rvimage(A, f, Memrel(i)))"
     9 by (blast intro: wf_rvimage wf_Memrel)
    10 
    11 
    12 constdefs
    13   wfrank :: "[i,i]=>i"
    14     "wfrank(r,a) == wfrec(r, a, %x f. \<Union>y \<in> r-``{x}. succ(f`y))"
    15 
    16 constdefs
    17   wftype :: "i=>i"
    18     "wftype(r) == \<Union>y \<in> range(r). succ(wfrank(r,y))"
    19 
    20 lemma wfrank: "wf(r) ==> wfrank(r,a) = (\<Union>y \<in> r-``{a}. succ(wfrank(r,y)))"
    21 by (subst wfrank_def [THEN def_wfrec], simp_all)
    22 
    23 lemma Ord_wfrank: "wf(r) ==> Ord(wfrank(r,a))"
    24 apply (rule_tac a=a in wf_induct, assumption)
    25 apply (subst wfrank, assumption)
    26 apply (rule Ord_succ [THEN Ord_UN], blast)
    27 done
    28 
    29 lemma wfrank_lt: "[|wf(r); <a,b> \<in> r|] ==> wfrank(r,a) < wfrank(r,b)"
    30 apply (rule_tac a1 = b in wfrank [THEN ssubst], assumption)
    31 apply (rule UN_I [THEN ltI])
    32 apply (simp add: Ord_wfrank vimage_iff)+
    33 done
    34 
    35 lemma Ord_wftype: "wf(r) ==> Ord(wftype(r))"
    36 by (simp add: wftype_def Ord_wfrank)
    37 
    38 lemma wftypeI: "\<lbrakk>wf(r);  x \<in> field(r)\<rbrakk> \<Longrightarrow> wfrank(r,x) \<in> wftype(r)"
    39 apply (simp add: wftype_def)
    40 apply (blast intro: wfrank_lt [THEN ltD])
    41 done
    42 
    43 
    44 lemma wf_imp_subset_rvimage:
    45      "[|wf(r); r \<subseteq> A*A|] ==> \<exists>i f. Ord(i) & r <= rvimage(A, f, Memrel(i))"
    46 apply (rule_tac x="wftype(r)" in exI)
    47 apply (rule_tac x="\<lambda>x\<in>A. wfrank(r,x)" in exI)
    48 apply (simp add: Ord_wftype, clarify)
    49 apply (frule subsetD, assumption, clarify)
    50 apply (simp add: rvimage_iff wfrank_lt [THEN ltD])
    51 apply (blast intro: wftypeI)
    52 done
    53 
    54 theorem wf_iff_subset_rvimage:
    55   "relation(r) ==> wf(r) <-> (\<exists>i f A. Ord(i) & r <= rvimage(A, f, Memrel(i)))"
    56 by (blast dest!: relation_field_times_field wf_imp_subset_rvimage
    57           intro: wf_rvimage_Ord [THEN wf_subset])
    58 
    59 
    60 subsection{*Transitive closure without fixedpoints*}
    61 
    62 constdefs
    63   rtrancl_alt :: "[i,i]=>i"
    64     "rtrancl_alt(A,r) ==
    65        {p \<in> A*A. \<exists>n\<in>nat. \<exists>f \<in> succ(n) -> A.
    66                  (\<exists>x y. p = <x,y> &  f`0 = x & f`n = y) &
    67                        (\<forall>i\<in>n. <f`i, f`succ(i)> \<in> r)}"
    68 
    69 lemma alt_rtrancl_lemma1 [rule_format]:
    70     "n \<in> nat
    71      ==> \<forall>f \<in> succ(n) -> field(r).
    72          (\<forall>i\<in>n. \<langle>f`i, f ` succ(i)\<rangle> \<in> r) --> \<langle>f`0, f`n\<rangle> \<in> r^*"
    73 apply (induct_tac n)
    74 apply (simp_all add: apply_funtype rtrancl_refl, clarify)
    75 apply (rename_tac n f)
    76 apply (rule rtrancl_into_rtrancl)
    77  prefer 2 apply assumption
    78 apply (drule_tac x="restrict(f,succ(n))" in bspec)
    79  apply (blast intro: restrict_type2)
    80 apply (simp add: Ord_succ_mem_iff nat_0_le [THEN ltD] leI [THEN ltD] ltI)
    81 done
    82 
    83 lemma rtrancl_alt_subset_rtrancl: "rtrancl_alt(field(r),r) <= r^*"
    84 apply (simp add: rtrancl_alt_def)
    85 apply (blast intro: alt_rtrancl_lemma1)
    86 done
    87 
    88 lemma rtrancl_subset_rtrancl_alt: "r^* <= rtrancl_alt(field(r),r)"
    89 apply (simp add: rtrancl_alt_def, clarify)
    90 apply (frule rtrancl_type [THEN subsetD], clarify, simp)
    91 apply (erule rtrancl_induct)
    92  txt{*Base case, trivial*}
    93  apply (rule_tac x=0 in bexI)
    94   apply (rule_tac x="lam x:1. xa" in bexI)
    95    apply simp_all
    96 txt{*Inductive step*}
    97 apply clarify
    98 apply (rename_tac n f)
    99 apply (rule_tac x="succ(n)" in bexI)
   100  apply (rule_tac x="lam i:succ(succ(n)). if i=succ(n) then z else f`i" in bexI)
   101   apply (simp add: Ord_succ_mem_iff nat_0_le [THEN ltD] leI [THEN ltD] ltI)
   102   apply (blast intro: mem_asym)
   103  apply typecheck
   104  apply auto
   105 done
   106 
   107 lemma rtrancl_alt_eq_rtrancl: "rtrancl_alt(field(r),r) = r^*"
   108 by (blast del: subsetI
   109 	  intro: rtrancl_alt_subset_rtrancl rtrancl_subset_rtrancl_alt)
   110 
   111 
   112 constdefs
   113 
   114   rtran_closure_mem :: "[i=>o,i,i,i] => o"
   115     --{*The property of belonging to @{text "rtran_closure(r)"}*}
   116     "rtran_closure_mem(M,A,r,p) ==
   117 	      \<exists>nnat[M]. \<exists>n[M]. \<exists>n'[M]. 
   118                omega(M,nnat) & n\<in>nnat & successor(M,n,n') &
   119 	       (\<exists>f[M]. typed_function(M,n',A,f) &
   120 		(\<exists>x[M]. \<exists>y[M]. \<exists>zero[M]. pair(M,x,y,p) & empty(M,zero) &
   121 		  fun_apply(M,f,zero,x) & fun_apply(M,f,n,y)) &
   122 		  (\<forall>j[M]. j\<in>n --> 
   123 		    (\<exists>fj[M]. \<exists>sj[M]. \<exists>fsj[M]. \<exists>ffp[M]. 
   124 		      fun_apply(M,f,j,fj) & successor(M,j,sj) &
   125 		      fun_apply(M,f,sj,fsj) & pair(M,fj,fsj,ffp) & ffp \<in> r)))"
   126 
   127   rtran_closure :: "[i=>o,i,i] => o"
   128     "rtran_closure(M,r,s) == 
   129         \<forall>A[M]. is_field(M,r,A) -->
   130  	 (\<forall>p[M]. p \<in> s <-> rtran_closure_mem(M,A,r,p))"
   131 
   132   tran_closure :: "[i=>o,i,i] => o"
   133     "tran_closure(M,r,t) ==
   134          \<exists>s[M]. rtran_closure(M,r,s) & composition(M,r,s,t)"
   135 
   136 lemma (in M_axioms) rtran_closure_mem_iff:
   137      "[|M(A); M(r); M(p)|]
   138       ==> rtran_closure_mem(M,A,r,p) <->
   139           (\<exists>n[M]. n\<in>nat & 
   140            (\<exists>f[M]. f \<in> succ(n) -> A &
   141             (\<exists>x[M]. \<exists>y[M]. p = <x,y> & f`0 = x & f`n = y) &
   142                            (\<forall>i\<in>n. <f`i, f`succ(i)> \<in> r)))"
   143 by (simp add: rtran_closure_mem_def Ord_succ_mem_iff nat_0_le [THEN ltD]) 
   144 
   145 
   146 locale M_trancl = M_axioms +
   147   assumes rtrancl_separation:
   148 	 "[| M(r); M(A) |] ==> separation (M, rtran_closure_mem(M,A,r))"
   149       and wellfounded_trancl_separation:
   150 	 "[| M(r); M(Z) |] ==> 
   151 	  separation (M, \<lambda>x. 
   152 	      \<exists>w[M]. \<exists>wx[M]. \<exists>rp[M]. 
   153 	       w \<in> Z & pair(M,w,x,wx) & tran_closure(M,r,rp) & wx \<in> rp)"
   154 
   155 
   156 lemma (in M_trancl) rtran_closure_rtrancl:
   157      "M(r) ==> rtran_closure(M,r,rtrancl(r))"
   158 apply (simp add: rtran_closure_def rtran_closure_mem_iff 
   159                  rtrancl_alt_eq_rtrancl [symmetric] rtrancl_alt_def)
   160 apply (auto simp add: nat_0_le [THEN ltD] apply_funtype) 
   161 done
   162 
   163 lemma (in M_trancl) rtrancl_closed [intro,simp]:
   164      "M(r) ==> M(rtrancl(r))"
   165 apply (insert rtrancl_separation [of r "field(r)"])
   166 apply (simp add: rtrancl_alt_eq_rtrancl [symmetric]
   167                  rtrancl_alt_def rtran_closure_mem_iff)
   168 done
   169 
   170 lemma (in M_trancl) rtrancl_abs [simp]:
   171      "[| M(r); M(z) |] ==> rtran_closure(M,r,z) <-> z = rtrancl(r)"
   172 apply (rule iffI)
   173  txt{*Proving the right-to-left implication*}
   174  prefer 2 apply (blast intro: rtran_closure_rtrancl)
   175 apply (rule M_equalityI)
   176 apply (simp add: rtran_closure_def rtrancl_alt_eq_rtrancl [symmetric]
   177                  rtrancl_alt_def rtran_closure_mem_iff)
   178 apply (auto simp add: nat_0_le [THEN ltD] apply_funtype) 
   179 done
   180 
   181 lemma (in M_trancl) trancl_closed [intro,simp]:
   182      "M(r) ==> M(trancl(r))"
   183 by (simp add: trancl_def comp_closed rtrancl_closed)
   184 
   185 lemma (in M_trancl) trancl_abs [simp]:
   186      "[| M(r); M(z) |] ==> tran_closure(M,r,z) <-> z = trancl(r)"
   187 by (simp add: tran_closure_def trancl_def)
   188 
   189 lemma (in M_trancl) wellfounded_trancl_separation':
   190      "[| M(r); M(Z) |] ==> separation (M, \<lambda>x. \<exists>w[M]. w \<in> Z & <w,x> \<in> r^+)"
   191 by (insert wellfounded_trancl_separation [of r Z], simp) 
   192 
   193 text{*Alternative proof of @{text wf_on_trancl}; inspiration for the
   194       relativized version.  Original version is on theory WF.*}
   195 lemma "[| wf[A](r);  r-``A <= A |] ==> wf[A](r^+)"
   196 apply (simp add: wf_on_def wf_def)
   197 apply (safe intro!: equalityI)
   198 apply (drule_tac x = "{x\<in>A. \<exists>w. \<langle>w,x\<rangle> \<in> r^+ & w \<in> Z}" in spec)
   199 apply (blast elim: tranclE)
   200 done
   201 
   202 lemma (in M_trancl) wellfounded_on_trancl:
   203      "[| wellfounded_on(M,A,r);  r-``A <= A; M(r); M(A) |]
   204       ==> wellfounded_on(M,A,r^+)"
   205 apply (simp add: wellfounded_on_def)
   206 apply (safe intro!: equalityI)
   207 apply (rename_tac Z x)
   208 apply (subgoal_tac "M({x\<in>A. \<exists>w[M]. w \<in> Z & \<langle>w,x\<rangle> \<in> r^+})")
   209  prefer 2
   210  apply (blast intro: wellfounded_trancl_separation') 
   211 apply (drule_tac x = "{x\<in>A. \<exists>w[M]. w \<in> Z & \<langle>w,x\<rangle> \<in> r^+}" in rspec, safe)
   212 apply (blast dest: transM, simp)
   213 apply (rename_tac y w)
   214 apply (drule_tac x=w in bspec, assumption, clarify)
   215 apply (erule tranclE)
   216   apply (blast dest: transM)   (*transM is needed to prove M(xa)*)
   217  apply blast
   218 done
   219 
   220 lemma (in M_trancl) wellfounded_trancl:
   221      "[|wellfounded(M,r); M(r)|] ==> wellfounded(M,r^+)"
   222 apply (rotate_tac -1)
   223 apply (simp add: wellfounded_iff_wellfounded_on_field)
   224 apply (rule wellfounded_on_subset_A, erule wellfounded_on_trancl)
   225    apply blast
   226   apply (simp_all add: trancl_type [THEN field_rel_subset])
   227 done
   228 
   229 text{*Relativized to M: Every well-founded relation is a subset of some
   230 inverse image of an ordinal.  Key step is the construction (in M) of a
   231 rank function.*}
   232 
   233 
   234 locale M_wfrank = M_trancl +
   235   assumes wfrank_separation:
   236      "M(r) ==>
   237       separation (M, \<lambda>x. 
   238          \<forall>rplus[M]. tran_closure(M,r,rplus) -->
   239          ~ (\<exists>f[M]. M_is_recfun(M, %x f y. is_range(M,f,y), rplus, x, f)))"
   240  and wfrank_strong_replacement:
   241      "M(r) ==>
   242       strong_replacement(M, \<lambda>x z. 
   243          \<forall>rplus[M]. tran_closure(M,r,rplus) -->
   244          (\<exists>y[M]. \<exists>f[M]. pair(M,x,y,z)  & 
   245                         M_is_recfun(M, %x f y. is_range(M,f,y), rplus, x, f) &
   246                         is_range(M,f,y)))"
   247  and Ord_wfrank_separation:
   248      "M(r) ==>
   249       separation (M, \<lambda>x.
   250          \<forall>rplus[M]. tran_closure(M,r,rplus) --> 
   251           ~ (\<forall>f[M]. \<forall>rangef[M]. 
   252              is_range(M,f,rangef) -->
   253              M_is_recfun(M, \<lambda>x f y. is_range(M,f,y), rplus, x, f) -->
   254              ordinal(M,rangef)))" 
   255 
   256 text{*Proving that the relativized instances of Separation or Replacement
   257 agree with the "real" ones.*}
   258 
   259 lemma (in M_wfrank) wfrank_separation':
   260      "M(r) ==>
   261       separation
   262 	   (M, \<lambda>x. ~ (\<exists>f[M]. is_recfun(r^+, x, %x f. range(f), f)))"
   263 apply (insert wfrank_separation [of r])
   264 apply (simp add: relativize2_def is_recfun_abs [of "%x. range"])
   265 done
   266 
   267 lemma (in M_wfrank) wfrank_strong_replacement':
   268      "M(r) ==>
   269       strong_replacement(M, \<lambda>x z. \<exists>y[M]. \<exists>f[M]. 
   270 		  pair(M,x,y,z) & is_recfun(r^+, x, %x f. range(f), f) &
   271 		  y = range(f))"
   272 apply (insert wfrank_strong_replacement [of r])
   273 apply (simp add: relativize2_def is_recfun_abs [of "%x. range"])
   274 done
   275 
   276 lemma (in M_wfrank) Ord_wfrank_separation':
   277      "M(r) ==>
   278       separation (M, \<lambda>x. 
   279          ~ (\<forall>f[M]. is_recfun(r^+, x, \<lambda>x. range, f) --> Ord(range(f))))" 
   280 apply (insert Ord_wfrank_separation [of r])
   281 apply (simp add: relativize2_def is_recfun_abs [of "%x. range"])
   282 done
   283 
   284 text{*This function, defined using replacement, is a rank function for
   285 well-founded relations within the class M.*}
   286 constdefs
   287  wellfoundedrank :: "[i=>o,i,i] => i"
   288     "wellfoundedrank(M,r,A) ==
   289         {p. x\<in>A, \<exists>y[M]. \<exists>f[M]. 
   290                        p = <x,y> & is_recfun(r^+, x, %x f. range(f), f) &
   291                        y = range(f)}"
   292 
   293 lemma (in M_wfrank) exists_wfrank:
   294     "[| wellfounded(M,r); M(a); M(r) |]
   295      ==> \<exists>f[M]. is_recfun(r^+, a, %x f. range(f), f)"
   296 apply (rule wellfounded_exists_is_recfun)
   297       apply (blast intro: wellfounded_trancl)
   298      apply (rule trans_trancl)
   299     apply (erule wfrank_separation')
   300    apply (erule wfrank_strong_replacement')
   301 apply (simp_all add: trancl_subset_times)
   302 done
   303 
   304 lemma (in M_wfrank) M_wellfoundedrank:
   305     "[| wellfounded(M,r); M(r); M(A) |] ==> M(wellfoundedrank(M,r,A))"
   306 apply (insert wfrank_strong_replacement' [of r])
   307 apply (simp add: wellfoundedrank_def)
   308 apply (rule strong_replacement_closed)
   309    apply assumption+
   310  apply (rule univalent_is_recfun)
   311    apply (blast intro: wellfounded_trancl)
   312   apply (rule trans_trancl)
   313  apply (simp add: trancl_subset_times, blast)
   314 done
   315 
   316 lemma (in M_wfrank) Ord_wfrank_range [rule_format]:
   317     "[| wellfounded(M,r); a\<in>A; M(r); M(A) |]
   318      ==> \<forall>f[M]. is_recfun(r^+, a, %x f. range(f), f) --> Ord(range(f))"
   319 apply (drule wellfounded_trancl, assumption)
   320 apply (rule wellfounded_induct, assumption, erule (1) transM)
   321   apply simp
   322  apply (blast intro: Ord_wfrank_separation', clarify)
   323 txt{*The reasoning in both cases is that we get @{term y} such that
   324    @{term "\<langle>y, x\<rangle> \<in> r^+"}.  We find that
   325    @{term "f`y = restrict(f, r^+ -`` {y})"}. *}
   326 apply (rule OrdI [OF _ Ord_is_Transset])
   327  txt{*An ordinal is a transitive set...*}
   328  apply (simp add: Transset_def)
   329  apply clarify
   330  apply (frule apply_recfun2, assumption)
   331  apply (force simp add: restrict_iff)
   332 txt{*...of ordinals.  This second case requires the induction hyp.*}
   333 apply clarify
   334 apply (rename_tac i y)
   335 apply (frule apply_recfun2, assumption)
   336 apply (frule is_recfun_imp_in_r, assumption)
   337 apply (frule is_recfun_restrict)
   338     (*simp_all won't work*)
   339     apply (simp add: trans_trancl trancl_subset_times)+
   340 apply (drule spec [THEN mp], assumption)
   341 apply (subgoal_tac "M(restrict(f, r^+ -`` {y}))")
   342  apply (drule_tac x="restrict(f, r^+ -`` {y})" in rspec)
   343 apply assumption
   344  apply (simp add: function_apply_equality [OF _ is_recfun_imp_function])
   345 apply (blast dest: pair_components_in_M)
   346 done
   347 
   348 lemma (in M_wfrank) Ord_range_wellfoundedrank:
   349     "[| wellfounded(M,r); r \<subseteq> A*A;  M(r); M(A) |]
   350      ==> Ord (range(wellfoundedrank(M,r,A)))"
   351 apply (frule wellfounded_trancl, assumption)
   352 apply (frule trancl_subset_times)
   353 apply (simp add: wellfoundedrank_def)
   354 apply (rule OrdI [OF _ Ord_is_Transset])
   355  prefer 2
   356  txt{*by our previous result the range consists of ordinals.*}
   357  apply (blast intro: Ord_wfrank_range)
   358 txt{*We still must show that the range is a transitive set.*}
   359 apply (simp add: Transset_def, clarify, simp)
   360 apply (rename_tac x i f u)
   361 apply (frule is_recfun_imp_in_r, assumption)
   362 apply (subgoal_tac "M(u) & M(i) & M(x)")
   363  prefer 2 apply (blast dest: transM, clarify)
   364 apply (rule_tac a=u in rangeI)
   365 apply (rule_tac x=u in ReplaceI)
   366   apply simp 
   367   apply (rule_tac x="restrict(f, r^+ -`` {u})" in rexI)
   368    apply (blast intro: is_recfun_restrict trans_trancl dest: apply_recfun2)
   369   apply simp 
   370 apply blast 
   371 txt{*Unicity requirement of Replacement*}
   372 apply clarify
   373 apply (frule apply_recfun2, assumption)
   374 apply (simp add: trans_trancl is_recfun_cut)
   375 done
   376 
   377 lemma (in M_wfrank) function_wellfoundedrank:
   378     "[| wellfounded(M,r); M(r); M(A)|]
   379      ==> function(wellfoundedrank(M,r,A))"
   380 apply (simp add: wellfoundedrank_def function_def, clarify)
   381 txt{*Uniqueness: repeated below!*}
   382 apply (drule is_recfun_functional, assumption)
   383      apply (blast intro: wellfounded_trancl)
   384     apply (simp_all add: trancl_subset_times trans_trancl)
   385 done
   386 
   387 lemma (in M_wfrank) domain_wellfoundedrank:
   388     "[| wellfounded(M,r); M(r); M(A)|]
   389      ==> domain(wellfoundedrank(M,r,A)) = A"
   390 apply (simp add: wellfoundedrank_def function_def)
   391 apply (rule equalityI, auto)
   392 apply (frule transM, assumption)
   393 apply (frule_tac a=x in exists_wfrank, assumption+, clarify)
   394 apply (rule_tac b="range(f)" in domainI)
   395 apply (rule_tac x=x in ReplaceI)
   396   apply simp 
   397   apply (rule_tac x=f in rexI, blast, simp_all)
   398 txt{*Uniqueness (for Replacement): repeated above!*}
   399 apply clarify
   400 apply (drule is_recfun_functional, assumption)
   401     apply (blast intro: wellfounded_trancl)
   402     apply (simp_all add: trancl_subset_times trans_trancl)
   403 done
   404 
   405 lemma (in M_wfrank) wellfoundedrank_type:
   406     "[| wellfounded(M,r);  M(r); M(A)|]
   407      ==> wellfoundedrank(M,r,A) \<in> A -> range(wellfoundedrank(M,r,A))"
   408 apply (frule function_wellfoundedrank [of r A], assumption+)
   409 apply (frule function_imp_Pi)
   410  apply (simp add: wellfoundedrank_def relation_def)
   411  apply blast
   412 apply (simp add: domain_wellfoundedrank)
   413 done
   414 
   415 lemma (in M_wfrank) Ord_wellfoundedrank:
   416     "[| wellfounded(M,r); a \<in> A; r \<subseteq> A*A;  M(r); M(A) |]
   417      ==> Ord(wellfoundedrank(M,r,A) ` a)"
   418 by (blast intro: apply_funtype [OF wellfoundedrank_type]
   419                  Ord_in_Ord [OF Ord_range_wellfoundedrank])
   420 
   421 lemma (in M_wfrank) wellfoundedrank_eq:
   422      "[| is_recfun(r^+, a, %x. range, f);
   423          wellfounded(M,r);  a \<in> A; M(f); M(r); M(A)|]
   424       ==> wellfoundedrank(M,r,A) ` a = range(f)"
   425 apply (rule apply_equality)
   426  prefer 2 apply (blast intro: wellfoundedrank_type)
   427 apply (simp add: wellfoundedrank_def)
   428 apply (rule ReplaceI)
   429   apply (rule_tac x="range(f)" in rexI) 
   430   apply blast
   431  apply simp_all
   432 txt{*Unicity requirement of Replacement*}
   433 apply clarify
   434 apply (drule is_recfun_functional, assumption)
   435     apply (blast intro: wellfounded_trancl)
   436     apply (simp_all add: trancl_subset_times trans_trancl)
   437 done
   438 
   439 
   440 lemma (in M_wfrank) wellfoundedrank_lt:
   441      "[| <a,b> \<in> r;
   442          wellfounded(M,r); r \<subseteq> A*A;  M(r); M(A)|]
   443       ==> wellfoundedrank(M,r,A) ` a < wellfoundedrank(M,r,A) ` b"
   444 apply (frule wellfounded_trancl, assumption)
   445 apply (subgoal_tac "a\<in>A & b\<in>A")
   446  prefer 2 apply blast
   447 apply (simp add: lt_def Ord_wellfoundedrank, clarify)
   448 apply (frule exists_wfrank [of concl: _ b], erule (1) transM, assumption)
   449 apply clarify
   450 apply (rename_tac fb)
   451 apply (frule is_recfun_restrict [of concl: "r^+" a])
   452     apply (rule trans_trancl, assumption)
   453    apply (simp_all add: r_into_trancl trancl_subset_times)
   454 txt{*Still the same goal, but with new @{text is_recfun} assumptions.*}
   455 apply (simp add: wellfoundedrank_eq)
   456 apply (frule_tac a=a in wellfoundedrank_eq, assumption+)
   457    apply (simp_all add: transM [of a])
   458 txt{*We have used equations for wellfoundedrank and now must use some
   459     for  @{text is_recfun}. *}
   460 apply (rule_tac a=a in rangeI)
   461 apply (simp add: is_recfun_type [THEN apply_iff] vimage_singleton_iff
   462                  r_into_trancl apply_recfun r_into_trancl)
   463 done
   464 
   465 
   466 lemma (in M_wfrank) wellfounded_imp_subset_rvimage:
   467      "[|wellfounded(M,r); r \<subseteq> A*A; M(r); M(A)|]
   468       ==> \<exists>i f. Ord(i) & r <= rvimage(A, f, Memrel(i))"
   469 apply (rule_tac x="range(wellfoundedrank(M,r,A))" in exI)
   470 apply (rule_tac x="wellfoundedrank(M,r,A)" in exI)
   471 apply (simp add: Ord_range_wellfoundedrank, clarify)
   472 apply (frule subsetD, assumption, clarify)
   473 apply (simp add: rvimage_iff wellfoundedrank_lt [THEN ltD])
   474 apply (blast intro: apply_rangeI wellfoundedrank_type)
   475 done
   476 
   477 lemma (in M_wfrank) wellfounded_imp_wf:
   478      "[|wellfounded(M,r); relation(r); M(r)|] ==> wf(r)"
   479 by (blast dest!: relation_field_times_field wellfounded_imp_subset_rvimage
   480           intro: wf_rvimage_Ord [THEN wf_subset])
   481 
   482 lemma (in M_wfrank) wellfounded_on_imp_wf_on:
   483      "[|wellfounded_on(M,A,r); relation(r); M(r); M(A)|] ==> wf[A](r)"
   484 apply (simp add: wellfounded_on_iff_wellfounded wf_on_def)
   485 apply (rule wellfounded_imp_wf)
   486 apply (simp_all add: relation_def)
   487 done
   488 
   489 
   490 theorem (in M_wfrank) wf_abs [simp]:
   491      "[|relation(r); M(r)|] ==> wellfounded(M,r) <-> wf(r)"
   492 by (blast intro: wellfounded_imp_wf wf_imp_relativized)
   493 
   494 theorem (in M_wfrank) wf_on_abs [simp]:
   495      "[|relation(r); M(r); M(A)|] ==> wellfounded_on(M,A,r) <-> wf[A](r)"
   496 by (blast intro: wellfounded_on_imp_wf_on wf_on_imp_relativized)
   497 
   498 
   499 text{*absoluteness for wfrec-defined functions.*}
   500 
   501 (*first use is_recfun, then M_is_recfun*)
   502 
   503 lemma (in M_trancl) wfrec_relativize:
   504   "[|wf(r); M(a); M(r);  
   505      strong_replacement(M, \<lambda>x z. \<exists>y[M]. \<exists>g[M].
   506           pair(M,x,y,z) & 
   507           is_recfun(r^+, x, \<lambda>x f. H(x, restrict(f, r -`` {x})), g) & 
   508           y = H(x, restrict(g, r -`` {x}))); 
   509      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   510    ==> wfrec(r,a,H) = z <-> 
   511        (\<exists>f[M]. is_recfun(r^+, a, \<lambda>x f. H(x, restrict(f, r -`` {x})), f) & 
   512             z = H(a,restrict(f,r-``{a})))"
   513 apply (frule wf_trancl) 
   514 apply (simp add: wftrec_def wfrec_def, safe)
   515  apply (frule wf_exists_is_recfun 
   516               [of concl: "r^+" a "\<lambda>x f. H(x, restrict(f, r -`` {x}))"]) 
   517       apply (simp_all add: trans_trancl function_restrictI trancl_subset_times)
   518  apply (clarify, rule_tac x=x in rexI) 
   519  apply (simp_all add: the_recfun_eq trans_trancl trancl_subset_times)
   520 done
   521 
   522 
   523 text{*Assuming @{term r} is transitive simplifies the occurrences of @{text H}.
   524       The premise @{term "relation(r)"} is necessary 
   525       before we can replace @{term "r^+"} by @{term r}. *}
   526 theorem (in M_trancl) trans_wfrec_relativize:
   527   "[|wf(r);  trans(r);  relation(r);  M(r);  M(a);
   528      wfrec_replacement(M,MH,r);  relativize2(M,MH,H);
   529      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   530    ==> wfrec(r,a,H) = z <-> (\<exists>f[M]. is_recfun(r,a,H,f) & z = H(a,f))" 
   531 apply (frule wfrec_replacement', assumption+) 
   532 apply (simp cong: is_recfun_cong
   533            add: wfrec_relativize trancl_eq_r
   534                 is_recfun_restrict_idem domain_restrict_idem)
   535 done
   536 
   537 theorem (in M_trancl) trans_wfrec_abs:
   538   "[|wf(r);  trans(r);  relation(r);  M(r);  M(a);  M(z);
   539      wfrec_replacement(M,MH,r);  relativize2(M,MH,H);
   540      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   541    ==> is_wfrec(M,MH,r,a,z) <-> z=wfrec(r,a,H)" 
   542 apply (simp add: trans_wfrec_relativize [THEN iff_sym] is_wfrec_abs, blast) 
   543 done
   544 
   545 lemma (in M_trancl) trans_eq_pair_wfrec_iff:
   546   "[|wf(r);  trans(r); relation(r); M(r);  M(y); 
   547      wfrec_replacement(M,MH,r);  relativize2(M,MH,H);
   548      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   549    ==> y = <x, wfrec(r, x, H)> <-> 
   550        (\<exists>f[M]. is_recfun(r,x,H,f) & y = <x, H(x,f)>)"
   551 apply safe 
   552  apply (simp add: trans_wfrec_relativize [THEN iff_sym, of concl: _ x]) 
   553 txt{*converse direction*}
   554 apply (rule sym)
   555 apply (simp add: trans_wfrec_relativize, blast) 
   556 done
   557 
   558 
   559 subsection{*M is closed under well-founded recursion*}
   560 
   561 text{*Lemma with the awkward premise mentioning @{text wfrec}.*}
   562 lemma (in M_wfrank) wfrec_closed_lemma [rule_format]:
   563      "[|wf(r); M(r); 
   564         strong_replacement(M, \<lambda>x y. y = \<langle>x, wfrec(r, x, H)\<rangle>);
   565         \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g)) |] 
   566       ==> M(a) --> M(wfrec(r,a,H))"
   567 apply (rule_tac a=a in wf_induct, assumption+)
   568 apply (subst wfrec, assumption, clarify)
   569 apply (drule_tac x1=x and x="\<lambda>x\<in>r -`` {x}. wfrec(r, x, H)" 
   570        in rspec [THEN rspec]) 
   571 apply (simp_all add: function_lam) 
   572 apply (blast intro: lam_closed dest: pair_components_in_M ) 
   573 done
   574 
   575 text{*Eliminates one instance of replacement.*}
   576 lemma (in M_wfrank) wfrec_replacement_iff:
   577      "strong_replacement(M, \<lambda>x z. 
   578           \<exists>y[M]. pair(M,x,y,z) & (\<exists>g[M]. is_recfun(r,x,H,g) & y = H(x,g))) <->
   579       strong_replacement(M, 
   580            \<lambda>x y. \<exists>f[M]. is_recfun(r,x,H,f) & y = <x, H(x,f)>)"
   581 apply simp 
   582 apply (rule strong_replacement_cong, blast) 
   583 done
   584 
   585 text{*Useful version for transitive relations*}
   586 theorem (in M_wfrank) trans_wfrec_closed:
   587      "[|wf(r); trans(r); relation(r); M(r); M(a);
   588        wfrec_replacement(M,MH,r);  relativize2(M,MH,H);
   589         \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g)) |] 
   590       ==> M(wfrec(r,a,H))"
   591 apply (frule wfrec_replacement', assumption+) 
   592 apply (frule wfrec_replacement_iff [THEN iffD1]) 
   593 apply (rule wfrec_closed_lemma, assumption+) 
   594 apply (simp_all add: wfrec_replacement_iff trans_eq_pair_wfrec_iff) 
   595 done
   596 
   597 section{*Absoluteness without assuming transitivity*}
   598 lemma (in M_trancl) eq_pair_wfrec_iff:
   599   "[|wf(r);  M(r);  M(y); 
   600      strong_replacement(M, \<lambda>x z. \<exists>y[M]. \<exists>g[M].
   601           pair(M,x,y,z) & 
   602           is_recfun(r^+, x, \<lambda>x f. H(x, restrict(f, r -`` {x})), g) & 
   603           y = H(x, restrict(g, r -`` {x}))); 
   604      \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g))|] 
   605    ==> y = <x, wfrec(r, x, H)> <-> 
   606        (\<exists>f[M]. is_recfun(r^+, x, \<lambda>x f. H(x, restrict(f, r -`` {x})), f) & 
   607             y = <x, H(x,restrict(f,r-``{x}))>)"
   608 apply safe  
   609  apply (simp add: wfrec_relativize [THEN iff_sym, of concl: _ x]) 
   610 txt{*converse direction*}
   611 apply (rule sym)
   612 apply (simp add: wfrec_relativize, blast) 
   613 done
   614 
   615 text{*Full version not assuming transitivity, but maybe not very useful.*}
   616 theorem (in M_wfrank) wfrec_closed:
   617      "[|wf(r); M(r); M(a);
   618         wfrec_replacement(M,MH,r^+);  
   619         relativize2(M,MH, \<lambda>x f. H(x, restrict(f, r -`` {x})));
   620         \<forall>x[M]. \<forall>g[M]. function(g) --> M(H(x,g)) |] 
   621       ==> M(wfrec(r,a,H))"
   622 apply (frule wfrec_replacement' 
   623                [of MH "r^+" "\<lambda>x f. H(x, restrict(f, r -`` {x}))"])
   624    prefer 4
   625    apply (frule wfrec_replacement_iff [THEN iffD1]) 
   626    apply (rule wfrec_closed_lemma, assumption+) 
   627      apply (simp_all add: eq_pair_wfrec_iff func.function_restrictI) 
   628 done
   629 
   630 end