src/Pure/theory.ML
author nipkow
Fri Nov 28 07:35:10 1997 +0100 (1997-11-28)
changeset 4318 9b672ea2dfe7
parent 4257 1663f9056045
child 4344 e000b5db4087
permissions -rw-r--r--
Fixed the definition of `termord': is now antisymmetric.
     1 (*  Title:      Pure/theory.ML
     2     ID:         $Id$
     3     Author:     Lawrence C Paulson and Markus Wenzel
     4     Copyright   1996  University of Cambridge
     5 
     6 Theories.
     7 *)
     8 
     9 (*this part made pervasive*)
    10 signature BASIC_THEORY =
    11 sig
    12   type theory
    13   exception THEORY of string * theory list
    14   val rep_theory: theory ->
    15     {sign: Sign.sg,
    16       axioms: term Symtab.table,
    17       oracles: ((Sign.sg * object -> term) * stamp) Symtab.table,
    18       parents: theory list,
    19       ancestors: theory list}
    20   val sign_of: theory -> Sign.sg
    21   val syn_of: theory -> Syntax.syntax
    22   val parents_of: theory -> theory list
    23   val ancestors_of: theory -> theory list
    24   val subthy: theory * theory -> bool
    25   val eq_thy: theory * theory -> bool
    26   val cert_axm: Sign.sg -> string * term -> string * term
    27   val read_axm: Sign.sg -> string * string -> string * term
    28   val inferT_axm: Sign.sg -> string * term -> string * term
    29   val merge_theories: string -> theory * theory -> theory
    30 end
    31 
    32 signature THEORY =
    33 sig
    34   include BASIC_THEORY
    35   val axiomK: string
    36   val oracleK: string
    37   (*theory extendsion primitives*)
    38   val add_classes: (bclass * xclass list) list -> theory -> theory
    39   val add_classes_i: (bclass * class list) list -> theory -> theory
    40   val add_classrel: (xclass * xclass) list -> theory -> theory
    41   val add_classrel_i: (class * class) list -> theory -> theory
    42   val add_defsort: xsort -> theory -> theory
    43   val add_defsort_i: sort -> theory -> theory
    44   val add_types: (bstring * int * mixfix) list -> theory -> theory
    45   val add_tyabbrs: (bstring * string list * string * mixfix) list
    46     -> theory -> theory
    47   val add_tyabbrs_i: (bstring * string list * typ * mixfix) list
    48     -> theory -> theory
    49   val add_arities: (xstring * xsort list * xsort) list -> theory -> theory
    50   val add_arities_i: (string * sort list * sort) list -> theory -> theory
    51   val add_consts: (bstring * string * mixfix) list -> theory -> theory
    52   val add_consts_i: (bstring * typ * mixfix) list -> theory -> theory
    53   val add_syntax: (bstring * string * mixfix) list -> theory -> theory
    54   val add_syntax_i: (bstring * typ * mixfix) list -> theory -> theory
    55   val add_modesyntax: string * bool -> (bstring * string * mixfix) list -> theory -> theory
    56   val add_modesyntax_i: string * bool -> (bstring * typ * mixfix) list -> theory -> theory
    57   val add_trfuns:
    58     (bstring * (Syntax.ast list -> Syntax.ast)) list *
    59     (bstring * (term list -> term)) list *
    60     (bstring * (term list -> term)) list *
    61     (bstring * (Syntax.ast list -> Syntax.ast)) list -> theory -> theory
    62   val add_trfunsT:
    63     (bstring * (bool -> typ -> term list -> term)) list -> theory -> theory
    64   val add_tokentrfuns:
    65     (string * string * (string -> string * int)) list -> theory -> theory
    66   val add_trrules: (string * string) Syntax.trrule list -> theory -> theory
    67   val add_trrules_i: Syntax.ast Syntax.trrule list -> theory -> theory
    68   val add_axioms: (bstring * string) list -> theory -> theory
    69   val add_axioms_i: (bstring * term) list -> theory -> theory
    70   val add_oracle: bstring * (Sign.sg * object -> term) -> theory -> theory
    71   val add_defs: (bstring * string) list -> theory -> theory
    72   val add_defs_i: (bstring * term) list -> theory -> theory
    73   val add_path: string -> theory -> theory
    74   val add_space: string * string list -> theory -> theory
    75   val add_name: string -> theory -> theory
    76   val init_data: (string * (object * (object -> object) *
    77     (object * object -> object) * (Sign.sg -> object -> unit))) list -> theory -> theory
    78   val get_data: theory -> string -> object
    79   val put_data: string * object -> theory -> theory
    80   val prep_ext: theory -> theory
    81   val prep_ext_merge: theory list -> theory
    82   val pre_pure: theory
    83 end;
    84 
    85 
    86 structure Theory: THEORY =
    87 struct
    88 
    89 
    90 (** datatype theory **)
    91 
    92 datatype theory =
    93   Theory of {
    94     sign: Sign.sg,
    95     axioms: term Symtab.table,
    96     oracles: ((Sign.sg * object -> term) * stamp) Symtab.table,
    97     parents: theory list,
    98     ancestors: theory list};
    99 
   100 fun make_thy sign axms oras parents ancestors =
   101   Theory {sign = sign, axioms = axms, oracles = oras,
   102     parents = parents, ancestors = ancestors};
   103 
   104 fun rep_theory (Theory args) = args;
   105 
   106 val sign_of = #sign o rep_theory;
   107 val syn_of = #syn o Sign.rep_sg o sign_of;
   108 val parents_of = #parents o rep_theory;
   109 val ancestors_of = #ancestors o rep_theory;
   110 
   111 (*errors involving theories*)
   112 exception THEORY of string * theory list;
   113 
   114 (*compare theories*)
   115 val subthy = Sign.subsig o pairself sign_of;
   116 val eq_thy = Sign.eq_sg o pairself sign_of;
   117 
   118 
   119 (* partial Pure theory *)
   120 
   121 val pre_pure = make_thy Sign.pre_pure Symtab.null Symtab.null [] [];
   122 
   123 
   124 
   125 (** extend theory **)
   126 
   127 (*name space kinds*)
   128 val axiomK = "axiom";
   129 val oracleK = "oracle";
   130 
   131 
   132 (* extend logical part of a theory *)
   133 
   134 fun err_dup_axms names =
   135   error ("Duplicate axiom name(s) " ^ commas_quote names);
   136 
   137 fun err_dup_oras names =
   138   error ("Duplicate oracles " ^ commas_quote names);
   139 
   140 
   141 fun ext_thy thy sign' new_axms new_oras =
   142   let
   143     val Theory {sign, axioms, oracles, parents, ancestors} = thy;
   144     val draft = Sign.is_draft sign;
   145     val axioms' =
   146       Symtab.extend_new (if draft then axioms else Symtab.null, new_axms)
   147         handle Symtab.DUPS names => err_dup_axms names;
   148     val oracles' =
   149       Symtab.extend_new (oracles, new_oras)
   150         handle Symtab.DUPS names => err_dup_oras names;
   151     val (parents', ancestors') =
   152       if draft then (parents, ancestors) else ([thy], thy :: ancestors);
   153   in
   154     make_thy sign' axioms' oracles' parents' ancestors'
   155   end;
   156 
   157 
   158 (* extend signature of a theory *)
   159 
   160 fun ext_sg extfun decls (thy as Theory {sign, ...}) =
   161   ext_thy thy (extfun decls sign) [] [];
   162 
   163 val add_classes      = ext_sg Sign.add_classes;
   164 val add_classes_i    = ext_sg Sign.add_classes_i;
   165 val add_classrel     = ext_sg Sign.add_classrel;
   166 val add_classrel_i   = ext_sg Sign.add_classrel_i;
   167 val add_defsort      = ext_sg Sign.add_defsort;
   168 val add_defsort_i    = ext_sg Sign.add_defsort_i;
   169 val add_types        = ext_sg Sign.add_types;
   170 val add_tyabbrs      = ext_sg Sign.add_tyabbrs;
   171 val add_tyabbrs_i    = ext_sg Sign.add_tyabbrs_i;
   172 val add_arities      = ext_sg Sign.add_arities;
   173 val add_arities_i    = ext_sg Sign.add_arities_i;
   174 val add_consts       = ext_sg Sign.add_consts;
   175 val add_consts_i     = ext_sg Sign.add_consts_i;
   176 val add_syntax       = ext_sg Sign.add_syntax;
   177 val add_syntax_i     = ext_sg Sign.add_syntax_i;
   178 val add_modesyntax   = curry (ext_sg Sign.add_modesyntax);
   179 val add_modesyntax_i = curry (ext_sg Sign.add_modesyntax_i);
   180 val add_trfuns       = ext_sg Sign.add_trfuns;
   181 val add_trfunsT      = ext_sg Sign.add_trfunsT;
   182 val add_tokentrfuns  = ext_sg Sign.add_tokentrfuns;
   183 val add_trrules      = ext_sg Sign.add_trrules;
   184 val add_trrules_i    = ext_sg Sign.add_trrules_i;
   185 val add_path         = ext_sg Sign.add_path;
   186 val add_space        = ext_sg Sign.add_space;
   187 val add_name         = ext_sg Sign.add_name;
   188 val prep_ext         = ext_sg (K Sign.prep_ext) ();
   189 
   190 
   191 
   192 (** add axioms **)
   193 
   194 (* prepare axioms *)
   195 
   196 fun err_in_axm name =
   197   error ("The error(s) above occurred in axiom " ^ quote name);
   198 
   199 fun no_vars tm =
   200   if null (term_vars tm) andalso null (term_tvars tm) then tm
   201   else error "Illegal schematic variable(s) in term";
   202 
   203 fun cert_axm sg (name, raw_tm) =
   204   let
   205     val (t, T, _) = Sign.certify_term sg raw_tm
   206       handle TYPE (msg, _, _) => error msg
   207            | TERM (msg, _) => error msg;
   208   in
   209     assert (T = propT) "Term not of type prop";
   210     (name, no_vars t)
   211   end
   212   handle ERROR => err_in_axm name;
   213 
   214 (*Some duplication of code with read_def_cterm*)
   215 fun read_axm sg (name, str) = 
   216   let
   217     val ts = Syntax.read (#syn (Sign.rep_sg sg)) propT str;
   218     val (t, _) = Sign.infer_types sg (K None) (K None) [] true (ts, propT);
   219   in cert_axm sg (name,t) end
   220   handle ERROR => err_in_axm name;
   221 
   222 fun inferT_axm sg (name, pre_tm) =
   223   let
   224     val (t, _) = Sign.infer_types sg (K None) (K None) [] true ([pre_tm], propT);
   225   in (name, no_vars t) end
   226   handle ERROR => err_in_axm name;
   227 
   228 
   229 (* extend axioms of a theory *)
   230 
   231 fun ext_axms prep_axm raw_axms (thy as Theory {sign, ...}) =
   232   let
   233     val raw_axms' = map (apfst (Sign.full_name sign)) raw_axms;
   234     val axioms =
   235       map (apsnd (Term.compress_term o Logic.varify) o prep_axm sign) raw_axms';
   236     val sign' = Sign.add_space (axiomK, map fst axioms) sign;
   237   in
   238     ext_thy thy sign' axioms []
   239   end;
   240 
   241 val add_axioms = ext_axms read_axm;
   242 val add_axioms_i = ext_axms cert_axm;
   243 
   244 
   245 (* add oracle **)
   246 
   247 fun add_oracle (raw_name, oracle) (thy as Theory {sign, ...}) =
   248   let
   249     val name = Sign.full_name sign raw_name;
   250     val sign' = Sign.add_space (oracleK, [name]) sign;
   251   in
   252     ext_thy thy sign' [] [(name, (oracle, stamp ()))]
   253   end;
   254 
   255 
   256 
   257 (** add constant definitions **)
   258 
   259 (* all_axioms_of *)
   260 
   261 (*results may contain duplicates!*)
   262 
   263 fun all_axioms_of thy =
   264   flat (map (Symtab.dest o #axioms o rep_theory) (thy :: ancestors_of thy));
   265 
   266 
   267 (* clash_types, clash_consts *)
   268 
   269 (*check if types have common instance (ignoring sorts)*)
   270 
   271 fun clash_types ty1 ty2 =
   272   let
   273     val ty1' = Type.varifyT ty1;
   274     val ty2' = incr_tvar (maxidx_of_typ ty1' + 1) (Type.varifyT ty2);
   275   in
   276     Type.raw_unify (ty1', ty2')
   277   end;
   278 
   279 fun clash_consts (c1, ty1) (c2, ty2) =
   280   c1 = c2 andalso clash_types ty1 ty2;
   281 
   282 
   283 (* clash_defns *)
   284 
   285 fun clash_defn c_ty (name, tm) =
   286   let val (c, ty') = dest_Const (head_of (fst (Logic.dest_equals tm))) in
   287     if clash_consts c_ty (c, ty') then Some (name, ty') else None
   288   end handle TERM _ => None;
   289 
   290 fun clash_defns c_ty axms =
   291   distinct (mapfilter (clash_defn c_ty) axms);
   292 
   293 
   294 (* dest_defn *)
   295 
   296 fun dest_defn tm =
   297   let
   298     fun err msg = raise TERM (msg, [tm]);
   299 
   300     val (lhs, rhs) = Logic.dest_equals (Logic.strip_imp_concl tm)
   301       handle TERM _ => err "Not a meta-equality (==)";
   302     val (head, args) = strip_comb lhs;
   303     val (c, ty) = dest_Const head
   304       handle TERM _ => err "Head of lhs not a constant";
   305 
   306     fun occs_const (Const c_ty') = (c_ty' = (c, ty))
   307       | occs_const (Abs (_, _, t)) = occs_const t
   308       | occs_const (t $ u) = occs_const t orelse occs_const u
   309       | occs_const _ = false;
   310 
   311     fun dest_free (Free (x, _)) = x
   312       | dest_free (Const ("TYPE", Type ("itself", [TFree (x, _)]))) = x
   313       | dest_free _ = raise Match;
   314 
   315     val show_frees = commas_quote o map dest_free;
   316     val show_tfrees = commas_quote o map fst;
   317 
   318     val lhs_dups = duplicates args;
   319     val rhs_extras = gen_rems (op =) (term_frees rhs, args);
   320     val rhs_extrasT = gen_rems (op =) (term_tfrees rhs, typ_tfrees ty);
   321   in
   322     if not (forall (can dest_free) args) then
   323       err "Arguments (on lhs) must be variables"
   324     else if not (null lhs_dups) then
   325       err ("Duplicate variables on lhs: " ^ show_frees lhs_dups)
   326     else if not (null rhs_extras) then
   327       err ("Extra variables on rhs: " ^ show_frees rhs_extras)
   328     else if not (null rhs_extrasT) then
   329       err ("Extra type variables on rhs: " ^ show_tfrees rhs_extrasT)
   330     else if occs_const rhs then
   331       err ("Constant to be defined occurs on rhs")
   332     else (c, ty)
   333   end;
   334 
   335 
   336 (* check_defn *)
   337 
   338 fun err_in_defn sg name msg =
   339   (writeln msg; error ("The error(s) above occurred in definition " ^
   340     quote (Sign.full_name sg name)));
   341 
   342 fun check_defn sign (axms, (name, tm)) =
   343   let
   344     fun show_const (c, ty) = quote (Pretty.string_of (Pretty.block
   345       [Pretty.str (c ^ " ::"), Pretty.brk 1, Sign.pretty_typ sign ty]));
   346 
   347     fun show_defn c (dfn, ty') = show_const (c, ty') ^ " in " ^ dfn;
   348     fun show_defns c = cat_lines o map (show_defn c);
   349 
   350     val (c, ty) = dest_defn tm
   351       handle TERM (msg, _) => err_in_defn sign name msg;
   352     val defns = clash_defns (c, ty) axms;
   353   in
   354     if not (null defns) then
   355       err_in_defn sign name ("Definition of " ^ show_const (c, ty) ^
   356         "\nclashes with " ^ show_defns c defns)
   357     else (name, tm) :: axms
   358   end;
   359 
   360 
   361 (* add_defs *)
   362 
   363 fun ext_defns prep_axm raw_axms thy =
   364   let
   365     val axms = map (prep_axm (sign_of thy)) raw_axms;
   366     val all_axms = all_axioms_of thy;
   367   in
   368     foldl (check_defn (sign_of thy)) (all_axms, axms);
   369     add_axioms_i axms thy
   370   end;
   371 
   372 val add_defs_i = ext_defns cert_axm;
   373 val add_defs = ext_defns read_axm;
   374 
   375 
   376 
   377 (** additional theory data **)
   378 
   379 fun init_data ds = foldl (op o) (I, map (ext_sg Sign.init_data) ds);
   380 val get_data = Sign.get_data o sign_of;
   381 val put_data = ext_sg Sign.put_data;
   382 
   383 
   384 
   385 (** merge theories **)		(*exception ERROR*)
   386 
   387 fun merge_sign (sg, thy) =
   388   Sign.merge (sg, sign_of thy) handle TERM (msg, _) => error msg;
   389 
   390 (*merge list of theories from left to right, preparing extend*)
   391 fun prep_ext_merge thys =
   392   if null thys then
   393     error "Merge: no parent theories"
   394   else if exists (Sign.is_draft o sign_of) thys then
   395     error "Attempt to merge draft theories"
   396   else
   397     let
   398       val sign' =
   399         foldl merge_sign (sign_of (hd thys), tl thys)
   400         |> Sign.prep_ext
   401         |> Sign.add_path "/";
   402 
   403       val axioms' = Symtab.null;
   404 
   405       fun eq_ora ((_, (_, s1: stamp)), (_, (_, s2))) = s1 = s2;
   406       val oracles' =
   407         Symtab.make (gen_distinct eq_ora
   408           (flat (map (Symtab.dest o #oracles o rep_theory) thys)))
   409         handle Symtab.DUPS names => err_dup_oras names;
   410 
   411       val parents' = gen_distinct eq_thy thys;
   412       val ancestors' =
   413         gen_distinct eq_thy (parents' @ flat (map ancestors_of thys));
   414     in
   415       make_thy sign' axioms' oracles' parents' ancestors'
   416     end;
   417 
   418 fun merge_theories name (thy1, thy2) =
   419   prep_ext_merge [thy1, thy2]
   420   |> add_name name;
   421 
   422 
   423 end;
   424 
   425 structure BasicTheory: BASIC_THEORY = Theory;
   426 open BasicTheory;