src/Pure/sign.ML
author clasohm
Fri Jul 07 13:57:24 1995 +0200 (1995-07-07)
changeset 1180 9b2efb601898
parent 1178 b28c6ecc3e6d
child 1214 3f3888213ceb
permissions -rw-r--r--
moved mixfix syntax to Syntax/mixfix.ML
     1 (*  Title:      Pure/sign.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4 
     5 The abstract type "sg" of signatures.
     6 *)
     7 
     8 signature SIGN =
     9 sig
    10   structure Symtab: SYMTAB
    11   structure Syntax: SYNTAX
    12   structure Type: TYPE
    13   sharing Symtab = Type.Symtab
    14   local open Type Syntax in
    15     type sg
    16     val rep_sg: sg ->
    17       {tsig: type_sig,
    18        const_tab: typ Symtab.table,
    19        syn: syntax,
    20        stamps: string ref list}
    21     val subsig: sg * sg -> bool
    22     val eq_sg: sg * sg -> bool
    23     val is_draft: sg -> bool
    24     val const_type: sg -> string -> typ option
    25     val classes: sg -> class list
    26     val subsort: sg -> sort * sort -> bool
    27     val norm_sort: sg -> sort -> sort
    28     val print_sg: sg -> unit
    29     val pretty_sg: sg -> Pretty.T
    30     val pprint_sg: sg -> pprint_args -> unit
    31     val pretty_term: sg -> term -> Pretty.T
    32     val pretty_typ: sg -> typ -> Pretty.T
    33     val pretty_sort: sort -> Pretty.T
    34     val string_of_term: sg -> term -> string
    35     val string_of_typ: sg -> typ -> string
    36     val pprint_term: sg -> term -> pprint_args -> unit
    37     val pprint_typ: sg -> typ -> pprint_args -> unit
    38     val certify_typ: sg -> typ -> typ
    39     val certify_term: sg -> term -> term * typ * int
    40     val read_typ: sg * (indexname -> sort option) -> string -> typ
    41     val infer_types: sg -> (indexname -> typ option) ->
    42       (indexname -> sort option) -> string list -> bool
    43       -> term list * typ -> int * term * (indexname * typ) list
    44     val add_classes: (class * class list) list -> sg -> sg
    45     val add_classrel: (class * class) list -> sg -> sg
    46     val add_defsort: sort -> sg -> sg
    47     val add_types: (string * int * mixfix) list -> sg -> sg
    48     val add_tyabbrs: (string * string list * string * mixfix) list -> sg -> sg
    49     val add_tyabbrs_i: (string * string list * typ * mixfix) list -> sg -> sg
    50     val add_arities: (string * sort list * sort) list -> sg -> sg
    51     val add_consts: (string * string * mixfix) list -> sg -> sg
    52     val add_consts_i: (string * typ * mixfix) list -> sg -> sg
    53     val add_syntax: (string * string * mixfix) list -> sg -> sg
    54     val add_syntax_i: (string * typ * mixfix) list -> sg -> sg
    55     val add_trfuns:
    56       (string * (ast list -> ast)) list *
    57       (string * (term list -> term)) list *
    58       (string * (term list -> term)) list *
    59       (string * (ast list -> ast)) list -> sg -> sg
    60     val add_trrules: (string * string) trrule list -> sg -> sg
    61     val add_trrules_i: ast trrule list -> sg -> sg
    62     val add_name: string -> sg -> sg
    63     val make_draft: sg -> sg
    64     val merge: sg * sg -> sg
    65     val proto_pure: sg
    66     val pure: sg
    67     val cpure: sg
    68     val const_of_class: class -> string
    69     val class_of_const: string -> class
    70   end
    71 end;
    72 
    73 functor SignFun(structure Syntax: SYNTAX and Type: TYPE): SIGN =
    74 struct
    75 
    76 structure Symtab = Type.Symtab;
    77 structure Syntax = Syntax;
    78 structure BasicSyntax: BASIC_SYNTAX = Syntax;
    79 structure Pretty = Syntax.Pretty;
    80 structure Type = Type;
    81 open BasicSyntax Type;
    82 
    83 
    84 (** datatype sg **)
    85 
    86 (*the "ref" in stamps ensures that no two signatures are identical -- it is
    87   impossible to forge a signature*)
    88 
    89 datatype sg =
    90   Sg of {
    91     tsig: type_sig,                 (*order-sorted signature of types*)
    92     const_tab: typ Symtab.table,    (*types of constants*)
    93     syn: Syntax.syntax,             (*syntax for parsing and printing*)
    94     stamps: string ref list};       (*unique theory indentifier*)
    95 
    96 fun rep_sg (Sg args) = args;
    97 val tsig_of = #tsig o rep_sg;
    98 
    99 
   100 (* stamps *)
   101 
   102 fun is_draft (Sg {stamps = ref "#" :: _, ...}) = true
   103   | is_draft _ = false;
   104 
   105 fun subsig (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) = s1 subset s2;
   106 
   107 fun eq_sg (Sg {stamps = s1, ...}, Sg {stamps = s2, ...}) = eq_set (s1, s2);
   108 
   109 
   110 (* consts *)
   111 
   112 fun const_type (Sg {const_tab, ...}) c =
   113   Symtab.lookup (const_tab, c);
   114 
   115 
   116 (* classes and sorts *)
   117 
   118 val classes = #classes o Type.rep_tsig o tsig_of;
   119 
   120 val subsort = Type.subsort o tsig_of;
   121 val norm_sort = Type.norm_sort o tsig_of;
   122 
   123 fun pretty_sort [c] = Pretty.str c
   124   | pretty_sort cs = Pretty.str_list "{" "}" cs;
   125 
   126 
   127 
   128 (** print signature **)
   129 
   130 val stamp_names = rev o map !;
   131 
   132 fun print_sg sg =
   133   let
   134     fun prt_typ syn ty = Pretty.quote (Syntax.pretty_typ syn ty);
   135 
   136     fun pretty_subclass (cl, cls) = Pretty.block
   137       [Pretty.str (cl ^ " <"), Pretty.brk 1, pretty_sort cls];
   138 
   139     fun pretty_default cls = Pretty.block
   140       [Pretty.str "default:", Pretty.brk 1, pretty_sort cls];
   141 
   142     fun pretty_ty (ty, n) = Pretty.str (ty ^ " " ^ string_of_int n);
   143 
   144     fun pretty_abbr syn (ty, (vs, rhs)) = Pretty.block
   145       [prt_typ syn (Type (ty, map (fn v => TVar ((v, 0), [])) vs)),
   146         Pretty.str " =", Pretty.brk 1, prt_typ syn rhs];
   147 
   148     fun pretty_arity ty (cl, []) = Pretty.block
   149           [Pretty.str (ty ^ " ::"), Pretty.brk 1, Pretty.str cl]
   150       | pretty_arity ty (cl, srts) = Pretty.block
   151           [Pretty.str (ty ^ " ::"), Pretty.brk 1,
   152             Pretty.list "(" ")" (map pretty_sort srts),
   153             Pretty.brk 1, Pretty.str cl];
   154 
   155     fun pretty_arities (ty, ars) = map (pretty_arity ty) ars;
   156 
   157     fun pretty_const syn (c, ty) = Pretty.block
   158       [Pretty.str (quote c ^ " ::"), Pretty.brk 1, prt_typ syn ty];
   159 
   160 
   161     val Sg {tsig, const_tab, syn, stamps} = sg;
   162     val {classes, subclass, default, tycons, abbrs, arities} = rep_tsig tsig;
   163   in
   164     Pretty.writeln (Pretty.strs ("stamps:" :: stamp_names stamps));
   165     Pretty.writeln (Pretty.strs ("classes:" :: classes));
   166     Pretty.writeln (Pretty.big_list "subclass:"
   167                       (map pretty_subclass subclass));
   168     Pretty.writeln (pretty_default default);
   169     Pretty.writeln (Pretty.big_list "types:" (map pretty_ty tycons));
   170     Pretty.writeln (Pretty.big_list "abbrs:" (map (pretty_abbr syn) abbrs));
   171     Pretty.writeln (Pretty.big_list "arities:"
   172                       (flat (map pretty_arities arities)));
   173     Pretty.writeln (Pretty.big_list "consts:"
   174                       (map (pretty_const syn) (Symtab.dest const_tab)))
   175   end;
   176 
   177 
   178 fun pretty_sg (Sg {stamps, ...}) =
   179   Pretty.str_list "{" "}" (stamp_names stamps);
   180 
   181 val pprint_sg = Pretty.pprint o pretty_sg;
   182 
   183 
   184 
   185 (** pretty printing of terms and types **)
   186 
   187 fun pretty_term (Sg {syn, stamps, ...}) =
   188   let val curried = "CPure" mem (map ! stamps);
   189   in Syntax.pretty_term curried syn end;
   190 
   191 fun pretty_typ (Sg {syn, ...}) = Syntax.pretty_typ syn;
   192 
   193 fun string_of_term (Sg {syn, stamps, ...}) = 
   194   let val curried = "CPure" mem (map ! stamps);
   195   in Syntax.string_of_term curried syn end;
   196 
   197 fun string_of_typ (Sg {syn, ...}) = Syntax.string_of_typ syn;
   198 
   199 fun pprint_term sg = Pretty.pprint o Pretty.quote o (pretty_term sg);
   200 fun pprint_typ sg = Pretty.pprint o Pretty.quote o (pretty_typ sg);
   201 
   202 
   203 
   204 (** read types **)  (*exception ERROR*)
   205 
   206 fun err_in_type s =
   207   error ("The error(s) above occurred in type " ^ quote s);
   208 
   209 fun read_raw_typ syn tsig sort_of str =
   210   Syntax.read_typ syn (fn x => if_none (sort_of x) (defaultS tsig)) str
   211     handle ERROR => err_in_type str;
   212 
   213 (*read and certify typ wrt a signature*)
   214 fun read_typ (Sg {tsig, syn, ...}, sort_of) str =
   215   cert_typ tsig (read_raw_typ syn tsig sort_of str)
   216     handle TYPE (msg, _, _) => (writeln msg; err_in_type str);
   217 
   218 
   219 
   220 (** certify types and terms **)   (*exception TYPE*)
   221 
   222 fun certify_typ (Sg {tsig, ...}) ty = cert_typ tsig ty;
   223 
   224 
   225 fun mapfilt_atoms f (Abs (_, _, t)) = mapfilt_atoms f t
   226   | mapfilt_atoms f (t $ u) = mapfilt_atoms f t @ mapfilt_atoms f u
   227   | mapfilt_atoms f a = (case f a of Some y => [y] | None => []);
   228 
   229 fun certify_term (sg as Sg {tsig, ...}) tm =
   230   let
   231     fun valid_const a T =
   232       (case const_type sg a of
   233         Some U => typ_instance (tsig, T, U)
   234       | _ => false);
   235 
   236     fun atom_err (Const (a, T)) =
   237           if valid_const a T then None
   238           else Some ("Illegal type for constant " ^ quote a ^ " :: " ^
   239             quote (string_of_typ sg T))
   240       | atom_err (Var ((x, i), _)) =
   241           if i < 0 then Some ("Negative index for Var " ^ quote x) else None
   242       | atom_err _ = None;
   243 
   244     val norm_tm =
   245       (case it_term_types (typ_errors tsig) (tm, []) of
   246         [] => map_term_types (norm_typ tsig) tm
   247       | errs => raise_type (cat_lines errs) [] [tm]);
   248   in
   249     (case mapfilt_atoms atom_err norm_tm of
   250       [] => (norm_tm, type_of norm_tm, maxidx_of_term norm_tm)
   251     | errs => raise_type (cat_lines errs) [] [norm_tm])
   252   end;
   253 
   254 
   255 
   256 (** infer_types **)         (*exception ERROR*)
   257 
   258 fun infer_types sg types sorts used freeze (ts, T) =
   259   let
   260     val Sg {tsig, ...} = sg;
   261     val show_typ = string_of_typ sg;
   262     val show_term = string_of_term sg;
   263 
   264     fun term_err [] = ""
   265       | term_err [t] = "\nInvolving this term:\n" ^ show_term t
   266       | term_err ts = 
   267           "\nInvolving these terms:\n" ^ cat_lines (map show_term ts);
   268 
   269     fun exn_type_msg (msg, Ts, ts) =
   270 	"\nType checking error: " ^ msg ^ "\n" ^
   271 	cat_lines (map show_typ Ts) ^ term_err ts ^ "\n";
   272 
   273     val T' = certify_typ sg T
   274              handle TYPE arg => error (exn_type_msg arg);
   275 
   276     val ct = const_type sg;
   277 
   278     fun warn() =
   279       if length ts > 1 andalso length ts <= !Syntax.ambiguity_level
   280       then (*no warning shown yet*)
   281            writeln "Warning: Currently parsed input \
   282                    \produces more than one parse tree.\n\
   283                    \For more information lower Syntax.ambiguity_level."
   284       else ();
   285 
   286     datatype result = One of int * term * (indexname * typ) list
   287                     | Errs of (string * typ list * term list)list
   288                     | Ambigs of term list;
   289 
   290     fun process_term(res,(t,i)) =
   291        let val (u,tye) = Type.infer_types(tsig,ct,types,sorts,used,freeze,T',t)
   292        in case res of
   293             One(_,t0,_) => Ambigs([u,t0])
   294           | Errs _ => One(i,u,tye)
   295           | Ambigs(us) => Ambigs(u::us)
   296        end
   297        handle TYPE arg => (case res of Errs(errs) => Errs(arg::errs)
   298                                      | _ => res);
   299 
   300   in case foldl process_term (Errs[], ts ~~ (0 upto (length ts - 1))) of
   301        One(res) =>
   302          (if length ts > !Syntax.ambiguity_level
   303           then writeln "Fortunately, only one parse tree is type correct.\n\
   304             \It helps (speed!) if you disambiguate your grammar or your input."
   305           else ();
   306           res)
   307      | Errs(errs) => (warn(); error(cat_lines(map exn_type_msg errs)))
   308      | Ambigs(us) =>
   309          (warn();
   310           let val old_show_brackets = !show_brackets
   311               val dummy = show_brackets := true;
   312               val errs = cat_lines(map show_term us)
   313           in show_brackets := old_show_brackets;
   314              error("Error: More than one term is type correct:\n" ^ errs)
   315           end)
   316   end;
   317 
   318 
   319 (** extend signature **)    (*exception ERROR*)
   320 
   321 (** signature extension functions **)  (*exception ERROR*)
   322 
   323 fun decls_of name_of mfixs =
   324   map (fn (x, y, mx) => (name_of x mx, y)) mfixs;
   325 
   326 
   327 (* add default sort *)
   328 
   329 fun ext_defsort (syn, tsig, ctab) defsort =
   330   (syn, ext_tsig_defsort tsig defsort, ctab);
   331 
   332 
   333 (* add type constructors *)
   334 
   335 fun ext_types (syn, tsig, ctab) types =
   336   (Syntax.extend_type_gram syn types,
   337     ext_tsig_types tsig (decls_of Syntax.type_name types),
   338     ctab);
   339 
   340 
   341 (* add type abbreviations *)
   342 
   343 fun read_abbr syn tsig (t, vs, rhs_src) =
   344   (t, vs, read_raw_typ syn tsig (K None) rhs_src)
   345     handle ERROR => error ("in type abbreviation " ^ t);
   346 
   347 fun ext_abbrs rd_abbr (syn, tsig, ctab) abbrs =
   348   let
   349     fun mfix_of (t, vs, _, mx) = (t, length vs, mx);
   350     val syn1 = Syntax.extend_type_gram syn (map mfix_of abbrs);
   351 
   352     fun decl_of (t, vs, rhs, mx) =
   353       rd_abbr syn1 tsig (Syntax.type_name t mx, vs, rhs);
   354   in
   355     (syn1, ext_tsig_abbrs tsig (map decl_of abbrs), ctab)
   356   end;
   357 
   358 val ext_tyabbrs_i = ext_abbrs (K (K I));
   359 val ext_tyabbrs = ext_abbrs read_abbr;
   360 
   361 
   362 (* add type arities *)
   363 
   364 fun ext_arities (syn, tsig, ctab) arities =
   365   let
   366     val tsig1 = ext_tsig_arities tsig arities;
   367     val log_types = logical_types tsig1;
   368   in
   369     (Syntax.extend_log_types syn log_types, tsig1, ctab)
   370   end;
   371 
   372 
   373 (* add term constants and syntax *)
   374 
   375 fun err_in_const c =
   376   error ("in declaration of constant " ^ quote c);
   377 
   378 fun err_dup_consts cs =
   379   error ("Duplicate declaration of constant(s) " ^ commas_quote cs);
   380 
   381 
   382 fun read_const syn tsig (c, ty_src, mx) =
   383   (c, read_raw_typ syn tsig (K None) ty_src, mx)
   384     handle ERROR => err_in_const (Syntax.const_name c mx);
   385 
   386 fun ext_cnsts rd_const syn_only (syn, tsig, ctab) raw_consts =
   387   let
   388     fun prep_const (c, ty, mx) = (c, varifyT (cert_typ tsig (no_tvars ty)), mx)
   389       handle TYPE (msg, _, _) => (writeln msg; err_in_const (Syntax.const_name c mx));
   390 
   391     val consts = map (prep_const o rd_const syn tsig) raw_consts;
   392     val decls =
   393       if syn_only then []
   394       else filter_out (equal "" o fst) (decls_of Syntax.const_name consts);
   395   in
   396     (Syntax.extend_const_gram syn consts, tsig,
   397       Symtab.extend_new (ctab, decls)
   398         handle Symtab.DUPS cs => err_dup_consts cs)
   399   end;
   400 
   401 val ext_consts_i = ext_cnsts (K (K I)) false;
   402 val ext_consts = ext_cnsts read_const false;
   403 val ext_syntax_i = ext_cnsts (K (K I)) true;
   404 val ext_syntax = ext_cnsts read_const true;
   405 
   406 
   407 (* add type classes *)
   408 
   409 fun const_of_class c = c ^ "_class";
   410 
   411 fun class_of_const c_class =
   412   let
   413     val c = implode (take (size c_class - 6, explode c_class));
   414   in
   415     if const_of_class c = c_class then c
   416     else raise_term ("class_of_const: bad name " ^ quote c_class) []
   417   end;
   418 
   419 
   420 fun ext_classes (syn, tsig, ctab) classes =
   421   let
   422     val names = map fst classes;
   423     val consts =
   424       map (fn c => (const_of_class c, a_itselfT --> propT, NoSyn)) names;
   425   in
   426     ext_consts_i
   427       (Syntax.extend_consts syn names, ext_tsig_classes tsig classes, ctab)
   428       consts
   429   end;
   430 
   431 
   432 (* add to subclass relation *)
   433 
   434 fun ext_classrel (syn, tsig, ctab) pairs =
   435   (syn, ext_tsig_subclass tsig pairs, ctab);
   436 
   437 
   438 (* add to syntax *)
   439 
   440 fun ext_syn extfun (syn, tsig, ctab) args =
   441   (extfun syn args, tsig, ctab);
   442 
   443 
   444 (* build signature *)
   445 
   446 fun ext_stamps stamps name =
   447   let
   448     val stmps = (case stamps of ref "#" :: ss => ss | ss => ss);
   449   in
   450     if exists (equal name o !) stmps then
   451       error ("Theory already contains a " ^ quote name ^ " component")
   452     else ref name :: stmps
   453   end;
   454 
   455 fun make_sign (syn, tsig, ctab) stamps name =
   456   Sg {tsig = tsig, const_tab = ctab, syn = syn,
   457     stamps = ext_stamps stamps name};
   458 
   459 fun extend_sign extfun name decls (Sg {tsig, const_tab, syn, stamps}) =
   460   make_sign (extfun (syn, tsig, const_tab) decls) stamps name;
   461 
   462 
   463 (* the external interfaces *)
   464 
   465 val add_classes   = extend_sign ext_classes "#";
   466 val add_classrel  = extend_sign ext_classrel "#";
   467 val add_defsort   = extend_sign ext_defsort "#";
   468 val add_types     = extend_sign ext_types "#";
   469 val add_tyabbrs   = extend_sign ext_tyabbrs "#";
   470 val add_tyabbrs_i = extend_sign ext_tyabbrs_i "#";
   471 val add_arities   = extend_sign ext_arities "#";
   472 val add_consts    = extend_sign ext_consts "#";
   473 val add_consts_i  = extend_sign ext_consts_i "#";
   474 val add_syntax    = extend_sign ext_syntax "#";
   475 val add_syntax_i  = extend_sign ext_syntax_i "#";
   476 val add_trfuns    = extend_sign (ext_syn Syntax.extend_trfuns) "#";
   477 val add_trrules   = extend_sign (ext_syn Syntax.extend_trrules) "#";
   478 val add_trrules_i = extend_sign (ext_syn Syntax.extend_trrules_i) "#";
   479 
   480 fun add_name name sg = extend_sign K name () sg;
   481 val make_draft = add_name "#";
   482 
   483 
   484 
   485 (** merge signatures **)    (*exception TERM*) (*exception ERROR (* FIXME *)*)
   486 
   487 fun merge (sg1, sg2) =
   488   if subsig (sg2, sg1) then sg1
   489   else if subsig (sg1, sg2) then sg2
   490   else if is_draft sg1 orelse is_draft sg2 then
   491     raise_term "Illegal merge of draft signatures" []
   492   else
   493     (*neither is union already; must form union*)
   494     let
   495       val Sg {tsig = tsig1, const_tab = const_tab1, syn = syn1,
   496         stamps = stamps1} = sg1;
   497       val Sg {tsig = tsig2, const_tab = const_tab2, syn = syn2,
   498         stamps = stamps2} = sg2;
   499 
   500 
   501       val stamps = merge_rev_lists stamps1 stamps2;
   502       val _ =
   503         (case duplicates (stamp_names stamps) of
   504           [] => ()
   505         | dups => raise_term ("Attempt to merge different versions of theories "
   506             ^ commas_quote dups) []);
   507 
   508       val tsig = merge_tsigs (tsig1, tsig2);
   509 
   510       val const_tab = Symtab.merge (op =) (const_tab1, const_tab2)
   511         handle Symtab.DUPS cs =>
   512           raise_term ("Incompatible types for constant(s) " ^ commas_quote cs) [];
   513 
   514       val syn = Syntax.merge_syntaxes syn1 syn2;
   515     in
   516       Sg {tsig = tsig, const_tab = const_tab, syn = syn, stamps = stamps}
   517     end;
   518 
   519 
   520 
   521 (** the Pure signature **)
   522 
   523 val proto_pure =
   524   make_sign (Syntax.pure_syn, tsig0, Symtab.null) [] "#"
   525   |> add_types
   526    (("fun", 2, NoSyn) ::
   527     ("prop", 0, NoSyn) ::
   528     ("itself", 1, NoSyn) ::
   529     Syntax.pure_types)
   530   |> add_classes [(logicC, [])]
   531   |> add_defsort logicS
   532   |> add_arities
   533    [("fun", [logicS, logicS], logicS),
   534     ("prop", [], logicS),
   535     ("itself", [logicS], logicS)]
   536   |> add_syntax Syntax.pure_syntax
   537   |> add_trfuns Syntax.pure_trfuns
   538   |> add_consts
   539    [("==", "['a::{}, 'a] => prop", Mixfix ("(_ ==/ _)", [3, 2], 2)),
   540     ("=?=", "['a::{}, 'a] => prop", Mixfix ("(_ =?=/ _)", [3, 2], 2)),
   541     ("==>", "[prop, prop] => prop", Mixfix ("(_ ==>/ _)", [2, 1], 1)),
   542     ("all", "('a => prop) => prop", Binder ("!!", 0, 0)),
   543     ("TYPE", "'a itself", NoSyn)]
   544   |> add_name "ProtoPure";
   545 
   546 val pure = proto_pure
   547   |> add_syntax Syntax.pure_appl_syntax
   548   |> add_name "Pure";
   549 
   550 val cpure = proto_pure
   551   |> add_syntax Syntax.pure_applC_syntax
   552   |> add_name "CPure";
   553 
   554 end;