src/HOL/Nat.thy
author obua
Mon Apr 10 16:00:34 2006 +0200 (2006-04-10)
changeset 19404 9bf2cdc9e8e8
parent 18702 7dc7dcd63224
child 19573 340c466c9605
permissions -rw-r--r--
Moved stuff from Ring_and_Field to Matrix
     1 (*  Title:      HOL/Nat.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow and Lawrence C Paulson
     4 
     5 Type "nat" is a linear order, and a datatype; arithmetic operators + -
     6 and * (for div, mod and dvd, see theory Divides).
     7 *)
     8 
     9 header {* Natural numbers *}
    10 
    11 theory Nat
    12 imports Wellfounded_Recursion Ring_and_Field
    13 begin
    14 
    15 subsection {* Type @{text ind} *}
    16 
    17 typedecl ind
    18 
    19 consts
    20   Zero_Rep      :: ind
    21   Suc_Rep       :: "ind => ind"
    22 
    23 axioms
    24   -- {* the axiom of infinity in 2 parts *}
    25   inj_Suc_Rep:          "inj Suc_Rep"
    26   Suc_Rep_not_Zero_Rep: "Suc_Rep x \<noteq> Zero_Rep"
    27 finalconsts
    28   Zero_Rep
    29   Suc_Rep
    30 
    31 subsection {* Type nat *}
    32 
    33 text {* Type definition *}
    34 
    35 consts
    36   Nat :: "ind set"
    37 
    38 inductive Nat
    39 intros
    40   Zero_RepI: "Zero_Rep : Nat"
    41   Suc_RepI: "i : Nat ==> Suc_Rep i : Nat"
    42 
    43 global
    44 
    45 typedef (open Nat)
    46   nat = Nat by (rule exI, rule Nat.Zero_RepI)
    47 
    48 instance nat :: "{ord, zero, one}" ..
    49 
    50 
    51 text {* Abstract constants and syntax *}
    52 
    53 consts
    54   Suc :: "nat => nat"
    55   pred_nat :: "(nat * nat) set"
    56 
    57 local
    58 
    59 defs
    60   Zero_nat_def: "0 == Abs_Nat Zero_Rep"
    61   Suc_def:      "Suc == (%n. Abs_Nat (Suc_Rep (Rep_Nat n)))"
    62   One_nat_def:  "1 == Suc 0"
    63 
    64   -- {* nat operations *}
    65   pred_nat_def: "pred_nat == {(m, n). n = Suc m}"
    66 
    67   less_def: "m < n == (m, n) : trancl pred_nat"
    68 
    69   le_def: "m \<le> (n::nat) == ~ (n < m)"
    70 
    71 declare One_nat_def [simp]
    72 
    73 
    74 text {* Induction *}
    75 
    76 theorem nat_induct: "P 0 ==> (!!n. P n ==> P (Suc n)) ==> P n"
    77   apply (unfold Zero_nat_def Suc_def)
    78   apply (rule Rep_Nat_inverse [THEN subst]) -- {* types force good instantiation *}
    79   apply (erule Rep_Nat [THEN Nat.induct])
    80   apply (iprover elim: Abs_Nat_inverse [THEN subst])
    81   done
    82 
    83 text {* Distinctness of constructors *}
    84 
    85 lemma Suc_not_Zero [iff]: "Suc m \<noteq> 0"
    86   by (simp add: Zero_nat_def Suc_def Abs_Nat_inject Rep_Nat Suc_RepI Zero_RepI
    87                 Suc_Rep_not_Zero_Rep) 
    88 
    89 lemma Zero_not_Suc [iff]: "0 \<noteq> Suc m"
    90   by (rule not_sym, rule Suc_not_Zero not_sym)
    91 
    92 lemma Suc_neq_Zero: "Suc m = 0 ==> R"
    93   by (rule notE, rule Suc_not_Zero)
    94 
    95 lemma Zero_neq_Suc: "0 = Suc m ==> R"
    96   by (rule Suc_neq_Zero, erule sym)
    97 
    98 text {* Injectiveness of @{term Suc} *}
    99 
   100 lemma inj_Suc[simp]: "inj_on Suc N"
   101   by (simp add: Suc_def inj_on_def Abs_Nat_inject Rep_Nat Suc_RepI 
   102                 inj_Suc_Rep [THEN inj_eq] Rep_Nat_inject) 
   103 
   104 lemma Suc_inject: "Suc x = Suc y ==> x = y"
   105   by (rule inj_Suc [THEN injD])
   106 
   107 lemma Suc_Suc_eq [iff]: "(Suc m = Suc n) = (m = n)"
   108   by (rule inj_Suc [THEN inj_eq])
   109 
   110 lemma nat_not_singleton: "(\<forall>x. x = (0::nat)) = False"
   111   by auto
   112 
   113 text {* @{typ nat} is a datatype *}
   114 
   115 rep_datatype nat
   116   distinct  Suc_not_Zero Zero_not_Suc
   117   inject    Suc_Suc_eq
   118   induction nat_induct
   119 
   120 lemma n_not_Suc_n: "n \<noteq> Suc n"
   121   by (induct n) simp_all
   122 
   123 lemma Suc_n_not_n: "Suc t \<noteq> t"
   124   by (rule not_sym, rule n_not_Suc_n)
   125 
   126 text {* A special form of induction for reasoning
   127   about @{term "m < n"} and @{term "m - n"} *}
   128 
   129 theorem diff_induct: "(!!x. P x 0) ==> (!!y. P 0 (Suc y)) ==>
   130     (!!x y. P x y ==> P (Suc x) (Suc y)) ==> P m n"
   131   apply (rule_tac x = m in spec)
   132   apply (induct n)
   133   prefer 2
   134   apply (rule allI)
   135   apply (induct_tac x, iprover+)
   136   done
   137 
   138 subsection {* Basic properties of "less than" *}
   139 
   140 lemma wf_pred_nat: "wf pred_nat"
   141   apply (unfold wf_def pred_nat_def, clarify)
   142   apply (induct_tac x, blast+)
   143   done
   144 
   145 lemma wf_less: "wf {(x, y::nat). x < y}"
   146   apply (unfold less_def)
   147   apply (rule wf_pred_nat [THEN wf_trancl, THEN wf_subset], blast)
   148   done
   149 
   150 lemma less_eq: "((m, n) : pred_nat^+) = (m < n)"
   151   apply (unfold less_def)
   152   apply (rule refl)
   153   done
   154 
   155 subsubsection {* Introduction properties *}
   156 
   157 lemma less_trans: "i < j ==> j < k ==> i < (k::nat)"
   158   apply (unfold less_def)
   159   apply (rule trans_trancl [THEN transD], assumption+)
   160   done
   161 
   162 lemma lessI [iff]: "n < Suc n"
   163   apply (unfold less_def pred_nat_def)
   164   apply (simp add: r_into_trancl)
   165   done
   166 
   167 lemma less_SucI: "i < j ==> i < Suc j"
   168   apply (rule less_trans, assumption)
   169   apply (rule lessI)
   170   done
   171 
   172 lemma zero_less_Suc [iff]: "0 < Suc n"
   173   apply (induct n)
   174   apply (rule lessI)
   175   apply (erule less_trans)
   176   apply (rule lessI)
   177   done
   178 
   179 subsubsection {* Elimination properties *}
   180 
   181 lemma less_not_sym: "n < m ==> ~ m < (n::nat)"
   182   apply (unfold less_def)
   183   apply (blast intro: wf_pred_nat wf_trancl [THEN wf_asym])
   184   done
   185 
   186 lemma less_asym:
   187   assumes h1: "(n::nat) < m" and h2: "~ P ==> m < n" shows P
   188   apply (rule contrapos_np)
   189   apply (rule less_not_sym)
   190   apply (rule h1)
   191   apply (erule h2)
   192   done
   193 
   194 lemma less_not_refl: "~ n < (n::nat)"
   195   apply (unfold less_def)
   196   apply (rule wf_pred_nat [THEN wf_trancl, THEN wf_not_refl])
   197   done
   198 
   199 lemma less_irrefl [elim!]: "(n::nat) < n ==> R"
   200   by (rule notE, rule less_not_refl)
   201 
   202 lemma less_not_refl2: "n < m ==> m \<noteq> (n::nat)" by blast
   203 
   204 lemma less_not_refl3: "(s::nat) < t ==> s \<noteq> t"
   205   by (rule not_sym, rule less_not_refl2)
   206 
   207 lemma lessE:
   208   assumes major: "i < k"
   209   and p1: "k = Suc i ==> P" and p2: "!!j. i < j ==> k = Suc j ==> P"
   210   shows P
   211   apply (rule major [unfolded less_def pred_nat_def, THEN tranclE], simp_all)
   212   apply (erule p1)
   213   apply (rule p2)
   214   apply (simp add: less_def pred_nat_def, assumption)
   215   done
   216 
   217 lemma not_less0 [iff]: "~ n < (0::nat)"
   218   by (blast elim: lessE)
   219 
   220 lemma less_zeroE: "(n::nat) < 0 ==> R"
   221   by (rule notE, rule not_less0)
   222 
   223 lemma less_SucE: assumes major: "m < Suc n"
   224   and less: "m < n ==> P" and eq: "m = n ==> P" shows P
   225   apply (rule major [THEN lessE])
   226   apply (rule eq, blast)
   227   apply (rule less, blast)
   228   done
   229 
   230 lemma less_Suc_eq: "(m < Suc n) = (m < n | m = n)"
   231   by (blast elim!: less_SucE intro: less_trans)
   232 
   233 lemma less_one [iff]: "(n < (1::nat)) = (n = 0)"
   234   by (simp add: less_Suc_eq)
   235 
   236 lemma less_Suc0 [iff]: "(n < Suc 0) = (n = 0)"
   237   by (simp add: less_Suc_eq)
   238 
   239 lemma Suc_mono: "m < n ==> Suc m < Suc n"
   240   by (induct n) (fast elim: less_trans lessE)+
   241 
   242 text {* "Less than" is a linear ordering *}
   243 lemma less_linear: "m < n | m = n | n < (m::nat)"
   244   apply (induct m)
   245   apply (induct n)
   246   apply (rule refl [THEN disjI1, THEN disjI2])
   247   apply (rule zero_less_Suc [THEN disjI1])
   248   apply (blast intro: Suc_mono less_SucI elim: lessE)
   249   done
   250 
   251 text {* "Less than" is antisymmetric, sort of *}
   252 lemma less_antisym: "\<lbrakk> \<not> n < m; n < Suc m \<rbrakk> \<Longrightarrow> m = n"
   253 apply(simp only:less_Suc_eq)
   254 apply blast
   255 done
   256 
   257 lemma nat_neq_iff: "((m::nat) \<noteq> n) = (m < n | n < m)"
   258   using less_linear by blast
   259 
   260 lemma nat_less_cases: assumes major: "(m::nat) < n ==> P n m"
   261   and eqCase: "m = n ==> P n m" and lessCase: "n<m ==> P n m"
   262   shows "P n m"
   263   apply (rule less_linear [THEN disjE])
   264   apply (erule_tac [2] disjE)
   265   apply (erule lessCase)
   266   apply (erule sym [THEN eqCase])
   267   apply (erule major)
   268   done
   269 
   270 
   271 subsubsection {* Inductive (?) properties *}
   272 
   273 lemma Suc_lessI: "m < n ==> Suc m \<noteq> n ==> Suc m < n"
   274   apply (simp add: nat_neq_iff)
   275   apply (blast elim!: less_irrefl less_SucE elim: less_asym)
   276   done
   277 
   278 lemma Suc_lessD: "Suc m < n ==> m < n"
   279   apply (induct n)
   280   apply (fast intro!: lessI [THEN less_SucI] elim: less_trans lessE)+
   281   done
   282 
   283 lemma Suc_lessE: assumes major: "Suc i < k"
   284   and minor: "!!j. i < j ==> k = Suc j ==> P" shows P
   285   apply (rule major [THEN lessE])
   286   apply (erule lessI [THEN minor])
   287   apply (erule Suc_lessD [THEN minor], assumption)
   288   done
   289 
   290 lemma Suc_less_SucD: "Suc m < Suc n ==> m < n"
   291   by (blast elim: lessE dest: Suc_lessD)
   292 
   293 lemma Suc_less_eq [iff, code]: "(Suc m < Suc n) = (m < n)"
   294   apply (rule iffI)
   295   apply (erule Suc_less_SucD)
   296   apply (erule Suc_mono)
   297   done
   298 
   299 lemma less_trans_Suc:
   300   assumes le: "i < j" shows "j < k ==> Suc i < k"
   301   apply (induct k, simp_all)
   302   apply (insert le)
   303   apply (simp add: less_Suc_eq)
   304   apply (blast dest: Suc_lessD)
   305   done
   306 
   307 lemma [code]: "((n::nat) < 0) = False" by simp
   308 lemma [code]: "(0 < Suc n) = True" by simp
   309 
   310 text {* Can be used with @{text less_Suc_eq} to get @{term "n = m | n < m"} *}
   311 lemma not_less_eq: "(~ m < n) = (n < Suc m)"
   312 by (rule_tac m = m and n = n in diff_induct, simp_all)
   313 
   314 text {* Complete induction, aka course-of-values induction *}
   315 lemma nat_less_induct:
   316   assumes prem: "!!n. \<forall>m::nat. m < n --> P m ==> P n" shows "P n"
   317   apply (rule_tac a=n in wf_induct)
   318   apply (rule wf_pred_nat [THEN wf_trancl])
   319   apply (rule prem)
   320   apply (unfold less_def, assumption)
   321   done
   322 
   323 lemmas less_induct = nat_less_induct [rule_format, case_names less]
   324 
   325 subsection {* Properties of "less than or equal" *}
   326 
   327 text {* Was @{text le_eq_less_Suc}, but this orientation is more useful *}
   328 lemma less_Suc_eq_le: "(m < Suc n) = (m \<le> n)"
   329   by (unfold le_def, rule not_less_eq [symmetric])
   330 
   331 lemma le_imp_less_Suc: "m \<le> n ==> m < Suc n"
   332   by (rule less_Suc_eq_le [THEN iffD2])
   333 
   334 lemma le0 [iff]: "(0::nat) \<le> n"
   335   by (unfold le_def, rule not_less0)
   336 
   337 lemma Suc_n_not_le_n: "~ Suc n \<le> n"
   338   by (simp add: le_def)
   339 
   340 lemma le_0_eq [iff]: "((i::nat) \<le> 0) = (i = 0)"
   341   by (induct i) (simp_all add: le_def)
   342 
   343 lemma le_Suc_eq: "(m \<le> Suc n) = (m \<le> n | m = Suc n)"
   344   by (simp del: less_Suc_eq_le add: less_Suc_eq_le [symmetric] less_Suc_eq)
   345 
   346 lemma le_SucE: "m \<le> Suc n ==> (m \<le> n ==> R) ==> (m = Suc n ==> R) ==> R"
   347   by (drule le_Suc_eq [THEN iffD1], iprover+)
   348 
   349 lemma Suc_leI: "m < n ==> Suc(m) \<le> n"
   350   apply (simp add: le_def less_Suc_eq)
   351   apply (blast elim!: less_irrefl less_asym)
   352   done -- {* formerly called lessD *}
   353 
   354 lemma Suc_leD: "Suc(m) \<le> n ==> m \<le> n"
   355   by (simp add: le_def less_Suc_eq)
   356 
   357 text {* Stronger version of @{text Suc_leD} *}
   358 lemma Suc_le_lessD: "Suc m \<le> n ==> m < n"
   359   apply (simp add: le_def less_Suc_eq)
   360   using less_linear
   361   apply blast
   362   done
   363 
   364 lemma Suc_le_eq: "(Suc m \<le> n) = (m < n)"
   365   by (blast intro: Suc_leI Suc_le_lessD)
   366 
   367 lemma le_SucI: "m \<le> n ==> m \<le> Suc n"
   368   by (unfold le_def) (blast dest: Suc_lessD)
   369 
   370 lemma less_imp_le: "m < n ==> m \<le> (n::nat)"
   371   by (unfold le_def) (blast elim: less_asym)
   372 
   373 text {* For instance, @{text "(Suc m < Suc n) = (Suc m \<le> n) = (m < n)"} *}
   374 lemmas le_simps = less_imp_le less_Suc_eq_le Suc_le_eq
   375 
   376 
   377 text {* Equivalence of @{term "m \<le> n"} and @{term "m < n | m = n"} *}
   378 
   379 lemma le_imp_less_or_eq: "m \<le> n ==> m < n | m = (n::nat)"
   380   apply (unfold le_def)
   381   using less_linear
   382   apply (blast elim: less_irrefl less_asym)
   383   done
   384 
   385 lemma less_or_eq_imp_le: "m < n | m = n ==> m \<le> (n::nat)"
   386   apply (unfold le_def)
   387   using less_linear
   388   apply (blast elim!: less_irrefl elim: less_asym)
   389   done
   390 
   391 lemma le_eq_less_or_eq: "(m \<le> (n::nat)) = (m < n | m=n)"
   392   by (iprover intro: less_or_eq_imp_le le_imp_less_or_eq)
   393 
   394 text {* Useful with @{text Blast}. *}
   395 lemma eq_imp_le: "(m::nat) = n ==> m \<le> n"
   396   by (rule less_or_eq_imp_le, rule disjI2)
   397 
   398 lemma le_refl: "n \<le> (n::nat)"
   399   by (simp add: le_eq_less_or_eq)
   400 
   401 lemma le_less_trans: "[| i \<le> j; j < k |] ==> i < (k::nat)"
   402   by (blast dest!: le_imp_less_or_eq intro: less_trans)
   403 
   404 lemma less_le_trans: "[| i < j; j \<le> k |] ==> i < (k::nat)"
   405   by (blast dest!: le_imp_less_or_eq intro: less_trans)
   406 
   407 lemma le_trans: "[| i \<le> j; j \<le> k |] ==> i \<le> (k::nat)"
   408   by (blast dest!: le_imp_less_or_eq intro: less_or_eq_imp_le less_trans)
   409 
   410 lemma le_anti_sym: "[| m \<le> n; n \<le> m |] ==> m = (n::nat)"
   411   by (blast dest!: le_imp_less_or_eq elim!: less_irrefl elim: less_asym)
   412 
   413 lemma Suc_le_mono [iff]: "(Suc n \<le> Suc m) = (n \<le> m)"
   414   by (simp add: le_simps)
   415 
   416 text {* Axiom @{text order_less_le} of class @{text order}: *}
   417 lemma nat_less_le: "((m::nat) < n) = (m \<le> n & m \<noteq> n)"
   418   by (simp add: le_def nat_neq_iff) (blast elim!: less_asym)
   419 
   420 lemma le_neq_implies_less: "(m::nat) \<le> n ==> m \<noteq> n ==> m < n"
   421   by (rule iffD2, rule nat_less_le, rule conjI)
   422 
   423 text {* Axiom @{text linorder_linear} of class @{text linorder}: *}
   424 lemma nat_le_linear: "(m::nat) \<le> n | n \<le> m"
   425   apply (simp add: le_eq_less_or_eq)
   426   using less_linear
   427   apply blast
   428   done
   429 
   430 text {* Type {@typ nat} is a wellfounded linear order *}
   431 
   432 instance nat :: "{order, linorder, wellorder}"
   433   by intro_classes
   434     (assumption |
   435       rule le_refl le_trans le_anti_sym nat_less_le nat_le_linear wf_less)+
   436 
   437 lemmas linorder_neqE_nat = linorder_neqE[where 'a = nat]
   438 
   439 lemma not_less_less_Suc_eq: "~ n < m ==> (n < Suc m) = (n = m)"
   440   by (blast elim!: less_SucE)
   441 
   442 text {*
   443   Rewrite @{term "n < Suc m"} to @{term "n = m"}
   444   if @{term "~ n < m"} or @{term "m \<le> n"} hold.
   445   Not suitable as default simprules because they often lead to looping
   446 *}
   447 lemma le_less_Suc_eq: "m \<le> n ==> (n < Suc m) = (n = m)"
   448   by (rule not_less_less_Suc_eq, rule leD)
   449 
   450 lemmas not_less_simps = not_less_less_Suc_eq le_less_Suc_eq
   451 
   452 
   453 text {*
   454   Re-orientation of the equations @{text "0 = x"} and @{text "1 = x"}. 
   455   No longer added as simprules (they loop) 
   456   but via @{text reorient_simproc} in Bin
   457 *}
   458 
   459 text {* Polymorphic, not just for @{typ nat} *}
   460 lemma zero_reorient: "(0 = x) = (x = 0)"
   461   by auto
   462 
   463 lemma one_reorient: "(1 = x) = (x = 1)"
   464   by auto
   465 
   466 subsection {* Arithmetic operators *}
   467 
   468 axclass power < type
   469 
   470 consts
   471   power :: "('a::power) => nat => 'a"            (infixr "^" 80)
   472 
   473 
   474 text {* arithmetic operators @{text "+ -"} and @{text "*"} *}
   475 
   476 instance nat :: "{plus, minus, times, power}" ..
   477 
   478 text {* size of a datatype value; overloaded *}
   479 consts size :: "'a => nat"
   480 
   481 primrec
   482   add_0:    "0 + n = n"
   483   add_Suc:  "Suc m + n = Suc (m + n)"
   484 
   485 primrec
   486   diff_0:   "m - 0 = m"
   487   diff_Suc: "m - Suc n = (case m - n of 0 => 0 | Suc k => k)"
   488 
   489 primrec
   490   mult_0:   "0 * n = 0"
   491   mult_Suc: "Suc m * n = n + (m * n)"
   492 
   493 text {* These two rules ease the use of primitive recursion. 
   494 NOTE USE OF @{text "=="} *}
   495 lemma def_nat_rec_0: "(!!n. f n == nat_rec c h n) ==> f 0 = c"
   496   by simp
   497 
   498 lemma def_nat_rec_Suc: "(!!n. f n == nat_rec c h n) ==> f (Suc n) = h n (f n)"
   499   by simp
   500 
   501 lemma not0_implies_Suc: "n \<noteq> 0 ==> \<exists>m. n = Suc m"
   502   by (case_tac n) simp_all
   503 
   504 lemma gr_implies_not0: "!!n::nat. m<n ==> n \<noteq> 0"
   505   by (case_tac n) simp_all
   506 
   507 lemma neq0_conv [iff]: "!!n::nat. (n \<noteq> 0) = (0 < n)"
   508   by (case_tac n) simp_all
   509 
   510 text {* This theorem is useful with @{text blast} *}
   511 lemma gr0I: "((n::nat) = 0 ==> False) ==> 0 < n"
   512   by (rule iffD1, rule neq0_conv, iprover)
   513 
   514 lemma gr0_conv_Suc: "(0 < n) = (\<exists>m. n = Suc m)"
   515   by (fast intro: not0_implies_Suc)
   516 
   517 lemma not_gr0 [iff]: "!!n::nat. (~ (0 < n)) = (n = 0)"
   518   apply (rule iffI)
   519   apply (rule ccontr, simp_all)
   520   done
   521 
   522 lemma Suc_le_D: "(Suc n \<le> m') ==> (? m. m' = Suc m)"
   523   by (induct m') simp_all
   524 
   525 text {* Useful in certain inductive arguments *}
   526 lemma less_Suc_eq_0_disj: "(m < Suc n) = (m = 0 | (\<exists>j. m = Suc j & j < n))"
   527   by (case_tac m) simp_all
   528 
   529 lemma nat_induct2: "[|P 0; P (Suc 0); !!k. P k ==> P (Suc (Suc k))|] ==> P n"
   530   apply (rule nat_less_induct)
   531   apply (case_tac n)
   532   apply (case_tac [2] nat)
   533   apply (blast intro: less_trans)+
   534   done
   535 
   536 subsection {* @{text LEAST} theorems for type @{typ nat}*}
   537 
   538 lemma Least_Suc:
   539      "[| P n; ~ P 0 |] ==> (LEAST n. P n) = Suc (LEAST m. P(Suc m))"
   540   apply (case_tac "n", auto)
   541   apply (frule LeastI)
   542   apply (drule_tac P = "%x. P (Suc x) " in LeastI)
   543   apply (subgoal_tac " (LEAST x. P x) \<le> Suc (LEAST x. P (Suc x))")
   544   apply (erule_tac [2] Least_le)
   545   apply (case_tac "LEAST x. P x", auto)
   546   apply (drule_tac P = "%x. P (Suc x) " in Least_le)
   547   apply (blast intro: order_antisym)
   548   done
   549 
   550 lemma Least_Suc2:
   551      "[|P n; Q m; ~P 0; !k. P (Suc k) = Q k|] ==> Least P = Suc (Least Q)"
   552   by (erule (1) Least_Suc [THEN ssubst], simp)
   553 
   554 
   555 
   556 subsection {* @{term min} and @{term max} *}
   557 
   558 lemma min_0L [simp]: "min 0 n = (0::nat)"
   559   by (rule min_leastL) simp
   560 
   561 lemma min_0R [simp]: "min n 0 = (0::nat)"
   562   by (rule min_leastR) simp
   563 
   564 lemma min_Suc_Suc [simp]: "min (Suc m) (Suc n) = Suc (min m n)"
   565   by (simp add: min_of_mono)
   566 
   567 lemma max_0L [simp]: "max 0 n = (n::nat)"
   568   by (rule max_leastL) simp
   569 
   570 lemma max_0R [simp]: "max n 0 = (n::nat)"
   571   by (rule max_leastR) simp
   572 
   573 lemma max_Suc_Suc [simp]: "max (Suc m) (Suc n) = Suc(max m n)"
   574   by (simp add: max_of_mono)
   575 
   576 
   577 subsection {* Basic rewrite rules for the arithmetic operators *}
   578 
   579 text {* Difference *}
   580 
   581 lemma diff_0_eq_0 [simp, code]: "0 - n = (0::nat)"
   582   by (induct n) simp_all
   583 
   584 lemma diff_Suc_Suc [simp, code]: "Suc(m) - Suc(n) = m - n"
   585   by (induct n) simp_all
   586 
   587 
   588 text {*
   589   Could be (and is, below) generalized in various ways
   590   However, none of the generalizations are currently in the simpset,
   591   and I dread to think what happens if I put them in
   592 *}
   593 lemma Suc_pred [simp]: "0 < n ==> Suc (n - Suc 0) = n"
   594   by (simp split add: nat.split)
   595 
   596 declare diff_Suc [simp del, code del]
   597 
   598 
   599 subsection {* Addition *}
   600 
   601 lemma add_0_right [simp]: "m + 0 = (m::nat)"
   602   by (induct m) simp_all
   603 
   604 lemma add_Suc_right [simp]: "m + Suc n = Suc (m + n)"
   605   by (induct m) simp_all
   606 
   607 lemma [code]: "Suc m + n = m + Suc n" by simp
   608 
   609 
   610 text {* Associative law for addition *}
   611 lemma nat_add_assoc: "(m + n) + k = m + ((n + k)::nat)"
   612   by (induct m) simp_all
   613 
   614 text {* Commutative law for addition *}
   615 lemma nat_add_commute: "m + n = n + (m::nat)"
   616   by (induct m) simp_all
   617 
   618 lemma nat_add_left_commute: "x + (y + z) = y + ((x + z)::nat)"
   619   apply (rule mk_left_commute [of "op +"])
   620   apply (rule nat_add_assoc)
   621   apply (rule nat_add_commute)
   622   done
   623 
   624 lemma nat_add_left_cancel [simp]: "(k + m = k + n) = (m = (n::nat))"
   625   by (induct k) simp_all
   626 
   627 lemma nat_add_right_cancel [simp]: "(m + k = n + k) = (m=(n::nat))"
   628   by (induct k) simp_all
   629 
   630 lemma nat_add_left_cancel_le [simp]: "(k + m \<le> k + n) = (m\<le>(n::nat))"
   631   by (induct k) simp_all
   632 
   633 lemma nat_add_left_cancel_less [simp]: "(k + m < k + n) = (m<(n::nat))"
   634   by (induct k) simp_all
   635 
   636 text {* Reasoning about @{text "m + 0 = 0"}, etc. *}
   637 
   638 lemma add_is_0 [iff]: "!!m::nat. (m + n = 0) = (m = 0 & n = 0)"
   639   by (case_tac m) simp_all
   640 
   641 lemma add_is_1: "(m+n= Suc 0) = (m= Suc 0 & n=0 | m=0 & n= Suc 0)"
   642   by (case_tac m) simp_all
   643 
   644 lemma one_is_add: "(Suc 0 = m + n) = (m = Suc 0 & n = 0 | m = 0 & n = Suc 0)"
   645   by (rule trans, rule eq_commute, rule add_is_1)
   646 
   647 lemma add_gr_0 [iff]: "!!m::nat. (0 < m + n) = (0 < m | 0 < n)"
   648   by (simp del: neq0_conv add: neq0_conv [symmetric])
   649 
   650 lemma add_eq_self_zero: "!!m::nat. m + n = m ==> n = 0"
   651   apply (drule add_0_right [THEN ssubst])
   652   apply (simp add: nat_add_assoc del: add_0_right)
   653   done
   654 
   655 
   656 lemma inj_on_add_nat[simp]: "inj_on (%n::nat. n+k) N"
   657 apply(induct k)
   658  apply simp
   659 apply(drule comp_inj_on[OF _ inj_Suc])
   660 apply (simp add:o_def)
   661 done
   662 
   663 
   664 subsection {* Multiplication *}
   665 
   666 text {* right annihilation in product *}
   667 lemma mult_0_right [simp]: "(m::nat) * 0 = 0"
   668   by (induct m) simp_all
   669 
   670 text {* right successor law for multiplication *}
   671 lemma mult_Suc_right [simp]: "m * Suc n = m + (m * n)"
   672   by (induct m) (simp_all add: nat_add_left_commute)
   673 
   674 text {* Commutative law for multiplication *}
   675 lemma nat_mult_commute: "m * n = n * (m::nat)"
   676   by (induct m) simp_all
   677 
   678 text {* addition distributes over multiplication *}
   679 lemma add_mult_distrib: "(m + n) * k = (m * k) + ((n * k)::nat)"
   680   by (induct m) (simp_all add: nat_add_assoc nat_add_left_commute)
   681 
   682 lemma add_mult_distrib2: "k * (m + n) = (k * m) + ((k * n)::nat)"
   683   by (induct m) (simp_all add: nat_add_assoc)
   684 
   685 text {* Associative law for multiplication *}
   686 lemma nat_mult_assoc: "(m * n) * k = m * ((n * k)::nat)"
   687   by (induct m) (simp_all add: add_mult_distrib)
   688 
   689 
   690 text{*The naturals form a @{text comm_semiring_1_cancel}*}
   691 instance nat :: comm_semiring_1_cancel
   692 proof
   693   fix i j k :: nat
   694   show "(i + j) + k = i + (j + k)" by (rule nat_add_assoc)
   695   show "i + j = j + i" by (rule nat_add_commute)
   696   show "0 + i = i" by simp
   697   show "(i * j) * k = i * (j * k)" by (rule nat_mult_assoc)
   698   show "i * j = j * i" by (rule nat_mult_commute)
   699   show "1 * i = i" by simp
   700   show "(i + j) * k = i * k + j * k" by (simp add: add_mult_distrib)
   701   show "0 \<noteq> (1::nat)" by simp
   702   assume "k+i = k+j" thus "i=j" by simp
   703 qed
   704 
   705 lemma mult_is_0 [simp]: "((m::nat) * n = 0) = (m=0 | n=0)"
   706   apply (induct m)
   707   apply (induct_tac [2] n, simp_all)
   708   done
   709 
   710 subsection {* Monotonicity of Addition *}
   711 
   712 text {* strict, in 1st argument *}
   713 lemma add_less_mono1: "i < j ==> i + k < j + (k::nat)"
   714   by (induct k) simp_all
   715 
   716 text {* strict, in both arguments *}
   717 lemma add_less_mono: "[|i < j; k < l|] ==> i + k < j + (l::nat)"
   718   apply (rule add_less_mono1 [THEN less_trans], assumption+)
   719   apply (induct j, simp_all)
   720   done
   721 
   722 text {* Deleted @{text less_natE}; use @{text "less_imp_Suc_add RS exE"} *}
   723 lemma less_imp_Suc_add: "m < n ==> (\<exists>k. n = Suc (m + k))"
   724   apply (induct n)
   725   apply (simp_all add: order_le_less)
   726   apply (blast elim!: less_SucE 
   727                intro!: add_0_right [symmetric] add_Suc_right [symmetric])
   728   done
   729 
   730 text {* strict, in 1st argument; proof is by induction on @{text "k > 0"} *}
   731 lemma mult_less_mono2: "(i::nat) < j ==> 0 < k ==> k * i < k * j"
   732   apply (erule_tac m1 = 0 in less_imp_Suc_add [THEN exE], simp)
   733   apply (induct_tac x) 
   734   apply (simp_all add: add_less_mono)
   735   done
   736 
   737 
   738 text{*The naturals form an ordered @{text comm_semiring_1_cancel}*}
   739 instance nat :: ordered_semidom
   740 proof
   741   fix i j k :: nat
   742   show "0 < (1::nat)" by simp
   743   show "i \<le> j ==> k + i \<le> k + j" by simp
   744   show "i < j ==> 0 < k ==> k * i < k * j" by (simp add: mult_less_mono2)
   745 qed
   746 
   747 lemma nat_mult_1: "(1::nat) * n = n"
   748   by simp
   749 
   750 lemma nat_mult_1_right: "n * (1::nat) = n"
   751   by simp
   752 
   753 
   754 subsection {* Additional theorems about "less than" *}
   755 
   756 text {* A [clumsy] way of lifting @{text "<"}
   757   monotonicity to @{text "\<le>"} monotonicity *}
   758 lemma less_mono_imp_le_mono:
   759   assumes lt_mono: "!!i j::nat. i < j ==> f i < f j"
   760   and le: "i \<le> j" shows "f i \<le> ((f j)::nat)" using le
   761   apply (simp add: order_le_less)
   762   apply (blast intro!: lt_mono)
   763   done
   764 
   765 text {* non-strict, in 1st argument *}
   766 lemma add_le_mono1: "i \<le> j ==> i + k \<le> j + (k::nat)"
   767   by (rule add_right_mono)
   768 
   769 text {* non-strict, in both arguments *}
   770 lemma add_le_mono: "[| i \<le> j;  k \<le> l |] ==> i + k \<le> j + (l::nat)"
   771   by (rule add_mono)
   772 
   773 lemma le_add2: "n \<le> ((m + n)::nat)"
   774   by (insert add_right_mono [of 0 m n], simp) 
   775 
   776 lemma le_add1: "n \<le> ((n + m)::nat)"
   777   by (simp add: add_commute, rule le_add2)
   778 
   779 lemma less_add_Suc1: "i < Suc (i + m)"
   780   by (rule le_less_trans, rule le_add1, rule lessI)
   781 
   782 lemma less_add_Suc2: "i < Suc (m + i)"
   783   by (rule le_less_trans, rule le_add2, rule lessI)
   784 
   785 lemma less_iff_Suc_add: "(m < n) = (\<exists>k. n = Suc (m + k))"
   786   by (iprover intro!: less_add_Suc1 less_imp_Suc_add)
   787 
   788 lemma trans_le_add1: "(i::nat) \<le> j ==> i \<le> j + m"
   789   by (rule le_trans, assumption, rule le_add1)
   790 
   791 lemma trans_le_add2: "(i::nat) \<le> j ==> i \<le> m + j"
   792   by (rule le_trans, assumption, rule le_add2)
   793 
   794 lemma trans_less_add1: "(i::nat) < j ==> i < j + m"
   795   by (rule less_le_trans, assumption, rule le_add1)
   796 
   797 lemma trans_less_add2: "(i::nat) < j ==> i < m + j"
   798   by (rule less_le_trans, assumption, rule le_add2)
   799 
   800 lemma add_lessD1: "i + j < (k::nat) ==> i < k"
   801   apply (rule le_less_trans [of _ "i+j"]) 
   802   apply (simp_all add: le_add1)
   803   done
   804 
   805 lemma not_add_less1 [iff]: "~ (i + j < (i::nat))"
   806   apply (rule notI)
   807   apply (erule add_lessD1 [THEN less_irrefl])
   808   done
   809 
   810 lemma not_add_less2 [iff]: "~ (j + i < (i::nat))"
   811   by (simp add: add_commute not_add_less1)
   812 
   813 lemma add_leD1: "m + k \<le> n ==> m \<le> (n::nat)"
   814   apply (rule order_trans [of _ "m+k"]) 
   815   apply (simp_all add: le_add1)
   816   done
   817 
   818 lemma add_leD2: "m + k \<le> n ==> k \<le> (n::nat)"
   819   apply (simp add: add_commute)
   820   apply (erule add_leD1)
   821   done
   822 
   823 lemma add_leE: "(m::nat) + k \<le> n ==> (m \<le> n ==> k \<le> n ==> R) ==> R"
   824   by (blast dest: add_leD1 add_leD2)
   825 
   826 text {* needs @{text "!!k"} for @{text add_ac} to work *}
   827 lemma less_add_eq_less: "!!k::nat. k < l ==> m + l = k + n ==> m < n"
   828   by (force simp del: add_Suc_right
   829     simp add: less_iff_Suc_add add_Suc_right [symmetric] add_ac)
   830 
   831 
   832 
   833 subsection {* Difference *}
   834 
   835 lemma diff_self_eq_0 [simp]: "(m::nat) - m = 0"
   836   by (induct m) simp_all
   837 
   838 text {* Addition is the inverse of subtraction:
   839   if @{term "n \<le> m"} then @{term "n + (m - n) = m"}. *}
   840 lemma add_diff_inverse: "~  m < n ==> n + (m - n) = (m::nat)"
   841   by (induct m n rule: diff_induct) simp_all
   842 
   843 lemma le_add_diff_inverse [simp]: "n \<le> m ==> n + (m - n) = (m::nat)"
   844   by (simp add: add_diff_inverse linorder_not_less)
   845 
   846 lemma le_add_diff_inverse2 [simp]: "n \<le> m ==> (m - n) + n = (m::nat)"
   847   by (simp add: le_add_diff_inverse add_commute)
   848 
   849 
   850 subsection {* More results about difference *}
   851 
   852 lemma Suc_diff_le: "n \<le> m ==> Suc m - n = Suc (m - n)"
   853   by (induct m n rule: diff_induct) simp_all
   854 
   855 lemma diff_less_Suc: "m - n < Suc m"
   856   apply (induct m n rule: diff_induct)
   857   apply (erule_tac [3] less_SucE)
   858   apply (simp_all add: less_Suc_eq)
   859   done
   860 
   861 lemma diff_le_self [simp]: "m - n \<le> (m::nat)"
   862   by (induct m n rule: diff_induct) (simp_all add: le_SucI)
   863 
   864 lemma less_imp_diff_less: "(j::nat) < k ==> j - n < k"
   865   by (rule le_less_trans, rule diff_le_self)
   866 
   867 lemma diff_diff_left: "(i::nat) - j - k = i - (j + k)"
   868   by (induct i j rule: diff_induct) simp_all
   869 
   870 lemma Suc_diff_diff [simp]: "(Suc m - n) - Suc k = m - n - k"
   871   by (simp add: diff_diff_left)
   872 
   873 lemma diff_Suc_less [simp]: "0<n ==> n - Suc i < n"
   874   apply (case_tac "n", safe)
   875   apply (simp add: le_simps)
   876   done
   877 
   878 text {* This and the next few suggested by Florian Kammueller *}
   879 lemma diff_commute: "(i::nat) - j - k = i - k - j"
   880   by (simp add: diff_diff_left add_commute)
   881 
   882 lemma diff_add_assoc: "k \<le> (j::nat) ==> (i + j) - k = i + (j - k)"
   883   by (induct j k rule: diff_induct) simp_all
   884 
   885 lemma diff_add_assoc2: "k \<le> (j::nat) ==> (j + i) - k = (j - k) + i"
   886   by (simp add: add_commute diff_add_assoc)
   887 
   888 lemma diff_add_inverse: "(n + m) - n = (m::nat)"
   889   by (induct n) simp_all
   890 
   891 lemma diff_add_inverse2: "(m + n) - n = (m::nat)"
   892   by (simp add: diff_add_assoc)
   893 
   894 lemma le_imp_diff_is_add: "i \<le> (j::nat) ==> (j - i = k) = (j = k + i)"
   895   apply safe
   896   apply (simp_all add: diff_add_inverse2)
   897   done
   898 
   899 lemma diff_is_0_eq [simp]: "((m::nat) - n = 0) = (m \<le> n)"
   900   by (induct m n rule: diff_induct) simp_all
   901 
   902 lemma diff_is_0_eq' [simp]: "m \<le> n ==> (m::nat) - n = 0"
   903   by (rule iffD2, rule diff_is_0_eq)
   904 
   905 lemma zero_less_diff [simp]: "(0 < n - (m::nat)) = (m < n)"
   906   by (induct m n rule: diff_induct) simp_all
   907 
   908 lemma less_imp_add_positive: "i < j  ==> \<exists>k::nat. 0 < k & i + k = j"
   909   apply (rule_tac x = "j - i" in exI)
   910   apply (simp (no_asm_simp) add: add_diff_inverse less_not_sym)
   911   done
   912 
   913 lemma zero_induct_lemma: "P k ==> (!!n. P (Suc n) ==> P n) ==> P (k - i)"
   914   apply (induct k i rule: diff_induct)
   915   apply (simp_all (no_asm))
   916   apply iprover
   917   done
   918 
   919 lemma zero_induct: "P k ==> (!!n. P (Suc n) ==> P n) ==> P 0"
   920   apply (rule diff_self_eq_0 [THEN subst])
   921   apply (rule zero_induct_lemma, iprover+)
   922   done
   923 
   924 lemma diff_cancel: "(k + m) - (k + n) = m - (n::nat)"
   925   by (induct k) simp_all
   926 
   927 lemma diff_cancel2: "(m + k) - (n + k) = m - (n::nat)"
   928   by (simp add: diff_cancel add_commute)
   929 
   930 lemma diff_add_0: "n - (n + m) = (0::nat)"
   931   by (induct n) simp_all
   932 
   933 
   934 text {* Difference distributes over multiplication *}
   935 
   936 lemma diff_mult_distrib: "((m::nat) - n) * k = (m * k) - (n * k)"
   937   by (induct m n rule: diff_induct) (simp_all add: diff_cancel)
   938 
   939 lemma diff_mult_distrib2: "k * ((m::nat) - n) = (k * m) - (k * n)"
   940   by (simp add: diff_mult_distrib mult_commute [of k])
   941   -- {* NOT added as rewrites, since sometimes they are used from right-to-left *}
   942 
   943 lemmas nat_distrib =
   944   add_mult_distrib add_mult_distrib2 diff_mult_distrib diff_mult_distrib2
   945 
   946 
   947 subsection {* Monotonicity of Multiplication *}
   948 
   949 lemma mult_le_mono1: "i \<le> (j::nat) ==> i * k \<le> j * k"
   950   by (simp add: mult_right_mono) 
   951 
   952 lemma mult_le_mono2: "i \<le> (j::nat) ==> k * i \<le> k * j"
   953   by (simp add: mult_left_mono) 
   954 
   955 text {* @{text "\<le>"} monotonicity, BOTH arguments *}
   956 lemma mult_le_mono: "i \<le> (j::nat) ==> k \<le> l ==> i * k \<le> j * l"
   957   by (simp add: mult_mono) 
   958 
   959 lemma mult_less_mono1: "(i::nat) < j ==> 0 < k ==> i * k < j * k"
   960   by (simp add: mult_strict_right_mono) 
   961 
   962 text{*Differs from the standard @{text zero_less_mult_iff} in that
   963       there are no negative numbers.*}
   964 lemma nat_0_less_mult_iff [simp]: "(0 < (m::nat) * n) = (0 < m & 0 < n)"
   965   apply (induct m)
   966   apply (case_tac [2] n, simp_all)
   967   done
   968 
   969 lemma one_le_mult_iff [simp]: "(Suc 0 \<le> m * n) = (1 \<le> m & 1 \<le> n)"
   970   apply (induct m)
   971   apply (case_tac [2] n, simp_all)
   972   done
   973 
   974 lemma mult_eq_1_iff [simp]: "(m * n = Suc 0) = (m = 1 & n = 1)"
   975   apply (induct m, simp)
   976   apply (induct n, simp, fastsimp)
   977   done
   978 
   979 lemma one_eq_mult_iff [simp]: "(Suc 0 = m * n) = (m = 1 & n = 1)"
   980   apply (rule trans)
   981   apply (rule_tac [2] mult_eq_1_iff, fastsimp)
   982   done
   983 
   984 lemma mult_less_cancel2 [simp]: "((m::nat) * k < n * k) = (0 < k & m < n)"
   985   apply (safe intro!: mult_less_mono1)
   986   apply (case_tac k, auto)
   987   apply (simp del: le_0_eq add: linorder_not_le [symmetric])
   988   apply (blast intro: mult_le_mono1)
   989   done
   990 
   991 lemma mult_less_cancel1 [simp]: "(k * (m::nat) < k * n) = (0 < k & m < n)"
   992   by (simp add: mult_commute [of k])
   993 
   994 lemma mult_le_cancel1 [simp]: "(k * (m::nat) \<le> k * n) = (0 < k --> m \<le> n)"
   995 by (simp add: linorder_not_less [symmetric], auto)
   996 
   997 lemma mult_le_cancel2 [simp]: "((m::nat) * k \<le> n * k) = (0 < k --> m \<le> n)"
   998 by (simp add: linorder_not_less [symmetric], auto)
   999 
  1000 lemma mult_cancel2 [simp]: "(m * k = n * k) = (m = n | (k = (0::nat)))"
  1001   apply (cut_tac less_linear, safe, auto)
  1002   apply (drule mult_less_mono1, assumption, simp)+
  1003   done
  1004 
  1005 lemma mult_cancel1 [simp]: "(k * m = k * n) = (m = n | (k = (0::nat)))"
  1006   by (simp add: mult_commute [of k])
  1007 
  1008 lemma Suc_mult_less_cancel1: "(Suc k * m < Suc k * n) = (m < n)"
  1009   by (subst mult_less_cancel1) simp
  1010 
  1011 lemma Suc_mult_le_cancel1: "(Suc k * m \<le> Suc k * n) = (m \<le> n)"
  1012   by (subst mult_le_cancel1) simp
  1013 
  1014 lemma Suc_mult_cancel1: "(Suc k * m = Suc k * n) = (m = n)"
  1015   by (subst mult_cancel1) simp
  1016 
  1017 text {* Lemma for @{text gcd} *}
  1018 lemma mult_eq_self_implies_10: "(m::nat) = m * n ==> n = 1 | m = 0"
  1019   apply (drule sym)
  1020   apply (rule disjCI)
  1021   apply (rule nat_less_cases, erule_tac [2] _)
  1022   apply (fastsimp elim!: less_SucE)
  1023   apply (fastsimp dest: mult_less_mono2)
  1024   done
  1025 
  1026 subsection {* Code generator setup *}
  1027 
  1028 code_alias
  1029   "nat" "Nat.nat"
  1030   "0" "Nat.Zero"
  1031   "1" "Nat.One"
  1032   "Suc" "Nat.Suc"
  1033 
  1034 end