src/HOL/Set.thy
author paulson
Thu Jan 01 21:47:07 2004 +0100 (2004-01-01)
changeset 14335 9c0b5e081037
parent 14302 6c24235e8d5d
child 14381 1189a8212a12
permissions -rw-r--r--
conversion of Real/PReal to Isar script;
type "complex" is now in class "field"
     1 (*  Title:      HOL/Set.thy
     2     ID:         $Id$
     3     Author:     Tobias Nipkow, Lawrence C Paulson and Markus Wenzel
     4     License:    GPL (GNU GENERAL PUBLIC LICENSE)
     5 *)
     6 
     7 header {* Set theory for higher-order logic *}
     8 
     9 theory Set = HOL:
    10 
    11 text {* A set in HOL is simply a predicate. *}
    12 
    13 
    14 subsection {* Basic syntax *}
    15 
    16 global
    17 
    18 typedecl 'a set
    19 arities set :: (type) type
    20 
    21 consts
    22   "{}"          :: "'a set"                             ("{}")
    23   UNIV          :: "'a set"
    24   insert        :: "'a => 'a set => 'a set"
    25   Collect       :: "('a => bool) => 'a set"              -- "comprehension"
    26   Int           :: "'a set => 'a set => 'a set"          (infixl 70)
    27   Un            :: "'a set => 'a set => 'a set"          (infixl 65)
    28   UNION         :: "'a set => ('a => 'b set) => 'b set"  -- "general union"
    29   INTER         :: "'a set => ('a => 'b set) => 'b set"  -- "general intersection"
    30   Union         :: "'a set set => 'a set"                -- "union of a set"
    31   Inter         :: "'a set set => 'a set"                -- "intersection of a set"
    32   Pow           :: "'a set => 'a set set"                -- "powerset"
    33   Ball          :: "'a set => ('a => bool) => bool"      -- "bounded universal quantifiers"
    34   Bex           :: "'a set => ('a => bool) => bool"      -- "bounded existential quantifiers"
    35   image         :: "('a => 'b) => 'a set => 'b set"      (infixr "`" 90)
    36 
    37 syntax
    38   "op :"        :: "'a => 'a set => bool"                ("op :")
    39 consts
    40   "op :"        :: "'a => 'a set => bool"                ("(_/ : _)" [50, 51] 50)  -- "membership"
    41 
    42 local
    43 
    44 instance set :: (type) ord ..
    45 instance set :: (type) minus ..
    46 
    47 
    48 subsection {* Additional concrete syntax *}
    49 
    50 syntax
    51   range         :: "('a => 'b) => 'b set"             -- "of function"
    52 
    53   "op ~:"       :: "'a => 'a set => bool"                 ("op ~:")  -- "non-membership"
    54   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ ~: _)" [50, 51] 50)
    55 
    56   "@Finset"     :: "args => 'a set"                       ("{(_)}")
    57   "@Coll"       :: "pttrn => bool => 'a set"              ("(1{_./ _})")
    58   "@SetCompr"   :: "'a => idts => bool => 'a set"         ("(1{_ |/_./ _})")
    59 
    60   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3INT _./ _)" 10)
    61   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3UN _./ _)" 10)
    62   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3INT _:_./ _)" 10)
    63   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3UN _:_./ _)" 10)
    64 
    65   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3ALL _:_./ _)" [0, 0, 10] 10)
    66   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3EX _:_./ _)" [0, 0, 10] 10)
    67 
    68 syntax (HOL)
    69   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3! _:_./ _)" [0, 0, 10] 10)
    70   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3? _:_./ _)" [0, 0, 10] 10)
    71 
    72 translations
    73   "range f"     == "f`UNIV"
    74   "x ~: y"      == "~ (x : y)"
    75   "{x, xs}"     == "insert x {xs}"
    76   "{x}"         == "insert x {}"
    77   "{x. P}"      == "Collect (%x. P)"
    78   "UN x y. B"   == "UN x. UN y. B"
    79   "UN x. B"     == "UNION UNIV (%x. B)"
    80   "UN x. B"     == "UN x:UNIV. B"
    81   "INT x y. B"  == "INT x. INT y. B"
    82   "INT x. B"    == "INTER UNIV (%x. B)"
    83   "INT x. B"    == "INT x:UNIV. B"
    84   "UN x:A. B"   == "UNION A (%x. B)"
    85   "INT x:A. B"  == "INTER A (%x. B)"
    86   "ALL x:A. P"  == "Ball A (%x. P)"
    87   "EX x:A. P"   == "Bex A (%x. P)"
    88 
    89 syntax (output)
    90   "_setle"      :: "'a set => 'a set => bool"             ("op <=")
    91   "_setle"      :: "'a set => 'a set => bool"             ("(_/ <= _)" [50, 51] 50)
    92   "_setless"    :: "'a set => 'a set => bool"             ("op <")
    93   "_setless"    :: "'a set => 'a set => bool"             ("(_/ < _)" [50, 51] 50)
    94 
    95 syntax (xsymbols)
    96   "_setle"      :: "'a set => 'a set => bool"             ("op \<subseteq>")
    97   "_setle"      :: "'a set => 'a set => bool"             ("(_/ \<subseteq> _)" [50, 51] 50)
    98   "_setless"    :: "'a set => 'a set => bool"             ("op \<subset>")
    99   "_setless"    :: "'a set => 'a set => bool"             ("(_/ \<subset> _)" [50, 51] 50)
   100   "op Int"      :: "'a set => 'a set => 'a set"           (infixl "\<inter>" 70)
   101   "op Un"       :: "'a set => 'a set => 'a set"           (infixl "\<union>" 65)
   102   "op :"        :: "'a => 'a set => bool"                 ("op \<in>")
   103   "op :"        :: "'a => 'a set => bool"                 ("(_/ \<in> _)" [50, 51] 50)
   104   "op ~:"       :: "'a => 'a set => bool"                 ("op \<notin>")
   105   "op ~:"       :: "'a => 'a set => bool"                 ("(_/ \<notin> _)" [50, 51] 50)
   106   "@UNION1"     :: "pttrns => 'b set => 'b set"           ("(3\<Union>_./ _)" 10)
   107   "@INTER1"     :: "pttrns => 'b set => 'b set"           ("(3\<Inter>_./ _)" 10)
   108   "@UNION"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Union>_\<in>_./ _)" 10)
   109   "@INTER"      :: "pttrn => 'a set => 'b set => 'b set"  ("(3\<Inter>_\<in>_./ _)" 10)
   110   Union         :: "'a set set => 'a set"                 ("\<Union>_" [90] 90)
   111   Inter         :: "'a set set => 'a set"                 ("\<Inter>_" [90] 90)
   112   "_Ball"       :: "pttrn => 'a set => bool => bool"      ("(3\<forall>_\<in>_./ _)" [0, 0, 10] 10)
   113   "_Bex"        :: "pttrn => 'a set => bool => bool"      ("(3\<exists>_\<in>_./ _)" [0, 0, 10] 10)
   114 
   115 translations
   116   "op \<subseteq>" => "op <= :: _ set => _ set => bool"
   117   "op \<subset>" => "op <  :: _ set => _ set => bool"
   118 
   119 
   120 typed_print_translation {*
   121   let
   122     fun le_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   123           list_comb (Syntax.const "_setle", ts)
   124       | le_tr' _ _ _ = raise Match;
   125 
   126     fun less_tr' _ (Type ("fun", (Type ("set", _) :: _))) ts =
   127           list_comb (Syntax.const "_setless", ts)
   128       | less_tr' _ _ _ = raise Match;
   129   in [("op <=", le_tr'), ("op <", less_tr')] end
   130 *}
   131 
   132 text {*
   133   \medskip Translate between @{text "{e | x1...xn. P}"} and @{text
   134   "{u. EX x1..xn. u = e & P}"}; @{text "{y. EX x1..xn. y = e & P}"} is
   135   only translated if @{text "[0..n] subset bvs(e)"}.
   136 *}
   137 
   138 parse_translation {*
   139   let
   140     val ex_tr = snd (mk_binder_tr ("EX ", "Ex"));
   141 
   142     fun nvars (Const ("_idts", _) $ _ $ idts) = nvars idts + 1
   143       | nvars _ = 1;
   144 
   145     fun setcompr_tr [e, idts, b] =
   146       let
   147         val eq = Syntax.const "op =" $ Bound (nvars idts) $ e;
   148         val P = Syntax.const "op &" $ eq $ b;
   149         val exP = ex_tr [idts, P];
   150       in Syntax.const "Collect" $ Abs ("", dummyT, exP) end;
   151 
   152   in [("@SetCompr", setcompr_tr)] end;
   153 *}
   154 
   155 (* To avoid eta-contraction of body: *)
   156 print_translation {*
   157 let
   158   fun btr' syn [A,Abs abs] =
   159     let val (x,t) = atomic_abs_tr' abs
   160     in Syntax.const syn $ x $ A $ t end
   161 in
   162 [("Ball", btr' "_Ball"),("Bex", btr' "_Bex"),
   163  ("UNION", btr' "@UNION"),("INTER", btr' "@INTER")]
   164 end
   165 *}
   166 
   167 print_translation {*
   168 let
   169   val ex_tr' = snd (mk_binder_tr' ("Ex", "DUMMY"));
   170 
   171   fun setcompr_tr' [Abs (abs as (_, _, P))] =
   172     let
   173       fun check (Const ("Ex", _) $ Abs (_, _, P), n) = check (P, n + 1)
   174         | check (Const ("op &", _) $ (Const ("op =", _) $ Bound m $ e) $ P, n) =
   175             n > 0 andalso m = n andalso not (loose_bvar1 (P, n)) andalso
   176             ((0 upto (n - 1)) subset add_loose_bnos (e, 0, []))
   177         | check _ = false
   178 
   179         fun tr' (_ $ abs) =
   180           let val _ $ idts $ (_ $ (_ $ _ $ e) $ Q) = ex_tr' [abs]
   181           in Syntax.const "@SetCompr" $ e $ idts $ Q end;
   182     in if check (P, 0) then tr' P
   183        else let val (x,t) = atomic_abs_tr' abs
   184             in Syntax.const "@Coll" $ x $ t end
   185     end;
   186   in [("Collect", setcompr_tr')] end;
   187 *}
   188 
   189 
   190 subsection {* Rules and definitions *}
   191 
   192 text {* Isomorphisms between predicates and sets. *}
   193 
   194 axioms
   195   mem_Collect_eq [iff]: "(a : {x. P(x)}) = P(a)"
   196   Collect_mem_eq [simp]: "{x. x:A} = A"
   197 
   198 defs
   199   Ball_def:     "Ball A P       == ALL x. x:A --> P(x)"
   200   Bex_def:      "Bex A P        == EX x. x:A & P(x)"
   201 
   202 defs (overloaded)
   203   subset_def:   "A <= B         == ALL x:A. x:B"
   204   psubset_def:  "A < B          == (A::'a set) <= B & ~ A=B"
   205   Compl_def:    "- A            == {x. ~x:A}"
   206   set_diff_def: "A - B          == {x. x:A & ~x:B}"
   207 
   208 defs
   209   Un_def:       "A Un B         == {x. x:A | x:B}"
   210   Int_def:      "A Int B        == {x. x:A & x:B}"
   211   INTER_def:    "INTER A B      == {y. ALL x:A. y: B(x)}"
   212   UNION_def:    "UNION A B      == {y. EX x:A. y: B(x)}"
   213   Inter_def:    "Inter S        == (INT x:S. x)"
   214   Union_def:    "Union S        == (UN x:S. x)"
   215   Pow_def:      "Pow A          == {B. B <= A}"
   216   empty_def:    "{}             == {x. False}"
   217   UNIV_def:     "UNIV           == {x. True}"
   218   insert_def:   "insert a B     == {x. x=a} Un B"
   219   image_def:    "f`A            == {y. EX x:A. y = f(x)}"
   220 
   221 
   222 subsection {* Lemmas and proof tool setup *}
   223 
   224 subsubsection {* Relating predicates and sets *}
   225 
   226 lemma CollectI: "P(a) ==> a : {x. P(x)}"
   227   by simp
   228 
   229 lemma CollectD: "a : {x. P(x)} ==> P(a)"
   230   by simp
   231 
   232 lemma Collect_cong: "(!!x. P x = Q x) ==> {x. P(x)} = {x. Q(x)}"
   233   by simp
   234 
   235 lemmas CollectE = CollectD [elim_format]
   236 
   237 
   238 subsubsection {* Bounded quantifiers *}
   239 
   240 lemma ballI [intro!]: "(!!x. x:A ==> P x) ==> ALL x:A. P x"
   241   by (simp add: Ball_def)
   242 
   243 lemmas strip = impI allI ballI
   244 
   245 lemma bspec [dest?]: "ALL x:A. P x ==> x:A ==> P x"
   246   by (simp add: Ball_def)
   247 
   248 lemma ballE [elim]: "ALL x:A. P x ==> (P x ==> Q) ==> (x ~: A ==> Q) ==> Q"
   249   by (unfold Ball_def) blast
   250 ML {* bind_thm("rev_ballE",permute_prems 1 1 (thm "ballE")) *}
   251 
   252 text {*
   253   \medskip This tactic takes assumptions @{prop "ALL x:A. P x"} and
   254   @{prop "a:A"}; creates assumption @{prop "P a"}.
   255 *}
   256 
   257 ML {*
   258   local val ballE = thm "ballE"
   259   in fun ball_tac i = etac ballE i THEN contr_tac (i + 1) end;
   260 *}
   261 
   262 text {*
   263   Gives better instantiation for bound:
   264 *}
   265 
   266 ML_setup {*
   267   claset_ref() := claset() addbefore ("bspec", datac (thm "bspec") 1);
   268 *}
   269 
   270 lemma bexI [intro]: "P x ==> x:A ==> EX x:A. P x"
   271   -- {* Normally the best argument order: @{prop "P x"} constrains the
   272     choice of @{prop "x:A"}. *}
   273   by (unfold Bex_def) blast
   274 
   275 lemma rev_bexI [intro?]: "x:A ==> P x ==> EX x:A. P x"
   276   -- {* The best argument order when there is only one @{prop "x:A"}. *}
   277   by (unfold Bex_def) blast
   278 
   279 lemma bexCI: "(ALL x:A. ~P x ==> P a) ==> a:A ==> EX x:A. P x"
   280   by (unfold Bex_def) blast
   281 
   282 lemma bexE [elim!]: "EX x:A. P x ==> (!!x. x:A ==> P x ==> Q) ==> Q"
   283   by (unfold Bex_def) blast
   284 
   285 lemma ball_triv [simp]: "(ALL x:A. P) = ((EX x. x:A) --> P)"
   286   -- {* Trival rewrite rule. *}
   287   by (simp add: Ball_def)
   288 
   289 lemma bex_triv [simp]: "(EX x:A. P) = ((EX x. x:A) & P)"
   290   -- {* Dual form for existentials. *}
   291   by (simp add: Bex_def)
   292 
   293 lemma bex_triv_one_point1 [simp]: "(EX x:A. x = a) = (a:A)"
   294   by blast
   295 
   296 lemma bex_triv_one_point2 [simp]: "(EX x:A. a = x) = (a:A)"
   297   by blast
   298 
   299 lemma bex_one_point1 [simp]: "(EX x:A. x = a & P x) = (a:A & P a)"
   300   by blast
   301 
   302 lemma bex_one_point2 [simp]: "(EX x:A. a = x & P x) = (a:A & P a)"
   303   by blast
   304 
   305 lemma ball_one_point1 [simp]: "(ALL x:A. x = a --> P x) = (a:A --> P a)"
   306   by blast
   307 
   308 lemma ball_one_point2 [simp]: "(ALL x:A. a = x --> P x) = (a:A --> P a)"
   309   by blast
   310 
   311 ML_setup {*
   312   local
   313     val Ball_def = thm "Ball_def";
   314     val Bex_def = thm "Bex_def";
   315 
   316     val prove_bex_tac =
   317       rewrite_goals_tac [Bex_def] THEN Quantifier1.prove_one_point_ex_tac;
   318     val rearrange_bex = Quantifier1.rearrange_bex prove_bex_tac;
   319 
   320     val prove_ball_tac =
   321       rewrite_goals_tac [Ball_def] THEN Quantifier1.prove_one_point_all_tac;
   322     val rearrange_ball = Quantifier1.rearrange_ball prove_ball_tac;
   323   in
   324     val defBEX_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   325       "defined BEX" ["EX x:A. P x & Q x"] rearrange_bex;
   326     val defBALL_regroup = Simplifier.simproc (Theory.sign_of (the_context ()))
   327       "defined BALL" ["ALL x:A. P x --> Q x"] rearrange_ball;
   328   end;
   329 
   330   Addsimprocs [defBALL_regroup, defBEX_regroup];
   331 *}
   332 
   333 
   334 subsubsection {* Congruence rules *}
   335 
   336 lemma ball_cong [cong]:
   337   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   338     (ALL x:A. P x) = (ALL x:B. Q x)"
   339   by (simp add: Ball_def)
   340 
   341 lemma bex_cong [cong]:
   342   "A = B ==> (!!x. x:B ==> P x = Q x) ==>
   343     (EX x:A. P x) = (EX x:B. Q x)"
   344   by (simp add: Bex_def cong: conj_cong)
   345 
   346 
   347 subsubsection {* Subsets *}
   348 
   349 lemma subsetI [intro!]: "(!!x. x:A ==> x:B) ==> A \<subseteq> B"
   350   by (simp add: subset_def)
   351 
   352 text {*
   353   \medskip Map the type @{text "'a set => anything"} to just @{typ
   354   'a}; for overloading constants whose first argument has type @{typ
   355   "'a set"}.
   356 *}
   357 
   358 lemma subsetD [elim]: "A \<subseteq> B ==> c \<in> A ==> c \<in> B"
   359   -- {* Rule in Modus Ponens style. *}
   360   by (unfold subset_def) blast
   361 
   362 declare subsetD [intro?] -- FIXME
   363 
   364 lemma rev_subsetD: "c \<in> A ==> A \<subseteq> B ==> c \<in> B"
   365   -- {* The same, with reversed premises for use with @{text erule} --
   366       cf @{text rev_mp}. *}
   367   by (rule subsetD)
   368 
   369 declare rev_subsetD [intro?] -- FIXME
   370 
   371 text {*
   372   \medskip Converts @{prop "A \<subseteq> B"} to @{prop "x \<in> A ==> x \<in> B"}.
   373 *}
   374 
   375 ML {*
   376   local val rev_subsetD = thm "rev_subsetD"
   377   in fun impOfSubs th = th RSN (2, rev_subsetD) end;
   378 *}
   379 
   380 lemma subsetCE [elim]: "A \<subseteq>  B ==> (c \<notin> A ==> P) ==> (c \<in> B ==> P) ==> P"
   381   -- {* Classical elimination rule. *}
   382   by (unfold subset_def) blast
   383 
   384 text {*
   385   \medskip Takes assumptions @{prop "A \<subseteq> B"}; @{prop "c \<in> A"} and
   386   creates the assumption @{prop "c \<in> B"}.
   387 *}
   388 
   389 ML {*
   390   local val subsetCE = thm "subsetCE"
   391   in fun set_mp_tac i = etac subsetCE i THEN mp_tac i end;
   392 *}
   393 
   394 lemma contra_subsetD: "A \<subseteq> B ==> c \<notin> B ==> c \<notin> A"
   395   by blast
   396 
   397 lemma subset_refl: "A \<subseteq> A"
   398   by fast
   399 
   400 lemma subset_trans: "A \<subseteq> B ==> B \<subseteq> C ==> A \<subseteq> C"
   401   by blast
   402 
   403 
   404 subsubsection {* Equality *}
   405 
   406 lemma set_ext: assumes prem: "(!!x. (x:A) = (x:B))" shows "A = B"
   407   apply (rule prem [THEN ext, THEN arg_cong, THEN box_equals])
   408    apply (rule Collect_mem_eq)
   409   apply (rule Collect_mem_eq)
   410   done
   411 
   412 lemma subset_antisym [intro!]: "A \<subseteq> B ==> B \<subseteq> A ==> A = B"
   413   -- {* Anti-symmetry of the subset relation. *}
   414   by (rules intro: set_ext subsetD)
   415 
   416 lemmas equalityI [intro!] = subset_antisym
   417 
   418 text {*
   419   \medskip Equality rules from ZF set theory -- are they appropriate
   420   here?
   421 *}
   422 
   423 lemma equalityD1: "A = B ==> A \<subseteq> B"
   424   by (simp add: subset_refl)
   425 
   426 lemma equalityD2: "A = B ==> B \<subseteq> A"
   427   by (simp add: subset_refl)
   428 
   429 text {*
   430   \medskip Be careful when adding this to the claset as @{text
   431   subset_empty} is in the simpset: @{prop "A = {}"} goes to @{prop "{}
   432   \<subseteq> A"} and @{prop "A \<subseteq> {}"} and then back to @{prop "A = {}"}!
   433 *}
   434 
   435 lemma equalityE: "A = B ==> (A \<subseteq> B ==> B \<subseteq> A ==> P) ==> P"
   436   by (simp add: subset_refl)
   437 
   438 lemma equalityCE [elim]:
   439     "A = B ==> (c \<in> A ==> c \<in> B ==> P) ==> (c \<notin> A ==> c \<notin> B ==> P) ==> P"
   440   by blast
   441 
   442 text {*
   443   \medskip Lemma for creating induction formulae -- for "pattern
   444   matching" on @{text p}.  To make the induction hypotheses usable,
   445   apply @{text spec} or @{text bspec} to put universal quantifiers over the free
   446   variables in @{text p}.
   447 *}
   448 
   449 lemma setup_induction: "p:A ==> (!!z. z:A ==> p = z --> R) ==> R"
   450   by simp
   451 
   452 lemma eqset_imp_iff: "A = B ==> (x : A) = (x : B)"
   453   by simp
   454 
   455 lemma eqelem_imp_iff: "x = y ==> (x : A) = (y : A)"
   456   by simp
   457 
   458 
   459 subsubsection {* The universal set -- UNIV *}
   460 
   461 lemma UNIV_I [simp]: "x : UNIV"
   462   by (simp add: UNIV_def)
   463 
   464 declare UNIV_I [intro]  -- {* unsafe makes it less likely to cause problems *}
   465 
   466 lemma UNIV_witness [intro?]: "EX x. x : UNIV"
   467   by simp
   468 
   469 lemma subset_UNIV: "A \<subseteq> UNIV"
   470   by (rule subsetI) (rule UNIV_I)
   471 
   472 text {*
   473   \medskip Eta-contracting these two rules (to remove @{text P})
   474   causes them to be ignored because of their interaction with
   475   congruence rules.
   476 *}
   477 
   478 lemma ball_UNIV [simp]: "Ball UNIV P = All P"
   479   by (simp add: Ball_def)
   480 
   481 lemma bex_UNIV [simp]: "Bex UNIV P = Ex P"
   482   by (simp add: Bex_def)
   483 
   484 
   485 subsubsection {* The empty set *}
   486 
   487 lemma empty_iff [simp]: "(c : {}) = False"
   488   by (simp add: empty_def)
   489 
   490 lemma emptyE [elim!]: "a : {} ==> P"
   491   by simp
   492 
   493 lemma empty_subsetI [iff]: "{} \<subseteq> A"
   494     -- {* One effect is to delete the ASSUMPTION @{prop "{} <= A"} *}
   495   by blast
   496 
   497 lemma equals0I: "(!!y. y \<in> A ==> False) ==> A = {}"
   498   by blast
   499 
   500 lemma equals0D: "A = {} ==> a \<notin> A"
   501     -- {* Use for reasoning about disjointness: @{prop "A Int B = {}"} *}
   502   by blast
   503 
   504 lemma ball_empty [simp]: "Ball {} P = True"
   505   by (simp add: Ball_def)
   506 
   507 lemma bex_empty [simp]: "Bex {} P = False"
   508   by (simp add: Bex_def)
   509 
   510 lemma UNIV_not_empty [iff]: "UNIV ~= {}"
   511   by (blast elim: equalityE)
   512 
   513 
   514 subsubsection {* The Powerset operator -- Pow *}
   515 
   516 lemma Pow_iff [iff]: "(A \<in> Pow B) = (A \<subseteq> B)"
   517   by (simp add: Pow_def)
   518 
   519 lemma PowI: "A \<subseteq> B ==> A \<in> Pow B"
   520   by (simp add: Pow_def)
   521 
   522 lemma PowD: "A \<in> Pow B ==> A \<subseteq> B"
   523   by (simp add: Pow_def)
   524 
   525 lemma Pow_bottom: "{} \<in> Pow B"
   526   by simp
   527 
   528 lemma Pow_top: "A \<in> Pow A"
   529   by (simp add: subset_refl)
   530 
   531 
   532 subsubsection {* Set complement *}
   533 
   534 lemma Compl_iff [simp]: "(c \<in> -A) = (c \<notin> A)"
   535   by (unfold Compl_def) blast
   536 
   537 lemma ComplI [intro!]: "(c \<in> A ==> False) ==> c \<in> -A"
   538   by (unfold Compl_def) blast
   539 
   540 text {*
   541   \medskip This form, with negated conclusion, works well with the
   542   Classical prover.  Negated assumptions behave like formulae on the
   543   right side of the notional turnstile ... *}
   544 
   545 lemma ComplD: "c : -A ==> c~:A"
   546   by (unfold Compl_def) blast
   547 
   548 lemmas ComplE [elim!] = ComplD [elim_format]
   549 
   550 
   551 subsubsection {* Binary union -- Un *}
   552 
   553 lemma Un_iff [simp]: "(c : A Un B) = (c:A | c:B)"
   554   by (unfold Un_def) blast
   555 
   556 lemma UnI1 [elim?]: "c:A ==> c : A Un B"
   557   by simp
   558 
   559 lemma UnI2 [elim?]: "c:B ==> c : A Un B"
   560   by simp
   561 
   562 text {*
   563   \medskip Classical introduction rule: no commitment to @{prop A} vs
   564   @{prop B}.
   565 *}
   566 
   567 lemma UnCI [intro!]: "(c~:B ==> c:A) ==> c : A Un B"
   568   by auto
   569 
   570 lemma UnE [elim!]: "c : A Un B ==> (c:A ==> P) ==> (c:B ==> P) ==> P"
   571   by (unfold Un_def) blast
   572 
   573 
   574 subsubsection {* Binary intersection -- Int *}
   575 
   576 lemma Int_iff [simp]: "(c : A Int B) = (c:A & c:B)"
   577   by (unfold Int_def) blast
   578 
   579 lemma IntI [intro!]: "c:A ==> c:B ==> c : A Int B"
   580   by simp
   581 
   582 lemma IntD1: "c : A Int B ==> c:A"
   583   by simp
   584 
   585 lemma IntD2: "c : A Int B ==> c:B"
   586   by simp
   587 
   588 lemma IntE [elim!]: "c : A Int B ==> (c:A ==> c:B ==> P) ==> P"
   589   by simp
   590 
   591 
   592 subsubsection {* Set difference *}
   593 
   594 lemma Diff_iff [simp]: "(c : A - B) = (c:A & c~:B)"
   595   by (unfold set_diff_def) blast
   596 
   597 lemma DiffI [intro!]: "c : A ==> c ~: B ==> c : A - B"
   598   by simp
   599 
   600 lemma DiffD1: "c : A - B ==> c : A"
   601   by simp
   602 
   603 lemma DiffD2: "c : A - B ==> c : B ==> P"
   604   by simp
   605 
   606 lemma DiffE [elim!]: "c : A - B ==> (c:A ==> c~:B ==> P) ==> P"
   607   by simp
   608 
   609 
   610 subsubsection {* Augmenting a set -- insert *}
   611 
   612 lemma insert_iff [simp]: "(a : insert b A) = (a = b | a:A)"
   613   by (unfold insert_def) blast
   614 
   615 lemma insertI1: "a : insert a B"
   616   by simp
   617 
   618 lemma insertI2: "a : B ==> a : insert b B"
   619   by simp
   620 
   621 lemma insertE [elim!]: "a : insert b A ==> (a = b ==> P) ==> (a:A ==> P) ==> P"
   622   by (unfold insert_def) blast
   623 
   624 lemma insertCI [intro!]: "(a~:B ==> a = b) ==> a: insert b B"
   625   -- {* Classical introduction rule. *}
   626   by auto
   627 
   628 lemma subset_insert_iff: "(A \<subseteq> insert x B) = (if x:A then A - {x} \<subseteq> B else A \<subseteq> B)"
   629   by auto
   630 
   631 
   632 subsubsection {* Singletons, using insert *}
   633 
   634 lemma singletonI [intro!]: "a : {a}"
   635     -- {* Redundant? But unlike @{text insertCI}, it proves the subgoal immediately! *}
   636   by (rule insertI1)
   637 
   638 lemma singletonD: "b : {a} ==> b = a"
   639   by blast
   640 
   641 lemmas singletonE [elim!] = singletonD [elim_format]
   642 
   643 lemma singleton_iff: "(b : {a}) = (b = a)"
   644   by blast
   645 
   646 lemma singleton_inject [dest!]: "{a} = {b} ==> a = b"
   647   by blast
   648 
   649 lemma singleton_insert_inj_eq [iff]: "({b} = insert a A) = (a = b & A \<subseteq> {b})"
   650   by blast
   651 
   652 lemma singleton_insert_inj_eq' [iff]: "(insert a A = {b}) = (a = b & A \<subseteq> {b})"
   653   by blast
   654 
   655 lemma subset_singletonD: "A \<subseteq> {x} ==> A = {} | A = {x}"
   656   by fast
   657 
   658 lemma singleton_conv [simp]: "{x. x = a} = {a}"
   659   by blast
   660 
   661 lemma singleton_conv2 [simp]: "{x. a = x} = {a}"
   662   by blast
   663 
   664 lemma diff_single_insert: "A - {x} \<subseteq> B ==> x \<in> A ==> A \<subseteq> insert x B"
   665   by blast
   666 
   667 
   668 subsubsection {* Unions of families *}
   669 
   670 text {*
   671   @{term [source] "UN x:A. B x"} is @{term "Union (B`A)"}.
   672 *}
   673 
   674 lemma UN_iff [simp]: "(b: (UN x:A. B x)) = (EX x:A. b: B x)"
   675   by (unfold UNION_def) blast
   676 
   677 lemma UN_I [intro]: "a:A ==> b: B a ==> b: (UN x:A. B x)"
   678   -- {* The order of the premises presupposes that @{term A} is rigid;
   679     @{term b} may be flexible. *}
   680   by auto
   681 
   682 lemma UN_E [elim!]: "b : (UN x:A. B x) ==> (!!x. x:A ==> b: B x ==> R) ==> R"
   683   by (unfold UNION_def) blast
   684 
   685 lemma UN_cong [cong]:
   686     "A = B ==> (!!x. x:B ==> C x = D x) ==> (UN x:A. C x) = (UN x:B. D x)"
   687   by (simp add: UNION_def)
   688 
   689 
   690 subsubsection {* Intersections of families *}
   691 
   692 text {* @{term [source] "INT x:A. B x"} is @{term "Inter (B`A)"}. *}
   693 
   694 lemma INT_iff [simp]: "(b: (INT x:A. B x)) = (ALL x:A. b: B x)"
   695   by (unfold INTER_def) blast
   696 
   697 lemma INT_I [intro!]: "(!!x. x:A ==> b: B x) ==> b : (INT x:A. B x)"
   698   by (unfold INTER_def) blast
   699 
   700 lemma INT_D [elim]: "b : (INT x:A. B x) ==> a:A ==> b: B a"
   701   by auto
   702 
   703 lemma INT_E [elim]: "b : (INT x:A. B x) ==> (b: B a ==> R) ==> (a~:A ==> R) ==> R"
   704   -- {* "Classical" elimination -- by the Excluded Middle on @{prop "a:A"}. *}
   705   by (unfold INTER_def) blast
   706 
   707 lemma INT_cong [cong]:
   708     "A = B ==> (!!x. x:B ==> C x = D x) ==> (INT x:A. C x) = (INT x:B. D x)"
   709   by (simp add: INTER_def)
   710 
   711 
   712 subsubsection {* Union *}
   713 
   714 lemma Union_iff [simp]: "(A : Union C) = (EX X:C. A:X)"
   715   by (unfold Union_def) blast
   716 
   717 lemma UnionI [intro]: "X:C ==> A:X ==> A : Union C"
   718   -- {* The order of the premises presupposes that @{term C} is rigid;
   719     @{term A} may be flexible. *}
   720   by auto
   721 
   722 lemma UnionE [elim!]: "A : Union C ==> (!!X. A:X ==> X:C ==> R) ==> R"
   723   by (unfold Union_def) blast
   724 
   725 
   726 subsubsection {* Inter *}
   727 
   728 lemma Inter_iff [simp]: "(A : Inter C) = (ALL X:C. A:X)"
   729   by (unfold Inter_def) blast
   730 
   731 lemma InterI [intro!]: "(!!X. X:C ==> A:X) ==> A : Inter C"
   732   by (simp add: Inter_def)
   733 
   734 text {*
   735   \medskip A ``destruct'' rule -- every @{term X} in @{term C}
   736   contains @{term A} as an element, but @{prop "A:X"} can hold when
   737   @{prop "X:C"} does not!  This rule is analogous to @{text spec}.
   738 *}
   739 
   740 lemma InterD [elim]: "A : Inter C ==> X:C ==> A:X"
   741   by auto
   742 
   743 lemma InterE [elim]: "A : Inter C ==> (X~:C ==> R) ==> (A:X ==> R) ==> R"
   744   -- {* ``Classical'' elimination rule -- does not require proving
   745     @{prop "X:C"}. *}
   746   by (unfold Inter_def) blast
   747 
   748 text {*
   749   \medskip Image of a set under a function.  Frequently @{term b} does
   750   not have the syntactic form of @{term "f x"}.
   751 *}
   752 
   753 lemma image_eqI [simp, intro]: "b = f x ==> x:A ==> b : f`A"
   754   by (unfold image_def) blast
   755 
   756 lemma imageI: "x : A ==> f x : f ` A"
   757   by (rule image_eqI) (rule refl)
   758 
   759 lemma rev_image_eqI: "x:A ==> b = f x ==> b : f`A"
   760   -- {* This version's more effective when we already have the
   761     required @{term x}. *}
   762   by (unfold image_def) blast
   763 
   764 lemma imageE [elim!]:
   765   "b : (%x. f x)`A ==> (!!x. b = f x ==> x:A ==> P) ==> P"
   766   -- {* The eta-expansion gives variable-name preservation. *}
   767   by (unfold image_def) blast
   768 
   769 lemma image_Un: "f`(A Un B) = f`A Un f`B"
   770   by blast
   771 
   772 lemma image_iff: "(z : f`A) = (EX x:A. z = f x)"
   773   by blast
   774 
   775 lemma image_subset_iff: "(f`A \<subseteq> B) = (\<forall>x\<in>A. f x \<in> B)"
   776   -- {* This rewrite rule would confuse users if made default. *}
   777   by blast
   778 
   779 lemma subset_image_iff: "(B \<subseteq> f`A) = (EX AA. AA \<subseteq> A & B = f`AA)"
   780   apply safe
   781    prefer 2 apply fast
   782   apply (rule_tac x = "{a. a : A & f a : B}" in exI, fast)
   783   done
   784 
   785 lemma image_subsetI: "(!!x. x \<in> A ==> f x \<in> B) ==> f`A \<subseteq> B"
   786   -- {* Replaces the three steps @{text subsetI}, @{text imageE},
   787     @{text hypsubst}, but breaks too many existing proofs. *}
   788   by blast
   789 
   790 text {*
   791   \medskip Range of a function -- just a translation for image!
   792 *}
   793 
   794 lemma range_eqI: "b = f x ==> b \<in> range f"
   795   by simp
   796 
   797 lemma rangeI: "f x \<in> range f"
   798   by simp
   799 
   800 lemma rangeE [elim?]: "b \<in> range (\<lambda>x. f x) ==> (!!x. b = f x ==> P) ==> P"
   801   by blast
   802 
   803 
   804 subsubsection {* Set reasoning tools *}
   805 
   806 text {*
   807   Rewrite rules for boolean case-splitting: faster than @{text
   808   "split_if [split]"}.
   809 *}
   810 
   811 lemma split_if_eq1: "((if Q then x else y) = b) = ((Q --> x = b) & (~ Q --> y = b))"
   812   by (rule split_if)
   813 
   814 lemma split_if_eq2: "(a = (if Q then x else y)) = ((Q --> a = x) & (~ Q --> a = y))"
   815   by (rule split_if)
   816 
   817 text {*
   818   Split ifs on either side of the membership relation.  Not for @{text
   819   "[simp]"} -- can cause goals to blow up!
   820 *}
   821 
   822 lemma split_if_mem1: "((if Q then x else y) : b) = ((Q --> x : b) & (~ Q --> y : b))"
   823   by (rule split_if)
   824 
   825 lemma split_if_mem2: "(a : (if Q then x else y)) = ((Q --> a : x) & (~ Q --> a : y))"
   826   by (rule split_if)
   827 
   828 lemmas split_ifs = if_bool_eq_conj split_if_eq1 split_if_eq2 split_if_mem1 split_if_mem2
   829 
   830 lemmas mem_simps =
   831   insert_iff empty_iff Un_iff Int_iff Compl_iff Diff_iff
   832   mem_Collect_eq UN_iff Union_iff INT_iff Inter_iff
   833   -- {* Each of these has ALREADY been added @{text "[simp]"} above. *}
   834 
   835 (*Would like to add these, but the existing code only searches for the
   836   outer-level constant, which in this case is just "op :"; we instead need
   837   to use term-nets to associate patterns with rules.  Also, if a rule fails to
   838   apply, then the formula should be kept.
   839   [("uminus", Compl_iff RS iffD1), ("op -", [Diff_iff RS iffD1]),
   840    ("op Int", [IntD1,IntD2]),
   841    ("Collect", [CollectD]), ("Inter", [InterD]), ("INTER", [INT_D])]
   842  *)
   843 
   844 ML_setup {*
   845   val mksimps_pairs = [("Ball", [thm "bspec"])] @ mksimps_pairs;
   846   simpset_ref() := simpset() setmksimps (mksimps mksimps_pairs);
   847 *}
   848 
   849 declare subset_UNIV [simp] subset_refl [simp]
   850 
   851 
   852 subsubsection {* The ``proper subset'' relation *}
   853 
   854 lemma psubsetI [intro!]: "A \<subseteq> B ==> A \<noteq> B ==> A \<subset> B"
   855   by (unfold psubset_def) blast
   856 
   857 lemma psubsetE [elim!]: 
   858     "[|A \<subset> B;  [|A \<subseteq> B; ~ (B\<subseteq>A)|] ==> R|] ==> R"
   859   by (unfold psubset_def) blast
   860 
   861 lemma psubset_insert_iff:
   862   "(A \<subset> insert x B) = (if x \<in> B then A \<subset> B else if x \<in> A then A - {x} \<subset> B else A \<subseteq> B)"
   863   by (auto simp add: psubset_def subset_insert_iff)
   864 
   865 lemma psubset_eq: "(A \<subset> B) = (A \<subseteq> B & A \<noteq> B)"
   866   by (simp only: psubset_def)
   867 
   868 lemma psubset_imp_subset: "A \<subset> B ==> A \<subseteq> B"
   869   by (simp add: psubset_eq)
   870 
   871 lemma psubset_trans: "[| A \<subset> B; B \<subset> C |] ==> A \<subset> C"
   872 apply (unfold psubset_def)
   873 apply (auto dest: subset_antisym)
   874 done
   875 
   876 lemma psubsetD: "[| A \<subset> B; c \<in> A |] ==> c \<in> B"
   877 apply (unfold psubset_def)
   878 apply (auto dest: subsetD)
   879 done
   880 
   881 lemma psubset_subset_trans: "A \<subset> B ==> B \<subseteq> C ==> A \<subset> C"
   882   by (auto simp add: psubset_eq)
   883 
   884 lemma subset_psubset_trans: "A \<subseteq> B ==> B \<subset> C ==> A \<subset> C"
   885   by (auto simp add: psubset_eq)
   886 
   887 lemma psubset_imp_ex_mem: "A \<subset> B ==> \<exists>b. b \<in> (B - A)"
   888   by (unfold psubset_def) blast
   889 
   890 lemma atomize_ball:
   891     "(!!x. x \<in> A ==> P x) == Trueprop (\<forall>x\<in>A. P x)"
   892   by (simp only: Ball_def atomize_all atomize_imp)
   893 
   894 declare atomize_ball [symmetric, rulify]
   895 
   896 
   897 subsection {* Further set-theory lemmas *}
   898 
   899 subsubsection {* Derived rules involving subsets. *}
   900 
   901 text {* @{text insert}. *}
   902 
   903 lemma subset_insertI: "B \<subseteq> insert a B"
   904   apply (rule subsetI)
   905   apply (erule insertI2)
   906   done
   907 
   908 lemma subset_insertI2: "A \<subseteq> B \<Longrightarrow> A \<subseteq> insert b B"
   909 by blast
   910 
   911 lemma subset_insert: "x \<notin> A ==> (A \<subseteq> insert x B) = (A \<subseteq> B)"
   912   by blast
   913 
   914 
   915 text {* \medskip Big Union -- least upper bound of a set. *}
   916 
   917 lemma Union_upper: "B \<in> A ==> B \<subseteq> Union A"
   918   by (rules intro: subsetI UnionI)
   919 
   920 lemma Union_least: "(!!X. X \<in> A ==> X \<subseteq> C) ==> Union A \<subseteq> C"
   921   by (rules intro: subsetI elim: UnionE dest: subsetD)
   922 
   923 
   924 text {* \medskip General union. *}
   925 
   926 lemma UN_upper: "a \<in> A ==> B a \<subseteq> (\<Union>x\<in>A. B x)"
   927   by blast
   928 
   929 lemma UN_least: "(!!x. x \<in> A ==> B x \<subseteq> C) ==> (\<Union>x\<in>A. B x) \<subseteq> C"
   930   by (rules intro: subsetI elim: UN_E dest: subsetD)
   931 
   932 
   933 text {* \medskip Big Intersection -- greatest lower bound of a set. *}
   934 
   935 lemma Inter_lower: "B \<in> A ==> Inter A \<subseteq> B"
   936   by blast
   937 
   938 lemma Inter_greatest: "(!!X. X \<in> A ==> C \<subseteq> X) ==> C \<subseteq> Inter A"
   939   by (rules intro: InterI subsetI dest: subsetD)
   940 
   941 lemma INT_lower: "a \<in> A ==> (\<Inter>x\<in>A. B x) \<subseteq> B a"
   942   by blast
   943 
   944 lemma INT_greatest: "(!!x. x \<in> A ==> C \<subseteq> B x) ==> C \<subseteq> (\<Inter>x\<in>A. B x)"
   945   by (rules intro: INT_I subsetI dest: subsetD)
   946 
   947 
   948 text {* \medskip Finite Union -- the least upper bound of two sets. *}
   949 
   950 lemma Un_upper1: "A \<subseteq> A \<union> B"
   951   by blast
   952 
   953 lemma Un_upper2: "B \<subseteq> A \<union> B"
   954   by blast
   955 
   956 lemma Un_least: "A \<subseteq> C ==> B \<subseteq> C ==> A \<union> B \<subseteq> C"
   957   by blast
   958 
   959 
   960 text {* \medskip Finite Intersection -- the greatest lower bound of two sets. *}
   961 
   962 lemma Int_lower1: "A \<inter> B \<subseteq> A"
   963   by blast
   964 
   965 lemma Int_lower2: "A \<inter> B \<subseteq> B"
   966   by blast
   967 
   968 lemma Int_greatest: "C \<subseteq> A ==> C \<subseteq> B ==> C \<subseteq> A \<inter> B"
   969   by blast
   970 
   971 
   972 text {* \medskip Set difference. *}
   973 
   974 lemma Diff_subset: "A - B \<subseteq> A"
   975   by blast
   976 
   977 lemma Diff_subset_conv: "(A - B \<subseteq> C) = (A \<subseteq> B \<union> C)"
   978 by blast
   979 
   980 
   981 text {* \medskip Monotonicity. *}
   982 
   983 lemma mono_Un: includes mono shows "f A \<union> f B \<subseteq> f (A \<union> B)"
   984   apply (rule Un_least)
   985    apply (rule Un_upper1 [THEN mono])
   986   apply (rule Un_upper2 [THEN mono])
   987   done
   988 
   989 lemma mono_Int: includes mono shows "f (A \<inter> B) \<subseteq> f A \<inter> f B"
   990   apply (rule Int_greatest)
   991    apply (rule Int_lower1 [THEN mono])
   992   apply (rule Int_lower2 [THEN mono])
   993   done
   994 
   995 
   996 subsubsection {* Equalities involving union, intersection, inclusion, etc. *}
   997 
   998 text {* @{text "{}"}. *}
   999 
  1000 lemma Collect_const [simp]: "{s. P} = (if P then UNIV else {})"
  1001   -- {* supersedes @{text "Collect_False_empty"} *}
  1002   by auto
  1003 
  1004 lemma subset_empty [simp]: "(A \<subseteq> {}) = (A = {})"
  1005   by blast
  1006 
  1007 lemma not_psubset_empty [iff]: "\<not> (A < {})"
  1008   by (unfold psubset_def) blast
  1009 
  1010 lemma Collect_empty_eq [simp]: "(Collect P = {}) = (\<forall>x. \<not> P x)"
  1011   by auto
  1012 
  1013 lemma Collect_neg_eq: "{x. \<not> P x} = - {x. P x}"
  1014   by blast
  1015 
  1016 lemma Collect_disj_eq: "{x. P x | Q x} = {x. P x} \<union> {x. Q x}"
  1017   by blast
  1018 
  1019 lemma Collect_conj_eq: "{x. P x & Q x} = {x. P x} \<inter> {x. Q x}"
  1020   by blast
  1021 
  1022 lemma Collect_all_eq: "{x. \<forall>y. P x y} = (\<Inter>y. {x. P x y})"
  1023   by blast
  1024 
  1025 lemma Collect_ball_eq: "{x. \<forall>y\<in>A. P x y} = (\<Inter>y\<in>A. {x. P x y})"
  1026   by blast
  1027 
  1028 lemma Collect_ex_eq: "{x. \<exists>y. P x y} = (\<Union>y. {x. P x y})"
  1029   by blast
  1030 
  1031 lemma Collect_bex_eq: "{x. \<exists>y\<in>A. P x y} = (\<Union>y\<in>A. {x. P x y})"
  1032   by blast
  1033 
  1034 
  1035 text {* \medskip @{text insert}. *}
  1036 
  1037 lemma insert_is_Un: "insert a A = {a} Un A"
  1038   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a {}"} *}
  1039   by blast
  1040 
  1041 lemma insert_not_empty [simp]: "insert a A \<noteq> {}"
  1042   by blast
  1043 
  1044 lemmas empty_not_insert [simp] = insert_not_empty [symmetric, standard]
  1045 
  1046 lemma insert_absorb: "a \<in> A ==> insert a A = A"
  1047   -- {* @{text "[simp]"} causes recursive calls when there are nested inserts *}
  1048   -- {* with \emph{quadratic} running time *}
  1049   by blast
  1050 
  1051 lemma insert_absorb2 [simp]: "insert x (insert x A) = insert x A"
  1052   by blast
  1053 
  1054 lemma insert_commute: "insert x (insert y A) = insert y (insert x A)"
  1055   by blast
  1056 
  1057 lemma insert_subset [simp]: "(insert x A \<subseteq> B) = (x \<in> B & A \<subseteq> B)"
  1058   by blast
  1059 
  1060 lemma mk_disjoint_insert: "a \<in> A ==> \<exists>B. A = insert a B & a \<notin> B"
  1061   -- {* use new @{text B} rather than @{text "A - {a}"} to avoid infinite unfolding *}
  1062   apply (rule_tac x = "A - {a}" in exI, blast)
  1063   done
  1064 
  1065 lemma insert_Collect: "insert a (Collect P) = {u. u \<noteq> a --> P u}"
  1066   by auto
  1067 
  1068 lemma UN_insert_distrib: "u \<in> A ==> (\<Union>x\<in>A. insert a (B x)) = insert a (\<Union>x\<in>A. B x)"
  1069   by blast
  1070 
  1071 lemma insert_inter_insert[simp]: "insert a A \<inter> insert a B = insert a (A \<inter> B)"
  1072 by blast
  1073 
  1074 lemma insert_disjoint[simp]:
  1075  "(insert a A \<inter> B = {}) = (a \<notin> B \<and> A \<inter> B = {})"
  1076 by blast
  1077 
  1078 lemma disjoint_insert[simp]:
  1079  "(B \<inter> insert a A = {}) = (a \<notin> B \<and> B \<inter> A = {})"
  1080 by blast
  1081 
  1082 text {* \medskip @{text image}. *}
  1083 
  1084 lemma image_empty [simp]: "f`{} = {}"
  1085   by blast
  1086 
  1087 lemma image_insert [simp]: "f ` insert a B = insert (f a) (f`B)"
  1088   by blast
  1089 
  1090 lemma image_constant: "x \<in> A ==> (\<lambda>x. c) ` A = {c}"
  1091   by blast
  1092 
  1093 lemma image_image: "f ` (g ` A) = (\<lambda>x. f (g x)) ` A"
  1094   by blast
  1095 
  1096 lemma insert_image [simp]: "x \<in> A ==> insert (f x) (f`A) = f`A"
  1097   by blast
  1098 
  1099 lemma image_is_empty [iff]: "(f`A = {}) = (A = {})"
  1100   by blast
  1101 
  1102 lemma image_Collect: "f ` {x. P x} = {f x | x. P x}"
  1103   -- {* NOT suitable as a default simprule: the RHS isn't simpler than the LHS, *}
  1104   -- {* with its implicit quantifier and conjunction.  Also image enjoys better *}
  1105   -- {* equational properties than does the RHS. *}
  1106   by blast
  1107 
  1108 lemma if_image_distrib [simp]:
  1109   "(\<lambda>x. if P x then f x else g x) ` S
  1110     = (f ` (S \<inter> {x. P x})) \<union> (g ` (S \<inter> {x. \<not> P x}))"
  1111   by (auto simp add: image_def)
  1112 
  1113 lemma image_cong: "M = N ==> (!!x. x \<in> N ==> f x = g x) ==> f`M = g`N"
  1114   by (simp add: image_def)
  1115 
  1116 
  1117 text {* \medskip @{text range}. *}
  1118 
  1119 lemma full_SetCompr_eq: "{u. \<exists>x. u = f x} = range f"
  1120   by auto
  1121 
  1122 lemma range_composition [simp]: "range (\<lambda>x. f (g x)) = f`range g"
  1123 by (subst image_image, simp)
  1124 
  1125 
  1126 text {* \medskip @{text Int} *}
  1127 
  1128 lemma Int_absorb [simp]: "A \<inter> A = A"
  1129   by blast
  1130 
  1131 lemma Int_left_absorb: "A \<inter> (A \<inter> B) = A \<inter> B"
  1132   by blast
  1133 
  1134 lemma Int_commute: "A \<inter> B = B \<inter> A"
  1135   by blast
  1136 
  1137 lemma Int_left_commute: "A \<inter> (B \<inter> C) = B \<inter> (A \<inter> C)"
  1138   by blast
  1139 
  1140 lemma Int_assoc: "(A \<inter> B) \<inter> C = A \<inter> (B \<inter> C)"
  1141   by blast
  1142 
  1143 lemmas Int_ac = Int_assoc Int_left_absorb Int_commute Int_left_commute
  1144   -- {* Intersection is an AC-operator *}
  1145 
  1146 lemma Int_absorb1: "B \<subseteq> A ==> A \<inter> B = B"
  1147   by blast
  1148 
  1149 lemma Int_absorb2: "A \<subseteq> B ==> A \<inter> B = A"
  1150   by blast
  1151 
  1152 lemma Int_empty_left [simp]: "{} \<inter> B = {}"
  1153   by blast
  1154 
  1155 lemma Int_empty_right [simp]: "A \<inter> {} = {}"
  1156   by blast
  1157 
  1158 lemma disjoint_eq_subset_Compl: "(A \<inter> B = {}) = (A \<subseteq> -B)"
  1159   by blast
  1160 
  1161 lemma disjoint_iff_not_equal: "(A \<inter> B = {}) = (\<forall>x\<in>A. \<forall>y\<in>B. x \<noteq> y)"
  1162   by blast
  1163 
  1164 lemma Int_UNIV_left [simp]: "UNIV \<inter> B = B"
  1165   by blast
  1166 
  1167 lemma Int_UNIV_right [simp]: "A \<inter> UNIV = A"
  1168   by blast
  1169 
  1170 lemma Int_eq_Inter: "A \<inter> B = \<Inter>{A, B}"
  1171   by blast
  1172 
  1173 lemma Int_Un_distrib: "A \<inter> (B \<union> C) = (A \<inter> B) \<union> (A \<inter> C)"
  1174   by blast
  1175 
  1176 lemma Int_Un_distrib2: "(B \<union> C) \<inter> A = (B \<inter> A) \<union> (C \<inter> A)"
  1177   by blast
  1178 
  1179 lemma Int_UNIV [simp]: "(A \<inter> B = UNIV) = (A = UNIV & B = UNIV)"
  1180   by blast
  1181 
  1182 lemma Int_subset_iff: "(C \<subseteq> A \<inter> B) = (C \<subseteq> A & C \<subseteq> B)"
  1183   by blast
  1184 
  1185 lemma Int_Collect: "(x \<in> A \<inter> {x. P x}) = (x \<in> A & P x)"
  1186   by blast
  1187 
  1188 
  1189 text {* \medskip @{text Un}. *}
  1190 
  1191 lemma Un_absorb [simp]: "A \<union> A = A"
  1192   by blast
  1193 
  1194 lemma Un_left_absorb: "A \<union> (A \<union> B) = A \<union> B"
  1195   by blast
  1196 
  1197 lemma Un_commute: "A \<union> B = B \<union> A"
  1198   by blast
  1199 
  1200 lemma Un_left_commute: "A \<union> (B \<union> C) = B \<union> (A \<union> C)"
  1201   by blast
  1202 
  1203 lemma Un_assoc: "(A \<union> B) \<union> C = A \<union> (B \<union> C)"
  1204   by blast
  1205 
  1206 lemmas Un_ac = Un_assoc Un_left_absorb Un_commute Un_left_commute
  1207   -- {* Union is an AC-operator *}
  1208 
  1209 lemma Un_absorb1: "A \<subseteq> B ==> A \<union> B = B"
  1210   by blast
  1211 
  1212 lemma Un_absorb2: "B \<subseteq> A ==> A \<union> B = A"
  1213   by blast
  1214 
  1215 lemma Un_empty_left [simp]: "{} \<union> B = B"
  1216   by blast
  1217 
  1218 lemma Un_empty_right [simp]: "A \<union> {} = A"
  1219   by blast
  1220 
  1221 lemma Un_UNIV_left [simp]: "UNIV \<union> B = UNIV"
  1222   by blast
  1223 
  1224 lemma Un_UNIV_right [simp]: "A \<union> UNIV = UNIV"
  1225   by blast
  1226 
  1227 lemma Un_eq_Union: "A \<union> B = \<Union>{A, B}"
  1228   by blast
  1229 
  1230 lemma Un_insert_left [simp]: "(insert a B) \<union> C = insert a (B \<union> C)"
  1231   by blast
  1232 
  1233 lemma Un_insert_right [simp]: "A \<union> (insert a B) = insert a (A \<union> B)"
  1234   by blast
  1235 
  1236 lemma Int_insert_left:
  1237     "(insert a B) Int C = (if a \<in> C then insert a (B \<inter> C) else B \<inter> C)"
  1238   by auto
  1239 
  1240 lemma Int_insert_right:
  1241     "A \<inter> (insert a B) = (if a \<in> A then insert a (A \<inter> B) else A \<inter> B)"
  1242   by auto
  1243 
  1244 lemma Un_Int_distrib: "A \<union> (B \<inter> C) = (A \<union> B) \<inter> (A \<union> C)"
  1245   by blast
  1246 
  1247 lemma Un_Int_distrib2: "(B \<inter> C) \<union> A = (B \<union> A) \<inter> (C \<union> A)"
  1248   by blast
  1249 
  1250 lemma Un_Int_crazy:
  1251     "(A \<inter> B) \<union> (B \<inter> C) \<union> (C \<inter> A) = (A \<union> B) \<inter> (B \<union> C) \<inter> (C \<union> A)"
  1252   by blast
  1253 
  1254 lemma subset_Un_eq: "(A \<subseteq> B) = (A \<union> B = B)"
  1255   by blast
  1256 
  1257 lemma Un_empty [iff]: "(A \<union> B = {}) = (A = {} & B = {})"
  1258   by blast
  1259 
  1260 lemma Un_subset_iff: "(A \<union> B \<subseteq> C) = (A \<subseteq> C & B \<subseteq> C)"
  1261   by blast
  1262 
  1263 lemma Un_Diff_Int: "(A - B) \<union> (A \<inter> B) = A"
  1264   by blast
  1265 
  1266 
  1267 text {* \medskip Set complement *}
  1268 
  1269 lemma Compl_disjoint [simp]: "A \<inter> -A = {}"
  1270   by blast
  1271 
  1272 lemma Compl_disjoint2 [simp]: "-A \<inter> A = {}"
  1273   by blast
  1274 
  1275 lemma Compl_partition: "A \<union> -A = UNIV"
  1276   by blast
  1277 
  1278 lemma Compl_partition2: "-A \<union> A = UNIV"
  1279   by blast
  1280 
  1281 lemma double_complement [simp]: "- (-A) = (A::'a set)"
  1282   by blast
  1283 
  1284 lemma Compl_Un [simp]: "-(A \<union> B) = (-A) \<inter> (-B)"
  1285   by blast
  1286 
  1287 lemma Compl_Int [simp]: "-(A \<inter> B) = (-A) \<union> (-B)"
  1288   by blast
  1289 
  1290 lemma Compl_UN [simp]: "-(\<Union>x\<in>A. B x) = (\<Inter>x\<in>A. -B x)"
  1291   by blast
  1292 
  1293 lemma Compl_INT [simp]: "-(\<Inter>x\<in>A. B x) = (\<Union>x\<in>A. -B x)"
  1294   by blast
  1295 
  1296 lemma subset_Compl_self_eq: "(A \<subseteq> -A) = (A = {})"
  1297   by blast
  1298 
  1299 lemma Un_Int_assoc_eq: "((A \<inter> B) \<union> C = A \<inter> (B \<union> C)) = (C \<subseteq> A)"
  1300   -- {* Halmos, Naive Set Theory, page 16. *}
  1301   by blast
  1302 
  1303 lemma Compl_UNIV_eq [simp]: "-UNIV = {}"
  1304   by blast
  1305 
  1306 lemma Compl_empty_eq [simp]: "-{} = UNIV"
  1307   by blast
  1308 
  1309 lemma Compl_subset_Compl_iff [iff]: "(-A \<subseteq> -B) = (B \<subseteq> A)"
  1310   by blast
  1311 
  1312 lemma Compl_eq_Compl_iff [iff]: "(-A = -B) = (A = (B::'a set))"
  1313   by blast
  1314 
  1315 
  1316 text {* \medskip @{text Union}. *}
  1317 
  1318 lemma Union_empty [simp]: "Union({}) = {}"
  1319   by blast
  1320 
  1321 lemma Union_UNIV [simp]: "Union UNIV = UNIV"
  1322   by blast
  1323 
  1324 lemma Union_insert [simp]: "Union (insert a B) = a \<union> \<Union>B"
  1325   by blast
  1326 
  1327 lemma Union_Un_distrib [simp]: "\<Union>(A Un B) = \<Union>A \<union> \<Union>B"
  1328   by blast
  1329 
  1330 lemma Union_Int_subset: "\<Union>(A \<inter> B) \<subseteq> \<Union>A \<inter> \<Union>B"
  1331   by blast
  1332 
  1333 lemma Union_empty_conv [iff]: "(\<Union>A = {}) = (\<forall>x\<in>A. x = {})"
  1334   by blast
  1335 
  1336 lemma empty_Union_conv [iff]: "({} = \<Union>A) = (\<forall>x\<in>A. x = {})"
  1337   by blast
  1338 
  1339 lemma Union_disjoint: "(\<Union>C \<inter> A = {}) = (\<forall>B\<in>C. B \<inter> A = {})"
  1340   by blast
  1341 
  1342 
  1343 text {* \medskip @{text Inter}. *}
  1344 
  1345 lemma Inter_empty [simp]: "\<Inter>{} = UNIV"
  1346   by blast
  1347 
  1348 lemma Inter_UNIV [simp]: "\<Inter>UNIV = {}"
  1349   by blast
  1350 
  1351 lemma Inter_insert [simp]: "\<Inter>(insert a B) = a \<inter> \<Inter>B"
  1352   by blast
  1353 
  1354 lemma Inter_Un_subset: "\<Inter>A \<union> \<Inter>B \<subseteq> \<Inter>(A \<inter> B)"
  1355   by blast
  1356 
  1357 lemma Inter_Un_distrib: "\<Inter>(A \<union> B) = \<Inter>A \<inter> \<Inter>B"
  1358   by blast
  1359 
  1360 lemma Inter_UNIV_conv [iff]:
  1361   "(\<Inter>A = UNIV) = (\<forall>x\<in>A. x = UNIV)"
  1362   "(UNIV = \<Inter>A) = (\<forall>x\<in>A. x = UNIV)"
  1363   by blast+
  1364 
  1365 
  1366 text {*
  1367   \medskip @{text UN} and @{text INT}.
  1368 
  1369   Basic identities: *}
  1370 
  1371 lemma UN_empty [simp]: "(\<Union>x\<in>{}. B x) = {}"
  1372   by blast
  1373 
  1374 lemma UN_empty2 [simp]: "(\<Union>x\<in>A. {}) = {}"
  1375   by blast
  1376 
  1377 lemma UN_singleton [simp]: "(\<Union>x\<in>A. {x}) = A"
  1378   by blast
  1379 
  1380 lemma UN_absorb: "k \<in> I ==> A k \<union> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. A i)"
  1381   by blast
  1382 
  1383 lemma INT_empty [simp]: "(\<Inter>x\<in>{}. B x) = UNIV"
  1384   by blast
  1385 
  1386 lemma INT_absorb: "k \<in> I ==> A k \<inter> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. A i)"
  1387   by blast
  1388 
  1389 lemma UN_insert [simp]: "(\<Union>x\<in>insert a A. B x) = B a \<union> UNION A B"
  1390   by blast
  1391 
  1392 lemma UN_Un: "(\<Union>i \<in> A \<union> B. M i) = (\<Union>i\<in>A. M i) \<union> (\<Union>i\<in>B. M i)"
  1393   by blast
  1394 
  1395 lemma UN_UN_flatten: "(\<Union>x \<in> (\<Union>y\<in>A. B y). C x) = (\<Union>y\<in>A. \<Union>x\<in>B y. C x)"
  1396   by blast
  1397 
  1398 lemma UN_subset_iff: "((\<Union>i\<in>I. A i) \<subseteq> B) = (\<forall>i\<in>I. A i \<subseteq> B)"
  1399   by blast
  1400 
  1401 lemma INT_subset_iff: "(B \<subseteq> (\<Inter>i\<in>I. A i)) = (\<forall>i\<in>I. B \<subseteq> A i)"
  1402   by blast
  1403 
  1404 lemma INT_insert [simp]: "(\<Inter>x \<in> insert a A. B x) = B a \<inter> INTER A B"
  1405   by blast
  1406 
  1407 lemma INT_Un: "(\<Inter>i \<in> A \<union> B. M i) = (\<Inter>i \<in> A. M i) \<inter> (\<Inter>i\<in>B. M i)"
  1408   by blast
  1409 
  1410 lemma INT_insert_distrib:
  1411     "u \<in> A ==> (\<Inter>x\<in>A. insert a (B x)) = insert a (\<Inter>x\<in>A. B x)"
  1412   by blast
  1413 
  1414 lemma Union_image_eq [simp]: "\<Union>(B`A) = (\<Union>x\<in>A. B x)"
  1415   by blast
  1416 
  1417 lemma image_Union: "f ` \<Union>S = (\<Union>x\<in>S. f ` x)"
  1418   by blast
  1419 
  1420 lemma Inter_image_eq [simp]: "\<Inter>(B`A) = (\<Inter>x\<in>A. B x)"
  1421   by blast
  1422 
  1423 lemma UN_constant [simp]: "(\<Union>y\<in>A. c) = (if A = {} then {} else c)"
  1424   by auto
  1425 
  1426 lemma INT_constant [simp]: "(\<Inter>y\<in>A. c) = (if A = {} then UNIV else c)"
  1427   by auto
  1428 
  1429 lemma UN_eq: "(\<Union>x\<in>A. B x) = \<Union>({Y. \<exists>x\<in>A. Y = B x})"
  1430   by blast
  1431 
  1432 lemma INT_eq: "(\<Inter>x\<in>A. B x) = \<Inter>({Y. \<exists>x\<in>A. Y = B x})"
  1433   -- {* Look: it has an \emph{existential} quantifier *}
  1434   by blast
  1435 
  1436 lemma UNION_empty_conv[iff]:
  1437   "({} = (UN x:A. B x)) = (\<forall>x\<in>A. B x = {})"
  1438   "((UN x:A. B x) = {}) = (\<forall>x\<in>A. B x = {})"
  1439 by blast+
  1440 
  1441 lemma INTER_UNIV_conv[iff]:
  1442  "(UNIV = (INT x:A. B x)) = (\<forall>x\<in>A. B x = UNIV)"
  1443  "((INT x:A. B x) = UNIV) = (\<forall>x\<in>A. B x = UNIV)"
  1444 by blast+
  1445 
  1446 
  1447 text {* \medskip Distributive laws: *}
  1448 
  1449 lemma Int_Union: "A \<inter> \<Union>B = (\<Union>C\<in>B. A \<inter> C)"
  1450   by blast
  1451 
  1452 lemma Int_Union2: "\<Union>B \<inter> A = (\<Union>C\<in>B. C \<inter> A)"
  1453   by blast
  1454 
  1455 lemma Un_Union_image: "(\<Union>x\<in>C. A x \<union> B x) = \<Union>(A`C) \<union> \<Union>(B`C)"
  1456   -- {* Devlin, Fundamentals of Contemporary Set Theory, page 12, exercise 5: *}
  1457   -- {* Union of a family of unions *}
  1458   by blast
  1459 
  1460 lemma UN_Un_distrib: "(\<Union>i\<in>I. A i \<union> B i) = (\<Union>i\<in>I. A i) \<union> (\<Union>i\<in>I. B i)"
  1461   -- {* Equivalent version *}
  1462   by blast
  1463 
  1464 lemma Un_Inter: "A \<union> \<Inter>B = (\<Inter>C\<in>B. A \<union> C)"
  1465   by blast
  1466 
  1467 lemma Int_Inter_image: "(\<Inter>x\<in>C. A x \<inter> B x) = \<Inter>(A`C) \<inter> \<Inter>(B`C)"
  1468   by blast
  1469 
  1470 lemma INT_Int_distrib: "(\<Inter>i\<in>I. A i \<inter> B i) = (\<Inter>i\<in>I. A i) \<inter> (\<Inter>i\<in>I. B i)"
  1471   -- {* Equivalent version *}
  1472   by blast
  1473 
  1474 lemma Int_UN_distrib: "B \<inter> (\<Union>i\<in>I. A i) = (\<Union>i\<in>I. B \<inter> A i)"
  1475   -- {* Halmos, Naive Set Theory, page 35. *}
  1476   by blast
  1477 
  1478 lemma Un_INT_distrib: "B \<union> (\<Inter>i\<in>I. A i) = (\<Inter>i\<in>I. B \<union> A i)"
  1479   by blast
  1480 
  1481 lemma Int_UN_distrib2: "(\<Union>i\<in>I. A i) \<inter> (\<Union>j\<in>J. B j) = (\<Union>i\<in>I. \<Union>j\<in>J. A i \<inter> B j)"
  1482   by blast
  1483 
  1484 lemma Un_INT_distrib2: "(\<Inter>i\<in>I. A i) \<union> (\<Inter>j\<in>J. B j) = (\<Inter>i\<in>I. \<Inter>j\<in>J. A i \<union> B j)"
  1485   by blast
  1486 
  1487 
  1488 text {* \medskip Bounded quantifiers.
  1489 
  1490   The following are not added to the default simpset because
  1491   (a) they duplicate the body and (b) there are no similar rules for @{text Int}. *}
  1492 
  1493 lemma ball_Un: "(\<forall>x \<in> A \<union> B. P x) = ((\<forall>x\<in>A. P x) & (\<forall>x\<in>B. P x))"
  1494   by blast
  1495 
  1496 lemma bex_Un: "(\<exists>x \<in> A \<union> B. P x) = ((\<exists>x\<in>A. P x) | (\<exists>x\<in>B. P x))"
  1497   by blast
  1498 
  1499 lemma ball_UN: "(\<forall>z \<in> UNION A B. P z) = (\<forall>x\<in>A. \<forall>z \<in> B x. P z)"
  1500   by blast
  1501 
  1502 lemma bex_UN: "(\<exists>z \<in> UNION A B. P z) = (\<exists>x\<in>A. \<exists>z\<in>B x. P z)"
  1503   by blast
  1504 
  1505 
  1506 text {* \medskip Set difference. *}
  1507 
  1508 lemma Diff_eq: "A - B = A \<inter> (-B)"
  1509   by blast
  1510 
  1511 lemma Diff_eq_empty_iff [simp]: "(A - B = {}) = (A \<subseteq> B)"
  1512   by blast
  1513 
  1514 lemma Diff_cancel [simp]: "A - A = {}"
  1515   by blast
  1516 
  1517 lemma Diff_idemp [simp]: "(A - B) - B = A - (B::'a set)"
  1518 by blast
  1519 
  1520 lemma Diff_triv: "A \<inter> B = {} ==> A - B = A"
  1521   by (blast elim: equalityE)
  1522 
  1523 lemma empty_Diff [simp]: "{} - A = {}"
  1524   by blast
  1525 
  1526 lemma Diff_empty [simp]: "A - {} = A"
  1527   by blast
  1528 
  1529 lemma Diff_UNIV [simp]: "A - UNIV = {}"
  1530   by blast
  1531 
  1532 lemma Diff_insert0 [simp]: "x \<notin> A ==> A - insert x B = A - B"
  1533   by blast
  1534 
  1535 lemma Diff_insert: "A - insert a B = A - B - {a}"
  1536   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1537   by blast
  1538 
  1539 lemma Diff_insert2: "A - insert a B = A - {a} - B"
  1540   -- {* NOT SUITABLE FOR REWRITING since @{text "{a} == insert a 0"} *}
  1541   by blast
  1542 
  1543 lemma insert_Diff_if: "insert x A - B = (if x \<in> B then A - B else insert x (A - B))"
  1544   by auto
  1545 
  1546 lemma insert_Diff1 [simp]: "x \<in> B ==> insert x A - B = A - B"
  1547   by blast
  1548 
  1549 lemma insert_Diff_single[simp]: "insert a (A - {a}) = insert a A"
  1550 by blast
  1551 
  1552 lemma insert_Diff: "a \<in> A ==> insert a (A - {a}) = A"
  1553   by blast
  1554 
  1555 lemma Diff_insert_absorb: "x \<notin> A ==> (insert x A) - {x} = A"
  1556   by auto
  1557 
  1558 lemma Diff_disjoint [simp]: "A \<inter> (B - A) = {}"
  1559   by blast
  1560 
  1561 lemma Diff_partition: "A \<subseteq> B ==> A \<union> (B - A) = B"
  1562   by blast
  1563 
  1564 lemma double_diff: "A \<subseteq> B ==> B \<subseteq> C ==> B - (C - A) = A"
  1565   by blast
  1566 
  1567 lemma Un_Diff_cancel [simp]: "A \<union> (B - A) = A \<union> B"
  1568   by blast
  1569 
  1570 lemma Un_Diff_cancel2 [simp]: "(B - A) \<union> A = B \<union> A"
  1571   by blast
  1572 
  1573 lemma Diff_Un: "A - (B \<union> C) = (A - B) \<inter> (A - C)"
  1574   by blast
  1575 
  1576 lemma Diff_Int: "A - (B \<inter> C) = (A - B) \<union> (A - C)"
  1577   by blast
  1578 
  1579 lemma Un_Diff: "(A \<union> B) - C = (A - C) \<union> (B - C)"
  1580   by blast
  1581 
  1582 lemma Int_Diff: "(A \<inter> B) - C = A \<inter> (B - C)"
  1583   by blast
  1584 
  1585 lemma Diff_Int_distrib: "C \<inter> (A - B) = (C \<inter> A) - (C \<inter> B)"
  1586   by blast
  1587 
  1588 lemma Diff_Int_distrib2: "(A - B) \<inter> C = (A \<inter> C) - (B \<inter> C)"
  1589   by blast
  1590 
  1591 lemma Diff_Compl [simp]: "A - (- B) = A \<inter> B"
  1592   by auto
  1593 
  1594 lemma Compl_Diff_eq [simp]: "- (A - B) = -A \<union> B"
  1595   by blast
  1596 
  1597 
  1598 text {* \medskip Quantification over type @{typ bool}. *}
  1599 
  1600 lemma all_bool_eq: "(\<forall>b::bool. P b) = (P True & P False)"
  1601   apply auto
  1602   apply (tactic {* case_tac "b" 1 *}, auto)
  1603   done
  1604 
  1605 lemma bool_induct: "P True \<Longrightarrow> P False \<Longrightarrow> P x"
  1606   by (rule conjI [THEN all_bool_eq [THEN iffD2], THEN spec])
  1607 
  1608 lemma ex_bool_eq: "(\<exists>b::bool. P b) = (P True | P False)"
  1609   apply auto
  1610   apply (tactic {* case_tac "b" 1 *}, auto)
  1611   done
  1612 
  1613 lemma Un_eq_UN: "A \<union> B = (\<Union>b. if b then A else B)"
  1614   by (auto simp add: split_if_mem2)
  1615 
  1616 lemma UN_bool_eq: "(\<Union>b::bool. A b) = (A True \<union> A False)"
  1617   apply auto
  1618   apply (tactic {* case_tac "b" 1 *}, auto)
  1619   done
  1620 
  1621 lemma INT_bool_eq: "(\<Inter>b::bool. A b) = (A True \<inter> A False)"
  1622   apply auto
  1623   apply (tactic {* case_tac "b" 1 *}, auto)
  1624   done
  1625 
  1626 
  1627 text {* \medskip @{text Pow} *}
  1628 
  1629 lemma Pow_empty [simp]: "Pow {} = {{}}"
  1630   by (auto simp add: Pow_def)
  1631 
  1632 lemma Pow_insert: "Pow (insert a A) = Pow A \<union> (insert a ` Pow A)"
  1633   by (blast intro: image_eqI [where ?x = "u - {a}", standard])
  1634 
  1635 lemma Pow_Compl: "Pow (- A) = {-B | B. A \<in> Pow B}"
  1636   by (blast intro: exI [where ?x = "- u", standard])
  1637 
  1638 lemma Pow_UNIV [simp]: "Pow UNIV = UNIV"
  1639   by blast
  1640 
  1641 lemma Un_Pow_subset: "Pow A \<union> Pow B \<subseteq> Pow (A \<union> B)"
  1642   by blast
  1643 
  1644 lemma UN_Pow_subset: "(\<Union>x\<in>A. Pow (B x)) \<subseteq> Pow (\<Union>x\<in>A. B x)"
  1645   by blast
  1646 
  1647 lemma subset_Pow_Union: "A \<subseteq> Pow (\<Union>A)"
  1648   by blast
  1649 
  1650 lemma Union_Pow_eq [simp]: "\<Union>(Pow A) = A"
  1651   by blast
  1652 
  1653 lemma Pow_Int_eq [simp]: "Pow (A \<inter> B) = Pow A \<inter> Pow B"
  1654   by blast
  1655 
  1656 lemma Pow_INT_eq: "Pow (\<Inter>x\<in>A. B x) = (\<Inter>x\<in>A. Pow (B x))"
  1657   by blast
  1658 
  1659 
  1660 text {* \medskip Miscellany. *}
  1661 
  1662 lemma set_eq_subset: "(A = B) = (A \<subseteq> B & B \<subseteq> A)"
  1663   by blast
  1664 
  1665 lemma subset_iff: "(A \<subseteq> B) = (\<forall>t. t \<in> A --> t \<in> B)"
  1666   by blast
  1667 
  1668 lemma subset_iff_psubset_eq: "(A \<subseteq> B) = ((A \<subset> B) | (A = B))"
  1669   by (unfold psubset_def) blast
  1670 
  1671 lemma all_not_in_conv [iff]: "(\<forall>x. x \<notin> A) = (A = {})"
  1672   by blast
  1673 
  1674 lemma ex_in_conv: "(\<exists>x. x \<in> A) = (A \<noteq> {})"
  1675   by blast
  1676 
  1677 lemma distinct_lemma: "f x \<noteq> f y ==> x \<noteq> y"
  1678   by rules
  1679 
  1680 
  1681 text {* \medskip Miniscoping: pushing in quantifiers and big Unions
  1682            and Intersections. *}
  1683 
  1684 lemma UN_simps [simp]:
  1685   "!!a B C. (UN x:C. insert a (B x)) = (if C={} then {} else insert a (UN x:C. B x))"
  1686   "!!A B C. (UN x:C. A x Un B)   = ((if C={} then {} else (UN x:C. A x) Un B))"
  1687   "!!A B C. (UN x:C. A Un B x)   = ((if C={} then {} else A Un (UN x:C. B x)))"
  1688   "!!A B C. (UN x:C. A x Int B)  = ((UN x:C. A x) Int B)"
  1689   "!!A B C. (UN x:C. A Int B x)  = (A Int (UN x:C. B x))"
  1690   "!!A B C. (UN x:C. A x - B)    = ((UN x:C. A x) - B)"
  1691   "!!A B C. (UN x:C. A - B x)    = (A - (INT x:C. B x))"
  1692   "!!A B. (UN x: Union A. B x) = (UN y:A. UN x:y. B x)"
  1693   "!!A B C. (UN z: UNION A B. C z) = (UN  x:A. UN z: B(x). C z)"
  1694   "!!A B f. (UN x:f`A. B x)     = (UN a:A. B (f a))"
  1695   by auto
  1696 
  1697 lemma INT_simps [simp]:
  1698   "!!A B C. (INT x:C. A x Int B) = (if C={} then UNIV else (INT x:C. A x) Int B)"
  1699   "!!A B C. (INT x:C. A Int B x) = (if C={} then UNIV else A Int (INT x:C. B x))"
  1700   "!!A B C. (INT x:C. A x - B)   = (if C={} then UNIV else (INT x:C. A x) - B)"
  1701   "!!A B C. (INT x:C. A - B x)   = (if C={} then UNIV else A - (UN x:C. B x))"
  1702   "!!a B C. (INT x:C. insert a (B x)) = insert a (INT x:C. B x)"
  1703   "!!A B C. (INT x:C. A x Un B)  = ((INT x:C. A x) Un B)"
  1704   "!!A B C. (INT x:C. A Un B x)  = (A Un (INT x:C. B x))"
  1705   "!!A B. (INT x: Union A. B x) = (INT y:A. INT x:y. B x)"
  1706   "!!A B C. (INT z: UNION A B. C z) = (INT x:A. INT z: B(x). C z)"
  1707   "!!A B f. (INT x:f`A. B x)    = (INT a:A. B (f a))"
  1708   by auto
  1709 
  1710 lemma ball_simps [simp]:
  1711   "!!A P Q. (ALL x:A. P x | Q) = ((ALL x:A. P x) | Q)"
  1712   "!!A P Q. (ALL x:A. P | Q x) = (P | (ALL x:A. Q x))"
  1713   "!!A P Q. (ALL x:A. P --> Q x) = (P --> (ALL x:A. Q x))"
  1714   "!!A P Q. (ALL x:A. P x --> Q) = ((EX x:A. P x) --> Q)"
  1715   "!!P. (ALL x:{}. P x) = True"
  1716   "!!P. (ALL x:UNIV. P x) = (ALL x. P x)"
  1717   "!!a B P. (ALL x:insert a B. P x) = (P a & (ALL x:B. P x))"
  1718   "!!A P. (ALL x:Union A. P x) = (ALL y:A. ALL x:y. P x)"
  1719   "!!A B P. (ALL x: UNION A B. P x) = (ALL a:A. ALL x: B a. P x)"
  1720   "!!P Q. (ALL x:Collect Q. P x) = (ALL x. Q x --> P x)"
  1721   "!!A P f. (ALL x:f`A. P x) = (ALL x:A. P (f x))"
  1722   "!!A P. (~(ALL x:A. P x)) = (EX x:A. ~P x)"
  1723   by auto
  1724 
  1725 lemma bex_simps [simp]:
  1726   "!!A P Q. (EX x:A. P x & Q) = ((EX x:A. P x) & Q)"
  1727   "!!A P Q. (EX x:A. P & Q x) = (P & (EX x:A. Q x))"
  1728   "!!P. (EX x:{}. P x) = False"
  1729   "!!P. (EX x:UNIV. P x) = (EX x. P x)"
  1730   "!!a B P. (EX x:insert a B. P x) = (P(a) | (EX x:B. P x))"
  1731   "!!A P. (EX x:Union A. P x) = (EX y:A. EX x:y. P x)"
  1732   "!!A B P. (EX x: UNION A B. P x) = (EX a:A. EX x:B a. P x)"
  1733   "!!P Q. (EX x:Collect Q. P x) = (EX x. Q x & P x)"
  1734   "!!A P f. (EX x:f`A. P x) = (EX x:A. P (f x))"
  1735   "!!A P. (~(EX x:A. P x)) = (ALL x:A. ~P x)"
  1736   by auto
  1737 
  1738 lemma ball_conj_distrib:
  1739   "(ALL x:A. P x & Q x) = ((ALL x:A. P x) & (ALL x:A. Q x))"
  1740   by blast
  1741 
  1742 lemma bex_disj_distrib:
  1743   "(EX x:A. P x | Q x) = ((EX x:A. P x) | (EX x:A. Q x))"
  1744   by blast
  1745 
  1746 
  1747 text {* \medskip Maxiscoping: pulling out big Unions and Intersections. *}
  1748 
  1749 lemma UN_extend_simps:
  1750   "!!a B C. insert a (UN x:C. B x) = (if C={} then {a} else (UN x:C. insert a (B x)))"
  1751   "!!A B C. (UN x:C. A x) Un B    = (if C={} then B else (UN x:C. A x Un B))"
  1752   "!!A B C. A Un (UN x:C. B x)   = (if C={} then A else (UN x:C. A Un B x))"
  1753   "!!A B C. ((UN x:C. A x) Int B) = (UN x:C. A x Int B)"
  1754   "!!A B C. (A Int (UN x:C. B x)) = (UN x:C. A Int B x)"
  1755   "!!A B C. ((UN x:C. A x) - B) = (UN x:C. A x - B)"
  1756   "!!A B C. (A - (INT x:C. B x)) = (UN x:C. A - B x)"
  1757   "!!A B. (UN y:A. UN x:y. B x) = (UN x: Union A. B x)"
  1758   "!!A B C. (UN  x:A. UN z: B(x). C z) = (UN z: UNION A B. C z)"
  1759   "!!A B f. (UN a:A. B (f a)) = (UN x:f`A. B x)"
  1760   by auto
  1761 
  1762 lemma INT_extend_simps:
  1763   "!!A B C. (INT x:C. A x) Int B = (if C={} then B else (INT x:C. A x Int B))"
  1764   "!!A B C. A Int (INT x:C. B x) = (if C={} then A else (INT x:C. A Int B x))"
  1765   "!!A B C. (INT x:C. A x) - B   = (if C={} then UNIV-B else (INT x:C. A x - B))"
  1766   "!!A B C. A - (UN x:C. B x)   = (if C={} then A else (INT x:C. A - B x))"
  1767   "!!a B C. insert a (INT x:C. B x) = (INT x:C. insert a (B x))"
  1768   "!!A B C. ((INT x:C. A x) Un B)  = (INT x:C. A x Un B)"
  1769   "!!A B C. A Un (INT x:C. B x)  = (INT x:C. A Un B x)"
  1770   "!!A B. (INT y:A. INT x:y. B x) = (INT x: Union A. B x)"
  1771   "!!A B C. (INT x:A. INT z: B(x). C z) = (INT z: UNION A B. C z)"
  1772   "!!A B f. (INT a:A. B (f a))    = (INT x:f`A. B x)"
  1773   by auto
  1774 
  1775 
  1776 subsubsection {* Monotonicity of various operations *}
  1777 
  1778 lemma image_mono: "A \<subseteq> B ==> f`A \<subseteq> f`B"
  1779   by blast
  1780 
  1781 lemma Pow_mono: "A \<subseteq> B ==> Pow A \<subseteq> Pow B"
  1782   by blast
  1783 
  1784 lemma Union_mono: "A \<subseteq> B ==> \<Union>A \<subseteq> \<Union>B"
  1785   by blast
  1786 
  1787 lemma Inter_anti_mono: "B \<subseteq> A ==> \<Inter>A \<subseteq> \<Inter>B"
  1788   by blast
  1789 
  1790 lemma UN_mono:
  1791   "A \<subseteq> B ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1792     (\<Union>x\<in>A. f x) \<subseteq> (\<Union>x\<in>B. g x)"
  1793   by (blast dest: subsetD)
  1794 
  1795 lemma INT_anti_mono:
  1796   "B \<subseteq> A ==> (!!x. x \<in> A ==> f x \<subseteq> g x) ==>
  1797     (\<Inter>x\<in>A. f x) \<subseteq> (\<Inter>x\<in>A. g x)"
  1798   -- {* The last inclusion is POSITIVE! *}
  1799   by (blast dest: subsetD)
  1800 
  1801 lemma insert_mono: "C \<subseteq> D ==> insert a C \<subseteq> insert a D"
  1802   by blast
  1803 
  1804 lemma Un_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<union> B \<subseteq> C \<union> D"
  1805   by blast
  1806 
  1807 lemma Int_mono: "A \<subseteq> C ==> B \<subseteq> D ==> A \<inter> B \<subseteq> C \<inter> D"
  1808   by blast
  1809 
  1810 lemma Diff_mono: "A \<subseteq> C ==> D \<subseteq> B ==> A - B \<subseteq> C - D"
  1811   by blast
  1812 
  1813 lemma Compl_anti_mono: "A \<subseteq> B ==> -B \<subseteq> -A"
  1814   by blast
  1815 
  1816 text {* \medskip Monotonicity of implications. *}
  1817 
  1818 lemma in_mono: "A \<subseteq> B ==> x \<in> A --> x \<in> B"
  1819   apply (rule impI)
  1820   apply (erule subsetD, assumption)
  1821   done
  1822 
  1823 lemma conj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 & P2) --> (Q1 & Q2)"
  1824   by rules
  1825 
  1826 lemma disj_mono: "P1 --> Q1 ==> P2 --> Q2 ==> (P1 | P2) --> (Q1 | Q2)"
  1827   by rules
  1828 
  1829 lemma imp_mono: "Q1 --> P1 ==> P2 --> Q2 ==> (P1 --> P2) --> (Q1 --> Q2)"
  1830   by rules
  1831 
  1832 lemma imp_refl: "P --> P" ..
  1833 
  1834 lemma ex_mono: "(!!x. P x --> Q x) ==> (EX x. P x) --> (EX x. Q x)"
  1835   by rules
  1836 
  1837 lemma all_mono: "(!!x. P x --> Q x) ==> (ALL x. P x) --> (ALL x. Q x)"
  1838   by rules
  1839 
  1840 lemma Collect_mono: "(!!x. P x --> Q x) ==> Collect P \<subseteq> Collect Q"
  1841   by blast
  1842 
  1843 lemma Int_Collect_mono:
  1844     "A \<subseteq> B ==> (!!x. x \<in> A ==> P x --> Q x) ==> A \<inter> Collect P \<subseteq> B \<inter> Collect Q"
  1845   by blast
  1846 
  1847 lemmas basic_monos =
  1848   subset_refl imp_refl disj_mono conj_mono
  1849   ex_mono Collect_mono in_mono
  1850 
  1851 lemma eq_to_mono: "a = b ==> c = d ==> b --> d ==> a --> c"
  1852   by rules
  1853 
  1854 lemma eq_to_mono2: "a = b ==> c = d ==> ~ b --> ~ d ==> ~ a --> ~ c"
  1855   by rules
  1856 
  1857 lemma Least_mono:
  1858   "mono (f::'a::order => 'b::order) ==> EX x:S. ALL y:S. x <= y
  1859     ==> (LEAST y. y : f ` S) = f (LEAST x. x : S)"
  1860     -- {* Courtesy of Stephan Merz *}
  1861   apply clarify
  1862   apply (erule_tac P = "%x. x : S" in LeastI2, fast)
  1863   apply (rule LeastI2)
  1864   apply (auto elim: monoD intro!: order_antisym)
  1865   done
  1866 
  1867 
  1868 subsection {* Inverse image of a function *}
  1869 
  1870 constdefs
  1871   vimage :: "('a => 'b) => 'b set => 'a set"    (infixr "-`" 90)
  1872   "f -` B == {x. f x : B}"
  1873 
  1874 
  1875 subsubsection {* Basic rules *}
  1876 
  1877 lemma vimage_eq [simp]: "(a : f -` B) = (f a : B)"
  1878   by (unfold vimage_def) blast
  1879 
  1880 lemma vimage_singleton_eq: "(a : f -` {b}) = (f a = b)"
  1881   by simp
  1882 
  1883 lemma vimageI [intro]: "f a = b ==> b:B ==> a : f -` B"
  1884   by (unfold vimage_def) blast
  1885 
  1886 lemma vimageI2: "f a : A ==> a : f -` A"
  1887   by (unfold vimage_def) fast
  1888 
  1889 lemma vimageE [elim!]: "a: f -` B ==> (!!x. f a = x ==> x:B ==> P) ==> P"
  1890   by (unfold vimage_def) blast
  1891 
  1892 lemma vimageD: "a : f -` A ==> f a : A"
  1893   by (unfold vimage_def) fast
  1894 
  1895 
  1896 subsubsection {* Equations *}
  1897 
  1898 lemma vimage_empty [simp]: "f -` {} = {}"
  1899   by blast
  1900 
  1901 lemma vimage_Compl: "f -` (-A) = -(f -` A)"
  1902   by blast
  1903 
  1904 lemma vimage_Un [simp]: "f -` (A Un B) = (f -` A) Un (f -` B)"
  1905   by blast
  1906 
  1907 lemma vimage_Int [simp]: "f -` (A Int B) = (f -` A) Int (f -` B)"
  1908   by fast
  1909 
  1910 lemma vimage_Union: "f -` (Union A) = (UN X:A. f -` X)"
  1911   by blast
  1912 
  1913 lemma vimage_UN: "f-`(UN x:A. B x) = (UN x:A. f -` B x)"
  1914   by blast
  1915 
  1916 lemma vimage_INT: "f-`(INT x:A. B x) = (INT x:A. f -` B x)"
  1917   by blast
  1918 
  1919 lemma vimage_Collect_eq [simp]: "f -` Collect P = {y. P (f y)}"
  1920   by blast
  1921 
  1922 lemma vimage_Collect: "(!!x. P (f x) = Q x) ==> f -` (Collect P) = Collect Q"
  1923   by blast
  1924 
  1925 lemma vimage_insert: "f-`(insert a B) = (f-`{a}) Un (f-`B)"
  1926   -- {* NOT suitable for rewriting because of the recurrence of @{term "{a}"}. *}
  1927   by blast
  1928 
  1929 lemma vimage_Diff: "f -` (A - B) = (f -` A) - (f -` B)"
  1930   by blast
  1931 
  1932 lemma vimage_UNIV [simp]: "f -` UNIV = UNIV"
  1933   by blast
  1934 
  1935 lemma vimage_eq_UN: "f-`B = (UN y: B. f-`{y})"
  1936   -- {* NOT suitable for rewriting *}
  1937   by blast
  1938 
  1939 lemma vimage_mono: "A \<subseteq> B ==> f -` A \<subseteq> f -` B"
  1940   -- {* monotonicity *}
  1941   by blast
  1942 
  1943 
  1944 subsection {* Transitivity rules for calculational reasoning *}
  1945 
  1946 lemma forw_subst: "a = b ==> P b ==> P a"
  1947   by (rule ssubst)
  1948 
  1949 lemma back_subst: "P a ==> a = b ==> P b"
  1950   by (rule subst)
  1951 
  1952 lemma set_rev_mp: "x:A ==> A \<subseteq> B ==> x:B"
  1953   by (rule subsetD)
  1954 
  1955 lemma set_mp: "A \<subseteq> B ==> x:A ==> x:B"
  1956   by (rule subsetD)
  1957 
  1958 lemma order_neq_le_trans: "a ~= b ==> (a::'a::order) <= b ==> a < b"
  1959   by (simp add: order_less_le)
  1960 
  1961 lemma order_le_neq_trans: "(a::'a::order) <= b ==> a ~= b ==> a < b"
  1962   by (simp add: order_less_le)
  1963 
  1964 lemma order_less_asym': "(a::'a::order) < b ==> b < a ==> P"
  1965   by (rule order_less_asym)
  1966 
  1967 lemma ord_le_eq_trans: "a <= b ==> b = c ==> a <= c"
  1968   by (rule subst)
  1969 
  1970 lemma ord_eq_le_trans: "a = b ==> b <= c ==> a <= c"
  1971   by (rule ssubst)
  1972 
  1973 lemma ord_less_eq_trans: "a < b ==> b = c ==> a < c"
  1974   by (rule subst)
  1975 
  1976 lemma ord_eq_less_trans: "a = b ==> b < c ==> a < c"
  1977   by (rule ssubst)
  1978 
  1979 lemma order_less_subst2: "(a::'a::order) < b ==> f b < (c::'c::order) ==>
  1980   (!!x y. x < y ==> f x < f y) ==> f a < c"
  1981 proof -
  1982   assume r: "!!x y. x < y ==> f x < f y"
  1983   assume "a < b" hence "f a < f b" by (rule r)
  1984   also assume "f b < c"
  1985   finally (order_less_trans) show ?thesis .
  1986 qed
  1987 
  1988 lemma order_less_subst1: "(a::'a::order) < f b ==> (b::'b::order) < c ==>
  1989   (!!x y. x < y ==> f x < f y) ==> a < f c"
  1990 proof -
  1991   assume r: "!!x y. x < y ==> f x < f y"
  1992   assume "a < f b"
  1993   also assume "b < c" hence "f b < f c" by (rule r)
  1994   finally (order_less_trans) show ?thesis .
  1995 qed
  1996 
  1997 lemma order_le_less_subst2: "(a::'a::order) <= b ==> f b < (c::'c::order) ==>
  1998   (!!x y. x <= y ==> f x <= f y) ==> f a < c"
  1999 proof -
  2000   assume r: "!!x y. x <= y ==> f x <= f y"
  2001   assume "a <= b" hence "f a <= f b" by (rule r)
  2002   also assume "f b < c"
  2003   finally (order_le_less_trans) show ?thesis .
  2004 qed
  2005 
  2006 lemma order_le_less_subst1: "(a::'a::order) <= f b ==> (b::'b::order) < c ==>
  2007   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2008 proof -
  2009   assume r: "!!x y. x < y ==> f x < f y"
  2010   assume "a <= f b"
  2011   also assume "b < c" hence "f b < f c" by (rule r)
  2012   finally (order_le_less_trans) show ?thesis .
  2013 qed
  2014 
  2015 lemma order_less_le_subst2: "(a::'a::order) < b ==> f b <= (c::'c::order) ==>
  2016   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2017 proof -
  2018   assume r: "!!x y. x < y ==> f x < f y"
  2019   assume "a < b" hence "f a < f b" by (rule r)
  2020   also assume "f b <= c"
  2021   finally (order_less_le_trans) show ?thesis .
  2022 qed
  2023 
  2024 lemma order_less_le_subst1: "(a::'a::order) < f b ==> (b::'b::order) <= c ==>
  2025   (!!x y. x <= y ==> f x <= f y) ==> a < f c"
  2026 proof -
  2027   assume r: "!!x y. x <= y ==> f x <= f y"
  2028   assume "a < f b"
  2029   also assume "b <= c" hence "f b <= f c" by (rule r)
  2030   finally (order_less_le_trans) show ?thesis .
  2031 qed
  2032 
  2033 lemma order_subst1: "(a::'a::order) <= f b ==> (b::'b::order) <= c ==>
  2034   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2035 proof -
  2036   assume r: "!!x y. x <= y ==> f x <= f y"
  2037   assume "a <= f b"
  2038   also assume "b <= c" hence "f b <= f c" by (rule r)
  2039   finally (order_trans) show ?thesis .
  2040 qed
  2041 
  2042 lemma order_subst2: "(a::'a::order) <= b ==> f b <= (c::'c::order) ==>
  2043   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2044 proof -
  2045   assume r: "!!x y. x <= y ==> f x <= f y"
  2046   assume "a <= b" hence "f a <= f b" by (rule r)
  2047   also assume "f b <= c"
  2048   finally (order_trans) show ?thesis .
  2049 qed
  2050 
  2051 lemma ord_le_eq_subst: "a <= b ==> f b = c ==>
  2052   (!!x y. x <= y ==> f x <= f y) ==> f a <= c"
  2053 proof -
  2054   assume r: "!!x y. x <= y ==> f x <= f y"
  2055   assume "a <= b" hence "f a <= f b" by (rule r)
  2056   also assume "f b = c"
  2057   finally (ord_le_eq_trans) show ?thesis .
  2058 qed
  2059 
  2060 lemma ord_eq_le_subst: "a = f b ==> b <= c ==>
  2061   (!!x y. x <= y ==> f x <= f y) ==> a <= f c"
  2062 proof -
  2063   assume r: "!!x y. x <= y ==> f x <= f y"
  2064   assume "a = f b"
  2065   also assume "b <= c" hence "f b <= f c" by (rule r)
  2066   finally (ord_eq_le_trans) show ?thesis .
  2067 qed
  2068 
  2069 lemma ord_less_eq_subst: "a < b ==> f b = c ==>
  2070   (!!x y. x < y ==> f x < f y) ==> f a < c"
  2071 proof -
  2072   assume r: "!!x y. x < y ==> f x < f y"
  2073   assume "a < b" hence "f a < f b" by (rule r)
  2074   also assume "f b = c"
  2075   finally (ord_less_eq_trans) show ?thesis .
  2076 qed
  2077 
  2078 lemma ord_eq_less_subst: "a = f b ==> b < c ==>
  2079   (!!x y. x < y ==> f x < f y) ==> a < f c"
  2080 proof -
  2081   assume r: "!!x y. x < y ==> f x < f y"
  2082   assume "a = f b"
  2083   also assume "b < c" hence "f b < f c" by (rule r)
  2084   finally (ord_eq_less_trans) show ?thesis .
  2085 qed
  2086 
  2087 text {*
  2088   Note that this list of rules is in reverse order of priorities.
  2089 *}
  2090 
  2091 lemmas basic_trans_rules [trans] =
  2092   order_less_subst2
  2093   order_less_subst1
  2094   order_le_less_subst2
  2095   order_le_less_subst1
  2096   order_less_le_subst2
  2097   order_less_le_subst1
  2098   order_subst2
  2099   order_subst1
  2100   ord_le_eq_subst
  2101   ord_eq_le_subst
  2102   ord_less_eq_subst
  2103   ord_eq_less_subst
  2104   forw_subst
  2105   back_subst
  2106   rev_mp
  2107   mp
  2108   set_rev_mp
  2109   set_mp
  2110   order_neq_le_trans
  2111   order_le_neq_trans
  2112   order_less_trans
  2113   order_less_asym'
  2114   order_le_less_trans
  2115   order_less_le_trans
  2116   order_trans
  2117   order_antisym
  2118   ord_le_eq_trans
  2119   ord_eq_le_trans
  2120   ord_less_eq_trans
  2121   ord_eq_less_trans
  2122   trans
  2123 
  2124 end