src/HOL/BNF_Def.thy
author haftmann
Tue Oct 13 09:21:14 2015 +0200 (2015-10-13)
changeset 61423 9b6a0fb85fa3
parent 61422 0dfcd0fb4172
child 61424 c3658c18b7bc
permissions -rw-r--r--
emphasized general nature of parameter
     1 (*  Title:      HOL/BNF_Def.thy
     2     Author:     Dmitriy Traytel, TU Muenchen
     3     Author:     Jasmin Blanchette, TU Muenchen
     4     Copyright   2012, 2013, 2014
     5 
     6 Definition of bounded natural functors.
     7 *)
     8 
     9 section \<open>Definition of Bounded Natural Functors\<close>
    10 
    11 theory BNF_Def
    12 imports BNF_Cardinal_Arithmetic Fun_Def_Base
    13 keywords
    14   "print_bnfs" :: diag and
    15   "bnf" :: thy_goal
    16 begin
    17 
    18 lemma Collect_splitD: "x \<in> Collect (case_prod A) \<Longrightarrow> A (fst x) (snd x)"
    19   by auto
    20 
    21 inductive
    22    rel_sum :: "('a \<Rightarrow> 'c \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> 'd \<Rightarrow> bool) \<Rightarrow> 'a + 'b \<Rightarrow> 'c + 'd \<Rightarrow> bool" for R1 R2
    23 where
    24   "R1 a c \<Longrightarrow> rel_sum R1 R2 (Inl a) (Inl c)"
    25 | "R2 b d \<Longrightarrow> rel_sum R1 R2 (Inr b) (Inr d)"
    26 
    27 hide_fact rel_sum_def
    28 
    29 definition
    30   rel_fun :: "('a \<Rightarrow> 'c \<Rightarrow> bool) \<Rightarrow> ('b \<Rightarrow> 'd \<Rightarrow> bool) \<Rightarrow> ('a \<Rightarrow> 'b) \<Rightarrow> ('c \<Rightarrow> 'd) \<Rightarrow> bool"
    31 where
    32   "rel_fun A B = (\<lambda>f g. \<forall>x y. A x y \<longrightarrow> B (f x) (g y))"
    33 
    34 lemma rel_funI [intro]:
    35   assumes "\<And>x y. A x y \<Longrightarrow> B (f x) (g y)"
    36   shows "rel_fun A B f g"
    37   using assms by (simp add: rel_fun_def)
    38 
    39 lemma rel_funD:
    40   assumes "rel_fun A B f g" and "A x y"
    41   shows "B (f x) (g y)"
    42   using assms by (simp add: rel_fun_def)
    43 
    44 lemma rel_fun_mono:
    45   "\<lbrakk> rel_fun X A f g; \<And>x y. Y x y \<longrightarrow> X x y; \<And>x y. A x y \<Longrightarrow> B x y \<rbrakk> \<Longrightarrow> rel_fun Y B f g"
    46 by(simp add: rel_fun_def)
    47 
    48 lemma rel_fun_mono' [mono]:
    49   "\<lbrakk> \<And>x y. Y x y \<longrightarrow> X x y; \<And>x y. A x y \<longrightarrow> B x y \<rbrakk> \<Longrightarrow> rel_fun X A f g \<longrightarrow> rel_fun Y B f g"
    50 by(simp add: rel_fun_def)
    51 
    52 definition rel_set :: "('a \<Rightarrow> 'b \<Rightarrow> bool) \<Rightarrow> 'a set \<Rightarrow> 'b set \<Rightarrow> bool"
    53   where "rel_set R = (\<lambda>A B. (\<forall>x\<in>A. \<exists>y\<in>B. R x y) \<and> (\<forall>y\<in>B. \<exists>x\<in>A. R x y))"
    54 
    55 lemma rel_setI:
    56   assumes "\<And>x. x \<in> A \<Longrightarrow> \<exists>y\<in>B. R x y"
    57   assumes "\<And>y. y \<in> B \<Longrightarrow> \<exists>x\<in>A. R x y"
    58   shows "rel_set R A B"
    59   using assms unfolding rel_set_def by simp
    60 
    61 lemma predicate2_transferD:
    62    "\<lbrakk>rel_fun R1 (rel_fun R2 (op =)) P Q; a \<in> A; b \<in> B; A \<subseteq> {(x, y). R1 x y}; B \<subseteq> {(x, y). R2 x y}\<rbrakk> \<Longrightarrow>
    63    P (fst a) (fst b) \<longleftrightarrow> Q (snd a) (snd b)"
    64   unfolding rel_fun_def by (blast dest!: Collect_splitD)
    65 
    66 definition collect where
    67   "collect F x = (\<Union>f \<in> F. f x)"
    68 
    69 lemma fstI: "x = (y, z) \<Longrightarrow> fst x = y"
    70   by simp
    71 
    72 lemma sndI: "x = (y, z) \<Longrightarrow> snd x = z"
    73   by simp
    74 
    75 lemma bijI': "\<lbrakk>\<And>x y. (f x = f y) = (x = y); \<And>y. \<exists>x. y = f x\<rbrakk> \<Longrightarrow> bij f"
    76   unfolding bij_def inj_on_def by auto blast
    77 
    78 (* Operator: *)
    79 definition "Gr A f = {(a, f a) | a. a \<in> A}"
    80 
    81 definition "Grp A f = (\<lambda>a b. b = f a \<and> a \<in> A)"
    82 
    83 definition vimage2p where
    84   "vimage2p f g R = (\<lambda>x y. R (f x) (g y))"
    85 
    86 lemma collect_comp: "collect F \<circ> g = collect ((\<lambda>f. f \<circ> g) ` F)"
    87   by (rule ext) (auto simp only: comp_apply collect_def)
    88 
    89 definition convol ("\<langle>(_,/ _)\<rangle>") where
    90   "\<langle>f, g\<rangle> \<equiv> \<lambda>a. (f a, g a)"
    91 
    92 lemma fst_convol: "fst \<circ> \<langle>f, g\<rangle> = f"
    93   apply(rule ext)
    94   unfolding convol_def by simp
    95 
    96 lemma snd_convol: "snd \<circ> \<langle>f, g\<rangle> = g"
    97   apply(rule ext)
    98   unfolding convol_def by simp
    99 
   100 lemma convol_mem_GrpI:
   101   "x \<in> A \<Longrightarrow> \<langle>id, g\<rangle> x \<in> (Collect (case_prod (Grp A g)))"
   102   unfolding convol_def Grp_def by auto
   103 
   104 definition csquare where
   105   "csquare A f1 f2 p1 p2 \<longleftrightarrow> (\<forall> a \<in> A. f1 (p1 a) = f2 (p2 a))"
   106 
   107 lemma eq_alt: "op = = Grp UNIV id"
   108   unfolding Grp_def by auto
   109 
   110 lemma leq_conversepI: "R = op = \<Longrightarrow> R \<le> R^--1"
   111   by auto
   112 
   113 lemma leq_OOI: "R = op = \<Longrightarrow> R \<le> R OO R"
   114   by auto
   115 
   116 lemma OO_Grp_alt: "(Grp A f)^--1 OO Grp A g = (\<lambda>x y. \<exists>z. z \<in> A \<and> f z = x \<and> g z = y)"
   117   unfolding Grp_def by auto
   118 
   119 lemma Grp_UNIV_id: "f = id \<Longrightarrow> (Grp UNIV f)^--1 OO Grp UNIV f = Grp UNIV f"
   120   unfolding Grp_def by auto
   121 
   122 lemma Grp_UNIV_idI: "x = y \<Longrightarrow> Grp UNIV id x y"
   123   unfolding Grp_def by auto
   124 
   125 lemma Grp_mono: "A \<le> B \<Longrightarrow> Grp A f \<le> Grp B f"
   126   unfolding Grp_def by auto
   127 
   128 lemma GrpI: "\<lbrakk>f x = y; x \<in> A\<rbrakk> \<Longrightarrow> Grp A f x y"
   129   unfolding Grp_def by auto
   130 
   131 lemma GrpE: "Grp A f x y \<Longrightarrow> (\<lbrakk>f x = y; x \<in> A\<rbrakk> \<Longrightarrow> R) \<Longrightarrow> R"
   132   unfolding Grp_def by auto
   133 
   134 lemma Collect_split_Grp_eqD: "z \<in> Collect (case_prod (Grp A f)) \<Longrightarrow> (f \<circ> fst) z = snd z"
   135   unfolding Grp_def comp_def by auto
   136 
   137 lemma Collect_split_Grp_inD: "z \<in> Collect (case_prod (Grp A f)) \<Longrightarrow> fst z \<in> A"
   138   unfolding Grp_def comp_def by auto
   139 
   140 definition "pick_middlep P Q a c = (SOME b. P a b \<and> Q b c)"
   141 
   142 lemma pick_middlep:
   143   "(P OO Q) a c \<Longrightarrow> P a (pick_middlep P Q a c) \<and> Q (pick_middlep P Q a c) c"
   144   unfolding pick_middlep_def apply(rule someI_ex) by auto
   145 
   146 definition fstOp where
   147   "fstOp P Q ac = (fst ac, pick_middlep P Q (fst ac) (snd ac))"
   148 
   149 definition sndOp where
   150   "sndOp P Q ac = (pick_middlep P Q (fst ac) (snd ac), (snd ac))"
   151 
   152 lemma fstOp_in: "ac \<in> Collect (case_prod (P OO Q)) \<Longrightarrow> fstOp P Q ac \<in> Collect (case_prod P)"
   153   unfolding fstOp_def mem_Collect_eq
   154   by (subst (asm) surjective_pairing, unfold prod.case) (erule pick_middlep[THEN conjunct1])
   155 
   156 lemma fst_fstOp: "fst bc = (fst \<circ> fstOp P Q) bc"
   157   unfolding comp_def fstOp_def by simp
   158 
   159 lemma snd_sndOp: "snd bc = (snd \<circ> sndOp P Q) bc"
   160   unfolding comp_def sndOp_def by simp
   161 
   162 lemma sndOp_in: "ac \<in> Collect (case_prod (P OO Q)) \<Longrightarrow> sndOp P Q ac \<in> Collect (case_prod Q)"
   163   unfolding sndOp_def mem_Collect_eq
   164   by (subst (asm) surjective_pairing, unfold prod.case) (erule pick_middlep[THEN conjunct2])
   165 
   166 lemma csquare_fstOp_sndOp:
   167   "csquare (Collect (f (P OO Q))) snd fst (fstOp P Q) (sndOp P Q)"
   168   unfolding csquare_def fstOp_def sndOp_def using pick_middlep by simp
   169 
   170 lemma snd_fst_flip: "snd xy = (fst \<circ> (%(x, y). (y, x))) xy"
   171   by (simp split: prod.split)
   172 
   173 lemma fst_snd_flip: "fst xy = (snd \<circ> (%(x, y). (y, x))) xy"
   174   by (simp split: prod.split)
   175 
   176 lemma flip_pred: "A \<subseteq> Collect (case_prod (R ^--1)) \<Longrightarrow> (%(x, y). (y, x)) ` A \<subseteq> Collect (case_prod R)"
   177   by auto
   178 
   179 lemma predicate2_eqD: "A = B \<Longrightarrow> A a b \<longleftrightarrow> B a b"
   180   by simp
   181 
   182 lemma case_sum_o_inj: "case_sum f g \<circ> Inl = f" "case_sum f g \<circ> Inr = g"
   183   by auto
   184 
   185 lemma map_sum_o_inj: "map_sum f g o Inl = Inl o f" "map_sum f g o Inr = Inr o g"
   186   by auto
   187 
   188 lemma card_order_csum_cone_cexp_def:
   189   "card_order r \<Longrightarrow> ( |A1| +c cone) ^c r = |Func UNIV (Inl ` A1 \<union> {Inr ()})|"
   190   unfolding cexp_def cone_def Field_csum Field_card_of by (auto dest: Field_card_order)
   191 
   192 lemma If_the_inv_into_in_Func:
   193   "\<lbrakk>inj_on g C; C \<subseteq> B \<union> {x}\<rbrakk> \<Longrightarrow>
   194    (\<lambda>i. if i \<in> g ` C then the_inv_into C g i else x) \<in> Func UNIV (B \<union> {x})"
   195   unfolding Func_def by (auto dest: the_inv_into_into)
   196 
   197 lemma If_the_inv_into_f_f:
   198   "\<lbrakk>i \<in> C; inj_on g C\<rbrakk> \<Longrightarrow> ((\<lambda>i. if i \<in> g ` C then the_inv_into C g i else x) \<circ> g) i = id i"
   199   unfolding Func_def by (auto elim: the_inv_into_f_f)
   200 
   201 lemma the_inv_f_o_f_id: "inj f \<Longrightarrow> (the_inv f \<circ> f) z = id z"
   202   by (simp add: the_inv_f_f)
   203 
   204 lemma vimage2pI: "R (f x) (g y) \<Longrightarrow> vimage2p f g R x y"
   205   unfolding vimage2p_def by -
   206 
   207 lemma rel_fun_iff_leq_vimage2p: "(rel_fun R S) f g = (R \<le> vimage2p f g S)"
   208   unfolding rel_fun_def vimage2p_def by auto
   209 
   210 lemma convol_image_vimage2p: "\<langle>f \<circ> fst, g \<circ> snd\<rangle> ` Collect (case_prod (vimage2p f g R)) \<subseteq> Collect (case_prod R)"
   211   unfolding vimage2p_def convol_def by auto
   212 
   213 lemma vimage2p_Grp: "vimage2p f g P = Grp UNIV f OO P OO (Grp UNIV g)\<inverse>\<inverse>"
   214   unfolding vimage2p_def Grp_def by auto
   215 
   216 lemma subst_Pair: "P x y \<Longrightarrow> a = (x, y) \<Longrightarrow> P (fst a) (snd a)"
   217   by simp
   218 
   219 lemma comp_apply_eq: "f (g x) = h (k x) \<Longrightarrow> (f \<circ> g) x = (h \<circ> k) x"
   220   unfolding comp_apply by assumption
   221 
   222 lemma refl_ge_eq: "(\<And>x. R x x) \<Longrightarrow> op = \<le> R"
   223   by auto
   224 
   225 lemma ge_eq_refl: "op = \<le> R \<Longrightarrow> R x x"
   226   by auto
   227 
   228 lemma reflp_eq: "reflp R = (op = \<le> R)"
   229   by (auto simp: reflp_def fun_eq_iff)
   230 
   231 lemma transp_relcompp: "transp r \<longleftrightarrow> r OO r \<le> r"
   232   by (auto simp: transp_def)
   233 
   234 lemma symp_conversep: "symp R = (R\<inverse>\<inverse> \<le> R)"
   235   by (auto simp: symp_def fun_eq_iff)
   236 
   237 lemma diag_imp_eq_le: "(\<And>x. x \<in> A \<Longrightarrow> R x x) \<Longrightarrow> \<forall>x y. x \<in> A \<longrightarrow> y \<in> A \<longrightarrow> x = y \<longrightarrow> R x y"
   238   by blast
   239 
   240 ML_file "Tools/BNF/bnf_util.ML"
   241 ML_file "Tools/BNF/bnf_tactics.ML"
   242 ML_file "Tools/BNF/bnf_def_tactics.ML"
   243 ML_file "Tools/BNF/bnf_def.ML"
   244 
   245 end