src/HOL/List.thy
author obua
Mon Apr 10 16:00:34 2006 +0200 (2006-04-10)
changeset 19404 9bf2cdc9e8e8
parent 19390 6c7383f80ad1
child 19487 d5e79a41bce0
permissions -rw-r--r--
Moved stuff from Ring_and_Field to Matrix
     1 (*  Title:      HOL/List.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow
     4 *)
     5 
     6 header {* The datatype of finite lists *}
     7 
     8 theory List
     9 imports PreList
    10 begin
    11 
    12 datatype 'a list =
    13     Nil    ("[]")
    14   | Cons 'a  "'a list"    (infixr "#" 65)
    15 
    16 subsection{*Basic list processing functions*}
    17 
    18 consts
    19   "@" :: "'a list => 'a list => 'a list"    (infixr 65)
    20   filter:: "('a => bool) => 'a list => 'a list"
    21   concat:: "'a list list => 'a list"
    22   foldl :: "('b => 'a => 'b) => 'b => 'a list => 'b"
    23   foldr :: "('a => 'b => 'b) => 'a list => 'b => 'b"
    24   hd:: "'a list => 'a"
    25   tl:: "'a list => 'a list"
    26   last:: "'a list => 'a"
    27   butlast :: "'a list => 'a list"
    28   set :: "'a list => 'a set"
    29   list_all2 :: "('a => 'b => bool) => 'a list => 'b list => bool"
    30   map :: "('a=>'b) => ('a list => 'b list)"
    31   nth :: "'a list => nat => 'a"    (infixl "!" 100)
    32   list_update :: "'a list => nat => 'a => 'a list"
    33   take:: "nat => 'a list => 'a list"
    34   drop:: "nat => 'a list => 'a list"
    35   takeWhile :: "('a => bool) => 'a list => 'a list"
    36   dropWhile :: "('a => bool) => 'a list => 'a list"
    37   rev :: "'a list => 'a list"
    38   zip :: "'a list => 'b list => ('a * 'b) list"
    39   upt :: "nat => nat => nat list" ("(1[_..</_'])")
    40   remdups :: "'a list => 'a list"
    41   remove1 :: "'a => 'a list => 'a list"
    42   null:: "'a list => bool"
    43   "distinct":: "'a list => bool"
    44   replicate :: "nat => 'a => 'a list"
    45   rotate1 :: "'a list \<Rightarrow> 'a list"
    46   rotate :: "nat \<Rightarrow> 'a list \<Rightarrow> 'a list"
    47   splice :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
    48   sublist :: "'a list => nat set => 'a list"
    49 (* For efficiency *)
    50   mem :: "'a => 'a list => bool"    (infixl 55)
    51   list_inter :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
    52   list_ex :: "('a \<Rightarrow> bool) \<Rightarrow> 'a list \<Rightarrow> bool"
    53   list_all:: "('a => bool) => ('a list => bool)"
    54   itrev :: "'a list \<Rightarrow> 'a list \<Rightarrow> 'a list"
    55   filtermap :: "('a \<Rightarrow> 'b option) \<Rightarrow> 'a list \<Rightarrow> 'b list"
    56   map_filter :: "('a => 'b) => ('a => bool) => 'a list => 'b list"
    57 
    58 abbreviation
    59   upto:: "nat => nat => nat list"    ("(1[_../_])")
    60   "[i..j] == [i..<(Suc j)]"
    61 
    62 
    63 nonterminals lupdbinds lupdbind
    64 
    65 syntax
    66   -- {* list Enumeration *}
    67   "@list" :: "args => 'a list"    ("[(_)]")
    68 
    69   -- {* Special syntax for filter *}
    70   "@filter" :: "[pttrn, 'a list, bool] => 'a list"    ("(1[_:_./ _])")
    71 
    72   -- {* list update *}
    73   "_lupdbind":: "['a, 'a] => lupdbind"    ("(2_ :=/ _)")
    74   "" :: "lupdbind => lupdbinds"    ("_")
    75   "_lupdbinds" :: "[lupdbind, lupdbinds] => lupdbinds"    ("_,/ _")
    76   "_LUpdate" :: "['a, lupdbinds] => 'a"    ("_/[(_)]" [900,0] 900)
    77 
    78 translations
    79   "[x, xs]" == "x#[xs]"
    80   "[x]" == "x#[]"
    81   "[x:xs . P]"== "filter (%x. P) xs"
    82 
    83   "_LUpdate xs (_lupdbinds b bs)"== "_LUpdate (_LUpdate xs b) bs"
    84   "xs[i:=x]" == "list_update xs i x"
    85 
    86 
    87 syntax (xsymbols)
    88   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    89 syntax (HTML output)
    90   "@filter" :: "[pttrn, 'a list, bool] => 'a list"("(1[_\<in>_ ./ _])")
    91 
    92 
    93 text {*
    94   Function @{text size} is overloaded for all datatypes. Users may
    95   refer to the list version as @{text length}. *}
    96 
    97 abbreviation
    98   length :: "'a list => nat"
    99   "length == size"
   100 
   101 primrec
   102   "hd(x#xs) = x"
   103 
   104 primrec
   105   "tl([]) = []"
   106   "tl(x#xs) = xs"
   107 
   108 primrec
   109   "null([]) = True"
   110   "null(x#xs) = False"
   111 
   112 primrec
   113   "last(x#xs) = (if xs=[] then x else last xs)"
   114 
   115 primrec
   116   "butlast []= []"
   117   "butlast(x#xs) = (if xs=[] then [] else x#butlast xs)"
   118 
   119 primrec
   120   "set [] = {}"
   121   "set (x#xs) = insert x (set xs)"
   122 
   123 primrec
   124   "map f [] = []"
   125   "map f (x#xs) = f(x)#map f xs"
   126 
   127 primrec
   128   append_Nil:"[]@ys = ys"
   129   append_Cons: "(x#xs)@ys = x#(xs@ys)"
   130 
   131 primrec
   132   "rev([]) = []"
   133   "rev(x#xs) = rev(xs) @ [x]"
   134 
   135 primrec
   136   "filter P [] = []"
   137   "filter P (x#xs) = (if P x then x#filter P xs else filter P xs)"
   138 
   139 primrec
   140   foldl_Nil:"foldl f a [] = a"
   141   foldl_Cons: "foldl f a (x#xs) = foldl f (f a x) xs"
   142 
   143 primrec
   144   "foldr f [] a = a"
   145   "foldr f (x#xs) a = f x (foldr f xs a)"
   146 
   147 primrec
   148   "concat([]) = []"
   149   "concat(x#xs) = x @ concat(xs)"
   150 
   151 primrec
   152   drop_Nil:"drop n [] = []"
   153   drop_Cons: "drop n (x#xs) = (case n of 0 => x#xs | Suc(m) => drop m xs)"
   154   -- {*Warning: simpset does not contain this definition, but separate
   155        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   156 
   157 primrec
   158   take_Nil:"take n [] = []"
   159   take_Cons: "take n (x#xs) = (case n of 0 => [] | Suc(m) => x # take m xs)"
   160   -- {*Warning: simpset does not contain this definition, but separate
   161        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   162 
   163 primrec
   164   nth_Cons:"(x#xs)!n = (case n of 0 => x | (Suc k) => xs!k)"
   165   -- {*Warning: simpset does not contain this definition, but separate
   166        theorems for @{text "n = 0"} and @{text "n = Suc k"} *}
   167 
   168 primrec
   169   "[][i:=v] = []"
   170   "(x#xs)[i:=v] = (case i of 0 => v # xs | Suc j => x # xs[j:=v])"
   171 
   172 primrec
   173   "takeWhile P [] = []"
   174   "takeWhile P (x#xs) = (if P x then x#takeWhile P xs else [])"
   175 
   176 primrec
   177   "dropWhile P [] = []"
   178   "dropWhile P (x#xs) = (if P x then dropWhile P xs else x#xs)"
   179 
   180 primrec
   181   "zip xs [] = []"
   182   zip_Cons: "zip xs (y#ys) = (case xs of [] => [] | z#zs => (z,y)#zip zs ys)"
   183   -- {*Warning: simpset does not contain this definition, but separate
   184        theorems for @{text "xs = []"} and @{text "xs = z # zs"} *}
   185 
   186 primrec
   187   upt_0: "[i..<0] = []"
   188   upt_Suc: "[i..<(Suc j)] = (if i <= j then [i..<j] @ [j] else [])"
   189 
   190 primrec
   191   "distinct [] = True"
   192   "distinct (x#xs) = (x ~: set xs \<and> distinct xs)"
   193 
   194 primrec
   195   "remdups [] = []"
   196   "remdups (x#xs) = (if x : set xs then remdups xs else x # remdups xs)"
   197 
   198 primrec
   199   "remove1 x [] = []"
   200   "remove1 x (y#xs) = (if x=y then xs else y # remove1 x xs)"
   201 
   202 primrec
   203   replicate_0: "replicate 0 x = []"
   204   replicate_Suc: "replicate (Suc n) x = x # replicate n x"
   205 
   206 defs
   207 rotate1_def: "rotate1 xs == (case xs of [] \<Rightarrow> [] | x#xs \<Rightarrow> xs @ [x])"
   208 rotate_def:  "rotate n == rotate1 ^ n"
   209 
   210 list_all2_def:
   211  "list_all2 P xs ys ==
   212   length xs = length ys \<and> (\<forall>(x, y) \<in> set (zip xs ys). P x y)"
   213 
   214 sublist_def:
   215  "sublist xs A == map fst (filter (%p. snd p : A) (zip xs [0..<size xs]))"
   216 
   217 primrec
   218 "splice [] ys = ys"
   219 "splice (x#xs) ys = (if ys=[] then x#xs else x # hd ys # splice xs (tl ys))"
   220   -- {*Warning: simpset does not contain the second eqn but a derived one. *}
   221 
   222 primrec
   223   "x mem [] = False"
   224   "x mem (y#ys) = (if y=x then True else x mem ys)"
   225 
   226 primrec
   227  "list_inter [] bs = []"
   228  "list_inter (a#as) bs =
   229   (if a \<in> set bs then a#(list_inter as bs) else list_inter as bs)"
   230 
   231 primrec
   232   "list_all P [] = True"
   233   "list_all P (x#xs) = (P(x) \<and> list_all P xs)"
   234 
   235 primrec
   236 "list_ex P [] = False"
   237 "list_ex P (x#xs) = (P x \<or> list_ex P xs)"
   238 
   239 primrec
   240  "filtermap f [] = []"
   241  "filtermap f (x#xs) =
   242     (case f x of None \<Rightarrow> filtermap f xs
   243      | Some y \<Rightarrow> y # (filtermap f xs))"
   244 
   245 primrec
   246   "map_filter f P [] = []"
   247   "map_filter f P (x#xs) = (if P x then f x # map_filter f P xs else 
   248                map_filter f P xs)"
   249 
   250 primrec
   251 "itrev [] ys = ys"
   252 "itrev (x#xs) ys = itrev xs (x#ys)"
   253 
   254 
   255 lemma not_Cons_self [simp]: "xs \<noteq> x # xs"
   256 by (induct xs) auto
   257 
   258 lemmas not_Cons_self2 [simp] = not_Cons_self [symmetric]
   259 
   260 lemma neq_Nil_conv: "(xs \<noteq> []) = (\<exists>y ys. xs = y # ys)"
   261 by (induct xs) auto
   262 
   263 lemma length_induct:
   264 "(!!xs. \<forall>ys. length ys < length xs --> P ys ==> P xs) ==> P xs"
   265 by (rule measure_induct [of length]) iprover
   266 
   267 
   268 subsubsection {* @{text length} *}
   269 
   270 text {*
   271 Needs to come before @{text "@"} because of theorem @{text
   272 append_eq_append_conv}.
   273 *}
   274 
   275 lemma length_append [simp]: "length (xs @ ys) = length xs + length ys"
   276 by (induct xs) auto
   277 
   278 lemma length_map [simp]: "length (map f xs) = length xs"
   279 by (induct xs) auto
   280 
   281 lemma length_rev [simp]: "length (rev xs) = length xs"
   282 by (induct xs) auto
   283 
   284 lemma length_tl [simp]: "length (tl xs) = length xs - 1"
   285 by (cases xs) auto
   286 
   287 lemma length_0_conv [iff]: "(length xs = 0) = (xs = [])"
   288 by (induct xs) auto
   289 
   290 lemma length_greater_0_conv [iff]: "(0 < length xs) = (xs \<noteq> [])"
   291 by (induct xs) auto
   292 
   293 lemma length_Suc_conv:
   294 "(length xs = Suc n) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   295 by (induct xs) auto
   296 
   297 lemma Suc_length_conv:
   298 "(Suc n = length xs) = (\<exists>y ys. xs = y # ys \<and> length ys = n)"
   299 apply (induct xs, simp, simp)
   300 apply blast
   301 done
   302 
   303 lemma impossible_Cons [rule_format]: 
   304   "length xs <= length ys --> xs = x # ys = False"
   305 apply (induct xs, auto)
   306 done
   307 
   308 lemma list_induct2[consumes 1]: "\<And>ys.
   309  \<lbrakk> length xs = length ys;
   310    P [] [];
   311    \<And>x xs y ys. \<lbrakk> length xs = length ys; P xs ys \<rbrakk> \<Longrightarrow> P (x#xs) (y#ys) \<rbrakk>
   312  \<Longrightarrow> P xs ys"
   313 apply(induct xs)
   314  apply simp
   315 apply(case_tac ys)
   316  apply simp
   317 apply(simp)
   318 done
   319 
   320 subsubsection {* @{text "@"} -- append *}
   321 
   322 lemma append_assoc [simp]: "(xs @ ys) @ zs = xs @ (ys @ zs)"
   323 by (induct xs) auto
   324 
   325 lemma append_Nil2 [simp]: "xs @ [] = xs"
   326 by (induct xs) auto
   327 
   328 lemma append_is_Nil_conv [iff]: "(xs @ ys = []) = (xs = [] \<and> ys = [])"
   329 by (induct xs) auto
   330 
   331 lemma Nil_is_append_conv [iff]: "([] = xs @ ys) = (xs = [] \<and> ys = [])"
   332 by (induct xs) auto
   333 
   334 lemma append_self_conv [iff]: "(xs @ ys = xs) = (ys = [])"
   335 by (induct xs) auto
   336 
   337 lemma self_append_conv [iff]: "(xs = xs @ ys) = (ys = [])"
   338 by (induct xs) auto
   339 
   340 lemma append_eq_append_conv [simp]:
   341  "!!ys. length xs = length ys \<or> length us = length vs
   342  ==> (xs@us = ys@vs) = (xs=ys \<and> us=vs)"
   343 apply (induct xs)
   344  apply (case_tac ys, simp, force)
   345 apply (case_tac ys, force, simp)
   346 done
   347 
   348 lemma append_eq_append_conv2: "!!ys zs ts.
   349  (xs @ ys = zs @ ts) =
   350  (EX us. xs = zs @ us & us @ ys = ts | xs @ us = zs & ys = us@ ts)"
   351 apply (induct xs)
   352  apply fastsimp
   353 apply(case_tac zs)
   354  apply simp
   355 apply fastsimp
   356 done
   357 
   358 lemma same_append_eq [iff]: "(xs @ ys = xs @ zs) = (ys = zs)"
   359 by simp
   360 
   361 lemma append1_eq_conv [iff]: "(xs @ [x] = ys @ [y]) = (xs = ys \<and> x = y)"
   362 by simp
   363 
   364 lemma append_same_eq [iff]: "(ys @ xs = zs @ xs) = (ys = zs)"
   365 by simp
   366 
   367 lemma append_self_conv2 [iff]: "(xs @ ys = ys) = (xs = [])"
   368 using append_same_eq [of _ _ "[]"] by auto
   369 
   370 lemma self_append_conv2 [iff]: "(ys = xs @ ys) = (xs = [])"
   371 using append_same_eq [of "[]"] by auto
   372 
   373 lemma hd_Cons_tl [simp]: "xs \<noteq> [] ==> hd xs # tl xs = xs"
   374 by (induct xs) auto
   375 
   376 lemma hd_append: "hd (xs @ ys) = (if xs = [] then hd ys else hd xs)"
   377 by (induct xs) auto
   378 
   379 lemma hd_append2 [simp]: "xs \<noteq> [] ==> hd (xs @ ys) = hd xs"
   380 by (simp add: hd_append split: list.split)
   381 
   382 lemma tl_append: "tl (xs @ ys) = (case xs of [] => tl ys | z#zs => zs @ ys)"
   383 by (simp split: list.split)
   384 
   385 lemma tl_append2 [simp]: "xs \<noteq> [] ==> tl (xs @ ys) = tl xs @ ys"
   386 by (simp add: tl_append split: list.split)
   387 
   388 
   389 lemma Cons_eq_append_conv: "x#xs = ys@zs =
   390  (ys = [] & x#xs = zs | (EX ys'. x#ys' = ys & xs = ys'@zs))"
   391 by(cases ys) auto
   392 
   393 lemma append_eq_Cons_conv: "(ys@zs = x#xs) =
   394  (ys = [] & zs = x#xs | (EX ys'. ys = x#ys' & ys'@zs = xs))"
   395 by(cases ys) auto
   396 
   397 
   398 text {* Trivial rules for solving @{text "@"}-equations automatically. *}
   399 
   400 lemma eq_Nil_appendI: "xs = ys ==> xs = [] @ ys"
   401 by simp
   402 
   403 lemma Cons_eq_appendI:
   404 "[| x # xs1 = ys; xs = xs1 @ zs |] ==> x # xs = ys @ zs"
   405 by (drule sym) simp
   406 
   407 lemma append_eq_appendI:
   408 "[| xs @ xs1 = zs; ys = xs1 @ us |] ==> xs @ ys = zs @ us"
   409 by (drule sym) simp
   410 
   411 
   412 text {*
   413 Simplification procedure for all list equalities.
   414 Currently only tries to rearrange @{text "@"} to see if
   415 - both lists end in a singleton list,
   416 - or both lists end in the same list.
   417 *}
   418 
   419 ML_setup {*
   420 local
   421 
   422 val append_assoc = thm "append_assoc";
   423 val append_Nil = thm "append_Nil";
   424 val append_Cons = thm "append_Cons";
   425 val append1_eq_conv = thm "append1_eq_conv";
   426 val append_same_eq = thm "append_same_eq";
   427 
   428 fun last (cons as Const("List.list.Cons",_) $ _ $ xs) =
   429   (case xs of Const("List.list.Nil",_) => cons | _ => last xs)
   430   | last (Const("List.op @",_) $ _ $ ys) = last ys
   431   | last t = t;
   432 
   433 fun list1 (Const("List.list.Cons",_) $ _ $ Const("List.list.Nil",_)) = true
   434   | list1 _ = false;
   435 
   436 fun butlast ((cons as Const("List.list.Cons",_) $ x) $ xs) =
   437   (case xs of Const("List.list.Nil",_) => xs | _ => cons $ butlast xs)
   438   | butlast ((app as Const("List.op @",_) $ xs) $ ys) = app $ butlast ys
   439   | butlast xs = Const("List.list.Nil",fastype_of xs);
   440 
   441 val rearr_ss = HOL_basic_ss addsimps [append_assoc, append_Nil, append_Cons];
   442 
   443 fun list_eq sg ss (F as (eq as Const(_,eqT)) $ lhs $ rhs) =
   444   let
   445     val lastl = last lhs and lastr = last rhs;
   446     fun rearr conv =
   447       let
   448         val lhs1 = butlast lhs and rhs1 = butlast rhs;
   449         val Type(_,listT::_) = eqT
   450         val appT = [listT,listT] ---> listT
   451         val app = Const("List.op @",appT)
   452         val F2 = eq $ (app$lhs1$lastl) $ (app$rhs1$lastr)
   453         val eq = HOLogic.mk_Trueprop (HOLogic.mk_eq (F,F2));
   454         val thm = Goal.prove sg [] [] eq
   455           (K (simp_tac (Simplifier.inherit_context ss rearr_ss) 1));
   456       in SOME ((conv RS (thm RS trans)) RS eq_reflection) end;
   457 
   458   in
   459     if list1 lastl andalso list1 lastr then rearr append1_eq_conv
   460     else if lastl aconv lastr then rearr append_same_eq
   461     else NONE
   462   end;
   463 
   464 in
   465 
   466 val list_eq_simproc =
   467   Simplifier.simproc (Theory.sign_of (the_context ())) "list_eq" ["(xs::'a list) = ys"] list_eq;
   468 
   469 end;
   470 
   471 Addsimprocs [list_eq_simproc];
   472 *}
   473 
   474 
   475 subsubsection {* @{text map} *}
   476 
   477 lemma map_ext: "(!!x. x : set xs --> f x = g x) ==> map f xs = map g xs"
   478 by (induct xs) simp_all
   479 
   480 lemma map_ident [simp]: "map (\<lambda>x. x) = (\<lambda>xs. xs)"
   481 by (rule ext, induct_tac xs) auto
   482 
   483 lemma map_append [simp]: "map f (xs @ ys) = map f xs @ map f ys"
   484 by (induct xs) auto
   485 
   486 lemma map_compose: "map (f o g) xs = map f (map g xs)"
   487 by (induct xs) (auto simp add: o_def)
   488 
   489 lemma rev_map: "rev (map f xs) = map f (rev xs)"
   490 by (induct xs) auto
   491 
   492 lemma map_eq_conv[simp]: "(map f xs = map g xs) = (!x : set xs. f x = g x)"
   493 by (induct xs) auto
   494 
   495 lemma map_cong [recdef_cong]:
   496 "xs = ys ==> (!!x. x : set ys ==> f x = g x) ==> map f xs = map g ys"
   497 -- {* a congruence rule for @{text map} *}
   498 by simp
   499 
   500 lemma map_is_Nil_conv [iff]: "(map f xs = []) = (xs = [])"
   501 by (cases xs) auto
   502 
   503 lemma Nil_is_map_conv [iff]: "([] = map f xs) = (xs = [])"
   504 by (cases xs) auto
   505 
   506 lemma map_eq_Cons_conv:
   507  "(map f xs = y#ys) = (\<exists>z zs. xs = z#zs \<and> f z = y \<and> map f zs = ys)"
   508 by (cases xs) auto
   509 
   510 lemma Cons_eq_map_conv:
   511  "(x#xs = map f ys) = (\<exists>z zs. ys = z#zs \<and> x = f z \<and> xs = map f zs)"
   512 by (cases ys) auto
   513 
   514 lemmas map_eq_Cons_D = map_eq_Cons_conv [THEN iffD1]
   515 lemmas Cons_eq_map_D = Cons_eq_map_conv [THEN iffD1]
   516 declare map_eq_Cons_D [dest!]  Cons_eq_map_D [dest!]
   517 
   518 lemma ex_map_conv:
   519   "(EX xs. ys = map f xs) = (ALL y : set ys. EX x. y = f x)"
   520 by(induct ys, auto simp add: Cons_eq_map_conv)
   521 
   522 lemma map_eq_imp_length_eq:
   523   "!!xs. map f xs = map f ys ==> length xs = length ys"
   524 apply (induct ys)
   525  apply simp
   526 apply(simp (no_asm_use))
   527 apply clarify
   528 apply(simp (no_asm_use))
   529 apply fast
   530 done
   531 
   532 lemma map_inj_on:
   533  "[| map f xs = map f ys; inj_on f (set xs Un set ys) |]
   534   ==> xs = ys"
   535 apply(frule map_eq_imp_length_eq)
   536 apply(rotate_tac -1)
   537 apply(induct rule:list_induct2)
   538  apply simp
   539 apply(simp)
   540 apply (blast intro:sym)
   541 done
   542 
   543 lemma inj_on_map_eq_map:
   544  "inj_on f (set xs Un set ys) \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   545 by(blast dest:map_inj_on)
   546 
   547 lemma map_injective:
   548  "!!xs. map f xs = map f ys ==> inj f ==> xs = ys"
   549 by (induct ys) (auto dest!:injD)
   550 
   551 lemma inj_map_eq_map[simp]: "inj f \<Longrightarrow> (map f xs = map f ys) = (xs = ys)"
   552 by(blast dest:map_injective)
   553 
   554 lemma inj_mapI: "inj f ==> inj (map f)"
   555 by (iprover dest: map_injective injD intro: inj_onI)
   556 
   557 lemma inj_mapD: "inj (map f) ==> inj f"
   558 apply (unfold inj_on_def, clarify)
   559 apply (erule_tac x = "[x]" in ballE)
   560  apply (erule_tac x = "[y]" in ballE, simp, blast)
   561 apply blast
   562 done
   563 
   564 lemma inj_map[iff]: "inj (map f) = inj f"
   565 by (blast dest: inj_mapD intro: inj_mapI)
   566 
   567 lemma inj_on_mapI: "inj_on f (\<Union>(set ` A)) \<Longrightarrow> inj_on (map f) A"
   568 apply(rule inj_onI)
   569 apply(erule map_inj_on)
   570 apply(blast intro:inj_onI dest:inj_onD)
   571 done
   572 
   573 lemma map_idI: "(\<And>x. x \<in> set xs \<Longrightarrow> f x = x) \<Longrightarrow> map f xs = xs"
   574 by (induct xs, auto)
   575 
   576 lemma map_fun_upd [simp]: "y \<notin> set xs \<Longrightarrow> map (f(y:=v)) xs = map f xs"
   577 by (induct xs) auto
   578 
   579 lemma map_fst_zip[simp]:
   580   "length xs = length ys \<Longrightarrow> map fst (zip xs ys) = xs"
   581 by (induct rule:list_induct2, simp_all)
   582 
   583 lemma map_snd_zip[simp]:
   584   "length xs = length ys \<Longrightarrow> map snd (zip xs ys) = ys"
   585 by (induct rule:list_induct2, simp_all)
   586 
   587 
   588 subsubsection {* @{text rev} *}
   589 
   590 lemma rev_append [simp]: "rev (xs @ ys) = rev ys @ rev xs"
   591 by (induct xs) auto
   592 
   593 lemma rev_rev_ident [simp]: "rev (rev xs) = xs"
   594 by (induct xs) auto
   595 
   596 lemma rev_swap: "(rev xs = ys) = (xs = rev ys)"
   597 by auto
   598 
   599 lemma rev_is_Nil_conv [iff]: "(rev xs = []) = (xs = [])"
   600 by (induct xs) auto
   601 
   602 lemma Nil_is_rev_conv [iff]: "([] = rev xs) = (xs = [])"
   603 by (induct xs) auto
   604 
   605 lemma rev_singleton_conv [simp]: "(rev xs = [x]) = (xs = [x])"
   606 by (cases xs) auto
   607 
   608 lemma singleton_rev_conv [simp]: "([x] = rev xs) = (xs = [x])"
   609 by (cases xs) auto
   610 
   611 lemma rev_is_rev_conv [iff]: "!!ys. (rev xs = rev ys) = (xs = ys)"
   612 apply (induct xs, force)
   613 apply (case_tac ys, simp, force)
   614 done
   615 
   616 lemma inj_on_rev[iff]: "inj_on rev A"
   617 by(simp add:inj_on_def)
   618 
   619 lemma rev_induct [case_names Nil snoc]:
   620   "[| P []; !!x xs. P xs ==> P (xs @ [x]) |] ==> P xs"
   621 apply(simplesubst rev_rev_ident[symmetric])
   622 apply(rule_tac list = "rev xs" in list.induct, simp_all)
   623 done
   624 
   625 ML {* val rev_induct_tac = induct_thm_tac (thm "rev_induct") *}-- "compatibility"
   626 
   627 lemma rev_exhaust [case_names Nil snoc]:
   628   "(xs = [] ==> P) ==>(!!ys y. xs = ys @ [y] ==> P) ==> P"
   629 by (induct xs rule: rev_induct) auto
   630 
   631 lemmas rev_cases = rev_exhaust
   632 
   633 lemma rev_eq_Cons_iff[iff]: "(rev xs = y#ys) = (xs = rev ys @ [y])"
   634 by(rule rev_cases[of xs]) auto
   635 
   636 
   637 subsubsection {* @{text set} *}
   638 
   639 lemma finite_set [iff]: "finite (set xs)"
   640 by (induct xs) auto
   641 
   642 lemma set_append [simp]: "set (xs @ ys) = (set xs \<union> set ys)"
   643 by (induct xs) auto
   644 
   645 lemma hd_in_set[simp]: "xs \<noteq> [] \<Longrightarrow> hd xs : set xs"
   646 by(cases xs) auto
   647 
   648 lemma set_subset_Cons: "set xs \<subseteq> set (x # xs)"
   649 by auto
   650 
   651 lemma set_ConsD: "y \<in> set (x # xs) \<Longrightarrow> y=x \<or> y \<in> set xs" 
   652 by auto
   653 
   654 lemma set_empty [iff]: "(set xs = {}) = (xs = [])"
   655 by (induct xs) auto
   656 
   657 lemma set_empty2[iff]: "({} = set xs) = (xs = [])"
   658 by(induct xs) auto
   659 
   660 lemma set_rev [simp]: "set (rev xs) = set xs"
   661 by (induct xs) auto
   662 
   663 lemma set_map [simp]: "set (map f xs) = f`(set xs)"
   664 by (induct xs) auto
   665 
   666 lemma set_filter [simp]: "set (filter P xs) = {x. x : set xs \<and> P x}"
   667 by (induct xs) auto
   668 
   669 lemma set_upt [simp]: "set[i..<j] = {k. i \<le> k \<and> k < j}"
   670 apply (induct j, simp_all)
   671 apply (erule ssubst, auto)
   672 done
   673 
   674 lemma in_set_conv_decomp: "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs)"
   675 proof (induct xs)
   676   case Nil show ?case by simp
   677   case (Cons a xs)
   678   show ?case
   679   proof 
   680     assume "x \<in> set (a # xs)"
   681     with prems show "\<exists>ys zs. a # xs = ys @ x # zs"
   682       by (simp, blast intro: Cons_eq_appendI)
   683   next
   684     assume "\<exists>ys zs. a # xs = ys @ x # zs"
   685     then obtain ys zs where eq: "a # xs = ys @ x # zs" by blast
   686     show "x \<in> set (a # xs)" 
   687       by (cases ys, auto simp add: eq)
   688   qed
   689 qed
   690 
   691 lemma in_set_conv_decomp_first:
   692  "(x : set xs) = (\<exists>ys zs. xs = ys @ x # zs \<and> x \<notin> set ys)"
   693 proof (induct xs)
   694   case Nil show ?case by simp
   695 next
   696   case (Cons a xs)
   697   show ?case
   698   proof cases
   699     assume "x = a" thus ?case using Cons by force
   700   next
   701     assume "x \<noteq> a"
   702     show ?case
   703     proof
   704       assume "x \<in> set (a # xs)"
   705       from prems show "\<exists>ys zs. a # xs = ys @ x # zs \<and> x \<notin> set ys"
   706 	by(fastsimp intro!: Cons_eq_appendI)
   707     next
   708       assume "\<exists>ys zs. a # xs = ys @ x # zs \<and> x \<notin> set ys"
   709       then obtain ys zs where eq: "a # xs = ys @ x # zs" by blast
   710       show "x \<in> set (a # xs)" by (cases ys, auto simp add: eq)
   711     qed
   712   qed
   713 qed
   714 
   715 lemmas split_list       = in_set_conv_decomp[THEN iffD1, standard]
   716 lemmas split_list_first = in_set_conv_decomp_first[THEN iffD1, standard]
   717 
   718 
   719 lemma finite_list: "finite A ==> EX l. set l = A"
   720 apply (erule finite_induct, auto)
   721 apply (rule_tac x="x#l" in exI, auto)
   722 done
   723 
   724 lemma card_length: "card (set xs) \<le> length xs"
   725 by (induct xs) (auto simp add: card_insert_if)
   726 
   727 
   728 subsubsection {* @{text filter} *}
   729 
   730 lemma filter_append [simp]: "filter P (xs @ ys) = filter P xs @ filter P ys"
   731 by (induct xs) auto
   732 
   733 lemma rev_filter: "rev (filter P xs) = filter P (rev xs)"
   734 by (induct xs) simp_all
   735 
   736 lemma filter_filter [simp]: "filter P (filter Q xs) = filter (\<lambda>x. Q x \<and> P x) xs"
   737 by (induct xs) auto
   738 
   739 lemma length_filter_le [simp]: "length (filter P xs) \<le> length xs"
   740 by (induct xs) (auto simp add: le_SucI)
   741 
   742 lemma sum_length_filter_compl:
   743   "length(filter P xs) + length(filter (%x. ~P x) xs) = length xs"
   744 by(induct xs) simp_all
   745 
   746 lemma filter_True [simp]: "\<forall>x \<in> set xs. P x ==> filter P xs = xs"
   747 by (induct xs) auto
   748 
   749 lemma filter_False [simp]: "\<forall>x \<in> set xs. \<not> P x ==> filter P xs = []"
   750 by (induct xs) auto
   751 
   752 lemma filter_empty_conv: "(filter P xs = []) = (\<forall>x\<in>set xs. \<not> P x)" 
   753   by (induct xs) simp_all
   754 
   755 lemma filter_id_conv: "(filter P xs = xs) = (\<forall>x\<in>set xs. P x)"
   756 apply (induct xs)
   757  apply auto
   758 apply(cut_tac P=P and xs=xs in length_filter_le)
   759 apply simp
   760 done
   761 
   762 lemma filter_map:
   763   "filter P (map f xs) = map f (filter (P o f) xs)"
   764 by (induct xs) simp_all
   765 
   766 lemma length_filter_map[simp]:
   767   "length (filter P (map f xs)) = length(filter (P o f) xs)"
   768 by (simp add:filter_map)
   769 
   770 lemma filter_is_subset [simp]: "set (filter P xs) \<le> set xs"
   771 by auto
   772 
   773 lemma length_filter_less:
   774   "\<lbrakk> x : set xs; ~ P x \<rbrakk> \<Longrightarrow> length(filter P xs) < length xs"
   775 proof (induct xs)
   776   case Nil thus ?case by simp
   777 next
   778   case (Cons x xs) thus ?case
   779     apply (auto split:split_if_asm)
   780     using length_filter_le[of P xs] apply arith
   781   done
   782 qed
   783 
   784 lemma length_filter_conv_card:
   785  "length(filter p xs) = card{i. i < length xs & p(xs!i)}"
   786 proof (induct xs)
   787   case Nil thus ?case by simp
   788 next
   789   case (Cons x xs)
   790   let ?S = "{i. i < length xs & p(xs!i)}"
   791   have fin: "finite ?S" by(fast intro: bounded_nat_set_is_finite)
   792   show ?case (is "?l = card ?S'")
   793   proof (cases)
   794     assume "p x"
   795     hence eq: "?S' = insert 0 (Suc ` ?S)"
   796       by(auto simp add: nth_Cons image_def split:nat.split elim:lessE)
   797     have "length (filter p (x # xs)) = Suc(card ?S)"
   798       using Cons by simp
   799     also have "\<dots> = Suc(card(Suc ` ?S))" using fin
   800       by (simp add: card_image inj_Suc)
   801     also have "\<dots> = card ?S'" using eq fin
   802       by (simp add:card_insert_if) (simp add:image_def)
   803     finally show ?thesis .
   804   next
   805     assume "\<not> p x"
   806     hence eq: "?S' = Suc ` ?S"
   807       by(auto simp add: nth_Cons image_def split:nat.split elim:lessE)
   808     have "length (filter p (x # xs)) = card ?S"
   809       using Cons by simp
   810     also have "\<dots> = card(Suc ` ?S)" using fin
   811       by (simp add: card_image inj_Suc)
   812     also have "\<dots> = card ?S'" using eq fin
   813       by (simp add:card_insert_if)
   814     finally show ?thesis .
   815   qed
   816 qed
   817 
   818 lemma Cons_eq_filterD:
   819  "x#xs = filter P ys \<Longrightarrow>
   820   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
   821   (concl is "\<exists>us vs. ?P ys us vs")
   822 proof(induct ys)
   823   case Nil thus ?case by simp
   824 next
   825   case (Cons y ys)
   826   show ?case (is "\<exists>x. ?Q x")
   827   proof cases
   828     assume Py: "P y"
   829     show ?thesis
   830     proof cases
   831       assume xy: "x = y"
   832       show ?thesis
   833       proof from Py xy Cons(2) show "?Q []" by simp qed
   834     next
   835       assume "x \<noteq> y" with Py Cons(2) show ?thesis by simp
   836     qed
   837   next
   838     assume Py: "\<not> P y"
   839     with Cons obtain us vs where 1 : "?P (y#ys) (y#us) vs" by fastsimp
   840     show ?thesis (is "? us. ?Q us")
   841     proof show "?Q (y#us)" using 1 by simp qed
   842   qed
   843 qed
   844 
   845 lemma filter_eq_ConsD:
   846  "filter P ys = x#xs \<Longrightarrow>
   847   \<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs"
   848 by(rule Cons_eq_filterD) simp
   849 
   850 lemma filter_eq_Cons_iff:
   851  "(filter P ys = x#xs) =
   852   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
   853 by(auto dest:filter_eq_ConsD)
   854 
   855 lemma Cons_eq_filter_iff:
   856  "(x#xs = filter P ys) =
   857   (\<exists>us vs. ys = us @ x # vs \<and> (\<forall>u\<in>set us. \<not> P u) \<and> P x \<and> xs = filter P vs)"
   858 by(auto dest:Cons_eq_filterD)
   859 
   860 lemma filter_cong[recdef_cong]:
   861  "xs = ys \<Longrightarrow> (\<And>x. x \<in> set ys \<Longrightarrow> P x = Q x) \<Longrightarrow> filter P xs = filter Q ys"
   862 apply simp
   863 apply(erule thin_rl)
   864 by (induct ys) simp_all
   865 
   866 
   867 subsubsection {* @{text concat} *}
   868 
   869 lemma concat_append [simp]: "concat (xs @ ys) = concat xs @ concat ys"
   870 by (induct xs) auto
   871 
   872 lemma concat_eq_Nil_conv [simp]: "(concat xss = []) = (\<forall>xs \<in> set xss. xs = [])"
   873 by (induct xss) auto
   874 
   875 lemma Nil_eq_concat_conv [simp]: "([] = concat xss) = (\<forall>xs \<in> set xss. xs = [])"
   876 by (induct xss) auto
   877 
   878 lemma set_concat [simp]: "set (concat xs) = \<Union>(set ` set xs)"
   879 by (induct xs) auto
   880 
   881 lemma map_concat: "map f (concat xs) = concat (map (map f) xs)"
   882 by (induct xs) auto
   883 
   884 lemma filter_concat: "filter p (concat xs) = concat (map (filter p) xs)"
   885 by (induct xs) auto
   886 
   887 lemma rev_concat: "rev (concat xs) = concat (map rev (rev xs))"
   888 by (induct xs) auto
   889 
   890 
   891 subsubsection {* @{text nth} *}
   892 
   893 lemma nth_Cons_0 [simp]: "(x # xs)!0 = x"
   894 by auto
   895 
   896 lemma nth_Cons_Suc [simp]: "(x # xs)!(Suc n) = xs!n"
   897 by auto
   898 
   899 declare nth.simps [simp del]
   900 
   901 lemma nth_append:
   902 "!!n. (xs @ ys)!n = (if n < length xs then xs!n else ys!(n - length xs))"
   903 apply (induct "xs", simp)
   904 apply (case_tac n, auto)
   905 done
   906 
   907 lemma nth_append_length [simp]: "(xs @ x # ys) ! length xs = x"
   908 by (induct "xs") auto
   909 
   910 lemma nth_append_length_plus[simp]: "(xs @ ys) ! (length xs + n) = ys ! n"
   911 by (induct "xs") auto
   912 
   913 lemma nth_map [simp]: "!!n. n < length xs ==> (map f xs)!n = f(xs!n)"
   914 apply (induct xs, simp)
   915 apply (case_tac n, auto)
   916 done
   917 
   918 lemma hd_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd xs = xs!0"
   919 by(cases xs) simp_all
   920 
   921 
   922 lemma list_eq_iff_nth_eq:
   923  "!!ys. (xs = ys) = (length xs = length ys \<and> (ALL i<length xs. xs!i = ys!i))"
   924 apply(induct xs)
   925  apply simp apply blast
   926 apply(case_tac ys)
   927  apply simp
   928 apply(simp add:nth_Cons split:nat.split)apply blast
   929 done
   930 
   931 lemma set_conv_nth: "set xs = {xs!i | i. i < length xs}"
   932 apply (induct xs, simp, simp)
   933 apply safe
   934 apply (rule_tac x = 0 in exI, simp)
   935  apply (rule_tac x = "Suc i" in exI, simp)
   936 apply (case_tac i, simp)
   937 apply (rename_tac j)
   938 apply (rule_tac x = j in exI, simp)
   939 done
   940 
   941 lemma in_set_conv_nth: "(x \<in> set xs) = (\<exists>i < length xs. xs!i = x)"
   942 by(auto simp:set_conv_nth)
   943 
   944 lemma list_ball_nth: "[| n < length xs; !x : set xs. P x|] ==> P(xs!n)"
   945 by (auto simp add: set_conv_nth)
   946 
   947 lemma nth_mem [simp]: "n < length xs ==> xs!n : set xs"
   948 by (auto simp add: set_conv_nth)
   949 
   950 lemma all_nth_imp_all_set:
   951 "[| !i < length xs. P(xs!i); x : set xs|] ==> P x"
   952 by (auto simp add: set_conv_nth)
   953 
   954 lemma all_set_conv_all_nth:
   955 "(\<forall>x \<in> set xs. P x) = (\<forall>i. i < length xs --> P (xs ! i))"
   956 by (auto simp add: set_conv_nth)
   957 
   958 
   959 subsubsection {* @{text list_update} *}
   960 
   961 lemma length_list_update [simp]: "!!i. length(xs[i:=x]) = length xs"
   962 by (induct xs) (auto split: nat.split)
   963 
   964 lemma nth_list_update:
   965 "!!i j. i < length xs==> (xs[i:=x])!j = (if i = j then x else xs!j)"
   966 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   967 
   968 lemma nth_list_update_eq [simp]: "i < length xs ==> (xs[i:=x])!i = x"
   969 by (simp add: nth_list_update)
   970 
   971 lemma nth_list_update_neq [simp]: "!!i j. i \<noteq> j ==> xs[i:=x]!j = xs!j"
   972 by (induct xs) (auto simp add: nth_Cons split: nat.split)
   973 
   974 lemma list_update_overwrite [simp]:
   975 "!!i. i < size xs ==> xs[i:=x, i:=y] = xs[i:=y]"
   976 by (induct xs) (auto split: nat.split)
   977 
   978 lemma list_update_id[simp]: "!!i. i < length xs ==> xs[i := xs!i] = xs"
   979 apply (induct xs, simp)
   980 apply(simp split:nat.splits)
   981 done
   982 
   983 lemma list_update_beyond[simp]: "\<And>i. length xs \<le> i \<Longrightarrow> xs[i:=x] = xs"
   984 apply (induct xs)
   985  apply simp
   986 apply (case_tac i)
   987 apply simp_all
   988 done
   989 
   990 lemma list_update_same_conv:
   991 "!!i. i < length xs ==> (xs[i := x] = xs) = (xs!i = x)"
   992 by (induct xs) (auto split: nat.split)
   993 
   994 lemma list_update_append1:
   995  "!!i. i < size xs \<Longrightarrow> (xs @ ys)[i:=x] = xs[i:=x] @ ys"
   996 apply (induct xs, simp)
   997 apply(simp split:nat.split)
   998 done
   999 
  1000 lemma list_update_append:
  1001   "!!n. (xs @ ys) [n:= x] = 
  1002   (if n < length xs then xs[n:= x] @ ys else xs @ (ys [n-length xs:= x]))"
  1003 by (induct xs) (auto split:nat.splits)
  1004 
  1005 lemma list_update_length [simp]:
  1006  "(xs @ x # ys)[length xs := y] = (xs @ y # ys)"
  1007 by (induct xs, auto)
  1008 
  1009 lemma update_zip:
  1010 "!!i xy xs. length xs = length ys ==>
  1011 (zip xs ys)[i:=xy] = zip (xs[i:=fst xy]) (ys[i:=snd xy])"
  1012 by (induct ys) (auto, case_tac xs, auto split: nat.split)
  1013 
  1014 lemma set_update_subset_insert: "!!i. set(xs[i:=x]) <= insert x (set xs)"
  1015 by (induct xs) (auto split: nat.split)
  1016 
  1017 lemma set_update_subsetI: "[| set xs <= A; x:A |] ==> set(xs[i := x]) <= A"
  1018 by (blast dest!: set_update_subset_insert [THEN subsetD])
  1019 
  1020 lemma set_update_memI: "!!n. n < length xs \<Longrightarrow> x \<in> set (xs[n := x])"
  1021 by (induct xs) (auto split:nat.splits)
  1022 
  1023 
  1024 subsubsection {* @{text last} and @{text butlast} *}
  1025 
  1026 lemma last_snoc [simp]: "last (xs @ [x]) = x"
  1027 by (induct xs) auto
  1028 
  1029 lemma butlast_snoc [simp]: "butlast (xs @ [x]) = xs"
  1030 by (induct xs) auto
  1031 
  1032 lemma last_ConsL: "xs = [] \<Longrightarrow> last(x#xs) = x"
  1033 by(simp add:last.simps)
  1034 
  1035 lemma last_ConsR: "xs \<noteq> [] \<Longrightarrow> last(x#xs) = last xs"
  1036 by(simp add:last.simps)
  1037 
  1038 lemma last_append: "last(xs @ ys) = (if ys = [] then last xs else last ys)"
  1039 by (induct xs) (auto)
  1040 
  1041 lemma last_appendL[simp]: "ys = [] \<Longrightarrow> last(xs @ ys) = last xs"
  1042 by(simp add:last_append)
  1043 
  1044 lemma last_appendR[simp]: "ys \<noteq> [] \<Longrightarrow> last(xs @ ys) = last ys"
  1045 by(simp add:last_append)
  1046 
  1047 lemma hd_rev: "xs \<noteq> [] \<Longrightarrow> hd(rev xs) = last xs"
  1048 by(rule rev_exhaust[of xs]) simp_all
  1049 
  1050 lemma last_rev: "xs \<noteq> [] \<Longrightarrow> last(rev xs) = hd xs"
  1051 by(cases xs) simp_all
  1052 
  1053 lemma last_in_set[simp]: "as \<noteq> [] \<Longrightarrow> last as \<in> set as"
  1054 by (induct as) auto
  1055 
  1056 lemma length_butlast [simp]: "length (butlast xs) = length xs - 1"
  1057 by (induct xs rule: rev_induct) auto
  1058 
  1059 lemma butlast_append:
  1060 "!!ys. butlast (xs @ ys) = (if ys = [] then butlast xs else xs @ butlast ys)"
  1061 by (induct xs) auto
  1062 
  1063 lemma append_butlast_last_id [simp]:
  1064 "xs \<noteq> [] ==> butlast xs @ [last xs] = xs"
  1065 by (induct xs) auto
  1066 
  1067 lemma in_set_butlastD: "x : set (butlast xs) ==> x : set xs"
  1068 by (induct xs) (auto split: split_if_asm)
  1069 
  1070 lemma in_set_butlast_appendI:
  1071 "x : set (butlast xs) | x : set (butlast ys) ==> x : set (butlast (xs @ ys))"
  1072 by (auto dest: in_set_butlastD simp add: butlast_append)
  1073 
  1074 lemma last_drop[simp]: "!!n. n < length xs \<Longrightarrow> last (drop n xs) = last xs"
  1075 apply (induct xs)
  1076  apply simp
  1077 apply (auto split:nat.split)
  1078 done
  1079 
  1080 lemma last_conv_nth: "xs\<noteq>[] \<Longrightarrow> last xs = xs!(length xs - 1)"
  1081 by(induct xs)(auto simp:neq_Nil_conv)
  1082 
  1083 
  1084 subsubsection {* @{text take} and @{text drop} *}
  1085 
  1086 lemma take_0 [simp]: "take 0 xs = []"
  1087 by (induct xs) auto
  1088 
  1089 lemma drop_0 [simp]: "drop 0 xs = xs"
  1090 by (induct xs) auto
  1091 
  1092 lemma take_Suc_Cons [simp]: "take (Suc n) (x # xs) = x # take n xs"
  1093 by simp
  1094 
  1095 lemma drop_Suc_Cons [simp]: "drop (Suc n) (x # xs) = drop n xs"
  1096 by simp
  1097 
  1098 declare take_Cons [simp del] and drop_Cons [simp del]
  1099 
  1100 lemma take_Suc: "xs ~= [] ==> take (Suc n) xs = hd xs # take n (tl xs)"
  1101 by(clarsimp simp add:neq_Nil_conv)
  1102 
  1103 lemma drop_Suc: "drop (Suc n) xs = drop n (tl xs)"
  1104 by(cases xs, simp_all)
  1105 
  1106 lemma drop_tl: "!!n. drop n (tl xs) = tl(drop n xs)"
  1107 by(induct xs, simp_all add:drop_Cons drop_Suc split:nat.split)
  1108 
  1109 lemma nth_via_drop: "!!n. drop n xs = y#ys \<Longrightarrow> xs!n = y"
  1110 apply (induct xs, simp)
  1111 apply(simp add:drop_Cons nth_Cons split:nat.splits)
  1112 done
  1113 
  1114 lemma take_Suc_conv_app_nth:
  1115  "!!i. i < length xs \<Longrightarrow> take (Suc i) xs = take i xs @ [xs!i]"
  1116 apply (induct xs, simp)
  1117 apply (case_tac i, auto)
  1118 done
  1119 
  1120 lemma drop_Suc_conv_tl:
  1121   "!!i. i < length xs \<Longrightarrow> (xs!i) # (drop (Suc i) xs) = drop i xs"
  1122 apply (induct xs, simp)
  1123 apply (case_tac i, auto)
  1124 done
  1125 
  1126 lemma length_take [simp]: "!!xs. length (take n xs) = min (length xs) n"
  1127 by (induct n) (auto, case_tac xs, auto)
  1128 
  1129 lemma length_drop [simp]: "!!xs. length (drop n xs) = (length xs - n)"
  1130 by (induct n) (auto, case_tac xs, auto)
  1131 
  1132 lemma take_all [simp]: "!!xs. length xs <= n ==> take n xs = xs"
  1133 by (induct n) (auto, case_tac xs, auto)
  1134 
  1135 lemma drop_all [simp]: "!!xs. length xs <= n ==> drop n xs = []"
  1136 by (induct n) (auto, case_tac xs, auto)
  1137 
  1138 lemma take_append [simp]:
  1139 "!!xs. take n (xs @ ys) = (take n xs @ take (n - length xs) ys)"
  1140 by (induct n) (auto, case_tac xs, auto)
  1141 
  1142 lemma drop_append [simp]:
  1143 "!!xs. drop n (xs @ ys) = drop n xs @ drop (n - length xs) ys"
  1144 by (induct n) (auto, case_tac xs, auto)
  1145 
  1146 lemma take_take [simp]: "!!xs n. take n (take m xs) = take (min n m) xs"
  1147 apply (induct m, auto)
  1148 apply (case_tac xs, auto)
  1149 apply (case_tac n, auto)
  1150 done
  1151 
  1152 lemma drop_drop [simp]: "!!xs. drop n (drop m xs) = drop (n + m) xs"
  1153 apply (induct m, auto)
  1154 apply (case_tac xs, auto)
  1155 done
  1156 
  1157 lemma take_drop: "!!xs n. take n (drop m xs) = drop m (take (n + m) xs)"
  1158 apply (induct m, auto)
  1159 apply (case_tac xs, auto)
  1160 done
  1161 
  1162 lemma drop_take: "!!m n. drop n (take m xs) = take (m-n) (drop n xs)"
  1163 apply(induct xs)
  1164  apply simp
  1165 apply(simp add: take_Cons drop_Cons split:nat.split)
  1166 done
  1167 
  1168 lemma append_take_drop_id [simp]: "!!xs. take n xs @ drop n xs = xs"
  1169 apply (induct n, auto)
  1170 apply (case_tac xs, auto)
  1171 done
  1172 
  1173 lemma take_eq_Nil[simp]: "!!n. (take n xs = []) = (n = 0 \<or> xs = [])"
  1174 apply(induct xs)
  1175  apply simp
  1176 apply(simp add:take_Cons split:nat.split)
  1177 done
  1178 
  1179 lemma drop_eq_Nil[simp]: "!!n. (drop n xs = []) = (length xs <= n)"
  1180 apply(induct xs)
  1181 apply simp
  1182 apply(simp add:drop_Cons split:nat.split)
  1183 done
  1184 
  1185 lemma take_map: "!!xs. take n (map f xs) = map f (take n xs)"
  1186 apply (induct n, auto)
  1187 apply (case_tac xs, auto)
  1188 done
  1189 
  1190 lemma drop_map: "!!xs. drop n (map f xs) = map f (drop n xs)"
  1191 apply (induct n, auto)
  1192 apply (case_tac xs, auto)
  1193 done
  1194 
  1195 lemma rev_take: "!!i. rev (take i xs) = drop (length xs - i) (rev xs)"
  1196 apply (induct xs, auto)
  1197 apply (case_tac i, auto)
  1198 done
  1199 
  1200 lemma rev_drop: "!!i. rev (drop i xs) = take (length xs - i) (rev xs)"
  1201 apply (induct xs, auto)
  1202 apply (case_tac i, auto)
  1203 done
  1204 
  1205 lemma nth_take [simp]: "!!n i. i < n ==> (take n xs)!i = xs!i"
  1206 apply (induct xs, auto)
  1207 apply (case_tac n, blast)
  1208 apply (case_tac i, auto)
  1209 done
  1210 
  1211 lemma nth_drop [simp]:
  1212 "!!xs i. n + i <= length xs ==> (drop n xs)!i = xs!(n + i)"
  1213 apply (induct n, auto)
  1214 apply (case_tac xs, auto)
  1215 done
  1216 
  1217 lemma hd_drop_conv_nth: "\<lbrakk> xs \<noteq> []; n < length xs \<rbrakk> \<Longrightarrow> hd(drop n xs) = xs!n"
  1218 by(simp add: hd_conv_nth)
  1219 
  1220 lemma set_take_subset: "\<And>n. set(take n xs) \<subseteq> set xs"
  1221 by(induct xs)(auto simp:take_Cons split:nat.split)
  1222 
  1223 lemma set_drop_subset: "\<And>n. set(drop n xs) \<subseteq> set xs"
  1224 by(induct xs)(auto simp:drop_Cons split:nat.split)
  1225 
  1226 lemma in_set_takeD: "x : set(take n xs) \<Longrightarrow> x : set xs"
  1227 using set_take_subset by fast
  1228 
  1229 lemma in_set_dropD: "x : set(drop n xs) \<Longrightarrow> x : set xs"
  1230 using set_drop_subset by fast
  1231 
  1232 lemma append_eq_conv_conj:
  1233 "!!zs. (xs @ ys = zs) = (xs = take (length xs) zs \<and> ys = drop (length xs) zs)"
  1234 apply (induct xs, simp, clarsimp)
  1235 apply (case_tac zs, auto)
  1236 done
  1237 
  1238 lemma take_add [rule_format]: 
  1239     "\<forall>i. i+j \<le> length(xs) --> take (i+j) xs = take i xs @ take j (drop i xs)"
  1240 apply (induct xs, auto) 
  1241 apply (case_tac i, simp_all) 
  1242 done
  1243 
  1244 lemma append_eq_append_conv_if:
  1245  "!! ys\<^isub>1. (xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>1 @ ys\<^isub>2) =
  1246   (if size xs\<^isub>1 \<le> size ys\<^isub>1
  1247    then xs\<^isub>1 = take (size xs\<^isub>1) ys\<^isub>1 \<and> xs\<^isub>2 = drop (size xs\<^isub>1) ys\<^isub>1 @ ys\<^isub>2
  1248    else take (size ys\<^isub>1) xs\<^isub>1 = ys\<^isub>1 \<and> drop (size ys\<^isub>1) xs\<^isub>1 @ xs\<^isub>2 = ys\<^isub>2)"
  1249 apply(induct xs\<^isub>1)
  1250  apply simp
  1251 apply(case_tac ys\<^isub>1)
  1252 apply simp_all
  1253 done
  1254 
  1255 lemma take_hd_drop:
  1256   "!!n. n < length xs \<Longrightarrow> take n xs @ [hd (drop n xs)] = take (n+1) xs"
  1257 apply(induct xs)
  1258 apply simp
  1259 apply(simp add:drop_Cons split:nat.split)
  1260 done
  1261 
  1262 lemma id_take_nth_drop:
  1263  "i < length xs \<Longrightarrow> xs = take i xs @ xs!i # drop (Suc i) xs" 
  1264 proof -
  1265   assume si: "i < length xs"
  1266   hence "xs = take (Suc i) xs @ drop (Suc i) xs" by auto
  1267   moreover
  1268   from si have "take (Suc i) xs = take i xs @ [xs!i]"
  1269     apply (rule_tac take_Suc_conv_app_nth) by arith
  1270   ultimately show ?thesis by auto
  1271 qed
  1272   
  1273 lemma upd_conv_take_nth_drop:
  1274  "i < length xs \<Longrightarrow> xs[i:=a] = take i xs @ a # drop (Suc i) xs"
  1275 proof -
  1276   assume i: "i < length xs"
  1277   have "xs[i:=a] = (take i xs @ xs!i # drop (Suc i) xs)[i:=a]"
  1278     by(rule arg_cong[OF id_take_nth_drop[OF i]])
  1279   also have "\<dots> = take i xs @ a # drop (Suc i) xs"
  1280     using i by (simp add: list_update_append)
  1281   finally show ?thesis .
  1282 qed
  1283 
  1284 
  1285 subsubsection {* @{text takeWhile} and @{text dropWhile} *}
  1286 
  1287 lemma takeWhile_dropWhile_id [simp]: "takeWhile P xs @ dropWhile P xs = xs"
  1288 by (induct xs) auto
  1289 
  1290 lemma takeWhile_append1 [simp]:
  1291 "[| x:set xs; ~P(x)|] ==> takeWhile P (xs @ ys) = takeWhile P xs"
  1292 by (induct xs) auto
  1293 
  1294 lemma takeWhile_append2 [simp]:
  1295 "(!!x. x : set xs ==> P x) ==> takeWhile P (xs @ ys) = xs @ takeWhile P ys"
  1296 by (induct xs) auto
  1297 
  1298 lemma takeWhile_tail: "\<not> P x ==> takeWhile P (xs @ (x#l)) = takeWhile P xs"
  1299 by (induct xs) auto
  1300 
  1301 lemma dropWhile_append1 [simp]:
  1302 "[| x : set xs; ~P(x)|] ==> dropWhile P (xs @ ys) = (dropWhile P xs)@ys"
  1303 by (induct xs) auto
  1304 
  1305 lemma dropWhile_append2 [simp]:
  1306 "(!!x. x:set xs ==> P(x)) ==> dropWhile P (xs @ ys) = dropWhile P ys"
  1307 by (induct xs) auto
  1308 
  1309 lemma set_take_whileD: "x : set (takeWhile P xs) ==> x : set xs \<and> P x"
  1310 by (induct xs) (auto split: split_if_asm)
  1311 
  1312 lemma takeWhile_eq_all_conv[simp]:
  1313  "(takeWhile P xs = xs) = (\<forall>x \<in> set xs. P x)"
  1314 by(induct xs, auto)
  1315 
  1316 lemma dropWhile_eq_Nil_conv[simp]:
  1317  "(dropWhile P xs = []) = (\<forall>x \<in> set xs. P x)"
  1318 by(induct xs, auto)
  1319 
  1320 lemma dropWhile_eq_Cons_conv:
  1321  "(dropWhile P xs = y#ys) = (xs = takeWhile P xs @ y # ys & \<not> P y)"
  1322 by(induct xs, auto)
  1323 
  1324 text{* The following two lemmmas could be generalized to an arbitrary
  1325 property. *}
  1326 
  1327 lemma takeWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  1328  takeWhile (\<lambda>y. y \<noteq> x) (rev xs) = rev (tl (dropWhile (\<lambda>y. y \<noteq> x) xs))"
  1329 by(induct xs) (auto simp: takeWhile_tail[where l="[]"])
  1330 
  1331 lemma dropWhile_neq_rev: "\<lbrakk>distinct xs; x \<in> set xs\<rbrakk> \<Longrightarrow>
  1332   dropWhile (\<lambda>y. y \<noteq> x) (rev xs) = x # rev (takeWhile (\<lambda>y. y \<noteq> x) xs)"
  1333 apply(induct xs)
  1334  apply simp
  1335 apply auto
  1336 apply(subst dropWhile_append2)
  1337 apply auto
  1338 done
  1339 
  1340 lemma takeWhile_not_last:
  1341  "\<lbrakk> xs \<noteq> []; distinct xs\<rbrakk> \<Longrightarrow> takeWhile (\<lambda>y. y \<noteq> last xs) xs = butlast xs"
  1342 apply(induct xs)
  1343  apply simp
  1344 apply(case_tac xs)
  1345 apply(auto)
  1346 done
  1347 
  1348 lemma takeWhile_cong [recdef_cong]:
  1349   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  1350   ==> takeWhile P l = takeWhile Q k"
  1351   by (induct k fixing: l, simp_all)
  1352 
  1353 lemma dropWhile_cong [recdef_cong]:
  1354   "[| l = k; !!x. x : set l ==> P x = Q x |] 
  1355   ==> dropWhile P l = dropWhile Q k"
  1356   by (induct k fixing: l, simp_all)
  1357 
  1358 
  1359 subsubsection {* @{text zip} *}
  1360 
  1361 lemma zip_Nil [simp]: "zip [] ys = []"
  1362 by (induct ys) auto
  1363 
  1364 lemma zip_Cons_Cons [simp]: "zip (x # xs) (y # ys) = (x, y) # zip xs ys"
  1365 by simp
  1366 
  1367 declare zip_Cons [simp del]
  1368 
  1369 lemma zip_Cons1:
  1370  "zip (x#xs) ys = (case ys of [] \<Rightarrow> [] | y#ys \<Rightarrow> (x,y)#zip xs ys)"
  1371 by(auto split:list.split)
  1372 
  1373 lemma length_zip [simp]:
  1374 "!!xs. length (zip xs ys) = min (length xs) (length ys)"
  1375 apply (induct ys, simp)
  1376 apply (case_tac xs, auto)
  1377 done
  1378 
  1379 lemma zip_append1:
  1380 "!!xs. zip (xs @ ys) zs =
  1381 zip xs (take (length xs) zs) @ zip ys (drop (length xs) zs)"
  1382 apply (induct zs, simp)
  1383 apply (case_tac xs, simp_all)
  1384 done
  1385 
  1386 lemma zip_append2:
  1387 "!!ys. zip xs (ys @ zs) =
  1388 zip (take (length ys) xs) ys @ zip (drop (length ys) xs) zs"
  1389 apply (induct xs, simp)
  1390 apply (case_tac ys, simp_all)
  1391 done
  1392 
  1393 lemma zip_append [simp]:
  1394  "[| length xs = length us; length ys = length vs |] ==>
  1395 zip (xs@ys) (us@vs) = zip xs us @ zip ys vs"
  1396 by (simp add: zip_append1)
  1397 
  1398 lemma zip_rev:
  1399 "length xs = length ys ==> zip (rev xs) (rev ys) = rev (zip xs ys)"
  1400 by (induct rule:list_induct2, simp_all)
  1401 
  1402 lemma nth_zip [simp]:
  1403 "!!i xs. [| i < length xs; i < length ys|] ==> (zip xs ys)!i = (xs!i, ys!i)"
  1404 apply (induct ys, simp)
  1405 apply (case_tac xs)
  1406  apply (simp_all add: nth.simps split: nat.split)
  1407 done
  1408 
  1409 lemma set_zip:
  1410 "set (zip xs ys) = {(xs!i, ys!i) | i. i < min (length xs) (length ys)}"
  1411 by (simp add: set_conv_nth cong: rev_conj_cong)
  1412 
  1413 lemma zip_update:
  1414 "length xs = length ys ==> zip (xs[i:=x]) (ys[i:=y]) = (zip xs ys)[i:=(x,y)]"
  1415 by (rule sym, simp add: update_zip)
  1416 
  1417 lemma zip_replicate [simp]:
  1418 "!!j. zip (replicate i x) (replicate j y) = replicate (min i j) (x,y)"
  1419 apply (induct i, auto)
  1420 apply (case_tac j, auto)
  1421 done
  1422 
  1423 
  1424 subsubsection {* @{text list_all2} *}
  1425 
  1426 lemma list_all2_lengthD [intro?]: 
  1427   "list_all2 P xs ys ==> length xs = length ys"
  1428 by (simp add: list_all2_def)
  1429 
  1430 lemma list_all2_Nil [iff,code]: "list_all2 P [] ys = (ys = [])"
  1431 by (simp add: list_all2_def)
  1432 
  1433 lemma list_all2_Nil2[iff]: "list_all2 P xs [] = (xs = [])"
  1434 by (simp add: list_all2_def)
  1435 
  1436 lemma list_all2_Cons [iff,code]:
  1437 "list_all2 P (x # xs) (y # ys) = (P x y \<and> list_all2 P xs ys)"
  1438 by (auto simp add: list_all2_def)
  1439 
  1440 lemma list_all2_Cons1:
  1441 "list_all2 P (x # xs) ys = (\<exists>z zs. ys = z # zs \<and> P x z \<and> list_all2 P xs zs)"
  1442 by (cases ys) auto
  1443 
  1444 lemma list_all2_Cons2:
  1445 "list_all2 P xs (y # ys) = (\<exists>z zs. xs = z # zs \<and> P z y \<and> list_all2 P zs ys)"
  1446 by (cases xs) auto
  1447 
  1448 lemma list_all2_rev [iff]:
  1449 "list_all2 P (rev xs) (rev ys) = list_all2 P xs ys"
  1450 by (simp add: list_all2_def zip_rev cong: conj_cong)
  1451 
  1452 lemma list_all2_rev1:
  1453 "list_all2 P (rev xs) ys = list_all2 P xs (rev ys)"
  1454 by (subst list_all2_rev [symmetric]) simp
  1455 
  1456 lemma list_all2_append1:
  1457 "list_all2 P (xs @ ys) zs =
  1458 (EX us vs. zs = us @ vs \<and> length us = length xs \<and> length vs = length ys \<and>
  1459 list_all2 P xs us \<and> list_all2 P ys vs)"
  1460 apply (simp add: list_all2_def zip_append1)
  1461 apply (rule iffI)
  1462  apply (rule_tac x = "take (length xs) zs" in exI)
  1463  apply (rule_tac x = "drop (length xs) zs" in exI)
  1464  apply (force split: nat_diff_split simp add: min_def, clarify)
  1465 apply (simp add: ball_Un)
  1466 done
  1467 
  1468 lemma list_all2_append2:
  1469 "list_all2 P xs (ys @ zs) =
  1470 (EX us vs. xs = us @ vs \<and> length us = length ys \<and> length vs = length zs \<and>
  1471 list_all2 P us ys \<and> list_all2 P vs zs)"
  1472 apply (simp add: list_all2_def zip_append2)
  1473 apply (rule iffI)
  1474  apply (rule_tac x = "take (length ys) xs" in exI)
  1475  apply (rule_tac x = "drop (length ys) xs" in exI)
  1476  apply (force split: nat_diff_split simp add: min_def, clarify)
  1477 apply (simp add: ball_Un)
  1478 done
  1479 
  1480 lemma list_all2_append:
  1481   "length xs = length ys \<Longrightarrow>
  1482   list_all2 P (xs@us) (ys@vs) = (list_all2 P xs ys \<and> list_all2 P us vs)"
  1483 by (induct rule:list_induct2, simp_all)
  1484 
  1485 lemma list_all2_appendI [intro?, trans]:
  1486   "\<lbrakk> list_all2 P a b; list_all2 P c d \<rbrakk> \<Longrightarrow> list_all2 P (a@c) (b@d)"
  1487   by (simp add: list_all2_append list_all2_lengthD)
  1488 
  1489 lemma list_all2_conv_all_nth:
  1490 "list_all2 P xs ys =
  1491 (length xs = length ys \<and> (\<forall>i < length xs. P (xs!i) (ys!i)))"
  1492 by (force simp add: list_all2_def set_zip)
  1493 
  1494 lemma list_all2_trans:
  1495   assumes tr: "!!a b c. P1 a b ==> P2 b c ==> P3 a c"
  1496   shows "!!bs cs. list_all2 P1 as bs ==> list_all2 P2 bs cs ==> list_all2 P3 as cs"
  1497         (is "!!bs cs. PROP ?Q as bs cs")
  1498 proof (induct as)
  1499   fix x xs bs assume I1: "!!bs cs. PROP ?Q xs bs cs"
  1500   show "!!cs. PROP ?Q (x # xs) bs cs"
  1501   proof (induct bs)
  1502     fix y ys cs assume I2: "!!cs. PROP ?Q (x # xs) ys cs"
  1503     show "PROP ?Q (x # xs) (y # ys) cs"
  1504       by (induct cs) (auto intro: tr I1 I2)
  1505   qed simp
  1506 qed simp
  1507 
  1508 lemma list_all2_all_nthI [intro?]:
  1509   "length a = length b \<Longrightarrow> (\<And>n. n < length a \<Longrightarrow> P (a!n) (b!n)) \<Longrightarrow> list_all2 P a b"
  1510   by (simp add: list_all2_conv_all_nth)
  1511 
  1512 lemma list_all2I:
  1513   "\<forall>x \<in> set (zip a b). split P x \<Longrightarrow> length a = length b \<Longrightarrow> list_all2 P a b"
  1514   by (simp add: list_all2_def)
  1515 
  1516 lemma list_all2_nthD:
  1517   "\<lbrakk> list_all2 P xs ys; p < size xs \<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1518   by (simp add: list_all2_conv_all_nth)
  1519 
  1520 lemma list_all2_nthD2:
  1521   "\<lbrakk>list_all2 P xs ys; p < size ys\<rbrakk> \<Longrightarrow> P (xs!p) (ys!p)"
  1522   by (frule list_all2_lengthD) (auto intro: list_all2_nthD)
  1523 
  1524 lemma list_all2_map1: 
  1525   "list_all2 P (map f as) bs = list_all2 (\<lambda>x y. P (f x) y) as bs"
  1526   by (simp add: list_all2_conv_all_nth)
  1527 
  1528 lemma list_all2_map2: 
  1529   "list_all2 P as (map f bs) = list_all2 (\<lambda>x y. P x (f y)) as bs"
  1530   by (auto simp add: list_all2_conv_all_nth)
  1531 
  1532 lemma list_all2_refl [intro?]:
  1533   "(\<And>x. P x x) \<Longrightarrow> list_all2 P xs xs"
  1534   by (simp add: list_all2_conv_all_nth)
  1535 
  1536 lemma list_all2_update_cong:
  1537   "\<lbrakk> i<size xs; list_all2 P xs ys; P x y \<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1538   by (simp add: list_all2_conv_all_nth nth_list_update)
  1539 
  1540 lemma list_all2_update_cong2:
  1541   "\<lbrakk>list_all2 P xs ys; P x y; i < length ys\<rbrakk> \<Longrightarrow> list_all2 P (xs[i:=x]) (ys[i:=y])"
  1542   by (simp add: list_all2_lengthD list_all2_update_cong)
  1543 
  1544 lemma list_all2_takeI [simp,intro?]:
  1545   "\<And>n ys. list_all2 P xs ys \<Longrightarrow> list_all2 P (take n xs) (take n ys)"
  1546   apply (induct xs)
  1547    apply simp
  1548   apply (clarsimp simp add: list_all2_Cons1)
  1549   apply (case_tac n)
  1550   apply auto
  1551   done
  1552 
  1553 lemma list_all2_dropI [simp,intro?]:
  1554   "\<And>n bs. list_all2 P as bs \<Longrightarrow> list_all2 P (drop n as) (drop n bs)"
  1555   apply (induct as, simp)
  1556   apply (clarsimp simp add: list_all2_Cons1)
  1557   apply (case_tac n, simp, simp)
  1558   done
  1559 
  1560 lemma list_all2_mono [intro?]:
  1561   "\<And>y. list_all2 P x y \<Longrightarrow> (\<And>x y. P x y \<Longrightarrow> Q x y) \<Longrightarrow> list_all2 Q x y"
  1562   apply (induct x, simp)
  1563   apply (case_tac y, auto)
  1564   done
  1565 
  1566 
  1567 subsubsection {* @{text foldl} and @{text foldr} *}
  1568 
  1569 lemma foldl_append [simp]:
  1570 "!!a. foldl f a (xs @ ys) = foldl f (foldl f a xs) ys"
  1571 by (induct xs) auto
  1572 
  1573 lemma foldr_append[simp]: "foldr f (xs @ ys) a = foldr f xs (foldr f ys a)"
  1574 by (induct xs) auto
  1575 
  1576 lemma foldl_cong [recdef_cong]:
  1577   "[| a = b; l = k; !!a x. x : set l ==> f a x = g a x |] 
  1578   ==> foldl f a l = foldl g b k"
  1579   by (induct k fixing: a b l, simp_all)
  1580 
  1581 lemma foldr_cong [recdef_cong]:
  1582   "[| a = b; l = k; !!a x. x : set l ==> f x a = g x a |] 
  1583   ==> foldr f l a = foldr g k b"
  1584   by (induct k fixing: a b l, simp_all)
  1585 
  1586 lemma foldr_foldl: "foldr f xs a = foldl (%x y. f y x) a (rev xs)"
  1587 by (induct xs) auto
  1588 
  1589 lemma foldl_foldr: "foldl f a xs = foldr (%x y. f y x) (rev xs) a"
  1590 by (simp add: foldr_foldl [of "%x y. f y x" "rev xs"])
  1591 
  1592 text {*
  1593 Note: @{text "n \<le> foldl (op +) n ns"} looks simpler, but is more
  1594 difficult to use because it requires an additional transitivity step.
  1595 *}
  1596 
  1597 lemma start_le_sum: "!!n::nat. m <= n ==> m <= foldl (op +) n ns"
  1598 by (induct ns) auto
  1599 
  1600 lemma elem_le_sum: "!!n::nat. n : set ns ==> n <= foldl (op +) 0 ns"
  1601 by (force intro: start_le_sum simp add: in_set_conv_decomp)
  1602 
  1603 lemma sum_eq_0_conv [iff]:
  1604 "!!m::nat. (foldl (op +) m ns = 0) = (m = 0 \<and> (\<forall>n \<in> set ns. n = 0))"
  1605 by (induct ns) auto
  1606 
  1607 
  1608 subsubsection {* @{text upto} *}
  1609 
  1610 lemma upt_rec[code]: "[i..<j] = (if i<j then i#[Suc i..<j] else [])"
  1611 -- {* simp does not terminate! *}
  1612 by (induct j) auto
  1613 
  1614 lemma upt_conv_Nil [simp]: "j <= i ==> [i..<j] = []"
  1615 by (subst upt_rec) simp
  1616 
  1617 lemma upt_eq_Nil_conv[simp]: "([i..<j] = []) = (j = 0 \<or> j <= i)"
  1618 by(induct j)simp_all
  1619 
  1620 lemma upt_eq_Cons_conv:
  1621  "!!x xs. ([i..<j] = x#xs) = (i < j & i = x & [i+1..<j] = xs)"
  1622 apply(induct j)
  1623  apply simp
  1624 apply(clarsimp simp add: append_eq_Cons_conv)
  1625 apply arith
  1626 done
  1627 
  1628 lemma upt_Suc_append: "i <= j ==> [i..<(Suc j)] = [i..<j]@[j]"
  1629 -- {* Only needed if @{text upt_Suc} is deleted from the simpset. *}
  1630 by simp
  1631 
  1632 lemma upt_conv_Cons: "i < j ==> [i..<j] = i # [Suc i..<j]"
  1633 apply(rule trans)
  1634 apply(subst upt_rec)
  1635  prefer 2 apply (rule refl, simp)
  1636 done
  1637 
  1638 lemma upt_add_eq_append: "i<=j ==> [i..<j+k] = [i..<j]@[j..<j+k]"
  1639 -- {* LOOPS as a simprule, since @{text "j <= j"}. *}
  1640 by (induct k) auto
  1641 
  1642 lemma length_upt [simp]: "length [i..<j] = j - i"
  1643 by (induct j) (auto simp add: Suc_diff_le)
  1644 
  1645 lemma nth_upt [simp]: "i + k < j ==> [i..<j] ! k = i + k"
  1646 apply (induct j)
  1647 apply (auto simp add: less_Suc_eq nth_append split: nat_diff_split)
  1648 done
  1649 
  1650 
  1651 lemma hd_upt[simp]: "i < j \<Longrightarrow> hd[i..<j] = i"
  1652 by(simp add:upt_conv_Cons)
  1653 
  1654 lemma last_upt[simp]: "i < j \<Longrightarrow> last[i..<j] = j - 1"
  1655 apply(cases j)
  1656  apply simp
  1657 by(simp add:upt_Suc_append)
  1658 
  1659 lemma take_upt [simp]: "!!i. i+m <= n ==> take m [i..<n] = [i..<i+m]"
  1660 apply (induct m, simp)
  1661 apply (subst upt_rec)
  1662 apply (rule sym)
  1663 apply (subst upt_rec)
  1664 apply (simp del: upt.simps)
  1665 done
  1666 
  1667 lemma drop_upt[simp]: "drop m [i..<j] = [i+m..<j]"
  1668 apply(induct j)
  1669 apply auto
  1670 apply arith
  1671 done
  1672 
  1673 lemma map_Suc_upt: "map Suc [m..<n] = [Suc m..n]"
  1674 by (induct n) auto
  1675 
  1676 lemma nth_map_upt: "!!i. i < n-m ==> (map f [m..<n]) ! i = f(m+i)"
  1677 apply (induct n m rule: diff_induct)
  1678 prefer 3 apply (subst map_Suc_upt[symmetric])
  1679 apply (auto simp add: less_diff_conv nth_upt)
  1680 done
  1681 
  1682 lemma nth_take_lemma:
  1683   "!!xs ys. k <= length xs ==> k <= length ys ==>
  1684      (!!i. i < k --> xs!i = ys!i) ==> take k xs = take k ys"
  1685 apply (atomize, induct k)
  1686 apply (simp_all add: less_Suc_eq_0_disj all_conj_distrib, clarify)
  1687 txt {* Both lists must be non-empty *}
  1688 apply (case_tac xs, simp)
  1689 apply (case_tac ys, clarify)
  1690  apply (simp (no_asm_use))
  1691 apply clarify
  1692 txt {* prenexing's needed, not miniscoping *}
  1693 apply (simp (no_asm_use) add: all_simps [symmetric] del: all_simps)
  1694 apply blast
  1695 done
  1696 
  1697 lemma nth_equalityI:
  1698  "[| length xs = length ys; ALL i < length xs. xs!i = ys!i |] ==> xs = ys"
  1699 apply (frule nth_take_lemma [OF le_refl eq_imp_le])
  1700 apply (simp_all add: take_all)
  1701 done
  1702 
  1703 (* needs nth_equalityI *)
  1704 lemma list_all2_antisym:
  1705   "\<lbrakk> (\<And>x y. \<lbrakk>P x y; Q y x\<rbrakk> \<Longrightarrow> x = y); list_all2 P xs ys; list_all2 Q ys xs \<rbrakk> 
  1706   \<Longrightarrow> xs = ys"
  1707   apply (simp add: list_all2_conv_all_nth) 
  1708   apply (rule nth_equalityI, blast, simp)
  1709   done
  1710 
  1711 lemma take_equalityI: "(\<forall>i. take i xs = take i ys) ==> xs = ys"
  1712 -- {* The famous take-lemma. *}
  1713 apply (drule_tac x = "max (length xs) (length ys)" in spec)
  1714 apply (simp add: le_max_iff_disj take_all)
  1715 done
  1716 
  1717 
  1718 lemma take_Cons':
  1719      "take n (x # xs) = (if n = 0 then [] else x # take (n - 1) xs)"
  1720 by (cases n) simp_all
  1721 
  1722 lemma drop_Cons':
  1723      "drop n (x # xs) = (if n = 0 then x # xs else drop (n - 1) xs)"
  1724 by (cases n) simp_all
  1725 
  1726 lemma nth_Cons': "(x # xs)!n = (if n = 0 then x else xs!(n - 1))"
  1727 by (cases n) simp_all
  1728 
  1729 lemmas take_Cons_number_of = take_Cons'[of "number_of v",standard]
  1730 lemmas drop_Cons_number_of = drop_Cons'[of "number_of v",standard]
  1731 lemmas nth_Cons_number_of = nth_Cons'[of _ _ "number_of v",standard]
  1732 
  1733 declare take_Cons_number_of [simp] 
  1734         drop_Cons_number_of [simp] 
  1735         nth_Cons_number_of [simp] 
  1736 
  1737 
  1738 subsubsection {* @{text "distinct"} and @{text remdups} *}
  1739 
  1740 lemma distinct_append [simp]:
  1741 "distinct (xs @ ys) = (distinct xs \<and> distinct ys \<and> set xs \<inter> set ys = {})"
  1742 by (induct xs) auto
  1743 
  1744 lemma distinct_rev[simp]: "distinct(rev xs) = distinct xs"
  1745 by(induct xs) auto
  1746 
  1747 lemma set_remdups [simp]: "set (remdups xs) = set xs"
  1748 by (induct xs) (auto simp add: insert_absorb)
  1749 
  1750 lemma distinct_remdups [iff]: "distinct (remdups xs)"
  1751 by (induct xs) auto
  1752 
  1753 lemma remdups_eq_nil_iff [simp]: "(remdups x = []) = (x = [])"
  1754   by (induct x, auto) 
  1755 
  1756 lemma remdups_eq_nil_right_iff [simp]: "([] = remdups x) = (x = [])"
  1757   by (induct x, auto)
  1758 
  1759 lemma length_remdups_leq[iff]: "length(remdups xs) <= length xs"
  1760 by (induct xs) auto
  1761 
  1762 lemma length_remdups_eq[iff]:
  1763   "(length (remdups xs) = length xs) = (remdups xs = xs)"
  1764 apply(induct xs)
  1765  apply auto
  1766 apply(subgoal_tac "length (remdups xs) <= length xs")
  1767  apply arith
  1768 apply(rule length_remdups_leq)
  1769 done
  1770 
  1771 
  1772 lemma distinct_map:
  1773   "distinct(map f xs) = (distinct xs & inj_on f (set xs))"
  1774 by (induct xs) auto
  1775 
  1776 
  1777 lemma distinct_filter [simp]: "distinct xs ==> distinct (filter P xs)"
  1778 by (induct xs) auto
  1779 
  1780 lemma distinct_upt[simp]: "distinct[i..<j]"
  1781 by (induct j) auto
  1782 
  1783 lemma distinct_take[simp]: "\<And>i. distinct xs \<Longrightarrow> distinct (take i xs)"
  1784 apply(induct xs)
  1785  apply simp
  1786 apply (case_tac i)
  1787  apply simp_all
  1788 apply(blast dest:in_set_takeD)
  1789 done
  1790 
  1791 lemma distinct_drop[simp]: "\<And>i. distinct xs \<Longrightarrow> distinct (drop i xs)"
  1792 apply(induct xs)
  1793  apply simp
  1794 apply (case_tac i)
  1795  apply simp_all
  1796 done
  1797 
  1798 lemma distinct_list_update:
  1799 assumes d: "distinct xs" and a: "a \<notin> set xs - {xs!i}"
  1800 shows "distinct (xs[i:=a])"
  1801 proof (cases "i < length xs")
  1802   case True
  1803   with a have "a \<notin> set (take i xs @ xs ! i # drop (Suc i) xs) - {xs!i}"
  1804     apply (drule_tac id_take_nth_drop) by simp
  1805   with d True show ?thesis
  1806     apply (simp add: upd_conv_take_nth_drop)
  1807     apply (drule subst [OF id_take_nth_drop]) apply assumption
  1808     apply simp apply (cases "a = xs!i") apply simp by blast
  1809 next
  1810   case False with d show ?thesis by auto
  1811 qed
  1812 
  1813 
  1814 text {* It is best to avoid this indexed version of distinct, but
  1815 sometimes it is useful. *}
  1816 
  1817 lemma distinct_conv_nth:
  1818 "distinct xs = (\<forall>i < size xs. \<forall>j < size xs. i \<noteq> j --> xs!i \<noteq> xs!j)"
  1819 apply (induct xs, simp, simp)
  1820 apply (rule iffI, clarsimp)
  1821  apply (case_tac i)
  1822 apply (case_tac j, simp)
  1823 apply (simp add: set_conv_nth)
  1824  apply (case_tac j)
  1825 apply (clarsimp simp add: set_conv_nth, simp)
  1826 apply (rule conjI)
  1827  apply (clarsimp simp add: set_conv_nth)
  1828  apply (erule_tac x = 0 in allE, simp)
  1829  apply (erule_tac x = "Suc i" in allE, simp, clarsimp)
  1830 apply (erule_tac x = "Suc i" in allE, simp)
  1831 apply (erule_tac x = "Suc j" in allE, simp)
  1832 done
  1833 
  1834 lemma nth_eq_iff_index_eq:
  1835  "\<lbrakk> distinct xs; i < length xs; j < length xs \<rbrakk> \<Longrightarrow> (xs!i = xs!j) = (i = j)"
  1836 by(auto simp: distinct_conv_nth)
  1837 
  1838 lemma distinct_card: "distinct xs ==> card (set xs) = size xs"
  1839   by (induct xs) auto
  1840 
  1841 lemma card_distinct: "card (set xs) = size xs ==> distinct xs"
  1842 proof (induct xs)
  1843   case Nil thus ?case by simp
  1844 next
  1845   case (Cons x xs)
  1846   show ?case
  1847   proof (cases "x \<in> set xs")
  1848     case False with Cons show ?thesis by simp
  1849   next
  1850     case True with Cons.prems
  1851     have "card (set xs) = Suc (length xs)" 
  1852       by (simp add: card_insert_if split: split_if_asm)
  1853     moreover have "card (set xs) \<le> length xs" by (rule card_length)
  1854     ultimately have False by simp
  1855     thus ?thesis ..
  1856   qed
  1857 qed
  1858 
  1859 
  1860 lemma length_remdups_concat:
  1861  "length(remdups(concat xss)) = card(\<Union>xs \<in> set xss. set xs)"
  1862 by(simp add: distinct_card[symmetric])
  1863 
  1864 
  1865 subsubsection {* @{text remove1} *}
  1866 
  1867 lemma remove1_append:
  1868   "remove1 x (xs @ ys) =
  1869   (if x \<in> set xs then remove1 x xs @ ys else xs @ remove1 x ys)"
  1870 by (induct xs) auto
  1871 
  1872 lemma set_remove1_subset: "set(remove1 x xs) <= set xs"
  1873 apply(induct xs)
  1874  apply simp
  1875 apply simp
  1876 apply blast
  1877 done
  1878 
  1879 lemma set_remove1_eq [simp]: "distinct xs ==> set(remove1 x xs) = set xs - {x}"
  1880 apply(induct xs)
  1881  apply simp
  1882 apply simp
  1883 apply blast
  1884 done
  1885 
  1886 lemma remove1_filter_not[simp]:
  1887   "\<not> P x \<Longrightarrow> remove1 x (filter P xs) = filter P xs"
  1888 by(induct xs) auto
  1889 
  1890 lemma notin_set_remove1[simp]: "x ~: set xs ==> x ~: set(remove1 y xs)"
  1891 apply(insert set_remove1_subset)
  1892 apply fast
  1893 done
  1894 
  1895 lemma distinct_remove1[simp]: "distinct xs ==> distinct(remove1 x xs)"
  1896 by (induct xs) simp_all
  1897 
  1898 
  1899 subsubsection {* @{text replicate} *}
  1900 
  1901 lemma length_replicate [simp]: "length (replicate n x) = n"
  1902 by (induct n) auto
  1903 
  1904 lemma map_replicate [simp]: "map f (replicate n x) = replicate n (f x)"
  1905 by (induct n) auto
  1906 
  1907 lemma replicate_app_Cons_same:
  1908 "(replicate n x) @ (x # xs) = x # replicate n x @ xs"
  1909 by (induct n) auto
  1910 
  1911 lemma rev_replicate [simp]: "rev (replicate n x) = replicate n x"
  1912 apply (induct n, simp)
  1913 apply (simp add: replicate_app_Cons_same)
  1914 done
  1915 
  1916 lemma replicate_add: "replicate (n + m) x = replicate n x @ replicate m x"
  1917 by (induct n) auto
  1918 
  1919 text{* Courtesy of Matthias Daum: *}
  1920 lemma append_replicate_commute:
  1921   "replicate n x @ replicate k x = replicate k x @ replicate n x"
  1922 apply (simp add: replicate_add [THEN sym])
  1923 apply (simp add: add_commute)
  1924 done
  1925 
  1926 lemma hd_replicate [simp]: "n \<noteq> 0 ==> hd (replicate n x) = x"
  1927 by (induct n) auto
  1928 
  1929 lemma tl_replicate [simp]: "n \<noteq> 0 ==> tl (replicate n x) = replicate (n - 1) x"
  1930 by (induct n) auto
  1931 
  1932 lemma last_replicate [simp]: "n \<noteq> 0 ==> last (replicate n x) = x"
  1933 by (atomize (full), induct n) auto
  1934 
  1935 lemma nth_replicate[simp]: "!!i. i < n ==> (replicate n x)!i = x"
  1936 apply (induct n, simp)
  1937 apply (simp add: nth_Cons split: nat.split)
  1938 done
  1939 
  1940 text{* Courtesy of Matthias Daum (2 lemmas): *}
  1941 lemma take_replicate[simp]: "take i (replicate k x) = replicate (min i k) x"
  1942 apply (case_tac "k \<le> i")
  1943  apply  (simp add: min_def)
  1944 apply (drule not_leE)
  1945 apply (simp add: min_def)
  1946 apply (subgoal_tac "replicate k x = replicate i x @ replicate (k - i) x")
  1947  apply  simp
  1948 apply (simp add: replicate_add [symmetric])
  1949 done
  1950 
  1951 lemma drop_replicate[simp]: "!!i. drop i (replicate k x) = replicate (k-i) x"
  1952 apply (induct k)
  1953  apply simp
  1954 apply clarsimp
  1955 apply (case_tac i)
  1956  apply simp
  1957 apply clarsimp
  1958 done
  1959 
  1960 
  1961 lemma set_replicate_Suc: "set (replicate (Suc n) x) = {x}"
  1962 by (induct n) auto
  1963 
  1964 lemma set_replicate [simp]: "n \<noteq> 0 ==> set (replicate n x) = {x}"
  1965 by (fast dest!: not0_implies_Suc intro!: set_replicate_Suc)
  1966 
  1967 lemma set_replicate_conv_if: "set (replicate n x) = (if n = 0 then {} else {x})"
  1968 by auto
  1969 
  1970 lemma in_set_replicateD: "x : set (replicate n y) ==> x = y"
  1971 by (simp add: set_replicate_conv_if split: split_if_asm)
  1972 
  1973 
  1974 subsubsection{*@{text rotate1} and @{text rotate}*}
  1975 
  1976 lemma rotate_simps[simp]: "rotate1 [] = [] \<and> rotate1 (x#xs) = xs @ [x]"
  1977 by(simp add:rotate1_def)
  1978 
  1979 lemma rotate0[simp]: "rotate 0 = id"
  1980 by(simp add:rotate_def)
  1981 
  1982 lemma rotate_Suc[simp]: "rotate (Suc n) xs = rotate1(rotate n xs)"
  1983 by(simp add:rotate_def)
  1984 
  1985 lemma rotate_add:
  1986   "rotate (m+n) = rotate m o rotate n"
  1987 by(simp add:rotate_def funpow_add)
  1988 
  1989 lemma rotate_rotate: "rotate m (rotate n xs) = rotate (m+n) xs"
  1990 by(simp add:rotate_add)
  1991 
  1992 lemma rotate1_rotate_swap: "rotate1 (rotate n xs) = rotate n (rotate1 xs)"
  1993 by(simp add:rotate_def funpow_swap1)
  1994 
  1995 lemma rotate1_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate1 xs = xs"
  1996 by(cases xs) simp_all
  1997 
  1998 lemma rotate_length01[simp]: "length xs <= 1 \<Longrightarrow> rotate n xs = xs"
  1999 apply(induct n)
  2000  apply simp
  2001 apply (simp add:rotate_def)
  2002 done
  2003 
  2004 lemma rotate1_hd_tl: "xs \<noteq> [] \<Longrightarrow> rotate1 xs = tl xs @ [hd xs]"
  2005 by(simp add:rotate1_def split:list.split)
  2006 
  2007 lemma rotate_drop_take:
  2008   "rotate n xs = drop (n mod length xs) xs @ take (n mod length xs) xs"
  2009 apply(induct n)
  2010  apply simp
  2011 apply(simp add:rotate_def)
  2012 apply(cases "xs = []")
  2013  apply (simp)
  2014 apply(case_tac "n mod length xs = 0")
  2015  apply(simp add:mod_Suc)
  2016  apply(simp add: rotate1_hd_tl drop_Suc take_Suc)
  2017 apply(simp add:mod_Suc rotate1_hd_tl drop_Suc[symmetric] drop_tl[symmetric]
  2018                 take_hd_drop linorder_not_le)
  2019 done
  2020 
  2021 lemma rotate_conv_mod: "rotate n xs = rotate (n mod length xs) xs"
  2022 by(simp add:rotate_drop_take)
  2023 
  2024 lemma rotate_id[simp]: "n mod length xs = 0 \<Longrightarrow> rotate n xs = xs"
  2025 by(simp add:rotate_drop_take)
  2026 
  2027 lemma length_rotate1[simp]: "length(rotate1 xs) = length xs"
  2028 by(simp add:rotate1_def split:list.split)
  2029 
  2030 lemma length_rotate[simp]: "!!xs. length(rotate n xs) = length xs"
  2031 by (induct n) (simp_all add:rotate_def)
  2032 
  2033 lemma distinct1_rotate[simp]: "distinct(rotate1 xs) = distinct xs"
  2034 by(simp add:rotate1_def split:list.split) blast
  2035 
  2036 lemma distinct_rotate[simp]: "distinct(rotate n xs) = distinct xs"
  2037 by (induct n) (simp_all add:rotate_def)
  2038 
  2039 lemma rotate_map: "rotate n (map f xs) = map f (rotate n xs)"
  2040 by(simp add:rotate_drop_take take_map drop_map)
  2041 
  2042 lemma set_rotate1[simp]: "set(rotate1 xs) = set xs"
  2043 by(simp add:rotate1_def split:list.split)
  2044 
  2045 lemma set_rotate[simp]: "set(rotate n xs) = set xs"
  2046 by (induct n) (simp_all add:rotate_def)
  2047 
  2048 lemma rotate1_is_Nil_conv[simp]: "(rotate1 xs = []) = (xs = [])"
  2049 by(simp add:rotate1_def split:list.split)
  2050 
  2051 lemma rotate_is_Nil_conv[simp]: "(rotate n xs = []) = (xs = [])"
  2052 by (induct n) (simp_all add:rotate_def)
  2053 
  2054 lemma rotate_rev:
  2055   "rotate n (rev xs) = rev(rotate (length xs - (n mod length xs)) xs)"
  2056 apply(simp add:rotate_drop_take rev_drop rev_take)
  2057 apply(cases "length xs = 0")
  2058  apply simp
  2059 apply(cases "n mod length xs = 0")
  2060  apply simp
  2061 apply(simp add:rotate_drop_take rev_drop rev_take)
  2062 done
  2063 
  2064 lemma hd_rotate_conv_nth: "xs \<noteq> [] \<Longrightarrow> hd(rotate n xs) = xs!(n mod length xs)"
  2065 apply(simp add:rotate_drop_take hd_append hd_drop_conv_nth hd_conv_nth)
  2066 apply(subgoal_tac "length xs \<noteq> 0")
  2067  prefer 2 apply simp
  2068 using mod_less_divisor[of "length xs" n] by arith
  2069 
  2070 
  2071 subsubsection {* @{text sublist} --- a generalization of @{text nth} to sets *}
  2072 
  2073 lemma sublist_empty [simp]: "sublist xs {} = []"
  2074 by (auto simp add: sublist_def)
  2075 
  2076 lemma sublist_nil [simp]: "sublist [] A = []"
  2077 by (auto simp add: sublist_def)
  2078 
  2079 lemma length_sublist:
  2080   "length(sublist xs I) = card{i. i < length xs \<and> i : I}"
  2081 by(simp add: sublist_def length_filter_conv_card cong:conj_cong)
  2082 
  2083 lemma sublist_shift_lemma_Suc:
  2084   "!!is. map fst (filter (%p. P(Suc(snd p))) (zip xs is)) =
  2085          map fst (filter (%p. P(snd p)) (zip xs (map Suc is)))"
  2086 apply(induct xs)
  2087  apply simp
  2088 apply (case_tac "is")
  2089  apply simp
  2090 apply simp
  2091 done
  2092 
  2093 lemma sublist_shift_lemma:
  2094      "map fst [p:zip xs [i..<i + length xs] . snd p : A] =
  2095       map fst [p:zip xs [0..<length xs] . snd p + i : A]"
  2096 by (induct xs rule: rev_induct) (simp_all add: add_commute)
  2097 
  2098 lemma sublist_append:
  2099      "sublist (l @ l') A = sublist l A @ sublist l' {j. j + length l : A}"
  2100 apply (unfold sublist_def)
  2101 apply (induct l' rule: rev_induct, simp)
  2102 apply (simp add: upt_add_eq_append[of 0] zip_append sublist_shift_lemma)
  2103 apply (simp add: add_commute)
  2104 done
  2105 
  2106 lemma sublist_Cons:
  2107 "sublist (x # l) A = (if 0:A then [x] else []) @ sublist l {j. Suc j : A}"
  2108 apply (induct l rule: rev_induct)
  2109  apply (simp add: sublist_def)
  2110 apply (simp del: append_Cons add: append_Cons[symmetric] sublist_append)
  2111 done
  2112 
  2113 lemma set_sublist: "!!I. set(sublist xs I) = {xs!i|i. i<size xs \<and> i \<in> I}"
  2114 apply(induct xs)
  2115  apply simp
  2116 apply(auto simp add:sublist_Cons nth_Cons split:nat.split elim: lessE)
  2117  apply(erule lessE)
  2118   apply auto
  2119 apply(erule lessE)
  2120 apply auto
  2121 done
  2122 
  2123 lemma set_sublist_subset: "set(sublist xs I) \<subseteq> set xs"
  2124 by(auto simp add:set_sublist)
  2125 
  2126 lemma notin_set_sublistI[simp]: "x \<notin> set xs \<Longrightarrow> x \<notin> set(sublist xs I)"
  2127 by(auto simp add:set_sublist)
  2128 
  2129 lemma in_set_sublistD: "x \<in> set(sublist xs I) \<Longrightarrow> x \<in> set xs"
  2130 by(auto simp add:set_sublist)
  2131 
  2132 lemma sublist_singleton [simp]: "sublist [x] A = (if 0 : A then [x] else [])"
  2133 by (simp add: sublist_Cons)
  2134 
  2135 
  2136 lemma distinct_sublistI[simp]: "!!I. distinct xs \<Longrightarrow> distinct(sublist xs I)"
  2137 apply(induct xs)
  2138  apply simp
  2139 apply(auto simp add:sublist_Cons)
  2140 done
  2141 
  2142 
  2143 lemma sublist_upt_eq_take [simp]: "sublist l {..<n} = take n l"
  2144 apply (induct l rule: rev_induct, simp)
  2145 apply (simp split: nat_diff_split add: sublist_append)
  2146 done
  2147 
  2148 lemma filter_in_sublist: "\<And>s. distinct xs \<Longrightarrow>
  2149   filter (%x. x \<in> set(sublist xs s)) xs = sublist xs s"
  2150 proof (induct xs)
  2151   case Nil thus ?case by simp
  2152 next
  2153   case (Cons a xs)
  2154   moreover hence "!x. x: set xs \<longrightarrow> x \<noteq> a" by auto
  2155   ultimately show ?case by(simp add: sublist_Cons cong:filter_cong)
  2156 qed
  2157 
  2158 
  2159 subsubsection {* @{const splice} *}
  2160 
  2161 lemma splice_Nil2[simp]:
  2162  "splice xs [] = xs"
  2163 by (cases xs) simp_all
  2164 
  2165 lemma splice_Cons_Cons[simp]:
  2166  "splice (x#xs) (y#ys) = x # y # splice xs ys"
  2167 by simp
  2168 
  2169 declare splice.simps(2)[simp del]
  2170 
  2171 subsubsection{*Sets of Lists*}
  2172 
  2173 subsubsection {* @{text lists}: the list-forming operator over sets *}
  2174 
  2175 consts lists :: "'a set => 'a list set"
  2176 inductive "lists A"
  2177  intros
  2178   Nil [intro!]: "[]: lists A"
  2179   Cons [intro!]: "[| a: A;l: lists A|] ==> a#l : lists A"
  2180 
  2181 inductive_cases listsE [elim!]: "x#l : lists A"
  2182 
  2183 lemma lists_mono [mono]: "A \<subseteq> B ==> lists A \<subseteq> lists B"
  2184 by (unfold lists.defs) (blast intro!: lfp_mono)
  2185 
  2186 lemma lists_IntI:
  2187   assumes l: "l: lists A" shows "l: lists B ==> l: lists (A Int B)" using l
  2188   by induct blast+
  2189 
  2190 lemma lists_Int_eq [simp]: "lists (A \<inter> B) = lists A \<inter> lists B"
  2191 proof (rule mono_Int [THEN equalityI])
  2192   show "mono lists" by (simp add: mono_def lists_mono)
  2193   show "lists A \<inter> lists B \<subseteq> lists (A \<inter> B)" by (blast intro: lists_IntI)
  2194 qed
  2195 
  2196 lemma append_in_lists_conv [iff]:
  2197      "(xs @ ys : lists A) = (xs : lists A \<and> ys : lists A)"
  2198 by (induct xs) auto
  2199 
  2200 lemma in_lists_conv_set: "(xs : lists A) = (\<forall>x \<in> set xs. x : A)"
  2201 -- {* eliminate @{text lists} in favour of @{text set} *}
  2202 by (induct xs) auto
  2203 
  2204 lemma in_listsD [dest!]: "xs \<in> lists A ==> \<forall>x\<in>set xs. x \<in> A"
  2205 by (rule in_lists_conv_set [THEN iffD1])
  2206 
  2207 lemma in_listsI [intro!]: "\<forall>x\<in>set xs. x \<in> A ==> xs \<in> lists A"
  2208 by (rule in_lists_conv_set [THEN iffD2])
  2209 
  2210 lemma lists_UNIV [simp]: "lists UNIV = UNIV"
  2211 by auto
  2212 
  2213 subsubsection {* For efficiency *}
  2214 
  2215 text{* Only use @{text mem} for generating executable code.  Otherwise
  2216 use @{prop"x : set xs"} instead --- it is much easier to reason about.
  2217 The same is true for @{const list_all} and @{const list_ex}: write
  2218 @{text"\<forall>x\<in>set xs"} and @{text"\<exists>x\<in>set xs"} instead because the HOL
  2219 quantifiers are aleady known to the automatic provers. In fact, the declarations in the Code subsection make sure that @{text"\<in>"}, @{text"\<forall>x\<in>set xs"}
  2220 and @{text"\<exists>x\<in>set xs"} are implemented efficiently.
  2221 
  2222 The functions @{const itrev}, @{const filtermap} and @{const
  2223 map_filter} are just there to generate efficient code. Do not use them
  2224 for modelling and proving. *}
  2225 
  2226 lemma mem_iff: "(x mem xs) = (x : set xs)"
  2227 by (induct xs) auto
  2228 
  2229 lemma list_inter_conv: "set(list_inter xs ys) = set xs \<inter> set ys"
  2230 by (induct xs) auto
  2231 
  2232 lemma list_all_iff: "list_all P xs = (\<forall>x \<in> set xs. P x)"
  2233 by (induct xs) auto
  2234 
  2235 lemma list_all_append [simp]:
  2236 "list_all P (xs @ ys) = (list_all P xs \<and> list_all P ys)"
  2237 by (induct xs) auto
  2238 
  2239 lemma list_all_rev [simp]: "list_all P (rev xs) = list_all P xs"
  2240 by (simp add: list_all_iff)
  2241 
  2242 lemma list_ex_iff: "list_ex P xs = (\<exists>x \<in> set xs. P x)"
  2243 by (induct xs) simp_all
  2244 
  2245 lemma itrev[simp]: "ALL ys. itrev xs ys = rev xs @ ys"
  2246 by (induct xs) simp_all
  2247 
  2248 lemma filtermap_conv:
  2249      "filtermap f xs = map (%x. the(f x)) (filter (%x. f x \<noteq> None) xs)"
  2250   by (induct xs) (simp_all split: option.split) 
  2251 
  2252 lemma map_filter_conv[simp]: "map_filter f P xs = map f (filter P xs)"
  2253 by (induct xs) auto
  2254 
  2255 
  2256 subsubsection {* Code generation *}
  2257 
  2258 text{* Defaults for generating efficient code for some standard functions. *}
  2259 
  2260 lemmas in_set_code[code unfold] = mem_iff[symmetric, THEN eq_reflection]
  2261 
  2262 lemma rev_code[code unfold]: "rev xs == itrev xs []"
  2263 by simp
  2264 
  2265 lemma distinct_Cons_mem[code]: "distinct (x#xs) = (~(x mem xs) \<and> distinct xs)"
  2266 by (simp add:mem_iff)
  2267 
  2268 lemma remdups_Cons_mem[code]:
  2269  "remdups (x#xs) = (if x mem xs then remdups xs else x # remdups xs)"
  2270 by (simp add:mem_iff)
  2271 
  2272 lemma list_inter_Cons_mem[code]:  "list_inter (a#as) bs =
  2273   (if a mem bs then a#(list_inter as bs) else list_inter as bs)"
  2274 by(simp add:mem_iff)
  2275 
  2276 text{* For implementing bounded quantifiers over lists by
  2277 @{const list_ex}/@{const list_all}: *}
  2278 
  2279 lemmas list_bex_code[code unfold] = list_ex_iff[symmetric, THEN eq_reflection]
  2280 lemmas list_ball_code[code unfold] = list_all_iff[symmetric, THEN eq_reflection]
  2281 
  2282 
  2283 subsubsection{* Inductive definition for membership *}
  2284 
  2285 consts ListMem :: "('a \<times> 'a list)set"
  2286 inductive ListMem
  2287 intros
  2288  elem:  "(x,x#xs) \<in> ListMem"
  2289  insert:  "(x,xs) \<in> ListMem \<Longrightarrow> (x,y#xs) \<in> ListMem"
  2290 
  2291 lemma ListMem_iff: "((x,xs) \<in> ListMem) = (x \<in> set xs)"
  2292 apply (rule iffI)
  2293  apply (induct set: ListMem)
  2294   apply auto
  2295 apply (induct xs)
  2296  apply (auto intro: ListMem.intros)
  2297 done
  2298 
  2299 
  2300 
  2301 subsubsection{*Lists as Cartesian products*}
  2302 
  2303 text{*@{text"set_Cons A Xs"}: the set of lists with head drawn from
  2304 @{term A} and tail drawn from @{term Xs}.*}
  2305 
  2306 constdefs
  2307   set_Cons :: "'a set \<Rightarrow> 'a list set \<Rightarrow> 'a list set"
  2308   "set_Cons A XS == {z. \<exists>x xs. z = x#xs & x \<in> A & xs \<in> XS}"
  2309 
  2310 lemma set_Cons_sing_Nil [simp]: "set_Cons A {[]} = (%x. [x])`A"
  2311 by (auto simp add: set_Cons_def)
  2312 
  2313 text{*Yields the set of lists, all of the same length as the argument and
  2314 with elements drawn from the corresponding element of the argument.*}
  2315 
  2316 consts  listset :: "'a set list \<Rightarrow> 'a list set"
  2317 primrec
  2318    "listset []    = {[]}"
  2319    "listset(A#As) = set_Cons A (listset As)"
  2320 
  2321 
  2322 subsection{*Relations on Lists*}
  2323 
  2324 subsubsection {* Length Lexicographic Ordering *}
  2325 
  2326 text{*These orderings preserve well-foundedness: shorter lists 
  2327   precede longer lists. These ordering are not used in dictionaries.*}
  2328 
  2329 consts lexn :: "('a * 'a)set => nat => ('a list * 'a list)set"
  2330         --{*The lexicographic ordering for lists of the specified length*}
  2331 primrec
  2332   "lexn r 0 = {}"
  2333   "lexn r (Suc n) =
  2334     (prod_fun (%(x,xs). x#xs) (%(x,xs). x#xs) ` (r <*lex*> lexn r n)) Int
  2335     {(xs,ys). length xs = Suc n \<and> length ys = Suc n}"
  2336 
  2337 constdefs
  2338   lex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
  2339     "lex r == \<Union>n. lexn r n"
  2340         --{*Holds only between lists of the same length*}
  2341 
  2342   lenlex :: "('a \<times> 'a) set => ('a list \<times> 'a list) set"
  2343     "lenlex r == inv_image (less_than <*lex*> lex r) (%xs. (length xs, xs))"
  2344         --{*Compares lists by their length and then lexicographically*}
  2345 
  2346 
  2347 lemma wf_lexn: "wf r ==> wf (lexn r n)"
  2348 apply (induct n, simp, simp)
  2349 apply(rule wf_subset)
  2350  prefer 2 apply (rule Int_lower1)
  2351 apply(rule wf_prod_fun_image)
  2352  prefer 2 apply (rule inj_onI, auto)
  2353 done
  2354 
  2355 lemma lexn_length:
  2356      "!!xs ys. (xs, ys) : lexn r n ==> length xs = n \<and> length ys = n"
  2357 by (induct n) auto
  2358 
  2359 lemma wf_lex [intro!]: "wf r ==> wf (lex r)"
  2360 apply (unfold lex_def)
  2361 apply (rule wf_UN)
  2362 apply (blast intro: wf_lexn, clarify)
  2363 apply (rename_tac m n)
  2364 apply (subgoal_tac "m \<noteq> n")
  2365  prefer 2 apply blast
  2366 apply (blast dest: lexn_length not_sym)
  2367 done
  2368 
  2369 lemma lexn_conv:
  2370   "lexn r n =
  2371     {(xs,ys). length xs = n \<and> length ys = n \<and>
  2372     (\<exists>xys x y xs' ys'. xs= xys @ x#xs' \<and> ys= xys @ y # ys' \<and> (x, y):r)}"
  2373 apply (induct n, simp)
  2374 apply (simp add: image_Collect lex_prod_def, safe, blast)
  2375  apply (rule_tac x = "ab # xys" in exI, simp)
  2376 apply (case_tac xys, simp_all, blast)
  2377 done
  2378 
  2379 lemma lex_conv:
  2380   "lex r =
  2381     {(xs,ys). length xs = length ys \<and>
  2382     (\<exists>xys x y xs' ys'. xs = xys @ x # xs' \<and> ys = xys @ y # ys' \<and> (x, y):r)}"
  2383 by (force simp add: lex_def lexn_conv)
  2384 
  2385 lemma wf_lenlex [intro!]: "wf r ==> wf (lenlex r)"
  2386 by (unfold lenlex_def) blast
  2387 
  2388 lemma lenlex_conv:
  2389     "lenlex r = {(xs,ys). length xs < length ys |
  2390                  length xs = length ys \<and> (xs, ys) : lex r}"
  2391 by (simp add: lenlex_def diag_def lex_prod_def measure_def inv_image_def)
  2392 
  2393 lemma Nil_notin_lex [iff]: "([], ys) \<notin> lex r"
  2394 by (simp add: lex_conv)
  2395 
  2396 lemma Nil2_notin_lex [iff]: "(xs, []) \<notin> lex r"
  2397 by (simp add:lex_conv)
  2398 
  2399 lemma Cons_in_lex [simp]:
  2400     "((x # xs, y # ys) : lex r) =
  2401       ((x, y) : r \<and> length xs = length ys | x = y \<and> (xs, ys) : lex r)"
  2402 apply (simp add: lex_conv)
  2403 apply (rule iffI)
  2404  prefer 2 apply (blast intro: Cons_eq_appendI, clarify)
  2405 apply (case_tac xys, simp, simp)
  2406 apply blast
  2407 done
  2408 
  2409 
  2410 subsubsection {* Lexicographic Ordering *}
  2411 
  2412 text {* Classical lexicographic ordering on lists, ie. "a" < "ab" < "b".
  2413     This ordering does \emph{not} preserve well-foundedness.
  2414      Author: N. Voelker, March 2005. *} 
  2415 
  2416 constdefs 
  2417   lexord :: "('a * 'a)set \<Rightarrow> ('a list * 'a list) set" 
  2418   "lexord  r == {(x,y). \<exists> a v. y = x @ a # v \<or> 
  2419             (\<exists> u a b v w. (a,b) \<in> r \<and> x = u @ (a # v) \<and> y = u @ (b # w))}"
  2420 
  2421 lemma lexord_Nil_left[simp]:  "([],y) \<in> lexord r = (\<exists> a x. y = a # x)"
  2422   by (unfold lexord_def, induct_tac y, auto) 
  2423 
  2424 lemma lexord_Nil_right[simp]: "(x,[]) \<notin> lexord r"
  2425   by (unfold lexord_def, induct_tac x, auto)
  2426 
  2427 lemma lexord_cons_cons[simp]:
  2428      "((a # x, b # y) \<in> lexord r) = ((a,b)\<in> r | (a = b & (x,y)\<in> lexord r))"
  2429   apply (unfold lexord_def, safe, simp_all)
  2430   apply (case_tac u, simp, simp)
  2431   apply (case_tac u, simp, clarsimp, blast, blast, clarsimp)
  2432   apply (erule_tac x="b # u" in allE)
  2433   by force
  2434 
  2435 lemmas lexord_simps = lexord_Nil_left lexord_Nil_right lexord_cons_cons
  2436 
  2437 lemma lexord_append_rightI: "\<exists> b z. y = b # z \<Longrightarrow> (x, x @ y) \<in> lexord r"
  2438   by (induct_tac x, auto)  
  2439 
  2440 lemma lexord_append_left_rightI:
  2441      "(a,b) \<in> r \<Longrightarrow> (u @ a # x, u @ b # y) \<in> lexord r"
  2442   by (induct_tac u, auto)
  2443 
  2444 lemma lexord_append_leftI: " (u,v) \<in> lexord r \<Longrightarrow> (x @ u, x @ v) \<in> lexord r"
  2445   by (induct x, auto)
  2446 
  2447 lemma lexord_append_leftD:
  2448      "\<lbrakk> (x @ u, x @ v) \<in> lexord r; (! a. (a,a) \<notin> r) \<rbrakk> \<Longrightarrow> (u,v) \<in> lexord r"
  2449   by (erule rev_mp, induct_tac x, auto)
  2450 
  2451 lemma lexord_take_index_conv: 
  2452    "((x,y) : lexord r) = 
  2453     ((length x < length y \<and> take (length x) y = x) \<or> 
  2454      (\<exists>i. i < min(length x)(length y) & take i x = take i y & (x!i,y!i) \<in> r))"
  2455   apply (unfold lexord_def Let_def, clarsimp) 
  2456   apply (rule_tac f = "(% a b. a \<or> b)" in arg_cong2)
  2457   apply auto 
  2458   apply (rule_tac x="hd (drop (length x) y)" in exI)
  2459   apply (rule_tac x="tl (drop (length x) y)" in exI)
  2460   apply (erule subst, simp add: min_def) 
  2461   apply (rule_tac x ="length u" in exI, simp) 
  2462   apply (rule_tac x ="take i x" in exI) 
  2463   apply (rule_tac x ="x ! i" in exI) 
  2464   apply (rule_tac x ="y ! i" in exI, safe) 
  2465   apply (rule_tac x="drop (Suc i) x" in exI)
  2466   apply (drule sym, simp add: drop_Suc_conv_tl) 
  2467   apply (rule_tac x="drop (Suc i) y" in exI)
  2468   by (simp add: drop_Suc_conv_tl) 
  2469 
  2470 -- {* lexord is extension of partial ordering List.lex *} 
  2471 lemma lexord_lex: " (x,y) \<in> lex r = ((x,y) \<in> lexord r \<and> length x = length y)"
  2472   apply (rule_tac x = y in spec) 
  2473   apply (induct_tac x, clarsimp) 
  2474   by (clarify, case_tac x, simp, force)
  2475 
  2476 lemma lexord_irreflexive: "(! x. (x,x) \<notin> r) \<Longrightarrow> (y,y) \<notin> lexord r"
  2477   by (induct y, auto)
  2478 
  2479 lemma lexord_trans: 
  2480     "\<lbrakk> (x, y) \<in> lexord r; (y, z) \<in> lexord r; trans r \<rbrakk> \<Longrightarrow> (x, z) \<in> lexord r"
  2481    apply (erule rev_mp)+
  2482    apply (rule_tac x = x in spec) 
  2483   apply (rule_tac x = z in spec) 
  2484   apply ( induct_tac y, simp, clarify)
  2485   apply (case_tac xa, erule ssubst) 
  2486   apply (erule allE, erule allE) -- {* avoid simp recursion *} 
  2487   apply (case_tac x, simp, simp) 
  2488   apply (case_tac x, erule allE, erule allE, simp) 
  2489   apply (erule_tac x = listb in allE) 
  2490   apply (erule_tac x = lista in allE, simp)
  2491   apply (unfold trans_def)
  2492   by blast
  2493 
  2494 lemma lexord_transI:  "trans r \<Longrightarrow> trans (lexord r)"
  2495   by (rule transI, drule lexord_trans, blast) 
  2496 
  2497 lemma lexord_linear: "(! a b. (a,b)\<in> r | a = b | (b,a) \<in> r) \<Longrightarrow> (x,y) : lexord r | x = y | (y,x) : lexord r"
  2498   apply (rule_tac x = y in spec) 
  2499   apply (induct_tac x, rule allI) 
  2500   apply (case_tac x, simp, simp) 
  2501   apply (rule allI, case_tac x, simp, simp) 
  2502   by blast
  2503 
  2504 
  2505 subsubsection{*Lifting a Relation on List Elements to the Lists*}
  2506 
  2507 consts  listrel :: "('a * 'a)set => ('a list * 'a list)set"
  2508 
  2509 inductive "listrel(r)"
  2510  intros
  2511    Nil:  "([],[]) \<in> listrel r"
  2512    Cons: "[| (x,y) \<in> r; (xs,ys) \<in> listrel r |] ==> (x#xs, y#ys) \<in> listrel r"
  2513 
  2514 inductive_cases listrel_Nil1 [elim!]: "([],xs) \<in> listrel r"
  2515 inductive_cases listrel_Nil2 [elim!]: "(xs,[]) \<in> listrel r"
  2516 inductive_cases listrel_Cons1 [elim!]: "(y#ys,xs) \<in> listrel r"
  2517 inductive_cases listrel_Cons2 [elim!]: "(xs,y#ys) \<in> listrel r"
  2518 
  2519 
  2520 lemma listrel_mono: "r \<subseteq> s \<Longrightarrow> listrel r \<subseteq> listrel s"
  2521 apply clarify  
  2522 apply (erule listrel.induct)
  2523 apply (blast intro: listrel.intros)+
  2524 done
  2525 
  2526 lemma listrel_subset: "r \<subseteq> A \<times> A \<Longrightarrow> listrel r \<subseteq> lists A \<times> lists A"
  2527 apply clarify 
  2528 apply (erule listrel.induct, auto) 
  2529 done
  2530 
  2531 lemma listrel_refl: "refl A r \<Longrightarrow> refl (lists A) (listrel r)" 
  2532 apply (simp add: refl_def listrel_subset Ball_def)
  2533 apply (rule allI) 
  2534 apply (induct_tac x) 
  2535 apply (auto intro: listrel.intros)
  2536 done
  2537 
  2538 lemma listrel_sym: "sym r \<Longrightarrow> sym (listrel r)" 
  2539 apply (auto simp add: sym_def)
  2540 apply (erule listrel.induct) 
  2541 apply (blast intro: listrel.intros)+
  2542 done
  2543 
  2544 lemma listrel_trans: "trans r \<Longrightarrow> trans (listrel r)" 
  2545 apply (simp add: trans_def)
  2546 apply (intro allI) 
  2547 apply (rule impI) 
  2548 apply (erule listrel.induct) 
  2549 apply (blast intro: listrel.intros)+
  2550 done
  2551 
  2552 theorem equiv_listrel: "equiv A r \<Longrightarrow> equiv (lists A) (listrel r)"
  2553 by (simp add: equiv_def listrel_refl listrel_sym listrel_trans) 
  2554 
  2555 lemma listrel_Nil [simp]: "listrel r `` {[]} = {[]}"
  2556 by (blast intro: listrel.intros)
  2557 
  2558 lemma listrel_Cons:
  2559      "listrel r `` {x#xs} = set_Cons (r``{x}) (listrel r `` {xs})";
  2560 by (auto simp add: set_Cons_def intro: listrel.intros) 
  2561 
  2562 
  2563 subsection{*Miscellany*}
  2564 
  2565 subsubsection {* Characters and strings *}
  2566 
  2567 datatype nibble =
  2568     Nibble0 | Nibble1 | Nibble2 | Nibble3 | Nibble4 | Nibble5 | Nibble6 | Nibble7
  2569   | Nibble8 | Nibble9 | NibbleA | NibbleB | NibbleC | NibbleD | NibbleE | NibbleF
  2570 
  2571 datatype char = Char nibble nibble
  2572   -- "Note: canonical order of character encoding coincides with standard term ordering"
  2573 
  2574 types string = "char list"
  2575 
  2576 syntax
  2577   "_Char" :: "xstr => char"    ("CHR _")
  2578   "_String" :: "xstr => string"    ("_")
  2579 
  2580 parse_ast_translation {*
  2581   let
  2582     val constants = Syntax.Appl o map Syntax.Constant;
  2583 
  2584     fun mk_nib n = "Nibble" ^ chr (n + (if n <= 9 then ord "0" else ord "A" - 10));
  2585     fun mk_char c =
  2586       if Symbol.is_ascii c andalso Symbol.is_printable c then
  2587         constants ["Char", mk_nib (ord c div 16), mk_nib (ord c mod 16)]
  2588       else error ("Printable ASCII character expected: " ^ quote c);
  2589 
  2590     fun mk_string [] = Syntax.Constant "Nil"
  2591       | mk_string (c :: cs) = Syntax.Appl [Syntax.Constant "Cons", mk_char c, mk_string cs];
  2592 
  2593     fun char_ast_tr [Syntax.Variable xstr] =
  2594         (case Syntax.explode_xstr xstr of
  2595           [c] => mk_char c
  2596         | _ => error ("Single character expected: " ^ xstr))
  2597       | char_ast_tr asts = raise AST ("char_ast_tr", asts);
  2598 
  2599     fun string_ast_tr [Syntax.Variable xstr] =
  2600         (case Syntax.explode_xstr xstr of
  2601           [] => constants [Syntax.constrainC, "Nil", "string"]
  2602         | cs => mk_string cs)
  2603       | string_ast_tr asts = raise AST ("string_tr", asts);
  2604   in [("_Char", char_ast_tr), ("_String", string_ast_tr)] end;
  2605 *}
  2606 
  2607 ML {*
  2608 fun int_of_nibble h =
  2609   if "0" <= h andalso h <= "9" then ord h - ord "0"
  2610   else if "A" <= h andalso h <= "F" then ord h - ord "A" + 10
  2611   else raise Match;
  2612 
  2613 fun nibble_of_int i =
  2614   if i <= 9 then chr (ord "0" + i) else chr (ord "A" + i - 10);
  2615 *}
  2616 
  2617 print_ast_translation {*
  2618   let
  2619     fun dest_nib (Syntax.Constant c) =
  2620         (case explode c of
  2621           ["N", "i", "b", "b", "l", "e", h] => int_of_nibble h
  2622         | _ => raise Match)
  2623       | dest_nib _ = raise Match;
  2624 
  2625     fun dest_chr c1 c2 =
  2626       let val c = chr (dest_nib c1 * 16 + dest_nib c2)
  2627       in if Symbol.is_printable c then c else raise Match end;
  2628 
  2629     fun dest_char (Syntax.Appl [Syntax.Constant "Char", c1, c2]) = dest_chr c1 c2
  2630       | dest_char _ = raise Match;
  2631 
  2632     fun xstr cs = Syntax.Appl [Syntax.Constant "_xstr", Syntax.Variable (Syntax.implode_xstr cs)];
  2633 
  2634     fun char_ast_tr' [c1, c2] = Syntax.Appl [Syntax.Constant "_Char", xstr [dest_chr c1 c2]]
  2635       | char_ast_tr' _ = raise Match;
  2636 
  2637     fun list_ast_tr' [args] = Syntax.Appl [Syntax.Constant "_String",
  2638             xstr (map dest_char (Syntax.unfold_ast "_args" args))]
  2639       | list_ast_tr' ts = raise Match;
  2640   in [("Char", char_ast_tr'), ("@list", list_ast_tr')] end;
  2641 *}
  2642 
  2643 subsubsection {* Code generator setup *}
  2644 
  2645 ML {*
  2646 local
  2647 
  2648 fun list_codegen thy defs gr dep thyname b t =
  2649   let val (gr', ps) = foldl_map (Codegen.invoke_codegen thy defs dep thyname false)
  2650     (gr, HOLogic.dest_list t)
  2651   in SOME (gr', Pretty.list "[" "]" ps) end handle TERM _ => NONE;
  2652 
  2653 fun dest_nibble (Const (s, _)) = int_of_nibble (unprefix "List.nibble.Nibble" s)
  2654   | dest_nibble _ = raise Match;
  2655 
  2656 fun char_codegen thy defs gr dep thyname b (Const ("List.char.Char", _) $ c1 $ c2) =
  2657     (let val c = chr (dest_nibble c1 * 16 + dest_nibble c2)
  2658      in if Symbol.is_printable c then SOME (gr, Pretty.quote (Pretty.str c))
  2659        else NONE
  2660      end handle Fail _ => NONE | Match => NONE)
  2661   | char_codegen thy defs gr dep thyname b _ = NONE;
  2662 
  2663 in
  2664 
  2665 val list_codegen_setup =
  2666   Codegen.add_codegen "list_codegen" list_codegen #>
  2667   Codegen.add_codegen "char_codegen" char_codegen #>
  2668   fold (CodegenPackage.add_pretty_list "Nil" "Cons") [
  2669     ("ml", (7, "::")),
  2670     ("haskell", (5, ":"))];
  2671 
  2672 end;
  2673 *}
  2674 
  2675 types_code
  2676   "list" ("_ list")
  2677 attach (term_of) {*
  2678 val term_of_list = HOLogic.mk_list;
  2679 *}
  2680 attach (test) {*
  2681 fun gen_list' aG i j = frequency
  2682   [(i, fn () => aG j :: gen_list' aG (i-1) j), (1, fn () => [])] ()
  2683 and gen_list aG i = gen_list' aG i i;
  2684 *}
  2685   "char" ("string")
  2686 attach (term_of) {*
  2687 val nibbleT = Type ("List.nibble", []);
  2688 
  2689 fun term_of_char c =
  2690   Const ("List.char.Char", nibbleT --> nibbleT --> Type ("List.char", [])) $
  2691     Const ("List.nibble.Nibble" ^ nibble_of_int (ord c div 16), nibbleT) $
  2692     Const ("List.nibble.Nibble" ^ nibble_of_int (ord c mod 16), nibbleT);
  2693 *}
  2694 attach (test) {*
  2695 fun gen_char i = chr (random_range (ord "a") (Int.min (ord "a" + i, ord "z")));
  2696 *}
  2697 
  2698 consts_code "Cons" ("(_ ::/ _)")
  2699 
  2700 code_alias
  2701   "List.op @" "List.append"
  2702   "List.op mem" "List.member"
  2703 
  2704 code_generate Nil Cons
  2705 
  2706 code_syntax_tyco
  2707   list
  2708     ml ("_ list")
  2709     haskell (target_atom "[_]")
  2710 
  2711 code_syntax_const
  2712   Nil
  2713     ml (target_atom "[]")
  2714     haskell (target_atom "[]")
  2715 
  2716 setup list_codegen_setup
  2717 
  2718 setup CodegenPackage.rename_inconsistent
  2719 
  2720 end