src/HOL/Library/FuncSet.thy
author wenzelm
Mon Aug 22 20:11:44 2011 +0200 (2011-08-22)
changeset 44382 9afa4a0e6f3c
parent 40631 b3f85ba3dae4
child 47761 dfe747e72fa8
permissions -rw-r--r--
reduced warnings;
     1 (*  Title:      HOL/Library/FuncSet.thy
     2     Author:     Florian Kammueller and Lawrence C Paulson, Lukas Bulwahn
     3 *)
     4 
     5 header {* Pi and Function Sets *}
     6 
     7 theory FuncSet
     8 imports Hilbert_Choice Main
     9 begin
    10 
    11 definition
    12   Pi :: "['a set, 'a => 'b set] => ('a => 'b) set" where
    13   "Pi A B = {f. \<forall>x. x \<in> A --> f x \<in> B x}"
    14 
    15 definition
    16   extensional :: "'a set => ('a => 'b) set" where
    17   "extensional A = {f. \<forall>x. x~:A --> f x = undefined}"
    18 
    19 definition
    20   "restrict" :: "['a => 'b, 'a set] => ('a => 'b)" where
    21   "restrict f A = (%x. if x \<in> A then f x else undefined)"
    22 
    23 abbreviation
    24   funcset :: "['a set, 'b set] => ('a => 'b) set"
    25     (infixr "->" 60) where
    26   "A -> B == Pi A (%_. B)"
    27 
    28 notation (xsymbols)
    29   funcset  (infixr "\<rightarrow>" 60)
    30 
    31 syntax
    32   "_Pi"  :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3PI _:_./ _)" 10)
    33   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3%_:_./ _)" [0,0,3] 3)
    34 
    35 syntax (xsymbols)
    36   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    37   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    38 
    39 syntax (HTML output)
    40   "_Pi" :: "[pttrn, 'a set, 'b set] => ('a => 'b) set"  ("(3\<Pi> _\<in>_./ _)"   10)
    41   "_lam" :: "[pttrn, 'a set, 'a => 'b] => ('a=>'b)"  ("(3\<lambda>_\<in>_./ _)" [0,0,3] 3)
    42 
    43 translations
    44   "PI x:A. B" == "CONST Pi A (%x. B)"
    45   "%x:A. f" == "CONST restrict (%x. f) A"
    46 
    47 definition
    48   "compose" :: "['a set, 'b => 'c, 'a => 'b] => ('a => 'c)" where
    49   "compose A g f = (\<lambda>x\<in>A. g (f x))"
    50 
    51 
    52 subsection{*Basic Properties of @{term Pi}*}
    53 
    54 lemma Pi_I[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> f \<in> Pi A B"
    55   by (simp add: Pi_def)
    56 
    57 lemma Pi_I'[simp]: "(!!x. x : A --> f x : B x) ==> f : Pi A B"
    58 by(simp add:Pi_def)
    59 
    60 lemma funcsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f \<in> A -> B"
    61   by (simp add: Pi_def)
    62 
    63 lemma Pi_mem: "[|f: Pi A B; x \<in> A|] ==> f x \<in> B x"
    64   by (simp add: Pi_def)
    65 
    66 lemma PiE [elim]:
    67   "f : Pi A B ==> (f x : B x ==> Q) ==> (x ~: A ==> Q) ==> Q"
    68 by(auto simp: Pi_def)
    69 
    70 lemma Pi_cong:
    71   "(\<And> w. w \<in> A \<Longrightarrow> f w = g w) \<Longrightarrow> f \<in> Pi A B \<longleftrightarrow> g \<in> Pi A B"
    72   by (auto simp: Pi_def)
    73 
    74 lemma funcset_id [simp]: "(\<lambda>x. x) \<in> A \<rightarrow> A"
    75   by auto
    76 
    77 lemma funcset_mem: "[|f \<in> A -> B; x \<in> A|] ==> f x \<in> B"
    78   by (simp add: Pi_def)
    79 
    80 lemma funcset_image: "f \<in> A\<rightarrow>B ==> f ` A \<subseteq> B"
    81 by auto
    82 
    83 lemma Pi_eq_empty[simp]: "((PI x: A. B x) = {}) = (\<exists>x\<in>A. B(x) = {})"
    84 apply (simp add: Pi_def, auto)
    85 txt{*Converse direction requires Axiom of Choice to exhibit a function
    86 picking an element from each non-empty @{term "B x"}*}
    87 apply (drule_tac x = "%u. SOME y. y \<in> B u" in spec, auto)
    88 apply (cut_tac P= "%y. y \<in> B x" in some_eq_ex, auto)
    89 done
    90 
    91 lemma Pi_empty [simp]: "Pi {} B = UNIV"
    92 by (simp add: Pi_def)
    93 
    94 lemma Pi_UNIV [simp]: "A -> UNIV = UNIV"
    95 by (simp add: Pi_def)
    96 (*
    97 lemma funcset_id [simp]: "(%x. x): A -> A"
    98   by (simp add: Pi_def)
    99 *)
   100 text{*Covariance of Pi-sets in their second argument*}
   101 lemma Pi_mono: "(!!x. x \<in> A ==> B x <= C x) ==> Pi A B <= Pi A C"
   102 by auto
   103 
   104 text{*Contravariance of Pi-sets in their first argument*}
   105 lemma Pi_anti_mono: "A' <= A ==> Pi A B <= Pi A' B"
   106 by auto
   107 
   108 lemma prod_final:
   109   assumes 1: "fst \<circ> f \<in> Pi A B" and 2: "snd \<circ> f \<in> Pi A C"
   110   shows "f \<in> (\<Pi> z \<in> A. B z \<times> C z)"
   111 proof (rule Pi_I) 
   112   fix z
   113   assume z: "z \<in> A" 
   114   have "f z = (fst (f z), snd (f z))" 
   115     by simp
   116   also have "...  \<in> B z \<times> C z"
   117     by (metis SigmaI PiE o_apply 1 2 z) 
   118   finally show "f z \<in> B z \<times> C z" .
   119 qed
   120 
   121 
   122 subsection{*Composition With a Restricted Domain: @{term compose}*}
   123 
   124 lemma funcset_compose:
   125   "[| f \<in> A -> B; g \<in> B -> C |]==> compose A g f \<in> A -> C"
   126 by (simp add: Pi_def compose_def restrict_def)
   127 
   128 lemma compose_assoc:
   129     "[| f \<in> A -> B; g \<in> B -> C; h \<in> C -> D |]
   130       ==> compose A h (compose A g f) = compose A (compose B h g) f"
   131 by (simp add: fun_eq_iff Pi_def compose_def restrict_def)
   132 
   133 lemma compose_eq: "x \<in> A ==> compose A g f x = g(f(x))"
   134 by (simp add: compose_def restrict_def)
   135 
   136 lemma surj_compose: "[| f ` A = B; g ` B = C |] ==> compose A g f ` A = C"
   137   by (auto simp add: image_def compose_eq)
   138 
   139 
   140 subsection{*Bounded Abstraction: @{term restrict}*}
   141 
   142 lemma restrict_in_funcset: "(!!x. x \<in> A ==> f x \<in> B) ==> (\<lambda>x\<in>A. f x) \<in> A -> B"
   143   by (simp add: Pi_def restrict_def)
   144 
   145 lemma restrictI[intro!]: "(!!x. x \<in> A ==> f x \<in> B x) ==> (\<lambda>x\<in>A. f x) \<in> Pi A B"
   146   by (simp add: Pi_def restrict_def)
   147 
   148 lemma restrict_apply [simp]:
   149     "(\<lambda>y\<in>A. f y) x = (if x \<in> A then f x else undefined)"
   150   by (simp add: restrict_def)
   151 
   152 lemma restrict_ext:
   153     "(!!x. x \<in> A ==> f x = g x) ==> (\<lambda>x\<in>A. f x) = (\<lambda>x\<in>A. g x)"
   154   by (simp add: fun_eq_iff Pi_def restrict_def)
   155 
   156 lemma inj_on_restrict_eq [simp]: "inj_on (restrict f A) A = inj_on f A"
   157   by (simp add: inj_on_def restrict_def)
   158 
   159 lemma Id_compose:
   160     "[|f \<in> A -> B;  f \<in> extensional A|] ==> compose A (\<lambda>y\<in>B. y) f = f"
   161   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   162 
   163 lemma compose_Id:
   164     "[|g \<in> A -> B;  g \<in> extensional A|] ==> compose A g (\<lambda>x\<in>A. x) = g"
   165   by (auto simp add: fun_eq_iff compose_def extensional_def Pi_def)
   166 
   167 lemma image_restrict_eq [simp]: "(restrict f A) ` A = f ` A"
   168   by (auto simp add: restrict_def)
   169 
   170 
   171 subsection{*Bijections Between Sets*}
   172 
   173 text{*The definition of @{const bij_betw} is in @{text "Fun.thy"}, but most of
   174 the theorems belong here, or need at least @{term Hilbert_Choice}.*}
   175 
   176 lemma bij_betwI:
   177 assumes "f \<in> A \<rightarrow> B" and "g \<in> B \<rightarrow> A"
   178     and g_f: "\<And>x. x\<in>A \<Longrightarrow> g (f x) = x" and f_g: "\<And>y. y\<in>B \<Longrightarrow> f (g y) = y"
   179 shows "bij_betw f A B"
   180 unfolding bij_betw_def
   181 proof
   182   show "inj_on f A" by (metis g_f inj_on_def)
   183 next
   184   have "f ` A \<subseteq> B" using `f \<in> A \<rightarrow> B` by auto
   185   moreover
   186   have "B \<subseteq> f ` A" by auto (metis Pi_mem `g \<in> B \<rightarrow> A` f_g image_iff)
   187   ultimately show "f ` A = B" by blast
   188 qed
   189 
   190 lemma bij_betw_imp_funcset: "bij_betw f A B \<Longrightarrow> f \<in> A \<rightarrow> B"
   191 by (auto simp add: bij_betw_def)
   192 
   193 lemma inj_on_compose:
   194   "[| bij_betw f A B; inj_on g B |] ==> inj_on (compose A g f) A"
   195 by (auto simp add: bij_betw_def inj_on_def compose_eq)
   196 
   197 lemma bij_betw_compose:
   198   "[| bij_betw f A B; bij_betw g B C |] ==> bij_betw (compose A g f) A C"
   199 apply (simp add: bij_betw_def compose_eq inj_on_compose)
   200 apply (auto simp add: compose_def image_def)
   201 done
   202 
   203 lemma bij_betw_restrict_eq [simp]:
   204   "bij_betw (restrict f A) A B = bij_betw f A B"
   205 by (simp add: bij_betw_def)
   206 
   207 
   208 subsection{*Extensionality*}
   209 
   210 lemma extensional_arb: "[|f \<in> extensional A; x\<notin> A|] ==> f x = undefined"
   211 by (simp add: extensional_def)
   212 
   213 lemma restrict_extensional [simp]: "restrict f A \<in> extensional A"
   214 by (simp add: restrict_def extensional_def)
   215 
   216 lemma compose_extensional [simp]: "compose A f g \<in> extensional A"
   217 by (simp add: compose_def)
   218 
   219 lemma extensionalityI:
   220   "[| f \<in> extensional A; g \<in> extensional A;
   221       !!x. x\<in>A ==> f x = g x |] ==> f = g"
   222 by (force simp add: fun_eq_iff extensional_def)
   223 
   224 lemma extensional_restrict:  "f \<in> extensional A \<Longrightarrow> restrict f A = f"
   225 by(rule extensionalityI[OF restrict_extensional]) auto
   226 
   227 lemma inv_into_funcset: "f ` A = B ==> (\<lambda>x\<in>B. inv_into A f x) : B -> A"
   228 by (unfold inv_into_def) (fast intro: someI2)
   229 
   230 lemma compose_inv_into_id:
   231   "bij_betw f A B ==> compose A (\<lambda>y\<in>B. inv_into A f y) f = (\<lambda>x\<in>A. x)"
   232 apply (simp add: bij_betw_def compose_def)
   233 apply (rule restrict_ext, auto)
   234 done
   235 
   236 lemma compose_id_inv_into:
   237   "f ` A = B ==> compose B f (\<lambda>y\<in>B. inv_into A f y) = (\<lambda>x\<in>B. x)"
   238 apply (simp add: compose_def)
   239 apply (rule restrict_ext)
   240 apply (simp add: f_inv_into_f)
   241 done
   242 
   243 
   244 subsection{*Cardinality*}
   245 
   246 lemma card_inj: "[|f \<in> A\<rightarrow>B; inj_on f A; finite B|] ==> card(A) \<le> card(B)"
   247 by (rule card_inj_on_le) auto
   248 
   249 lemma card_bij:
   250   "[|f \<in> A\<rightarrow>B; inj_on f A;
   251      g \<in> B\<rightarrow>A; inj_on g B; finite A; finite B|] ==> card(A) = card(B)"
   252 by (blast intro: card_inj order_antisym)
   253 
   254 subsection {* Extensional Function Spaces *} 
   255 
   256 definition extensional_funcset
   257 where "extensional_funcset S T = (S -> T) \<inter> (extensional S)"
   258 
   259 lemma extensional_empty[simp]: "extensional {} = {%x. undefined}"
   260 unfolding extensional_def by auto
   261 
   262 lemma extensional_funcset_empty_domain: "extensional_funcset {} T = {%x. undefined}"
   263 unfolding extensional_funcset_def by simp
   264 
   265 lemma extensional_funcset_empty_range:
   266   assumes "S \<noteq> {}"
   267   shows "extensional_funcset S {} = {}"
   268 using assms unfolding extensional_funcset_def by auto
   269 
   270 lemma extensional_funcset_arb:
   271   assumes "f \<in> extensional_funcset S T" "x \<notin> S"
   272   shows "f x = undefined"
   273 using assms
   274 unfolding extensional_funcset_def by auto (auto dest!: extensional_arb)
   275 
   276 lemma extensional_funcset_mem: "f \<in> extensional_funcset S T \<Longrightarrow> x \<in> S \<Longrightarrow> f x \<in> T"
   277 unfolding extensional_funcset_def by auto
   278 
   279 lemma extensional_subset: "f : extensional A ==> A <= B ==> f : extensional B"
   280 unfolding extensional_def by auto
   281 
   282 lemma extensional_funcset_extend_domainI: "\<lbrakk> y \<in> T; f \<in> extensional_funcset S T\<rbrakk> \<Longrightarrow> f(x := y) \<in> extensional_funcset (insert x S) T"
   283 unfolding extensional_funcset_def extensional_def by auto
   284 
   285 lemma extensional_funcset_restrict_domain:
   286   "x \<notin> S \<Longrightarrow> f \<in> extensional_funcset (insert x S) T \<Longrightarrow> f(x := undefined) \<in> extensional_funcset S T"
   287 unfolding extensional_funcset_def extensional_def by auto
   288 
   289 lemma extensional_funcset_extend_domain_eq:
   290   assumes "x \<notin> S"
   291   shows
   292     "extensional_funcset (insert x S) T = (\<lambda>(y, g). g(x := y)) ` {(y, g). y \<in> T \<and> g \<in> extensional_funcset S T}"
   293   using assms
   294 proof -
   295   {
   296     fix f
   297     assume "f : extensional_funcset (insert x S) T"
   298     from this assms have "f : (%(y, g). g(x := y)) ` (T <*> extensional_funcset S T)"
   299       unfolding image_iff
   300       apply (rule_tac x="(f x, f(x := undefined))" in bexI)
   301     apply (auto intro: extensional_funcset_extend_domainI extensional_funcset_restrict_domain extensional_funcset_mem) done 
   302   }
   303   moreover
   304   {
   305     fix f
   306     assume "f : (%(y, g). g(x := y)) ` (T <*> extensional_funcset S T)"
   307     from this assms have "f : extensional_funcset (insert x S) T"
   308       by (auto intro: extensional_funcset_extend_domainI)
   309   }
   310   ultimately show ?thesis by auto
   311 qed
   312 
   313 lemma extensional_funcset_fun_upd_restricts_rangeI:  "\<forall> y \<in> S. f x \<noteq> f y ==> f : extensional_funcset (insert x S) T ==> f(x := undefined) : extensional_funcset S (T - {f x})"
   314 unfolding extensional_funcset_def extensional_def
   315 apply auto
   316 apply (case_tac "x = xa")
   317 apply auto done
   318 
   319 lemma extensional_funcset_fun_upd_extends_rangeI:
   320   assumes "a \<in> T" "f : extensional_funcset S (T - {a})"
   321   shows "f(x := a) : extensional_funcset (insert x S) T"
   322   using assms unfolding extensional_funcset_def extensional_def by auto
   323 
   324 subsubsection {* Injective Extensional Function Spaces *}
   325 
   326 lemma extensional_funcset_fun_upd_inj_onI:
   327   assumes "f \<in> extensional_funcset S (T - {a})" "inj_on f S"
   328   shows "inj_on (f(x := a)) S"
   329   using assms unfolding extensional_funcset_def by (auto intro!: inj_on_fun_updI)
   330 
   331 lemma extensional_funcset_extend_domain_inj_on_eq:
   332   assumes "x \<notin> S"
   333   shows"{f. f \<in> extensional_funcset (insert x S) T \<and> inj_on f (insert x S)} =
   334     (%(y, g). g(x:=y)) ` {(y, g). y \<in> T \<and> g \<in> extensional_funcset S (T - {y}) \<and> inj_on g S}"
   335 proof -
   336   from assms show ?thesis
   337     apply auto
   338     apply (auto intro: extensional_funcset_fun_upd_inj_onI extensional_funcset_fun_upd_extends_rangeI)
   339     apply (auto simp add: image_iff inj_on_def)
   340     apply (rule_tac x="xa x" in exI)
   341     apply (auto intro: extensional_funcset_mem)
   342     apply (rule_tac x="xa(x := undefined)" in exI)
   343     apply (auto intro!: extensional_funcset_fun_upd_restricts_rangeI)
   344     apply (auto dest!: extensional_funcset_mem split: split_if_asm)
   345     done
   346 qed
   347 
   348 lemma extensional_funcset_extend_domain_inj_onI:
   349   assumes "x \<notin> S"
   350   shows "inj_on (\<lambda>(y, g). g(x := y)) {(y, g). y \<in> T \<and> g \<in> extensional_funcset S (T - {y}) \<and> inj_on g S}"
   351 proof -
   352   from assms show ?thesis
   353     apply (auto intro!: inj_onI)
   354     apply (metis fun_upd_same)
   355     by (metis assms extensional_funcset_arb fun_upd_triv fun_upd_upd)
   356 qed
   357   
   358 
   359 subsubsection {* Cardinality *}
   360 
   361 lemma card_extensional_funcset:
   362   assumes "finite S"
   363   shows "card (extensional_funcset S T) = (card T) ^ (card S)"
   364 using assms
   365 proof (induct rule: finite_induct)
   366   case empty
   367   show ?case
   368     by (auto simp add: extensional_funcset_empty_domain)
   369 next
   370   case (insert x S)
   371   {
   372     fix g g' y y'
   373     assume assms: "g \<in> extensional_funcset S T"
   374       "g' \<in> extensional_funcset S T"
   375       "y \<in> T" "y' \<in> T"
   376       "g(x := y) = g'(x := y')"
   377     from this have "y = y'"
   378       by (metis fun_upd_same)
   379     have "g = g'"
   380       by (metis assms(1) assms(2) assms(5) extensional_funcset_arb fun_upd_triv fun_upd_upd insert(2))
   381   from `y = y'` `g = g'` have "y = y' & g = g'" by simp
   382   }
   383   from this have "inj_on (\<lambda>(y, g). g (x := y)) (T \<times> extensional_funcset S T)"
   384     by (auto intro: inj_onI)
   385   from this insert.hyps show ?case
   386     by (simp add: extensional_funcset_extend_domain_eq card_image card_cartesian_product)
   387 qed
   388 
   389 lemma finite_extensional_funcset:
   390   assumes "finite S" "finite T"
   391   shows "finite (extensional_funcset S T)"
   392 proof -
   393   from card_extensional_funcset[OF assms(1), of T] assms(2)
   394   have "(card (extensional_funcset S T) \<noteq> 0) \<or> (S \<noteq> {} \<and> T = {})"
   395     by auto
   396   from this show ?thesis
   397   proof
   398     assume "card (extensional_funcset S T) \<noteq> 0"
   399     from this show ?thesis
   400       by (auto intro: card_ge_0_finite)
   401   next
   402     assume "S \<noteq> {} \<and> T = {}"
   403     from this show ?thesis
   404       by (auto simp add: extensional_funcset_empty_range)
   405   qed
   406 qed
   407 
   408 end