src/HOL/Archimedean_Field.thy
author hoelzl
Tue Aug 19 18:37:32 2014 +0200 (2014-08-19)
changeset 58040 9a867afaab5a
parent 54489 03ff4d1e6784
child 58097 cfd3cff9387b
permissions -rw-r--r--
better linarith support for floor, ceiling, natfloor, and natceiling
     1 (*  Title:      HOL/Archimedean_Field.thy
     2     Author:     Brian Huffman
     3 *)
     4 
     5 header {* Archimedean Fields, Floor and Ceiling Functions *}
     6 
     7 theory Archimedean_Field
     8 imports Main
     9 begin
    10 
    11 subsection {* Class of Archimedean fields *}
    12 
    13 text {* Archimedean fields have no infinite elements. *}
    14 
    15 class archimedean_field = linordered_field +
    16   assumes ex_le_of_int: "\<exists>z. x \<le> of_int z"
    17 
    18 lemma ex_less_of_int:
    19   fixes x :: "'a::archimedean_field" shows "\<exists>z. x < of_int z"
    20 proof -
    21   from ex_le_of_int obtain z where "x \<le> of_int z" ..
    22   then have "x < of_int (z + 1)" by simp
    23   then show ?thesis ..
    24 qed
    25 
    26 lemma ex_of_int_less:
    27   fixes x :: "'a::archimedean_field" shows "\<exists>z. of_int z < x"
    28 proof -
    29   from ex_less_of_int obtain z where "- x < of_int z" ..
    30   then have "of_int (- z) < x" by simp
    31   then show ?thesis ..
    32 qed
    33 
    34 lemma ex_less_of_nat:
    35   fixes x :: "'a::archimedean_field" shows "\<exists>n. x < of_nat n"
    36 proof -
    37   obtain z where "x < of_int z" using ex_less_of_int ..
    38   also have "\<dots> \<le> of_int (int (nat z))" by simp
    39   also have "\<dots> = of_nat (nat z)" by (simp only: of_int_of_nat_eq)
    40   finally show ?thesis ..
    41 qed
    42 
    43 lemma ex_le_of_nat:
    44   fixes x :: "'a::archimedean_field" shows "\<exists>n. x \<le> of_nat n"
    45 proof -
    46   obtain n where "x < of_nat n" using ex_less_of_nat ..
    47   then have "x \<le> of_nat n" by simp
    48   then show ?thesis ..
    49 qed
    50 
    51 text {* Archimedean fields have no infinitesimal elements. *}
    52 
    53 lemma ex_inverse_of_nat_Suc_less:
    54   fixes x :: "'a::archimedean_field"
    55   assumes "0 < x" shows "\<exists>n. inverse (of_nat (Suc n)) < x"
    56 proof -
    57   from `0 < x` have "0 < inverse x"
    58     by (rule positive_imp_inverse_positive)
    59   obtain n where "inverse x < of_nat n"
    60     using ex_less_of_nat ..
    61   then obtain m where "inverse x < of_nat (Suc m)"
    62     using `0 < inverse x` by (cases n) (simp_all del: of_nat_Suc)
    63   then have "inverse (of_nat (Suc m)) < inverse (inverse x)"
    64     using `0 < inverse x` by (rule less_imp_inverse_less)
    65   then have "inverse (of_nat (Suc m)) < x"
    66     using `0 < x` by (simp add: nonzero_inverse_inverse_eq)
    67   then show ?thesis ..
    68 qed
    69 
    70 lemma ex_inverse_of_nat_less:
    71   fixes x :: "'a::archimedean_field"
    72   assumes "0 < x" shows "\<exists>n>0. inverse (of_nat n) < x"
    73   using ex_inverse_of_nat_Suc_less [OF `0 < x`] by auto
    74 
    75 lemma ex_less_of_nat_mult:
    76   fixes x :: "'a::archimedean_field"
    77   assumes "0 < x" shows "\<exists>n. y < of_nat n * x"
    78 proof -
    79   obtain n where "y / x < of_nat n" using ex_less_of_nat ..
    80   with `0 < x` have "y < of_nat n * x" by (simp add: pos_divide_less_eq)
    81   then show ?thesis ..
    82 qed
    83 
    84 
    85 subsection {* Existence and uniqueness of floor function *}
    86 
    87 lemma exists_least_lemma:
    88   assumes "\<not> P 0" and "\<exists>n. P n"
    89   shows "\<exists>n. \<not> P n \<and> P (Suc n)"
    90 proof -
    91   from `\<exists>n. P n` have "P (Least P)" by (rule LeastI_ex)
    92   with `\<not> P 0` obtain n where "Least P = Suc n"
    93     by (cases "Least P") auto
    94   then have "n < Least P" by simp
    95   then have "\<not> P n" by (rule not_less_Least)
    96   then have "\<not> P n \<and> P (Suc n)"
    97     using `P (Least P)` `Least P = Suc n` by simp
    98   then show ?thesis ..
    99 qed
   100 
   101 lemma floor_exists:
   102   fixes x :: "'a::archimedean_field"
   103   shows "\<exists>z. of_int z \<le> x \<and> x < of_int (z + 1)"
   104 proof (cases)
   105   assume "0 \<le> x"
   106   then have "\<not> x < of_nat 0" by simp
   107   then have "\<exists>n. \<not> x < of_nat n \<and> x < of_nat (Suc n)"
   108     using ex_less_of_nat by (rule exists_least_lemma)
   109   then obtain n where "\<not> x < of_nat n \<and> x < of_nat (Suc n)" ..
   110   then have "of_int (int n) \<le> x \<and> x < of_int (int n + 1)" by simp
   111   then show ?thesis ..
   112 next
   113   assume "\<not> 0 \<le> x"
   114   then have "\<not> - x \<le> of_nat 0" by simp
   115   then have "\<exists>n. \<not> - x \<le> of_nat n \<and> - x \<le> of_nat (Suc n)"
   116     using ex_le_of_nat by (rule exists_least_lemma)
   117   then obtain n where "\<not> - x \<le> of_nat n \<and> - x \<le> of_nat (Suc n)" ..
   118   then have "of_int (- int n - 1) \<le> x \<and> x < of_int (- int n - 1 + 1)" by simp
   119   then show ?thesis ..
   120 qed
   121 
   122 lemma floor_exists1:
   123   fixes x :: "'a::archimedean_field"
   124   shows "\<exists>!z. of_int z \<le> x \<and> x < of_int (z + 1)"
   125 proof (rule ex_ex1I)
   126   show "\<exists>z. of_int z \<le> x \<and> x < of_int (z + 1)"
   127     by (rule floor_exists)
   128 next
   129   fix y z assume
   130     "of_int y \<le> x \<and> x < of_int (y + 1)"
   131     "of_int z \<le> x \<and> x < of_int (z + 1)"
   132   with le_less_trans [of "of_int y" "x" "of_int (z + 1)"]
   133        le_less_trans [of "of_int z" "x" "of_int (y + 1)"]
   134   show "y = z" by (simp del: of_int_add)
   135 qed
   136 
   137 
   138 subsection {* Floor function *}
   139 
   140 class floor_ceiling = archimedean_field +
   141   fixes floor :: "'a \<Rightarrow> int"
   142   assumes floor_correct: "of_int (floor x) \<le> x \<and> x < of_int (floor x + 1)"
   143 
   144 notation (xsymbols)
   145   floor  ("\<lfloor>_\<rfloor>")
   146 
   147 notation (HTML output)
   148   floor  ("\<lfloor>_\<rfloor>")
   149 
   150 lemma floor_unique: "\<lbrakk>of_int z \<le> x; x < of_int z + 1\<rbrakk> \<Longrightarrow> floor x = z"
   151   using floor_correct [of x] floor_exists1 [of x] by auto
   152 
   153 lemma of_int_floor_le: "of_int (floor x) \<le> x"
   154   using floor_correct ..
   155 
   156 lemma le_floor_iff: "z \<le> floor x \<longleftrightarrow> of_int z \<le> x"
   157 proof
   158   assume "z \<le> floor x"
   159   then have "(of_int z :: 'a) \<le> of_int (floor x)" by simp
   160   also have "of_int (floor x) \<le> x" by (rule of_int_floor_le)
   161   finally show "of_int z \<le> x" .
   162 next
   163   assume "of_int z \<le> x"
   164   also have "x < of_int (floor x + 1)" using floor_correct ..
   165   finally show "z \<le> floor x" by (simp del: of_int_add)
   166 qed
   167 
   168 lemma floor_less_iff: "floor x < z \<longleftrightarrow> x < of_int z"
   169   by (simp add: not_le [symmetric] le_floor_iff)
   170 
   171 lemma less_floor_iff: "z < floor x \<longleftrightarrow> of_int z + 1 \<le> x"
   172   using le_floor_iff [of "z + 1" x] by auto
   173 
   174 lemma floor_le_iff: "floor x \<le> z \<longleftrightarrow> x < of_int z + 1"
   175   by (simp add: not_less [symmetric] less_floor_iff)
   176 
   177 lemma floor_split[arith_split]: "P (floor t) \<longleftrightarrow> (\<forall>i. of_int i \<le> t \<and> t < of_int i + 1 \<longrightarrow> P i)"
   178   by (metis floor_correct floor_unique less_floor_iff not_le order_refl)
   179 
   180 lemma floor_mono: assumes "x \<le> y" shows "floor x \<le> floor y"
   181 proof -
   182   have "of_int (floor x) \<le> x" by (rule of_int_floor_le)
   183   also note `x \<le> y`
   184   finally show ?thesis by (simp add: le_floor_iff)
   185 qed
   186 
   187 lemma floor_less_cancel: "floor x < floor y \<Longrightarrow> x < y"
   188   by (auto simp add: not_le [symmetric] floor_mono)
   189 
   190 lemma floor_of_int [simp]: "floor (of_int z) = z"
   191   by (rule floor_unique) simp_all
   192 
   193 lemma floor_of_nat [simp]: "floor (of_nat n) = int n"
   194   using floor_of_int [of "of_nat n"] by simp
   195 
   196 lemma le_floor_add: "floor x + floor y \<le> floor (x + y)"
   197   by (simp only: le_floor_iff of_int_add add_mono of_int_floor_le)
   198 
   199 text {* Floor with numerals *}
   200 
   201 lemma floor_zero [simp]: "floor 0 = 0"
   202   using floor_of_int [of 0] by simp
   203 
   204 lemma floor_one [simp]: "floor 1 = 1"
   205   using floor_of_int [of 1] by simp
   206 
   207 lemma floor_numeral [simp]: "floor (numeral v) = numeral v"
   208   using floor_of_int [of "numeral v"] by simp
   209 
   210 lemma floor_neg_numeral [simp]: "floor (- numeral v) = - numeral v"
   211   using floor_of_int [of "- numeral v"] by simp
   212 
   213 lemma zero_le_floor [simp]: "0 \<le> floor x \<longleftrightarrow> 0 \<le> x"
   214   by (simp add: le_floor_iff)
   215 
   216 lemma one_le_floor [simp]: "1 \<le> floor x \<longleftrightarrow> 1 \<le> x"
   217   by (simp add: le_floor_iff)
   218 
   219 lemma numeral_le_floor [simp]:
   220   "numeral v \<le> floor x \<longleftrightarrow> numeral v \<le> x"
   221   by (simp add: le_floor_iff)
   222 
   223 lemma neg_numeral_le_floor [simp]:
   224   "- numeral v \<le> floor x \<longleftrightarrow> - numeral v \<le> x"
   225   by (simp add: le_floor_iff)
   226 
   227 lemma zero_less_floor [simp]: "0 < floor x \<longleftrightarrow> 1 \<le> x"
   228   by (simp add: less_floor_iff)
   229 
   230 lemma one_less_floor [simp]: "1 < floor x \<longleftrightarrow> 2 \<le> x"
   231   by (simp add: less_floor_iff)
   232 
   233 lemma numeral_less_floor [simp]:
   234   "numeral v < floor x \<longleftrightarrow> numeral v + 1 \<le> x"
   235   by (simp add: less_floor_iff)
   236 
   237 lemma neg_numeral_less_floor [simp]:
   238   "- numeral v < floor x \<longleftrightarrow> - numeral v + 1 \<le> x"
   239   by (simp add: less_floor_iff)
   240 
   241 lemma floor_le_zero [simp]: "floor x \<le> 0 \<longleftrightarrow> x < 1"
   242   by (simp add: floor_le_iff)
   243 
   244 lemma floor_le_one [simp]: "floor x \<le> 1 \<longleftrightarrow> x < 2"
   245   by (simp add: floor_le_iff)
   246 
   247 lemma floor_le_numeral [simp]:
   248   "floor x \<le> numeral v \<longleftrightarrow> x < numeral v + 1"
   249   by (simp add: floor_le_iff)
   250 
   251 lemma floor_le_neg_numeral [simp]:
   252   "floor x \<le> - numeral v \<longleftrightarrow> x < - numeral v + 1"
   253   by (simp add: floor_le_iff)
   254 
   255 lemma floor_less_zero [simp]: "floor x < 0 \<longleftrightarrow> x < 0"
   256   by (simp add: floor_less_iff)
   257 
   258 lemma floor_less_one [simp]: "floor x < 1 \<longleftrightarrow> x < 1"
   259   by (simp add: floor_less_iff)
   260 
   261 lemma floor_less_numeral [simp]:
   262   "floor x < numeral v \<longleftrightarrow> x < numeral v"
   263   by (simp add: floor_less_iff)
   264 
   265 lemma floor_less_neg_numeral [simp]:
   266   "floor x < - numeral v \<longleftrightarrow> x < - numeral v"
   267   by (simp add: floor_less_iff)
   268 
   269 text {* Addition and subtraction of integers *}
   270 
   271 lemma floor_add_of_int [simp]: "floor (x + of_int z) = floor x + z"
   272   using floor_correct [of x] by (simp add: floor_unique)
   273 
   274 lemma floor_add_numeral [simp]:
   275     "floor (x + numeral v) = floor x + numeral v"
   276   using floor_add_of_int [of x "numeral v"] by simp
   277 
   278 lemma floor_add_one [simp]: "floor (x + 1) = floor x + 1"
   279   using floor_add_of_int [of x 1] by simp
   280 
   281 lemma floor_diff_of_int [simp]: "floor (x - of_int z) = floor x - z"
   282   using floor_add_of_int [of x "- z"] by (simp add: algebra_simps)
   283 
   284 lemma floor_diff_numeral [simp]:
   285   "floor (x - numeral v) = floor x - numeral v"
   286   using floor_diff_of_int [of x "numeral v"] by simp
   287 
   288 lemma floor_diff_one [simp]: "floor (x - 1) = floor x - 1"
   289   using floor_diff_of_int [of x 1] by simp
   290 
   291 subsection {* Ceiling function *}
   292 
   293 definition
   294   ceiling :: "'a::floor_ceiling \<Rightarrow> int" where
   295   "ceiling x = - floor (- x)"
   296 
   297 notation (xsymbols)
   298   ceiling  ("\<lceil>_\<rceil>")
   299 
   300 notation (HTML output)
   301   ceiling  ("\<lceil>_\<rceil>")
   302 
   303 lemma ceiling_correct: "of_int (ceiling x) - 1 < x \<and> x \<le> of_int (ceiling x)"
   304   unfolding ceiling_def using floor_correct [of "- x"] by simp
   305 
   306 lemma ceiling_unique: "\<lbrakk>of_int z - 1 < x; x \<le> of_int z\<rbrakk> \<Longrightarrow> ceiling x = z"
   307   unfolding ceiling_def using floor_unique [of "- z" "- x"] by simp
   308 
   309 lemma le_of_int_ceiling: "x \<le> of_int (ceiling x)"
   310   using ceiling_correct ..
   311 
   312 lemma ceiling_le_iff: "ceiling x \<le> z \<longleftrightarrow> x \<le> of_int z"
   313   unfolding ceiling_def using le_floor_iff [of "- z" "- x"] by auto
   314 
   315 lemma less_ceiling_iff: "z < ceiling x \<longleftrightarrow> of_int z < x"
   316   by (simp add: not_le [symmetric] ceiling_le_iff)
   317 
   318 lemma ceiling_less_iff: "ceiling x < z \<longleftrightarrow> x \<le> of_int z - 1"
   319   using ceiling_le_iff [of x "z - 1"] by simp
   320 
   321 lemma le_ceiling_iff: "z \<le> ceiling x \<longleftrightarrow> of_int z - 1 < x"
   322   by (simp add: not_less [symmetric] ceiling_less_iff)
   323 
   324 lemma ceiling_mono: "x \<ge> y \<Longrightarrow> ceiling x \<ge> ceiling y"
   325   unfolding ceiling_def by (simp add: floor_mono)
   326 
   327 lemma ceiling_less_cancel: "ceiling x < ceiling y \<Longrightarrow> x < y"
   328   by (auto simp add: not_le [symmetric] ceiling_mono)
   329 
   330 lemma ceiling_of_int [simp]: "ceiling (of_int z) = z"
   331   by (rule ceiling_unique) simp_all
   332 
   333 lemma ceiling_of_nat [simp]: "ceiling (of_nat n) = int n"
   334   using ceiling_of_int [of "of_nat n"] by simp
   335 
   336 lemma ceiling_add_le: "ceiling (x + y) \<le> ceiling x + ceiling y"
   337   by (simp only: ceiling_le_iff of_int_add add_mono le_of_int_ceiling)
   338 
   339 text {* Ceiling with numerals *}
   340 
   341 lemma ceiling_zero [simp]: "ceiling 0 = 0"
   342   using ceiling_of_int [of 0] by simp
   343 
   344 lemma ceiling_one [simp]: "ceiling 1 = 1"
   345   using ceiling_of_int [of 1] by simp
   346 
   347 lemma ceiling_numeral [simp]: "ceiling (numeral v) = numeral v"
   348   using ceiling_of_int [of "numeral v"] by simp
   349 
   350 lemma ceiling_neg_numeral [simp]: "ceiling (- numeral v) = - numeral v"
   351   using ceiling_of_int [of "- numeral v"] by simp
   352 
   353 lemma ceiling_le_zero [simp]: "ceiling x \<le> 0 \<longleftrightarrow> x \<le> 0"
   354   by (simp add: ceiling_le_iff)
   355 
   356 lemma ceiling_le_one [simp]: "ceiling x \<le> 1 \<longleftrightarrow> x \<le> 1"
   357   by (simp add: ceiling_le_iff)
   358 
   359 lemma ceiling_le_numeral [simp]:
   360   "ceiling x \<le> numeral v \<longleftrightarrow> x \<le> numeral v"
   361   by (simp add: ceiling_le_iff)
   362 
   363 lemma ceiling_le_neg_numeral [simp]:
   364   "ceiling x \<le> - numeral v \<longleftrightarrow> x \<le> - numeral v"
   365   by (simp add: ceiling_le_iff)
   366 
   367 lemma ceiling_less_zero [simp]: "ceiling x < 0 \<longleftrightarrow> x \<le> -1"
   368   by (simp add: ceiling_less_iff)
   369 
   370 lemma ceiling_less_one [simp]: "ceiling x < 1 \<longleftrightarrow> x \<le> 0"
   371   by (simp add: ceiling_less_iff)
   372 
   373 lemma ceiling_less_numeral [simp]:
   374   "ceiling x < numeral v \<longleftrightarrow> x \<le> numeral v - 1"
   375   by (simp add: ceiling_less_iff)
   376 
   377 lemma ceiling_less_neg_numeral [simp]:
   378   "ceiling x < - numeral v \<longleftrightarrow> x \<le> - numeral v - 1"
   379   by (simp add: ceiling_less_iff)
   380 
   381 lemma zero_le_ceiling [simp]: "0 \<le> ceiling x \<longleftrightarrow> -1 < x"
   382   by (simp add: le_ceiling_iff)
   383 
   384 lemma one_le_ceiling [simp]: "1 \<le> ceiling x \<longleftrightarrow> 0 < x"
   385   by (simp add: le_ceiling_iff)
   386 
   387 lemma numeral_le_ceiling [simp]:
   388   "numeral v \<le> ceiling x \<longleftrightarrow> numeral v - 1 < x"
   389   by (simp add: le_ceiling_iff)
   390 
   391 lemma neg_numeral_le_ceiling [simp]:
   392   "- numeral v \<le> ceiling x \<longleftrightarrow> - numeral v - 1 < x"
   393   by (simp add: le_ceiling_iff)
   394 
   395 lemma zero_less_ceiling [simp]: "0 < ceiling x \<longleftrightarrow> 0 < x"
   396   by (simp add: less_ceiling_iff)
   397 
   398 lemma one_less_ceiling [simp]: "1 < ceiling x \<longleftrightarrow> 1 < x"
   399   by (simp add: less_ceiling_iff)
   400 
   401 lemma numeral_less_ceiling [simp]:
   402   "numeral v < ceiling x \<longleftrightarrow> numeral v < x"
   403   by (simp add: less_ceiling_iff)
   404 
   405 lemma neg_numeral_less_ceiling [simp]:
   406   "- numeral v < ceiling x \<longleftrightarrow> - numeral v < x"
   407   by (simp add: less_ceiling_iff)
   408 
   409 text {* Addition and subtraction of integers *}
   410 
   411 lemma ceiling_add_of_int [simp]: "ceiling (x + of_int z) = ceiling x + z"
   412   using ceiling_correct [of x] by (simp add: ceiling_unique)
   413 
   414 lemma ceiling_add_numeral [simp]:
   415     "ceiling (x + numeral v) = ceiling x + numeral v"
   416   using ceiling_add_of_int [of x "numeral v"] by simp
   417 
   418 lemma ceiling_add_one [simp]: "ceiling (x + 1) = ceiling x + 1"
   419   using ceiling_add_of_int [of x 1] by simp
   420 
   421 lemma ceiling_diff_of_int [simp]: "ceiling (x - of_int z) = ceiling x - z"
   422   using ceiling_add_of_int [of x "- z"] by (simp add: algebra_simps)
   423 
   424 lemma ceiling_diff_numeral [simp]:
   425   "ceiling (x - numeral v) = ceiling x - numeral v"
   426   using ceiling_diff_of_int [of x "numeral v"] by simp
   427 
   428 lemma ceiling_diff_one [simp]: "ceiling (x - 1) = ceiling x - 1"
   429   using ceiling_diff_of_int [of x 1] by simp
   430 
   431 lemma ceiling_split[arith_split]: "P (ceiling t) \<longleftrightarrow> (\<forall>i. of_int i - 1 < t \<and> t \<le> of_int i \<longrightarrow> P i)"
   432   by (auto simp add: ceiling_unique ceiling_correct)
   433 
   434 lemma ceiling_diff_floor_le_1: "ceiling x - floor x \<le> 1"
   435 proof -
   436   have "of_int \<lceil>x\<rceil> - 1 < x" 
   437     using ceiling_correct[of x] by simp
   438   also have "x < of_int \<lfloor>x\<rfloor> + 1"
   439     using floor_correct[of x] by simp_all
   440   finally have "of_int (\<lceil>x\<rceil> - \<lfloor>x\<rfloor>) < (of_int 2::'a)"
   441     by simp
   442   then show ?thesis
   443     unfolding of_int_less_iff by simp
   444 qed
   445 
   446 subsection {* Negation *}
   447 
   448 lemma floor_minus: "floor (- x) = - ceiling x"
   449   unfolding ceiling_def by simp
   450 
   451 lemma ceiling_minus: "ceiling (- x) = - floor x"
   452   unfolding ceiling_def by simp
   453 
   454 end