src/HOL/Groebner_Basis.thy
author haftmann
Thu May 06 16:32:20 2010 +0200 (2010-05-06)
changeset 36700 9b85b9d74b83
parent 36699 816da1023508
child 36702 b455ebd63799
permissions -rw-r--r--
dropped auxiliary method sring_norm; integrated normalizer.ML and normalizer_data.ML
     1 (*  Title:      HOL/Groebner_Basis.thy
     2     Author:     Amine Chaieb, TU Muenchen
     3 *)
     4 
     5 header {* Semiring normalization and Groebner Bases *}
     6 
     7 theory Groebner_Basis
     8 imports Numeral_Simprocs Nat_Transfer
     9 uses
    10   "Tools/Groebner_Basis/normalizer.ML"
    11   ("Tools/Groebner_Basis/groebner.ML")
    12 begin
    13 
    14 subsection {* Semiring normalization *}
    15 
    16 setup Normalizer.setup
    17 
    18 locale gb_semiring =
    19   fixes add mul pwr r0 r1
    20   assumes add_a:"(add x (add y z) = add (add x y) z)"
    21     and add_c: "add x y = add y x" and add_0:"add r0 x = x"
    22     and mul_a:"mul x (mul y z) = mul (mul x y) z" and mul_c:"mul x y = mul y x"
    23     and mul_1:"mul r1 x = x" and  mul_0:"mul r0 x = r0"
    24     and mul_d:"mul x (add y z) = add (mul x y) (mul x z)"
    25     and pwr_0:"pwr x 0 = r1" and pwr_Suc:"pwr x (Suc n) = mul x (pwr x n)"
    26 begin
    27 
    28 lemma mul_pwr:"mul (pwr x p) (pwr x q) = pwr x (p + q)"
    29 proof (induct p)
    30   case 0
    31   then show ?case by (auto simp add: pwr_0 mul_1)
    32 next
    33   case Suc
    34   from this [symmetric] show ?case
    35     by (auto simp add: pwr_Suc mul_1 mul_a)
    36 qed
    37 
    38 lemma pwr_mul: "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    39 proof (induct q arbitrary: x y, auto simp add:pwr_0 pwr_Suc mul_1)
    40   fix q x y
    41   assume "\<And>x y. pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    42   have "mul (mul x y) (mul (pwr x q) (pwr y q)) = mul x (mul y (mul (pwr x q) (pwr y q)))"
    43     by (simp add: mul_a)
    44   also have "\<dots> = (mul (mul y (mul (pwr y q) (pwr x q))) x)" by (simp add: mul_c)
    45   also have "\<dots> = (mul (mul y (pwr y q)) (mul (pwr x q) x))" by (simp add: mul_a)
    46   finally show "mul (mul x y) (mul (pwr x q) (pwr y q)) =
    47     mul (mul x (pwr x q)) (mul y (pwr y q))" by (simp add: mul_c)
    48 qed
    49 
    50 lemma pwr_pwr: "pwr (pwr x p) q = pwr x (p * q)"
    51 proof (induct p arbitrary: q)
    52   case 0
    53   show ?case using pwr_Suc mul_1 pwr_0 by (induct q) auto
    54 next
    55   case Suc
    56   thus ?case by (auto simp add: mul_pwr [symmetric] pwr_mul pwr_Suc)
    57 qed
    58 
    59 
    60 subsubsection {* Declaring the abstract theory *}
    61 
    62 lemma semiring_ops:
    63   shows "TERM (add x y)" and "TERM (mul x y)" and "TERM (pwr x n)"
    64     and "TERM r0" and "TERM r1" .
    65 
    66 lemma semiring_rules:
    67   "add (mul a m) (mul b m) = mul (add a b) m"
    68   "add (mul a m) m = mul (add a r1) m"
    69   "add m (mul a m) = mul (add a r1) m"
    70   "add m m = mul (add r1 r1) m"
    71   "add r0 a = a"
    72   "add a r0 = a"
    73   "mul a b = mul b a"
    74   "mul (add a b) c = add (mul a c) (mul b c)"
    75   "mul r0 a = r0"
    76   "mul a r0 = r0"
    77   "mul r1 a = a"
    78   "mul a r1 = a"
    79   "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
    80   "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
    81   "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
    82   "mul (mul lx ly) rx = mul (mul lx rx) ly"
    83   "mul (mul lx ly) rx = mul lx (mul ly rx)"
    84   "mul lx (mul rx ry) = mul (mul lx rx) ry"
    85   "mul lx (mul rx ry) = mul rx (mul lx ry)"
    86   "add (add a b) (add c d) = add (add a c) (add b d)"
    87   "add (add a b) c = add a (add b c)"
    88   "add a (add c d) = add c (add a d)"
    89   "add (add a b) c = add (add a c) b"
    90   "add a c = add c a"
    91   "add a (add c d) = add (add a c) d"
    92   "mul (pwr x p) (pwr x q) = pwr x (p + q)"
    93   "mul x (pwr x q) = pwr x (Suc q)"
    94   "mul (pwr x q) x = pwr x (Suc q)"
    95   "mul x x = pwr x 2"
    96   "pwr (mul x y) q = mul (pwr x q) (pwr y q)"
    97   "pwr (pwr x p) q = pwr x (p * q)"
    98   "pwr x 0 = r1"
    99   "pwr x 1 = x"
   100   "mul x (add y z) = add (mul x y) (mul x z)"
   101   "pwr x (Suc q) = mul x (pwr x q)"
   102   "pwr x (2*n) = mul (pwr x n) (pwr x n)"
   103   "pwr x (Suc (2*n)) = mul x (mul (pwr x n) (pwr x n))"
   104 proof -
   105   show "add (mul a m) (mul b m) = mul (add a b) m" using mul_d mul_c by simp
   106 next show"add (mul a m) m = mul (add a r1) m" using mul_d mul_c mul_1 by simp
   107 next show "add m (mul a m) = mul (add a r1) m" using mul_c mul_d mul_1 add_c by simp
   108 next show "add m m = mul (add r1 r1) m" using mul_c mul_d mul_1 by simp
   109 next show "add r0 a = a" using add_0 by simp
   110 next show "add a r0 = a" using add_0 add_c by simp
   111 next show "mul a b = mul b a" using mul_c by simp
   112 next show "mul (add a b) c = add (mul a c) (mul b c)" using mul_c mul_d by simp
   113 next show "mul r0 a = r0" using mul_0 by simp
   114 next show "mul a r0 = r0" using mul_0 mul_c by simp
   115 next show "mul r1 a = a" using mul_1 by simp
   116 next show "mul a r1 = a" using mul_1 mul_c by simp
   117 next show "mul (mul lx ly) (mul rx ry) = mul (mul lx rx) (mul ly ry)"
   118     using mul_c mul_a by simp
   119 next show "mul (mul lx ly) (mul rx ry) = mul lx (mul ly (mul rx ry))"
   120     using mul_a by simp
   121 next
   122   have "mul (mul lx ly) (mul rx ry) = mul (mul rx ry) (mul lx ly)" by (rule mul_c)
   123   also have "\<dots> = mul rx (mul ry (mul lx ly))" using mul_a by simp
   124   finally
   125   show "mul (mul lx ly) (mul rx ry) = mul rx (mul (mul lx ly) ry)"
   126     using mul_c by simp
   127 next show "mul (mul lx ly) rx = mul (mul lx rx) ly" using mul_c mul_a by simp
   128 next
   129   show "mul (mul lx ly) rx = mul lx (mul ly rx)" by (simp add: mul_a)
   130 next show "mul lx (mul rx ry) = mul (mul lx rx) ry" by (simp add: mul_a )
   131 next show "mul lx (mul rx ry) = mul rx (mul lx ry)" by (simp add: mul_a,simp add: mul_c)
   132 next show "add (add a b) (add c d) = add (add a c) (add b d)"
   133     using add_c add_a by simp
   134 next show "add (add a b) c = add a (add b c)" using add_a by simp
   135 next show "add a (add c d) = add c (add a d)"
   136     apply (simp add: add_a) by (simp only: add_c)
   137 next show "add (add a b) c = add (add a c) b" using add_a add_c by simp
   138 next show "add a c = add c a" by (rule add_c)
   139 next show "add a (add c d) = add (add a c) d" using add_a by simp
   140 next show "mul (pwr x p) (pwr x q) = pwr x (p + q)" by (rule mul_pwr)
   141 next show "mul x (pwr x q) = pwr x (Suc q)" using pwr_Suc by simp
   142 next show "mul (pwr x q) x = pwr x (Suc q)" using pwr_Suc mul_c by simp
   143 next show "mul x x = pwr x 2" by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   144 next show "pwr (mul x y) q = mul (pwr x q) (pwr y q)" by (rule pwr_mul)
   145 next show "pwr (pwr x p) q = pwr x (p * q)" by (rule pwr_pwr)
   146 next show "pwr x 0 = r1" using pwr_0 .
   147 next show "pwr x 1 = x" unfolding One_nat_def by (simp add: nat_number' pwr_Suc pwr_0 mul_1 mul_c)
   148 next show "mul x (add y z) = add (mul x y) (mul x z)" using mul_d by simp
   149 next show "pwr x (Suc q) = mul x (pwr x q)" using pwr_Suc by simp
   150 next show "pwr x (2 * n) = mul (pwr x n) (pwr x n)" by (simp add: nat_number' mul_pwr)
   151 next show "pwr x (Suc (2 * n)) = mul x (mul (pwr x n) (pwr x n))"
   152     by (simp add: nat_number' pwr_Suc mul_pwr)
   153 qed
   154 
   155 
   156 lemmas gb_semiring_axioms' =
   157   gb_semiring_axioms [normalizer
   158     semiring ops: semiring_ops
   159     semiring rules: semiring_rules]
   160 
   161 end
   162 
   163 interpretation class_semiring: gb_semiring
   164     "op +" "op *" "op ^" "0::'a::{comm_semiring_1}" "1"
   165   proof qed (auto simp add: algebra_simps)
   166 
   167 lemmas nat_arith =
   168   add_nat_number_of
   169   diff_nat_number_of
   170   mult_nat_number_of
   171   eq_nat_number_of
   172   less_nat_number_of
   173 
   174 lemma not_iszero_Numeral1: "\<not> iszero (Numeral1::'a::number_ring)"
   175   by simp
   176 
   177 lemmas comp_arith =
   178   Let_def arith_simps nat_arith rel_simps neg_simps if_False
   179   if_True add_0 add_Suc add_number_of_left mult_number_of_left
   180   numeral_1_eq_1[symmetric] Suc_eq_plus1
   181   numeral_0_eq_0[symmetric] numerals[symmetric]
   182   iszero_simps not_iszero_Numeral1
   183 
   184 lemmas semiring_norm = comp_arith
   185 
   186 ML {*
   187 local
   188 
   189 open Conv;
   190 
   191 fun numeral_is_const ct = can HOLogic.dest_number (Thm.term_of ct);
   192 
   193 fun int_of_rat x =
   194   (case Rat.quotient_of_rat x of (i, 1) => i
   195   | _ => error "int_of_rat: bad int");
   196 
   197 val numeral_conv =
   198   Simplifier.rewrite (HOL_basic_ss addsimps @{thms semiring_norm}) then_conv
   199   Simplifier.rewrite (HOL_basic_ss addsimps
   200     (@{thms numeral_1_eq_1} @ @{thms numeral_0_eq_0} @ @{thms numerals(1-2)}));
   201 
   202 in
   203 
   204 fun normalizer_funs key =
   205   Normalizer.funs key
   206    {is_const = fn phi => numeral_is_const,
   207     dest_const = fn phi => fn ct =>
   208       Rat.rat_of_int (snd
   209         (HOLogic.dest_number (Thm.term_of ct)
   210           handle TERM _ => error "ring_dest_const")),
   211     mk_const = fn phi => fn cT => fn x => Numeral.mk_cnumber cT (int_of_rat x),
   212     conv = fn phi => K numeral_conv}
   213 
   214 end
   215 *}
   216 
   217 declaration {* normalizer_funs @{thm class_semiring.gb_semiring_axioms'} *}
   218 
   219 locale gb_ring = gb_semiring +
   220   fixes sub :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   221     and neg :: "'a \<Rightarrow> 'a"
   222   assumes neg_mul: "neg x = mul (neg r1) x"
   223     and sub_add: "sub x y = add x (neg y)"
   224 begin
   225 
   226 lemma ring_ops: shows "TERM (sub x y)" and "TERM (neg x)" .
   227 
   228 lemmas ring_rules = neg_mul sub_add
   229 
   230 lemmas gb_ring_axioms' =
   231   gb_ring_axioms [normalizer
   232     semiring ops: semiring_ops
   233     semiring rules: semiring_rules
   234     ring ops: ring_ops
   235     ring rules: ring_rules]
   236 
   237 end
   238 
   239 
   240 interpretation class_ring: gb_ring "op +" "op *" "op ^"
   241     "0::'a::{comm_semiring_1,number_ring}" 1 "op -" "uminus"
   242   proof qed simp_all
   243 
   244 
   245 declaration {* normalizer_funs @{thm class_ring.gb_ring_axioms'} *}
   246 
   247 locale gb_field = gb_ring +
   248   fixes divide :: "'a \<Rightarrow> 'a \<Rightarrow> 'a"
   249     and inverse:: "'a \<Rightarrow> 'a"
   250   assumes divide_inverse: "divide x y = mul x (inverse y)"
   251      and inverse_divide: "inverse x = divide r1 x"
   252 begin
   253 
   254 lemma field_ops: shows "TERM (divide x y)" and "TERM (inverse x)" .
   255 
   256 lemmas field_rules = divide_inverse inverse_divide
   257 
   258 lemmas gb_field_axioms' =
   259   gb_field_axioms [normalizer
   260     semiring ops: semiring_ops
   261     semiring rules: semiring_rules
   262     ring ops: ring_ops
   263     ring rules: ring_rules
   264     field ops: field_ops
   265     field rules: field_rules]
   266 
   267 end
   268 
   269 
   270 subsection {* Groebner Bases *}
   271 
   272 locale semiringb = gb_semiring +
   273   assumes add_cancel: "add (x::'a) y = add x z \<longleftrightarrow> y = z"
   274   and add_mul_solve: "add (mul w y) (mul x z) =
   275     add (mul w z) (mul x y) \<longleftrightarrow> w = x \<or> y = z"
   276 begin
   277 
   278 lemma noteq_reduce: "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   279 proof-
   280   have "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> \<not> (a = b \<or> c = d)" by simp
   281   also have "\<dots> \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   282     using add_mul_solve by blast
   283   finally show "a \<noteq> b \<and> c \<noteq> d \<longleftrightarrow> add (mul a c) (mul b d) \<noteq> add (mul a d) (mul b c)"
   284     by simp
   285 qed
   286 
   287 lemma add_scale_eq_noteq: "\<lbrakk>r \<noteq> r0 ; (a = b) \<and> ~(c = d)\<rbrakk>
   288   \<Longrightarrow> add a (mul r c) \<noteq> add b (mul r d)"
   289 proof(clarify)
   290   assume nz: "r\<noteq> r0" and cnd: "c\<noteq>d"
   291     and eq: "add b (mul r c) = add b (mul r d)"
   292   hence "mul r c = mul r d" using cnd add_cancel by simp
   293   hence "add (mul r0 d) (mul r c) = add (mul r0 c) (mul r d)"
   294     using mul_0 add_cancel by simp
   295   thus "False" using add_mul_solve nz cnd by simp
   296 qed
   297 
   298 lemma add_r0_iff: " x = add x a \<longleftrightarrow> a = r0"
   299 proof-
   300   have "a = r0 \<longleftrightarrow> add x a = add x r0" by (simp add: add_cancel)
   301   thus "x = add x a \<longleftrightarrow> a = r0" by (auto simp add: add_c add_0)
   302 qed
   303 
   304 declare gb_semiring_axioms' [normalizer del]
   305 
   306 lemmas semiringb_axioms' = semiringb_axioms [normalizer
   307   semiring ops: semiring_ops
   308   semiring rules: semiring_rules
   309   idom rules: noteq_reduce add_scale_eq_noteq]
   310 
   311 end
   312 
   313 locale ringb = semiringb + gb_ring + 
   314   assumes subr0_iff: "sub x y = r0 \<longleftrightarrow> x = y"
   315 begin
   316 
   317 declare gb_ring_axioms' [normalizer del]
   318 
   319 lemmas ringb_axioms' = ringb_axioms [normalizer
   320   semiring ops: semiring_ops
   321   semiring rules: semiring_rules
   322   ring ops: ring_ops
   323   ring rules: ring_rules
   324   idom rules: noteq_reduce add_scale_eq_noteq
   325   ideal rules: subr0_iff add_r0_iff]
   326 
   327 end
   328 
   329 
   330 lemma no_zero_divirors_neq0:
   331   assumes az: "(a::'a::no_zero_divisors) \<noteq> 0"
   332     and ab: "a*b = 0" shows "b = 0"
   333 proof -
   334   { assume bz: "b \<noteq> 0"
   335     from no_zero_divisors [OF az bz] ab have False by blast }
   336   thus "b = 0" by blast
   337 qed
   338 
   339 interpretation class_ringb: ringb
   340   "op +" "op *" "op ^" "0::'a::{idom,number_ring}" "1" "op -" "uminus"
   341 proof(unfold_locales, simp add: algebra_simps, auto)
   342   fix w x y z ::"'a::{idom,number_ring}"
   343   assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   344   hence ynz': "y - z \<noteq> 0" by simp
   345   from p have "w * y + x* z - w*z - x*y = 0" by simp
   346   hence "w* (y - z) - x * (y - z) = 0" by (simp add: algebra_simps)
   347   hence "(y - z) * (w - x) = 0" by (simp add: algebra_simps)
   348   with  no_zero_divirors_neq0 [OF ynz']
   349   have "w - x = 0" by blast
   350   thus "w = x"  by simp
   351 qed
   352 
   353 declaration {* normalizer_funs @{thm class_ringb.ringb_axioms'} *}
   354 
   355 interpretation natgb: semiringb
   356   "op +" "op *" "op ^" "0::nat" "1"
   357 proof (unfold_locales, simp add: algebra_simps)
   358   fix w x y z ::"nat"
   359   { assume p: "w * y + x * z = w * z + x * y" and ynz: "y \<noteq> z"
   360     hence "y < z \<or> y > z" by arith
   361     moreover {
   362       assume lt:"y <z" hence "\<exists>k. z = y + k \<and> k > 0" by (rule_tac x="z - y" in exI, auto)
   363       then obtain k where kp: "k>0" and yz:"z = y + k" by blast
   364       from p have "(w * y + x *y) + x*k = (w * y + x*y) + w*k" by (simp add: yz algebra_simps)
   365       hence "x*k = w*k" by simp
   366       hence "w = x" using kp by simp }
   367     moreover {
   368       assume lt: "y >z" hence "\<exists>k. y = z + k \<and> k>0" by (rule_tac x="y - z" in exI, auto)
   369       then obtain k where kp: "k>0" and yz:"y = z + k" by blast
   370       from p have "(w * z + x *z) + w*k = (w * z + x*z) + x*k" by (simp add: yz algebra_simps)
   371       hence "w*k = x*k" by simp
   372       hence "w = x" using kp by simp }
   373     ultimately have "w=x" by blast }
   374   thus "(w * y + x * z = w * z + x * y) = (w = x \<or> y = z)" by auto
   375 qed
   376 
   377 declaration {* normalizer_funs @{thm natgb.semiringb_axioms'} *}
   378 
   379 locale fieldgb = ringb + gb_field
   380 begin
   381 
   382 declare gb_field_axioms' [normalizer del]
   383 
   384 lemmas fieldgb_axioms' = fieldgb_axioms [normalizer
   385   semiring ops: semiring_ops
   386   semiring rules: semiring_rules
   387   ring ops: ring_ops
   388   ring rules: ring_rules
   389   field ops: field_ops
   390   field rules: field_rules
   391   idom rules: noteq_reduce add_scale_eq_noteq
   392   ideal rules: subr0_iff add_r0_iff]
   393 
   394 end
   395 
   396 
   397 lemmas bool_simps = simp_thms(1-34)
   398 lemma dnf:
   399     "(P & (Q | R)) = ((P&Q) | (P&R))" "((Q | R) & P) = ((Q&P) | (R&P))"
   400     "(P \<and> Q) = (Q \<and> P)" "(P \<or> Q) = (Q \<or> P)"
   401   by blast+
   402 
   403 lemmas weak_dnf_simps = dnf bool_simps
   404 
   405 lemma nnf_simps:
   406     "(\<not>(P \<and> Q)) = (\<not>P \<or> \<not>Q)" "(\<not>(P \<or> Q)) = (\<not>P \<and> \<not>Q)" "(P \<longrightarrow> Q) = (\<not>P \<or> Q)"
   407     "(P = Q) = ((P \<and> Q) \<or> (\<not>P \<and> \<not> Q))" "(\<not> \<not>(P)) = P"
   408   by blast+
   409 
   410 lemma PFalse:
   411     "P \<equiv> False \<Longrightarrow> \<not> P"
   412     "\<not> P \<Longrightarrow> (P \<equiv> False)"
   413   by auto
   414 
   415 use "Tools/Groebner_Basis/groebner.ML"
   416 
   417 method_setup algebra =
   418 {*
   419 let
   420  fun keyword k = Scan.lift (Args.$$$ k -- Args.colon) >> K ()
   421  val addN = "add"
   422  val delN = "del"
   423  val any_keyword = keyword addN || keyword delN
   424  val thms = Scan.repeat (Scan.unless any_keyword Attrib.multi_thm) >> flat;
   425 in
   426   ((Scan.optional (keyword addN |-- thms) []) -- 
   427    (Scan.optional (keyword delN |-- thms) [])) >>
   428   (fn (add_ths, del_ths) => fn ctxt =>
   429        SIMPLE_METHOD' (Groebner.algebra_tac add_ths del_ths ctxt))
   430 end
   431 *} "solve polynomial equations over (semi)rings and ideal membership problems using Groebner bases"
   432 declare dvd_def[algebra]
   433 declare dvd_eq_mod_eq_0[symmetric, algebra]
   434 declare mod_div_trivial[algebra]
   435 declare mod_mod_trivial[algebra]
   436 declare conjunct1[OF DIVISION_BY_ZERO, algebra]
   437 declare conjunct2[OF DIVISION_BY_ZERO, algebra]
   438 declare zmod_zdiv_equality[symmetric,algebra]
   439 declare zdiv_zmod_equality[symmetric, algebra]
   440 declare zdiv_zminus_zminus[algebra]
   441 declare zmod_zminus_zminus[algebra]
   442 declare zdiv_zminus2[algebra]
   443 declare zmod_zminus2[algebra]
   444 declare zdiv_zero[algebra]
   445 declare zmod_zero[algebra]
   446 declare mod_by_1[algebra]
   447 declare div_by_1[algebra]
   448 declare zmod_minus1_right[algebra]
   449 declare zdiv_minus1_right[algebra]
   450 declare mod_div_trivial[algebra]
   451 declare mod_mod_trivial[algebra]
   452 declare mod_mult_self2_is_0[algebra]
   453 declare mod_mult_self1_is_0[algebra]
   454 declare zmod_eq_0_iff[algebra]
   455 declare dvd_0_left_iff[algebra]
   456 declare zdvd1_eq[algebra]
   457 declare zmod_eq_dvd_iff[algebra]
   458 declare nat_mod_eq_iff[algebra]
   459 
   460 subsection{* Groebner Bases for fields *}
   461 
   462 interpretation class_fieldgb:
   463   fieldgb "op +" "op *" "op ^" "0::'a::{field,number_ring}" "1" "op -" "uminus" "op /" "inverse" apply (unfold_locales) by (simp_all add: divide_inverse)
   464 
   465 lemma divide_Numeral1: "(x::'a::{field, number_ring}) / Numeral1 = x" by simp
   466 lemma divide_Numeral0: "(x::'a::{field_inverse_zero, number_ring}) / Numeral0 = 0"
   467   by simp
   468 lemma mult_frac_frac: "((x::'a::field_inverse_zero) / y) * (z / w) = (x*z) / (y*w)"
   469   by simp
   470 lemma mult_frac_num: "((x::'a::field_inverse_zero) / y) * z  = (x*z) / y"
   471   by simp
   472 lemma mult_num_frac: "((x::'a::field_inverse_zero) / y) * z  = (x*z) / y"
   473   by simp
   474 
   475 lemma Numeral1_eq1_nat: "(1::nat) = Numeral1" by simp
   476 
   477 lemma add_frac_num: "y\<noteq> 0 \<Longrightarrow> (x::'a::field_inverse_zero) / y + z = (x + z*y) / y"
   478   by (simp add: add_divide_distrib)
   479 lemma add_num_frac: "y\<noteq> 0 \<Longrightarrow> z + (x::'a::field_inverse_zero) / y = (x + z*y) / y"
   480   by (simp add: add_divide_distrib)
   481 
   482 ML {*
   483 let open Conv
   484 in fconv_rule (arg_conv (arg1_conv (rewr_conv (mk_meta_eq @{thm mult_commute})))) (@{thm field_divide_inverse} RS sym)
   485 end
   486 *}
   487 
   488 ML{* 
   489 local
   490  val zr = @{cpat "0"}
   491  val zT = ctyp_of_term zr
   492  val geq = @{cpat "op ="}
   493  val eqT = Thm.dest_ctyp (ctyp_of_term geq) |> hd
   494  val add_frac_eq = mk_meta_eq @{thm "add_frac_eq"}
   495  val add_frac_num = mk_meta_eq @{thm "add_frac_num"}
   496  val add_num_frac = mk_meta_eq @{thm "add_num_frac"}
   497 
   498  fun prove_nz ss T t =
   499     let
   500       val z = instantiate_cterm ([(zT,T)],[]) zr
   501       val eq = instantiate_cterm ([(eqT,T)],[]) geq
   502       val th = Simplifier.rewrite (ss addsimps @{thms simp_thms})
   503            (Thm.capply @{cterm "Trueprop"} (Thm.capply @{cterm "Not"}
   504                   (Thm.capply (Thm.capply eq t) z)))
   505     in equal_elim (symmetric th) TrueI
   506     end
   507 
   508  fun proc phi ss ct =
   509   let
   510     val ((x,y),(w,z)) =
   511          (Thm.dest_binop #> (fn (a,b) => (Thm.dest_binop a, Thm.dest_binop b))) ct
   512     val _ = map (HOLogic.dest_number o term_of) [x,y,z,w]
   513     val T = ctyp_of_term x
   514     val [y_nz, z_nz] = map (prove_nz ss T) [y, z]
   515     val th = instantiate' [SOME T] (map SOME [y,z,x,w]) add_frac_eq
   516   in SOME (implies_elim (implies_elim th y_nz) z_nz)
   517   end
   518   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   519 
   520  fun proc2 phi ss ct =
   521   let
   522     val (l,r) = Thm.dest_binop ct
   523     val T = ctyp_of_term l
   524   in (case (term_of l, term_of r) of
   525       (Const(@{const_name Rings.divide},_)$_$_, _) =>
   526         let val (x,y) = Thm.dest_binop l val z = r
   527             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   528             val ynz = prove_nz ss T y
   529         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,x,z]) add_frac_num) ynz)
   530         end
   531      | (_, Const (@{const_name Rings.divide},_)$_$_) =>
   532         let val (x,y) = Thm.dest_binop r val z = l
   533             val _ = map (HOLogic.dest_number o term_of) [x,y,z]
   534             val ynz = prove_nz ss T y
   535         in SOME (implies_elim (instantiate' [SOME T] (map SOME [y,z,x]) add_num_frac) ynz)
   536         end
   537      | _ => NONE)
   538   end
   539   handle CTERM _ => NONE | TERM _ => NONE | THM _ => NONE
   540 
   541  fun is_number (Const(@{const_name Rings.divide},_)$a$b) = is_number a andalso is_number b
   542    | is_number t = can HOLogic.dest_number t
   543 
   544  val is_number = is_number o term_of
   545 
   546  fun proc3 phi ss ct =
   547   (case term_of ct of
   548     Const(@{const_name Orderings.less},_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   549       let
   550         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   551         val _ = map is_number [a,b,c]
   552         val T = ctyp_of_term c
   553         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_less_eq"}
   554       in SOME (mk_meta_eq th) end
   555   | Const(@{const_name Orderings.less_eq},_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   556       let
   557         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   558         val _ = map is_number [a,b,c]
   559         val T = ctyp_of_term c
   560         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_le_eq"}
   561       in SOME (mk_meta_eq th) end
   562   | Const("op =",_)$(Const(@{const_name Rings.divide},_)$_$_)$_ =>
   563       let
   564         val ((a,b),c) = Thm.dest_binop ct |>> Thm.dest_binop
   565         val _ = map is_number [a,b,c]
   566         val T = ctyp_of_term c
   567         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "divide_eq_eq"}
   568       in SOME (mk_meta_eq th) end
   569   | Const(@{const_name Orderings.less},_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   570     let
   571       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   572         val _ = map is_number [a,b,c]
   573         val T = ctyp_of_term c
   574         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "less_divide_eq"}
   575       in SOME (mk_meta_eq th) end
   576   | Const(@{const_name Orderings.less_eq},_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   577     let
   578       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   579         val _ = map is_number [a,b,c]
   580         val T = ctyp_of_term c
   581         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "le_divide_eq"}
   582       in SOME (mk_meta_eq th) end
   583   | Const("op =",_)$_$(Const(@{const_name Rings.divide},_)$_$_) =>
   584     let
   585       val (a,(b,c)) = Thm.dest_binop ct ||> Thm.dest_binop
   586         val _ = map is_number [a,b,c]
   587         val T = ctyp_of_term c
   588         val th = instantiate' [SOME T] (map SOME [a,b,c]) @{thm "eq_divide_eq"}
   589       in SOME (mk_meta_eq th) end
   590   | _ => NONE)
   591   handle TERM _ => NONE | CTERM _ => NONE | THM _ => NONE
   592 
   593 val add_frac_frac_simproc =
   594        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + (?w::?'a::field)/?z"}],
   595                      name = "add_frac_frac_simproc",
   596                      proc = proc, identifier = []}
   597 
   598 val add_frac_num_simproc =
   599        make_simproc {lhss = [@{cpat "(?x::?'a::field)/?y + ?z"}, @{cpat "?z + (?x::?'a::field)/?y"}],
   600                      name = "add_frac_num_simproc",
   601                      proc = proc2, identifier = []}
   602 
   603 val ord_frac_simproc =
   604   make_simproc
   605     {lhss = [@{cpat "(?a::(?'a::{field, ord}))/?b < ?c"},
   606              @{cpat "(?a::(?'a::{field, ord}))/?b \<le> ?c"},
   607              @{cpat "?c < (?a::(?'a::{field, ord}))/?b"},
   608              @{cpat "?c \<le> (?a::(?'a::{field, ord}))/?b"},
   609              @{cpat "?c = ((?a::(?'a::{field, ord}))/?b)"},
   610              @{cpat "((?a::(?'a::{field, ord}))/ ?b) = ?c"}],
   611              name = "ord_frac_simproc", proc = proc3, identifier = []}
   612 
   613 local
   614 open Conv
   615 in
   616 
   617 val ths = [@{thm "mult_numeral_1"}, @{thm "mult_numeral_1_right"},
   618            @{thm "divide_Numeral1"},
   619            @{thm "divide_zero"}, @{thm "divide_Numeral0"},
   620            @{thm "divide_divide_eq_left"}, @{thm "mult_frac_frac"},
   621            @{thm "mult_num_frac"}, @{thm "mult_frac_num"},
   622            @{thm "mult_frac_frac"}, @{thm "times_divide_eq_right"},
   623            @{thm "times_divide_eq_left"}, @{thm "divide_divide_eq_right"},
   624            @{thm "diff_def"}, @{thm "minus_divide_left"},
   625            @{thm "Numeral1_eq1_nat"}, @{thm "add_divide_distrib"} RS sym,
   626            @{thm field_divide_inverse} RS sym, @{thm inverse_divide}, 
   627            fconv_rule (arg_conv (arg1_conv (rewr_conv (mk_meta_eq @{thm mult_commute}))))   
   628            (@{thm field_divide_inverse} RS sym)]
   629 
   630 val comp_conv = (Simplifier.rewrite
   631 (HOL_basic_ss addsimps @{thms "Groebner_Basis.comp_arith"}
   632               addsimps ths addsimps @{thms simp_thms}
   633               addsimprocs Numeral_Simprocs.field_cancel_numeral_factors
   634                addsimprocs [add_frac_frac_simproc, add_frac_num_simproc,
   635                             ord_frac_simproc]
   636                 addcongs [@{thm "if_weak_cong"}]))
   637 then_conv (Simplifier.rewrite (HOL_basic_ss addsimps
   638   [@{thm numeral_1_eq_1},@{thm numeral_0_eq_0}] @ @{thms numerals(1-2)}))
   639 end
   640 
   641 fun numeral_is_const ct =
   642   case term_of ct of
   643    Const (@{const_name Rings.divide},_) $ a $ b =>
   644      can HOLogic.dest_number a andalso can HOLogic.dest_number b
   645  | Const (@{const_name Rings.inverse},_)$t => can HOLogic.dest_number t
   646  | t => can HOLogic.dest_number t
   647 
   648 fun dest_const ct = ((case term_of ct of
   649    Const (@{const_name Rings.divide},_) $ a $ b=>
   650     Rat.rat_of_quotient (snd (HOLogic.dest_number a), snd (HOLogic.dest_number b))
   651  | Const (@{const_name Rings.inverse},_)$t => 
   652                Rat.inv (Rat.rat_of_int (snd (HOLogic.dest_number t)))
   653  | t => Rat.rat_of_int (snd (HOLogic.dest_number t))) 
   654    handle TERM _ => error "ring_dest_const")
   655 
   656 fun mk_const phi cT x =
   657  let val (a, b) = Rat.quotient_of_rat x
   658  in if b = 1 then Numeral.mk_cnumber cT a
   659     else Thm.capply
   660          (Thm.capply (Drule.cterm_rule (instantiate' [SOME cT] []) @{cpat "op /"})
   661                      (Numeral.mk_cnumber cT a))
   662          (Numeral.mk_cnumber cT b)
   663   end
   664 
   665 in
   666  val field_comp_conv = comp_conv;
   667  val fieldgb_declaration = 
   668   Normalizer.funs @{thm class_fieldgb.fieldgb_axioms'}
   669    {is_const = K numeral_is_const,
   670     dest_const = K dest_const,
   671     mk_const = mk_const,
   672     conv = K (K comp_conv)}
   673 end;
   674 *}
   675 
   676 declaration fieldgb_declaration
   677 
   678 end