src/Pure/raw_simplifier.ML
author wenzelm
Sun Nov 11 20:31:46 2012 +0100 (2012-11-11)
changeset 50081 9b92ee8dec98
parent 49660 de49d9b4d7bc
child 51590 c52891242de2
permissions -rw-r--r--
tuned;
     1 (*  Title:      Pure/raw_simplifier.ML
     2     Author:     Tobias Nipkow and Stefan Berghofer, TU Muenchen
     3 
     4 Higher-order Simplification.
     5 *)
     6 
     7 infix 4
     8   addsimps delsimps addsimprocs delsimprocs
     9   setloop' setloop addloop addloop' delloop
    10   setSSolver addSSolver setSolver addSolver;
    11 
    12 signature BASIC_RAW_SIMPLIFIER =
    13 sig
    14   val simp_depth_limit: int Config.T
    15   val simp_trace_depth_limit: int Config.T
    16   val simp_debug: bool Config.T
    17   val simp_trace: bool Config.T
    18   type rrule
    19   val eq_rrule: rrule * rrule -> bool
    20   type simpset
    21   type proc
    22   type solver
    23   val mk_solver: string -> (simpset -> int -> tactic) -> solver
    24   val empty_ss: simpset
    25   val merge_ss: simpset * simpset -> simpset
    26   val dest_ss: simpset ->
    27    {simps: (string * thm) list,
    28     procs: (string * cterm list) list,
    29     congs: (string * thm) list,
    30     weak_congs: string list,
    31     loopers: string list,
    32     unsafe_solvers: string list,
    33     safe_solvers: string list}
    34   type simproc
    35   val eq_simproc: simproc * simproc -> bool
    36   val transform_simproc: morphism -> simproc -> simproc
    37   val make_simproc: {name: string, lhss: cterm list,
    38     proc: morphism -> simpset -> cterm -> thm option, identifier: thm list} -> simproc
    39   val mk_simproc: string -> cterm list -> (theory -> simpset -> term -> thm option) -> simproc
    40   val addsimps: simpset * thm list -> simpset
    41   val delsimps: simpset * thm list -> simpset
    42   val addsimprocs: simpset * simproc list -> simpset
    43   val delsimprocs: simpset * simproc list -> simpset
    44   val setloop': simpset * (simpset -> int -> tactic) -> simpset
    45   val setloop: simpset * (int -> tactic) -> simpset
    46   val addloop': simpset * (string * (simpset -> int -> tactic)) -> simpset
    47   val addloop: simpset * (string * (int -> tactic)) -> simpset
    48   val delloop: simpset * string -> simpset
    49   val setSSolver: simpset * solver -> simpset
    50   val addSSolver: simpset * solver -> simpset
    51   val setSolver: simpset * solver -> simpset
    52   val addSolver: simpset * solver -> simpset
    53 
    54   val rewrite_rule: thm list -> thm -> thm
    55   val rewrite_goals_rule: thm list -> thm -> thm
    56   val rewrite_goals_tac: thm list -> tactic
    57   val rewrite_goal_tac: thm list -> int -> tactic
    58   val prune_params_tac: tactic
    59   val fold_rule: thm list -> thm -> thm
    60   val fold_goals_tac: thm list -> tactic
    61   val norm_hhf: thm -> thm
    62   val norm_hhf_protect: thm -> thm
    63 end;
    64 
    65 signature RAW_SIMPLIFIER =
    66 sig
    67   include BASIC_RAW_SIMPLIFIER
    68   exception SIMPLIFIER of string * thm
    69   val internal_ss: simpset ->
    70    {rules: rrule Net.net,
    71     prems: thm list,
    72     bounds: int * ((string * typ) * string) list,
    73     depth: int * bool Unsynchronized.ref,
    74     context: Proof.context option} *
    75    {congs: (string * thm) list * string list,
    76     procs: proc Net.net,
    77     mk_rews:
    78      {mk: simpset -> thm -> thm list,
    79       mk_cong: simpset -> thm -> thm,
    80       mk_sym: simpset -> thm -> thm option,
    81       mk_eq_True: simpset -> thm -> thm option,
    82       reorient: theory -> term list -> term -> term -> bool},
    83     termless: term * term -> bool,
    84     subgoal_tac: simpset -> int -> tactic,
    85     loop_tacs: (string * (simpset -> int -> tactic)) list,
    86     solvers: solver list * solver list}
    87   val prems_of: simpset -> thm list
    88   val add_simp: thm -> simpset -> simpset
    89   val del_simp: thm -> simpset -> simpset
    90   val add_eqcong: thm -> simpset -> simpset
    91   val del_eqcong: thm -> simpset -> simpset
    92   val add_cong: thm -> simpset -> simpset
    93   val del_cong: thm -> simpset -> simpset
    94   val mksimps: simpset -> thm -> thm list
    95   val set_mksimps: (simpset -> thm -> thm list) -> simpset -> simpset
    96   val set_mkcong: (simpset -> thm -> thm) -> simpset -> simpset
    97   val set_mksym: (simpset -> thm -> thm option) -> simpset -> simpset
    98   val set_mkeqTrue: (simpset -> thm -> thm option) -> simpset -> simpset
    99   val set_termless: (term * term -> bool) -> simpset -> simpset
   100   val set_subgoaler: (simpset -> int -> tactic) -> simpset -> simpset
   101   val solver: simpset -> solver -> int -> tactic
   102   val simp_depth_limit_raw: Config.raw
   103   val clear_ss: simpset -> simpset
   104   val default_mk_sym: simpset -> thm -> thm option
   105   val simproc_global_i: theory -> string -> term list
   106     -> (theory -> simpset -> term -> thm option) -> simproc
   107   val simproc_global: theory -> string -> string list
   108     -> (theory -> simpset -> term -> thm option) -> simproc
   109   val simp_trace_depth_limit_raw: Config.raw
   110   val simp_trace_depth_limit_default: int Unsynchronized.ref
   111   val simp_trace_default: bool Unsynchronized.ref
   112   val simp_trace_raw: Config.raw
   113   val simp_debug_raw: Config.raw
   114   val add_prems: thm list -> simpset -> simpset
   115   val inherit_context: simpset -> simpset -> simpset
   116   val the_context: simpset -> Proof.context
   117   val context: Proof.context -> simpset -> simpset
   118   val global_context: theory -> simpset -> simpset
   119   val with_context: Proof.context -> (simpset -> simpset) -> simpset -> simpset
   120   val debug_bounds: bool Unsynchronized.ref
   121   val set_reorient: (theory -> term list -> term -> term -> bool) -> simpset -> simpset
   122   val set_solvers: solver list -> simpset -> simpset
   123   val rewrite_cterm: bool * bool * bool -> (simpset -> thm -> thm option) -> simpset -> conv
   124   val rewrite_term: theory -> thm list -> (term -> term option) list -> term -> term
   125   val rewrite_thm: bool * bool * bool ->
   126     (simpset -> thm -> thm option) -> simpset -> thm -> thm
   127   val generic_rewrite_goal_tac: bool * bool * bool ->
   128     (simpset -> tactic) -> simpset -> int -> tactic
   129   val rewrite: bool -> thm list -> conv
   130   val simplify: bool -> thm list -> thm -> thm
   131 end;
   132 
   133 structure Raw_Simplifier: RAW_SIMPLIFIER =
   134 struct
   135 
   136 (** datatype simpset **)
   137 
   138 (* rewrite rules *)
   139 
   140 type rrule =
   141  {thm: thm,         (*the rewrite rule*)
   142   name: string,     (*name of theorem from which rewrite rule was extracted*)
   143   lhs: term,        (*the left-hand side*)
   144   elhs: cterm,      (*the etac-contracted lhs*)
   145   extra: bool,      (*extra variables outside of elhs*)
   146   fo: bool,         (*use first-order matching*)
   147   perm: bool};      (*the rewrite rule is permutative*)
   148 
   149 (*
   150 Remarks:
   151   - elhs is used for matching,
   152     lhs only for preservation of bound variable names;
   153   - fo is set iff
   154     either elhs is first-order (no Var is applied),
   155       in which case fo-matching is complete,
   156     or elhs is not a pattern,
   157       in which case there is nothing better to do;
   158 *)
   159 
   160 fun eq_rrule ({thm = thm1, ...}: rrule, {thm = thm2, ...}: rrule) =
   161   Thm.eq_thm_prop (thm1, thm2);
   162 
   163 
   164 (* simplification sets, procedures, and solvers *)
   165 
   166 (*A simpset contains data required during conversion:
   167     rules: discrimination net of rewrite rules;
   168     prems: current premises;
   169     bounds: maximal index of bound variables already used
   170       (for generating new names when rewriting under lambda abstractions);
   171     depth: simp_depth and exceeded flag;
   172     congs: association list of congruence rules and
   173            a list of `weak' congruence constants.
   174            A congruence is `weak' if it avoids normalization of some argument.
   175     procs: discrimination net of simplification procedures
   176       (functions that prove rewrite rules on the fly);
   177     mk_rews:
   178       mk: turn simplification thms into rewrite rules;
   179       mk_cong: prepare congruence rules;
   180       mk_sym: turn == around;
   181       mk_eq_True: turn P into P == True;
   182     termless: relation for ordered rewriting;*)
   183 
   184 datatype simpset =
   185   Simpset of
   186    {rules: rrule Net.net,
   187     prems: thm list,
   188     bounds: int * ((string * typ) * string) list,
   189     depth: int * bool Unsynchronized.ref,
   190     context: Proof.context option} *
   191    {congs: (string * thm) list * string list,
   192     procs: proc Net.net,
   193     mk_rews:
   194      {mk: simpset -> thm -> thm list,
   195       mk_cong: simpset -> thm -> thm,
   196       mk_sym: simpset -> thm -> thm option,
   197       mk_eq_True: simpset -> thm -> thm option,
   198       reorient: theory -> term list -> term -> term -> bool},
   199     termless: term * term -> bool,
   200     subgoal_tac: simpset -> int -> tactic,
   201     loop_tacs: (string * (simpset -> int -> tactic)) list,
   202     solvers: solver list * solver list}
   203 and proc =
   204   Proc of
   205    {name: string,
   206     lhs: cterm,
   207     proc: simpset -> cterm -> thm option,
   208     id: stamp * thm list}
   209 and solver =
   210   Solver of
   211    {name: string,
   212     solver: simpset -> int -> tactic,
   213     id: stamp};
   214 
   215 
   216 fun internal_ss (Simpset args) = args;
   217 
   218 fun make_ss1 (rules, prems, bounds, depth, context) =
   219   {rules = rules, prems = prems, bounds = bounds, depth = depth, context = context};
   220 
   221 fun map_ss1 f {rules, prems, bounds, depth, context} =
   222   make_ss1 (f (rules, prems, bounds, depth, context));
   223 
   224 fun make_ss2 (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =
   225   {congs = congs, procs = procs, mk_rews = mk_rews, termless = termless,
   226     subgoal_tac = subgoal_tac, loop_tacs = loop_tacs, solvers = solvers};
   227 
   228 fun map_ss2 f {congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers} =
   229   make_ss2 (f (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   230 
   231 fun make_simpset (args1, args2) = Simpset (make_ss1 args1, make_ss2 args2);
   232 
   233 fun map_simpset1 f (Simpset (r1, r2)) = Simpset (map_ss1 f r1, r2);
   234 fun map_simpset2 f (Simpset (r1, r2)) = Simpset (r1, map_ss2 f r2);
   235 
   236 fun prems_of (Simpset ({prems, ...}, _)) = prems;
   237 
   238 fun eq_procid ((s1: stamp, ths1: thm list), (s2, ths2)) =
   239   s1 = s2 andalso eq_list Thm.eq_thm (ths1, ths2);
   240 fun eq_proc (Proc {id = id1, ...}, Proc {id = id2, ...}) = eq_procid (id1, id2);
   241 
   242 fun mk_solver name solver = Solver {name = name, solver = solver, id = stamp ()};
   243 
   244 fun solver_name (Solver {name, ...}) = name;
   245 fun solver ss (Solver {solver = tac, ...}) = tac ss;
   246 fun eq_solver (Solver {id = id1, ...}, Solver {id = id2, ...}) = (id1 = id2);
   247 
   248 
   249 (* simp depth *)
   250 
   251 val simp_depth_limit_raw = Config.declare "simp_depth_limit" (K (Config.Int 100));
   252 val simp_depth_limit = Config.int simp_depth_limit_raw;
   253 
   254 val simp_trace_depth_limit_default = Unsynchronized.ref 1;
   255 val simp_trace_depth_limit_raw = Config.declare "simp_trace_depth_limit"
   256   (fn _ => Config.Int (! simp_trace_depth_limit_default));
   257 val simp_trace_depth_limit = Config.int simp_trace_depth_limit_raw;
   258 
   259 fun simp_trace_depth_limit_of NONE = ! simp_trace_depth_limit_default
   260   | simp_trace_depth_limit_of (SOME ctxt) = Config.get ctxt simp_trace_depth_limit;
   261 
   262 fun trace_depth (Simpset ({depth = (depth, exceeded), context, ...}, _)) msg =
   263   if depth > simp_trace_depth_limit_of context then
   264     if ! exceeded then () else (tracing "simp_trace_depth_limit exceeded!"; exceeded := true)
   265   else
   266     (tracing (enclose "[" "]" (string_of_int depth) ^ msg); exceeded := false);
   267 
   268 val inc_simp_depth = map_simpset1 (fn (rules, prems, bounds, (depth, exceeded), context) =>
   269   (rules, prems, bounds,
   270     (depth + 1,
   271       if depth = simp_trace_depth_limit_of context then Unsynchronized.ref false else exceeded), context));
   272 
   273 fun simp_depth (Simpset ({depth = (depth, _), ...}, _)) = depth;
   274 
   275 
   276 (* diagnostics *)
   277 
   278 exception SIMPLIFIER of string * thm;
   279 
   280 val simp_debug_raw = Config.declare "simp_debug" (K (Config.Bool false));
   281 val simp_debug = Config.bool simp_debug_raw;
   282 
   283 val simp_trace_default = Unsynchronized.ref false;
   284 val simp_trace_raw = Config.declare "simp_trace" (fn _ => Config.Bool (! simp_trace_default));
   285 val simp_trace = Config.bool simp_trace_raw;
   286 
   287 fun if_enabled (Simpset ({context, ...}, _)) flag f =
   288   (case context of
   289     SOME ctxt => if Config.get ctxt flag then f ctxt else ()
   290   | NONE => ())
   291 
   292 fun if_visible (Simpset ({context, ...}, _)) f x =
   293   (case context of
   294     SOME ctxt => Context_Position.if_visible ctxt f x
   295   | NONE => ());
   296 
   297 local
   298 
   299 fun prnt ss warn a = if warn then warning a else trace_depth ss a;
   300 
   301 fun show_bounds (Simpset ({bounds = (_, bs), ...}, _)) t =
   302   let
   303     val names = Term.declare_term_names t Name.context;
   304     val xs = rev (#1 (fold_map Name.variant (rev (map #2 bs)) names));
   305     fun subst (((b, T), _), x') = (Free (b, T), Syntax_Trans.mark_bound_abs (x', T));
   306   in Term.subst_atomic (ListPair.map subst (bs, xs)) t end;
   307 
   308 fun print_term ss warn a t ctxt = prnt ss warn (a () ^ "\n" ^
   309   Syntax.string_of_term ctxt
   310     (if Config.get ctxt simp_debug then t else show_bounds ss t));
   311 
   312 in
   313 
   314 fun print_term_global ss warn a thy t =
   315   print_term ss warn (K a) t (Proof_Context.init_global thy);
   316 
   317 fun debug warn a ss = if_enabled ss simp_debug (fn _ => prnt ss warn (a ()));
   318 fun trace warn a ss = if_enabled ss simp_trace (fn _ => prnt ss warn (a ()));
   319 
   320 fun debug_term warn a ss t = if_enabled ss simp_debug (print_term ss warn a t);
   321 fun trace_term warn a ss t = if_enabled ss simp_trace (print_term ss warn a t);
   322 
   323 fun trace_cterm warn a ss ct =
   324   if_enabled ss simp_trace (print_term ss warn a (Thm.term_of ct));
   325 
   326 fun trace_thm a ss th =
   327   if_enabled ss simp_trace (print_term ss false a (Thm.full_prop_of th));
   328 
   329 fun trace_named_thm a ss (th, name) =
   330   if_enabled ss simp_trace (print_term ss false
   331     (fn () => if name = "" then a () else a () ^ " " ^ quote name ^ ":")
   332     (Thm.full_prop_of th));
   333 
   334 fun warn_thm a ss th =
   335   print_term_global ss true a (Thm.theory_of_thm th) (Thm.full_prop_of th);
   336 
   337 fun cond_warn_thm a ss th = if_visible ss (fn () => warn_thm a ss th) ();
   338 
   339 end;
   340 
   341 
   342 
   343 (** simpset operations **)
   344 
   345 (* context *)
   346 
   347 fun eq_bound (x: string, (y, _)) = x = y;
   348 
   349 fun add_bound bound = map_simpset1 (fn (rules, prems, (count, bounds), depth, context) =>
   350   (rules, prems, (count + 1, bound :: bounds), depth, context));
   351 
   352 fun add_prems ths = map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   353   (rules, ths @ prems, bounds, depth, context));
   354 
   355 fun inherit_context (Simpset ({bounds, depth, context, ...}, _)) =
   356   map_simpset1 (fn (rules, prems, _, _, _) => (rules, prems, bounds, depth, context));
   357 
   358 fun the_context (Simpset ({context = SOME ctxt, ...}, _)) = ctxt
   359   | the_context _ = raise Fail "Simplifier: no proof context in simpset";
   360 
   361 fun context ctxt =
   362   map_simpset1 (fn (rules, prems, bounds, depth, _) => (rules, prems, bounds, depth, SOME ctxt));
   363 
   364 val global_context = context o Proof_Context.init_global;
   365 
   366 fun activate_context thy ss =
   367   let
   368     val ctxt = the_context ss;
   369     val ctxt' = ctxt
   370       |> Context.raw_transfer (Theory.merge (thy, Proof_Context.theory_of ctxt))
   371       |> Context_Position.set_visible false;
   372   in context ctxt' ss end;
   373 
   374 fun with_context ctxt f ss = inherit_context ss (f (context ctxt ss));
   375 
   376 
   377 (* maintain simp rules *)
   378 
   379 (* FIXME: it seems that the conditions on extra variables are too liberal if
   380 prems are nonempty: does solving the prems really guarantee instantiation of
   381 all its Vars? Better: a dynamic check each time a rule is applied.
   382 *)
   383 fun rewrite_rule_extra_vars prems elhs erhs =
   384   let
   385     val elhss = elhs :: prems;
   386     val tvars = fold Term.add_tvars elhss [];
   387     val vars = fold Term.add_vars elhss [];
   388   in
   389     erhs |> Term.exists_type (Term.exists_subtype
   390       (fn TVar v => not (member (op =) tvars v) | _ => false)) orelse
   391     erhs |> Term.exists_subterm
   392       (fn Var v => not (member (op =) vars v) | _ => false)
   393   end;
   394 
   395 fun rrule_extra_vars elhs thm =
   396   rewrite_rule_extra_vars [] (term_of elhs) (Thm.full_prop_of thm);
   397 
   398 fun mk_rrule2 {thm, name, lhs, elhs, perm} =
   399   let
   400     val t = term_of elhs;
   401     val fo = Pattern.first_order t orelse not (Pattern.pattern t);
   402     val extra = rrule_extra_vars elhs thm;
   403   in {thm = thm, name = name, lhs = lhs, elhs = elhs, extra = extra, fo = fo, perm = perm} end;
   404 
   405 fun del_rrule (rrule as {thm, elhs, ...}) ss =
   406   ss |> map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   407     (Net.delete_term eq_rrule (term_of elhs, rrule) rules, prems, bounds, depth, context))
   408   handle Net.DELETE => (cond_warn_thm "Rewrite rule not in simpset:" ss thm; ss);
   409 
   410 fun insert_rrule (rrule as {thm, name, ...}) ss =
   411  (trace_named_thm (fn () => "Adding rewrite rule") ss (thm, name);
   412   ss |> map_simpset1 (fn (rules, prems, bounds, depth, context) =>
   413     let
   414       val rrule2 as {elhs, ...} = mk_rrule2 rrule;
   415       val rules' = Net.insert_term eq_rrule (term_of elhs, rrule2) rules;
   416     in (rules', prems, bounds, depth, context) end)
   417   handle Net.INSERT => (cond_warn_thm "Ignoring duplicate rewrite rule:" ss thm; ss));
   418 
   419 fun vperm (Var _, Var _) = true
   420   | vperm (Abs (_, _, s), Abs (_, _, t)) = vperm (s, t)
   421   | vperm (t1 $ t2, u1 $ u2) = vperm (t1, u1) andalso vperm (t2, u2)
   422   | vperm (t, u) = (t = u);
   423 
   424 fun var_perm (t, u) =
   425   vperm (t, u) andalso eq_set (op =) (Term.add_vars t [], Term.add_vars u []);
   426 
   427 (*simple test for looping rewrite rules and stupid orientations*)
   428 fun default_reorient thy prems lhs rhs =
   429   rewrite_rule_extra_vars prems lhs rhs
   430     orelse
   431   is_Var (head_of lhs)
   432     orelse
   433 (* turns t = x around, which causes a headache if x is a local variable -
   434    usually it is very useful :-(
   435   is_Free rhs andalso not(is_Free lhs) andalso not(Logic.occs(rhs,lhs))
   436   andalso not(exists_subterm is_Var lhs)
   437     orelse
   438 *)
   439   exists (fn t => Logic.occs (lhs, t)) (rhs :: prems)
   440     orelse
   441   null prems andalso Pattern.matches thy (lhs, rhs)
   442     (*the condition "null prems" is necessary because conditional rewrites
   443       with extra variables in the conditions may terminate although
   444       the rhs is an instance of the lhs; example: ?m < ?n ==> f(?n) == f(?m)*)
   445     orelse
   446   is_Const lhs andalso not (is_Const rhs);
   447 
   448 fun decomp_simp thm =
   449   let
   450     val thy = Thm.theory_of_thm thm;
   451     val prop = Thm.prop_of thm;
   452     val prems = Logic.strip_imp_prems prop;
   453     val concl = Drule.strip_imp_concl (Thm.cprop_of thm);
   454     val (lhs, rhs) = Thm.dest_equals concl handle TERM _ =>
   455       raise SIMPLIFIER ("Rewrite rule not a meta-equality", thm);
   456     val elhs = Thm.dest_arg (Thm.cprop_of (Thm.eta_conversion lhs));
   457     val erhs = Envir.eta_contract (term_of rhs);
   458     val perm =
   459       var_perm (term_of elhs, erhs) andalso
   460       not (term_of elhs aconv erhs) andalso
   461       not (is_Var (term_of elhs));
   462   in (thy, prems, term_of lhs, elhs, term_of rhs, perm) end;
   463 
   464 fun decomp_simp' thm =
   465   let val (_, _, lhs, _, rhs, _) = decomp_simp thm in
   466     if Thm.nprems_of thm > 0 then raise SIMPLIFIER ("Bad conditional rewrite rule", thm)
   467     else (lhs, rhs)
   468   end;
   469 
   470 fun mk_eq_True (ss as Simpset (_, {mk_rews = {mk_eq_True, ...}, ...})) (thm, name) =
   471   (case mk_eq_True ss thm of
   472     NONE => []
   473   | SOME eq_True =>
   474       let
   475         val (_, _, lhs, elhs, _, _) = decomp_simp eq_True;
   476       in [{thm = eq_True, name = name, lhs = lhs, elhs = elhs, perm = false}] end);
   477 
   478 (*create the rewrite rule and possibly also the eq_True variant,
   479   in case there are extra vars on the rhs*)
   480 fun rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm2) =
   481   let val rrule = {thm = thm, name = name, lhs = lhs, elhs = elhs, perm = false} in
   482     if rewrite_rule_extra_vars [] lhs rhs then
   483       mk_eq_True ss (thm2, name) @ [rrule]
   484     else [rrule]
   485   end;
   486 
   487 fun mk_rrule ss (thm, name) =
   488   let val (_, prems, lhs, elhs, rhs, perm) = decomp_simp thm in
   489     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   490     else
   491       (*weak test for loops*)
   492       if rewrite_rule_extra_vars prems lhs rhs orelse is_Var (term_of elhs)
   493       then mk_eq_True ss (thm, name)
   494       else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   495   end;
   496 
   497 fun orient_rrule ss (thm, name) =
   498   let
   499     val (thy, prems, lhs, elhs, rhs, perm) = decomp_simp thm;
   500     val Simpset (_, {mk_rews = {reorient, mk_sym, ...}, ...}) = ss;
   501   in
   502     if perm then [{thm = thm, name = name, lhs = lhs, elhs = elhs, perm = true}]
   503     else if reorient thy prems lhs rhs then
   504       if reorient thy prems rhs lhs
   505       then mk_eq_True ss (thm, name)
   506       else
   507         (case mk_sym ss thm of
   508           NONE => []
   509         | SOME thm' =>
   510             let val (_, _, lhs', elhs', rhs', _) = decomp_simp thm'
   511             in rrule_eq_True (thm', name, lhs', elhs', rhs', ss, thm) end)
   512     else rrule_eq_True (thm, name, lhs, elhs, rhs, ss, thm)
   513   end;
   514 
   515 fun extract_rews (ss as Simpset (_, {mk_rews = {mk, ...}, ...}), thms) =
   516   maps (fn thm => map (rpair (Thm.get_name_hint thm)) (mk ss thm)) thms;
   517 
   518 fun extract_safe_rrules (ss, thm) =
   519   maps (orient_rrule ss) (extract_rews (ss, [thm]));
   520 
   521 
   522 (* add/del rules explicitly *)
   523 
   524 fun comb_simps comb mk_rrule (ss, thms) =
   525   let
   526     val rews = extract_rews (ss, thms);
   527   in fold (fold comb o mk_rrule) rews ss end;
   528 
   529 fun ss addsimps thms =
   530   comb_simps insert_rrule (mk_rrule ss) (ss, thms);
   531 
   532 fun ss delsimps thms =
   533   comb_simps del_rrule (map mk_rrule2 o mk_rrule ss) (ss, thms);
   534 
   535 fun add_simp thm ss = ss addsimps [thm];
   536 fun del_simp thm ss = ss delsimps [thm];
   537 
   538 
   539 (* congs *)
   540 
   541 fun cong_name (Const (a, _)) = SOME a
   542   | cong_name (Free (a, _)) = SOME ("Free: " ^ a)
   543   | cong_name _ = NONE;
   544 
   545 local
   546 
   547 fun is_full_cong_prems [] [] = true
   548   | is_full_cong_prems [] _ = false
   549   | is_full_cong_prems (p :: prems) varpairs =
   550       (case Logic.strip_assums_concl p of
   551         Const ("==", _) $ lhs $ rhs =>
   552           let val (x, xs) = strip_comb lhs and (y, ys) = strip_comb rhs in
   553             is_Var x andalso forall is_Bound xs andalso
   554             not (has_duplicates (op =) xs) andalso xs = ys andalso
   555             member (op =) varpairs (x, y) andalso
   556             is_full_cong_prems prems (remove (op =) (x, y) varpairs)
   557           end
   558       | _ => false);
   559 
   560 fun is_full_cong thm =
   561   let
   562     val prems = Thm.prems_of thm and concl = Thm.concl_of thm;
   563     val (lhs, rhs) = Logic.dest_equals concl;
   564     val (f, xs) = strip_comb lhs and (g, ys) = strip_comb rhs;
   565   in
   566     f = g andalso not (has_duplicates (op =) (xs @ ys)) andalso length xs = length ys andalso
   567     is_full_cong_prems prems (xs ~~ ys)
   568   end;
   569 
   570 fun mk_cong (ss as Simpset (_, {mk_rews = {mk_cong = f, ...}, ...})) = f ss;
   571 
   572 in
   573 
   574 fun add_eqcong thm ss = ss |>
   575   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   576     let
   577       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm)
   578         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   579     (*val lhs = Envir.eta_contract lhs;*)
   580       val a = the (cong_name (head_of lhs)) handle Option.Option =>
   581         raise SIMPLIFIER ("Congruence must start with a constant or free variable", thm);
   582       val (xs, weak) = congs;
   583       val _ =
   584         if AList.defined (op =) xs a
   585         then if_visible ss warning ("Overwriting congruence rule for " ^ quote a)
   586         else ();
   587       val xs' = AList.update (op =) (a, thm) xs;
   588       val weak' = if is_full_cong thm then weak else a :: weak;
   589     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   590 
   591 fun del_eqcong thm ss = ss |>
   592   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   593     let
   594       val (lhs, _) = Logic.dest_equals (Thm.concl_of thm)
   595         handle TERM _ => raise SIMPLIFIER ("Congruence not a meta-equality", thm);
   596     (*val lhs = Envir.eta_contract lhs;*)
   597       val a = the (cong_name (head_of lhs)) handle Option.Option =>
   598         raise SIMPLIFIER ("Congruence must start with a constant", thm);
   599       val (xs, _) = congs;
   600       val xs' = filter_out (fn (x : string, _) => x = a) xs;
   601       val weak' = xs' |> map_filter (fn (a, thm) =>
   602         if is_full_cong thm then NONE else SOME a);
   603     in ((xs', weak'), procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) end);
   604 
   605 fun add_cong thm ss = add_eqcong (mk_cong ss thm) ss;
   606 fun del_cong thm ss = del_eqcong (mk_cong ss thm) ss;
   607 
   608 end;
   609 
   610 
   611 (* simprocs *)
   612 
   613 datatype simproc =
   614   Simproc of
   615     {name: string,
   616      lhss: cterm list,
   617      proc: morphism -> simpset -> cterm -> thm option,
   618      id: stamp * thm list};
   619 
   620 fun eq_simproc (Simproc {id = id1, ...}, Simproc {id = id2, ...}) = eq_procid (id1, id2);
   621 
   622 fun transform_simproc phi (Simproc {name, lhss, proc, id = (s, ths)}) =
   623   Simproc
   624    {name = name,
   625     lhss = map (Morphism.cterm phi) lhss,
   626     proc = Morphism.transform phi proc,
   627     id = (s, Morphism.fact phi ths)};
   628 
   629 fun make_simproc {name, lhss, proc, identifier} =
   630   Simproc {name = name, lhss = lhss, proc = proc, id = (stamp (), identifier)};
   631 
   632 fun mk_simproc name lhss proc =
   633   make_simproc {name = name, lhss = lhss, proc = fn _ => fn ss => fn ct =>
   634     proc (Proof_Context.theory_of (the_context ss)) ss (Thm.term_of ct), identifier = []};
   635 
   636 (* FIXME avoid global thy and Logic.varify_global *)
   637 fun simproc_global_i thy name = mk_simproc name o map (Thm.cterm_of thy o Logic.varify_global);
   638 fun simproc_global thy name = simproc_global_i thy name o map (Syntax.read_term_global thy);
   639 
   640 
   641 local
   642 
   643 fun add_proc (proc as Proc {name, lhs, ...}) ss =
   644  (trace_cterm false (fn () => "Adding simplification procedure " ^ quote name ^ " for") ss lhs;
   645   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   646     (congs, Net.insert_term eq_proc (term_of lhs, proc) procs,
   647       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   648   handle Net.INSERT =>
   649     (if_visible ss warning ("Ignoring duplicate simplification procedure " ^ quote name); ss));
   650 
   651 fun del_proc (proc as Proc {name, lhs, ...}) ss =
   652   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   653     (congs, Net.delete_term eq_proc (term_of lhs, proc) procs,
   654       mk_rews, termless, subgoal_tac, loop_tacs, solvers)) ss
   655   handle Net.DELETE =>
   656     (if_visible ss warning ("Simplification procedure " ^ quote name ^ " not in simpset"); ss);
   657 
   658 fun prep_procs (Simproc {name, lhss, proc, id}) =
   659   lhss |> map (fn lhs => Proc {name = name, lhs = lhs, proc = Morphism.form proc, id = id});
   660 
   661 in
   662 
   663 fun ss addsimprocs ps = fold (fold add_proc o prep_procs) ps ss;
   664 fun ss delsimprocs ps = fold (fold del_proc o prep_procs) ps ss;
   665 
   666 end;
   667 
   668 
   669 (* mk_rews *)
   670 
   671 local
   672 
   673 fun map_mk_rews f = map_simpset2 (fn (congs, procs, {mk, mk_cong, mk_sym, mk_eq_True, reorient},
   674       termless, subgoal_tac, loop_tacs, solvers) =>
   675   let
   676     val (mk', mk_cong', mk_sym', mk_eq_True', reorient') =
   677       f (mk, mk_cong, mk_sym, mk_eq_True, reorient);
   678     val mk_rews' = {mk = mk', mk_cong = mk_cong', mk_sym = mk_sym', mk_eq_True = mk_eq_True',
   679       reorient = reorient'};
   680   in (congs, procs, mk_rews', termless, subgoal_tac, loop_tacs, solvers) end);
   681 
   682 in
   683 
   684 fun mksimps (ss as Simpset (_, {mk_rews = {mk, ...}, ...})) = mk ss;
   685 
   686 fun set_mksimps mk = map_mk_rews (fn (_, mk_cong, mk_sym, mk_eq_True, reorient) =>
   687   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   688 
   689 fun set_mkcong mk_cong = map_mk_rews (fn (mk, _, mk_sym, mk_eq_True, reorient) =>
   690   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   691 
   692 fun set_mksym mk_sym = map_mk_rews (fn (mk, mk_cong, _, mk_eq_True, reorient) =>
   693   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   694 
   695 fun set_mkeqTrue mk_eq_True = map_mk_rews (fn (mk, mk_cong, mk_sym, _, reorient) =>
   696   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   697 
   698 fun set_reorient reorient = map_mk_rews (fn (mk, mk_cong, mk_sym, mk_eq_True, _) =>
   699   (mk, mk_cong, mk_sym, mk_eq_True, reorient));
   700 
   701 end;
   702 
   703 
   704 (* termless *)
   705 
   706 fun set_termless termless =
   707   map_simpset2 (fn (congs, procs, mk_rews, _, subgoal_tac, loop_tacs, solvers) =>
   708    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   709 
   710 
   711 (* tactics *)
   712 
   713 fun set_subgoaler subgoal_tac =
   714   map_simpset2 (fn (congs, procs, mk_rews, termless, _, loop_tacs, solvers) =>
   715    (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers));
   716 
   717 fun ss setloop' tac = ss |>
   718   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, _, solvers) =>
   719    (congs, procs, mk_rews, termless, subgoal_tac, [("", tac)], solvers));
   720 
   721 fun ss setloop tac = ss setloop' (K tac);
   722 
   723 fun ss addloop' (name, tac) = ss |>
   724   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   725     (congs, procs, mk_rews, termless, subgoal_tac,
   726      (if AList.defined (op =) loop_tacs name
   727       then if_visible ss warning ("Overwriting looper " ^ quote name)
   728       else (); AList.update (op =) (name, tac) loop_tacs), solvers));
   729 
   730 fun ss addloop (name, tac) = ss addloop' (name, K tac);
   731 
   732 fun ss delloop name = ss |>
   733   map_simpset2 (fn (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, solvers) =>
   734     (congs, procs, mk_rews, termless, subgoal_tac,
   735      (if AList.defined (op =) loop_tacs name then ()
   736       else if_visible ss warning ("No such looper in simpset: " ^ quote name);
   737       AList.delete (op =) name loop_tacs), solvers));
   738 
   739 fun ss setSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   740   subgoal_tac, loop_tacs, (unsafe_solvers, _)) =>
   741     (congs, procs, mk_rews, termless, subgoal_tac, loop_tacs, (unsafe_solvers, [solver])));
   742 
   743 fun ss addSSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   744   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   745     subgoal_tac, loop_tacs, (unsafe_solvers, insert eq_solver solver solvers)));
   746 
   747 fun ss setSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   748   subgoal_tac, loop_tacs, (_, solvers)) => (congs, procs, mk_rews, termless,
   749     subgoal_tac, loop_tacs, ([solver], solvers)));
   750 
   751 fun ss addSolver solver = ss |> map_simpset2 (fn (congs, procs, mk_rews, termless,
   752   subgoal_tac, loop_tacs, (unsafe_solvers, solvers)) => (congs, procs, mk_rews, termless,
   753     subgoal_tac, loop_tacs, (insert eq_solver solver unsafe_solvers, solvers)));
   754 
   755 fun set_solvers solvers = map_simpset2 (fn (congs, procs, mk_rews, termless,
   756   subgoal_tac, loop_tacs, _) => (congs, procs, mk_rews, termless,
   757   subgoal_tac, loop_tacs, (solvers, solvers)));
   758 
   759 
   760 (* empty *)
   761 
   762 fun init_ss mk_rews termless subgoal_tac solvers =
   763   make_simpset ((Net.empty, [], (0, []), (0, Unsynchronized.ref false), NONE),
   764     (([], []), Net.empty, mk_rews, termless, subgoal_tac, [], solvers));
   765 
   766 fun clear_ss (ss as Simpset (_, {mk_rews, termless, subgoal_tac, solvers, ...})) =
   767   init_ss mk_rews termless subgoal_tac solvers
   768   |> inherit_context ss;
   769 
   770 fun default_mk_sym _ th = SOME (th RS Drule.symmetric_thm);
   771 
   772 val empty_ss =
   773   init_ss
   774     {mk = fn _ => fn th => if can Logic.dest_equals (Thm.concl_of th) then [th] else [],
   775       mk_cong = K I,
   776       mk_sym = default_mk_sym,
   777       mk_eq_True = K (K NONE),
   778       reorient = default_reorient}
   779     Term_Ord.termless (K (K no_tac)) ([], []);
   780 
   781 
   782 (* merge *)  (*NOTE: ignores some fields of 2nd simpset*)
   783 
   784 fun merge_ss (ss1, ss2) =
   785   if pointer_eq (ss1, ss2) then ss1
   786   else
   787     let
   788       val Simpset ({rules = rules1, prems = prems1, bounds = bounds1, depth = depth1, context = _},
   789        {congs = (congs1, weak1), procs = procs1, mk_rews, termless, subgoal_tac,
   790         loop_tacs = loop_tacs1, solvers = (unsafe_solvers1, solvers1)}) = ss1;
   791       val Simpset ({rules = rules2, prems = prems2, bounds = bounds2, depth = depth2, context = _},
   792        {congs = (congs2, weak2), procs = procs2, mk_rews = _, termless = _, subgoal_tac = _,
   793         loop_tacs = loop_tacs2, solvers = (unsafe_solvers2, solvers2)}) = ss2;
   794 
   795       val rules' = Net.merge eq_rrule (rules1, rules2);
   796       val prems' = Thm.merge_thms (prems1, prems2);
   797       val bounds' = if #1 bounds1 < #1 bounds2 then bounds2 else bounds1;
   798       val depth' = if #1 depth1 < #1 depth2 then depth2 else depth1;
   799       val congs' = merge (Thm.eq_thm_prop o pairself #2) (congs1, congs2);
   800       val weak' = merge (op =) (weak1, weak2);
   801       val procs' = Net.merge eq_proc (procs1, procs2);
   802       val loop_tacs' = AList.merge (op =) (K true) (loop_tacs1, loop_tacs2);
   803       val unsafe_solvers' = merge eq_solver (unsafe_solvers1, unsafe_solvers2);
   804       val solvers' = merge eq_solver (solvers1, solvers2);
   805     in
   806       make_simpset ((rules', prems', bounds', depth', NONE), ((congs', weak'), procs',
   807         mk_rews, termless, subgoal_tac, loop_tacs', (unsafe_solvers', solvers')))
   808     end;
   809 
   810 
   811 (* dest_ss *)
   812 
   813 fun dest_ss (Simpset ({rules, ...}, {congs, procs, loop_tacs, solvers, ...})) =
   814  {simps = Net.entries rules
   815     |> map (fn {name, thm, ...} => (name, thm)),
   816   procs = Net.entries procs
   817     |> map (fn Proc {name, lhs, id, ...} => ((name, lhs), id))
   818     |> partition_eq (eq_snd eq_procid)
   819     |> map (fn ps => (fst (fst (hd ps)), map (snd o fst) ps)),
   820   congs = #1 congs,
   821   weak_congs = #2 congs,
   822   loopers = map fst loop_tacs,
   823   unsafe_solvers = map solver_name (#1 solvers),
   824   safe_solvers = map solver_name (#2 solvers)};
   825 
   826 
   827 
   828 (** rewriting **)
   829 
   830 (*
   831   Uses conversions, see:
   832     L C Paulson, A higher-order implementation of rewriting,
   833     Science of Computer Programming 3 (1983), pages 119-149.
   834 *)
   835 
   836 fun check_conv msg ss thm thm' =
   837   let
   838     val thm'' = Thm.transitive thm thm' handle THM _ =>
   839      Thm.transitive thm (Thm.transitive
   840        (Thm.symmetric (Drule.beta_eta_conversion (Thm.lhs_of thm'))) thm')
   841   in if msg then trace_thm (fn () => "SUCCEEDED") ss thm' else (); SOME thm'' end
   842   handle THM _ =>
   843     let
   844       val _ $ _ $ prop0 = Thm.prop_of thm;
   845     in
   846       trace_thm (fn () => "Proved wrong thm (Check subgoaler?)") ss thm';
   847       trace_term false (fn () => "Should have proved:") ss prop0;
   848       NONE
   849     end;
   850 
   851 
   852 (* mk_procrule *)
   853 
   854 fun mk_procrule ss thm =
   855   let val (_, prems, lhs, elhs, rhs, _) = decomp_simp thm in
   856     if rewrite_rule_extra_vars prems lhs rhs
   857     then (cond_warn_thm "Extra vars on rhs:" ss thm; [])
   858     else [mk_rrule2 {thm = thm, name = "", lhs = lhs, elhs = elhs, perm = false}]
   859   end;
   860 
   861 
   862 (* rewritec: conversion to apply the meta simpset to a term *)
   863 
   864 (*Since the rewriting strategy is bottom-up, we avoid re-normalizing already
   865   normalized terms by carrying around the rhs of the rewrite rule just
   866   applied. This is called the `skeleton'. It is decomposed in parallel
   867   with the term. Once a Var is encountered, the corresponding term is
   868   already in normal form.
   869   skel0 is a dummy skeleton that is to enforce complete normalization.*)
   870 
   871 val skel0 = Bound 0;
   872 
   873 (*Use rhs as skeleton only if the lhs does not contain unnormalized bits.
   874   The latter may happen iff there are weak congruence rules for constants
   875   in the lhs.*)
   876 
   877 fun uncond_skel ((_, weak), (lhs, rhs)) =
   878   if null weak then rhs  (*optimization*)
   879   else if exists_Const (member (op =) weak o #1) lhs then skel0
   880   else rhs;
   881 
   882 (*Behaves like unconditional rule if rhs does not contain vars not in the lhs.
   883   Otherwise those vars may become instantiated with unnormalized terms
   884   while the premises are solved.*)
   885 
   886 fun cond_skel (args as (_, (lhs, rhs))) =
   887   if subset (op =) (Term.add_vars rhs [], Term.add_vars lhs []) then uncond_skel args
   888   else skel0;
   889 
   890 (*
   891   Rewriting -- we try in order:
   892     (1) beta reduction
   893     (2) unconditional rewrite rules
   894     (3) conditional rewrite rules
   895     (4) simplification procedures
   896 
   897   IMPORTANT: rewrite rules must not introduce new Vars or TVars!
   898 *)
   899 
   900 fun rewritec (prover, thyt, maxt) ss t =
   901   let
   902     val ctxt = the_context ss;
   903     val Simpset ({rules, ...}, {congs, procs, termless, ...}) = ss;
   904     val eta_thm = Thm.eta_conversion t;
   905     val eta_t' = Thm.rhs_of eta_thm;
   906     val eta_t = term_of eta_t';
   907     fun rew {thm, name, lhs, elhs, extra, fo, perm} =
   908       let
   909         val prop = Thm.prop_of thm;
   910         val (rthm, elhs') =
   911           if maxt = ~1 orelse not extra then (thm, elhs)
   912           else (Thm.incr_indexes (maxt + 1) thm, Thm.incr_indexes_cterm (maxt + 1) elhs);
   913         val insts =
   914           if fo then Thm.first_order_match (elhs', eta_t')
   915           else Thm.match (elhs', eta_t');
   916         val thm' = Thm.instantiate insts (Thm.rename_boundvars lhs eta_t rthm);
   917         val prop' = Thm.prop_of thm';
   918         val unconditional = (Logic.count_prems prop' = 0);
   919         val (lhs', rhs') = Logic.dest_equals (Logic.strip_imp_concl prop')
   920       in
   921         if perm andalso not (termless (rhs', lhs'))
   922         then (trace_named_thm (fn () => "Cannot apply permutative rewrite rule") ss (thm, name);
   923               trace_thm (fn () => "Term does not become smaller:") ss thm'; NONE)
   924         else (trace_named_thm (fn () => "Applying instance of rewrite rule") ss (thm, name);
   925            if unconditional
   926            then
   927              (trace_thm (fn () => "Rewriting:") ss thm';
   928               let
   929                 val lr = Logic.dest_equals prop;
   930                 val SOME thm'' = check_conv false ss eta_thm thm';
   931               in SOME (thm'', uncond_skel (congs, lr)) end)
   932            else
   933              (trace_thm (fn () => "Trying to rewrite:") ss thm';
   934               if simp_depth ss > Config.get ctxt simp_depth_limit
   935               then
   936                 let
   937                   val s = "simp_depth_limit exceeded - giving up";
   938                   val _ = trace false (fn () => s) ss;
   939                   val _ = if_visible ss warning s;
   940                 in NONE end
   941               else
   942               case prover ss thm' of
   943                 NONE => (trace_thm (fn () => "FAILED") ss thm'; NONE)
   944               | SOME thm2 =>
   945                   (case check_conv true ss eta_thm thm2 of
   946                      NONE => NONE |
   947                      SOME thm2' =>
   948                        let val concl = Logic.strip_imp_concl prop
   949                            val lr = Logic.dest_equals concl
   950                        in SOME (thm2', cond_skel (congs, lr)) end)))
   951       end
   952 
   953     fun rews [] = NONE
   954       | rews (rrule :: rrules) =
   955           let val opt = rew rrule handle Pattern.MATCH => NONE
   956           in case opt of NONE => rews rrules | some => some end;
   957 
   958     fun sort_rrules rrs =
   959       let
   960         fun is_simple ({thm, ...}: rrule) =
   961           (case Thm.prop_of thm of
   962             Const ("==", _) $ _ $ _ => true
   963           | _ => false);
   964         fun sort [] (re1, re2) = re1 @ re2
   965           | sort (rr :: rrs) (re1, re2) =
   966               if is_simple rr
   967               then sort rrs (rr :: re1, re2)
   968               else sort rrs (re1, rr :: re2);
   969       in sort rrs ([], []) end;
   970 
   971     fun proc_rews [] = NONE
   972       | proc_rews (Proc {name, proc, lhs, ...} :: ps) =
   973           if Pattern.matches thyt (Thm.term_of lhs, Thm.term_of t) then
   974             (debug_term false (fn () => "Trying procedure " ^ quote name ^ " on:") ss eta_t;
   975              case proc ss eta_t' of
   976                NONE => (debug false (fn () => "FAILED") ss; proc_rews ps)
   977              | SOME raw_thm =>
   978                  (trace_thm (fn () => "Procedure " ^ quote name ^ " produced rewrite rule:")
   979                    ss raw_thm;
   980                   (case rews (mk_procrule ss raw_thm) of
   981                     NONE => (trace_cterm true (fn () => "IGNORED result of simproc " ^ quote name ^
   982                       " -- does not match") ss t; proc_rews ps)
   983                   | some => some)))
   984           else proc_rews ps;
   985   in
   986     (case eta_t of
   987       Abs _ $ _ => SOME (Thm.transitive eta_thm (Thm.beta_conversion false eta_t'), skel0)
   988     | _ =>
   989       (case rews (sort_rrules (Net.match_term rules eta_t)) of
   990         NONE => proc_rews (Net.match_term procs eta_t)
   991       | some => some))
   992   end;
   993 
   994 
   995 (* conversion to apply a congruence rule to a term *)
   996 
   997 fun congc prover ss maxt cong t =
   998   let val rthm = Thm.incr_indexes (maxt + 1) cong;
   999       val rlhs = fst (Thm.dest_equals (Drule.strip_imp_concl (cprop_of rthm)));
  1000       val insts = Thm.match (rlhs, t)
  1001       (* Thm.match can raise Pattern.MATCH;
  1002          is handled when congc is called *)
  1003       val thm' = Thm.instantiate insts (Thm.rename_boundvars (term_of rlhs) (term_of t) rthm);
  1004       val _ = trace_thm (fn () => "Applying congruence rule:") ss thm';
  1005       fun err (msg, thm) = (trace_thm (fn () => msg) ss thm; NONE)
  1006   in
  1007     (case prover thm' of
  1008       NONE => err ("Congruence proof failed.  Could not prove", thm')
  1009     | SOME thm2 =>
  1010         (case check_conv true ss (Drule.beta_eta_conversion t) thm2 of
  1011           NONE => err ("Congruence proof failed.  Should not have proved", thm2)
  1012         | SOME thm2' =>
  1013             if op aconv (pairself term_of (Thm.dest_equals (cprop_of thm2')))
  1014             then NONE else SOME thm2'))
  1015   end;
  1016 
  1017 val (cA, (cB, cC)) =
  1018   apsnd Thm.dest_equals (Thm.dest_implies (hd (cprems_of Drule.imp_cong)));
  1019 
  1020 fun transitive1 NONE NONE = NONE
  1021   | transitive1 (SOME thm1) NONE = SOME thm1
  1022   | transitive1 NONE (SOME thm2) = SOME thm2
  1023   | transitive1 (SOME thm1) (SOME thm2) = SOME (Thm.transitive thm1 thm2)
  1024 
  1025 fun transitive2 thm = transitive1 (SOME thm);
  1026 fun transitive3 thm = transitive1 thm o SOME;
  1027 
  1028 fun bottomc ((simprem, useprem, mutsimp), prover, thy, maxidx) =
  1029   let
  1030     fun botc skel ss t =
  1031           if is_Var skel then NONE
  1032           else
  1033           (case subc skel ss t of
  1034              some as SOME thm1 =>
  1035                (case rewritec (prover, thy, maxidx) ss (Thm.rhs_of thm1) of
  1036                   SOME (thm2, skel2) =>
  1037                     transitive2 (Thm.transitive thm1 thm2)
  1038                       (botc skel2 ss (Thm.rhs_of thm2))
  1039                 | NONE => some)
  1040            | NONE =>
  1041                (case rewritec (prover, thy, maxidx) ss t of
  1042                   SOME (thm2, skel2) => transitive2 thm2
  1043                     (botc skel2 ss (Thm.rhs_of thm2))
  1044                 | NONE => NONE))
  1045 
  1046     and try_botc ss t =
  1047           (case botc skel0 ss t of
  1048              SOME trec1 => trec1 | NONE => (Thm.reflexive t))
  1049 
  1050     and subc skel (ss as Simpset ({bounds, ...}, {congs, ...})) t0 =
  1051        (case term_of t0 of
  1052            Abs (a, T, _) =>
  1053              let
  1054                  val b = Name.bound (#1 bounds);
  1055                  val (v, t') = Thm.dest_abs (SOME b) t0;
  1056                  val b' = #1 (Term.dest_Free (Thm.term_of v));
  1057                  val _ =
  1058                    if b <> b' then
  1059                      warning ("Simplifier: renamed bound variable " ^
  1060                        quote b ^ " to " ^ quote b' ^ Position.here (Position.thread_data ()))
  1061                    else ();
  1062                  val ss' = add_bound ((b', T), a) ss;
  1063                  val skel' = case skel of Abs (_, _, sk) => sk | _ => skel0;
  1064              in case botc skel' ss' t' of
  1065                   SOME thm => SOME (Thm.abstract_rule a v thm)
  1066                 | NONE => NONE
  1067              end
  1068          | t $ _ => (case t of
  1069              Const ("==>", _) $ _  => impc t0 ss
  1070            | Abs _ =>
  1071                let val thm = Thm.beta_conversion false t0
  1072                in case subc skel0 ss (Thm.rhs_of thm) of
  1073                     NONE => SOME thm
  1074                   | SOME thm' => SOME (Thm.transitive thm thm')
  1075                end
  1076            | _  =>
  1077                let fun appc () =
  1078                      let
  1079                        val (tskel, uskel) = case skel of
  1080                            tskel $ uskel => (tskel, uskel)
  1081                          | _ => (skel0, skel0);
  1082                        val (ct, cu) = Thm.dest_comb t0
  1083                      in
  1084                      (case botc tskel ss ct of
  1085                         SOME thm1 =>
  1086                           (case botc uskel ss cu of
  1087                              SOME thm2 => SOME (Thm.combination thm1 thm2)
  1088                            | NONE => SOME (Thm.combination thm1 (Thm.reflexive cu)))
  1089                       | NONE =>
  1090                           (case botc uskel ss cu of
  1091                              SOME thm1 => SOME (Thm.combination (Thm.reflexive ct) thm1)
  1092                            | NONE => NONE))
  1093                      end
  1094                    val (h, ts) = strip_comb t
  1095                in case cong_name h of
  1096                     SOME a =>
  1097                       (case AList.lookup (op =) (fst congs) a of
  1098                          NONE => appc ()
  1099                        | SOME cong =>
  1100   (*post processing: some partial applications h t1 ... tj, j <= length ts,
  1101     may be a redex. Example: map (%x. x) = (%xs. xs) wrt map_cong*)
  1102                           (let
  1103                              val thm = congc (prover ss) ss maxidx cong t0;
  1104                              val t = the_default t0 (Option.map Thm.rhs_of thm);
  1105                              val (cl, cr) = Thm.dest_comb t
  1106                              val dVar = Var(("", 0), dummyT)
  1107                              val skel =
  1108                                list_comb (h, replicate (length ts) dVar)
  1109                            in case botc skel ss cl of
  1110                                 NONE => thm
  1111                               | SOME thm' => transitive3 thm
  1112                                   (Thm.combination thm' (Thm.reflexive cr))
  1113                            end handle Pattern.MATCH => appc ()))
  1114                   | _ => appc ()
  1115                end)
  1116          | _ => NONE)
  1117 
  1118     and impc ct ss =
  1119       if mutsimp then mut_impc0 [] ct [] [] ss else nonmut_impc ct ss
  1120 
  1121     and rules_of_prem ss prem =
  1122       if maxidx_of_term (term_of prem) <> ~1
  1123       then (trace_cterm true
  1124         (fn () => "Cannot add premise as rewrite rule because it contains (type) unknowns:")
  1125           ss prem; ([], NONE))
  1126       else
  1127         let val asm = Thm.assume prem
  1128         in (extract_safe_rrules (ss, asm), SOME asm) end
  1129 
  1130     and add_rrules (rrss, asms) ss =
  1131       (fold o fold) insert_rrule rrss ss |> add_prems (map_filter I asms)
  1132 
  1133     and disch r prem eq =
  1134       let
  1135         val (lhs, rhs) = Thm.dest_equals (Thm.cprop_of eq);
  1136         val eq' = Thm.implies_elim (Thm.instantiate
  1137           ([], [(cA, prem), (cB, lhs), (cC, rhs)]) Drule.imp_cong)
  1138           (Thm.implies_intr prem eq)
  1139       in if not r then eq' else
  1140         let
  1141           val (prem', concl) = Thm.dest_implies lhs;
  1142           val (prem'', _) = Thm.dest_implies rhs
  1143         in Thm.transitive (Thm.transitive
  1144           (Thm.instantiate ([], [(cA, prem'), (cB, prem), (cC, concl)])
  1145              Drule.swap_prems_eq) eq')
  1146           (Thm.instantiate ([], [(cA, prem), (cB, prem''), (cC, concl)])
  1147              Drule.swap_prems_eq)
  1148         end
  1149       end
  1150 
  1151     and rebuild [] _ _ _ _ eq = eq
  1152       | rebuild (prem :: prems) concl (_ :: rrss) (_ :: asms) ss eq =
  1153           let
  1154             val ss' = add_rrules (rev rrss, rev asms) ss;
  1155             val concl' =
  1156               Drule.mk_implies (prem, the_default concl (Option.map Thm.rhs_of eq));
  1157             val dprem = Option.map (disch false prem)
  1158           in
  1159             (case rewritec (prover, thy, maxidx) ss' concl' of
  1160               NONE => rebuild prems concl' rrss asms ss (dprem eq)
  1161             | SOME (eq', _) => transitive2 (fold (disch false)
  1162                   prems (the (transitive3 (dprem eq) eq')))
  1163                 (mut_impc0 (rev prems) (Thm.rhs_of eq') (rev rrss) (rev asms) ss))
  1164           end
  1165 
  1166     and mut_impc0 prems concl rrss asms ss =
  1167       let
  1168         val prems' = strip_imp_prems concl;
  1169         val (rrss', asms') = split_list (map (rules_of_prem ss) prems')
  1170       in
  1171         mut_impc (prems @ prems') (strip_imp_concl concl) (rrss @ rrss')
  1172           (asms @ asms') [] [] [] [] ss ~1 ~1
  1173       end
  1174 
  1175     and mut_impc [] concl [] [] prems' rrss' asms' eqns ss changed k =
  1176         transitive1 (fold (fn (eq1, prem) => fn eq2 => transitive1 eq1
  1177             (Option.map (disch false prem) eq2)) (eqns ~~ prems') NONE)
  1178           (if changed > 0 then
  1179              mut_impc (rev prems') concl (rev rrss') (rev asms')
  1180                [] [] [] [] ss ~1 changed
  1181            else rebuild prems' concl rrss' asms' ss
  1182              (botc skel0 (add_rrules (rev rrss', rev asms') ss) concl))
  1183 
  1184       | mut_impc (prem :: prems) concl (rrs :: rrss) (asm :: asms)
  1185           prems' rrss' asms' eqns ss changed k =
  1186         case (if k = 0 then NONE else botc skel0 (add_rrules
  1187           (rev rrss' @ rrss, rev asms' @ asms) ss) prem) of
  1188             NONE => mut_impc prems concl rrss asms (prem :: prems')
  1189               (rrs :: rrss') (asm :: asms') (NONE :: eqns) ss changed
  1190               (if k = 0 then 0 else k - 1)
  1191           | SOME eqn =>
  1192             let
  1193               val prem' = Thm.rhs_of eqn;
  1194               val tprems = map term_of prems;
  1195               val i = 1 + fold Integer.max (map (fn p =>
  1196                 find_index (fn q => q aconv p) tprems) (Thm.hyps_of eqn)) ~1;
  1197               val (rrs', asm') = rules_of_prem ss prem'
  1198             in mut_impc prems concl rrss asms (prem' :: prems')
  1199               (rrs' :: rrss') (asm' :: asms') (SOME (fold_rev (disch true)
  1200                 (take i prems)
  1201                 (Drule.imp_cong_rule eqn (Thm.reflexive (Drule.list_implies
  1202                   (drop i prems, concl))))) :: eqns)
  1203                   ss (length prems') ~1
  1204             end
  1205 
  1206      (*legacy code - only for backwards compatibility*)
  1207     and nonmut_impc ct ss =
  1208       let
  1209         val (prem, conc) = Thm.dest_implies ct;
  1210         val thm1 = if simprem then botc skel0 ss prem else NONE;
  1211         val prem1 = the_default prem (Option.map Thm.rhs_of thm1);
  1212         val ss1 =
  1213           if not useprem then ss
  1214           else add_rrules (apsnd single (apfst single (rules_of_prem ss prem1))) ss
  1215       in
  1216         (case botc skel0 ss1 conc of
  1217           NONE =>
  1218             (case thm1 of
  1219               NONE => NONE
  1220             | SOME thm1' => SOME (Drule.imp_cong_rule thm1' (Thm.reflexive conc)))
  1221         | SOME thm2 =>
  1222             let val thm2' = disch false prem1 thm2 in
  1223               (case thm1 of
  1224                 NONE => SOME thm2'
  1225               | SOME thm1' =>
  1226                  SOME (Thm.transitive (Drule.imp_cong_rule thm1' (Thm.reflexive conc)) thm2'))
  1227             end)
  1228       end
  1229 
  1230  in try_botc end;
  1231 
  1232 
  1233 (* Meta-rewriting: rewrites t to u and returns the theorem t==u *)
  1234 
  1235 (*
  1236   Parameters:
  1237     mode = (simplify A,
  1238             use A in simplifying B,
  1239             use prems of B (if B is again a meta-impl.) to simplify A)
  1240            when simplifying A ==> B
  1241     prover: how to solve premises in conditional rewrites and congruences
  1242 *)
  1243 
  1244 val debug_bounds = Unsynchronized.ref false;
  1245 
  1246 fun check_bounds ss ct =
  1247   if ! debug_bounds then
  1248     let
  1249       val Simpset ({bounds = (_, bounds), ...}, _) = ss;
  1250       val bs = fold_aterms (fn Free (x, _) =>
  1251           if Name.is_bound x andalso not (AList.defined eq_bound bounds x)
  1252           then insert (op =) x else I
  1253         | _ => I) (term_of ct) [];
  1254     in
  1255       if null bs then ()
  1256       else print_term_global ss true ("Simplifier: term contains loose bounds: " ^ commas_quote bs)
  1257         (Thm.theory_of_cterm ct) (Thm.term_of ct)
  1258     end
  1259   else ();
  1260 
  1261 fun rewrite_cterm mode prover raw_ss raw_ct =
  1262   let
  1263     val thy = Thm.theory_of_cterm raw_ct;
  1264     val ct = Thm.adjust_maxidx_cterm ~1 raw_ct;
  1265     val {maxidx, ...} = Thm.rep_cterm ct;
  1266     val ss = inc_simp_depth (activate_context thy raw_ss);
  1267     val depth = simp_depth ss;
  1268     val _ =
  1269       if depth mod 20 = 0 then
  1270         if_visible ss warning ("Simplification depth " ^ string_of_int depth)
  1271       else ();
  1272     val _ = trace_cterm false (fn () => "SIMPLIFIER INVOKED ON THE FOLLOWING TERM:") ss ct;
  1273     val _ = check_bounds ss ct;
  1274   in bottomc (mode, Option.map Drule.flexflex_unique oo prover, thy, maxidx) ss ct end;
  1275 
  1276 val simple_prover =
  1277   SINGLE o (fn ss => ALLGOALS (resolve_tac (prems_of ss)));
  1278 
  1279 fun rewrite _ [] ct = Thm.reflexive ct
  1280   | rewrite full thms ct = rewrite_cterm (full, false, false) simple_prover
  1281       (global_context (Thm.theory_of_cterm ct) empty_ss addsimps thms) ct;
  1282 
  1283 fun simplify full thms = Conv.fconv_rule (rewrite full thms);
  1284 val rewrite_rule = simplify true;
  1285 
  1286 (*simple term rewriting -- no proof*)
  1287 fun rewrite_term thy rules procs =
  1288   Pattern.rewrite_term thy (map decomp_simp' rules) procs;
  1289 
  1290 fun rewrite_thm mode prover ss = Conv.fconv_rule (rewrite_cterm mode prover ss);
  1291 
  1292 (*Rewrite the subgoals of a proof state (represented by a theorem)*)
  1293 fun rewrite_goals_rule thms th =
  1294   Conv.fconv_rule (Conv.prems_conv ~1 (rewrite_cterm (true, true, true) simple_prover
  1295     (global_context (Thm.theory_of_thm th) empty_ss addsimps thms))) th;
  1296 
  1297 
  1298 (** meta-rewriting tactics **)
  1299 
  1300 (*Rewrite all subgoals*)
  1301 fun rewrite_goals_tac defs = PRIMITIVE (rewrite_goals_rule defs);
  1302 
  1303 (*Rewrite one subgoal*)
  1304 fun generic_rewrite_goal_tac mode prover_tac ss i thm =
  1305   if 0 < i andalso i <= Thm.nprems_of thm then
  1306     Seq.single (Conv.gconv_rule (rewrite_cterm mode (SINGLE o prover_tac) ss) i thm)
  1307   else Seq.empty;
  1308 
  1309 fun rewrite_goal_tac rews =
  1310   let val ss = empty_ss addsimps rews in
  1311     fn i => fn st => generic_rewrite_goal_tac (true, false, false) (K no_tac)
  1312       (global_context (Thm.theory_of_thm st) ss) i st
  1313   end;
  1314 
  1315 (*Prunes all redundant parameters from the proof state by rewriting.*)
  1316 val prune_params_tac = rewrite_goals_tac [Drule.triv_forall_equality];
  1317 
  1318 
  1319 (* for folding definitions, handling critical pairs *)
  1320 
  1321 (*The depth of nesting in a term*)
  1322 fun term_depth (Abs (_, _, t)) = 1 + term_depth t
  1323   | term_depth (f $ t) = 1 + Int.max (term_depth f, term_depth t)
  1324   | term_depth _ = 0;
  1325 
  1326 val lhs_of_thm = #1 o Logic.dest_equals o prop_of;
  1327 
  1328 (*folding should handle critical pairs!  E.g. K == Inl(0),  S == Inr(Inl(0))
  1329   Returns longest lhs first to avoid folding its subexpressions.*)
  1330 fun sort_lhs_depths defs =
  1331   let val keylist = AList.make (term_depth o lhs_of_thm) defs
  1332       val keys = sort_distinct (rev_order o int_ord) (map #2 keylist)
  1333   in map (AList.find (op =) keylist) keys end;
  1334 
  1335 val rev_defs = sort_lhs_depths o map Thm.symmetric;
  1336 
  1337 fun fold_rule defs = fold rewrite_rule (rev_defs defs);
  1338 fun fold_goals_tac defs = EVERY (map rewrite_goals_tac (rev_defs defs));
  1339 
  1340 
  1341 (* HHF normal form: !! before ==>, outermost !! generalized *)
  1342 
  1343 local
  1344 
  1345 fun gen_norm_hhf ss th =
  1346   (if Drule.is_norm_hhf (Thm.prop_of th) then th
  1347    else Conv.fconv_rule
  1348     (rewrite_cterm (true, false, false) (K (K NONE)) (global_context (Thm.theory_of_thm th) ss)) th)
  1349   |> Thm.adjust_maxidx_thm ~1
  1350   |> Drule.gen_all;
  1351 
  1352 val hhf_ss = empty_ss addsimps Drule.norm_hhf_eqs;
  1353 
  1354 in
  1355 
  1356 val norm_hhf = gen_norm_hhf hhf_ss;
  1357 val norm_hhf_protect = gen_norm_hhf (hhf_ss |> add_eqcong Drule.protect_cong);
  1358 
  1359 end;
  1360 
  1361 end;
  1362 
  1363 structure Basic_Meta_Simplifier: BASIC_RAW_SIMPLIFIER = Raw_Simplifier;
  1364 open Basic_Meta_Simplifier;