src/HOL/Auth/TLS.thy
author paulson
Tue Sep 08 15:17:11 1998 +0200 (1998-09-08)
changeset 5434 9b4bed3f394c
parent 5359 bd539b72d484
child 5653 204083e3f368
permissions -rw-r--r--
Got rid of not_Says_to_self and most uses of ~= in definitions and theorems
     1 (*  Title:      HOL/Auth/TLS
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson, Cambridge University Computer Laboratory
     4     Copyright   1997  University of Cambridge
     5 
     6 Inductive relation "tls" for the TLS (Transport Layer Security) protocol.
     7 This protocol is essentially the same as SSL 3.0.
     8 
     9 Abstracted from "The TLS Protocol, Version 1.0" by Tim Dierks and Christopher
    10 Allen, Transport Layer Security Working Group, 21 May 1997,
    11 INTERNET-DRAFT draft-ietf-tls-protocol-03.txt.  Section numbers below refer
    12 to that memo.
    13 
    14 An RSA cryptosystem is assumed, and X.509v3 certificates are abstracted down
    15 to the trivial form {A, publicKey(A)}privateKey(Server), where Server is a
    16 global signing authority.
    17 
    18 A is the client and B is the server, not to be confused with the constant
    19 Server, who is in charge of all public keys.
    20 
    21 The model assumes that no fraudulent certificates are present, but it does
    22 assume that some private keys are to the spy.
    23 
    24 REMARK.  The event "Notes A {|Agent B, Nonce PMS|}" appears in ClientKeyExch,
    25 CertVerify, ClientFinished to record that A knows M.  It is a note from A to
    26 herself.  Nobody else can see it.  In ClientKeyExch, the Spy can substitute
    27 his own certificate for A's, but he cannot replace A's note by one for himself.
    28 
    29 The Note event avoids a weakness in the public-key model.  Each
    30 agent's state is recorded as the trace of messages.  When the true client (A)
    31 invents PMS, he encrypts PMS with B's public key before sending it.  The model
    32 does not distinguish the original occurrence of such a message from a replay.
    33 In the shared-key model, the ability to encrypt implies the ability to
    34 decrypt, so the problem does not arise.
    35 
    36 Proofs would be simpler if ClientKeyExch included A's name within
    37 Crypt KB (Nonce PMS).  As things stand, there is much overlap between proofs
    38 about that message (which B receives) and the stronger event
    39 	Notes A {|Agent B, Nonce PMS|}.
    40 *)
    41 
    42 TLS = Public + 
    43 
    44 consts
    45   (*Pseudo-random function of Section 5*)
    46   PRF  :: "nat*nat*nat => nat"
    47 
    48   (*Client, server write keys are generated uniformly by function sessionK
    49     to avoid duplicating their properties.  They are indexed by a further
    50     natural number, not a bool, to avoid the peculiarities of if-and-only-if.
    51     Session keys implicitly include MAC secrets.*)
    52   sessionK :: "(nat*nat*nat)*nat => key"
    53 
    54   certificate      :: "[agent,key] => msg"
    55 
    56 defs
    57   certificate_def
    58     "certificate A KA == Crypt (priK Server) {|Agent A, Key KA|}"
    59 
    60 syntax
    61     clientK, serverK :: "nat*nat*nat => key"
    62 
    63 translations
    64   "clientK X" == "sessionK(X,0)"
    65   "serverK X" == "sessionK(X,1)"
    66 
    67 rules
    68   (*the pseudo-random function is collision-free*)
    69   inj_PRF       "inj PRF"	
    70 
    71   (*sessionK is collision-free; also, no clientK clashes with any serverK.*)
    72   inj_sessionK  "inj sessionK"	
    73 
    74   (*sessionK makes symmetric keys*)
    75   isSym_sessionK "isSymKey (sessionK nonces)"
    76 
    77 
    78 consts    tls :: event list set
    79 inductive tls
    80   intrs 
    81     Nil  (*Initial trace is empty*)
    82          "[]: tls"
    83 
    84     Fake (*The spy, an active attacker, MAY say anything he CAN say.*)
    85          "[| evs: tls;  X: synth (analz (spies evs)) |]
    86           ==> Says Spy B X # evs : tls"
    87 
    88     SpyKeys (*The spy may apply PRF & sessionK to available nonces*)
    89          "[| evsSK: tls;
    90 	     {Nonce NA, Nonce NB, Nonce M} <= analz (spies evsSK) |]
    91           ==> Notes Spy {| Nonce (PRF(M,NA,NB)),
    92 			   Key (sessionK((NA,NB,M),b)) |} # evsSK : tls"
    93 
    94     ClientHello
    95 	 (*(7.4.1.2)
    96 	   PA represents CLIENT_VERSION, CIPHER_SUITES and COMPRESSION_METHODS.
    97 	   It is uninterpreted but will be confirmed in the FINISHED messages.
    98 	   NA is CLIENT RANDOM, while SID is SESSION_ID.
    99            UNIX TIME is omitted because the protocol doesn't use it.
   100            May assume NA ~: range PRF because CLIENT RANDOM is 28 bytes
   101 	   while MASTER SECRET is 48 bytes*)
   102          "[| evsCH: tls;  Nonce NA ~: used evsCH;  NA ~: range PRF |]
   103           ==> Says A B {|Agent A, Nonce NA, Number SID, Number PA|}
   104 	        # evsCH  :  tls"
   105 
   106     ServerHello
   107          (*7.4.1.3 of the TLS Internet-Draft
   108 	   PB represents CLIENT_VERSION, CIPHER_SUITE and COMPRESSION_METHOD.
   109            SERVER CERTIFICATE (7.4.2) is always present.
   110            CERTIFICATE_REQUEST (7.4.4) is implied.*)
   111          "[| evsSH: tls;  Nonce NB ~: used evsSH;  NB ~: range PRF;
   112              Says A' B {|Agent A, Nonce NA, Number SID, Number PA|}
   113 	       : set evsSH |]
   114           ==> Says B A {|Nonce NB, Number SID, Number PB|} # evsSH  :  tls"
   115 
   116     Certificate
   117          (*SERVER (7.4.2) or CLIENT (7.4.6) CERTIFICATE.*)
   118          "[| evsC: tls |]
   119           ==> Says B A (certificate B (pubK B)) # evsC  :  tls"
   120 
   121     ClientKeyExch
   122          (*CLIENT KEY EXCHANGE (7.4.7).
   123            The client, A, chooses PMS, the PREMASTER SECRET.
   124            She encrypts PMS using the supplied KB, which ought to be pubK B.
   125            We assume PMS ~: range PRF because a clash betweem the PMS
   126            and another MASTER SECRET is highly unlikely (even though
   127 	   both items have the same length, 48 bytes).
   128            The Note event records in the trace that she knows PMS
   129                (see REMARK at top). *)
   130          "[| evsCX: tls;  Nonce PMS ~: used evsCX;  PMS ~: range PRF;
   131              Says B' A (certificate B KB) : set evsCX |]
   132           ==> Says A B (Crypt KB (Nonce PMS))
   133 	      # Notes A {|Agent B, Nonce PMS|}
   134 	      # evsCX  :  tls"
   135 
   136     CertVerify
   137 	(*The optional Certificate Verify (7.4.8) message contains the
   138           specific components listed in the security analysis, F.1.1.2.
   139           It adds the pre-master-secret, which is also essential!
   140           Checking the signature, which is the only use of A's certificate,
   141           assures B of A's presence*)
   142          "[| evsCV: tls;  
   143              Says B' A {|Nonce NB, Number SID, Number PB|} : set evsCV;
   144 	     Notes A {|Agent B, Nonce PMS|} : set evsCV |]
   145           ==> Says A B (Crypt (priK A) (Hash{|Nonce NB, Agent B, Nonce PMS|}))
   146               # evsCV  :  tls"
   147 
   148 	(*Finally come the FINISHED messages (7.4.8), confirming PA and PB
   149           among other things.  The master-secret is PRF(PMS,NA,NB).
   150           Either party may sent its message first.*)
   151 
   152     ClientFinished
   153         (*The occurrence of Notes A {|Agent B, Nonce PMS|} stops the 
   154           rule's applying when the Spy has satisfied the "Says A B" by
   155           repaying messages sent by the true client; in that case, the
   156           Spy does not know PMS and could not sent ClientFinished.  One
   157           could simply put A~=Spy into the rule, but one should not
   158           expect the spy to be well-behaved.*)
   159          "[| evsCF: tls;  
   160 	     Says A  B {|Agent A, Nonce NA, Number SID, Number PA|}
   161 	       : set evsCF;
   162              Says B' A {|Nonce NB, Number SID, Number PB|} : set evsCF;
   163              Notes A {|Agent B, Nonce PMS|} : set evsCF;
   164 	     M = PRF(PMS,NA,NB) |]
   165           ==> Says A B (Crypt (clientK(NA,NB,M))
   166 			(Hash{|Number SID, Nonce M,
   167 			       Nonce NA, Number PA, Agent A, 
   168 			       Nonce NB, Number PB, Agent B|}))
   169               # evsCF  :  tls"
   170 
   171     ServerFinished
   172 	(*Keeping A' and A'' distinct means B cannot even check that the
   173           two messages originate from the same source. *)
   174          "[| evsSF: tls;
   175 	     Says A' B  {|Agent A, Nonce NA, Number SID, Number PA|}
   176 	       : set evsSF;
   177 	     Says B  A  {|Nonce NB, Number SID, Number PB|} : set evsSF;
   178 	     Says A'' B (Crypt (pubK B) (Nonce PMS)) : set evsSF;
   179 	     M = PRF(PMS,NA,NB) |]
   180           ==> Says B A (Crypt (serverK(NA,NB,M))
   181 			(Hash{|Number SID, Nonce M,
   182 			       Nonce NA, Number PA, Agent A, 
   183 			       Nonce NB, Number PB, Agent B|}))
   184               # evsSF  :  tls"
   185 
   186     ClientAccepts
   187 	(*Having transmitted ClientFinished and received an identical
   188           message encrypted with serverK, the client stores the parameters
   189           needed to resume this session.  The "Notes A ..." premise is
   190           used to prove Notes_master_imp_Crypt_PMS.*)
   191          "[| evsCA: tls;
   192 	     Notes A {|Agent B, Nonce PMS|} : set evsCA;
   193 	     M = PRF(PMS,NA,NB);  
   194 	     X = Hash{|Number SID, Nonce M,
   195 	               Nonce NA, Number PA, Agent A, 
   196 		       Nonce NB, Number PB, Agent B|};
   197              Says A  B (Crypt (clientK(NA,NB,M)) X) : set evsCA;
   198              Says B' A (Crypt (serverK(NA,NB,M)) X) : set evsCA |]
   199           ==> 
   200              Notes A {|Number SID, Agent A, Agent B, Nonce M|} # evsCA  :  tls"
   201 
   202     ServerAccepts
   203 	(*Having transmitted ServerFinished and received an identical
   204           message encrypted with clientK, the server stores the parameters
   205           needed to resume this session.  The "Says A'' B ..." premise is
   206           used to prove Notes_master_imp_Crypt_PMS.*)
   207          "[| evsSA: tls;
   208 	     A ~= B;
   209              Says A'' B (Crypt (pubK B) (Nonce PMS)) : set evsSA;
   210 	     M = PRF(PMS,NA,NB);  
   211 	     X = Hash{|Number SID, Nonce M,
   212 	               Nonce NA, Number PA, Agent A, 
   213 		       Nonce NB, Number PB, Agent B|};
   214              Says B  A (Crypt (serverK(NA,NB,M)) X) : set evsSA;
   215              Says A' B (Crypt (clientK(NA,NB,M)) X) : set evsSA |]
   216           ==> 
   217              Notes B {|Number SID, Agent A, Agent B, Nonce M|} # evsSA  :  tls"
   218 
   219     ClientResume
   220          (*If A recalls the SESSION_ID, then she sends a FINISHED message
   221            using the new nonces and stored MASTER SECRET.*)
   222          "[| evsCR: tls;  
   223 	     Says A  B {|Agent A, Nonce NA, Number SID, Number PA|}: set evsCR;
   224              Says B' A {|Nonce NB, Number SID, Number PB|} : set evsCR;
   225              Notes A {|Number SID, Agent A, Agent B, Nonce M|} : set evsCR |]
   226           ==> Says A B (Crypt (clientK(NA,NB,M))
   227 			(Hash{|Number SID, Nonce M,
   228 			       Nonce NA, Number PA, Agent A, 
   229 			       Nonce NB, Number PB, Agent B|}))
   230               # evsCR  :  tls"
   231 
   232     ServerResume
   233          (*Resumption (7.3):  If B finds the SESSION_ID then he can send
   234            a FINISHED message using the recovered MASTER SECRET*)
   235          "[| evsSR: tls;
   236 	     Says A' B {|Agent A, Nonce NA, Number SID, Number PA|}: set evsSR;
   237 	     Says B  A {|Nonce NB, Number SID, Number PB|} : set evsSR;  
   238              Notes B {|Number SID, Agent A, Agent B, Nonce M|} : set evsSR |]
   239           ==> Says B A (Crypt (serverK(NA,NB,M))
   240 			(Hash{|Number SID, Nonce M,
   241 			       Nonce NA, Number PA, Agent A, 
   242 			       Nonce NB, Number PB, Agent B|})) # evsSR
   243 	        :  tls"
   244 
   245     Oops 
   246          (*The most plausible compromise is of an old session key.  Losing
   247            the MASTER SECRET or PREMASTER SECRET is more serious but
   248            rather unlikely.  The assumption A ~= Spy is essential: otherwise
   249            the Spy could learn session keys merely by replaying messages!*)
   250          "[| evso: tls;  A ~= Spy;
   251 	     Says A B (Crypt (sessionK((NA,NB,M),b)) X) : set evso |]
   252           ==> Says A Spy (Key (sessionK((NA,NB,M),b))) # evso  :  tls"
   253 
   254 end