src/HOL/Library/Cardinality.thy
author Andreas Lochbihler
Thu May 31 17:10:43 2012 +0200 (2012-05-31)
changeset 48053 9bc78a08ff0a
parent 48052 b74766e4c11e
child 48058 11a732f7d79f
child 48063 f02b4302d5dd
permissions -rw-r--r--
tuned proofs
     1 (*  Title:      HOL/Library/Cardinality.thy
     2     Author:     Brian Huffman, Andreas Lochbihler
     3 *)
     4 
     5 header {* Cardinality of types *}
     6 
     7 theory Cardinality
     8 imports "~~/src/HOL/Main"
     9 begin
    10 
    11 subsection {* Preliminary lemmas *}
    12 (* These should be moved elsewhere *)
    13 
    14 lemma (in type_definition) univ:
    15   "UNIV = Abs ` A"
    16 proof
    17   show "Abs ` A \<subseteq> UNIV" by (rule subset_UNIV)
    18   show "UNIV \<subseteq> Abs ` A"
    19   proof
    20     fix x :: 'b
    21     have "x = Abs (Rep x)" by (rule Rep_inverse [symmetric])
    22     moreover have "Rep x \<in> A" by (rule Rep)
    23     ultimately show "x \<in> Abs ` A" by (rule image_eqI)
    24   qed
    25 qed
    26 
    27 lemma (in type_definition) card: "card (UNIV :: 'b set) = card A"
    28   by (simp add: univ card_image inj_on_def Abs_inject)
    29 
    30 
    31 subsection {* Cardinalities of types *}
    32 
    33 syntax "_type_card" :: "type => nat" ("(1CARD/(1'(_')))")
    34 
    35 translations "CARD('t)" => "CONST card (CONST UNIV \<Colon> 't set)"
    36 
    37 typed_print_translation (advanced) {*
    38   let
    39     fun card_univ_tr' ctxt _ [Const (@{const_syntax UNIV}, Type (_, [T, _]))] =
    40       Syntax.const @{syntax_const "_type_card"} $ Syntax_Phases.term_of_typ ctxt T;
    41   in [(@{const_syntax card}, card_univ_tr')] end
    42 *}
    43 
    44 lemma card_unit [simp]: "CARD(unit) = 1"
    45   unfolding UNIV_unit by simp
    46 
    47 lemma card_prod [simp]: "CARD('a \<times> 'b) = CARD('a::finite) * CARD('b::finite)"
    48   unfolding UNIV_Times_UNIV [symmetric] by (simp only: card_cartesian_product)
    49 
    50 lemma card_sum [simp]: "CARD('a + 'b) = CARD('a::finite) + CARD('b::finite)"
    51   unfolding UNIV_Plus_UNIV [symmetric] by (simp only: finite card_Plus)
    52 
    53 lemma card_option [simp]: "CARD('a option) = Suc CARD('a::finite)"
    54   unfolding UNIV_option_conv
    55   apply (subgoal_tac "(None::'a option) \<notin> range Some")
    56   apply (simp add: card_image)
    57   apply fast
    58   done
    59 
    60 lemma card_set [simp]: "CARD('a set) = 2 ^ CARD('a::finite)"
    61   unfolding Pow_UNIV [symmetric]
    62   by (simp only: card_Pow finite)
    63 
    64 lemma card_nat [simp]: "CARD(nat) = 0"
    65   by (simp add: card_eq_0_iff)
    66 
    67 
    68 subsection {* Classes with at least 1 and 2  *}
    69 
    70 text {* Class finite already captures "at least 1" *}
    71 
    72 lemma zero_less_card_finite [simp]: "0 < CARD('a::finite)"
    73   unfolding neq0_conv [symmetric] by simp
    74 
    75 lemma one_le_card_finite [simp]: "Suc 0 \<le> CARD('a::finite)"
    76   by (simp add: less_Suc_eq_le [symmetric])
    77 
    78 text {* Class for cardinality "at least 2" *}
    79 
    80 class card2 = finite + 
    81   assumes two_le_card: "2 \<le> CARD('a)"
    82 
    83 lemma one_less_card: "Suc 0 < CARD('a::card2)"
    84   using two_le_card [where 'a='a] by simp
    85 
    86 lemma one_less_int_card: "1 < int CARD('a::card2)"
    87   using one_less_card [where 'a='a] by simp
    88 
    89 subsection {* A type class for computing the cardinality of types *}
    90 
    91 class card_UNIV = 
    92   fixes card_UNIV :: "'a itself \<Rightarrow> nat"
    93   assumes card_UNIV: "card_UNIV x = card (UNIV :: 'a set)"
    94 begin
    95 
    96 lemma card_UNIV_neq_0_finite_UNIV:
    97   "card_UNIV x \<noteq> 0 \<longleftrightarrow> finite (UNIV :: 'a set)"
    98 by(simp add: card_UNIV card_eq_0_iff)
    99 
   100 lemma card_UNIV_ge_0_finite_UNIV:
   101   "card_UNIV x > 0 \<longleftrightarrow> finite (UNIV :: 'a set)"
   102 by(auto simp add: card_UNIV intro: card_ge_0_finite finite_UNIV_card_ge_0)
   103 
   104 lemma card_UNIV_eq_0_infinite_UNIV:
   105   "card_UNIV x = 0 \<longleftrightarrow> \<not> finite (UNIV :: 'a set)"
   106 by(simp add: card_UNIV card_eq_0_iff)
   107 
   108 definition is_list_UNIV :: "'a list \<Rightarrow> bool"
   109 where "is_list_UNIV xs = (let c = card_UNIV (TYPE('a)) in if c = 0 then False else size (remdups xs) = c)"
   110 
   111 lemma is_list_UNIV_iff: fixes xs :: "'a list"
   112   shows "is_list_UNIV xs \<longleftrightarrow> set xs = UNIV"
   113 proof
   114   assume "is_list_UNIV xs"
   115   hence c: "card_UNIV (TYPE('a)) > 0" and xs: "size (remdups xs) = card_UNIV (TYPE('a))"
   116     unfolding is_list_UNIV_def by(simp_all add: Let_def split: split_if_asm)
   117   from c have fin: "finite (UNIV :: 'a set)" by(auto simp add: card_UNIV_ge_0_finite_UNIV)
   118   have "card (set (remdups xs)) = size (remdups xs)" by(subst distinct_card) auto
   119   also note set_remdups
   120   finally show "set xs = UNIV" using fin unfolding xs card_UNIV by-(rule card_eq_UNIV_imp_eq_UNIV)
   121 next
   122   assume xs: "set xs = UNIV"
   123   from finite_set[of xs] have fin: "finite (UNIV :: 'a set)" unfolding xs .
   124   hence "card_UNIV (TYPE ('a)) \<noteq> 0" unfolding card_UNIV_neq_0_finite_UNIV .
   125   moreover have "size (remdups xs) = card (set (remdups xs))"
   126     by(subst distinct_card) auto
   127   ultimately show "is_list_UNIV xs" using xs by(simp add: is_list_UNIV_def Let_def card_UNIV)
   128 qed
   129 
   130 lemma card_UNIV_eq_0_is_list_UNIV_False:
   131   assumes cU0: "card_UNIV x = 0"
   132   shows "is_list_UNIV = (\<lambda>xs. False)"
   133 proof(rule ext)
   134   fix xs :: "'a list"
   135   from cU0 have "\<not> finite (UNIV :: 'a set)"
   136     by(auto simp only: card_UNIV_eq_0_infinite_UNIV)
   137   moreover have "finite (set xs)" by(rule finite_set)
   138   ultimately have "(UNIV :: 'a set) \<noteq> set xs" by(auto simp del: finite_set)
   139   thus "is_list_UNIV xs = False" unfolding is_list_UNIV_iff by simp
   140 qed
   141 
   142 end
   143 
   144 subsection {* Instantiations for @{text "card_UNIV"} *}
   145 
   146 subsubsection {* @{typ "nat"} *}
   147 
   148 instantiation nat :: card_UNIV begin
   149 definition "card_UNIV_class.card_UNIV = (\<lambda>a :: nat itself. 0)"
   150 instance by intro_classes (simp add: card_UNIV_nat_def)
   151 end
   152 
   153 subsubsection {* @{typ "int"} *}
   154 
   155 instantiation int :: card_UNIV begin
   156 definition "card_UNIV = (\<lambda>a :: int itself. 0)"
   157 instance by intro_classes (simp add: card_UNIV_int_def infinite_UNIV_int)
   158 end
   159 
   160 subsubsection {* @{typ "'a list"} *}
   161 
   162 instantiation list :: (type) card_UNIV begin
   163 definition "card_UNIV = (\<lambda>a :: 'a list itself. 0)"
   164 instance by intro_classes (simp add: card_UNIV_list_def infinite_UNIV_listI)
   165 end
   166 
   167 subsubsection {* @{typ "unit"} *}
   168 
   169 instantiation unit :: card_UNIV begin
   170 definition "card_UNIV = (\<lambda>a :: unit itself. 1)"
   171 instance by intro_classes (simp add: card_UNIV_unit_def card_UNIV_unit)
   172 end
   173 
   174 subsubsection {* @{typ "bool"} *}
   175 
   176 instantiation bool :: card_UNIV begin
   177 definition "card_UNIV = (\<lambda>a :: bool itself. 2)"
   178 instance by(intro_classes)(simp add: card_UNIV_bool_def card_UNIV_bool)
   179 end
   180 
   181 subsubsection {* @{typ "char"} *}
   182 
   183 lemma card_UNIV_char: "card (UNIV :: char set) = 256"
   184 proof -
   185   from enum_distinct
   186   have "card (set (Enum.enum :: char list)) = length (Enum.enum :: char list)"
   187     by (rule distinct_card)
   188   also have "set Enum.enum = (UNIV :: char set)" by (auto intro: in_enum)
   189   also note enum_chars
   190   finally show ?thesis by (simp add: chars_def)
   191 qed
   192 
   193 instantiation char :: card_UNIV begin
   194 definition "card_UNIV_class.card_UNIV = (\<lambda>a :: char itself. 256)"
   195 instance by intro_classes (simp add: card_UNIV_char_def card_UNIV_char)
   196 end
   197 
   198 subsubsection {* @{typ "'a \<times> 'b"} *}
   199 
   200 instantiation prod :: (card_UNIV, card_UNIV) card_UNIV begin
   201 definition "card_UNIV = (\<lambda>a :: ('a \<times> 'b) itself. card_UNIV (TYPE('a)) * card_UNIV (TYPE('b)))"
   202 instance 
   203   by intro_classes (simp add: card_UNIV_prod_def card_UNIV UNIV_Times_UNIV[symmetric] card_cartesian_product del: UNIV_Times_UNIV)
   204 end
   205 
   206 subsubsection {* @{typ "'a + 'b"} *}
   207 
   208 instantiation sum :: (card_UNIV, card_UNIV) card_UNIV begin
   209 definition "card_UNIV_class.card_UNIV = (\<lambda>a :: ('a + 'b) itself. 
   210   let ca = card_UNIV (TYPE('a)); cb = card_UNIV (TYPE('b))
   211   in if ca \<noteq> 0 \<and> cb \<noteq> 0 then ca + cb else 0)"
   212 instance
   213   by intro_classes (auto simp add: card_UNIV_sum_def card_UNIV card_eq_0_iff UNIV_Plus_UNIV[symmetric] finite_Plus_iff Let_def card_Plus simp del: UNIV_Plus_UNIV dest!: card_ge_0_finite)
   214 end
   215 
   216 subsubsection {* @{typ "'a \<Rightarrow> 'b"} *}
   217 
   218 instantiation "fun" :: (card_UNIV, card_UNIV) card_UNIV begin
   219 
   220 definition "card_UNIV = 
   221   (\<lambda>a :: ('a \<Rightarrow> 'b) itself. let ca = card_UNIV (TYPE('a)); cb = card_UNIV (TYPE('b))
   222                             in if ca \<noteq> 0 \<and> cb \<noteq> 0 \<or> cb = 1 then cb ^ ca else 0)"
   223 
   224 instance proof
   225   fix x :: "('a \<Rightarrow> 'b) itself"
   226 
   227   { assume "0 < card (UNIV :: 'a set)"
   228     and "0 < card (UNIV :: 'b set)"
   229     hence fina: "finite (UNIV :: 'a set)" and finb: "finite (UNIV :: 'b set)"
   230       by(simp_all only: card_ge_0_finite)
   231     from finite_distinct_list[OF finb] obtain bs 
   232       where bs: "set bs = (UNIV :: 'b set)" and distb: "distinct bs" by blast
   233     from finite_distinct_list[OF fina] obtain as
   234       where as: "set as = (UNIV :: 'a set)" and dista: "distinct as" by blast
   235     have cb: "card (UNIV :: 'b set) = length bs"
   236       unfolding bs[symmetric] distinct_card[OF distb] ..
   237     have ca: "card (UNIV :: 'a set) = length as"
   238       unfolding as[symmetric] distinct_card[OF dista] ..
   239     let ?xs = "map (\<lambda>ys. the o map_of (zip as ys)) (Enum.n_lists (length as) bs)"
   240     have "UNIV = set ?xs"
   241     proof(rule UNIV_eq_I)
   242       fix f :: "'a \<Rightarrow> 'b"
   243       from as have "f = the \<circ> map_of (zip as (map f as))"
   244         by(auto simp add: map_of_zip_map)
   245       thus "f \<in> set ?xs" using bs by(auto simp add: set_n_lists)
   246     qed
   247     moreover have "distinct ?xs" unfolding distinct_map
   248     proof(intro conjI distinct_n_lists distb inj_onI)
   249       fix xs ys :: "'b list"
   250       assume xs: "xs \<in> set (Enum.n_lists (length as) bs)"
   251         and ys: "ys \<in> set (Enum.n_lists (length as) bs)"
   252         and eq: "the \<circ> map_of (zip as xs) = the \<circ> map_of (zip as ys)"
   253       from xs ys have [simp]: "length xs = length as" "length ys = length as"
   254         by(simp_all add: length_n_lists_elem)
   255       have "map_of (zip as xs) = map_of (zip as ys)"
   256       proof
   257         fix x
   258         from as bs have "\<exists>y. map_of (zip as xs) x = Some y" "\<exists>y. map_of (zip as ys) x = Some y"
   259           by(simp_all add: map_of_zip_is_Some[symmetric])
   260         with eq show "map_of (zip as xs) x = map_of (zip as ys) x"
   261           by(auto dest: fun_cong[where x=x])
   262       qed
   263       with dista show "xs = ys" by(simp add: map_of_zip_inject)
   264     qed
   265     hence "card (set ?xs) = length ?xs" by(simp only: distinct_card)
   266     moreover have "length ?xs = length bs ^ length as" by(simp add: length_n_lists)
   267     ultimately have "card (UNIV :: ('a \<Rightarrow> 'b) set) = card (UNIV :: 'b set) ^ card (UNIV :: 'a set)"
   268       using cb ca by simp }
   269   moreover {
   270     assume cb: "card (UNIV :: 'b set) = Suc 0"
   271     then obtain b where b: "UNIV = {b :: 'b}" by(auto simp add: card_Suc_eq)
   272     have eq: "UNIV = {\<lambda>x :: 'a. b ::'b}"
   273     proof(rule UNIV_eq_I)
   274       fix x :: "'a \<Rightarrow> 'b"
   275       { fix y
   276         have "x y \<in> UNIV" ..
   277         hence "x y = b" unfolding b by simp }
   278       thus "x \<in> {\<lambda>x. b}" by(auto)
   279     qed
   280     have "card (UNIV :: ('a \<Rightarrow> 'b) set) = Suc 0" unfolding eq by simp }
   281   ultimately show "card_UNIV x = card (UNIV :: ('a \<Rightarrow> 'b) set)"
   282     unfolding card_UNIV_fun_def card_UNIV Let_def
   283     by(auto simp del: One_nat_def)(auto simp add: card_eq_0_iff dest: finite_fun_UNIVD2 finite_fun_UNIVD1)
   284 qed
   285 
   286 end
   287 
   288 subsubsection {* @{typ "'a option"} *}
   289 
   290 instantiation option :: (card_UNIV) card_UNIV
   291 begin
   292 
   293 definition "card_UNIV = (\<lambda>a :: 'a option itself. let c = card_UNIV (TYPE('a)) in if c \<noteq> 0 then Suc c else 0)"
   294 
   295 instance proof
   296   fix x :: "'a option itself"
   297   show "card_UNIV x = card (UNIV :: 'a option set)"
   298     by(auto simp add: UNIV_option_conv card_UNIV_option_def card_UNIV card_eq_0_iff Let_def intro: inj_Some dest: finite_imageD)
   299       (subst card_insert_disjoint, auto simp add: card_eq_0_iff card_image inj_Some intro: finite_imageI card_ge_0_finite)
   300 qed
   301 
   302 end
   303 
   304 subsection {* Code setup for equality on sets *}
   305 
   306 definition eq_set :: "'a :: card_UNIV set \<Rightarrow> 'a :: card_UNIV set \<Rightarrow> bool"
   307 where [simp, code del]: "eq_set = op ="
   308 
   309 lemmas [code_unfold] = eq_set_def[symmetric]
   310 
   311 lemma card_Compl:
   312   "finite A \<Longrightarrow> card (- A) = card (UNIV :: 'a set) - card (A :: 'a set)"
   313 by (metis Compl_eq_Diff_UNIV card_Diff_subset top_greatest)
   314 
   315 lemma eq_set_code [code]:
   316   fixes xs ys :: "'a :: card_UNIV list"
   317   defines "rhs \<equiv> 
   318   let n = card_UNIV TYPE('a)
   319   in if n = 0 then False else 
   320         let xs' = remdups xs; ys' = remdups ys 
   321         in length xs' + length ys' = n \<and> (\<forall>x \<in> set xs'. x \<notin> set ys') \<and> (\<forall>y \<in> set ys'. y \<notin> set xs')"
   322   shows "eq_set (List.coset xs) (set ys) \<longleftrightarrow> rhs" (is ?thesis1)
   323   and "eq_set (set ys) (List.coset xs) \<longleftrightarrow> rhs" (is ?thesis2)
   324   and "eq_set (set xs) (set ys) \<longleftrightarrow> (\<forall>x \<in> set xs. x \<in> set ys) \<and> (\<forall>y \<in> set ys. y \<in> set xs)" (is ?thesis3)
   325   and "eq_set (List.coset xs) (List.coset ys) \<longleftrightarrow> (\<forall>x \<in> set xs. x \<in> set ys) \<and> (\<forall>y \<in> set ys. y \<in> set xs)" (is ?thesis4)
   326 proof -
   327   show ?thesis1 (is "?lhs \<longleftrightarrow> ?rhs")
   328   proof
   329     assume ?lhs thus ?rhs
   330       by(auto simp add: rhs_def Let_def List.card_set[symmetric] card_Un_Int[where A="set xs" and B="- set xs"] card_UNIV Compl_partition card_gt_0_iff dest: sym)(metis finite_compl finite_set)
   331   next
   332     assume ?rhs
   333     moreover have "\<lbrakk> \<forall>y\<in>set xs. y \<notin> set ys; \<forall>x\<in>set ys. x \<notin> set xs \<rbrakk> \<Longrightarrow> set xs \<inter> set ys = {}" by blast
   334     ultimately show ?lhs
   335       by(auto simp add: rhs_def Let_def List.card_set[symmetric] card_UNIV card_gt_0_iff card_Un_Int[where A="set xs" and B="set ys"] dest: card_eq_UNIV_imp_eq_UNIV split: split_if_asm)
   336   qed
   337   thus ?thesis2 unfolding eq_set_def by blast
   338   show ?thesis3 ?thesis4 unfolding eq_set_def List.coset_def by blast+
   339 qed
   340 
   341 (* test code setup *)
   342 value [code] "List.coset [True] = set [False] \<and> set [] = List.coset [True, False]"
   343 
   344 end