src/HOL/Probability/Lebesgue_Integration.thy
author haftmann
Sun Mar 16 18:09:04 2014 +0100 (2014-03-16)
changeset 56166 9a241bc276cd
parent 56154 f0a927235162
child 56193 c726ecfb22b6
permissions -rw-r--r--
normalising simp rules for compound operators
     1 (*  Title:      HOL/Probability/Lebesgue_Integration.thy
     2     Author:     Johannes Hölzl, TU München
     3     Author:     Armin Heller, TU München
     4 *)
     5 
     6 header {*Lebesgue Integration*}
     7 
     8 theory Lebesgue_Integration
     9   imports Measure_Space Borel_Space
    10 begin
    11 
    12 lemma tendsto_real_max:
    13   fixes x y :: real
    14   assumes "(X ---> x) net"
    15   assumes "(Y ---> y) net"
    16   shows "((\<lambda>x. max (X x) (Y x)) ---> max x y) net"
    17 proof -
    18   have *: "\<And>x y :: real. max x y = y + ((x - y) + norm (x - y)) / 2"
    19     by (auto split: split_max simp: field_simps)
    20   show ?thesis
    21     unfolding *
    22     by (intro tendsto_add assms tendsto_divide tendsto_norm tendsto_diff) auto
    23 qed
    24 
    25 lemma measurable_sets2[intro]:
    26   assumes "f \<in> measurable M M'" "g \<in> measurable M M''"
    27   and "A \<in> sets M'" "B \<in> sets M''"
    28   shows "f -` A \<inter> g -` B \<inter> space M \<in> sets M"
    29 proof -
    30   have "f -` A \<inter> g -` B \<inter> space M = (f -` A \<inter> space M) \<inter> (g -` B \<inter> space M)"
    31     by auto
    32   then show ?thesis using assms by (auto intro: measurable_sets)
    33 qed
    34 
    35 section "Simple function"
    36 
    37 text {*
    38 
    39 Our simple functions are not restricted to positive real numbers. Instead
    40 they are just functions with a finite range and are measurable when singleton
    41 sets are measurable.
    42 
    43 *}
    44 
    45 definition "simple_function M g \<longleftrightarrow>
    46     finite (g ` space M) \<and>
    47     (\<forall>x \<in> g ` space M. g -` {x} \<inter> space M \<in> sets M)"
    48 
    49 lemma simple_functionD:
    50   assumes "simple_function M g"
    51   shows "finite (g ` space M)" and "g -` X \<inter> space M \<in> sets M"
    52 proof -
    53   show "finite (g ` space M)"
    54     using assms unfolding simple_function_def by auto
    55   have "g -` X \<inter> space M = g -` (X \<inter> g`space M) \<inter> space M" by auto
    56   also have "\<dots> = (\<Union>x\<in>X \<inter> g`space M. g-`{x} \<inter> space M)" by auto
    57   finally show "g -` X \<inter> space M \<in> sets M" using assms
    58     by (auto simp del: UN_simps simp: simple_function_def)
    59 qed
    60 
    61 lemma simple_function_measurable2[intro]:
    62   assumes "simple_function M f" "simple_function M g"
    63   shows "f -` A \<inter> g -` B \<inter> space M \<in> sets M"
    64 proof -
    65   have "f -` A \<inter> g -` B \<inter> space M = (f -` A \<inter> space M) \<inter> (g -` B \<inter> space M)"
    66     by auto
    67   then show ?thesis using assms[THEN simple_functionD(2)] by auto
    68 qed
    69 
    70 lemma simple_function_indicator_representation:
    71   fixes f ::"'a \<Rightarrow> ereal"
    72   assumes f: "simple_function M f" and x: "x \<in> space M"
    73   shows "f x = (\<Sum>y \<in> f ` space M. y * indicator (f -` {y} \<inter> space M) x)"
    74   (is "?l = ?r")
    75 proof -
    76   have "?r = (\<Sum>y \<in> f ` space M.
    77     (if y = f x then y * indicator (f -` {y} \<inter> space M) x else 0))"
    78     by (auto intro!: setsum_cong2)
    79   also have "... =  f x *  indicator (f -` {f x} \<inter> space M) x"
    80     using assms by (auto dest: simple_functionD simp: setsum_delta)
    81   also have "... = f x" using x by (auto simp: indicator_def)
    82   finally show ?thesis by auto
    83 qed
    84 
    85 lemma simple_function_notspace:
    86   "simple_function M (\<lambda>x. h x * indicator (- space M) x::ereal)" (is "simple_function M ?h")
    87 proof -
    88   have "?h ` space M \<subseteq> {0}" unfolding indicator_def by auto
    89   hence [simp, intro]: "finite (?h ` space M)" by (auto intro: finite_subset)
    90   have "?h -` {0} \<inter> space M = space M" by auto
    91   thus ?thesis unfolding simple_function_def by auto
    92 qed
    93 
    94 lemma simple_function_cong:
    95   assumes "\<And>t. t \<in> space M \<Longrightarrow> f t = g t"
    96   shows "simple_function M f \<longleftrightarrow> simple_function M g"
    97 proof -
    98   have "f ` space M = g ` space M"
    99     "\<And>x. f -` {x} \<inter> space M = g -` {x} \<inter> space M"
   100     using assms by (auto intro!: image_eqI)
   101   thus ?thesis unfolding simple_function_def using assms by simp
   102 qed
   103 
   104 lemma simple_function_cong_algebra:
   105   assumes "sets N = sets M" "space N = space M"
   106   shows "simple_function M f \<longleftrightarrow> simple_function N f"
   107   unfolding simple_function_def assms ..
   108 
   109 lemma borel_measurable_simple_function[measurable_dest]:
   110   assumes "simple_function M f"
   111   shows "f \<in> borel_measurable M"
   112 proof (rule borel_measurableI)
   113   fix S
   114   let ?I = "f ` (f -` S \<inter> space M)"
   115   have *: "(\<Union>x\<in>?I. f -` {x} \<inter> space M) = f -` S \<inter> space M" (is "?U = _") by auto
   116   have "finite ?I"
   117     using assms unfolding simple_function_def
   118     using finite_subset[of "f ` (f -` S \<inter> space M)" "f ` space M"] by auto
   119   hence "?U \<in> sets M"
   120     apply (rule sets.finite_UN)
   121     using assms unfolding simple_function_def by auto
   122   thus "f -` S \<inter> space M \<in> sets M" unfolding * .
   123 qed
   124 
   125 lemma simple_function_borel_measurable:
   126   fixes f :: "'a \<Rightarrow> 'x::{t2_space}"
   127   assumes "f \<in> borel_measurable M" and "finite (f ` space M)"
   128   shows "simple_function M f"
   129   using assms unfolding simple_function_def
   130   by (auto intro: borel_measurable_vimage)
   131 
   132 lemma simple_function_eq_borel_measurable:
   133   fixes f :: "'a \<Rightarrow> ereal"
   134   shows "simple_function M f \<longleftrightarrow> finite (f`space M) \<and> f \<in> borel_measurable M"
   135   using simple_function_borel_measurable[of f] borel_measurable_simple_function[of M f]
   136   by (fastforce simp: simple_function_def)
   137 
   138 lemma simple_function_const[intro, simp]:
   139   "simple_function M (\<lambda>x. c)"
   140   by (auto intro: finite_subset simp: simple_function_def)
   141 lemma simple_function_compose[intro, simp]:
   142   assumes "simple_function M f"
   143   shows "simple_function M (g \<circ> f)"
   144   unfolding simple_function_def
   145 proof safe
   146   show "finite ((g \<circ> f) ` space M)"
   147     using assms unfolding simple_function_def by (auto simp: image_comp [symmetric])
   148 next
   149   fix x assume "x \<in> space M"
   150   let ?G = "g -` {g (f x)} \<inter> (f`space M)"
   151   have *: "(g \<circ> f) -` {(g \<circ> f) x} \<inter> space M =
   152     (\<Union>x\<in>?G. f -` {x} \<inter> space M)" by auto
   153   show "(g \<circ> f) -` {(g \<circ> f) x} \<inter> space M \<in> sets M"
   154     using assms unfolding simple_function_def *
   155     by (rule_tac sets.finite_UN) auto
   156 qed
   157 
   158 lemma simple_function_indicator[intro, simp]:
   159   assumes "A \<in> sets M"
   160   shows "simple_function M (indicator A)"
   161 proof -
   162   have "indicator A ` space M \<subseteq> {0, 1}" (is "?S \<subseteq> _")
   163     by (auto simp: indicator_def)
   164   hence "finite ?S" by (rule finite_subset) simp
   165   moreover have "- A \<inter> space M = space M - A" by auto
   166   ultimately show ?thesis unfolding simple_function_def
   167     using assms by (auto simp: indicator_def [abs_def])
   168 qed
   169 
   170 lemma simple_function_Pair[intro, simp]:
   171   assumes "simple_function M f"
   172   assumes "simple_function M g"
   173   shows "simple_function M (\<lambda>x. (f x, g x))" (is "simple_function M ?p")
   174   unfolding simple_function_def
   175 proof safe
   176   show "finite (?p ` space M)"
   177     using assms unfolding simple_function_def
   178     by (rule_tac finite_subset[of _ "f`space M \<times> g`space M"]) auto
   179 next
   180   fix x assume "x \<in> space M"
   181   have "(\<lambda>x. (f x, g x)) -` {(f x, g x)} \<inter> space M =
   182       (f -` {f x} \<inter> space M) \<inter> (g -` {g x} \<inter> space M)"
   183     by auto
   184   with `x \<in> space M` show "(\<lambda>x. (f x, g x)) -` {(f x, g x)} \<inter> space M \<in> sets M"
   185     using assms unfolding simple_function_def by auto
   186 qed
   187 
   188 lemma simple_function_compose1:
   189   assumes "simple_function M f"
   190   shows "simple_function M (\<lambda>x. g (f x))"
   191   using simple_function_compose[OF assms, of g]
   192   by (simp add: comp_def)
   193 
   194 lemma simple_function_compose2:
   195   assumes "simple_function M f" and "simple_function M g"
   196   shows "simple_function M (\<lambda>x. h (f x) (g x))"
   197 proof -
   198   have "simple_function M ((\<lambda>(x, y). h x y) \<circ> (\<lambda>x. (f x, g x)))"
   199     using assms by auto
   200   thus ?thesis by (simp_all add: comp_def)
   201 qed
   202 
   203 lemmas simple_function_add[intro, simp] = simple_function_compose2[where h="op +"]
   204   and simple_function_diff[intro, simp] = simple_function_compose2[where h="op -"]
   205   and simple_function_uminus[intro, simp] = simple_function_compose[where g="uminus"]
   206   and simple_function_mult[intro, simp] = simple_function_compose2[where h="op *"]
   207   and simple_function_div[intro, simp] = simple_function_compose2[where h="op /"]
   208   and simple_function_inverse[intro, simp] = simple_function_compose[where g="inverse"]
   209   and simple_function_max[intro, simp] = simple_function_compose2[where h=max]
   210 
   211 lemma simple_function_setsum[intro, simp]:
   212   assumes "\<And>i. i \<in> P \<Longrightarrow> simple_function M (f i)"
   213   shows "simple_function M (\<lambda>x. \<Sum>i\<in>P. f i x)"
   214 proof cases
   215   assume "finite P" from this assms show ?thesis by induct auto
   216 qed auto
   217 
   218 lemma
   219   fixes f g :: "'a \<Rightarrow> real" assumes sf: "simple_function M f"
   220   shows simple_function_ereal[intro, simp]: "simple_function M (\<lambda>x. ereal (f x))"
   221   by (auto intro!: simple_function_compose1[OF sf])
   222 
   223 lemma
   224   fixes f g :: "'a \<Rightarrow> nat" assumes sf: "simple_function M f"
   225   shows simple_function_real_of_nat[intro, simp]: "simple_function M (\<lambda>x. real (f x))"
   226   by (auto intro!: simple_function_compose1[OF sf])
   227 
   228 lemma borel_measurable_implies_simple_function_sequence:
   229   fixes u :: "'a \<Rightarrow> ereal"
   230   assumes u: "u \<in> borel_measurable M"
   231   shows "\<exists>f. incseq f \<and> (\<forall>i. \<infinity> \<notin> range (f i) \<and> simple_function M (f i)) \<and>
   232              (\<forall>x. (SUP i. f i x) = max 0 (u x)) \<and> (\<forall>i x. 0 \<le> f i x)"
   233 proof -
   234   def f \<equiv> "\<lambda>x i. if real i \<le> u x then i * 2 ^ i else natfloor (real (u x) * 2 ^ i)"
   235   { fix x j have "f x j \<le> j * 2 ^ j" unfolding f_def
   236     proof (split split_if, intro conjI impI)
   237       assume "\<not> real j \<le> u x"
   238       then have "natfloor (real (u x) * 2 ^ j) \<le> natfloor (j * 2 ^ j)"
   239          by (cases "u x") (auto intro!: natfloor_mono simp: mult_nonneg_nonneg)
   240       moreover have "real (natfloor (j * 2 ^ j)) \<le> j * 2^j"
   241         by (intro real_natfloor_le) (auto simp: mult_nonneg_nonneg)
   242       ultimately show "natfloor (real (u x) * 2 ^ j) \<le> j * 2 ^ j"
   243         unfolding real_of_nat_le_iff by auto
   244     qed auto }
   245   note f_upper = this
   246 
   247   have real_f:
   248     "\<And>i x. real (f x i) = (if real i \<le> u x then i * 2 ^ i else real (natfloor (real (u x) * 2 ^ i)))"
   249     unfolding f_def by auto
   250 
   251   let ?g = "\<lambda>j x. real (f x j) / 2^j :: ereal"
   252   show ?thesis
   253   proof (intro exI[of _ ?g] conjI allI ballI)
   254     fix i
   255     have "simple_function M (\<lambda>x. real (f x i))"
   256     proof (intro simple_function_borel_measurable)
   257       show "(\<lambda>x. real (f x i)) \<in> borel_measurable M"
   258         using u by (auto simp: real_f)
   259       have "(\<lambda>x. real (f x i))`space M \<subseteq> real`{..i*2^i}"
   260         using f_upper[of _ i] by auto
   261       then show "finite ((\<lambda>x. real (f x i))`space M)"
   262         by (rule finite_subset) auto
   263     qed
   264     then show "simple_function M (?g i)"
   265       by (auto intro: simple_function_ereal simple_function_div)
   266   next
   267     show "incseq ?g"
   268     proof (intro incseq_ereal incseq_SucI le_funI)
   269       fix x and i :: nat
   270       have "f x i * 2 \<le> f x (Suc i)" unfolding f_def
   271       proof ((split split_if)+, intro conjI impI)
   272         assume "ereal (real i) \<le> u x" "\<not> ereal (real (Suc i)) \<le> u x"
   273         then show "i * 2 ^ i * 2 \<le> natfloor (real (u x) * 2 ^ Suc i)"
   274           by (cases "u x") (auto intro!: le_natfloor)
   275       next
   276         assume "\<not> ereal (real i) \<le> u x" "ereal (real (Suc i)) \<le> u x"
   277         then show "natfloor (real (u x) * 2 ^ i) * 2 \<le> Suc i * 2 ^ Suc i"
   278           by (cases "u x") auto
   279       next
   280         assume "\<not> ereal (real i) \<le> u x" "\<not> ereal (real (Suc i)) \<le> u x"
   281         have "natfloor (real (u x) * 2 ^ i) * 2 = natfloor (real (u x) * 2 ^ i) * natfloor 2"
   282           by simp
   283         also have "\<dots> \<le> natfloor (real (u x) * 2 ^ i * 2)"
   284         proof cases
   285           assume "0 \<le> u x" then show ?thesis
   286             by (intro le_mult_natfloor) 
   287         next
   288           assume "\<not> 0 \<le> u x" then show ?thesis
   289             by (cases "u x") (auto simp: natfloor_neg mult_nonpos_nonneg)
   290         qed
   291         also have "\<dots> = natfloor (real (u x) * 2 ^ Suc i)"
   292           by (simp add: ac_simps)
   293         finally show "natfloor (real (u x) * 2 ^ i) * 2 \<le> natfloor (real (u x) * 2 ^ Suc i)" .
   294       qed simp
   295       then show "?g i x \<le> ?g (Suc i) x"
   296         by (auto simp: field_simps)
   297     qed
   298   next
   299     fix x show "(SUP i. ?g i x) = max 0 (u x)"
   300     proof (rule SUP_eqI)
   301       fix i show "?g i x \<le> max 0 (u x)" unfolding max_def f_def
   302         by (cases "u x") (auto simp: field_simps real_natfloor_le natfloor_neg
   303                                      mult_nonpos_nonneg mult_nonneg_nonneg)
   304     next
   305       fix y assume *: "\<And>i. i \<in> UNIV \<Longrightarrow> ?g i x \<le> y"
   306       have "\<And>i. 0 \<le> ?g i x" by (auto simp: divide_nonneg_pos)
   307       from order_trans[OF this *] have "0 \<le> y" by simp
   308       show "max 0 (u x) \<le> y"
   309       proof (cases y)
   310         case (real r)
   311         with * have *: "\<And>i. f x i \<le> r * 2^i" by (auto simp: divide_le_eq)
   312         from reals_Archimedean2[of r] * have "u x \<noteq> \<infinity>" by (auto simp: f_def) (metis less_le_not_le)
   313         then have "\<exists>p. max 0 (u x) = ereal p \<and> 0 \<le> p" by (cases "u x") (auto simp: max_def)
   314         then guess p .. note ux = this
   315         obtain m :: nat where m: "p < real m" using reals_Archimedean2 ..
   316         have "p \<le> r"
   317         proof (rule ccontr)
   318           assume "\<not> p \<le> r"
   319           with LIMSEQ_inverse_realpow_zero[unfolded LIMSEQ_iff, rule_format, of 2 "p - r"]
   320           obtain N where "\<forall>n\<ge>N. r * 2^n < p * 2^n - 1" by (auto simp: inverse_eq_divide field_simps)
   321           then have "r * 2^max N m < p * 2^max N m - 1" by simp
   322           moreover
   323           have "real (natfloor (p * 2 ^ max N m)) \<le> r * 2 ^ max N m"
   324             using *[of "max N m"] m unfolding real_f using ux
   325             by (cases "0 \<le> u x") (simp_all add: max_def mult_nonneg_nonneg split: split_if_asm)
   326           then have "p * 2 ^ max N m - 1 < r * 2 ^ max N m"
   327             by (metis real_natfloor_gt_diff_one less_le_trans)
   328           ultimately show False by auto
   329         qed
   330         then show "max 0 (u x) \<le> y" using real ux by simp
   331       qed (insert `0 \<le> y`, auto)
   332     qed
   333   qed (auto simp: divide_nonneg_pos)
   334 qed
   335 
   336 lemma borel_measurable_implies_simple_function_sequence':
   337   fixes u :: "'a \<Rightarrow> ereal"
   338   assumes u: "u \<in> borel_measurable M"
   339   obtains f where "\<And>i. simple_function M (f i)" "incseq f" "\<And>i. \<infinity> \<notin> range (f i)"
   340     "\<And>x. (SUP i. f i x) = max 0 (u x)" "\<And>i x. 0 \<le> f i x"
   341   using borel_measurable_implies_simple_function_sequence[OF u] by auto
   342 
   343 lemma simple_function_induct[consumes 1, case_names cong set mult add, induct set: simple_function]:
   344   fixes u :: "'a \<Rightarrow> ereal"
   345   assumes u: "simple_function M u"
   346   assumes cong: "\<And>f g. simple_function M f \<Longrightarrow> simple_function M g \<Longrightarrow> (AE x in M. f x = g x) \<Longrightarrow> P f \<Longrightarrow> P g"
   347   assumes set: "\<And>A. A \<in> sets M \<Longrightarrow> P (indicator A)"
   348   assumes mult: "\<And>u c. P u \<Longrightarrow> P (\<lambda>x. c * u x)"
   349   assumes add: "\<And>u v. P u \<Longrightarrow> P v \<Longrightarrow> P (\<lambda>x. v x + u x)"
   350   shows "P u"
   351 proof (rule cong)
   352   from AE_space show "AE x in M. (\<Sum>y\<in>u ` space M. y * indicator (u -` {y} \<inter> space M) x) = u x"
   353   proof eventually_elim
   354     fix x assume x: "x \<in> space M"
   355     from simple_function_indicator_representation[OF u x]
   356     show "(\<Sum>y\<in>u ` space M. y * indicator (u -` {y} \<inter> space M) x) = u x" ..
   357   qed
   358 next
   359   from u have "finite (u ` space M)"
   360     unfolding simple_function_def by auto
   361   then show "P (\<lambda>x. \<Sum>y\<in>u ` space M. y * indicator (u -` {y} \<inter> space M) x)"
   362   proof induct
   363     case empty show ?case
   364       using set[of "{}"] by (simp add: indicator_def[abs_def])
   365   qed (auto intro!: add mult set simple_functionD u)
   366 next
   367   show "simple_function M (\<lambda>x. (\<Sum>y\<in>u ` space M. y * indicator (u -` {y} \<inter> space M) x))"
   368     apply (subst simple_function_cong)
   369     apply (rule simple_function_indicator_representation[symmetric])
   370     apply (auto intro: u)
   371     done
   372 qed fact
   373 
   374 lemma simple_function_induct_nn[consumes 2, case_names cong set mult add]:
   375   fixes u :: "'a \<Rightarrow> ereal"
   376   assumes u: "simple_function M u" and nn: "\<And>x. 0 \<le> u x"
   377   assumes cong: "\<And>f g. simple_function M f \<Longrightarrow> simple_function M g \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> P f \<Longrightarrow> P g"
   378   assumes set: "\<And>A. A \<in> sets M \<Longrightarrow> P (indicator A)"
   379   assumes mult: "\<And>u c. 0 \<le> c \<Longrightarrow> simple_function M u \<Longrightarrow> (\<And>x. 0 \<le> u x) \<Longrightarrow> P u \<Longrightarrow> P (\<lambda>x. c * u x)"
   380   assumes add: "\<And>u v. simple_function M u \<Longrightarrow> (\<And>x. 0 \<le> u x) \<Longrightarrow> P u \<Longrightarrow> simple_function M v \<Longrightarrow> (\<And>x. 0 \<le> v x) \<Longrightarrow> P v \<Longrightarrow> P (\<lambda>x. v x + u x)"
   381   shows "P u"
   382 proof -
   383   show ?thesis
   384   proof (rule cong)
   385     fix x assume x: "x \<in> space M"
   386     from simple_function_indicator_representation[OF u x]
   387     show "(\<Sum>y\<in>u ` space M. y * indicator (u -` {y} \<inter> space M) x) = u x" ..
   388   next
   389     show "simple_function M (\<lambda>x. (\<Sum>y\<in>u ` space M. y * indicator (u -` {y} \<inter> space M) x))"
   390       apply (subst simple_function_cong)
   391       apply (rule simple_function_indicator_representation[symmetric])
   392       apply (auto intro: u)
   393       done
   394   next
   395     from u nn have "finite (u ` space M)" "\<And>x. x \<in> u ` space M \<Longrightarrow> 0 \<le> x"
   396       unfolding simple_function_def by auto
   397     then show "P (\<lambda>x. \<Sum>y\<in>u ` space M. y * indicator (u -` {y} \<inter> space M) x)"
   398     proof induct
   399       case empty show ?case
   400         using set[of "{}"] by (simp add: indicator_def[abs_def])
   401     qed (auto intro!: add mult set simple_functionD u setsum_nonneg
   402        simple_function_setsum)
   403   qed fact
   404 qed
   405 
   406 lemma borel_measurable_induct[consumes 2, case_names cong set mult add seq, induct set: borel_measurable]:
   407   fixes u :: "'a \<Rightarrow> ereal"
   408   assumes u: "u \<in> borel_measurable M" "\<And>x. 0 \<le> u x"
   409   assumes cong: "\<And>f g. f \<in> borel_measurable M \<Longrightarrow> g \<in> borel_measurable M \<Longrightarrow> (\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> P g \<Longrightarrow> P f"
   410   assumes set: "\<And>A. A \<in> sets M \<Longrightarrow> P (indicator A)"
   411   assumes mult: "\<And>u c. 0 \<le> c \<Longrightarrow> u \<in> borel_measurable M \<Longrightarrow> (\<And>x. 0 \<le> u x) \<Longrightarrow> P u \<Longrightarrow> P (\<lambda>x. c * u x)"
   412   assumes add: "\<And>u v. u \<in> borel_measurable M \<Longrightarrow> (\<And>x. 0 \<le> u x) \<Longrightarrow> P u \<Longrightarrow> v \<in> borel_measurable M \<Longrightarrow> (\<And>x. 0 \<le> v x) \<Longrightarrow> P v \<Longrightarrow> P (\<lambda>x. v x + u x)"
   413   assumes seq: "\<And>U. (\<And>i. U i \<in> borel_measurable M) \<Longrightarrow>  (\<And>i x. 0 \<le> U i x) \<Longrightarrow>  (\<And>i. P (U i)) \<Longrightarrow> incseq U \<Longrightarrow> P (SUP i. U i)"
   414   shows "P u"
   415   using u
   416 proof (induct rule: borel_measurable_implies_simple_function_sequence')
   417   fix U assume U: "\<And>i. simple_function M (U i)" "incseq U" "\<And>i. \<infinity> \<notin> range (U i)" and
   418     sup: "\<And>x. (SUP i. U i x) = max 0 (u x)" and nn: "\<And>i x. 0 \<le> U i x"
   419   have u_eq: "u = (SUP i. U i)"
   420     using nn u sup by (auto simp: max_def)
   421   
   422   from U have "\<And>i. U i \<in> borel_measurable M"
   423     by (simp add: borel_measurable_simple_function)
   424 
   425   show "P u"
   426     unfolding u_eq
   427   proof (rule seq)
   428     fix i show "P (U i)"
   429       using `simple_function M (U i)` nn
   430       by (induct rule: simple_function_induct_nn)
   431          (auto intro: set mult add cong dest!: borel_measurable_simple_function)
   432   qed fact+
   433 qed
   434 
   435 lemma simple_function_If_set:
   436   assumes sf: "simple_function M f" "simple_function M g" and A: "A \<inter> space M \<in> sets M"
   437   shows "simple_function M (\<lambda>x. if x \<in> A then f x else g x)" (is "simple_function M ?IF")
   438 proof -
   439   def F \<equiv> "\<lambda>x. f -` {x} \<inter> space M" and G \<equiv> "\<lambda>x. g -` {x} \<inter> space M"
   440   show ?thesis unfolding simple_function_def
   441   proof safe
   442     have "?IF ` space M \<subseteq> f ` space M \<union> g ` space M" by auto
   443     from finite_subset[OF this] assms
   444     show "finite (?IF ` space M)" unfolding simple_function_def by auto
   445   next
   446     fix x assume "x \<in> space M"
   447     then have *: "?IF -` {?IF x} \<inter> space M = (if x \<in> A
   448       then ((F (f x) \<inter> (A \<inter> space M)) \<union> (G (f x) - (G (f x) \<inter> (A \<inter> space M))))
   449       else ((F (g x) \<inter> (A \<inter> space M)) \<union> (G (g x) - (G (g x) \<inter> (A \<inter> space M)))))"
   450       using sets.sets_into_space[OF A] by (auto split: split_if_asm simp: G_def F_def)
   451     have [intro]: "\<And>x. F x \<in> sets M" "\<And>x. G x \<in> sets M"
   452       unfolding F_def G_def using sf[THEN simple_functionD(2)] by auto
   453     show "?IF -` {?IF x} \<inter> space M \<in> sets M" unfolding * using A by auto
   454   qed
   455 qed
   456 
   457 lemma simple_function_If:
   458   assumes sf: "simple_function M f" "simple_function M g" and P: "{x\<in>space M. P x} \<in> sets M"
   459   shows "simple_function M (\<lambda>x. if P x then f x else g x)"
   460 proof -
   461   have "{x\<in>space M. P x} = {x. P x} \<inter> space M" by auto
   462   with simple_function_If_set[OF sf, of "{x. P x}"] P show ?thesis by simp
   463 qed
   464 
   465 lemma simple_function_subalgebra:
   466   assumes "simple_function N f"
   467   and N_subalgebra: "sets N \<subseteq> sets M" "space N = space M"
   468   shows "simple_function M f"
   469   using assms unfolding simple_function_def by auto
   470 
   471 lemma simple_function_comp:
   472   assumes T: "T \<in> measurable M M'"
   473     and f: "simple_function M' f"
   474   shows "simple_function M (\<lambda>x. f (T x))"
   475 proof (intro simple_function_def[THEN iffD2] conjI ballI)
   476   have "(\<lambda>x. f (T x)) ` space M \<subseteq> f ` space M'"
   477     using T unfolding measurable_def by auto
   478   then show "finite ((\<lambda>x. f (T x)) ` space M)"
   479     using f unfolding simple_function_def by (auto intro: finite_subset)
   480   fix i assume i: "i \<in> (\<lambda>x. f (T x)) ` space M"
   481   then have "i \<in> f ` space M'"
   482     using T unfolding measurable_def by auto
   483   then have "f -` {i} \<inter> space M' \<in> sets M'"
   484     using f unfolding simple_function_def by auto
   485   then have "T -` (f -` {i} \<inter> space M') \<inter> space M \<in> sets M"
   486     using T unfolding measurable_def by auto
   487   also have "T -` (f -` {i} \<inter> space M') \<inter> space M = (\<lambda>x. f (T x)) -` {i} \<inter> space M"
   488     using T unfolding measurable_def by auto
   489   finally show "(\<lambda>x. f (T x)) -` {i} \<inter> space M \<in> sets M" .
   490 qed
   491 
   492 section "Simple integral"
   493 
   494 definition simple_integral :: "'a measure \<Rightarrow> ('a \<Rightarrow> ereal) \<Rightarrow> ereal" ("integral\<^sup>S") where
   495   "integral\<^sup>S M f = (\<Sum>x \<in> f ` space M. x * emeasure M (f -` {x} \<inter> space M))"
   496 
   497 syntax
   498   "_simple_integral" :: "pttrn \<Rightarrow> ereal \<Rightarrow> 'a measure \<Rightarrow> ereal" ("\<integral>\<^sup>S _. _ \<partial>_" [60,61] 110)
   499 
   500 translations
   501   "\<integral>\<^sup>S x. f \<partial>M" == "CONST simple_integral M (%x. f)"
   502 
   503 lemma simple_integral_cong:
   504   assumes "\<And>t. t \<in> space M \<Longrightarrow> f t = g t"
   505   shows "integral\<^sup>S M f = integral\<^sup>S M g"
   506 proof -
   507   have "f ` space M = g ` space M"
   508     "\<And>x. f -` {x} \<inter> space M = g -` {x} \<inter> space M"
   509     using assms by (auto intro!: image_eqI)
   510   thus ?thesis unfolding simple_integral_def by simp
   511 qed
   512 
   513 lemma simple_integral_const[simp]:
   514   "(\<integral>\<^sup>Sx. c \<partial>M) = c * (emeasure M) (space M)"
   515 proof (cases "space M = {}")
   516   case True thus ?thesis unfolding simple_integral_def by simp
   517 next
   518   case False hence "(\<lambda>x. c) ` space M = {c}" by auto
   519   thus ?thesis unfolding simple_integral_def by simp
   520 qed
   521 
   522 lemma simple_function_partition:
   523   assumes f: "simple_function M f" and g: "simple_function M g"
   524   shows "integral\<^sup>S M f = (\<Sum>A\<in>(\<lambda>x. f -` {f x} \<inter> g -` {g x} \<inter> space M) ` space M. the_elem (f`A) * (emeasure M) A)"
   525     (is "_ = setsum _ (?p ` space M)")
   526 proof-
   527   let ?sub = "\<lambda>x. ?p ` (f -` {x} \<inter> space M)"
   528   let ?SIGMA = "Sigma (f`space M) ?sub"
   529 
   530   have [intro]:
   531     "finite (f ` space M)"
   532     "finite (g ` space M)"
   533     using assms unfolding simple_function_def by simp_all
   534 
   535   { fix A
   536     have "?p ` (A \<inter> space M) \<subseteq>
   537       (\<lambda>(x,y). f -` {x} \<inter> g -` {y} \<inter> space M) ` (f`space M \<times> g`space M)"
   538       by auto
   539     hence "finite (?p ` (A \<inter> space M))"
   540       by (rule finite_subset) auto }
   541   note this[intro, simp]
   542   note sets = simple_function_measurable2[OF f g]
   543 
   544   { fix x assume "x \<in> space M"
   545     have "\<Union>(?sub (f x)) = (f -` {f x} \<inter> space M)" by auto
   546     with sets have "(emeasure M) (f -` {f x} \<inter> space M) = setsum (emeasure M) (?sub (f x))"
   547       by (subst setsum_emeasure) (auto simp: disjoint_family_on_def) }
   548   hence "integral\<^sup>S M f = (\<Sum>(x,A)\<in>?SIGMA. x * (emeasure M) A)"
   549     unfolding simple_integral_def using f sets
   550     by (subst setsum_Sigma[symmetric])
   551        (auto intro!: setsum_cong setsum_ereal_right_distrib)
   552   also have "\<dots> = (\<Sum>A\<in>?p ` space M. the_elem (f`A) * (emeasure M) A)"
   553   proof -
   554     have [simp]: "\<And>x. x \<in> space M \<Longrightarrow> f ` ?p x = {f x}" by (auto intro!: imageI)
   555     have "(\<lambda>A. (the_elem (f ` A), A)) ` ?p ` space M
   556       = (\<lambda>x. (f x, ?p x)) ` space M"
   557     proof safe
   558       fix x assume "x \<in> space M"
   559       thus "(f x, ?p x) \<in> (\<lambda>A. (the_elem (f`A), A)) ` ?p ` space M"
   560         by (auto intro!: image_eqI[of _ _ "?p x"])
   561     qed auto
   562     thus ?thesis
   563       apply (auto intro!: setsum_reindex_cong[of "\<lambda>A. (the_elem (f`A), A)"] inj_onI)
   564       apply (rule_tac x="xa" in image_eqI)
   565       by simp_all
   566   qed
   567   finally show ?thesis .
   568 qed
   569 
   570 lemma simple_integral_add[simp]:
   571   assumes f: "simple_function M f" and "\<And>x. 0 \<le> f x" and g: "simple_function M g" and "\<And>x. 0 \<le> g x"
   572   shows "(\<integral>\<^sup>Sx. f x + g x \<partial>M) = integral\<^sup>S M f + integral\<^sup>S M g"
   573 proof -
   574   { fix x let ?S = "g -` {g x} \<inter> f -` {f x} \<inter> space M"
   575     assume "x \<in> space M"
   576     hence "(\<lambda>a. f a + g a) ` ?S = {f x + g x}" "f ` ?S = {f x}" "g ` ?S = {g x}"
   577         "(\<lambda>x. (f x, g x)) -` {(f x, g x)} \<inter> space M = ?S"
   578       by auto }
   579   with assms show ?thesis
   580     unfolding
   581       simple_function_partition[OF simple_function_add[OF f g] simple_function_Pair[OF f g]]
   582       simple_function_partition[OF f g]
   583       simple_function_partition[OF g f]
   584     by (subst (3) Int_commute)
   585        (auto simp add: ereal_left_distrib setsum_addf[symmetric] intro!: setsum_cong)
   586 qed
   587 
   588 lemma simple_integral_setsum[simp]:
   589   assumes "\<And>i x. i \<in> P \<Longrightarrow> 0 \<le> f i x"
   590   assumes "\<And>i. i \<in> P \<Longrightarrow> simple_function M (f i)"
   591   shows "(\<integral>\<^sup>Sx. (\<Sum>i\<in>P. f i x) \<partial>M) = (\<Sum>i\<in>P. integral\<^sup>S M (f i))"
   592 proof cases
   593   assume "finite P"
   594   from this assms show ?thesis
   595     by induct (auto simp: simple_function_setsum simple_integral_add setsum_nonneg)
   596 qed auto
   597 
   598 lemma simple_integral_mult[simp]:
   599   assumes f: "simple_function M f" "\<And>x. 0 \<le> f x"
   600   shows "(\<integral>\<^sup>Sx. c * f x \<partial>M) = c * integral\<^sup>S M f"
   601 proof -
   602   note mult = simple_function_mult[OF simple_function_const[of _ c] f(1)]
   603   { fix x let ?S = "f -` {f x} \<inter> (\<lambda>x. c * f x) -` {c * f x} \<inter> space M"
   604     assume "x \<in> space M"
   605     hence "(\<lambda>x. c * f x) ` ?S = {c * f x}" "f ` ?S = {f x}"
   606       by auto }
   607   with assms show ?thesis
   608     unfolding simple_function_partition[OF mult f(1)]
   609               simple_function_partition[OF f(1) mult]
   610     by (subst setsum_ereal_right_distrib)
   611        (auto intro!: ereal_0_le_mult setsum_cong simp: mult_assoc)
   612 qed
   613 
   614 lemma simple_integral_mono_AE:
   615   assumes f: "simple_function M f" and g: "simple_function M g"
   616   and mono: "AE x in M. f x \<le> g x"
   617   shows "integral\<^sup>S M f \<le> integral\<^sup>S M g"
   618 proof -
   619   let ?S = "\<lambda>x. (g -` {g x} \<inter> space M) \<inter> (f -` {f x} \<inter> space M)"
   620   have *: "\<And>x. g -` {g x} \<inter> f -` {f x} \<inter> space M = ?S x"
   621     "\<And>x. f -` {f x} \<inter> g -` {g x} \<inter> space M = ?S x" by auto
   622   show ?thesis
   623     unfolding *
   624       simple_function_partition[OF f g]
   625       simple_function_partition[OF g f]
   626   proof (safe intro!: setsum_mono)
   627     fix x assume "x \<in> space M"
   628     then have *: "f ` ?S x = {f x}" "g ` ?S x = {g x}" by auto
   629     show "the_elem (f`?S x) * (emeasure M) (?S x) \<le> the_elem (g`?S x) * (emeasure M) (?S x)"
   630     proof (cases "f x \<le> g x")
   631       case True then show ?thesis
   632         using * assms(1,2)[THEN simple_functionD(2)]
   633         by (auto intro!: ereal_mult_right_mono)
   634     next
   635       case False
   636       obtain N where N: "{x\<in>space M. \<not> f x \<le> g x} \<subseteq> N" "N \<in> sets M" "(emeasure M) N = 0"
   637         using mono by (auto elim!: AE_E)
   638       have "?S x \<subseteq> N" using N `x \<in> space M` False by auto
   639       moreover have "?S x \<in> sets M" using assms
   640         by (rule_tac sets.Int) (auto intro!: simple_functionD)
   641       ultimately have "(emeasure M) (?S x) \<le> (emeasure M) N"
   642         using `N \<in> sets M` by (auto intro!: emeasure_mono)
   643       moreover have "0 \<le> (emeasure M) (?S x)"
   644         using assms(1,2)[THEN simple_functionD(2)] by auto
   645       ultimately have "(emeasure M) (?S x) = 0" using `(emeasure M) N = 0` by auto
   646       then show ?thesis by simp
   647     qed
   648   qed
   649 qed
   650 
   651 lemma simple_integral_mono:
   652   assumes "simple_function M f" and "simple_function M g"
   653   and mono: "\<And> x. x \<in> space M \<Longrightarrow> f x \<le> g x"
   654   shows "integral\<^sup>S M f \<le> integral\<^sup>S M g"
   655   using assms by (intro simple_integral_mono_AE) auto
   656 
   657 lemma simple_integral_cong_AE:
   658   assumes "simple_function M f" and "simple_function M g"
   659   and "AE x in M. f x = g x"
   660   shows "integral\<^sup>S M f = integral\<^sup>S M g"
   661   using assms by (auto simp: eq_iff intro!: simple_integral_mono_AE)
   662 
   663 lemma simple_integral_cong':
   664   assumes sf: "simple_function M f" "simple_function M g"
   665   and mea: "(emeasure M) {x\<in>space M. f x \<noteq> g x} = 0"
   666   shows "integral\<^sup>S M f = integral\<^sup>S M g"
   667 proof (intro simple_integral_cong_AE sf AE_I)
   668   show "(emeasure M) {x\<in>space M. f x \<noteq> g x} = 0" by fact
   669   show "{x \<in> space M. f x \<noteq> g x} \<in> sets M"
   670     using sf[THEN borel_measurable_simple_function] by auto
   671 qed simp
   672 
   673 lemma simple_integral_indicator:
   674   assumes "A \<in> sets M"
   675   assumes f: "simple_function M f"
   676   shows "(\<integral>\<^sup>Sx. f x * indicator A x \<partial>M) =
   677     (\<Sum>x \<in> f ` space M. x * (emeasure M) (f -` {x} \<inter> space M \<inter> A))"
   678 proof (cases "A = space M")
   679   case True
   680   then have "(\<integral>\<^sup>Sx. f x * indicator A x \<partial>M) = integral\<^sup>S M f"
   681     by (auto intro!: simple_integral_cong)
   682   with True show ?thesis by (simp add: simple_integral_def)
   683 next
   684   assume "A \<noteq> space M"
   685   then obtain x where x: "x \<in> space M" "x \<notin> A" using sets.sets_into_space[OF assms(1)] by auto
   686   have I: "(\<lambda>x. f x * indicator A x) ` space M = f ` A \<union> {0}" (is "?I ` _ = _")
   687   proof safe
   688     fix y assume "?I y \<notin> f ` A" hence "y \<notin> A" by auto thus "?I y = 0" by auto
   689   next
   690     fix y assume "y \<in> A" thus "f y \<in> ?I ` space M"
   691       using sets.sets_into_space[OF assms(1)] by (auto intro!: image_eqI[of _ _ y])
   692   next
   693     show "0 \<in> ?I ` space M" using x by (auto intro!: image_eqI[of _ _ x])
   694   qed
   695   have *: "(\<integral>\<^sup>Sx. f x * indicator A x \<partial>M) =
   696     (\<Sum>x \<in> f ` space M \<union> {0}. x * (emeasure M) (f -` {x} \<inter> space M \<inter> A))"
   697     unfolding simple_integral_def I
   698   proof (rule setsum_mono_zero_cong_left)
   699     show "finite (f ` space M \<union> {0})"
   700       using assms(2) unfolding simple_function_def by auto
   701     show "f ` A \<union> {0} \<subseteq> f`space M \<union> {0}"
   702       using sets.sets_into_space[OF assms(1)] by auto
   703     have "\<And>x. f x \<notin> f ` A \<Longrightarrow> f -` {f x} \<inter> space M \<inter> A = {}"
   704       by (auto simp: image_iff)
   705     thus "\<forall>i\<in>f ` space M \<union> {0} - (f ` A \<union> {0}).
   706       i * (emeasure M) (f -` {i} \<inter> space M \<inter> A) = 0" by auto
   707   next
   708     fix x assume "x \<in> f`A \<union> {0}"
   709     hence "x \<noteq> 0 \<Longrightarrow> ?I -` {x} \<inter> space M = f -` {x} \<inter> space M \<inter> A"
   710       by (auto simp: indicator_def split: split_if_asm)
   711     thus "x * (emeasure M) (?I -` {x} \<inter> space M) =
   712       x * (emeasure M) (f -` {x} \<inter> space M \<inter> A)" by (cases "x = 0") simp_all
   713   qed
   714   show ?thesis unfolding *
   715     using assms(2) unfolding simple_function_def
   716     by (auto intro!: setsum_mono_zero_cong_right)
   717 qed
   718 
   719 lemma simple_integral_indicator_only[simp]:
   720   assumes "A \<in> sets M"
   721   shows "integral\<^sup>S M (indicator A) = emeasure M A"
   722 proof cases
   723   assume "space M = {}" hence "A = {}" using sets.sets_into_space[OF assms] by auto
   724   thus ?thesis unfolding simple_integral_def using `space M = {}` by auto
   725 next
   726   assume "space M \<noteq> {}" hence "(\<lambda>x. 1) ` space M = {1::ereal}" by auto
   727   thus ?thesis
   728     using simple_integral_indicator[OF assms simple_function_const[of _ 1]]
   729     using sets.sets_into_space[OF assms]
   730     by (auto intro!: arg_cong[where f="(emeasure M)"])
   731 qed
   732 
   733 lemma simple_integral_null_set:
   734   assumes "simple_function M u" "\<And>x. 0 \<le> u x" and "N \<in> null_sets M"
   735   shows "(\<integral>\<^sup>Sx. u x * indicator N x \<partial>M) = 0"
   736 proof -
   737   have "AE x in M. indicator N x = (0 :: ereal)"
   738     using `N \<in> null_sets M` by (auto simp: indicator_def intro!: AE_I[of _ _ N])
   739   then have "(\<integral>\<^sup>Sx. u x * indicator N x \<partial>M) = (\<integral>\<^sup>Sx. 0 \<partial>M)"
   740     using assms apply (intro simple_integral_cong_AE) by auto
   741   then show ?thesis by simp
   742 qed
   743 
   744 lemma simple_integral_cong_AE_mult_indicator:
   745   assumes sf: "simple_function M f" and eq: "AE x in M. x \<in> S" and "S \<in> sets M"
   746   shows "integral\<^sup>S M f = (\<integral>\<^sup>Sx. f x * indicator S x \<partial>M)"
   747   using assms by (intro simple_integral_cong_AE) auto
   748 
   749 lemma simple_integral_cmult_indicator:
   750   assumes A: "A \<in> sets M"
   751   shows "(\<integral>\<^sup>Sx. c * indicator A x \<partial>M) = c * (emeasure M) A"
   752   using simple_integral_mult[OF simple_function_indicator[OF A]]
   753   unfolding simple_integral_indicator_only[OF A] by simp
   754 
   755 lemma simple_integral_positive:
   756   assumes f: "simple_function M f" and ae: "AE x in M. 0 \<le> f x"
   757   shows "0 \<le> integral\<^sup>S M f"
   758 proof -
   759   have "integral\<^sup>S M (\<lambda>x. 0) \<le> integral\<^sup>S M f"
   760     using simple_integral_mono_AE[OF _ f ae] by auto
   761   then show ?thesis by simp
   762 qed
   763 
   764 section "Continuous positive integration"
   765 
   766 definition positive_integral :: "'a measure \<Rightarrow> ('a \<Rightarrow> ereal) \<Rightarrow> ereal" ("integral\<^sup>P") where
   767   "integral\<^sup>P M f = (SUP g : {g. simple_function M g \<and> g \<le> max 0 \<circ> f}. integral\<^sup>S M g)"
   768 
   769 syntax
   770   "_positive_integral" :: "pttrn \<Rightarrow> ereal \<Rightarrow> 'a measure \<Rightarrow> ereal" ("\<integral>\<^sup>+ _. _ \<partial>_" [60,61] 110)
   771 
   772 translations
   773   "\<integral>\<^sup>+ x. f \<partial>M" == "CONST positive_integral M (%x. f)"
   774 
   775 lemma positive_integral_positive:
   776   "0 \<le> integral\<^sup>P M f"
   777   by (auto intro!: SUP_upper2[of "\<lambda>x. 0"] simp: positive_integral_def le_fun_def)
   778 
   779 lemma positive_integral_not_MInfty[simp]: "integral\<^sup>P M f \<noteq> -\<infinity>"
   780   using positive_integral_positive[of M f] by auto
   781 
   782 lemma positive_integral_def_finite:
   783   "integral\<^sup>P M f = (SUP g : {g. simple_function M g \<and> g \<le> max 0 \<circ> f \<and> range g \<subseteq> {0 ..< \<infinity>}}. integral\<^sup>S M g)"
   784     (is "_ = SUPR ?A ?f")
   785   unfolding positive_integral_def
   786 proof (safe intro!: antisym SUP_least)
   787   fix g assume g: "simple_function M g" "g \<le> max 0 \<circ> f"
   788   let ?G = "{x \<in> space M. \<not> g x \<noteq> \<infinity>}"
   789   note gM = g(1)[THEN borel_measurable_simple_function]
   790   have \<mu>_G_pos: "0 \<le> (emeasure M) ?G" using gM by auto
   791   let ?g = "\<lambda>y x. if g x = \<infinity> then y else max 0 (g x)"
   792   from g gM have g_in_A: "\<And>y. 0 \<le> y \<Longrightarrow> y \<noteq> \<infinity> \<Longrightarrow> ?g y \<in> ?A"
   793     apply (safe intro!: simple_function_max simple_function_If)
   794     apply (force simp: max_def le_fun_def split: split_if_asm)+
   795     done
   796   show "integral\<^sup>S M g \<le> SUPR ?A ?f"
   797   proof cases
   798     have g0: "?g 0 \<in> ?A" by (intro g_in_A) auto
   799     assume "(emeasure M) ?G = 0"
   800     with gM have "AE x in M. x \<notin> ?G"
   801       by (auto simp add: AE_iff_null intro!: null_setsI)
   802     with gM g show ?thesis
   803       by (intro SUP_upper2[OF g0] simple_integral_mono_AE)
   804          (auto simp: max_def intro!: simple_function_If)
   805   next
   806     assume \<mu>_G: "(emeasure M) ?G \<noteq> 0"
   807     have "SUPR ?A (integral\<^sup>S M) = \<infinity>"
   808     proof (intro SUP_PInfty)
   809       fix n :: nat
   810       let ?y = "ereal (real n) / (if (emeasure M) ?G = \<infinity> then 1 else (emeasure M) ?G)"
   811       have "0 \<le> ?y" "?y \<noteq> \<infinity>" using \<mu>_G \<mu>_G_pos by (auto simp: ereal_divide_eq)
   812       then have "?g ?y \<in> ?A" by (rule g_in_A)
   813       have "real n \<le> ?y * (emeasure M) ?G"
   814         using \<mu>_G \<mu>_G_pos by (cases "(emeasure M) ?G") (auto simp: field_simps)
   815       also have "\<dots> = (\<integral>\<^sup>Sx. ?y * indicator ?G x \<partial>M)"
   816         using `0 \<le> ?y` `?g ?y \<in> ?A` gM
   817         by (subst simple_integral_cmult_indicator) auto
   818       also have "\<dots> \<le> integral\<^sup>S M (?g ?y)" using `?g ?y \<in> ?A` gM
   819         by (intro simple_integral_mono) auto
   820       finally show "\<exists>i\<in>?A. real n \<le> integral\<^sup>S M i"
   821         using `?g ?y \<in> ?A` by blast
   822     qed
   823     then show ?thesis by simp
   824   qed
   825 qed (auto intro: SUP_upper)
   826 
   827 lemma positive_integral_mono_AE:
   828   assumes ae: "AE x in M. u x \<le> v x" shows "integral\<^sup>P M u \<le> integral\<^sup>P M v"
   829   unfolding positive_integral_def
   830 proof (safe intro!: SUP_mono)
   831   fix n assume n: "simple_function M n" "n \<le> max 0 \<circ> u"
   832   from ae[THEN AE_E] guess N . note N = this
   833   then have ae_N: "AE x in M. x \<notin> N" by (auto intro: AE_not_in)
   834   let ?n = "\<lambda>x. n x * indicator (space M - N) x"
   835   have "AE x in M. n x \<le> ?n x" "simple_function M ?n"
   836     using n N ae_N by auto
   837   moreover
   838   { fix x have "?n x \<le> max 0 (v x)"
   839     proof cases
   840       assume x: "x \<in> space M - N"
   841       with N have "u x \<le> v x" by auto
   842       with n(2)[THEN le_funD, of x] x show ?thesis
   843         by (auto simp: max_def split: split_if_asm)
   844     qed simp }
   845   then have "?n \<le> max 0 \<circ> v" by (auto simp: le_funI)
   846   moreover have "integral\<^sup>S M n \<le> integral\<^sup>S M ?n"
   847     using ae_N N n by (auto intro!: simple_integral_mono_AE)
   848   ultimately show "\<exists>m\<in>{g. simple_function M g \<and> g \<le> max 0 \<circ> v}. integral\<^sup>S M n \<le> integral\<^sup>S M m"
   849     by force
   850 qed
   851 
   852 lemma positive_integral_mono:
   853   "(\<And>x. x \<in> space M \<Longrightarrow> u x \<le> v x) \<Longrightarrow> integral\<^sup>P M u \<le> integral\<^sup>P M v"
   854   by (auto intro: positive_integral_mono_AE)
   855 
   856 lemma positive_integral_cong_AE:
   857   "AE x in M. u x = v x \<Longrightarrow> integral\<^sup>P M u = integral\<^sup>P M v"
   858   by (auto simp: eq_iff intro!: positive_integral_mono_AE)
   859 
   860 lemma positive_integral_cong:
   861   "(\<And>x. x \<in> space M \<Longrightarrow> u x = v x) \<Longrightarrow> integral\<^sup>P M u = integral\<^sup>P M v"
   862   by (auto intro: positive_integral_cong_AE)
   863 
   864 lemma positive_integral_eq_simple_integral:
   865   assumes f: "simple_function M f" "\<And>x. 0 \<le> f x" shows "integral\<^sup>P M f = integral\<^sup>S M f"
   866 proof -
   867   let ?f = "\<lambda>x. f x * indicator (space M) x"
   868   have f': "simple_function M ?f" using f by auto
   869   with f(2) have [simp]: "max 0 \<circ> ?f = ?f"
   870     by (auto simp: fun_eq_iff max_def split: split_indicator)
   871   have "integral\<^sup>P M ?f \<le> integral\<^sup>S M ?f" using f'
   872     by (force intro!: SUP_least simple_integral_mono simp: le_fun_def positive_integral_def)
   873   moreover have "integral\<^sup>S M ?f \<le> integral\<^sup>P M ?f"
   874     unfolding positive_integral_def
   875     using f' by (auto intro!: SUP_upper)
   876   ultimately show ?thesis
   877     by (simp cong: positive_integral_cong simple_integral_cong)
   878 qed
   879 
   880 lemma positive_integral_eq_simple_integral_AE:
   881   assumes f: "simple_function M f" "AE x in M. 0 \<le> f x" shows "integral\<^sup>P M f = integral\<^sup>S M f"
   882 proof -
   883   have "AE x in M. f x = max 0 (f x)" using f by (auto split: split_max)
   884   with f have "integral\<^sup>P M f = integral\<^sup>S M (\<lambda>x. max 0 (f x))"
   885     by (simp cong: positive_integral_cong_AE simple_integral_cong_AE
   886              add: positive_integral_eq_simple_integral)
   887   with assms show ?thesis
   888     by (auto intro!: simple_integral_cong_AE split: split_max)
   889 qed
   890 
   891 lemma positive_integral_SUP_approx:
   892   assumes f: "incseq f" "\<And>i. f i \<in> borel_measurable M" "\<And>i x. 0 \<le> f i x"
   893   and u: "simple_function M u" "u \<le> (SUP i. f i)" "u`space M \<subseteq> {0..<\<infinity>}"
   894   shows "integral\<^sup>S M u \<le> (SUP i. integral\<^sup>P M (f i))" (is "_ \<le> ?S")
   895 proof (rule ereal_le_mult_one_interval)
   896   have "0 \<le> (SUP i. integral\<^sup>P M (f i))"
   897     using f(3) by (auto intro!: SUP_upper2 positive_integral_positive)
   898   then show "(SUP i. integral\<^sup>P M (f i)) \<noteq> -\<infinity>" by auto
   899   have u_range: "\<And>x. x \<in> space M \<Longrightarrow> 0 \<le> u x \<and> u x \<noteq> \<infinity>"
   900     using u(3) by auto
   901   fix a :: ereal assume "0 < a" "a < 1"
   902   hence "a \<noteq> 0" by auto
   903   let ?B = "\<lambda>i. {x \<in> space M. a * u x \<le> f i x}"
   904   have B: "\<And>i. ?B i \<in> sets M"
   905     using f `simple_function M u` by auto
   906 
   907   let ?uB = "\<lambda>i x. u x * indicator (?B i) x"
   908 
   909   { fix i have "?B i \<subseteq> ?B (Suc i)"
   910     proof safe
   911       fix i x assume "a * u x \<le> f i x"
   912       also have "\<dots> \<le> f (Suc i) x"
   913         using `incseq f`[THEN incseq_SucD] unfolding le_fun_def by auto
   914       finally show "a * u x \<le> f (Suc i) x" .
   915     qed }
   916   note B_mono = this
   917 
   918   note B_u = sets.Int[OF u(1)[THEN simple_functionD(2)] B]
   919 
   920   let ?B' = "\<lambda>i n. (u -` {i} \<inter> space M) \<inter> ?B n"
   921   have measure_conv: "\<And>i. (emeasure M) (u -` {i} \<inter> space M) = (SUP n. (emeasure M) (?B' i n))"
   922   proof -
   923     fix i
   924     have 1: "range (?B' i) \<subseteq> sets M" using B_u by auto
   925     have 2: "incseq (?B' i)" using B_mono by (auto intro!: incseq_SucI)
   926     have "(\<Union>n. ?B' i n) = u -` {i} \<inter> space M"
   927     proof safe
   928       fix x i assume x: "x \<in> space M"
   929       show "x \<in> (\<Union>i. ?B' (u x) i)"
   930       proof cases
   931         assume "u x = 0" thus ?thesis using `x \<in> space M` f(3) by simp
   932       next
   933         assume "u x \<noteq> 0"
   934         with `a < 1` u_range[OF `x \<in> space M`]
   935         have "a * u x < 1 * u x"
   936           by (intro ereal_mult_strict_right_mono) (auto simp: image_iff)
   937         also have "\<dots> \<le> (SUP i. f i x)" using u(2) by (auto simp: le_fun_def)
   938         finally obtain i where "a * u x < f i x" unfolding SUP_def
   939           by (auto simp add: less_SUP_iff)
   940         hence "a * u x \<le> f i x" by auto
   941         thus ?thesis using `x \<in> space M` by auto
   942       qed
   943     qed
   944     then show "?thesis i" using SUP_emeasure_incseq[OF 1 2] by simp
   945   qed
   946 
   947   have "integral\<^sup>S M u = (SUP i. integral\<^sup>S M (?uB i))"
   948     unfolding simple_integral_indicator[OF B `simple_function M u`]
   949   proof (subst SUPR_ereal_setsum, safe)
   950     fix x n assume "x \<in> space M"
   951     with u_range show "incseq (\<lambda>i. u x * (emeasure M) (?B' (u x) i))" "\<And>i. 0 \<le> u x * (emeasure M) (?B' (u x) i)"
   952       using B_mono B_u by (auto intro!: emeasure_mono ereal_mult_left_mono incseq_SucI simp: ereal_zero_le_0_iff)
   953   next
   954     show "integral\<^sup>S M u = (\<Sum>i\<in>u ` space M. SUP n. i * (emeasure M) (?B' i n))"
   955       using measure_conv u_range B_u unfolding simple_integral_def
   956       by (auto intro!: setsum_cong SUPR_ereal_cmult[symmetric])
   957   qed
   958   moreover
   959   have "a * (SUP i. integral\<^sup>S M (?uB i)) \<le> ?S"
   960     apply (subst SUPR_ereal_cmult[symmetric])
   961   proof (safe intro!: SUP_mono bexI)
   962     fix i
   963     have "a * integral\<^sup>S M (?uB i) = (\<integral>\<^sup>Sx. a * ?uB i x \<partial>M)"
   964       using B `simple_function M u` u_range
   965       by (subst simple_integral_mult) (auto split: split_indicator)
   966     also have "\<dots> \<le> integral\<^sup>P M (f i)"
   967     proof -
   968       have *: "simple_function M (\<lambda>x. a * ?uB i x)" using B `0 < a` u(1) by auto
   969       show ?thesis using f(3) * u_range `0 < a`
   970         by (subst positive_integral_eq_simple_integral[symmetric])
   971            (auto intro!: positive_integral_mono split: split_indicator)
   972     qed
   973     finally show "a * integral\<^sup>S M (?uB i) \<le> integral\<^sup>P M (f i)"
   974       by auto
   975   next
   976     fix i show "0 \<le> \<integral>\<^sup>S x. ?uB i x \<partial>M" using B `0 < a` u(1) u_range
   977       by (intro simple_integral_positive) (auto split: split_indicator)
   978   qed (insert `0 < a`, auto)
   979   ultimately show "a * integral\<^sup>S M u \<le> ?S" by simp
   980 qed
   981 
   982 lemma incseq_positive_integral:
   983   assumes "incseq f" shows "incseq (\<lambda>i. integral\<^sup>P M (f i))"
   984 proof -
   985   have "\<And>i x. f i x \<le> f (Suc i) x"
   986     using assms by (auto dest!: incseq_SucD simp: le_fun_def)
   987   then show ?thesis
   988     by (auto intro!: incseq_SucI positive_integral_mono)
   989 qed
   990 
   991 text {* Beppo-Levi monotone convergence theorem *}
   992 lemma positive_integral_monotone_convergence_SUP:
   993   assumes f: "incseq f" "\<And>i. f i \<in> borel_measurable M" "\<And>i x. 0 \<le> f i x"
   994   shows "(\<integral>\<^sup>+ x. (SUP i. f i x) \<partial>M) = (SUP i. integral\<^sup>P M (f i))"
   995 proof (rule antisym)
   996   show "(SUP j. integral\<^sup>P M (f j)) \<le> (\<integral>\<^sup>+ x. (SUP i. f i x) \<partial>M)"
   997     by (auto intro!: SUP_least SUP_upper positive_integral_mono)
   998 next
   999   show "(\<integral>\<^sup>+ x. (SUP i. f i x) \<partial>M) \<le> (SUP j. integral\<^sup>P M (f j))"
  1000     unfolding positive_integral_def_finite[of _ "\<lambda>x. SUP i. f i x"]
  1001   proof (safe intro!: SUP_least)
  1002     fix g assume g: "simple_function M g"
  1003       and *: "g \<le> max 0 \<circ> (\<lambda>x. SUP i. f i x)" "range g \<subseteq> {0..<\<infinity>}"
  1004     then have "\<And>x. 0 \<le> (SUP i. f i x)" and g': "g`space M \<subseteq> {0..<\<infinity>}"
  1005       using f by (auto intro!: SUP_upper2)
  1006     with * show "integral\<^sup>S M g \<le> (SUP j. integral\<^sup>P M (f j))"
  1007       by (intro  positive_integral_SUP_approx[OF f g _ g'])
  1008          (auto simp: le_fun_def max_def)
  1009   qed
  1010 qed
  1011 
  1012 lemma positive_integral_monotone_convergence_SUP_AE:
  1013   assumes f: "\<And>i. AE x in M. f i x \<le> f (Suc i) x \<and> 0 \<le> f i x" "\<And>i. f i \<in> borel_measurable M"
  1014   shows "(\<integral>\<^sup>+ x. (SUP i. f i x) \<partial>M) = (SUP i. integral\<^sup>P M (f i))"
  1015 proof -
  1016   from f have "AE x in M. \<forall>i. f i x \<le> f (Suc i) x \<and> 0 \<le> f i x"
  1017     by (simp add: AE_all_countable)
  1018   from this[THEN AE_E] guess N . note N = this
  1019   let ?f = "\<lambda>i x. if x \<in> space M - N then f i x else 0"
  1020   have f_eq: "AE x in M. \<forall>i. ?f i x = f i x" using N by (auto intro!: AE_I[of _ _ N])
  1021   then have "(\<integral>\<^sup>+ x. (SUP i. f i x) \<partial>M) = (\<integral>\<^sup>+ x. (SUP i. ?f i x) \<partial>M)"
  1022     by (auto intro!: positive_integral_cong_AE)
  1023   also have "\<dots> = (SUP i. (\<integral>\<^sup>+ x. ?f i x \<partial>M))"
  1024   proof (rule positive_integral_monotone_convergence_SUP)
  1025     show "incseq ?f" using N(1) by (force intro!: incseq_SucI le_funI)
  1026     { fix i show "(\<lambda>x. if x \<in> space M - N then f i x else 0) \<in> borel_measurable M"
  1027         using f N(3) by (intro measurable_If_set) auto
  1028       fix x show "0 \<le> ?f i x"
  1029         using N(1) by auto }
  1030   qed
  1031   also have "\<dots> = (SUP i. (\<integral>\<^sup>+ x. f i x \<partial>M))"
  1032     using f_eq by (force intro!: arg_cong[where f="SUPR UNIV"] positive_integral_cong_AE ext)
  1033   finally show ?thesis .
  1034 qed
  1035 
  1036 lemma positive_integral_monotone_convergence_SUP_AE_incseq:
  1037   assumes f: "incseq f" "\<And>i. AE x in M. 0 \<le> f i x" and borel: "\<And>i. f i \<in> borel_measurable M"
  1038   shows "(\<integral>\<^sup>+ x. (SUP i. f i x) \<partial>M) = (SUP i. integral\<^sup>P M (f i))"
  1039   using f[unfolded incseq_Suc_iff le_fun_def]
  1040   by (intro positive_integral_monotone_convergence_SUP_AE[OF _ borel])
  1041      auto
  1042 
  1043 lemma positive_integral_monotone_convergence_simple:
  1044   assumes f: "incseq f" "\<And>i x. 0 \<le> f i x" "\<And>i. simple_function M (f i)"
  1045   shows "(SUP i. integral\<^sup>S M (f i)) = (\<integral>\<^sup>+x. (SUP i. f i x) \<partial>M)"
  1046   using assms unfolding positive_integral_monotone_convergence_SUP[OF f(1)
  1047     f(3)[THEN borel_measurable_simple_function] f(2)]
  1048   by (auto intro!: positive_integral_eq_simple_integral[symmetric] arg_cong[where f="SUPR UNIV"] ext)
  1049 
  1050 lemma positive_integral_max_0:
  1051   "(\<integral>\<^sup>+x. max 0 (f x) \<partial>M) = integral\<^sup>P M f"
  1052   by (simp add: le_fun_def positive_integral_def)
  1053 
  1054 lemma positive_integral_cong_pos:
  1055   assumes "\<And>x. x \<in> space M \<Longrightarrow> f x \<le> 0 \<and> g x \<le> 0 \<or> f x = g x"
  1056   shows "integral\<^sup>P M f = integral\<^sup>P M g"
  1057 proof -
  1058   have "integral\<^sup>P M (\<lambda>x. max 0 (f x)) = integral\<^sup>P M (\<lambda>x. max 0 (g x))"
  1059   proof (intro positive_integral_cong)
  1060     fix x assume "x \<in> space M"
  1061     from assms[OF this] show "max 0 (f x) = max 0 (g x)"
  1062       by (auto split: split_max)
  1063   qed
  1064   then show ?thesis by (simp add: positive_integral_max_0)
  1065 qed
  1066 
  1067 lemma SUP_simple_integral_sequences:
  1068   assumes f: "incseq f" "\<And>i x. 0 \<le> f i x" "\<And>i. simple_function M (f i)"
  1069   and g: "incseq g" "\<And>i x. 0 \<le> g i x" "\<And>i. simple_function M (g i)"
  1070   and eq: "AE x in M. (SUP i. f i x) = (SUP i. g i x)"
  1071   shows "(SUP i. integral\<^sup>S M (f i)) = (SUP i. integral\<^sup>S M (g i))"
  1072     (is "SUPR _ ?F = SUPR _ ?G")
  1073 proof -
  1074   have "(SUP i. integral\<^sup>S M (f i)) = (\<integral>\<^sup>+x. (SUP i. f i x) \<partial>M)"
  1075     using f by (rule positive_integral_monotone_convergence_simple)
  1076   also have "\<dots> = (\<integral>\<^sup>+x. (SUP i. g i x) \<partial>M)"
  1077     unfolding eq[THEN positive_integral_cong_AE] ..
  1078   also have "\<dots> = (SUP i. ?G i)"
  1079     using g by (rule positive_integral_monotone_convergence_simple[symmetric])
  1080   finally show ?thesis by simp
  1081 qed
  1082 
  1083 lemma positive_integral_const[simp]:
  1084   "0 \<le> c \<Longrightarrow> (\<integral>\<^sup>+ x. c \<partial>M) = c * (emeasure M) (space M)"
  1085   by (subst positive_integral_eq_simple_integral) auto
  1086 
  1087 lemma positive_integral_linear:
  1088   assumes f: "f \<in> borel_measurable M" "\<And>x. 0 \<le> f x" and "0 \<le> a"
  1089   and g: "g \<in> borel_measurable M" "\<And>x. 0 \<le> g x"
  1090   shows "(\<integral>\<^sup>+ x. a * f x + g x \<partial>M) = a * integral\<^sup>P M f + integral\<^sup>P M g"
  1091     (is "integral\<^sup>P M ?L = _")
  1092 proof -
  1093   from borel_measurable_implies_simple_function_sequence'[OF f(1)] guess u .
  1094   note u = positive_integral_monotone_convergence_simple[OF this(2,5,1)] this
  1095   from borel_measurable_implies_simple_function_sequence'[OF g(1)] guess v .
  1096   note v = positive_integral_monotone_convergence_simple[OF this(2,5,1)] this
  1097   let ?L' = "\<lambda>i x. a * u i x + v i x"
  1098 
  1099   have "?L \<in> borel_measurable M" using assms by auto
  1100   from borel_measurable_implies_simple_function_sequence'[OF this] guess l .
  1101   note l = positive_integral_monotone_convergence_simple[OF this(2,5,1)] this
  1102 
  1103   have inc: "incseq (\<lambda>i. a * integral\<^sup>S M (u i))" "incseq (\<lambda>i. integral\<^sup>S M (v i))"
  1104     using u v `0 \<le> a`
  1105     by (auto simp: incseq_Suc_iff le_fun_def
  1106              intro!: add_mono ereal_mult_left_mono simple_integral_mono)
  1107   have pos: "\<And>i. 0 \<le> integral\<^sup>S M (u i)" "\<And>i. 0 \<le> integral\<^sup>S M (v i)" "\<And>i. 0 \<le> a * integral\<^sup>S M (u i)"
  1108     using u v `0 \<le> a` by (auto simp: simple_integral_positive)
  1109   { fix i from pos[of i] have "a * integral\<^sup>S M (u i) \<noteq> -\<infinity>" "integral\<^sup>S M (v i) \<noteq> -\<infinity>"
  1110       by (auto split: split_if_asm) }
  1111   note not_MInf = this
  1112 
  1113   have l': "(SUP i. integral\<^sup>S M (l i)) = (SUP i. integral\<^sup>S M (?L' i))"
  1114   proof (rule SUP_simple_integral_sequences[OF l(3,6,2)])
  1115     show "incseq ?L'" "\<And>i x. 0 \<le> ?L' i x" "\<And>i. simple_function M (?L' i)"
  1116       using u v  `0 \<le> a` unfolding incseq_Suc_iff le_fun_def
  1117       by (auto intro!: add_mono ereal_mult_left_mono ereal_add_nonneg_nonneg)
  1118     { fix x
  1119       { fix i have "a * u i x \<noteq> -\<infinity>" "v i x \<noteq> -\<infinity>" "u i x \<noteq> -\<infinity>" using `0 \<le> a` u(6)[of i x] v(6)[of i x]
  1120           by auto }
  1121       then have "(SUP i. a * u i x + v i x) = a * (SUP i. u i x) + (SUP i. v i x)"
  1122         using `0 \<le> a` u(3) v(3) u(6)[of _ x] v(6)[of _ x]
  1123         by (subst SUPR_ereal_cmult[symmetric, OF u(6) `0 \<le> a`])
  1124            (auto intro!: SUPR_ereal_add
  1125                  simp: incseq_Suc_iff le_fun_def add_mono ereal_mult_left_mono ereal_add_nonneg_nonneg) }
  1126     then show "AE x in M. (SUP i. l i x) = (SUP i. ?L' i x)"
  1127       unfolding l(5) using `0 \<le> a` u(5) v(5) l(5) f(2) g(2)
  1128       by (intro AE_I2) (auto split: split_max simp add: ereal_add_nonneg_nonneg)
  1129   qed
  1130   also have "\<dots> = (SUP i. a * integral\<^sup>S M (u i) + integral\<^sup>S M (v i))"
  1131     using u(2, 6) v(2, 6) `0 \<le> a` by (auto intro!: arg_cong[where f="SUPR UNIV"] ext)
  1132   finally have "(\<integral>\<^sup>+ x. max 0 (a * f x + g x) \<partial>M) = a * (\<integral>\<^sup>+x. max 0 (f x) \<partial>M) + (\<integral>\<^sup>+x. max 0 (g x) \<partial>M)"
  1133     unfolding l(5)[symmetric] u(5)[symmetric] v(5)[symmetric]
  1134     unfolding l(1)[symmetric] u(1)[symmetric] v(1)[symmetric]
  1135     apply (subst SUPR_ereal_cmult[symmetric, OF pos(1) `0 \<le> a`])
  1136     apply (subst SUPR_ereal_add[symmetric, OF inc not_MInf]) .
  1137   then show ?thesis by (simp add: positive_integral_max_0)
  1138 qed
  1139 
  1140 lemma positive_integral_cmult:
  1141   assumes f: "f \<in> borel_measurable M" "0 \<le> c"
  1142   shows "(\<integral>\<^sup>+ x. c * f x \<partial>M) = c * integral\<^sup>P M f"
  1143 proof -
  1144   have [simp]: "\<And>x. c * max 0 (f x) = max 0 (c * f x)" using `0 \<le> c`
  1145     by (auto split: split_max simp: ereal_zero_le_0_iff)
  1146   have "(\<integral>\<^sup>+ x. c * f x \<partial>M) = (\<integral>\<^sup>+ x. c * max 0 (f x) \<partial>M)"
  1147     by (simp add: positive_integral_max_0)
  1148   then show ?thesis
  1149     using positive_integral_linear[OF _ _ `0 \<le> c`, of "\<lambda>x. max 0 (f x)" _ "\<lambda>x. 0"] f
  1150     by (auto simp: positive_integral_max_0)
  1151 qed
  1152 
  1153 lemma positive_integral_multc:
  1154   assumes "f \<in> borel_measurable M" "0 \<le> c"
  1155   shows "(\<integral>\<^sup>+ x. f x * c \<partial>M) = integral\<^sup>P M f * c"
  1156   unfolding mult_commute[of _ c] positive_integral_cmult[OF assms] by simp
  1157 
  1158 lemma positive_integral_indicator[simp]:
  1159   "A \<in> sets M \<Longrightarrow> (\<integral>\<^sup>+ x. indicator A x\<partial>M) = (emeasure M) A"
  1160   by (subst positive_integral_eq_simple_integral)
  1161      (auto simp: simple_integral_indicator)
  1162 
  1163 lemma positive_integral_cmult_indicator:
  1164   "0 \<le> c \<Longrightarrow> A \<in> sets M \<Longrightarrow> (\<integral>\<^sup>+ x. c * indicator A x \<partial>M) = c * (emeasure M) A"
  1165   by (subst positive_integral_eq_simple_integral)
  1166      (auto simp: simple_function_indicator simple_integral_indicator)
  1167 
  1168 lemma positive_integral_indicator':
  1169   assumes [measurable]: "A \<inter> space M \<in> sets M"
  1170   shows "(\<integral>\<^sup>+ x. indicator A x \<partial>M) = emeasure M (A \<inter> space M)"
  1171 proof -
  1172   have "(\<integral>\<^sup>+ x. indicator A x \<partial>M) = (\<integral>\<^sup>+ x. indicator (A \<inter> space M) x \<partial>M)"
  1173     by (intro positive_integral_cong) (simp split: split_indicator)
  1174   also have "\<dots> = emeasure M (A \<inter> space M)"
  1175     by simp
  1176   finally show ?thesis .
  1177 qed
  1178 
  1179 lemma positive_integral_add:
  1180   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
  1181   and g: "g \<in> borel_measurable M" "AE x in M. 0 \<le> g x"
  1182   shows "(\<integral>\<^sup>+ x. f x + g x \<partial>M) = integral\<^sup>P M f + integral\<^sup>P M g"
  1183 proof -
  1184   have ae: "AE x in M. max 0 (f x) + max 0 (g x) = max 0 (f x + g x)"
  1185     using assms by (auto split: split_max simp: ereal_add_nonneg_nonneg)
  1186   have "(\<integral>\<^sup>+ x. f x + g x \<partial>M) = (\<integral>\<^sup>+ x. max 0 (f x + g x) \<partial>M)"
  1187     by (simp add: positive_integral_max_0)
  1188   also have "\<dots> = (\<integral>\<^sup>+ x. max 0 (f x) + max 0 (g x) \<partial>M)"
  1189     unfolding ae[THEN positive_integral_cong_AE] ..
  1190   also have "\<dots> = (\<integral>\<^sup>+ x. max 0 (f x) \<partial>M) + (\<integral>\<^sup>+ x. max 0 (g x) \<partial>M)"
  1191     using positive_integral_linear[of "\<lambda>x. max 0 (f x)" _ 1 "\<lambda>x. max 0 (g x)"] f g
  1192     by auto
  1193   finally show ?thesis
  1194     by (simp add: positive_integral_max_0)
  1195 qed
  1196 
  1197 lemma positive_integral_setsum:
  1198   assumes "\<And>i. i\<in>P \<Longrightarrow> f i \<in> borel_measurable M" "\<And>i. i\<in>P \<Longrightarrow> AE x in M. 0 \<le> f i x"
  1199   shows "(\<integral>\<^sup>+ x. (\<Sum>i\<in>P. f i x) \<partial>M) = (\<Sum>i\<in>P. integral\<^sup>P M (f i))"
  1200 proof cases
  1201   assume f: "finite P"
  1202   from assms have "AE x in M. \<forall>i\<in>P. 0 \<le> f i x" unfolding AE_finite_all[OF f] by auto
  1203   from f this assms(1) show ?thesis
  1204   proof induct
  1205     case (insert i P)
  1206     then have "f i \<in> borel_measurable M" "AE x in M. 0 \<le> f i x"
  1207       "(\<lambda>x. \<Sum>i\<in>P. f i x) \<in> borel_measurable M" "AE x in M. 0 \<le> (\<Sum>i\<in>P. f i x)"
  1208       by (auto intro!: setsum_nonneg)
  1209     from positive_integral_add[OF this]
  1210     show ?case using insert by auto
  1211   qed simp
  1212 qed simp
  1213 
  1214 lemma positive_integral_Markov_inequality:
  1215   assumes u: "u \<in> borel_measurable M" "AE x in M. 0 \<le> u x" and "A \<in> sets M" and c: "0 \<le> c"
  1216   shows "(emeasure M) ({x\<in>space M. 1 \<le> c * u x} \<inter> A) \<le> c * (\<integral>\<^sup>+ x. u x * indicator A x \<partial>M)"
  1217     (is "(emeasure M) ?A \<le> _ * ?PI")
  1218 proof -
  1219   have "?A \<in> sets M"
  1220     using `A \<in> sets M` u by auto
  1221   hence "(emeasure M) ?A = (\<integral>\<^sup>+ x. indicator ?A x \<partial>M)"
  1222     using positive_integral_indicator by simp
  1223   also have "\<dots> \<le> (\<integral>\<^sup>+ x. c * (u x * indicator A x) \<partial>M)" using u c
  1224     by (auto intro!: positive_integral_mono_AE
  1225       simp: indicator_def ereal_zero_le_0_iff)
  1226   also have "\<dots> = c * (\<integral>\<^sup>+ x. u x * indicator A x \<partial>M)"
  1227     using assms
  1228     by (auto intro!: positive_integral_cmult simp: ereal_zero_le_0_iff)
  1229   finally show ?thesis .
  1230 qed
  1231 
  1232 lemma positive_integral_noteq_infinite:
  1233   assumes g: "g \<in> borel_measurable M" "AE x in M. 0 \<le> g x"
  1234   and "integral\<^sup>P M g \<noteq> \<infinity>"
  1235   shows "AE x in M. g x \<noteq> \<infinity>"
  1236 proof (rule ccontr)
  1237   assume c: "\<not> (AE x in M. g x \<noteq> \<infinity>)"
  1238   have "(emeasure M) {x\<in>space M. g x = \<infinity>} \<noteq> 0"
  1239     using c g by (auto simp add: AE_iff_null)
  1240   moreover have "0 \<le> (emeasure M) {x\<in>space M. g x = \<infinity>}" using g by (auto intro: measurable_sets)
  1241   ultimately have "0 < (emeasure M) {x\<in>space M. g x = \<infinity>}" by auto
  1242   then have "\<infinity> = \<infinity> * (emeasure M) {x\<in>space M. g x = \<infinity>}" by auto
  1243   also have "\<dots> \<le> (\<integral>\<^sup>+x. \<infinity> * indicator {x\<in>space M. g x = \<infinity>} x \<partial>M)"
  1244     using g by (subst positive_integral_cmult_indicator) auto
  1245   also have "\<dots> \<le> integral\<^sup>P M g"
  1246     using assms by (auto intro!: positive_integral_mono_AE simp: indicator_def)
  1247   finally show False using `integral\<^sup>P M g \<noteq> \<infinity>` by auto
  1248 qed
  1249 
  1250 lemma positive_integral_diff:
  1251   assumes f: "f \<in> borel_measurable M"
  1252   and g: "g \<in> borel_measurable M" "AE x in M. 0 \<le> g x"
  1253   and fin: "integral\<^sup>P M g \<noteq> \<infinity>"
  1254   and mono: "AE x in M. g x \<le> f x"
  1255   shows "(\<integral>\<^sup>+ x. f x - g x \<partial>M) = integral\<^sup>P M f - integral\<^sup>P M g"
  1256 proof -
  1257   have diff: "(\<lambda>x. f x - g x) \<in> borel_measurable M" "AE x in M. 0 \<le> f x - g x"
  1258     using assms by (auto intro: ereal_diff_positive)
  1259   have pos_f: "AE x in M. 0 \<le> f x" using mono g by auto
  1260   { fix a b :: ereal assume "0 \<le> a" "a \<noteq> \<infinity>" "0 \<le> b" "a \<le> b" then have "b - a + a = b"
  1261       by (cases rule: ereal2_cases[of a b]) auto }
  1262   note * = this
  1263   then have "AE x in M. f x = f x - g x + g x"
  1264     using mono positive_integral_noteq_infinite[OF g fin] assms by auto
  1265   then have **: "integral\<^sup>P M f = (\<integral>\<^sup>+x. f x - g x \<partial>M) + integral\<^sup>P M g"
  1266     unfolding positive_integral_add[OF diff g, symmetric]
  1267     by (rule positive_integral_cong_AE)
  1268   show ?thesis unfolding **
  1269     using fin positive_integral_positive[of M g]
  1270     by (cases rule: ereal2_cases[of "\<integral>\<^sup>+ x. f x - g x \<partial>M" "integral\<^sup>P M g"]) auto
  1271 qed
  1272 
  1273 lemma positive_integral_suminf:
  1274   assumes f: "\<And>i. f i \<in> borel_measurable M" "\<And>i. AE x in M. 0 \<le> f i x"
  1275   shows "(\<integral>\<^sup>+ x. (\<Sum>i. f i x) \<partial>M) = (\<Sum>i. integral\<^sup>P M (f i))"
  1276 proof -
  1277   have all_pos: "AE x in M. \<forall>i. 0 \<le> f i x"
  1278     using assms by (auto simp: AE_all_countable)
  1279   have "(\<Sum>i. integral\<^sup>P M (f i)) = (SUP n. \<Sum>i<n. integral\<^sup>P M (f i))"
  1280     using positive_integral_positive by (rule suminf_ereal_eq_SUPR)
  1281   also have "\<dots> = (SUP n. \<integral>\<^sup>+x. (\<Sum>i<n. f i x) \<partial>M)"
  1282     unfolding positive_integral_setsum[OF f] ..
  1283   also have "\<dots> = \<integral>\<^sup>+x. (SUP n. \<Sum>i<n. f i x) \<partial>M" using f all_pos
  1284     by (intro positive_integral_monotone_convergence_SUP_AE[symmetric])
  1285        (elim AE_mp, auto simp: setsum_nonneg simp del: setsum_lessThan_Suc intro!: AE_I2 setsum_mono3)
  1286   also have "\<dots> = \<integral>\<^sup>+x. (\<Sum>i. f i x) \<partial>M" using all_pos
  1287     by (intro positive_integral_cong_AE) (auto simp: suminf_ereal_eq_SUPR)
  1288   finally show ?thesis by simp
  1289 qed
  1290 
  1291 text {* Fatou's lemma: convergence theorem on limes inferior *}
  1292 lemma positive_integral_lim_INF:
  1293   fixes u :: "nat \<Rightarrow> 'a \<Rightarrow> ereal"
  1294   assumes u: "\<And>i. u i \<in> borel_measurable M" "\<And>i. AE x in M. 0 \<le> u i x"
  1295   shows "(\<integral>\<^sup>+ x. liminf (\<lambda>n. u n x) \<partial>M) \<le> liminf (\<lambda>n. integral\<^sup>P M (u n))"
  1296 proof -
  1297   have pos: "AE x in M. \<forall>i. 0 \<le> u i x" using u by (auto simp: AE_all_countable)
  1298   have "(\<integral>\<^sup>+ x. liminf (\<lambda>n. u n x) \<partial>M) =
  1299     (SUP n. \<integral>\<^sup>+ x. (INF i:{n..}. u i x) \<partial>M)"
  1300     unfolding liminf_SUPR_INFI using pos u
  1301     by (intro positive_integral_monotone_convergence_SUP_AE)
  1302        (elim AE_mp, auto intro!: AE_I2 intro: INF_greatest INF_superset_mono)
  1303   also have "\<dots> \<le> liminf (\<lambda>n. integral\<^sup>P M (u n))"
  1304     unfolding liminf_SUPR_INFI
  1305     by (auto intro!: SUP_mono exI INF_greatest positive_integral_mono INF_lower)
  1306   finally show ?thesis .
  1307 qed
  1308 
  1309 lemma positive_integral_null_set:
  1310   assumes "N \<in> null_sets M" shows "(\<integral>\<^sup>+ x. u x * indicator N x \<partial>M) = 0"
  1311 proof -
  1312   have "(\<integral>\<^sup>+ x. u x * indicator N x \<partial>M) = (\<integral>\<^sup>+ x. 0 \<partial>M)"
  1313   proof (intro positive_integral_cong_AE AE_I)
  1314     show "{x \<in> space M. u x * indicator N x \<noteq> 0} \<subseteq> N"
  1315       by (auto simp: indicator_def)
  1316     show "(emeasure M) N = 0" "N \<in> sets M"
  1317       using assms by auto
  1318   qed
  1319   then show ?thesis by simp
  1320 qed
  1321 
  1322 lemma positive_integral_0_iff:
  1323   assumes u: "u \<in> borel_measurable M" and pos: "AE x in M. 0 \<le> u x"
  1324   shows "integral\<^sup>P M u = 0 \<longleftrightarrow> emeasure M {x\<in>space M. u x \<noteq> 0} = 0"
  1325     (is "_ \<longleftrightarrow> (emeasure M) ?A = 0")
  1326 proof -
  1327   have u_eq: "(\<integral>\<^sup>+ x. u x * indicator ?A x \<partial>M) = integral\<^sup>P M u"
  1328     by (auto intro!: positive_integral_cong simp: indicator_def)
  1329   show ?thesis
  1330   proof
  1331     assume "(emeasure M) ?A = 0"
  1332     with positive_integral_null_set[of ?A M u] u
  1333     show "integral\<^sup>P M u = 0" by (simp add: u_eq null_sets_def)
  1334   next
  1335     { fix r :: ereal and n :: nat assume gt_1: "1 \<le> real n * r"
  1336       then have "0 < real n * r" by (cases r) (auto split: split_if_asm simp: one_ereal_def)
  1337       then have "0 \<le> r" by (auto simp add: ereal_zero_less_0_iff) }
  1338     note gt_1 = this
  1339     assume *: "integral\<^sup>P M u = 0"
  1340     let ?M = "\<lambda>n. {x \<in> space M. 1 \<le> real (n::nat) * u x}"
  1341     have "0 = (SUP n. (emeasure M) (?M n \<inter> ?A))"
  1342     proof -
  1343       { fix n :: nat
  1344         from positive_integral_Markov_inequality[OF u pos, of ?A "ereal (real n)"]
  1345         have "(emeasure M) (?M n \<inter> ?A) \<le> 0" unfolding u_eq * using u by simp
  1346         moreover have "0 \<le> (emeasure M) (?M n \<inter> ?A)" using u by auto
  1347         ultimately have "(emeasure M) (?M n \<inter> ?A) = 0" by auto }
  1348       thus ?thesis by simp
  1349     qed
  1350     also have "\<dots> = (emeasure M) (\<Union>n. ?M n \<inter> ?A)"
  1351     proof (safe intro!: SUP_emeasure_incseq)
  1352       fix n show "?M n \<inter> ?A \<in> sets M"
  1353         using u by (auto intro!: sets.Int)
  1354     next
  1355       show "incseq (\<lambda>n. {x \<in> space M. 1 \<le> real n * u x} \<inter> {x \<in> space M. u x \<noteq> 0})"
  1356       proof (safe intro!: incseq_SucI)
  1357         fix n :: nat and x
  1358         assume *: "1 \<le> real n * u x"
  1359         also from gt_1[OF *] have "real n * u x \<le> real (Suc n) * u x"
  1360           using `0 \<le> u x` by (auto intro!: ereal_mult_right_mono)
  1361         finally show "1 \<le> real (Suc n) * u x" by auto
  1362       qed
  1363     qed
  1364     also have "\<dots> = (emeasure M) {x\<in>space M. 0 < u x}"
  1365     proof (safe intro!: arg_cong[where f="(emeasure M)"] dest!: gt_1)
  1366       fix x assume "0 < u x" and [simp, intro]: "x \<in> space M"
  1367       show "x \<in> (\<Union>n. ?M n \<inter> ?A)"
  1368       proof (cases "u x")
  1369         case (real r) with `0 < u x` have "0 < r" by auto
  1370         obtain j :: nat where "1 / r \<le> real j" using real_arch_simple ..
  1371         hence "1 / r * r \<le> real j * r" unfolding mult_le_cancel_right using `0 < r` by auto
  1372         hence "1 \<le> real j * r" using real `0 < r` by auto
  1373         thus ?thesis using `0 < r` real by (auto simp: one_ereal_def)
  1374       qed (insert `0 < u x`, auto)
  1375     qed auto
  1376     finally have "(emeasure M) {x\<in>space M. 0 < u x} = 0" by simp
  1377     moreover
  1378     from pos have "AE x in M. \<not> (u x < 0)" by auto
  1379     then have "(emeasure M) {x\<in>space M. u x < 0} = 0"
  1380       using AE_iff_null[of M] u by auto
  1381     moreover have "(emeasure M) {x\<in>space M. u x \<noteq> 0} = (emeasure M) {x\<in>space M. u x < 0} + (emeasure M) {x\<in>space M. 0 < u x}"
  1382       using u by (subst plus_emeasure) (auto intro!: arg_cong[where f="emeasure M"])
  1383     ultimately show "(emeasure M) ?A = 0" by simp
  1384   qed
  1385 qed
  1386 
  1387 lemma positive_integral_0_iff_AE:
  1388   assumes u: "u \<in> borel_measurable M"
  1389   shows "integral\<^sup>P M u = 0 \<longleftrightarrow> (AE x in M. u x \<le> 0)"
  1390 proof -
  1391   have sets: "{x\<in>space M. max 0 (u x) \<noteq> 0} \<in> sets M"
  1392     using u by auto
  1393   from positive_integral_0_iff[of "\<lambda>x. max 0 (u x)"]
  1394   have "integral\<^sup>P M u = 0 \<longleftrightarrow> (AE x in M. max 0 (u x) = 0)"
  1395     unfolding positive_integral_max_0
  1396     using AE_iff_null[OF sets] u by auto
  1397   also have "\<dots> \<longleftrightarrow> (AE x in M. u x \<le> 0)" by (auto split: split_max)
  1398   finally show ?thesis .
  1399 qed
  1400 
  1401 lemma AE_iff_positive_integral: 
  1402   "{x\<in>space M. P x} \<in> sets M \<Longrightarrow> (AE x in M. P x) \<longleftrightarrow> integral\<^sup>P M (indicator {x. \<not> P x}) = 0"
  1403   by (subst positive_integral_0_iff_AE) (auto simp: one_ereal_def zero_ereal_def
  1404     sets.sets_Collect_neg indicator_def[abs_def] measurable_If)
  1405 
  1406 lemma positive_integral_const_If:
  1407   "(\<integral>\<^sup>+x. a \<partial>M) = (if 0 \<le> a then a * (emeasure M) (space M) else 0)"
  1408   by (auto intro!: positive_integral_0_iff_AE[THEN iffD2])
  1409 
  1410 lemma positive_integral_subalgebra:
  1411   assumes f: "f \<in> borel_measurable N" "\<And>x. 0 \<le> f x"
  1412   and N: "sets N \<subseteq> sets M" "space N = space M" "\<And>A. A \<in> sets N \<Longrightarrow> emeasure N A = emeasure M A"
  1413   shows "integral\<^sup>P N f = integral\<^sup>P M f"
  1414 proof -
  1415   have [simp]: "\<And>f :: 'a \<Rightarrow> ereal. f \<in> borel_measurable N \<Longrightarrow> f \<in> borel_measurable M"
  1416     using N by (auto simp: measurable_def)
  1417   have [simp]: "\<And>P. (AE x in N. P x) \<Longrightarrow> (AE x in M. P x)"
  1418     using N by (auto simp add: eventually_ae_filter null_sets_def)
  1419   have [simp]: "\<And>A. A \<in> sets N \<Longrightarrow> A \<in> sets M"
  1420     using N by auto
  1421   from f show ?thesis
  1422     apply induct
  1423     apply (simp_all add: positive_integral_add positive_integral_cmult positive_integral_monotone_convergence_SUP N)
  1424     apply (auto intro!: positive_integral_cong cong: positive_integral_cong simp: N(2)[symmetric])
  1425     done
  1426 qed
  1427 
  1428 lemma positive_integral_nat_function:
  1429   fixes f :: "'a \<Rightarrow> nat"
  1430   assumes "f \<in> measurable M (count_space UNIV)"
  1431   shows "(\<integral>\<^sup>+x. ereal (of_nat (f x)) \<partial>M) = (\<Sum>t. emeasure M {x\<in>space M. t < f x})"
  1432 proof -
  1433   def F \<equiv> "\<lambda>i. {x\<in>space M. i < f x}"
  1434   with assms have [measurable]: "\<And>i. F i \<in> sets M"
  1435     by auto
  1436 
  1437   { fix x assume "x \<in> space M"
  1438     have "(\<lambda>i. if i < f x then 1 else 0) sums (of_nat (f x)::real)"
  1439       using sums_If_finite[of "\<lambda>i. i < f x" "\<lambda>_. 1::real"] by simp
  1440     then have "(\<lambda>i. ereal(if i < f x then 1 else 0)) sums (ereal(of_nat(f x)))"
  1441       unfolding sums_ereal .
  1442     moreover have "\<And>i. ereal (if i < f x then 1 else 0) = indicator (F i) x"
  1443       using `x \<in> space M` by (simp add: one_ereal_def F_def)
  1444     ultimately have "ereal(of_nat(f x)) = (\<Sum>i. indicator (F i) x)"
  1445       by (simp add: sums_iff) }
  1446   then have "(\<integral>\<^sup>+x. ereal (of_nat (f x)) \<partial>M) = (\<integral>\<^sup>+x. (\<Sum>i. indicator (F i) x) \<partial>M)"
  1447     by (simp cong: positive_integral_cong)
  1448   also have "\<dots> = (\<Sum>i. emeasure M (F i))"
  1449     by (simp add: positive_integral_suminf)
  1450   finally show ?thesis
  1451     by (simp add: F_def)
  1452 qed
  1453 
  1454 section "Lebesgue Integral"
  1455 
  1456 definition integrable :: "'a measure \<Rightarrow> ('a \<Rightarrow> real) \<Rightarrow> bool" where
  1457   "integrable M f \<longleftrightarrow> f \<in> borel_measurable M \<and>
  1458     (\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<noteq> \<infinity> \<and> (\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<noteq> \<infinity>"
  1459 
  1460 lemma borel_measurable_integrable[measurable_dest]:
  1461   "integrable M f \<Longrightarrow> f \<in> borel_measurable M"
  1462   by (auto simp: integrable_def)
  1463 
  1464 lemma integrableD[dest]:
  1465   assumes "integrable M f"
  1466   shows "f \<in> borel_measurable M" "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) \<noteq> \<infinity>" "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<noteq> \<infinity>"
  1467   using assms unfolding integrable_def by auto
  1468 
  1469 definition lebesgue_integral :: "'a measure \<Rightarrow> ('a \<Rightarrow> real) \<Rightarrow> real" ("integral\<^sup>L") where
  1470   "integral\<^sup>L M f = real ((\<integral>\<^sup>+ x. ereal (f x) \<partial>M)) - real ((\<integral>\<^sup>+ x. ereal (- f x) \<partial>M))"
  1471 
  1472 syntax
  1473   "_lebesgue_integral" :: "pttrn \<Rightarrow> real \<Rightarrow> 'a measure \<Rightarrow> real" ("\<integral> _. _ \<partial>_" [60,61] 110)
  1474 
  1475 translations
  1476   "\<integral> x. f \<partial>M" == "CONST lebesgue_integral M (%x. f)"
  1477 
  1478 lemma integrableE:
  1479   assumes "integrable M f"
  1480   obtains r q where
  1481     "(\<integral>\<^sup>+x. ereal (f x)\<partial>M) = ereal r"
  1482     "(\<integral>\<^sup>+x. ereal (-f x)\<partial>M) = ereal q"
  1483     "f \<in> borel_measurable M" "integral\<^sup>L M f = r - q"
  1484   using assms unfolding integrable_def lebesgue_integral_def
  1485   using positive_integral_positive[of M "\<lambda>x. ereal (f x)"]
  1486   using positive_integral_positive[of M "\<lambda>x. ereal (-f x)"]
  1487   by (cases rule: ereal2_cases[of "(\<integral>\<^sup>+x. ereal (-f x)\<partial>M)" "(\<integral>\<^sup>+x. ereal (f x)\<partial>M)"]) auto
  1488 
  1489 lemma integral_cong:
  1490   assumes "\<And>x. x \<in> space M \<Longrightarrow> f x = g x"
  1491   shows "integral\<^sup>L M f = integral\<^sup>L M g"
  1492   using assms by (simp cong: positive_integral_cong add: lebesgue_integral_def)
  1493 
  1494 lemma integral_cong_AE:
  1495   assumes cong: "AE x in M. f x = g x"
  1496   shows "integral\<^sup>L M f = integral\<^sup>L M g"
  1497 proof -
  1498   have *: "AE x in M. ereal (f x) = ereal (g x)"
  1499     "AE x in M. ereal (- f x) = ereal (- g x)" using cong by auto
  1500   show ?thesis
  1501     unfolding *[THEN positive_integral_cong_AE] lebesgue_integral_def ..
  1502 qed
  1503 
  1504 lemma integrable_cong_AE:
  1505   assumes borel: "f \<in> borel_measurable M" "g \<in> borel_measurable M"
  1506   assumes "AE x in M. f x = g x"
  1507   shows "integrable M f = integrable M g"
  1508 proof -
  1509   have "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) = (\<integral>\<^sup>+ x. ereal (g x) \<partial>M)"
  1510     "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) = (\<integral>\<^sup>+ x. ereal (- g x) \<partial>M)"
  1511     using assms by (auto intro!: positive_integral_cong_AE)
  1512   with assms show ?thesis
  1513     by (auto simp: integrable_def)
  1514 qed
  1515 
  1516 lemma integrable_cong:
  1517   "(\<And>x. x \<in> space M \<Longrightarrow> f x = g x) \<Longrightarrow> integrable M f \<longleftrightarrow> integrable M g"
  1518   by (simp cong: positive_integral_cong measurable_cong add: integrable_def)
  1519 
  1520 lemma integral_mono_AE:
  1521   assumes fg: "integrable M f" "integrable M g"
  1522   and mono: "AE t in M. f t \<le> g t"
  1523   shows "integral\<^sup>L M f \<le> integral\<^sup>L M g"
  1524 proof -
  1525   have "AE x in M. ereal (f x) \<le> ereal (g x)"
  1526     using mono by auto
  1527   moreover have "AE x in M. ereal (- g x) \<le> ereal (- f x)"
  1528     using mono by auto
  1529   ultimately show ?thesis using fg
  1530     by (auto intro!: add_mono positive_integral_mono_AE real_of_ereal_positive_mono
  1531              simp: positive_integral_positive lebesgue_integral_def algebra_simps)
  1532 qed
  1533 
  1534 lemma integral_mono:
  1535   assumes "integrable M f" "integrable M g" "\<And>t. t \<in> space M \<Longrightarrow> f t \<le> g t"
  1536   shows "integral\<^sup>L M f \<le> integral\<^sup>L M g"
  1537   using assms by (auto intro: integral_mono_AE)
  1538 
  1539 lemma positive_integral_eq_integral:
  1540   assumes f: "integrable M f"
  1541   assumes nonneg: "AE x in M. 0 \<le> f x" 
  1542   shows "(\<integral>\<^sup>+ x. ereal (f x) \<partial>M) = integral\<^sup>L M f"
  1543 proof -
  1544   have "(\<integral>\<^sup>+ x. max 0 (ereal (- f x)) \<partial>M) = (\<integral>\<^sup>+ x. 0 \<partial>M)"
  1545     using nonneg by (intro positive_integral_cong_AE) (auto split: split_max)
  1546   with f positive_integral_positive show ?thesis
  1547     by (cases "\<integral>\<^sup>+ x. ereal (f x) \<partial>M")
  1548        (auto simp add: lebesgue_integral_def positive_integral_max_0 integrable_def)
  1549 qed
  1550   
  1551 lemma integral_eq_positive_integral:
  1552   assumes f: "\<And>x. 0 \<le> f x"
  1553   shows "integral\<^sup>L M f = real (\<integral>\<^sup>+ x. ereal (f x) \<partial>M)"
  1554 proof -
  1555   { fix x have "max 0 (ereal (- f x)) = 0" using f[of x] by (simp split: split_max) }
  1556   then have "0 = (\<integral>\<^sup>+ x. max 0 (ereal (- f x)) \<partial>M)" by simp
  1557   also have "\<dots> = (\<integral>\<^sup>+ x. ereal (- f x) \<partial>M)" unfolding positive_integral_max_0 ..
  1558   finally show ?thesis
  1559     unfolding lebesgue_integral_def by simp
  1560 qed
  1561 
  1562 lemma integral_minus[intro, simp]:
  1563   assumes "integrable M f"
  1564   shows "integrable M (\<lambda>x. - f x)" "(\<integral>x. - f x \<partial>M) = - integral\<^sup>L M f"
  1565   using assms by (auto simp: integrable_def lebesgue_integral_def)
  1566 
  1567 lemma integral_minus_iff[simp]:
  1568   "integrable M (\<lambda>x. - f x) \<longleftrightarrow> integrable M f"
  1569 proof
  1570   assume "integrable M (\<lambda>x. - f x)"
  1571   then have "integrable M (\<lambda>x. - (- f x))"
  1572     by (rule integral_minus)
  1573   then show "integrable M f" by simp
  1574 qed (rule integral_minus)
  1575 
  1576 lemma integral_of_positive_diff:
  1577   assumes integrable: "integrable M u" "integrable M v"
  1578   and f_def: "\<And>x. f x = u x - v x" and pos: "\<And>x. 0 \<le> u x" "\<And>x. 0 \<le> v x"
  1579   shows "integrable M f" and "integral\<^sup>L M f = integral\<^sup>L M u - integral\<^sup>L M v"
  1580 proof -
  1581   let ?f = "\<lambda>x. max 0 (ereal (f x))"
  1582   let ?mf = "\<lambda>x. max 0 (ereal (- f x))"
  1583   let ?u = "\<lambda>x. max 0 (ereal (u x))"
  1584   let ?v = "\<lambda>x. max 0 (ereal (v x))"
  1585 
  1586   from borel_measurable_diff[of u M v] integrable
  1587   have f_borel: "?f \<in> borel_measurable M" and
  1588     mf_borel: "?mf \<in> borel_measurable M" and
  1589     v_borel: "?v \<in> borel_measurable M" and
  1590     u_borel: "?u \<in> borel_measurable M" and
  1591     "f \<in> borel_measurable M"
  1592     by (auto simp: f_def[symmetric] integrable_def)
  1593 
  1594   have "(\<integral>\<^sup>+ x. ereal (u x - v x) \<partial>M) \<le> integral\<^sup>P M ?u"
  1595     using pos by (auto intro!: positive_integral_mono simp: positive_integral_max_0)
  1596   moreover have "(\<integral>\<^sup>+ x. ereal (v x - u x) \<partial>M) \<le> integral\<^sup>P M ?v"
  1597     using pos by (auto intro!: positive_integral_mono simp: positive_integral_max_0)
  1598   ultimately show f: "integrable M f"
  1599     using `integrable M u` `integrable M v` `f \<in> borel_measurable M`
  1600     by (auto simp: integrable_def f_def positive_integral_max_0)
  1601 
  1602   have "\<And>x. ?u x + ?mf x = ?v x + ?f x"
  1603     unfolding f_def using pos by (simp split: split_max)
  1604   then have "(\<integral>\<^sup>+ x. ?u x + ?mf x \<partial>M) = (\<integral>\<^sup>+ x. ?v x + ?f x \<partial>M)" by simp
  1605   then have "real (integral\<^sup>P M ?u + integral\<^sup>P M ?mf) =
  1606       real (integral\<^sup>P M ?v + integral\<^sup>P M ?f)"
  1607     using positive_integral_add[OF u_borel _ mf_borel]
  1608     using positive_integral_add[OF v_borel _ f_borel]
  1609     by auto
  1610   then show "integral\<^sup>L M f = integral\<^sup>L M u - integral\<^sup>L M v"
  1611     unfolding positive_integral_max_0
  1612     unfolding pos[THEN integral_eq_positive_integral]
  1613     using integrable f by (auto elim!: integrableE)
  1614 qed
  1615 
  1616 lemma integral_linear:
  1617   assumes "integrable M f" "integrable M g" and "0 \<le> a"
  1618   shows "integrable M (\<lambda>t. a * f t + g t)"
  1619   and "(\<integral> t. a * f t + g t \<partial>M) = a * integral\<^sup>L M f + integral\<^sup>L M g" (is ?EQ)
  1620 proof -
  1621   let ?f = "\<lambda>x. max 0 (ereal (f x))"
  1622   let ?g = "\<lambda>x. max 0 (ereal (g x))"
  1623   let ?mf = "\<lambda>x. max 0 (ereal (- f x))"
  1624   let ?mg = "\<lambda>x. max 0 (ereal (- g x))"
  1625   let ?p = "\<lambda>t. max 0 (a * f t) + max 0 (g t)"
  1626   let ?n = "\<lambda>t. max 0 (- (a * f t)) + max 0 (- g t)"
  1627 
  1628   from assms have linear:
  1629     "(\<integral>\<^sup>+ x. ereal a * ?f x + ?g x \<partial>M) = ereal a * integral\<^sup>P M ?f + integral\<^sup>P M ?g"
  1630     "(\<integral>\<^sup>+ x. ereal a * ?mf x + ?mg x \<partial>M) = ereal a * integral\<^sup>P M ?mf + integral\<^sup>P M ?mg"
  1631     by (auto intro!: positive_integral_linear simp: integrable_def)
  1632 
  1633   have *: "(\<integral>\<^sup>+x. ereal (- ?p x) \<partial>M) = 0" "(\<integral>\<^sup>+x. ereal (- ?n x) \<partial>M) = 0"
  1634     using `0 \<le> a` assms by (auto simp: positive_integral_0_iff_AE integrable_def)
  1635   have **: "\<And>x. ereal a * ?f x + ?g x = max 0 (ereal (?p x))"
  1636            "\<And>x. ereal a * ?mf x + ?mg x = max 0 (ereal (?n x))"
  1637     using `0 \<le> a` by (auto split: split_max simp: zero_le_mult_iff mult_le_0_iff)
  1638 
  1639   have "integrable M ?p" "integrable M ?n"
  1640       "\<And>t. a * f t + g t = ?p t - ?n t" "\<And>t. 0 \<le> ?p t" "\<And>t. 0 \<le> ?n t"
  1641     using linear assms unfolding integrable_def ** *
  1642     by (auto simp: positive_integral_max_0)
  1643   note diff = integral_of_positive_diff[OF this]
  1644 
  1645   show "integrable M (\<lambda>t. a * f t + g t)" by (rule diff)
  1646   from assms linear show ?EQ
  1647     unfolding diff(2) ** positive_integral_max_0
  1648     unfolding lebesgue_integral_def *
  1649     by (auto elim!: integrableE simp: field_simps)
  1650 qed
  1651 
  1652 lemma integral_add[simp, intro]:
  1653   assumes "integrable M f" "integrable M g"
  1654   shows "integrable M (\<lambda>t. f t + g t)"
  1655   and "(\<integral> t. f t + g t \<partial>M) = integral\<^sup>L M f + integral\<^sup>L M g"
  1656   using assms integral_linear[where a=1] by auto
  1657 
  1658 lemma integral_zero[simp, intro]:
  1659   shows "integrable M (\<lambda>x. 0)" "(\<integral> x.0 \<partial>M) = 0"
  1660   unfolding integrable_def lebesgue_integral_def
  1661   by auto
  1662 
  1663 lemma lebesgue_integral_uminus:
  1664     "(\<integral>x. - f x \<partial>M) = - integral\<^sup>L M f"
  1665   unfolding lebesgue_integral_def by simp
  1666 
  1667 lemma lebesgue_integral_cmult_nonneg:
  1668   assumes f: "f \<in> borel_measurable M" and "0 \<le> c"
  1669   shows "(\<integral>x. c * f x \<partial>M) = c * integral\<^sup>L M f"
  1670 proof -
  1671   { have "real (ereal c * integral\<^sup>P M (\<lambda>x. max 0 (ereal (f x)))) =
  1672       real (integral\<^sup>P M (\<lambda>x. ereal c * max 0 (ereal (f x))))"
  1673       using f `0 \<le> c` by (subst positive_integral_cmult) auto
  1674     also have "\<dots> = real (integral\<^sup>P M (\<lambda>x. max 0 (ereal (c * f x))))"
  1675       using `0 \<le> c` by (auto intro!: arg_cong[where f=real] positive_integral_cong simp: max_def zero_le_mult_iff)
  1676     finally have "real (integral\<^sup>P M (\<lambda>x. ereal (c * f x))) = c * real (integral\<^sup>P M (\<lambda>x. ereal (f x)))"
  1677       by (simp add: positive_integral_max_0) }
  1678   moreover
  1679   { have "real (ereal c * integral\<^sup>P M (\<lambda>x. max 0 (ereal (- f x)))) =
  1680       real (integral\<^sup>P M (\<lambda>x. ereal c * max 0 (ereal (- f x))))"
  1681       using f `0 \<le> c` by (subst positive_integral_cmult) auto
  1682     also have "\<dots> = real (integral\<^sup>P M (\<lambda>x. max 0 (ereal (- c * f x))))"
  1683       using `0 \<le> c` by (auto intro!: arg_cong[where f=real] positive_integral_cong simp: max_def mult_le_0_iff)
  1684     finally have "real (integral\<^sup>P M (\<lambda>x. ereal (- c * f x))) = c * real (integral\<^sup>P M (\<lambda>x. ereal (- f x)))"
  1685       by (simp add: positive_integral_max_0) }
  1686   ultimately show ?thesis
  1687     by (simp add: lebesgue_integral_def field_simps)
  1688 qed
  1689 
  1690 lemma lebesgue_integral_cmult:
  1691   assumes f: "f \<in> borel_measurable M"
  1692   shows "(\<integral>x. c * f x \<partial>M) = c * integral\<^sup>L M f"
  1693 proof (cases rule: linorder_le_cases)
  1694   assume "0 \<le> c" with f show ?thesis by (rule lebesgue_integral_cmult_nonneg)
  1695 next
  1696   assume "c \<le> 0"
  1697   with lebesgue_integral_cmult_nonneg[OF f, of "-c"]
  1698   show ?thesis
  1699     by (simp add: lebesgue_integral_def)
  1700 qed
  1701 
  1702 lemma lebesgue_integral_multc:
  1703   "f \<in> borel_measurable M \<Longrightarrow> (\<integral>x. f x * c \<partial>M) = integral\<^sup>L M f * c"
  1704   using lebesgue_integral_cmult[of f M c] by (simp add: ac_simps)
  1705 
  1706 lemma integral_multc:
  1707   "integrable M f \<Longrightarrow> (\<integral> x. f x * c \<partial>M) = integral\<^sup>L M f * c"
  1708   by (simp add: lebesgue_integral_multc)
  1709 
  1710 lemma integral_cmult[simp, intro]:
  1711   assumes "integrable M f"
  1712   shows "integrable M (\<lambda>t. a * f t)" (is ?P)
  1713   and "(\<integral> t. a * f t \<partial>M) = a * integral\<^sup>L M f" (is ?I)
  1714 proof -
  1715   have "integrable M (\<lambda>t. a * f t) \<and> (\<integral> t. a * f t \<partial>M) = a * integral\<^sup>L M f"
  1716   proof (cases rule: le_cases)
  1717     assume "0 \<le> a" show ?thesis
  1718       using integral_linear[OF assms integral_zero(1) `0 \<le> a`]
  1719       by simp
  1720   next
  1721     assume "a \<le> 0" hence "0 \<le> - a" by auto
  1722     have *: "\<And>t. - a * t + 0 = (-a) * t" by simp
  1723     show ?thesis using integral_linear[OF assms integral_zero(1) `0 \<le> - a`]
  1724         integral_minus(1)[of M "\<lambda>t. - a * f t"]
  1725       unfolding * integral_zero by simp
  1726   qed
  1727   thus ?P ?I by auto
  1728 qed
  1729 
  1730 lemma integral_diff[simp, intro]:
  1731   assumes f: "integrable M f" and g: "integrable M g"
  1732   shows "integrable M (\<lambda>t. f t - g t)"
  1733   and "(\<integral> t. f t - g t \<partial>M) = integral\<^sup>L M f - integral\<^sup>L M g"
  1734   using integral_add[OF f integral_minus(1)[OF g]]
  1735   unfolding integral_minus(2)[OF g]
  1736   by auto
  1737 
  1738 lemma integral_indicator[simp, intro]:
  1739   assumes "A \<in> sets M" and "(emeasure M) A \<noteq> \<infinity>"
  1740   shows "integral\<^sup>L M (indicator A) = real (emeasure M A)" (is ?int)
  1741   and "integrable M (indicator A)" (is ?able)
  1742 proof -
  1743   from `A \<in> sets M` have *:
  1744     "\<And>x. ereal (indicator A x) = indicator A x"
  1745     "(\<integral>\<^sup>+x. ereal (- indicator A x) \<partial>M) = 0"
  1746     by (auto split: split_indicator simp: positive_integral_0_iff_AE one_ereal_def)
  1747   show ?int ?able
  1748     using assms unfolding lebesgue_integral_def integrable_def
  1749     by (auto simp: *)
  1750 qed
  1751 
  1752 lemma integral_cmul_indicator:
  1753   assumes "A \<in> sets M" and "c \<noteq> 0 \<Longrightarrow> (emeasure M) A \<noteq> \<infinity>"
  1754   shows "integrable M (\<lambda>x. c * indicator A x)" (is ?P)
  1755   and "(\<integral>x. c * indicator A x \<partial>M) = c * real ((emeasure M) A)" (is ?I)
  1756 proof -
  1757   show ?P
  1758   proof (cases "c = 0")
  1759     case False with assms show ?thesis by simp
  1760   qed simp
  1761 
  1762   show ?I
  1763   proof (cases "c = 0")
  1764     case False with assms show ?thesis by simp
  1765   qed simp
  1766 qed
  1767 
  1768 lemma integral_setsum[simp, intro]:
  1769   assumes "\<And>n. n \<in> S \<Longrightarrow> integrable M (f n)"
  1770   shows "(\<integral>x. (\<Sum> i \<in> S. f i x) \<partial>M) = (\<Sum> i \<in> S. integral\<^sup>L M (f i))" (is "?int S")
  1771     and "integrable M (\<lambda>x. \<Sum> i \<in> S. f i x)" (is "?I S")
  1772 proof -
  1773   have "?int S \<and> ?I S"
  1774   proof (cases "finite S")
  1775     assume "finite S"
  1776     from this assms show ?thesis by (induct S) simp_all
  1777   qed simp
  1778   thus "?int S" and "?I S" by auto
  1779 qed
  1780 
  1781 lemma integrable_bound:
  1782   assumes "integrable M f" and f: "AE x in M. \<bar>g x\<bar> \<le> f x"
  1783   assumes borel: "g \<in> borel_measurable M"
  1784   shows "integrable M g"
  1785 proof -
  1786   have "(\<integral>\<^sup>+ x. ereal (g x) \<partial>M) \<le> (\<integral>\<^sup>+ x. ereal \<bar>g x\<bar> \<partial>M)"
  1787     by (auto intro!: positive_integral_mono)
  1788   also have "\<dots> \<le> (\<integral>\<^sup>+ x. ereal (f x) \<partial>M)"
  1789     using f by (auto intro!: positive_integral_mono_AE)
  1790   also have "\<dots> < \<infinity>"
  1791     using `integrable M f` unfolding integrable_def by auto
  1792   finally have pos: "(\<integral>\<^sup>+ x. ereal (g x) \<partial>M) < \<infinity>" .
  1793 
  1794   have "(\<integral>\<^sup>+ x. ereal (- g x) \<partial>M) \<le> (\<integral>\<^sup>+ x. ereal (\<bar>g x\<bar>) \<partial>M)"
  1795     by (auto intro!: positive_integral_mono)
  1796   also have "\<dots> \<le> (\<integral>\<^sup>+ x. ereal (f x) \<partial>M)"
  1797     using f by (auto intro!: positive_integral_mono_AE)
  1798   also have "\<dots> < \<infinity>"
  1799     using `integrable M f` unfolding integrable_def by auto
  1800   finally have neg: "(\<integral>\<^sup>+ x. ereal (- g x) \<partial>M) < \<infinity>" .
  1801 
  1802   from neg pos borel show ?thesis
  1803     unfolding integrable_def by auto
  1804 qed
  1805 
  1806 lemma integrable_abs:
  1807   assumes f[measurable]: "integrable M f"
  1808   shows "integrable M (\<lambda> x. \<bar>f x\<bar>)"
  1809 proof -
  1810   from assms have *: "(\<integral>\<^sup>+x. ereal (- \<bar>f x\<bar>)\<partial>M) = 0"
  1811     "\<And>x. ereal \<bar>f x\<bar> = max 0 (ereal (f x)) + max 0 (ereal (- f x))"
  1812     by (auto simp: integrable_def positive_integral_0_iff_AE split: split_max)
  1813   with assms show ?thesis
  1814     by (simp add: positive_integral_add positive_integral_max_0 integrable_def)
  1815 qed
  1816 
  1817 lemma integral_subalgebra:
  1818   assumes borel: "f \<in> borel_measurable N"
  1819   and N: "sets N \<subseteq> sets M" "space N = space M" "\<And>A. A \<in> sets N \<Longrightarrow> emeasure N A = emeasure M A"
  1820   shows "integrable N f \<longleftrightarrow> integrable M f" (is ?P)
  1821     and "integral\<^sup>L N f = integral\<^sup>L M f" (is ?I)
  1822 proof -
  1823   have "(\<integral>\<^sup>+ x. max 0 (ereal (f x)) \<partial>N) = (\<integral>\<^sup>+ x. max 0 (ereal (f x)) \<partial>M)"
  1824        "(\<integral>\<^sup>+ x. max 0 (ereal (- f x)) \<partial>N) = (\<integral>\<^sup>+ x. max 0 (ereal (- f x)) \<partial>M)"
  1825     using borel by (auto intro!: positive_integral_subalgebra N)
  1826   moreover have "f \<in> borel_measurable M \<longleftrightarrow> f \<in> borel_measurable N"
  1827     using assms unfolding measurable_def by auto
  1828   ultimately show ?P ?I
  1829     by (auto simp: integrable_def lebesgue_integral_def positive_integral_max_0)
  1830 qed
  1831 
  1832 lemma lebesgue_integral_nonneg:
  1833   assumes ae: "(AE x in M. 0 \<le> f x)" shows "0 \<le> integral\<^sup>L M f"
  1834 proof -
  1835   have "(\<integral>\<^sup>+x. max 0 (ereal (- f x)) \<partial>M) = (\<integral>\<^sup>+x. 0 \<partial>M)"
  1836     using ae by (intro positive_integral_cong_AE) (auto simp: max_def)
  1837   then show ?thesis
  1838     by (auto simp: lebesgue_integral_def positive_integral_max_0
  1839              intro!: real_of_ereal_pos positive_integral_positive)
  1840 qed
  1841 
  1842 lemma integrable_abs_iff:
  1843   "f \<in> borel_measurable M \<Longrightarrow> integrable M (\<lambda> x. \<bar>f x\<bar>) \<longleftrightarrow> integrable M f"
  1844   by (auto intro!: integrable_bound[where g=f] integrable_abs)
  1845 
  1846 lemma integrable_max:
  1847   assumes int: "integrable M f" "integrable M g"
  1848   shows "integrable M (\<lambda> x. max (f x) (g x))"
  1849 proof (rule integrable_bound)
  1850   show "integrable M (\<lambda>x. \<bar>f x\<bar> + \<bar>g x\<bar>)"
  1851     using int by (simp add: integrable_abs)
  1852   show "(\<lambda>x. max (f x) (g x)) \<in> borel_measurable M"
  1853     using int unfolding integrable_def by auto
  1854 qed auto
  1855 
  1856 lemma integrable_min:
  1857   assumes int: "integrable M f" "integrable M g"
  1858   shows "integrable M (\<lambda> x. min (f x) (g x))"
  1859 proof (rule integrable_bound)
  1860   show "integrable M (\<lambda>x. \<bar>f x\<bar> + \<bar>g x\<bar>)"
  1861     using int by (simp add: integrable_abs)
  1862   show "(\<lambda>x. min (f x) (g x)) \<in> borel_measurable M"
  1863     using int unfolding integrable_def by auto
  1864 qed auto
  1865 
  1866 lemma integral_triangle_inequality:
  1867   assumes "integrable M f"
  1868   shows "\<bar>integral\<^sup>L M f\<bar> \<le> (\<integral>x. \<bar>f x\<bar> \<partial>M)"
  1869 proof -
  1870   have "\<bar>integral\<^sup>L M f\<bar> = max (integral\<^sup>L M f) (- integral\<^sup>L M f)" by auto
  1871   also have "\<dots> \<le> (\<integral>x. \<bar>f x\<bar> \<partial>M)"
  1872       using assms integral_minus(2)[of M f, symmetric]
  1873       by (auto intro!: integral_mono integrable_abs simp del: integral_minus)
  1874   finally show ?thesis .
  1875 qed
  1876 
  1877 lemma integrable_nonneg:
  1878   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x" "(\<integral>\<^sup>+ x. f x \<partial>M) \<noteq> \<infinity>"
  1879   shows "integrable M f"
  1880   unfolding integrable_def
  1881 proof (intro conjI f)
  1882   have "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) = 0"
  1883     using f by (subst positive_integral_0_iff_AE) auto
  1884   then show "(\<integral>\<^sup>+ x. ereal (- f x) \<partial>M) \<noteq> \<infinity>" by simp
  1885 qed
  1886 
  1887 lemma integral_positive:
  1888   assumes "integrable M f" "\<And>x. x \<in> space M \<Longrightarrow> 0 \<le> f x"
  1889   shows "0 \<le> integral\<^sup>L M f"
  1890 proof -
  1891   have "0 = (\<integral>x. 0 \<partial>M)" by auto
  1892   also have "\<dots> \<le> integral\<^sup>L M f"
  1893     using assms by (rule integral_mono[OF integral_zero(1)])
  1894   finally show ?thesis .
  1895 qed
  1896 
  1897 lemma integral_monotone_convergence_pos:
  1898   assumes i: "\<And>i. integrable M (f i)" and mono: "AE x in M. mono (\<lambda>n. f n x)"
  1899     and pos: "\<And>i. AE x in M. 0 \<le> f i x"
  1900     and lim: "AE x in M. (\<lambda>i. f i x) ----> u x"
  1901     and ilim: "(\<lambda>i. integral\<^sup>L M (f i)) ----> x"
  1902     and u: "u \<in> borel_measurable M"
  1903   shows "integrable M u"
  1904   and "integral\<^sup>L M u = x"
  1905 proof -
  1906   have "(\<integral>\<^sup>+ x. ereal (u x) \<partial>M) = (SUP n. (\<integral>\<^sup>+ x. ereal (f n x) \<partial>M))"
  1907   proof (subst positive_integral_monotone_convergence_SUP_AE[symmetric])
  1908     fix i
  1909     from mono pos show "AE x in M. ereal (f i x) \<le> ereal (f (Suc i) x) \<and> 0 \<le> ereal (f i x)"
  1910       by eventually_elim (auto simp: mono_def)
  1911     show "(\<lambda>x. ereal (f i x)) \<in> borel_measurable M"
  1912       using i by auto
  1913   next
  1914     show "(\<integral>\<^sup>+ x. ereal (u x) \<partial>M) = \<integral>\<^sup>+ x. (SUP i. ereal (f i x)) \<partial>M"
  1915       apply (rule positive_integral_cong_AE)
  1916       using lim mono
  1917       by eventually_elim (simp add: SUP_eq_LIMSEQ[THEN iffD2])
  1918   qed
  1919   also have "\<dots> = ereal x"
  1920     using mono i unfolding positive_integral_eq_integral[OF i pos]
  1921     by (subst SUP_eq_LIMSEQ) (auto simp: mono_def intro!: integral_mono_AE ilim)
  1922   finally have "(\<integral>\<^sup>+ x. ereal (u x) \<partial>M) = ereal x" .
  1923   moreover have "(\<integral>\<^sup>+ x. ereal (- u x) \<partial>M) = 0"
  1924   proof (subst positive_integral_0_iff_AE)
  1925     show "(\<lambda>x. ereal (- u x)) \<in> borel_measurable M"
  1926       using u by auto
  1927     from mono pos[of 0] lim show "AE x in M. ereal (- u x) \<le> 0"
  1928     proof eventually_elim
  1929       fix x assume "mono (\<lambda>n. f n x)" "0 \<le> f 0 x" "(\<lambda>i. f i x) ----> u x"
  1930       then show "ereal (- u x) \<le> 0"
  1931         using incseq_le[of "\<lambda>n. f n x" "u x" 0] by (simp add: mono_def incseq_def)
  1932     qed
  1933   qed
  1934   ultimately show "integrable M u" "integral\<^sup>L M u = x"
  1935     by (auto simp: integrable_def lebesgue_integral_def u)
  1936 qed
  1937 
  1938 lemma integral_monotone_convergence:
  1939   assumes f: "\<And>i. integrable M (f i)" and mono: "AE x in M. mono (\<lambda>n. f n x)"
  1940   and lim: "AE x in M. (\<lambda>i. f i x) ----> u x"
  1941   and ilim: "(\<lambda>i. integral\<^sup>L M (f i)) ----> x"
  1942   and u: "u \<in> borel_measurable M"
  1943   shows "integrable M u"
  1944   and "integral\<^sup>L M u = x"
  1945 proof -
  1946   have 1: "\<And>i. integrable M (\<lambda>x. f i x - f 0 x)"
  1947     using f by auto
  1948   have 2: "AE x in M. mono (\<lambda>n. f n x - f 0 x)"
  1949     using mono by (auto simp: mono_def le_fun_def)
  1950   have 3: "\<And>n. AE x in M. 0 \<le> f n x - f 0 x"
  1951     using mono by (auto simp: field_simps mono_def le_fun_def)
  1952   have 4: "AE x in M. (\<lambda>i. f i x - f 0 x) ----> u x - f 0 x"
  1953     using lim by (auto intro!: tendsto_diff)
  1954   have 5: "(\<lambda>i. (\<integral>x. f i x - f 0 x \<partial>M)) ----> x - integral\<^sup>L M (f 0)"
  1955     using f ilim by (auto intro!: tendsto_diff)
  1956   have 6: "(\<lambda>x. u x - f 0 x) \<in> borel_measurable M"
  1957     using f[of 0] u by auto
  1958   note diff = integral_monotone_convergence_pos[OF 1 2 3 4 5 6]
  1959   have "integrable M (\<lambda>x. (u x - f 0 x) + f 0 x)"
  1960     using diff(1) f by (rule integral_add(1))
  1961   with diff(2) f show "integrable M u" "integral\<^sup>L M u = x"
  1962     by auto
  1963 qed
  1964 
  1965 lemma integral_0_iff:
  1966   assumes "integrable M f"
  1967   shows "(\<integral>x. \<bar>f x\<bar> \<partial>M) = 0 \<longleftrightarrow> (emeasure M) {x\<in>space M. f x \<noteq> 0} = 0"
  1968 proof -
  1969   have *: "(\<integral>\<^sup>+x. ereal (- \<bar>f x\<bar>) \<partial>M) = 0"
  1970     using assms by (auto simp: positive_integral_0_iff_AE integrable_def)
  1971   have "integrable M (\<lambda>x. \<bar>f x\<bar>)" using assms by (rule integrable_abs)
  1972   hence "(\<lambda>x. ereal (\<bar>f x\<bar>)) \<in> borel_measurable M"
  1973     "(\<integral>\<^sup>+ x. ereal \<bar>f x\<bar> \<partial>M) \<noteq> \<infinity>" unfolding integrable_def by auto
  1974   from positive_integral_0_iff[OF this(1)] this(2)
  1975   show ?thesis unfolding lebesgue_integral_def *
  1976     using positive_integral_positive[of M "\<lambda>x. ereal \<bar>f x\<bar>"]
  1977     by (auto simp add: real_of_ereal_eq_0)
  1978 qed
  1979 
  1980 lemma positive_integral_PInf:
  1981   assumes f: "f \<in> borel_measurable M"
  1982   and not_Inf: "integral\<^sup>P M f \<noteq> \<infinity>"
  1983   shows "(emeasure M) (f -` {\<infinity>} \<inter> space M) = 0"
  1984 proof -
  1985   have "\<infinity> * (emeasure M) (f -` {\<infinity>} \<inter> space M) = (\<integral>\<^sup>+ x. \<infinity> * indicator (f -` {\<infinity>} \<inter> space M) x \<partial>M)"
  1986     using f by (subst positive_integral_cmult_indicator) (auto simp: measurable_sets)
  1987   also have "\<dots> \<le> integral\<^sup>P M (\<lambda>x. max 0 (f x))"
  1988     by (auto intro!: positive_integral_mono simp: indicator_def max_def)
  1989   finally have "\<infinity> * (emeasure M) (f -` {\<infinity>} \<inter> space M) \<le> integral\<^sup>P M f"
  1990     by (simp add: positive_integral_max_0)
  1991   moreover have "0 \<le> (emeasure M) (f -` {\<infinity>} \<inter> space M)"
  1992     by (rule emeasure_nonneg)
  1993   ultimately show ?thesis
  1994     using assms by (auto split: split_if_asm)
  1995 qed
  1996 
  1997 lemma positive_integral_PInf_AE:
  1998   assumes "f \<in> borel_measurable M" "integral\<^sup>P M f \<noteq> \<infinity>" shows "AE x in M. f x \<noteq> \<infinity>"
  1999 proof (rule AE_I)
  2000   show "(emeasure M) (f -` {\<infinity>} \<inter> space M) = 0"
  2001     by (rule positive_integral_PInf[OF assms])
  2002   show "f -` {\<infinity>} \<inter> space M \<in> sets M"
  2003     using assms by (auto intro: borel_measurable_vimage)
  2004 qed auto
  2005 
  2006 lemma simple_integral_PInf:
  2007   assumes "simple_function M f" "\<And>x. 0 \<le> f x"
  2008   and "integral\<^sup>S M f \<noteq> \<infinity>"
  2009   shows "(emeasure M) (f -` {\<infinity>} \<inter> space M) = 0"
  2010 proof (rule positive_integral_PInf)
  2011   show "f \<in> borel_measurable M" using assms by (auto intro: borel_measurable_simple_function)
  2012   show "integral\<^sup>P M f \<noteq> \<infinity>"
  2013     using assms by (simp add: positive_integral_eq_simple_integral)
  2014 qed
  2015 
  2016 lemma integral_real:
  2017   "AE x in M. \<bar>f x\<bar> \<noteq> \<infinity> \<Longrightarrow> (\<integral>x. real (f x) \<partial>M) = real (integral\<^sup>P M f) - real (integral\<^sup>P M (\<lambda>x. - f x))"
  2018   using assms unfolding lebesgue_integral_def
  2019   by (subst (1 2) positive_integral_cong_AE) (auto simp add: ereal_real)
  2020 
  2021 lemma (in finite_measure) lebesgue_integral_const[simp]:
  2022   shows "integrable M (\<lambda>x. a)"
  2023   and  "(\<integral>x. a \<partial>M) = a * measure M (space M)"
  2024 proof -
  2025   { fix a :: real assume "0 \<le> a"
  2026     then have "(\<integral>\<^sup>+ x. ereal a \<partial>M) = ereal a * (emeasure M) (space M)"
  2027       by (subst positive_integral_const) auto
  2028     moreover
  2029     from `0 \<le> a` have "(\<integral>\<^sup>+ x. ereal (-a) \<partial>M) = 0"
  2030       by (subst positive_integral_0_iff_AE) auto
  2031     ultimately have "integrable M (\<lambda>x. a)" by (auto simp: integrable_def) }
  2032   note * = this
  2033   show "integrable M (\<lambda>x. a)"
  2034   proof cases
  2035     assume "0 \<le> a" with * show ?thesis .
  2036   next
  2037     assume "\<not> 0 \<le> a"
  2038     then have "0 \<le> -a" by auto
  2039     from *[OF this] show ?thesis by simp
  2040   qed
  2041   show "(\<integral>x. a \<partial>M) = a * measure M (space M)"
  2042     by (simp add: lebesgue_integral_def positive_integral_const_If emeasure_eq_measure)
  2043 qed
  2044 
  2045 lemma (in finite_measure) integrable_const_bound:
  2046   assumes "AE x in M. \<bar>f x\<bar> \<le> B" and "f \<in> borel_measurable M" shows "integrable M f"
  2047   by (auto intro: integrable_bound[where f="\<lambda>x. B"] lebesgue_integral_const assms)
  2048 
  2049 lemma indicator_less[simp]:
  2050   "indicator A x \<le> (indicator B x::ereal) \<longleftrightarrow> (x \<in> A \<longrightarrow> x \<in> B)"
  2051   by (simp add: indicator_def not_le)
  2052 
  2053 lemma (in finite_measure) integral_less_AE:
  2054   assumes int: "integrable M X" "integrable M Y"
  2055   assumes A: "(emeasure M) A \<noteq> 0" "A \<in> sets M" "AE x in M. x \<in> A \<longrightarrow> X x \<noteq> Y x"
  2056   assumes gt: "AE x in M. X x \<le> Y x"
  2057   shows "integral\<^sup>L M X < integral\<^sup>L M Y"
  2058 proof -
  2059   have "integral\<^sup>L M X \<le> integral\<^sup>L M Y"
  2060     using gt int by (intro integral_mono_AE) auto
  2061   moreover
  2062   have "integral\<^sup>L M X \<noteq> integral\<^sup>L M Y"
  2063   proof
  2064     assume eq: "integral\<^sup>L M X = integral\<^sup>L M Y"
  2065     have "integral\<^sup>L M (\<lambda>x. \<bar>Y x - X x\<bar>) = integral\<^sup>L M (\<lambda>x. Y x - X x)"
  2066       using gt by (intro integral_cong_AE) auto
  2067     also have "\<dots> = 0"
  2068       using eq int by simp
  2069     finally have "(emeasure M) {x \<in> space M. Y x - X x \<noteq> 0} = 0"
  2070       using int by (simp add: integral_0_iff)
  2071     moreover
  2072     have "(\<integral>\<^sup>+x. indicator A x \<partial>M) \<le> (\<integral>\<^sup>+x. indicator {x \<in> space M. Y x - X x \<noteq> 0} x \<partial>M)"
  2073       using A by (intro positive_integral_mono_AE) auto
  2074     then have "(emeasure M) A \<le> (emeasure M) {x \<in> space M. Y x - X x \<noteq> 0}"
  2075       using int A by (simp add: integrable_def)
  2076     ultimately have "emeasure M A = 0"
  2077       using emeasure_nonneg[of M A] by simp
  2078     with `(emeasure M) A \<noteq> 0` show False by auto
  2079   qed
  2080   ultimately show ?thesis by auto
  2081 qed
  2082 
  2083 lemma (in finite_measure) integral_less_AE_space:
  2084   assumes int: "integrable M X" "integrable M Y"
  2085   assumes gt: "AE x in M. X x < Y x" "(emeasure M) (space M) \<noteq> 0"
  2086   shows "integral\<^sup>L M X < integral\<^sup>L M Y"
  2087   using gt by (intro integral_less_AE[OF int, where A="space M"]) auto
  2088 
  2089 lemma integral_dominated_convergence:
  2090   assumes u[measurable]: "\<And>i. integrable M (u i)" and bound: "\<And>j. AE x in M. \<bar>u j x\<bar> \<le> w x"
  2091   and w[measurable]: "integrable M w"
  2092   and u': "AE x in M. (\<lambda>i. u i x) ----> u' x"
  2093   and [measurable]: "u' \<in> borel_measurable M"
  2094   shows "integrable M u'"
  2095   and "(\<lambda>i. (\<integral>x. \<bar>u i x - u' x\<bar> \<partial>M)) ----> 0" (is "?lim_diff")
  2096   and "(\<lambda>i. integral\<^sup>L M (u i)) ----> integral\<^sup>L M u'" (is ?lim)
  2097 proof -
  2098   have all_bound: "AE x in M. \<forall>j. \<bar>u j x\<bar> \<le> w x"
  2099     using bound by (auto simp: AE_all_countable)
  2100   with u' have u'_bound: "AE x in M. \<bar>u' x\<bar> \<le> w x"
  2101     by eventually_elim (auto intro: LIMSEQ_le_const2 tendsto_rabs)
  2102 
  2103   from bound[of 0] have w_pos: "AE x in M. 0 \<le> w x"
  2104     by eventually_elim auto
  2105 
  2106   show "integrable M u'"
  2107     by (rule integrable_bound) fact+
  2108 
  2109   let ?diff = "\<lambda>n x. 2 * w x - \<bar>u n x - u' x\<bar>"
  2110   have diff: "\<And>n. integrable M (\<lambda>x. \<bar>u n x - u' x\<bar>)"
  2111     using w u `integrable M u'` by (auto intro!: integrable_abs)
  2112 
  2113   from u'_bound all_bound
  2114   have diff_less_2w: "AE x in M. \<forall>j. \<bar>u j x - u' x\<bar> \<le> 2 * w x"
  2115   proof (eventually_elim, intro allI)
  2116     fix x j assume *: "\<bar>u' x\<bar> \<le> w x" "\<forall>j. \<bar>u j x\<bar> \<le> w x"
  2117     then have "\<bar>u j x - u' x\<bar> \<le> \<bar>u j x\<bar> + \<bar>u' x\<bar>" by auto
  2118     also have "\<dots> \<le> w x + w x"
  2119       using * by (intro add_mono) auto
  2120     finally show "\<bar>u j x - u' x\<bar> \<le> 2 * w x" by simp
  2121   qed
  2122 
  2123   have PI_diff: "\<And>n. (\<integral>\<^sup>+ x. ereal (?diff n x) \<partial>M) =
  2124     (\<integral>\<^sup>+ x. ereal (2 * w x) \<partial>M) - (\<integral>\<^sup>+ x. ereal \<bar>u n x - u' x\<bar> \<partial>M)"
  2125     using diff w diff_less_2w w_pos
  2126     by (subst positive_integral_diff[symmetric])
  2127        (auto simp: integrable_def intro!: positive_integral_cong_AE)
  2128 
  2129   have "integrable M (\<lambda>x. 2 * w x)"
  2130     using w by auto
  2131   hence I2w_fin: "(\<integral>\<^sup>+ x. ereal (2 * w x) \<partial>M) \<noteq> \<infinity>" and
  2132     borel_2w: "(\<lambda>x. ereal (2 * w x)) \<in> borel_measurable M"
  2133     unfolding integrable_def by auto
  2134 
  2135   have "limsup (\<lambda>n. \<integral>\<^sup>+ x. ereal \<bar>u n x - u' x\<bar> \<partial>M) = 0" (is "limsup ?f = 0")
  2136   proof cases
  2137     assume eq_0: "(\<integral>\<^sup>+ x. max 0 (ereal (2 * w x)) \<partial>M) = 0" (is "?wx = 0")
  2138     { fix n
  2139       have "?f n \<le> ?wx" (is "integral\<^sup>P M ?f' \<le> _")
  2140         using diff_less_2w unfolding positive_integral_max_0
  2141         by (intro positive_integral_mono_AE) auto
  2142       then have "?f n = 0"
  2143         using positive_integral_positive[of M ?f'] eq_0 by auto }
  2144     then show ?thesis by (simp add: Limsup_const)
  2145   next
  2146     assume neq_0: "(\<integral>\<^sup>+ x. max 0 (ereal (2 * w x)) \<partial>M) \<noteq> 0" (is "?wx \<noteq> 0")
  2147     have "0 = limsup (\<lambda>n. 0 :: ereal)" by (simp add: Limsup_const)
  2148     also have "\<dots> \<le> limsup (\<lambda>n. \<integral>\<^sup>+ x. ereal \<bar>u n x - u' x\<bar> \<partial>M)"
  2149       by (simp add: Limsup_mono  positive_integral_positive)
  2150     finally have pos: "0 \<le> limsup (\<lambda>n. \<integral>\<^sup>+ x. ereal \<bar>u n x - u' x\<bar> \<partial>M)" .
  2151     have "?wx = (\<integral>\<^sup>+ x. liminf (\<lambda>n. max 0 (ereal (?diff n x))) \<partial>M)"
  2152       using u'
  2153     proof (intro positive_integral_cong_AE, eventually_elim)
  2154       fix x assume u': "(\<lambda>i. u i x) ----> u' x"
  2155       show "max 0 (ereal (2 * w x)) = liminf (\<lambda>n. max 0 (ereal (?diff n x)))"
  2156         unfolding ereal_max_0
  2157       proof (rule lim_imp_Liminf[symmetric], unfold lim_ereal)
  2158         have "(\<lambda>i. ?diff i x) ----> 2 * w x - \<bar>u' x - u' x\<bar>"
  2159           using u' by (safe intro!: tendsto_intros)
  2160         then show "(\<lambda>i. max 0 (?diff i x)) ----> max 0 (2 * w x)"
  2161           by (auto intro!: tendsto_real_max)
  2162       qed (rule trivial_limit_sequentially)
  2163     qed
  2164     also have "\<dots> \<le> liminf (\<lambda>n. \<integral>\<^sup>+ x. max 0 (ereal (?diff n x)) \<partial>M)"
  2165       using w u unfolding integrable_def
  2166       by (intro positive_integral_lim_INF) (auto intro!: positive_integral_lim_INF)
  2167     also have "\<dots> = (\<integral>\<^sup>+ x. ereal (2 * w x) \<partial>M) -
  2168         limsup (\<lambda>n. \<integral>\<^sup>+ x. ereal \<bar>u n x - u' x\<bar> \<partial>M)"
  2169       unfolding PI_diff positive_integral_max_0
  2170       using positive_integral_positive[of M "\<lambda>x. ereal (2 * w x)"]
  2171       by (subst liminf_ereal_cminus) auto
  2172     finally show ?thesis
  2173       using neq_0 I2w_fin positive_integral_positive[of M "\<lambda>x. ereal (2 * w x)"] pos
  2174       unfolding positive_integral_max_0
  2175       by (cases rule: ereal2_cases[of "\<integral>\<^sup>+ x. ereal (2 * w x) \<partial>M" "limsup (\<lambda>n. \<integral>\<^sup>+ x. ereal \<bar>u n x - u' x\<bar> \<partial>M)"])
  2176          auto
  2177   qed
  2178 
  2179   have "liminf ?f \<le> limsup ?f"
  2180     by (intro Liminf_le_Limsup trivial_limit_sequentially)
  2181   moreover
  2182   { have "0 = liminf (\<lambda>n. 0 :: ereal)" by (simp add: Liminf_const)
  2183     also have "\<dots> \<le> liminf ?f"
  2184       by (simp add: Liminf_mono positive_integral_positive)
  2185     finally have "0 \<le> liminf ?f" . }
  2186   ultimately have liminf_limsup_eq: "liminf ?f = ereal 0" "limsup ?f = ereal 0"
  2187     using `limsup ?f = 0` by auto
  2188   have "\<And>n. (\<integral>\<^sup>+ x. ereal \<bar>u n x - u' x\<bar> \<partial>M) = ereal (\<integral>x. \<bar>u n x - u' x\<bar> \<partial>M)"
  2189     using diff positive_integral_positive[of M]
  2190     by (subst integral_eq_positive_integral[of _ M]) (auto simp: ereal_real integrable_def)
  2191   then show ?lim_diff
  2192     using Liminf_eq_Limsup[OF trivial_limit_sequentially liminf_limsup_eq]
  2193     by simp
  2194 
  2195   show ?lim
  2196   proof (rule LIMSEQ_I)
  2197     fix r :: real assume "0 < r"
  2198     from LIMSEQ_D[OF `?lim_diff` this]
  2199     obtain N where N: "\<And>n. N \<le> n \<Longrightarrow> (\<integral>x. \<bar>u n x - u' x\<bar> \<partial>M) < r"
  2200       using diff by (auto simp: integral_positive)
  2201 
  2202     show "\<exists>N. \<forall>n\<ge>N. norm (integral\<^sup>L M (u n) - integral\<^sup>L M u') < r"
  2203     proof (safe intro!: exI[of _ N])
  2204       fix n assume "N \<le> n"
  2205       have "\<bar>integral\<^sup>L M (u n) - integral\<^sup>L M u'\<bar> = \<bar>(\<integral>x. u n x - u' x \<partial>M)\<bar>"
  2206         using u `integrable M u'` by auto
  2207       also have "\<dots> \<le> (\<integral>x. \<bar>u n x - u' x\<bar> \<partial>M)" using u `integrable M u'`
  2208         by (rule_tac integral_triangle_inequality) auto
  2209       also note N[OF `N \<le> n`]
  2210       finally show "norm (integral\<^sup>L M (u n) - integral\<^sup>L M u') < r" by simp
  2211     qed
  2212   qed
  2213 qed
  2214 
  2215 lemma integral_sums:
  2216   assumes integrable[measurable]: "\<And>i. integrable M (f i)"
  2217   and summable: "\<And>x. x \<in> space M \<Longrightarrow> summable (\<lambda>i. \<bar>f i x\<bar>)"
  2218   and sums: "summable (\<lambda>i. (\<integral>x. \<bar>f i x\<bar> \<partial>M))"
  2219   shows "integrable M (\<lambda>x. (\<Sum>i. f i x))" (is "integrable M ?S")
  2220   and "(\<lambda>i. integral\<^sup>L M (f i)) sums (\<integral>x. (\<Sum>i. f i x) \<partial>M)" (is ?integral)
  2221 proof -
  2222   have "\<forall>x\<in>space M. \<exists>w. (\<lambda>i. \<bar>f i x\<bar>) sums w"
  2223     using summable unfolding summable_def by auto
  2224   from bchoice[OF this]
  2225   obtain w where w: "\<And>x. x \<in> space M \<Longrightarrow> (\<lambda>i. \<bar>f i x\<bar>) sums w x" by auto
  2226   then have w_borel: "w \<in> borel_measurable M" unfolding sums_def
  2227     by (rule borel_measurable_LIMSEQ) auto
  2228 
  2229   let ?w = "\<lambda>y. if y \<in> space M then w y else 0"
  2230 
  2231   obtain x where abs_sum: "(\<lambda>i. (\<integral>x. \<bar>f i x\<bar> \<partial>M)) sums x"
  2232     using sums unfolding summable_def ..
  2233 
  2234   have 1: "\<And>n. integrable M (\<lambda>x. \<Sum>i = 0..<n. f i x)"
  2235     using integrable by auto
  2236 
  2237   have 2: "\<And>j. AE x in M. \<bar>\<Sum>i = 0..<j. f i x\<bar> \<le> ?w x"
  2238     using AE_space
  2239   proof eventually_elim
  2240     fix j x assume [simp]: "x \<in> space M"
  2241     have "\<bar>\<Sum>i = 0..< j. f i x\<bar> \<le> (\<Sum>i = 0..< j. \<bar>f i x\<bar>)" by (rule setsum_abs)
  2242     also have "\<dots> \<le> w x" using w[of x] series_pos_le[of "\<lambda>i. \<bar>f i x\<bar>"] unfolding sums_iff by auto
  2243     finally show "\<bar>\<Sum>i = 0..<j. f i x\<bar> \<le> ?w x" by simp
  2244   qed
  2245 
  2246   have 3: "integrable M ?w"
  2247   proof (rule integral_monotone_convergence(1))
  2248     let ?F = "\<lambda>n y. (\<Sum>i = 0..<n. \<bar>f i y\<bar>)"
  2249     let ?w' = "\<lambda>n y. if y \<in> space M then ?F n y else 0"
  2250     have "\<And>n. integrable M (?F n)"
  2251       using integrable by (auto intro!: integrable_abs)
  2252     thus "\<And>n. integrable M (?w' n)" by (simp cong: integrable_cong)
  2253     show "AE x in M. mono (\<lambda>n. ?w' n x)"
  2254       by (auto simp: mono_def le_fun_def intro!: setsum_mono2)
  2255     show "AE x in M. (\<lambda>n. ?w' n x) ----> ?w x"
  2256         using w by (simp_all add: tendsto_const sums_def)
  2257     have *: "\<And>n. integral\<^sup>L M (?w' n) = (\<Sum>i = 0..< n. (\<integral>x. \<bar>f i x\<bar> \<partial>M))"
  2258       using integrable by (simp add: integrable_abs cong: integral_cong)
  2259     from abs_sum
  2260     show "(\<lambda>i. integral\<^sup>L M (?w' i)) ----> x" unfolding * sums_def .
  2261   qed (simp add: w_borel measurable_If_set)
  2262 
  2263   from summable[THEN summable_rabs_cancel]
  2264   have 4: "AE x in M. (\<lambda>n. \<Sum>i = 0..<n. f i x) ----> (\<Sum>i. f i x)"
  2265     by (auto intro: summable_sumr_LIMSEQ_suminf)
  2266 
  2267   note int = integral_dominated_convergence(1,3)[OF 1 2 3 4
  2268     borel_measurable_suminf[OF integrableD(1)[OF integrable]]]
  2269 
  2270   from int show "integrable M ?S" by simp
  2271 
  2272   show ?integral unfolding sums_def integral_setsum(1)[symmetric, OF integrable]
  2273     using int(2) by simp
  2274 qed
  2275 
  2276 lemma integrable_mult_indicator:
  2277   "A \<in> sets M \<Longrightarrow> integrable M f \<Longrightarrow> integrable M (\<lambda>x. f x * indicator A x)"
  2278   by (rule integrable_bound[where f="\<lambda>x. \<bar>f x\<bar>"])
  2279      (auto intro: integrable_abs split: split_indicator)
  2280 
  2281 lemma tendsto_integral_at_top:
  2282   fixes M :: "real measure"
  2283   assumes M: "sets M = sets borel" and f[measurable]: "integrable M f"
  2284   shows "((\<lambda>y. \<integral> x. f x * indicator {.. y} x \<partial>M) ---> \<integral> x. f x \<partial>M) at_top"
  2285 proof -
  2286   have M_measure[simp]: "borel_measurable M = borel_measurable borel"
  2287     using M by (simp add: sets_eq_imp_space_eq measurable_def)
  2288   { fix f assume f: "integrable M f" "\<And>x. 0 \<le> f x"
  2289     then have [measurable]: "f \<in> borel_measurable borel"
  2290       by (simp add: integrable_def)
  2291     have "((\<lambda>y. \<integral> x. f x * indicator {.. y} x \<partial>M) ---> \<integral> x. f x \<partial>M) at_top"
  2292     proof (rule tendsto_at_topI_sequentially)
  2293       have "\<And>j. AE x in M. \<bar>f x * indicator {.. j} x\<bar> \<le> f x"
  2294         using f(2) by (intro AE_I2) (auto split: split_indicator)
  2295       have int: "\<And>n. integrable M (\<lambda>x. f x * indicator {.. n} x)"
  2296         by (rule integrable_mult_indicator) (auto simp: M f)
  2297       show "(\<lambda>n. \<integral> x. f x * indicator {..real n} x \<partial>M) ----> integral\<^sup>L M f"
  2298       proof (rule integral_dominated_convergence)
  2299         { fix x have "eventually (\<lambda>n. f x * indicator {..real n} x = f x) sequentially"
  2300             by (rule eventually_sequentiallyI[of "natceiling x"])
  2301                (auto split: split_indicator simp: natceiling_le_eq) }
  2302         from filterlim_cong[OF refl refl this]
  2303         show "AE x in M. (\<lambda>n. f x * indicator {..real n} x) ----> f x"
  2304           by (simp add: tendsto_const)
  2305       qed (fact+, simp)
  2306       show "mono (\<lambda>y. \<integral> x. f x * indicator {..y} x \<partial>M)"
  2307         by (intro monoI integral_mono int) (auto split: split_indicator intro: f)
  2308     qed }
  2309   note nonneg = this
  2310   let ?P = "\<lambda>y. \<integral> x. max 0 (f x) * indicator {..y} x \<partial>M"
  2311   let ?N = "\<lambda>y. \<integral> x. max 0 (- f x) * indicator {..y} x \<partial>M"
  2312   let ?p = "integral\<^sup>L M (\<lambda>x. max 0 (f x))"
  2313   let ?n = "integral\<^sup>L M (\<lambda>x. max 0 (- f x))"
  2314   have "(?P ---> ?p) at_top" "(?N ---> ?n) at_top"
  2315     by (auto intro!: nonneg integrable_max f)
  2316   note tendsto_diff[OF this]
  2317   also have "(\<lambda>y. ?P y - ?N y) = (\<lambda>y. \<integral> x. f x * indicator {..y} x \<partial>M)"
  2318     by (subst integral_diff(2)[symmetric])
  2319        (auto intro!: integrable_mult_indicator integrable_max f integral_cong ext
  2320              simp: M split: split_max)
  2321   also have "?p - ?n = integral\<^sup>L M f"
  2322     by (subst integral_diff(2)[symmetric])
  2323        (auto intro!: integrable_max f integral_cong ext simp: M split: split_max)
  2324   finally show ?thesis .
  2325 qed
  2326 
  2327 lemma integral_monotone_convergence_at_top:
  2328   fixes M :: "real measure"
  2329   assumes M: "sets M = sets borel"
  2330   assumes nonneg: "AE x in M. 0 \<le> f x"
  2331   assumes borel: "f \<in> borel_measurable borel"
  2332   assumes int: "\<And>y. integrable M (\<lambda>x. f x * indicator {.. y} x)"
  2333   assumes conv: "((\<lambda>y. \<integral> x. f x * indicator {.. y} x \<partial>M) ---> x) at_top"
  2334   shows "integrable M f" "integral\<^sup>L M f = x"
  2335 proof -
  2336   from nonneg have "AE x in M. mono (\<lambda>n::nat. f x * indicator {..real n} x)"
  2337     by (auto split: split_indicator intro!: monoI)
  2338   { fix x have "eventually (\<lambda>n. f x * indicator {..real n} x = f x) sequentially"
  2339       by (rule eventually_sequentiallyI[of "natceiling x"])
  2340          (auto split: split_indicator simp: natceiling_le_eq) }
  2341   from filterlim_cong[OF refl refl this]
  2342   have "AE x in M. (\<lambda>i. f x * indicator {..real i} x) ----> f x"
  2343     by (simp add: tendsto_const)
  2344   have "(\<lambda>i. \<integral> x. f x * indicator {..real i} x \<partial>M) ----> x"
  2345     using conv filterlim_real_sequentially by (rule filterlim_compose)
  2346   have M_measure[simp]: "borel_measurable M = borel_measurable borel"
  2347     using M by (simp add: sets_eq_imp_space_eq measurable_def)
  2348   have "f \<in> borel_measurable M"
  2349     using borel by simp
  2350   show "integrable M f"
  2351     by (rule integral_monotone_convergence) fact+
  2352   show "integral\<^sup>L M f = x"
  2353     by (rule integral_monotone_convergence) fact+
  2354 qed
  2355 
  2356 
  2357 section "Lebesgue integration on countable spaces"
  2358 
  2359 lemma integral_on_countable:
  2360   assumes f: "f \<in> borel_measurable M"
  2361   and bij: "bij_betw enum S (f ` space M)"
  2362   and enum_zero: "enum ` (-S) \<subseteq> {0}"
  2363   and fin: "\<And>x. x \<noteq> 0 \<Longrightarrow> (emeasure M) (f -` {x} \<inter> space M) \<noteq> \<infinity>"
  2364   and abs_summable: "summable (\<lambda>r. \<bar>enum r * real ((emeasure M) (f -` {enum r} \<inter> space M))\<bar>)"
  2365   shows "integrable M f"
  2366   and "(\<lambda>r. enum r * real ((emeasure M) (f -` {enum r} \<inter> space M))) sums integral\<^sup>L M f" (is ?sums)
  2367 proof -
  2368   let ?A = "\<lambda>r. f -` {enum r} \<inter> space M"
  2369   let ?F = "\<lambda>r x. enum r * indicator (?A r) x"
  2370   have enum_eq: "\<And>r. enum r * real ((emeasure M) (?A r)) = integral\<^sup>L M (?F r)"
  2371     using f fin by (simp add: borel_measurable_vimage integral_cmul_indicator)
  2372 
  2373   { fix x assume "x \<in> space M"
  2374     hence "f x \<in> enum ` S" using bij unfolding bij_betw_def by auto
  2375     then obtain i where "i\<in>S" "enum i = f x" by auto
  2376     have F: "\<And>j. ?F j x = (if j = i then f x else 0)"
  2377     proof cases
  2378       fix j assume "j = i"
  2379       thus "?thesis j" using `x \<in> space M` `enum i = f x` by (simp add: indicator_def)
  2380     next
  2381       fix j assume "j \<noteq> i"
  2382       show "?thesis j" using bij `i \<in> S` `j \<noteq> i` `enum i = f x` enum_zero
  2383         by (cases "j \<in> S") (auto simp add: indicator_def bij_betw_def inj_on_def)
  2384     qed
  2385     hence F_abs: "\<And>j. \<bar>if j = i then f x else 0\<bar> = (if j = i then \<bar>f x\<bar> else 0)" by auto
  2386     have "(\<lambda>i. ?F i x) sums f x"
  2387          "(\<lambda>i. \<bar>?F i x\<bar>) sums \<bar>f x\<bar>"
  2388       by (auto intro!: sums_single simp: F F_abs) }
  2389   note F_sums_f = this(1) and F_abs_sums_f = this(2)
  2390 
  2391   have int_f: "integral\<^sup>L M f = (\<integral>x. (\<Sum>r. ?F r x) \<partial>M)" "integrable M f = integrable M (\<lambda>x. \<Sum>r. ?F r x)"
  2392     using F_sums_f by (auto intro!: integral_cong integrable_cong simp: sums_iff)
  2393 
  2394   { fix r
  2395     have "(\<integral>x. \<bar>?F r x\<bar> \<partial>M) = (\<integral>x. \<bar>enum r\<bar> * indicator (?A r) x \<partial>M)"
  2396       by (auto simp: indicator_def intro!: integral_cong)
  2397     also have "\<dots> = \<bar>enum r\<bar> * real ((emeasure M) (?A r))"
  2398       using f fin by (simp add: borel_measurable_vimage integral_cmul_indicator)
  2399     finally have "(\<integral>x. \<bar>?F r x\<bar> \<partial>M) = \<bar>enum r * real ((emeasure M) (?A r))\<bar>"
  2400       using f by (subst (2) abs_mult_pos[symmetric]) (auto intro!: real_of_ereal_pos measurable_sets) }
  2401   note int_abs_F = this
  2402 
  2403   have 1: "\<And>i. integrable M (\<lambda>x. ?F i x)"
  2404     using f fin by (simp add: borel_measurable_vimage integral_cmul_indicator)
  2405 
  2406   have 2: "\<And>x. x \<in> space M \<Longrightarrow> summable (\<lambda>i. \<bar>?F i x\<bar>)"
  2407     using F_abs_sums_f unfolding sums_iff by auto
  2408 
  2409   from integral_sums(2)[OF 1 2, unfolded int_abs_F, OF _ abs_summable]
  2410   show ?sums unfolding enum_eq int_f by simp
  2411 
  2412   from integral_sums(1)[OF 1 2, unfolded int_abs_F, OF _ abs_summable]
  2413   show "integrable M f" unfolding int_f by simp
  2414 qed
  2415 
  2416 section {* Distributions *}
  2417 
  2418 lemma positive_integral_distr':
  2419   assumes T: "T \<in> measurable M M'"
  2420   and f: "f \<in> borel_measurable (distr M M' T)" "\<And>x. 0 \<le> f x"
  2421   shows "integral\<^sup>P (distr M M' T) f = (\<integral>\<^sup>+ x. f (T x) \<partial>M)"
  2422   using f 
  2423 proof induct
  2424   case (cong f g)
  2425   with T show ?case
  2426     apply (subst positive_integral_cong[of _ f g])
  2427     apply simp
  2428     apply (subst positive_integral_cong[of _ "\<lambda>x. f (T x)" "\<lambda>x. g (T x)"])
  2429     apply (simp add: measurable_def Pi_iff)
  2430     apply simp
  2431     done
  2432 next
  2433   case (set A)
  2434   then have eq: "\<And>x. x \<in> space M \<Longrightarrow> indicator A (T x) = indicator (T -` A \<inter> space M) x"
  2435     by (auto simp: indicator_def)
  2436   from set T show ?case
  2437     by (subst positive_integral_cong[OF eq])
  2438        (auto simp add: emeasure_distr intro!: positive_integral_indicator[symmetric] measurable_sets)
  2439 qed (simp_all add: measurable_compose[OF T] T positive_integral_cmult positive_integral_add
  2440                    positive_integral_monotone_convergence_SUP le_fun_def incseq_def)
  2441 
  2442 lemma positive_integral_distr:
  2443   "T \<in> measurable M M' \<Longrightarrow> f \<in> borel_measurable M' \<Longrightarrow> integral\<^sup>P (distr M M' T) f = (\<integral>\<^sup>+ x. f (T x) \<partial>M)"
  2444   by (subst (1 2) positive_integral_max_0[symmetric])
  2445      (simp add: positive_integral_distr')
  2446 
  2447 lemma integral_distr:
  2448   "T \<in> measurable M M' \<Longrightarrow> f \<in> borel_measurable M' \<Longrightarrow> integral\<^sup>L (distr M M' T) f = (\<integral> x. f (T x) \<partial>M)"
  2449   unfolding lebesgue_integral_def
  2450   by (subst (1 2) positive_integral_distr) auto
  2451 
  2452 lemma integrable_distr_eq:
  2453   "T \<in> measurable M M' \<Longrightarrow> f \<in> borel_measurable M' \<Longrightarrow> integrable (distr M M' T) f \<longleftrightarrow> integrable M (\<lambda>x. f (T x))"
  2454   unfolding integrable_def 
  2455   by (subst (1 2) positive_integral_distr) (auto simp: comp_def)
  2456 
  2457 lemma integrable_distr:
  2458   "T \<in> measurable M M' \<Longrightarrow> integrable (distr M M' T) f \<Longrightarrow> integrable M (\<lambda>x. f (T x))"
  2459   by (subst integrable_distr_eq[symmetric]) auto
  2460 
  2461 section {* Lebesgue integration on @{const count_space} *}
  2462 
  2463 lemma simple_function_count_space[simp]:
  2464   "simple_function (count_space A) f \<longleftrightarrow> finite (f ` A)"
  2465   unfolding simple_function_def by simp
  2466 
  2467 lemma positive_integral_count_space:
  2468   assumes A: "finite {a\<in>A. 0 < f a}"
  2469   shows "integral\<^sup>P (count_space A) f = (\<Sum>a|a\<in>A \<and> 0 < f a. f a)"
  2470 proof -
  2471   have *: "(\<integral>\<^sup>+x. max 0 (f x) \<partial>count_space A) =
  2472     (\<integral>\<^sup>+ x. (\<Sum>a|a\<in>A \<and> 0 < f a. f a * indicator {a} x) \<partial>count_space A)"
  2473     by (auto intro!: positive_integral_cong
  2474              simp add: indicator_def if_distrib setsum_cases[OF A] max_def le_less)
  2475   also have "\<dots> = (\<Sum>a|a\<in>A \<and> 0 < f a. \<integral>\<^sup>+ x. f a * indicator {a} x \<partial>count_space A)"
  2476     by (subst positive_integral_setsum)
  2477        (simp_all add: AE_count_space ereal_zero_le_0_iff less_imp_le)
  2478   also have "\<dots> = (\<Sum>a|a\<in>A \<and> 0 < f a. f a)"
  2479     by (auto intro!: setsum_cong simp: positive_integral_cmult_indicator one_ereal_def[symmetric])
  2480   finally show ?thesis by (simp add: positive_integral_max_0)
  2481 qed
  2482 
  2483 lemma integrable_count_space:
  2484   "finite X \<Longrightarrow> integrable (count_space X) f"
  2485   by (auto simp: positive_integral_count_space integrable_def)
  2486 
  2487 lemma positive_integral_count_space_finite:
  2488     "finite A \<Longrightarrow> (\<integral>\<^sup>+x. f x \<partial>count_space A) = (\<Sum>a\<in>A. max 0 (f a))"
  2489   by (subst positive_integral_max_0[symmetric])
  2490      (auto intro!: setsum_mono_zero_left simp: positive_integral_count_space less_le)
  2491 
  2492 lemma lebesgue_integral_count_space_finite_support:
  2493   assumes f: "finite {a\<in>A. f a \<noteq> 0}" shows "(\<integral>x. f x \<partial>count_space A) = (\<Sum>a | a \<in> A \<and> f a \<noteq> 0. f a)"
  2494 proof -
  2495   have *: "\<And>r::real. 0 < max 0 r \<longleftrightarrow> 0 < r" "\<And>x. max 0 (ereal x) = ereal (max 0 x)"
  2496     "\<And>a. a \<in> A \<and> 0 < f a \<Longrightarrow> max 0 (f a) = f a"
  2497     "\<And>a. a \<in> A \<and> f a < 0 \<Longrightarrow> max 0 (- f a) = - f a"
  2498     "{a \<in> A. f a \<noteq> 0} = {a \<in> A. 0 < f a} \<union> {a \<in> A. f a < 0}"
  2499     "({a \<in> A. 0 < f a} \<inter> {a \<in> A. f a < 0}) = {}"
  2500     by (auto split: split_max)
  2501   have "finite {a \<in> A. 0 < f a}" "finite {a \<in> A. f a < 0}"
  2502     by (auto intro: finite_subset[OF _ f])
  2503   then show ?thesis
  2504     unfolding lebesgue_integral_def
  2505     apply (subst (1 2) positive_integral_max_0[symmetric])
  2506     apply (subst (1 2) positive_integral_count_space)
  2507     apply (auto simp add: * setsum_negf setsum_Un
  2508                 simp del: ereal_max)
  2509     done
  2510 qed
  2511 
  2512 lemma lebesgue_integral_count_space_finite:
  2513     "finite A \<Longrightarrow> (\<integral>x. f x \<partial>count_space A) = (\<Sum>a\<in>A. f a)"
  2514   apply (auto intro!: setsum_mono_zero_left
  2515               simp: positive_integral_count_space_finite lebesgue_integral_def)
  2516   apply (subst (1 2)  setsum_real_of_ereal[symmetric])
  2517   apply (auto simp: max_def setsum_subtractf[symmetric] intro!: setsum_cong)
  2518   done
  2519 
  2520 lemma borel_measurable_count_space[simp, intro!]:
  2521   "f \<in> borel_measurable (count_space A)"
  2522   by simp
  2523 
  2524 lemma lessThan_eq_empty_iff: "{..< n::nat} = {} \<longleftrightarrow> n = 0"
  2525   by auto
  2526 
  2527 lemma emeasure_UN_countable:
  2528   assumes sets: "\<And>i. i \<in> I \<Longrightarrow> X i \<in> sets M" and I: "countable I" 
  2529   assumes disj: "disjoint_family_on X I"
  2530   shows "emeasure M (UNION I X) = (\<integral>\<^sup>+i. emeasure M (X i) \<partial>count_space I)"
  2531 proof cases
  2532   assume "finite I" with sets disj show ?thesis
  2533     by (subst setsum_emeasure[symmetric])
  2534        (auto intro!: setsum_cong simp add: max_def subset_eq positive_integral_count_space_finite emeasure_nonneg)
  2535 next
  2536   assume f: "\<not> finite I"
  2537   then have [intro]: "I \<noteq> {}" by auto
  2538   from from_nat_into_inj_infinite[OF I f] from_nat_into[OF this] disj
  2539   have disj2: "disjoint_family (\<lambda>i. X (from_nat_into I i))"
  2540     unfolding disjoint_family_on_def by metis
  2541 
  2542   from f have "bij_betw (from_nat_into I) UNIV I"
  2543     using bij_betw_from_nat_into[OF I] by simp
  2544   then have "(\<Union>i\<in>I. X i) = (\<Union>i. (X \<circ> from_nat_into I) i)"
  2545     unfolding SUP_def image_comp [symmetric] by (simp add: bij_betw_def)
  2546   then have "emeasure M (UNION I X) = emeasure M (\<Union>i. X (from_nat_into I i))"
  2547     by simp
  2548   also have "\<dots> = (\<Sum>i. emeasure M (X (from_nat_into I i)))"
  2549     by (intro suminf_emeasure[symmetric] disj disj2) (auto intro!: sets from_nat_into[OF `I \<noteq> {}`])
  2550   also have "\<dots> = (\<Sum>n. \<integral>\<^sup>+i. emeasure M (X i) * indicator {from_nat_into I n} i \<partial>count_space I)"
  2551   proof (intro arg_cong[where f=suminf] ext)
  2552     fix i
  2553     have eq: "{a \<in> I. 0 < emeasure M (X a) * indicator {from_nat_into I i} a}
  2554      = (if 0 < emeasure M (X (from_nat_into I i)) then {from_nat_into I i} else {})"
  2555      using ereal_0_less_1
  2556      by (auto simp: ereal_zero_less_0_iff indicator_def from_nat_into `I \<noteq> {}` simp del: ereal_0_less_1)
  2557     have "(\<integral>\<^sup>+ ia. emeasure M (X ia) * indicator {from_nat_into I i} ia \<partial>count_space I) =
  2558       (if 0 < emeasure M (X (from_nat_into I i)) then emeasure M (X (from_nat_into I i)) else 0)"
  2559       by (subst positive_integral_count_space) (simp_all add: eq)
  2560     also have "\<dots> = emeasure M (X (from_nat_into I i))"
  2561       by (simp add: less_le emeasure_nonneg)
  2562     finally show "emeasure M (X (from_nat_into I i)) =
  2563          \<integral>\<^sup>+ ia. emeasure M (X ia) * indicator {from_nat_into I i} ia \<partial>count_space I" ..
  2564   qed
  2565   also have "\<dots> = (\<integral>\<^sup>+i. emeasure M (X i) \<partial>count_space I)"
  2566     apply (subst positive_integral_suminf[symmetric])
  2567     apply (auto simp: emeasure_nonneg intro!: positive_integral_cong)
  2568   proof -
  2569     fix x assume "x \<in> I"
  2570     then have "(\<Sum>i. emeasure M (X x) * indicator {from_nat_into I i} x) = (\<Sum>i\<in>{to_nat_on I x}. emeasure M (X x) * indicator {from_nat_into I i} x)"
  2571       by (intro suminf_finite) (auto simp: indicator_def I f)
  2572     also have "\<dots> = emeasure M (X x)"
  2573       by (simp add: I f `x\<in>I`)
  2574     finally show "(\<Sum>i. emeasure M (X x) * indicator {from_nat_into I i} x) = emeasure M (X x)" .
  2575   qed
  2576   finally show ?thesis .
  2577 qed
  2578 
  2579 section {* Measures with Restricted Space *}
  2580 
  2581 lemma positive_integral_restrict_space:
  2582   assumes \<Omega>: "\<Omega> \<in> sets M" and f: "f \<in> borel_measurable M" "\<And>x. 0 \<le> f x" "\<And>x. x \<in> space M - \<Omega> \<Longrightarrow> f x = 0"
  2583   shows "positive_integral (restrict_space M \<Omega>) f = positive_integral M f"
  2584 using f proof (induct rule: borel_measurable_induct)
  2585   case (cong f g) then show ?case
  2586     using positive_integral_cong[of M f g] positive_integral_cong[of "restrict_space M \<Omega>" f g]
  2587       sets.sets_into_space[OF `\<Omega> \<in> sets M`]
  2588     by (simp add: subset_eq space_restrict_space)
  2589 next
  2590   case (set A)
  2591   then have "A \<subseteq> \<Omega>"
  2592     unfolding indicator_eq_0_iff by (auto dest: sets.sets_into_space)
  2593   with set `\<Omega> \<in> sets M` sets.sets_into_space[OF `\<Omega> \<in> sets M`] show ?case
  2594     by (subst positive_integral_indicator')
  2595        (auto simp add: sets_restrict_space_iff space_restrict_space
  2596                   emeasure_restrict_space Int_absorb2
  2597                 dest: sets.sets_into_space)
  2598 next
  2599   case (mult f c) then show ?case
  2600     by (cases "c = 0") (simp_all add: measurable_restrict_space1 \<Omega> positive_integral_cmult)
  2601 next
  2602   case (add f g) then show ?case
  2603     by (simp add: measurable_restrict_space1 \<Omega> positive_integral_add ereal_add_nonneg_eq_0_iff)
  2604 next
  2605   case (seq F) then show ?case
  2606     by (auto simp add: SUP_eq_iff measurable_restrict_space1 \<Omega> positive_integral_monotone_convergence_SUP)
  2607 qed
  2608 
  2609 section {* Measure spaces with an associated density *}
  2610 
  2611 definition density :: "'a measure \<Rightarrow> ('a \<Rightarrow> ereal) \<Rightarrow> 'a measure" where
  2612   "density M f = measure_of (space M) (sets M) (\<lambda>A. \<integral>\<^sup>+ x. f x * indicator A x \<partial>M)"
  2613 
  2614 lemma 
  2615   shows sets_density[simp]: "sets (density M f) = sets M"
  2616     and space_density[simp]: "space (density M f) = space M"
  2617   by (auto simp: density_def)
  2618 
  2619 (* FIXME: add conversion to simplify space, sets and measurable *)
  2620 lemma space_density_imp[measurable_dest]:
  2621   "\<And>x M f. x \<in> space (density M f) \<Longrightarrow> x \<in> space M" by auto
  2622 
  2623 lemma 
  2624   shows measurable_density_eq1[simp]: "g \<in> measurable (density Mg f) Mg' \<longleftrightarrow> g \<in> measurable Mg Mg'"
  2625     and measurable_density_eq2[simp]: "h \<in> measurable Mh (density Mh' f) \<longleftrightarrow> h \<in> measurable Mh Mh'"
  2626     and simple_function_density_eq[simp]: "simple_function (density Mu f) u \<longleftrightarrow> simple_function Mu u"
  2627   unfolding measurable_def simple_function_def by simp_all
  2628 
  2629 lemma density_cong: "f \<in> borel_measurable M \<Longrightarrow> f' \<in> borel_measurable M \<Longrightarrow>
  2630   (AE x in M. f x = f' x) \<Longrightarrow> density M f = density M f'"
  2631   unfolding density_def by (auto intro!: measure_of_eq positive_integral_cong_AE sets.space_closed)
  2632 
  2633 lemma density_max_0: "density M f = density M (\<lambda>x. max 0 (f x))"
  2634 proof -
  2635   have "\<And>x A. max 0 (f x) * indicator A x = max 0 (f x * indicator A x)"
  2636     by (auto simp: indicator_def)
  2637   then show ?thesis
  2638     unfolding density_def by (simp add: positive_integral_max_0)
  2639 qed
  2640 
  2641 lemma density_ereal_max_0: "density M (\<lambda>x. ereal (f x)) = density M (\<lambda>x. ereal (max 0 (f x)))"
  2642   by (subst density_max_0) (auto intro!: arg_cong[where f="density M"] split: split_max)
  2643 
  2644 lemma emeasure_density:
  2645   assumes f[measurable]: "f \<in> borel_measurable M" and A[measurable]: "A \<in> sets M"
  2646   shows "emeasure (density M f) A = (\<integral>\<^sup>+ x. f x * indicator A x \<partial>M)"
  2647     (is "_ = ?\<mu> A")
  2648   unfolding density_def
  2649 proof (rule emeasure_measure_of_sigma)
  2650   show "sigma_algebra (space M) (sets M)" ..
  2651   show "positive (sets M) ?\<mu>"
  2652     using f by (auto simp: positive_def intro!: positive_integral_positive)
  2653   have \<mu>_eq: "?\<mu> = (\<lambda>A. \<integral>\<^sup>+ x. max 0 (f x) * indicator A x \<partial>M)" (is "?\<mu> = ?\<mu>'")
  2654     apply (subst positive_integral_max_0[symmetric])
  2655     apply (intro ext positive_integral_cong_AE AE_I2)
  2656     apply (auto simp: indicator_def)
  2657     done
  2658   show "countably_additive (sets M) ?\<mu>"
  2659     unfolding \<mu>_eq
  2660   proof (intro countably_additiveI)
  2661     fix A :: "nat \<Rightarrow> 'a set" assume "range A \<subseteq> sets M"
  2662     then have "\<And>i. A i \<in> sets M" by auto
  2663     then have *: "\<And>i. (\<lambda>x. max 0 (f x) * indicator (A i) x) \<in> borel_measurable M"
  2664       by (auto simp: set_eq_iff)
  2665     assume disj: "disjoint_family A"
  2666     have "(\<Sum>n. ?\<mu>' (A n)) = (\<integral>\<^sup>+ x. (\<Sum>n. max 0 (f x) * indicator (A n) x) \<partial>M)"
  2667       using f * by (simp add: positive_integral_suminf)
  2668     also have "\<dots> = (\<integral>\<^sup>+ x. max 0 (f x) * (\<Sum>n. indicator (A n) x) \<partial>M)" using f
  2669       by (auto intro!: suminf_cmult_ereal positive_integral_cong_AE)
  2670     also have "\<dots> = (\<integral>\<^sup>+ x. max 0 (f x) * indicator (\<Union>n. A n) x \<partial>M)"
  2671       unfolding suminf_indicator[OF disj] ..
  2672     finally show "(\<Sum>n. ?\<mu>' (A n)) = ?\<mu>' (\<Union>x. A x)" by simp
  2673   qed
  2674 qed fact
  2675 
  2676 lemma null_sets_density_iff:
  2677   assumes f: "f \<in> borel_measurable M"
  2678   shows "A \<in> null_sets (density M f) \<longleftrightarrow> A \<in> sets M \<and> (AE x in M. x \<in> A \<longrightarrow> f x \<le> 0)"
  2679 proof -
  2680   { assume "A \<in> sets M"
  2681     have eq: "(\<integral>\<^sup>+x. f x * indicator A x \<partial>M) = (\<integral>\<^sup>+x. max 0 (f x) * indicator A x \<partial>M)"
  2682       apply (subst positive_integral_max_0[symmetric])
  2683       apply (intro positive_integral_cong)
  2684       apply (auto simp: indicator_def)
  2685       done
  2686     have "(\<integral>\<^sup>+x. f x * indicator A x \<partial>M) = 0 \<longleftrightarrow> 
  2687       emeasure M {x \<in> space M. max 0 (f x) * indicator A x \<noteq> 0} = 0"
  2688       unfolding eq
  2689       using f `A \<in> sets M`
  2690       by (intro positive_integral_0_iff) auto
  2691     also have "\<dots> \<longleftrightarrow> (AE x in M. max 0 (f x) * indicator A x = 0)"
  2692       using f `A \<in> sets M`
  2693       by (intro AE_iff_measurable[OF _ refl, symmetric]) auto
  2694     also have "(AE x in M. max 0 (f x) * indicator A x = 0) \<longleftrightarrow> (AE x in M. x \<in> A \<longrightarrow> f x \<le> 0)"
  2695       by (auto simp add: indicator_def max_def split: split_if_asm)
  2696     finally have "(\<integral>\<^sup>+x. f x * indicator A x \<partial>M) = 0 \<longleftrightarrow> (AE x in M. x \<in> A \<longrightarrow> f x \<le> 0)" . }
  2697   with f show ?thesis
  2698     by (simp add: null_sets_def emeasure_density cong: conj_cong)
  2699 qed
  2700 
  2701 lemma AE_density:
  2702   assumes f: "f \<in> borel_measurable M"
  2703   shows "(AE x in density M f. P x) \<longleftrightarrow> (AE x in M. 0 < f x \<longrightarrow> P x)"
  2704 proof
  2705   assume "AE x in density M f. P x"
  2706   with f obtain N where "{x \<in> space M. \<not> P x} \<subseteq> N" "N \<in> sets M" and ae: "AE x in M. x \<in> N \<longrightarrow> f x \<le> 0"
  2707     by (auto simp: eventually_ae_filter null_sets_density_iff)
  2708   then have "AE x in M. x \<notin> N \<longrightarrow> P x" by auto
  2709   with ae show "AE x in M. 0 < f x \<longrightarrow> P x"
  2710     by (rule eventually_elim2) auto
  2711 next
  2712   fix N assume ae: "AE x in M. 0 < f x \<longrightarrow> P x"
  2713   then obtain N where "{x \<in> space M. \<not> (0 < f x \<longrightarrow> P x)} \<subseteq> N" "N \<in> null_sets M"
  2714     by (auto simp: eventually_ae_filter)
  2715   then have *: "{x \<in> space (density M f). \<not> P x} \<subseteq> N \<union> {x\<in>space M. \<not> 0 < f x}"
  2716     "N \<union> {x\<in>space M. \<not> 0 < f x} \<in> sets M" and ae2: "AE x in M. x \<notin> N"
  2717     using f by (auto simp: subset_eq intro!: sets.sets_Collect_neg AE_not_in)
  2718   show "AE x in density M f. P x"
  2719     using ae2
  2720     unfolding eventually_ae_filter[of _ "density M f"] Bex_def null_sets_density_iff[OF f]
  2721     by (intro exI[of _ "N \<union> {x\<in>space M. \<not> 0 < f x}"] conjI *)
  2722        (auto elim: eventually_elim2)
  2723 qed
  2724 
  2725 lemma positive_integral_density':
  2726   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
  2727   assumes g: "g \<in> borel_measurable M" "\<And>x. 0 \<le> g x"
  2728   shows "integral\<^sup>P (density M f) g = (\<integral>\<^sup>+ x. f x * g x \<partial>M)"
  2729 using g proof induct
  2730   case (cong u v)
  2731   then show ?case
  2732     apply (subst positive_integral_cong[OF cong(3)])
  2733     apply (simp_all cong: positive_integral_cong)
  2734     done
  2735 next
  2736   case (set A) then show ?case
  2737     by (simp add: emeasure_density f)
  2738 next
  2739   case (mult u c)
  2740   moreover have "\<And>x. f x * (c * u x) = c * (f x * u x)" by (simp add: field_simps)
  2741   ultimately show ?case
  2742     using f by (simp add: positive_integral_cmult)
  2743 next
  2744   case (add u v)
  2745   then have "\<And>x. f x * (v x + u x) = f x * v x + f x * u x"
  2746     by (simp add: ereal_right_distrib)
  2747   with add f show ?case
  2748     by (auto simp add: positive_integral_add ereal_zero_le_0_iff intro!: positive_integral_add[symmetric])
  2749 next
  2750   case (seq U)
  2751   from f(2) have eq: "AE x in M. f x * (SUP i. U i x) = (SUP i. f x * U i x)"
  2752     by eventually_elim (simp add: SUPR_ereal_cmult seq)
  2753   from seq f show ?case
  2754     apply (simp add: positive_integral_monotone_convergence_SUP)
  2755     apply (subst positive_integral_cong_AE[OF eq])
  2756     apply (subst positive_integral_monotone_convergence_SUP_AE)
  2757     apply (auto simp: incseq_def le_fun_def intro!: ereal_mult_left_mono)
  2758     done
  2759 qed
  2760 
  2761 lemma positive_integral_density:
  2762   "f \<in> borel_measurable M \<Longrightarrow> AE x in M. 0 \<le> f x \<Longrightarrow> g' \<in> borel_measurable M \<Longrightarrow> 
  2763     integral\<^sup>P (density M f) g' = (\<integral>\<^sup>+ x. f x * g' x \<partial>M)"
  2764   by (subst (1 2) positive_integral_max_0[symmetric])
  2765      (auto intro!: positive_integral_cong_AE
  2766            simp: measurable_If max_def ereal_zero_le_0_iff positive_integral_density')
  2767 
  2768 lemma integral_density:
  2769   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
  2770     and g: "g \<in> borel_measurable M"
  2771   shows "integral\<^sup>L (density M f) g = (\<integral> x. f x * g x \<partial>M)"
  2772     and "integrable (density M f) g \<longleftrightarrow> integrable M (\<lambda>x. f x * g x)"
  2773   unfolding lebesgue_integral_def integrable_def using f g
  2774   by (auto simp: positive_integral_density)
  2775 
  2776 lemma emeasure_restricted:
  2777   assumes S: "S \<in> sets M" and X: "X \<in> sets M"
  2778   shows "emeasure (density M (indicator S)) X = emeasure M (S \<inter> X)"
  2779 proof -
  2780   have "emeasure (density M (indicator S)) X = (\<integral>\<^sup>+x. indicator S x * indicator X x \<partial>M)"
  2781     using S X by (simp add: emeasure_density)
  2782   also have "\<dots> = (\<integral>\<^sup>+x. indicator (S \<inter> X) x \<partial>M)"
  2783     by (auto intro!: positive_integral_cong simp: indicator_def)
  2784   also have "\<dots> = emeasure M (S \<inter> X)"
  2785     using S X by (simp add: sets.Int)
  2786   finally show ?thesis .
  2787 qed
  2788 
  2789 lemma measure_restricted:
  2790   "S \<in> sets M \<Longrightarrow> X \<in> sets M \<Longrightarrow> measure (density M (indicator S)) X = measure M (S \<inter> X)"
  2791   by (simp add: emeasure_restricted measure_def)
  2792 
  2793 lemma (in finite_measure) finite_measure_restricted:
  2794   "S \<in> sets M \<Longrightarrow> finite_measure (density M (indicator S))"
  2795   by default (simp add: emeasure_restricted)
  2796 
  2797 lemma emeasure_density_const:
  2798   "A \<in> sets M \<Longrightarrow> 0 \<le> c \<Longrightarrow> emeasure (density M (\<lambda>_. c)) A = c * emeasure M A"
  2799   by (auto simp: positive_integral_cmult_indicator emeasure_density)
  2800 
  2801 lemma measure_density_const:
  2802   "A \<in> sets M \<Longrightarrow> 0 < c \<Longrightarrow> c \<noteq> \<infinity> \<Longrightarrow> measure (density M (\<lambda>_. c)) A = real c * measure M A"
  2803   by (auto simp: emeasure_density_const measure_def)
  2804 
  2805 lemma density_density_eq:
  2806    "f \<in> borel_measurable M \<Longrightarrow> g \<in> borel_measurable M \<Longrightarrow> AE x in M. 0 \<le> f x \<Longrightarrow>
  2807    density (density M f) g = density M (\<lambda>x. f x * g x)"
  2808   by (auto intro!: measure_eqI simp: emeasure_density positive_integral_density ac_simps)
  2809 
  2810 lemma distr_density_distr:
  2811   assumes T: "T \<in> measurable M M'" and T': "T' \<in> measurable M' M"
  2812     and inv: "\<forall>x\<in>space M. T' (T x) = x"
  2813   assumes f: "f \<in> borel_measurable M'"
  2814   shows "distr (density (distr M M' T) f) M T' = density M (f \<circ> T)" (is "?R = ?L")
  2815 proof (rule measure_eqI)
  2816   fix A assume A: "A \<in> sets ?R"
  2817   { fix x assume "x \<in> space M"
  2818     with sets.sets_into_space[OF A]
  2819     have "indicator (T' -` A \<inter> space M') (T x) = (indicator A x :: ereal)"
  2820       using T inv by (auto simp: indicator_def measurable_space) }
  2821   with A T T' f show "emeasure ?R A = emeasure ?L A"
  2822     by (simp add: measurable_comp emeasure_density emeasure_distr
  2823                   positive_integral_distr measurable_sets cong: positive_integral_cong)
  2824 qed simp
  2825 
  2826 lemma density_density_divide:
  2827   fixes f g :: "'a \<Rightarrow> real"
  2828   assumes f: "f \<in> borel_measurable M" "AE x in M. 0 \<le> f x"
  2829   assumes g: "g \<in> borel_measurable M" "AE x in M. 0 \<le> g x"
  2830   assumes ac: "AE x in M. f x = 0 \<longrightarrow> g x = 0"
  2831   shows "density (density M f) (\<lambda>x. g x / f x) = density M g"
  2832 proof -
  2833   have "density M g = density M (\<lambda>x. f x * (g x / f x))"
  2834     using f g ac by (auto intro!: density_cong measurable_If)
  2835   then show ?thesis
  2836     using f g by (subst density_density_eq) auto
  2837 qed
  2838 
  2839 section {* Point measure *}
  2840 
  2841 definition point_measure :: "'a set \<Rightarrow> ('a \<Rightarrow> ereal) \<Rightarrow> 'a measure" where
  2842   "point_measure A f = density (count_space A) f"
  2843 
  2844 lemma
  2845   shows space_point_measure: "space (point_measure A f) = A"
  2846     and sets_point_measure: "sets (point_measure A f) = Pow A"
  2847   by (auto simp: point_measure_def)
  2848 
  2849 lemma measurable_point_measure_eq1[simp]:
  2850   "g \<in> measurable (point_measure A f) M \<longleftrightarrow> g \<in> A \<rightarrow> space M"
  2851   unfolding point_measure_def by simp
  2852 
  2853 lemma measurable_point_measure_eq2_finite[simp]:
  2854   "finite A \<Longrightarrow>
  2855    g \<in> measurable M (point_measure A f) \<longleftrightarrow>
  2856     (g \<in> space M \<rightarrow> A \<and> (\<forall>a\<in>A. g -` {a} \<inter> space M \<in> sets M))"
  2857   unfolding point_measure_def by (simp add: measurable_count_space_eq2)
  2858 
  2859 lemma simple_function_point_measure[simp]:
  2860   "simple_function (point_measure A f) g \<longleftrightarrow> finite (g ` A)"
  2861   by (simp add: point_measure_def)
  2862 
  2863 lemma emeasure_point_measure:
  2864   assumes A: "finite {a\<in>X. 0 < f a}" "X \<subseteq> A"
  2865   shows "emeasure (point_measure A f) X = (\<Sum>a|a\<in>X \<and> 0 < f a. f a)"
  2866 proof -
  2867   have "{a. (a \<in> X \<longrightarrow> a \<in> A \<and> 0 < f a) \<and> a \<in> X} = {a\<in>X. 0 < f a}"
  2868     using `X \<subseteq> A` by auto
  2869   with A show ?thesis
  2870     by (simp add: emeasure_density positive_integral_count_space ereal_zero_le_0_iff
  2871                   point_measure_def indicator_def)
  2872 qed
  2873 
  2874 lemma emeasure_point_measure_finite:
  2875   "finite A \<Longrightarrow> (\<And>i. i \<in> A \<Longrightarrow> 0 \<le> f i) \<Longrightarrow> X \<subseteq> A \<Longrightarrow> emeasure (point_measure A f) X = (\<Sum>a\<in>X. f a)"
  2876   by (subst emeasure_point_measure) (auto dest: finite_subset intro!: setsum_mono_zero_left simp: less_le)
  2877 
  2878 lemma emeasure_point_measure_finite2:
  2879   "X \<subseteq> A \<Longrightarrow> finite X \<Longrightarrow> (\<And>i. i \<in> X \<Longrightarrow> 0 \<le> f i) \<Longrightarrow> emeasure (point_measure A f) X = (\<Sum>a\<in>X. f a)"
  2880   by (subst emeasure_point_measure)
  2881      (auto dest: finite_subset intro!: setsum_mono_zero_left simp: less_le)
  2882 
  2883 lemma null_sets_point_measure_iff:
  2884   "X \<in> null_sets (point_measure A f) \<longleftrightarrow> X \<subseteq> A \<and> (\<forall>x\<in>X. f x \<le> 0)"
  2885  by (auto simp: AE_count_space null_sets_density_iff point_measure_def)
  2886 
  2887 lemma AE_point_measure:
  2888   "(AE x in point_measure A f. P x) \<longleftrightarrow> (\<forall>x\<in>A. 0 < f x \<longrightarrow> P x)"
  2889   unfolding point_measure_def
  2890   by (subst AE_density) (auto simp: AE_density AE_count_space point_measure_def)
  2891 
  2892 lemma positive_integral_point_measure:
  2893   "finite {a\<in>A. 0 < f a \<and> 0 < g a} \<Longrightarrow>
  2894     integral\<^sup>P (point_measure A f) g = (\<Sum>a|a\<in>A \<and> 0 < f a \<and> 0 < g a. f a * g a)"
  2895   unfolding point_measure_def
  2896   apply (subst density_max_0)
  2897   apply (subst positive_integral_density)
  2898   apply (simp_all add: AE_count_space positive_integral_density)
  2899   apply (subst positive_integral_count_space )
  2900   apply (auto intro!: setsum_cong simp: max_def ereal_zero_less_0_iff)
  2901   apply (rule finite_subset)
  2902   prefer 2
  2903   apply assumption
  2904   apply auto
  2905   done
  2906 
  2907 lemma positive_integral_point_measure_finite:
  2908   "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> 0 \<le> f a) \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> 0 \<le> g a) \<Longrightarrow>
  2909     integral\<^sup>P (point_measure A f) g = (\<Sum>a\<in>A. f a * g a)"
  2910   by (subst positive_integral_point_measure) (auto intro!: setsum_mono_zero_left simp: less_le)
  2911 
  2912 lemma lebesgue_integral_point_measure_finite:
  2913   "finite A \<Longrightarrow> (\<And>a. a \<in> A \<Longrightarrow> 0 \<le> f a) \<Longrightarrow> integral\<^sup>L (point_measure A f) g = (\<Sum>a\<in>A. f a * g a)"
  2914   by (simp add: lebesgue_integral_count_space_finite AE_count_space integral_density point_measure_def)
  2915 
  2916 lemma integrable_point_measure_finite:
  2917   "finite A \<Longrightarrow> integrable (point_measure A (\<lambda>x. ereal (f x))) g"
  2918   unfolding point_measure_def
  2919   apply (subst density_ereal_max_0)
  2920   apply (subst integral_density)
  2921   apply (auto simp: AE_count_space integrable_count_space)
  2922   done
  2923 
  2924 section {* Uniform measure *}
  2925 
  2926 definition "uniform_measure M A = density M (\<lambda>x. indicator A x / emeasure M A)"
  2927 
  2928 lemma
  2929   shows sets_uniform_measure[simp]: "sets (uniform_measure M A) = sets M"
  2930     and space_uniform_measure[simp]: "space (uniform_measure M A) = space M"
  2931   by (auto simp: uniform_measure_def)
  2932 
  2933 lemma emeasure_uniform_measure[simp]:
  2934   assumes A: "A \<in> sets M" and B: "B \<in> sets M"
  2935   shows "emeasure (uniform_measure M A) B = emeasure M (A \<inter> B) / emeasure M A"
  2936 proof -
  2937   from A B have "emeasure (uniform_measure M A) B = (\<integral>\<^sup>+x. (1 / emeasure M A) * indicator (A \<inter> B) x \<partial>M)"
  2938     by (auto simp add: uniform_measure_def emeasure_density split: split_indicator
  2939              intro!: positive_integral_cong)
  2940   also have "\<dots> = emeasure M (A \<inter> B) / emeasure M A"
  2941     using A B
  2942     by (subst positive_integral_cmult_indicator) (simp_all add: sets.Int emeasure_nonneg)
  2943   finally show ?thesis .
  2944 qed
  2945 
  2946 lemma emeasure_neq_0_sets: "emeasure M A \<noteq> 0 \<Longrightarrow> A \<in> sets M"
  2947   using emeasure_notin_sets[of A M] by blast
  2948 
  2949 lemma measure_uniform_measure[simp]:
  2950   assumes A: "emeasure M A \<noteq> 0" "emeasure M A \<noteq> \<infinity>" and B: "B \<in> sets M"
  2951   shows "measure (uniform_measure M A) B = measure M (A \<inter> B) / measure M A"
  2952   using emeasure_uniform_measure[OF emeasure_neq_0_sets[OF A(1)] B] A
  2953   by (cases "emeasure M A" "emeasure M (A \<inter> B)" rule: ereal2_cases) (simp_all add: measure_def)
  2954 
  2955 section {* Uniform count measure *}
  2956 
  2957 definition "uniform_count_measure A = point_measure A (\<lambda>x. 1 / card A)"
  2958  
  2959 lemma 
  2960   shows space_uniform_count_measure: "space (uniform_count_measure A) = A"
  2961     and sets_uniform_count_measure: "sets (uniform_count_measure A) = Pow A"
  2962     unfolding uniform_count_measure_def by (auto simp: space_point_measure sets_point_measure)
  2963  
  2964 lemma emeasure_uniform_count_measure:
  2965   "finite A \<Longrightarrow> X \<subseteq> A \<Longrightarrow> emeasure (uniform_count_measure A) X = card X / card A"
  2966   by (simp add: real_eq_of_nat emeasure_point_measure_finite uniform_count_measure_def)
  2967  
  2968 lemma measure_uniform_count_measure:
  2969   "finite A \<Longrightarrow> X \<subseteq> A \<Longrightarrow> measure (uniform_count_measure A) X = card X / card A"
  2970   by (simp add: real_eq_of_nat emeasure_point_measure_finite uniform_count_measure_def measure_def)
  2971 
  2972 end