src/Pure/defs.ML
author wenzelm
Sun Nov 11 20:31:46 2012 +0100 (2012-11-11)
changeset 50081 9b92ee8dec98
parent 42389 b2c6033fc7e4
child 55544 cf1baba89a27
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/defs.ML
     2     Author:     Makarius
     3 
     4 Global well-formedness checks for constant definitions.  Covers plain
     5 definitions and simple sub-structural overloading.
     6 *)
     7 
     8 signature DEFS =
     9 sig
    10   val pretty_const: Proof.context -> string * typ list -> Pretty.T
    11   val plain_args: typ list -> bool
    12   type T
    13   type spec =
    14     {def: string option, description: string, lhs: typ list, rhs: (string * typ list) list}
    15   val all_specifications_of: T -> (string * spec list) list
    16   val specifications_of: T -> string -> spec list
    17   val dest: T ->
    18    {restricts: ((string * typ list) * string) list,
    19     reducts: ((string * typ list) * (string * typ list) list) list}
    20   val empty: T
    21   val merge: Proof.context -> T * T -> T
    22   val define: Proof.context -> bool -> string option -> string ->
    23     string * typ list -> (string * typ list) list -> T -> T
    24 end
    25 
    26 structure Defs: DEFS =
    27 struct
    28 
    29 (* type arguments *)
    30 
    31 type args = typ list;
    32 
    33 fun pretty_const ctxt (c, args) =
    34   let
    35     val prt_args =
    36       if null args then []
    37       else [Pretty.list "(" ")" (map (Syntax.pretty_typ ctxt o Logic.unvarifyT_global) args)];
    38   in Pretty.block (Pretty.str c :: prt_args) end;
    39 
    40 fun plain_args args =
    41   forall Term.is_TVar args andalso not (has_duplicates (op =) args);
    42 
    43 fun disjoint_args (Ts, Us) =
    44   not (Type.could_unifys (Ts, Us)) orelse
    45     ((Type.raw_unifys (Ts, map (Logic.incr_tvar (maxidx_of_typs Ts + 1)) Us) Vartab.empty; false)
    46       handle Type.TUNIFY => true);
    47 
    48 fun match_args (Ts, Us) =
    49   Option.map Envir.subst_type
    50     (SOME (Type.raw_matches (Ts, Us) Vartab.empty) handle Type.TYPE_MATCH => NONE);
    51 
    52 
    53 (* datatype defs *)
    54 
    55 type spec =
    56   {def: string option, description: string, lhs: args, rhs: (string * args) list};
    57 
    58 type def =
    59  {specs: spec Inttab.table,                 (*source specifications*)
    60   restricts: (args * string) list,          (*global restrictions imposed by incomplete patterns*)
    61   reducts: (args * (string * args) list) list};  (*specifications as reduction system*)
    62 
    63 fun make_def (specs, restricts, reducts) =
    64   {specs = specs, restricts = restricts, reducts = reducts}: def;
    65 
    66 fun map_def c f =
    67   Symtab.default (c, make_def (Inttab.empty, [], [])) #>
    68   Symtab.map_entry c (fn {specs, restricts, reducts}: def =>
    69     make_def (f (specs, restricts, reducts)));
    70 
    71 
    72 datatype T = Defs of def Symtab.table;
    73 
    74 fun lookup_list which defs c =
    75   (case Symtab.lookup defs c of
    76     SOME (def: def) => which def
    77   | NONE => []);
    78 
    79 fun all_specifications_of (Defs defs) =
    80   (map o apsnd) (map snd o Inttab.dest o #specs) (Symtab.dest defs);
    81 
    82 fun specifications_of (Defs defs) = lookup_list (map snd o Inttab.dest o #specs) defs;
    83 
    84 val restricts_of = lookup_list #restricts;
    85 val reducts_of = lookup_list #reducts;
    86 
    87 fun dest (Defs defs) =
    88   let
    89     val restricts = Symtab.fold (fn (c, {restricts, ...}) =>
    90       fold (fn (args, description) => cons ((c, args), description)) restricts) defs [];
    91     val reducts = Symtab.fold (fn (c, {reducts, ...}) =>
    92       fold (fn (args, deps) => cons ((c, args), deps)) reducts) defs [];
    93   in {restricts = restricts, reducts = reducts} end;
    94 
    95 val empty = Defs Symtab.empty;
    96 
    97 
    98 (* specifications *)
    99 
   100 fun disjoint_specs c (i, {lhs = Ts, description = a, ...}: spec) =
   101   Inttab.forall (fn (j, {lhs = Us, description = b, ...}: spec) =>
   102     i = j orelse disjoint_args (Ts, Us) orelse
   103       error ("Clash of specifications " ^ quote a ^ " and " ^ quote b ^
   104         " for constant " ^ quote c));
   105 
   106 fun join_specs c ({specs = specs1, restricts, reducts}, {specs = specs2, ...}: def) =
   107   let
   108     val specs' =
   109       Inttab.fold (fn spec2 => (disjoint_specs c spec2 specs1; Inttab.update spec2)) specs2 specs1;
   110   in make_def (specs', restricts, reducts) end;
   111 
   112 fun update_specs c spec = map_def c (fn (specs, restricts, reducts) =>
   113   (disjoint_specs c spec specs; (Inttab.update spec specs, restricts, reducts)));
   114 
   115 
   116 (* normalized dependencies: reduction with well-formedness check *)
   117 
   118 local
   119 
   120 val prt = Pretty.string_of oo pretty_const;
   121 fun err ctxt (c, args) (d, Us) s1 s2 =
   122   error (s1 ^ " dependency of constant " ^ prt ctxt (c, args) ^ " -> " ^ prt ctxt (d, Us) ^ s2);
   123 
   124 fun contained (U as TVar _) (Type (_, Ts)) = exists (fn T => T = U orelse contained U T) Ts
   125   | contained _ _ = false;
   126 
   127 fun acyclic ctxt (c, args) (d, Us) =
   128   c <> d orelse
   129   exists (fn U => exists (contained U) args) Us orelse
   130   is_none (match_args (args, Us)) orelse
   131   err ctxt (c, args) (d, Us) "Circular" "";
   132 
   133 fun wellformed ctxt defs (c, args) (d, Us) =
   134   forall is_TVar Us orelse
   135   (case find_first (fn (Ts, _) => not (disjoint_args (Ts, Us))) (restricts_of defs d) of
   136     SOME (Ts, description) =>
   137       err ctxt (c, args) (d, Us) "Malformed"
   138         ("\n(restriction " ^ prt ctxt (d, Ts) ^ " from " ^ quote description ^ ")")
   139   | NONE => true);
   140 
   141 fun reduction ctxt defs const deps =
   142   let
   143     fun reduct Us (Ts, rhs) =
   144       (case match_args (Ts, Us) of
   145         NONE => NONE
   146       | SOME subst => SOME (map (apsnd (map subst)) rhs));
   147     fun reducts (d, Us) = get_first (reduct Us) (reducts_of defs d);
   148 
   149     val reds = map (`reducts) deps;
   150     val deps' =
   151       if forall (is_none o #1) reds then NONE
   152       else SOME (fold_rev
   153         (fn (NONE, dp) => insert (op =) dp | (SOME dps, _) => fold (insert (op =)) dps) reds []);
   154     val _ = forall (acyclic ctxt const) (the_default deps deps');
   155   in deps' end;
   156 
   157 in
   158 
   159 fun normalize ctxt =
   160   let
   161     fun norm_update (c, {reducts, ...}: def) (changed, defs) =
   162       let
   163         val reducts' = reducts |> map (fn (args, deps) =>
   164           (args, perhaps (reduction ctxt defs (c, args)) deps));
   165       in
   166         if reducts = reducts' then (changed, defs)
   167         else (true, defs |> map_def c (fn (specs, restricts, _) => (specs, restricts, reducts')))
   168       end;
   169     fun norm_all defs =
   170       (case Symtab.fold norm_update defs (false, defs) of
   171         (true, defs') => norm_all defs'
   172       | (false, _) => defs);
   173     fun check defs (c, {reducts, ...}: def) =
   174       reducts |> forall (fn (args, deps) => forall (wellformed ctxt defs (c, args)) deps);
   175   in norm_all #> (fn defs => tap (Symtab.forall (check defs)) defs) end;
   176 
   177 fun dependencies ctxt (c, args) restr deps =
   178   map_def c (fn (specs, restricts, reducts) =>
   179     let
   180       val restricts' = Library.merge (op =) (restricts, restr);
   181       val reducts' = insert (op =) (args, deps) reducts;
   182     in (specs, restricts', reducts') end)
   183   #> normalize ctxt;
   184 
   185 end;
   186 
   187 
   188 (* merge *)
   189 
   190 fun merge ctxt (Defs defs1, Defs defs2) =
   191   let
   192     fun add_deps (c, args) restr deps defs =
   193       if AList.defined (op =) (reducts_of defs c) args then defs
   194       else dependencies ctxt (c, args) restr deps defs;
   195     fun add_def (c, {restricts, reducts, ...}: def) =
   196       fold (fn (args, deps) => add_deps (c, args) restricts deps) reducts;
   197   in
   198     Defs (Symtab.join join_specs (defs1, defs2)
   199       |> normalize ctxt |> Symtab.fold add_def defs2)
   200   end;
   201 
   202 
   203 (* define *)
   204 
   205 fun define ctxt unchecked def description (c, args) deps (Defs defs) =
   206   let
   207     val restr =
   208       if plain_args args orelse
   209         (case args of [Type (_, rec_args)] => plain_args rec_args | _ => false)
   210       then [] else [(args, description)];
   211     val spec =
   212       (serial (), {def = def, description = description, lhs = args, rhs = deps});
   213     val defs' = defs |> update_specs c spec;
   214   in Defs (defs' |> (if unchecked then I else dependencies ctxt (c, args) restr deps)) end;
   215 
   216 end;