src/HOL/Nat.thy
author blanchet
Wed Feb 12 08:37:28 2014 +0100 (2014-02-12)
changeset 55424 9ab4129a76a3
parent 55423 07dea66779f3
child 55443 3def821deb70
permissions -rw-r--r--
remove hidden fact about hidden constant from code generator setup
     1 (*  Title:      HOL/Nat.thy
     2     Author:     Tobias Nipkow and Lawrence C Paulson and Markus Wenzel
     3 
     4 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     5 and * (for div and mod, see theory Divides).
     6 *)
     7 
     8 header {* Natural numbers *}
     9 
    10 theory Nat
    11 imports Inductive Typedef Fun Fields
    12 begin
    13 
    14 ML_file "~~/src/Tools/rat.ML"
    15 ML_file "Tools/arith_data.ML"
    16 ML_file "~~/src/Provers/Arith/fast_lin_arith.ML"
    17 
    18 
    19 subsection {* Type @{text ind} *}
    20 
    21 typedecl ind
    22 
    23 axiomatization Zero_Rep :: ind and Suc_Rep :: "ind => ind" where
    24   -- {* the axiom of infinity in 2 parts *}
    25   Suc_Rep_inject:       "Suc_Rep x = Suc_Rep y ==> x = y" and
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 
    28 subsection {* Type nat *}
    29 
    30 text {* Type definition *}
    31 
    32 inductive Nat :: "ind \<Rightarrow> bool" where
    33   Zero_RepI: "Nat Zero_Rep"
    34 | Suc_RepI: "Nat i \<Longrightarrow> Nat (Suc_Rep i)"
    35 
    36 typedef nat = "{n. Nat n}"
    37   morphisms Rep_Nat Abs_Nat
    38   using Nat.Zero_RepI by auto
    39 
    40 lemma Nat_Rep_Nat:
    41   "Nat (Rep_Nat n)"
    42   using Rep_Nat by simp
    43 
    44 lemma Nat_Abs_Nat_inverse:
    45   "Nat n \<Longrightarrow> Rep_Nat (Abs_Nat n) = n"
    46   using Abs_Nat_inverse by simp
    47 
    48 lemma Nat_Abs_Nat_inject:
    49   "Nat n \<Longrightarrow> Nat m \<Longrightarrow> Abs_Nat n = Abs_Nat m \<longleftrightarrow> n = m"
    50   using Abs_Nat_inject by simp
    51 
    52 instantiation nat :: zero
    53 begin
    54 
    55 definition Zero_nat_def:
    56   "0 = Abs_Nat Zero_Rep"
    57 
    58 instance ..
    59 
    60 end
    61 
    62 definition Suc :: "nat \<Rightarrow> nat" where
    63   "Suc n = Abs_Nat (Suc_Rep (Rep_Nat n))"
    64 
    65 lemma Suc_not_Zero: "Suc m \<noteq> 0"
    66   by (simp add: Zero_nat_def Suc_def Suc_RepI Zero_RepI Nat_Abs_Nat_inject Suc_Rep_not_Zero_Rep Nat_Rep_Nat)
    67 
    68 lemma Zero_not_Suc: "0 \<noteq> Suc m"
    69   by (rule not_sym, rule Suc_not_Zero not_sym)
    70 
    71 lemma Suc_Rep_inject': "Suc_Rep x = Suc_Rep y \<longleftrightarrow> x = y"
    72   by (rule iffI, rule Suc_Rep_inject) simp_all
    73 
    74 lemma nat_induct0:
    75   fixes n
    76   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
    77   shows "P n"
    78 using assms
    79 apply (unfold Zero_nat_def Suc_def)
    80 apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    81 apply (erule Nat_Rep_Nat [THEN Nat.induct])
    82 apply (iprover elim: Nat_Abs_Nat_inverse [THEN subst])
    83 done
    84 
    85 wrap_free_constructors ["0 \<Colon> nat", Suc] case_nat [=] [[], [pred]]
    86   apply atomize_elim
    87   apply (rename_tac n, induct_tac n rule: nat_induct0, auto)
    88  apply (simp add: Suc_def Nat_Abs_Nat_inject Nat_Rep_Nat Suc_RepI
    89    Suc_Rep_inject' Rep_Nat_inject)
    90 apply (simp only: Suc_not_Zero)
    91 done
    92 
    93 -- {* Avoid name clashes by prefixing the output of @{text rep_datatype} with @{text old}. *}
    94 setup {* Sign.mandatory_path "old" *}
    95 
    96 rep_datatype "0 \<Colon> nat" Suc
    97   apply (erule nat_induct0, assumption)
    98  apply (rule nat.inject)
    99 apply (rule nat.distinct(1))
   100 done
   101 
   102 setup {* Sign.parent_path *}
   103 
   104 -- {* But erase the prefix for properties that are not generated by @{text wrap_free_constructors}. *}
   105 setup {* Sign.mandatory_path "nat" *}
   106 
   107 declare
   108   old.nat.inject[iff del]
   109   old.nat.distinct(1)[simp del, induct_simp del]
   110 
   111 lemmas induct = old.nat.induct
   112 lemmas inducts = old.nat.inducts
   113 lemmas recs = old.nat.recs
   114 lemmas cases = nat.case
   115 lemmas simps = nat.inject nat.distinct nat.case old.nat.recs
   116 
   117 setup {* Sign.parent_path *}
   118 
   119 abbreviation rec_nat :: "'a \<Rightarrow> (nat \<Rightarrow> 'a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a" where
   120   "rec_nat \<equiv> old.rec_nat"
   121 
   122 declare nat.sel[code del]
   123 
   124 hide_const Nat.pred -- {* hide everything related to the selector *}
   125 hide_fact
   126   nat.case_eq_if
   127   nat.collapse
   128   nat.expand
   129   nat.sel
   130   nat.sel_exhaust
   131   nat.sel_split
   132   nat.sel_split_asm
   133 
   134 lemma nat_exhaust [case_names 0 Suc, cases type: nat]:
   135   -- {* for backward compatibility -- names of variables differ *}
   136   "(y = 0 \<Longrightarrow> P) \<Longrightarrow> (\<And>nat. y = Suc nat \<Longrightarrow> P) \<Longrightarrow> P"
   137 by (rule old.nat.exhaust)
   138 
   139 lemma nat_induct [case_names 0 Suc, induct type: nat]:
   140   -- {* for backward compatibility -- names of variables differ *}
   141   fixes n
   142   assumes "P 0" and "\<And>n. P n \<Longrightarrow> P (Suc n)"
   143   shows "P n"
   144 using assms by (rule nat.induct)
   145 
   146 hide_fact
   147   nat_exhaust
   148   nat_induct0
   149 
   150 text {* Injectiveness and distinctness lemmas *}
   151 
   152 lemma inj_Suc[simp]: "inj_on Suc N"
   153   by (simp add: inj_on_def)
   154 
   155 lemma Suc_neq_Zero: "Suc m = 0 \<Longrightarrow> R"
   156 by (rule notE, rule Suc_not_Zero)
   157 
   158 lemma Zero_neq_Suc: "0 = Suc m \<Longrightarrow> R"
   159 by (rule Suc_neq_Zero, erule sym)
   160 
   161 lemma Suc_inject: "Suc x = Suc y \<Longrightarrow> x = y"
   162 by (rule inj_Suc [THEN injD])
   163 
   164 lemma n_not_Suc_n: "n \<noteq> Suc n"
   165 by (induct n) simp_all
   166 
   167 lemma Suc_n_not_n: "Suc n \<noteq> n"
   168 by (rule not_sym, rule n_not_Suc_n)
   169 
   170 text {* A special form of induction for reasoning
   171   about @{term "m < n"} and @{term "m - n"} *}
   172 
   173 lemma diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   174     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   175   apply (rule_tac x = m in spec)
   176   apply (induct n)
   177   prefer 2
   178   apply (rule allI)
   179   apply (induct_tac x, iprover+)
   180   done
   181 
   182 
   183 subsection {* Arithmetic operators *}
   184 
   185 instantiation nat :: comm_monoid_diff
   186 begin
   187 
   188 primrec plus_nat where
   189   add_0:      "0 + n = (n\<Colon>nat)"
   190 | add_Suc:  "Suc m + n = Suc (m + n)"
   191 
   192 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   193   by (induct m) simp_all
   194 
   195 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   196   by (induct m) simp_all
   197 
   198 declare add_0 [code]
   199 
   200 lemma add_Suc_shift [code]: "Suc m + n = m + Suc n"
   201   by simp
   202 
   203 primrec minus_nat where
   204   diff_0 [code]: "m - 0 = (m\<Colon>nat)"
   205 | diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   206 
   207 declare diff_Suc [simp del]
   208 
   209 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   210   by (induct n) (simp_all add: diff_Suc)
   211 
   212 lemma diff_Suc_Suc [simp, code]: "Suc m - Suc n = m - n"
   213   by (induct n) (simp_all add: diff_Suc)
   214 
   215 instance proof
   216   fix n m q :: nat
   217   show "(n + m) + q = n + (m + q)" by (induct n) simp_all
   218   show "n + m = m + n" by (induct n) simp_all
   219   show "0 + n = n" by simp
   220   show "n - 0 = n" by simp
   221   show "0 - n = 0" by simp
   222   show "(q + n) - (q + m) = n - m" by (induct q) simp_all
   223   show "n - m - q = n - (m + q)" by (induct q) (simp_all add: diff_Suc)
   224 qed
   225 
   226 end
   227 
   228 hide_fact (open) add_0 add_0_right diff_0
   229 
   230 instantiation nat :: comm_semiring_1_cancel
   231 begin
   232 
   233 definition
   234   One_nat_def [simp]: "1 = Suc 0"
   235 
   236 primrec times_nat where
   237   mult_0:     "0 * n = (0\<Colon>nat)"
   238 | mult_Suc: "Suc m * n = n + (m * n)"
   239 
   240 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   241   by (induct m) simp_all
   242 
   243 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   244   by (induct m) (simp_all add: add_left_commute)
   245 
   246 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   247   by (induct m) (simp_all add: add_assoc)
   248 
   249 instance proof
   250   fix n m q :: nat
   251   show "0 \<noteq> (1::nat)" unfolding One_nat_def by simp
   252   show "1 * n = n" unfolding One_nat_def by simp
   253   show "n * m = m * n" by (induct n) simp_all
   254   show "(n * m) * q = n * (m * q)" by (induct n) (simp_all add: add_mult_distrib)
   255   show "(n + m) * q = n * q + m * q" by (rule add_mult_distrib)
   256   assume "n + m = n + q" thus "m = q" by (induct n) simp_all
   257 qed
   258 
   259 end
   260 
   261 subsubsection {* Addition *}
   262 
   263 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   264   by (rule add_assoc)
   265 
   266 lemma nat_add_commute: "m + n = n + (m::nat)"
   267   by (rule add_commute)
   268 
   269 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   270   by (rule add_left_commute)
   271 
   272 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   273   by (rule add_left_cancel)
   274 
   275 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   276   by (rule add_right_cancel)
   277 
   278 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   279 
   280 lemma add_is_0 [iff]:
   281   fixes m n :: nat
   282   shows "(m + n = 0) = (m = 0 & n = 0)"
   283   by (cases m) simp_all
   284 
   285 lemma add_is_1:
   286   "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   287   by (cases m) simp_all
   288 
   289 lemma one_is_add:
   290   "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   291   by (rule trans, rule eq_commute, rule add_is_1)
   292 
   293 lemma add_eq_self_zero:
   294   fixes m n :: nat
   295   shows "m + n = m \<Longrightarrow> n = 0"
   296   by (induct m) simp_all
   297 
   298 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   299   apply (induct k)
   300    apply simp
   301   apply(drule comp_inj_on[OF _ inj_Suc])
   302   apply (simp add:o_def)
   303   done
   304 
   305 lemma Suc_eq_plus1: "Suc n = n + 1"
   306   unfolding One_nat_def by simp
   307 
   308 lemma Suc_eq_plus1_left: "Suc n = 1 + n"
   309   unfolding One_nat_def by simp
   310 
   311 
   312 subsubsection {* Difference *}
   313 
   314 lemma diff_self_eq_0 [simp]: "(m\<Colon>nat) - m = 0"
   315   by (induct m) simp_all
   316 
   317 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   318   by (induct i j rule: diff_induct) simp_all
   319 
   320 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   321   by (simp add: diff_diff_left)
   322 
   323 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   324   by (simp add: diff_diff_left add_commute)
   325 
   326 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   327   by (induct n) simp_all
   328 
   329 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   330   by (simp add: diff_add_inverse add_commute [of m n])
   331 
   332 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   333   by (induct k) simp_all
   334 
   335 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   336   by (simp add: diff_cancel add_commute)
   337 
   338 lemma diff_add_0: "n - (n + m) = (0::nat)"
   339   by (induct n) simp_all
   340 
   341 lemma diff_Suc_1 [simp]: "Suc n - 1 = n"
   342   unfolding One_nat_def by simp
   343 
   344 text {* Difference distributes over multiplication *}
   345 
   346 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   347 by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   348 
   349 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   350 by (simp add: diff_mult_distrib mult_commute [of k])
   351   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   352 
   353 
   354 subsubsection {* Multiplication *}
   355 
   356 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   357   by (rule mult_assoc)
   358 
   359 lemma nat_mult_commute: "m * n = n * (m::nat)"
   360   by (rule mult_commute)
   361 
   362 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   363   by (rule distrib_left)
   364 
   365 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   366   by (induct m) auto
   367 
   368 lemmas nat_distrib =
   369   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   370 
   371 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = Suc 0 & n = Suc 0)"
   372   apply (induct m)
   373    apply simp
   374   apply (induct n)
   375    apply auto
   376   done
   377 
   378 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = Suc 0 & n = Suc 0)"
   379   apply (rule trans)
   380   apply (rule_tac [2] mult_eq_1_iff, fastforce)
   381   done
   382 
   383 lemma nat_mult_eq_1_iff [simp]: "m * n = (1::nat) \<longleftrightarrow> m = 1 \<and> n = 1"
   384   unfolding One_nat_def by (rule mult_eq_1_iff)
   385 
   386 lemma nat_1_eq_mult_iff [simp]: "(1::nat) = m * n \<longleftrightarrow> m = 1 \<and> n = 1"
   387   unfolding One_nat_def by (rule one_eq_mult_iff)
   388 
   389 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
   390 proof -
   391   have "k \<noteq> 0 \<Longrightarrow> k * m = k * n \<Longrightarrow> m = n"
   392   proof (induct n arbitrary: m)
   393     case 0 then show "m = 0" by simp
   394   next
   395     case (Suc n) then show "m = Suc n"
   396       by (cases m) (simp_all add: eq_commute [of "0"])
   397   qed
   398   then show ?thesis by auto
   399 qed
   400 
   401 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
   402   by (simp add: mult_commute)
   403 
   404 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
   405   by (subst mult_cancel1) simp
   406 
   407 
   408 subsection {* Orders on @{typ nat} *}
   409 
   410 subsubsection {* Operation definition *}
   411 
   412 instantiation nat :: linorder
   413 begin
   414 
   415 primrec less_eq_nat where
   416   "(0\<Colon>nat) \<le> n \<longleftrightarrow> True"
   417 | "Suc m \<le> n \<longleftrightarrow> (case n of 0 \<Rightarrow> False | Suc n \<Rightarrow> m \<le> n)"
   418 
   419 declare less_eq_nat.simps [simp del]
   420 lemma le0 [iff]: "0 \<le> (n\<Colon>nat)" by (simp add: less_eq_nat.simps)
   421 lemma [code]: "(0\<Colon>nat) \<le> n \<longleftrightarrow> True" by simp
   422 
   423 definition less_nat where
   424   less_eq_Suc_le: "n < m \<longleftrightarrow> Suc n \<le> m"
   425 
   426 lemma Suc_le_mono [iff]: "Suc n \<le> Suc m \<longleftrightarrow> n \<le> m"
   427   by (simp add: less_eq_nat.simps(2))
   428 
   429 lemma Suc_le_eq [code]: "Suc m \<le> n \<longleftrightarrow> m < n"
   430   unfolding less_eq_Suc_le ..
   431 
   432 lemma le_0_eq [iff]: "(n\<Colon>nat) \<le> 0 \<longleftrightarrow> n = 0"
   433   by (induct n) (simp_all add: less_eq_nat.simps(2))
   434 
   435 lemma not_less0 [iff]: "\<not> n < (0\<Colon>nat)"
   436   by (simp add: less_eq_Suc_le)
   437 
   438 lemma less_nat_zero_code [code]: "n < (0\<Colon>nat) \<longleftrightarrow> False"
   439   by simp
   440 
   441 lemma Suc_less_eq [iff]: "Suc m < Suc n \<longleftrightarrow> m < n"
   442   by (simp add: less_eq_Suc_le)
   443 
   444 lemma less_Suc_eq_le [code]: "m < Suc n \<longleftrightarrow> m \<le> n"
   445   by (simp add: less_eq_Suc_le)
   446 
   447 lemma le_SucI: "m \<le> n \<Longrightarrow> m \<le> Suc n"
   448   by (induct m arbitrary: n)
   449     (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   450 
   451 lemma Suc_leD: "Suc m \<le> n \<Longrightarrow> m \<le> n"
   452   by (cases n) (auto intro: le_SucI)
   453 
   454 lemma less_SucI: "m < n \<Longrightarrow> m < Suc n"
   455   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   456 
   457 lemma Suc_lessD: "Suc m < n \<Longrightarrow> m < n"
   458   by (simp add: less_eq_Suc_le) (erule Suc_leD)
   459 
   460 instance
   461 proof
   462   fix n m :: nat
   463   show "n < m \<longleftrightarrow> n \<le> m \<and> \<not> m \<le> n" 
   464   proof (induct n arbitrary: m)
   465     case 0 then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   466   next
   467     case (Suc n) then show ?case by (cases m) (simp_all add: less_eq_Suc_le)
   468   qed
   469 next
   470   fix n :: nat show "n \<le> n" by (induct n) simp_all
   471 next
   472   fix n m :: nat assume "n \<le> m" and "m \<le> n"
   473   then show "n = m"
   474     by (induct n arbitrary: m)
   475       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   476 next
   477   fix n m q :: nat assume "n \<le> m" and "m \<le> q"
   478   then show "n \<le> q"
   479   proof (induct n arbitrary: m q)
   480     case 0 show ?case by simp
   481   next
   482     case (Suc n) then show ?case
   483       by (simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   484         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits, clarify,
   485         simp_all (no_asm_use) add: less_eq_nat.simps(2) split: nat.splits)
   486   qed
   487 next
   488   fix n m :: nat show "n \<le> m \<or> m \<le> n"
   489     by (induct n arbitrary: m)
   490       (simp_all add: less_eq_nat.simps(2) split: nat.splits)
   491 qed
   492 
   493 end
   494 
   495 instantiation nat :: order_bot
   496 begin
   497 
   498 definition bot_nat :: nat where
   499   "bot_nat = 0"
   500 
   501 instance proof
   502 qed (simp add: bot_nat_def)
   503 
   504 end
   505 
   506 instance nat :: no_top
   507   by default (auto intro: less_Suc_eq_le [THEN iffD2])
   508 
   509 
   510 subsubsection {* Introduction properties *}
   511 
   512 lemma lessI [iff]: "n < Suc n"
   513   by (simp add: less_Suc_eq_le)
   514 
   515 lemma zero_less_Suc [iff]: "0 < Suc n"
   516   by (simp add: less_Suc_eq_le)
   517 
   518 
   519 subsubsection {* Elimination properties *}
   520 
   521 lemma less_not_refl: "~ n < (n::nat)"
   522   by (rule order_less_irrefl)
   523 
   524 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)"
   525   by (rule not_sym) (rule less_imp_neq) 
   526 
   527 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   528   by (rule less_imp_neq)
   529 
   530 lemma less_irrefl_nat: "(n::nat) < n ==> R"
   531   by (rule notE, rule less_not_refl)
   532 
   533 lemma less_zeroE: "(n::nat) < 0 ==> R"
   534   by (rule notE) (rule not_less0)
   535 
   536 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   537   unfolding less_Suc_eq_le le_less ..
   538 
   539 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   540   by (simp add: less_Suc_eq)
   541 
   542 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   543   unfolding One_nat_def by (rule less_Suc0)
   544 
   545 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   546   by simp
   547 
   548 text {* "Less than" is antisymmetric, sort of *}
   549 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   550   unfolding not_less less_Suc_eq_le by (rule antisym)
   551 
   552 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   553   by (rule linorder_neq_iff)
   554 
   555 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   556   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   557   shows "P n m"
   558   apply (rule less_linear [THEN disjE])
   559   apply (erule_tac [2] disjE)
   560   apply (erule lessCase)
   561   apply (erule sym [THEN eqCase])
   562   apply (erule major)
   563   done
   564 
   565 
   566 subsubsection {* Inductive (?) properties *}
   567 
   568 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   569   unfolding less_eq_Suc_le [of m] le_less by simp 
   570 
   571 lemma lessE:
   572   assumes major: "i < k"
   573   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   574   shows P
   575 proof -
   576   from major have "\<exists>j. i \<le> j \<and> k = Suc j"
   577     unfolding less_eq_Suc_le by (induct k) simp_all
   578   then have "(\<exists>j. i < j \<and> k = Suc j) \<or> k = Suc i"
   579     by (clarsimp simp add: less_le)
   580   with p1 p2 show P by auto
   581 qed
   582 
   583 lemma less_SucE: assumes major: "m < Suc n"
   584   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   585   apply (rule major [THEN lessE])
   586   apply (rule eq, blast)
   587   apply (rule less, blast)
   588   done
   589 
   590 lemma Suc_lessE: assumes major: "Suc i < k"
   591   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   592   apply (rule major [THEN lessE])
   593   apply (erule lessI [THEN minor])
   594   apply (erule Suc_lessD [THEN minor], assumption)
   595   done
   596 
   597 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   598   by simp
   599 
   600 lemma less_trans_Suc:
   601   assumes le: "i < j" shows "j < k ==> Suc i < k"
   602   apply (induct k, simp_all)
   603   apply (insert le)
   604   apply (simp add: less_Suc_eq)
   605   apply (blast dest: Suc_lessD)
   606   done
   607 
   608 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   609 lemma not_less_eq: "\<not> m < n \<longleftrightarrow> n < Suc m"
   610   unfolding not_less less_Suc_eq_le ..
   611 
   612 lemma not_less_eq_eq: "\<not> m \<le> n \<longleftrightarrow> Suc n \<le> m"
   613   unfolding not_le Suc_le_eq ..
   614 
   615 text {* Properties of "less than or equal" *}
   616 
   617 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   618   unfolding less_Suc_eq_le .
   619 
   620 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   621   unfolding not_le less_Suc_eq_le ..
   622 
   623 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   624   by (simp add: less_Suc_eq_le [symmetric] less_Suc_eq)
   625 
   626 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   627   by (drule le_Suc_eq [THEN iffD1], iprover+)
   628 
   629 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   630   unfolding Suc_le_eq .
   631 
   632 text {* Stronger version of @{text Suc_leD} *}
   633 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   634   unfolding Suc_le_eq .
   635 
   636 lemma less_imp_le_nat: "m < n ==> m \<le> (n::nat)"
   637   unfolding less_eq_Suc_le by (rule Suc_leD)
   638 
   639 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   640 lemmas le_simps = less_imp_le_nat less_Suc_eq_le Suc_le_eq
   641 
   642 
   643 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   644 
   645 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   646   unfolding le_less .
   647 
   648 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   649   by (rule le_less)
   650 
   651 text {* Useful with @{text blast}. *}
   652 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   653   by auto
   654 
   655 lemma le_refl: "n \<le> (n::nat)"
   656   by simp
   657 
   658 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   659   by (rule order_trans)
   660 
   661 lemma le_antisym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   662   by (rule antisym)
   663 
   664 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   665   by (rule less_le)
   666 
   667 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   668   unfolding less_le ..
   669 
   670 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   671   by (rule linear)
   672 
   673 lemmas linorder_neqE_nat = linorder_neqE [where 'a = nat]
   674 
   675 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   676   unfolding less_Suc_eq_le by auto
   677 
   678 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   679   unfolding not_less by (rule le_less_Suc_eq)
   680 
   681 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   682 
   683 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   684 by (cases n) simp_all
   685 
   686 lemma gr0_implies_Suc: "n > 0 ==> \<exists>m. n = Suc m"
   687 by (cases n) simp_all
   688 
   689 lemma gr_implies_not0: fixes n :: nat shows "m<n ==> n \<noteq> 0"
   690 by (cases n) simp_all
   691 
   692 lemma neq0_conv[iff]: fixes n :: nat shows "(n \<noteq> 0) = (0 < n)"
   693 by (cases n) simp_all
   694 
   695 text {* This theorem is useful with @{text blast} *}
   696 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   697 by (rule neq0_conv[THEN iffD1], iprover)
   698 
   699 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   700 by (fast intro: not0_implies_Suc)
   701 
   702 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   703 using neq0_conv by blast
   704 
   705 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   706 by (induct m') simp_all
   707 
   708 text {* Useful in certain inductive arguments *}
   709 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   710 by (cases m) simp_all
   711 
   712 
   713 subsubsection {* Monotonicity of Addition *}
   714 
   715 lemma Suc_pred [simp]: "n>0 ==> Suc (n - Suc 0) = n"
   716 by (simp add: diff_Suc split: nat.split)
   717 
   718 lemma Suc_diff_1 [simp]: "0 < n ==> Suc (n - 1) = n"
   719 unfolding One_nat_def by (rule Suc_pred)
   720 
   721 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   722 by (induct k) simp_all
   723 
   724 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   725 by (induct k) simp_all
   726 
   727 lemma add_gr_0 [iff]: "!!m::nat. (m + n > 0) = (m>0 | n>0)"
   728 by(auto dest:gr0_implies_Suc)
   729 
   730 text {* strict, in 1st argument *}
   731 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   732 by (induct k) simp_all
   733 
   734 text {* strict, in both arguments *}
   735 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   736   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   737   apply (induct j, simp_all)
   738   done
   739 
   740 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   741 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   742   apply (induct n)
   743   apply (simp_all add: order_le_less)
   744   apply (blast elim!: less_SucE
   745                intro!: Nat.add_0_right [symmetric] add_Suc_right [symmetric])
   746   done
   747 
   748 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   749 lemma mult_less_mono2: "(i::nat) < j ==> 0<k ==> k * i < k * j"
   750 apply(auto simp: gr0_conv_Suc)
   751 apply (induct_tac m)
   752 apply (simp_all add: add_less_mono)
   753 done
   754 
   755 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   756 instance nat :: linordered_semidom
   757 proof
   758   show "0 < (1::nat)" by simp
   759   show "\<And>m n q :: nat. m \<le> n \<Longrightarrow> q + m \<le> q + n" by simp
   760   show "\<And>m n q :: nat. m < n \<Longrightarrow> 0 < q \<Longrightarrow> q * m < q * n" by (simp add: mult_less_mono2)
   761 qed
   762 
   763 instance nat :: no_zero_divisors
   764 proof
   765   fix a::nat and b::nat show "a ~= 0 \<Longrightarrow> b ~= 0 \<Longrightarrow> a * b ~= 0" by auto
   766 qed
   767 
   768 
   769 subsubsection {* @{term min} and @{term max} *}
   770 
   771 lemma mono_Suc: "mono Suc"
   772 by (rule monoI) simp
   773 
   774 lemma min_0L [simp]: "min 0 n = (0::nat)"
   775 by (rule min_absorb1) simp
   776 
   777 lemma min_0R [simp]: "min n 0 = (0::nat)"
   778 by (rule min_absorb2) simp
   779 
   780 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   781 by (simp add: mono_Suc min_of_mono)
   782 
   783 lemma min_Suc1:
   784    "min (Suc n) m = (case m of 0 => 0 | Suc m' => Suc(min n m'))"
   785 by (simp split: nat.split)
   786 
   787 lemma min_Suc2:
   788    "min m (Suc n) = (case m of 0 => 0 | Suc m' => Suc(min m' n))"
   789 by (simp split: nat.split)
   790 
   791 lemma max_0L [simp]: "max 0 n = (n::nat)"
   792 by (rule max_absorb2) simp
   793 
   794 lemma max_0R [simp]: "max n 0 = (n::nat)"
   795 by (rule max_absorb1) simp
   796 
   797 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   798 by (simp add: mono_Suc max_of_mono)
   799 
   800 lemma max_Suc1:
   801    "max (Suc n) m = (case m of 0 => Suc n | Suc m' => Suc(max n m'))"
   802 by (simp split: nat.split)
   803 
   804 lemma max_Suc2:
   805    "max m (Suc n) = (case m of 0 => Suc n | Suc m' => Suc(max m' n))"
   806 by (simp split: nat.split)
   807 
   808 lemma nat_mult_min_left:
   809   fixes m n q :: nat
   810   shows "min m n * q = min (m * q) (n * q)"
   811   by (simp add: min_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   812 
   813 lemma nat_mult_min_right:
   814   fixes m n q :: nat
   815   shows "m * min n q = min (m * n) (m * q)"
   816   by (simp add: min_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   817 
   818 lemma nat_add_max_left:
   819   fixes m n q :: nat
   820   shows "max m n + q = max (m + q) (n + q)"
   821   by (simp add: max_def)
   822 
   823 lemma nat_add_max_right:
   824   fixes m n q :: nat
   825   shows "m + max n q = max (m + n) (m + q)"
   826   by (simp add: max_def)
   827 
   828 lemma nat_mult_max_left:
   829   fixes m n q :: nat
   830   shows "max m n * q = max (m * q) (n * q)"
   831   by (simp add: max_def not_le) (auto dest: mult_right_le_imp_le mult_right_less_imp_less le_less_trans)
   832 
   833 lemma nat_mult_max_right:
   834   fixes m n q :: nat
   835   shows "m * max n q = max (m * n) (m * q)"
   836   by (simp add: max_def not_le) (auto dest: mult_left_le_imp_le mult_left_less_imp_less le_less_trans)
   837 
   838 
   839 subsubsection {* Additional theorems about @{term "op \<le>"} *}
   840 
   841 text {* Complete induction, aka course-of-values induction *}
   842 
   843 instance nat :: wellorder proof
   844   fix P and n :: nat
   845   assume step: "\<And>n::nat. (\<And>m. m < n \<Longrightarrow> P m) \<Longrightarrow> P n"
   846   have "\<And>q. q \<le> n \<Longrightarrow> P q"
   847   proof (induct n)
   848     case (0 n)
   849     have "P 0" by (rule step) auto
   850     thus ?case using 0 by auto
   851   next
   852     case (Suc m n)
   853     then have "n \<le> m \<or> n = Suc m" by (simp add: le_Suc_eq)
   854     thus ?case
   855     proof
   856       assume "n \<le> m" thus "P n" by (rule Suc(1))
   857     next
   858       assume n: "n = Suc m"
   859       show "P n"
   860         by (rule step) (rule Suc(1), simp add: n le_simps)
   861     qed
   862   qed
   863   then show "P n" by auto
   864 qed
   865 
   866 lemma Least_Suc:
   867      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   868   apply (cases n, auto)
   869   apply (frule LeastI)
   870   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   871   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   872   apply (erule_tac [2] Least_le)
   873   apply (cases "LEAST x. P x", auto)
   874   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   875   apply (blast intro: order_antisym)
   876   done
   877 
   878 lemma Least_Suc2:
   879    "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   880   apply (erule (1) Least_Suc [THEN ssubst])
   881   apply simp
   882   done
   883 
   884 lemma ex_least_nat_le: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k\<le>n. (\<forall>i<k. \<not>P i) & P(k)"
   885   apply (cases n)
   886    apply blast
   887   apply (rule_tac x="LEAST k. P(k)" in exI)
   888   apply (blast intro: Least_le dest: not_less_Least intro: LeastI_ex)
   889   done
   890 
   891 lemma ex_least_nat_less: "\<not>P(0) \<Longrightarrow> P(n::nat) \<Longrightarrow> \<exists>k<n. (\<forall>i\<le>k. \<not>P i) & P(k+1)"
   892   unfolding One_nat_def
   893   apply (cases n)
   894    apply blast
   895   apply (frule (1) ex_least_nat_le)
   896   apply (erule exE)
   897   apply (case_tac k)
   898    apply simp
   899   apply (rename_tac k1)
   900   apply (rule_tac x=k1 in exI)
   901   apply (auto simp add: less_eq_Suc_le)
   902   done
   903 
   904 lemma nat_less_induct:
   905   assumes "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   906   using assms less_induct by blast
   907 
   908 lemma measure_induct_rule [case_names less]:
   909   fixes f :: "'a \<Rightarrow> nat"
   910   assumes step: "\<And>x. (\<And>y. f y < f x \<Longrightarrow> P y) \<Longrightarrow> P x"
   911   shows "P a"
   912 by (induct m\<equiv>"f a" arbitrary: a rule: less_induct) (auto intro: step)
   913 
   914 text {* old style induction rules: *}
   915 lemma measure_induct:
   916   fixes f :: "'a \<Rightarrow> nat"
   917   shows "(\<And>x. \<forall>y. f y < f x \<longrightarrow> P y \<Longrightarrow> P x) \<Longrightarrow> P a"
   918   by (rule measure_induct_rule [of f P a]) iprover
   919 
   920 lemma full_nat_induct:
   921   assumes step: "(!!n. (ALL m. Suc m <= n --> P m) ==> P n)"
   922   shows "P n"
   923   by (rule less_induct) (auto intro: step simp:le_simps)
   924 
   925 text{*An induction rule for estabilishing binary relations*}
   926 lemma less_Suc_induct:
   927   assumes less:  "i < j"
   928      and  step:  "!!i. P i (Suc i)"
   929      and  trans: "!!i j k. i < j ==> j < k ==>  P i j ==> P j k ==> P i k"
   930   shows "P i j"
   931 proof -
   932   from less obtain k where j: "j = Suc (i + k)" by (auto dest: less_imp_Suc_add)
   933   have "P i (Suc (i + k))"
   934   proof (induct k)
   935     case 0
   936     show ?case by (simp add: step)
   937   next
   938     case (Suc k)
   939     have "0 + i < Suc k + i" by (rule add_less_mono1) simp
   940     hence "i < Suc (i + k)" by (simp add: add_commute)
   941     from trans[OF this lessI Suc step]
   942     show ?case by simp
   943   qed
   944   thus "P i j" by (simp add: j)
   945 qed
   946 
   947 text {* The method of infinite descent, frequently used in number theory.
   948 Provided by Roelof Oosterhuis.
   949 $P(n)$ is true for all $n\in\mathbb{N}$ if
   950 \begin{itemize}
   951   \item case ``0'': given $n=0$ prove $P(n)$,
   952   \item case ``smaller'': given $n>0$ and $\neg P(n)$ prove there exists
   953         a smaller integer $m$ such that $\neg P(m)$.
   954 \end{itemize} *}
   955 
   956 text{* A compact version without explicit base case: *}
   957 lemma infinite_descent:
   958   "\<lbrakk> !!n::nat. \<not> P n \<Longrightarrow>  \<exists>m<n. \<not>  P m \<rbrakk> \<Longrightarrow>  P n"
   959 by (induct n rule: less_induct) auto
   960 
   961 lemma infinite_descent0[case_names 0 smaller]: 
   962   "\<lbrakk> P 0; !!n. n>0 \<Longrightarrow> \<not> P n \<Longrightarrow> (\<exists>m::nat. m < n \<and> \<not>P m) \<rbrakk> \<Longrightarrow> P n"
   963 by (rule infinite_descent) (case_tac "n>0", auto)
   964 
   965 text {*
   966 Infinite descent using a mapping to $\mathbb{N}$:
   967 $P(x)$ is true for all $x\in D$ if there exists a $V: D \to \mathbb{N}$ and
   968 \begin{itemize}
   969 \item case ``0'': given $V(x)=0$ prove $P(x)$,
   970 \item case ``smaller'': given $V(x)>0$ and $\neg P(x)$ prove there exists a $y \in D$ such that $V(y)<V(x)$ and $~\neg P(y)$.
   971 \end{itemize}
   972 NB: the proof also shows how to use the previous lemma. *}
   973 
   974 corollary infinite_descent0_measure [case_names 0 smaller]:
   975   assumes A0: "!!x. V x = (0::nat) \<Longrightarrow> P x"
   976     and   A1: "!!x. V x > 0 \<Longrightarrow> \<not>P x \<Longrightarrow> (\<exists>y. V y < V x \<and> \<not>P y)"
   977   shows "P x"
   978 proof -
   979   obtain n where "n = V x" by auto
   980   moreover have "\<And>x. V x = n \<Longrightarrow> P x"
   981   proof (induct n rule: infinite_descent0)
   982     case 0 -- "i.e. $V(x) = 0$"
   983     with A0 show "P x" by auto
   984   next -- "now $n>0$ and $P(x)$ does not hold for some $x$ with $V(x)=n$"
   985     case (smaller n)
   986     then obtain x where vxn: "V x = n " and "V x > 0 \<and> \<not> P x" by auto
   987     with A1 obtain y where "V y < V x \<and> \<not> P y" by auto
   988     with vxn obtain m where "m = V y \<and> m<n \<and> \<not> P y" by auto
   989     then show ?case by auto
   990   qed
   991   ultimately show "P x" by auto
   992 qed
   993 
   994 text{* Again, without explicit base case: *}
   995 lemma infinite_descent_measure:
   996 assumes "!!x. \<not> P x \<Longrightarrow> \<exists>y. (V::'a\<Rightarrow>nat) y < V x \<and> \<not> P y" shows "P x"
   997 proof -
   998   from assms obtain n where "n = V x" by auto
   999   moreover have "!!x. V x = n \<Longrightarrow> P x"
  1000   proof (induct n rule: infinite_descent, auto)
  1001     fix x assume "\<not> P x"
  1002     with assms show "\<exists>m < V x. \<exists>y. V y = m \<and> \<not> P y" by auto
  1003   qed
  1004   ultimately show "P x" by auto
  1005 qed
  1006 
  1007 text {* A [clumsy] way of lifting @{text "<"}
  1008   monotonicity to @{text "\<le>"} monotonicity *}
  1009 lemma less_mono_imp_le_mono:
  1010   "\<lbrakk> !!i j::nat. i < j \<Longrightarrow> f i < f j; i \<le> j \<rbrakk> \<Longrightarrow> f i \<le> ((f j)::nat)"
  1011 by (simp add: order_le_less) (blast)
  1012 
  1013 
  1014 text {* non-strict, in 1st argument *}
  1015 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
  1016 by (rule add_right_mono)
  1017 
  1018 text {* non-strict, in both arguments *}
  1019 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
  1020 by (rule add_mono)
  1021 
  1022 lemma le_add2: "n \<le> ((m + n)::nat)"
  1023 by (insert add_right_mono [of 0 m n], simp)
  1024 
  1025 lemma le_add1: "n \<le> ((n + m)::nat)"
  1026 by (simp add: add_commute, rule le_add2)
  1027 
  1028 lemma less_add_Suc1: "i < Suc (i + m)"
  1029 by (rule le_less_trans, rule le_add1, rule lessI)
  1030 
  1031 lemma less_add_Suc2: "i < Suc (m + i)"
  1032 by (rule le_less_trans, rule le_add2, rule lessI)
  1033 
  1034 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
  1035 by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
  1036 
  1037 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
  1038 by (rule le_trans, assumption, rule le_add1)
  1039 
  1040 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
  1041 by (rule le_trans, assumption, rule le_add2)
  1042 
  1043 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
  1044 by (rule less_le_trans, assumption, rule le_add1)
  1045 
  1046 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
  1047 by (rule less_le_trans, assumption, rule le_add2)
  1048 
  1049 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
  1050 apply (rule le_less_trans [of _ "i+j"])
  1051 apply (simp_all add: le_add1)
  1052 done
  1053 
  1054 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
  1055 apply (rule notI)
  1056 apply (drule add_lessD1)
  1057 apply (erule less_irrefl [THEN notE])
  1058 done
  1059 
  1060 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
  1061 by (simp add: add_commute)
  1062 
  1063 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
  1064 apply (rule order_trans [of _ "m+k"])
  1065 apply (simp_all add: le_add1)
  1066 done
  1067 
  1068 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
  1069 apply (simp add: add_commute)
  1070 apply (erule add_leD1)
  1071 done
  1072 
  1073 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
  1074 by (blast dest: add_leD1 add_leD2)
  1075 
  1076 text {* needs @{text "!!k"} for @{text add_ac} to work *}
  1077 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
  1078 by (force simp del: add_Suc_right
  1079     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
  1080 
  1081 
  1082 subsubsection {* More results about difference *}
  1083 
  1084 text {* Addition is the inverse of subtraction:
  1085   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
  1086 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
  1087 by (induct m n rule: diff_induct) simp_all
  1088 
  1089 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
  1090 by (simp add: add_diff_inverse linorder_not_less)
  1091 
  1092 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
  1093 by (simp add: add_commute)
  1094 
  1095 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
  1096 by (induct m n rule: diff_induct) simp_all
  1097 
  1098 lemma diff_less_Suc: "m - n < Suc m"
  1099 apply (induct m n rule: diff_induct)
  1100 apply (erule_tac [3] less_SucE)
  1101 apply (simp_all add: less_Suc_eq)
  1102 done
  1103 
  1104 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
  1105 by (induct m n rule: diff_induct) (simp_all add: le_SucI)
  1106 
  1107 lemma le_iff_add: "(m::nat) \<le> n = (\<exists>k. n = m + k)"
  1108   by (auto simp: le_add1 dest!: le_add_diff_inverse sym [of _ n])
  1109 
  1110 instance nat :: ordered_cancel_comm_monoid_diff
  1111 proof
  1112   show "\<And>m n :: nat. m \<le> n \<longleftrightarrow> (\<exists>q. n = m + q)" by (fact le_iff_add)
  1113 qed
  1114 
  1115 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
  1116 by (rule le_less_trans, rule diff_le_self)
  1117 
  1118 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
  1119 by (cases n) (auto simp add: le_simps)
  1120 
  1121 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
  1122 by (induct j k rule: diff_induct) simp_all
  1123 
  1124 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
  1125 by (simp add: add_commute diff_add_assoc)
  1126 
  1127 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
  1128 by (auto simp add: diff_add_inverse2)
  1129 
  1130 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
  1131 by (induct m n rule: diff_induct) simp_all
  1132 
  1133 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
  1134 by (rule iffD2, rule diff_is_0_eq)
  1135 
  1136 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
  1137 by (induct m n rule: diff_induct) simp_all
  1138 
  1139 lemma less_imp_add_positive:
  1140   assumes "i < j"
  1141   shows "\<exists>k::nat. 0 < k & i + k = j"
  1142 proof
  1143   from assms show "0 < j - i & i + (j - i) = j"
  1144     by (simp add: order_less_imp_le)
  1145 qed
  1146 
  1147 text {* a nice rewrite for bounded subtraction *}
  1148 lemma nat_minus_add_max:
  1149   fixes n m :: nat
  1150   shows "n - m + m = max n m"
  1151     by (simp add: max_def not_le order_less_imp_le)
  1152 
  1153 lemma nat_diff_split:
  1154   "P(a - b::nat) = ((a<b --> P 0) & (ALL d. a = b + d --> P d))"
  1155     -- {* elimination of @{text -} on @{text nat} *}
  1156 by (cases "a < b")
  1157   (auto simp add: diff_is_0_eq [THEN iffD2] diff_add_inverse
  1158     not_less le_less dest!: sym [of a] sym [of b] add_eq_self_zero)
  1159 
  1160 lemma nat_diff_split_asm:
  1161   "P(a - b::nat) = (~ (a < b & ~ P 0 | (EX d. a = b + d & ~ P d)))"
  1162     -- {* elimination of @{text -} on @{text nat} in assumptions *}
  1163 by (auto split: nat_diff_split)
  1164 
  1165 lemma Suc_pred': "0 < n ==> n = Suc(n - 1)"
  1166   by simp
  1167 
  1168 lemma add_eq_if: "(m::nat) + n = (if m=0 then n else Suc ((m - 1) + n))"
  1169   unfolding One_nat_def by (cases m) simp_all
  1170 
  1171 lemma mult_eq_if: "(m::nat) * n = (if m=0 then 0 else n + ((m - 1) * n))"
  1172   unfolding One_nat_def by (cases m) simp_all
  1173 
  1174 lemma Suc_diff_eq_diff_pred: "0 < n ==> Suc m - n = m - (n - 1)"
  1175   unfolding One_nat_def by (cases n) simp_all
  1176 
  1177 lemma diff_Suc_eq_diff_pred: "m - Suc n = (m - 1) - n"
  1178   unfolding One_nat_def by (cases m) simp_all
  1179 
  1180 lemma Let_Suc [simp]: "Let (Suc n) f == f (Suc n)"
  1181   by (fact Let_def)
  1182 
  1183 
  1184 subsubsection {* Monotonicity of Multiplication *}
  1185 
  1186 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
  1187 by (simp add: mult_right_mono)
  1188 
  1189 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
  1190 by (simp add: mult_left_mono)
  1191 
  1192 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
  1193 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
  1194 by (simp add: mult_mono)
  1195 
  1196 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
  1197 by (simp add: mult_strict_right_mono)
  1198 
  1199 text{*Differs from the standard @{text zero_less_mult_iff} in that
  1200       there are no negative numbers.*}
  1201 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
  1202   apply (induct m)
  1203    apply simp
  1204   apply (case_tac n)
  1205    apply simp_all
  1206   done
  1207 
  1208 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (Suc 0 \<le> m & Suc 0 \<le> n)"
  1209   apply (induct m)
  1210    apply simp
  1211   apply (case_tac n)
  1212    apply simp_all
  1213   done
  1214 
  1215 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
  1216   apply (safe intro!: mult_less_mono1)
  1217   apply (cases k, auto)
  1218   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
  1219   apply (blast intro: mult_le_mono1)
  1220   done
  1221 
  1222 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
  1223 by (simp add: mult_commute [of k])
  1224 
  1225 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
  1226 by (simp add: linorder_not_less [symmetric], auto)
  1227 
  1228 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
  1229 by (simp add: linorder_not_less [symmetric], auto)
  1230 
  1231 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1232 by (subst mult_less_cancel1) simp
  1233 
  1234 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1235 by (subst mult_le_cancel1) simp
  1236 
  1237 lemma le_square: "m \<le> m * (m::nat)"
  1238   by (cases m) (auto intro: le_add1)
  1239 
  1240 lemma le_cube: "(m::nat) \<le> m * (m * m)"
  1241   by (cases m) (auto intro: le_add1)
  1242 
  1243 text {* Lemma for @{text gcd} *}
  1244 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1245   apply (drule sym)
  1246   apply (rule disjCI)
  1247   apply (rule nat_less_cases, erule_tac [2] _)
  1248    apply (drule_tac [2] mult_less_mono2)
  1249     apply (auto)
  1250   done
  1251 
  1252 lemma mono_times_nat:
  1253   fixes n :: nat
  1254   assumes "n > 0"
  1255   shows "mono (times n)"
  1256 proof
  1257   fix m q :: nat
  1258   assume "m \<le> q"
  1259   with assms show "n * m \<le> n * q" by simp
  1260 qed
  1261 
  1262 text {* the lattice order on @{typ nat} *}
  1263 
  1264 instantiation nat :: distrib_lattice
  1265 begin
  1266 
  1267 definition
  1268   "(inf \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = min"
  1269 
  1270 definition
  1271   "(sup \<Colon> nat \<Rightarrow> nat \<Rightarrow> nat) = max"
  1272 
  1273 instance by intro_classes
  1274   (auto simp add: inf_nat_def sup_nat_def max_def not_le min_def
  1275     intro: order_less_imp_le antisym elim!: order_trans order_less_trans)
  1276 
  1277 end
  1278 
  1279 
  1280 subsection {* Natural operation of natural numbers on functions *}
  1281 
  1282 text {*
  1283   We use the same logical constant for the power operations on
  1284   functions and relations, in order to share the same syntax.
  1285 *}
  1286 
  1287 consts compow :: "nat \<Rightarrow> 'a \<Rightarrow> 'a"
  1288 
  1289 abbreviation compower :: "'a \<Rightarrow> nat \<Rightarrow> 'a" (infixr "^^" 80) where
  1290   "f ^^ n \<equiv> compow n f"
  1291 
  1292 notation (latex output)
  1293   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1294 
  1295 notation (HTML output)
  1296   compower ("(_\<^bsup>_\<^esup>)" [1000] 1000)
  1297 
  1298 text {* @{text "f ^^ n = f o ... o f"}, the n-fold composition of @{text f} *}
  1299 
  1300 overloading
  1301   funpow == "compow :: nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> ('a \<Rightarrow> 'a)"
  1302 begin
  1303 
  1304 primrec funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1305   "funpow 0 f = id"
  1306 | "funpow (Suc n) f = f o funpow n f"
  1307 
  1308 end
  1309 
  1310 lemma funpow_Suc_right:
  1311   "f ^^ Suc n = f ^^ n \<circ> f"
  1312 proof (induct n)
  1313   case 0 then show ?case by simp
  1314 next
  1315   fix n
  1316   assume "f ^^ Suc n = f ^^ n \<circ> f"
  1317   then show "f ^^ Suc (Suc n) = f ^^ Suc n \<circ> f"
  1318     by (simp add: o_assoc)
  1319 qed
  1320 
  1321 lemmas funpow_simps_right = funpow.simps(1) funpow_Suc_right
  1322 
  1323 text {* for code generation *}
  1324 
  1325 definition funpow :: "nat \<Rightarrow> ('a \<Rightarrow> 'a) \<Rightarrow> 'a \<Rightarrow> 'a" where
  1326   funpow_code_def [code_abbrev]: "funpow = compow"
  1327 
  1328 lemma [code]:
  1329   "funpow (Suc n) f = f o funpow n f"
  1330   "funpow 0 f = id"
  1331   by (simp_all add: funpow_code_def)
  1332 
  1333 hide_const (open) funpow
  1334 
  1335 lemma funpow_add:
  1336   "f ^^ (m + n) = f ^^ m \<circ> f ^^ n"
  1337   by (induct m) simp_all
  1338 
  1339 lemma funpow_mult:
  1340   fixes f :: "'a \<Rightarrow> 'a"
  1341   shows "(f ^^ m) ^^ n = f ^^ (m * n)"
  1342   by (induct n) (simp_all add: funpow_add)
  1343 
  1344 lemma funpow_swap1:
  1345   "f ((f ^^ n) x) = (f ^^ n) (f x)"
  1346 proof -
  1347   have "f ((f ^^ n) x) = (f ^^ (n + 1)) x" by simp
  1348   also have "\<dots>  = (f ^^ n o f ^^ 1) x" by (simp only: funpow_add)
  1349   also have "\<dots> = (f ^^ n) (f x)" by simp
  1350   finally show ?thesis .
  1351 qed
  1352 
  1353 lemma comp_funpow:
  1354   fixes f :: "'a \<Rightarrow> 'a"
  1355   shows "comp f ^^ n = comp (f ^^ n)"
  1356   by (induct n) simp_all
  1357 
  1358 lemma Suc_funpow[simp]: "Suc ^^ n = (op + n)"
  1359   by (induct n) simp_all
  1360 
  1361 lemma id_funpow[simp]: "id ^^ n = id"
  1362   by (induct n) simp_all
  1363 
  1364 subsection {* Kleene iteration *}
  1365 
  1366 lemma Kleene_iter_lpfp:
  1367 assumes "mono f" and "f p \<le> p" shows "(f^^k) (bot::'a::order_bot) \<le> p"
  1368 proof(induction k)
  1369   case 0 show ?case by simp
  1370 next
  1371   case Suc
  1372   from monoD[OF assms(1) Suc] assms(2)
  1373   show ?case by simp
  1374 qed
  1375 
  1376 lemma lfp_Kleene_iter: assumes "mono f" and "(f^^Suc k) bot = (f^^k) bot"
  1377 shows "lfp f = (f^^k) bot"
  1378 proof(rule antisym)
  1379   show "lfp f \<le> (f^^k) bot"
  1380   proof(rule lfp_lowerbound)
  1381     show "f ((f^^k) bot) \<le> (f^^k) bot" using assms(2) by simp
  1382   qed
  1383 next
  1384   show "(f^^k) bot \<le> lfp f"
  1385     using Kleene_iter_lpfp[OF assms(1)] lfp_unfold[OF assms(1)] by simp
  1386 qed
  1387 
  1388 
  1389 subsection {* Embedding of the Naturals into any @{text semiring_1}: @{term of_nat} *}
  1390 
  1391 context semiring_1
  1392 begin
  1393 
  1394 definition of_nat :: "nat \<Rightarrow> 'a" where
  1395   "of_nat n = (plus 1 ^^ n) 0"
  1396 
  1397 lemma of_nat_simps [simp]:
  1398   shows of_nat_0: "of_nat 0 = 0"
  1399     and of_nat_Suc: "of_nat (Suc m) = 1 + of_nat m"
  1400   by (simp_all add: of_nat_def)
  1401 
  1402 lemma of_nat_1 [simp]: "of_nat 1 = 1"
  1403   by (simp add: of_nat_def)
  1404 
  1405 lemma of_nat_add [simp]: "of_nat (m + n) = of_nat m + of_nat n"
  1406   by (induct m) (simp_all add: add_ac)
  1407 
  1408 lemma of_nat_mult: "of_nat (m * n) = of_nat m * of_nat n"
  1409   by (induct m) (simp_all add: add_ac distrib_right)
  1410 
  1411 primrec of_nat_aux :: "('a \<Rightarrow> 'a) \<Rightarrow> nat \<Rightarrow> 'a \<Rightarrow> 'a" where
  1412   "of_nat_aux inc 0 i = i"
  1413 | "of_nat_aux inc (Suc n) i = of_nat_aux inc n (inc i)" -- {* tail recursive *}
  1414 
  1415 lemma of_nat_code:
  1416   "of_nat n = of_nat_aux (\<lambda>i. i + 1) n 0"
  1417 proof (induct n)
  1418   case 0 then show ?case by simp
  1419 next
  1420   case (Suc n)
  1421   have "\<And>i. of_nat_aux (\<lambda>i. i + 1) n (i + 1) = of_nat_aux (\<lambda>i. i + 1) n i + 1"
  1422     by (induct n) simp_all
  1423   from this [of 0] have "of_nat_aux (\<lambda>i. i + 1) n 1 = of_nat_aux (\<lambda>i. i + 1) n 0 + 1"
  1424     by simp
  1425   with Suc show ?case by (simp add: add_commute)
  1426 qed
  1427 
  1428 end
  1429 
  1430 declare of_nat_code [code]
  1431 
  1432 text{*Class for unital semirings with characteristic zero.
  1433  Includes non-ordered rings like the complex numbers.*}
  1434 
  1435 class semiring_char_0 = semiring_1 +
  1436   assumes inj_of_nat: "inj of_nat"
  1437 begin
  1438 
  1439 lemma of_nat_eq_iff [simp]: "of_nat m = of_nat n \<longleftrightarrow> m = n"
  1440   by (auto intro: inj_of_nat injD)
  1441 
  1442 text{*Special cases where either operand is zero*}
  1443 
  1444 lemma of_nat_0_eq_iff [simp]: "0 = of_nat n \<longleftrightarrow> 0 = n"
  1445   by (fact of_nat_eq_iff [of 0 n, unfolded of_nat_0])
  1446 
  1447 lemma of_nat_eq_0_iff [simp]: "of_nat m = 0 \<longleftrightarrow> m = 0"
  1448   by (fact of_nat_eq_iff [of m 0, unfolded of_nat_0])
  1449 
  1450 end
  1451 
  1452 context linordered_semidom
  1453 begin
  1454 
  1455 lemma of_nat_0_le_iff [simp]: "0 \<le> of_nat n"
  1456   by (induct n) simp_all
  1457 
  1458 lemma of_nat_less_0_iff [simp]: "\<not> of_nat m < 0"
  1459   by (simp add: not_less)
  1460 
  1461 lemma of_nat_less_iff [simp]: "of_nat m < of_nat n \<longleftrightarrow> m < n"
  1462   by (induct m n rule: diff_induct, simp_all add: add_pos_nonneg)
  1463 
  1464 lemma of_nat_le_iff [simp]: "of_nat m \<le> of_nat n \<longleftrightarrow> m \<le> n"
  1465   by (simp add: not_less [symmetric] linorder_not_less [symmetric])
  1466 
  1467 lemma less_imp_of_nat_less: "m < n \<Longrightarrow> of_nat m < of_nat n"
  1468   by simp
  1469 
  1470 lemma of_nat_less_imp_less: "of_nat m < of_nat n \<Longrightarrow> m < n"
  1471   by simp
  1472 
  1473 text{*Every @{text linordered_semidom} has characteristic zero.*}
  1474 
  1475 subclass semiring_char_0 proof
  1476 qed (auto intro!: injI simp add: eq_iff)
  1477 
  1478 text{*Special cases where either operand is zero*}
  1479 
  1480 lemma of_nat_le_0_iff [simp]: "of_nat m \<le> 0 \<longleftrightarrow> m = 0"
  1481   by (rule of_nat_le_iff [of _ 0, simplified])
  1482 
  1483 lemma of_nat_0_less_iff [simp]: "0 < of_nat n \<longleftrightarrow> 0 < n"
  1484   by (rule of_nat_less_iff [of 0, simplified])
  1485 
  1486 end
  1487 
  1488 context ring_1
  1489 begin
  1490 
  1491 lemma of_nat_diff: "n \<le> m \<Longrightarrow> of_nat (m - n) = of_nat m - of_nat n"
  1492 by (simp add: algebra_simps of_nat_add [symmetric])
  1493 
  1494 end
  1495 
  1496 context linordered_idom
  1497 begin
  1498 
  1499 lemma abs_of_nat [simp]: "\<bar>of_nat n\<bar> = of_nat n"
  1500   unfolding abs_if by auto
  1501 
  1502 end
  1503 
  1504 lemma of_nat_id [simp]: "of_nat n = n"
  1505   by (induct n) simp_all
  1506 
  1507 lemma of_nat_eq_id [simp]: "of_nat = id"
  1508   by (auto simp add: fun_eq_iff)
  1509 
  1510 
  1511 subsection {* The Set of Natural Numbers *}
  1512 
  1513 context semiring_1
  1514 begin
  1515 
  1516 definition Nats  :: "'a set" where
  1517   "Nats = range of_nat"
  1518 
  1519 notation (xsymbols)
  1520   Nats  ("\<nat>")
  1521 
  1522 lemma of_nat_in_Nats [simp]: "of_nat n \<in> \<nat>"
  1523   by (simp add: Nats_def)
  1524 
  1525 lemma Nats_0 [simp]: "0 \<in> \<nat>"
  1526 apply (simp add: Nats_def)
  1527 apply (rule range_eqI)
  1528 apply (rule of_nat_0 [symmetric])
  1529 done
  1530 
  1531 lemma Nats_1 [simp]: "1 \<in> \<nat>"
  1532 apply (simp add: Nats_def)
  1533 apply (rule range_eqI)
  1534 apply (rule of_nat_1 [symmetric])
  1535 done
  1536 
  1537 lemma Nats_add [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a + b \<in> \<nat>"
  1538 apply (auto simp add: Nats_def)
  1539 apply (rule range_eqI)
  1540 apply (rule of_nat_add [symmetric])
  1541 done
  1542 
  1543 lemma Nats_mult [simp]: "a \<in> \<nat> \<Longrightarrow> b \<in> \<nat> \<Longrightarrow> a * b \<in> \<nat>"
  1544 apply (auto simp add: Nats_def)
  1545 apply (rule range_eqI)
  1546 apply (rule of_nat_mult [symmetric])
  1547 done
  1548 
  1549 lemma Nats_cases [cases set: Nats]:
  1550   assumes "x \<in> \<nat>"
  1551   obtains (of_nat) n where "x = of_nat n"
  1552   unfolding Nats_def
  1553 proof -
  1554   from `x \<in> \<nat>` have "x \<in> range of_nat" unfolding Nats_def .
  1555   then obtain n where "x = of_nat n" ..
  1556   then show thesis ..
  1557 qed
  1558 
  1559 lemma Nats_induct [case_names of_nat, induct set: Nats]:
  1560   "x \<in> \<nat> \<Longrightarrow> (\<And>n. P (of_nat n)) \<Longrightarrow> P x"
  1561   by (rule Nats_cases) auto
  1562 
  1563 end
  1564 
  1565 
  1566 subsection {* Further Arithmetic Facts Concerning the Natural Numbers *}
  1567 
  1568 lemma subst_equals:
  1569   assumes 1: "t = s" and 2: "u = t"
  1570   shows "u = s"
  1571   using 2 1 by (rule trans)
  1572 
  1573 setup Arith_Data.setup
  1574 
  1575 ML_file "Tools/nat_arith.ML"
  1576 
  1577 simproc_setup nateq_cancel_sums
  1578   ("(l::nat) + m = n" | "(l::nat) = m + n" | "Suc m = n" | "m = Suc n") =
  1579   {* fn phi => try o Nat_Arith.cancel_eq_conv *}
  1580 
  1581 simproc_setup natless_cancel_sums
  1582   ("(l::nat) + m < n" | "(l::nat) < m + n" | "Suc m < n" | "m < Suc n") =
  1583   {* fn phi => try o Nat_Arith.cancel_less_conv *}
  1584 
  1585 simproc_setup natle_cancel_sums
  1586   ("(l::nat) + m \<le> n" | "(l::nat) \<le> m + n" | "Suc m \<le> n" | "m \<le> Suc n") =
  1587   {* fn phi => try o Nat_Arith.cancel_le_conv *}
  1588 
  1589 simproc_setup natdiff_cancel_sums
  1590   ("(l::nat) + m - n" | "(l::nat) - (m + n)" | "Suc m - n" | "m - Suc n") =
  1591   {* fn phi => try o Nat_Arith.cancel_diff_conv *}
  1592 
  1593 ML_file "Tools/lin_arith.ML"
  1594 setup {* Lin_Arith.global_setup *}
  1595 declaration {* K Lin_Arith.setup *}
  1596 
  1597 simproc_setup fast_arith_nat ("(m::nat) < n" | "(m::nat) <= n" | "(m::nat) = n") =
  1598   {* fn _ => fn ss => fn ct => Lin_Arith.simproc ss (term_of ct) *}
  1599 (* Because of this simproc, the arithmetic solver is really only
  1600 useful to detect inconsistencies among the premises for subgoals which are
  1601 *not* themselves (in)equalities, because the latter activate
  1602 fast_nat_arith_simproc anyway. However, it seems cheaper to activate the
  1603 solver all the time rather than add the additional check. *)
  1604 
  1605 
  1606 lemmas [arith_split] = nat_diff_split split_min split_max
  1607 
  1608 context order
  1609 begin
  1610 
  1611 lemma lift_Suc_mono_le:
  1612   assumes mono: "\<And>n. f n \<le> f (Suc n)" and "n \<le> n'"
  1613   shows "f n \<le> f n'"
  1614 proof (cases "n < n'")
  1615   case True
  1616   then show ?thesis
  1617     by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1618 qed (insert `n \<le> n'`, auto) -- {* trivial for @{prop "n = n'"} *}
  1619 
  1620 lemma lift_Suc_mono_less:
  1621   assumes mono: "\<And>n. f n < f (Suc n)" and "n < n'"
  1622   shows "f n < f n'"
  1623 using `n < n'`
  1624 by (induct n n' rule: less_Suc_induct [consumes 1]) (auto intro: mono)
  1625 
  1626 lemma lift_Suc_mono_less_iff:
  1627   "(\<And>n. f n < f (Suc n)) \<Longrightarrow> f n < f m \<longleftrightarrow> n < m"
  1628   by (blast intro: less_asym' lift_Suc_mono_less [of f]
  1629     dest: linorder_not_less[THEN iffD1] le_eq_less_or_eq [THEN iffD1])
  1630 
  1631 end
  1632 
  1633 lemma mono_iff_le_Suc:
  1634   "mono f \<longleftrightarrow> (\<forall>n. f n \<le> f (Suc n))"
  1635   unfolding mono_def by (auto intro: lift_Suc_mono_le [of f])
  1636 
  1637 lemma mono_nat_linear_lb:
  1638   fixes f :: "nat \<Rightarrow> nat"
  1639   assumes "\<And>m n. m < n \<Longrightarrow> f m < f n"
  1640   shows "f m + k \<le> f (m + k)"
  1641 proof (induct k)
  1642   case 0 then show ?case by simp
  1643 next
  1644   case (Suc k)
  1645   then have "Suc (f m + k) \<le> Suc (f (m + k))" by simp
  1646   also from assms [of "m + k" "Suc (m + k)"] have "Suc (f (m + k)) \<le> f (Suc (m + k))"
  1647     by (simp add: Suc_le_eq)
  1648   finally show ?case by simp
  1649 qed
  1650 
  1651 
  1652 text{*Subtraction laws, mostly by Clemens Ballarin*}
  1653 
  1654 lemma diff_less_mono: "[| a < (b::nat); c \<le> a |] ==> a-c < b-c"
  1655 by arith
  1656 
  1657 lemma less_diff_conv: "(i < j-k) = (i+k < (j::nat))"
  1658 by arith
  1659 
  1660 lemma less_diff_conv2:
  1661   fixes j k i :: nat
  1662   assumes "k \<le> j"
  1663   shows "j - k < i \<longleftrightarrow> j < i + k"
  1664   using assms by arith
  1665 
  1666 lemma le_diff_conv: "(j-k \<le> (i::nat)) = (j \<le> i+k)"
  1667 by arith
  1668 
  1669 lemma le_diff_conv2: "k \<le> j ==> (i \<le> j-k) = (i+k \<le> (j::nat))"
  1670 by arith
  1671 
  1672 lemma diff_diff_cancel [simp]: "i \<le> (n::nat) ==> n - (n - i) = i"
  1673 by arith
  1674 
  1675 lemma le_add_diff: "k \<le> (n::nat) ==> m \<le> n + m - k"
  1676 by arith
  1677 
  1678 (*Replaces the previous diff_less and le_diff_less, which had the stronger
  1679   second premise n\<le>m*)
  1680 lemma diff_less[simp]: "!!m::nat. [| 0<n; 0<m |] ==> m - n < m"
  1681 by arith
  1682 
  1683 text {* Simplification of relational expressions involving subtraction *}
  1684 
  1685 lemma diff_diff_eq: "[| k \<le> m;  k \<le> (n::nat) |] ==> ((m-k) - (n-k)) = (m-n)"
  1686 by (simp split add: nat_diff_split)
  1687 
  1688 hide_fact (open) diff_diff_eq
  1689 
  1690 lemma eq_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k = n-k) = (m=n)"
  1691 by (auto split add: nat_diff_split)
  1692 
  1693 lemma less_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k < n-k) = (m<n)"
  1694 by (auto split add: nat_diff_split)
  1695 
  1696 lemma le_diff_iff: "[| k \<le> m;  k \<le> (n::nat) |] ==> (m-k \<le> n-k) = (m\<le>n)"
  1697 by (auto split add: nat_diff_split)
  1698 
  1699 text{*(Anti)Monotonicity of subtraction -- by Stephan Merz*}
  1700 
  1701 (* Monotonicity of subtraction in first argument *)
  1702 lemma diff_le_mono: "m \<le> (n::nat) ==> (m-l) \<le> (n-l)"
  1703 by (simp split add: nat_diff_split)
  1704 
  1705 lemma diff_le_mono2: "m \<le> (n::nat) ==> (l-n) \<le> (l-m)"
  1706 by (simp split add: nat_diff_split)
  1707 
  1708 lemma diff_less_mono2: "[| m < (n::nat); m<l |] ==> (l-n) < (l-m)"
  1709 by (simp split add: nat_diff_split)
  1710 
  1711 lemma diffs0_imp_equal: "!!m::nat. [| m-n = 0; n-m = 0 |] ==>  m=n"
  1712 by (simp split add: nat_diff_split)
  1713 
  1714 lemma min_diff: "min (m - (i::nat)) (n - i) = min m n - i"
  1715 by auto
  1716 
  1717 lemma inj_on_diff_nat: 
  1718   assumes k_le_n: "\<forall>n \<in> N. k \<le> (n::nat)"
  1719   shows "inj_on (\<lambda>n. n - k) N"
  1720 proof (rule inj_onI)
  1721   fix x y
  1722   assume a: "x \<in> N" "y \<in> N" "x - k = y - k"
  1723   with k_le_n have "x - k + k = y - k + k" by auto
  1724   with a k_le_n show "x = y" by auto
  1725 qed
  1726 
  1727 text{*Rewriting to pull differences out*}
  1728 
  1729 lemma diff_diff_right [simp]: "k\<le>j --> i - (j - k) = i + (k::nat) - j"
  1730 by arith
  1731 
  1732 lemma diff_Suc_diff_eq1 [simp]: "k \<le> j ==> m - Suc (j - k) = m + k - Suc j"
  1733 by arith
  1734 
  1735 lemma diff_Suc_diff_eq2 [simp]: "k \<le> j ==> Suc (j - k) - m = Suc j - (k + m)"
  1736 by arith
  1737 
  1738 lemma Suc_diff_Suc: "n < m \<Longrightarrow> Suc (m - Suc n) = m - n"
  1739 by simp
  1740 
  1741 (*The others are
  1742       i - j - k = i - (j + k),
  1743       k \<le> j ==> j - k + i = j + i - k,
  1744       k \<le> j ==> i + (j - k) = i + j - k *)
  1745 lemmas add_diff_assoc = diff_add_assoc [symmetric]
  1746 lemmas add_diff_assoc2 = diff_add_assoc2[symmetric]
  1747 declare diff_diff_left [simp]  add_diff_assoc [simp] add_diff_assoc2[simp]
  1748 
  1749 text{*At present we prove no analogue of @{text not_less_Least} or @{text
  1750 Least_Suc}, since there appears to be no need.*}
  1751 
  1752 text{*Lemmas for ex/Factorization*}
  1753 
  1754 lemma one_less_mult: "[| Suc 0 < n; Suc 0 < m |] ==> Suc 0 < m*n"
  1755 by (cases m) auto
  1756 
  1757 lemma n_less_m_mult_n: "[| Suc 0 < n; Suc 0 < m |] ==> n<m*n"
  1758 by (cases m) auto
  1759 
  1760 lemma n_less_n_mult_m: "[| Suc 0 < n; Suc 0 < m |] ==> n<n*m"
  1761 by (cases m) auto
  1762 
  1763 text {* Specialized induction principles that work "backwards": *}
  1764 
  1765 lemma inc_induct[consumes 1, case_names base step]:
  1766   assumes less: "i \<le> j"
  1767   assumes base: "P j"
  1768   assumes step: "\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P (Suc n) \<Longrightarrow> P n"
  1769   shows "P i"
  1770   using less step
  1771 proof (induct d\<equiv>"j - i" arbitrary: i)
  1772   case (0 i)
  1773   hence "i = j" by simp
  1774   with base show ?case by simp
  1775 next
  1776   case (Suc d n)
  1777   hence "n \<le> n" "n < j" "P (Suc n)"
  1778     by simp_all
  1779   then show "P n" by fact
  1780 qed
  1781 
  1782 lemma strict_inc_induct[consumes 1, case_names base step]:
  1783   assumes less: "i < j"
  1784   assumes base: "!!i. j = Suc i ==> P i"
  1785   assumes step: "!!i. [| i < j; P (Suc i) |] ==> P i"
  1786   shows "P i"
  1787   using less
  1788 proof (induct d=="j - i - 1" arbitrary: i)
  1789   case (0 i)
  1790   with `i < j` have "j = Suc i" by simp
  1791   with base show ?case by simp
  1792 next
  1793   case (Suc d i)
  1794   hence "i < j" "P (Suc i)"
  1795     by simp_all
  1796   thus "P i" by (rule step)
  1797 qed
  1798 
  1799 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
  1800   using inc_induct[of "k - i" k P, simplified] by blast
  1801 
  1802 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
  1803   using inc_induct[of 0 k P] by blast
  1804 
  1805 text {* Further induction rule similar to @{thm inc_induct} *}
  1806 
  1807 lemma dec_induct[consumes 1, case_names base step]:
  1808   "i \<le> j \<Longrightarrow> P i \<Longrightarrow> (\<And>n. i \<le> n \<Longrightarrow> n < j \<Longrightarrow> P n \<Longrightarrow> P (Suc n)) \<Longrightarrow> P j"
  1809   by (induct j arbitrary: i) (auto simp: le_Suc_eq)
  1810  
  1811 subsection {* The divides relation on @{typ nat} *}
  1812 
  1813 lemma dvd_1_left [iff]: "Suc 0 dvd k"
  1814 unfolding dvd_def by simp
  1815 
  1816 lemma dvd_1_iff_1 [simp]: "(m dvd Suc 0) = (m = Suc 0)"
  1817 by (simp add: dvd_def)
  1818 
  1819 lemma nat_dvd_1_iff_1 [simp]: "m dvd (1::nat) \<longleftrightarrow> m = 1"
  1820 by (simp add: dvd_def)
  1821 
  1822 lemma dvd_antisym: "[| m dvd n; n dvd m |] ==> m = (n::nat)"
  1823   unfolding dvd_def
  1824   by (force dest: mult_eq_self_implies_10 simp add: mult_assoc)
  1825 
  1826 text {* @{term "op dvd"} is a partial order *}
  1827 
  1828 interpretation dvd: order "op dvd" "\<lambda>n m \<Colon> nat. n dvd m \<and> \<not> m dvd n"
  1829   proof qed (auto intro: dvd_refl dvd_trans dvd_antisym)
  1830 
  1831 lemma dvd_diff_nat[simp]: "[| k dvd m; k dvd n |] ==> k dvd (m-n :: nat)"
  1832 unfolding dvd_def
  1833 by (blast intro: diff_mult_distrib2 [symmetric])
  1834 
  1835 lemma dvd_diffD: "[| k dvd m-n; k dvd n; n\<le>m |] ==> k dvd (m::nat)"
  1836   apply (erule linorder_not_less [THEN iffD2, THEN add_diff_inverse, THEN subst])
  1837   apply (blast intro: dvd_add)
  1838   done
  1839 
  1840 lemma dvd_diffD1: "[| k dvd m-n; k dvd m; n\<le>m |] ==> k dvd (n::nat)"
  1841 by (drule_tac m = m in dvd_diff_nat, auto)
  1842 
  1843 lemma dvd_reduce: "(k dvd n + k) = (k dvd (n::nat))"
  1844   apply (rule iffI)
  1845    apply (erule_tac [2] dvd_add)
  1846    apply (rule_tac [2] dvd_refl)
  1847   apply (subgoal_tac "n = (n+k) -k")
  1848    prefer 2 apply simp
  1849   apply (erule ssubst)
  1850   apply (erule dvd_diff_nat)
  1851   apply (rule dvd_refl)
  1852   done
  1853 
  1854 lemma dvd_mult_cancel: "!!k::nat. [| k*m dvd k*n; 0<k |] ==> m dvd n"
  1855   unfolding dvd_def
  1856   apply (erule exE)
  1857   apply (simp add: mult_ac)
  1858   done
  1859 
  1860 lemma dvd_mult_cancel1: "0<m ==> (m*n dvd m) = (n = (1::nat))"
  1861   apply auto
  1862    apply (subgoal_tac "m*n dvd m*1")
  1863    apply (drule dvd_mult_cancel, auto)
  1864   done
  1865 
  1866 lemma dvd_mult_cancel2: "0<m ==> (n*m dvd m) = (n = (1::nat))"
  1867   apply (subst mult_commute)
  1868   apply (erule dvd_mult_cancel1)
  1869   done
  1870 
  1871 lemma dvd_imp_le: "[| k dvd n; 0 < n |] ==> k \<le> (n::nat)"
  1872 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1873 
  1874 lemma nat_dvd_not_less:
  1875   fixes m n :: nat
  1876   shows "0 < m \<Longrightarrow> m < n \<Longrightarrow> \<not> n dvd m"
  1877 by (auto elim!: dvdE) (auto simp add: gr0_conv_Suc)
  1878 
  1879 lemma dvd_plusE:
  1880   fixes m n q :: nat
  1881   assumes "m dvd n + q" "m dvd n"
  1882   obtains "m dvd q"
  1883 proof (cases "m = 0")
  1884   case True with assms that show thesis by simp
  1885 next
  1886   case False then have "m > 0" by simp
  1887   from assms obtain r s where "n = m * r" and "n + q = m * s" by (blast elim: dvdE)
  1888   then have *: "m * r + q = m * s" by simp
  1889   show thesis proof (cases "r \<le> s")
  1890     case False then have "s < r" by (simp add: not_le)
  1891     with * have "m * r + q - m * s = m * s - m * s" by simp
  1892     then have "m * r + q - m * s = 0" by simp
  1893     with `m > 0` `s < r` have "m * r - m * s + q = 0" by (unfold less_le_not_le) auto
  1894     then have "m * (r - s) + q = 0" by auto
  1895     then have "m * (r - s) = 0" by simp
  1896     then have "m = 0 \<or> r - s = 0" by simp
  1897     with `s < r` have "m = 0" by (simp add: less_le_not_le)
  1898     with `m > 0` show thesis by auto
  1899   next
  1900     case True with * have "m * r + q - m * r = m * s - m * r" by simp
  1901     with `m > 0` `r \<le> s` have "m * r - m * r + q = m * s - m * r" by simp
  1902     then have "q = m * (s - r)" by (simp add: diff_mult_distrib2)
  1903     with assms that show thesis by (auto intro: dvdI)
  1904   qed
  1905 qed
  1906 
  1907 lemma dvd_plus_eq_right:
  1908   fixes m n q :: nat
  1909   assumes "m dvd n"
  1910   shows "m dvd n + q \<longleftrightarrow> m dvd q"
  1911   using assms by (auto elim: dvd_plusE)
  1912 
  1913 lemma dvd_plus_eq_left:
  1914   fixes m n q :: nat
  1915   assumes "m dvd q"
  1916   shows "m dvd n + q \<longleftrightarrow> m dvd n"
  1917   using assms by (simp add: dvd_plus_eq_right add_commute [of n])
  1918 
  1919 lemma less_eq_dvd_minus:
  1920   fixes m n :: nat
  1921   assumes "m \<le> n"
  1922   shows "m dvd n \<longleftrightarrow> m dvd n - m"
  1923 proof -
  1924   from assms have "n = m + (n - m)" by simp
  1925   then obtain q where "n = m + q" ..
  1926   then show ?thesis by (simp add: dvd_reduce add_commute [of m])
  1927 qed
  1928 
  1929 lemma dvd_minus_self:
  1930   fixes m n :: nat
  1931   shows "m dvd n - m \<longleftrightarrow> n < m \<or> m dvd n"
  1932   by (cases "n < m") (auto elim!: dvdE simp add: not_less le_imp_diff_is_add)
  1933 
  1934 lemma dvd_minus_add:
  1935   fixes m n q r :: nat
  1936   assumes "q \<le> n" "q \<le> r * m"
  1937   shows "m dvd n - q \<longleftrightarrow> m dvd n + (r * m - q)"
  1938 proof -
  1939   have "m dvd n - q \<longleftrightarrow> m dvd r * m + (n - q)"
  1940     by (auto elim: dvd_plusE)
  1941   also from assms have "\<dots> \<longleftrightarrow> m dvd r * m + n - q" by simp
  1942   also from assms have "\<dots> \<longleftrightarrow> m dvd (r * m - q) + n" by simp
  1943   also have "\<dots> \<longleftrightarrow> m dvd n + (r * m - q)" by (simp add: add_commute)
  1944   finally show ?thesis .
  1945 qed
  1946 
  1947 
  1948 subsection {* aliases *}
  1949 
  1950 lemma nat_mult_1: "(1::nat) * n = n"
  1951   by (rule mult_1_left)
  1952  
  1953 lemma nat_mult_1_right: "n * (1::nat) = n"
  1954   by (rule mult_1_right)
  1955 
  1956 
  1957 subsection {* size of a datatype value *}
  1958 
  1959 class size =
  1960   fixes size :: "'a \<Rightarrow> nat" -- {* see further theory @{text Wellfounded} *}
  1961 
  1962 
  1963 subsection {* code module namespace *}
  1964 
  1965 code_identifier
  1966   code_module Nat \<rightharpoonup> (SML) Arith and (OCaml) Arith and (Haskell) Arith
  1967 
  1968 hide_const (open) of_nat_aux
  1969 
  1970 end